136 lines
4.1 KiB
OCaml
136 lines
4.1 KiB
OCaml
(***********************************************************************)
|
|
(* *)
|
|
(* Objective Caml *)
|
|
(* *)
|
|
(* Xavier Leroy, projet Cristal, INRIA Rocquencourt *)
|
|
(* *)
|
|
(* Copyright 1996 Institut National de Recherche en Informatique et *)
|
|
(* Automatique. Distributed only by permission. *)
|
|
(* *)
|
|
(***********************************************************************)
|
|
|
|
(* $Id$ *)
|
|
|
|
module type OrderedType =
|
|
sig
|
|
type t
|
|
val compare: t -> t -> int
|
|
end
|
|
|
|
module type S =
|
|
sig
|
|
type key
|
|
type 'a t
|
|
val empty: 'a t
|
|
val add: key -> 'a -> 'a t -> 'a t
|
|
val find: key -> 'a t -> 'a
|
|
val remove: key -> 'a t -> 'a t
|
|
val iter: (key -> 'a -> 'b) -> 'a t -> unit
|
|
val map: ('a -> 'b) -> 'a t -> 'b t
|
|
val fold: (key -> 'a -> 'b -> 'b) -> 'a t -> 'b -> 'b
|
|
end
|
|
|
|
module Make(Ord: OrderedType) = struct
|
|
|
|
type key = Ord.t
|
|
|
|
type 'a t =
|
|
Empty
|
|
| Node of 'a t * key * 'a * 'a t * int
|
|
|
|
let empty = Empty
|
|
|
|
let height = function
|
|
Empty -> 0
|
|
| Node(_,_,_,_,h) -> h
|
|
|
|
let create l x d r =
|
|
let hl = height l and hr = height r in
|
|
Node(l, x, d, r, (if hl >= hr then hl + 1 else hr + 1))
|
|
|
|
let bal l x d r =
|
|
let hl = match l with Empty -> 0 | Node(_,_,_,_,h) -> h in
|
|
let hr = match r with Empty -> 0 | Node(_,_,_,_,h) -> h in
|
|
if hl > hr + 2 then begin
|
|
match l with
|
|
Empty -> invalid_arg "Map.bal"
|
|
| Node(ll, lv, ld, lr, _) ->
|
|
if height ll >= height lr then
|
|
create ll lv ld (create lr x d r)
|
|
else begin
|
|
match lr with
|
|
Empty -> invalid_arg "Map.bal"
|
|
| Node(lrl, lrv, lrd, lrr, _)->
|
|
create (create ll lv ld lrl) lrv lrd (create lrr x d r)
|
|
end
|
|
end else if hr > hl + 2 then begin
|
|
match r with
|
|
Empty -> invalid_arg "Map.bal"
|
|
| Node(rl, rv, rd, rr, _) ->
|
|
if height rr >= height rl then
|
|
create (create l x d rl) rv rd rr
|
|
else begin
|
|
match rl with
|
|
Empty -> invalid_arg "Map.bal"
|
|
| Node(rll, rlv, rld, rlr, _) ->
|
|
create (create l x d rll) rlv rld (create rlr rv rd rr)
|
|
end
|
|
end else
|
|
Node(l, x, d, r, (if hl >= hr then hl + 1 else hr + 1))
|
|
|
|
let rec add x data = function
|
|
Empty ->
|
|
Node(Empty, x, data, Empty, 1)
|
|
| Node(l, v, d, r, h) as t ->
|
|
let c = Ord.compare x v in
|
|
if c = 0 then
|
|
Node(l, x, data, r, h)
|
|
else if c < 0 then
|
|
bal (add x data l) v d r
|
|
else
|
|
bal l v d (add x data r)
|
|
|
|
let rec find x = function
|
|
Empty ->
|
|
raise Not_found
|
|
| Node(l, v, d, r, _) ->
|
|
let c = Ord.compare x v in
|
|
if c = 0 then d
|
|
else find x (if c < 0 then l else r)
|
|
|
|
let rec merge t1 t2 =
|
|
match (t1, t2) with
|
|
(Empty, t) -> t
|
|
| (t, Empty) -> t
|
|
| (Node(l1, v1, d1, r1, h1), Node(l2, v2, d2, r2, h2)) ->
|
|
bal l1 v1 d1 (bal (merge r1 l2) v2 d2 r2)
|
|
|
|
let rec remove x = function
|
|
Empty ->
|
|
Empty
|
|
| Node(l, v, d, r, h) as t ->
|
|
let c = Ord.compare x v in
|
|
if c = 0 then
|
|
merge l r
|
|
else if c < 0 then
|
|
bal (remove x l) v d r
|
|
else
|
|
bal l v d (remove x r)
|
|
|
|
let rec iter f = function
|
|
Empty -> ()
|
|
| Node(l, v, d, r, _) ->
|
|
iter f l; f v d; iter f r
|
|
|
|
let rec map f = function
|
|
Empty -> Empty
|
|
| Node(l, v, d, r, h) -> Node(map f l, v, f d, map f r, h)
|
|
|
|
let rec fold f m accu =
|
|
match m with
|
|
Empty -> accu
|
|
| Node(l, v, d, r, _) ->
|
|
fold f l (f v d (fold f r accu))
|
|
|
|
end
|