cc17f84ccc
`std.GeneralPurposeAllocator` is now available. It is a function that takes a configuration struct (with default field values) and returns an allocator. There is a detailed description of this allocator in the doc comments at the top of the new file. The main feature of this allocator is that it is *safe*. It prevents double-free, use-after-free, and detects leaks. Some deprecation compile errors are removed. The Allocator interface gains `old_align` as a new parameter to `resizeFn`. This is useful to quickly look up allocations. `std.heap.page_allocator` is improved to use mmap address hints to avoid obtaining the same virtual address pages when unmapping and mapping pages. The new general purpose allocator uses the page allocator as its backing allocator by default. `std.testing.allocator` is replaced with usage of this new allocator, which does leak checking, and so the LeakCheckAllocator is retired. stage1 is improved so that the `@typeInfo` of a pointer has a lazy value for the alignment of the child type, to avoid false dependency loops when dealing with pointers to async function frames. The `std.mem.Allocator` interface is refactored to be in its own file. `std.Mutex` now exposes the dummy mutex with `std.Mutex.Dummy`. This allocator is great for debug mode, however it needs some work to have better performance in release modes. The next step will be setting up a series of tests in ziglang/gotta-go-fast and then making improvements to the implementation.
83 lines
2.9 KiB
Zig
83 lines
2.9 KiB
Zig
const std = @import("../std.zig");
|
|
const mem = std.mem;
|
|
|
|
/// Allocator that fails after N allocations, useful for making sure out of
|
|
/// memory conditions are handled correctly.
|
|
///
|
|
/// To use this, first initialize it and get an allocator with
|
|
///
|
|
/// `const failing_allocator = &FailingAllocator.init(<allocator>,
|
|
/// <fail_index>).allocator;`
|
|
///
|
|
/// Then use `failing_allocator` anywhere you would have used a
|
|
/// different allocator.
|
|
pub const FailingAllocator = struct {
|
|
allocator: mem.Allocator,
|
|
index: usize,
|
|
fail_index: usize,
|
|
internal_allocator: *mem.Allocator,
|
|
allocated_bytes: usize,
|
|
freed_bytes: usize,
|
|
allocations: usize,
|
|
deallocations: usize,
|
|
|
|
/// `fail_index` is the number of successful allocations you can
|
|
/// expect from this allocator. The next allocation will fail.
|
|
/// For example, if this is called with `fail_index` equal to 2,
|
|
/// the following test will pass:
|
|
///
|
|
/// var a = try failing_alloc.create(i32);
|
|
/// var b = try failing_alloc.create(i32);
|
|
/// testing.expectError(error.OutOfMemory, failing_alloc.create(i32));
|
|
pub fn init(allocator: *mem.Allocator, fail_index: usize) FailingAllocator {
|
|
return FailingAllocator{
|
|
.internal_allocator = allocator,
|
|
.fail_index = fail_index,
|
|
.index = 0,
|
|
.allocated_bytes = 0,
|
|
.freed_bytes = 0,
|
|
.allocations = 0,
|
|
.deallocations = 0,
|
|
.allocator = mem.Allocator{
|
|
.allocFn = alloc,
|
|
.resizeFn = resize,
|
|
},
|
|
};
|
|
}
|
|
|
|
fn alloc(allocator: *std.mem.Allocator, len: usize, ptr_align: u29, len_align: u29) error{OutOfMemory}![]u8 {
|
|
const self = @fieldParentPtr(FailingAllocator, "allocator", allocator);
|
|
if (self.index == self.fail_index) {
|
|
return error.OutOfMemory;
|
|
}
|
|
const result = try self.internal_allocator.allocFn(self.internal_allocator, len, ptr_align, len_align);
|
|
self.allocated_bytes += result.len;
|
|
self.allocations += 1;
|
|
self.index += 1;
|
|
return result;
|
|
}
|
|
|
|
fn resize(
|
|
allocator: *std.mem.Allocator,
|
|
old_mem: []u8,
|
|
old_align: u29,
|
|
new_len: usize,
|
|
len_align: u29,
|
|
) error{OutOfMemory}!usize {
|
|
const self = @fieldParentPtr(FailingAllocator, "allocator", allocator);
|
|
const r = self.internal_allocator.resizeFn(self.internal_allocator, old_mem, old_align, new_len, len_align) catch |e| {
|
|
std.debug.assert(new_len > old_mem.len);
|
|
return e;
|
|
};
|
|
if (new_len == 0) {
|
|
self.deallocations += 1;
|
|
self.freed_bytes += old_mem.len;
|
|
} else if (r < old_mem.len) {
|
|
self.freed_bytes += old_mem.len - r;
|
|
} else {
|
|
self.allocated_bytes += r - old_mem.len;
|
|
}
|
|
return r;
|
|
}
|
|
};
|