#
#   moo/configure.ac
#

m4_define([moo_major_version], [0])
m4_define([moo_minor_version], [6])
m4_define([moo_micro_version], [2])
m4_define([moo_version], [moo_major_version.moo_minor_version.moo_micro_version])

AC_INIT(libmoo, [moo_version], [muntyan@math.tamu.edu], libmoo)
AM_INIT_AUTOMAKE(libmoo, [moo_version])
AC_CANONICAL_HOST

AC_CONFIG_HEADERS(config.h)
MOO_DEFINE_VERSIONS

AC_PROG_CC
AC_PROG_CC_STDC
AC_HEADER_STDC
# AC_LIBTOOL_WIN32_DLL
# AC_PROG_LIBTOOL
AC_PROG_INSTALL
MOO_AC_PROG_WINDRES

AC_SUBST(ACLOCAL_FLAGS)

#  Misc stuff
MOO_AC_FUNCS

#  Check debug options
MOO_AC_DEBUG

#  Check operating system
MOO_AC_CHECK_OS

#  GTK libraries
MOO_PKG_CHECK_GTK_VERSIONS

#  File monitoring
MOO_AC_FAM

#  libxml2
MOO_AC_XML

#  xdgmime
MOO_AC_XDGMIME

#  Python stuff
MOO_AC_PYGTK

# pcre
MOO_AC_PCRE


# Components
MOO_COMPONENTS


moo_top_src_dir=`cd $srcdir && pwd`
moo_top_build_dir=`cd ./$ac_top_builddir && pwd`
MOO_CFLAGS="-I$moo_top_src_dir/moo $GTK_CFLAGS -DXDG_PREFIX=_moo_edit_xdg -DG_LOG_DOMAIN=\\\"Moo\\\" -D__MOO__ -DMOO_MARSHALS_H=\\\"mooutils/moomarshals.h\\\""
MOO_LIBS="$GTK_LIBS $MOO_LIBS"

if test x$MOO_USE_FAM = xyes; then
    MOO_LIBS="$FAM_LIBS $MOO_LIBS"
fi

AC_SUBST(MOO_CFLAGS)
AC_SUBST(MOO_LIBS)


################################################################################
#  MooEdit stuff
#
if test "x$build_mooedit" != "xno"; then
    MOO_CFLAGS="$MOO_CFLAGS $XML_CFLAGS"
    MOO_LIBS="$MOO_LIBS $XML_LIBS"
fi


################################################################################
#  Installation directories, etc.
#
MOO_SRC_PREFIX="moo"
AC_SUBST(MOO_SRC_PREFIX)

if test "x${prefix}" = "xNONE"; then
  mooprefix=${ac_default_prefix}
else
  mooprefix=${prefix}
fi

moodatadir=share

moorootdir=${moodatadir}/moo-1.0
NO_PREFIX_MOO_ROOT_DIR="${moorootdir}"
AC_SUBST(NO_PREFIX_MOO_ROOT_DIR)
MOO_ROOT_DIR="${mooprefix}/${moorootdir}"
AC_SUBST(MOO_ROOT_DIR)

AC_DEFINE_UNQUOTED(MOO_ROOT_DIR, "${mooprefix}/${moorootdir}", [data files go to MOO_ROOT_DIR])

MOO_TEXT_LANG_FILES_DIR="${mooprefix}/${moorootdir}/syntax"
AC_SUBST(MOO_TEXT_LANG_FILES_DIR)
AC_DEFINE_UNQUOTED(MOO_TEXT_LANG_FILES_DIR, "${mooprefix}/${moorootdir}/syntax", [lang files dir])


moolibdir=lib/moo-1.0
NO_PREFIX_MOO_LIB_DIR="${moolibdir}"
AC_SUBST(NO_PREFIX_MOO_LIB_DIR)
MOO_LIB_DIR="${mooprefix}/${moolibdir}"
AC_SUBST(MOO_LIB_DIR)
AC_DEFINE_UNQUOTED(MOO_LIB_DIR, "${mooprefix}/${moolibdir}", [plugins and stuff go to MOO_LIB_DIR])
MOO_PLUGINS_DIR="${mooprefix}/${moolibdir}/plugins"
AC_SUBST(MOO_PLUGINS_DIR)
AC_DEFINE_UNQUOTED(MOO_PLUGINS_DIR, "${mooprefix}/${moolibdir}/plugins", [plugins dir])


AM_CONDITIONAL(MOO_BUILD_LIB, false)


################################################################################
#  Created files
#
AC_OUTPUT([
Makefile
moo/mooterm/termhelper_res.rc
moo/mooutils/pcre/pcre.h
moo/moopython/pygtk/moo-mod.py
moo/moo.pc
tests/pyapp.py
m4/Makefile
])


################################################################################
#  Configuration info
#
if test x$MOO_OS_CYGWIN != "xyes"; then
    if test "x$MOO_OS_MINGW" = "xyes"; then
        system="MINGW"
    elif test "x$MOO_OS_DARWIN" = "xyes"; then
        system="UNIX (DARWIN)"
    elif test "x$MOO_OS_BSD" = "xyes"; then
        system="UNIX (BSD)"
    else
        system="UNIX"
    fi

    if test x$use_xml != "xyes"; then
        use_xml="no"
    fi

    echo
    echo "    OS                                        = $system"
    echo "    python support                            = $MOO_USE_PYTHON"
    echo "    pygtk support                             = $MOO_USE_PYGTK"
    echo "    xml support                               = $MOO_USE_XML"
    echo "    fam support                               = $MOO_USE_FAM"
    echo "    xdgmime support                           = $MOO_USE_XDGMIME"
    echo
    echo "    prefix                                    = $mooprefix"
    echo "    editor lang files go to                   = $MOO_TEXT_LANG_FILES_DIR"
    echo "    plugins go to                             = $MOO_PLUGINS_DIR"
    echo
    echo "    components: $MOO_BUILD_COMPS"
else
    echo
    echo "    Building termhelper.exe on CYGWIN"
    echo
fi