commit 7edfae6d56d324431300bb322e285a29f8ed67ad
Author: historicalsource <historicalsoftware@textfiles.com>
Date:   Tue Apr 16 09:35:32 2019 -0400

    Release Version

diff --git a/README.md b/README.md
new file mode 100644
index 0000000..0684440
--- /dev/null
+++ b/README.md
@@ -0,0 +1 @@
+# shogun
diff --git a/a5.zil b/a5.zil
new file mode 100644
index 0000000..2f2facb
--- /dev/null
+++ b/a5.zil
@@ -0,0 +1,80 @@
+"A5 for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc. All Rights Reserved."
+
+<PRINC "
+*** SHOGUN: A Story of Japan ***
+">
+
+<VERSION YZIP>
+<ZIP-OPTIONS BIG COLOR UNDO MOUSE DISPLAY>
+<SETG NEW-PARSER? T>		;"use new parser"
+<FREQUENT-WORDS?>		;"include frequent words"
+<SET REDEFINE T>		;"don't stop and ask"
+<ORDER-OBJECTS? ROOMS-FIRST>
+<NEVER-ZAP-TO-SOURCE-DIRECTORY?>
+
+;"segments"
+
+<DEFINE-SEGMENT STARTUP T>
+<DEFINE-SEGMENT RECORD <>>
+<DEFINE-SEGMENT ERASMUS <> ANJIRO>
+<DEFINE-SEGMENT ANJIRO <> ERASMUS YABU>
+<DEFINE-SEGMENT YABU <> ANJIRO PIT>
+<DEFINE-SEGMENT PIT <> YABU RODRIGUES>
+<DEFINE-SEGMENT RODRIGUES <> PIT VOYAGE>
+<DEFINE-SEGMENT VOYAGE <> RODRIGUES AUDIENCE>
+<DEFINE-SEGMENT AUDIENCE <> VOYAGE PRISON>
+<DEFINE-SEGMENT PRISON <> AUDIENCE MARIKO>
+<DEFINE-SEGMENT MARIKO <> PRISON ESCAPE>
+<DEFINE-SEGMENT ESCAPE <> MARIKO MAZE>
+<DEFINE-SEGMENT MAZE <> ESCAPE QUAKE>
+<DEFINE-SEGMENT QUAKE <> MAZE ZATAKI>
+<DEFINE-SEGMENT ZATAKI <> QUAKE YOKOSE>
+<DEFINE-SEGMENT YOKOSE <> ZATAKI OCHIBA>
+<DEFINE-SEGMENT OCHIBA <> YOKOSE DEPARTURE>
+<DEFINE-SEGMENT DEPARTURE <> OCHIBA SEPPUKU>
+<DEFINE-SEGMENT SEPPUKU <> DEPARTURE NINJA>
+<DEFINE-SEGMENT NINJA <> SEPPUKU YOKOHAMA>
+<DEFINE-SEGMENT YOKOHAMA <> NINJA AFTERMATH>
+<DEFINE-SEGMENT AFTERMATH <> YOKOHAMA SEKIGAHARA>
+<DEFINE-SEGMENT SEKIGAHARA <> AFTERMATH>
+<DEFINE-SEGMENT HINTS <>>
+
+<INSERT-FILE "DEFS">		;"redefinitions"
+<XFLOAD "~INTERLOGIC/ZILLIB/PARSER/PARSER.SHOGUN">	;"new parser"
+
+;"game substrate"
+
+<INSERT-FILE "PICDEF">		;"picture constants"
+<INSERT-FILE "MISC">
+<INSERT-FILE "~INTERLOGIC/ZILLIB/SOFT">	;"function key stuff"
+<INSERT-FILE "~INTERLOGIC/ZILLIB/MENU">	;"menu stuff"
+<INSERT-FILE "STATUS">	;"status line"
+<INSERT-FILE "PIC">		;"picture stuff"
+<INSERT-FILE "DESC">		;"describers"
+<INSERT-FILE "SYNTAX">
+<INSERT-FILE "RECORD">
+<INSERT-FILE "VERBS">
+<INSERT-FILE "~INTERLOGIC/ZILLIB/PARSER/PRARE">
+<INSERT-FILE "QVERBS">
+<INSERT-FILE "GLOBALS">
+
+;"game files"
+
+<INSERT-FILE "CAST">	;"characters"
+<INSERT-FILE "ERASMUS">	;"arrival in japan"
+<INSERT-FILE "ANJIRO">	;"arrival at village"
+<INSERT-FILE "VOYAGE">	;"voyage to osaka/saving rodrigues"
+<INSERT-FILE "AUDIENCE"> ;"audience with toranaga"
+<INSERT-FILE "OSAKA">	;"escape from osaka"
+<INSERT-FILE "MAZE">	;"maze of alleys in osaka"
+<INSERT-FILE "QUAKE">	;"earthquake"
+<INSERT-FILE "MARIKO">	;"framing story"
+<INSERT-FILE "ATTACK">	;"ninja attack on castle"
+
+<XFLOAD "~INTERLOGIC/ZILLIB/CLUES.XFLOAD">
+<INSERT-FILE "HINTS">
+
+<PROPDEF SIZE 5>
+<PROPDEF CAPACITY 0>
diff --git a/anjiro.zil b/anjiro.zil
new file mode 100644
index 0000000..4aab208
--- /dev/null
+++ b/anjiro.zil
@@ -0,0 +1,3530 @@
+"ANJIRO for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc.  All Rights Reserved."
+
+<FILE-FLAGS SENTENCE-ENDS?>
+
+<BEGIN-SEGMENT ANJIRO>
+
+<CONSTANT J-PLUNGE 20>
+<CONSTANT J-GUARDS 21>
+
+<ROOM GARDEN
+      (LOC ROOMS)
+      (SCENE S-ANJIRO S-RODRIGUES)
+      (DESC "Garden")
+      (SYNONYM GARDEN)
+      (ADJECTIVE SMALL)
+      (LDESC
+"This is a small garden surrounded by a high wall.  It is unlike anything
+you have ever seen: a little waterfall and stream and a small bridge
+and manicured pebbled paths and rocks and flowers and shrubs.  It's so
+clean, so neat.  The house is to the west, the village to the east.")
+      (IN PER MURA-HOUSE-EXIT)
+      (WEST PER MURA-HOUSE-EXIT)
+      (EAST TO ANJIRO)
+      (OUT TO ANJIRO)
+      (FLAGS ONBIT OUTSIDE)
+      (GLOBAL MURA-DOOR MURA-HOUSE LG-VILLAGE)
+      (ACTION GARDEN-F)>
+
+<ROUTINE MURA-HOUSE-EXIT ("OPT" (RARG <>) (STRICT? <>))
+	 <COND (<RARG? ENTER> ,MURA-HOUSE)
+	       (<FSET? ,BOOTS ,WEARBIT>
+		<TELL
+CTHE ,ONNA " runs up to you, very agitated.  As politely as she can,
+she points to your boots, bowing and shaking her head." CR>
+		<RFALSE>)
+	       (ELSE ,MURA-HOUSE)>>
+
+<ROUTINE GARDEN-F (RARG)
+	 <COND (<RARG? ENTER>
+		<COND (<SCENE? ,S-ANJIRO>
+		       <QUEUE I-SEBASTIO -1>
+		       <COND (<IN? ,ONNA ,MURA-HOUSE>
+			      <MOVE ,ONNA ,GARDEN>)>)>)
+	       (<RARG? BEG>
+		<COND (<P? LISTEN (<> NOISE)>
+		       <TELL
+G"It sounds like a group of people.  ""You can't be sure, but one seems
+to be speaking Portuguese!" CR>)
+		      (<P? EXAMINE NOISE>
+		       <TELL "You'll have to go out to do that." CR>)
+		      (<P? LISTEN PORTUGUESE>
+		       <TELL
+"It definitely sounds like Portuguese, but you're too far away to
+be sure." CR>)
+		      (<AND <SCENE? ,S-ANJIRO>
+			    <VERB? WALK WALK-TO>
+			    <HENCHMEN-RESTRAIN>>
+		       <RTRUE>)>)>>
+
+<OBJECT HIGH-WALL
+	(LOC GARDEN)
+	(DESC "high wall")
+	(SYNONYM WALL)
+	(ADJECTIVE HIGH)
+	(FLAGS NDESCBIT)
+	(ACTION HIGH-WALL-F)>
+
+<ROUTINE HIGH-WALL-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The wall is made of small stones mortared together with great
+precision.  It is at first completely a wall and at then suggests a
+high mountain
+cliff with the garden plants growing up to the base." CR>)
+	       (<VERB? CLIMB-UP CLIMB-FOO>
+		<TELL
+"You're too weak to climb the wall." CR>)>>
+
+<OBJECT WATERFALL
+	(LOC GARDEN)
+	(DESC "little waterfall")
+	(SYNONYM WATERFALL WATER POOL)
+	(ADJECTIVE LITTLE)
+	(FLAGS NDESCBIT)
+	(ACTION WATERFALL-F)>
+
+<ROUTINE WATERFALL-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"A fall of sweet, clear water drops from one level of the garden to
+the other.  The gentle tinkling sound is very soothing." CR>)
+	       (<VERB? LOOK-INSIDE>
+		<TELL
+"The little pool at the base of waterfall is filled with carp." CR>)
+	       (<VERB? DRINK>
+		<TELL
+"The water is cool and tasty." CR>)>>
+
+<OBJECT PATHS
+	(LOC GARDEN)
+	(DESC "manicured path")
+	(SYNONYM PATH PATHS)
+	(ADJECTIVE MANICURED)
+	(FLAGS NDESCBIT)
+	(ACTION PATHS-F)>
+
+<ROUTINE PATHS-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The paths lead in neat, seemingly chance-laid loops throughout the
+garden." CR>)
+	       (<VERB? FOLLOW>
+		<TELL
+"You walk about for a while, following the paths.  The garden is so
+neat, so orderly.  Just walking in it is calming.  You haven't seen a
+living plant during all your long voyage, and here there are so many." CR>)>>
+
+<OBJECT SMALL-BRIDGE
+	(LOC GARDEN)
+	(SCENE S-ANJIRO)
+	(DESC "small bridge")
+	(SYNONYM BRIDGE)
+	(ADJECTIVE SMALL)
+	(FLAGS NDESCBIT)
+	(ACTION SMALL-BRIDGE-F)>
+
+<ROUTINE SMALL-BRIDGE-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"It's a small, decorative footbridge that crosses the little stream." CR>)
+	       (<VERB? CROSS>
+		<TELL
+"You cross the little bridge, standing in the center looking at the slowly
+flowing stream for a while.  The garden is very peaceful.  You cross
+back." CR>)>>
+
+<OBJECT STREAM
+	(LOC GARDEN)
+	(DESC "stream")
+	(SYNONYM STREAM)
+	(ADJECTIVE LITTLE)
+	(FLAGS NDESCBIT VEHBIT)
+	(ACTION STREAM-F)>
+
+<ROUTINE STREAM-F ()
+	 <COND (<VERB? BOARD STEP-ON CLIMB-DOWN>
+		<TELL
+"You content yourself with splashing a little water on your face." CR>)>>
+
+<OBJECT PLANTS
+	(LOC GARDEN)
+	(DESC "plant")
+	(SYNONYM FLOWER SHRUB FLOWERS SHRUBS PLANT)
+	(FLAGS NDESCBIT)
+	(ACTION PLANTS-F)>
+
+<ROUTINE PLANTS-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The garden is planted with flowers, shrubs, and odd small trees.  It
+looks like a small patch of orderly wilderness." CR>)
+	       (<VERB? TAKE>
+		<TELL
+"You think better of disturbing the harmony of the garden." CR>)
+	       (<VERB? SMELL>
+		<TELL
+"The flowers smell very nice.  Your nose has had little to smell of
+comparable fragrance for years." CR>)>>
+
+
+
+<ROOM ANJIRO-WATERFRONT
+      (LOC ROOMS)
+      (SCENE S-RODRIGUES)
+      (AFTER LEAVE-ANJIRO-AFTER-F)
+      (SCORE 4)
+      (DESC "Waterfront")
+      (FDESC
+"The next day you walk down the hill, four samurai flanking you.  Ahead
+the street curves with the contour of the hillside, slides down toward
+the harbor.")
+      (SYNONYM WATERFRONT)
+      (WEST TO ANJIRO)
+      (EAST TO ANJIRO-HARBOR)
+      (GLOBAL LG-ERASMUS SAMURAI-GUARDS LG-SEA LG-VILLAGE LG-BAY VILLAGERS
+       LG-LAND)
+      (FLAGS ONBIT OUTSIDE)
+      (ACTION ANJIRO-WATERFRONT-F)>
+
+<ROUTINE ANJIRO-WATERFRONT-F (RARG)
+	 <COND (<RARG? SCENE-SETUP>
+		<DRESS-BLACKTHORNE T>
+		<NEW-SDESC ,HIRO-MATSU "old man">
+		<FCLEAR ,HIRO-MATSU ,NOABIT>
+		<FCLEAR ,HIRO-MATSU ,NOTHEBIT>
+		<FSET ,HIRO-MATSU ,AN>
+		<NEW-SDESC ,OMI "Omi">
+		<MOVE-CREW ,PIT>
+		<REMOVE ,HENCHMAN-BODY>
+		<REMOVE ,HENCHMAN-HEAD>
+		<MOVE ,SECRET-RUTTER ,GENERIC-OBJECTS>
+		<MOVE ,RUTTER ,GENERIC-OBJECTS>
+		<MOVE ,SEA-CHEST ,PILOTS-CABIN>
+		<FSET ,SEA-CHEST ,OPENBIT>
+		<MOVE ,SMALL-BOAT ,ANJIRO-WATERFRONT>
+		<MOVE ,BOAT-OAR ,SMALL-BOAT>
+		<MOVE ,SLAVER ,ANJIRO-WATERFRONT>
+		<MOVE ,MURA ,ANJIRO-WATERFRONT>
+		<MOVE ,OMI ,ANJIRO-WATERFRONT>
+		<MOVE ,YABU ,ANJIRO-WATERFRONT>
+		<MOVE ,HIRO-MATSU ,ANJIRO-WATERFRONT>
+		<MOVE ,ARCHERS ,ANJIRO-WATERFRONT>
+		<FCLEAR ,ARCHERS ,INVISIBLE>
+		<QUEUE I-MEET-RODRIGUES -1>)
+	       (<RARG? LOOK>
+		<TELL
+"This is the waterfront of the village.  The ground is cobbled and a
+stone launching ramp goes from the shore into the sea.  There are men and
+women cleaning fish.  Small islands are visible to the east and south.  At
+anchor, to the east, is the "I"Erasmus""." CR>)
+	       (<RARG? ENTER>
+		<COND (<SCENE? ,S-ANJIRO>
+		       <COND (<IN? ,WINNER ,SMALL-BOAT>
+			      <TELL
+"You row the boat up onto the beach." CR CR>)
+			     (<NOT <FSET? ,RUTTER ,RMUNGBIT>>
+			      <QUEUE I-RUTTER-CLUE 1>)>)>)
+	       (<RARG? BEG>
+		<COND (<AND <SCENE? S-RODRIGUES>
+			    <OR <P? (POINT EXAMINE) LG-ERASMUS>
+				<P? SHOW LG-ERASMUS RODRIGUES>>>
+		       <TELL
+"You look out at the "I"Erasmus"", and " THE ,RODRIGUES " watches you.">
+		       <COND (<NOT <FSET? ,LIZARD ,SCOREBIT>>
+			      <THIS-IS-IT ,LG-ERASMUS>
+			      <SETG QCONTEXT ,RODRIGUES>
+			      <TELL " She's
+moored a hundred yards away.  \"Tell me about her, Ingeles,\" asks
+the Portuguese.  \"She looks like a pisscutter!\"">)>
+		       <CRLF>)
+		      (<AND <SCENE? S-RODRIGUES>
+			    <P? (WALK WALK-TO) (P?WEST P?NORTH P?SOUTH)>>
+		       <TELL
+"Mura restrains you with iron gentleness." CR>)
+		      (<AND <SCENE? S-ANJIRO>
+			    <VERB? WALK WALK-TO>
+			    <HENCHMEN-RESTRAIN>>
+		       <RTRUE>)
+		      (<AND <OR <VERB? SWIM>
+				<P? THROUGH (LG-SEA LG-BAY)>
+				<P? WALK (P?EAST P?OUT)>
+				<P? WALK-TO LG-ERASMUS>>
+			    <NOT <IN? ,WINNER ,SMALL-BOAT>>>
+		       <TELL
+"You wade into the water, striding deeper and deeper, until you
+realize that you haven't regained enough strength to swim.  You return to
+the beach." CR>)
+		      (<P? WALK (P?NORTH P?SOUTH)>
+		       <FCLEAR ,OMI ,RMUNGBIT> ;"he won't kill you"
+		       <TELL
+"You wander through the village, but the villagers are apparently
+unwilling to let you go too far, and you are gently guided back to the
+pebbled beach of the waterfront." CR>)>)
+	       (<RARG? END>
+		<VILLAGERS-STARE>)>>
+
+<ROUTINE VILLAGERS-STARE ()
+	 <COND (<AND <SCENE? ,S-ANJIRO>
+		     <NOT <FSET? ,CLOTHES ,WEARBIT>>
+		     <OR <NOT ,STATIONARY?> <PROB 33>>>
+		<TELL CR
+G"The villagers stare at you, and the little children laugh and
+point.  They've never seen a naked barbarian before." CR>)>>
+
+<OBJECT ARCHERS
+	(DESC "archers")
+	(SYNONYM ARCHER ARCHERS SAMURAI BOW ARROW MEN)
+	(FLAGS PERSON JAPANESEBIT PLURAL SCOREBIT INVISIBLE AN NOABIT)
+	(ACTION ARCHERS-F)>
+
+<ROUTINE ARCHERS-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<WAKARIMASEN>)
+	       (<RARG? <>>
+		<COND (<VERB? EXAMINE>
+		       <COND (<FSET? ,ARCHERS ,RMUNGBIT>
+			      <TELL
+"One of the archers has drawn out an arrow, and is putting it in his bow." CR>)
+			     (ELSE
+			      <TELL
+"These are archers from the galley, all dressed in the same uniform as " THE
+,HIRO-MATSU "." CR>)>)
+		      (<OR <P? (WARN TELL-ABOUT) RODRIGUES ARCHERS>
+			   <P? POINT ARCHERS>>
+		       <COND (<IN? ,WINNER ,SMALL-BOAT>
+			      <TELL
+"Rodrigues stops rowing immediately, and turns toward shore">
+			      <COND (<FSET? ,ARCHERS ,RMUNGBIT>
+				     <TELL ", waving and
+babbling in pidgin Japanese, reassuring the captain samurai, who says
+something to the man with the arrow.  Now the man puts it away." CR>
+				     <FCLEAR ,ARCHERS ,RMUNGBIT>
+				     <SCORE-OBJECT ,ARCHERS>)
+				    (ELSE
+				     <TELL
+", where nothing is happening.  \"No games, Ingeles,\" he warns." CR>)>)>)
+		      (<VERB? TELL>
+		       <TELL "They aren't allowed to talk to you." CR>
+		       <END-QUOTE>
+		       <RFATAL>)>)>>
+
+<ROUTINE I-RUTTER-CLUE ()
+	 <COND (<NOT <FSET? ,RUTTER ,RMUNGBIT>>
+		<FSET ,RUTTER ,RMUNGBIT>
+		<TELL CR
+"It comes suddenly to mind that since you awoke, you haven't
+seen your rutters or the rest of the crew.  ">
+		<COND (<HERE? ,ON-DECK>
+		       <TELL "Could they be aboard">)
+		      (ELSE
+		       <TELL "Can they still be on the "I"Erasmus">)>
+		<TELL ", you wonder?" CR>)>>
+
+<OBJECT SMALL-BOAT
+	(LOC ANJIRO-WATERFRONT)
+	(SCENE S-ANJIRO S-RODRIGUES)
+	(DESC "small boat")
+	(SYNONYM BOAT ROWBOAT)
+	(ADJECTIVE SMALL)
+	(FLAGS VEHBIT CONTBIT OPENBIT SEARCHBIT)
+	(CAPACITY 300)
+	(ACTION SMALL-BOAT-F)>
+
+<ROUTINE SMALL-BOAT-F (RARG)
+	 <COND (<RARG? BEG>
+		<COND (<VERB? LAUNCH>
+		       <DO-WALK ,P?EAST>
+		       <RTRUE>)
+		      (<VERB? WALK-TO WALK>
+		       <COND (<OR <P? WALK P?OUT>
+				  <AND <P? WALK ,P?UP>
+				       <HERE? AT-ERASMUS>>>
+			      <PERFORM ,V?DISEMBARK>
+			      <RTRUE>)
+			     (<NOT <HELD? ,BOAT-OAR>>
+			      <TELL
+"You need an oar to row." CR>)
+			     (<OR <P? WALK-TO LG-ERASMUS>
+				  <P? WALK (P?EAST ,P?OUT)>>
+			      <COND (<HERE? ,ANJIRO-WATERFRONT>
+				     <TELL
+"You launch the boat and row out into the harbor towards the "I"Erasmus""."
+CR CR>
+				     <GOTO ,ANJIRO-HARBOR>)
+				    (<HERE? ,ANJIRO-HARBOR>
+				     <TELL
+"You row up to the side of the "I"Erasmus"".  The samurai aboard eye you
+curiously." CR CR>
+				     <GOTO ,AT-ERASMUS>)>)
+			     (<P? WALK-TO LG-LAND>
+			      <DO-WALK ,P?WEST>)
+			     (<P? WALK ,P?WEST>
+			      <COND (<HERE? ,ANJIRO-WATERFRONT>
+				     <TELL
+"You can't row the boat over land!" CR>)
+				    (ELSE <RFALSE>)>)
+			     (<PRSO? ,P?UP ,P?DOWN>
+			      <TELL
+"If you can row a boat that way, you're a better seaman than Drake
+himself!" CR>)
+			     (ELSE
+			      <TELL
+"You row that way for a while, but there is nothing interesting in that
+direction." CR>)>)
+		      (<VERB? SWIM SWIM-TO>
+		       <TELL
+"Why swim when you're in a nice dry boat?" CR>)
+		      (<P? (BOARD THROUGH) LG-ERASMUS>
+		       <PERFORM ,V?DISEMBARK>
+		       <RTRUE>)
+		      (<VERB? DISEMBARK>
+		       <COND (<HERE? ,AT-ERASMUS>
+			      <TELL
+"You clamber up the gangway onto the deck.  One samurai, more elaborately
+dressed than the others, comes over to you and bows." CR CR>
+			      <MOVE ,WINNER ,HERE>
+			      <GOTO ,ON-DECK>)
+			     (<HERE? ,ANJIRO-HARBOR>
+			      <PERFORM ,V?LEAP ,LG-SEA>
+			      <RTRUE>)
+			     (<HERE? ,ANJIRO-WATERFRONT>
+			      <MOVE ,WINNER ,HERE>
+			      <TELL "You disembark from the boat." CR>)>)
+		      (<P? (ENTER BOARD THROUGH) LG-SEA>
+		       <COND (<HERE? ,ANJIRO-HARBOR ,AT-ERASMUS>
+			      <COND (<IN? ,RODRIGUES ,SMALL-BOAT>
+				     <TELL
+"Rodrigues grabs you.  \"Not so fast, Ingeles!\"" CR>)
+				    (<JIGS-UP? ,J-PLUNGE
+"You reconsider.  You are very tired, and might not be able to stay
+afloat.">
+				     <MOVE ,WINNER ,HERE>
+				     <JIGS-UP
+"You plunge into the water.  All too soon, you realize you were more tired
+than you originally thought.  You struggle to return to the boat, but you
+aren't strong enough to pull yourself aboard.">)
+				    (ELSE <RTRUE>)>)
+			     (<HERE? ,ANJIRO-WATERFRONT>
+			      <TELL
+"The boat is on dry land here." CR>)>)>)
+	       (<RARG? <>>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"It's just a small wooden rowboat.">
+		       <COND (<NOT <FSET? ,RUTTER ,RMUNGBIT>>
+			      <FSET ,RUTTER ,RMUNGBIT>
+			      <TELL " It reminds you that you haven't
+seen your rutters anywhere, and you glance out at the "I"Erasmus"".">)>
+		       <CRLF>)
+		      (<VERB? BOARD>
+		       <COND (<SCENE? ,S-ANJIRO>
+			      <HENCHMEN-RESTRAIN>)
+			     (<SCENE? ,S-RODRIGUES>
+			      <COND (<NOT <IN? ,RODRIGUES ,SMALL-BOAT>>
+				     <COND (<IN? ,RODRIGUES ,HERE>
+					    <COND (<FSET? ,LIZARD ,SCOREBIT>
+						   <TELL
+"\"I'm not done with you yet">)
+						  (ELSE
+						   <TELL "\"Me first">)>
+					    <TELL
+", Ingeles!\" says " THE ,RODRIGUES "." CR>)
+					   (ELSE
+					    <TELL
+"Mura stops you and points to the galley.  \"No, Anjin-san.  So sorry, go
+there.\"" CR>)>)>)>)
+		      (<VERB? LAUNCH>
+		       <COND (<SCENE? ,S-ANJIRO>
+			      <COND (<HENCHMEN-RESTRAIN>
+				     <RTRUE>)
+				    (ELSE
+				     <MOVE ,WINNER ,PRSO>
+				     <TELL
+"You launch the boat, pushing it into the water, and although you are
+still weak, you manage to haul yourself into it." CR CR>
+				     <DO-WALK ,P?EAST>
+				     <RTRUE>)>)
+			     (<SCENE? ,S-RODRIGUES>
+			      <PERFORM ,V?BOARD ,SMALL-BOAT>
+			      <RTRUE>)>)>)>>
+
+<OBJECT BOAT-OAR
+	(LOC SMALL-BOAT)
+	(SCENE S-ANJIRO S-RODRIGUES)
+	(DESC "oars")
+	(SYNONYM OAR OARS)
+	(FLAGS TAKEBIT NOABIT PLURAL)>
+
+<OBJECT LG-SMALL-BOAT
+	(LOC LOCAL-GLOBALS)
+	(SCENE S-ANJIRO S-RODRIGUES)
+	(DESC "small boat")
+	(SYNONYM BOAT ROWBOAT)
+	(ADJECTIVE SMALL)
+	(FLAGS NDESCBIT VEHBIT)
+	(ACTION LG-SMALL-BOAT-F)>
+
+<ROUTINE LG-SMALL-BOAT-F ()
+	 <COND (<OR <NOT <SCENE? ,S-ANJIRO>>
+		    <NOT <IN? ,SMALL-BOAT ,AT-ERASMUS>>>
+		<TELL
+"There's no " D ,SMALL-BOAT " to be found here." CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"You sneak a quick glance over the side.  Yes, the boat's still
+there, bobbing in the light waves." CR>)
+	       (<VERB? BOARD>
+		<DO-WALK ,P?DOWN>)>>
+
+<ROUTINE HENCHMEN-RESTRAIN ()
+	 <COND (<FSET? ,SEBASTIO-HENCHMEN ,RMUNGBIT>
+		<RFALSE>)
+	       (<IN? ,OMI ,HERE>
+		<TELL
+CTHE ,SEBASTIO " points to you, saying something in Japanese to " THE
+,OMI ", who nods.  The priest's companions restrain you." CR>)
+	       (<IN? ,SEBASTIO ,HERE>
+		<TELL
+CTHE ,SEBASTIO " motions to his companions, who restrain you." CR>)
+	       (ELSE <RFALSE>)>>
+
+<ROOM ANJIRO-HARBOR
+      (LOC ROOMS)
+      (DESC "Harbor")
+      (SYNONYM HARBOR)
+      (EAST TO AT-ERASMUS)
+      (WEST TO ANJIRO-WATERFRONT)
+      (FLAGS ONBIT OUTSIDE)
+      (GLOBAL LG-ERASMUS SAMURAI-GUARDS LG-SEA LG-BAY LG-LAND ARCHERS)
+      (ACTION ANJIRO-HARBOR-F)>
+
+<ROUTINE ANJIRO-HARBOR-F (RARG)
+	 <COND (<RARG? LOOK>
+		<TELL
+"This is the middle of the harbor.  The "I"Erasmus"" is to the east, the
+waterfront to the west.  Small islands lie distantly toward the eastern
+and southern horizons." CR>)
+	       (<RARG? BEG>
+		<COND (<AND <P? WALK (P?EAST ,P?OUT)>
+			    <NOT <IN? ,WINNER ,SMALL-BOAT>>>
+		       <TELL "You are too weak to swim that far." CR>)>)>>
+
+<ROOM AT-ERASMUS
+      (LOC ROOMS)
+      (DESC "Beside the Erasmus")
+      (UP TO ON-DECK)
+      (WEST TO ANJIRO-HARBOR)
+      (FLAGS ONBIT OUTSIDE)
+      (GLOBAL LG-ERASMUS SAMURAI-GUARDS GANGWAY LG-SEA LG-LAND LG-BAY ARCHERS)
+      (ACTION AT-ERASMUS-F)>
+
+<ROUTINE AT-ERASMUS-F (RARG)
+	 <COND (<RARG? LOOK>
+		<TELL
+"The "I"Erasmus"" rides at anchor here, held by three bow cables." CR>)
+	       (<RARG? ENTER>
+		<COND (<AND <EQUAL? ,OHERE ,ON-DECK>
+			    <SCENE? ,S-ANJIRO>>
+		       <TELL
+"As you climb down the gangway you can still feel the sweat trickling
+down your spine.  You hate everything about the Japans and wish yourself
+and your crew back aboard, armed, and out to sea." CR CR>
+		       <MOVE ,BLACKTHORNE ,HERE>
+		       <NEXT-SCENE>)>)>>
+
+<ROOM ANJIRO
+      (LOC ROOMS)
+      ;(SCENE S-ANJIRO)
+      (DESC "Anjiro")
+      (SYNONYM ANJIRO ;VILLAGE)
+      (PICTURE P-ANJIRO)
+      (IN TO GARDEN)
+      (WEST TO GARDEN)
+      (EAST TO ANJIRO-WATERFRONT)
+      (GLOBAL MURA-DOOR LG-ERASMUS LG-VILLAGE VILLAGERS)
+      (FLAGS ONBIT OUTSIDE RMUNGBIT ;"kludge to make picture come up")
+      (ACTION ANJIRO-F)>
+
+<ROUTINE ANJIRO-F ("OPT" (RARG <>))
+	 <COND (<RARG? LOOK>
+		<TELL
+"The village is set around a crescent harbor that faces east, perhaps
+two hundred houses unlike any you've ever seen nestling at the beginning
+of the mountain which spills down to the shore.  Above are terraced
+fields to the west and dirt roads that lead north and south.  Below to
+the east is the waterfront.  In the harbor you can see the "I"Erasmus"
+" riding at anchor." CR>)
+	       (<RARG? BEG>
+		<COND (<AND <SCENE? S-ANJIRO>
+			    <VERB? WALK WALK-TO>
+			    <HENCHMEN-RESTRAIN>>
+		       <RTRUE>)
+		      (<P? WALK (P?NORTH P?SOUTH)>
+		       <FCLEAR ,OMI ,RMUNGBIT> ;"he won't kill you"
+		       <TELL
+"You follow the dirt road through the village, conscious of many people
+watching you.  When they see you have noticed them, they bow to you.  They
+pass to and fro, like so many multicolored butterflies.  After a while you
+find you've returned to the house you left." CR>)
+		      (<P? WALK P?UP>
+		       <FCLEAR ,OMI ,RMUNGBIT> ;"he won't kill you"
+		       <TELL
+"You walk up the dirt path that leads to the fields, watched by curious
+eyes every second.  In the terraced fields are farmers up to the their knees
+in water, planting and weeding.  How can anything grow in such wetness,
+you wonder, and how can the fields have been built on such steep
+hillsides?  Confused, you walk back to the house you left." CR>)>)
+	       (<RARG? END>
+		<VILLAGERS-STARE>)
+	       (<RARG? <>>
+		<COND (<VERB? FIND>
+		       <COND (<G? ,SCENE ,S-ERASMUS>
+			      <TELL
+"Anjiro is a small fishing village in the province of Izu." CR>)
+			     (ELSE
+			      <TELL
+"You've never heard of any place called Anjiro." CR>)>)>)>>
+
+<OBJECT VILLAGERS
+	(LOC LOCAL-GLOBALS)
+	(DESC "villagers")
+	(SYNONYM VILLAGERS WOMEN MEN FISHERMEN)
+	(FLAGS PERSON JAPANESEBIT PLURAL OPENBIT CONTBIT SEARCHBIT)
+	(ACTION VILLAGERS-F)>
+
+<ROUTINE VILLAGERS-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<TELL "They don't understand you." CR>
+		<END-QUOTE>)
+	       (<RARG? <>>
+		<COND (<VERB? EXAMINE>
+		       <COND (<HERE? ,VILLAGE-SQUARE>
+			      <TELL
+"They are watching everything that's going on with great interest." CR>)
+			     (ELSE
+			      <TELL
+"They go about their daily activities, pretending not to be interested in
+you." CR>)>)
+		      (<VERB? BOW>
+		       <TELL
+"They return your bow with amusement.  You are obviously a new and amazing
+sight for them." CR>)>)>>
+
+<OBJECT SEBASTIO-HENCHMEN
+	(SCENE S-ANJIRO)
+	(DESC "priest's henchmen")
+	(OWNER SEBASTIO)
+	(SYNONYM MEN HENCHMEN HENCHMAN COMPANIONS)
+	(ADJECTIVE JAPANESE)
+	(FLAGS PERSON JAPANESEBIT THE NOABIT SCOREBIT PLURAL)
+	(ACTION SEBASTIO-HENCHMEN-F)>
+
+<ROUTINE SEBASTIO-HENCHMEN-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<TELL CTHE ,SEBASTIO " interrupts.  \"None of these men
+understand Portuguese, heretic.\"" CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"There are ten of them, all natives, black-haired and black-eyed,
+one dressed like " THE ,SEBASTIO " except that he has thong slippers.  The
+rest are in varicolored robes, loose trousers, or loincloths." CR>)
+	       (<OR <HOSTILE-VERB?>
+		    <VERB? PARRY STOP>
+		    <P? HELP ME>>
+		<COND (<IN? ,OMI ,HERE>
+		       <TELL
+CTHE ,OMI " barks an order, and they quickly and efficiently pin you
+in place.  You are so weak you can hardly struggle." CR>)
+		      (<FSET? ,SEBASTIO-HENCHMEN ,SCOREBIT>
+		       <TELL
+"You are outnumbered and weak, but you manage to smash the nose of
+one.  The noise of his scream slows the rest down a little." CR>
+		       <SCORE-OBJECT ,SEBASTIO-HENCHMEN>)
+		      (ELSE
+		       <TELL "You try your best to fend them off." CR>)>)>>
+
+<OBJECT HENCHMAN-BODY
+	(DESC "body")
+	(SYNONYM BODY CORPSE MAN)
+	(ADJECTIVE DEAD KILLED MURDERED HEADLESS)
+	(SIZE 200)
+	(FLAGS PERSON JAPANESEBIT DEAD TAKEBIT TRYTAKEBIT)
+	(ACTION HENCHMAN-BODY-F)>
+
+<ROUTINE HENCHMAN-BODY-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<VERB? EXAMINE>
+		<TELL
+"He looks like a typical villager, but he's quite dead." CR>)
+	       (<AND <IN? ,OMI ,HERE>
+		     <OR <VERB? TAKE>
+			 <HOSTILE-VERB?>>>
+		<TELL G"Omi prevents you, threatening with his still-bloody
+sword.  \""I"Ikinasai""!\" he repeats." CR>)>>
+
+<OBJECT HENCHMAN-HEAD
+	(DESC "severed head")
+	(SYNONYM HEAD)
+	(ADJECTIVE SEVERED)
+	(FLAGS TAKEBIT TRYTAKEBIT PERSON DEAD)
+	(ACTION HENCHMAN-HEAD-F)>
+
+<ROUTINE HENCHMAN-HEAD-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<VERB? EXAMINE>
+		<TELL "Its expression is frozen in a grimace of death." CR>)
+	       (<AND <P? GIVE HENCHMAN-HEAD>
+		     <FSET? ,PRSI ,PERSON>
+		     <NOT <FSET? ,PRSI ,DEAD>>>
+		<TELL
+CTHE ,PRSI " doesn't seem interested." CR>)
+	       (<AND <OR <VERB? TAKE>
+			 <HOSTILE-VERB?>>
+		     <IN? ,OMI ,HERE>>
+		<TELL G"Omi prevents you, threatening with his still-bloody
+sword.  \"">
+		<COND (<VERB? KICK>
+		       <TELL I"What sizzle!""\" he exclaims." CR>)
+		      (ELSE <TELL I"Ikinasai!""\" he repeats." CR>)>)>>
+
+<ROUTINE I-SEBASTIO ()
+	 <ZLINES ,SEBASTIO-CNT
+		 (DELAY
+		  <COND (<HERE? ,ANJIRO ,ANJIRO-WATERFRONT>)
+			(<G? ,DELAY-CNT 5>
+			 <TELL CR
+"Your curiosity gets the better of you and you go out into the street."
+CR CR>
+			 <GOTO ,ANJIRO>)
+			(<AND <G? ,DELAY-CNT 2>
+			      <HERE? ,MURA-HOUSE ,GARDEN>>
+			 <TELL CR
+"You hear a commotion outside." CR>
+			 <RTRUE>)
+			(ELSE <RFALSE>)>)
+		 (<MOVE ,SEBASTIO ,HERE>
+		  <SETG QCONTEXT ,SEBASTIO>
+		  <THIS-IS-IT ,SEBASTIO>
+		  <THIS-IS-IT ,SEBASTIO-HENCHMEN>
+		  <MOVE ,SEBASTIO-HENCHMEN ,HERE>
+		  <TELL CR
+"You see a tonsured man approaching and fear sweeps sickeningly from
+your testicles into your stomach.  He is obviously a Portuguese or
+Spanish priest, and though his flowing robe is orange, there is no
+mistaking the crucifix and rosary at his belt, or the cold hostility
+on his face.  Priests here!  A world away in Europe, England and Holland
+are fighting for their freedom from the priests.  Is there no place not
+infested by these idolators and their Inquisition?  Your fear begins to
+give way to rage.|
+|
+Behind him are several Japanese." CR>)
+		 (<TELL CR
+"\"Who are you?\" the priest says in Portuguese.  ">
+		  <COND (<NOT <FSET? ,CLOTHES ,WEARBIT>>
+			 <TELL
+"\"You're as naked as a savage!  You have no shame, just like the pagans
+here!  Put on some clothes and hide your shame!\"  ">)>
+		  <TELL "He points to the
+harbor.  \"That's a Netherlander privateer.  You're a heretic
+Dutchman.  You're pirates.  You're an enemy of the church!\"" CR>)
+		 (<TELL CR
+"\"They crucify criminals here.  You're going to die.  The "I"daimyo's"" coming
+with his samurai.  God have mercy on you!\"" CR>)
+		 (<THIS-IS-IT ,SEBASTIO-HENCHMEN>
+		  <SETG OPPONENT ,SEBASTIO-HENCHMEN>
+		  <TELL CR
+"The priest lifts his crucifix and holds it between you as a shield.  \"Oh,
+God, protect us from this evil!  May God have mercy on your soul.\"|
+|
+He snaps something in Japanese and the men surge toward you, grabbing and
+pinioning your arms.  You feel yourself choking!" CR>)
+		 (DELAY
+		  <COND (<FSET? ,SEBASTIO-HENCHMEN ,SCOREBIT>
+			 <COND (<EQUAL? ,DELAY-CNT 1>
+				<TELL CR
+"You can feel the life being choked out of you!" CR>
+				<RTRUE>)
+			       (ELSE
+				<CRLF>
+				<JIGS-UP
+"One of the priest's henchmen gives you a chop on the windpipe, crushing
+it.  You fall to the ground, choking and gasping, and then you die.">
+				<RFATAL>)>)>)
+		 (<QUEUE I-OMI -1>
+		  <DEQUEUE I-SEBASTIO>)>>
+
+<GLOBAL PISS-FLAG <>>
+
+<GLOBAL OMI-QUESTION 0>
+
+<ROUTINE I-OMI ("AUX" TMP)
+	 <ZLINES ,OMI-CNT
+		 (<SETG OPPONENT <>>
+		  <MOVE ,OMI ,HERE>
+		  <THIS-IS-IT ,OMI>
+		  <TELL CR
+"Suddenly the attack ceases.  A young man is ten paces away.  He wears two
+scabbarded swords in his belt.  His right hand is casually on the hilt
+of the longer one.  \""I"Nanigoto da?""\" he asks harshly.  \""I"NANIGOTO DA?""\"
+The Japanese fall to their knees." CR>)
+		 (<SETG QCONTEXT ,SEBASTIO>
+		  <SETG OMI-QUESTION 1>
+		  <SETUP-ANSWER "i am">
+		  <TELL CR
+CTHE ,OMI " says, \""I"Doko no kuni no monoda?""\" The priest
+translates, \"Kasigi Omi-san says, 'What's your nationality?'\"" CR>)
+		 (DELAY
+		  <COND (,OMI-QUESTION
+			 <COND (<G? ,DELAY-CNT 2>
+				<OMI-KILLS-YOU>
+				<RFATAL>)>
+			 <SETUP-ANSWER "i am">
+			 <TELL-ANSWER-OR-DIE "What's your nationality">
+			 <RTRUE>)>)
+		 (<SETG QCONTEXT ,SEBASTIO>
+		  <SETG OMI-QUESTION 2>
+		  <TELL CR
+CTHE ,OMI " says, \""I"Onushi ittai doko kara kitanoda?">
+		  <NEW-SDESC ,OMI "Omi">
+		  <SETUP-ANSWER "i sailed from">
+		  <TELL "\" The priest
+says nervously, \"Kasigi Omi-san says, 'Where did you sail from?'\"" CR>)
+		 (DELAY
+		  <COND (,OMI-QUESTION
+			 <COND (<G? ,DELAY-CNT 2>
+				<OMI-KILLS-YOU>
+				<RFATAL>)>
+			 <SETUP-ANSWER "i sailed from">
+			 <TELL-ANSWER-OR-DIE "Where did you sail from">
+			 <RTRUE>)>)
+		 (<SETG QCONTEXT ,SEBASTIO>
+		  <SETG OMI-QUESTION 3>
+		  <SETUP-ANSWER "i am">
+		  <TELL CR
+"Another flurry of words from Omi.  \"Omi-san asks if you're the
+leader.  The headman says there are only a few of you heretics alive and most
+are sick.\"" CR>)
+		 (DELAY
+		  <COND (,OMI-QUESTION
+			 <COND (<G? ,DELAY-CNT 2>
+				<OMI-KILLS-YOU>
+				<RFATAL>)>
+			 <SETUP-ANSWER "i am">
+			 <TELL-ANSWER-OR-DIE "Are you the leader">
+			 <RTRUE>)>)
+		 (<SETG QCONTEXT ,OMI>
+		  <TELL CR
+"Another spate of words from the samurai.  \"Omi-san says because you
+are the leader you will be allowed to walk around the village freely, until
+his master comes.\"" CR>)
+		 (<FSET ,SEBASTIO-HENCHMEN ,RMUNGBIT>
+		  <MOVE ,HENCHMAN-BODY ,HERE>
+		  <MOVE ,HENCHMAN-HEAD ,HERE>
+		  <TELL CR
+"Omi speaks contemptuously to the priest and his men, then waves
+them away.  They all bow low,
+except for one man who rises deliberately, without bowing.  With blinding
+speed Omi's killing sword hisses in a silver arc and the man's head
+topples off his shoulders.  No one else moves a muscle.  \""I"Ikinasai!""\" he
+says, motioning everyone away." CR>)
+		 (<COND (<IN? ,SEBASTIO ,HERE>
+			 <TELL CR
+CTHE ,SEBASTIO " gravely makes the sign of the cross over the body.  \"In
+nomine Patris et Filii et Spiritus Sancti.\"  He stares at the samurai,
+who again says \""I"Ikinasai!""\"" CR>)>)
+		 (<SET TMP <LOC ,SEBASTIO>>
+		  <REMOVE ,SEBASTIO>
+		  <REMOVE ,SEBASTIO-HENCHMEN>
+		  <FSET ,OMI ,RMUNGBIT>
+		  <COND (<EQUAL? .TMP ,HERE>
+			 <TELL CR
+"The priest turns and walks away.  His remaining supporters follow." CR>)>)
+		 (<SETG QCONTEXT <>>
+		  <COND (<OR <NOT <IN? ,OMI ,HERE>>
+			     <NOT <FSET? ,OMI ,RMUNGBIT>>>
+			 <MOVE ,OMI ,GENERIC-OBJECTS>
+			 <DEQUEUE I-OMI>
+			 <TELL CR
+"In the distance, you can hear Omi laughing uproariously." CR>)
+			(ELSE
+			 <CRLF>
+			 <JIGS-UP
+"Omi scowls at you, then begins to laugh uproariously.  In one swift
+stroke he removes your head.">)>)>>
+
+<ROUTINE TELL-ANSWER-OR-DIE (STR)
+	 <TELL CR
+CTHE ,OMI " scowls, fingering the sword in his scabbard.  The priest
+looks nervously at him and then at you.  \"" .STR "?  Answer!\"
+rasps the priest.  \"Answer or die, heretic!\"" CR>>
+
+<ROUTINE OMI-KILLS-YOU ()
+	 <TELL CR
+CTHE ,OMI " barks a few impatient words to " THE ,SEBASTIO ", who nods
+eagerly.  Moments later, " THE ,OMI "'s sword separates your head from
+your body." CR>
+	 <JIGS-UP>>
+
+<ROOM MURA-HOUSE
+      (LOC ROOMS)
+      (SCENE S-ANJIRO S-RODRIGUES)
+      (DESC "Mura's House")
+      (OWNER MURA)
+      (SYNONYM HOUSE)
+      (SCORE 4)
+      (FDESC
+"You awaken suddenly.  For a moment you think you are dreaming, because
+you are ashore and in a small, clean room whose floor is covered with
+soft mats.  You are lying on a thick quilt.|
+|
+You realize that you aren't dreaming because you are terribly hungry.")
+      (LDESC
+"The room is filled with muted light shining through the opaque paper
+that fills squares of cedar lathe.  The ceiling is polished cedar.")
+      (EAST TO GARDEN IF MURA-DOOR IS OPEN)
+      (OUT TO GARDEN IF MURA-DOOR IS OPEN)
+      (FLAGS ONBIT)
+      (GLOBAL MURA-DOOR LG-VILLAGE)
+      (ACTION MURA-HOUSE-F)>
+
+<ROUTINE MURA-HOUSE-F (RARG "AUX" H)
+	 <COND (<RARG? SCENE-SETUP>
+		<FCLEAR ,ON-DECK ,TOUCHBIT>
+		<MOVE ,BLACKTHORNE ,QUILT>
+		<B-SIT>
+		<REMOVE ,BOOTS>
+		<FCLEAR ,BOOTS ,WEARBIT>
+		<REMOVE ,CLOTHES>
+		<FCLEAR ,CLOTHES ,WEARBIT>
+		<PUTP ,BLACKTHORNE ,P?HEALTH 1>
+		<MOVE ,SMALL-BOAT ,ANJIRO-WATERFRONT>
+		<MOVE ,BOAT-OAR ,SMALL-BOAT>
+		<FCLEAR ,PASSAGE-DOOR ,OPENBIT>
+		<FCLEAR ,FOCSLE-DOOR ,OPENBIT>
+		<MOVE-CREW <>>
+		<MOVE ,SAMURAI-GUARDS ,ON-DECK>
+		<REMOVE ,ERASMUS-ANCHOR>
+		<MOVE ,RIBBON ,ON-DECK>
+		<SETG COLLAPSE-CNT 0>
+		<QUEUE I-COLLAPSE -1>)
+	       (<RARG? BEG>
+		<SET H <GETP ,WINNER ,P?HEALTH>>
+		<COND (<AND <P? LOOK-OUT ROOMS>
+			    <FSET? ,MURA-DOOR ,OPENBIT>>
+		       <TELL
+"You see a beautiful, neat garden." CR>)
+		      (<VERB? SLEEP>
+		       <TELL
+"You have just awakened.  Don't be a sleepy-head." CR>)
+		      (<P? LISTEN (<> NOISE)>
+		       <TELL
+G"It sounds like a group of people.  ""One of them is speaking Portuguese!" CR>)
+		      (<AND <P? DRESS>
+			    <IN? ,CLOTHES ,HERE>>
+		       <PERFORM ,V?WEAR ,CLOTHES>
+		       <RTRUE>)
+		      (<AND <VERB? STAND>
+			    <B-NOT-STANDING?>>
+		       <COND (<L? .H 3>
+			      <SETG COLLAPSE-CNT 4>
+			      <QUEUE I-COLLAPSE -1>
+			      <TELL
+"You try to stand but you're still too weak." CR>)
+			     (ELSE
+			      <B-STAND>
+			      <TELL
+"You stand shakily." CR>)>)
+		      (<VERB? DANCE>
+		       <TELL "You don't have the strength." CR>)
+		      (<AND <P? MAKE SIGN-OF-CROSS>
+			    <IN? ,ONNA ,HERE>>
+		       <TELL
+"She smiles at you and nods." CR>)>)>>
+
+<ROUTINE I-COLLAPSE ("AUX" (H <GETP ,BLACKTHORNE ,P?HEALTH>))
+	 <COND (<EQUAL? .H 3>
+		<DEQUEUE I-COLLAPSE>)
+	       (ELSE
+		<ZLINES ,COLLAPSE-CNT
+			(4)
+			(<COND (<EQUAL? .H 1>
+				<TELL CR
+"You are still extremely weak and hungry." CR>)
+			       (<EQUAL? .H 2>
+				<TELL CR
+"You are feeling better, but still on the verge of collapse." CR>)>)
+			(3)
+			(<COND (<EQUAL? .H 1 2>
+				<TELL CR
+"You are on the verge of collapsing from weakness and hunger." CR>)>)
+			(<COND (<EQUAL? .H 1 2>
+				<CRLF>
+				<JIGS-UP
+"You collapse from accumulated weakness and hunger.">)>)>)>>
+
+<OBJECT MURA-DOOR
+	(LOC LOCAL-GLOBALS)
+	(DESC "door")
+	(SYNONYM SHOJI DOOR PANEL PAPER SCREEN SQUARES LATHES)
+	(ADJECTIVE PAPER WOOD TRANSLUCENT)
+	(FLAGS NDESCBIT DOORBIT TRYTAKEBIT)
+	(ACTION MURA-DOOR-F)>
+
+<ROUTINE MURA-DOOR-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<FSET? ,MURA-DOOR ,RMUNGBIT>
+		       <TELL
+"The door has been broken by your clumsiness." CR>)
+		      (ELSE
+		       <TELL
+"The door is made of square wood lathes and covered with paper.  It
+looks translucent, shadows from the outside mottling the light and
+flimsy structure." CR>)>)
+	       (<VERB? OPEN MUNG TEAR RUB>
+		<COND (<FSET? ,MURA-DOOR ,RMUNGBIT>
+		       <COND (<VERB? OPEN>
+			      <COND (<NOT <FSET? ,PRSO ,OPENBIT>>
+				     <FSET ,MURA-DOOR ,OPENBIT>
+				     <TELL
+"You gingerly slide open the broken door." CR>)
+				    (ELSE
+				     <ITS-ALREADY-X "open">)>)
+			     (ELSE
+			      <TELL
+"You've already broken it." CR>)>)
+		      (<AND <HERE? ,MURA-HOUSE>
+			    <NOT <FSET? ,MURA-DOOR ,RMUNGBIT>>>
+		       <COND (<B-NOT-STANDING?>
+			      <TELL
+,YOU-HAVE-TO "stand up to reach the door." CR>
+			      <RTRUE>)
+			     (<VERB? MUNG TEAR>
+			      <TELL
+"That wouldn't be very nice, even if the door is flimsy-looking." CR>
+			      <RTRUE>)>
+		       <FSET ,MURA-DOOR ,OPENBIT>
+		       <FSET ,MURA-DOOR ,RMUNGBIT>
+		       <MOVE ,ONNA ,HERE>
+		       <MARGINAL-PIC ,P-GARDEN>
+		       <TELL
+"You reach to open the door, reeling slightly as you are still very
+weak, and put out a hand to steady yourself but the light, square wood
+lathes can't bear your weight and they shatter, paper ripping apart.  ">
+		       <COND (<IN? ,FOOD ,WINNER>
+			      <MOVE ,FOOD ,HERE>
+			      <TELL "You drop the food.  ">)>
+		       <COND (<IN? ,CHOPSTICKS ,WINNER>
+			      <MOVE ,CHOPSTICKS ,HERE>
+			      <TELL "You drop the sticks.  ">)>
+		       <COND (<IN? ,TRAY ,WINNER>
+			      <MOVE ,TRAY ,HERE>
+			      <MOVE-ALL ,TRAY ,HERE>
+			      <TELL "You drop the tray.  ">)>
+		       <TELL "
+You marvel at how flimsy it is, not at
+all like the sturdy wooden doors of England.  Are there no thieves
+here?|
+|
+You right yourself and manage to open the door.  ">
+		       <COND (<QUEUED? I-ONNA-RETURNS>
+			      <MOVE ,FOOD ,TRAY>
+			      <MOVE ,TRAY ,HERE>
+			      <MOVE ,CLOTHES ,HERE>
+			      <MOVE ,BOOTS ,GARDEN>
+			      <DEQUEUE I-ONNA-RETURNS>
+			      <TELL
+"Behind the door, carrying a tray of food and a bundle of your clothes,
+is a shocked " D ,ONNA ".  She places the tray on the floor and retreats
+with as much calm as she can muster." CR>)
+			     (ELSE
+			      <TELL
+"The shocked woman in the corridor is staring at you." CR>)>)>)
+	       (<AND <VERB? REPAIR>
+		     <FSET? ,PRSO ,RMUNGBIT>>
+		<TELL "You try to fix the door, but it's futile." CR>)>>
+
+<OBJECT QUILT
+	(LOC MURA-HOUSE)
+	(SCENE S-ANJIRO)
+	(DESC "quilt")
+	(SYNONYM QUILT)
+	(ADJECTIVE THICK PADDED SOFT COTTON)
+	(FLAGS TAKEBIT VEHBIT OPENBIT CONTBIT SEARCHBIT FURNITURE SURFACEBIT)
+	(ACTION QUILT-F)>
+
+<ROUTINE QUILT-F ("OPT" (RARG <>))
+	 <COND (<RARG? <>>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"It's a thick padded cotton quilt." CR>)>)
+	       (<RARG? BEG>
+		<COND (<MOTION-VERB?>
+		       <COND (<L? <GETP ,WINNER ,P?HEALTH> 3>
+			      <TELL "You're still too weak." CR>)
+			     (ELSE
+			      <MOVE ,WINNER ,HERE>
+			      <RFALSE>)>)>)>>
+
+<OBJECT MURA-CRUCIFIX
+	(LOC MURA-HOUSE)
+	(SCENE S-ANJIRO)
+	(DESC "crucifix")
+	(FDESC "Hanging on the wall is a crucifix.")
+	(SYNONYM CRUCIFIX CROSS)
+	(FLAGS TAKEBIT TRYTAKEBIT)
+	(ACTION MURA-CRUCIFIX-F)>
+
+<ROUTINE MURA-CRUCIFIX-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"This is the sort of crucifix you would expect to find in a Catholic
+country.  You cannot help but look at it with anger and dread, as Spain
+and Portugal, the Catholic powers, have been at war with England for
+decades.|
+|
+All your life you have heard rumors of Portugal's secret
+empire in the East, how they had by now converted the heathens to
+Catholicism and so held them in bondage.  Can these rumors have been
+true?  If so, what about the other rumors, that gold here is as cheap as
+pig iron, and emeralds and diamonds are as plentiful as pebbles on the
+beach?" CR>)
+	       (<VERB? TAKE MOVE LOWER>
+		<TELL
+"It's fixed to the wall." CR>)
+	       (<VERB? MUNG>
+		<TELL
+"Much as you might like to break it, idolatrous symbol of the hated
+enemy that it is, you can't get to it." CR>)>>
+
+<OBJECT TRAY
+	(LOC MURA-HOUSE)
+	(DESC "red lacquered tray")
+	(SYNONYM TRAY BOWL)
+	(ADJECTIVE RED LACQUERED)
+	(CAPACITY 10)
+	(FLAGS TAKEBIT SEARCHBIT OPENBIT CONTBIT SURFACEBIT)>
+
+<OBJECT CHOPSTICKS
+	(LOC TRAY)
+	(DESC "pair of sticks")
+	(OWNER CHOPSTICKS)
+	(SYNONYM STICKS CHOPSTICKS STICK PAIR)
+	(ADJECTIVE CHOP ;PAIR)
+	(FLAGS TAKEBIT TOOLBIT PLURAL)
+	(ACTION CHOPSTICKS-F)>
+
+<ROUTINE CHOPSTICKS-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"These are two short sticks of polished wood, slightly pointed at one
+end.  You have no idea what they are for." CR>)
+	       (<AND <HOSTILE-VERB?>
+		     <PRSI? ,CHOPSTICKS>>
+		<TELL
+"A pair of chopsticks makes a poor substitute for a weapon." CR>)
+	       (<OR <P? EAT FOOD>
+		    <P? USE CHOPSTICKS>
+		    <P? PICK-UP FOOD>>
+		<COND (<OR <IN? ,FOOD ,TRAY>
+			   <HELD? ,FOOD>>
+		       <TELL
+"You try to scoop the food with the sticks, but it doesn't work.  Why
+there is no knife or spoon here, you cannot understand." CR>)
+		      (ELSE
+		       <TELL
+"You can't understand how to use the sticks." CR>)>)>>
+
+<OBJECT FOOD
+	(LOC TRAY)
+	(DESC "food")
+	(SYNONYM FOOD VEGETABLES SOUP PORRIDGE)
+	(ADJECTIVE MORE FISH COOKED COLD THICK)
+	(FLAGS TAKEBIT FOODBIT SCOREBIT NOABIT)
+	(ACTION FOOD-F)>
+
+<ROUTINE FOOD-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The food consists of cold cooked vegetables, fish soup, and a thick
+porridge of wheat or barley." CR>)
+	       (<VERB? WAIT-FOR>
+		<COND (<QUEUED? I-ONNA-RETURNS>
+		       <TELL
+"Your stomach rumbles as you wait for more food; perhaps there'll be
+grog or a good roast capon this time!" CR>)>)
+	       (<VERB? SMELL>
+		<TELL
+"It smells very strange.  Oh for a loaf of fresh crunchy bread, or a
+roast with gravy!  Nonetheless, it's all you've got." CR>)
+	       (<P? EAT FOOD (<> FINGERS HANDS MOUTH)>
+		<REMOVE ,FOOD>
+		<COND (<L? <GETP ,BLACKTHORNE ,P?HEALTH> 2>
+		       <QUEUE I-REMEMBER 1>
+		       <QUEUE I-ONNA 2>
+		       <TELL
+"You wolf down the vegetables, which have a piquant taste.  You drain the
+bowl of soup.  You eat the porridge with your fingers, as there appear to
+be no utensils, just some sticks of wood.|
+|
+You are still ravenously hungry." CR>
+		       <PUTP ,BLACKTHORNE ,P?HEALTH 2>)
+		      (ELSE
+		       <PUTP ,BLACKTHORNE ,P?HEALTH 3>
+		       <TELL
+"This tray of food is the same as the first.  There is no meat and no
+grog or brandy.  You can eat more slowly now, and you try to savor the
+unfamiliar fare, but you can't convince yourself it's more than just
+filling.  Your stomach is pleasantly full when you finish, though." CR>
+		       <SCORE-OBJECT ,FOOD>)>)>>
+
+<ROUTINE I-REMEMBER ()
+	 <TELL CR
+"With an effort you try to collect yourself.  You remember getting the
+anchor out.  With Vinck.  At least you think it was Vinck.  There were lights
+ashore.  Then there were lights and strange voices.  One of the natives talked
+a little Portuguese.  They must have carried you ashore and put you here." CR>>
+
+<ROUTINE I-ONNA ()
+	 <MOVE ,ONNA ,MURA-HOUSE>
+	 <FSET ,MURA-DOOR ,OPENBIT>
+	 <THIS-IS-IT ,ONNA>
+	 <SETG QCONTEXT ,ONNA>
+	 <TELL CR
+"A panel in the wall slides open.  A middle-aged, heavy-set, round-faced
+woman drops to her knees beside the door and bows and smiles at
+you.  \""I"Goshujinsama, gokibun wa ikaga desu ka?""\" she asks." CR>>
+
+<NEW-ADD-WORD "HAKU" NOUN>
+
+<OBJECT ONNA
+	(SDESC "middle-aged woman")
+	(SYNONYM WOMAN ONNA ONNA LADY)
+	(ADJECTIVE MIDDLE-AGED HEAVY-SET ROUND-FACED)
+	(FLAGS PERSON JAPANESEBIT FEMALE THE OPENBIT SEARCHBIT CONTBIT)
+	(ACTION ONNA-F)>
+
+<ROUTINE ONNA-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<OR <P? BE? THIS JAPAN>
+			   <P? FIND ;WHERE ME>>
+		       <TELL G"She stares at you uncomprehendingly""." CR>)
+		      (<VERB? WHO>
+		       <NEW-SDESC ,ONNA "Onna">
+		       <TELL
+"She doesn't understand you, so you point to yourself and say
+\"Blackthorne\" several times, very deliberately.  She frowns,
+and then with a flood of understanding
+points at herself and says, \"Onna!  Onna!\"" CR>)
+		      (<AND <OR <VERB? SORRY>
+				<AND <P? BE (ME BLACKTHORNE) INTADJ>
+				     <ADJ? ,W?SORRY>>>
+			    <FSET? ,MURA-DOOR ,RMUNGBIT>>
+		       <TELL
+"\"I'm sorry,\" you say, gesturing toward the broken door.  The woman
+finally understands, and smiles as if to indicate that she forgives you." CR>)
+		      (ELSE
+		       <TELL
+G"She stares at you uncomprehendingly"" and says something you cannot
+understand." CR>)>)
+	       (<VERB? EXAMINE>
+		<TELL
+"She is a middle-aged, heavy-set, round-faced woman." CR>)
+	       (<VERB? FIND WHERE>
+		<COND (<IN? ,MURA ,HERE>
+		       <SETG WINNER ,MURA>
+		       <PERFORM ,V?FIND ,PRSO>
+		       <SETG WINNER ,BLACKTHORNE>
+		       <RTRUE>)>)
+	       (<P? ASK-FOR ONNA *>
+		<TELL
+"She doesn't understand you." CR>)
+	       (<P? RUB (STOMACH TRAY)>
+		<PERFORM ,V?SHOW ,PRSO ,ONNA>
+		<RTRUE>)
+	       (<P? (SHOW GIVE) * ONNA>
+		<COND (<PRSO? ,ME>
+		       <SETG WINNER ,ONNA>
+		       <PERFORM ,V?WHO>
+		       <SETG WINNER ,PLAYER>
+		       <RTRUE>)
+		      (<OR <PRSO? HENCHMAN-HEAD>
+			   <PRSO? <LOC ,HENCHMAN-HEAD>>>
+		       <TELL
+"She screams and crosses herself." CR>)
+		      (<HERE? ,MURA-HOUSE ,GARDEN>
+		       <COND (<VERB? SHOW>
+			      <TELL "You point to ">)
+			     (ELSE
+			      <COND (<FSET? ,PRSO ,TAKEBIT>
+				     <FCLEAR ,PRSO ,WEARBIT>
+				     <MOVE ,PRSO ,ONNA>)>
+			      <TELL "You give her ">)>
+		       <COND (<AND <PRSO? ,GLOBAL-FOOD>
+				   <IN? ,TRAY ,HERE>>
+			      <TELL "the empty tray">)
+			     (ELSE <TELL THE ,PRSO>)>
+		       <TELL
+", and the woman looks at " HIM/HER ,PRSO " and ">
+		       <COND (<PRSO? ,MURA-CRUCIFIX>
+			      <TELL "makes the sign of the cross." CR>)
+			     (<AND <PRSO? ,TRAY ,FOOD ,MOUTH ,STOMACH
+					  ,GLOBAL-FOOD>
+				   <NOT <LOC ,CLOTHES>>>
+			      <MOVE ,ONNA ,GARDEN>
+			      <COND (<NOT <FSET? ,MURA-DOOR ,RMUNGBIT>>
+				     <FCLEAR ,MURA-DOOR ,OPENBIT>)>
+			      <MOVE ,TRAY ,ONNA>
+			      <QUEUE I-ONNA-RETURNS 2>
+			      <TELL "nods.  She smiles, politely takes the tray, and ">
+			      <COND (<FSET? ,MURA-DOOR ,RMUNGBIT>
+				     <TELL "then glances ruefully at the door." CR>)
+				    (ELSE
+				     <TELL "slides the door shut." CR>)>)
+			     (ELSE
+			      <TELL
+"says something incomprehensible." CR>)>)>)
+	       (<VERB? RUB RAISE FUCK>
+		<TELL
+CTHE ,ONNA " seems surprised, but not unwilling." CR>)>>
+
+<ROUTINE I-ONNA-RETURNS ()
+	 <MOVE ,FOOD ,TRAY>
+	 <MOVE ,CLOTHES ,HERE>
+	 <MOVE ,TRAY ,HERE>
+	 <MOVE ,BOOTS ,GARDEN>
+	 <TELL CR
+"The ">
+	 <COND (<HERE? ,MURA-HOUSE>
+		<TELL "door slides open again, and the ">)>
+	 <TELL "small woman reappears with more
+food, and your clothes which she places in a neat pile.  She bows
+again and departs." CR>>
+
+<OBJECT RIBBON
+	(DESC "silk ribbon")
+	(LDESC
+"Stretched across each doorway is a red silk ribbon.")
+	(SYNONYM RIBBON TAPE BANNER)
+	(ADJECTIVE RED SILK)
+	(FLAGS TAKEBIT READBIT)
+	(ACTION RIBBON-F)>
+
+<GLOBAL RIBBON-CNT 0>
+
+<ROUTINE RIBBON-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The wide band of red silk is pasted across the doorway.  It is covered with
+queer, squiggly writing." CR>)
+	       (<VERB? READ>
+		<TELL
+"The ribbon is covered with queer, squiggled writing.  You can't read it,
+though." CR>)
+	       (<VERB? POINT>
+		<TELL
+"The leader says, politely, \""I"Kasigi Yabu-sama!  Kinjiru!""\" ">
+		<COND (<NOT ,RIBBON-CNT>
+		       <TELL "He smiles politely." CR>)
+		      (ELSE
+		       <TELL "His expression is very serious." CR>)>)
+	       (<NOT <PASSIVE-VERB?>>
+		<TELL
+"\""I"Hotte oke!""\"  The samurai on guard shakes his head to make the point
+clear.">
+		<COND (<SCENE? S-ANJIRO>
+		       <TELL "He is no longer smiling.|
+|
+You try again.  \""I"Kinjiru!""\" the guards say emphatically.|
+|
+When you still don't seem to be listening, the guard yells,
+\""I"KINJIRU!""\" You are jerked around to face the samurai.  Their swords
+are half out of the scabbards.  They wait for you to make up your mind.|
+|
+You realize they are not going to let you retrieve your rutters, and
+begin to retreat.  You remember to bow and at once all hostility vanishes,
+but the guards are still watchful." CR>
+		       <SCORE-OBJECT ,SAMURAI-GUARDS>
+		       <CRLF>
+		       <GOTO ,AT-ERASMUS>)
+		      (ELSE
+		       <COND (<IN? ,RODRIGUES ,HERE>
+			      <TELL CR
+"\"Leave this to me, Ingeles!\" blusters Rodrigues." CR>)
+			     (ELSE <CRLF>)>)>)>>
+
+<ROUTINE I-RIBBON ()
+	 <COND (<AND <HERE? ,ON-DECK ,BRIDGE-OF-ERASMUS>
+		     <NOT <FSET? ,SAMURAI-GUARDS ,RMUNGBIT>>>
+		<SETG RIBBON-CNT <+ ,RIBBON-CNT 1>>
+		<COND (<G=? ,RIBBON-CNT 3>
+		       <CRLF>
+		       <JIGS-UP
+"In a flash, the samurai indicate that you have wasted too much of
+their time and patience.  You cannot benefit from this decision, as
+an instant later you are dead.">)
+		      (ELSE
+		       <QUEUE I-RIBBON 4>
+		       <TELL CR
+"The samurai leader makes a long speech part of which emphatically
+seems to indicate you are expected to leave immediately.   But what
+of your rutters?  How can you retrieve them?" CR>)>)>>
+
+<OBJECT SAMURAI-GUARDS
+	(SCENE S-ANJIRO S-RODRIGUES S-ESCAPE)
+	(DESC "samurai guards")
+	(SYNONYM SAMURAI GUARDS GUARD MAN MEN CREW CREWMEN CREWMAN)
+	(FLAGS PERSON JAPANESEBIT PLURAL SCOREBIT NOABIT)
+	(DESCFCN SAMURAI-GUARDS-DESC)
+	(GENERIC GENERIC-SAMURAI-F)
+	(ACTION SAMURAI-GUARDS-F)>
+
+<ROUTINE SAMURAI-GUARDS-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (<RARG? OBJDESC>
+		<TELL
+"Several samurai are at posts on the main deck.">
+		<COND (,RIBBON-CNT
+		       <TELL " They watch you warily.">)
+		      (<FSET? ,SAMURAI-GUARDS ,RMUNGBIT>
+		       <TELL " They seem relaxed.">)
+		      (ELSE
+		       <TELL " They seem a little nervous.">)>)>>
+
+<ROUTINE SAMURAI-GUARDS-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<TELL
+"None of the guards appear to understand you." CR>)
+	       (<VERB? EXAMINE>
+		<COND (<SCENE? S-ESCAPE>
+		       <TELL
+"They are at attention, alert, and rigidly correct in their bearing." CR>)
+		      (<HERE? ,ON-DECK ,AT-ERASMUS ,BRIDGE-OF-ERASMUS>
+		       <TELL
+"These men are all samurai.  Some have steel breastplates but most wear
+simple kimonos, and the two swords.  All wear their hair the same way:
+the top of the head shaved and the hair at the back and sides gathered
+into a queue, oiled, then doubled over the crown and tied neatly." CR>)
+		      (ELSE
+		       <TELL
+"You can't see the "I"Erasmus"" well enough from here to tell much about
+who's crewing it." CR>)>)
+	       (<VERB? WHO>
+		<COND (<SCENE? ,S-ANJIRO>
+		       <TELL
+"They are all dressed alike, so perhaps they are soldiers put here by
+the "I"daimyo""." CR>)
+		      (<SCENE? ,S-RODRIGUES>
+		       <TELL
+"They are samurai of Kasigi Yabu, the "I"daimyo"" of this province." CR>)>)
+	       (<HOSTILE-VERB?>
+		<COND (<OR <HERE? ,ON-DECK> <SCENE? ,S-ESCAPE>>
+		       <COND (<JIGS-UP? ,J-GUARDS>
+			      <JIGS-UP
+"They efficiently fill their function as guards.">)
+			     (ELSE <RTRUE>)>)
+		      (ELSE
+		       <TELL
+"Luckily for you, you aren't close enough to attack the guards." CR>)>)
+	       (<AND <HERE? ,ANJIRO-WATERFRONT>
+		     <NOT <ABSTRACT-VERB?>>>
+		<TELL
+"The crewmen on the "I"Erasmus"" aren't here." CR>
+		<COND (<VERB? TELL> <END-QUOTE> <RFATAL>)
+		      (ELSE <RTRUE>)>)
+	       (<VERB? GIVE SHOW>
+		<COND (<PRSO? ,HENCHMAN-HEAD>
+		       <TELL
+"They discuss it among themselves.  They don't seem upset or disgusted by it." CR>)
+		      (ELSE
+		       <TELL "They don't seem interested." CR>)>)
+	       (<VERB? BOW>
+		<COND (<SCENE? S-ESCAPE>
+		       <TELL
+"They return your bow with perfect military correctness." CR>)
+		      (<NOT <FSET? ,PRSO ,RMUNGBIT>>
+		       <FSET ,PRSO ,RMUNGBIT>
+		       <COND (<EQUAL? ,RIBBON-CNT 3>
+			      <TELL
+"You bow politely.  At once all the hostility vanishes and they all
+bow and smile again." CR>)
+			     (ELSE
+			      <TELL
+"All the guards relax slightly and begin to smile." CR>)>)
+		      (ELSE
+		       <TELL "The leader returns your bow.">
+		       <COND (,RIBBON-CNT
+			      <TELL
+"  The guards seem more relaxed now.">)>
+		       <CRLF>)>)
+	       (<VERB? TELL-ABOUT>
+		<TELL
+"They don't appear to understand you." CR>)>>
+
+<END-SEGMENT>
+
+
+
+"YABU for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc.  All Rights Reserved."
+
+<BEGIN-SEGMENT YABU>
+
+<ROOM VILLAGE-SQUARE	;"setup s-yabu"
+      (LOC ROOMS)
+      (SCENE S-YABU)
+      (DESC "Village Square")
+      (SCORE 2)
+      (FDESC
+"The next day, you and your crewmen are brought before the
+daimyo.  Samurai slam all of you on your knees and push your heads into the dust.")
+      (SYNONYM SQUARE)
+      (ADJECTIVE VILLAGE)
+      (NORTH TO BATH-HOUSE IF BATH-FLAG)
+      (FLAGS OUTSIDE ONBIT SCOREBIT)
+      (GLOBAL CREWMEN LG-ERASMUS VILLAGERS PIT LG-VILLAGE)
+      (ACTION VILLAGE-SQUARE-F)>
+
+<ROUTINE VILLAGE-SQUARE-F (RARG)
+	 <COND (<RARG? SCENE-SETUP>
+		<COND (<SCENE? ,S-YABU>
+		       <DRESS-BLACKTHORNE T>
+		       <B-KNEEL>
+		       <MOVE-CREW ,HERE T ;"set their ndescbits">
+		       <MOVE ,MURA ,HERE>
+		       <MOVE ,SEBASTIO ,HERE>
+		       <NEW-SDESC ,SEBASTIO "Father Sebastio">
+		       <MOVE ,OMI ,HERE>
+		       <NEW-SDESC ,OMI "Omi">
+		       <MOVE ,YABU ,HERE>
+		       <SETG YABU-CNT 0>
+		       <QUEUE I-YABU-AUDIENCE -1>)>)
+	       (<RARG? LOOK>
+		<TELL
+"This is the village square of Anjiro.  The day is clear and warm.">
+		<COND (<SCENE? S-YABU>
+		       <TELL " You are ">
+		       <COND (<B-KNEELING?>
+			      <TELL "kneeling">)
+			     (ELSE <TELL "standing">)>
+		       <TELL " in front of the platform.">)>
+		<COND (,BATH-FLAG
+		       <TELL
+" A narrow path leads north between two wooden fences.">)>
+		<CRLF>)
+	       (<RARG? BEG>
+		<COND (<AND <SCENE? ,S-YABU ,S-PIT>
+			    <P? BOW (<> OMI YABU)>>
+		       <COND (<NOT ,PRSO> <SETG PRSO ,YABU>)>
+		       <TELL "You bow">
+		       <COND (<B-NOT-STANDING?>
+			      <TELL ", bending forward from your ">
+			      <COND (<B-KNEELING?>
+				     <TELL "kneeling">)
+				    (ELSE <TELL "sitting">)>
+			      <TELL " position">)>
+		       <TELL ".  ">
+		       <COND (<QUEUED? I-BOW?>
+			      <DEQUEUE I-BOW?>
+			      <COND (<SCENE? ,S-YABU>
+				     <DEQUEUE I-YABU-AUDIENCE>
+				     <TELL
+"Yabu motions the guards forward, giving them curt orders.  \"You have
+insulted the Lord Yabu with your bad manners and incredible impertinence,\"
+explains Father Sebastio smugly.  Yabu turns to confer with Omi." CR>
+				     <COND (<FSET? ,SEBASTIO-CRUCIFIX ,SCOREBIT>
+					    <TELL CR
+"\"You are to be put to death for being a pirate and a heretic,\" says
+Sebastio, but for some reason you think he is lying.  Yabu looks pleased and
+Omi unhappy about the outcome.  Why, you wonder?  As the guards lead you
+away, you can't help believing you were close to convincing them to let you
+live." CR>
+					    <JIGS-UP>
+					    <RFATAL>)
+					   (ELSE
+					    <TELL CR
+"After a while, Yabu and Omi finish their polite discussion.  Yabu speaks
+to the guards again, and Father Sebastio explodes with indignation.  \"They
+are sparing you and your crew precisely because you are heretics who hate
+the true Church!  Surely this land is in the power of Satan!\"|
+|
+Yabu smiles happily at you and your crewmen, then points to you and barks
+an additional order to Omi, who bows.  You shudder, wondering what fate
+could be in store for you, and afraid you are about to find out." CR CR>
+					    <NEXT-SCENE>)>)
+				    (ELSE
+				     <TELL
+CTHE ,PRSO " returns your bow, and relaxes." CR>)>)
+			     (<SCENE? ,S-YABU>
+			      <TELL
+CTHE ,PRSO " returns your bow.  He seems at once astonished and amused by
+your behavior, but it's clear he has no love for the priest." CR>)
+			     (ELSE
+			      <TELL
+CTHE ,PRSO " seems pleased by this display of manners." CR>)>)
+		      (<SCENE? S-YABU>
+		       <COND (<AND <VERB? STAND>
+				   <B-NOT-STANDING?>>
+			      <TELL
+"You stand up.  The Japanese seem surprised by your audacity." CR>)
+			     (<ACT-CRAZY?>
+			      <TELL
+"Yabu stares at you in surprise.  You must be insane!" CR>)
+			     (<AND <VERB? TELL SEND>
+				   <NOT <PRSO? YABU SEBASTIO>>>
+			      <SPEAK-ONLY-TO-YABU>
+			      <COND (<VERB? TELL> <END-QUOTE> <RFATAL>)
+				    (ELSE <RTRUE>)>)>)
+		      (<SCENE? ,S-PIT>
+		       <COND (<P? THROUGH PIT>
+			      <DO-WALK ,P?DOWN>)
+			     (<AND <P? WALK P?DOWN>
+				   <IN? ,LADDER ,HERE>>
+			      <PERFORM ,V?CLIMB-DOWN ,LADDER>
+			      <RTRUE>)
+			     (<AND <VERB? LIE-DOWN BOARD LOWER>
+				   ,ANSWER-HAI?
+				   <FSET? ,CROOCQ ,SCOREBIT>>
+			      <COND (<NOT <B-LYING?>>
+				     <B-LIE-DOWN>
+				     <TELL
+"You do as you were ordered." CR>
+				     <SCORE-OBJECT ,CROOCQ>)>)>)>)>>
+
+<ROUTINE SPEAK-ONLY-TO-YABU ()
+	 <TELL
+"Yabu says something sharply, and the priest warns, \"Speak only to
+the Lord Yabu!  You are endangering your miserable life, heretic!\""
+CR>>
+
+<OBJECT SEBASTIO-CRUCIFIX
+	(SCENE S-ANJIRO S-YABU S-PIT)
+	(LOC SEBASTIO)
+	(DESC "crucifix")
+	(OWNER SEBASTIO)
+	(SYNONYM CRUCIFIX CROSS)
+	(ADJECTIVE PECTORAL WOOD WOODEN)
+	(FLAGS DONT-ALL TAKEBIT TRYTAKEBIT NDESCBIT SCOREBIT)
+	(ACTION SEBASTIO-CRUCIFIX-F)>
+
+<ROUTINE SEBASTIO-CRUCIFIX-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"It's wooden, beautifully carved">
+		<COND (<IN? ,PRSO ,SEBASTIO>
+		       <TELL ", and hangs on a long chain from the priest's
+belt." CR>)
+		      (ELSE <TELL "." CR>)>)
+	       (<VERB? MUNG THROW>
+		<COND (<AND ,PRSI
+			    <FSET? ,PRSI ,PERSON>
+			    <NOT <PRSI? ,SEBASTIO>>>
+		       <RFALSE>)
+		      (<IN? ,PRSO ,PLAYER>
+		       <COND (<AND <IN? ,OMI ,HERE> <IN? ,YABU ,HERE>>
+			      <QUEUE I-BOW? 2>)>
+		       <QUEUE I-SEBASTIO-PRAYS 1>
+		       <MOVE ,SEBASTIO-CRUCIFIX ,HERE>
+		       <COND (<VERB? MUNG>
+			      <TELL
+"You break the crucifix in two, and hurl the pieces ">)
+			     (ELSE
+			      <TELL
+"You throw the crucifix ">)>
+		       <COND (<PRSI? ,SEBASTIO>
+			      <TELL "at " THE ,SEBASTIO ".">)
+			     (ELSE <TELL "on the ground.">)>
+		       <COND (<AND <IN? ,OMI ,HERE> <IN? ,YABU ,HERE>>
+			      <TELL
+" The samurai watch.  Omi, in particular, seems interested and excited.">)>
+		       <CRLF>
+		       <SCORE-OBJECT ,SEBASTIO-CRUCIFIX>)
+		      (ELSE
+		       <TELL
+"You don't have it." CR>)>)
+	       (<VERB? PISS>
+		<TELL
+"You are so nervous that you can't." CR>)
+	       (<VERB? SPIT>
+		<TELL
+"Your mouth is so dry from tension and fear that you can't muster any
+spit." CR>)
+	       (<P? GIVE SEBASTIO-CRUCIFIX>
+		<COND (<PRSI? SEBASTIO>
+		       <MOVE ,SEBASTIO-CRUCIFIX ,SEBASTIO>
+		       <TELL
+"He snatches it back, snarling." CR>)
+		      (<PRSI? ,YABU ,OMI>
+		       <TELL
+"He refuses, looking rather surprised." CR>)>)
+	       (<VERB? TAKE>
+		<COND (<NOT <FSET? ,PRSO ,SCOREBIT>>
+		       <TELL
+"You pick up the broken pieces of the crucifix.  Sebastio watches you
+with contempt and hatred." CR>)
+		      (<NOT <IN? ,PRSO ,SEBASTIO>>
+		       <RFALSE>)
+		      (<FSET? ,SEBASTIO-CRUCIFIX ,RMUNGBIT>
+		       <QUEUE I-BOW? 2>
+		       <FCLEAR ,PRSO ,DONT-ALL>
+		       <MOVE ,PRSO ,PLAYER>
+		       <FSET ,PRSO ,TOUCHBIT>
+		       <TELL
+"You snatch the crucifix from " THE ,SEBASTIO "'s hand.  He stares at
+you, shocked and astonished.  Yabu watches your incredible behavior
+with disgust, Omi with increasing interest.  You can almost see his
+curiosity: what will the barbarian do next?" CR>)
+		      (ELSE
+		       <TELL
+"You grab for the crucifix, but Sebastio snatches it away, holding
+it up as if to ward you off.  \"Demon!  Heretic!\" he screams.  \"You'd
+love to defile this holy cross to prove to these pagans you're also a
+satan worshipper and an enemy of the church!  You'll die first!\"" CR>
+		       <JAPANESE-INTERESTED?>)>)>>
+
+<ROUTINE JAPANESE-INTERESTED? ()
+	 <COND (<IN? ,OMI ,HERE>
+		<COND (<IN? ,YABU ,HERE>
+		       <TELL CR
+"Yabu appears a little less bored, and Omi somewhat interested by
+your behavior." CR>)
+		      (ELSE
+		       <TELL CR
+CTHE ,OMI " watches this exchange with interest.  He seems
+very excited by your apparent hatred of the priest." CR>)>)>
+	 <RTRUE>>
+
+<ROUTINE I-SEBASTIO-PRAYS ()
+	 <TELL CR
+CTHE ,SEBASTIO " kneels, staring fixedly at the pieces of the cross.  He
+picks up the violated wood.  He turns to you, and says quietly, \"I
+will pray for you, heretic.\"" CR>>
+
+<ROUTINE I-BOW? ()
+	 <TELL CR
+"Yabu seems to have taken your treatment of the priest as a personal
+insult.  Amazed by your lack of manners, he orders you
+put to death." CR>
+	 <JIGS-UP>
+	 <RFATAL>>
+
+<GLOBAL YABU-QUESTION 0>
+
+<ROUTINE I-YABU-AUDIENCE ()
+	 <ZLINES ,YABU-CNT
+		 (<SETUP-ANSWER "i am">
+		  <THIS-IS-IT ,SEBASTIO>
+		  <SETG QCONTEXT ,YABU>
+		  <SETG YABU-QUESTION 1>
+		  <TELL CR
+"Father Sebastio comes forward.  \"I will translate for you,\" he
+says.  \"The "I"daimyo"", Kasigi Yabu, Lord of Izu, wants to know who you are,
+where you come from, how you got here, and what acts of piracy you have
+committed.\"" CR>)
+		 (DELAY
+		  <COND (<EQUAL? ,YABU-QUESTION 1>
+			 <THIS-IS-IT ,SEBASTIO>
+			 <COND (<G? ,DELAY-CNT 3>
+				<YABU-SAYS "filthy barbarian pirate">
+				<RFATAL>)
+			       (ELSE
+				<SETUP-ANSWER "i am">
+				<TELL CR
+"\"Answer the "I"daimyo"", heretic!  Who are you?\"" CR>
+				<RTRUE>)>)>)
+		 (<SETUP-ANSWER "i sailed from">
+		  <THIS-IS-IT ,SEBASTIO>
+		  <SETG QCONTEXT ,YABU>
+		  <SETG YABU-QUESTION 2>
+		  <TELL CR
+"Father Sebastio asks, \"Where did you sail from?\"" CR>)
+		 (DELAY
+		  <COND (<EQUAL? ,YABU-QUESTION 2>
+			 <THIS-IS-IT ,SEBASTIO>
+			 <COND (<G? ,DELAY-CNT 3>
+				<YABU-SAYS "mannerless freak">
+				<RFATAL>)
+			       (ELSE
+				<SETUP-ANSWER "i sailed from">
+				<TELL CR
+"\"Answer the "I"daimyo"", heretic!  Where did your pirate ship sail
+from?\"" CR>
+				<RTRUE>)>)>)
+		 (<SETG YABU-QUESTION 3>
+		  <THIS-IS-IT ,SEBASTIO>
+		  <SETG QCONTEXT ,YABU>
+		  <SETUP-ANSWER "i am">
+		  <TELL CR
+"The Jesuit asks, \"What are you?  You're not the Captain!\"" CR>)
+		 (DELAY
+		  <COND (<EQUAL? ,YABU-QUESTION 3>
+			 <THIS-IS-IT ,SEBASTIO>
+			 <COND (<G? ,DELAY-CNT 3>
+				<CRLF>
+				<YABU-SAYS "barbarian ape">
+				<RFATAL>)
+			       (ELSE
+				<SETUP-ANSWER "i am">
+				<TELL CR
+"\"Answer the "I"daimyo"", heretic!  What are you?  You're obviously
+an officer!\"" CR>
+				<RTRUE>)>)>)
+		 (<SETG YABU-QUESTION 4>
+		  <THIS-IS-IT ,SEBASTIO>
+		  <SETG QCONTEXT ,YABU>
+		  <SETUP-ANSWER "i sailed">
+		  <TELL CR
+"Father Sebastio asks, trying to control his anger, \"How did you get
+here?\"" CR>)
+		 (DELAY
+		  <COND (<EQUAL? ,YABU-QUESTION 4>
+			 <THIS-IS-IT ,SEBASTIO>
+			 <COND (<G? ,DELAY-CNT 2>
+				<SETG YABU-QUESTION 0>
+				<TELL CR
+G"The priest confers with Yabu.  \"Yabu says ""it is unimportant.  We
+will find out these facts in due time.\"" CR>
+				<RFATAL>)
+			       (ELSE
+				<SETUP-ANSWER "i sailed">
+				<TELL CR
+"\"Answer the "I"daimyo""!  How did you get here?\"" CR>
+				<RTRUE>)>)>)
+		 (<SETG YABU-QUESTION 0>
+		  <THIS-IS-IT ,SEBASTIO>
+		  <SETG QCONTEXT <>>
+		  <SETUP-ANSWER <>>
+		  <FSET ,SEBASTIO-CRUCIFIX ,RMUNGBIT>
+		  <THIS-IS-IT ,SEBASTIO-CRUCIFIX>
+		  <TELL CR
+"Now, " THE ,SEBASTIO " is barely listening to you.  \"You're a lying
+heretic pirate!\" screams the priest, spittle flying from his mouth
+as he whirls toward you, shaking his fist.  His crucifix on its long
+chain waves mockingly near your face." CR>)
+		 (<THIS-IS-IT ,YABU>
+		  <TELL CR
+"\""I"Ano mono wa nani o moshite oru?\""" the "I"daimyo"" snaps
+impatiently." CR>)
+		 (2
+		  <THIS-IS-IT ,YABU>
+		  <TELL CR
+"Yabu is becoming bored and impatient.  He turns his back to the priest,
+obvious detestation all over his face." CR>)
+		 (3
+		  <TELL CR
+CTHE ,SEBASTIO " translates Yabu's sentence. \"This ship, alien, non-Portuguese, and pirate, is
+confiscated with all it contains.  All pirates are sentenced to immediate
+crucifixion.\"" CR>
+		  <DEQUEUE I-YABU-AUDIENCE>
+		  <JIGS-UP>)>>
+
+<ROUTINE YABU-SAYS (STR)
+	 <CRLF>
+	 <TELL
+G"The priest confers with Yabu.  \"Yabu says ""you are a " .STR ", and you
+are condemned to death.\"">
+	 <JIGS-UP>>
+
+<END-SEGMENT>
+
+
+
+<BEGIN-SEGMENT PIT>
+
+<ROOM PIT	;"setup s-pit"
+      (LOC ROOMS)
+      (SCENE S-PIT)
+      (DESC "Pit")
+      (AFTER PIT-AFTER-F)
+      (SYNONYM PIT CELLAR)
+      (SCORE 5)
+      (FDESC
+"At Yabu's order, the samurai herd you and your crew across the square,
+down a ladder, and underground.  A trap door locks above you.")
+      (FLAGS ONBIT)
+      (GLOBAL TRAPDOOR LG-CREWMEN PIETERZOON)
+      (ACTION PIT-F)>
+
+<ROUTINE PIT-F (RARG)
+	 <COND (<RARG? SCENE-SETUP>
+		<DRESS-BLACKTHORNE T>
+		<PUTP ,VILLAGE-SQUARE ,P?FDESC <>>
+		<NEW-SDESC ,ONNA "Onna">
+		<NEW-SDESC ,SEBASTIO "Father Sebastio">
+		<REMOVE ,SEBASTIO-CRUCIFIX>
+		<NEW-SDESC ,OMI "Omi">
+		<MOVE ,CAULDRON ,VILLAGE-SQUARE>
+		<MOVE-CREW ,PIT>
+		<REMOVE ,CREWMEN>
+		<MOVE ,ROPER ,HERE>
+		<MOVE ,SONK ,HERE>
+		<QUEUE I-PIT -1>)
+	       (<RARG? LOOK>
+		<TELL
+"You are crammed into a deep cellar, one of the many that the fishermen
+use to store sun-dried fish.  The cellar is five paces long and five wide
+and four deep, with an earthen floor and walls.  ">
+		<COND (<IN? ,OFFAL ,HERE>
+		       <TELL
+"The floor is awash with rotting fish offal and seawater.  ">)>
+		<TELL-CEILING>)
+	       (<RARG? BEG>
+		<COND (<P? DISEMBARK ROOMS>
+		       <DO-WALK ,P?UP>)
+		      (<P? BOARD GLOBAL-HERE>
+		       <TELL G"You already are." CR>)
+		      (<AND <VERB? PICK>
+			    <FSET? ,PRSO ,PERSON>
+			    ,MUST-CHOOSE?>
+		       <TELL
+"\"The only fair thing is to draw straws!\" says Vinck." CR>)
+		      (<AND <HOSTILE-VERB?>
+			    <PRSO? ,OMI ,MURA ,SEBASTIO>>
+		       <TELL
+G"You can't reach ""him." CR>)
+		      (<AND <VERB? PISS>
+			    ,PRSO
+			    <FSET? ,PRSO ,PERSON>>
+		       <TELL
+"The crewmen are appalled at your behavior.  " CTHE ,PRSO " squirms
+away, trying to clean himself off." CR>)
+		      (<AND <P? SIT (ROOMS GROUND)>
+			    <B-STANDING?>
+			    <IN? ,OFFAL ,HERE>>
+		       <B-SIT>
+		       <TELL
+"You find a relatively dry spot and sit down.  The others complain but
+they finally rearrange themselves and quiet down." CR>)
+		      (<AND <P? LIE-DOWN>
+			    <IN? ,OFFAL ,HERE>>
+		       <TELL
+"You want to lie down in old fish heads?  You must be a barbarian!" CR>)
+		      (<VERB? YELL YELL-AT>
+		       <COND (<NOT <FSET? ,TRAPDOOR ,OPENBIT>>
+			      <TELL
+"You begin yelling, and everyone else joins in.  \"Water!  And food, by
+God!  Let us out of here!\"" CR>)
+			     (ELSE
+			      <TELL
+"The Japanese look at you with contempt." CR>)>)
+		      (<P? LOOK-UP>
+		       <TELL-CEILING>)
+		      (<P? WALK (P?UP P?OUT)>
+		       <COND (<IN? ,LADDER ,HERE>
+			      <PERFORM ,V?CLIMB-FOO ,LADDER>
+			      <RTRUE>)
+			     (ELSE
+			      <TELL
+"You can't climb out without a ladder.  The pit is too deep." CR>)>)
+		      (<P? (PARRY STOP) <>>
+		       <COND (<OR <IN? ,OMI-SAMURAI ,LADDER>
+				  <IN? ,OMI-SAMURAI ,PIT>>
+			      <PERFORM ,V?ATTACK ,OMI-SAMURAI>
+			      <RTRUE>)>)
+		      (<OR <P? (HELP TAKE STOP PUSH-DOWN SIT)
+			       (VINCK PIETERZOON)>
+			   <P? (HELP STOP) ME>>
+		       <COND (<PRSO? VINCK ME>
+			      <PERFORM ,V?STOP ,LADDER>
+			      <RTRUE>)
+			     (<AND <PRSO? PIETERZOON>
+				   <IN? ,PIETERZOON ,CAULDRON>>
+			      <TELL
+			       "\"">
+			      <COND (,VINCK-PICKED? <TELL "Vinck">)
+				    (ELSE <TELL "The Pilot">)>
+			      <TELL
+" should have gone.  He was the lamb of God.  And now his
+soul's forfeit, he'll burn for all eternity.\"" CR>)>)
+		      (<AND <P? LISTEN (<> PIETERZOON VINCK)>
+			    <OR <IN? ,PIETERZOON ,CAULDRON>
+				<IN? ,VINCK ,CAULDRON>>>
+		       <TELL
+"There is no longer any sound.  The silence, you fear, is that of death." CR>)>)>>
+
+<ROUTINE TELL-CEILING ()
+	 <TELL
+"The ceiling is made of planks with a foot of earth above and a single ">
+	 <COND (<FSET? ,TRAPDOOR ,OPENBIT>
+		<TELL "open ">)
+	       (ELSE
+		<TELL "closed ">)>
+	 <TELL D ,TRAPDOOR " set into it." CR>>
+
+<OBJECT SEAWATER
+	(DESC "seawater")
+	(SYNONYM SEAWATER WATER)
+	(ADJECTIVE SEA)
+	(FLAGS NDESCBIT)
+	(ACTION SEAWATER-F)>
+
+<ROUTINE SEAWATER-F ()
+	 <COND (<VERB? DRINK>
+		<TELL
+"You'll go mad from drinking seawater!" CR>)>>
+
+<OBJECT OFFAL
+	(DESC "offal")
+	(SYNONYM OFFAL HEADS FISH ENTRAILS)
+	(ADJECTIVE FISH ROTTING)
+	(FLAGS NDESCBIT)
+	(ACTION OFFAL-F)>
+
+<ROUTINE OFFAL-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"It's rotting fish heads and entrails." CR>)
+	       (<VERB? SMELL>
+		<TELL
+"It smells offal." CR>)
+	       (<VERB? EAT>
+		<TELL
+"You'd be crazy to eat that!" CR>)>>
+
+<GLOBAL VINCK-PICKED? <>>
+
+<ROUTINE I-PIT ()
+	 <ZLINES ,PIT-CNT
+		 (<TELL CR
+"Captain-General Spillbergen, half-awake and querulous, says \"Pass the
+water.\"" CR CR
+"\"There isn't any, Paulus\" Van Nekk answers gloomily, \"We haven't
+even got a pot to piss in!\"" CR CR
+"Spillbergen points at Vinck.  \"Ask for water!\" he orders." CR CR
+"Vinck stands under the opening and shouts, \"Hey!  You up there!  Give
+us God-cursed water!  We want food and water!\"" CR CR
+"There is no answer." CR>)
+		 (<FSET ,TRAPDOOR ,OPENBIT>
+		  <MOVE ,OMI ,TRAPDOOR>
+		  <MOVE ,SEBASTIO ,TRAPDOOR>
+		  <MOVE ,MURA ,TRAPDOOR>
+		  <MARGINAL-PIC ,P-PIT>
+		  <TELL CR
+"The trapdoor opens.  Omi looks down at you.  Beside him are Mura and the
+priest.">
+		  <COND (<VERB? YELL YELL-AT>
+			 <TELL
+" Everyone but you begins yelling.  \"Water!  And food, by God!  Let
+us out of here!\"">)
+			(ELSE
+			 <TELL
+" Everyone is still yelling.">)>
+		  <MOVE ,OFFAL ,PIT>
+		  <MOVE ,SEAWATER ,PIT>
+		  <TELL " Omi motions to Mura, who nods and leaves." CR CR
+"Mura returns with another fisherman, carrying a large barrel.  They empty
+the contents, rotting fish offal and seawater, onto your heads." CR>)
+		 (<SETG MUST-CHOOSE? T>
+		  <FCLEAR ,TRAPDOOR ,OPENBIT>
+		  <MOVE ,SEBASTIO ,VILLAGE-SQUARE>
+		  <MOVE ,MURA ,VILLAGE-SQUARE>
+		  <MOVE ,OMI ,VILLAGE-SQUARE>
+		  <TELL CR
+"Omi begins talking.  When he finishes, the priest nervously
+translates.  \"These are Kasigi Omi's orders: You will begin to act like
+decent human
+beings.  You will make no more noise.  When you have learned to behave, you
+will be allowed up into the world of men.  Lord Yabu has spared all your
+lives, providing you serve him loyally.  All except one.  One of you is to
+die.  At dusk.  You are to choose who it will be.\"" CR CR
+"The trapdoor slams into place." CR>)
+		 (<MOVE ,VINCKS-STRAW ,HERE>
+		  <SETG VINCK-PICKED? <>>
+		  <COND (<PROB 50> <SETG VINCK-PICKED? T>)>
+		  <MOVE ,STRAW ,SPILLBERGEN>
+		  <TELL CR
+"It's now very near dusk." CR CR
+"Spillbergen collects a bundle of rice straw stalks from the litter in
+the pit.  Slowly, reluctantly,
+the crewmen draw straws.  Sonk first, then Pieterzoon, then Jan Roper,
+Salomon, and Croocq.  Then Ginsel is safe.  Five left.  Maetsukker, weeping
+openly, pushes Vinck aside and takes a straw.  He can't believe it's not
+the one.  Van Nekk picks and the straw is not short!|
+|
+Vinck watches his fingers select a straw and it falls to
+the ground but everyone sees it's the shortest straw yet.|
+|
+Now it's your turn.  Spillbergen holds out his trembling hand toward
+you.  There are only two straws left; one for you and one for the
+Captain." CR>)
+		 (DELAY
+		  <COND (<NOT <OR <IN? ,SHORT-STRAW ,BLACKTHORNE>
+				  <IN? ,LONG-STRAW ,BLACKTHORNE>>>
+			 <COND (<G? ,DELAY-CNT 5>
+				<TELL CR
+"One of the men hits you over the head, you fight back, and in no time
+it's a melee.  You are knocked unconscious, and drown, unnoticed as the
+rest of the crew squabbles." CR>
+				<JIGS-UP>
+				<RFATAL>)
+			       (ELSE
+				<TELL CR
+"\"Pick, curse you!\" yells Maetsukker.  \"Yes, pick!\" the other crewmen
+take up the cry." CR>
+				<COND (<EQUAL? ,DELAY-CNT 5>
+				       <TELL CR
+"You realize you'd better pick now, or you'll be forced to." CR>)>
+				<RTRUE>)>)>)
+		 (<TELL CR
+"Spillbergen, last to pick, unclenches his hand and you see that
+his straw is long.  Everyone stares at ">
+		  <SETG PIT-CNT 0>
+		  <SETG MUST-CHOOSE? <>>
+		  <DEQUEUE I-PIT>
+		  <COND (,VINCK-PICKED?
+			 <QUEUE I-TAKE-VINCK -1>
+			 <TELL "Vinck.  \"I'm dead!\" he
+laughs, unnerving you all." CR>)
+			(ELSE
+			 <QUEUE I-TAKE-YOU -1>
+			 <TELL "you.  The men ease away from you." CR>)>)>>
+
+<GLOBAL MUST-CHOOSE? <>>
+
+<ROUTINE TRAPDOOR-OPENS ()
+	 <TELL CR
+"The trapdoor opens.  Omi stands etched against the sky, his kimono blooded
+by the dying sun.  The ladder is lowered, and Omi motions for the one man
+to come up.  \""I"Isogi""!\" he barks.  Hurry up.  ">>
+
+<ROUTINE I-TAKE-VINCK ()
+	 <ZLINES ,PIT-CNT
+		 (<FSET ,TRAPDOOR ,OPENBIT>
+		  <MOVE ,OMI ,TRAPDOOR>
+		  <MOVE ,LADDER ,HERE>
+		  <TRAPDOOR-OPENS>
+		  <TELL "Vinck tries to stand, but
+his legs fail him.  Pieterzoon bends down to help him to his feet." CR>)
+		 (<COND (<NOT <FSET? ,VINCK ,RMUNGBIT>>
+			 <THEY-TAKE-VICTIM ,VINCK>)
+			(<FSET? ,LADDER ,SCOREBIT>
+			 <TELL CR
+"\"Get away from the ladder, Pilot!  You're ordered away!\"  Spillbergen shakily
+keeps to his corner, as far from the ladder as possible." CR>)
+			(ELSE
+			 <TELL CR
+"Vinck comes out of his cataleptic state and throws himself at one of the
+samurai, berserk.  He intercepts a blow that would have sliced your wrist
+off." CR>)>)
+		 (<COND (<FSET? ,LADDER ,SCOREBIT>
+			 <TELL CR
+"Vinck begins to climb the ladder, almost in a trance." CR>)
+			(<FSET? ,OMI-SAMURAI ,RMUNGBIT>
+			 <FCLEAR ,OMI-SAMURAI ,RMUNGBIT>
+			 <RFALSE>)
+			(ELSE
+			 <OMI-BARKS>)>)
+		 (DELAY
+		  <COND (<AND <FSET? ,LADDER ,RMUNGBIT>
+			      <L? ,DELAY-CNT 2>>
+			 <FCLEAR ,LADDER ,RMUNGBIT>
+			 <RFALSE>)
+			(<AND <IN? ,LOSING-SAMURAI ,PIT>
+			      <FSET? ,LOSING-SAMURAI ,SCOREBIT>
+			      <L? ,DELAY-CNT 5>>
+			 <RFALSE>)>)
+		 (<COND (<FSET? ,LADDER ,SCOREBIT>
+			 <FCLEAR ,LADDER ,SCOREBIT>
+			 <TELL CR
+G"The samurai are hampered by the confined space, but a kick from one of
+them catches Vinck in the face and he reels away." CR>)
+			(ELSE
+			 <THEY-TAKE-VICTIM ,PIETERZOON>)>)
+		 (DELAY
+		  <COND (<FSET? ,LADDER ,RMUNGBIT>
+			 <FCLEAR ,LADDER ,RMUNGBIT>
+			 <RFALSE>)
+			(<AND <IN? ,LOSING-SAMURAI ,PIT>
+			      <FSET? ,LOSING-SAMURAI ,SCOREBIT>
+			      <L? ,DELAY-CNT 5>>
+			 <RFALSE>)>)
+		 (<COND (<NOT <FSET? ,LADDER ,SCOREBIT>>
+			 <THEY-TAKE-VICTIM ,PIETERZOON>)>)>>
+
+<ROUTINE OMI-BARKS ()
+	 <TELL CR
+"Omi barks an order, and several ">
+	 <COND (<IN? ,OMI-SAMURAI ,LADDER> <TELL "more ">)
+	       (ELSE
+		<FSET ,OMI-SAMURAI ,RMUNGBIT>
+		<MOVE ,OMI-SAMURAI ,LADDER>)>
+	 <THIS-IS-IT ,OMI-SAMURAI>
+	 <TELL "samurai start to descend the ladder." CR>
+	 <SCORE-OBJECT ,LADDER>
+	 <RTRUE>>
+
+<ROUTINE I-TAKE-YOU ()
+	 <COND (<IN? ,BLACKTHORNE ,VILLAGE-SQUARE>
+		<DEQUEUE I-TAKE-YOU>
+		<CRLF>
+		<JIGS-UP
+"Almost immediately, the samurai surround you, truss you up, and
+dump you in the huge iron cauldron.  The fire beneath it is lit,
+the water begins to heat up.|
+|
+At first the heat is almost pleasant, but then it begins to sear
+into your exhausted flesh, and you struggle vainly to break your
+bonds.  You begin to scream.|
+|
+Just as you lose consciousness, you see the samurai bringing up
+Vinck, and you can't help but wonder what would have happened had
+you resisted.">
+		<RFATAL>)>
+	 <ZLINES ,PIT-CNT
+		 (<FSET ,TRAPDOOR ,OPENBIT>
+		  <MOVE ,OMI ,TRAPDOOR>
+		  <MOVE ,LADDER ,HERE>
+		  <TRAPDOOR-OPENS>
+		  <TELL
+"Roper says, \"Don't be afraid, Pilot.  You're the anointed of God.  You're
+in God's hands.\"" CR>)
+		 (<COND (<FSET? ,OMI-SAMURAI ,RMUNGBIT>
+			 <FCLEAR ,OMI-SAMURAI ,RMUNGBIT>
+			 <RFALSE>)
+			(ELSE
+			 <OMI-BARKS>
+			 <RTRUE>)>)
+		 (<TELL CR
+G"The samurai are hampered by the confined space, but a kick from one of
+them catches Vinck in the face and he reels away." CR>)
+		 (DELAY
+		  <COND (<AND <IN? ,LOSING-SAMURAI ,PIT>
+				  <FSET? ,LOSING-SAMURAI ,SCOREBIT>>
+			 <RFALSE>)
+			(<FSET? ,LADDER ,SCOREBIT>
+			 <COND (<G? ,DELAY-CNT 4>
+				<FCLEAR ,LADDER ,SCOREBIT>)>
+			 <RFALSE>)>)
+		 (<COND (<NOT <FSET? ,LADDER ,SCOREBIT>>
+			 <THEY-TAKE-VICTIM ,PIETERZOON>)>)
+		 (<DEQUEUE I-TAKE-YOU>
+		  <RFALSE>)>>
+
+<NEW-ADD-WORD "STRAWS" NOUN <VOC "STRAW"> ,PLURAL-FLAG>
+
+<OBJECT STRAW
+	(DESC "straw")
+	(SYNONYM STRAW STALK)
+	(ADJECTIVE RICE)
+	(FLAGS TAKEBIT)
+	(GENERIC GENERIC-STRAW-F)
+	(ACTION STRAW-F)>
+
+<ROUTINE GENERIC-STRAW-F (R F)
+	 <COND (<AND <LOC ,LONG-STRAW> <LOC ,SHORT-STRAW>>
+		<>)
+	       (ELSE ,STRAW)>>
+
+<ROUTINE STRAW-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"There are two straws in Spillbergen's hand.  You stare at them intently,
+but you can discern no difference between them." CR>)
+	       (<VERB? TAKE PICK DRAW>
+		<REMOVE ,STRAW>
+		<COND (,VINCK-PICKED?
+		       <MOVE ,SHORT-STRAW <LOC ,VINCKS-STRAW>>
+		       <REMOVE ,VINCKS-STRAW>
+		       <PUTP ,SHORT-STRAW ,P?OWNER ,VINCK>
+		       <MOVE ,LONG-STRAW ,BLACKTHORNE>
+		       <TELL
+"You pick a straw, drawing your life out of Spillbergen's hand.  It's
+long!" CR>)
+		      (ELSE
+		       <MOVE ,LONG-STRAW <LOC ,VINCKS-STRAW>>
+		       <REMOVE ,VINCKS-STRAW>
+		       <PUTP ,LONG-STRAW ,P?OWNER ,VINCK>
+		       <MOVE ,SHORT-STRAW ,BLACKTHORNE>
+		       <TELL
+"You take a straw, and as you see it emerge, you realize that it's
+short, very short!  Shorter than Vinck's.  Vinck laughs a short, barking
+laugh, then is quiet." CR>)>)>>
+
+<OBJECT VINCKS-STRAW
+	(DESC "Vinck's straw")
+	(OWNER VINCK)
+	(SYNONYM STRAW STALK)
+	(ADJECTIVE RICE SHORTEST)
+	(FLAGS TAKEBIT NOABIT)
+	(GENERIC GENERIC-STRAW-F)
+	(ACTION VINCKS-STRAW-F)>
+
+<ROUTINE VINCKS-STRAW-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"It's the shortest drawn yet." CR>)
+	       (<VERB? TAKE>
+		<TELL "\"No, Pilot, draw your own straw!\"" CR>)>>
+
+<OBJECT SHORT-STRAW
+	(DESC "short straw")
+	(OWNER <>)
+	(SYNONYM STRAW STALK)
+	(ADJECTIVE RICE SHORT)
+	(FLAGS TAKEBIT)
+	(GENERIC GENERIC-STRAW-F)
+	(ACTION SHORT-STRAW-F)>
+
+<ROUTINE SHORT-STRAW-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"It's very short." CR>)
+	       (<VERB? TRADE GIVE>
+		<TELL
+"No one wants the short straw." CR>)
+	       (<P? ASK-FOR VINCK SHORT-STRAW>
+		<PERFORM ,V?TRADE ,LONG-STRAW ,VINCK>
+		<RTRUE>)>>
+
+<OBJECT LONG-STRAW
+	(DESC "long straw")
+	(OWNER <>)
+	(SYNONYM STRAW STALK)
+	(ADJECTIVE RICE LONG)
+	(FLAGS TAKEBIT)
+	(GENERIC GENERIC-STRAW-F)
+	(ACTION LONG-STRAW-F)>
+
+<ROUTINE LONG-STRAW-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"It's blessedly long." CR>)
+	       (<P? ASK-FOR>
+		<PERFORM ,V?TRADE ,SHORT-STRAW>
+		<RTRUE>)
+	       (<AND <P? (TRADE GIVE) LONG-STRAW (<> VINCK SHORT-STRAW)>
+		     <HELD? ,LONG-STRAW>>
+		<REMOVE ,LONG-STRAW>
+		<DEQUEUE I-TAKE-VINCK>
+		<QUEUE I-TAKE-YOU -1>
+		<TELL
+"\"Bless you, Pilot!\" babbles Vinck">
+		<COND (<IN? ,SHORT-STRAW ,VINCK>
+		       <MOVE ,SHORT-STRAW ,PLAYER>
+		       <TELL
+", thrusting the death straw into your hands." CR>)
+		      (ELSE <TELL "." CR>)>)>>
+
+<ROUTINE THEY-TAKE-VICTIM (WHO)
+	 <MOVE ,OMI ,VILLAGE-SQUARE>
+	 <MOVE ,OMI-SAMURAI ,VILLAGE-SQUARE>
+	 <NEW-SDESC ,OMI-SAMURAI "samurai guards" T>
+	 <FSET ,OMI-SAMURAI ,NOABIT>
+	 <MOVE ,BLACKTHORNE ,HERE>
+	 <REMOVE ,LADDER>
+	 <MOVE .WHO ,CAULDRON>
+	 ;<FSET .WHO ,NDESCBIT>
+	 <FCLEAR ,TRAPDOOR ,OPENBIT>
+	 <FCLEAR ,LADDER ,SCOREBIT> ;"just in case"
+	 <COND (<EQUAL? .WHO ,VINCK>
+		<TELL CR
+"Vinck, in an almost cataleptic state, climbs onto the ladder, pulling
+himself painfully upward.  Van Nekk and Jan Roper are praying silently,
+their eyes closed.  Pieterzoon cannot watch.  You stare ashamedly at Vinck,
+hating yourself for letting him go." CR CR
+"As he reaches the top of the ladder, three samurai grab him.  The ladder
+is quickly pulled up and the trapdoor slams shut like the sound of doom." CR>
+		<FAILED-SCENE>
+		<RTRUE>)
+	       (<EQUAL? .WHO ,PIETERZOON>
+		<MOVE ,VINCK ,HERE>
+		<TELL CR
+"Three more samurai, carrying knives and wearing only loincloths, leap
+nimbly into the cellar.  The first two crash into you, carrying you
+helpless to the floor.  ">
+		<COND (<IN? ,DAGGER ,BLACKTHORNE>
+		       <MOVE ,DAGGER ,HERE>
+		       <TELL "The dagger falls from your grip.  ">)>
+		<TELL
+"They attack viciously, and the crewmen retreat.">
+		<COND (<IN? ,DAGGER ,HERE>
+		       <REMOVE ,DAGGER>
+		       <TELL "One samurai retrieves the dagger.">)>
+		<TELL "|
+|
+Omi comes arrogantly into the pit and grabs the nearest man, who is
+Pieterzoon.  He jerks him toward the ladder.  \"Christ help me, it's not
+me that's to go -- \"Pieterzoon is being driven up the ladder." CR CR
+"Omi follows without hurrying.  The samurai retreat">
+		<COND (<IN? ,LOSING-SAMURAI ,HERE>
+		       <COND (<FSET? ,LOSING-SAMURAI ,SCOREBIT>
+			      <REMOVE ,LOSING-SAMURAI>
+			      <TELL ", including the one you knocked off
+of the ladder, though he appears wary and even embarassed.">)
+			     (ELSE
+			      <TELL " stepping contemptuously over
+the prostrate body of their unconscious comrade.">)>)
+		      (ELSE <TELL ".">)>
+		<TELL " The ladder is jerked aloft.  Air and
+sky and light vanish.  Bolts crash into place." CR>)>
+	 <DEQUEUE I-TAKE-VINCK>
+	 <DEQUEUE I-TAKE-YOU>
+	 <SETG PIT-CNT 0>
+	 <QUEUE I-TAKE-CROOCQ -1>
+	 <RTRUE>>
+
+<OBJECT TRAPDOOR
+	(LOC PIT)
+	(DESC "trapdoor")
+	(SYNONYM TRAPDOOR DOOR OPENING CEILING)
+	(ADJECTIVE TRAP)
+	(FLAGS DOORBIT SEARCHBIT)
+	(DESCFCN TRAPDOOR-DESC)
+	(ACTION TRAPDOOR-F)>
+
+<ROUTINE TRAPDOOR-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?>
+		<COND (<FSET? .OBJ ,OPENBIT> <RTRUE>)
+		      (ELSE <RFATAL>)>)
+	       (ELSE
+		<TELL
+"Through the open trapdoor you can see Omi">
+		<COND (<IN? ,MURA ,TRAPDOOR>
+		       <TELL ", Father Sebastio and Mura">)>
+		<TELL " silhouetted against the sky.">)>>
+
+<ROUTINE TRAPDOOR-F ("OPT" (RARG <>))
+	 <COND (.RARG <RFALSE>)
+	       (<VERB? OPEN CLOSE>
+		<COND (<IN? ,WINNER ,LADDER>
+		       <TELL
+"The weapons of the samurai prevent you from climbing high enough." CR>)
+		      (ELSE
+		       <TELL G"You can't reach ""it." CR>)>)
+	       (<VERB? LOOK-INSIDE>
+		<COND (<NOT <FSET? ,TRAPDOOR ,OPENBIT>>
+		       <TELL
+"It's closed." CR>)
+		      (<IN? ,OMI ,TRAPDOOR>
+		       <TRAPDOOR-DESC ,M-OBJDESC ,TRAPDOOR>
+		       <CRLF>)>)
+	       (<VERB? KNOCK>
+		<TELL G"You can't reach ""it." CR>)>>
+
+<OBJECT LADDER
+	(DESC "ladder")
+	(SYNONYM LADDER)
+	(FLAGS SURFACEBIT TAKEBIT TRYTAKEBIT VEHBIT
+	       SCOREBIT OPENBIT CONTBIT SEARCHBIT)
+	(DESCFCN LADDER-DESC)
+	(ACTION LADDER-F)>
+
+<ROUTINE LADDER-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (ELSE
+		<TELL "A ladder leads ">
+		<COND (<HERE? ,PIT>
+		       <TELL "up through the open trap door.">)
+		      (ELSE
+		       <TELL "down into the pit.">)>)>>
+
+<ROUTINE LADDER-F ("OPT" (RARG <>))
+	 <COND (<RARG? <>>
+		<COND (<VERB? EXAMINE>
+		       <COND (<IN? ,OMI-SAMURAI ,LADDER>
+			      <TELL
+"There are samurai on the ladder." CR>)
+			     (ELSE
+			      <TELL
+"It's a rickety wooden ladder." CR>)>)
+		      (<VERB? STOP KINJIRU>
+		       <COND (<IN? ,OMI-SAMURAI ,LADDER>
+			      <TELL
+"Swords swinging, the samurai continue down the ladder." CR>)
+			     (<IN? ,OMI-SAMURAI ,PIT>
+			      <TELL
+"There's nothing to block or stop." CR>)
+			     (<NOT <IN? ,LADDER ,HERE>>
+			      <COND (<FSET? ,LADDER ,SCOREBIT>
+				     <TELL "You hold ">
+				     <COND (,VINCK-PICKED? <TELL "him ">)>
+				     <TELL
+"back.  The others grumble, but Roper says \"Aye, no
+need to go until they come for you.\"" CR>)
+				    (,VINCK-PICKED?
+				     <TELL
+"You grab Vinck, but he pulls away." CR>)
+				    (ELSE
+				     <TELL "You hold back." CR>)>)
+			     (<AND ,VINCK-PICKED?
+				   <NOT <FSET? ,VINCK ,RMUNGBIT>>>
+			      <FSET ,VINCK ,RMUNGBIT>
+			      <TELL
+"You move between Vinck and the ladder.  \""I"Kinjiru"G"!\" you say,
+remembering the word from the ship.  \"None of my crew is walking to
+death without a fight!\"|
+|
+\"It's all right, Pilot,\" Vinck whispers.  \"We did agree and it was
+fair.  It's God's will.  I'm going.\"""  He steps to the foot of the ladder." CR>)
+			     (<FSET? ,LADDER ,SCOREBIT>
+			      <TELL
+"You stand implacably ">
+			      <COND (,VINCK-PICKED?
+				     <TELL "in the way.  ">)
+				    (ELSE
+				     <TELL
+"at the foot of the ladder.  The watchers can see no one is coming up.  ">)>
+			      <SAMURAI-ON-LADDER>)>)
+		      (<OR <VERB? TAKE SHAKE MOVE LOWER KICK>
+			   <P? PUSH-DOWN <> LADDER>>
+		       <COND (<HERE? ,VILLAGE-SQUARE>
+			      <TELL
+G"Two of the samurai prevent you, and although you struggle, they hold
+you easily." CR>)
+			     (ELSE
+			      <TELL
+"You shake the ladder.">
+			      <FSET ,LADDER ,RMUNGBIT>
+			      <COND (<QUEUED? I-TAKE-CROOCQ>
+				     <TELL
+" There is no reaction from those above.  They wait patiently." CR>)
+				    (<IN? ,OMI-SAMURAI ,LADDER>
+				     <TELL
+" The samurai hold tightly onto the ladder, but one swings a sword at
+you!" CR>
+				     <SCORE-OBJECT ,LADDER>)
+				    (ELSE
+				     <TELL
+" A gasp goes through the cellar.  ">
+				     <SAMURAI-ON-LADDER>
+				     <RTRUE>)>)>)
+		      (<VERB? CLIMB-FOO CLIMB-ON CLIMB-UP CLIMB-DOWN BOARD>
+		       <COND (<HERE? ,VILLAGE-SQUARE>
+			      <TELL
+G"Two of the samurai prevent you, and although you struggle, they hold
+you easily." CR>)
+			     (<OR <QUEUED? I-TAKE-CROOCQ>
+				  <QUEUED? I-TAKE-YOU>>
+			      <MOVE ,LADDER ,VILLAGE-SQUARE>
+			      <MOVE ,OMI-SAMURAI ,VILLAGE-SQUARE>
+			      <NEW-SDESC ,OMI-SAMURAI "samurai guards" T>
+			      <FSET ,OMI-SAMURAI ,NOABIT>
+			      <MOVE ,SEBASTIO ,VILLAGE-SQUARE>
+			      <MOVE ,OMI ,VILLAGE-SQUARE>
+			      <TELL
+"You climb up the ladder into the sunlight, blinking in the brightness.">
+			      <COND (<HELD? ,DAGGER>
+				     <REMOVE ,DAGGER>
+				     <TELL
+" As you reach the top of the ladder, strong hands grab you and force
+you to drop the dagger.">)>
+			      <CRLF>
+			      <CRLF>
+			      <GOTO ,VILLAGE-SQUARE>)
+			     (ELSE
+			      <MOVE ,PLAYER ,LADDER>
+			      <COND (<IN? ,OMI ,TRAPDOOR>
+				     <FSET ,OMI-SAMURAI ,RMUNGBIT>
+				     <MOVE ,OMI-SAMURAI ,LADDER>
+				     <THIS-IS-IT ,OMI-SAMURAI>
+				     <TELL
+"You begin to climb onto the ladder, but Omi orders two samurai forward,
+and they climb down, swords unsheathed." CR>
+				     <SCORE-OBJECT ,LADDER>)
+				    (<IN? ,OMI-SAMURAI ,LADDER>
+				     <TELL
+"Swords swinging, the samurai block your progress and then continue
+down the ladder." CR>)
+				    (<AND ,VINCK-PICKED?
+					  <NOT <FSET? ,VINCK ,RMUNGBIT>>>
+				     <FSET ,VINCK ,RMUNGBIT>
+				     <TELL
+"You block Vinck from the ladder.  \""I"Kinjiru"G"!\" you say,
+remembering the word from the ship.  \"None of my crew is walking to
+death without a fight!\"|
+|
+\"It's all right, Pilot,\" Vinck whispers.  \"We did agree and it was
+fair.  It's God's will.  I'm going.\"""  He continues toward the ladder." CR>)
+				    (<FSET? ,LADDER ,SCOREBIT>
+				     <TELL
+"You climb onto the lower rungs of the ladder, ">
+				     <COND (,VINCK-PICKED?
+					    <TELL "blocking it.  ">)
+					   (ELSE
+					    <TELL
+"then stop.  The watchers can see you are coming no higher.  ">)>
+				     <SAMURAI-ON-LADDER>)>)>)>)>>
+
+<ROUTINE SAMURAI-ON-LADDER ()
+	 <FSET ,OMI-SAMURAI ,RMUNGBIT>
+	 <MOVE ,OMI-SAMURAI ,LADDER>
+	 <THIS-IS-IT ,OMI-SAMURAI>
+	 <TELL G"Omi snarls orders to his men.  At once
+a samurai, followed by two others, starts down the steps, swords
+unsheathed." CR>
+	 <SCORE-OBJECT ,LADDER>>
+
+<OBJECT LOSING-SAMURAI
+	(DESC "captured samurai")
+	(SCENE S-PIT)
+	(SYNONYM SAMURAI COMRADE)
+	(ADJECTIVE CAPTURED PROSTRATE UNCONSCIOUS)
+	(FLAGS PERSON JAPANESEBIT SCOREBIT OPENBIT SEARCHBIT CONTBIT)
+	(GENERIC GENERIC-SAMURAI-F)
+	(CONTFCN LOSING-SAMURAI-F)
+	(ACTION LOSING-SAMURAI-F)>
+
+<ROUTINE LOSING-SAMURAI-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<AND <RARG? CONTAINER>
+		     <NOT <PASSIVE-VERB?>>>
+		<PERFORM ,V?ATTACK ,LOSING-SAMURAI>
+		<RTRUE>)
+	       (<RARG? WINNER>
+		<COND (<NOT <FSET? ,LOSING-SAMURAI ,SCOREBIT>>
+		       <TELL
+G"He appears to be unconscious." CR>)
+		      (ELSE
+		       <TELL
+G"He doesn't respond." CR>)>)
+	       (<VERB? EXAMINE>
+		<COND (<NOT <FSET? ,LOSING-SAMURAI ,SCOREBIT>>
+		       <TELL
+G"He appears to be unconscious." CR>)
+		      (ELSE
+		       <TELL
+"He's fighting, kicking and punching, trying to get away." CR>)>)
+	       (<VERB? WAKE>
+		<COND (<NOT <FSET? ,LOSING-SAMURAI ,SCOREBIT>>
+		       <TELL
+"He's alive, but he doesn't wake up." CR>)>)
+	       (<VERB? SEARCH>
+		<COND (<NOT <FSET? ,LOSING-SAMURAI ,SCOREBIT>>
+		       <TELL
+"You don't find anything of interest." CR>)>)
+	       (<OR <VERB? TAKE MOVE> <HOSTILE-VERB?>>
+		<COND (<FSET? ,LOSING-SAMURAI ,SCOREBIT>
+		       <DROPS-DAGGER>)
+		      (<VERB? KILL>
+		       <COND (<FSET? ,LOSING-SAMURAI ,DEAD>
+			      <TELL
+"He's already dead." CR>)
+			     (<PRSI? ,DAGGER>
+			      <FSET ,LOSING-SAMURAI ,DEAD>
+			      <TELL
+"You stab him in the heart.  He's dead." CR>)
+			     (ELSE
+			      <FSET ,LOSING-SAMURAI ,DEAD>
+			      <TELL
+"You hold his face under the water until he stops breathing.  He's dead." CR>)>)
+		      (<VERB? TAKE MOVE>
+		       <TELL
+"You move him up against the wall where he won't drown.  The others are saying
+\"Kill him, Pilot!\" or \"Use him as a hostage!\"" CR>)
+		      (ELSE
+		       <TELL
+"He's already unconscious." CR>)>)>>
+
+<OBJECT OMI-SAMURAI
+	(SDESC "attacking samurai") ;"samurai guards"
+	(SCENE S-PIT)
+	(OWNER OMI)
+	(SYNONYM SAMURAI GUARDS GUARD)
+	(ADJECTIVE ATTACKING)
+	(FLAGS PERSON JAPANESEBIT NOABIT PLURAL)
+	(DESCFCN OMI-SAMURAI-DESC)
+	(GENERIC GENERIC-SAMURAI-F)
+	(ACTION OMI-SAMURAI-F)>
+
+<ROUTINE OMI-SAMURAI-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?>
+		<COND (<IN? ,OMI-SAMURAI ,LADDER> <RTRUE>)
+		      (ELSE <RFALSE>)>)
+	       (<RARG? OBJDESC>
+		<TELL
+"Advancing down the ladder are ">
+		<COND (<IN? ,LOSING-SAMURAI ,PIT>
+		       <TELL "two">)
+		      (ELSE <TELL "three">)>
+		<TELL " samurai.">)>>
+
+<ROUTINE OMI-SAMURAI-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<TELL
+"They seem uninterested in conversing with barbarians." CR>
+		<END-QUOTE>)
+	       (<OR <VERB? TAKE MOVE PARRY STOP> <HOSTILE-VERB?>>
+		<COND (<HERE? ,VILLAGE-SQUARE>
+		       <TELL
+"You are easily subdued by Omi's guards." CR>)
+		      (<IN? ,OMI-SAMURAI ,LADDER>
+		       <SETG OPPONENT ,OMI-SAMURAI>
+		       <COND (<NOT <IN? ,LOSING-SAMURAI ,HERE>>
+			      <MOVE ,LOSING-SAMURAI ,HERE>
+			      <SETG OPPONENT ,LOSING-SAMURAI>
+			      <THIS-IS-IT ,LOSING-SAMURAI>
+			      <QUEUE I-LOSING-SAMURAI -1>
+			      <TELL
+"You grapple with one of the samurai, who kicks viciously.  The entire
+crew hurls themselves at the ladder.  The man manages to throw his
+sword out of the pit, but tumbles heavily into the mud." CR>)
+			     (ELSE
+			      <TELL
+"The remaining samurai are more wary this time.  Oddly, they make no effort
+to rescue their comrade." CR>)>)
+		      (<FSET? ,LOSING-SAMURAI ,SCOREBIT>
+		       <DROPS-DAGGER>)>)>>
+
+<ROUTINE I-LOSING-SAMURAI ()
+	 <COND (<AND <HERE? ,PIT>
+		     <IN? ,LOSING-SAMURAI ,HERE>
+		     <FSET? ,LOSING-SAMURAI ,SCOREBIT>>
+		<THIS-IS-IT ,LOSING-SAMURAI>
+		<COND (<NOT <FSET? ,LOSING-SAMURAI ,RMUNGBIT>>
+		       <FSET ,LOSING-SAMURAI ,RMUNGBIT>
+		       <TELL CR
+"The samurai you knocked off of the ladder gropes his way to his feet.  The
+fall obviously hurt him." CR>)
+		      (<NOT <FSET? ,LOSING-SAMURAI ,SURFACEBIT>>
+		       <FSET ,LOSING-SAMURAI ,SURFACEBIT>
+		       <TELL CR
+"The muddy samurai draws a dagger and slashes at you.  He is like a cornered
+rat." CR>)
+		      (ELSE
+		       <TELL CR
+"The samurai charges, and almost as much by blind ferocity as skill, he
+shoves his dagger into your chest, ending your life." CR>
+		       <JIGS-UP>)>)
+	       (ELSE
+		<DEQUEUE I-LOSING-SAMURAI>
+		<RFALSE>)>>
+
+<ROUTINE DROPS-DAGGER ()
+	 <MOVE ,DAGGER ,HERE>
+	 <TELL
+"You attempt to subdue the samurai, and Vinck helps, pounding again
+and again.  \"Don't kill him -- we can use him as a hostage!\" you
+warn.  Finally, Vinck kicks him in the back of the neck and he goes
+limp, dropping his dagger." CR>
+	 <SCORE-OBJECT ,LOSING-SAMURAI>>
+
+<OBJECT DAGGER
+	(LOC LOSING-SAMURAI)
+	(DESC "dagger")
+	(SYNONYM DAGGER)
+	(FLAGS TAKEBIT WEAPONBIT)>
+
+<OBJECT CAULDRON
+	(DESC "cauldron")
+	(SYNONYM CAULDRON)
+	(FLAGS OPENBIT CONTBIT SEARCHBIT VEHBIT)
+	(DESCFCN CAULDRON-DESC)
+	(CONTFCN CAULDRON-F)
+	(ACTION CAULDRON-F)>
+
+<ROUTINE CAULDRON-F ("OPT" (RARG <>))
+	 <COND (<P? (THROUGH BOARD) CAULDRON>
+		<TELL
+"They'll put you in soon enough!" CR>)
+	       (<NOT <PASSIVE-VERB?>>
+		<TELL
+"The guards prevent you from getting close to the cauldron." CR>)>>
+
+<ROUTINE CAULDRON-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (<RARG? OBJDESC>
+		<TELL
+"A huge black-iron cauldron stands in the square.">
+		<COND (<IN? ,CROOCQ ,CAULDRON>
+		       <TELL " The boy Croocq, trussed like a chicken,
+is inside.">)>
+		<RFATAL>)>>
+
+<ROUTINE I-TAKE-CROOCQ ("AUX" TMP)
+	 <ZLINES ,PIT-CNT
+		 (<COND (<SET TMP <FIRST? ,CAULDRON>>
+			 <FSET .TMP ,DEAD>)>
+		  <TELL CR
+"The screams begin when the moon is high, and cease just before first
+light." CR>)
+		 (<REMOVE ,SHORT-STRAW>
+		  <REMOVE ,LONG-STRAW>
+		  <MOVE ,OMI ,TRAPDOOR>
+		  <MOVE ,SEBASTIO ,TRAPDOOR>
+		  <FSET ,TRAPDOOR ,OPENBIT>
+		  <MOVE ,LADDER ,PIT>
+		  <TELL CR
+"Finally, it is high noon.  Everyone is nervous, tired and scared from
+listening to the screams.|
+|
+There are footsteps above.  The trapdoor opens and the ladder is lowered
+again.  The priest stands there
+flanked by samurai.|
+|
+\"Pilot.  You are to come up.  You are to come up alone,\" he says." CR>)
+		 (DELAY
+		  <COND (<IN? ,BLACKTHORNE ,PIT>
+			 <COND (<G? ,DELAY-CNT 2>
+				<MOVE ,OMI ,VILLAGE-SQUARE>
+				<MOVE ,SEBASTIO ,VILLAGE-SQUARE>
+				<TELL CR
+"A samurai points at you and beckons you up.  Another samurai shoves a
+long barbed staff into the cellar and hooks you out." CR CR>
+				<GOTO ,VILLAGE-SQUARE>
+				<RTRUE>)
+			       (ELSE
+				<TELL CR
+"\"I don't know what they want,\" Father Sebastio says gravely.  \"But
+you must come up at once.\"" CR>
+				<RTRUE>)>)>)
+		 (<SETG ANSWER-HAI? <>>
+		  <FSET ,CROOCQ ,SCOREBIT>
+		  <SETG QCONTEXT ,OMI>
+		  <TELL CR
+"The priest says, \"Omi-san says that you will be given a bath.  And
+food and drink.  If you behave, you will not be put back into the pit.  Your
+men will stay below.  If you do not behave, another of your men
+will be taken up.  There is plenty of firewood.\"  He pauses while Omi
+speaks to him at length.  \"Omi-san says you must obey.  Do what you are
+told.  Eat dung if need be.  The Japanese for 'yes' is '"I"hai"".'  If you
+agree, say it directly to him.\"" CR>)
+		 (DELAY
+		  <COND (<NOT ,ANSWER-HAI?>
+			 <COND (<EQUAL? <CROOCQ-IN-CAULDRON> T>
+				<COND (<EQUAL? ,DELAY-CNT 1 2>
+				       <OMI-SAYS-LIE-DOWN>)>)>
+			 <RFATAL>)
+			(<NOT <B-LYING?>>
+			 <COND (<EQUAL? ,DELAY-CNT 1>
+				<TELL CR
+"Omi watches you with great curiousity." CR>
+				<RTRUE>)
+			       (<EQUAL? <CROOCQ-IN-CAULDRON> T>
+				<COND (<EQUAL? ,DELAY-CNT 2 3>
+				       <OMI-SAYS-LIE-DOWN>
+				       <RTRUE>)
+				      (ELSE
+				       <TELL CR
+"\"Omi-san says, to make an agreement and then not keep it is
+stupid.\"  Omi then removes your head." CR>
+				       <JIGS-UP>
+				       <RFATAL>)>)>)>)
+		 (<SETG QCONTEXT ,OMI>
+		  <TELL CR
+"\"Omi-san says that ">
+		  <COND (,PISS-FLAG
+			 <TELL
+"he did not insult you personally, neither was there
+any cause for you to insult him.  B">)
+			(ELSE <TELL "b">)>
+		  <TELL "ecause you are a barbarian and know no
+better yet, you will not be killed.  But you will be taught manners.\"  You
+see Omi hitch up his kimono.  He pisses on your back.">
+		  <COND (,PISS-FLAG
+			 <TELL " \"Omi-san says, it
+is very bad manners to say you will piss on anyone.  It is bad manners and
+very stupid to say you will piss on anyone when you are unarmed.  It is
+very bad manners and even more stupid to say you will piss on anyone
+when you are unarmed, powerless, and not prepared to allow your friends
+or family or whomever to perish first.\"">)>
+		  <REPLACE-SYNONYM ,BLACKTHORNE ,W?PILOT ,W?ANJIN>
+		  <REPLACE-SYNONYM ,BLACKTHORNE ,W?PILOT-MAJOR ,W?ANJIN-SAN>
+		  <TELL CR CR>
+		  <COND (<IN? ,CROOCQ ,CAULDRON>
+			 <MOVE ,CROOCQ ,HERE>
+			 <TELL
+"You watch the samurai remove the unconscious boy from the cauldron.  ">)>
+<TELL "By the Lord God,
+you swear, I will remember this day and somehow, somewhere, Omi will pay.|
+|
+Omi adjusts his kimono and continues to speak in a casual way.  The priest
+translates, \"Omi-san says that because no one can say the barbarous sounds
+of your name, you are to be called Anjin -- Pilot.  He asks me to
+impress upon you that this is not intended as an insult.  If you continue
+to behave, you will be called Anjin-san -- Mr. Pilot -- when you merit
+it.\"" CR>)
+		 (<SETG QCONTEXT ,OMI>
+		  <SETG BATH-FLAG T>
+		  <TELL CR
+"The priest translates.  \"Omi-san suggests that you take a bath.\"  He
+smirks contemptuously.  \"A
+barbarous custom.  Once when you're born and once when you're laid out
+is good enough for us, but here they bathe constantly.  Mura says there is a
+bath house over there.\"  He points to the north." CR>
+		  <DEQUEUE I-TAKE-CROOCQ>)>>
+
+<GLOBAL CROOCQ-CNT 0>
+
+<ROUTINE CROOCQ-IN-CAULDRON ()
+	 <SETG CROOCQ-CNT <+ ,CROOCQ-CNT 1>>
+	 <COND (<EQUAL? ,CROOCQ-CNT 1>
+		<MOVE ,CROOCQ ,CAULDRON>
+		<TELL CR
+"Omi gives a quiet order.  Instantly two samurai go down into the pit
+and bring out Croocq, the boy.  They drag him over to the cauldron,
+truss him while others bring firewood and water.  They put the petrified
+boy into the brimming cauldron and ignite the wood." CR>)
+	       (<EQUAL? ,CROOCQ-CNT 2>
+		<TELL CR
+"The fire is beginning to warm the water, and a nauseating groan breaks
+from Croocq's mouth." CR>)
+	       (<EQUAL? ,CROOCQ-CNT 3>
+		<TELL CR
+"Flames from the wooden fire set in the bricks below the grate lick
+the metal of the cauldron.  More wood is put on." CR>)
+	       (<EQUAL? ,CROOCQ-CNT 4>
+		<TELL CR
+"Croocq screams a thin, wailing scream, and then faints.  A man with a
+pole pokes him until he revives." CR>)
+	       (<EQUAL? ,CROOCQ-CNT 5>
+		<TELL CR
+"The boy begins begging, shouting, \"Pilot, don't let them boil me
+alive, Pilot!\"" CR>)
+	       (ELSE
+		<TELL CR
+"\"Omi-san says he will train someone else,\" a nauseated-looking
+Sebastio tells you.  You have only a moment to ruminate on that before
+he removes your head." CR>
+		<JIGS-UP>
+		<RFATAL>)>
+	 <RTRUE>>
+
+<ROUTINE OMI-SAYS-LIE-DOWN ()
+	 <THIS-IS-IT ,ORDERS>
+	 <TELL CR
+"\"Omi-san says, ">
+	 <COND (,ANSWER-HAI?
+		<TELL "lie down immediately!\"" CR>)
+	       (ELSE
+		<TELL "you agree to behave?\"" CR>)>>
+
+<GLOBAL ANSWER-HAI? <>>
+<GLOBAL BATH-FLAG <>>
+
+<ROOM BATH-HOUSE
+      (LOC ROOMS)
+      (DESC "Bath House")
+      (SYNONYM HOUSE)
+      (ADJECTIVE BATH)
+      (SOUTH TO VILLAGE-SQUARE)
+      (FLAGS ONBIT)
+      (ACTION BATH-HOUSE-F)>
+
+<ROUTINE BATH-HOUSE-F ("OPT" (RARG <>))
+	 <COND (<RARG? LOOK>
+		<TELL
+"The bath house is dominated by a huge wooden tub, steaming with
+scalding water.  You are reminded of the torture you have just
+seen, and shiver with fear." CR>)
+	       (<RARG? ENTER>
+		<COND (<NOT <IN? ,MURA ,BATH-HOUSE>>
+		       ;<DRESS-BLACKTHORNE T>
+		       <MOVE ,CROWD ,BATH-HOUSE>
+		       <MOVE ,ONNA ,BATH-HOUSE>
+		       <MOVE ,MURA ,BATH-HOUSE>
+		       <QUEUE I-BATH -1>
+		       <TELL
+"You enter the bath house, followed by Mura, who keeps a close eye on
+you." CR CR>)>)
+	       (<RARG? BEG>
+		<COND (<AND <OR <P? WALK P?SOUTH>
+				<HOSTILE-VERB?>>
+			    <NOT <IN? ,BLACKTHORNE ,BATHTUB>>>
+		       <TELL
+"Mura moves to stop you, and you are thinking, \"How can this little man
+stop me?\",
+when, like a flash he seems to pull you toward him and over his shoulder
+in one fluid movement and you are sprawled gasping on the floor, out of
+breath.  \"So sorry, Captain-san,\" he says, in very bad Portuguese." CR>)
+		      (<AND <IN? ,PLAYER ,HERE>
+			    <TAKE-A-BATH?>>
+		       <PERFORM ,V?BOARD ,BATHTUB>
+		       <RTRUE>)
+		      (<AND <P? BATHE *> ,PRSO>
+		       <COND (<FSET? ,PRSO ,PERSON>
+			      <COND (<FSET? ,PRSO ,PLURAL>
+				     <TELL
+G"There wouldn't be room for so many!" CR>)
+				    (ELSE
+				     <TELL
+CTHE ,PRSO G" smiles at your invitation, but shakes " HIS/HER ,PRSO
+" head." CR>)>)
+			     (ELSE
+			      <TELL
+CTHE ,PRSO G" would probably be worse for the experience." CR>)>)
+		      (<VERB? STRIP>
+		       <SETG DELAY-CNT 0>
+		       <COND (<OR <FSET? ,BOOTS ,WEARBIT>
+				  <FSET? ,CLOTHES ,WEARBIT>>
+			      <COND (<FSET? ,BOOTS ,WEARBIT>
+				     <PERFORM ,V?TAKE-OFF ,BOOTS>
+				     <COND (<FSET? ,CLOTHES ,WEARBIT>
+					    <CRLF>)>)>
+			      <COND (<FSET? ,CLOTHES ,WEARBIT>
+				     <PERFORM ,V?TAKE-OFF ,CLOTHES>)>
+			      <RTRUE>)
+			     (ELSE
+			      <TELL "You're naked." CR>)>)
+		      (<AND <P? TAKE-OFF BOOTS>
+			    <FSET? ,BOOTS ,WEARBIT>>
+		       <SETG DELAY-CNT 0>
+		       <MOVE ,BOOTS ,WINNER>
+		       <FCLEAR ,BOOTS ,WEARBIT>
+		       <TELL
+"You remove your boots.  The old women watching cackle and nudge each
+other in the ribs." CR>)
+		      (<P? TAKE-OFF CLOTHES>
+		       <SETG DELAY-CNT 0>
+		       <COND (<FSET? ,BOOTS ,WEARBIT>
+			      <TELL
+,YOU-HAVE-TO G"take off ""your boots first.  Your pants won't go over the
+boots." CR>)
+			     (ELSE
+			      <MOVE ,CLOTHES ,WINNER>
+			      <FCLEAR ,CLOTHES ,WEARBIT>
+			      <TELL
+"You slowly remove your clothes, embarrassed by the audience.  They don't
+even have the courtesy of looking the other way.  The old women laugh
+and joke with each other.  Finally, you are naked, covering yourself as
+best you can.  One old crone claps her hands, and Mura says to you, with
+enormous gravity, \"Captain-san, Mother-san thank you, best she's ever
+seen, now die happy!\"" CR>)>)
+		      (<P? BATHE (BOOTS CLOTHES)>
+		       <TELL
+"You should leave that to your hosts." CR>)>)
+	       (<AND <RARG? END>
+		     <NOT <FSET? ,BATHTUB ,SCOREBIT>>>
+		<FSET ,PIT ,INVISIBLE>
+		<NEXT-SCENE>)>>
+
+<ROUTINE I-BATH ()
+	 <ZLINES ,BATH-CNT
+		 (DELAY
+		  <COND (<OR <FSET? ,BOOTS ,WEARBIT>
+			     <FSET? ,CLOTHES ,WEARBIT>>
+			 <COND (<G? ,DELAY-CNT 5>
+				<SETG DELAY-CNT 0>
+				<FCLEAR ,CLOTHES ,WEARBIT>
+				<FCLEAR ,BOOTS ,WEARBIT>
+				<MOVE ,CLOTHES ,MURA>
+				<MOVE ,BOOTS ,MURA>
+				<TELL CR
+"Mura signals to some of the onlookers, and you are surrounded, overpowered,
+and stripped before you can even react.  \"So sorry, Anjin,\" says Mura." CR>
+				<RTRUE>)
+			       (ELSE
+				<TELL CR
+"Mura pantomimes removing your clothes, saying \""I"Dozo, Anjin, gomen nasai.""\"" CR>
+				<RTRUE>)>)
+			(<OR <HELD? ,CLOTHES>
+			     <HELD? ,BOOTS>>
+			 <TELL CR
+"Mura points to your ">
+			 <COND (<HELD? ,CLOTHES> <TELL "clothes." CR>)
+			       (ELSE <TELL "boots." CR>)>
+			 <RTRUE>)
+			(<NOT <IN? ,BLACKTHORNE ,BATHTUB>>
+			 <COND (<G? ,DELAY-CNT 3>
+				<TELL CR
+"Mura looks extremely annoyed.  \"Bath, please.  Stinku.  Bad.  Like all
+Portuguese.\"  He chops you in the forearm, then calmly touches a nerve in
+your neck.  There is blinding pain.  \"Please excuse me, Anjin,\" he says,
+bowing very low.  \"Bath very good.\"  Then they lower you into the scalding
+water." CR>
+				<NEXT-SCENE>
+				<RTRUE>)
+			       (ELSE
+				<TELL CR
+"Mura points to the bathtub.  \"Please go there,\" he says in halting
+Portuguese." CR>
+				<RTRUE>)>)>)
+		 (<DEQUEUE I-BATH>
+		  <RFALSE>)>>
+
+<OBJECT CROWD
+	(SCENE S-PIT)
+	(LOC BATH-HOUSE)
+	(DESC "crowd of villagers")
+	(OWNER CROWD)
+	(SYNONYM VILLAGERS CROWD WOMEN MEN CRONE)
+	(ADJECTIVE OLD GAPING STARING)
+	(FLAGS PERSON JAPANESEBIT PLURAL OPENBIT CONTBIT SEARCHBIT)
+	(DESCFCN CROWD-DESC)
+	(ACTION CROWD-F)>
+
+<ROUTINE CROWD-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<TELL "They just giggle." CR>
+		<END-QUOTE>)>>
+
+<ROUTINE CROWD-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (ELSE
+		<TELL
+"A crowd of villagers, old women and men, are sitting and standing
+around the tub.  They seem intensely interested in the proceedings.">)>>
+
+<OBJECT BATHTUB
+	(LOC BATH-HOUSE)
+	(DESC "bath tub")
+	(SYNONYM TUB BATH POOL WATER)
+	(ADJECTIVE BATH WOODEN HOT)
+	(FLAGS NDESCBIT CANT-HOLD VEHBIT OPENBIT CONTBIT SEARCHBIT SCOREBIT)
+	(CAPACITY 300)
+	(ACTION BATHTUB-F)>
+
+<ROUTINE BATHTUB-F ("OPT" (RARG <>) "AUX" RUIN)
+	 <COND (<RARG? BEG>
+		<COND (<VERB? WALK>
+		       <YOULL-HAVE-TO "get out of the tub">)
+		      (<AND <VERB? WEAR>
+			    <NOT <IN? ,PRSO ,BATHTUB>>>
+		       <TELL
+G"You'd get it wet!" CR>)
+		      (<VERB? LIE-DOWN KNEEL>
+		       <TELL G"You would drown." CR>)
+		      (<OR <VERB? LEAP DIVE>
+			   <TAKE-A-BATH?>>
+		       <TELL
+"You splash some of the scalding water half-heartedly over yourself.  The
+water is soapy and scented, and it washes away the filth.  Three times
+you make them scour your back with the roughest stone and with pumice.  You
+begin to feel cleaner, but your back still burns with shame.|
+|
+Before long, even your hatred of Omi becomes a banked fire as the heat of
+the bath burns into you, relaxing every muscle and dissolving your
+fatigue." CR>
+		       <SCORE-OBJECT ,BATHTUB>)
+		      (<P? EXIT GLOBAL-HERE>
+		       <PERFORM ,V?DISEMBARK>
+		       <RTRUE>)
+		      (<OUTSIDE-TUB? ,BATHTUB>
+		       <TELL
+CTHE ,PRSO IS/ARE ,PRSO G" outside the tub and out of reach." CR>)>)
+	       (<RARG? <>>
+		<COND (<VERB? EXAMINE>
+		       <COND (<NOUN-USED? ,PRSO ,W?WATER>
+			      <TELL
+"It's very hot, and very clean." CR>)
+			     (ELSE
+			      <TELL
+G"The tub is wooden, large enough for several people, and deep enough
+that they could sit in it with only their heads above water." CR>)>)
+		      (<P? (TAKE MOVE) BATHTUB>
+		       <COND (<AND <EQUAL? ,P-PRSA-WORD ,W?TAKE>
+				   <NOUN-USED? ,PRSO ,W?BATH>>
+			      <PERFORM ,V?BATHE ,ME>
+			      <RTRUE>)
+			     (ELSE
+			      <TELL
+G"It's much too heavy!" CR>)>)
+		      (<VERB? POUR>
+		       <TELL G"And waste all that nice hot water?" CR>)
+		      (<VERB? CLIMB-FOO BOARD ENTER>
+		       <SET RUIN <RUINABLE? ,WINNER>>
+		       <COND (.RUIN
+			      <MURA-STOPS-YOU .RUIN>
+			      <COND (<FSET? .RUIN ,WEARBIT>
+				     <TELL
+" He pantomimes removing them, and the old women
+giggle and make loud remarks to him." CR>)
+				    (ELSE <CRLF>)>)
+			     (ELSE
+			      <MOVE ,WINNER ,BATHTUB>
+			      <TELL
+G"You climb gingerly up and over the side of the tub, and ease yourself
+in.  The water is scalding!" CR>)>)
+		      (<AND <P? (PUT THROW) * BATHTUB>
+			    <HELD? ,PRSO>
+			    <FSET? ,PRSO ,WEARABLE>>
+		       <MURA-STOPS-YOU ,PRSO>
+		       <CRLF>)
+		      (<VERB? DRINK TASTE>
+		       <TELL
+G"You try to drink the scalding bathwater, but it's far too hot." CR>)>)>>
+
+<ROUTINE TAKE-A-BATH? ()
+	 <OR <P? BATHE (<> ME)>
+	     <AND <P? TAKE (BATHTUB YOKOSE-BATHTUB)>
+		  <NOUN-USED? ,PRSO ,W?BATH>>>>
+
+<ROUTINE RUINABLE? (WHO "AUX" WEAR)
+	 <COND (<AND <IN? ,BOOTS .WHO>
+		     <FSET? ,BOOTS ,WEARBIT>>
+		<RETURN ,BOOTS>)
+	       (<AND <IN? ,CLOTHES .WHO>
+		     <FSET? ,CLOTHES ,WEARBIT>>
+		<RETURN ,CLOTHES>)
+	       (ELSE
+		<SET WEAR <FIRST? .WHO>>
+		<REPEAT ()
+			<COND (<NOT .WEAR> <RFALSE>)
+			      (<NOT <EQUAL? .WEAR ,LONG-STRAW ,SHORT-STRAW>>
+			       <RETURN .WEAR>)
+			      (ELSE
+			       <SET WEAR <NEXT? .WEAR>>)>>)>>
+
+<ROUTINE MURA-STOPS-YOU (OBJ)
+	 <TELL 'MURA>
+	 <THIS-IS-IT ,MURA>
+	 <COND (<NOT <FSET? .OBJ ,WEARBIT>>
+		<TELL
+" offers to take ">)
+	       (ELSE
+		<TELL
+", whose grip is surprisingly strong, stops you before you ruin ">)>
+	 <TELL D .OBJ ".">>
+
+<ROUTINE PIT-AFTER-F ()
+	 <TELL
+"Yabu and Omi are sitting sipping "I"cha"" -- tea -- with all the ceremony Omi's
+mother can command.  \"Where did you learn so much about the barbarian mind?\" he
+asks Omi.|
+|
+\"When I was fourteen I had a teacher who had been a Christian priest.  He said
+that Christians were vulnerable because they were taught that all people should
+'love' one another, and that life was sacred.  These new barbarians are just a
+different sect.  I thought we could control the leader by taking the life or
+threatening to take the life of one of his men.\"  Omi avoids mentioning the
+torture death, the befouled death, reining in his disgust.|
+|
+\"Is the barbarian broken for good?\" asks Yabu.  \"Is it temporary or
+permanent?\"|
+|
+\"Temporary,\" Omi answers hesitantly.  \"Only temporary, Lord.\"" CR>>
+
+<END-SEGMENT>
+
+
+
+"S-RODRIGUES"
+
+;"The next day, Lord Toda Hiro-matsu, Lord Toranaga's favorite general, arrives
+by galley from Osaka.  How, Yabu wonders, does he know of the
+ship?  Spies!  But who?|
+|
+Hiro-matsu seizes your ship and its cargo for his liege Lord
+Toranaga, and then
+stuns Yabu by saying, \"I'm taking the pirate leader to Osaka.  Lord
+Toranaga wants to see him!\""
+
+<BEGIN-SEGMENT RODRIGUES>
+
+<OBJECT SLAVER
+	(SCENE S-RODRIGUES)
+	(OWNER TORANAGA)
+	(DESC "galley")
+	(SYNONYM GALLEY SLAVER VESSEL SHIP)
+	(ADJECTIVE SLAVE)
+	(FLAGS VEHBIT)
+	(DESCFCN SLAVER-DESC)
+	(GENERIC GENERIC-GALLEY-F)
+	(ACTION SLAVER-F)>
+
+<ROUTINE SLAVER-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (ELSE
+		<TELL
+"A sixty-oared galley is anchored off of one of the jetties.">)>>
+
+<ROUTINE SLAVER-F ("OPT" (RARG <>))
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"This is a sixty-oared galley, thirty oars a side, neat and trim, the oars
+stacked with care, ready for instant departure." CR>)
+	       (<VERB? BOARD WALK-TO>
+		<COND (<IN? ,RODRIGUES ,HERE>
+		       <TELL
+"\"No need, Ingeles, the galley isn't ready to leave.  There's time.\"  You
+are startled.  Minutes ago they were herding you aboard.  What does this
+man want from you?" CR>)
+		      (ELSE
+		       <TELL
+"You move to board the galley, but you can't give yourself up to
+slavery.  What of the promise they made, that if you behaved they would
+treat you well?  Are they betraying it now?" CR>)>)>>
+
+<OBJECT MURA-ROPE
+	(SCENE S-RODRIGUES)
+	(OWNER MURA)
+	(DESC "rope")
+	(SYNONYM ROPE)>
+
+<GLOBAL RODRIGUES-QUESTION 0>
+
+<ROUTINE I-MEET-RODRIGUES ()
+	 <ZLINES ,MEET-CNT
+		 (<FCLEAR ,BRIDGE-OF-ERASMUS ,TOUCHBIT>
+		  <FCLEAR ,ON-DECK ,TOUCHBIT>
+		  <FCLEAR ,PASSAGEWAY ,TOUCHBIT>
+		  <FCLEAR ,PILOTS-CABIN ,TOUCHBIT>
+		  <TELL CR
+"You can see that even Omi and Yabu are deferring to the old man.  He
+has evidently come from the slave galley.|
+|
+You shiver involuntarily.  The last time you saw a slave galley was
+two years ago when the fleet was outward bound off the Gold Coast.  You've
+always had a mortal fear of being taken alive and made a galley
+slave -- not an unusual fate for a captured seaman." CR>)
+		 (<SETG QCONTEXT ,MURA>
+		  <SETG OPPONENT ,MURA>
+		  <TELL CR
+"Omi kneels before the old man, and you do the same, bowing exactly as
+low as Omi.  Now there is a discussion among Omi, the old man and
+Yabu.  Yabu speaks to Mura.|
+|
+Mura points at the galley.  \"Anjin-san.  Please go there.\"" CR>)
+		 (<SETG QCONTEXT ,OMI>
+		  <MOVE ,MURA-ROPE ,MURA>
+		  <THIS-IS-IT ,ARCHERS>
+		  <TELL CR
+"\""I"Isogi!""\" Omi commands, waving you toward the galley.|
+|
+When you still don't move, there is an immediate order from Omi and
+four samurai fall on you and pinion your arms.  Mura produces a rope and
+begins to bind your hands." CR>)
+		 (<MOVE ,RODRIGUES ,ANJIRO-WATERFRONT>
+		  <SETG QCONTEXT ,RODRIGUES>
+		  <SETG RODRIGUES-QUESTION 1>
+		  <TELL CR
+"\"Madonna!  Leave him alone!  Hey, let that bastard alone!  "I"Kinjiru,
+neh?""  Is he the pilot?  The Anjin?\"|
+|
+You can scarcely believe your ears.  The boisterous abuse in Portuguese
+comes from the deck of the galley.  Then you see a man start down the
+gangway, a Portuguese seaman!|
+|
+\"Are you the pilot?  The pilot of the Dutchman?\"" CR>)
+		 (DELAY
+		  <COND (<EQUAL? ,RODRIGUES-QUESTION 1>
+			 <COND (<G? ,DELAY-CNT 3>
+				<DIE-IN-STORM>
+				<RFATAL>)
+			       (ELSE
+				<TELL CR
+"\"Well, are you the pilot or no?  I'm trying to help you, you fool!\"" CR>
+				<RTRUE>)>)>)
+		 (<SETG RODRIGUES-QUESTION 2>
+		  <SETG QCONTEXT ,RODRIGUES>
+		  <SETUP-ANSWER "i trained at">
+		  <TELL CR
+"\"Now tell me where you trained as a pilot?\"" CR>)
+		 (DELAY
+		  <COND (<EQUAL? ,RODRIGUES-QUESTION 2>
+			 <COND (<G? ,DELAY-CNT 3>
+				<DIE-IN-STORM>
+				<RFATAL>)
+			       (ELSE
+				<TELL CR
+"\"All you Ingeles pilots come out of the same nest of pirates!  If you're
+really one, you'll know, so tell!  Where did you train?\"" CR>
+				<RTRUE>)>)>)
+		 (<SETG RODRIGUES-QUESTION 3>
+		  <SETG QCONTEXT ,RODRIGUES>
+		  <SETUP-ANSWER "the latitude is">
+		  <TELL CR
+"\"Maybe you are a pilot!  Now, what's the latitude of
+The Lizard?\"" CR>)
+		 (DELAY
+		  <COND (<EQUAL? ,RODRIGUES-QUESTION 3>
+			 <COND (<G? ,DELAY-CNT 3>
+				<DIE-IN-STORM>
+				<RFATAL>)
+			       (ELSE
+				<TELL CR
+"\"Well, are you a pilot or no?  I'm trying to help you, you
+fool!  What's the latitude of The Lizard?\"" CR>
+				<RTRUE>)>)>)
+		 (<TELL CR
+"\"All right, Ingeles!\"  " THE ,RODRIGUES " looks out into the harbor.  \"She's
+got good lines, your ship.  Madonna, she'd be fast, very fast.  Very rough
+to deal with.\"" CR>)
+		 (DELAY
+		  <COND (<FSET? ,LG-ERASMUS ,SCOREBIT>
+			 <COND (<G? ,DELAY-CNT 3>
+				<CRLF>
+				<LETS-GO-ABOARD <>>
+				<FCLEAR ,LG-ERASMUS ,SCOREBIT>
+				<RTRUE>)
+			       (ELSE <RFALSE>)>)>)
+		 (<TELL CR
+"Rodrigues yells to the surprised samurai, \"You don't have to worry
+about him, Captain-san, I'm responsible.  Me, Rodrigu-san, "I"ichi ban"
+" Anjin-san, by the Virgin!  "I"Wakarimasu ka?""\"" CR>)
+		 (DELAY
+		  <COND (<NOT <IN? ,BLACKTHORNE ,SMALL-BOAT>>
+			 <COND (<G? ,DELAY-CNT 3>
+				<DIE-IN-STORM>)
+			       (ELSE
+				<TELL CR
+"\"Hurry, hurry!  Get in the boat!  Hurry up!\"  " CTHE ,RODRIGUES " continues his
+dominating abuse of the astonished samurai." CR>)>
+			 <RTRUE>)>)
+		 (<MOVE ,BOAT-OAR ,RODRIGUES>
+		  <SETG OPPONENT ,ARCHERS>
+		  <TELL CR
+CTHE ,RODRIGUES " grabs the oars and shoves off with great skill.  The captain
+samurai calls out, unmistakably beckoning you to come back.  " CTHE ,RODRIGUES "
+points to the "I"Erasmus.""  \"Just go there,\" he shouts.  \"Tell me if
+the archers put arrows in their bows, Ingeles!\"" CR CR>
+		  <GOTO ,ANJIRO-HARBOR>)
+		 (<FSET ,ARCHERS ,RMUNGBIT>
+		  <TELL CR
+CTHE ,RODRIGUES " rows toward the "I"Erasmus"", pushing against the oars
+in Japanese fashion while standing amidships." CR>) 
+		 (<TELL CR
+CTHE ,RODRIGUES " continues to row toward the "I"Erasmus""." CR>)
+		 (<COND (<FSET? ,ARCHERS ,SCOREBIT>
+			 <JIGS-UP
+"One of the archers fires an arrow with incredible accuracy.  It takes
+Rodrigues in the back, and he falls.  The second arrow takes you.">
+			 <RFATAL>)
+			(ELSE
+			 <TELL CR
+"You are at the "I"Erasmus.""  " CTHE ,RODRIGUES " ships the oars under the
+watchful eyes of the samurai on board." CR CR>
+			 <GOTO ,AT-ERASMUS>)>)
+		 (<MOVE ,BOAT-OAR ,SMALL-BOAT>
+		  <MOVE ,RODRIGUES ,ON-DECK>
+		  <TELL CR
+CTHE ,RODRIGUES " vaults onto the deck.  \""I"Konnichi wa"" to all sod-eating
+samas!\" he bellows, bowing like a courtier.">
+		  <COND (<HERE? ,ON-DECK>
+			 <TELL "">
+			 <SEALED-PASSAGE>)
+			(ELSE
+			 <CRLF>)>)
+		 (DELAY
+		  <COND (<NOT <HERE? ,ON-DECK>>
+			 <COND (<G? ,DELAY-CNT 3>
+				<JIGS-UP
+"The watching Japanese don't know what's gone wrong, but assume you're
+trying to escape.  A flight of arrows ends your life.">
+				<RFATAL>)
+			       (<IN? ,PLAYER ,SMALL-BOAT>
+				<TELL CR
+"\"Come on, Ingeles!  Hurry!\"  " CTHE ,RODRIGUES " continues his
+half-obsequious, half-insulting banter with the suspicious
+samurai.  \"I can't keep this up, we can't give them time to think!\"" CR>
+				<RTRUE>)
+			       (ELSE
+				<TELL CR
+"The last you hear from " CTHE ,RODRIGUES " is a volley of blistering
+curses." CR>
+				<RTRUE>)>)>)
+		 (<MOVE ,RODRIGUES ,PASSAGEWAY>
+		  <COND (<HERE? ,ON-DECK ,PASSAGEWAY>
+			 <FSET ,PASSAGE-DOOR ,OPENBIT>
+			 <NEW-SDESC ,HIRO-MATSU "Hiro-matsu">
+			 <FCLEAR ,HIRO-MATSU ,AN>
+			 <TELL CR
+"\""I"Kinjiru,"" eh?\" Rodrigues says, unimpressed.  \"I'm from Toda Hiro-matsu-sama,
+who's a bigger king than your bugger and Toady-sama's from Toranaga-sama,
+who's the biggest bugger-sama in this whole world.  "I"Neh?""\"  He rips
+the seal off the door, and drops a hand to one of his pistols.|
+|
+\"Toranaga-sama!\" he yells.  \""I"Wakarimasu ka?""\"  The samurai hesitate,
+swords ready.  " CTHE ,RODRIGUES " crashes his foot against the door, the latch
+snaps, and the door bursts open.  \""I"WAKARIMASU KA?""\"|
+|
+\"Wakarimasu, Anjin-san.\" The samurai
+quickly put their swords away, and " THE ,RODRIGUES " says hoarsely, \"That's
+better,\" and leads the way aft." CR>)>)
+		 (DELAY
+		  <COND (<NOT <HERE? ,PASSAGEWAY>>
+			 <COND (<G? ,DELAY-CNT 3>
+				<DIE-IN-STORM>
+				<RFATAL>)
+			       (<HERE? ,ON-DECK ,CAPTAINS-CABIN ,MATES-CABIN>
+				<TELL CR
+"Rodrigues yells back to you, \"If you value your life, Ingeles, follow
+me!\"" CR>
+				<RTRUE>)
+			       (ELSE
+				<HEAR-RODRIGUES>
+				<RTRUE>)>)>)
+		 (<MOVE ,RODRIGUES ,PILOTS-CABIN>
+		  <FSET ,PILOTS-CABIN-DOOR ,OPENBIT>
+		  <COND (<HERE? ,PILOTS-CABIN>
+			 <TELL CR
+"\"This must be your cabin, eh?\" says Rodrigues and follows you inside." CR>)
+			(<HERE? ,PASSAGEWAY>
+			 <TELL CR
+"\"Which is your cabin?\" asks " THE ,RODRIGUES ", and when you point it out
+he enters.  The door was unlocked." CR>)
+			(<HERE? ,ON-DECK ,MATES-CABIN ,CAPTAINS-CABIN
+				,BELOW-DECKS>
+			 <DONT-BE-STUPID>)>)
+		 (DELAY
+		  <COND (<NOT <HERE? ,PILOTS-CABIN>>
+			 <COND (<G? ,DELAY-CNT 3>
+				<DIE-IN-STORM>
+				<RFATAL>)
+			       (<HERE? ,PASSAGEWAY ,MATES-CABIN
+				       ,CAPTAINS-CABIN>
+				<DONT-BE-STUPID>
+				<RTRUE>)
+			       (ELSE
+				<HEAR-RODRIGUES>
+				<RTRUE>)>)>)
+		 (<SETG QCONTEXT ,RODRIGUES>
+		  <TELL CR
+"\"Where are they?\" " THE ,RODRIGUES " asks.  \"Your rutters.  Where are your
+rutters?  No pilot would worry about clothes, you came for the rutters,
+didn't you?  Why do you think I came aboard?  I was here two or three
+hours ago, and searched for them, but found nothing!  The Portuguese
+rutter -- it had to be Portuguese!  Where is it?\"|
+|
+\"Stolen.  They're stolen!\"  It's all you can say." CR CR>
+		  <SETG QCONTEXT <>>
+		  <NEXT-SCENE>)>>
+
+<ROUTINE LETS-GO-ABOARD (YOU?)
+	 <TELL
+"\"Ah, Ingeles, let's go aboard.  I'd like see what she's like.  Come on,
+get in the boat.\"" CR>
+	 <COND (<NOT .YOU?>
+		<TELL CR
+"\"Good idea. I'd like to retrieve my clothes,\" you say, trying to not
+mention your rutters." CR>)>
+	 <MOVE ,RODRIGUES ,SMALL-BOAT>
+	 <TELL CR
+"He points to a small boat pulled up on the beach, and jumps in." CR>
+	 <RTRUE>>
+
+<ROUTINE HEAR-RODRIGUES ()
+	 <TELL CR
+"You hear Rodrigues calling for you, scorching the air with invective." CR>>
+
+<ROUTINE DIE-IN-STORM ()
+	 <CRLF>
+	 <JIGS-UP
+"\"You're a stubborn bastard, Ingeles!\"  Rodrigues says a few words of
+gutter Japanese to the samurai, and you are bound and hustled off to a
+cramped cabin below decks on the galley.|
+|
+You spend an awful night below, and the next day when the storm catches
+the galley, you wish you were on deck, helping.  When the sea pours in and
+the galley sinks, you wish so even more strongly.">
+	 <RFATAL>>
+
+<ROUTINE DONT-BE-STUPID ()
+	 <TELL CR
+"\"Get in here, we haven't much time!  These buggers are going to start
+wondering what we're doing!\" says Rodrigues." CR>>
+
+<ROUTINE LEAVE-ANJIRO-AFTER-F ()
+	 <TELL
+"Omi and the others waited on the jetty until the galley rounded the headland
+and vanished.  He then returned to the pit, summoning the priest.|
+|
+\"Priest, tell the barbarians they are to come up, one by one.  Lord Yabu has
+said they may live again in the world of men.  But the smallest breaking of a
+rule, and two will be put back into the pit.  They are to behave and obey all
+orders.\"" CR>>
+
+<END-SEGMENT>
diff --git a/attack.zil b/attack.zil
new file mode 100644
index 0000000..5b07b5d
--- /dev/null
+++ b/attack.zil
@@ -0,0 +1,3070 @@
+"ATTACK for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc.  All Rights Reserved."
+
+<FILE-FLAGS SENTENCE-ENDS?>
+
+<BEGIN-SEGMENT NINJA>
+
+<OBJECT PISTOL
+	(OWNER BLACKTHORNE)
+	(DESC "pistol")
+	(SYNONYM PISTOL GUN)
+	(FLAGS TAKEBIT WEAPONBIT)
+	(ACTION PISTOL-F)>
+
+<ROUTINE PISTOL-F ()
+	 <COND (<FSET? ,PISTOL ,NDESCBIT>
+		<TELL
+"You can't find your pistol anywhere!  It must have been blown out of
+your grasp by the force of the explosion!" CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"This is a">
+		<COND (<FSET? ,PISTOL ,RMUNGBIT> <TELL "n unloaded">)
+		      (ELSE <TELL " loaded">)>
+		<TELL " pistol." CR>)
+	       (<P? LOAD PISTOL (<> POWDER-HORN)>
+		<COND (<NOT <HELD? ,POWDER-HORN>>
+		       <TELL
+"You don't have any powder!" CR>)
+		      (<FSET? ,PISTOL ,RMUNGBIT>
+		       <COND (<QUEUED? I-LOAD-PISTOL>
+			      <TELL
+"With all the speed you can, you work on loading the pistol." CR>)
+			     (ELSE
+			      <QUEUE I-LOAD-PISTOL -1>
+			      <TELL
+"You begin the laborious task of loading the pistol." CR>)>)
+		      (ELSE
+		       <TELL "It's already loaded." CR>)>)>>
+
+<OBJECT POWDER-HORN
+	(LOC BLACKTHORNE-QUARTERS)
+	(DESC "powder horn")
+	(SYNONYM HORN POWDER)
+	(ADJECTIVE POWDER)
+	(FLAGS TAKEBIT)
+	(ACTION POWDER-HORN-F)>
+
+<ROUTINE POWDER-HORN-F ()
+	 <COND (<VERB? EXAMINE LOOK-INSIDE>
+		<TELL
+"There is plenty of powder in the horn." CR>)
+	       (<P? PUT POWDER-HORN (TOP-CATCH BOTTOM-CATCH)>
+		<TELL
+"The powder won't stay on the catch." CR>)
+	       (<P? PUT POWDER-HORN PISTOL>
+		<PERFORM ,V?LOAD ,PISTOL>
+		<RTRUE>)
+	       (<OR <P? SHOOT PISTOL>
+		    <P? EXPLODE * POWDER-HORN>>
+		<TELL
+"You would blow yourself up too!" CR>)>>
+
+;<GLOBAL LOAD-PISTOL-CNT 0>
+
+<ROUTINE I-LOAD-PISTOL ()
+	 <ZLINES ,LOAD-PISTOL-CNT
+		 (<TELL CR
+"First the powder, tamping it carefully." CR>)
+		 (<TELL CR
+G"You continue loading the pistol.  Next"" the paper plug to hold the charge
+tight." CR>)
+		 (<TELL CR
+G"You continue loading the pistol.  Next"" the lead ball and another
+plug." CR>)
+		 (<SETG LOAD-PISTOL-CNT 0>
+		  <FCLEAR ,PISTOL ,RMUNGBIT>
+		  <DEQUEUE I-LOAD-PISTOL>
+		  <TELL CR
+G"You continue loading the pistol.  Next"", blow the dust carefully away from
+the flint.  Finished!" CR>)>>
+
+<ROOM PRIVATE-QUARTERS
+      (LOC ROOMS)
+      (SCENE S-NINJA)
+      (DESC "Mariko's Quarters")
+      (OWNER MARIKO)
+      (SYNONYM QUARTERS)
+      (SCORE 6)
+      (FDESC
+"It is early in the morning of the day after Mariko's confrontation, two
+or three hours before dawn.  After she woke, you and Mariko had an hour
+alone together.  \"I still cannot believe that Ishido gave in,\" she
+said.  \"I knew it was my karma to bring the hostages out of Osaka.  Only I could
+do that for Lord Toranaga.  And now it's done.  But at what a cost, neh?
+Madonna forgive me.\"|
+|
+Now you, Mariko, Kiri, Lady Etsu, and Achiko, the granddaughter of Kiyama, are
+together in Mariko's quarters.  You are still suspicious enough of Ishido's
+intentions to be carrying your pistol.")
+      (AFTER ETSU-AFTER-F)
+      (NORTH TO SECRET-REDOUBT IF SECRET-REDOUBT-DOOR IS OPEN)
+      (IN TO SECRET-REDOUBT IF SECRET-REDOUBT-DOOR IS OPEN)
+      (SOUTH TO OUTER-ROOM IF NORTH-SHOJI IS OPEN)
+      (OUT TO OUTER-ROOM IF NORTH-SHOJI IS OPEN)
+      (WEST TO PRIVATE-QUARTERS-2)
+      (EAST TO BLACKTHORNE-QUARTERS)
+      (GLOBAL NORTH-SHOJI SECRET-REDOUBT-DOOR LG-NINJA LG-WOMEN)
+      (FLAGS ONBIT NOTHEBIT NOABIT)
+      (ACTION PRIVATE-QUARTERS-F)>
+
+<ROUTINE PRIVATE-QUARTERS-F (RARG)
+	 <COND (<RARG? SCENE-SETUP>
+		<DRESS-BLACKTHORNE>
+		<PUTP ,OUTER-CORRIDOR ,P?FDESC <>>
+		<FCLEAR ,OUTER-CORRIDOR ,TOUCHBIT>
+		<FCLEAR ,AUDIENCE-CHAMBER ,TOUCHBIT>
+		<MOVE ,SWORDS ,BLACKTHORNE-QUARTERS>
+		<MOVE ,PISTOL ,BLACKTHORNE>
+		<MOVE ,MARIKO ,HERE>
+		<FSET ,MARIKO ,SCOREBIT>
+		<MOVE ,KIRITSUBO ,HERE>
+		<MOVE ,GUARDS ,AUDIENCE-CHAMBER>
+		<MOVE ,GRAY-CAPTAIN ,AUDIENCE-CHAMBER>
+		<MOVE ,YABU ,OUTER-ROOM>
+		<QUEUE I-CHIMMOKO 1>)
+	       (<RARG? LOOK>
+		<TELL
+"These are Lady Mariko's private quarters.  Shojis screen a private room to
+the west, your room to the east, and an outer room which leads to a
+corridor on the south.">
+		<COND (<NOT <FSET? ,SECRET-REDOUBT-DOOR ,INVISIBLE>>
+		       <TELL
+" On the north wall is the iron-bound door to Lord Toranaga's secret
+room.">)>
+		<CRLF>)
+	       (<RARG? BEG>
+		<COND (<AND <VERB? WALK>
+			    <IN? ,NINJA ,HERE>
+			    ,KNOCKOUT-CNT>
+		       <TELL
+G"You can't break through the encircling ninja!" CR>)
+		      (<AND <P? WALK (P?SOUTH P?OUT)>
+			    <IN? ,NINJA ,HERE>>
+		       <TELL
+G"You would have to walk right through the ninja!" CR>)
+		      (<VERB? LEAVE>
+		       <DO-WALK <COND (<FSET? ,SECRET-REDOUBT-DOOR ,OPENBIT>
+				       ,P?NORTH)
+				      (ELSE ,P?WEST)>>)>)
+	       (<RARG? END>
+		<COND (<AND <NOT ,MARIKO-PLAN?>
+			    <FSET? ,OUTER-ROOM ,TOUCHBIT>
+			    <FSET? ,YABU ,TOUCHBIT>
+			    <IN? ,MARIKO ,HERE>
+			    <IN? ,KIRITSUBO ,HERE>
+			    <FSET? ,LG-NINJA ,INVISIBLE>>
+		       <THIS-IS-IT ,YABU>
+		       <SETG QCONTEXT ,MARIKO>
+		       <SETG MARIKO-PLAN? T>
+		       <TELL CR
+"Kiri asks you a question which you don't understand.  Mariko translates for
+her.  \"Did you ask Yabu about the 'plan'?\"" CR>)
+		      (<AND ,NINJA-ATTACKING-CUL-DE-SAC?
+			    <FSET? ,SECRET-REDOUBT-DOOR ,INVISIBLE>
+			    <IN? ,BLACKTHORNE ,PRIVATE-QUARTERS>
+			    <IN? ,KIRITSUBO ,PRIVATE-QUARTERS>>
+		       <FCLEAR ,SECRET-REDOUBT-DOOR ,INVISIBLE>
+		       <TELL CR
+"Kiri pulls a section of shoji on the north wall aside, revealing a hidden
+iron-fortified door set into the stone wall beyond.  The hinges are
+well oiled.  \"This is my Master's secret haven,\" she pants." CR>)>)>>
+
+<GLOBAL MARIKO-PLAN? <>>
+
+<OBJECT PLAN
+	(LOC GENERIC-OBJECTS)
+	(DESC "plan")
+	(SYNONYM PLAN)
+	(ADJECTIVE SECRET)
+	(FLAGS SCOREBIT)>
+
+<OBJECT CHIMMOKO
+	(LOC OUTER-ROOM)
+	(OWNER MARIKO)
+	(DESC "Chimmoko")
+	(SYNONYM CHIMMOKO MAID)
+	(FLAGS PERSON JAPANESEBIT FEMALE NOABIT NOTHEBIT)
+	(ACTION CHIMMOKO-F)>
+
+<ROUTINE CHIMMOKO-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<COND (<P? FIND ;WHERE (YABU LG-YABU)>
+		       <COND (<IN? ,YABU ,OUTER-ROOM>
+			      <TELL
+"\"He is in the outer chamber, Anjin-san.\"" CR>)
+			     (ELSE
+			      <TELL
+"\"I don't know, Anjin-san.  He was very angry.\"" CR>)>)
+		      (ELSE
+		       <WAKARIMASEN>)>)
+	       (<P? ASK-ABOUT CHIMMOKO>
+		<COND (<SCENE? ,S-SEPPUKU>
+		       <TELL
+"\"Please go to my mistress, Anjin-san. This is no time for questions.\"" CR>)
+		      (ELSE
+		       <TELL
+"She has nothing to say about " THE ,PRSI "." CR>)>)
+	       (<VERB? WHO>
+		<TELL "Chimmoko is one of Mariko's maids." CR>)>>
+
+<ROUTINE I-CHIMMOKO ()
+	 <COND (<IN? ,YABU ,OUTER-ROOM>
+		<COND (<HERE? ,PRIVATE-QUARTERS ,PRIVATE-QUARTERS-2
+			      ,BLACKTHORNE-QUARTERS>
+		       <SETG YABU-CNT 0>
+		       <QUEUE I-YABU -1>
+		       <QUEUE I-YABU-LEAVES 4>
+		       <MOVE ,CHIMMOKO ,HERE>
+		       <TELL CR
+"Chimmoko, Mariko's servant, enters and bows.  \"Lord Yabu wishes to
+speak with the Anjin-san,\" she says.">
+		       <COND (<NOT <HERE? <LOC ,YABU>>>
+			      <TELL " \"He is waiting in the outer room.\"">)>
+		       <CRLF>)
+		      (ELSE
+		       <QUEUE I-CHIMMOKO 1>)>)>>
+
+<OBJECT ETSU
+	(LOC PRIVATE-QUARTERS-2)
+	(DESC "Lady Etsu")
+	(SYNONYM LADY ETSU)
+	(ADJECTIVE LADY OLD)
+	(FLAGS PERSON JAPANESEBIT FEMALE NOABIT NOTHEBIT)
+	(ACTION ETSU-F)>
+
+<ROUTINE ETSU-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<VERB? STOP>
+		       <SETG WINNER ,PLAYER>
+		       <PERFORM ,V?HELP ,ETSU>
+		       <RTRUE>)
+		      (ELSE
+		       <WAKARIMASEN>)>)
+	       (<VERB? WHO>
+		<TELL "Lady Maeda Etsu is Lord Maeda's mother, an elderly
+samurai of very high lineage." CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"She is an elderly samurai and customarily leans painfully on her cane;
+\"It's my joints, they get worse every day.\"  Her hair is white but her
+back is straight." CR>)>>
+
+<OBJECT ACHIKO
+	(LOC PRIVATE-QUARTERS)
+	(DESC "Achiko")
+	(SYNONYM ACHIKO GIRL)
+	(ADJECTIVE LADY YOUNG KIYAMA)
+	(FLAGS PERSON JAPANESEBIT FEMALE NOABIT NOTHEBIT)
+	(ACTION ACHIKO-F)>
+
+<ROUTINE ACHIKO-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<WAKARIMASEN>)
+	       (<RARG? SUBJ>
+		<RFALSE>)
+	       (<VERB? WHO>
+		<TELL
+"Kiyama Achiko is the granddaughter-in-law of Lord Kiyama." CR>)
+	       (<VERB? EXAMINE>
+		<COND (<FSET? ,PRSO ,DEAD>
+		       <TELL
+"Achiko's lifeless body is spawled on the floor." CR>)
+		      (ELSE
+		       <TELL
+"She appears to be holding up well." CR>)>)>>
+
+<ROUTINE I-WOMEN ("AUX" (NINJA? <NOT <IN? ,NINJA ,SECRET-ROOM>>))
+	 <COND (<IN? ,ETSU ,BLACKTHORNE-QUARTERS>
+		<CHOREOGRAPH ,PRIVATE-QUARTERS T>)
+	       (<IN? ,ETSU ,PRIVATE-QUARTERS-2>
+		<CHOREOGRAPH ,PRIVATE-QUARTERS T>)
+	       (<IN? ,ETSU ,SECRET-REDOUBT>
+		<COND (<AND .NINJA? <FSET? ,BALCONY-DOOR ,OPENBIT>>
+		       <CHOREOGRAPH ,BALCONY>)>)
+	       (<IN? ,ETSU ,PRIVATE-QUARTERS>
+		<COND (.NINJA?
+		       <COND (<FSET? ,SECRET-REDOUBT-DOOR ,OPENBIT>
+			      <CHOREOGRAPH ,SECRET-REDOUBT>)
+			     (ELSE <RFALSE>)>)
+		      (ELSE
+		       <FSET ,NORTH-SHOJI ,OPENBIT>
+		       <CHOREOGRAPH ,OUTER-ROOM T>)>)
+	       (<IN? ,ETSU ,OUTER-ROOM>
+		<COND (.NINJA?
+		       <FSET ,NORTH-SHOJI ,OPENBIT>
+		       <CHOREOGRAPH ,PRIVATE-QUARTERS>)
+		      (ELSE
+		       <FSET ,SOUTH-SHOJI ,OPENBIT>
+		       <CHOREOGRAPH ,INNER-CORRIDOR T>)>)
+	       (<IN? ,ETSU ,INNER-CORRIDOR>
+		<COND (.NINJA?
+		       <FSET ,SOUTH-SHOJI ,OPENBIT>
+		       <CHOREOGRAPH ,OUTER-ROOM>)
+		      (<FSET? ,INNER-DOOR ,OPENBIT>
+		       <CHOREOGRAPH ,AUDIENCE-CHAMBER T>)
+		      (<HERE? ,INNER-CORRIDOR>
+		       <TELL CR
+"The women stop inside the door, listening intently." CR>)>)
+	       (<IN? ,ETSU ,AUDIENCE-CHAMBER>
+		<COND (.NINJA?
+		       <COND (<FSET? ,INNER-DOOR ,OPENBIT>
+			      <COND (<QUEUED? I-NINJA-COWED>
+				     <CHOREOGRAPH ,INNER-CORRIDOR>)>)
+			     (<QUEUED? I-NINJA-TAKE-MARIKO>
+			      <TELL CR
+"The women huddle in fear against the closed door." CR>)
+			     (ELSE
+			      <TELL CR
+"Mariko pounds on the closed door as the rest of the women huddle
+around her in fear.  \"Anjin-san!  Open the door!\"" CR>)>)>)>>
+
+<ROUTINE CHOREOGRAPH (RM "OPT" (MARIKO? <>)
+		      "AUX" (NINJA? <>) (ORM <LOC ,ETSU>))
+	 <COND (<NOT <IN? ,NINJA ,SECRET-ROOM>>
+		<SET NINJA? T>)>
+	 <COND (<OR <QUEUED? I-NINJA-TAKE-MARIKO>
+		    <QUEUED? I-MARIKO-FOLLOW>>
+		<SET MARIKO? <>>)>
+	 <MOVE ,CHIMMOKO .RM>
+	 <MOVE ,ACHIKO .RM>
+	 <MOVE ,ETSU .RM>
+	 <MOVE ,KIRITSUBO .RM>
+	 <COND (.MARIKO? <MOVE ,MARIKO .RM>)>
+	 <COND (<EQUAL? .ORM ,HERE>
+		<CRLF>
+		<COND (.MARIKO? <TELL
+"Mariko and the other">)
+		      (ELSE <TELL
+"The">)>
+		<TELL " women">
+		<COND (.NINJA?
+		       <COND (<IN? ,MARIKO ,HERE>
+			      <TELL ", save Mariko,">)>
+		       <TELL " flee">)
+		      (ELSE
+		       <TELL
+", treading a narrow path between fear and curiosity, leave">)>
+		<TELL " the room and crowd into " THE .RM "." CR>)
+	       (<EQUAL? .RM ,HERE>
+		<CRLF>
+		<COND (.NINJA?
+		       <COND (.MARIKO?
+			      <TELL
+"Mariko and the rest of the">)
+			     (ELSE
+			      <TELL
+"The">)>
+		       <TELL
+" women pour out of " THE .ORM ", fleeing the ninja." CR>)
+		      (ELSE
+		       <COND (.MARIKO?
+			      <TELL "Mariko ">
+			      <COND (,STATIONARY? <TELL "comes from ">)
+				    (ELSE <TELL "follows you into ">)>
+			      <TELL
+THE .ORM " into the room.  The rest of the women follow her,">)
+			     (ELSE
+			      <TELL "The women ">
+			      <COND (,STATIONARY? <TELL "come">)
+				    (ELSE <TELL "follow you">)>
+			      <TELL " into the room,">)>
+		       <TELL
+" curious about the commotion, but huddled together in some fear." CR>)>)
+	       (<NEXT-ROOM? .RM T>
+		<TELL CR
+"The women">
+		<COND (.NINJA?
+		       <TELL ", fleeing the ninja, pour">)
+		      (ELSE
+		       <TELL " come">)>
+		<TELL " into " THE .RM "." CR>)>>
+
+<ROUTINE I-MARIKO-FOLLOW ()
+	 <COND (<NOT <IN? ,MARIKO ,HERE>>
+		<COND (,CAPTURE-CNT
+		       <COND (<NEXT-ROOM? <LOC ,MARIKO>>
+			      <TELL CR
+"In the next room, you can hear Mariko struggling vainly to break free
+of the encircling ninja.  \"Anjin-san!\" she calls." CR>)
+			     (ELSE
+			      <TELL CR
+"You can dimly hear Mariko calling for help." CR>)>)
+		      (ELSE
+		       <MOVE ,MARIKO ,HERE>
+		       <COND (<HERE? ,SECRET-REDOUBT>
+			      <DEQUEUE I-MARIKO-FOLLOW>)>
+		       <TELL CR
+"Mariko follows ">
+		       <COND (<OR <SCENE? ,S-NINJA ,S-ESCAPE>
+				  <PROB 50>>
+			      <TELL
+"quickly after you." CR>)
+			     (ELSE
+			      <TELL
+"a pace behind, as is the custom." CR>)>)>)>>
+
+<ROOM PRIVATE-QUARTERS-2
+      (LOC ROOMS)
+      (SCENE S-NINJA)
+      (DESC "Private Quarters")
+      (ADJECTIVE PRIVATE)
+      (SYNONYM QUARTERS)
+      (LDESC
+"This is a smaller room, part of Mariko's quarters.  The Lady Etsu has
+been staying here.")
+      (EAST TO PRIVATE-QUARTERS)
+      (FLAGS ONBIT)
+      (GLOBAL LG-NINJA LG-WOMEN)>
+
+<ROOM BLACKTHORNE-QUARTERS
+      (LOC ROOMS)
+      (SCENE S-NINJA)
+      (DESC "Your Quarters")
+      (OWNER BLACKTHORNE)
+      (SYNONYM QUARTERS ROOM)
+      (ADJECTIVE SMALL)
+      (LDESC
+"This is a small room in which you are quartered.")
+      (WEST TO PRIVATE-QUARTERS)
+      (OUT TO PRIVATE-QUARTERS)
+      (FLAGS ONBIT)
+      (GLOBAL LG-NINJA LG-WOMEN)>
+
+<OBJECT SWORDS
+	(OWNER BLACKTHORNE)
+	(DESC "swords")
+	(SYNONYM SWORDS SWORD SELLER)
+	(ADJECTIVE PAIR KILLING STABBING OIL LONG SHORT)
+	(FLAGS TAKEBIT WEARABLE WEAPONBIT NOABIT SCOREBIT PLURAL)
+	(GENERIC GENERIC-SWORD-F)
+	(ACTION SWORDS-F)>
+
+<ROUTINE SWORDS-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<FSET? ,SWORDS ,RMUNGBIT>
+		       <FCLEAR ,SWORDS ,RMUNGBIT>
+		       <FSET ,SWORDS ,SCOREBIT>
+		       <SCORE-OBJECT ,SWORDS>
+		       <TELL
+"You quickly check your sword belt.  It's loose, almost ready to fall
+off!  What a stroke of luck you checked it!  How embarrassing if it had
+fallen off!" CR>)
+		      (ELSE
+		       <TELL
+"You have a pair of samurai swords, one the long killing sword">
+		       <COND (<G? ,SCENE ,S-QUAKE>
+			      <TELL
+" named 'Oil Seller'">)>
+		       <TELL ", and
+the other the shorter stabbing sword." CR>)>)
+	       (<AND <VERB? WHO WHAT>
+		     <NOUN-USED? ,PRSO ,W?SELLER>>
+		<TELL
+"The name comes from an experience you would rather forget.  One day
+hunting with Toranaga, your path had been blocked by a weather-beaten
+old oil
+seller.  Cursing, you commanded him to move, and he cursed you
+back.  Toranaga pointed to one of his bodyguards, asked you to give him
+your sword, and before you realized what was happening, the samurai
+lunged at the peddler.  He walked on a pace before falling, divided
+in two at the waist.  Toranaga suggested you call your sword 'Oil
+Seller' in honor of the incident.  \"Your sword has now become legend.\"" CR>)
+	       (<VERB? WEAR>
+		<COND (<NOT <FSET? ,PRSO ,WEARBIT>>
+		       <FSET ,PRSO ,WEARBIT>
+		       <TELL
+"You shove the sword into your sash." CR>)
+		      (ELSE
+		       <TELL "The sword is already in your sash." CR>)>)
+	       (<AND <VERB? TAKE>
+		     <NOT <HELD? ,PRSO>>>
+		<COND (<EQUAL? <ITAKE> T>
+		       <FSET ,SWORDS ,WEARBIT>
+		       <TELL
+"You take the sword and shove it into your sash." CR>)
+		      (ELSE <RTRUE>)>)
+	       (<OR <AND <VERB? DRAW PICK USE TAKE>
+			 <HELD? ,PRSO>>
+		    <P? PUT * HANDS>>
+		<COND (<FSET? ,PRSO ,WEARBIT>
+		       <FCLEAR ,PRSO ,WEARBIT>
+		       <TELL
+"Your skill with the sword is not great, but you are now as ready as
+you will ever be!" CR>)
+		      (ELSE
+		       <TELL "You've already drawn your sword." CR>)>)>>
+
+<ROOM SECRET-REDOUBT
+      (LOC ROOMS)
+      (SCENE S-NINJA)
+      (DESC "Secret Redoubt")
+      (SYNONYM REDOUBT BOLTHOLE HOLE HAVEN)
+      (ADJECTIVE SECRET BOLT)
+      (SOUTH TO PRIVATE-QUARTERS IF SECRET-REDOUBT-DOOR IS OPEN)
+      (NORTH TO BALCONY IF BALCONY-DOOR IS OPEN)
+      (OUT TO BALCONY IF BALCONY-DOOR IS OPEN)
+      (GLOBAL SECRET-REDOUBT-DOOR BALCONY-DOOR LG-NINJA LG-WOMEN)
+      (FLAGS ONBIT)
+      (ACTION SECRET-REDOUBT-F)>
+
+<ROUTINE SECRET-REDOUBT-F (RARG "AUX" (CNT <GETP ,BOLTS ,P?COUNT>))
+	 <COND (<RARG? LOOK>
+		<TELL
+"This is Lord Toranaga's secret bolt hole.  ">
+		<COND (<IN? ,SECRET-REDOUBT-DOOR ,LOCAL-GLOBALS>
+		       <TELL "An iron-bound
+door, well-oiled and well-maintained, is on the south wall.  There
+are three iron bolts on the door, ">
+		       <BOLT-STATE .CNT>
+		       <TELL ".  ">)
+		      (ELSE
+		       <TELL
+"There is an explosion-scarred hole on the south wall.  ">)>
+		<TELL "On the
+north wall is the door to the balcony, its bolts rusty and not so
+well-maintained." CR>)
+	       (<RARG? BEG>
+		<COND (<AND <VERB? WALK>
+			    <IN? ,NINJA ,HERE>
+			    ,KNOCKOUT-CNT>
+		       <TELL
+G"You can't break through the encircling ninja!" CR>)
+		      (<AND <P? WALK P?SOUTH>
+			    <IN? ,NINJA ,HERE>>
+		       <TELL
+G"You would have to walk right through the ninja!" CR>)>)>>
+
+<ROUTINE BOLT-STATE (CNT)
+	 <COND (<ZERO? .CNT>
+		<TELL "and they are all shut">)
+	       (<EQUAL? .CNT 1 2 4>
+		<TELL "but one of them is open">)
+	       (<EQUAL? .CNT 3 5 6>
+		<TELL "but two are currently open">)
+	       (ELSE
+		<TELL "but none of them are latched now">)>>
+
+<ROUTINE BOLTS-REMAINING (CNT)
+	 <TELL "">
+	 <COND (<EQUAL? .CNT 7>
+		<TELL "All the bolts are now open." CR>)
+	       (<EQUAL? .CNT 3 5 6>
+		<TELL "Two bolts are open." CR>)
+	       (<EQUAL? .CNT 1 2 4>
+		<TELL "One bolt is open." CR>)
+	       (<ZERO? .CNT>
+		<TELL "All the bolts are now closed." CR>)>>
+
+<OBJECT BOLTS
+	(LOC SECRET-REDOUBT)
+	(DESC "bolt")
+	(SYNONYM BOLT BOLTS)
+	(ADJECTIVE IRON FIRST SECOND THIRD)
+	(FLAGS NDESCBIT OPENBIT OPENABLE)
+	(COUNT 7) ;"bit on means bolt open"
+	(ACTION BOLTS-F)>
+
+<ROUTINE BOLTS-F ("AUX" (CNT <GETP ,BOLTS ,P?COUNT>))
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"There are three iron bolts to hold the door securely closed, ">
+		<BOLT-STATE .CNT>
+		<TELL "." CR>)
+	       (<VERB? OPEN UNLOCK>
+		<COND (<ADJ-USED? ,PRSO ,W?FIRST>
+		       <COND (<ZERO? <BAND .CNT 1>>
+			      <SET CNT <BOR .CNT 1>>
+			      <TELL G"You open the first bolt.">)
+			     (ELSE
+			      <TELL "The first bolt is already open.">)>)
+		      (<ADJ-USED? ,PRSO ,W?SECOND>
+		       <COND (<ZERO? <BAND .CNT 2>>
+			      <SET CNT <BOR .CNT 2>>
+			      <TELL G"You open the second bolt.">)
+			     (ELSE
+			      <TELL "The second bolt is already open.">)>)
+		      (<ADJ-USED? ,PRSO ,W?THIRD>
+		       <COND (<ZERO? <BAND .CNT 4>>
+			      <SET CNT <BOR .CNT 4>>
+			      <TELL G"You open the third bolt.">)
+			     (ELSE
+			      <TELL "The third bolt is already open.">)>)
+		      (ELSE
+		       <COND (<ZERO? <BAND .CNT 1>>
+			      <SET CNT <BOR .CNT 1>>
+			      <TELL G"You open the first bolt.">)
+			     (<ZERO? <BAND .CNT 2>>
+			      <SET CNT <BOR .CNT 2>>
+			      <TELL G"You open the second bolt.">)
+			     (<ZERO? <BAND .CNT 4>>
+			      <SET CNT <BOR .CNT 4>>
+			      <TELL G"You open the third bolt.">)
+			     (ELSE
+			      <TELL "All the bolts are open already." CR>
+			      <RTRUE>)>)>
+		<COND (<NOT <ZERO? .CNT>>
+		       <FCLEAR ,SECRET-REDOUBT-DOOR ,LOCKED>)>
+		<PUTP ,BOLTS ,P?COUNT .CNT>
+		<BOLTS-REMAINING .CNT>
+		<RTRUE>)
+	       (<VERB? CLOSE LOCK>
+		<COND (<FSET? ,SECRET-REDOUBT-DOOR ,OPENBIT>
+		       <TELL
+"The door isn't closed, so there's no point in locking the bolts!" CR>)
+		      (<ADJ-USED? ,PRSO ,W?FIRST>
+		       <COND (<NOT <ZERO? <BAND .CNT 1>>>
+			      <SET CNT <BAND .CNT 6>>
+			      <TELL G"You close the first bolt.">)
+			     (ELSE
+			      <TELL "The first bolt is already closed.">)>)
+		      (<ADJ-USED? ,PRSO ,W?SECOND>
+		       <COND (<NOT <ZERO? <BAND .CNT 2>>>
+			      <SET CNT <BAND .CNT 5>>
+			      <TELL G"You close the second bolt.">)
+			     (ELSE
+			      <TELL "The second bolt is already closed.">)>)
+		      (<ADJ-USED? ,PRSO ,W?THIRD>
+		       <COND (<NOT <ZERO? <BAND .CNT 4>>>
+			      <SET CNT <BAND .CNT 3>>
+			      <TELL G"You close the third bolt.">)
+			     (ELSE
+			      <TELL "The third bolt is already closed.">)>)
+		      (ELSE
+		       <COND (<NOT <ZERO? <BAND .CNT 1>>>
+			      <SET CNT <BAND .CNT 6>>
+			      <TELL G"You close the first bolt.">)
+			     (<NOT <ZERO? <BAND .CNT 2>>>
+			      <SET CNT <BAND .CNT 5>>
+			      <TELL G"You close the second bolt.">)
+			     (<NOT <ZERO? <BAND .CNT 4>>>
+			      <SET CNT <BAND .CNT 3>>
+			      <TELL G"You close the third bolt.">)
+			     (ELSE
+			      <TELL "All the bolts are closed already." CR>
+			      <RTRUE>)>)>
+		<COND (<ZERO? .CNT>
+		       <FSET ,SECRET-REDOUBT-DOOR ,LOCKED>)>
+		<PUTP ,BOLTS ,P?COUNT .CNT>
+		<BOLTS-REMAINING .CNT>
+		<RTRUE>)>>
+
+<OBJECT SECRET-REDOUBT-DOOR
+	(LOC LOCAL-GLOBALS)
+	(DESC "secret door")
+	(LDESC "The iron-bound door lies shattered in a corner.")
+	(SYNONYM DOOR)
+	(ADJECTIVE SECRET HIDDEN IRON-FORTIFIED IRON)
+	(FLAGS INVISIBLE DOORBIT LOCKABLE)
+	(ACTION SECRET-REDOUBT-DOOR-F)>
+
+<ROUTINE SECRET-REDOUBT-DOOR-F ("AUX" (CNT <GETP ,BOLTS ,P?COUNT>))
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"This is a heavy, iron-bound door.  It looks very strong.">
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <TELL
+" The door is open now.">)>
+		<COND (<HERE? ,SECRET-REDOUBT>
+		       <TELL
+" There are three iron bolts to secure the door, ">
+		       <BOLT-STATE .CNT>
+		       <TELL "." CR>)>
+		<CRLF>)
+	       (<VERB? OPEN>
+		<COND (<EQUAL? .CNT 7> <RFALSE>)
+		      (ELSE <TELL "The door is still bolted." CR>)>)
+	       (<VERB? LOCK>
+		<PERFORM ,V?CLOSE ,BOLTS>
+		<RTRUE>)
+	       (<VERB? UNLOCK>
+		<PERFORM ,V?OPEN ,BOLTS>
+		<RTRUE>)>>
+
+<OBJECT BALCONY-DOOR
+	(LOC LOCAL-GLOBALS)
+	(DESC "balcony door")
+	(SYNONYM DOOR)
+	(ADJECTIVE BALCONY)
+	(FLAGS DOORBIT LOCKABLE TRYTAKEBIT)
+	(ACTION BALCONY-DOOR-F)>
+
+<ROUTINE BALCONY-DOOR-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"This strong, iron-bound door has rarely been used.  The catches
+are rusty and the door itself is covered with cobwebs.  Unfortunately,
+it appears to be the only other exit from the room." CR>)
+	       (<VERB? OPEN>
+		<COND (<OR <NOT <FSET? ,TOP-CATCH ,OPENBIT>>
+			   <NOT <FSET? ,BOTTOM-CATCH ,OPENBIT>>>
+		       <TELL
+"The door won't open.  The rusty ">
+		       <COND (<FSET? ,TOP-CATCH ,OPENBIT>
+			      <TELL
+"bottom catch holds">)
+			     (<FSET? ,BOTTOM-CATCH ,OPENBIT>
+			      <TELL
+"top catch holds">)
+			     (ELSE
+			      <TELL
+"top and bottom catches hold">)>
+		       <TELL " it securely closed." CR>)
+		      (<AND <HERE? ,SECRET-REDOUBT>
+			    <OR <QUEUED? I-NINJA-VS-SECRET-DOOR>
+				<QUEUED? I-NINJA-TAKE-MARIKO>>>
+		       <FSET ,PRSO ,OPENBIT>
+		       <TELL
+"You throw the door open.  Sweet night air rushes in">
+		       <COND (<IN? ,ETSU ,SECRET-REDOUBT>
+			      <MOVE ,ETSU ,BALCONY>
+			      <MOVE ,ACHIKO ,BALCONY>
+			      <MOVE ,CHIMMOKO ,BALCONY>
+			      <MOVE ,KIRITSUBO ,BALCONY>
+			      <TELL
+", and the women
+pour onto the veranda.  Old Lady Etsu stumbles and you help her
+through, then turn to help Mariko." CR>)
+			     (ELSE <TELL "." CR>)>)>)
+	       (<VERB? LOCK UNLOCK>
+		<TELL "There's no lock, only a top and bottom catch." CR>)
+	       (<HOSTILE-VERB?>
+		<COND (<NOT <FSET? ,TOP-CATCH ,OPENBIT>>
+		       <REDIRECT ,BALCONY-DOOR ,TOP-CATCH>)
+		      (<NOT <FSET? ,TOP-CATCH ,OPENBIT>>
+		       <REDIRECT ,BALCONY-DOOR ,BOTTOM-CATCH>)
+		      (ELSE
+		       <PERFORM ,V?OPEN ,BALCONY-DOOR>)>
+		<RTRUE>)>>
+
+<NEW-ADD-WORD "CATCHES" NOUN <VOC "CATCH"> ,PLURAL-FLAG>
+
+<OBJECT TOP-CATCH
+	(LOC SECRET-REDOUBT)
+	(DESC "top catch")
+	(SYNONYM CATCH ;CATCHES)
+	(ADJECTIVE UPPER TOP RUSTY IRON)
+	(FLAGS NDESCBIT OPENABLE LOCKED)
+	(ACTION CATCH-F)>
+
+<OBJECT BOTTOM-CATCH
+	(LOC SECRET-REDOUBT)
+	(DESC "bottom catch")
+	(SYNONYM CATCH ;CATCHES)
+	(ADJECTIVE LOWER BOTTOM RUSTY IRON)
+	(FLAGS NDESCBIT OPENABLE LOCKED)
+	(ACTION CATCH-F)>
+
+<ROUTINE CATCH-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <TELL CTHE ,PRSO " is open." CR>)
+		      (<NOT <FSET? ,PRSO ,LOCKED>>
+		       <TELL CTHE ,PRSO " is closed." CR>)
+		      (<FSET? ,PRSO ,RMUNGBIT>
+		       <TELL "It looks a little looser than before." CR>)
+		      (ELSE
+		       <TELL
+"This rusty iron catch hasn't been used in years, but it still looks
+strong." CR>)>)
+	       (<VERB? OPEN>
+		<COND (<FSET? ,PRSO ,LOCKED>
+		       <TELL
+"The catches are very rusty and won't open." CR>)>)
+	       (<AND <VERB? SHOOT>
+		     <NOT <FSET? ,PISTOL ,RMUNGBIT>>>
+		<FSET ,PISTOL ,RMUNGBIT>
+		<TELL
+"The pistol goes off, but it doesn't appear to have
+done anything to " THE ,PRSI "." CR>)
+	       (<AND <HOSTILE-VERB?>
+		     <NOT <FSET? ,PRSO ,OPENBIT>>>
+		<COND (<NOT <FSET? ,PRSO ,RMUNGBIT>>
+		       <FSET ,PRSO ,RMUNGBIT>
+		       <TELL
+"You pound on " THE ,PRSO " with all your might, small flakes of rust
+falling like snow, but it only gives a little." CR>)
+		      (ELSE
+		       <FSET ,PRSO ,OPENBIT>
+		       <FCLEAR ,PRSO ,LOCKED>
+		       <TELL
+"You smash again and again, and finally " THE ,PRSO " clatters open." CR>)>)
+	       (<AND <VERB? CLOSE>
+		     <FSET? ,PRSO ,OPENBIT>>
+		<FCLEAR ,PRSO ,OPENBIT>
+		<TELL
+"The catch slides closed with a rusty squeal">
+		<COND (<FSET? ,BALCONY-DOOR ,OPENBIT>
+		       <TELL
+", but " THE ,BALCONY-DOOR " is still open">)>
+		<TELL "." CR>)>>
+
+<ROOM BALCONY
+      (LOC ROOMS)
+      (DESC "Balcony")
+      (SYNONYM BALCONY)
+      (LDESC
+"This is a small balcony surrounded by a low battlement.  The night air
+is cool and sweet here after the smoke and confusion inside.  The only
+exit is back into the redoubt.  This is as far as you can retreat.")
+      (IN TO SECRET-REDOUBT IF BALCONY-DOOR IS OPEN)
+      (SOUTH TO SECRET-REDOUBT IF BALCONY-DOOR IS OPEN)
+      (FLAGS ONBIT OUTSIDE)
+      (GLOBAL BALCONY-DOOR LG-NINJA LG-WOMEN)
+      (ACTION BALCONY-F)>
+
+<ROUTINE BALCONY-F ("OPT" (RARG <>))
+	 <COND (<RARG? BEG>
+		<COND (<AND <VERB? WALK>
+			    <IN? ,NINJA ,HERE>
+			    ,KNOCKOUT-CNT>
+		       <TELL
+G"You can't break through the encircling ninja!" CR>)
+		      (<AND <P? WALK (P?SOUTH P?IN)>
+			    <IN? ,NINJA ,HERE>>
+		       <TELL
+G"You would have to walk right through the ninja!" CR>)
+		      (<P? (LEAP DIVE) (BALCONY GLOBAL-HERE)>
+		       <COND (<JIGS-UP? ,J-PLUNGE>
+			      <JIGS-UP "You plunge to your death.">)
+			     (ELSE <RTRUE>)>)>)>>
+
+<OBJECT NORTH-SHOJI
+	(LOC LOCAL-GLOBALS)
+	(DESC "inner shoji")
+	(SYNONYM SHOJI DOOR)
+	(ADJECTIVE INNER)
+	(FLAGS DOORBIT)>
+
+<OBJECT SOUTH-SHOJI
+	(LOC LOCAL-GLOBALS)
+	(DESC "outer shoji")
+	(SYNONYM SHOJI DOOR)
+	(ADJECTIVE OUTER)
+	(FLAGS DOORBIT)>
+
+<ROOM OUTER-ROOM
+      (LOC ROOMS)
+      (DESC "Outer Room")
+      (SYNONYM ROOM)
+      (ADJECTIVE OUTER)
+      (LDESC
+"This is a waiting room outside Mariko's quarters.  There are shoji
+screens all around.  One opens north to the private rooms, and one
+south to the inner corridor.")
+      (NORTH TO PRIVATE-QUARTERS IF NORTH-SHOJI IS OPEN)
+      (IN TO PRIVATE-QUARTERS IF NORTH-SHOJI IS OPEN)
+      (OUT TO INNER-CORRIDOR IF SOUTH-SHOJI IS OPEN)
+      (SOUTH TO INNER-CORRIDOR IF SOUTH-SHOJI IS OPEN)
+      (FLAGS ONBIT)
+      (GLOBAL LG-NINJA NORTH-SHOJI SOUTH-SHOJI LG-WOMEN)
+      (ACTION OUTER-ROOM-F)>
+
+<ROUTINE OUTER-ROOM-F (RARG)
+	 <COND (<RARG? BEG>
+		<COND (<VERB? LEAVE>
+		       <DO-WALK ,P?NORTH>)
+		      (<VERB? WALK>
+		       <COND (<IN? ,YABU ,HERE>
+			      <TELL
+"\"Please, Anjin-san, don't leave until I am done.\"" CR>)
+			     (<IN? ,NINJA ,HERE>
+			      <COND (,KNOCKOUT-CNT
+				     <TELL
+G"You can't break through the encircling ninja!" CR>)
+				    (<PRSO? P?SOUTH P?OUT>
+				     <TELL
+G"You would have to walk right through the ninja!" CR>)>)>)>)
+	       (<RARG? ENTER>
+		<COND (<IN? ,YABU ,HERE>
+		       <FSET ,YABU ,TOUCHBIT>
+		       <DEQUEUE I-YABU-LEAVES>
+		       <SETG YABU-CNT 0>
+		       <QUEUE I-YABU -1>
+		       <TELL
+"As you enter, you see Yabu waiting impatiently.  Beyond him you see
+a guard watching curiously." CR CR>)>)>>
+
+<ROUTINE I-YABU-LEAVES ()
+	 <COND (<L? ,YABU-CNT 3>
+		<SETG YABU-CNT 3>)>
+	 <MOVE ,YABU ,INNER-CORRIDOR>
+	 <MOVE ,CHIMMOKO ,HERE>
+	 <TELL CR
+"Mariko's servant Chimmoko approaches you, very agitated.  \"Anjin-san,
+Lord Yabu has left!  He was very disturbed!\"" CR>>
+
+<GLOBAL FOLLOW-FLAG <>>
+
+<ROUTINE SETUP-FOLLOW-YABU ()
+	 <COND (<AND <QUEUED? I-YABU>
+		     <NOT <EQUAL? ,FOLLOW-FLAG ,YABU>>>
+		<SETG FOLLOW-FLAG ,YABU>
+		<DEQUEUE I-YABU>
+		<QUEUE I-FOLLOW-YABU -1>
+		<QUEUE I-YABU -1>)>>
+
+<ROUTINE I-FOLLOW-YABU ("AUX" (L <LOC ,YABU>))
+	 <COND (,FOLLOW-FLAG
+		<COND (<AND <NOT <HERE? .L>>
+			    <NOT <NEXT-ROOM? .L>>>
+		       <SETG FOLLOW-FLAG <>>
+		       <DEQUEUE I-FOLLOW-YABU>
+		       <TELL CR
+"You seem to have lost Yabu!  He's gotten too far ahead of you." CR>)>)
+	       (ELSE
+		<DEQUEUE I-FOLLOW-YABU>
+		<RFALSE>)>>
+
+<GLOBAL YABU-BETRAYED? <>>
+
+<ROUTINE I-YABU ()
+	 <THIS-IS-IT ,YABU>
+	 <ZLINES ,YABU-CNT
+		 (DELAY
+		  <COND (<AND <IN? ,YABU ,OUTER-ROOM>
+			      <NOT <IN? ,PLAYER ,OUTER-ROOM>>>
+			 <RFALSE>)>)
+		 (;1
+		  <COND (<IN? ,YABU ,HERE>
+			 <SETG QCONTEXT ,YABU>
+			 <TELL CR
+"\"So sorry to disturb you, Anjin-san.  I just want see -- make sure
+all right, understand?  Lady Toda all right?  Not sick?\"  Yabu seems
+nervous.  You are reminded that this afternoon Yabu said something
+about a \"plan.\"" CR>)>)
+		 (;2
+		  <COND (<IN? ,YABU ,HERE>
+			 <SETG QCONTEXT ,YABU>
+			 <TELL CR
+"Yabu says, trying to keep his words simple so you will understand,
+\"Just want make sure all right.  Understand?\"" CR>)>)
+		 (;3
+		  <MOVE ,YABU ,INNER-CORRIDOR>
+		  <SETG QCONTEXT <>>
+		  <COND (<HERE? ,OUTER-ROOM>
+			 <TELL CR
+"Yabu bows, very friendly, and leaves.  His manner seems very
+suspicious.  The guard closes the shoji behind him." CR>)>)
+		 (DELAY
+		  <COND (<HERE? ,INNER-CORRIDOR>)
+			(<L? ,DELAY-CNT 2>
+			 <RFALSE>)>)
+		 (;4
+		  <MOVE ,YABU ,AUDIENCE-CHAMBER>
+		  <COND (<HERE? ,INNER-CORRIDOR>
+			 <TELL CR
+"Yabu walks through the audience chamber, checking that the guards are
+alert." CR>)>)
+		 (DELAY
+		  <COND (<HERE? ,AUDIENCE-CHAMBER>)
+			(<AND <NOT <HERE? ,INNER-CORRIDOR ,AUDIENCE-CHAMBER>>
+			      <L? ,DELAY-CNT 2>>
+			 <RFALSE>)>)
+		 (<MOVE ,YABU ,OUTER-CORRIDOR>
+		  <COND (<HERE? ,AUDIENCE-CHAMBER>
+			 <TELL CR
+"Yabu leaves the audience chamber for the outer corridor, heading for
+the main stairway." CR>)>)
+		 (DELAY
+		  <COND (<HERE? ,OUTER-CORRIDOR>)
+			(<AND <NOT <HERE? ,AUDIENCE-CHAMBER ,OUTER-CORRIDOR>>
+			      <L? ,DELAY-CNT 2>>
+			 <RFALSE>)>)
+		 (<MOVE ,YABU ,STAIRS>
+		  <COND (<HERE? ,OUTER-CORRIDOR>
+			 <TELL CR
+"Yabu goes down the stairs." CR>)>)
+		 (DELAY
+		  <COND (<HERE? ,STAIRS>)
+			(<AND <NOT <HERE? ,OUTER-CORRIDOR ,STAIRS>>
+			      <L? ,DELAY-CNT 2>>
+			 <RFALSE>)>)
+		 (<MOVE ,YABU ,SERVANTS-QUARTERS>
+		  <COND (<HERE? ,STAIRS>
+			 <TELL CR
+"Yabu goes down the steps and enters the servants' quarters.  The servants
+drag themselves out of sleep and put their heads to the flagstones." CR>)>)
+		 (DELAY
+		  <COND (<HERE? ,SERVANTS-QUARTERS>)
+			(<AND <NOT <HERE? ,STAIRS ,SERVANTS-QUARTERS>>
+			      <L? ,DELAY-CNT 2>>
+			 <RFALSE>)>)
+		 (<MOVE ,YABU ,CELLARS>
+		  <COND (<HERE? ,SERVANTS-QUARTERS>
+			 <TELL CR
+"Yabu leads the way deeper into the bowels of the fortress, down steps,
+along little-used corridors.  There are no guards here." CR>)>)
+		 (DELAY
+		  <COND (<HERE? ,CELLARS>)
+			(<AND <NOT <HERE? ,SERVANTS-QUARTERS ,CELLARS>>
+			      <L? ,DELAY-CNT 2>>
+			 <RFALSE>)>)
+		 (<COND (<HERE? ,CELLARS>
+			 <TELL CR
+"Yabu stands in the middle of a large cellar room.  He seems to be
+composing himself, glancing nervously ahead." CR>)>)
+		 (<MOVE ,NINJA ,CELLARS>
+		  <FSET ,CELLAR-DOOR ,OPENBIT>
+		  <COND (<HERE? ,CELLARS>
+			 <TELL CR
+"Yabu rushes for a hardly noticed, heavily barred, small iron door.  He
+fights back the rusted bolts.  A draught of cool air from outside, then
+a spear stabs for his throat and stops just in time.  Sinister black shapes
+stare in from the darkness beyond the door.|
+|
+\"I'm Kasigi Yabu,\" he says, and makes a sign with his hands.  Instantly
+twenty black-clad men pour out of the dark
+and rush for a long-forgotten back way to the floors above.  Yabu watches
+them intently, sweat beading on his brow." CR>
+			 <SCORE-OBJECT ,CELLARS>)
+			(ELSE
+			 <FCLEAR ,CELLARS ,SCOREBIT>)>
+		  <SETG FOLLOW-FLAG <>>
+		  <RTRUE>)
+		 (<COND (<AND <HERE? ,CELLARS>
+			      <FSET? ,BARRELS ,SCOREBIT>>
+			 <CRLF>
+			 <JIGS-UP
+"One of the ninja notices you lurking in the dark, and quickly and
+quietly you are surrounded, overpowered, and killed.">
+			 <RFATAL>)>
+		  <MOVE ,YABU ,GENERIC-OBJECTS>
+		  <MOVE ,NINJA ,SECRET-ROOM>
+		  <FCLEAR ,CELLAR-DOOR ,OPENBIT>
+		  <SETG YABU-BETRAYED? T>
+		  <COND (<HERE? ,CELLARS>
+			 <SETG FOLLOW-FLAG <>>
+			 <TELL CR
+"Yabu nervously watches more "I"ninja"" pour into the cellar.  As soon
+as they are gone, he closes the door and slips away.|
+|
+As quickly and quietly as possible you return to the living quarters,
+fearing that anyone you encounter may be in on the plot." CR CR>
+			 <GOTO ,OUTER-ROOM>)>
+		  <RTRUE>)
+		 (<DEQUEUE I-YABU>
+		  <QUEUE I-ATTACK -1>
+		  <RFALSE>)>>
+
+<ROOM STAIRS
+      (LOC ROOMS)
+      (DESC "Winding Stairs")
+      (SYNONYM STAIRS)
+      (ADJECTIVE WINDING)
+      (LDESC
+"This is the main staircase leading from the tower to the cellars of Toranaga's
+keep at Osaka.")
+      (UP TO OUTER-CORRIDOR)
+      (DOWN TO SERVANTS-QUARTERS)
+      (FLAGS ONBIT)
+      (ACTION STAIRS-F)>
+
+<ROUTINE STAIRS-F (RARG)
+	 <COND (<RARG? BEG>
+		<COND (<AND <P? WALK P?DOWN>
+			    <IN? ,YABU ,HERE>>
+		       <YABU-LISTENS>)>)>>
+
+<ROOM SERVANTS-QUARTERS
+      (LOC ROOMS)
+      (SCENE S-NINJA)
+      (DESC "Servants' Quarters")
+      (SYNONYM QUARTERS)
+      (ADJECTIVE SERVANTS)
+      (LDESC
+"This is a crowded, narrow room full of servants.  Many of them are
+asleep.  Others are kneeling, head to flagstones.  A stairway leads
+down to the cellars from here.")
+      (UP TO STAIRS)
+      (DOWN TO CELLARS)
+      (FLAGS ONBIT)
+      (ACTION SERVANTS-QUARTERS-F)>
+
+<ROUTINE SERVANTS-QUARTERS-F (RARG)
+	 <COND (<RARG? BEG>
+		<COND (<AND <P? WALK P?DOWN>
+			    <IN? ,YABU ,HERE>>
+		       <YABU-LISTENS>)>)>>
+
+<OBJECT SERVANTS
+	(LOC SERVANTS-QUARTERS)
+	(DESC "servants")
+	(SYNONYM SERVANTS SERVANT)
+	(FLAGS NDESCBIT PERSON JAPANESEBIT PLURAL OPENBIT CONTBIT SEARCHBIT)
+	(ACTION SERVANTS-F)>
+
+<ROUTINE SERVANTS-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<TELL "They seem afraid to respond." CR>
+		<END-QUOTE>)
+	       (<VERB? EXAMINE>
+		<TELL
+"Those that are not asleep are prostrate on the stone floor,
+bowing abjectly and pretending not to exist." CR>)
+	       (<VERB? WAKE>
+		<TELL
+"You would only call even more attention to yourself.  Yabu might hear." CR>)>>
+
+<ROOM CELLARS
+      (LOC ROOMS)
+      (DESC "Cellars")
+      (SYNONYM CELLAR CELLARS)
+      (UP TO SERVANTS-QUARTERS)
+      (GLOBAL CELLAR-DOOR)
+      (FLAGS ONBIT SCOREBIT)
+      (ACTION CELLARS-F)>
+
+<ROUTINE CELLARS-F (RARG)
+	 <COND (<RARG? LOOK>
+		<TELL
+"These are the cellars of the fortress.  The stone walls are damp and
+mildewed, though well-lit.  Crates, boxes and barrels are everywhere.">
+		<COND (,YABU-BETRAYED?
+		       <TELL
+" An ">
+		       <COND (<FSET? ,CELLAR-DOOR ,OPENBIT>
+			      <TELL "open ">)>
+		       <TELL "iron-bound door is set in the east wall.">)>
+		<CRLF>)
+	       (<RARG? ENTER>
+		<COND (,YABU-BETRAYED?
+		       <TELL
+"As you make your way down into the cellars, wondering where Yabu has gotten
+to, you"G" are surprised by a force of attacking ninja!  They are equally
+surprised, but react more quickly." CR>
+		       <JIGS-UP>
+		       <RFATAL>)>)
+	       (<RARG? BEG>
+		<COND (<VERB? HIDE>
+		       <PERFORM ,V?HIDE-BEHIND ,BARRELS>
+		       <RTRUE>)
+		      (<AND <NOT <VERB? HIDE-BEHIND HIDE-UNDER>>
+			    <MOTION-VERB?>>
+		       <COND (<JIGS-UP? ,J-CELLAR
+"If you were to emerge from hiding, you would be seen.">
+			      <COND (<P? WALK P?EAST>
+				     <TELL
+"You emerge from the shadows and approach the door.  ">)
+				    (ELSE
+				     <TELL
+"You try to sneak across the cellar.  ">)>
+			      <COND (<IN? ,NINJA ,HERE>
+				     <TELL CTHE ,NINJA " notice">)
+				    (<IN? ,YABU ,HERE>
+				     <TELL D ,YABU " notices">)
+				    (ELSE
+				     <TELL "The ninja rear guard notices">)>
+			      <TELL
+" you almost immediately.  A glint of metal in the
+torchlight is your last sight.">
+			      <JIGS-UP>)
+			     (ELSE <RTRUE>)>)
+		      (<AND <P? SHOOT PISTOL *>
+			    <NOT <FSET? ,PISTOL ,RMUNGBIT>>>
+		       <COND (<JIGS-UP? ,J-SHOOT>
+			      <TELL
+"The shot rings out, but in the dim light of the cellars, you don't hit
+anything.  ">
+			      <COND (<FSET? ,PRSO ,PERSON>
+				     <TELL
+CTHE ,PRSO " doesn't miss, however.">)>
+			      <CRLF>
+			      <JIGS-UP>)
+			     (ELSE <RTRUE>)>)>)
+	       (<RARG? END>
+		<COND (,YABU-HEARD?
+		       <TELL CR
+"Yabu stops for a moment as though he heard something, then turns and
+rushes back toward you, drawing his sword as he charges.  It's quite
+clear he heard you following him some time ago!" CR>
+		       <JIGS-UP>
+		       <RFATAL>)>)>>
+
+<OBJECT BARRELS
+	(LOC CELLARS)
+	(DESC "crates, barrels, and boxes")
+	(SYNONYM CRATE BARREL BOX CRATES BARRELS BOXES PILE STACK)
+	(FLAGS NDESCBIT FURNITURE SURFACEBIT VEHBIT SCOREBIT)
+	(ACTION BARRELS-F)>
+
+<ROUTINE BARRELS-F ()
+	 <COND (<VERB? HIDE-UNDER HIDE-BEHIND BOARD WALK-AROUND>
+		<COND (<NOT <FSET? ,BARRELS ,SCOREBIT>>
+		       <TELL G"You already are." CR>)
+		      (ELSE
+		       <TELL
+"Quietly, you conceal yourself behind one of the piles, and watch." CR>
+		       <SCORE-OBJECT ,BARRELS>)>)>>
+
+<OBJECT CELLAR-DOOR
+	(LOC LOCAL-GLOBALS)
+	(DESC "iron-bound door")
+	(SYNONYM DOOR)
+	(ADJECTIVE CELLAR IRON-BOUND IRON BOUND)
+	(FLAGS AN DOORBIT LOCKABLE)
+	(ACTION CELLAR-DOOR-F)>
+
+<ROUTINE CELLAR-DOOR-F ()
+	 <COND (<SCENE? ,S-AFTERMATH>
+		<COND (<NOT <PAST-TENSE?>>
+		       <TELL "There's no door here." CR>)>)
+	       (<NOT <PASSIVE-VERB?>>
+		<DO-WALK ,P?EAST>)>>
+
+<ROOM INNER-CORRIDOR
+      (LOC ROOMS)
+      (DESC "Inner Corridor")
+      (SYNONYM CORRIDOR)
+      (ADJECTIVE INNER)
+      (LDESC
+"This inner corridor is between the Audience Chamber to the west, and
+the inner apartments of the keep to the north.  A sturdy iron-barred door
+separates the Audience Chamber and the corridor.")
+      (NORTH TO OUTER-ROOM IF SOUTH-SHOJI IS OPEN)
+      (IN TO OUTER-ROOM IF SOUTH-SHOJI IS OPEN)
+      (WEST TO AUDIENCE-CHAMBER IF INNER-DOOR IS OPEN)
+      (OUT TO AUDIENCE-CHAMBER IF INNER-DOOR IS OPEN)
+      (GLOBAL INNER-DOOR LG-NINJA SOUTH-SHOJI GUARDS)
+      (FLAGS ONBIT)
+      (ACTION INNER-CORRIDOR-F)>
+
+<ROUTINE INNER-CORRIDOR-F (RARG)
+	 <COND (<RARG? BEG>
+		<COND (<VERB? LEAVE>
+		       <DO-WALK ,P?NORTH>)
+		      (<AND <VERB? WALK>
+			    <IN? ,NINJA ,HERE>
+			    ,KNOCKOUT-CNT>
+		       <TELL
+G"You can't break through the encircling ninja!" CR>)
+		      (<AND <P? WALK (P?WEST P?OUT)>
+			    <IN? ,NINJA ,HERE>>
+		       <TELL
+G"You would have to walk right through the ninja!" CR>)
+		      (<AND <P? WALK P?WEST>
+			    <IN? ,YABU ,HERE>>
+		       <COND (<JIGS-UP? ,J-FOLLOW-CLOSE
+"You realize you're getting too close to Yabu, so you wait instead of
+walking.">
+			      <YABU-LISTENS>)
+			     (ELSE <RTRUE>)>)>)>>
+
+<ROUTINE YABU-LISTENS ()
+	 <COND (<PROB 50> <SETG YABU-HEARD? T>)
+	       (ELSE <SETG STUPID-MOVE <>>)>
+	 <TELL
+"You're getting too close to Yabu.  He stops briefly: he may have heard
+you!" CR>>
+
+<GLOBAL YABU-HEARD? <>>
+
+<ROOM SECRET-ROOM
+      (LOC ROOMS)
+      (DESC "Secret Room")
+      (SYNONYM ROOM)
+      (ADJECTIVE SECRET)
+      (LDESC
+"This is a secret room south of the Audience Chamber. A dark and narrow
+stairway leads down as well.")
+      (NORTH TO AUDIENCE-CHAMBER IF SECRET-ROOM-DOOR IS OPEN)
+      (GLOBAL SECRET-ROOM-DOOR LG-NINJA)
+      (FLAGS ONBIT)
+      (ACTION SECRET-ROOM-F)>
+
+<ROUTINE SECRET-ROOM-F (RARG)
+	 <COND (<RARG? BEG>
+		<COND (<P? WALK P?DOWN>
+		       <COND (<JIGS-UP? ,J-REAR-GUARD
+"You suddenly realize that the ninja have probably left a rear guard, and
+decide not to follow.">
+			      <JIGS-UP
+"You walk right into the ninja rear guard, which is lurking in the
+darkness.">)
+			     (ELSE <RTRUE>)>)>)>>
+
+<OBJECT SECRET-ROOM-DOOR
+	(LOC LOCAL-GLOBALS)
+	(DESC "secret door")
+	(SYNONYM DOOR)
+	(ADJECTIVE SECRET)
+	(FLAGS INVISIBLE DOORBIT LOCKABLE)>
+
+<OBJECT INNER-DOOR
+	(LOC LOCAL-GLOBALS)
+	(DESC "iron-barred inner door")
+	(SYNONYM DOOR)
+	(ADJECTIVE IRON-BARRED IRON-BOUND INNER STURDY)
+	(FLAGS DOORBIT OPENBIT LOCKABLE)
+	(ACTION INNER-DOOR-F)>
+
+<ROUTINE INNER-DOOR-F ()
+	 <COND (<VERB? OPEN>
+		<COND (<FSET? ,INNER-DOOR ,LOCKED>
+		       <TELL
+"The iron bar is firmly in place.  The door won't open." CR>)>)
+	       (<VERB? CLOSE>
+		<COND (<AND <IN? ,MARIKO ,AUDIENCE-CHAMBER>
+			    <HERE? ,INNER-CORRIDOR>>
+		       <TELL
+"Mariko screams through the narrowing gap, \"Anjin-san!  Don't leave me
+behind!\"" CR CR>
+		       <RFALSE>)
+		      (<AND <IN? ,GRAY-CAPTAIN ,AUDIENCE-CHAMBER>
+			    <NOT <FSET? ,GRAY-CAPTAIN ,DEAD>>>
+		       <TELL
+CTHE ,GUARDS G" stop you from closing the door." CR>)
+		      (<IN? ,GUARDS ,AUDIENCE-CHAMBER>
+		       <TELL
+CTHE ,GUARDS G" stop you from closing the door." CR>)>)
+	       (<VERB? LOCK>
+		<PERFORM ,V?CLOSE ,IRON-BAR>
+		<RTRUE>)
+	       (<VERB? UNLOCK>
+		<PERFORM ,V?OPEN ,IRON-BAR>
+		<RTRUE>)>>
+
+<OBJECT IRON-BAR
+	(LOC INNER-CORRIDOR)
+	(DESC "iron bar")
+	(SYNONYM BAR)
+	(ADJECTIVE IRON)
+	(FLAGS NDESCBIT OPENBIT OPENABLE)
+	(ACTION IRON-BAR-F)>
+
+<ROUTINE IRON-BAR-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL-OPEN-CLOSED>)
+	       (<AND <VERB? OPEN>
+		     <NOT <FSET? ,IRON-BAR ,OPENBIT>>>
+		<FSET ,IRON-BAR ,OPENBIT>
+		<FCLEAR ,INNER-DOOR ,LOCKED>
+		<TELL
+"You slide the bar aside." CR>)
+	       (<AND <VERB? CLOSE>
+		     <FSET? ,IRON-BAR ,OPENBIT>>
+		<COND (<AND <IN? ,GRAY-CAPTAIN ,AUDIENCE-CHAMBER>
+			    <NOT <FSET? ,GRAY-CAPTAIN ,DEAD>>>
+		       <TELL
+CTHE ,GUARDS G" stop you from barring the door." CR>)
+		      (<IN? ,GUARDS ,AUDIENCE-CHAMBER>
+		       <TELL
+CTHE ,GUARDS G" stop you from barring the door." CR>)
+		      (ELSE
+		       <FCLEAR ,IRON-BAR ,OPENBIT>
+		       <FSET ,INNER-DOOR ,LOCKED>
+		       <TELL
+			"You slide the bar into place." CR>)>)>>
+
+<OBJECT OUTER-DOOR
+	(LOC LOCAL-GLOBALS)
+	(DESC "outer door")
+	(SYNONYM DOOR)
+	(ADJECTIVE OUTER)
+	(FLAGS AN LOCKABLE DOORBIT OPENBIT)>
+
+<ROUTINE I-ATTACK ()
+	 <ZLINES ,ATTACK-CNT
+		 (2
+		  <COND (<HERE? ,STAIRS ,SERVANTS-QUARTERS>
+			 <TELL
+"You"G" are surprised by a force of attacking ninja!  They are equally
+surprised, but react quickly." CR>
+			 <JIGS-UP>
+			 <RFATAL>)>)
+		 (DELAY
+		  <COND (<OR <NOT ,YABU-BETRAYED?>
+			     <L=? ,DELAY-CNT 3>>
+			 <RFALSE>)>)
+		 (<COND (<HERE? <LOC ,ACHIKO>>
+			 <TELL CR
+"The young girl, Achiko, mumbles in her sleep.  She had asked to stay
+with Mariko, as had old Lady Etsu.  Kiyama had sent for Achiko, his
+granddaughter-in-law, but she refused to leave Mariko.  At once the
+daimyo had disowned her." CR>)>)
+		 (1)
+		 (<QUEUE I-WOMEN -1>
+		  <FCLEAR ,LG-NINJA ,INVISIBLE>
+		  <TELL CR
+"Suddenly, the quiet is shattered by the cry \"Ninja!\"" CR>)
+		 (<TELL CR
+"From below come the sounds of battle being joined.  Furious cries,
+screams, and the clash of swords fill the air." CR>)
+		 (<MOVE ,NINJA ,SECRET-ROOM>
+		  <MOVE ,NINJA-LEADER ,SECRET-ROOM>
+		  <TELL CR
+G"The sounds of ""battle continue, a violent shouting melee.">
+		  <COND (<HERE? ,AUDIENCE-CHAMBER ,OUTER-CORRIDOR
+				,INNER-CORRIDOR>
+			 <TELL " The frantic
+guards at the fortified door to the outer corridor listen anxiously to
+the mounting holocaust below.">)>
+		  <CRLF>)
+		 (<QUEUE I-NINJA -1>
+		  <COND (<NOT <FSET? ,OUTER-DOOR ,OPENBIT>>
+			 <FSET ,OUTER-DOOR ,OPENBIT>
+			 <TELL CR
+"The guards reopen the outer door, so as to better hear the melee below." CR>)>
+		  <MOVE ,GUARDS ,OUTER-CORRIDOR>
+		  <COND (<OR <HERE? ,AUDIENCE-CHAMBER>
+			     <AND <HERE? ,INNER-CORRIDOR>
+				  <FSET? ,INNER-DOOR ,OPENBIT>>>
+			 <TELL CR
+"The officers of the Browns and Grays order their men to take up defensive
+positions at the far end of the corridor, no longer able to stand the
+waiting.  Only the captain of the Grays remains, beside the door to the
+inner corridor." CR>)
+			(ELSE
+			 <TELL CR
+"You can hear officers shouting orders." CR>)>)
+		 (<DEQUEUE I-ATTACK>
+		  <COND (<NOT <FSET? ,GRAY-CAPTAIN ,DEAD>>
+			 <MOVE ,GRAY-CAPTAIN ,OUTER-CORRIDOR>
+			 <COND (<OR <HERE? ,AUDIENCE-CHAMBER>
+				    <AND <HERE? ,INNER-CORRIDOR>
+					 <FSET? ,INNER-DOOR ,OPENBIT>>>
+				<TELL CR
+"Now the captain of the Grays leaves the audience chamber." CR>)>)
+			(ELSE <RFALSE>)>)>>
+
+<OBJECT GRAY-CAPTAIN
+	(SCENE S-NINJA S-PRISON)
+	(OWNER <>)
+	(DESC "Gray Captain")
+	(SYNONYM CAPTAIN)
+	(ADJECTIVE GRAY)
+	(FLAGS PERSON)
+	(HEALTH 4)
+	(GENERIC GENERIC-CAPTAIN-F)
+	(ACTION GRAY-CAPTAIN-F)>
+
+<ROUTINE GRAY-CAPTAIN-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<WAKARIMASEN>)
+	       (<RARG? SUBJ>
+		<RFALSE>)
+	       (<VERB? EXAMINE>
+		<COND (<FSET? ,PRSO ,DEAD>
+		       <COND (<EQUAL? <GETP ,PRSO ,P?OWNER> ,NINJA>
+			      <TELL
+"He has been hacked to death by the ninja." CR>)
+			     (ELSE
+			      <TELL
+"He is dead.  You killed him, remember?" CR>)>)
+		      (<AND <NOT <FSET? ,LG-NINJA ,INVISIBLE>>
+			    <SCENE? ,S-NINJA>>
+		       <TELL
+"He is impatient to join the battle, torn between his duty to guard
+the hostages and his desire to destroy the attackers." CR>)
+		      (ELSE
+		       <TELL
+"He is supervising the guards." CR>)>)
+	       (<P? SHOOT * PISTOL>
+		<COND (<FSET? ,PISTOL ,RMUNGBIT>
+		       <RFALSE>)
+		      (ELSE
+		       <COND (<OR <NOT <IN? ,GUARDS ,HERE>>
+				  <JIGS-UP? ,J-KILL-CAPTAIN>>
+			      <PUTP ,GRAY-CAPTAIN ,P?OWNER ,BLACKTHORNE>
+			      <FSET ,GRAY-CAPTAIN ,DEAD>
+			      <TELL
+"You fire the pistol, killing the captain instantly.">
+			      <COND (<IN? ,GUARDS ,HERE>
+				     <JIGS-UP
+" The other guards turn and immediately assume this is a
+betrayal.  They cut you down in short order.">)
+				    (ELSE
+				     <TELL
+" As the gray guards aren't here, you may get away with it." CR>)>)
+			     (ELSE <RTRUE>)>)>)
+	       (<AND <HOSTILE-VERB?>
+		     <NOT <FSET? ,GRAY-CAPTAIN ,DEAD>>>
+		<COND (<JIGS-UP? ,J-KILL-CAPTAIN>
+		       <JIGS-UP
+"You attack the captain.  Surprised, and assuming you are part of
+some scheme of betrayal, he fights back, and you are dispatched quickly.">)
+		      (ELSE <RTRUE>)>)>>
+
+<CONSTANT J-PLUNGE 170>
+<CONSTANT J-CELLAR 171>
+<CONSTANT J-SHOOT 172>
+<CONSTANT J-FOLLOW-CLOSE 173>
+<CONSTANT J-REAR-GUARD 174>
+<CONSTANT J-KILL-CAPTAIN 175>
+<CONSTANT J-KILL-GUARDS 176>
+<CONSTANT J-CALTROPS 177>
+
+<OBJECT GUARDS
+	;(LOC AUDIENCE-CHAMBER)
+	(DESC "guards")
+	(SYNONYM GUARDS GUARD)
+	(ADJECTIVE SAMURAI GRAY BROWN)
+	(FLAGS PERSON JAPANESEBIT PLURAL NOABIT)
+	(GENERIC GENERIC-SAMURAI-F)
+	(DESCFCN GUARDS-DESC)
+	(ACTION GUARDS-F)>
+
+<ROUTINE GUARDS-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (<RARG? OBJDESC>
+		<COND (<SCENE? ,S-TORANAGA>
+		       <TELL
+"Guards stand at attention around the perimeter of the room.">)
+		      (<SCENE? ,S-PRISON>
+		       <TELL
+"Samurai guards supervise the activities.">)
+		      (ELSE
+		       <TELL
+"Guards on watch stand here and there about the room.">)>)>>
+
+<ROUTINE GUARDS-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<VERB? EXAMINE>
+		<TELL
+"The guards are Grays, Ishido's men." CR>)
+	       (<VERB? TELL>
+		<TELL
+"They don't respond, as they are on duty." CR>
+		<END-QUOTE>
+		<RFATAL>)
+	       (<HOSTILE-VERB?>
+		<COND (<JIGS-UP? ,J-KILL-GUARDS>
+		       <JIGS-UP
+"The guards, assuming this is some sort of betrayal, respond to your
+attack by killing you.">)
+		      (ELSE <RTRUE>)>)>>
+
+<OBJECT LG-NINJA
+	(LOC LOCAL-GLOBALS)
+	(DESC "ninja")
+	(SYNONYM NINJA FIGURE MEN)
+	(ADJECTIVE RED SPOT BLACK CLAD)
+	(FLAGS INVISIBLE PERSON)
+	(GENERIC GENERIC-NINJA-F)
+	(ACTION LG-NINJA-F)>
+
+<ROUTINE LG-NINJA-F ("OPT" (RARG <>) "AUX" NEARBY? RM)
+	 <SET NEARBY? <NEXT-ROOM? <LOC ,NINJA>>>
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (.NEARBY?
+		       <TELL G"There is no response." CR>)
+		      (ELSE
+		       <TELL "There are no ninja nearby." CR>)>)
+	       (<AND <SCENE? S-AFTERMATH>
+		     <OR <PASSIVE-VERB?>
+			 ,QCONTEXT>>
+		<RFALSE>)
+	       (<VERB? FIND ;WHERE LISTEN>
+		<TELL
+"You see no ninja nearby, but there is plenty of noise." CR>)
+	       (<VERB? FOLLOW>
+		<COND (<QUEUED? I-NINJA-TAKE-MARIKO>
+		       <TELL "You ">
+		       <COND (<EQUAL? ,FOLLOW-FLAG ,NINJA>
+			      <TELL "continue">)
+			     (ELSE
+			      <SETG FOLLOW-FLAG ,NINJA>
+			      <TELL "begin">)>
+		       <TELL
+G" following the ninja, trying to keep up with
+them as they take Mariko." CR>
+		       <SET RM <LOC ,NINJA>>
+		       <COND (<HERE? .RM>
+			      <COND (,FOLLOW-FLAG
+				     <TELL
+"You continue following the ninja, pushing your way ahead, trying to
+keep close." CR>)
+				    (ELSE
+				     <SETUP-FOLLOW-NINJA>
+				     <TELL
+"You begin"
+G" following the ninja, trying to keep up with
+them as they take Mariko." CR>)>)
+			     (<NEXT-ROOM? <LOC ,NINJA>>
+			      <TELL "You ">
+			      <COND (,FOLLOW-FLAG
+				     <TELL "continue">)
+				    (ELSE
+				     <SETUP-FOLLOW-NINJA>
+				     <TELL "begin">)>
+			      <TELL
+" following the ninja, desperate to keep up as they retreat with Mariko." CR>)
+			     (ELSE
+			      <SETG FOLLOW-FLAG <>>
+			      <TELL "You've lost them!" CR>)>
+		       <RTRUE>)
+		      (<FSET? ,NINJA ,INVISIBLE>
+		       <TELL "They are gone." CR>)
+		      (ELSE
+		       <TELL
+"They don't seem to be going anywhere." CR>)>)
+	       (<P? AIM PISTOL LG-NINJA>
+		<TELL
+"The pistol doesn't seem to scare them unless it's fired." CR>)
+	       (<P? SHOOT PISTOL LG-NINJA>
+		<COND (.NEARBY?
+		       <PERFORM ,V?SHOOT ,PISTOL ,NINJA>
+		       <RTRUE>)
+		      (ELSE
+		       <FSET ,PISTOL ,RMUNGBIT>
+		       <TELL
+"The ninja aren't close enough, so your shot is wasted." CR>)>)
+	       (<OR <VERB? TAKE> <HOSTILE-VERB?>>
+		<TELL
+"The ninja aren't close enough to attack." CR>)>>
+
+<OBJECT NINJA-LEADER
+	(LOC SECRET-ROOM)
+	(DESC "ninja leader")
+	(SYNONYM LEADER MAN)
+	(ADJECTIVE RED SPOT NINJA)
+	(FLAGS NDESCBIT PERSON JAPANESEBIT SCOREBIT)
+	(ACTION NINJA-F)>
+
+<OBJECT NINJA
+	(LOC SECRET-ROOM)
+	(DESC "ninja")
+	(SYNONYM NINJA FIGURE MEN)
+	(ADJECTIVE RED SPOT BLACK CLAD)
+	(FLAGS PERSON JAPANESEBIT SCOREBIT PLURAL)
+	(COUNT 5)
+	(DESCFCN NINJA-DESC)
+	(GENERIC GENERIC-NINJA-F)
+	(ACTION NINJA-F)>
+
+<ROUTINE GENERIC-NINJA-F (R F)
+	 ,LG-NINJA>
+
+<ROUTINE NINJA-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (<RARG? OBJDESC>
+		<TELL
+"A force of black-clad, black-masked ninja is here.">)>>
+
+<ROUTINE NINJA-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<TELL
+"The black-masked " D ,WINNER " doesn't answer." CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"The ninja are black-clad, black-masked shapes of darkness." CR>)
+	       (<VERB? COUNT>
+		<TELL
+"It's hard to tell, they are like black-clad ghosts in the dim, pre-dawn
+light." CR>)
+	       (<P? AIM PISTOL (NINJA NINJA-LEADER)>
+		<COND (<FSET? ,PISTOL ,RMUNGBIT>
+		       <TELL
+"The ninja know the pistol isn't loaded." CR>)
+		      (ELSE
+		       <TELL
+"The ninja don't seem too impressed." CR>)>)
+	       (<P? SHOOT PISTOL (NINJA NINJA-LEADER)>
+		<COND (<HERE? ,CELLARS>
+		       <COND (<JIGS-UP? ,J-CELLAR>
+			      <JIGS-UP
+"Your pistol shatters the quiet of the cellars.  Yabu turns, shocked,
+and realizes you have been following him.  He charges, sword drawn,
+and dispatches you before you can escape.">)>
+		       <RFATAL>)>
+		<SETG KNOCKOUT-CNT 0>
+		<COND (<NOT <FSET? ,BALCONY ,TOUCHBIT>>
+		       <QUEUE I-NINJA-COWED <GETP ,NINJA ,P?COUNT>>)>
+		<FSET ,PISTOL ,RMUNGBIT>
+		<COND (<AND <OR <HERE? ,AUDIENCE-CHAMBER>
+				<AND <HERE? ,INNER-CORRIDOR>
+				     <FSET? ,INNER-DOOR ,OPENBIT>>>
+			    <FSET? ,NINJA ,SCOREBIT>>
+		       <QUEUE I-CAPTAIN-RETURNS 1>
+		       <MARGINAL-PIC ,P-NINJA <>>
+		       <REMOVE ,NINJA-LEADER>
+		       <TELL
+"The pistol goes off, and the back of the ninja leader's head disappears,
+momentarily stopping the charge.">
+		       <COND (<NOT <FSET? ,GRAY-CAPTAIN ,DEAD>>
+			      <TELL
+"  The shot alerts the Captain of the Grays.">)>
+		       <CRLF>
+		       <SCORE-OBJECT ,NINJA>)
+		      (ELSE
+		       <TELL
+"Your pistol fires, blasting " A ,PRSI " into his next
+incarnation." CR>)>)
+	       (<OR <P? (KILL ATTACK HIT) (NINJA NINJA-LEADER) SWORDS>
+		    <P? (SWING THROW) SWORDS (NINJA NINJA-LEADER)>>
+		<COND (<VERB? THROW> <MOVE ,SWORDS ,HERE>)>
+		<TELL
+"You strike at a ninja, but there are too many of them to take them on
+one at a time." CR>)
+	       (<OR <VERB? TAKE> <HOSTILE-VERB?>>
+		<TELL
+,YOU-HAVE-TO "use a weapon to have any chance of survival." CR>)>>
+
+<ROUTINE I-CAPTAIN-RETURNS ()
+	 <COND (<NOT <FSET? ,GRAY-CAPTAIN ,DEAD>>
+		<FSET ,GRAY-CAPTAIN ,DEAD>
+		<PUTP ,GRAY-CAPTAIN ,P?OWNER ,NINJA>
+		<COND (<HERE? ,AUDIENCE-CHAMBER ,INNER-CORRIDOR>
+		       <TELL CR
+"The Captain of the Grays charges back into the Audience Chamber,
+attacking with mindless ferocity.  He cuts down one ninja, then the pack
+falls on him and he dies." CR>)
+		      (ELSE
+		       <TELL CR
+"There are sounds of a short fight outside, and then all is quiet." CR>)>)>>
+
+;<GLOBAL CAPTURE-CNT 0>
+;<GLOBAL KNOCKOUT-CNT 0>
+
+;<GLOBAL NINJA-COWED-CNT 0>
+
+<ROUTINE I-NINJA ("AUX" (L <LOC ,NINJA>) C NEAR)
+	 <COND (<QUEUED? I-CAPTAIN-RETURNS>
+		<RFALSE>)
+	       (<SET C <QUEUED? I-NINJA-COWED>>
+		<SET C <GET .C ,C-TICK>>
+		<COND (<IN? ,NINJA ,HERE>
+		       <COND (<G? .C 1>
+			      <ZLINES ,NINJA-COWED-CNT
+				      (<TELL CR
+"The ninja near you seem wary of your pistol, expecting another shot." CR>)
+				      (<TELL CR
+"The ninja seem hesitant to risk another blast." CR>)
+				      (<TELL CR
+"The ninja are beginning to overcome their fear." CR>)>
+			      <RTRUE>)>)
+		      (<NOT <NEXT-ROOM? <LOC ,NINJA>>>
+		       <COND (<G? .C 1>
+			      <SETG KNOCKOUT-CNT 0>
+			      <QUEUE I-NINJA-COWED 1>
+			      <TELL CR
+"You can hear the ninja preparing to resume the attack." CR>
+			      <RTRUE>)>)
+		      (ELSE
+		       <COND (<G? .C 1>
+			      <TELL CR
+"The ninja seem quiet, perhaps they are afraid of your pistol." CR>
+			      <RTRUE>)>)>
+		<RFALSE>)
+	       (<NOT <FSET? ,MARIKO ,RMUNGBIT>>
+		<COND (<EQUAL? .L <META-LOC ,MARIKO>>
+		       <COND (<HERE? .L>
+			      <ZLINES ,CAPTURE-CNT
+				      (<TELL CR
+"The ninja surge toward you, trying to get to Mariko." CR>)
+				      (<COND (<HELD? ,MARIKO>
+					      <MOVE ,MARIKO ,HERE>
+					      <TELL CR
+"You drop Mariko, telling her to run, trying to hold off the ninja." CR>)>
+				       <TELL CR
+"The ninja are trying to move between you and Mariko, cutting you off." CR>)
+				      (<TELL CR
+"A bold ninja grabs for Mariko, who stabs him with a small but effective
+dagger." CR>)
+				      (<DEQUEUE I-NINJA>
+				       <QUEUE I-NINJA-TAKE-MARIKO -1>
+				       <COND (<HERE? BALCONY>
+					      <TELL CR
+"Mariko tries to run for the parapet, but the ninja overpower her." CR>)
+					     (ELSE
+					      <TELL CR
+G"The ninja overpower Mariko"G" and quickly begin forcing her back towards
+the exit." CR>)>)>
+			      <RTRUE>)
+			     (ELSE
+			      <SET NEAR <NEXT-ROOM? .L T>>
+			      <ZLINES ,CAPTURE-CNT
+				      (<COND (.NEAR
+					      <TELL CR
+G"You hear the sounds of a struggle"" between Mariko and the ninja." CR>
+					      <RTRUE>)>)
+				      (<COND (.NEAR
+					      <TELL CR
+"The sounds of "G"struggle continue." CR>
+					      <RTRUE>)>)
+				      (<DEQUEUE I-NINJA>
+				       <QUEUE I-NINJA-TAKE-MARIKO -1>
+				       <COND (.NEAR
+					      <TELL CR
+G"The ninja overpower Mariko"G" and quickly begin forcing her back towards
+the exit." CR>
+					      <RTRUE>)>)>)>)
+		      (<EQUAL? .L <LOC ,BLACKTHORNE>>
+		       <ZLINES ,KNOCKOUT-CNT
+			       (<TELL CR "The ninja surround you." CR>
+				<RTRUE>)
+			       (<TELL CR
+"The ninja are all around you.  First, they try a few quick feints to
+gauge your speed." CR>
+				<RTRUE>)
+			       (<JIGS-UP
+"Satisfying themselves as to your abilities, they close in and moments
+later, you are knocked out by a blow you didn't even see.">
+				<RFATAL>)>)>)>
+	 <SETG CAPTURE-CNT 0> ;"ninja not in room with mariko"
+	 <SETG KNOCKOUT-CNT 0> ;"ninja not in room with blackthorne"
+	 <COND (<IN? ,NINJA ,SECRET-ROOM>
+		<COND (<AND ;<IN? ,BLACKTHORNE ,AUDIENCE-CHAMBER>
+			    <NOT <IN? ,GRAY-CAPTAIN ,AUDIENCE-CHAMBER>>
+			    <OR <IN? ,MARIKO ,AUDIENCE-CHAMBER>
+				<FSET? ,INNER-DOOR ,LOCKED>>>
+		       <FCLEAR ,SECRET-ROOM-DOOR ,INVISIBLE>
+		       <FSET ,SECRET-ROOM-DOOR ,OPENBIT>
+		       <MOVE ,NINJA ,AUDIENCE-CHAMBER>
+		       <THIS-IS-IT ,NINJA>
+		       <COND (<LOC ,NINJA-LEADER>
+			      <MOVE ,NINJA-LEADER ,AUDIENCE-CHAMBER>
+			      <THIS-IS-IT ,NINJA-LEADER>)>
+		       <COND (<HERE? ,AUDIENCE-CHAMBER>
+			      <TELL CR
+"Suddenly, a secret door on the south side of the room bursts open, and
+a black-clad figure charges through the door, directly at you!  Behind
+him the rest of his men are crowding into the opening." CR>)
+			     (<AND <HERE? ,INNER-CORRIDOR>
+				   <FSET? ,INNER-DOOR ,LOCKED>>
+			      <TELL CR
+"You hear noises outside the door, quiet and stealthy, but definitely
+there." CR>)
+			     (ELSE
+			      <TELL CR
+"There is a sudden commotion in the audience chamber." CR>)>)>)
+	       (<IN? ,NINJA ,AUDIENCE-CHAMBER>
+		<COND (<FSET? ,INNER-DOOR ,OPENBIT>
+		       <SETG NINJA-ATTACKING-CUL-DE-SAC? T>
+		       <MOVE ,NINJA ,INNER-CORRIDOR>
+		       <COND (<LOC ,NINJA-LEADER>
+			      <MOVE ,NINJA-LEADER ,INNER-CORRIDOR>)>
+		       <COND (<HERE? ,AUDIENCE-CHAMBER ,INNER-CORRIDOR
+				     ,OUTER-CORRIDOR>
+			      <TELL CR
+"The ninja crowd through the door into the inner corridor." CR>)
+			     (ELSE
+			      <TELL CR
+G"The sounds of ""the fighting are getting closer." CR>)>)
+		      (<NOT <QUEUED? I-NINJA-VS-INNER-DOOR>>
+		       <SETG NINJA-ATTACKING-CUL-DE-SAC? T>
+		       <FCLEAR ,OUTER-DOOR ,OPENBIT>
+		       <FSET ,OUTER-DOOR ,LOCKED>
+		       <QUEUE I-NINJA-VS-INNER-DOOR -1>
+		       <COND (<HERE? ,INNER-CORRIDOR ,AUDIENCE-CHAMBER>
+			      <TELL CR
+"The ninja circle the door, then begin tearing at it with crowbars.  Others
+secure the doors to the audience chamber, cutting off this entire
+section of the keep." CR>)
+			     (ELSE
+			      <TELL CR
+"You can hear the sound of the ninja tearing at the inner door." CR>)>)>)
+	       (<IN? ,NINJA ,INNER-CORRIDOR>
+		<FSET ,SOUTH-SHOJI ,OPENBIT>
+		<FSET ,SOUTH-SHOJI ,RMUNGBIT>
+		<MOVE ,NINJA ,OUTER-ROOM>
+		<COND (<LOC ,NINJA-LEADER>
+		       <MOVE ,NINJA-LEADER ,OUTER-ROOM>)>
+		<COND (<HERE? ,OUTER-ROOM ,INNER-CORRIDOR>
+		       <TELL CR
+"The ninja surge through the flimsy shojis into the outer reception
+room." CR>)
+		      (ELSE
+		       <TELL CR
+"You can hear shojis bursting to shards; the ninja are probably in
+the reception room!" CR>)>)
+	       (<IN? ,NINJA ,OUTER-ROOM>
+		<FSET ,NORTH-SHOJI ,OPENBIT>
+		<FSET ,NORTH-SHOJI ,RMUNGBIT>
+		<MOVE ,NINJA ,PRIVATE-QUARTERS>
+		<COND (<LOC ,NINJA-LEADER>
+		       <MOVE ,NINJA-LEADER ,PRIVATE-QUARTERS>)>
+		<COND (<HERE? ,PRIVATE-QUARTERS ,PRIVATE-QUARTERS-2
+			      ,BLACKTHORNE-QUARTERS>
+		       <TELL CR
+"The ninja storm into the private apartments, scenting their quarry." CR>)
+		      (ELSE
+		       <TELL CR
+"You can hear the ninja ransacking the private apartments." CR>)>)
+	       (<IN? ,NINJA ,PRIVATE-QUARTERS>
+		<COND (<FSET? ,SECRET-REDOUBT-DOOR ,OPENBIT>
+		       <MOVE ,NINJA ,SECRET-REDOUBT>
+		       <COND (<LOC ,NINJA-LEADER>
+			      <MOVE ,NINJA-LEADER ,SECRET-REDOUBT>)>
+		       <COND (<HERE? ,PRIVATE-QUARTERS ,SECRET-REDOUBT
+				     ,PRIVATE-QUARTERS-2 ,BLACKTHORNE-QUARTERS>
+			      <TELL CR
+"The ninja storm through the door into the bolt hole." CR>)
+			     (ELSE
+			      <TELL CR
+"The sound quiets; the ninja must be behind more formidable walls now." CR>)>)
+		      (<NOT <QUEUED? I-NINJA-VS-SECRET-DOOR>>
+		       <SETG DOOR-CNT 0>
+		       <QUEUE I-NINJA-VS-SECRET-DOOR -1>
+		       <COND (<HERE? ,SECRET-REDOUBT ,PRIVATE-QUARTERS>
+			      <TELL CR
+"The ninja gather outside the door, scraping at the hinges and
+the floor." CR>)
+			     (ELSE
+			      <TELL CR
+"You hear the sounds of scraping and pounding." CR>)>)>)
+	       (<IN? ,NINJA ,SECRET-REDOUBT>
+		<COND (<FSET? ,MARIKO ,RMUNGBIT> <RFALSE>)
+		      (<FSET? ,BALCONY-DOOR ,OPENBIT>
+		       <MOVE ,NINJA ,BALCONY>
+		       <COND (<LOC ,NINJA-LEADER>
+			      <MOVE ,NINJA-LEADER ,BALCONY>)>
+		       <COND (<HERE? ,BALCONY ,SECRET-REDOUBT>
+			      <TELL CR
+"The ninja crowd out onto the balcony." CR>)>)
+		      (ELSE
+		       <COND (<HERE? ,BALCONY ,SECRET-REDOUBT>
+			      <FSET ,BALCONY-DOOR ,OPENBIT>
+			      <TELL CR
+"The ninja begin to attack the door, and almost immediately smash it open." CR>)>)>)>>
+
+<ROUTINE SETUP-FOLLOW-NINJA ()
+	 <COND (<AND <QUEUED? I-NINJA-TAKE-MARIKO>
+		     <NOT <EQUAL? ,FOLLOW-FLAG ,NINJA>>>
+		<SETG FOLLOW-FLAG ,NINJA>
+		<DEQUEUE I-NINJA-TAKE-MARIKO>
+		<QUEUE I-FOLLOW-NINJA -1>
+		<QUEUE I-NINJA-TAKE-MARIKO -1>)>>
+
+<ROUTINE I-FOLLOW-NINJA ("AUX" (L <LOC ,NINJA>))
+	 <COND (,FOLLOW-FLAG
+		<COND (<HERE? .L>
+		       <TELL CR
+"You've caught up with the ninja!" CR>)
+		      (<NEXT-ROOM? .L>
+		       <CRLF>
+		       <TELL
+"You are managing to keep up with the retreating ninja.">
+		       <TELL CR CR>
+		       <GOTO .L>
+		       <RTRUE>)
+		      (ELSE
+		       <SETG FOLLOW-FLAG <>>
+		       <DEQUEUE I-FOLLOW-NINJA>
+		       <TELL
+"You've lost the ninja!  They're too far ahead of you, and you can't
+be sure where they've headed." CR>)>)
+	       (ELSE
+		<DEQUEUE I-FOLLOW-NINJA>
+		<RFALSE>)>>
+
+<ROUTINE I-MARIKO-STRUGGLES ()
+	 <COND (<HELD? ,MARIKO>
+		<TELL CR
+"Mariko tries to break free of your hold." CR>)
+	       (<FSET? ,MARIKO ,DEAD>
+		<DEQUEUE I-MARIKO-STRUGGLES>
+		<RFALSE>)
+	       (ELSE
+		<COND (<AND <IN? ,MARIKO ,BALCONY>
+			    <NOT <HELD? ,MARIKO>>
+			    <FSET? ,BALCONY-DOOR ,OPENBIT>>
+		       <MOVE ,MARIKO ,SECRET-REDOUBT>
+		       <COND (<HERE? ,BALCONY ,SECRET-REDOUBT>
+			      <TELL CR
+"Mariko flees back into the redoubt." CR>)>)
+		      (<IN? ,MARIKO ,HERE>
+		       <TELL CR
+"Mariko scurries away from you." CR>)>)>>
+
+<ROUTINE I-NINJA-TAKE-MARIKO ("AUX" (L <LOC ,NINJA>) D)
+	 <COND (<IN? ,MARIKO .L>
+		<COND (<QUEUED? I-NINJA-COWED>
+		       <DEQUEUE I-NINJA-TAKE-MARIKO>
+		       <SETG CAPTURE-CNT 0>
+		       <QUEUE I-NINJA -1>
+		       <SETG FOLLOW-FLAG <>>
+		       <COND (<IN? ,MARIKO ,HERE>
+			      <TELL CR
+"Mariko takes advantage of the ninja's confusion to bite at her
+captor's hand, breaking free and shoving her way to your side." CR>
+			      <RTRUE>)
+			     (ELSE
+			      <TELL CR
+"You hear shouts of frustration from the ninja." CR>
+			      <RTRUE>)>)>
+		<COND (<IN? ,NINJA ,SECRET-ROOM>
+		       <REMOVE ,NINJA-LEADER>
+		       <REMOVE ,NINJA>
+		       <REMOVE ,MARIKO>
+		       <SETG FOLLOW-FLAG <>>
+		       <SETG CAPTURE-CNT 0>
+		       <DEQUEUE I-NINJA-COWED>
+		       <DEQUEUE I-NINJA-TAKE-MARIKO>
+		       <COND (<HERE? ,SECRET-ROOM ,AUDIENCE-CHAMBER
+				     ,INNER-CORRIDOR>
+			      <TELL CR
+"You hear a shout of triumph from the ninja as they carry Mariko
+away.  You realize that this was their goal, and that one way or another,
+Ishido was behind it." CR>)
+			     (ELSE
+			      <TELL CR
+"You realize that by now the ninja have escaped with Mariko.  You have
+no doubt that Ishido was behind it." CR>)>
+		       <FAILED-SCENE>
+		       <RFATAL>)>
+		<SET D
+		     <COND (<IN? ,NINJA ,AUDIENCE-CHAMBER>
+			    ,SECRET-ROOM)
+			   (<IN? ,NINJA ,INNER-CORRIDOR>
+			    ,AUDIENCE-CHAMBER)
+			   (<IN? ,NINJA ,OUTER-ROOM>
+			    ,INNER-CORRIDOR)
+			   (<IN? ,NINJA ,PRIVATE-QUARTERS>
+			    ,OUTER-ROOM)
+			   (<OR <IN? ,NINJA ,PRIVATE-QUARTERS-2>
+				<IN? ,NINJA ,BLACKTHORNE-QUARTERS>
+				<IN? ,NINJA ,SECRET-REDOUBT>>
+			    ,PRIVATE-QUARTERS)
+			   (<IN? ,NINJA ,BALCONY>
+			    ,SECRET-REDOUBT)>>
+		<MOVE ,NINJA .D>
+		<COND (<LOC ,NINJA-LEADER>
+		       <MOVE ,NINJA-LEADER .D>)>
+		<MOVE ,MARIKO .D>
+		<COND (<AND <IN? ,CALTROPS ,NINJA>
+			    <PROB 50>>
+		       <MOVE ,CALTROPS .L>
+		       <COND (<HERE? .L>
+			      <TELL CR
+"The ninja scatter handfuls of tiny, spiked metal balls on the floor." CR>)>)
+		      (<AND <IN? ,SMOKE-BOMB ,NINJA>
+			    <PROB 50>>
+		       <MOVE ,SMOKE-BOMB .L>
+		       <QUEUE I-REMOVE-SMOKE 2>
+		       <COND (<HERE? .L>
+			      <TELL CR
+"One of the ninja throws a smoke bomb which fills the room with choking,
+acrid smoke." CR>)>)
+		      (<AND <IN? ,FIRE-BOMB ,NINJA>
+			    <PROB 50>>
+		       <MOVE ,FIRE-BOMB .L>
+		       <QUEUE I-REMOVE-FIRE 2>
+		       <COND (<HERE? .L>
+			      <TELL CR
+"A ninja tosses a fire bomb which spreads sticky burning pitch on the
+floor." CR>)>)>
+		<COND (<HERE? .D .L>
+		       <TELL CR
+"The ninja retreat, " <PICK-ONE ,MARIKO-STRUGGLES>>
+		       <COND (<AND <EQUAL? ,FOLLOW-FLAG ,NINJA>
+				   <HERE? .L>>
+			      <TELL " You follow, fighting your way
+through the chaos, trying to catch up." CR CR>
+			      <GOTO .D>)
+			     (ELSE <CRLF>)>
+		       <RTRUE>)>)>>
+
+<OBJECT CALTROPS
+	(LOC NINJA)
+	(DESC "caltrops")
+	(SYNONYM CALTROPS CALTROP BALLS BALL)
+	(ADJECTIVE TINY SPIKED METAL)
+	(FLAGS TAKEBIT PLURAL)
+	(ACTION CALTROPS-F)>
+
+<GLOBAL AVOID-CALTROPS? <>>
+
+<ROUTINE CALTROPS-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"These are tiny spiked metal balls that remind you of the caltrops used in
+Europe to stop cavalry attacks.  They are festooned with needle-like
+spines." CR>)
+	       (<VERB? TAKE>
+		<COND (<JIGS-UP? ,J-CALTROPS
+"At the last second, you remember that ninja are famous for using poison.">
+		       <JIGS-UP
+"Unlike caltrops in Europe, these are poisoned!  Almost immediately you feel
+a searing pain in your hand.  Within moments you are writhing on the floor.">)
+		      (ELSE <RTRUE>)>)
+	       (<VERB? AVOID>
+		<SETG AVOID-CALTROPS? T>
+		<TELL
+"You do your best to avoid stepping on the caltrops." CR>)>>
+
+<OBJECT SMOKE-BOMB
+	(LOC NINJA)
+	(DESC "smoke")
+	(SYNONYM BOMB SMOKE)
+	(ADJECTIVE SMOKE)
+	(FLAGS NDESCBIT)
+	(ACTION SMOKE-BOMB-F)>
+
+<ROUTINE SMOKE-BOMB-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The smoke chokes your lungs and blocks your view just enough to make the
+area a confusing, incomprehensible hell." CR>)>>
+
+<ROUTINE I-REMOVE-SMOKE ("AUX" (L <LOC ,SMOKE-BOMB>))
+	 <REMOVE ,SMOKE-BOMB>
+	 <COND (<HERE? .L>
+		<TELL CR
+"The smoke has dissipated enough that you can breathe and see better
+now." CR>)>>
+
+<OBJECT FIRE-BOMB
+	(LOC NINJA)
+	(DESC "fire bomb")
+	(SYNONYM BOMB FIRE)
+	(ADJECTIVE FIRE)
+	(FLAGS NDESCBIT)
+	(ACTION FIRE-BOMB-F)>
+
+<ROUTINE FIRE-BOMB-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The fire bomb has broadcast burning pitch all over the floor.  It looks
+like it would be dangerous to move." CR>)>>
+
+<ROUTINE I-REMOVE-FIRE ("AUX" (L <LOC ,FIRE-BOMB>))
+	 <REMOVE ,FIRE-BOMB>
+	 <COND (<HERE? .L>
+		<TELL CR
+"The fire from the bomb has died down somewhat now." CR>)>>
+
+<CONSTANT MARIKO-STRUGGLES
+	  <LTABLE 0
+		  "dragging a struggling Mariko with them."
+		  "pulling Mariko along."
+		  "several manhandling Mariko into step with them."
+		  "Mariko being pushed along ahead of them.">>
+
+<GLOBAL NINJA-ATTACKING-CUL-DE-SAC? <>>
+
+<ROUTINE I-NINJA-COWED ("AUX" (CNT <GETP ,NINJA ,P?COUNT>)) 
+	 <COND (<LOC ,NINJA>
+	 <SETG NINJA-COWED-CNT 0>
+	 <COND (<G? .CNT 2>
+		<SET CNT <- .CNT 2>>
+		<PUTP ,NINJA ,P?COUNT .CNT>
+		<COND (<IN? ,NINJA ,HERE>
+		       <TELL CR
+"The ninja resume their attack." CR>)
+		      (ELSE
+		       <TELL CR
+G"The sounds of ""fighting redouble in intensity." CR>)>)
+	       (ELSE 
+		<COND (<IN? ,NINJA ,HERE>
+		       <TELL CR
+"The ninja have realized how long it takes to reload the pistol, and
+fearlessly resume their attack." CR>)
+		      (ELSE
+		       <TELL CR
+G"The sounds of ""fighting resume their former intensity." CR>)>)>)>>
+
+;<GLOBAL DOOR-CNT 0>
+
+<ROUTINE I-NINJA-VS-INNER-DOOR ()
+	 <COND (<FSET? ,INNER-DOOR ,OPENBIT>
+		<DEQUEUE I-NINJA-VS-INNER-DOOR>
+		<RFALSE>)
+	       (<QUEUED? I-NINJA-COWED>
+		<COND (<HERE? ,INNER-CORRIDOR ,OUTER-ROOM>
+		       <TELL CR
+"There are only muffled sounds outside the door as the ninja regroup." CR>
+		       <RTRUE>)
+		      (ELSE
+		       <RFALSE>)>)
+	       (<FSET? ,IRON-BAR ,OPENBIT>
+		<FSET ,INNER-DOOR ,OPENBIT>
+		<DEQUEUE I-NINJA-VS-INNER-DOOR>
+		<COND (<HERE? ,INNER-CORRIDOR>
+		       <TELL CR
+"The inner door jerks inward as the ninja smash against it, and they realize
+that it isn't barred.  They throw the door open!" CR>
+		       <RTRUE>)
+		      (<HERE? ,OUTER-ROOM>
+		       <TELL CR
+"From the corridor comes the thud of the ninja crashing against the
+unbarred inner door, and then the sound of the door being opened." CR>
+		       <RTRUE>)>)
+	       (<HERE? ,OUTER-ROOM>
+		<TELL CR
+"You can hear the ninja furiously attacking the inner door." CR>)>
+	 <ZLINES ,DOOR-CNT
+		 (<COND (<HERE? ,INNER-CORRIDOR>
+			 <TELL CR
+"The door rocks under the furious blows of the assault jimmies." CR>)>)
+		 (<COND (<HERE? ,INNER-CORRIDOR>
+			 <TELL CR
+"The wood of the door begins to splinter." CR>)>)
+		 (<COND (<HERE? ,INNER-CORRIDOR>
+			 <TELL CR
+"The men with the crowbars rip at the door, which shrieks under the
+blows." CR>)>)
+		 (<MOVE ,DOOR-CRACK ,INNER-CORRIDOR>
+		  <COND (<HERE? ,INNER-CORRIDOR>
+			 <TELL CR
+"One of the door panels cracks, then a hinge snaps and the tip of a
+jimmy comes through to widen the crack." CR>)>)
+		 (<COND (<HERE? ,INNER-CORRIDOR>
+			 <TELL CR
+"The whole door shakes as ninja tear at it with shoulders and raging
+fists and feet and weapons.  The door bellows and shudders and one of
+the bolts springs away and clatters to the floor." CR>)>)
+		 (<COND (<HERE? ,INNER-CORRIDOR>
+			 <TELL CR
+"The door is near collapsing." CR>)>)
+		 (<COND (<HERE? ,INNER-CORRIDOR>
+			 <TELL CR
+"The entire door teeters as another bolt flies off." CR>)>)
+		 (<DEQUEUE I-NINJA-VS-INNER-DOOR>
+		  <REMOVE ,DOOR-CRACK>
+		  <FSET ,INNER-DOOR ,OPENBIT>
+		  <FSET ,INNER-DOOR ,RMUNGBIT>
+		  <COND (<HERE? ,INNER-CORRIDOR>
+			 <TELL CR
+"The door shatters, opening the way for the ninja!" CR>)
+			(<HERE? ,OUTER-ROOM>
+			 <TELL CR
+"Suddenly, you hear the door crash to the floor, and the ninjas
+are through!" CR>)>)>>
+
+<OBJECT DOOR-CRACK
+	(DESC "crack")
+	(SYNONYM CRACK)
+	(FLAGS NDESCBIT)
+	(ACTION DOOR-CRACK-F)>
+
+<ROUTINE DOOR-CRACK-F ()
+	 <COND (<VERB? EXAMINE LOOK-INSIDE>
+		<TELL
+"The crack is large enough to fire a pistol through." CR>)
+	       (<P? SHOOT * DOOR-CRACK>
+		<PERFORM ,V?SHOOT ,PRSO ,NINJA>
+		<RTRUE>)>>
+
+<ROUTINE I-NINJA-VS-SECRET-DOOR ("AUX" CNT NUM)
+	 <COND (<AND <FSET? ,SECRET-REDOUBT-DOOR ,OPENBIT>
+		     <NOT <FSET? ,SECRET-REDOUBT-DOOR ,RMUNGBIT>>>
+		<DEQUEUE I-NINJA-VS-SECRET-DOOR>
+		<RFALSE>)
+	       (<NOT <ZERO? <SET CNT <GETP ,BOLTS ,P?COUNT>>>>
+		<COND (<EQUAL? .CNT 1 2 4> <SET NUM 1>)
+		      (<EQUAL? .CNT 2 5 6> <SET NUM 2>)
+		      (ELSE <SET NUM 3>)> 
+		<COND (<OR <EQUAL? .NUM 3>
+			   <PROB <* .NUM 33>>>
+		       <FCLEAR ,SECRET-REDOUBT-DOOR ,LOCKED>
+		       <FSET ,SECRET-REDOUBT-DOOR ,OPENBIT>)>
+		<COND (<HERE? ,SECRET-REDOUBT>
+		       <COND (<FSET? ,SECRET-REDOUBT-DOOR ,OPENBIT>
+			      <TELL CR
+"The ninja smash against the ">
+			      <COND (<EQUAL? .NUM 3>
+				     <TELL
+"unsecured door, and it bursts open!" CR>
+				     <RTRUE>)
+				    (ELSE
+				     <TELL
+"partly secured door, the ">
+				     <COND (<EQUAL? .NUM 2>
+					    <TELL "bolt tears">)
+					   (ELSE
+					    <TELL "bolts tear">)>
+				     <TELL
+" free, and the door bursts open!" CR>
+				     <RTRUE>)>)
+			     (ELSE
+			      <TELL CR
+"The door jolts inward as the open bolts wiggle uselessly." CR>
+			      <RTRUE>)>)
+		      (<HERE? ,BALCONY>
+		       <TELL CR
+"You can hear the ninja hitting the door in the redoubt." CR>)
+		      (ELSE <RFALSE>)>)>
+	 <ZLINES ,DOOR-CNT
+		 (<COND (<HERE? ,SECRET-REDOUBT>
+			 <TELL CR
+"There is a sudden hammering and a harsh muffled voice from outside.  Mariko
+licks her dry lips.  \"He said to open the door and surrender
+or he'd -- he'd blow it up.\"" CR>)>)
+		 (<COND (<HERE? ,SECRET-REDOUBT>
+			 <TELL CR
+"The muffled voice becomes angrier and more demanding">
+			 <COND (<IN? ,ETSU ,HERE>
+				<TELL ", all eyes in the room look at you">)>
+			 <TELL ".  Mariko translates, \"He said, if we open the
+door and surrender, everyone will go free except for you.  He said
+they want you as a hostage, Anjin-san.\"" CR>)>)
+		 (<COND (<HERE? ,SECRET-REDOUBT>
+			 <TELL CR
+"A ferocious pounding on the door, iron clanging on iron, then
+the voice begins, a short violent crescendo.  All sound outside ceases.  \"Get
+away from the door,\" Mariko shouts, \"He's going to explode
+the door!\"" CR>)>)
+		 (4
+		  <MOVE ,NINJA ,SECRET-REDOUBT>
+		  <COND (<LOC ,NINJA-LEADER>
+			 <MOVE ,NINJA-LEADER ,SECRET-REDOUBT>)>
+		  <MOVE ,SECRET-REDOUBT-DOOR ,SECRET-REDOUBT>
+		  <FSET ,SECRET-REDOUBT-DOOR ,OPENBIT>
+		  <FSET ,SECRET-REDOUBT-DOOR ,RMUNGBIT>
+		  <COND (<IN? ,MARIKO ,SECRET-REDOUBT>
+			 <FSET ,MARIKO ,RMUNGBIT>
+			 <FSET ,MARIKO ,SCOREBIT>
+			 <MOVE ,ROSARY ,MARIKO>)>
+		  <COND (<HERE? ,SECRET-REDOUBT>
+			 <DEQUEUE I-LOAD-PISTOL>
+			 <COND (<HELD? ,MARIKO>
+				<TELL CR
+"Mariko pounds you on the shoulders.  \"Let me go, Anjin-san!  Let me...\"">
+				<TELL G"The explosion
+blows you aside as the door wrenches loose from its hinges and blasts
+into the room"><TELL ", killing you instantly." CR>
+				<JIGS-UP>
+				<RFATAL>)
+			       (ELSE
+				<FSET ,BLACKTHORNE ,RMUNGBIT> ;"out of it"
+				<B-LIE-DOWN>
+				<COND (<IN? ,PISTOL ,BLACKTHORNE>
+				       <MOVE ,PISTOL ,HERE>
+				       <FSET ,PISTOL ,NDESCBIT>)>
+				<MARGINAL-PIC ,P-EXPLOSION <>
+					      ,P-EXPLOSION-CORNER>
+				<TELL CR
+"Mariko presses back against the iron and calls out firmly, \"I, Toda
+Mariko, protest this shameful attack and by my death --\"">
+				<TELL G" The explosion
+blows you aside as the door wrenches loose from its hinges and blasts
+into the room">
+<TELL " and shrieks off a far wall.  The detonation knocks you off
+your feet.  Smoke gushes into the room, the ninja
+following instantly.  The door comes to rest in a corner." CR>)>)
+			(<HERE? ,BALCONY>
+			 <TELL CR
+"There is a tremendous explosion in the redoubt, and smoke and debris
+pour out onto the balcony." CR>)>)
+		 (<COND (<AND <HERE? ,SECRET-REDOUBT>
+			      <FSET? ,MARIKO ,RMUNGBIT>>
+			 <TELL CR
+"A ninja goes to his knees beside Mariko, seeing at once that
+she is broken and dying fast." CR>)>)
+		 (<COND (<FSET? ,MARIKO ,RMUNGBIT>
+			 <FSET ,MARIKO ,DEAD>)>
+		  <COND (<IN? ,NINJA <LOC ,ACHIKO>>
+			 <FSET ,ACHIKO ,DEAD>
+			 <COND (<HERE? <LOC ,ACHIKO>>
+				<TELL CR
+"The ninja recognizes Achiko, draws his knife, and as she
+charges him, knifes her in the left breast." CR>)
+			       (ELSE
+				<TELL CR
+"You hear a woman's scream, then all is silent." CR>)>)>)
+		 (<COND (<FSET? ,MARIKO ,RMUNGBIT>
+			 <REMOVE ,NINJA>
+			 <FSET ,NINJA ,INVISIBLE>
+			 <REMOVE ,NINJA-LEADER>
+			 <DEQUEUE I-NINJA-COWED>
+			 <COND (<HERE? ,SECRET-REDOUBT>
+				<TELL CR
+"The ninja leader signals the retreat, and the ninja melt
+away into the night." CR>)>)>)
+		 (<COND (<FSET? ,MARIKO ,RMUNGBIT>
+			 <MOVE ,YABU ,SECRET-REDOUBT>
+			 <COND (<HERE? ,SECRET-REDOUBT>
+				<TELL CR
+"Yabu comes into the room, his face ashen.  He looks over, sees you
+are still alive, and much of the anxiety leaves him.  He looks at
+Mariko, rasps an order, then rips off his kimono and covers her to
+the neck." CR>)>)>)
+		 (<COND (<FSET? ,MARIKO ,RMUNGBIT>
+			 <COND (<HERE? ,SECRET-REDOUBT>
+				<TELL CR
+"Your eyes clear for a moment and you see Yabu, his image twisting
+drunkenly, then you see Mariko.  You can't tell if she is alive or
+dead." CR>)>)>)
+		 (DELAY
+		  <COND (<NOT <FSET? ,MARIKO ,RMUNGBIT>>
+			 <RFALSE>)
+			(<G? ,DELAY-CNT 4>)
+			(<AND <FSET? ,MARIKO ,RMUNGBIT>
+			      <FSET? ,MARIKO ,SCOREBIT>>
+			 <RFALSE>)>)
+		 (<DEQUEUE I-NINJA-VS-SECRET-DOOR>
+		  <TELL CR
+"Your head seems to burst with red and purple light and you
+collapse.  Kind hands catch you and help you to the floor." CR>
+		  <NEXT-SCENE>)>>
+
+<ROUTINE ETSU-AFTER-F ()
+	 <TELL
+"On the balcony, Lady Etsu stands, supported by her maid.  \"I, Maeda
+Etsu,\" she says, her voice frail, \"attest that Toda Mariko-sama
+cast away her life to save herself from dishonorable capture, and that
+but for the barbarian samurai's bravery Lady Toda would have been
+captured and dishonored.  I accuse Lord General Ishido of mounting this
+dishonorable attack.  I ask you all to bear witness that I can no longer
+live with this shame.\"|
+|
+She mounts painfully to the battlement.  Everyone bows to her.|
+|
+\"I have told the truth.  I attest to it by my death,\" she says.  Then
+she closes her eyes thankfully and lets herself fall forward to welcome
+death.">>
+
+<OBJECT ROSARY
+	(DESC "rosary")
+	(SYNONYM ROSARY CROSS)
+	(ADJECTIVE GOLD TINY GOLDEN)
+	(FLAGS TAKEBIT WEARBIT)
+	(ACTION ROSARY-F)>
+
+<ROUTINE ROSARY-F ()
+	 <COND (<VERB? TAKE>
+		<TELL
+"You lift it gently from her chest.  How, you wonder, could she be at
+once samurai and Christian?  How could she choose her own death to
+aid her liege Lord, and at the same time pray to the Christian God
+who abhors suicide?  "I"Karma, neh?""  You did not need to understand
+her, only to love her.  You replace the rosary." CR>)>>
+
+<END-SEGMENT>
+
+<BEGIN-SEGMENT YOKOHAMA>
+
+<CONSTANT J-GRAB-PISTOL 180>
+
+<ROOM YOKOHAMA
+      (LOC ROOMS)
+      (SCENE S-YOKOHAMA)
+      (DESC "Yokohama")
+      (FDESC
+"You recuperate for a few days, and then, to your surprise, your guards are
+gone.  You are taken down to the dock, where you are met by the Captain-General
+of the Black Ship, Ferriera, and Dell'Aqua, the Father-Visitor of the Jesuits.|
+|
+Dell'Aqua says, \"Pilot, I'm taking you to your galley.  Are you all right?\"|
+|
+\"You're really letting me go?  Why?\"|
+|
+\"Because the Lady Mariko asked us to protect you.\"|
+|
+\"But that's no reason!  You wouldn't do that just because she asked you.\"|
+|
+\"I agree,\" Ferriera says.  \"Eminence, why not tell him the whole truth?\"|
+|
+\"It doesn't make sense.  You know I'm going to destroy you.  I'll take your
+Black Ship.\"|
+|
+Ferriera laughs scornfully.  \"With what, Ingeles?  You have no ship!\"")
+      (FLAGS OUTSIDE ONBIT SCOREBIT)
+      (SCORE 1)
+      (GLOBAL LG-ERASMUS LG-SEA)
+      (ACTION YOKOHAMA-F)>
+
+<ROUTINE YOKOHAMA-F ("OPT" (RARG <>))
+	 <COND (<RARG? SCENE-SETUP>
+		<DRESS-BLACKTHORNE>
+		<MOVE ,VINCK ,HERE>
+		<FSET ,VINCK ,OPENBIT>
+		<FSET ,VINCK ,SEARCHBIT>
+		<FSET ,VINCK ,CONTBIT>
+		<FCLEAR ,VINCK ,NDESCBIT>
+		<FCLEAR ,PISTOL ,NDESCBIT>
+		<QUEUE I-VINCK-NUTS -1>)
+	       (<RARG? LOOK>
+		<TELL
+"This is the harbor at Yokohama, the best harbor you have ever seen, a
+beautiful protected anchorage.  The burned hulk of the "I"Erasmus"" lies in the
+shallows just off the beach.  All around you are the grisly remains of the
+heads of the guards who failed in their duty when the "I"Erasmus"" burned, more
+than a hundred.  Seabirds ravage and quarrel over the feast." CR>)
+	       (<RARG? BEG>
+		<COND (<P? EXAMINE LG-ERASMUS>
+		       <MARGINAL-PIC ,P-BURNED-ERASMUS>
+		       <TELL
+"You study the hulk of the ship.  Naga has told you it happened at night,
+during an earthquake and "I"tai-fun"".  It had still been burning, there
+in the shallows, on the next day.  Now only the black gutted ribs rise out
+of the sea." CR>)
+		      (<P? (BOARD WALK-TO) LG-ERASMUS>
+		       <TELL
+"She's aground in twenty feet of water, and you have no boat." CR>)
+		      (<P? TAKE PISTOL>
+		       <COND (<FSET? ,VINCK ,DEAD>
+			      <RFALSE>)
+			     (ELSE
+			      <PERFORM ,V?ATTACK ,VINCK>
+			      <RTRUE>)>)
+		      (<AND <P? BOW VINCK>
+			    <NOT <FSET? ,VINCK ,DEAD>>>
+		       <TELL
+"\"You've become a sod-eating Jappo, Pilot!  Look at you!  You're damned
+to hell like all these heathens!\"" CR>)
+		      (<AND <NOT <FSET? ,VINCK ,DEAD>>
+			    <HOSTILE-VERB?>
+			    <PRSO? VINCK>>
+		       <COND (<IN? ,PISTOL ,VINCK>
+			      <COND (<JIGS-UP? ,J-GRAB-PISTOL
+"You take another look at Vinck's mad eyes, and think better of it.">
+				     <TELL
+"You grab for Vinck's pistol, hoping that his madness will give you time
+to get it before he fires, but you're wrong, he's fast, too fast!  The
+pistol fires, and you realize that you were ready for death, prepared, and
+that it doesn't matter.  You've lost Mariko, and lost the "I"Erasmus"", and it's
+only "I"karma"", nothing to worry about." CR>
+				     <JIGS-UP>)
+				    (ELSE <RTRUE>)>)
+			     (ELSE
+			      <TELL
+"You can hardly tell whether it's rage or a desire to snap him out of his
+fit, but either way, it doesn't work." CR>)>)
+		      (<AND <P? (MOVE BURY HELP TAKE) VINCK>
+			    <FSET? ,VINCK ,DEAD>>
+		       <MOVE ,VINCK ,WINNER>
+		       <SCORE-OBJECT ,YOKOHAMA>
+		       <MARGINAL-PIC ,P-VINCK <>>
+		       <TELL
+"You close his eyes and pick him up and sling him over your shoulder and
+walk back.  Samurai run toward you, Naga and Yabu at their head.|
+|
+\"What happened, Anjin-san?\"|
+|
+\"He went mad.\"" CR>
+		       <NEXT-SCENE>)>)>>
+
+<OBJECT HEADS
+	(LOC YOKOHAMA)
+	(DESC "severed heads")
+	(SYNONYM HEADS HEAD POLE POLES REMAINS)
+	(ADJECTIVE SEVERED GRISLY DEAD)
+	(FLAGS NDESCBIT)
+	(ACTION HEADS-F)>
+
+<ROUTINE HEADS-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"They have been here on the beach for several days.  They are no better
+for the experience." CR>)
+	       (<OR <VERB? TAKE>
+		    <HOSTILE-VERB?>>
+		<TELL
+"You want to lash out, to destroy whoever burned the "I"Erasmus"", but
+these men are beyond all revenge.  You want to just take them away and
+bury them.  "I"Shigata ga nai, neh?" CR>)>>
+
+<ROUTINE I-VINCK-NUTS ()
+	 <ZLINES ,VINCK-CNT
+		 (<TELL CR
+"\"You should never have left her to them, Pilot!  What are we going to do
+now?  How are we going to get home?  You should have left her at Yedo safe,
+an' us safe, with our eters.\"  The whine in Vinck's voice irritates
+you.  Everything about him irritates you now.  Three times in the last week you
+have almost told your vassals to knife Vinck quietly and throw him overboard
+to put him out of his misery.  But you always curbed your temper and sought
+out Yabu.  Near Yabu, Vinck made no sound, petrified of him, and rightly." CR>)
+		 (<TELL CR
+"\"We're marooned with these piss eaters for the rest of our lives!  Eh?\"" CR CR
+"\"We're to grovel to these God-cursed heathens for the rest of our
+muck-eating lives and how long'll that be when all they talk about's war war
+war?\"" CR>)
+		 (<TELL CR
+"\"It's your fault!  You said to come to the Japans and we come and how many
+died coming here?  You're to blame.\"" CR CR
+"\"How're we going to get home?  That's your God-cursed job, to get us
+home!  How you going to do that?  Eh?\"|
+|
+\"Another of our ships'll get here, Johann.  We've just got to wait,\" you
+reply." CR>)
+		 (<MOVE ,PISTOL ,VINCK>
+		  <PUTP ,PISTOL ,P?OWNER ,VINCK>
+		  <FCLEAR ,PISTOL ,RMUNGBIT>
+		  <TELL CR
+"\"Wait?  Five muck-plagued years?  Twenty?\"  Vinck's mind snaps.  \"They're going
+to chop off our heads and stick them like those there and the birds'll eat
+us ... \"  A paroxysm of insane laughter shakes him and he reaches into his
+shirt for his pistol.  Vinck waves the pistol in your face." CR>)
+		 (<FSET ,VINCK ,DEAD>
+		  <TELL CR
+"Vinck takes to his heels down the beach, the seabirds scudding into the air,
+mewing and cawing out of his path.  Vinck runs for a frantic hundred paces or
+more, then collapses, ending up on his back, his legs still moving, arms
+waving, mouthing obscenities.  After a moment he turns on his belly with a
+last shriek, facing you, and freezes." CR>)
+		 (<CRLF>
+		  <COND (<IN? ,PISTOL ,VINCK>
+			 <TELL "The pistol is leveled at you, Vinck's">)
+			(ELSE
+			 <TELL "His empty fist is pointed at you, his">)>
+		  <FSET ,VINCK ,RMUNGBIT>
+		  <TELL " eyes staring with demented antagonism,
+the lips pulled back from his teeth.  Vinck is dead." CR>)
+		 (DELAY
+		  <COND (<NOT <HELD? ,VINCK>>
+			 <RFALSE>)>)
+		 (<DEQUEUE I-VINCK-NUTS>
+		  <RFALSE>)>> 
+
+<END-SEGMENT>
+
+
+
+"S-AFTERMATH"
+
+<BEGIN-SEGMENT AFTERMATH>
+
+<ROOM STABLE
+      (LOC ROOMS)
+      (SCENE S-AFTERMATH)
+      (SCORE 3)
+      (AFTER NEVER-AFTER-F)
+      (FDESC
+"Toranaga is checking the girths of his saddle.  Deftly he knees the
+horse in the belly, her stomach muscles relax, and he tightens the
+strap another two notches.  Rotten animal, he thinks, despising horses
+for their constant trickeries and treacheries and ill-tempered
+dangerousness.  He waits a moment and knees the horse hard again.  The
+horse grunts and rattles her bridle and he tightens the straps completely.|
+|
+\"Good, Sire!  Very good,\" the Hunt Master says with admiration.  \"Many
+would have been satisfied the first time.\"")
+      (DESC "Stable")
+      (SYNONYM STABLE)
+      (LDESC
+"This is the stable area of the camp at Anjiro.")
+      (FLAGS ONBIT OUTSIDE)
+      (GLOBAL LG-SHIP LG-NINJA CELLAR-DOOR)
+      (ACTION STABLE-F)>
+
+<ROUTINE STABLE-F (RARG)
+	 <COND (<RARG? SCENE-SETUP>
+		<DRESS-BLACKTHORNE>
+		<FCLEAR ,LG-NINJA ,INVISIBLE>
+		<MOVE ,YABU ,HERE>
+		<MOVE ,OMI ,HERE>
+		<MOVE ,HIRO-MATSU ,HERE>
+		<MOVE ,TORANAGA ,HERE>
+		<THIS-IS-IT ,TORANAGA>
+		<QUEUE I-STABLE -1>)
+	       (<RARG? BEG>
+		<COND (<EQUAL? ,AFTERMATH-QUESTION 4>
+		       <COND (<P? TELL-ABOUT TORANAGA SEALED-SCROLL>
+			      <BUILD-ANOTHER-SHIP>)
+			     (<AND <P? MAKE LG-SHIP>
+				   <TRY-QCONTEXT?>>
+			      <RTRUE>)>)
+		      (<EQUAL? ,AFTERMATH-QUESTION 1>
+		       <COND (<P? TELL-ABOUT TORANAGA>
+			      <COND (<PRSI? YABU PLAN>
+				     <SETG WINNER ,TORANAGA>
+				     <PERFORM ,V?NO>
+				     <RTRUE>)
+				    (ELSE
+				     <TELL
+G"Toranaga looks annoyed.  \"Please answer the question, Anjin-san.\"" CR>)>)>)
+		      (<EQUAL? ,AFTERMATH-QUESTION 2>
+		       <COND (<P? TELL-ABOUT TORANAGA>
+			      <COND (<PRSI? LG-NINJA>
+				     <YABU-BETRAYED-YOU>)
+				    (<PRSI? PLAN>
+				     <TELL
+"\"I don't care about that!  What did he do?  I'm not interested in talk,\"
+replies Toranaga." CR>)
+				    (ELSE
+				     <TELL
+G"Toranaga looks annoyed.  \"Please answer the question, Anjin-san.\"" CR>)>)>)>)>>
+
+<ROUTINE I-STABLE ()
+	 <ZLINES ,STABLE-CNT
+		 (<MOVE ,SEALED-SCROLL ,BLACKTHORNE>
+		  <THIS-IS-IT ,SEALED-SCROLL>
+		  <TELL CR
+"\"Listen, Anjin-san, before Mariko-sama
+left Yedo, she gave me this.  Mariko-sama said if you live after Osaka --
+if you live, understand -- she asked me to give this to you.\"  Toranaga hands you a sealed scroll." CR>)
+		 (DELAY
+		  <COND (<FSET? ,SEALED-SCROLL ,SCOREBIT>
+			 <TELL CR
+"\"Please ">
+			 <COND (<FSET? ,SEALED-SCROLL ,OPENBIT>
+				<TELL "read the message">)
+			       (ELSE
+				<TELL "open the scroll">)>
+			 <TELL ", Anjin-san.\"" CR>
+			 <RTRUE>)>)
+		 (<SETG AFTERMATH-QUESTION 4>
+		  <SETG QCONTEXT ,TORANAGA>
+		  <TELL CR
+G"\"What did the message say, Anjin-san?\"" CR>)
+		 (DELAY
+		  <COND (<EQUAL? ,AFTERMATH-QUESTION 4>
+			 <TELL CR
+G"\"What did the message say, Anjin-san?\"" CR>
+			 <RTRUE>)>)
+		 (<TELL CR
+"Toranaga turns to the watchers.  \"So, Hiro-matsu-san, how's the training
+of the musket regiment?\"|
+|
+Hiro-matsu scowls.  \"I still think this is all dishonorable and
+unnecessary.  Soon we'll be able to forget it.  We'll piss all over
+Ishido without this
+sort of treachery.\"" CR>)
+		 (<SETG AFTERMATH-QUESTION 1>
+		  <SETG QCONTEXT ,TORANAGA>
+		  <THIS-IS-IT ,YABU>
+		  <TELL CR
+"Yabu says, \"Please excuse me, but without these guns, we'll lose.  This
+is a modern war, this way we've a chance to win.\"  He looks back at
+Toranaga.  \"I heard in the night that Jikkyu's dead.  My informant reports
+he died two days ago.  He's been sick for some time.  Doesn't this open
+up the southern route?  We could slice into Ishido's underbelly!\"|
+|
+\"What did Jikkyu die of?\" asks Toranaga.|
+|
+\"Sickness, Sire.\"|
+|
+\"A five-hundred-koku sickness?\"|
+|
+Yabu laughs nervously, wondering how Toranaga could have breached his
+security net.  \"Yes, I would assume so.  Cheap, "I"neh""?  Five hundred
+koku for the southern route.\"|
+|
+Hiro-matsu says stiffly to Toranaga, \"Please excuse me but I think
+that's a disgusting story.\"|
+|
+\"Treachery's a weapon of war.  Jikkyu was an enemy and a fool.  Yabu-sama
+has served me well.  Here and at Osaka.  "I"Neh"", Yabu-san?\"|
+|
+\"I always try to serve you loyally, Sire.\"|
+|
+\"Yes, it is true.\"  Toranaga turns to you.  \"Isn't it true, Anjin-san,
+that Yabu served me loyally at Osaka?\"" CR>)
+		 (DELAY
+		  <COND (<EQUAL? ,AFTERMATH-QUESTION 1>
+			 <COND (<G? ,DELAY-CNT 3>
+				<TORANAGA-LOSES-PATIENCE>
+				<RFATAL>)
+			       (ELSE
+				<TELL CR
+"\"Anjin-san, isn't it true that Yabu is my loyal vassal?,\" asks
+Toranaga." CR>
+				<RTRUE>)>)>)
+		 (<SETG AFTERMATH-QUESTION 2>
+		  <THIS-IS-IT ,YABU>
+		  <SETG QCONTEXT ,TORANAGA>
+		  <TELL CR
+"Calmly and genially, Toranaga asks \"What did Yabu do, then, to
+betray me?\"" CR>)
+		 (DELAY
+		  <COND (<EQUAL? ,AFTERMATH-QUESTION 2>
+			 <COND (<G? ,DELAY-CNT 3>
+				<TORANAGA-LOSES-PATIENCE>
+				<RFATAL>)
+			       (ELSE
+				<TELL CR
+"\"What did Yabu do, Anjin-san?\" asks Toranaga." CR>
+				<RTRUE>)>)>)
+		 (<SETG AFTERMATH-QUESTION 3>
+		  <THIS-IS-IT ,YABU>
+		  <SETG QCONTEXT ,TORANAGA>
+		  <TELL CR
+"Toranaga, steel in his voice, but still very quiet, asks \"What did
+he say to the ninja?\"" CR>)
+		 (DELAY
+		  <COND (<EQUAL? ,AFTERMATH-QUESTION 3>
+			 <COND (<G? ,DELAY-CNT 3>
+				<TORANAGA-LOSES-PATIENCE>
+				<RFATAL>)
+			       (ELSE
+				<TELL CR
+"\"What did he say, Anjin-san?\" asks Toranaga." CR>
+				<RTRUE>)>)>)
+		 (<MOVE ,OMI ,GENERIC-OBJECTS>
+		  <MOVE ,YABU ,GENERIC-OBJECTS>
+		  <MOVE ,BUNTARO ,GENERIC-OBJECTS>
+		  <TELL CR
+"\"Thank you, Anjin-san.  You have confirmed what was said by a servant
+who survived the attack.  I wanted the word of a samurai as well.\"|
+|
+\"What am I accused of, Sire?  Helping "I"ninja""?  Ridiculous!  What have
+the fantasies of servants and barbarians to do with me?  They're liars!\"|
+|
+\"Yabu-sama, did you do these things?\" Hiro-matsu asks.|
+|
+\"Of course not!\"|
+|
+Toranaga says, \"But I think you did, so all your lands are forfeit.  Please
+slit your belly today.  Before noon.  What arrangements do you
+want made?\"|
+|
+\"Just some paper and ink and a brush for my will and death poem, and
+two tatamis -- there's no reason to hurt my knees or to kneel in the
+dirt like a stinking peasant.  "I"Neh?""\" Yabu adds with bravado.|
+|
+Buntaro and a party of samurai warily lead Yabu away, looking from
+one to the other with suppressed excitement." CR>)
+		 (<MOVE ,PEDESTAL ,HERE>
+		  <THIS-IS-IT ,YABU-HEAD>
+		  <MOVE ,OMI ,HERE>
+		  <TELL CR
+"Just after noon, Omi returns and unwraps Yabu's head.  \"Lord Kasigi
+Yabu obeyed, Sire, just before noon.\"  Toranaga inspects his enemy
+as he has done ten thousand times before, wondering how his head would
+look after death, viewed by his conqueror, and whether terror would
+show, or agony or anger or horror or all of them or none of them.  Or
+dignity." CR>)
+		 (<TELL CR
+"\"Did he die well?\"|
+|
+\"The best I have ever seen, Sire.\"  He pauses.  \"Do you wish me to bury
+it, or display it?\"|
+|
+\"Put it on a spear, facing the wreck of the Anjin-san's ship.\"|
+|
+\"Yes, Sire.\"|
+|
+\"What was his death poem?\"|
+|
+Omi says,|
+	\"'What are clouds|
+	But an excuse for the sky?|
+	What is life|
+	But an escape from death?'\"|
+|
+Toranaga smiles." CR>
+		  <DEQUEUE I-STABLE>
+		  <NEXT-SCENE>)>>
+
+<ROUTINE TORANAGA-LOSES-PATIENCE ()
+	 <TELL CR
+"Toranaga loses his patience with you.  \"The Anjin was probably a part of
+the conspiracy! Take this barbarian away and
+dispose of him.  Then send the body to the "I"eta""!\"">
+	 <JIGS-UP>>
+
+<ROUTINE BUILD-ANOTHER-SHIP ()
+	 <SETG AFTERMATH-QUESTION 0>
+	 <SETG QCONTEXT <>>
+	 <TELL
+"\"Mariko-sama say this ship is not necessary.  Say build new
+ship.  Say -- \"|
+|
+\"Ah!  Possible?  Possible?  Anjin-san?\"|
+|
+\"Yes,\" you reply, \"Yes!\"  And you think, by next year, a new ship,
+a ship like her, trim and miniature like a Yoshitomo blade, and just
+as dangerous.  Next year she'll take the Black Ship, a prize twenty
+times her own weight, like Mariko did at Osaka.  \""I"The Lady"" will
+be her name,\" you say aloud.|
+|
+Toranaga salutes you warmly, for the first time as an equal." CR>>
+
+<ROUTINE AFTERMATH-ANSWERS ()
+	 <COND (<EQUAL? ,AFTERMATH-QUESTION 4>
+		<COND (<P? MAKE LG-SHIP>
+		       <BUILD-ANOTHER-SHIP>)>)
+	       (<EQUAL? ,AFTERMATH-QUESTION 1>
+		<COND (<OR <VERB? NO IYE>
+			   <AND <EQUAL? ,PRSS ,YABU>
+				<P? BETRAY YOU>
+				<PAST-TENSE?>>>
+		       <SETG AFTERMATH-QUESTION 0>
+		       <TELL
+"\"No, Toranaga-sama, Yabu was not loyal to you at Osaka,\" you
+reply.  Yabu starts, but Toranaga merely nods." CR>)>)
+	       (<EQUAL? ,AFTERMATH-QUESTION 2>
+		<COND (<YABU-LET-IN-NINJA?>
+		       <YABU-BETRAYED-YOU>)>)
+	       (<EQUAL? ,AFTERMATH-QUESTION 3>
+		<COND (<P? BE ME YABU>
+		       <SETG AFTERMATH-QUESTION 0>
+		       <FSET ,YABU ,SCOREBIT>
+		       <TELL
+"\"He said to them, 'I am Kasigi Yabu,' and they poured through
+the door into the keep.  I returned as fast as I could to protect
+Mariko, Kiritsubo and the rest, knowing I would be killed if I
+tried to fight them there.\"" CR>
+		       <SCORE-OBJECT ,YABU>)>)>>
+
+<ROUTINE YABU-BETRAYED-YOU ()
+	 <SETG AFTERMATH-QUESTION 0>
+	 <TELL
+"\"Yabu betrayed you, Sire.  I followed him to the cellars of the
+keep where he let in a force of "I"ninja"".\"  Yabu is turning red
+with barely suppressed rage." CR>
+	 <SCORE-OBJECT ,TRAITOR>>
+
+<ROUTINE YABU-LET-IN-NINJA? ()
+	 <COND (<EQUAL? ,PRSS ,YABU>
+		<COND (<P? LET-IN LG-NINJA> <RTRUE>)
+		      (<AND <P? SEND LG-NINJA>
+			    <PAST-TENSE?>>
+		       <RTRUE>)
+		      (<AND <P? (OPEN UNLOCK) CELLAR-DOOR>
+			    <PAST-TENSE?>>
+		       <RTRUE>)
+		      (<AND <P? (KILL BETRAY) MARIKO>
+			    <PAST-TENSE?>>
+		       <RTRUE>)>)
+	       (<NOT ,PRSS>
+		<COND (<P? TELL-ABOUT TORANAGA LG-NINJA>
+		       <RTRUE>)>)>>
+
+<GLOBAL AFTERMATH-QUESTION <>>
+
+<OBJECT SEALED-SCROLL
+	(SDESC "sealed scroll")
+	(OWNER MARIKO)
+	(SCENE S-AFTERMATH)
+	(SYNONYM SCROLL LETTER MESSAGE SEAL)
+	(ADJECTIVE SEALED RICE-PAPER)
+	(FLAGS CONTBIT SEARCHBIT TAKEBIT READBIT SCOREBIT OPENABLE)
+	(ACTION SEALED-SCROLL-F)>
+
+<ROUTINE SEALED-SCROLL-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL "It's a rice-paper scroll." CR>)
+	       (<VERB? READ>
+		<COND (<NOT <HELD? ,PRSO>>
+		       <NOT-HOLDING ,PRSO>)
+		      (<FSET? ,PRSO ,OPENBIT>
+		       <TELL
+"Mariko has written in Latin \"Thou.  I love thee.  If this is read by
+thee then I am dead in Osaka and perhaps, because of me, thy ship
+is dead too.  I may sacrifice this most prized part of thy life because
+of my Faith, to safeguard my Church, but more to save thy life which is
+more precious to me than everything -- even the interest of my Lord
+Toranaga.  It may come to a choice, my love: thee or thy ship.  So sorry,
+but I choose life for thee.  This ship is doomed anyway -- with or
+without thee.  I will concede thy ship to thine enemy so that thou may
+live.  This ship is nothing.  "I"Build another.""  I believe Lord Toranaga
+will give thee all the craftsmen and carpenters necessary.  Build another
+ship and build another life, my love.  Forgive me -- but thy life is
+all important.  I love thee.\"" CR>
+		       <SCORE-OBJECT ,SEALED-SCROLL>)
+		      (ELSE
+		       <YOULL-HAVE-TO "break the seal">)>)
+	       (<P? (SHOW GIVE) * TORANAGA>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <TELL
+"The message is written in Latin.  It's gibberish to him." CR>)
+		      (ELSE
+		       <TELL
+"He has already seen the scroll.  He gave it to you, didn't he?" CR>)>)
+	       (<AND <VERB? MUNG OPEN TEAR>
+		     <NOUN-USED? ,PRSO ,W?SEAL>>
+		<COND (<NOT <HELD? ,PRSO>>
+		       <NOT-HOLDING ,PRSO>)
+		      (<NOT <FSET? ,PRSO ,OPENBIT>>
+		       <FSET ,PRSO ,OPENBIT>
+		       <NEW-SDESC ,SEALED-SCROLL "scroll">
+		       <TELL
+"You break the seal and open the scroll." CR>)
+		      (ELSE
+		       <TELL G"It already is." CR>)>)>>
+
+<OBJECT PEDESTAL
+	(DESC "pedestal")
+	(SCENE S-AFTERMATH)
+	(SYNONYM PEDESTAL SPIKE)
+	(ADJECTIVE SMALL)
+	(FLAGS OPENBIT CONTBIT SEARCHBIT TAKEBIT)
+	(ACTION YABU-HEAD-F)>
+
+<OBJECT YABU-HEAD
+	(LOC PEDESTAL)
+	(DESC "head")
+	(SCENE S-AFTERMATH)
+	(OWNER YABU)
+	(SYNONYM HEAD MASK)
+	(ADJECTIVE DEATH)
+	(FLAGS PERSON DEAD TAKEBIT)
+	(ACTION YABU-HEAD-F)>
+
+<ROUTINE YABU-HEAD-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"Yabu's death mask shows only berserk wrath, the lips pulled back
+into a ferocious challenge.  The head has been freshly washed, the
+hair groomed, and it is stuck
+on the spike of a small pedestal that is customarily used for the
+viewing." CR>)
+	       (<VERB? TAKE>
+		<TELL
+"You pick up the head and its pedestal, at once fascinated and
+repelled.  You replace it carefully, thinking it was Yabu's "I"karma"" to
+end this way." CR>)>>
+
+<ROUTINE NEVER-AFTER-F ()
+	 <TELL
+"Before long, you and a hundred samurai are working to raise the keel
+of the "I"Erasmus"".  One day, you notice Father Alvito standing on a
+dune overlooking the beach.  You join him.|
+|
+\"You really believe you can float the hulk?\" he asks.  \"No matter.  It
+will all be a waste, all that labor.\"|
+|
+\"There'll be another 'Act of God?'  Another sabotage?  Then I'll build
+another, and if that fails, another.  I'll get back to England and then
+I'm coming back, with a privateer!\"|
+|
+\"Yes. I know. That's why you will never leave.  You know too much,
+Anjin-san.  You're a fine adversary, one to respect.  Surely we can have
+a truce, and make peace.  I ask it because of Mariko-sama.\"|
+|
+\"I'll offer you a truce, not peace.  In her memory.\"" CR>>
+
+<END-SEGMENT>
+
+
+
+"S-EPILOGUE"
+
+<BEGIN-SEGMENT SEKIGAHARA>
+
+<ROOM SEKIGAHARA
+      (LOC ROOMS)
+      (SCENE S-EPILOGUE)
+      (DESC "Sekigahara")
+      (FLAGS ONBIT)
+      (SCORE 0)
+      (ACTION SEKIGAHARA-F)>
+
+<ROUTINE SEKIGAHARA-F ("OPT" (RARG <>) "AUX" LEFT WIDE Y)
+	 <COND (<RARG? ENTER>
+		<SET LEFT <WINGET ,S-TEXT ,WLEFT>>
+		<SET WIDE <WINGET ,S-TEXT ,WWIDE>>
+		<PICINF ,P-CREST ,YX-TBL>
+		<WINDEF 4
+			<WINGET ,S-TEXT ,WTOP> .LEFT
+			<+ <GET ,YX-TBL 0> <* 2 ,FONT-Y>> .WIDE>
+		<SCREEN 4>
+		<CLEAR 4>
+		<CENTER-PIC ,P-CREST>
+		<SET Y <+ <WINGET 4 ,WHIGH> <WINGET 4 ,WTOP>>>
+		<WINDEF ,S-TEXT .Y .LEFT <- <LOWCORE VWRD> .Y 1> .WIDE>
+		<SCREEN ,S-TEXT>)
+	       (<RARG? LOOK>
+		<TELL
+"That year, at dawn on the twenty-first day of the tenth month, the
+Month without Gods, the main armies clashed.  It was in the mountains
+near Sekigahara, astride the North Road, the weather foul -- fog, then
+sleet.  By late afternoon Toranaga had won the battle and the slaughter
+began.  Forty thousand heads were taken.|
+|
+Three days later Ishido was captured alive and Toranaga genially
+reminded him of the prophecy and sent him in chains to Osaka for
+public viewing, ordering the "I"eta"" to plant the General Lord Ishido's
+feet firm in the earth, with only his head outside the earth, and to
+invite passersby to saw at the most famous neck in the realm with a
+bamboo saw.  Ishido lingered three days and died very old." CR CR>
+		<TYPE-ANY-KEY>
+		<RESET-MARGIN>
+		<CLEAR ,S-TEXT>
+		<FINISH T>)>>
+
+<END-SEGMENT>
diff --git a/audience.zil b/audience.zil
new file mode 100644
index 0000000..9357135
--- /dev/null
+++ b/audience.zil
@@ -0,0 +1,2121 @@
+"AUDIENCE for
+				 SHOGUN
+	 (c) Copyright 1988 Infocom, Inc.  All Rights Reserved."
+
+<FILE-FLAGS SENTENCE-ENDS?>
+
+<BEGIN-SEGMENT AUDIENCE>
+
+<CONSTANT J-JOKE 70>
+<CONSTANT J-SIT 71>
+
+<ROOM OUTER-CORRIDOR ;"setup s-toranaga"
+      (LOC ROOMS)
+      (SCENE S-TORANAGA)
+      (AFTER ISHIDO-VS-TORANAGA-AFTER-F)
+      (DESC "Outer Corridor")
+      (SYNONYM CORRIDOR)
+      (ADJECTIVE OUTER)
+      (PICTURE P-OSAKA)
+      (SCORE 3)
+      (FDESC
+"You take your leave of Rodrigues, and then you are on deck,
+your mind whirling from the impact of Osaka, its immensity, the teeming
+anthills
+of people, and the enormous castle that dominates the city.  From within
+the castle's vastness comes the soaring beauty of the donjon, seven or
+eight stories high, pointed gables with curved roofs at each level,
+the tiles all gilded and the walls blue.|
+|
+The next day you are brought by Hiro-matsu to Toranaga's keep within
+the castle.")
+      (IN TO AUDIENCE-CHAMBER IF OUTER-DOOR IS OPEN)
+      (EAST TO AUDIENCE-CHAMBER IF OUTER-DOOR IS OPEN)
+      (WEST PER STAIRS-EXIT)
+      (DOWN PER STAIRS-EXIT)
+      (GLOBAL OUTER-DOOR LG-NINJA)
+      (FLAGS ONBIT)
+      (ACTION OUTER-CORRIDOR-F)>
+
+<ROUTINE STAIRS-EXIT ("OPT" (RARG <>) (STRICT? <>))
+	 <COND (<SCENE? ,S-NINJA> ,STAIRS)
+	       (ELSE
+		<COND (<NOT .RARG>
+		       <TELL
+"The guards point to toward the audience chamber instead." CR>)>
+		<RFALSE>)>>
+
+<ROUTINE OUTER-CORRIDOR-F (RARG)
+	 <COND (<RARG? SCENE-SETUP>
+		<DRESS-BLACKTHORNE>
+		<REPLACE-SYNONYM ,LG-CREWMEN ,W?MAN ,W?CREWMAN T>
+		<REPLACE-SYNONYM ,LG-CREWMEN ,W?MEN ,W?CREWMEN T>
+		<MOVE ,HIRO-MATSU ,HERE>
+		<MOVE ,TORANAGAS-GUARDS ,AUDIENCE-CHAMBER>
+		<MOVE ,ALVITO ,AUDIENCE-CHAMBER>
+		<MOVE ,YABU ,AUDIENCE-CHAMBER>
+		<MOVE ,TORANAGA ,AUDIENCE-CHAMBER>
+		<MOVE ,FALCON ,TORANAGA>
+		<PUTP ,BLACKTHORNE ,P?HEALTH 4>
+		<FCLEAR ,OUTER-DOOR ,OPENBIT>
+		<QUEUE I-AUDIENCE -1>)
+	       (<RARG? LOOK>
+		<TELL
+"This outer corridor is where those who are about to be granted
+audience with Toranaga wait.  The great Audience Chamber is to the
+east and stairs down to the lower part of the keep are to the west.">
+		<COND (<SCENE? ,S-TORANAGA>
+		       <TELL " Massed samurai, their young officer in
+front of them, protect the last door -- each with right hand on the
+sword hilt, left on the scabbard, motionless and ready, staring at
+you.">)>
+		<CRLF>)
+	       (<RARG? BEG>
+		<COND (<SCENE? ,S-NINJA>
+		       <COND (<AND <VERB? WALK>
+				   <IN? ,NINJA ,HERE>
+				   ,KNOCKOUT-CNT>
+			      <TELL
+G"You can't break through the encircling ninja!" CR>)
+			     (<AND <P? WALK P?WEST>
+				   <IN? ,YABU ,HERE>>
+			      <YABU-LISTENS>)>)>)>>
+
+<ROOM AUDIENCE-CHAMBER
+      (LOC ROOMS)
+      (DESC "Audience Chamber")
+      (SYNONYM CHAMBER ROOM)
+      (ADJECTIVE AUDIENCE)
+      (WEST TO OUTER-CORRIDOR IF OUTER-DOOR IS OPEN)
+      (EAST TO INNER-CORRIDOR IF INNER-DOOR IS OPEN)
+      (IN TO INNER-CORRIDOR IF INNER-DOOR IS OPEN)
+      (SOUTH TO SECRET-ROOM IF SECRET-ROOM-DOOR IS OPEN)
+      (GLOBAL INNER-DOOR OUTER-DOOR SECRET-ROOM-DOOR LG-NINJA LG-MEN LG-WOMEN)
+      (FLAGS ONBIT SCOREBIT)
+      (ACTION AUDIENCE-CHAMBER-F)>
+
+<GLOBAL POINTEE ALVITO>
+
+<ROUTINE AUDIENCE-CHAMBER-F (RARG)
+	 <COND (<RARG? LOOK>
+		<TELL
+"This is the immense audience room.  The room is forty paces square and
+ten high, the tatami mats the best quality, four fingers thick and
+impeccable.">
+		<COND (<NOT <FSET? ,VASE ,TOUCHBIT>>
+		       <TELL
+" Near the dais, in a niche, is a small earthenware vase
+with a single spray of cherry blossom and this fills the room with
+color and fragrance.">)>
+		<COND (<SCENE? S-TORANAGA>
+		       <TELL
+" Ten paces from the dais, circling it, are
+twenty samurai, seated cross-legged and facing outward.">)>
+		<TELL " Doors lead east and west to the outer
+and inner corridors, respectively.">
+		<COND (<NOT <FSET? ,SECRET-ROOM-DOOR ,INVISIBLE>>
+		       <TELL
+" On the south wall is a formerly secret door used by the ninja
+attackers.">)>
+		<CRLF>)
+	       (<RARG? BEG>
+		<COND (<SCENE? ,S-TORANAGA>
+		       <COND (<P? LISTEN
+				  (<> TORANAGA ALVITO HIRO-MATSU LG-MEN)>
+			      <TELL
+"You can't understand anything they say in Japanese">
+			      <COND (<PROB 25>
+				     <TELL
+", except that once you hear the word \"Anjin.\"" CR>)
+				    (ELSE <TELL "." CR>)>)
+			     (<VERB? TEKI SAY>
+			      <COND (<OR <AND <P? SAY INTQUOTE>
+					      <EQUAL? ,W?TEKI
+						      <GET-INTQUOTE 0>
+						      <GET-INTQUOTE 1>>>
+					 <P? TEKI>
+					 <P? SAY TEKI>>
+				     <COND (<NOT <FSET? ,TEKI ,RMUNGBIT>>
+					    <TELL
+"That's not a word you know." CR>
+					    <RTRUE>)
+					   (<NOT <FSET? ,ALVITO ,SCOREBIT>>
+					    <TELL
+"You've already said that.  Don't belabor it." CR>
+					    <RTRUE>)
+					   (<EQUAL? ,POINTEE ,ALVITO>
+					    <FCLEAR ,ALVITO ,RMUNGBIT>
+					    <TELL
+"You say "I"teki"".  Toranaga speaks curtly, and
+the priest begins translating simultaneously, a few words behind.  \"Why
+are you an enemy of Tsukku-san, who's the enemy of no
+one?\"  Alvito adds, \"The Japanese cannot pronounce my name either.  Tsukku
+is a pun on "I"tsuyaku"" -- to interpret.\"" CR>
+					    <SCORE-OBJECT ,ALVITO>
+					    <RTRUE>)>)>
+			      <COND (<JIGS-UP? ,J-JOKE
+"You remember Rodrigues' advice, and decide not to test the local sense
+of humor.">
+				     <JIGS-UP
+"Toranaga speaks angrily to Hiro-matsu.  Alvito translates.  \"This is no
+time for jokes.  You have made one joke too many, Englishman!\"">)
+				    (ELSE <RTRUE>)>)
+			     (<ACT-CRAZY?>
+			      <TELL
+"Toranaga looks at you with surprise.  He seems to think you are crazy." CR>)
+			     (<AND <VERB? POINT>
+				   <NOT <PRSO? ,ALVITO>>>
+			      <SETG POINTEE ,PRSO>
+			      <TELL
+"You point at " THE ,PRSO ".  " CTHE ,ALVITO " seems
+pleased at how foolishly you are acting." CR>)
+			     (<AND <P? (LOOK-UP EXAMINE) (ROOMS TORANAGA)>
+				   <B-NOT-STANDING?>
+				   <FSET? ,FALCON ,RMUNGBIT>>
+			      <FCLEAR ,FALCON ,RMUNGBIT>
+			      <TELL
+"You look up boldly at Toranaga.  He seems surprised and amused
+at your impertinence." CR>)
+			     (<OR <VERB? WALK-AROUND>
+				  <P? (WALK-TO FOLLOW JOIN)
+				      (ALVITO TORANAGA DAIS)>
+				  <P? WALK (P?FORE P?IN)>
+				  <P? AVOID (INNER-DOOR OUTER-DOOR)>>
+			      <COND (<NOT <FSET? ,DAIS ,RMUNGBIT>>
+				     <TELL
+"Alvito hisses, \"Captain, Lord Toranaga has not given you permission
+to move.\"" CR>) 
+				    (<FSET? ,DAIS ,SCOREBIT>
+				     <TELL
+"You carefully and quietly stand, bow to Toranaga, and move to Alvito's
+side, away from the main door." CR>
+				     <SCORE-OBJECT ,DAIS>)
+				    (<PRSO? DAIS TORANAGA>
+				     <TELL
+"You are already as close to the dais as Toranaga's samurai will allow." CR>)
+				    (ELSE
+				     <TELL
+"Alvito hisses, \"If you move again, it will mean your life!\"" CR>)>)
+			     (<VERB? WALK LEAVE>
+			      <TELL
+"You are not allowed to leave." CR>)
+			     (<AND <IN? ,ISHIDO ,HERE>
+				   <OR <VERB? TELL YELL YELL-AT SAY>
+				       <AND <NOT <PASSIVE-VERB?>>
+					    <NOT <GAME-VERB?>>
+					    <NOT <VERB? SIT>>>>>
+			      <TELL
+"Alvito hisses, \"As you value your life, Englishman, keep silent!\"" CR>
+			      <COND (<VERB? TELL>
+				     <END-QUOTE>
+				     <RFATAL>)
+				    (ELSE <RTRUE>)>)
+			     (<AND <VERB? SPEAK PICK>
+				   ,ALVITO-TRANSLATES?>
+			      <ALVITO-SPEAKS>)
+			     (<AND <NOT ,ALVITO-TRANSLATES?>
+				   <VERB? TELL>>
+			      <TELL
+"Your impatience and impertinence could cost you your life." CR>
+			      <END-QUOTE>
+			      <RFATAL>)
+			     (<IN? ,FALCON ,TORANAGA>
+			      <COND (<P? BOW (<> TORANAGA)>
+				     <COND (<NOT <FSET? ,HERE ,RMUNGBIT>>
+					    <FSET ,HERE ,RMUNGBIT>
+					    <TELL
+"You bow as you have learned to, remembering Rodrigues' words: \"Behave
+like a king and they'll treat you like a king.\"  You don't want to
+kneel." CR>)
+					   (<B-NOT-STANDING?>
+					    <TELL
+"You count slowly to six, and then you incline your head and bow
+slightly again." CR>)
+					   (ELSE
+					    <TELL
+"You've already bowed once.  You glance nervously around at the seated
+samurai.  What can you do to show you are respectful but equal?" CR>)>)
+				    (<VERB? SIT>
+				     <COND (<NOT <FSET? ,HERE ,RMUNGBIT>>
+					    <COND (<JIGS-UP? ,J-SIT
+"You think, and decide that a show of pride is one thing, a show of contempt
+another.">
+						   <B-SIT>
+						   <TELL
+"You sit cross-legged without bowing and stare at Toranaga.  Everyone in
+the room is deathly silent, watching to see what he will do.  The answer
+comes quickly, with a flash of steel you barely see before it ends
+your life.">
+						   <JIGS-UP>)
+						  (ELSE <RTRUE>)>)
+					   (<B-STANDING?>
+					    <B-SIT>
+					    <TELL
+"Taking a deep breath, you sit cross-legged and stare at Toranaga." CR>)>)
+				    (<VERB? KNEEL>
+				     <B-KNEEL>
+				     <TELL
+"You kneel abjectly, in imitation of Hiro-matsu." CR>)>)>)
+		      (<SCENE? ,S-NINJA>
+		       <COND (<VERB? LEAVE>
+			      <DO-WALK ,P?EAST>)
+			     (<AND <VERB? WALK>
+				   <IN? ,NINJA ,HERE>
+				   ,KNOCKOUT-CNT>
+			      <TELL
+G"You can't break through the encircling ninja!" CR>)
+			     (<P? WALK P?WEST>
+			      <COND (<IN? ,YABU ,HERE>
+				     <YABU-LISTENS>)
+				    (<AND <QUEUED? I-ATTACK>
+					  <IN? ,NINJA ,SECRET-ROOM>
+					  <NOT <FSET? ,NINJA ,INVISIBLE>>>
+				     <TELL
+"You go toward the exit to the outer corridor and the stairs, but the
+guards motion you back." CR>)
+				    (<AND <P? WALK (P?WEST P?SOUTH)>
+					  <IN? ,NINJA ,HERE>>
+				     <TELL
+G"You would have to walk right through the ninja!" CR>)>)>)>)>>
+
+<ROUTINE ISHIDO-VS-TORANAGA-AFTER-F ()
+	 <TELL
+"Toranaga watches you
+leave the room, taking his mind off the interview and coming to grips
+with the problem of Ishido.  Toranaga was summoned to Osaka to give
+answers to the Council of Regents, and against the advice of his
+advisors, he chose to obey.  Now he is stuck, the meeting delayed and
+delayed, Toranaga caught in the castle of his most deadly enemy.|
+|
+Ishido comes instantly to the point. \"What is your answer to the
+Council of Regents?\"|
+|
+Toranaga answers, \"As President of the
+Council of Regents I do not believe an answer is necessary.  Our late
+Master, the Taiko, has been dead a year.  I don't threaten his house
+or my nephew Yaemon, the Taiko's Heir.  I seek no more territory.  By
+the Lord Buddha, I'll not be the first to break the peace.\"|
+|
+Ishido
+bristles.  \"The Lady Ochiba, the mother of the heir, is hostage in
+your castle at Yedo, against your safety here.  The Council requests
+her presence in Osaka instantly.  We're all agreed: Lord Sugiyama,
+Lord Onoshi, Lord Kiyama, and I.  Here are their signatures.\"|
+|
+Toranaga is livid.  Why had Kiyama and Onoshi defected to Ishido?
+Four to one means isolation and disaster!" CR>>
+
+<OBJECT VASE
+ 	(LOC AUDIENCE-CHAMBER)
+ 	(DESC "vase")
+ 	(SYNONYM VASE)
+	(ADJECTIVE EARTHENWARE CERAMIC)
+ 	(FLAGS NDESCBIT TAKEBIT TRYTAKEBIT OPENBIT CONTBIT SEARCHBIT)
+ 	(CAPACITY 10)
+ 	(ACTION VASE-F)>
+
+<ROUTINE VASE-F ()
+ 	 <COND (<VERB? TAKE>
+ 		<FCLEAR ,FLOWER ,NDESCBIT>
+ 		<FCLEAR ,VASE ,NDESCBIT>
+		<RFALSE>)
+	       (<AND <VERB? LOOK-INSIDE>
+		     <FSET? ,FLOWER ,NDESCBIT>>
+ 		<TELL "The vase contains one sprig of cherry blossoms." CR>)>>
+
+<OBJECT FLOWER
+ 	(LOC VASE)
+ 	(DESC "cherry blossom")
+	(SYNONYM SPRAY FLOWER BLOSSOM)
+	(ADJECTIVE CHERRY)
+ 	(FLAGS NDESCBIT TAKEBIT TRYTAKEBIT)
+ 	(ACTION FLOWER-F)>
+
+<ROUTINE FLOWER-F ()
+ 	 <COND (<VERB? EXAMINE>
+ 		<TELL
+"The cherry blossoms are past their peak, but still beautiful." CR>)
+	       (<VERB? TAKE>
+ 		<COND (<SCENE? ,S-TORANAGA>
+		       <TELL
+"It would be worth your life to take that sprig of cherry." CR>)
+		      (ELSE
+		       <FCLEAR ,PRSO ,NDESCBIT>
+		       <RFALSE>)>)>>
+
+<OBJECT DAIS
+ 	(LOC AUDIENCE-CHAMBER)
+ 	(DESC "dais")
+ 	(OWNER TORANAGA)
+ 	(SYNONYM DAIS)
+ 	(FLAGS NDESCBIT SCOREBIT OPENBIT CONTBIT VEHBIT SEARCHBIT)>
+
+<OBJECT FALCON
+	(DESC "peregrine")
+	(OWNER TORANAGA)
+	(SYNONYM FALCON PEREGRINE WORK)
+	(FLAGS NDESCBIT RMUNGBIT)
+	(ACTION FALCON-F)>
+
+<ROUTINE FALCON-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The falcon has a broken wing feather, which Toranaga is repairing.  The
+falcon is hooded." CR>)>>
+
+<OBJECT TORANAGAS-GUARDS
+	(DESC "samurai guards")
+	(OWNER TORANAGA)
+	(SYNONYM GUARDS SAMURAI)
+	(FLAGS NDESCBIT PERSON JAPANESEBIT PLURAL
+	 OPENBIT CONTBIT SEARCHBIT NOABIT THE)
+	(GENERIC GENERIC-SAMURAI-F)
+	(ACTION TORANAGAS-GUARDS-F)>
+
+<ROUTINE TORANAGAS-GUARDS-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<WAKARIMASEN>
+		<END-QUOTE>)>>
+
+<OBJECT ALVITO
+	(LOC GENERIC-OBJECTS) ;"was in global-objects"
+	(SCENE S-TORANAGA)
+	(SDESC "tonsured priest" ;"Father Alvito")
+	(SYNONYM ALVITO PRIEST MAN FATHER JESUIT)
+	(ADJECTIVE FATHER MARTIN TONSURED LEAN-FACED PORTUGUESE)
+	(PICTURE P-ALVITO)
+	(FLAGS PERSON PORTUGUESEBIT OPENBIT CONTBIT SEARCHBIT SCOREBIT)
+	(GENERIC GENERIC-MAN-F)
+	(ACTION ALVITO-F)>
+
+<ROUTINE ALVITO-F ("OPT" (RARG <>) "AUX" ADJ)
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<AND <VERB? SPEAK PICK>
+			    ,ALVITO-TRANSLATES?>
+		       <ALVITO-SPEAKS>)
+		      (<OR <VERB? HELLO>
+			   <AND <VERB? YES>
+				<EQUAL? ,P-PRSA-WORD ,W?NOD>>>
+		       <TELL
+CTHE ,ALVITO " bows in response, more like a European courtier than a
+Japanese." CR>)
+		      (<VERB? SORRY>
+		       <TELL
+"\"It is of no consequence now.\"  You are not sure he is sincere." CR>)
+		      (<P? WHO YOU>
+		       <NEW-SDESC ,ALVITO "Father Alvito">
+		       <TELL
+G"\"My name is Martin Alvito of the Society of Jesus, Captain-Pilot.  Lord
+Toranaga has asked me to interpret for him.\"" CR>)
+		      (<P? BE? YOU INTADJ>
+		       <SET ADJ <PARSE-ADJ ,PARSE-RESULT>>
+		       <COND (<EQUAL? .ADJ ,W?PORTUGUESE>
+			      <TELL
+"\"I have that privilege.\"" CR>)>)
+		      (<P? BE (ME BLACKTHORNE) ENGLAND>
+		       <TELL
+"\"Yes, Pilot, you are of the enemy.  In spite of this, you may trust
+me to translate what you say accurately.  I am merely the Lord Toranaga's
+instrument in this.\"" CR>)
+		      (ELSE
+		       <TELL
+CTHE ,ALVITO " ruminates on your remark, but doesn't reply." CR>)>)
+	       (<VERB? BOW>
+		<PERFORM ,V?HELLO ,ALVITO>
+		<RTRUE>)
+	       (<VERB? EXAMINE>
+		<TELL
+CTHE ,ALVITO " is a graceful, handsome man, perhaps a few years older
+than you.  He wears tabi socks and a flowing kimono that seems, on him,
+to belong.  A rosary and a carved golden cross hang at his belt.  He has
+an easy elegance, and the aura of strength and natural power of the
+Jesuits." CR>)
+	       (<AND <VERB? POINT>
+		     <FSET? ,ALVITO ,RMUNGBIT>>
+		<SETG POINTEE ,ALVITO>
+		<TELL
+"You point to Alvito." CR>)>>
+
+<ROUTINE ALVITO-SPEAKS ()
+	 <COND (<OR <PRSO? PORTUGUESE LATIN SPANISH>
+		    <AND <PRSO? ALVITO>
+			 <ADJ-USED? ,ALVITO
+				    ,W?PORTUGUESE>>>
+		<TELL
+"\"Very well,\" Alvito replies." CR>)
+	       (ELSE
+		<TELL
+"\"This is not a time for foolishness!\" Alvito answers, and speaks
+briefly to Toranaga, who scowls." CR>)>>
+
+<GLOBAL ALVITO-TRANSLATES? <>>
+
+<ROUTINE I-AUDIENCE ()
+	 <ZLINES ,AUDIENCE-CNT
+		 (<FSET ,OUTER-DOOR ,OPENBIT>
+		  <TELL CR
+"You and Hiro-matsu stop before the officer of the watch, a mean-tempered,
+dangerous young man.  He and Hiro-matsu converse briefly, and then several
+of the samurai search you expertly.  Nothing would have escaped them.|
+|
+The officer opens the thick door himself, and you and Hiro-matsu are
+ushered into the audience room." CR CR>
+		  <MOVE ,HIRO-MATSU ,AUDIENCE-CHAMBER>
+		  <THIS-IS-IT ,ORDERS>
+		  <THIS-IS-IT ,HIRO-MATSU>
+		  <GOTO ,AUDIENCE-CHAMBER>
+		  <TELL CR
+"Just beyond the doorway Hiro-matsu kneels, puts his swords on the
+floor, and bows his head low, waiting in that abject position.|
+|
+The officer indicates to you to do the same, but you are disgusted with
+the old man's servility." CR>)
+		 (DELAY
+		  <COND (<B-STANDING?>
+			 <COND (<OR <G? ,DELAY-CNT 3>
+				    <NOT <PASSIVE-VERB?>>>
+				<TELL CR
+"Toranaga looks up slowly, gestures imperceptably at Hiro-matsu, and
+goes back to his falconry.  Hiro-matsu rises, bows to Toranaga, and
+slays you with a single stroke.">
+				<JIGS-UP>
+				<RFATAL>)
+			       (<EQUAL? ,DELAY-CNT 1>
+				<TELL CR
+"In the doorway the officer's hand is on his sword.  Hiro-matsu has
+already grasped his, though his head is still bent." CR>
+				<RTRUE>)
+			       (<EQUAL? ,DELAY-CNT 2>
+				<TELL CR
+"The tension in the room rises as everyone begins to stare at you.  But as a
+true-born Englishman and vassal of the Queen, it's unmanly to degrade yourself
+as they do here." CR>
+				<RTRUE>)
+			       (<EQUAL? ,DELAY-CNT 3>
+				<TELL CR
+"Hiro-matsu's sword inches out of its scabbard.  He is preparing
+himself to cleanse your disrespect to his liege lord.  Will you die rather
+than abase yourself?" CR>
+				<RTRUE>)>)>)
+		 (<TELL CR
+"Toranaga looks up slowly.  He watches you briefly, his face impassive, then
+looks down and concentrates on his work again.  Tension subsides in the
+room." CR>
+		  <SCORE-OBJECT ,AUDIENCE-CHAMBER>)
+		 (<REMOVE ,FALCON>
+		  <TELL CR
+"Toranaga gives the falcon to a handler, who bows and leaves.  Then
+Toranaga greets Hiro-matsu, and they converse briefly and casually.  At
+one point they are clearly talking about you." CR>)
+		 (<FCLEAR ,FALCON ,RMUNGBIT>
+		  <SETG ALVITO-TRANSLATES? T>
+		  <NEW-SDESC ,ALVITO "Father Alvito">
+		  <THIS-IS-IT ,ALVITO>
+		  <SETG QCONTEXT ,ALVITO>
+		  <TELL CR
+"Toranaga turns and beckons to the lean-faced Portuguese who is sitting
+patiently in his shadow.  The priest comes forward, and kneels close to
+the dais.  Toranaga speaks briefly to him, and the man then glances
+pleasantly at you.  He speaks to you in Portuguese.  "
+G"\"My name is Martin Alvito of the Society of Jesus,
+Captain-Pilot.  Lord Toranaga has asked me to interpret for him.  We can speak
+Portuguese, Spanish, or, of course, Latin -- whichever
+you prefer,\" Alvito offers smoothly." CR>)
+		 (<FSET ,ALVITO ,RMUNGBIT>
+		  <FSET ,TEKI ,RMUNGBIT> ;"now know the word"
+		  <TELL CR
+"\"The Japanese word for 'enemy' is '"I"teki"".'  You may use it if you
+wish.  If you point at me and use the word, Lord Toranaga will understand
+clearly what you mean.  I am your enemy, but not your assassin.  That you
+will do yourself.\"" CR>)
+		 (DELAY
+		  <COND (<FSET? ,ALVITO ,SCOREBIT>
+			 <COND (<G? ,DELAY-CNT 3>
+				<FCLEAR ,ALVITO ,RMUNGBIT>
+				<FCLEAR ,ALVITO ,SCOREBIT>
+				<TELL
+"\"Very well, I will tell him myself.\"  Alvito speaks to Toranaga, who
+responds gruffly, scowling at you.  The priest seems very satisfied with
+the outcome." CR>
+				<RTRUE>)
+			       (ELSE
+				<TELL CR
+"Alvito waits patiently.">
+				<COND (<EQUAL? ,DELAY-CNT 1>
+				       <TELL
+" You wonder if '"I"teki""' truly means 'enemy.'  Of course it does, you
+tell yourself.  This man's not like the other one.">)>
+				<CRLF>
+				<RTRUE>)>)>)
+		 (<TELL CR
+"Toranaga begins to interrogate you, Alvito translating smoothly,
+calmly.  It's clear that Alvito has told him some of the questions to ask, but
+others obviously surprise the Jesuit.  The existence of the Protestant
+religion, and the English and Dutch alliance against Spain and Portugal
+make Toranaga pause and think: the Catholics are not the only sort of
+Christian after all, and a small island country can hold off, perhaps
+even beat a great empire through command of the seas!  Before long Alvito
+is sweating; this is worse, far worse than he anticipated." CR>)
+		 (<SETG QCONTEXT <>>
+		  <FSET ,DAIS ,RMUNGBIT>
+		  <THIS-IS-IT ,ORDERS>
+		  <TELL CR
+"Suddenly, there is the sound of loud voices outside the room.  Hiro-matsu
+and half the guards are instantly at the doorway and the rest move into
+a tight knot screening the dais.|
+|
+\"You are to come over here, Captain Blackthorne, away from the door,\"
+Father Alvito says with carefully contained urgency.  \"If you value your
+life, do not move suddenly or say anything!\"" CR>)
+		 (DELAY
+		  <COND (<FSET? ,DAIS ,SCOREBIT>
+			 <COND (<G? ,DELAY-CNT 1>
+				<FCLEAR ,DAIS ,SCOREBIT>
+				<TELL CR
+"Toranaga gestures to the guards, who unceremoniously grab you and
+hustle you across the room, setting you down with a thump next to
+Alvito, who can barely suppress a smile at your treatment." CR>
+				<RTRUE>)
+			       (ELSE
+				<TELL CR
+"\"Captain, it is your death if you do not come here immediately!\"" CR>
+				<RTRUE>)>)>)
+		 (<MOVE ,ISHIDO ,AUDIENCE-CHAMBER>
+		  <MOVE ,GRAYS ,AUDIENCE-CHAMBER>
+		  <FCLEAR ,DAIS ,RMUNGBIT>
+		  <TELL CR
+"The door at the far end shivers open.  Alvito translates what
+follows.  \"Lord Ishido wishes to see you,
+Sire,\" Naga announces.  \"He's -- he's here in the corridor and he wishes
+to see you.  At once, he says.\"|
+|
+\"Naga-san, tell Lord Ishido he is always welcome.  Ask him to come in.\"|
+|
+A tall man strides into the room.  Ten of his samurai, gray-uniformed,
+follow.|
+|
+Toranaga says, \"Welcome, Lord Ishido.  Please sit there.\"  He gestures
+at the single cushion on the dais.  \"I'd like you to be comfortable.\"|
+|
+\"Thank you, no,\" responds Ishido.  \"I'd be embarrassed to be comfortable
+while you were not.  One day I will take your cushion, but not today.\"" CR>)
+		 (<TELL CR
+"Ishido looks at you with pronounced distaste.  \"I heard he was ugly but
+not this ugly!  Rumor has it that he's a pirate.  Before you crucify him,
+please let me have him for half a day.  Perhaps he could be taught to dance
+like a bear, and you could exhibit him throughout the Empire: 'The Freak
+from the East.'\"|
+|
+Toranaga smiles.  \"You're a man of vast humor, Lord Ishido.  I agree
+the sooner the barbarian's removed the better.  Naga-san, send some men
+and put him with the common criminals.\"  Alvito turns to you, and says
+\"You are to follow these men.  You are to be detained.  I don't know how
+for how long: until Lord Toranaga decides.\"" CR>
+		  <MOVE ,ALVITO ,GENERIC-OBJECTS>
+		  <REPLACE-SYNONYM ,ALVITO ,W?PRIEST ,W?ALVITO T>
+		  <MOVE ,ISHIDO ,GENERIC-OBJECTS>
+		  <MOVE ,TORANAGA ,GENERIC-OBJECTS>
+		  <REMOVE ,GRAYS>
+		  <REMOVE ,TORANAGAS-GUARDS>
+		  <DEQUEUE I-AUDIENCE>
+		  <NEXT-SCENE>)>>
+
+<END-SEGMENT>
+
+<BEGIN-SEGMENT PRISON>
+
+<OBJECT LG-LINE
+	(LOC LOCAL-GLOBALS)
+	(SCENE S-PRISON)
+	(DESC "line")
+	(SYNONYM LINE)
+	(FLAGS NDESCBIT VEHBIT SCOREBIT)
+	(ACTION LG-LINE-F)>
+
+<ROUTINE LG-LINE-F ()
+	 <COND (<HERE? ,PRISON>
+		<COND (<P? BOARD LG-LINE>
+		       <TELL
+"Now that the food has been distributed, the line has vanished.  Everyone
+is back in his own little space." CR>)>)
+	       (<P? BOARD LG-LINE>
+		<COND (<FSET? ,LG-LINE ,SCOREBIT>
+		       <TELL
+"You join the line of prisoners." CR>
+		       <SCORE-OBJECT ,LG-LINE>)
+		      (ELSE
+		       <TELL "You're in line already." CR>)>)
+	       (<P? (DISEMBARK EXIT) LG-LINE>
+		<COND (<FSET? ,LG-LINE ,SCOREBIT>
+		       <TELL "You aren't in line." CR>)
+		      (ELSE
+		       <TELL
+"You are nudged back into line." CR>)>)>>
+
+<ROOM PRISON
+      (LOC ROOMS)
+      (SCENE S-PRISON S-MARIKO)
+      (SCORE 6)
+      (DESC "Cell Block")
+      (AFTER PRISON-AFTER-F)
+      (SYNONYM PRISON JAIL CELL BLOCK)
+      (ADJECTIVE CELL)
+      (FDESC
+"Toranaga's guards take you to the prison, strip you, and force you
+through the door of one of the cell blocks.|
+|
+At dawn it is feeding time and the guards pass out cups of gruel
+and water through a small opening.  The lining up for food and water
+is unusually calm -- without discipline no one would eat.  You take
+your ration and pick your way over the bodies toward a corner.")
+      (LDESC
+"This murky and suffocating room is fifty paces long and ten wide and
+packed with naked, sweating Japanese.  Scarcely any light filters through
+the boards and beams that make up the walls and low ceiling.  A heavy iron
+door seals the prisoners in.")
+      (OUT TO PRISON-COURTYARD IF IRON-DOOR IS OPEN)
+      (EAST TO PRISON-COURTYARD IF IRON-DOOR IS OPEN)
+      (FLAGS ONBIT)
+      (GLOBAL LG-LINE IRON-DOOR PRISON MADMAN)
+      (THINGS <> PRISONER PRISONER-PSEUDO
+	      <> PRISONERS PRISONER-PSEUDO)
+      (ACTION PRISON-F)>
+
+<ROUTINE PRISONER-PSEUDO ()
+	 <TELL "The other prisoners ">
+	 <COND (<HERE? ,PRISON>
+		<TELL "avoid you." CR>)
+	       (ELSE
+		<TELL "seem resigned to their fate." CR>)>>
+
+<ROUTINE PRISON-F (RARG "AUX" C)
+	 <COND (<RARG? SCENE-SETUP>
+		<MOVE ,CUP ,BLACKTHORNE>
+		<QUEUE I-PRISON -1>)
+	       (<RARG? END>
+		<COND (<OR <QUESTION-VERB?>
+			   <VERB? TELL-ME-ABOUT ASK-ABOUT TELL-ABOUT>>
+		       <COND (<SET C <QUEUED? I-BULLDOG>>
+			      <PUT .C ,C-TICK <+ <GET .C ,C-TICK> 1>>)>
+		       <COND (<SET C <QUEUED? I-OUT-OF-PRISON>>
+			      <PUT .C ,C-TICK <+ <GET .C ,C-TICK> 1>>)>)>)
+	       (<RARG? BEG>
+		<COND (<AND <VERB? LEAVE>
+			    <NOT <FSET? ,THUG ,DEAD>>>
+		       <TELL
+"You try to get away, but the thug grabs you as you try to squeeze
+through the crowd of watchers." CR>) 
+		      (<AND <VERB? SPEAK> <IN? ,DOMINGO ,HERE>>
+		       <COND (<AND ,PRSI <NOT <PRSI? ,DOMINGO>>>
+			      <TELL
+CTHE ,PRSI " doesn't seem to understand you, but " THE ,DOMINGO " looks
+at you with excitement.  ">)>
+		       <DOMINGO-STARES>
+		       <COND (<PRSO? ,SPANISH>
+			      <DEQUEUE I-PRISON>
+			      <COND (<NOT <QUEUED? I-OUT-OF-PRISON>>
+				     <QUEUE I-MADMAN 3>
+				     <QUEUE I-BULLDOG 5>
+				     <QUEUE I-OUT-OF-PRISON 10>)>
+			      <TELL
+"\"The mother tongue!  Oh, it is so good to hear it again, my son!\"" CR>
+			      <SCORE-OBJECT ,DOMINGO>)
+			     (<PRSO? ,LATIN>
+			      <TELL
+"\"You are an educated man, senor!\" he replies with obvious pleasure">
+			      <COND (<FSET? ,DOMINGO ,SCOREBIT>
+				     <TELL ",
+then stops suddenly.  \"The senor is not a Jesuit?  Does the senor speak
+Spanish?\"" CR>)
+				    (ELSE <TELL "." CR>)>)
+			     (<PRSO? ,DUTCH>
+			      <TELL
+"\"Ah, the senor is from our dominions in Spanish Flanders!">
+			      <COND (<FSET? ,DOMINGO ,SCOREBIT>
+				     <TELL " But please,
+speak Spanish!  I have heard no Spanish since I came to this awful
+place!\"">)>
+			      <CRLF>)
+			     (<PRSO? ,PORTUGUESE ,ENGLISH>
+			      <TELL
+"\"The senor is ">
+			      <COND (<PRSO? ,PORTUGUESE>
+				     <TELL "a Portuguese">)
+				    (ELSE
+				     <TELL "a heretic English">)>
+			      <MOVE ,DOMINGO ,GENERIC-OBJECTS>
+			      <DEQUEUE I-PRISON>
+			      <QUEUE I-OUT-OF-PRISON 2>
+			      <TELL "!\"  He begins to rant and rave in a
+mixture of Spanish and Latin, growing ever more angry.  The nearby
+Japanese shift uneasily.  One of them gets up and shakes the priest
+gently, and gradually he comes out of his fit, but from then on he
+ignores you, and ultimately his flock leads him away." CR>)>)
+		      (<AND <P? BOW <>>
+			    <IN? ,BULLDOG ,HERE>>
+		       <PERFORM ,V?BOW ,BULLDOG>
+		       <RTRUE>)
+		      (<VERB? SLEEP>
+		       <COND (<NOT <FSET? ,THUG ,DEAD>>
+			      <TELL "To sleep now would be fatal!" CR>)
+			     (ELSE
+			      <TELL
+"You try to find a safe place to rest in this hell." CR>)>)>)
+	       (<RARG? <>>
+		<COND (<P? OPEN PRISON>
+		       <PERFORM ,V?OPEN ,IRON-DOOR>
+		       <RTRUE>)>)>>
+
+<OBJECT IRON-DOOR
+	(SCENE S-PRISON)
+	(LOC LOCAL-GLOBALS)
+	(DESC "iron door")
+	(SYNONYM DOOR)
+	(ADJECTIVE IRON)
+	(FLAGS LOCKED LOCKABLE OPENABLE DOORBIT)>
+
+<OBJECT CUP
+	(SCENE S-PRISON)
+	(DESC "cup")
+	(OWNER GRUEL)
+	(SYNONYM CUP)
+	(FLAGS TAKEBIT OPENBIT CONTBIT SEARCHBIT)
+	(CAPACITY 10)
+	(ACTION CUP-F)>
+
+<ROUTINE CUP-F ()
+	 <COND (<VERB? LOOK-INSIDE>
+		<TELL
+"It contains thin, watery gruel, but it's food, by God!" CR>)
+	       (<AND <VERB? EAT DRINK>
+		     <IN? ,GRUEL ,CUP>>
+		<PERFORM ,PRSA ,GRUEL>
+		<RTRUE>)
+	       (<VERB? TAKE>
+		<COND (<IN? ,CUP ,THUG>
+		       <TELL
+"The thug jerks his hand away, and kicks you in the knee." CR>)>)
+	       (<AND <P? GIVE CUP>
+		     <HERE? ,PRISON>>
+		<REMOVE ,CUP>
+		<COND (<PRSI? ,DOMINGO>
+		       <TELL
+CTHE ,DOMINGO " takes the gruel and eats it thankfully." CR>)
+		      (ELSE
+		       <TELL
+"Surprised that you don't want the gruel, the other prisoners fight each
+other for it." CR>)>)
+	       (<VERB? DROP>
+		<COND (<AND <NOT <FSET? ,CUP ,TOUCHBIT>>
+			    <HERE? ,PRISON>>
+		       <TELL "You drop the cup.  ">)>)
+	       (<VERB? POUR POUR-FROM>
+		<COND (<AND <NOT <FSET? ,CUP ,TOUCHBIT>>
+			    <HERE? ,PRISON>>
+		       <TELL "You start to tip the cup to pour it.  ">
+		       <START-FIGHT>)
+		      (ELSE
+		       <TELL
+"What a waste of good gruel, gruel that cost a man his life!" CR>)>)>>
+
+<OBJECT GRUEL
+	(SCENE S-PRISON)
+	(LOC CUP)
+	(DESC "gruel")
+	(SYNONYM GRUEL RATION FOOD)
+	(ADJECTIVE GRUEL)
+	(FLAGS TAKEBIT FOODBIT)
+	(ACTION GRUEL-F)>
+
+<ROUTINE GRUEL-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL "It's thin, watery stuff." CR>)
+	       (<VERB? TAKE DROP GIVE POUR THROW>
+		<REDIRECT ,GRUEL ,CUP>
+		<RTRUE>)
+	       (<VERB? EAT DRINK>
+		<COND (<AND <NOT <FSET? ,CUP ,TOUCHBIT>>
+			    <HERE? ,PRISON>>
+		       <TELL "You bring the cup towards your lips.  ">
+		       <START-FIGHT>)
+		      (<IN? ,CUP ,THUG>
+		       <TELL ,YOU-HAVE-TO "fight for it!" CR>)
+		      (ELSE
+		       <REMOVE ,GRUEL>
+		       <TELL
+"It's thin, watery barley and rice, but you wolf it down." CR>)>)>>
+
+<OBJECT THUG
+	(LOC PRISON)
+	(DESC "apelike man")
+	(SYNONYM APE MAN THUG CONVICT PRISONER)
+	(ADJECTIVE APELIKE UNSHAVEN FILTHY LICE-RIDDEN FILTHY ;"DEAD")
+	(FLAGS AN PERSON JAPANESEBIT OPENBIT CONTBIT SEARCHBIT SCOREBIT)
+	(HEALTH 3)
+	(DESCFCN THUG-DESC)
+	(ACTION THUG-F)>
+
+<ROUTINE THUG-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (ELSE
+		<COND (<FSET? ,THUG ,DEAD>
+		       <TELL
+"The dead thug lies in the filth of the floor, his head at an unnatural
+angle to his body.">)
+		      (ELSE
+		       <TELL
+"An apelike man stares at you with hatred.">)>)>>
+
+<ROUTINE THUG-F ("OPT" (RARG <>)"AUX" TMP)
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<TELL
+"He appears uninterested in talking to you." CR>)
+	       (<AND <P? GIVE CUP THUG>
+		     <NOT <FSET? ,THUG ,DEAD>>>
+		<MOVE ,CUP ,THUG>
+		<REMOVE ,GRUEL>
+		<TELL
+"He grabs it out of your hand and wolfs it down.  His hostility only
+seems to have increased, though." CR>)
+	       (<VERB? TAKE>
+		<COND (<FSET? ,THUG ,DEAD>
+		       <TELL
+"He's too heavy, especially in light of what you've been through lately." CR>)
+		      (ELSE
+		       <PERFORM ,V?ATTACK ,THUG>
+		       <RTRUE>)>)
+	       (<VERB? MOVE>
+		<COND (<FSET? ,THUG ,DEAD>
+		       <TELL
+"You shove his lifeless body." CR>)
+		      (ELSE
+		       <TELL
+"You shove him away from you." CR>)>)
+	       (<HOSTILE-VERB?>
+		<COND (<VERB? THROW> <MOVE ,PRSO ,HERE>)>
+		<COND (<FSET? ,THUG ,DEAD>
+		       <COND (<VERB? PISS>
+			      <TELL "Adding insult to injury." CR>)
+			     (ELSE
+			      <TELL "He's already very dead." CR>)>)
+		      (ELSE
+		       <COND (<NOT <FSET? ,THUG ,RMUNGBIT>>
+			      <FSET ,THUG ,RMUNGBIT>
+			      <PUTP ,THUG ,P?HEALTH 1000>)>
+		       <SET TMP <- <GETP ,THUG ,P?HEALTH> 1>>
+		       <PUTP ,THUG ,P?HEALTH .TMP> 
+		       <COND (<NOT <ZERO? .TMP>>
+			      <COND (<VERB? BITE>
+				     <TELL
+"You grapple with him, and in desperation bite him on the arm.  He
+jerks away, bleeding." CR>)
+				    (<VERB? THROW>
+				     <TELL
+CTHE ,PRSO " hits him and clatters to the ground." CR>)
+				    (<VERB? KICK>
+				     <TELL
+"You kick him savagely, and he staggers back." CR>)
+				    (<VERB? MOVE>
+				     <TELL
+"You grab for him and try to pull him past you and down." CR>)
+				    (<VERB? PUSH>
+				     <TELL
+"You shove him, and he momentarily loses his balance." CR>)
+				    (<VERB? HIT>
+				     <TELL
+"You smash him in the jaw, knocking him backwards." CR>)
+				    (ELSE
+				     <TELL <PICK-ONE ,YOU-ATTACKS> CR>)>)
+			     (ELSE
+			      <MOVE ,CUP ,HERE>
+			      <FSET ,THUG ,DEAD>
+			      <REPLACE-ADJECTIVE ,THUG ,W?FILTHY ,W?DEAD>
+			      <SETG OPPONENT <>>
+			      <MOVE ,BULLDOG ,HERE>
+			      <TELL
+"You close with him, intending to ">
+			      <PRINTB ,P-PRSA-WORD>
+			      <TELL " him, but he grabs you.  You manage
+to grab his throat and hammer his head against a beam
+until he's senseless.  He falls on some of the other prisoners, who
+curse loudly, and one of them, a heavyset bulldog of a man, chops
+him viciously on the neck with the side of his hand.  There is a dry
+snap and the thug's head sags.  The bulldog man lifts the half-shaven
+head and lets it fall.  He smiles at you and shrugs." CR>
+			      <SCORE-OBJECT ,THUG>)>)>)>>
+
+<CONSTANT YOU-ATTACKS
+	  <LTABLE 0
+"You butt your head into the man's face."
+"You kick him in the shins and he skips aside."
+"You feign momentary helplessness, then kick him viciously.">>
+
+<CONSTANT THUG-ATTACKS
+	  <LTABLE 0
+"The man leaps at you, trying to knock you down with a vicious
+attack."
+"The prisoner tries to bite you."
+"The thug kicks out, trying to trip you.">>		  
+
+<ROUTINE START-FIGHT ("OPT" (INT? <>) "AUX" (BAD? <>))
+	 <COND (<FSET? ,THUG ,RMUNGBIT> <SET BAD? T>)>
+	 <PUTP ,BLACKTHORNE ,P?HEALTH 4>
+	 <FSET ,THUG ,RMUNGBIT>
+	 <FSET ,CUP ,TOUCHBIT>
+	 <THIS-IS-IT ,THUG>
+	 <SETG OPPONENT ,THUG>
+	 <COND (.INT? <CRLF>)>
+	 <COND (<OR .BAD? <NOT <LOC ,GRUEL>>>
+		<TELL "The">)
+	       (ELSE <TELL "Suddenly, the">)>
+	 <TELL " apelike man -- unshaven, filthy, lice-ridden -- ">
+	 <COND (<B-NOT-STANDING?>
+		<B-STAND>
+		<TELL "jerks you to your feet, ">)>
+	 <TELL "chops you over the kidneys and ">
+	 <COND (<IN? ,CUP ,THUG> <TELL "spits out">)
+	       (<IN? ,CUP ,BLACKTHORNE> <TELL "takes">)
+	       (ELSE <TELL "then picks up">)>
+	 <MOVE ,CUP ,THUG>
+	 <TELL " your ration.  The others wait to see what will happen." CR>>
+
+<ROUTINE I-PRISON ("AUX" TMP)
+	 <ZLINES ,PRISON-CNT
+		 (1)
+		 (<COND (<NOT <FSET? ,CUP ,TOUCHBIT>>
+			 <START-FIGHT T>)>)
+		 (DELAY
+		  <COND (<FSET? ,THUG ,SCOREBIT>
+			 <SET TMP <- <GETP ,BLACKTHORNE ,P?HEALTH> 1>>
+			 <PUTP ,BLACKTHORNE ,P?HEALTH .TMP>
+			 <COND (<NOT <ZERO? .TMP>>
+				<TELL CR
+<PICK-ONE ,THUG-ATTACKS> CR CR
+"The other prisoners watch impassively." CR>
+				<RTRUE>)
+			       (ELSE
+				<TELL CR
+"With a ferocious overhand blow, the thug smashes you to the floor,
+and then jumps on you, breaking your neck.">
+				<JIGS-UP>
+				<RFATAL>)>)>)
+		 (<QUEUE I-BULLDOG-EATS-IT 2>
+		  <THIS-IS-IT ,CUP>
+		  <THIS-IS-IT ,BULLDOG>
+		  <TELL CR
+"To your amazement, the bulldog-like man offers you the cup of gruel
+that you had presumed lost." CR>)
+		 (3)
+		 (<B-SIT>
+		  <MOVE ,DOMINGO ,HERE>
+		  <THIS-IS-IT ,DOMINGO>
+		  <SETG QCONTEXT ,DOMINGO>
+		  <TELL CR
+"Your exhaustion is beginning to take its toll, and you start to fall
+into a nightmare.  In what seems like moments, you are jerked to
+wakefulness, your ears exploding
+with the sonorous Latin of the Last Sacrament: \"In nomine Patris
+et Filii et Spiritus Sancti.\"  There is another European, a toothless
+old scarecrow of a man, bending over you!" CR>)
+		 (DELAY
+		  <COND (<FSET? ,DOMINGO ,SCOREBIT>
+			 <COND (<G? ,DELAY-CNT 5>
+				<TELL CR
+"He shakes his head, as though trying to wake from a dream.  \"The senor
+is a dream.  The devil is sending me dreams, yes!\"  He hobbles away, his
+followers grouped closely about him." CR>
+				<DEQUEUE I-PRISON>
+				<QUEUE I-OUT-OF-PRISON 2>
+				<RFATAL>)
+			       (ELSE
+				<SETG QCONTEXT ,DOMINGO>
+				<TELL CR
+"\"The senor speaks Spanish, eh?  The senor is not a thrice-damned
+heretic, is he?\"  There is an edge of hysteria in the old man's
+voice.  His followers
+edge closer to him." CR>)>)>)
+		 (<DEQUEUE I-PRISON>
+		  <RFALSE>)>>
+
+<ROUTINE I-BULLDOG-EATS-IT ("OPT" (NOT-INT? <>))
+	 <COND (<AND <IN? ,CUP ,HERE>
+		     <IN? ,GRUEL ,CUP>>
+		<REMOVE ,CUP>
+		<COND (<NOT .NOT-INT?> <CRLF>)>
+		<TELL
+"The bulldog man, amazed that you don't want the gruel, eats it,
+nodding happily in your direction." CR>)>>
+
+<OBJECT BULLDOG
+	(DESC "bulldog-like man")
+	(SYNONYM MAN PRISONER BULLDOG AKABO GONZALEZ)
+	(ADJECTIVE BULLDOG BULLDOG-LIKE)
+	(FLAGS PERSON JAPANESEBIT NDESCBIT OPENBIT CONTBIT SEARCHBIT SCOREBIT)
+	(ACTION BULLDOG-F)>
+
+<ROUTINE BULLDOG-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<COND (<VERB? DOMO>
+		       <TELL "He smiles at you." CR>)
+		      (ELSE
+		       <TELL "He appears well-disposed to you, but doesn't
+understand what you say." CR>
+		       <END-QUOTE>)>)
+	       (<RARG? <>>
+		<COND (<P? GIVE CUP>
+		       <I-BULLDOG-EATS-IT T>)>)>>
+
+<OBJECT DOMINGO
+	(SDESC "old priest" ;"Fr. Domingo")
+	(DESC "old priest")
+	(SCENE S-PRISON S-MARIKO S-ESCAPE)
+	(SYNONYM FATHER PRIEST MAN DOMINGO FRANCISCAN FRIAR EUROPEAN)
+	(ADJECTIVE OLD FATHER FRIAR)
+	(FLAGS AN PERSON SPANISHBIT OPENBIT CONTBIT SEARCHBIT SCOREBIT)
+	(ACTION DOMINGO-F)>
+
+<ROUTINE DOMINGO-STARES ()
+	 <COND (<NOT <FSET? ,DOMINGO ,TOUCHBIT>>
+		<FSET ,DOMINGO ,TOUCHBIT>
+		<TELL
+"He stares down at you with rheumy eyes.  \"Oh blessed Virgin!  The senor
+is real!\"  His words become a jumble of Japanese and Latin and
+Spanish.  His head twitches.  \"The senor is real?\" he asks again.  ">)>>
+
+<ROUTINE DOMINGO-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<DOMINGO-STARES>
+		<COND (<AND <EQUAL? ,QCONTEXT ,DOMINGO>
+			    <FSET? ,DOMINGO ,SCOREBIT>
+			    <VERB? YES NO>>
+		       <COND (<VERB? YES>
+			      <SETG DELAY-CNT 5>
+			      <TELL
+"\"The devil is testing me!  He sends me a fellow Christian, and then he
+transforms him into a heretic!\"" CR>)
+			     (ELSE
+			      <TELL
+"\"Then show me you are of our Empire!  The senor is a German, perhaps?
+Speak Spanish and prove to me you are a subject of the King!\"" CR>)>)
+		      (<VERB? YES NO>
+		       <TELL
+"He seems oblivious to your answer, listening only to what language
+you are speaking." CR>)
+		      (<AND <P? BE (ME BLACKTHORNE)> ,PRSI>
+		       <COND (<ENGLISH?>
+			      <PERFORM ,V?SPEAK ,ENGLISH>
+			      <RTRUE>)
+			     (<DUTCH?>
+			      <PERFORM ,V?SPEAK ,DUTCH>
+			      <RTRUE>)
+			     (<SPANISH?>
+			      <TELL
+"\"I can tell you aren't Spanish, senor.\"" CR>)
+			     (<PORTUGUESE?>
+			      <PERFORM ,V?SPEAK ,PORTUGUESE>
+			      <RTRUE>)
+			     (ELSE
+			      <TELL
+"He doesn't seem too excited to hear this." CR>)>)
+		      (<FSET? ,DOMINGO ,SCOREBIT>
+		       <TELL
+"He seems to ignore what you say, only listening to the sound of the language
+itself." CR>)
+		      (<OR <P? WHO (YOU DOMINGO)>
+			   <VERB? HELLO>>
+		       <FCLEAR ,DOMINGO ,AN>
+		       <NEW-SDESC ,DOMINGO "Friar Domingo">
+		       <TELL
+"\"I'm Friar...  Friar Domingo...  Domingo of the Sacred Order of St.
+Francis.  I came here to teach the heathen, to bring them to the light,
+but Jesuits put me here, Jesuits poured filth into the ears of the
+Taiko!\"" CR>)
+		      (<P? HELP (ME BLACKTHORNE)>
+		       <TELL
+"\"Only God can help us, senor.\"" CR>)
+		      (<P? FIND ;WHERE (ME BLACKTHORNE)>
+		       <TELL
+"\"This is the prison, senor.  All here await their fate.\"" CR>)
+		      (<OR <P? TEACH (ME BLACKTHORNE) (<> JAPANESE)>
+			   <AND <JAPANESE-VERB?>
+				<G? <GETP ,JAPANESE ,P?COUNT> 0>>>
+		       <QUEUE I-TEACH 2>
+		       <I-TEACH T>
+		       <RTRUE>)
+		      (<AND <QUESTION-VERB?>
+			    <NOT <FSET? ,JAPAN ,RMUNGBIT>>>
+		       <DOMINGO-OFFERS-HELP>)
+		      (<VERB? TELL-ME-ABOUT WHO WHAT>
+		       <COND (<PRSO? ,MADMAN ,CRAZY>
+			      <TELL
+"\"Everyone here believes that madness is caused only by "I"kami"", who
+are evil, malicious spirits.  Thus, madmen, like children and the very
+old, are not responsible for their actions and have special privileges.\"">)
+			     (<PRSO? ,SUICIDE>
+			      <TELL
+"\"A sin against God, senor!  They are so touchy, so pride-filled, that
+if they are thwarted, or if they cannot do their duty, they will kill
+themselves.  They'll do it if their liege orders it, in a wink.  A heinous
+sin!\"">)
+			     (<PRSO? ,PRISON>
+			      <TELL
+"\"The Japanese didn't have prisons until recently.  Only the guilty
+come here.  For just a little while.\"">)
+			     (<PRSO? ,GLOBAL-SAMURAI>
+			      <TELL
+"\"Samurai means 'servant,' but they are fierce warriors who serve their
+heathen masters.  Men and women, too, are samurai.  They own everything,
+they are everything, but some have seen the
+light!\"">)
+			     (<PRSO? ,JESUITS>
+			      <TELL
+"\"Their lies put me here and caused twenty-six Holy Fathers to be
+martyred!  Does the senor know that Jesuits are merely traders, gun runners,
+and usurers?  That they control all the silk trade here, all trade with
+China?  That the annual Black Ship is worth a million in gold?  That they've
+forced His Holiness, the Pope, to grant them total power over Asia --
+them and their dogs, the Portuguese?  That all other religions are forbidden
+here?  That they secretly smuggled guns into Japan for Christian kings here,
+inciting them to rebellion?\"">)
+			     (<PRSO? ,CHURCH ,GOD>
+			      <TELL
+"\"My son, you must want to make your confession.  I will be glad to help
+you.\"">)
+			     (<PRSO? ,SATAN>
+			      <TELL
+"\"He tests me constantly!  I fight, but it's so difficult!\"">)
+			     (<PRSO? ,ALVITO>
+			      <TELL
+"\"That Jesuit puppy!  He had the temerity to try to 'intercede' with the
+Taiko when that imp of Satan threatened to ban us from Japan!  As though
+our own priests weren't good enough to speak with that monster!\"">)
+			     (<PRSO? ,BLACK-SHIP>
+			      <TELL
+"\"They're the greatest ships in the world, almost two thousand tons.  I'm
+told they sail well before the wind but lumber when the wind's abeam.  They
+carry twenty or thirty guns.  They are the greatest treasure ships
+in all Asia, carrying the silks of China here to Japan!  The silver alone
+is a fortune beyond calculation!\"">)
+			     (<PRSO? ,DOMINGO ,YOU>
+			      <PERFORM ,V?WHO ,DOMINGO>
+			      <RTRUE>)
+			     (<PRSO? ,JAPAN>
+			      <TELL
+"\"The land was discovered in 1542, senor, the year I was born.  There
+were three men, da Mota, Peixoto, and one other.  They were all
+Portuguese traders, they were blown off course to land in Kyushu.  Soon
+after, the Church sent missionaries to convert the heathen.\"">)
+			     (<PRSO? ,GORODA>
+			      <TELL
+"\"He was a devil!  He conquered all Japan and made a mountain of skulls
+and declared himself Dictator, but still wasn't powerful enough to be
+Shogun!  Then he was assassinated by one of his generals.  Now he burns
+in Hell!\"">)
+			     (<PRSO? ,TAIKO>
+			      <TELL
+"\"He was an ugly little man.  The Jesuits filled his ears with lies.  He
+was Goroda's general, born a peasant, so he could never be Shogun, even
+though he brought the whole of Japan under his devil's rule!  He turned
+against us, and the Hand of God lay heavy on him: a storm smashed his
+great castle.  It was marvelous to behold!  Now he is
+dead and the carrion crows, Toranaga, Ishido and the rest, fight over
+the carcass -- and the filthy Jesuits aren't the least of these!\"">)
+			     (<PRSO? ,KIYAMA>
+			      <TELL
+"\"Lord Kiyama is a good Christian, but under the thumb of the Jesuits!\"">)
+			     (<PRSO? ,SHOGUN>
+			      <TELL
+"\"The Shogun is the Supreme Ruler.  Save for the Emperor himself, he is
+all powerful.  There has been no Shogun for hundreds of years, even the
+Taiko never became Shogun, but Toranaga!  Ah, he would be Shogun if he
+could!\"">)
+			     (<PRSO? ,TORANAGA>
+			      <TELL
+"\"He's a sly one.  Vicious and sly as a snake, subtle as a fox!\"">)
+			     (<PRSO? ,ISHIDO>
+			      <TELL
+"\"He hates the Church, but he hates us all, Jesuit and Franciscan
+alike!  An evil man.\"">)
+			     (<PRSO? ,SPAIN>
+			      <TELL
+"\"Ah, Spain!  My village is outside Madrid, senor, in the mountains.  It
+is called Santa Veronica.\"">)
+			     (<PRSO? ,BULLDOG>
+			      <TELL "\"">
+			      <COND (<NOT <NOUN-USED? ,PRSO ,W?GONZALEZ>>
+				     <TELL
+"His name is Gonzalez, senor.  ">)>
+			      <TELL "He is one of us.\"">)
+			     (<FSET? ,PRSO ,PERSON>
+			      <TELL
+"\"I know nothing of " HIM/HER ,PRSO ", senor.\"">)
+			     (<FSET? ,JAPAN ,RMUNGBIT>
+			      <TELL
+CTHE ,DOMINGO " seems to have lost the thread of your question.  "
+<PICK-ONE ,DOMINGO-RAMBLES> CR>
+			      <RTRUE>)>
+		       <COND (<NOT <FSET? ,JAPAN ,RMUNGBIT>>
+			      <TELL "">
+			      <DOMINGO-OFFERS-HELP>)
+			     (ELSE <CRLF>)>)
+		      (<PROB 60>
+		       <TELL
+CTHE ,DOMINGO " doesn't seem to be listening.  He mutters something irrelevant.  " <PICK-ONE ,DOMINGO-RAMBLES>
+CR>)
+		      (ELSE
+		       <TELL
+"His mind seems to have wandered.  In any case, he doesn't respond." CR>)>)
+	       (<AND <NOT <SCENE? S-PRISON>>
+		     <NOT <ABSTRACT-VERB?>>>
+		<TELL
+"Father Domingo isn't here." CR>
+		<COND (<VERB? TELL> <END-QUOTE> <RFATAL>)
+		      (ELSE <RTRUE>)>)
+	       (<VERB? LIE>
+		<TELL
+"Volunteer nothing, but don't lie." CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"He is a toothless old man with long filthy hair and a matted beard and
+broken nails.  He wears a foul, threadbare smock.  In one hand he carries
+a wooden cross." CR>)
+	       (<HOSTILE-VERB?>
+		<TELL
+"You can't bring yourself to hurt this saintly, if slightly addled,
+man.  He may be a hated Spaniard, but he has made a place for himself
+in this hell." CR>)>>
+
+<ROUTINE DOMINGO-OFFERS-HELP ()
+	 <FSET ,JAPAN ,RMUNGBIT>
+	 <TELL
+"He is very excited.  \"If the senor has never been to Asia before, he will
+be like a child in the wilderness.  I will teach you!  I will tell you
+all the secrets you will need to survive!\"" CR>>
+
+<CONSTANT DOMINGO-RAMBLES
+	  <LTABLE 0
+"\"The Japanese truly have but one punishment -- death.  They have almost
+no other punishment.  Imprisonment is not one of their punishments, my
+son.  To them, prison is just a temporary place to keep the man until they
+decide his sentence.  Only the guilty come here.\""
+"\"Jesuits put me here, my son.  Jesuits and their filthy lies.\""
+"\"Thy ship was Spanish out of where?  I'm so glad!  The senor is from
+Spanish Flanders?  Or the Duchy of Brandenburg?  Some part of our
+Dominions in Germania?\""
+"\"Oh, it's so good to talk the blessed mother tongue again.\""
+"\"These men are my flock, senor.  They are all my sons in the Blessed
+Lord Jesus.  I've converted so many here!\""
+"\"I was put here in September -- it was in the year of our Lord
+fifteen hundred ninety eight.\"  You realize with a shock that this was
+almost two years ago!  Two years in this filthy hole!">>
+
+<ROUTINE I-TEACH ("OPT" (P? <>) "AUX" CNT)
+	 <COND (<IN? ,DOMINGO ,HERE>
+		<QUEUE I-TEACH -1 T>
+		<COND (<OR .P? <NOT <P? TEACH ME JAPANESE>>>
+		       <PUTP ,JAPANESE ,P?COUNT
+			     <SET CNT <+ <GETP ,JAPANESE ,P?COUNT> 1>>>
+		       <COND (<NOT .P?> <CRLF>)>
+		       <TELL "\"">
+		       <COND (<JAPANESE-VERB?>
+			      <TELL
+"Very good, my son!  ">)>
+		       <COND (<EQUAL? .CNT 1>
+			      <TELL
+"Ah, Japanese!  It's a devil's own language for us, but they find our
+languages as hard, or worse!  The first thing you must know is to be polite,
+always polite, even when you're spitting in their eyes.  '"I"Domo"",' that's
+the first word to know.  It means 'thank you,' sometimes you say '"I"arigato""'
+as well, '"I"domo arigato"".'\"" CR>
+			      <SCORE-OBJECT ,JAPANESE>)
+			     (<EQUAL? .CNT 2>
+			      <TELL
+"To greet someone politely, you say '"I"Konnichi wa.""'  It means 'How
+are you?'  To say you are well, you say '"I"Domo, genki desu"".'\"" CR>)
+			     (<EQUAL? .CNT 3>
+			      <COND (<IN? ,BULLDOG ,HERE>
+				     <TELL
+"That man over there, he tells me he">)
+				    (ELSE
+				     <TELL "That man who">)>
+			      <TELL " helped you.  His name is Gonzalez,
+but before he became a Christian he was Akabo.  It just means 'porter,'
+senor.  They don't have names.  Only samurai have names.\"" CR>)
+			     (<EQUAL? .CNT 4>
+			      <REPLACE-SYNONYM ,GLOBAL-WATER ,W?WATER ,W?MIZU>
+			      <TELL
+"As '"I"domo""' is 'thank you,' '"I"dozo""' is 'please.' 'Water' is '"I"mizu"".'\"" CR>)
+			     (<EQUAL? .CNT 5>
+			      <TELL
+"'"I"Gomen nasai""' is 'sorry,' remember the Japanese put a great price on
+manners and courtesy!\"" CR>)
+			     (<EQUAL? .CNT 6>
+			      <TELL
+"'"I"Nihon go ga hanase-masen""' is 'I don't speak Japanese,' and yes, you
+must apologize, so you say '"I"gomen nasai""' as well.  The daimyos are
+prideful and as touchy as wasps, but courteous, ah, so courteous!\"" CR>)
+			     (ELSE
+			      <DEQUEUE I-TEACH>
+			      <TELL
+"It is so good to teach, senor!\"  Domingo continues to teach you simple
+words and phrases.  The old man is
+lonely, and proud of his knowledge, and his success in converting the
+prisoners." CR>)>)>)
+	       (ELSE
+		<DEQUEUE I-TEACH>
+		<RFALSE>)>>
+
+<OBJECT MADMAN
+	(DESC "madman")
+	(SYNONYM MADMAN MAN)
+	(ADJECTIVE CRAZY MAD INSANE POSSESSED)
+	(FLAGS PERSON JAPANESEBIT)
+	(GENERIC GENERIC-CRAZY-F)
+	(ACTION MADMAN-F)>
+
+<ROUTINE GENERIC-CRAZY-F (R F)
+	 <COND (<SCENE? ,S-PRISON> ,MADMAN)
+	       (ELSE ,CRAZY)>>
+
+<ROUTINE MADMAN-F ("OPT" RARG)
+	 <COND (<RARG? WINNER>
+		<TELL
+"He laughs insanely, pointing his finger and making faces." CR>
+		<END-QUOTE>)
+	       (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? <>>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"He's wild-eyed and drooling.  You shudder.  Is this your fate?  Will
+you ever be released?" CR>)
+		      (<HOSTILE-VERB?>
+		       <TELL
+"The other prisoners stop you, indicating that he is not to be hurt." CR>)>)>>
+
+<ROUTINE I-MADMAN ()
+	 <COND (<IN? ,MADMAN ,HERE>
+		<MOVE ,MADMAN ,GENERIC-OBJECTS>
+		<TELL CR
+"The madman capers away, singing and drooling.  You lose sight of him in
+the crowd of prisoners." CR>)
+	       (ELSE
+		<MOVE ,MADMAN ,HERE>
+		<QUEUE I-MADMAN 3>
+		<TELL CR
+"Suddenly the crowd of prisoners parts and a naked, filthy prisoner
+comes into view.  He is singing something noisy and incomprehensible.  He
+starts to dance a wild capering dance.  The man is obviously crazy,
+but no one hurts him or kicks him aside, even when he accidentally knocks
+over a cup of food.  Father Domingo makes the sign of the cross and
+shakes his head." CR>)>>
+
+<ROUTINE I-BULLDOG ()
+	 <REMOVE ,BULLDOG>
+	 <TELL CR
+"The iron door of the cell swings open.  Guards begin to call names from
+a list.  The man who befriended you is one of those called.  One of
+Domingo's followers is also among those called.  He kneels before Domingo,
+who gives him the sign of the cross and the Last Sacrament.  He walks
+away, and the door closes again.|
+|
+\"His Calvary is outside the door,\" says Domingo." CR>>
+
+<ROUTINE I-OUT-OF-PRISON ()
+	 <COND (<NOT <QUEUED? I-TEACH>>
+		<TIME-PASSES>
+		<TELL CR
+"For three days and three nights, you ">
+		<COND (<AND <IN? ,DOMINGO ,HERE>
+			    <NOT <ZERO? <GETP ,JAPANESE ,P?COUNT>>>>
+		       <TELL "fill your mind with facts and
+Japanese words and phrases.  For three days and three nights you sit
+with Father Domingo and question and listen and learn and sleep in
+nightmare.">)
+		      (ELSE
+		       <TELL "endure the hell of the prison.">)>
+		<TELL "|
+|
+Then, on the fourth day, they call out your name.|
+|
+\"Anjin-san!\"">
+		<COND (<IN? ,DOMINGO ,HERE>
+		       <TELL "|
+|
+\"Thy confession, my son, say it quickly,\" cries Father Domingo.|
+|
+\"Go with God, Father\" you reply, and the door slams behind you.">)>
+		<CRLF><CRLF>
+		<GOTO ,PRISON-COURTYARD>)
+	       (ELSE
+		<QUEUE I-OUT-OF-PRISON 1>
+		<RFALSE>)>>
+
+<ROOM PRISON-COURTYARD
+      (LOC ROOMS)
+      (DESC "Prison Courtyard")
+      (IN TO PRISON IF IRON-DOOR IS OPEN)
+      (WEST TO PRISON IF IRON-DOOR IS OPEN)
+      (EAST TO OUTSIDE-PRISON IF PRISON-GATE IS OPEN)
+      (FLAGS ONBIT)
+      (GLOBAL LG-LINE LG-MEN PRISON-GATE)
+      (THINGS <> PRISONER PRISONER-PSEUDO
+	      <> PRISONERS PRISONER-PSEUDO)
+      (ACTION PRISON-COURTYARD-F)>
+
+<ROUTINE PRISON-COURTYARD-F (RARG)
+	 <COND (<RARG? LOOK>
+		<TELL
+"This is a courtyard with great doors to the east.  A line of naked
+prisoners stands before an official in a somber kimono." CR>)
+	       (<RARG? BEG>
+		<COND (<AND <P? WALK P?EAST>
+			    <NOT <FSET? ,LG-LINE ,RMUNGBIT>>>
+		       <TELL "The jailers ">
+		       <COND (<FSET? ,LG-LINE ,SCOREBIT>
+			      <TELL
+"and your escort prevent you from leaving." CR>)
+			     (ELSE
+			      <TELL
+"roughly prod you back into line." CR>)>)>)
+	       (<RARG? ENTER>
+		<QUEUE I-LEAVE-PRISON -1>
+		<MOVE ,DOMINGO ,GENERIC-OBJECTS>
+		<MOVE ,GRAYS ,HERE>
+		<THIS-IS-IT ,GRAYS>
+		<TELL
+"The air is incredibly cool and sweet, the clouds meandering before a fine
+southeasterly wind.  You gulp deep draughts of the clean, glorious air.  The
+joy of life fills you." CR CR>)>>
+
+<OBJECT OFFICIAL
+	(LOC PRISON-COURTYARD)
+	(DESC "official")
+	(SYNONYM OFFICIAL)
+	(ADJECTIVE SOMBER)
+	(FLAGS NDESCBIT PERSON JAPANESEBIT)
+	(ACTION OFFICIAL-F)>
+
+<ROUTINE OFFICIAL-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<WAKARIMASEN>)
+	       (<RARG? <>>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"The official is dressed in a somber kimono and an overmantle with starched,
+winglike shoulders." CR>)>)>>
+
+<ROUTINE I-LEAVE-PRISON ()
+	 <ZLINES ,LEAVE-CNT
+		 (DELAY
+		  <COND (<FSET? ,LG-LINE ,SCOREBIT>
+			 <COND (<G? ,DELAY-CNT 3>
+				<FCLEAR ,LG-LINE ,SCOREBIT>
+				<TELL CR
+"A jailer shoves you to the ground, then kicks you into line
+with a stream of invective." CR>
+				<RTRUE>)
+			       (ELSE
+				<TELL CR
+"One of the jailers prods you roughly toward the line." CR>
+			 <RTRUE>)>)>)
+		 (<TELL CR
+"The official stands in front of the first prisoner and reads from a
+delicate scroll.  As he finishes, each man begins to plod after his
+party of jailers toward the great doors of the courtyard." CR>)
+		 (<MOVE ,KIMONO ,BLACKTHORNE>
+		  <MOVE ,SOCKS ,BLACKTHORNE>
+		  <MOVE ,SANDALS ,BLACKTHORNE>
+		  <FSET ,LG-LINE ,RMUNGBIT>
+		  <FSET ,PRISON-GATE ,OPENBIT>
+		  <THIS-IS-IT ,CLOTHES>
+		  <TELL CR
+"You reach the front of the line.  Unlike the others, you are given
+clean clothes to wear.  Your
+guards are samurai, and they motion you to put on the clothes." CR>)
+		 (DELAY
+		  <COND (<HERE? PRISON-COURTYARD>
+			 <TELL CR
+"Your guards hustle you towards the gate." CR>
+			 <COND (<G? ,DELAY-CNT 1>
+				<CRLF>
+				<GOTO ,OUTSIDE-PRISON>)>
+			 <RTRUE>)>)
+		 (1)
+		 (<TELL CR
+"One man is already roped to his cross and the cross is being lifted
+into the sky.  Beside each cross two "I"eta"" wait, their long lances
+sparkling in the sun.|
+|
+The samurai jostle closer, hurrying you.  You prepare to lunge for
+the nearest sword, thinking numbly that it would be better to die now,
+quickly.  But suddenly they are turning away from the arena, heading
+toward the paths that lead through the woods to the city and the
+castle!" CR CR>
+		  <MOVE ,GRAYS ,DEEP-WOODS>
+		  <GOTO ,DEEP-WOODS>)
+		 (<TELL CR
+"When you are deep in the woods, another party of thirty-odd Grays
+approaches from around a curve ahead.  The two parties of Grays greet
+each other, and then, just as the new group is preparing to leave, their
+leader calmly pulls out his sword and impales the leader of your
+samurai.  The ambush is so sudden that all your escort is dead almost
+in the same instant.  Not one has even had time to draw his sword." CR>
+		  <REMOVE ,GRAYS>
+		  <MOVE ,BANDITS ,HERE>
+		  <MOVE ,BANDIT-LEADER ,HERE>
+		  <TELL CR
+"At a command from the leader, these new Grays strip off their uniform
+kimonos.  Underneath they wear a motley collection of rags and ancient
+kimonos.  All pull on masks.  The bandit leader smiles and motions you
+to begin walking back toward the city." CR>)
+		 (<MOVE ,BROWNS ,HERE>
+		  <MOVE ,GRAYS ,HERE>
+		  <MOVE ,GRAY-CAPTAIN ,HERE>
+		  <MOVE ,YABU ,YABU-PALANQUIN>
+		  <MOVE ,YABU-PALANQUIN ,HERE>
+		  <TELL CR
+"Suddenly there are noises ahead and another party of samurai rounds
+the bend.  Browns and Grays, the Browns the vanguard, their leader in
+a palanquin.  Both groups move into skirmish positions, eyeing each
+other hostilely." CR>
+		  <MOVE ,YABU ,HERE>
+		  <SETG DODGED? <>>
+		  <SETG OPPONENT ,BANDIT-LEADER>
+		  <TELL CR
+"The man in the palanquin gets down and you recognize him.  It is Kasigi
+Yabu!  He shouts at the bandit leader but the man shakes his sword furiously,
+ordering them out of the way.  Yabu gives a curt order, and charges with
+a screaming battle cry, limping slightly.  The bandit guarding you
+swings his sword at you!" CR>)
+		 (<REMOVE ,BANDITS>
+		  <REMOVE ,BANDIT-LEADER>
+		  <SETG OPPONENT <>>
+		  <COND (<NOT ,DODGED?>
+			 <TELL CR
+"The bandit leader's sword plunges into you.  As a red mist comes
+over your sight, Yabu, enraged, tries to avenge you, but his leg
+slows him." CR>)>
+		  <TELL CR
+"The bandit leader turns and flees, his men following.  The Browns and
+Grays are quickly beside you.  Some scramble after the fleeing bandits
+into the bushes.  Yabu stops at the edge of the brush, shouts orders
+imperiously, then comes back slowly, his limp more pronounced." CR>
+		  <COND (<NOT ,DODGED?> <JIGS-UP>)>)
+		 (<FSET ,YABU-PALANQUIN ,SCOREBIT>
+		  <TELL CR
+"None of the bandits are captured.  Yabu and the Gray leader begin to
+argue, Yabu pointing to the castle, and the Gray to the woods.  You
+hear the word "I"shunjin"", which you know to mean 'prisoner.'  They
+are trying to decide what to do with you!  To return you to Toranaga
+at the castle, or send you on with the Grays to Ishido.|
+|
+Yabu motions you to get into the palanquin.  The Gray captain says,
+\""I"Iye!""\"" CR>)
+		 (DELAY
+		  <COND (<NOT <IN? ,BLACKTHORNE ,YABU-PALANQUIN>>
+			 <TELL CR
+"Yabu points to the palanquin.  The Gray captain violently disagrees,
+saying, \""I"Iye!""\"" CR>
+			 <RTRUE>)>)
+		 (<DEQUEUE I-LEAVE-PRISON>
+		  <RFALSE>)>>
+
+<OBJECT BANDIT-LEADER
+	(DESC "bandit leader")
+	(SYNONYM BANDIT LEADER RONIN)
+	(ADJECTIVE BANDIT)
+	(FLAGS PERSON JAPANESEBIT)
+	(GENERIC GENERIC-BANDIT-F)
+	(ACTION BANDIT-LEADER-F)>
+
+<ROUTINE GENERIC-BANDIT-F (R F)
+	 <COND (<EQUAL? ,BANDIT-LEADER ,OPPONENT> ,BANDIT-LEADER)
+	       (ELSE ,BANDITS)>>
+
+<ROUTINE BANDIT-LEADER-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<TELL G"He doesn't respond." CR>)
+	       (<RARG? <>>
+		<COND (<VERB? FOLLOW>
+		       <TELL
+"You bow in agreement and prepare to follow the bandits." CR>)>)>>
+
+<OBJECT BANDITS
+	(DESC "bandits")
+	(SYNONYM BANDITS RONIN BANDIT ATTACKER ATTACKERS)
+	(FLAGS PERSON JAPANESEBIT PLURAL SCOREBIT)
+	(GENERIC GENERIC-BANDIT-F)
+	(ACTION BANDITS-F)>
+
+<ROUTINE BANDITS-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<TELL "They don't respond." CR>)>>
+
+<OBJECT YABU-PALANQUIN
+	(OWNER YABU)
+	(DESC "palanquin")
+	(SYNONYM PALANQUIN LITTER)
+	(FLAGS VEHBIT OPENBIT CONTBIT SEARCHBIT)
+	(CAPACITY 100)
+	(GENERIC GENERIC-LITTER-F)
+	(ACTION YABU-PALANQUIN-F)>
+
+<ROUTINE YABU-PALANQUIN-F ("OPT" (RARG <>))
+	 <COND (<RARG? BEG>
+		<COND (<VERB? SIT>
+		       <TELL G"You are already sitting down." CR>)>)
+	       (<RARG? <>>
+		<COND (<VERB? BOARD>
+		       <COND (<FIRST? ,PRSO>
+			      <TELL
+"There's someone using it already." CR>)
+			     (<FSET? ,YABU-PALANQUIN ,SCOREBIT>
+			      <TELL
+"You speak in halting Japanese, knowing the words to be ungrammatical,
+but hoping they will be understood, \"I friend.  Not prisoner.  Want
+bath.  Tired.  Hungry.  Bath.\"  You point to the castle.  \"Go
+there!  Now, please.  Lord Toranaga.  Go now.\"  You get awkwardly into the
+palanquin and lay down on the cushions, your feet sticking far out.|
+|
+Then Yabu laughs, and everyone joins in.  He bows mockingly.  \"Ah so,
+Anjin-sama!\"|
+|
+\"Iye, Yabu-sama.  Anjin-san.\"" CR>
+			      <SCORE-OBJECT ,YABU-PALANQUIN>
+			      <NEXT-SCENE>)
+			     (ELSE
+			      <TELL "No one will let you in it." CR>)>)>)>>
+
+<ROOM DEEP-WOODS
+      (LOC ROOMS)
+      (DESC "Deep in the Woods")
+      (FLAGS ONBIT)
+      (WEST TO OUTSIDE-PRISON)
+      (EAST PER DEEP-WOODS-EXIT)
+      (GLOBAL LG-CASTLE CITY)
+      (ACTION DEEP-WOODS-F)>
+
+<ROUTINE DEEP-WOODS-EXIT ("OPT" (RARG <>) (STRICT? <>))
+	 <COND (.RARG <RFALSE>)
+	       (ELSE
+		<COND (<IN? ,BANDITS ,HERE>
+		       <TELL "The bandits"G" have you surrounded." CR>)
+		      (<IN? ,YABU ,HERE>
+		       <TELL "Yabu stops you and points toward the city." CR>)
+		      (<IN? ,BROWNS ,HERE>
+		       <TELL "The Grays"G" have you surrounded." CR>)
+		      (ELSE
+		       <TELL "The escort won't let you get ahead of the party." CR>)>
+		<RFALSE>)>>
+
+<ROUTINE DEEP-WOODS-F (RARG)
+	 <COND (<RARG? LOOK>
+		<TELL
+"This is a wide track deep in the woods.  There are tall trees and
+a well-tended sward which feels soft underfoot.  The castle is to the
+west and the path continues to the east." CR>)
+	       (<RARG? BEG>
+		<COND (<VERB? SIT>
+		       <TELL
+"You are rudely jerked to your feet." CR>)
+		      (<OR <P? WALK P?WEST>
+			   <P? WALK-TO (LG-CASTLE CITY)>>
+		       <COND (<IN? ,BANDITS ,HERE>
+			      <TELL
+"You start back toward the city, walking as slowly as possible." CR>)
+			     (ELSE
+			      <TELL
+G"No one will let you leave the party." CR>)>)
+		      (<AND <EQUAL? ,OPPONENT ,BANDIT-LEADER>
+			    <NOT ,DODGED?>
+			    <MOTION-VERB?>>
+		       <SETG DODGED? T>
+		       <TELL
+"With all your remaining strength you jerk away from the bandit and
+roll to one side.  His sword slashes down, but he misses." CR>
+		       <SCORE-OBJECT ,BANDITS>)
+		      (<AND <FSET? ,YABU-PALANQUIN ,SCOREBIT>
+			    <P? POINT LG-CASTLE>>
+		       <PERFORM ,V?BOARD ,YABU-PALANQUIN>
+		       <RTRUE>)>)>>
+
+<OBJECT LG-CASTLE
+	(LOC LOCAL-GLOBALS)
+	(DESC "Osaka castle")
+	(SYNONYM CASTLE)
+	(ADJECTIVE OSAKA)>
+
+<OBJECT PRISON-GATE
+	(LOC LOCAL-GLOBALS)
+	(DESC "prison gate")
+	(SYNONYM GATE)
+	(ADJECTIVE PRISON)
+	(FLAGS DOORBIT TRYTAKEBIT)
+	(ACTION PRISON-GATE-F)>
+
+<ROUTINE PRISON-GATE-F ()
+	 <COND (<VERB? OPEN CLOSE>
+		<TELL
+"The jailers would not appreciate your usurping their job." CR>)>>
+
+<ROUTINE CROWD-PSEUDO ()
+	 <TELL "The crowd ignores you." CR>>
+
+<ROOM OUTSIDE-PRISON
+      (LOC ROOMS)
+      (DESC "Outside Prison")
+      (WEST TO PRISON-COURTYARD IF PRISON-GATE IS OPEN)
+      (FLAGS ONBIT OUTSIDE)
+      (THINGS LARGE CROWD CROWD-PSEUDO
+	      SPRUCE CROWD CROWD-PSEUDO
+	      <> PRISONER PRISONER-PSEUDO
+	      <> PRISONERS PRISONER-PSEUDO)
+      (ACTION OUTSIDE-PRISON-F)>
+
+<ROUTINE OUTSIDE-PRISON-F (RARG)
+	 <COND (<RARG? LOOK>
+		<TELL
+"Prisoners are being executed here.  A large, spruce crowd looks on,
+crimson and yellow with golden sunshades." CR>)
+	       (<RARG? BEG>
+		<COND (<P? WALK P?WEST>
+		       <TELL
+"Your escort refuses to let you return to the prison." CR>)>)
+	       (<RARG? ENTER>
+		<MOVE ,GRAYS ,HERE>
+		<TELL "Your guards keep pace and a wary eye on you." CR CR>)>>
+
+<ROUTINE PRISON-AFTER-F ()
+	 <TELL
+"A bath and massage and two hours of sleep immeasurably refresh you.  The
+bath attendants, all women of girth and strength, pummel you and
+shampoo your hair, and the barber trims your beard.  The futons on which
+you sleep are so clean, like the room.  It all seems dreamlike.  You wait
+impatiently, hoping to be brought to Toranaga again.|
+|
+You know, beyond
+all doubt, because of what Friar Domingo told you about the Portuguese
+and Japanese politics and trade, that you can help Toranaga, who, in
+return, can easily give you the riches and freedom you desire.  There is
+no ship in all Asia like yours, and if Toranaga commands, you can sweep
+the Portuguese and Spanish from the seas with it, make a gift to him of
+the Black Ship, destroy his enemies, anything!" CR>>
+
+<END-SEGMENT>
+
+"S-MARIKO"
+
+<BEGIN-SEGMENT MARIKO>
+
+<ROOM MAPLE-GLADE
+      (LOC ROOMS)
+      (OWNER MAPLE-GLADE)
+      (SCENE S-MARIKO)
+      (AFTER ALVITO-AFTER-F)
+      (SCORE 3)
+      (DESC "Glade of Maples")
+      (FDESC "And at last, Toranaga summons you.")
+      (SYNONYM GLADE MAPLES)
+      (FLAGS ONBIT OUTSIDE SCOREBIT)
+      (GLOBAL DOMINGO PRISON LG-CREWMEN TEA-HOUSE)
+      (ACTION MAPLE-GLADE-F)>
+
+<ROUTINE MAPLE-GLADE-F (RARG)
+	 <COND (<RARG? SCENE-SETUP>
+		<DRESS-BLACKTHORNE>
+		<REPLACE-SYNONYM ,RUTTER ,W?MAP ,W?RUTTER T>
+		<REPLACE-SYNONYM ,SECRET-RUTTER ,W?MAP ,W?RUTTER T>
+		<NEW-SDESC ,MARIKO "woman" T>
+		<REPLACE-SYNONYM ,MARIKO ,W?MARIKO ,W?WOMAN T>
+		<REPLACE-SYNONYM ,MARIKO ,W?TODA ,W?WOMAN T>
+		<REPLACE-ADJECTIVE ,MARIKO ,W?TODA ,W?LADY T>
+		<THIS-IS-IT ,MARIKO>
+		<FCLEAR ,MARIKO ,THE>
+		<NEW-SDESC ,YAEMON "young boy" T>
+		<FCLEAR ,YAEMON ,THE>
+		<FCLEAR ,YAEMON ,NOABIT>
+		<FCLEAR ,YAEMON ,NOTHEBIT>
+		<SETG QCONTEXT ,TORANAGA> ;"so 'konnichi wa' will work"
+		<THIS-IS-IT ,TORANAGA>
+		<MOVE ,YAEMON ,HERE>
+		<MOVE ,MARIKO ,HERE>
+		<MOVE ,TORANAGA ,HERE>
+		<QUEUE I-YAEMON -1>)
+	       (<RARG? LOOK>
+		<TELL
+"This is Toranaga's private garden within Osaka Castle.  You are in
+a glade of maples near a little thatched hut." CR>)
+	       (<RARG? BEG>
+		<COND (<P? (ENTER THROUGH) TEA-HOUSE>
+		       <TELL "That would be very impolite." CR>)
+		      (<P? EXAMINE MARIKO>
+		       <PRE-EXAMINE>
+		       <TELL
+G"You have never seen anyone so petite.  You could pick her up with one hand"
+".  You wonder if she is Toranaga's consort.  What would it be like to have
+such a woman in bed?  You'd be afraid of crushing her.  No, she wouldn't
+break.  There are women in England almost as small.  But not like her." CR>)
+		      (<AND <FSET? ,YAEMON ,SCOREBIT>
+			    <OR <P? ,V?WINK <>>
+				<P? MAKE HEAD>
+				<ACT-CRAZY?>>>
+		       <PERFORM ,V?SMILE ,YAEMON>
+		       <RTRUE>)
+		      (<AND <P? (KONNICHI-WA BOW)
+				(MARIKO TORANAGA YAEMON <>)>
+			    <FSET? ,MAPLE-GLADE ,SCOREBIT>>
+		       <B-SIT>
+		       <COND (<VERB? KONNICHI-WA>
+			      <TELL
+"You use the phrases the old monk taught you.  \""I"Konnichi wa"",\" you
+say.  ">)
+			     (ELSE
+			      <TELL "You bow to ">
+			      <COND (,PRSO <TELL THE ,PRSO>)
+				    (ELSE <TELL D ,TORANAGA>)>
+			      <TELL ".  ">)>
+		       <NEW-SDESC ,MARIKO "Mariko">
+		       <REPLACE-SYNONYM ,MARIKO ,W?WOMAN ,W?MARIKO>
+		       <REPLACE-SYNONYM ,MARIKO ,W?WOMAN ,W?TODA>
+		       <REPLACE-ADJECTIVE ,MARIKO ,W?LADY ,W?TODA>
+		       <COND (<NOT <PRSO? <> ,TORANAGA>>
+			      <TELL "You bow to " D ,TORANAGA " as well.  ">)>
+		       <COND (<VERB? KONNICHI-WA>
+			      <TELL
+"\""I"Konnichi wa, Toranaga-sama.""\"  You gather
+your kimono around you and sit.  \""I"Gomen nasai, Toranaga-sama, nihon go ga
+hanase-masen.  Tsuyaku go imasu ka?""\"|
+|
+The woman looks surprised.  \"">
+			      <COND (<NOT <FSET? ,HERE ,RMUNGBIT>>
+				     <FSET ,HERE ,RMUNGBIT>
+				     <TELL
+"I am your interpreter, senhor,\" she says at once.  \"My name is
+Mariko.  ">)>
+			      <SETG QCONTEXT ,MARIKO>
+			      <SETUP-ANSWER "i learned from">
+			      <TELL "But you
+speak Japanese?\" she asks.  You explain that you know only a few words and
+phrases.  \"My Master wishes to know where you learned your 'few words and
+phrases.'\"" CR>
+			      <SCORE-OBJECT ,MAPLE-GLADE>)
+			     (ELSE
+			      <FSET ,HERE ,RMUNGBIT>
+			      <TELL
+"The woman greets you.  \"My name is Mariko.  I am your interpreter,
+senhor.\"" CR>)>)
+		      (<AND <IN? ,ISHIDO ,HERE>
+			    <OR <P? TELL TORANAGA>
+				<P? (ASK-ABOUT TELL-ABOUT) TORANAGA>>>
+		       <TELL
+"Mariko motions you not to interrupt Toranaga." CR>
+		       <COND (<VERB? TELL> <END-QUOTE>)
+			     (ELSE <RTRUE>)>)
+		      (<P? TELL-ABOUT TORANAGA>
+		       <PERFORM ,V?TELL-ABOUT ,MARIKO ,PRSI>
+		       <RTRUE>) 
+		      (<P? DRAW WORLD>
+		       <TELL
+"You kneel in the sand.  With your finger you begin to draw a crude map, upside
+down so they can see it better.  You sketch boldly.  \"I can draw a more
+accurate map later, with pen and paper.\"  You gesture.  \"This is north and
+south, east and west.  Japan is here, my country's on the other side of the
+world, there.  This is all unknown and unexplored.\"  Your hand waves away the
+vast expanse of western North America, the interior of South America, all Asia
+north and east of Muscovy, and inland Africa.  \"We know the coastlines, but
+little else.  The interiors are almost entirely mysteries.\"" CR>)
+		      (<P? BOW ISHIDO>
+		       <COND (<FSET? ,ISHIDO ,RMUNGBIT>
+			      <TELL
+"You copy the Japanese.  Toranaga seems impressed." CR>)
+			     (ELSE
+			      <TELL
+"You bow to Ishido, but he ignores you." CR>)>)>)>>
+
+<ROUTINE HOW-I-LEARNED ()
+	 <SETG QCONTEXT <>>
+	 <SETUP-ANSWER <>>
+	 <TELL
+"\"There was a monk in the prison, senhorita, a Francisan monk, and he taught
+me.  Things like 'food, friend, bath, go, come, true, false,' and so on.  Would
+you please tell Lord Toranaga that I'm better prepared now to answer his
+questions, to help, and more than a little pleased to be out of prison.  For
+which I thank him.\"" CR>>
+
+<GLOBAL MARIKO-IMPATIENT 0>
+<GLOBAL YAEMON-BORED? 0>
+
+<ROUTINE I-YAEMON ()
+	 <COND (<FSET? ,YAEMON ,SCOREBIT>
+		<COND (<OR <EQUAL? ,YAEMON-CNT 1>
+			   <AND <G? ,YAEMON-CNT 1>
+				<PROB 67>>>
+		       <SETG YAEMON-BORED? T>
+		       <TELL CR
+CTHE ,YAEMON " seems bored with you.  He reminds you of your own son when
+the talk of adults becomes too serious.  ">
+		       <COND (<PROB 50>
+			      <TELL "He yawns." CR>)
+			     (ELSE
+			      <TELL "His attention is drifting." CR>)>)>)>
+	 <COND (<EQUAL? ,QCONTEXT ,MARIKO>
+		<SETG MARIKO-IMPATIENT <+ ,MARIKO-IMPATIENT 1>>
+		<COND (<G? ,MARIKO-IMPATIENT 1>
+		       <TELL CR
+"\"Please answer, senhor.  My Master grows impatient.\"" CR>
+		       <RTRUE>)
+		      (ELSE
+		       <RFALSE>)>)>
+	 <ZLINES ,YAEMON-CNT
+		 (DELAY
+		  <COND (<FSET? ,MAPLE-GLADE ,SCOREBIT>
+			 <COND (<EQUAL? ,DELAY-CNT 1>
+				<TELL CR
+"The three Japanese are watching you.  The woman is curious but nervous,
+Toranaga is like a hawk watching a rabbit, and the boy stares at you as he
+would stare at a fabulous monster.  It's exactly what your own son, so
+far away in England, would do.  ">)
+			       (ELSE
+				<TELL CR
+"The three Japanese continue to watch you.  ">)>
+			 <TELL "What was the polite phrase the old monk
+taught you?  You try to remember." CR>
+			 <RTRUE>)>)
+		 (<THIS-IS-IT ,MARIKO>
+		  <TELL CR
+"Mariko begins to ask you questions.  Where you were born, whether you are
+married, where you lived in England.  She is not as good an interpreter as
+Father Alvito, but she is more pleasant to talk to, and beautiful.  At one
+point you compliment her on her flawless grasp of Portuguese, and she
+blushes, fluttering her fan." CR>)
+		 (<THIS-IS-IT ,MARIKO>
+		  <THIS-IS-IT ,TORANAGA>
+		  <TELL CR
+"\"My Lord wishes to know about you and your family,\" Mariko
+continues.  \"About your country, its queen and previous rulers, habits,
+customs, and
+history.  Similarly about all other countries, particularly Portugal and
+Spain.  All about the world you live in.  About your ships, weapons, foods,
+trade.  About
+your wars and battles and how to navigate a ship, how you guided your ship
+and what happened on the voyage.  He wants to understand -- Excuse me, why do
+you laugh?\"|
+|
+\"Only because, senhorita,\" you reply, \"that seems to be just about
+everything I know.\"|
+|
+\"That is precisely what my Master wishes.\"" CR>)
+		 (<MOVE ,ISHIDO ,HERE>
+		  <FSET ,ISHIDO ,RMUNGBIT>
+		  <TELL CR
+"Ishido appears at the edge of the glade, bows formally to the young boy,
+and to Toranaga, who looks annoyed at the interruption but bows back." CR>)
+		 (<FCLEAR ,ISHIDO ,RMUNGBIT>
+		  <TELL CR
+"Ishido and Toranaga converse.  Mariko translates for you.  \"Please excuse me,
+Lord Toranaga,\" he says.  \"There is an important matter I wish to see you
+about.  The last formal meeting of the Regents has been postponed.  We do not
+meet tonight at sunset.  Lord Kiyama's sick.  Lord Sugiyama and Lord Onoshi
+have agreed to the delay.  A few days are unimportant, aren't they, on such
+important matters?\"|
+|
+\"When will the meeting be?\" Toranaga asks, seething.  Any delay jeopardizes
+him immeasurably." CR>)
+		 (<TELL CR
+"\"I understand Lord Kiyama should be well tomorrow, or perhaps the next
+day.  His physician has forbidden any visitors.  The disease might be
+contagious.\"  Ishido is very nonchalant, implying the delay could be
+indefinite." CR>)
+		 (<MOVE ,ISHIDO ,GENERIC-OBJECTS>
+		  <MOVE ,PROPHECY ,GENERIC-OBJECTS>
+		  <TELL CR
+"\"I'll visit Lord Kiyama the day after tomorrow,\" Toranaga says, naming a
+deadline.  \"The contagion that will topple me has not yet been born.  Remember
+the soothsayer's prediction!\"|
+|
+\"No, Lord Toranaga, I haven't forgotten,\" Ishido says, remembering very
+well.  He bows again, very deferential to the boy, and leaves." CR>)
+		 (<DEQUEUE I-YAEMON>
+		  <TELL CR
+"Soon the interview is over, and the Heir is sent for his swimming
+lesson.  Toranaga installs you in his own sleeping chamber, as a mark of his
+favor.  Things are looking up, indeed!" CR>
+		  <NEXT-SCENE>)>>
+
+<OBJECT PROPHECY
+	;(LOC GENERIC-OBJECTS)
+	(DESC "prophecy")
+	(SYNONYM PROPHECY PREDICTION)
+	(FLAGS SCOREBIT)>
+
+<OBJECT YAEMON
+	(LOC GENERIC-OBJECTS)
+	(SDESC "Yaemon")
+	(SYNONYM BOY YAEMON HEIR)
+	(ADJECTIVE YOUNG)
+	(FLAGS PERSON NOABIT NOTHEBIT JAPANESEBIT SCOREBIT)
+	(ACTION YAEMON-F)>
+
+<ROUTINE YAEMON-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<WAKARIMASEN>)
+	       (ELSE
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"The boy is small and straight and round-eyed, his full black hair tied into
+a short queue, his pate unshaven.  His curiosity seems enormous." CR>)
+		      (<VERB? SMILE WINK>
+		       <COND (,YAEMON-BORED?
+			      <COND (<FSET? ,YAEMON ,SCOREBIT>
+				     <TELL
+"The boy jumps, then laughs and interrupts Mariko and points and speaks out,
+and everyone listens indulgently and no one hushes him.|
+|
+\"Lord Toranaga asks why you did that, senor?\"|
+|
+You think for a moment and reply, \"Oh, just to amuse the lad.  He's a child
+like any, and children in my country would usually laugh if you did that.  My
+son must be about his age now.  My son's seven.\"|
+|
+\"The Heir is seven,\" Mariko says after a pause." CR>
+				     <SCORE-OBJECT ,YAEMON>)
+				    (ELSE
+				     <TELL
+"There is no response this time." CR>)>)
+			     (ELSE
+			      <TELL
+CTHE ,YAEMON " jumps back, startled." CR>)>)
+		      (<VERB? WHO>
+		       <TELL
+"He is the Heir, the only son of the Taiko, who died a year ago.  The Council
+of Regents is to guide him and rule Japan through his minority." CR>)>)>>
+
+<ROUTINE ALVITO-AFTER-F ()
+	 <TELL
+"Elsewhere in Osaka, Father Alvito reports to his superior, dell'Aqua,
+the Father-Visitor of Asia,
+the most powerful Jesuit and thus the most powerful man in Asia.|
+|
+\"We're already in trouble.  Toranaga began by saying that he understands from
+the Ingeles that incredible profits are being made from the Portuguese monopoly
+of the silk trade with China.  He 'invites' you to report to the Regents on rates
+of exchange.  He does not object to our making a large profit, providing it comes
+from the Chinese.  I'm sorry to tell you that Blackthorne seems to be particularly
+well informed.\"|
+|
+Ferriera, the Spanish Captain of the Black Ship, says coldly, \"The sooner the heretic's
+dead the better.  If the Dutch and English start spreading their filth in Asia we're
+in for trouble!\"|
+|
+\"I regret to tell you, Captain, that Toranaga said that if any harm befalls the
+Ingeles, it's quite possible the Taiko's Expulsion Edicts would be reexamined and
+all Christian churches, schools, places of rest, would be immediately closed.\"" CR>>
+
+<END-SEGMENT>
diff --git a/cartoon.zil b/cartoon.zil
new file mode 100644
index 0000000..5945005
--- /dev/null
+++ b/cartoon.zil
@@ -0,0 +1,29 @@
+<VERSION YZIP>
+
+<SINGLE-FILE? T>
+
+<ROUTINE ANIMATE (CELS)
+	 <REPEAT ()
+		 <SETG CARTOON .CELS>
+		 <SETG CARTOON-N 0>
+		 <INPUT 1 1 ,NEXT-CEL>>>
+
+<GLOBAL CARTOON <>>
+<GLOBAL CARTOON-N 0>
+
+<ROUTINE NEXT-CEL ("AUX" (N <GET ,CARTOON 1>))
+	 <COND (<IGRTR? CARTOON-N <GET ,CARTOON 0>>
+		<SET N 1>)>
+	 <SCREEN 1>
+	 <DISPLAY <GET ,CARTOON .N> 1 1>
+	 <SCREEN 0>
+	 <RFALSE>>
+	 
+<ROUTINE GO
+	 <CLEAR -1>
+	 <SPLIT </ <WINGET 0 ,WHIGH> 4>>
+	 <ANIMATE ,CEL-TABLE>
+	 <QUIT>>
+
+<CONSTANT CEL-TABLE
+	  <LTABLE 1 2 3 4 5 6 7 8>>
diff --git a/cast.zil b/cast.zil
new file mode 100644
index 0000000..eabf424
--- /dev/null
+++ b/cast.zil
@@ -0,0 +1,769 @@
+"CAST for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc.  All Rights Reserved."
+
+<FILE-FLAGS SENTENCE-ENDS?>
+
+<BEGIN-SEGMENT 0>
+
+<CONSTANT J-HEAD 1>
+<CONSTANT J-KILL-MARIKO 2>
+<CONSTANT J-SEPPUKU 3>
+<CONSTANT J-CALL-YABU 4>
+<CONSTANT J-SHOOT-YABU 5>
+<CONSTANT J-ATTACK-ISHIDO 6>
+<CONSTANT J-LAUGH-AT-TORANAGA 7>
+<CONSTANT J-SWITCH 8>
+<CONSTANT J-WRONG-ANSWER 9>
+
+<ROUTINE NEW-SDESC (OBJ STR "OPT" (IMPROPER? <>))
+	 <COND (.IMPROPER?
+		<FSET .OBJ ,THE>
+		<FCLEAR .OBJ ,NOTHEBIT>
+		<FCLEAR .OBJ ,NOABIT>)
+	       (ELSE
+		<FCLEAR .OBJ ,THE>
+		<FSET .OBJ ,NOTHEBIT>
+		<FSET .OBJ ,NOABIT>)>
+	 <PUTP .OBJ ,P?SDESC .STR>>
+
+<ROUTINE WAKARIMASEN ()
+	 <COND (<OR <P? KONNICHI-WA ROOMS>
+		    <P? KONBANWA>>
+		<TELL
+I"\"Domo, genki desu,\"" " " THE ,WINNER " answers politely." CR>)
+	       (<P? NIHON-GO-GA HANASE-MASEN>
+		<TELL
+CTHE ,WINNER " seems to understand, but is at a loss what to say next." CR>)
+	       (<JAPANESE-VERB?>
+		<TELL
+CTHE ,WINNER " seems impressed that you know some Japanese, but apparently
+isn't sure what you are getting at." CR>)
+	       (ELSE
+		<TELL
+"\""I"Wakarimasen, Anjin-san.""\"  " CTHE ,WINNER " doesn't appear to
+understand you." CR>)>>
+
+<VOC "ANJIN" NOUN>
+<VOC "ANJIN-SAN" NOUN>
+
+<OBJECT BLACKTHORNE
+	(LOC BRIDGE-OF-ERASMUS)
+	(OWNER LG-ERASMUS)
+	(DESC "Blackthorne")
+	(SYNONYM JOHN BLACKTHORNE
+		 PILOT PILOT-MAJOR
+		 PILOT ;ANJIN PILOT-MAJOR ;ANJIN-SAN)
+	(ADJECTIVE JOHN)
+	(FLAGS PERSON ENGLISHBIT NOABIT NOTHEBIT OPENBIT CONTBIT SEARCHBIT)
+	(HEALTH 3)	;"0=ERASMUS, 1=ANJIRO, 2=ANJIRO, 3 otherwise"
+	(GENERIC GENERIC-PILOT-F)
+	(ACTION BLACKTHORNE-F)>
+
+<ROUTINE GENERIC-PILOT-F (R F)
+	 <COND (<SCENE? ,S-RODRIGUES> ,RODRIGUES)
+	       (ELSE ,BLACKTHORNE)>>
+
+<ROUTINE BLACKTHORNE-F ("OPT" (RARG <>))
+	 <COND (<RARG? <>>
+		<COND (<P? (BE BE?) (ME BLACKTHORNE)>
+		       <COND (<PRSI? BLACKTHORNE>
+			      <TELL
+"That's correct." CR>)
+			     (<PRSI? ENGLISH>
+			      <TELL
+"That's right, although your mother was Dutch." CR>)>)
+		      (<VERB? BE? BE WHERE HOW>
+		       <RFALSE>)
+		      (<PRSO? BLACKTHORNE>
+		       <PERFORM ,PRSA ,ME ,PRSI>
+		       <RTRUE>)>)
+	       (<RARG? WINNER>
+		<COND (<AND <B-NOT-STANDING?>
+			    <OR <MOTION-VERB?>
+				<AND <HOSTILE-VERB?>
+				     ,OPPONENT
+				     <EQUAL? ,OPPONENT ,PRSO ,PRSI>>
+				<AND <VERB? OPEN CLOSE>
+				     <FSET? ,PRSO ,DOORBIT>>>
+			    <NOT <PAST-TENSE?>>>
+		       <COND (<HERE? ,MURA-HOUSE> <RFALSE>)
+			     (<FSET? <LOC ,WINNER> ,VEHBIT>
+			      <RFALSE>)
+			     (<AND <SCENE? ,S-NINJA>
+				   <FSET? ,MARIKO ,RMUNGBIT>>
+			      <COND (<NOT <IN? ,YABU ,SECRET-REDOUBT>>
+				     <TELL
+"You are too shaken to stand." CR>)
+				    (ELSE
+				     <B-STAND>
+				     <FCLEAR ,BLACKTHORNE ,RMUNGBIT>
+				     <TELL
+"You lurch up, Yabu helping you, and painfully approach Mariko." CR>)>)
+			     (<SCENE? ,S-TORANAGA> <RFALSE>)
+			     (<AND <SCENE? ,S-QUAKE>
+				   <OR ,QUAKE?
+				       <QUEUED? I-CRAWL>>>
+			      <RFALSE>)
+			     (ELSE
+			      <B-STAND>
+			      <TELL "You stand up">
+			      <COND (<OR <P? STAND> <P? WALK ,P?UP>>
+				     <TELL "." CR>)
+				    (ELSE
+				     <TELL " first." CR>)>)>)
+		      (<AND <FSET? ,WINNER ,RMUNGBIT>
+			    <SCENE? ,S-NINJA>>
+		       <COND (<GAME-VERB?> <RFALSE>)
+			     (<AND <NOT <ABSTRACT-VERB?>>
+				   <OR <PRSO? MARIKO>
+				       <PRSI? MARIKO>>>
+			      <YOULL-HAVE-TO "get closer to her">)
+			     (<NOT <PASSIVE-VERB?>>
+			      <TELL
+"The explosion has left you too dazed to do anything." CR>)>)>)>>
+
+<ROUTINE I-DONT-KNOW? ()
+	 <AND <VERB? KNOW>
+	      <EQUAL? ,PRSS ,ME>
+	      <EQUAL? ,PRSQ ,V?DO?>
+	      <NOT <BTST <PARSE-FLAGS ,PARSE-RESULT> ,PARSE-QUESTION>>
+	      <BTST <PARSE-FLAGS ,PARSE-RESULT> ,PARSE-NOT>>>
+
+<OBJECT BOOTS
+	(OWNER BLACKTHORNE)
+	(DESC "your boots")
+	(FDESC "Sitting at the bottom of the steps are your boots.")
+	(SYNONYM BOOTS PAIR)
+	(FLAGS TAKEBIT WEARABLE PLURAL NOTHEBIT NOABIT)
+	(ACTION BOOTS-F)>
+
+<ROUTINE BOOTS-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<SCENE? ,S-ERASMUS>
+		       <TELL
+"They are salt-encrusted and worn." CR>)
+		      (ELSE
+		       <TELL
+"They have been cleaned and shined." CR>)>)
+	       (<VERB? LOOK-INSIDE SMELL>
+		<TELL
+"They are the same boots you've been wearing for two years now.  Let's
+just say they aren't in perfect condition any more." CR>)
+	       (<AND <VERB? TAKE-OFF>
+		     <FSET? ,BOOTS ,WEARBIT>>	
+		<COND (<SCENE? S-ERASMUS>
+		       <TELL
+"You'd be crazy to remove your boots in this weather!" CR>)>)
+	       (<VERB? WEAR>
+		<COND (<AND <NOT <HELD? ,PRSO>>
+			    <NOT <EQUAL? <ITAKE> T>>>
+		       <RTRUE>)
+		      (<NOT <FSET? ,BOOTS ,WEARBIT>>
+		       <FSET ,BOOTS ,WEARBIT>
+		       <TELL
+"You put on your boots." CR>)>)>>
+
+<OBJECT CLOTHES
+	(OWNER BLACKTHORNE)
+	(DESC "your clothes")
+	(SYNONYM CLOTHES)
+	(ADJECTIVE ;MY PILE)
+	(FLAGS TAKEBIT WEARABLE PLURAL NOTHEBIT NOABIT)
+	(ACTION CLOTHES-F)>
+
+<ROUTINE CLOTHES-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<SCENE? ,S-ERASMUS>
+		       <TELL
+"They are filthy, torn, and wet." CR>)
+		      (<NOT <FSET? ,CLOTHES ,TOUCHBIT>>
+		       <TELL
+"They are in a neat pile, washed and pressed and mended with tiny,
+exquisite stitching.  But your knife is gone, and so are your
+keys.  Your boots are nowhere to be found.  Worst of all, there is no sign
+of your precious rutters!" CR>)>)
+	       (<VERB? TAKE>
+		<COND (<AND <SCENE? ,S-ANJIRO>
+			    <L? <GETP ,WINNER ,P?HEALTH> 3>>
+		       <QUEUE I-COLLAPSE 4>
+		       <TELL
+"You are still too weak to stand and go over to the clothes." CR>)>)
+	       (<VERB? WEAR>
+		<COND (<AND <NOT <HELD? ,PRSO>>
+			    <L? <GETP ,WINNER ,P?HEALTH> 3>>
+		       <PERFORM ,V?TAKE ,CLOTHES>
+		       <RTRUE>)
+		      (<AND <NOT <FSET? ,CLOTHES ,WEARBIT>>
+			    <OR <IN? ,CLOTHES ,WINNER>
+				<ITAKE>>>
+		       <FSET ,CLOTHES ,WEARBIT>
+		       <TELL "You ">
+		       <COND (<IN? ,WINNER ,QUILT>
+			      <MOVE ,WINNER ,HERE>)>
+		       <COND (<B-NOT-STANDING?>
+			      <B-STAND>
+			      <TELL "stand shakily and ">)>
+		       <TELL "put on your clothes">
+		       <COND (<NOT <HELD? ,BOOTS>>
+			      <TELL ", feeling strange without your boots">)>
+		       <TELL "." CR>)>)
+	       (<VERB? TAKE-OFF>
+		<COND (<SCENE? S-ERASMUS>
+		       <TELL
+"You would freeze, or at least take a terrible chill." CR>)
+		      (<FSET? ,BOOTS ,WEARBIT>
+		       <YOULL-HAVE-TO "take off your boots">)
+		      (<AND <VERB? TAKE-OFF> <FORMAL-SCENE?>>
+		       <TELL
+"You would expose yourself to ridicule." CR>)
+		      (ELSE
+		       <FCLEAR ,CLOTHES ,WEARBIT>
+		       <TELL
+"You remove your clothes." CR>)>)
+	       (<VERB? TEAR>
+		<COND (<SCENE? ,S-ERASMUS>
+		       <TELL
+"You are in desperate straits, but rending your garments seems like an odd
+reaction." CR>)
+		      (ELSE 
+		       <TELL
+"Your clothes are thick, strong European fabrics and don't tear at all
+easily." CR>)>)>>
+
+<OBJECT SEBASTIO
+	(SDESC "priest")
+	;(DESC "Father Sebastio")
+	(SYNONYM PRIEST SEBASTIO MAN FATHER JESUIT EUROPEAN)
+	(ADJECTIVE FATHER TONSURED)
+	(FLAGS PERSON PORTUGUESEBIT OPENBIT CONTBIT SEARCHBIT NOABIT
+	 THE)
+	(ACTION SEBASTIO-F)>
+
+<ROUTINE SEBASTIO-F ("OPT" (RARG <>) "AUX" OW)
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<P? HELP ME>
+		       <TELL
+"\"Ah, help!\"  he says with icy contempt.  \"Help a heretic pirate!\"" CR>)
+		      (<VERB? HELLO>
+		       <TELL
+CTHE ,SEBASTIO " ignores your greeting." CR>)
+		      (<P? FIND ;WHERE (ME THIS)>
+		       <COND (,YABU-QUESTION
+			      <SPEAK-ONLY-TO-YABU>)
+			     (ELSE
+			      <TELL
+"\"The Japans, pirate.\" the priest says angrily." CR>)>)
+		      (<P? BE THIS JAPAN>
+		       <COND (,YABU-QUESTION
+			      <SPEAK-ONLY-TO-YABU>)
+			     (ELSE
+			      <TELL
+"\"Yes, Japan.  Nippon,\" the priest says impatiently." CR>)>)
+		      (<VERB? WHO>
+		       <COND (<PRSO? YOU>
+			      <COND (,YABU-QUESTION <SPEAK-ONLY-TO-YABU>)
+				    (ELSE
+				     <NEW-SDESC ,SEBASTIO "Father Sebastio">
+				     <TELL
+"\"Father Sebastio.  I'm from Portugal.  I'm a Jesuit.\"" CR>)>)
+			     (<AND <PRSO? ,YABU ,GLOBAL-DAIMYO>
+				   <NOUN-USED? ,PRSO ,W?DAIMYO>>
+			      <TELL
+"\"The "I"daimyo"" is Kasigi Yabu."G" He owns this whole province.\"" CR>)
+			     (<PRSO? ,OMI>
+			      <COND (,YABU-QUESTION <SPEAK-ONLY-TO-YABU>)
+				    (ELSE
+				     <TELL "\"">
+				     <COND (<NOT <FSET? ,OMI ,NOTHEBIT>>
+					    <TELL
+"Who told you about Kasigi Omi-san?  ">)>
+				     <TELL
+"Kasigi Omi-san is the samurai in charge of this village.  He is
+the Lord Yabu's nephew.\"" CR>)>)
+			     (<PRSO? ,MURA>
+			      <COND (,YABU-QUESTION <SPEAK-ONLY-TO-YABU>)
+				    (ELSE
+				     <TELL
+"\"He is the headman of this village.  He, at least, is a good
+Christian.\"" CR>)>)
+			     (ELSE
+			      <TELL
+G"\"I'm not here to answer your questions, pirate!\"" CR>)>)
+		      (<VERB? WHAT>
+		       <COND (<PRSO? YOU>
+			      <PERFORM ,V?WHO ,YOU>
+			      <RTRUE>)
+			     (<PRSO? ,GLOBAL-DAIMYO ,YABU>
+			      <COND (<NOUN-USED? ,PRSO ,W?DAIMYO>
+				     <TELL
+"\"The "I"daimyo"" is a feudal lord."G" He owns this whole province.\"" CR>)
+				    (ELSE
+				     <TELL
+"\"Who told you about " D ,YABU "?\"" CR>)>)
+			     (<PRSO? ,GLOBAL-SAMURAI>
+			      <TELL
+"\"Warriors -- soldiers -- members of the warrior caste.\"" CR>)
+			     (ELSE
+			      <TELL
+G"\"I'm not here to answer your questions, pirate!\"" CR>)>)
+		      (,OMI-QUESTION
+		       <SET OW ,WINNER>
+		       <SETG WINNER ,OMI>
+		       <PERFORM ,PRSA ,PRSO ,PRSI>
+		       <SETG WINNER .OW>
+		       <RTRUE>)
+		      (,YABU-QUESTION
+		       <COND (<VERB? TRANSLATE>
+			      <TELL
+"You harden your voice.  \""I"Que va!""  First translate what I
+said.  Now!\"  The priest reddens, and you see that the exchange has not gone
+unnoticed by the "I"daimyo""." CR>)
+			     (ELSE
+			      <SET OW ,WINNER>
+			      <SETG WINNER ,YABU>
+			      <PERFORM ,PRSA ,PRSO ,PRSI>
+			      <SETG WINNER .OW>
+			      <RTRUE>)>)
+		      (<VERB? TRANSLATE>
+		       <TELL
+"\"It's not your place to command me, heretic!\"" CR>)
+		      (<P? BE ME>
+		       <COND (<AND <PRSI? ,HERETIC ,PIRATE>
+				   <P-NEGATIVE?>>
+			      <TELL
+"\"Liar!\" storms the priest." CR>)
+			     (<PRSI? ,BLACKTHORNE>
+			      <TELL
+"He doesn't seem to have heard of you before." CR>)
+			     (ELSE
+			      <TELL
+"\"I'll know who and what you are soon enough!\"" CR>)>)
+		      (ELSE
+		       <TELL
+CTHE ,SEBASTIO " looks at you with contempt." CR>)>)
+	       (<VERB? EXAMINE>
+		<TELL
+CTHE ,SEBASTIO " is a short, thick man with dark hair and a long
+beard.  His robe is travel-stained and his boots are besmirched with
+mud.  He is
+obviously a Portuguese or Spanish priest, and though his flowing robe is
+orange, there is no mistaking the ">
+		<COND (<IN? ,SEBASTIO-CRUCIFIX ,PRSO>
+		       <TELL "crucifix and ">)>
+		<TELL "rosary at his
+belt, or the cold hostility on his face." CR>)
+	       (<AND <P? TELL-ABOUT SEBASTIO STRAIT-OF-MAGELLAN>
+		     <EQUAL? ,YABU-QUESTION 4>>
+		<PERFORM ,PRSA ,YABU ,PRSI>
+		<RTRUE>)
+	       (<VERB? ANSWER REPLY>
+		<TELL
+"\"That's no response, pirate!\" rages " THE ,SEBASTIO "." CR>)
+	       (<VERB? BOW>
+		<TELL
+"\"You learn fast, pirate!\" he says, surprised, but he doesn't return
+your bow." CR>)
+	       (<P? THROW SEBASTIO-CRUCIFIX SEBASTIO>
+		<RFALSE>)
+	       (<HOSTILE-VERB?>
+		<TELL "You ">
+		<COND (<B-NOT-STANDING?>
+		       <B-STAND>
+		       <TELL "storm to your feet, ">)>
+		<COND (<VERB? THROW>
+		       <MOVE ,PRSO ,HERE>
+		       <TELL "throw " THE ,PRSO " at">)
+		      (<VERB? SPIT>
+		       <TELL "spit at">)
+		      (<VERB? KICK>
+		       <TELL "kick">)
+		      (<VERB? PISS>
+		       <TELL "piss on">)
+		      (ELSE
+		       <TELL "strike">)>
+		<TELL " " THE ,SEBASTIO ", and he curses at you
+but turns the other cheek." CR>
+		<COND (<AND <IN? ,OMI ,HERE> <IN? ,YABU ,HERE>>
+		       <QUEUE I-BOW? 2>
+		       <TELL CR
+"Omi and Yabu look at each other in surprise." CR>)>
+		<RTRUE>)>>
+
+<OBJECT OMI
+	;(SDESC "Omi")
+	(SDESC "young man")
+	(SYNONYM MAN OMI OMI-SAN SAMURAI)
+	(ADJECTIVE YOUNG KASIGI)
+	(PICTURE P-OMI)
+	(FLAGS PERSON JAPANESEBIT SCOREBIT THE ;NOTHEBIT)
+	(GENERIC GENERIC-SAMURAI-F)
+	(ACTION OMI-F)>
+
+<ROUTINE OMI-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<OR <VERB? PISS CURSE FUCK>
+			   <AND <VERB? NO IYE>
+				<QUEUED? I-TAKE-CROOCQ>>>
+		       <SETG WINNER ,PLAYER>
+		       <PERFORM ,V?CURSE ,OMI>
+		       <RTRUE>)
+		      (<OR <QUESTION-VERB?>
+			   <VERB? ASK-ABOUT TELL-ME-ABOUT>>
+		       <TELL
+CTHE ,SEBASTIO " snaps, \"You're to answer questions, not ask
+them.\"  He says something to the samurai, who scowls." CR>)
+		      (<AND ,OMI-QUESTION
+			    <I-DONT-KNOW?>>
+		       <TELL
+"\"Liar!\" screams " THE ,SEBASTIO ".  \"They use torture here.  They can
+find out anything!\"" CR>)
+		      (<AND <EQUAL? ,OMI-QUESTION 1>
+			    <P? BE (ME BLACKTHORNE)> ,PRSI>
+		       <COND (<AND <OR <ENGLISH?> <DUTCH?>>
+				   <NOT <P-NEGATIVE?>>>
+			      <SETG QCONTEXT <>>
+			      <SETG OMI-QUESTION 0>
+			      <TELL CTHE ,SEBASTIO>
+			      <COND (<ENGLISH?>
+				     <TELL
+" steps back as though struck.  \"English!  England">)
+				    (ELSE
+				     <TELL
+" nods suspiciously.  \"Dutch!  Holland">)>
+			      <TELL
+"!\"He begins to explain to Omi but the samurai cuts him short." CR>)
+			     (ELSE
+			      <SETUP-ANSWER "i am">
+			      <SEBASTIO-SCREAMS>
+			      <COND (<PRSI? ,BLACKTHORNE>
+				     <TELL
+"I want to know your nationality, not your name, heretic!\"" CR>)
+				    (ELSE
+				     <TELL
+"I know you aren't what you say you are!\"" CR>)>)>)
+		      (<AND <EQUAL? ,OMI-QUESTION 2>
+			    <OR <P? BE (BLACKTHORNE ME) INTPP>
+				<P? COME-FROM>>>
+		       <COND (<OR <P? COME-FROM HOLLAND>
+				  <PP? ,W?FROM ,HOLLAND>>
+			      <SETG QCONTEXT <>>
+			      <SETG OMI-QUESTION 0>
+			      <TELL
+CTHE ,SEBASTIO "'s anger is obvious.  \"A Dutch pirate ship!\" he
+gasps.  He says something haltingly to Omi-san." CR>)
+			     (ELSE
+			      <SEBASTIO-SCREAMS>
+			      <TELL "That's a
+Dutch pirate ship!  Admit you're a heretic, murdering Dutchman!\"" CR>)>)
+		      (<AND <EQUAL? ,OMI-QUESTION 3>
+			    <VERB? YES NO IYE BE HAI>>
+		       <COND (<OR <VERB? YES HAI>
+				  <AND <P? BE (BLACKTHORNE ME) LEADER>
+				       <NOT <P-NEGATIVE?>>>>
+			      <SETG QCONTEXT <>>
+			      <SETG OMI-QUESTION 0>
+			      <SETG ORPHAN-ANSWER <>>
+			      <TELL CTHE ,SEBASTIO>
+			      <COND (<VERB? HAI>
+				     <TELL
+" looks surprised at your knowledge of Japanese, and
+speaks rapidly and excitedly to Omi." CR>)
+				    (ELSE
+				     <TELL
+" translates for Omi, still digesting what you have
+told him." CR>)>
+			      <SCORE-OBJECT ,OMI>)
+			     (ELSE
+			      <SETUP-ANSWER "i am">
+			      <TELL
+CTHE ,SEBASTIO " screams, \"Coward, I know you're the leader!  The
+villagers have already told me so!\"" CR>)>)
+		      (,OMI-QUESTION
+		       <COND (<VERB? SAY REPLY>
+			      <PERFORM ,V?BE ,ME ,PRSO>
+			      <RTRUE>)
+			     (ELSE
+			      <TELL
+CTHE ,OMI " doesn't respond, but the priest says, \"You'd better learn to be
+polite -- and find some manners quickly.  Here they don't tolerate lack
+of manners.\"  His voice edges.  \"Hurry up and answer!\"" CR>)>)
+		      (<AND <VERB? STOP>
+			    <NOT ,ANSWER-HAI?>
+			    <HERE? ,VILLAGE-SQUARE>
+			    <QUEUED? I-TAKE-CROOCQ>>
+		       <SETG QCONTEXT ,OMI>
+		       <TELL
+"\"Omi-san says, you agree to behave?  You will obey all orders?\"" CR>)
+		      (<AND <VERB? HAI YES>
+			    <NOT ,ANSWER-HAI?>
+			    <HERE? ,VILLAGE-SQUARE>
+			    <QUEUED? I-TAKE-CROOCQ>>
+		       <COND (<VERB? YES>
+			      <TELL
+"\"You must speak to him in Japanese, heretic!  You must say 'hai.'\"  "
+D ,SEBASTIO " is sweating and nervous." CR>)
+			     (ELSE
+			      <SETG ANSWER-HAI? T>
+			      <SETG DELAY-CNT 0>
+			      <THIS-IS-IT ,ORDERS>
+			      <TELL
+"\"Omi-san says, lie down.  Immediately.\"" CR>
+			      <SCORE-OBJECT ,VILLAGE-SQUARE>)>)
+		      (ELSE
+		       <TELL
+CTHE ,OMI " ignores you, for now." CR>)>)
+	       (<VERB? EXAMINE>
+		<TELL
+"The young man is a head shorter and much younger than you, his
+handsome face slightly pockmarked though.  He wears breeches and clogs
+and a light kimono with two scabbarded swords stuck into the belt.  One
+is daggerlike, the other, a two-handed killing sword, is long and
+slightly curved." CR>)
+	       (<VERB? WHO>
+		<TELL
+CTHE ,OMI " is an ambitious young man.  He serves his masters well, but
+himself better." CR>)
+	       (<VERB? THANK>
+		<COND (<IN? ,SEBASTIO ,HERE>
+		       <TELL
+CTHE ,SEBASTIO " translates.  Omi seems pleased by your politeness." CR>)
+		      (ELSE
+		       <TELL
+"Omi responds with a curt bow, and says \"Domo.\"" CR>)>)
+	       (<OR <VERB? PISS CURSE FUCK>
+		    <AND <OR <VERB? NO IYE> <HOSTILE-VERB?>>
+			 <QUEUED? I-TAKE-CROOCQ>>>
+		<COND (<SCENE? S-PIT>
+		       <COND (<NOT ,PISS-FLAG>
+			      <SETG PISS-FLAG T>
+			      <TELL
+"You lose your composure.  \"Tell him to go to hell.  Tell him I piss on
+him and his whole country.  Tell him exactly what I said!  Exactly, by
+God!\" you yell at the priest.  Omi listens, then the knuckles on his
+sword hand whiten.  You can see he is trying not to give way to his
+emotions." CR>)
+			     (ELSE
+			      <TELL
+"You continue to scream abuse at Omi." CR>)>)>)
+	       (<OR <HOSTILE-VERB?> <VERB? STOP>>
+		<REMOVES-YOUR-HEAD ,OMI>)>>
+
+<ROUTINE SEBASTIO-SCREAMS ()
+	 <TELL
+CTHE ,SEBASTIO " screams, \"Lying pig of a heretic!  ">>
+
+<ROUTINE REMOVES-YOUR-HEAD (WHO)
+	 <COND (<JIGS-UP? ,J-HEAD>
+		<TELL
+CTHE .WHO " responds to your feeble attack by removing your head." CR>
+		<JIGS-UP>)
+	       (ELSE <RTRUE>)>>
+
+<OBJECT MURA
+	(LOC GENERIC-OBJECTS)
+	(DESC "Mura")
+	(SYNONYM MURA HEADMAN MAN)
+	(FLAGS PERSON JAPANESEBIT NOABIT NOTHEBIT OPENBIT CONTBIT SEARCHBIT)
+	(GENERIC GENERIC-MAN-F)
+	(ACTION MURA-F)>
+
+<ROUTINE GENERIC-MAN-F (R F)
+	 <TELL "You'll have to be more specific." CR>
+	 ,ROOMS ;"means 'handled'">
+
+<ROUTINE MURA-F ("OPT" (RARG <>))
+	 <COND ;(<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<AND <VERB? TAKE>
+			    <IN? ,PRSO ,PLAYER>
+			    <NOT <FSET? ,PRSO ,WEARBIT>>>
+		       <SETG WINNER ,PLAYER>
+		       <PERFORM ,V?GIVE ,PRSO ,MURA>)
+		      (<AND <VERB? NO IYE>
+			    <EQUAL? ,QCONTEXT ,MURA>
+			    <SCENE? ,S-RODRIGUES>>
+		       <TELL
+"Mura replies in halting Portuguese, \"So sorry, Anjin-san, you must
+go.\"" CR>)
+		      (<P? (TELL-ME-ABOUT FIND) ONNA>
+		       <NEW-SDESC ,ONNA "Haku">
+		       <REPLACE-SYNONYM ,ONNA ,W?ONNA ,W?HAKU>
+		       <TELL
+"\"Where's Onna?\" you ask. \"I want Onna!\"  Mura replies in heavily-accented
+Portuguese, \""I"Onna"" mean 'woman.'  Her name Haku.\"" CR>)
+		      (ELSE
+		       <WAKARIMASEN>)>)
+	       (<RARG? <>>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"Mura is a short, wiry, middle-aged man.  You realize there's more
+to him than the simple fisherman he appears to be." CR>)
+		      (<AND <P? GIVE * MURA>
+			    <HERE? ,BATH-HOUSE>
+			    <NOT <FSET? ,PRSO ,WEARBIT>>>
+		       <MOVE ,PRSO ,MURA>
+		       <TELL
+"Mura takes " THE ,PRSO "." CR>)
+		      (<VERB? ATTACK HIT>
+		       <TELL
+"Mura is unarmed, but the moment you get within reach, he chops your
+elbow with the side of his hand and your arm hangs down, momentarily
+paralyzed.  \"Please excuse me, Captain-san,\" he says in very
+bad Portuguese." CR>)
+		      (<VERB? WHO>
+		       <TELL
+"Mura is the headman of the village of Anjiro." CR>)>)>>
+
+<OBJECT MARIKO
+	;(DESC "Mariko")
+	(SDESC "Mariko")
+	(PICTURE P-MARIKO)
+	(SYNONYM MARIKO TODA WOMAN)
+	(ADJECTIVE LADY TODA)
+	(FLAGS PERSON JAPANESEBIT FEMALE NOABIT NOTHEBIT
+	 OPENBIT CONTBIT SEARCHBIT SCOREBIT)
+	(DESCFCN MARIKO-DESC)
+	(ACTION MARIKO-F)>
+
+<ROUTINE MARIKO-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?>
+		<COND (<AND <SCENE? ,S-SEPPUKU>
+			    <HERE? ,TEA-HOUSE ,FORECOURT>>
+		       <RTRUE>)
+		      (<AND <SCENE? ,S-NINJA>
+			    <OR <FSET? ,MARIKO ,DEAD>
+				<FSET? ,MARIKO ,RMUNGBIT>>>
+		       <RTRUE>)>)
+	       (<RARG? OBJDESC>
+		<TELL "Mariko ">
+		<COND (<HERE? ,TEA-HOUSE>
+		       <TELL
+"kneels here, facing the doorway.">)
+		      (<HERE? ,FORECOURT>
+		       <COND (<FSET? ,MARIKO ,SITTING>
+			      <TELL
+"kneels serenely in the center of the crimson coverlet.">)
+			     (ELSE
+			      <TELL
+"is standing in the center of the main gate.">)>)
+		      (<SCENE? ,S-NINJA>
+		       <TELL "lies ">
+		       <COND (<FSET? ,MARIKO ,DEAD>
+			      <TELL "dead">)
+			     (ELSE
+			      <TELL "dying">)>
+		       <TELL " on the floor.">)>)>>
+
+<ROUTINE MARIKO-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<OR <FSET? ,MARIKO ,DEAD>
+			   <FSET? ,MARIKO ,RMUNGBIT>>
+		       <TELL
+"Mariko can no longer respond." CR>)
+		      (<P? (WHO TELL-ME-ABOUT) (YOU MARIKO)>
+		       <TELL
+"\"I am Lady Toda Mariko-noh-Buntaro.  The priests know me as Lady Maria,
+as I am Christian.\"" CR>)
+		      (<P? (WHAT TELL-ME-ABOUT) PROPHECY>
+		       <COND (<HERE? ,MAPLE-GLADE>
+			      <TELL
+"Mariko asks permission of Toranaga, who nods.  ">)>
+		       <TELL
+"\"Six years ago a Chinese embassy came to the Taiko to try to settle the
+Japanese-Chinese-Korean war.  A famous astrologer was among them.  He forecast
+many things which have since come true.  The Taiko asked him to predict the
+deaths of certain of his counselors.  The astrologer said that Toranaga would
+die by the sword when he was middle-aged.  Ishido, the famous conqueror of
+Korea, would die undiseased, an old man, his feet firm in the earth, the
+most famous man of his day.  The Taiko himself would die in his bed, respected,
+revered, of old age, leaving a healthy son to follow him.  At this time Yaemon
+had not yet been born, so that part of the prophecy has already come to
+pass.\"" CR>
+		       <SCORE-OBJECT ,PROPHECY>)
+		      (<SCENE? ,S-MARIKO>
+		       <COND (<OR <P? KONNICHI-WA ROOMS>
+				  <P? NIHON-GO-GA HANASE-MASEN>>
+			      <COND (<FSET? ,MAPLE-GLADE ,SCOREBIT>
+				     <SETG WINNER ,PLAYER>
+				     <PERFORM ,V?KONNICHI-WA ,MARIKO>
+				     <RTRUE>)>)
+			     (<AND <EQUAL? ,QCONTEXT ,MARIKO>
+				   <VERB? LEARN TRAIN TEACH>
+				   <PAST-TENSE?>>
+			      <COND (<OR <AND <EQUAL? ,PRSS ,DOMINGO>
+					      <PRSO? ME>>
+					 <PRSO? PRISON DOMINGO>>
+				     <HOW-I-LEARNED>)
+				    (ELSE
+				     <TELL
+"She doesn't seem to believe you." CR>)>)
+			     (<P? TEACH ME JAPANESE>
+			      <TELL
+"\"If my master wishes,\" she answers, turning to Toranaga.  They converse
+for a while.  \"My Master says that only a few bar -- foreigners have been
+able to learn our language, and these are all priests.  But he would like to
+be able to talk to you directly, without the need for an interpreter.  He will
+consider this request.\"" CR>)
+			     (<P? (WHO TELL-ME-ABOUT) YAEMON>
+			      <NEW-SDESC ,YAEMON "Yaemon">
+			      <TELL
+"\"This is the Heir, the only son of the Taiko.  His name is Yaemon.\"" CR>)
+			     (<P? (WHO TELL-ME-ABOUT) (YOU MARIKO)>
+			      <TELL
+"\"My name is Toda Mariko noh-Buntaro.  I am a 'senhora,' not a 'senhorita,'
+if you please.\"" CR>)
+			     (<OR <QUESTION-VERB?>
+				  <VERB? ASK-ABOUT TELL-ME-ABOUT>>
+			      <TELL
+"\"Lord Toranaga has instructed me to say that ">
+			      <COND (<EQUAL? ,LG-CREWMEN ,PRSO ,PRSI>
+				     <TELL
+"your crewmen are being treated well.  They will given a place to live, and
+to learn to be civilized.\"" CR>)
+				    (ELSE
+				     <TELL
+"you will please confine yourself
+to answering questions only, for the moment.\"  Then she says, \"I'm sure, if
+you are patient, Pilot-Captain B'ackthon, that you'll be given an opportunity
+to ask anything you wish later.\"" CR>)>)
+			     (<JAPANESE-VERB?>
+			      <TELL
+"\"If you will excuse me, senhor, my Master orders me to say your accent is a
+little wrong.\"  She repeats the word several times slowly, showing you how to
+say it." CR>)
+			     (ELSE
+			      <I-DONT-UNDERSTAND>)>)
+		      (<VERB? THOU>
+		       <I-LOVE-YOU>)
+		      (<VERB? TELL-ME-ABOUT>
+		       <COND (<PRSO? ,SUICIDE>
+			      <TELL
+"\"If the shame is too great, or if our liege Lord commands, we
+take our lives.  I have been trained to do so, as have all samurai.\"" CR>
+			      <RTRUE>)
+			     (<PRSO? ,KIYAMA>
+			      <TELL
+"\"Lord Kiyama is a member of the Council of Regents, and the most powerful
+of the Christian daimyos.\"" CR>)
+			     (<SCENE? ,S-NINJA>
+			      <COND (<PRSO? ,YABU>
+				     <TELL
+"\"He is very angry with me for confronting Lord Ishido, and even
+angrier that I did not go through with my seppuku, but that was my
+"I"karma"", Anjin-san.\"" CR>
+				     <RTRUE>)
+				    (<PRSO? ,ACHIKO>
+				     <TELL
+"\"Her grandfather-in-law, Lord Kiyama, opposes Lord Toranaga.  He has
+disowned her for her presumption in joining us.\"" CR>
+				     <RTRUE>)>)>
+		       <TELL
+"\"I cannot tell you
\ No newline at end of file
diff --git a/defs.zil b/defs.zil
new file mode 100644
index 0000000..9142344
--- /dev/null
+++ b/defs.zil
@@ -0,0 +1,339 @@
+"DEFS for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc. All Rights Reserved."
+
+;"see if we can save some space"
+
+<CHRSET 0 "abcdefghiklmnoprstuwyT.,\"">
+<CHRSET 1 "jqvxzABCEGHIJLMNOPRSWY?!'-">
+<CHRSET 2 "DFKQUVXZ123[]:;=*()#}>/	">
+
+<INCLUDE "SYMBOLS">
+
+<COMPILATION-FLAG P-DEBUGGING-PARSER T>
+
+<TELL-TOKENS (CRLF CR)		<CRLF>
+	     (NUM N) *		<PRINTN .X>
+	     (CHAR CHR C) *	<PRINTC .X>
+	     G *:STRING		<PRINT .X>
+	     D ,PRSO		<DPRINT-PRSO>
+	     D ,PRSI		<DPRINT-PRSI>	
+	     D *		<DPRINT .X>
+	     CD ,PRSO		<CDPRINT-PRSO>
+	     CD ,PRSI		<CDPRINT-PRSI>
+	     CD *		<CDPRINT .X>
+	     THE ,PRSO		<THE-PRINT-PRSO>
+	     THE ,PRSI		<THE-PRINT-PRSI>
+	     THE *		<THE-PRINT .X>
+	     CTHE ,PRSO		<CTHE-PRINT-PRSO>
+	     CTHE ,PRSI		<CTHE-PRINT-PRSI>
+	     CTHE *		<CTHE-PRINT .X>
+	     (A AN) ,PRSO	<PRINTA-PRSO>
+	     (A AN) ,PRSI	<PRINTA-PRSI>
+	     (A AN) *		<PRINTA .X>
+	     (CA CAN) ,PRSO	<CPRINTA-PRSO>
+	     (CA CAN) ,PRSI	<CPRINTA-PRSI>
+	     (CA CAN) *		<CPRINTA .X>
+	     I *:STRING		<PRINTUNDER .X>
+	     HIM/HER *		<PRINT-HIM/HER .X>
+	     CHE/SHE *		<CPRINT-HE/SHE .X>
+	     HE/SHE *		<PRINT-HE/SHE .X>
+	     HIS/HER *		<PRINT-HIS/HER .X>
+	     IS/ARE *		<PRINT-IS/ARE .X>
+	     S *		<PRINT-PLURAL .X>>
+
+<REPLACE-DEFINITION	BUZZER-WORD?
+	<ROUTINE BUZZER-WORD? (WD PTR) <>>>
+
+<REPLACE-DEFINITION	DIR-VERB-PRSI?
+	<ROUTINE DIR-VERB-PRSI? (NP) <>>>
+
+<DELAY-DEFINITION	GAME-VERB?>	;"to replace parser's versions"
+
+<BLOCK (<ROOT>)>
+TELL-CTHE
+TELL-THE
+THINGS
+<ENDBLOCK>
+
+<REPLACE-DEFINITION	TELL-THE
+	<DEFMAC TELL-THE ("ARGS" X) <FORM THE-PRINT !.X>>>
+
+<REPLACE-DEFINITION	TELL-CTHE
+	<DEFMAC TELL-CTHE ("ARGS" X) <FORM CTHE-PRINT !.X>>>
+
+<REPLACE-DEFINITION	OWNERS
+			<CONSTANT OWNERS
+				  <TABLE (PURE LENGTH)
+					 BLACKTHORNE
+					 CHOPSTICKS
+					 CITY
+					 CREWMEN
+					 CROWD
+					 GALLEY
+					 GOD
+					 GRUEL
+					 GYOKO
+					 ISHIDO
+					 KIRITSUBO
+					 LG-ERASMUS
+					 LIZARD
+					 MAPLE-GLADE
+					 MARIKO
+					 MATES
+					 MURA
+					 OMI
+					 PARCHMENT
+					 REEF
+					 SEARCH-PARTY
+					 SEBASTIO
+					 SIGN-OF-CROSS
+					 SPILLBERGEN
+					 STRAIT-OF-MAGELLAN
+					 TORANAGA
+					 VINCK
+					 YABU
+					 YOSHINAKA>>>
+
+<DELAY-DEFINITION	READ-INPUT>
+<REPLACE-DEFINITION	PERSONBIT <CONSTANT PERSONBIT PERSON>>
+<REPLACE-DEFINITION	NARTICLEBIT <CONSTANT NARTICLEBIT NOTHEBIT>>
+<REPLACE-DEFINITION	REFRESH
+			<ROUTINE V-$REFRESH ()
+				 <SETG SHERE <>>
+				 <COND (<NOT <EQUAL? ,P-CAN-UNDO 2>>
+					<REPAINT-DISPLAY>)
+				       (<EQUAL? ,P-CAN-UNDO 2>
+					<COLOR ,FG-COLOR ,BG-COLOR>
+					<RESET-MARGIN>
+					<CLEAR 0>
+					<UPDATE-STATUS-LINE>
+					<COND (<EQUAL? ,HERE ,MAZE>
+					       <DISPLAY-MAZE>)>
+					<COND (<QUEUED? I-SETUP-ANSWER>
+					       <I-SETUP-ANSWER>
+					       ;"interrupts won't run")>
+					<TELL "[UNDO done.]" CR>)>>>
+<REPLACE-DEFINITION	ROOMSBIT
+			<CONSTANT ROOMSBIT RLANDBIT>>
+<REPLACE-DEFINITION	SETUP-ORPHAN-NP
+			<CONSTANT SETUP-ORPHAN-NP 0>>
+<DELAY-DEFINITION	STATUS-LINE>
+<DELAY-DEFINITION	YES?>
+
+<COMPILATION-FLAG P-PS-COMMA T>
+<TERMINALS VERB NOUN ADJ
+	   ;ADV QUANT MISCWORD
+	   DIR TOBE QWORD CANDO COMMA
+	   PARTICLE PREP ;"keep these two in order! -- SWG"
+	   ASKWORD
+	   COMMA APOSTR OFWORD ARTICLE QUOTE>
+
+
+<PROPDEF DIRECTIONS <>		;"direction defs for 'rooms-first'"
+	 (DIR TO R:ROOM =
+	  (UEXIT 1)	;444	#SEMI "UNCONDITIONAL EXIT"
+	  (REXIT <ROOM .R>)	#SEMI "TO ROOM")
+	 (DIR S:STRING =
+	  (NEXIT 2)	;99	#SEMI "IMPOSSIBLE EXIT"
+	  (NEXITSTR <STRING .S>) #SEMI "FAILURE MESSAGE")
+	 (DIR SORRY S:STRING =
+	  (NEXIT 2)		#SEMI "IMPOSSIBLE EXIT"
+	  (NEXITSTR <STRING .S>) #SEMI "FAILURE MESSAGE")
+	 (DIR PER F:FCN =
+	  (FEXIT 3)	;53	#SEMI "CONDITIONAL EXIT"
+	  (FEXITFCN <WORD .F>)	#SEMI "PER FUNCTION"
+	  <BYTE 0>)
+	 (DIR TO R:ROOM IF F:GLOBAL "OPT" ELSE S:STRING =
+	  (CEXIT 4)	;7	#SEMI "CONDITIONAL EXIT"
+	  (REXIT <ROOM .R>)	#SEMI "TO ROOM"
+	  (CEXITFLAG <GLOBAL .F>) #SEMI "IF FLAG IS TRUE"
+	  (CEXITSTR <STRING .S>) #SEMI "FAILURE MESSAGE")
+	 (DIR TO R:ROOM IF O:OBJECT IS OPEN "OPT" ELSE S:STRING =
+	  (DEXIT 5)	;15	#SEMI "CONDITIONAL EXIT"
+	  (DEXITOBJ <OBJECT .O>) #SEMI "IF DOOR IS OPEN"
+	  (DEXITSTR <STRING .S>) #SEMI "FAILURE MESSAGE"
+	  (DEXITRM <ROOM .R>)	#SEMI "TO ROOM")>
+
+<DIRECTIONS NORTH NE EAST SE SOUTH SW WEST NW
+	    UP DOWN IN OUT FORE AFT PORT STARBOARD>
+
+<SETG L-SEARCH-PATH (["P" ""] !,L-SEARCH-PATH)>
+
+<REPLACE-DEFINITION WINNER-SAYS-WHICH?
+	 <ROUTINE WINNER-SAYS-WHICH? (NP)
+		  <RFATAL>>>
+
+<REPLACE-DEFINITION INVALID-OBJECT?
+<ROUTINE INVALID-OBJECT? (OBJ)
+	 <COND (<NOT <LOC .OBJ>> <RTRUE>)
+	       (<AND <NOT <IN? .OBJ ,GLOBAL-OBJECTS>>
+		     <NOT <IN? .OBJ ,GENERIC-OBJECTS>>
+		     <NOT <IN-SCENE? .OBJ>>>
+		<RTRUE>)
+	       (ELSE <RFALSE>)>>>
+
+<REPLACE-DEFINITION VERB-ALL-TEST
+<DEFINE VERB-ALL-TEST (O I "AUX" L)	;"O=PRSO I=PRSI"
+ <SET L <LOC .O>>
+ <COND (<EQUAL? ,PRSA ,V?DROP ,V?GIVE>
+	<COND (<AND <EQUAL? .L ,WINNER>
+		    <NOT <FSET? .L ,WEARBIT>>>
+	       <RTRUE>)
+	      (T <RFALSE>)>)
+       (<EQUAL? ,PRSA ,V?PUT>
+	<COND (<EQUAL? .O .I>
+	       <RFALSE>)
+	      (<NOT <IN? .O .I>>
+	       <RTRUE>)
+	      (T <RFALSE>)>)
+       (<EQUAL? ,PRSA ,V?TAKE>
+	<COND (<FSET? .O ,DONT-ALL> <RFALSE>)
+	      (<FSET? .O ,WEARBIT> <RFALSE>)
+	      (<AND <NOT <FSET? .O ,TAKEBIT>>
+		    <NOT <FSET? .O ,TRYTAKEBIT>>>
+	       <RFALSE>)>
+	<COND (<NOT <ZERO? .I>>
+	       <COND (<NOT <EQUAL? .L .I>>
+		      <RFALSE>)>)
+	      (<EQUAL? .L ;,WINNER ,HERE>
+	       <RTRUE>)>
+	<COND (<OR <FSET? .L ,PERSONBIT>
+		   <FSET? .L ,SURFACEBIT>>
+	       <RTRUE>)
+	      (<AND <FSET? .L ,CONTBIT>
+		    <FSET? .L ,OPENBIT>>
+	       <RTRUE>)
+	      (T <RFALSE>)>)
+       (<AND <EQUAL? ,PRSA ,V?WEAR>
+	     <NOT <FSET? .O ,WEARABLE>>>
+	<RFALSE>)
+       (<NOT <ZERO? .I>>
+	<COND (<NOT <EQUAL? .O .I>>
+	       <RTRUE>)
+	      (T <RFALSE>)>)
+       (T <RTRUE>)>>>
+
+<REPLACE-DEFINITION SPECIAL-CONTRACTION?
+ <VOC "FO">
+ <VOC "C">
+ <VOC "FOC">
+ <VOC "SLE">
+ <ROUTINE SPECIAL-CONTRACTION? (PTR)
+	<COND (<AND <EQUAL? <ZGET .PTR 0> ,W?FO>
+		    <EQUAL? <ZGET .PTR ,P-LEXELEN> ,W?APOSTROPHE>
+		    <EQUAL? <ZGET .PTR <* 2 ,P-LEXELEN>> ,W?C>>
+	       ,W?FOC)
+	      (<AND <EQUAL? <ZGET .PTR 0> ,W?FOC>
+		    <EQUAL? <ZGET .PTR ,P-LEXELEN> ,W?APOSTROPHE>
+		    <EQUAL? <ZGET .PTR <* 2 ,P-LEXELEN>> ,W?SLE>>
+	       ,W?FOCSLE)>>>
+
+<REPLACE-DEFINITION SPEAKING-VERB?
+ <DEFINE SPEAKING-VERB? ("OPT" (A ,PRSA) ;(PER 0))
+ <COND (<EQUAL? .A ,V?ANSWER ,V?ASK-ABOUT ,V?ASK-FOR ,V?CURSE ,V?HELLO
+		,V?NO ,V?REPLY ,V?SAY ,V?SPEAK ,V?TELL ,V?TELL-ABOUT
+		,V?THANK ,V?THOU ,V?YELL ,V?YELL-AT ,V?YES>
+	<COND (T ;<EQUAL? .PER 0 ,PRSO>
+	       <RTRUE>)>)>>>
+
+<REPLACE-DEFINITION CAPITAL-NOUN?
+	<ROUTINE CAPITAL-NOUN? (WD)
+		 <EQUAL? .WD 
+,W?ACHIKO
+,W?AKABO
+,W?ALVITO
+,W?BACCUS
+,W?BLACKTHORNE
+,W?BROWN
+,W?BROWNS
+,W?BUNTARO
+,W?CAPTAIN
+,W?CAPTAIN-GENERAL
+,W?CHIMMOKO
+,W?CROOCQ
+,W?DANZENJI
+,W?DOMINGO
+,W?ENGLAND
+,W?ERASMUS
+,W?ETSU
+,W?GINSEL
+,W?GONZALEZ
+,W?GORODA
+,W?GRAY
+,W?GRAYS
+,W?GYOKO
+,W?HENDRIK
+,W?HIRO-MATSU
+,W?HOLLAND
+,W?I
+,W?ISHIDO
+,W?JAN
+,W?JOHANN
+,W?JOHN
+,W?KASIGI
+,W?KAZUNARI
+,W?KIKU
+,W?KIRI
+,W?KIRITSUBO
+,W?KIYAMA
+,W?KOJIMA
+,W?KWAMPAKU
+,W?MAETSUKKER
+,W?MARIKO
+,W?MARTIN
+,W?MAXIMILIAN
+,W?MURA
+,W?NAKAMURA
+,W?NEKK
+,W?OCHIBA
+,W?OMI
+,W?ONNA
+,W?PAULUS
+,W?PIETERZOON
+,W?POPE,W?RODRIGUES
+,W?ROPER
+,W?SAIGAWA
+,W?SALAMON
+,W?SAZUKO
+,W?SEBASTIO
+,W?SHOGUN
+,W?SONK
+,W?SPECZ
+,W?SPILLBERGEN
+,W?SUMIYORI
+,W?TAIKO
+,W?TODA
+,W?TORANAGA
+,W?VASCO
+,W?VINCK
+,W?YABU
+,W?YAEMON
+,W?YAMAZAKI
+,W?YOSHI
+,W?YOSHINAKA
+,W?ZATAKI
+ >>>
+
+<REPLACE-DEFINITION SOFT-KEY-DEFINITIONS
+	<SOFT-KEYS
+	 ,UP-ARROW "n"
+	 ,DOWN-ARROW "s"
+	 ,LEFT-ARROW "w"
+	 ,RIGHT-ARROW "e"
+	 ;"vt100 keypad keys"
+	 ,F1 "sw" 
+	 ,F2 "s"
+	 ,F3 "se"
+	 ,F4 "w"
+	 ,F5 ""
+	 ,F6 "e"
+	 ,F7 "nw"
+	 ,F8 "n"
+	 ,F9 "ne"
+	 ,F10 ""
+	 -1 0
+	 -1 <TABLE "Save Definition File" SOFT-SAVE-DEFS>
+	 -1 <TABLE "Restore Definition File" SOFT-RESTORE-DEFS>
+	 -1 <TABLE "Reset Defaults" SOFT-RESET-DEFAULTS>
+	 -1 <TABLE "Exit" SOFT-EXIT>>>
diff --git a/desc.zil b/desc.zil
new file mode 100644
index 0000000..bf881fe
--- /dev/null
+++ b/desc.zil
@@ -0,0 +1,308 @@
+"DESC for
+			       Your Game
+	(c) Copyright 1986 Infocom, Inc. All Rights Reserved."
+
+<BEGIN-SEGMENT 0>
+
+"The fabled new describers, as updated and modified to conform to the
+latest bug fixes.  See ZD:DESC.DOC for details.  See Z:DESC.ZIL for
+the source."
+
+<GLOBAL DESCRIBED-ROOM? <>>
+
+<ROUTINE DESCRIBE-ROOM ("OPTIONAL" (LOOK? <>) "AUX" V? STR AV)
+	 <COND (<NOT ,LIT>
+		<TELL "It is pitch black." CR>
+		<RFALSE>)>
+	 <COND (<IN? ,HERE ,ROOMS>
+		<HLIGHT ,H-BOLD>
+		<TELL 'HERE>
+		<HLIGHT ,H-NORMAL>)>
+	 <SET AV <LOC ,WINNER>>
+	 <COND (<FSET? .AV ,VEHBIT>
+		<COND (<FSET? .AV ,SURFACEBIT>
+		       <TELL ", on ">)
+		      (ELSE
+		       <TELL ", in ">)>
+		<TELL THE .AV>)>
+	 <CRLF>
+	 <SET V? <OR .LOOK? <EQUAL? ,VERBOSITY 2>>>
+	 <COND (<NOT <FSET? ,HERE ,TOUCHBIT>>
+		<FSET ,HERE ,TOUCHBIT>
+		<COND (,VERBOSITY <SET V? T>)>)>
+	 <SETG DESCRIBED-ROOM? .V?>
+	 <COND (.V?
+		<COND (<AND <NOT <EQUAL? ,HERE .AV>>
+			    <FSET? .AV ,VEHBIT>
+			    <APPLY <GETP .AV ,P?ACTION> ,M-LOOK>>
+		       <RTRUE>)
+		      (<APPLY <GETP ,HERE ,P?ACTION> ,M-LOOK>
+		       <RTRUE>)
+		      (<SET STR <GETP ,HERE ,P?LDESC>>
+		       <TELL .STR CR>)>)>
+	 T>
+
+<ROUTINE DESCRIBE-OBJECTS ("AUX" O STR (AV <LOC ,WINNER>) TMP)
+	 <SET O <FIRST? ,HERE>>
+	 <COND (<NOT .O> <RFALSE>)>
+	 <REPEAT () ;"FDESCS and MISC."
+		 <COND (<NOT .O> <RETURN>)
+		       (<AND <DESCRIBABLE? .O>
+			     <NOT <FSET? .O ,TOUCHBIT>>
+			     <SET STR <GETP .O ,P?FDESC>>>
+			<THIS-IS-IT .O>
+			<CRLF>
+			<TELL .STR>
+			<COND (<FSET? .O ,CONTBIT>
+			       <DESCRIBE-CONTENTS .O
+						  T
+						  <+ ,D-ALL?
+						     ,D-PARA?>>)>
+			<CRLF>)>
+		 <SET O <NEXT? .O>>>
+	 <SET O <FIRST? ,HERE>>
+	 <REPEAT () ;"DESCFCNS and LDESCS"
+		 <COND (<NOT .O> <RETURN>)
+		       (<OR <NOT <DESCRIBABLE? .O>>
+			    <AND <GETP .O ,P?FDESC>
+				 <NOT <FSET? .O ,TOUCHBIT>>>>
+			T)
+		       (<AND <SET STR <GETP .O ,P?DESCFCN>>
+			     <SET TMP <APPLY .STR ,M-OBJDESC? .O>>>
+			<COND (<NOT <EQUAL? .TMP ,M-FATAL>>
+			       <THIS-IS-IT .O>
+			       <CRLF>
+			       <COND (<SET STR <APPLY .STR ,M-OBJDESC .O>>
+				      <COND (<AND <FSET? .O ,CONTBIT>
+						  <N==? .STR ,M-FATAL>>
+					     <DESCRIBE-CONTENTS
+					      .O
+					      T
+					      <+ ,D-ALL?
+						 ,D-PARA?>>)>)>
+			       <CRLF>)>)
+		       (<SET STR <GETP .O ,P?LDESC>>
+			<THIS-IS-IT .O>
+			<CRLF>
+			<TELL .STR>
+			<COND (<FSET? .O ,CONTBIT>
+			       <DESCRIBE-CONTENTS .O
+						  T
+						  <+ ,D-ALL?
+						     ,D-PARA?>>)>
+			<CRLF>)>
+		 <SET O <NEXT? .O>>>
+	 <SETG D-BIT <- ,PERSON>>
+	 <DESCRIBE-CONTENTS ,HERE <> <>>
+	 <SETG D-BIT ,PERSON>
+	 <DESCRIBE-CONTENTS ,HERE <> <>>
+	 <SETG D-BIT <>>
+	 <COND (<AND .AV <NOT <EQUAL? ,HERE .AV>>>
+		<DESCRIBE-CONTENTS .AV <> <>>)>>
+
+<CONSTANT D-ALL? 1>	;"print everything?"
+<CONSTANT D-PARA? 2>	;"started paragraph yet?"
+
+"<DESCRIBE-CONTENTS object-whose-contents-to-describe
+		    level: -1 means only top level (default)
+			    <> means top-level (include crlf)
+			    T for all other levels
+			    or string to print
+		    all?: t if not being called from room-desc >
+
+Prints nothing and rfalses if there was nothing to list.
+
+'The wall crumbles to dust, revealing ' <DESCRIBE-CONTENTS .OBJ> "
+
+<ROUTINE DESCRIBE-CONTENTS (OBJ "OPTIONAL" (LEVEL -1) (ALL? ,D-ALL?)
+			    "AUX" (F <>) N (1ST? T) (IT? <>) (TWO? <>)
+			    (START? <>) (PARA? <>) DB)
+	 <COND (<EQUAL? .LEVEL 2>
+		<SET LEVEL T>
+		<SET PARA? T>
+		<SET START? T>)
+	       (<BTST .ALL? ,D-PARA?>
+		<SET PARA? T>)>
+	 <SET N <FIRST? .OBJ>>
+	 <COND (<OR .START?
+		    <IN? .OBJ ,ROOMS>
+		    <FSET? .OBJ ,PERSON>
+		    <AND .N
+			 <FSET? .OBJ ,CONTBIT>
+			 <OR <FSET? .OBJ ,OPENBIT>
+			     <FSET? .OBJ ,TRANSBIT>>
+			 <OR <EQUAL? .LEVEL -1>
+			     <FSET? .OBJ ,SEARCHBIT>>>>
+		<REPEAT ()
+		 <COND (<OR <NOT .N>
+			    <AND <DESCRIBABLE? .N>
+				 <OR <BTST .ALL? ,D-ALL?>
+				     <SIMPLE-DESC? .N>>>>
+			<COND (.F
+			       <COND (.1ST?
+				      <SET 1ST? <>>
+				      <COND (<EQUAL? .LEVEL <> T>
+					     <COND (<NOT .START?>
+						    <COND (<NOT .PARA?>
+							   <SET PARA? T>
+							   <CRLF>)
+							  (<EQUAL? .LEVEL T>
+							   <TELL " ">)>
+						    <DESCRIBE-START
+						      .OBJ
+						      <COND (<FSET? .F ,PLURAL>
+							     T)
+							    (ELSE .N)>>)>)
+					    (<NOT <EQUAL? .LEVEL -1>>
+					     <TELL .LEVEL>)>)
+				     (.N
+				      <TELL ", ">)
+				     (ELSE
+				      <TELL " and ">)>
+			       <TELL A .F>
+			       <DESCRIBE-SPECIAL .F>
+			       <COND (<AND <NOT .IT?> <NOT .TWO?>>
+				      <SET IT? .F>)
+				     (T
+				      <SET TWO? T>
+				      <SET IT? <>>)>)>
+			<SET F .N>)>
+		 <COND (.N <SET N <NEXT? .N>>)>
+		 <COND (<AND <NOT .F> <NOT .N>>
+			<COND (<AND .IT? <NOT .TWO?>>
+			       <THIS-IS-IT .IT?>)>
+			<COND (<AND .1ST? .START?>
+			       <TELL " nothing">
+			       <RFALSE>)
+			      (<AND <NOT .1ST?>
+				    <EQUAL? .LEVEL <> T>>
+			       <COND (<EQUAL? .OBJ ,HERE>
+				      <TELL " here">)>
+			       <TELL ".">)>
+			<RETURN>)>>
+		<COND (<EQUAL? .LEVEL <> T>
+		       <SET F <FIRST? .OBJ>>
+		       <REPEAT ()
+			       <COND (<NOT .F> <RETURN>)
+				     (<AND <OR <FSET? .F ,CONTBIT>
+					       <EQUAL? .F ,HERE>>
+					   <DESCRIBABLE? .F T>
+					   <OR <BTST .ALL? ,D-ALL?>
+					       <SIMPLE-DESC? .F>>>
+				      <SET DB ,D-BIT>
+				      <SETG D-BIT <>>
+				      <COND (<DESCRIBE-CONTENTS
+					      .F
+					      T
+					      <COND (.PARA?
+						     <+ ,D-ALL?
+							,D-PARA?>)
+						    (ELSE ,D-ALL?)>>
+					     <SET 1ST? <>>
+					     <SET PARA? T>)>
+				      <SETG D-BIT .DB>)>
+			       <SET F <NEXT? .F>>>)>
+		<COND (<AND <NOT .1ST?>
+			    <EQUAL? .LEVEL <> T>
+			    <EQUAL? .OBJ ,HERE <LOC ,WINNER>>>
+		       <CRLF>)>
+		<NOT .1ST?>)>>
+
+"DESCRIBE-START -- add starters for special classes of objects here"
+
+<ROUTINE DESCRIBE-START (OBJ N)
+	 <COND (<EQUAL? .OBJ ,HERE>
+		<COND (<EQUAL? ,D-BIT ,PERSON>
+		       <TELL "You see ">)
+		      (ELSE
+		       <TELL "There ">
+		       <COND (.N <TELL "are ">)
+			     (ELSE <TELL "is ">)>)>)
+	       (<EQUAL? .OBJ ,PLAYER>
+		<COND (<EQUAL? ,D-BIT ,WEARBIT>
+		       <TELL " You are wearing ">)
+		      (T
+		       <TELL "You are carrying ">)>)
+	       (<FSET? .OBJ ,PERSON>
+		;<COND (<NOT <FSET? .OBJ ,NOTHEBIT>>
+		       <TELL "The ">)> ;"hand is only one this clause catches"
+		<TELL CTHE .OBJ " has ">)
+	       (<FSET? .OBJ ,SURFACEBIT>
+		<COND (<EQUAL? .OBJ ,LADDER> <TELL "Stand">)
+		      (ELSE <TELL "Sitt">)>
+		<TELL "ing on " THE .OBJ>
+		<COND (.N <TELL " are ">)
+		      (ELSE <TELL " is ">)>)
+	       (ELSE
+		<TELL CTHE .OBJ " contains ">)>>
+
+"DESCRIBE-SPECIAL -- add special trailers to object descriptions here"
+
+<ROUTINE DESCRIBE-SPECIAL (OBJ)
+	 <COND (<FSET? .OBJ ,ONBIT>
+		<TELL " (providing light)">)>>
+
+"determines if an object is describable at all."
+
+<GLOBAL D-BIT <>>	;"bit to screen objects"
+
+<ROUTINE DESCRIBABLE? (OBJ "OPT" (CONT? <>))
+	 <COND (<FSET? .OBJ ,INVISIBLE> <RFALSE>)
+	       (<EQUAL? .OBJ ,WINNER> <RFALSE>)
+	       (<AND <EQUAL? .OBJ <LOC ,WINNER>>
+		     <NOT <EQUAL? ,HERE <LOC ,WINNER>>>>
+		<RFALSE>)
+	       (<AND <NOT .CONT?> <FSET? .OBJ ,NDESCBIT>>
+		<RFALSE>)
+	       (,D-BIT
+		<COND (<G? ,D-BIT 0>
+		       <COND (<FSET? .OBJ ,D-BIT> <RTRUE>)
+			     (ELSE <RFALSE>)>)
+		      (<NOT <FSET? .OBJ <- ,D-BIT>>>
+		       <RTRUE>)
+		      (ELSE <RFALSE>)>)
+	       (ELSE
+		<RTRUE>)>>
+
+"Determines, for DESCRIBE-OBJECTS, if an object has a simple description
+ (not a FDESC, LDESC, or whatever)."
+
+<ROUTINE SIMPLE-DESC? (OBJ "AUX" STR)
+	 <COND (<AND <GETP .OBJ ,P?FDESC>
+		     <NOT <FSET? .OBJ ,TOUCHBIT>>>
+		<RFALSE>)
+	       (<AND <SET STR <GETP .OBJ ,P?DESCFCN>>
+		     <APPLY .STR ,M-OBJDESC? .OBJ>>
+		<RFALSE>)
+	       (<GETP .OBJ ,P?LDESC> <RFALSE>)
+	       (ELSE <RTRUE>)>>
+
+
+
+"DESCRIBE-REST finishes 'Opening the crocodile's mouth reveals '"
+
+<ROUTINE DESCRIBE-REST (OBJ)
+	 <COND (<NOT <DESCRIBE-CONTENTS .OBJ>>
+	        <TELL "nothing">)>
+	 <RTRUE>>
+
+"DESCRIBE-SENT does the whole ball of wax"
+
+<ROUTINE DESCRIBE-SENT (OBJ)
+	 <COND (<NOT <DESCRIBE-CONTENTS .OBJ <> <+ ,D-ALL? ,D-PARA?>>>
+	        <TELL "The " D .OBJ " is empty.">)>
+	 <RTRUE>>
+
+"DESCRIBE-NOTHING returns false if nothing was described"
+
+;<ROUTINE DESCRIBE-NOTHING ()
+	 <COND (<DESCRIBE-CONTENTS ,PRSO 2>
+	 	<COND (<NOT <IN? ,WINNER ,PRSO>>
+		       <CRLF>)>
+		<RTRUE>)
+	       (T ;"nothing"
+		<RFALSE>)>>
+
+<END-SEGMENT>
+
+;"END"
\ No newline at end of file
diff --git a/erasmus.zil b/erasmus.zil
new file mode 100644
index 0000000..da206f8
--- /dev/null
+++ b/erasmus.zil
@@ -0,0 +1,3097 @@
+"ERASMUS for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc.  All Rights Reserved."
+
+<FILE-FLAGS SENTENCE-ENDS?>
+
+<BEGIN-SEGMENT ERASMUS>
+
+;<CONSTANT CREW
+	  <LTABLE HENDRIK VINCK MAETSUKKER GINSEL SPILLBERGEN VAN-NEKK
+		  CROOCQ SONK ROPER PIETERZOON SALAMON>>
+
+<OBJECT COMPASS
+	(SCENE S-ERASMUS)
+	(DESC "compass")
+	(SYNONYM COMPASS)
+	(ADJECTIVE MAGNETIC)
+	(FLAGS TAKEBIT READBIT)
+	(ACTION COMPASS-F)>
+
+<ROUTINE COMPASS-F ()
+	 <COND (<VERB? EXAMINE READ>
+		<TELL
+"The compass points north.  From it you can see that the course is ">
+		<TELL-DIRECTION ,SHIP-DIRECTION>
+		<TELL " and that the wind is out of the east, perhaps
+a point or two south of east." CR>)>>
+
+<OBJECT DECK
+	(SCENE S-ERASMUS)
+	(LOC LOCAL-GLOBALS)
+	(DESC "deck")
+	(SYNONYM DECK ABOVE WATCH POST POSTS)
+	(FLAGS NDESCBIT TAKEBIT)
+	(GENERIC GENERIC-DECK-F)
+	(ACTION DECK-F)>
+
+<ROUTINE DECK-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<NOUN-USED? ,PRSO ,W?WATCH>
+		       <COND (<FSET? ,MAETSUKKER ,SCOREBIT>
+			      <TELL
+"The men on watch are tired." CR>)
+			     (ELSE
+			      <TELL
+"The watch is as fresh as can be expected." CR>)>)>)
+	       (<VERB? TAKE>
+		<COND (<NOUN-USED? ,PRSO ,W?WATCH>
+		       <TELL
+"You are too tired to take the watch yourself." CR>)
+		      (ELSE
+		       <TELL "You can't take that." CR>)>)
+	       (<VERB? RELEASE>
+		<COND (<HERE? ,BELOW-DECKS>
+		       <TELL
+"You should probably send some of these men out to relieve the
+watch." CR>)
+		      (ELSE
+		       <TELL
+,YOU-HAVE-TO "send some fresh crewmen out to do that." CR>)>)
+	       (<VERB? WALK-UNDER>
+		<DO-WALK ,P?FORE>)
+	       (<VERB? STEP-ON BOARD>
+		<DO-WALK ,P?OUT>)>>
+
+<OBJECT REEF
+	(LOC LOCAL-GLOBALS)
+	(OWNER REEF)
+	(DESC "reef")
+	(SYNONYM REEF REEFS REEF-TOPS ROCKS GAP BREAK)
+	(FLAGS NDESCBIT SCOREBIT)
+	(ACTION REEF-F)>
+
+<ROUTINE REEF-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<SCENE? ,S-ANJIRO ,S-RODRIGUES>
+		       <TELL
+"The reefs are over the horizon, invisible." CR>)
+		      (<NOT ,REEF-FLAG>
+		       <TELL
+"You've been avoiding reefs for days.  Right now the visibility is
+terrible; only a few hundred yards.  You couldn't see a reef unless
+you were almost on top of it.  A horrible thought!" CR>)
+		      (<AND <EQUAL? ,SHIP-X 8> ;"10"
+			    <EQUAL? ,SHIP-Y 2>>
+		       <TELL
+G"There's a break in the reef ahead and to starboard!" CR>)
+		      (<AND <EQUAL? ,SHIP-X 6> ;"11"
+			    <EQUAL? ,SHIP-Y 2>>
+		       <TELL
+"The gap in the reef is to port." CR>)
+		      (<AND <EQUAL? ,SHIP-Y 1> ;"12"
+			    <EQUAL? ,SHIP-X 5>>
+		       <TELL
+"The neck of the pass is right here, right to starboard, a maelstrom
+of foaming sea and crashing combers." CR>)
+		      (<AND <EQUAL? ,SHIP-Y 1>
+			    <G? ,SHIP-X 0>
+			    <L? ,SHIP-Y 5>>
+		       <TELL
+"The reef surrounds you on both sides, a terrifyingly narrow channel
+hemmed in by rocks and smashed by waves." CR>)
+		      (<EQUAL? ,REEF-X ,REEF-Y>
+		       <TELL
+"The reef is barely two hundred yards ">
+		       <COND (<EQUAL? ,SHIP-DIRECTION ,P?WEST>
+			      <TELL "ahead">)
+			     (<EQUAL? ,SHIP-DIRECTION ,P?SW>
+			      <TELL "to starboard">)
+			     (<EQUAL? ,SHIP-DIRECTION ,P?NW>
+			      <TELL "to port">)
+			     (ELSE <TELL "away">)>
+		       <TELL ", great black claws of rocks
+pounded by the hungry sea.  A foaming line of surf looms ahead,
+broken intermittently to port." CR>)
+		      (ELSE
+		       <TELL
+"The reef is off to the west, veiled in storm but revealed by
+breakers." CR>)>)
+	       (<VERB? TURN-AROUND>
+		<TELL ,YOU-HAVE-TO G"specify a direction." CR>)
+	       (<VERB? TURN-TOWARD TURN-AWAY AVOID>
+		<COND (,REEF-FLAG
+		       <COND (<VERB? TURN-TOWARD>
+			      <SETG P-DIRECTION ,P?STARBOARD>)
+			     (ELSE
+			      <SETG P-DIRECTION ,P?PORT>)>
+		       <PERFORM ,V?TURN ,WHEEL ,INTDIR>
+		       <RTRUE>)>)>>
+
+<OBJECT FORESAILS
+	(LOC LOCAL-GLOBALS)
+	(DESC "foresails")
+	(SYNONYM FORESAILS SAILS SAIL HALLIARD)
+	(ADJECTIVE FORE)
+	(FLAGS NDESCBIT SCOREBIT)
+	(ACTION FORESAILS-F)>
+
+<ROUTINE FORESAILS-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<FSET? ,FORESAILS ,TRYTAKEBIT>
+		       <TELL "The foremast has snapped.  You may be able
+to survive without it for a while, though." CR>)
+		      (ELSE
+		       <TELL
+"In this storm, only the barest storm sails are necessary, but you
+can't get by with none.  The foresails ">
+		       <COND (<FSET? ,PRSO ,RMUNGBIT>
+			      <TELL "have been torn away!" CR>)
+			     (ELSE
+			      <TELL "are barely hanging together." CR>)>)>)
+	       (<P? ASK-ABOUT * FORESAILS>
+		<TELL
+D ,PRSO " replies, \"Foresails only in a storm like this, by
+God!  Anything more and we'd lose the mast!\"" CR>)
+	       (<VERB? LOWER>
+		<COND (<OR <FSET? ,FORESAILS ,RMUNGBIT>
+			   <FSET? ,FORESAILS ,TRYTAKEBIT>>
+		       <TELL "No need for that!" CR>)
+		      (ELSE
+		       <TELL
+"Without foresails, there would be no control, and the ship would be
+doomed.  You wisely reconsider." CR>)>)
+	       (<VERB? RAISE REPAIR>
+		<COND (<FSET? ,FORESAILS ,TRYTAKEBIT>
+		       <TELL
+"The mast itself has snapped, there's no way to repair the sails!" CR>)
+		      (<NOT <FSET? ,FORESAILS ,RMUNGBIT>>
+		       <COND (<FSET? ,FORESAILS ,SCOREBIT>
+			      <TELL
+"The foresails are still holding on, the maximum sail that the
+ship can tolerate in this terrific gale." CR>)
+			     (ELSE
+			      <TELL
+"The new foresails have already been raised." CR>)>)
+		      (,CREW-ON-DECK?
+		       <FCLEAR ,FORESAILS ,RMUNGBIT>
+		       <TELL
+"You yell to the crewmen, \"Fores'ls ho!\"  Foot by foot they haul
+themselves into the shrouds of the foremast rigging, dragging new
+sails aloft as others below
+lean on the ropes to give them a hand.  They curse the sail out of
+its ropes.  It falls open, cracking like a cannonade as the wind
+fills it, and the ship lurches.  Now you have some control!" CR>
+		       <SCORE-OBJECT ,FORESAILS>)
+		      (<OR <IN? ,HENDRIK ,ON-DECK>
+			   <IN? ,GINSEL ,ON-DECK>
+			   <IN? ,VINCK ,ON-DECK>
+			   <IN? ,MAETSUKKER ,ON-DECK>>
+		       <QUEUE I-HANDS 2>
+		       <TELL
+"The crewmen on deck try to obey, but there are too few of them!  You
+need more crew on deck!  They ring the bell.  \"All hands on deck!\"
+someone screams." CR>)
+		      (ELSE
+		       <TELL
+"There's no one here to carry out your order!" CR>)>)>>
+
+<OBJECT LG-ERASMUS
+	(LOC LOCAL-GLOBALS)
+	(OWNER BLACKTHORNE)
+	(DESC "Erasmus")
+	(SYNONYM ERASMUS SHIP BOAT)
+	(FLAGS NDESCBIT THE ;PERSON FEMALE VEHBIT SCOREBIT)
+	(GENERIC GENERIC-SHIP-F)
+	(ACTION LG-ERASMUS-F)>
+
+<ROUTINE GENERIC-SHIP-F (R F)
+	 ,LG-ERASMUS>
+
+<ROUTINE LG-ERASMUS-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<P? (TELL ASK-ABOUT) LG-ERASMUS>
+		<TELL "You have been at sea too long!" CR>)
+	       (<VERB? EXAMINE>
+		<COND (<SCENE? ,S-ANJIRO>
+		       <COND (<HERE? ,ANJIRO ,ANJIRO-WATERFRONT
+				     ,ANJIRO-HARBOR ,AT-ERASMUS>
+			      <TELL
+"The " I "Erasmus"" is anchored neatly, fifty yards from shore, in good
+water, with three bow cables.  You can see native men aboard." CR>
+			      <COND (<NOT <FSET? ,RUTTER ,RMUNGBIT>>
+				     <FSET ,RUTTER ,RMUNGBIT>
+				     <TELL CR
+"With a start you realize you don't know where your rutters are!  Can
+they still be on the ship?  They are your most precious possessions,
+and the stolen Portuguese one is a death sentence in any Catholic
+country!" CR>)>
+			      <RTRUE>)
+			     (ELSE
+			      <TELL
+"You are surprised at how neat the ship is.  The tattered sails are down
+and tied in place.  But the lashings are different from any you've ever
+seen.  You presume the Japaners have made the vessel secure." CR>)>)
+		      (<FSET? ,FORESAILS ,TRYTAKEBIT>
+		       <TELL
+"The ship is without a foremast!" CR>)
+		      (<FSET? ,FORESAILS ,RMUNGBIT>
+		       <TELL
+"Right now, the "I"Erasmus"" is missing her foresails." CR>)
+		      (ELSE
+		       <TELL
+"The " I "Erasmus"" is a pisscutter of a ship, lean and taut as a
+greyhound.  If she can make it to port, God willing, all will be
+well.  Otherwise, you're a dead man." CR>)>)
+	       (<AND <VERB? DROP>
+		     <EQUAL? ,P-PRSA-WORD ,W?ABANDON>
+		     <SCENE? ,S-ERASMUS>>
+		<TELL
+G"That would be suicide in this storm." CR>)
+	       (<VERB? WALK-TO>
+		<COND (<AND <SCENE? ,S-ANJIRO ,S-RODRIGUES>
+			    <NOT <IN? ,PLAYER ,SMALL-BOAT>>>
+		       <TELL
+,YOU-HAVE-TO "use a boat to do that." CR>)>)
+	       (<VERB? LEAP DIVE>
+		<COND (<HERE? ,ON-DECK ,BRIDGE-OF-ERASMUS>
+		       <COND (<SCENE? ,S-ERASMUS>
+			      <TELL
+G"That would be suicide in this storm." CR>)
+			     (ELSE
+			      <TELL
+"You hurry over the side and down the gangway!" CR CR>
+			      <DO-WALK ,P?DOWN>)>)
+		      (ELSE
+		       <TELL
+"You can hardly jump overboard from here!" CR>)>)
+	       (<AND <VERB? DISEMBARK EXIT>
+		     <SCENE? ,S-ANJIRO ,S-RODRIGUES>>
+		<DO-WALK ,P?DOWN>)
+	       (<VERB? POINT>
+		<COND (<EQUAL? ,OMI-QUESTION 1 2>
+		       <TELL
+"\"That's no answer, heretic!\"" CR>)
+		      (<IN? ,SEBASTIO ,HERE>
+		       <TELL
+"\"Your ship has been well cared for, pirate!\"" CR>)>)
+	       (<VERB? BOARD CLIMB-ON THROUGH CLIMB-UP>
+		<COND (<HERE? ,AT-ERASMUS>
+		       <DO-WALK ,P?UP>)
+		      (<HERE? ,ON-DECK ,BRIDGE-OF-ERASMUS
+			      ,PASSAGEWAY ,PILOTS-CABIN ,MATES-CABIN
+			      ,CAPTAINS-CABIN>
+		       <TELL "You already are!" CR>)
+		      (ELSE
+		       <YOULL-HAVE-TO "get to it">)>)
+	       (<VERB? TURN>
+		<COND (<HERE? ,BRIDGE-OF-ERASMUS>
+		       <PERFORM ,V?TURN ,WHEEL ,PRSI>
+		       <RTRUE>)
+		      (<SCENE? ,S-ERASMUS>
+		       <ARENT-WHERE-PRSO-IS>
+		       <FRUSTRATED <COND (<FSET? ,HENDRIK ,DEAD> ,VINCK)
+					 (ELSE ,HENDRIK)>>)>)
+	       (<VERB? REPAIR>
+		<MORE-SPECIFIC>)
+	       (<HOSTILE-VERB?>
+		<TELL "What an infantile idea." CR>)>>
+
+<ROUTINE ARENT-WHERE-PRSO-IS ()
+	 <TELL
+"You aren't on the bridge, where " THE ,PRSO " is.">>
+
+<OBJECT GANGWAY
+	(LOC LOCAL-GLOBALS)
+	(DESC "gangway")
+	(SYNONYM GANGWAY)
+	(FLAGS NDESCBIT)
+	(ACTION GANGWAY-F)>
+
+<ROUTINE GANGWAY-F ()
+	 <COND (<VERB? CLIMB-UP>
+		<DO-WALK ,P?UP>)
+	       (<VERB? CLIMB-DOWN>
+		<DO-WALK ,P?DOWN>)
+	       (<VERB? CLIMB-FOO CLIMB-ON>
+		<COND (<HERE? ,AT-ERASMUS ,WHARF>
+		       <DO-WALK ,P?UP>)
+		      (<HERE? ,ON-DECK ,MAIN-DECK>
+		       <DO-WALK ,P?DOWN>)>)>>
+
+<GLOBAL STORM-DELAY? <>>
+
+<GLOBAL SHIP-DIRECTION <>>
+<GLOBAL SHIP-X 21>
+<GLOBAL SHIP-Y 9>
+
+<GLOBAL SHIP-COURSE <>>
+
+;<GLOBAL SHIP-DEBUG <>>	;"T to print out ship position stuff"
+
+;<ROUTINE SHIP-INFO ()
+	 <TELL
+"[Course ">
+	 <TELL-DIRECTION ,SHIP-DIRECTION>
+	 <TELL "; wheel ">
+	 <TELL-DIRECTION ,SHIP-COURSE>
+	 <TELL "; X=" N ,SHIP-X ",Y=" N ,SHIP-Y "; Reef X=" N ,REEF-X ",Y=" N ,REEF-Y "]" CR>>
+
+<ROUTINE QUEUE-STORM ("AUX" S DONE?)
+	 <SET S <GETPT <GET ,SCENE-LOCS ,SCENE> ,P?SCORE>>
+	 <SET S <GETB .S 0>>
+	 <SET DONE? <DONE-BELOW?>>
+	 <COND (<L? ,STORM-DELAY? 0>
+		<SETG STORM-DELAY? <+ ,STORM-DELAY? 1>>
+		<QUEUE I-STORM 30>)
+	       (<AND ,STORM-DELAY? ;"delay storm if loser increased score"
+		     <FSET? ,BELL ,SCOREBIT> ;"unless we're in height of storm"
+		     <G? .S ,STORM-DELAY?>
+		     <NOT .DONE?>>
+		<SETG STORM-DELAY? .S>
+		<QUEUE I-STORM 10>
+		<RFALSE>)
+	       (<OR <FSET? ,HERE ,OUTSIDE> ;"storm fast if outside"
+		    .DONE? ;"or hanging around below decks too long">
+		<SETG STORM-DELAY? .S>
+		<QUEUE I-STORM
+		       <COND (<OR ,REEF-FLAG <EQUAL? .S 7>> 4)
+			     (<AND <FSET? ,HERE ,OUTSIDE> .DONE?> 3)
+			     (ELSE 9)>>)
+	       (<AND <EQUAL? ,SHIP-COURSE ,P?PORT ,P?STARBOARD> ;"or if stupid"
+		     <NOT <FSET? ,WHEEL ,RMUNGBIT>>
+		     <NOT <FSET? ,HENDRIK ,TRYTAKEBIT>>>
+		<QUEUE I-STORM 2>)
+	       (ELSE ;"storm slow if inside"
+		<SETG STORM-DELAY? .S>
+		<QUEUE I-STORM
+		       <COND (,REEF-FLAG 7) (ELSE 15)>>)>>
+
+<GLOBAL WHEEL-SPINNING? <>>
+
+<ROUTINE I-STORM ()
+	 <COND (<NOT <QUEUE-STORM>> ;"returns false if storm-delay in effect"
+		<RFALSE>)>
+	 <COND (<EQUAL? ,SHIP-COURSE ,P?FORE>)
+	       (<EQUAL? ,SHIP-COURSE ,P?PORT>
+		<COND (<EQUAL? ,SHIP-DIRECTION ,P?WEST>
+		       <SETG SHIP-DIRECTION ,P?SW>)
+		      (<EQUAL? ,SHIP-DIRECTION ,P?SW>
+		       <SETG SHIP-DIRECTION ,P?SOUTH>)
+		      (<EQUAL? ,SHIP-DIRECTION ,P?NW>
+		       <SETG SHIP-DIRECTION ,P?WEST>)
+		      (<EQUAL? ,SHIP-DIRECTION ,P?NORTH>
+		       <SETG SHIP-DIRECTION ,P?NW>)>)
+	       (<EQUAL? ,SHIP-COURSE ,P?STARBOARD>
+		<COND (<EQUAL? ,SHIP-DIRECTION ,P?WEST>
+		       <SETG SHIP-DIRECTION ,P?NW>)
+		      (<EQUAL? ,SHIP-DIRECTION ,P?SW>
+		       <SETG SHIP-DIRECTION ,P?WEST>)
+		      (<EQUAL? ,SHIP-DIRECTION ,P?NW>
+		       <SETG SHIP-DIRECTION ,P?NORTH>)
+		      (<EQUAL? ,SHIP-DIRECTION ,P?SOUTH>
+		       <SETG SHIP-DIRECTION ,P?SW>)>)>
+	 <COND (<EQUAL? ,SHIP-DIRECTION ,P?WEST>
+		<COND (<OR <FSET? ,FORESAILS ,RMUNGBIT>
+			   <AND <EQUAL? ,SHIP-Y 1>
+				<L? ,SHIP-X 6>>>
+		       <SETG SHIP-X <- ,SHIP-X 1>>)
+		      (ELSE
+		       <SETG SHIP-X <- ,SHIP-X 2>>)>)
+	       (<EQUAL? ,SHIP-DIRECTION ,P?SW>
+		<SETG SHIP-X <- ,SHIP-X 1>>
+		<SETG SHIP-Y <- ,SHIP-Y 1>>)
+	       (<EQUAL? ,SHIP-DIRECTION ,P?NW>
+		<SETG SHIP-X <- ,SHIP-X 1>>
+		<SETG SHIP-Y <+ ,SHIP-Y 1>>)
+	       (<EQUAL? ,SHIP-DIRECTION ,P?NORTH ,P?SOUTH>
+		<SHIP-BROADSIDE>)>
+	 <COND (<NOT <REEF-DISTANCE>>
+		<COND (<G? ,SHIP-X 6>
+		       <TELL CR
+"The waiting spines of the reef tear into the ship!">
+		       <COND (<FSET? ,HERE ,OUTSIDE>
+			      <TELL " The gap is tantalizingly
+close, but you missed it.">)>
+		       <TELL " Two years out from England, and it ends here in
+a watery grave." CR>
+		       <JIGS-UP>)
+		      (<EQUAL? ,SHIP-X 6>
+		       <TELL CR
+"The ship smashes into the ">
+		       <COND (<FSET? ,HERE ,OUTSIDE>
+			      <TELL "side of the gap in the ">)>
+		       <TELL "reef, tearing a huge
+rent in the hull.  Water pours in, and the stern crashes against the rocks">
+		       <COND (<FSET? ,HERE ,OUTSIDE>
+			      <TELL
+", throwing you to the deck.  Suddenly the mainmast gives way.  It's crashing
+down upon you">)>
+		       <TELL "!" CR>
+		       <JIGS-UP>)
+		      (ELSE
+		       <CRLF>
+		       <COND (<FSET? ,HERE ,OUTSIDE>
+			      <TELL "You steer">)
+			     (ELSE
+			      <TELL "The ship steers">)>
+		       <TELL
+" directly into the waiting rocks!" CR>
+		       <JIGS-UP>)>
+		<RFATAL>)>
+	 <COND (<AND <L? ,SHIP-X 19>
+		     <NOT <GETP ,BLACKTHORNE ,P?HEALTH>>>
+		<QUEUE I-TIRED-WARNING 5 T>
+		<QUEUE I-TIRED 10 T>)>
+	 ;<COND (,SHIP-DEBUG <SHIP-INFO>)>
+	 <COND (,REEF-FLAG)
+	       (<REEF-SIGHTED?>
+		<SETG REEF-FLAG T>
+		<CRLF>
+		<COND (<FSET? ,HERE ,OUTSIDE>
+		       <COND (<IN? ,GINSEL ,BELOW-DECKS>
+			      <TELL "The bow lookout">)
+			     (ELSE
+			      <TELL "Ginsel, the bow lookout,">)>
+		       <TELL " yells \"Rotz vooruit!\"  Reef
+ahead!  A foaming line of surf stretches ahead of you,
+broken intermittently to port!" CR>
+		       <COND (<AND <HERE? ,BRIDGE-OF-ERASMUS>
+				   <FSET? ,HENDRIK ,RMUNGBIT>>
+			      <FCLEAR ,HENDRIK ,RMUNGBIT>
+			      <TELL CR
+"The yelling wakes Hendrik." CR>)>)
+		      (ELSE
+		       <FCLEAR ,HENDRIK ,RMUNGBIT>
+		       <TELL
+"Faintly, over the roar of the storm, you hear the terrified
+cry \"Rotz vooruit!\"  Reef ahead!  ">
+		       <COND (<HERE? ,BELOW-DECKS>
+			      <TELL
+"The crewmen pull themselves painfully from their bunks.  \"We're
+dead men!\" screams one.">
+			      <COND (<IN? ,VINCK ,HERE>
+				     <MOVE ,VINCK ,ON-DECK>
+				     <TELL
+" \"We'd better go above, Pilot,\" urges Vinck as he shuffles toward
+the door." CR>)
+				    (ELSE <CRLF>)>)
+			     (<HERE? ,CAPTAINS-CABIN>
+			      <TELL
+"\"Get out there, Pilot!\" Spillbergen orders you.  \"We'll all die
+thanks to you!  Out!\"" CR>)
+			     (ELSE
+			      <TELL
+"You sense from the terror in the voice that the reefs are close.">
+			      <COND (<IN? ,GINSEL ,BELOW-DECKS>
+				     <TELL
+" Has the watch been asleep?  All too likely!">)>
+			      <CRLF>)>)>
+		<RTRUE>)>
+	 <COND (<AND <EQUAL? ,SHIP-Y 9>
+		     <EQUAL? ,SHIP-X 19>>
+		<QUEUE I-HENDRIK -1>
+		<FCLEAR ,WHEEL ,ONBIT>
+		<TELL CR
+"The ship heels in a sudden squall, throwing you ">
+		<COND (<FSET? ,WHEEL ,RMUNGBIT>
+		       <COND (<HERE? ,BRIDGE-OF-ERASMUS>
+			      <TELL
+"from your post at the wheel." CR>)
+			     (ELSE
+			      <TELL "to the deck." CR>)>)
+		      (ELSE
+		       <COND (<HERE? ,BRIDGE-OF-ERASMUS>
+			      <TELL
+"from your post at the wheel, which">)
+			     (ELSE
+			      <TELL "to the deck.  The wheel">)>
+		       <SETG SHIP-COURSE ,P?PORT>
+		       <SETG SHIP-DIRECTION ,P?SW>
+		       <QUEUE I-BROADSIDE 4>
+		       <QUEUE I-SHIP-BROADSIDE 8>
+		       <TELL
+", uncontrolled, begins to turn to port." CR>)>
+		<RTRUE>)
+	       (<OR <EQUAL? ,SHIP-X 18>
+		    <AND <EQUAL? ,SHIP-Y 9>
+			 <EQUAL? ,SHIP-X 17>>>
+		<TELL CR
+"The wind freshens even more, and the ship lurches." CR>
+		<RTRUE>)
+	       (<AND <EQUAL? ,SHIP-Y 8>
+		     <EQUAL? ,SHIP-X 14>>
+		<COND (<FSET? ,HERE ,OUTSIDE>
+		       <TELL CR
+"A forepeak halliard snaps, and the highest top gallant spar is carried
+away into the sea, ">
+		       <COND (<EQUAL? ,SHIP-DIRECTION ,P?SW>
+			      <TELL
+"but the ship is now making way parallel to the reef." CR>)
+			     (ELSE
+			      <TELL
+"and the ship continues to approach the waiting reef." CR>)>)>)
+	       (<AND <EQUAL? ,SHIP-Y 7>
+		     <EQUAL? ,SHIP-X 13>>
+		<COND (<FSET? ,HERE ,OUTSIDE>
+		       <CRLF>
+		       <COND (<EQUAL? ,SHIP-DIRECTION ,P?SW>
+			      <TELL
+"The ship runs parallel to the reef, barely staying away from it, and a huge following wave towers over the ship!" CR>)
+			     (ELSE
+			      <TELL
+"The ship is being carried still closer to the reef, and a huge wave is
+approaching from the starboard side!" CR>)>)>)
+	       (<AND <EQUAL? ,SHIP-Y 6>
+		     <EQUAL? ,SHIP-X 12>>
+		<COND (<NOT <EQUAL? ,SHIP-DIRECTION ,P?SW>>
+		       <FSET ,LG-ERASMUS ,RMUNGBIT>)>
+		<COND (<FSET? ,HERE ,OUTSIDE>
+		       <TELL CR
+"Another halliard gives, block and tackle swinging wildly.  The wave breaks
+over the ship!  ">
+		       <COND (<EQUAL? ,SHIP-DIRECTION ,P?SW>
+			      <TELL "It looks for a moment like you're
+going to founder, but she shakes it off." CR>)
+			     (ELSE
+			      <TELL
+"The force of the wave drives the ship onto the reef, the sharp
+rocks tearing into the wooden hull!  In what seems like an instant, she's
+sinking!" CR>)>
+		       <RTRUE>)>)
+	       (<AND <EQUAL? ,SHIP-Y 5>
+		     <EQUAL? ,SHIP-X 11>>
+		<FSET ,FORESAILS ,RMUNGBIT>
+		<COND (<FSET? ,HERE ,OUTSIDE>
+		       <CRLF>
+		       <COND (<EQUAL? ,SHIP-DIRECTION ,P?SW>
+			      <TELL
+"Another following sea towers above the ship.  The ship is wallowing,
+and the foresails are torn away by the tempest." CR>
+			      <RTRUE>)
+			     (ELSE
+			      <JIGS-UP
+"You struggle to stay afloat in the raging sea, but you are too weak to
+fight the waves for long, and are dashed against the rocks.">
+			      <RFATAL>)>)>)
+		 (<AND <EQUAL? ,SHIP-Y 4>
+		       <EQUAL? ,SHIP-X 10>>
+		  <FSET ,HENDRIK ,DEAD>
+		  <REMOVE ,HENDRIK>
+		  <COND (<FSET? ,HERE ,OUTSIDE>
+			 <TELL CR
+"This wave comes in stronger than the last.  Hendrik is caught and lifted,
+gasping and struggling, into the sea." CR>
+			 <TELL CR
+"A giant comber throws Hendrik high above the ship, then takes him
+away and pulps him against a rock spine." CR>)>)
+		 (<AND <EQUAL? ,SHIP-Y 2>
+		       <EQUAL? ,SHIP-X 8>>
+		  <COND (<FSET? ,HERE ,OUTSIDE>
+			 <TELL CR
+G"There's a break in the reef ahead and to starboard!" CR>)>)
+		 (<AND <EQUAL? ,SHIP-Y 2>
+		       <EQUAL? ,SHIP-X 6>>
+		  <COND (<FSET? ,HERE ,OUTSIDE>
+			 <TELL CR
+"The gulch through the reef is three points to windward, and you aren't gaining
+way!  You search desperately for another channel but know there is
+none.  The "I"Erasmus"" is heading for the rocks starboard of the gap!" CR>)>)
+		 (<AND <EQUAL? ,SHIP-Y 1>
+		       <EQUAL? ,SHIP-X 7>>
+		  <COND (<FSET? ,HERE ,OUTSIDE>
+			 <TELL CR
+"The ship is swept past the gap in the reef!" CR>)>)
+		 (<AND <EQUAL? ,SHIP-Y 1>
+		       <EQUAL? ,SHIP-X 5>>
+		  <COND (<HERE? ,BRIDGE-OF-ERASMUS ,ON-DECK>
+			 <MOVE ,VINCK ,HERE>)
+			(ELSE <MOVE ,VINCK ,BRIDGE-OF-ERASMUS>)>
+		  <COND (<FSET? ,HERE ,OUTSIDE>
+			 <TELL CR
+"The ship is gaining way, helped by the fall off from the wind.  You are
+holding course parallel to the reef and approaching a narrow gap which
+heads to starboard." CR CR
+"You see Vinck making his way up the companionway to the bridge." CR>)>)
+		 (<AND <EQUAL? ,SHIP-Y 1>
+		       <EQUAL? ,SHIP-X 4>
+		       <EQUAL? ,SHIP-DIRECTION ,P?WEST>>
+		  <TELL CR
+"There is a wailing, tormented shudder as the keel scrapes the razor
+spines of the reef below!">
+		  <COND (<NOT <FSET? ,WHEEL ,RMUNGBIT>>
+			 <SETG WHEEL-SPINNING? T>
+			 <DEQUEUE I-BROADSIDE>
+			 <COND (<FSET? ,WHEEL ,ONBIT>
+				<FCLEAR ,WHEEL ,ONBIT>
+				<COND (<FSET? ,HERE ,OUTSIDE>
+				       <TELL
+"The"G" wheel spins out of your hands!" CR>)>)
+			       (ELSE
+				<TELL
+"The wheel begins spinning wildly!" CR>)>)>)
+		 (<AND <EQUAL? ,SHIP-Y 1>
+		       <EQUAL? ,SHIP-X 3>
+		       <EQUAL? ,SHIP-DIRECTION ,P?WEST>>
+		  <COND (<FSET? ,HERE ,OUTSIDE>
+			 <TELL CR
+"The ship is sucked into a narrow vortex between the rocks.  ">
+			 <COND (<AND <NOT <FSET? ,WHEEL ,ONBIT>>
+				     <NOT <FSET? ,WHEEL ,RMUNGBIT>>>
+				<TELL
+"The wheel spins from side to side, out of control!  ">)>
+			 <FSET ,FORESAILS ,TRYTAKEBIT> ;"can't be repaired"
+			 <TELL "The bowsprit
+catches a rock and is torn loose!  The foremast snaps!  The men on deck
+fall on the rigging with axes and cut it adrift as the ship founders
+down the channel." CR>)>)
+		 (<AND <EQUAL? ,SHIP-Y 1>
+		       <EQUAL? ,SHIP-X 2>
+		       <EQUAL? ,SHIP-DIRECTION ,P?WEST>>
+		  <COND (<AND <NOT <FSET? ,WHEEL ,ONBIT>>
+			      <NOT <FSET? ,WHEEL ,RMUNGBIT>>>
+			 <CRLF>
+			 <JIGS-UP
+"Out of control, the ship spins broadside, and holes against the rocks.">
+			 <RFATAL>)
+			(<FSET? ,HERE ,OUTSIDE>
+			 <TELL CR
+"The ship is pulled by the waves deeper into the strait, and then
+pushed back by the return, but she's making some progress." CR>)>)
+		 (<AND <EQUAL? ,SHIP-Y 1>
+		       <EQUAL? ,SHIP-X 1>
+		       <EQUAL? ,SHIP-DIRECTION ,P?WEST>>
+		  <COND (<FSET? ,HERE ,OUTSIDE>
+			 <TELL CR
+"For an instant, the strait broadens.  Ahead, it narrows ominously and
+turns to port." CR>)>)
+		 (<AND <ZERO? ,SHIP-Y>
+		       <ZERO? ,SHIP-X>
+		       <EQUAL? ,SHIP-DIRECTION ,P?SW>>
+		  <DEQUEUE I-STORM>
+		  <COND (<FSET? ,HERE ,OUTSIDE>
+			 <TELL CR
+"The sea race quickens.  The ship is in the neck and dead, but then the
+keel scrapes a mud shoal, and the shock turns her head.  The rudder bites
+into the sea, the wind and sea join to help, and before the wind she
+speeds through the pass to safety.  Into the bay beyond." CR>
+			 <COND (<IN? ,COMPASS ,BLACKTHORNE>
+				<REMOVE ,COMPASS>)>
+			 <COND (<IN? ,QUILL ,BLACKTHORNE>
+				<REMOVE ,QUILL>)>
+			 <REMOVE ,APPLE>
+			 <SCORE-OBJECT ,REEF>
+			 <CRLF>
+			 <NEXT-SCENE>)>)>>
+
+<GLOBAL REEF-FLAG <>>
+
+"returns T the first time the reef is sighted"
+
+<ROUTINE REEF-SIGHTED? ()
+	 <COND (,REEF-FLAG <RFALSE>)
+	       (<OR <L=? ,REEF-X 2>
+		    <L=? ,REEF-Y 2>>
+		<RTRUE>)
+	       (ELSE <RFALSE>)>>
+
+<GLOBAL REEF-X <>>	;"x distance from ship to reef"
+<GLOBAL REEF-Y <>>	;"y distance from ship to reef"
+
+<ROUTINE REEF-DISTANCE ()
+	 <SETG REEF-X 0>
+	 <SETG REEF-Y 0>
+	 <COND (<EQUAL? ,SHIP-X 0>
+		<COND (<ZERO? ,SHIP-Y>
+		       <SETG REEF-X 1000>
+		       <SETG REEF-Y 1000>)
+		      (ELSE <RFALSE>)>)
+	       (<AND <EQUAL? ,SHIP-Y 0>
+		     <G? ,SHIP-X 0>
+		     <L? ,SHIP-X 7>>
+		<RFALSE>)
+	       (<AND <EQUAL? ,SHIP-Y 1>
+		     <EQUAL? ,SHIP-X 6>>
+		<RFALSE>)
+	       (<AND <EQUAL? ,SHIP-Y 0 1>
+		     <EQUAL? ,SHIP-X 7>>
+		<SETG REEF-X 1>
+		<SETG REEF-Y <- 3 ,SHIP-Y>>)
+	       (<AND <EQUAL? ,SHIP-Y 1>
+		     <L=? ,SHIP-X 5>>
+		<SETG REEF-X ,SHIP-X>
+		<SETG REEF-Y 1>)
+	       (<L=? ,SHIP-Y 1>
+		<COND (<L? ,SHIP-X 7>
+		       <RFALSE>)
+		      (ELSE
+		       <SETG REEF-X <- ,SHIP-X 6>>
+		       <SETG REEF-Y <+ <- ,SHIP-Y> <- ,SHIP-X 4>>>)>)
+	       (<G=? ,SHIP-Y 11>
+		<SETG REEF-X <- ,SHIP-X 15>>
+		<COND (<G? ,SHIP-X 15> <SETG REEF-Y 1000>)
+		      (ELSE <SETG REEF-Y 0>)>)
+	       (<AND <EQUAL? ,SHIP-Y 2>
+		     <EQUAL? ,SHIP-X 6 7>>
+		<SETG REEF-X <- ,SHIP-X 5>>
+		<SETG REEF-Y 1>)
+	       (<G=? ,SHIP-Y 2>
+		<SETG REEF-X <- <- ,SHIP-X 6> <- ,SHIP-Y 2>>>
+		<SETG REEF-Y <- <- ,SHIP-X 4> ,SHIP-Y>>)>
+	 <COND (<OR <L=? ,REEF-X 0> <L=? ,REEF-Y 0>>
+		<SETG REEF-X 0>
+		<SETG REEF-Y 0>
+		<RFALSE>)
+	       (ELSE <RTRUE>)>>
+
+
+
+<OBJECT CREWMEN
+	(LOC BELOW-DECKS)
+	(DESC "crewmen")
+	(SYNONYM CREW CREWMEN CREWMAN MEN MAN SAILOR SAILORS)
+	(FLAGS PERSON DUTCHBIT NOABIT THE PLURAL DONT-ALL)
+	(DESCFCN CREWMEN-DESC)
+	(GENERIC GENERIC-CREWMEN-F)
+	(ACTION LG-CREWMEN-F)>
+
+<ROUTINE GENERIC-CREWMEN-F (R F)
+	 ,LG-CREWMEN>
+
+<ROUTINE CREWMEN-DESC ("OPT" RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (<RARG? OBJDESC>
+		<COND (<HERE? ,BELOW-DECKS>
+		       <COND (,CREW-ON-DECK?
+			      <TELL
+"A few of the worst-off crewmen are still here.">)
+			     (,REEF-FLAG
+			      <TELL
+"Most of the surviving crewmen are preparing to go on deck.">)
+			     (ELSE
+			      <TELL
+"Most of the survivors of the crew are here in bunks
+and hammocks, some sleeping, some awake.">)>)
+		      (<HERE? ,VILLAGE-SQUARE>
+		       <TELL
+"The rabble of the ship's crew kneel behind you, guards watching them.">)>)>>
+
+<OBJECT LG-CREWMEN
+	(LOC LOCAL-GLOBALS)
+	(DESC "crewmen")
+	(SYNONYM CREW CREWMEN CREWMAN MAN MEN)
+	(FLAGS PERSON DUTCHBIT JAPANESEBIT NOABIT THE PLURAL)
+	(GENERIC GENERIC-CREWMEN-F)
+	(ACTION LG-CREWMEN-F)>
+
+<GLOBAL CREW-ON-DECK? <>>
+
+<ROUTINE LG-CREWMEN-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<SCENE? S-ERASMUS S-YABU> ;"dutch crew"
+		<COND (<RARG? WINNER>
+		       <COND (<OR <HERE? PILOTS-CABIN CAPTAINS-CABIN
+					 PASSAGEWAY>
+				  <AND <HERE? ,BELOW-DECKS>
+				       ,CREW-ON-DECK?>>
+			      <TELL "There are no crewmen here." CR>)
+			     (<P? WHO YOU>
+			      <SETG WINNER ,PLAYER>
+			      <PERFORM ,V?WHO ,CREWMEN>
+			      <END-QUOTE>
+			      <RFATAL>)
+			     (<HERE? ,BELOW-DECKS ,MATES-CABIN>
+			      <TELL
+G"The crewmen whine and groan and pretend you are referring to someone
+else.  You'll have to order specific crewmen to get any results." CR>)
+			     (<P? (RAISE REPAIR LOWER REPLACE) FORESAILS>
+			      <RFALSE>)
+			     (<AND <IN? ,VINCK ,HERE>
+				   <P? HELP>
+				   <P? TAKE WHEEL>>
+			      <SETG WINNER ,VINCK>
+			      <PERFORM ,PRSA ,PRSO ,PRSI>
+			      <RTRUE>)
+			     (<AND <HERE? BELOW-DECKS>
+				   <SEND-HIM-OUT?>>
+			      <TELL
+"The crewmen mutter among themselves, but no one moves." CR>)
+			     (ELSE
+			      <CURSES-IN "Dutch">)>)
+		      (<VERB? EXAMINE WHO>
+		       <LIST-PEOPLE ,CREWMAN? "crewman" "crewmen">
+		       <COND (<HERE? ,BELOW-DECKS>
+			      <COND (<IN? ,VINCK ,BELOW-DECKS>
+				     <COND (<IN? ,GINSEL ,BELOW-DECKS>
+					    <COND (<IN? ,MAETSUKKER
+							,BELOW-DECKS>
+						   <TELL
+" Vinck, Ginsel, and Maetsukker are">)
+						  (ELSE
+						   <TELL
+" Vinck and Ginsel are">)>)
+					   (<IN? ,MAETSUKKER ,BELOW-DECKS>
+					    <TELL
+" Vinck and Maetsukker are">)
+					   (ELSE
+					    <TELL
+" Vinck is">)>)
+				    (<IN? ,GINSEL ,BELOW-DECKS>
+				     <COND (<IN? ,MAETSUKKER ,BELOW-DECKS>
+					    <TELL
+" Ginsel and Maetsukker are">)
+					   (ELSE
+					    <TELL
+" Ginsel is">)>)
+				    (<IN? ,MAETSUKKER ,BELOW-DECKS>
+				     <TELL
+" Maetsukker is">)
+				    (ELSE <CRLF> <RTRUE>)>
+			      <TELL
+" in the best condition, although everyone is badly off.">)
+			     (<HERE? ,BRIDGE-OF-ERASMUS>
+			      <TELL "">
+			      <LIST-PEOPLE ,CREWMAN? "crewman" "crewmen"
+					   ,ON-DECK "elsewhere on deck">)
+			     (<HERE? ,ON-DECK>
+			      <TELL "">
+			      <LIST-PEOPLE ,CREWMAN?
+					   "crewman" "crewmen"
+					   ,BRIDGE-OF-ERASMUS
+					   "on the bridge">)>
+		       <CRLF>)
+		      (<AND <VERB? TELL>
+			    ,CREW-ON-DECK?
+			    <HERE? ,BRIDGE-OF-ERASMUS ,ON-DECK>>
+		       <RFALSE>)
+		      (<NOT <CREW-HERE?>>
+		       <TELL
+G"There aren't any crewmen here." CR>
+		       <COND (<VERB? TELL>
+			      <END-QUOTE>
+			      <RFATAL>)
+			     (ELSE <RTRUE>)>)
+		      (<AND <HERE? ,BELOW-DECKS>
+			    <VERB? SEND>>
+		       <TELL
+G"The crewmen whine and groan and pretend you are referring to someone
+else.  You'll have to order specific crewmen to get any results." CR>)
+		      (<AND <VERB? WAKE> <HERE? ,BELOW-DECKS>>
+		       <TELL
+"You cuff a few of the sleepers into wakefulness, but most are too far
+gone to do more than curse feebly." CR>)>)
+	       (<SCENE? S-PIT>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"They look scared." CR>)>)
+	       (<SCENE? S-RODRIGUES>
+		<TELL "There are no longer any crewmen aboard." CR>)
+	       (<SCENE? S-VOYAGE> ;"japanese crew of galley"
+		<COND (<RARG? WINNER>
+		       <COND (<P? (DROP THROW PUT LOWER) ANCHOR>
+			      <RFALSE>)
+			     (ELSE
+			      <CURSES-IN "Japanese">)>)>)
+	       (<SCENE? S-MARIKO>
+ 		<COND (<NOT <ABSTRACT-VERB?>>
+		       <TELL CTHE ,LG-CREWMEN " aren't here." CR>
+		       <COND (<VERB? TELL> <END-QUOTE> <RFATAL>)
+			     (ELSE <RTRUE>)>)>)>>
+
+<ROUTINE CURSES-IN (L)
+	 <TELL
+"The only responses are muttered curses in " .L "." CR>>
+
+<ROUTINE CREW-HERE? ()
+	 <REPEAT ((F <FIRST? ,HERE>))
+		 <COND (<NOT .F>
+			<RFALSE>)
+		       (<AND <NOT <EQUAL? .F ,CREWMEN>>
+			     <FSET? .F ,DUTCHBIT>>
+			<RTRUE>)>
+		 <SET F <NEXT? .F>>>>
+
+<OBJECT HENDRIK
+	(DESC "Hendrik Specz")
+	(SYNONYM HENDRIK SPECZ MATE)
+	(ADJECTIVE HENDRIK THIRD)
+	(FLAGS PERSON DUTCHBIT NOABIT NOTHEBIT)
+	(DESCFCN HENDRIK-DESC)
+	(ACTION HENDRIK-F)>
+
+<ROUTINE HENDRIK-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?>
+		<COND (<FSET? ,HENDRIK ,RMUNGBIT> <RTRUE>)
+		      (<FSET? ,HENDRIK ,TRYTAKEBIT> <RTRUE>)
+		      (ELSE <RFALSE>)>)
+	       (<RARG? OBJDESC>
+		<TELL "Hendrik Specz ">
+		<COND (<FSET? ,HENDRIK ,RMUNGBIT>
+		       <TELL "is asleep at">)
+		      (ELSE
+		       <TELL "has">)>
+		<TELL " the wheel.">)>>
+
+<ROUTINE HENDRIK-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<VERB? FOLLOW WALK WALK-TO WALK-UNDER>
+		       <COND (<FSET? ,WHEEL ,ONBIT>
+			      <TELL
+"\"Pilot, it's my watch.  Let me take the wheel.  You must rest.\"" CR>)
+			     (ELSE
+			      <TELL
+"\"One of us must stay and hold the God-cursed wheel, or we all die!\"" CR>)>)
+		      (<OR <P? TAKE-OVER (<> WHEEL DECK)>
+			   <P? (TAKE TURN) (WHEEL DECK)>>
+		       <FSET ,HENDRIK ,TRYTAKEBIT> ;"hendrik has the wheel"
+		       <HENDRIK-TAKES-WHEEL>
+		       <TELL
+"\"Aye, Pilot, I take the wheel.\"" CR>)
+		      (<P? (RAISE REPAIR LOWER) FORESAILS>
+		       <RFALSE>)
+		      (<PRSO? ,WHEEL>
+		       <TELL
+"\"If you want the wheel, take it,\" snarls Hendrik." CR>)
+		      (<OR <P? SHUT-UP ROOMS>
+			   <AND <P? BE INTADJ>
+				<ADJ? ,W?QUIET>>>
+		       <TELL
+"\"We'll all be quiet soon enough!\"" CR>)
+		      (<VERB? TELL-ME-ABOUT>
+		       <COND (<PRSO? ,JAPAN>
+			      <TELL
+"\"You're the one who said it's here.  Between latitudes thirty and
+forty north, you said.  Well, I don't see it.\"" CR>)
+			     (<PRSO? ,SPILLBERGEN>
+			      <TELL
+"\"He's a maggot-eaten fool and we'll all be dead because of him.\"" CR>)
+			     (ELSE
+			      <TELL
+"He doesn't answer." CR>)>)
+		      (<I-DONT-KNOW?>
+		       <TELL
+"\"You don't know?  You're the God-cursed Pilot, you'd better know!\"" CR>)
+		      (ELSE
+		       <TELL
+"Hendrik's reply is a mixture of whining and curses." CR>)>)
+	       (<VERB? TELL>
+		<COND (<FSET? ,HENDRIK ,RMUNGBIT>
+		       <TELL
+"Hendrik is asleep." CR>
+		       <END-QUOTE>)>)
+	       (<P? EXAMINE>
+		<TELL
+"Hendrik, like all the crew members, is suffering from scurvy.  His face
+is gray, his eyes are sunken, and his skin is blotched and sallow.  He
+is dying." CR>)
+	       (<VERB? GIVE>
+		<COND (<FSET? ,HENDRIK ,RMUNGBIT>
+		       <YOULL-HAVE-TO "wake him">)
+		      (<PRSO? WHEEL>
+		       <SETG WINNER ,HENDRIK>
+		       <PERFORM ,V?TAKE ,WHEEL>
+		       <SETG WINNER ,PLAYER>
+		       <RTRUE>)>)
+	       (<VERB? SOOTHE>
+		<TELL
+"He remains skeptical, muttering quietly to himself." CR>)
+	       (<OR <HOSTILE-VERB?>
+		    <AND <VERB? WAKE>
+			 <FSET? ,PRSO ,RMUNGBIT>>>
+		<COND (<FSET? ,PRSO ,RMUNGBIT>
+		       <FCLEAR ,PRSO ,RMUNGBIT>
+		       <TELL "You awaken Hendrik.  ">
+		       <COND (,REEF-FLAG
+			      <TELL
+"\"We're lost,\" he screams.  \"Oh, Lord Jesus help us!\"" CR>)
+			     (ELSE
+			      <TELL
+"\"I wasn't asleep,\" he says, sheepishly." CR>)>)
+		      (ELSE
+		       <TELL
+"You realize it's only your fatigue making you want to hurt him, and
+refrain." CR>)>)>>
+
+<ROUTINE I-HENDRIK ()
+	 <ZLINES ,HENDRIK-CNT
+		 (<MOVE ,HENDRIK ,HERE>
+		  <TELL CR
+"Hendrik Specz, the third mate, appears on deck, pulling himself
+painfully up the gangway.  ">
+		  <THIS-IS-IT ,HENDRIK>
+		  <COND (<HERE? ,BRIDGE-OF-ERASMUS>
+			 <TELL
+"He joins you on the bridge.  \"Go below, Pilot.  I take this watch if
+it pleases you.\"  Gray with fatigue, he leans heavily against the
+binnacle and retches.  \"Blessed Lord Jesus help me!\"" CR>)
+			(ELSE
+			 <TELL
+"\"God curse you, Pilot!  Have you gone mad at last!  No one is at the
+wheel!  We'll head onto the reef, God rot your bones!\"" CR>)>)
+		 (<COND (<HERE? ,BRIDGE-OF-ERASMUS>
+			 <MOVE ,HENDRIK ,HERE>
+			 <SETG QCONTEXT ,HENDRIK>
+			 <TELL CR
+"\"Where's the landfall you promised us?  Where's the Japans?  Where is it,
+I ask?\"" CR>)
+			(<HERE? ,ON-DECK>
+			 <COND (<AND <NOT <FSET? ,WHEEL ,RMUNGBIT>>
+				     <NOT <FSET? ,WHEEL ,ONBIT>>
+				     <NOT <FSET? ,HENDRIK ,TRYTAKEBIT>>>
+				<TELL CR
+"\"You'll drown us all, you crazy Englishman!\" Hendrik screams">
+				<COND (<NOT <IN? ,HENDRIK ,BRIDGE-OF-ERASMUS>>
+				       <MOVE ,HENDRIK ,BRIDGE-OF-ERASMUS>
+				       <TELL
+" as he rushes to the bridge." CR>)
+				      (ELSE <TELL "." CR>)>)
+			       (ELSE
+				<TELL CR
+G"Hendrik is muttering to himself.  Only a few curses are audible." CR>)>)>)
+		 (<SETG QCONTEXT <>>
+		  <COND (<HERE? ,BRIDGE-OF-ERASMUS>
+			 <MOVE ,HENDRIK ,HERE>
+			 <TELL CR
+"\"Perhaps there is no Japans,\" Hendrik mutters scornfully.  \"It's just a "
+I "Gottbewonden" " legend.\"" CR>)
+			(<HERE? ,ON-DECK>
+			 <TELL CR
+G"Hendrik is muttering to himself.  Only a few curses are audible." CR>)>)
+		 (<DEQUEUE I-HENDRIK>
+		  <MOVE ,HENDRIK ,BRIDGE-OF-ERASMUS>
+		  <COND (<AND <NOT <FSET? ,WHEEL ,RMUNGBIT>>
+			      <NOT <FSET? ,WHEEL ,ONBIT>>
+			      <NOT <FSET? ,HENDRIK ,TRYTAKEBIT>>>
+			 <HENDRIK-SAVES-THE-DAY>)>
+		  <COND (<AND <FSET? ,HERE ,OUTSIDE>
+			      <NOT <HERE? ,ON-DECK>>>
+			 <QUEUE I-TIRED-WARNING 4 T>
+			 <QUEUE I-TIRED 8 T>)>
+		  <TELL CR
+"You are tired, deathly tired, and near starving.">
+		  <COND (<OR <IN? ,VINCK ,BELOW-DECKS>
+			     <IN? ,GINSEL ,BELOW-DECKS>
+			     <IN? ,MAETSUKKER ,BELOW-DECKS>>
+			 <COND (<AND <IN? ,VINCK ,BELOW-DECKS>
+				     <IN? ,GINSEL ,BELOW-DECKS>
+				     <IN? ,MAETSUKKER ,BELOW-DECKS>>
+				<TELL
+"With a start, you realize it's time to ">
+				<COND (<FSET? ,HERE ,OUTSIDE>
+				       <TELL "go below and ">)>
+				<TELL "send out replacements for the
+men on watch, by now freezing and windburned.">)
+			       (ELSE
+				<TELL "You know more men are needed
+on watch.">)>)>
+		  <COND (<ZERO? <GETP ,BLACKTHORNE ,P?HEALTH>>
+			 <TELL
+"It's past time to eat some of your meager cache of food; a few shrivelled
+apples.">)>
+		  <COND (<FSET? ,FLAGON ,SCOREBIT>
+			 <TELL
+"Time, too, for the unpleasant task of visiting Captain Spillbergen,
+still in nominal command but deathly sick, confined to his cabin.">)>
+		  <COND (<FSET? ,RUTTER ,SCOREBIT>
+			 <TELL "It's also time to write
+in your rutter, though God knows there is nothing new since yesterday;
+nothing, that is, but death.">)>
+		  <CRLF>)>>
+
+<ROUTINE HENDRIK-TAKES-WHEEL ()
+	 <FSET ,HENDRIK ,TRYTAKEBIT>
+	 <SETG SHIP-COURSE ,P?FORE>
+	 <SETG SHIP-DIRECTION P?WEST>
+	 <DEQUEUE I-BROADSIDE>
+	 <DEQUEUE I-SHIP-BROADSIDE>>
+
+<ROUTINE HENDRIK-SAVES-THE-DAY ()
+	 <FCLEAR ,WHEEL ,SCOREBIT>
+	 <HENDRIK-TAKES-WHEEL>
+	 <COND (<HERE? ,ON-DECK ,BRIDGE-OF-ERASMUS>
+		<TELL CR
+"Hendrik grabs the wheel, muttering vile curses on you and your kin." CR>)>>
+
+<OBJECT MAETSUKKER
+	(LOC BELOW-DECKS)
+	(DESC "Maetsukker")
+	(SYNONYM MAETSUKKER)
+	(FLAGS NDESCBIT PERSON DUTCHBIT NOABIT NOTHEBIT SCOREBIT)
+	(ACTION MAETSUKKER-F)>
+
+<ROUTINE MAETSUKKER-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<P? (RAISE REPAIR LOWER) FORESAILS>
+		       <RFALSE>)
+		      (<SEND-HIM-OUT?>
+		       <SETG WINNER ,PLAYER>
+		       <PERFORM ,V?SEND ,MAETSUKKER ,ROOMS>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"Maetsukker makes an almost inaudible remark about your mother." CR>)>)
+	       (<VERB? EXAMINE>
+		<TELL
+"Maetsukker is a small, sharp-featured man.  He is in better shape than
+most of the crew members." CR>)
+	       (<AND <P? SEND MAETSUKKER>
+		     <SCENE? ,S-ERASMUS>>
+		<COND (<NOT <HERE? ,BELOW-DECKS>>
+		       <TELL
+"\"I'm already on watch, Pilot!\" he snarls." CR>)
+		      (<NOT <FSET? ,MAETSUKKER ,RMUNGBIT>>
+		       <FSET ,MAETSUKKER ,RMUNGBIT>
+		       <TELL
+"\"I'm near death,\" the small, sharp-featured man says, and cringes
+away from you.  \"I'm sick.  Look, the scurvy's taken all my
+teeth.  Take someone else!\"  Other members of the crew take up the
+refrain.  They are all sick, all scurvied, all tired unto death." CR>)
+		      (ELSE
+		       <TELL
+"\"I'm a merchant, not a seaman!  I'm not part of the crew!  Take someone
+else!\"  Other crewmen nod in agreement.  None of them want to go on deck
+if they can avoid it." CR>)>)
+	       (<OR <VERB? TAKE>
+		    <HOSTILE-VERB?>>
+		<COND (<NOT <HERE? ,BELOW-DECKS>>
+		       <TELL
+"The two of you begin fighting, but before you can do any damage, the
+other crewmen pull you apart." CR>)
+		      (<FSET? ,MAETSUKKER ,RMUNGBIT>
+		       <MOVE ,MAETSUKKER ,ON-DECK>
+		       <TELL
+"Maetsukker screams as you ">
+		       <COND (<VERB? KICK>
+			      <TELL "kick him like a dog and then ">)
+			     (<VERB? HIT SWING>
+			      <TELL "punch him in the stomach and then ">)
+			     (<VERB? BITE>
+			      <TELL "growl, baring your teeth, and then ">)>
+		       <TELL "jerk him to his feet.  Blood flecks his
+mouth as he pulls the door open and flees in agony.  The other crewmen
+grumble, but seem to accept this assertion of your authority." CR>
+		       <COND (<AND <IN? ,GINSEL ,ON-DECK>
+				   <IN? ,VINCK ,ON-DECK>>
+			      <RESTART-STORM?>
+			      <SCORE-OBJECT ,MAETSUKKER>)>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"You have no reason to attack Maetsukker." CR>)>)>>
+
+<OBJECT GINSEL
+	(LOC BELOW-DECKS)
+	(DESC "Ginsel")
+	(SYNONYM GINSEL)
+	(FLAGS NDESCBIT PERSON DUTCHBIT NOABIT NOTHEBIT)
+	(ACTION GINSEL-F)>
+
+<ROUTINE GINSEL-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<P? (RAISE REPAIR LOWER) FORESAILS>
+		       <RFALSE>)
+		      (<SEND-HIM-OUT?>
+		       <SETG WINNER ,PLAYER>
+		       <PERFORM ,V?SEND ,GINSEL ,ROOMS>
+		       <RTRUE>)
+		      (<HOSTILE-VERB?>
+		       <TELL "He looks at you as though you are crazy." CR>)
+		      (ELSE
+		       <TELL "Ginsel nods weakly." CR>)>)
+	       (<RARG? <>>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"Ginsel is a tall, good-looking youth with short arms and very bowed
+legs.  He has lost all his teeth to scurvy and looks very weak." CR>)
+		      (<P? SEND GINSEL>
+		       <MOVE ,GINSEL ,ON-DECK>
+		       <TELL
+"\"Ginsel, you're bow lookout,\" you say quietly.|
+\"Yes, sir.\"  Ginsel pulls himself upright and stumbles out." CR>
+		       <COND (<AND <IN? ,MAETSUKKER ,ON-DECK>
+				   <IN? ,VINCK ,ON-DECK>>
+			      <RESTART-STORM?>
+			      <SCORE-OBJECT ,MAETSUKKER>)>
+		       <RTRUE>)>)>>
+
+<ROOM BRIDGE-OF-ERASMUS
+      (LOC ROOMS)
+      (SCENE S-ERASMUS)
+      (OWNER LG-ERASMUS)
+      (DESC "Bridge")
+      (SYNONYM BRIDGE)
+      (PICTURE P-STORM)
+      (SCORE 11)
+      (FDESC
+"The gale tears at you, biting deep within, and you know that if you
+don't make landfall soon you'll all be dead.  You are John Blackthorne,
+Pilot-Major of a dead fleet: one ship left out of five, eight and twenty
+men out of one hundred and seven, and only ten of those can walk.  Little
+food, almost no water, and that brackish and foul.")
+      (DOWN TO ON-DECK)
+      (FORE TO ON-DECK)
+      (PORT SORRY "You would fall overboard.")
+      (STARBOARD SORRY "You would fall overboard.")
+      (AFT SORRY "You would fall overboard.")
+      (ACTION BRIDGE-OF-ERASMUS-F)
+      (GLOBAL LG-ERASMUS REEF FORESAILS LG-CREWMEN LG-SEA DECK)
+      (FLAGS ONBIT OUTSIDE)>
+
+<ROUTINE BRIDGE-OF-ERASMUS-F (RARG)
+	 <COND (<RARG? SCENE-SETUP>
+		<DRESS-BLACKTHORNE T>
+		<MOVE ,COMPASS ,BLACKTHORNE>
+		<PUTP ,BLACKTHORNE ,P?HEALTH 0>
+		<SETG SHIP-COURSE ,P?FORE>
+		<SETG SHIP-DIRECTION ,P?WEST>
+		<QUEUE I-BROADSIDE 4>
+		<QUEUE I-SHIP-BROADSIDE 8>
+		<SETG STORM-DELAY? -2> ;"give 2*25 moves before storm serious"
+		<QUEUE I-STORM -1>)
+	       (<RARG? LOOK>
+		<TELL
+"This is the bridge of the " I "Erasmus"", a Dutch merchant and
+privateer.  The ">
+		<COND (<FSET? ,WHEEL ,RMUNGBIT>
+		       <TELL "securely lashed">)
+		      (ELSE
+		       <TELL "unlashed">)>
+		<TELL
+" wheel is directly forward of you, a sea chair is lashed to the
+deck aft of the wheel, and the ship's bell is hanging here.">
+		<COND (<QUEUED? I-STORM>
+		       <TELL
+" Spray blows past in an angry torrent.">)>
+		<CRLF>)
+	       (<RARG? ENTER>
+		<COND (<AND <SCENE? ,S-ERASMUS>
+			    <NOT <FSET? ,HENDRIK ,RMUNGBIT>>
+			    <FSET? ,BELL ,SCOREBIT>
+			    <OR <FSET? ,PASSAGEWAY ,TOUCHBIT>
+				<FSET? ,BELOW-DECKS ,TOUCHBIT>>>
+		       <FSET ,HENDRIK ,RMUNGBIT> ;"asleep"
+		       <FSET ,WHEEL ,RMUNGBIT> ;"lash wheel"
+		       <TELL
+"As you climb onto the bridge, you see that Hendrik has fallen asleep
+at his post.  At least the wheel is lashed in place." CR CR>)>)
+	       (<RARG? BEG>
+		<COND (<P? LISTEN <>>
+		       <PERFORM ,V?LISTEN ,WIND>
+		       <RTRUE>)
+		      (<AND <P? WALK (P?DOWN P?FORE)>
+			    <NOT <FSET? ,WHEEL ,RMUNGBIT>>
+			    <NOT <FSET? ,WHEEL ,ONBIT>>
+			    <OR <NOT <IN? ,HENDRIK ,BRIDGE-OF-ERASMUS>>
+				<NOT <FSET? ,HENDRIK ,TRYTAKEBIT>>>>
+		       <COND (<AND <IN? ,HENDRIK ,BRIDGE-OF-ERASMUS>
+				   <NOT <FSET? ,HENDRIK ,TRYTAKEBIT>>>
+			      <TELL
+"Hendrik grabs for the wheel as you leave.  \"Curse you, Pilot!  Someone
+has to hold the course!\"">)
+			     (ELSE
+			      <TELL
+"As you climb down to the deck, you see the wheel spinning
+uncontrolled.">)>
+		       <CRLF>
+		       <CRLF>
+		       <RFALSE>)
+		      (<P? TURN INTDIR>
+		       <PERFORM ,V?TURN ,WHEEL ,INTDIR>
+		       <RTRUE>)
+		      (<P? TAKE-OVER <>>
+		       <PERFORM ,V?TAKE-OVER ,WHEEL>
+		       <RTRUE>)
+		      (<AND <VERB? SHRUG>
+			    <IN? ,HENDRIK ,HERE>>
+		       <TELL
+"Hendrik's reaction is unprintable." CR>)
+		      (<P? LOOK-UP ROOMS>
+		       <PERFORM ,V?EXAMINE ,FORESAILS>
+		       <RTRUE>)>)>>
+
+<ROUTINE DONE-BELOW? ()
+	 <COND (<AND <NOT <FSET? ,ROPER ,SCOREBIT>>
+		     <NOT <FSET? ,APPLE ,SCOREBIT>>
+		     <NOT <FSET? ,KEY ,SCOREBIT>>
+		     <NOT <FSET? ,RUTTER ,SCOREBIT>>
+		     <NOT <FSET? ,CAPTAINS-DESK ,SCOREBIT>>
+		     <NOT <FSET? ,FLAGON ,SCOREBIT>>
+		     <NOT <FSET? ,MAETSUKKER ,SCOREBIT>>>
+		<RTRUE>)>>
+
+<ROUTINE RESTART-STORM? ()
+	 <COND (<DONE-BELOW?>
+		<SETG STORM-DELAY? 0>
+		<QUEUE I-STORM 2>
+		<RTRUE>)>>
+
+<OBJECT BELL
+	(LOC BRIDGE-OF-ERASMUS)
+	(DESC "bell")
+	(SYNONYM BELL)
+	(FLAGS NDESCBIT SCOREBIT)
+	(ACTION BELL-F)>
+
+<ROUTINE BELL-F ()
+	 <COND (<VERB? RING>
+		<TELL "You ring the bell.  \"All hands on deck!\" you yell.">
+		<COND (<SCENE? ,S-ERASMUS>
+		       <QUEUE I-HANDS 2>
+		       <COND (<AND <IN? ,HENDRIK ,BRIDGE-OF-ERASMUS>
+				   <FSET? ,HENDRIK ,RMUNGBIT>>
+			      <FCLEAR ,HENDRIK ,RMUNGBIT>
+			      <TELL " The noise wakes Hendrik.  \"We're
+lost,\" he screams.  \"Oh, Lord Jesus help us!\"">)>
+		       <CRLF>
+		       <COND (<AND ,REEF-FLAG
+				   <FSET? ,BELL ,SCOREBIT>>
+			      <SCORE-OBJECT ,BELL>)>)
+		      (ELSE <CRLF>)>
+		<RTRUE>)>>
+
+<ROUTINE MOVE-CREW (RM "OPT" (NDESC? <>))
+	 <COND (<NOT .RM>
+		<REMOVE ,CREWMEN>
+		<REMOVE ,HENDRIK>
+		<REMOVE ,VINCK>
+		<REMOVE ,MAETSUKKER>
+		<REMOVE ,GINSEL>
+		<REMOVE ,SPILLBERGEN>
+		<REMOVE ,VAN-NEKK>
+		<REMOVE ,CROOCQ>
+		<REMOVE ,SONK>
+		<REMOVE ,ROPER>
+		<REMOVE ,PIETERZOON>
+		<REMOVE ,SALAMON>)
+	       (ELSE
+		<SETG CREW-ON-DECK? T>
+		<COND (<EQUAL? .RM ,VILLAGE-SQUARE ,PIT>
+		       <MOVE ,PIETERZOON .RM>
+		       <COND (.NDESC? <FSET ,PIETERZOON ,NDESCBIT>)
+			     (ELSE <FCLEAR ,PIETERZOON ,NDESCBIT>)>
+		       <MOVE ,ROPER .RM>
+		       <COND (.NDESC? <FSET ,ROPER ,NDESCBIT>)
+			     (ELSE <FCLEAR ,ROPER ,NDESCBIT>)>
+		       <MOVE ,SONK .RM>
+		       <COND (.NDESC? <FSET ,SONK ,NDESCBIT>)
+			     (ELSE <FCLEAR ,SONK ,NDESCBIT>)>
+		       <MOVE ,SALAMON .RM>
+		       <COND (.NDESC? <FSET ,SALAMON ,NDESCBIT>)
+			     (ELSE <FCLEAR ,SALAMON ,NDESCBIT>)>)>
+		<MOVE ,VINCK .RM>
+		<COND (.NDESC? <FSET ,VINCK ,NDESCBIT>)
+		      (ELSE <FCLEAR ,VINCK ,NDESCBIT>)>
+		<MOVE ,CROOCQ .RM>
+		<COND (.NDESC? <FSET ,CROOCQ ,NDESCBIT>)
+		      (ELSE <FCLEAR ,CROOCQ ,NDESCBIT>)>
+		<MOVE ,GINSEL .RM>
+		<COND (.NDESC? <FSET ,GINSEL ,NDESCBIT>)
+		      (ELSE <FCLEAR ,GINSEL ,NDESCBIT>)>
+		<MOVE ,MAETSUKKER .RM>
+		<COND (.NDESC? <FSET ,MAETSUKKER ,NDESCBIT>)
+		      (ELSE <FCLEAR ,MAETSUKKER ,NDESCBIT>)>
+		<MOVE ,VAN-NEKK .RM>
+		<COND (.NDESC? <FSET ,VAN-NEKK ,NDESCBIT>)
+		      (ELSE <FCLEAR ,VAN-NEKK ,NDESCBIT>)>
+		<COND (<EQUAL? .RM ,VILLAGE-SQUARE ,PIT>
+		       <MOVE ,SPILLBERGEN .RM>)>
+		<MOVE ,CREWMEN .RM>)>>
+
+<ROUTINE I-HANDS ()
+	 <COND (<NOT ,CREW-ON-DECK?>
+		<TELL CR
+"The noise of the bell and your yelling have aroused the crew and
+they pull themselves out onto the deck.">
+		<COND (,REEF-FLAG
+		       <MOVE-CREW ,ON-DECK>
+		       <TELL " They are terrified when they
+see the encroaching reef, most are panicked and don't know what
+to do next, but a few with their last reserves of strength
+try ineffectually to get the ship under control." CR>)
+		      (ELSE
+		<TELL " They sullenly look around, see that there is
+no danger, and muttering curses, return below, oblivious to your
+entreaties." CR>)>)>>
+
+<OBJECT SEA-CHAIR
+	(LOC BRIDGE-OF-ERASMUS)
+	(DESC "sea chair")
+	(SYNONYM CHAIR)
+	(ADJECTIVE SEA)
+	(FLAGS NDESCBIT FURNITURE OPENBIT CONTBIT VEHBIT SEARCHBIT)
+	(ACTION SEA-CHAIR-F)>
+
+<ROUTINE SEA-CHAIR-F (RARG)
+	 <COND (<RARG? BEG>
+		<COND (<VERB? WALK>
+		       <YOULL-HAVE-TO "get out of the sea chair">)
+		      (<VERB? STAND>
+		       <B-STAND>
+		       <MOVE ,WINNER ,HERE>
+		       <TELL
+"You rise to your feet." CR>)>)
+	       (ELSE
+		<COND (<VERB? BOARD SIT>
+		       <COND (<NOT <IN? ,WINNER ,SEA-CHAIR>>
+			      <MOVE ,WINNER ,SEA-CHAIR>
+			      <B-SIT>
+			      <TELL
+"You are now sitting in the sea chair." CR>)>)>)>>
+
+<OBJECT FOCSLE-DOOR
+	(LOC LOCAL-GLOBALS)
+	(OWNER CREWMEN)
+	(DESC "focsle door")
+	(SYNONYM DOOR)
+	(ADJECTIVE CREW FOCSLE FORECASTLE)
+	(FLAGS DOORBIT LOCKABLE)
+	(ACTION FOCSLE-DOOR-F)>
+
+<ROUTINE FOCSLE-DOOR-F ()
+	 <COND (<AND <NOT <PASSIVE-VERB?>>
+		     <SCENE? ,S-ANJIRO>>
+		<PERFORM ,V?RUB ,RIBBON>
+		<RTRUE>)>>
+
+<ROOM BELOW-DECKS
+      (LOC ROOMS)
+      (SCENE S-ERASMUS)
+      (DESC "Below Decks")
+      (SYNONYM QUARTERS FORECASTLE FOCSLE DECKS)
+      (ADJECTIVE CREW ;BELOW)
+      (PICTURE P-BELOW-DECKS)
+      (UP TO ON-DECK IF FOCSLE-DOOR IS OPEN)
+      (AFT TO ON-DECK IF FOCSLE-DOOR IS OPEN)
+      (OUT TO ON-DECK IF FOCSLE-DOOR IS OPEN)
+      (ACTION BELOW-DECKS-F)
+      (FLAGS ONBIT)
+      (GLOBAL DECK LG-ERASMUS FOCSLE-DOOR LG-CREWMEN LG-BUNK)
+      (THINGS <> RAT RAT-PSEUDO
+	      <> COCKROACH COCKROACH-PSEUDO)>
+
+<ROUTINE BELOW-DECKS-F (RARG)
+	 <COND (<RARG? LOOK>
+		<TELL
+"The crew's quarters of the "I"Erasmus"".  A companionway leads up to the
+deck.  It's dim, warm and close here, and the stench is abominable." CR>)
+	       (<RARG? ENTER>
+		<COND (<AND <SCENE? S-ERASMUS>
+			    <EQUAL? ,OHERE ,ON-DECK>
+			    <NOT ,CREW-ON-DECK?>>
+		       <SETG TIRED-TIME <DEQUEUE I-TIRED>>
+		       <FCLEAR ,FOCSLE-DOOR ,OPENBIT>
+		       <THIS-IS-IT ,CREWMEN>
+		       <COND (,REEF-FLAG
+			      <TELL
+"As you enter, you see the men resignedly preparing to go on deck." CR CR>)
+			     (ELSE
+			      <TELL
+"As you enter, a volley of feeble curses greets you.  You close the door
+and they subside.  No one moves." CR CR>)>)>)
+	       (<RARG? BEG>
+		<COND (<VERB? SMELL>
+		       <TELL
+"The stench here is terrible.  Rotten food, rotten flesh, offal, and
+worse." CR>)
+		      (<AND <P? TAKE * LG-BUNK>
+			    <FSET? ,PRSO ,PERSON>>
+		       <PERFORM ,V?MOVE ,PRSO>
+		       <RTRUE>)
+		      (<P? YELL-AT (<> CREWMEN)>
+		       <TELL
+"They just yell right back at you." CR>)
+		      (<P? (ATTACK HIT) CREWMEN>
+		       <TELL
+"They back off, intimidated." CR>)>)>>
+
+<ROOM ON-DECK
+      (SCENE S-ERASMUS)
+      (LOC ROOMS)
+      (DESC "Deck")
+      (SYNONYM DECK)
+      (UP TO BRIDGE-OF-ERASMUS)
+      (DOWN SORRY "The gangways are fore and aft.  Down is ambiguous.")
+      (PORT SORRY "You would fall overboard.")
+      (STARBOARD SORRY "You would fall overboard.")
+      (AFT TO PASSAGEWAY IF PASSAGE-DOOR IS OPEN)
+      (FORE TO BELOW-DECKS IF FOCSLE-DOOR IS OPEN)
+      (FLAGS ONBIT OUTSIDE)
+      (GLOBAL LG-ERASMUS FOCSLE-DOOR PASSAGE-DOOR REEF LG-CREWMEN FORESAILS
+       DECK GANGWAY LG-SEA LG-SMALL-BOAT)
+      (ACTION ON-DECK-F)>
+
+<ROUTINE ON-DECK-F (RARG)
+	 <COND (<RARG? LOOK>
+		<TELL
+"This is the main deck of the "I"Erasmus"".  A companionway leads up to the
+bridge, and another one forward leads below decks to the
+crew quarters.  A stairway aft leads to the officers' cabins." CR>)
+	       (<RARG? BEG>
+		<COND (<SCENE? ,S-ANJIRO ,S-RODRIGUES>
+		       <COND (<P? LISTEN <>>
+			      <PERFORM ,V?LISTEN ,WIND>
+			      <RTRUE>)
+			     (<P? WALK (P?UP P?FORE P?AFT)>
+			      <COND (<IN? ,RODRIGUES ,PASSAGEWAY>
+				     <RFALSE>)
+				    (ELSE
+				     <PERFORM ,V?RUB ,RIBBON>
+				     <RTRUE>)>)
+			     (<P? WALK (P?DOWN ,P?PORT ,P?WEST)>
+			      <COND (<FSET? ,SAMURAI-GUARDS ,RMUNGBIT>
+				     <TELL
+"You climb down the gangway into the ">
+				     <COND (<IN? ,SMALL-BOAT ,AT-ERASMUS>
+					    <MOVE ,WINNER ,SMALL-BOAT>
+					    <TELL D ,SMALL-BOAT>)
+					   (ELSE
+					    <TELL "water">)>
+				     <TELL "." CR CR>
+				     <GOTO ,AT-ERASMUS>)
+				    (<EQUAL? ,RIBBON-CNT 3>
+				     <TELL
+"You start down the gangway, and stop.  You feel your cold sweat and see
+the samurai staring at you malevolently." CR>)
+				    (ELSE
+				     <TELL
+"You start to climb down the gangway, but you can't force yourself
+to leave without trying to regain your rutters." CR>)>)
+			     (<P? BOW <>>
+			      <PERFORM ,V?BOW ,SAMURAI-GUARDS>
+			      <RTRUE>)>)
+		      (<SCENE? ,S-ERASMUS>
+		       <COND (<P? LOOK-UP ROOMS>
+			      <PERFORM ,V?EXAMINE ,FORESAILS>
+			      <RTRUE>)>)>)
+	       (<RARG? ENTER>
+		<COND (<SCENE? S-ERASMUS>
+		       <COND (<AND ,TIRED-TIME
+				   <EQUAL? ,OHERE ,BELOW-DECKS ,PASSAGEWAY>>
+			      <QUEUE I-TIRED ,TIRED-TIME>)>
+		       <COND (<OR <EQUAL? <SCORE-HAVE> 7> ;"almost done"
+				  <AND <EQUAL? ,OHERE ,PASSAGEWAY>
+				       <FSET? ,APPLE ,SCOREBIT>>
+				  <AND <EQUAL? ,OHERE ,BELOW-DECKS>
+				       <FSET? ,MAETSUKKER ,SCOREBIT>>>
+			      <SETG STORM-DELAY? <>>
+			      <QUEUE-STORM>)>)
+		      (<SCENE? ,S-ANJIRO>
+		       <COND (<EQUAL? ,OHERE ,AT-ERASMUS>
+			      <QUEUE I-RIBBON 3>)>)
+		      (<SCENE? ,S-RODRIGUES>
+		       <COND (<AND <EQUAL? ,OHERE ,AT-ERASMUS>
+				   <IN? ,RODRIGUES ,HERE>>
+			      <TELL
+"As you climb aboard, ">
+			      <SEALED-PASSAGE>
+			      <CRLF>)>)>)>>
+
+<ROUTINE SEALED-PASSAGE ()
+	 <TELL "Rodrigues heads immediately for
+the sealed passage.  \""I"Kinjiru, gomen nasai,""\" says one of the samurai." CR>>
+
+<OBJECT ERASMUS-ANCHOR
+	(LOC ON-DECK)
+	(OWNER LG-ERASMUS)
+	(DESC "anchor")
+	(SYNONYM ANCHOR)
+	(SIZE 200)
+	(FLAGS TAKEBIT AN)
+	(DESCFCN ERASMUS-ANCHOR-DESC)
+	(ACTION ERASMUS-ANCHOR-F)>
+
+<ROUTINE ERASMUS-ANCHOR-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?>
+		<COND (<SCENE? ,S-ERASMUS> <RTRUE>)
+		      (ELSE <RFALSE>)>)
+	       (<RARG? OBJDESC>
+		<TELL
+"The anchor hangs over the side, ready to be dropped if ever, by the
+grace of God and your good piloting, the "I"Erasmus"" reaches port.">)>>
+
+<ROUTINE ERASMUS-ANCHOR-F ()
+	 <COND (<VERB? RAISE>
+		<PERFORM ,V?TAKE ,PRSO>
+		<RTRUE>)
+	       (<VERB? DROP THROW PUT LOWER>
+		<TELL
+G"That would be suicide in this storm." CR>)>>
+
+<ROOM PASSAGEWAY
+      (LOC ROOMS)
+      (DESC "Passageway")
+      (SYNONYM PASSAGEWAY)
+      (LDESC
+"The Captain's cabin is aft of here.  Your cabin is to port, and the Mates'
+cabin to starboard.  The main deck is forward of here.")
+      (AFT TO CAPTAINS-CABIN IF CAPTAINS-CABIN-DOOR IS OPEN)
+      (STARBOARD TO MATES-CABIN IF MATES-CABIN-DOOR IS OPEN)
+      (PORT TO PILOTS-CABIN IF PILOTS-CABIN-DOOR IS OPEN)
+      (FORE TO ON-DECK IF PASSAGE-DOOR IS OPEN)
+      (OUT TO ON-DECK IF PASSAGE-DOOR IS OPEN)
+      (FLAGS ONBIT)
+      (GLOBAL DECK LG-ERASMUS LG-CREWMEN PASSAGE-DOOR
+              PILOTS-CABIN CAPTAINS-CABIN MATES-CABIN
+	      PILOTS-CABIN-DOOR CAPTAINS-CABIN-DOOR MATES-CABIN-DOOR)
+      (ACTION PASSAGEWAY-F)
+      (THINGS <> RAT RAT-PSEUDO
+	      <> COCKROACH COCKROACH-PSEUDO)>
+
+<ROUTINE PASSAGEWAY-F (RARG)
+	 <COND (<RARG? ENTER>
+		<SETG TIRED-TIME <DEQUEUE I-TIRED>>
+		<QUEUE I-BELOW-DECKS -1 T>
+		<COND (<IN? ,ROPER ,PASSAGEWAY>
+		       <MOVE ,ROPER ,MATES-CABIN>
+		       <MOVE ,APPLE ,ROPER>
+		       <TELL
+"As you enter the relative quiet of the aft passageway, you notice
+Jan Roper heading across the passage from your cabin to the Mates'
+cabin." CR CR>)>)
+	       (<RARG? BEG>
+		<COND (<P? (OPEN CLOSE)>
+		       <COND (<PRSO? PILOTS-CABIN>
+			      <PERFORM ,PRSA ,PILOTS-CABIN-DOOR>
+			      <RTRUE>)
+			     (<PRSO? MATES-CABIN>
+			      <PERFORM ,PRSA ,MATES-CABIN-DOOR>
+			      <RTRUE>)
+			     (<PRSO? CAPTAINS-CABIN>
+			      <PERFORM ,PRSA ,CAPTAINS-CABIN-DOOR>
+			      <RTRUE>)>)>)>>
+
+<ROUTINE I-BELOW-DECKS ()
+	 <COND (<FSET? ,HERE ,OUTSIDE>
+		<DEQUEUE I-BELOW-DECKS>
+		<RFALSE>)
+	       (<PROB 25>
+		<TELL CR <PICK-ONE ,BELOW-DECKS-BACKGROUND> CR>)>>
+
+<GLOBAL BELOW-DECKS-BACKGROUND
+	<LTABLE 0
+		"A rat scurries in the shadows cast by a hanging oil lamp."
+		"Timbers creak pleasantly."
+		"Cockroaches swarm on the floor.">>
+
+<ROOM CAPTAINS-CABIN
+      (LOC ROOMS)
+      (DESC "Captain's Cabin")
+      (OWNER SPILLBERGEN)
+      (SYNONYM CABIN ROOM)
+      (LDESC
+"This is the great cabin, the Captain-General's quarters and
+magazine.  The passageway leading to the other officers' cabins
+is forward.")
+      (FORE TO PASSAGEWAY IF CAPTAINS-CABIN-DOOR IS OPEN)
+      (OUT TO PASSAGEWAY IF CAPTAINS-CABIN-DOOR IS OPEN)
+      (FLAGS ONBIT)
+      (GLOBAL DECK LG-ERASMUS CAPTAINS-CABIN-DOOR LG-CREWMEN LG-BUNK)
+      (ACTION CAPTAINS-CABIN-F)
+      (THINGS <> RAT RAT-PSEUDO
+	      <> COCKROACH COCKROACH-PSEUDO)>
+
+<ROUTINE CAPTAINS-CABIN-F (RARG)
+	 <COND (<RARG? BEG>
+		<COND (<P? FIND GLOBAL-WATER>
+		       <PERFORM ,V?OPEN ,CAPTAINS-DESK>
+		       <RTRUE>)>)
+	       (<RARG? LEAVE>
+		<COND (<SCENE? S-ERASMUS>
+		       <DEQUEUE I-WHINE>
+		       <TELL CR
+"You close your ears to the whines and leave, hating Spillbergen
+anew." CR CR>)>)
+	       (<RARG? END>
+		<COND (<AND <SCENE? S-ERASMUS>
+			    <NOT <QUEUED? I-WHINE>>>
+		       <I-WHINE T>)>)>>
+
+<ROUTINE I-WHINE ("OPT" (END <>))
+	 <QUEUE I-WHINE 3>
+	 <THIS-IS-IT ,SPILLBERGEN>
+	 <TELL CR
+"Spillbergen whines weakly.  \"I'm ">
+	 <COND (<FSET? ,FLAGON ,SCOREBIT> <TELL "thirsty">)
+	       (ELSE <TELL "hungry">)>
+	 <TELL ",\" he rasps.">
+	 <COND (.END
+		<TELL
+"You've set some water aside for him, out of pity.">)>
+	 <CRLF>>
+
+<OBJECT FLAGON
+	(LOC CAPTAINS-DESK)
+	(DESC "flagon")
+	(SYNONYM FLAGON WATER DRINK)
+	(FLAGS TAKEBIT SEARCHBIT OPENABLE TRANSBIT CONTBIT SCOREBIT)
+	(CAPACITY 10)
+	(ACTION FLAGON-F)>
+
+<ROUTINE FLAGON-F ("AUX" (W <NOUN-USED? ,PRSO ,W?WATER>))
+	 <COND (<AND <VERB? LEAP DIVE> .W>
+		<PERFORM ,PRSA ,LG-SEA>
+		<RTRUE>)
+	       (<AND .W <FSET? ,FLAGON ,RMUNGBIT>>
+		<TELL "There's no longer any water in the flagon." CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"This is a flagon ">
+		<COND (<FSET? ,FLAGON ,RMUNGBIT>
+		       <TELL "which contained">)
+		      (ELSE <TELL "containing">)>
+		<TELL " a secret cache of water you've set aside
+for the Captain-General.  The water doesn't look too palatable." CR>)
+	       (<VERB? PUT-AWAY>
+		<MOVE ,FLAGON ,CAPTAINS-DESK>
+		<TELL "You put the flagon back into the desk." CR>)
+	       (<VERB? LOOK-INSIDE>
+		<COND (<NOT <FSET? ,FLAGON ,OPENBIT>>
+		       <TELL CTHE ,FLAGON " isn't open." CR>)
+		      (<FSET? ,FLAGON ,RMUNGBIT>
+		       <TELL CTHE ,FLAGON " is now empty." CR>)
+		      (ELSE
+		       <TELL
+"There is some water in the flagon." CR>)>)
+	       (<VERB? POUR>
+		<COND (<NOT <FSET? ,FLAGON ,OPENBIT>>
+		       <TELL CTHE ,FLAGON " isn't open." CR>)
+		      (<FSET? ,FLAGON ,RMUNGBIT>
+		       <TELL CTHE ,FLAGON " is empty." CR>)
+		      (ELSE
+		       <FSET ,FLAGON ,RMUNGBIT>
+		       <TELL
+"You pour the water">
+		       <COND (<AND <HERE? ,CAPTAINS-CABIN>
+				   <PRSI? <> ,SPILLBERGEN>>
+			      <TELL
+" on the Captain, who whines pitifully at your
+cruelty." CR>)
+			     (ELSE <TELL "." CR>)>)>)
+	       (<VERB? DRINK TASTE>
+		<COND (<NOT <FSET? ,FLAGON ,OPENBIT>>
+		       <TELL CTHE ,FLAGON " isn't open." CR>)
+		      (<FSET? ,FLAGON ,RMUNGBIT>
+		       <TELL
+"There's no more water." CR>)
+		      (ELSE
+		       <TELL
+"You sip a little">
+		       <COND (<FSET? ,FLAGON ,SCOREBIT>
+			      <TELL ", reserving the rest for Spillbergen">)>
+		       <TELL
+".  The water tastes terrible, but at least it's not salt water.  It's
+well known that if you descend to drinking salt water, you go mad." CR>)>)
+	       (<AND <P? GIVE>
+		     <NOT <FSET? ,FLAGON ,RMUNGBIT>>
+		     <FSET? ,PRSI ,PERSON>>
+		<COND (<FSET? ,PRSI ,PLURAL>
+		       <TELL
+"You can't share that little bit of water among so many." CR>)
+		      (ELSE
+		       <MOVE ,FLAGON ,PRSI>
+		       <FSET ,FLAGON ,OPENBIT>
+		       <TELL CTHE ,PRSI " drinks it greedily." CR>)>)
+	       (<AND <VERB? TAKE>
+		     <NOUN-USED? ,PRSO ,W?WATER>>
+		<COND (<HELD? ,FLAGON>
+		       <COND (<FSET? ,FLAGON ,RMUNGBIT>
+			      <TELL
+"The flagon held the last of the good water, tarry but drinkable." CR>)
+			     (ELSE
+			      <TELL
+"You already have a flagon full of water." CR>)>)
+		      (ELSE
+		       <RFALSE>)>)>>
+
+<OBJECT SECRET-DRAWER
+	(LOC CAPTAINS-CABIN)
+	(OWNER SPILLBERGEN)
+	(DESC "secret drawer")
+	(SYNONYM DRAWER CATCH ORNAMENTATION)
+	(ADJECTIVE SECRET SMALL)
+	(FLAGS INVISIBLE NDESCBIT SEARCHBIT OPENABLE CONTBIT FURNITURE)
+	(ACTION SECRET-DRAWER-F)>
+
+<ROUTINE SECRET-DRAWER-F ()
+	 <COND (<VERB? EXAMINE OPEN CLOSE>
+		<PERFORM ,PRSA ,CAPTAINS-DESK>
+		<RTRUE>)
+	       (<VERB? PUSH MOVE>
+		<PERFORM ,V?OPEN ,CAPTAINS-DESK>
+		<RTRUE>)>>
+
+<OBJECT CAPTAINS-DESK
+	(LOC CAPTAINS-CABIN)
+	(OWNER SPILLBERGEN)
+	(DESC "desk")
+	(LDESC "The Captain's ornate desk fills one wall of the cabin.")
+	(SYNONYM DESK)
+	(ADJECTIVE CAPTAIN)
+	(FLAGS SEARCHBIT SURFACEBIT OPENABLE CONTBIT FURNITURE SCOREBIT)
+	(CAPACITY 100)
+	(ACTION CAPTAINS-DESK-F)>
+
+<ROUTINE CAPTAINS-DESK-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"This desk is much like your own, but the captain hasn't used it in
+weeks.  He is too sick to leave his bunk.">
+		<COND (<NOT <FSET? ,CAPTAINS-DESK ,RMUNGBIT>>
+		       <TELL "">
+		       <PERFORM ,V?OPEN ,CAPTAINS-DESK>
+		       <RTRUE>)>
+		<CRLF>)
+	       (<VERB? OPEN LOOK-INSIDE SEARCH LOOK-ON>
+		<COND (<NOT <FSET? ,CAPTAINS-DESK ,RMUNGBIT>>
+		       <FSET ,CAPTAINS-DESK ,RMUNGBIT>
+		       <FCLEAR ,SECRET-DRAWER ,INVISIBLE>
+		       <TELL
+"You look through the desk, knowing you left a flagon of water in it.  In your
+tiredness you fumble around, unsure where you put it, and then remember
+the secret drawer.  Where's that catch?  Ah, there it is, a small piece of
+ornamentation." CR>)
+		      (<NOT <FSET? ,CAPTAINS-DESK ,OPENBIT>>
+		       <FSET ,CAPTAINS-DESK ,OPENBIT>
+		       <FSET ,SECRET-DRAWER ,OPENBIT>
+		       <TELL
+"You open the secret drawer to the desk, revealing ">
+		       <DESCRIBE-REST ,CAPTAINS-DESK>
+		       <TELL "." CR>
+		       <RESTART-STORM?>
+		       <SCORE-OBJECT ,CAPTAINS-DESK>)>)>>
+
+<ROOM PILOTS-CABIN
+      (LOC ROOMS)
+      (DESC "Pilot's Cabin")
+      (SCENE S-ERASMUS S-ANJIRO S-RODRIGUES)
+      (OWNER BLACKTHORNE)
+      (SYNONYM CABIN ROOM)
+      ;(ADJECTIVE MY)
+      (STARBOARD TO PASSAGEWAY IF PILOTS-CABIN-DOOR IS OPEN)
+      (OUT TO PASSAGEWAY IF PILOTS-CABIN-DOOR IS OPEN)
+      (FLAGS ONBIT)
+      (GLOBAL DECK PILOTS-CABIN-DOOR LG-ERASMUS LG-CREWMEN)
+      (THINGS <> RAT RAT-PSEUDO
+	      <> COCKROACH COCKROACH-PSEUDO)
+      (ACTION PILOTS-CABIN-F)>
+
+<ROUTINE PILOTS-CABIN-F (RARG)
+	 <COND (<RARG? LOOK>
+		<TELL
+"This is your cabin, sparsely furnished and small but nonetheless the
+second best on the ship.  The only exit is out to the passageway.">
+		<COND (<AND <SCENE? S-ERASMUS>
+			    <NOT <FSET? ,HERE ,TOUCHBIT>>>
+		       <TELL
+" There's something wrong here.  Your cabin has been disturbed.  As
+you look around, trying to see what's wrong, your eyes stray to the
+sea chest which contains your rutters.  You do it almost in a panic, for
+a pilot's rutters are his life.">)
+		      (<SCENE? S-RODRIGUES>
+		       <TELL
+" The room looks as though it has been tidied up and then thoroughly
+turned over again.">)>
+		<CRLF>)
+	       (<RARG? ENTER>
+		<COND (<SCENE? S-ERASMUS>
+		       <QUEUE I-BUNK 4>)>)
+	       (<RARG? LEAVE>
+		<COND (<SCENE? ,S-ERASMUS>
+		       <DEQUEUE I-BUNK>)>)
+	       (<RARG? BEG>
+		<COND (<P? WALK (P?OUT P?STARBOARD)>
+		       <COND (<OR <HELD? ,RUTTER>
+				  <HELD? ,SECRET-RUTTER>>
+			      <TELL
+"As you start to leave, you remember you are carrying one of your
+precious rutters out into the storm or into the inquisitive eyes
+of your crew.  You think better of it." CR>)>)
+		      (<VERB? SLEEP LIE-DOWN>
+		       <PERFORM ,V?BOARD ,BUNK>
+		       <RTRUE>)>)>>
+
+<NEW-ADD-WORD "RUTTERS" NOUN <VOC "RUTTER"> ,PLURAL-FLAG>
+<NEW-ADD-WORD "MAPS" NOUN <VOC "MAP"> ,PLURAL-FLAG>
+
+<OBJECT SECRET-RUTTER
+	(LOC SEA-CHEST)
+	(DESC "secret Portuguese rutter")
+	(SYNONYM RUTTER MAP)
+	(ADJECTIVE SECRET PORTUGUESE)
+	(FLAGS READBIT TAKEBIT OPENABLE)
+	(ACTION SECRET-RUTTER-F)>
+
+<ROUTINE SECRET-RUTTER-F ()
+	 <COND (<OR <VERB? ;WHERE FIND>
+		    <AND <P? BE * INTPP>
+			 <PP? ,W?ON ,LG-ERASMUS>>>
+		<COND (<SCENE? ,S-ANJIRO>
+		       <PERFORM ,PRSA ,RUTTER ,PRSI>
+		       <RTRUE>)>)
+	       (<IN? ,RUTTER ,GENERIC-OBJECTS>
+		<COND (<ABSTRACT-VERB?> <RFALSE>)
+		      (ELSE
+		       <TELL
+G"There's no rutter here." CR>)>)
+	       (<P? PUT-AWAY SECRET-RUTTER ROOMS>
+		<PERFORM ,PRSA ,PRSO ,SEA-CHEST>
+		<RTRUE>)
+	       (<VERB? EXAMINE READ OPEN>
+		<FSET ,PRSO ,OPENBIT>
+		<TELL
+"This rutter explains the sea route through Magellan's Pass into the
+Pacific and up the west coast of Spanish America.  It is a treasure
+beyond price." CR>)
+	       (<VERB? WRITE>
+		<TELL
+"You haven't written in this rutter since you fled the Spanish into
+the Pacific.  It deals with Magellan's Pass, and goes no further than
+Chile." CR>)
+	       (<VERB? FOLLOW STEER-BY>
+		<TELL
+G"You are in uncharted territory now, and the rutter is no help." CR>)
+	       (<P? SHOW * (VINCK HENDRIK)>
+		<TELL
+CTHE ,PRSI " appears interested, probably wondering why you are
+revealing your secret now.  Perhaps you expect to die..." CR>)
+	       (<VERB? MUNG TEAR>
+		<TELL G"You could never destroy such a valuable object." CR>)
+	       (<VERB? PUT DROP>
+		<FCLEAR ,PRSO ,OPENBIT>
+		<RFALSE>)>>
+
+<OBJECT RUTTER
+	(LOC SEA-CHEST)
+	(OWNER BLACKTHORNE)
+	(DESC "your rutter")
+	(SYNONYM RUTTER ;RUTTERS MAP ;MAPS)
+	;(ADJECTIVE MY)
+	(FLAGS NOABIT NOTHEBIT READBIT TAKEBIT SCOREBIT OPENABLE)
+	(ACTION RUTTER-F)>
+
+<ROUTINE RUTTER-F ()
+	 <COND (<OR <VERB? ;WHERE FIND>
+		    <AND <P? BE * INTPP>
+			 <PP? ,W?ON ,LG-ERASMUS>>>
+		<COND (<SCENE? ,S-ANJIRO>
+		       <FSET ,RUTTER ,RMUNGBIT>
+		       <TELL
+"You haven't seen your rutters.  Could they still be on the "I"Erasmus""?  Or
+worse, could they have been taken?  They are your most precious
+possessions, and the secret one could cost you your life in any
+Catholic nation!" CR>)>)
+	       (<VERB? WHAT>
+		<TELL
+"A rutter is a small book containing the detailed observation of
+a pilot who has been there before.  It records magnetic compass courses
+between ports and capes, headlands and channels.  It sets down how we
+got there and how we got back.  Rutters that reveal the mysteries of
+the Pass of Magellan into the Pacific -- a Portuguese discovery -- and
+thence the seaways to Asia are guarded as national treasures by the
+Spanish and Portuguese." CR>)
+	       (<IN? ,RUTTER ,GENERIC-OBJECTS>
+		<COND (<ABSTRACT-VERB?> <RFALSE>)
+		      (ELSE
+		       <TELL
+G"There's no rutter here." CR>)>)
+	       (<P? PUT-AWAY RUTTER ROOMS>
+		<PERFORM ,PRSA ,PRSO ,SEA-CHEST>
+		<RTRUE>)
+	       (<VERB? FOLLOW STEER-BY>
+		<TELL
+G"You are in uncharted territory now, and the rutter is no help." CR>)
+	       (<VERB? EXAMINE READ OPEN>
+		<FSET ,RUTTER ,OPENBIT>
+		<TELL
+"This rutter is the record of your voyage from Rotterdam in the Netherlands
+south through the Atlantic, through the Pass of Magellan, up the west
+coast of South America, and into the unknown Pacific." CR>)
+	       (<VERB? WRITE>
+		<COND (<NOT <PRSI? <> ,QUILL>>
+		       <CANT-X-WITH-PRSI "write">)
+		      (<FSET? ,RUTTER ,SCOREBIT>
+		       <TELL "You">
+		       <COND (<NOT <HELD? ,QUILL>>
+			      <SETG PRSO ,QUILL>
+			      <COND (<NOT <ITAKE <>>>
+				     <TELL
+"'ll have a devil of a time writing without a quill." CR>
+				     <RTRUE>)
+				    (ELSE
+				     <TELL " take the quill and">)>
+			      <SETG PRSO ,RUTTER>)>
+		       <FSET ,RUTTER ,OPENBIT>
+		       <TELL " write: \"April 21 1600.  Fifth
+hour.  Dusk.  133d day from Santa Maria Island, Chile, on the 32 degree
+North line
+of latitude.  Sea still high and wind strong.  We are running before the
+wind along a course of 270 degrees, making way briskly.  Large reefs
+were sighted at half the hour bearing North East by North half a
+league distant.  Three men died in the night of the scurvy.  Today
+Bosun Rijckloff died.  I estimate we are still on course and that
+landfall in the Japans should be soon.\"|
+|
+But how soon, you wonder?" CR>
+		       <RESTART-STORM?>
+		       <SCORE-OBJECT ,RUTTER>)
+		      (ELSE
+		       <TELL
+"You've already written in the rutter today.  Perhaps you need some
+rest." CR>)>)
+	       (<VERB? MUNG TEAR>
+		<TELL G"You could never destroy such a valuable object." CR>)
+	       (<VERB? PUT DROP>
+		<FCLEAR ,RUTTER ,OPENBIT>
+		<RFALSE>)>>
+
+<OBJECT SEA-CHEST
+	(LOC PILOTS-CABIN)
+	(DESC "sea chest")
+	(SYNONYM CHEST TRUNK)
+	(ADJECTIVE SEA)
+	(SIZE 200)
+	(FLAGS LOCKED LOCKABLE TAKEBIT SEARCHBIT CONTBIT OPENABLE)
+	(CAPACITY 20)
+	(ACTION SEA-CHEST-F)>
+
+<ROUTINE SEA-CHEST-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<AND <NOT <FSET? ,PRSO ,OPENBIT>>
+			    <FSET? ,PRSO ,LOCKED>>
+		       <FSET ,SEA-CHEST ,RMUNGBIT>	
+		       <TELL
+"It's locked and appears undisturbed." CR>)>)
+	       (<VERB? OPEN>
+		<COND (<PRSI? ,KEY>
+		       <PERFORM ,V?UNLOCK ,SEA-CHEST ,KEY>
+		       <RTRUE>)
+		      (<FSET? ,SEA-CHEST ,LOCKED>
+		       <FSET ,SEA-CHEST ,RMUNGBIT>
+		       <TELL
+"It's locked.  Your keep your rutters in it, and they are your most
+precious possessions." CR>)
+		      (<NOT <FSET? ,SEA-CHEST ,OPENBIT>>
+		       <FSET ,SEA-CHEST ,OPENBIT>
+		       <TELL
+"The sea chest opens.  Inside it is ">
+		       <DESCRIBE-REST ,SEA-CHEST>
+		       <TELL "." CR>)>)
+	       (<AND <P? LOCK SEA-CHEST (<> KEY)>
+		     <NOT <FSET? ,SEA-CHEST ,LOCKED>>>
+		<COND (<FSET? ,SEA-CHEST ,OPENBIT>
+		       <YOULL-HAVE-TO "close it">)
+		      (<HELD? ,KEY>
+		       <FSET ,SEA-CHEST ,LOCKED>
+		       <TELL "You've now locked it securely." CR>)
+		      (ELSE
+		       <TELL G"You don't have the key." CR>)>)
+	       (<AND <P? UNLOCK SEA-CHEST (<> KEY)>
+		     <FSET? ,SEA-CHEST ,LOCKED>>
+		<COND (<HELD? ,KEY>
+		       <FCLEAR ,SEA-CHEST ,LOCKED>
+		       <TELL "You unlock " THE ,PRSO "." CR>)
+		      (ELSE
+		       <FSET ,SEA-CHEST ,RMUNGBIT>
+		       <TELL G"You don't have the key." CR>)>)
+	       (<VERB? CLOSE>
+		<COND (<FSET? ,SEA-CHEST ,OPENBIT>
+		       <FCLEAR ,SEA-CHEST ,OPENBIT>
+		       <TELL
+"The sea chest is now closed." CR>)>)>>
+
+<ROUTINE I-BUNK ("AUX" CNT)
+	 <COND (<G? <GETP ,BLACKTHORNE ,P?HEALTH> 0>
+		<RFALSE>)>
+	 <QUEUE I-BUNK 6>
+	 <PUTP ,BUNK ,P?COUNT <SET CNT <+ 1 <GETP ,BUNK ,P?COUNT>>>>
+	 <TELL CR
+"You glance at your bunk.  You are so tired.  Go to sleep just for an hour,
+for ten minutes..." CR CR>
+	 <COND (<G? .CNT 4>
+		<TELL "\"I must sleep.  Sleep.  They rely on me...\" You
+fall into a deep, exhausted sleep which is interrupted only when the "
+I"Erasmus"" is holed on the reef and sinks to the bottom." CR>
+		<JIGS-UP>)
+	       (ELSE
+		<TELL "\"I won't, I'll sleep tomorrow,\" you force yourself
+to say." CR>)>>
+
+<OBJECT LG-BUNK
+	(LOC LOCAL-GLOBALS)
+	(SCENE S-ERASMUS S-ANJIRO S-RODRIGUES)
+	(DESC "bed")
+	(SYNONYM BUNK BED HAMMOCK BUNKS BEDS HAMMOCKS)
+	(FLAGS FURNITURE VEHBIT)
+	(ACTION LG-BUNK-F)>
+
+<ROUTINE LG-BUNK-F ()
+	 <COND (<VERB? BOARD>
+		<TELL
+"This is no time to think of sleep!" CR>)>>
+
+<OBJECT BUNK
+	(LOC PILOTS-CABIN)
+	(SCENE S-ERASMUS S-ANJIRO S-RODRIGUES)
+	(DESC "bunk")
+	(FDESC "The long narrow bunk with its straw palliasse looks inviting.")
+	(SYNONYM BUNK BED)
+	(ADJECTIVE LONG NARROW)
+	(FLAGS FURNITURE VEHBIT)
+	(COUNT 0)
+	(ACTION BUNK-F)>
+
+<CONSTANT J-BUNK 10>
+
+<ROUTINE BUNK-F ()
+	 <COND (<VERB? BOARD CLIMB-ON>
+		<COND (<JIGS-UP? ,J-BUNK
+"Your tired brain tells you that if you lie down, you will sleep, and if
+you sleep, the ship will be lost, so you push yourself away.">
+		       <TELL
+"While you might have had a chance of resisting sleep if you hadn't lain
+in the bunk, once you are in it, you fall quickly into an exhausted
+slumber.  When you are awakened, it is by the wrenching, tearing sound of
+the reef scraping the hull off of the ship.  You and the "I"Erasmus"" are
+doomed." CR>
+		       <JIGS-UP>)
+		      (ELSE <RTRUE>)>)>>
+
+<OBJECT DESK
+	(LOC PILOTS-CABIN)
+	(DESC "desk")
+	(SYNONYM DESK)
+	(FLAGS FURNITURE OPENBIT SURFACEBIT CONTBIT SEARCHBIT)
+	(CAPACITY 100)
+	(ACTION DESK-F)>
+
+<ROUTINE DESK-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"This is a battered old writing desk, with a top large enough for
+charts and rutters.">
+		<COND (<AND <SCENE? ,S-ERASMUS> <IN? ,APPLE ,ROPER>>
+		       <TELL
+"You don't see the apples you've been saving.">)>
+		<CRLF>)
+	       (<VERB? OPEN>
+		<COND (<AND <FSET? ,KEY ,NDESCBIT>
+			    <SCENE? ,S-ERASMUS>>
+		       <PERFORM ,V?SEARCH ,DESK>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"Opening the desk reveals little of interest.  You've seen it all a
+thousand times before." CR>)>)
+	       (<VERB? SEARCH>
+		<COND (<AND <FSET? ,KEY ,NDESCBIT>
+			    <SCENE? ,S-ERASMUS>>
+		       <FSET ,KEY ,TAKEBIT>
+		       <FSET ,KEY ,TRYTAKEBIT>
+		       <FCLEAR ,KEY ,NDESCBIT>
+		       <COND (<IN? ,APPLE ,ROPER>
+			      <TELL
+"The first thing you notice is that the apples you've been saving are
+gone!  ">)>
+		       <COND (<FSET? ,SEA-CHEST ,RMUNGBIT>
+			      <FCLEAR ,SEA-CHEST ,RMUNGBIT>
+			      <MOVE ,KEY ,WINNER>
+			      <THIS-IS-IT ,KEY>
+			      <TELL
+"You search for the key to your sea-chest.  Can someone have taken it?  No!  There it is.  You take it with thanks." CR>)
+			     (ELSE
+			      <TELL "You notice the key to your sea-chest,
+safe and sound where you left it." CR>)>
+		       <RESTART-STORM?>
+		       <SCORE-OBJECT ,KEY>)
+		      (ELSE
+		       <TELL
+"You search the desk, finding nothing of particular interest." CR>)>)>>
+
+<OBJECT QUILL
+	(LOC DESK)
+	(DESC "quill")
+	(SYNONYM QUILL PEN)
+	(ADJECTIVE FRESH QUILL)
+	(FLAGS TAKEBIT TOOLBIT)>
+
+<OBJECT KEY
+	(LOC PILOTS-CABIN)
+	(DESC "rusty key")
+	(SYNONYM KEY)
+	(ADJECTIVE RUSTY)
+	(FLAGS NDESCBIT ;TRYTAKEBIT ;TAKEBIT SCOREBIT)
+	(ACTION KEY-F)>
+
+<ROUTINE KEY-F ()
+	 <COND (<VERB? FIND>
+		<COND (<FSET? ,KEY ,NDESCBIT>
+		       <TELL
+"You keep the key in your desk, so you look there first.  ">)>
+		<PERFORM ,V?SEARCH ,DESK>
+		<RTRUE>)
+	       (<FSET? ,KEY ,NDESCBIT>
+		<TELL
+"You see no key here." CR>)
+	       (<AND <P? UNLOCK SEA-CHEST KEY>
+		     <FSET? ,SEA-CHEST ,LOCKED>>
+		<FCLEAR ,SEA-CHEST ,LOCKED>
+		<TELL
+"The chest unlocks with a rusty click." CR>)
+	       (<AND <P? LOCK SEA-CHEST KEY>
+		     <NOT <FSET? ,SEA-CHEST ,LOCKED>>>
+		<FCLEAR ,SEA-CHEST ,OPENBIT>
+		<FSET ,SEA-CHEST ,LOCKED>
+		<TELL
+"The chest is now securely locked." CR>)>>
+
+<OBJECT APPLE
+	(DESC "tiny bruised apple")
+	(OWNER BLACKTHORNE)
+	(SYNONYM APPLE APPLES SLICE)
+	(ADJECTIVE BRUISED TINY MOLDY)
+	(FLAGS NDESCBIT TAKEBIT FOODBIT SCOREBIT DONT-ALL)
+	(COUNT 4)
+	(ACTION APPLE-F)>
+
+<ROUTINE APPLE-F ("AUX" TMP)
+	 <COND (<VERB? FIND>
+		<COND (<AND <IN? ,APPLE ,ROPER>
+			    <FSET? ,APPLE ,NDESCBIT>>
+		       <TELL
+"A cursory search of the premises reveals no apple." CR>)>)
+	       (<VERB? EXAMINE>
+		<COND (<IN? ,APPLE ,ROPER>
+		       <COND (<FSET? ,APPLE ,NDESCBIT>
+			      <TELL
+"You see no apple." CR>)
+			     (ELSE
+			      <TELL
+"This is the last of the apples you have carefully hoarded all the way
+from Santa Maria Island, off Chile.  It's bruised and tiny, with mold on
+a rotting section." CR>)>)>)
+	       (<VERB? EAT>
+		<COND (<NOT <HELD? ,APPLE>>
+		       <TELL
+"You don't have the apple." CR>
+		       <RTRUE>)>
+		<SET TMP <- <GETP ,APPLE ,P?COUNT> 1>>
+		<PUTP ,APPLE ,P?COUNT .TMP>
+		<COND (<ZERO? .TMP>
+		       <REMOVE ,APPLE>
+		       <TELL
+"You eat the last quarter of the apple." CR>)
+		      (ELSE
+		       <TELL
+"You carefully eat a quarter of the apple, wrap the remainder, and put it
+away.  There are a few maggots in the quarter you've cut off, but you
+heed the old sea legend that apple maggots are effective against
+scurvy.  You chew the fruit gently because your teeth are aching and your gums
+sore and tender.  After you finish the apple, you feel better." CR>
+		       <COND (<EQUAL? .TMP 3>
+			      <PUTP ,WINNER ,P?HEALTH 1>
+			      <SETG TIRED-TIME 0>
+			      <DEQUEUE I-TIRED-WARNING>
+			      <DEQUEUE I-TIRED>
+			      <RESTART-STORM?>
+			      <SCORE-OBJECT ,APPLE>)>
+		       <RTRUE>)>)
+	       (<AND <P? GIVE APPLE *>
+		     <FSET? ,PRSI ,PERSON>>
+		<REMOVE ,APPLE>
+		<TELL
+CTHE ,PRSI " take" S ,PRSI " the apple and gobble" S ,PRSI " it greedily.">
+		<COND (<PRSI? ,VINCK ,PIETERZOON CROOCQ>
+		       <TELL
+" \"Thank you, Pilot.  Thank you!\"">)>
+		<CRLF>)>>
+
+<ROUTINE RAT-PSEUDO ()
+	 <RANDOM-PSEUDO "rat">>
+
+<ROUTINE COCKROACH-PSEUDO ()
+	 <RANDOM-PSEUDO "cockroaches">>
+
+<ROUTINE RANDOM-PSEUDO (WHAT)
+	 <TELL "You don't see the " .WHAT " any more." CR>>
+
+<ROOM MATES-CABIN
+      (LOC ROOMS)
+      (DESC "Mates' Cabin")
+      (OWNER MATES)
+      (SYNONYM CABIN ROOM)
+      (ADJECTIVE MATES)
+      (PORT TO PASSAGEWAY IF MATES-CABIN-DOOR IS OPEN)
+      (OUT TO PASSAGEWAY IF MATES-CABIN-DOOR IS OPEN)
+      (FLAGS ONBIT)
+      (GLOBAL DECK MATES-CABIN-DOOR LG-ERASMUS LG-CREWMEN)
+      (THINGS <> RAT RAT-PSEUDO
+	      <> COCKROACH COCKROACH-PSEUDO)
+      (ACTION MATES-CABIN-F)>
+
+<ROUTINE MATES-CABIN-F (RARG)
+	 <COND (<RARG? LOOK>
+		<TELL
+"This is the Mates' cabin.">
+		<COND (<SCENE? ,S-ERASMUS>
+		       <TELL " It is now shared by Baccus van Nekk, the
+chief merchant, Hendrik the third mate, and the boy, Croocq.">)>
+		<TELL " The passageway is outside." CR>)
+	       (<RARG? BEG>
+		<COND (<AND <P? SEARCH GLOBAL-HERE>
+			    <IN? ,APPLE ,ROPER>>
+		       <TELL
+"You find nothing.  Roper watches with a smirk on his face.  \"Go ahead,
+Pilot.  Search all you want.\"" CR>)
+		      (<AND <P? SEARCH (PIETERZOON VAN-NEKK CROOCQ)>
+			    <IN? ,APPLE ,ROPER>>
+		       <TELL
+D ,PRSO " reluctantly allows himself to be searched, cursing you all
+the while.  You find nothing." CR>)>)>>
+
+<OBJECT PILOTS-CABIN-DOOR
+	(LOC LOCAL-GLOBALS)
+	(OWNER BLACKTHORNE)
+	(DESC "Pilot's cabin door")
+	(SYNONYM DOOR)
+	(ADJECTIVE ;MY CABIN)
+	(FLAGS DOORBIT LOCKABLE)>
+
+<OBJECT CAPTAINS-CABIN-DOOR
+	(LOC LOCAL-GLOBALS)
+	(OWNER SPILLBERGEN)
+	(DESC "Captain's cabin door")
+	(SYNONYM DOOR)
+	(ADJECTIVE CABIN)
+	(FLAGS DOORBIT LOCKABLE)
+	(ACTION CAPTAINS-CABIN-DOOR-F)>
+
+<ROUTINE CAPTAINS-CABIN-DOOR-F ()
+	 <COND (<VERB? KNOCK>
+		<TELL
+"You hear a faint response." CR>)>>
+
+<OBJECT MATES
+	(LOC GENERIC-OBJECTS)
+	(DESC "Mates")
+	(SYNONYM MATES MATE OFFICERS OFFICER)
+	(ADJECTIVE FIRST SECOND THIRD)
+	(FLAGS PERSON DUTCHBIT)>
+
+<OBJECT MATES-CABIN-DOOR
+	(LOC LOCAL-GLOBALS)
+	(OWNER MATES)
+	(DESC "Mates' cabin door")
+	(SYNONYM DOOR)
+	(ADJECTIVE CABIN)
+	(FLAGS DOORBIT LOCKABLE)
+	(ACTION MATES-CABIN-DOOR-F)>
+
+<ROUTINE MATES-CABIN-DOOR-F ()
+	 <COND (<VERB? KNOCK>
+		<TELL
+"\"Aye?  Come in, damn you!  Do think this is a palace?\"" CR>)>>
+
+<OBJECT PASSAGE-DOOR
+	(LOC LOCAL-GLOBALS)
+	(DESC "passageway door")
+	(SYNONYM DOOR)
+	(ADJECTIVE PASSAGE PASSAGEWAY)
+	(FLAGS DOORBIT LOCKABLE)
+	(ACTION PASSAGE-DOOR-F)>
+
+<ROUTINE PASSAGE-DOOR-F ()
+	 <COND (<SCENE? ,S-ANJIRO>
+		<COND (<NOT <PASSIVE-VERB?>>
+		       <PERFORM ,V?RUB ,RIBBON>
+		       <RTRUE>)>)
+	       (<SCENE? ,S-ERASMUS>
+		<COND (<VERB? KNOCK>
+		       <TELL
+"You hear noise inside, but no response to your knock." CR>)>)>>
+
+<OBJECT LASHING
+	(LOC BRIDGE-OF-ERASMUS)
+	(DESC "protective lashing")
+	(SYNONYM LASHING ROPE)
+	(ADJECTIVE PROTECTIVE)
+	(FLAGS NDESCBIT)>
+
+<OBJECT WHEEL
+	(LOC BRIDGE-OF-ERASMUS)
+	(OWNER LG-ERASMUS)
+	(DESC "wheel")
+	(SYNONYM WHEEL RUDDER HELM TILLER)
+	(ADJECTIVE SHIPS)
+	(DESCFCN WHEEL-DESC)
+	(FLAGS CANT-HOLD SCOREBIT)
+	(ACTION WHEEL-F)>
+
+<ROUTINE WHEEL-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (<RARG? OBJDESC>
+		<TELL
+"The wheel dominates the quarterdeck.  It is
+turned ">
+		<COND (<EQUAL? ,SHIP-COURSE ,P?PORT> <TELL "to port">)
+		      (<EQUAL? ,SHIP-COURSE ,P?STARBOARD> <TELL "to starboard">)
+		      (ELSE <TELL "straight">)>
+	 <TELL " and ">
+	 <COND (<FSET? ,WHEEL ,RMUNGBIT>
+		<TELL "lashed in place">)
+	       (ELSE <TELL "free to turn">)>
+	 <TELL  " now.">)>>
+
+<ROUTINE WHEEL-F ("AUX" (ST? <>) (TOOK? <>))
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The wheel is connected to the rudder and steers the ship.  It is
+turned ">
+		<COND (<EQUAL? ,SHIP-COURSE ,P?PORT> <TELL "to port">)
+		      (<EQUAL? ,SHIP-COURSE ,P?STARBOARD> <TELL "to starboard">)
+		      (ELSE <TELL "straight">)>
+		<TELL " now, ">
+		<COND (<FSET? ,WHEEL ,RMUNGBIT>
+		       <TELL
+"lashed in place against the surging sea." CR>)
+		      (<FSET? ,WHEEL ,ONBIT>
+		       <TELL
+"unlashed and held steady only by all the strength you can summon
+from a weakened body." CR>)
+		      (ELSE
+		       <TELL
+"spinning freely from side to side, the lashing hanging loosely beside
+it." CR>)>)
+	       (<VERB? TAKE TAKE-OVER>
+		<COND (<FSET? ,WHEEL ,RMUNGBIT>
+		       <PERFORM ,V?UNTIE ,WHEEL>
+		       <RTRUE>)
+		      (<NOT <FSET? ,WHEEL ,ONBIT>>
+		       <TELL
+"You take hold of the wheel, trying to keep it under control">
+		       <COND (<AND <EQUAL? ,SHIP-Y 1> ;">=13"
+				   <G? ,SHIP-X 0>
+				   <L? ,SHIP-X 6>>
+			      <TELL ", but the currents and the
+crashing waves spin it away from from you.  You just aren't strong
+enough to hold it alone.  \"Piss on you, storm!  Get your dung-eating
+hands off my ship!\", you rage in frustration." CR>)
+			     (ELSE
+			      <FCLEAR ,HENDRIK ,TRYTAKEBIT>
+			      <FSET ,WHEEL ,ONBIT>
+			      <TELL "." CR>)>)
+		      (ELSE
+		       <TELL
+"You hold the wheel as strongly as you can, fighting the surging
+sea." CR>)>)
+	       (<VERB? DROP>
+		<COND (<FSET? ,WHEEL ,RMUNGBIT>
+		       <PERFORM ,V?UNTIE ,WHEEL>
+		       <RTRUE>)
+		      (<FSET? ,WHEEL ,ONBIT>
+		       <FCLEAR ,WHEEL ,ONBIT>
+		       <TELL
+"You let go of the wheel." CR>)
+		      (ELSE
+		       <TELL
+"You arent' holding it." CR>)>)
+	       (<P? PUT LASHING WHEEL>
+		<PERFORM ,V?TIE ,WHEEL>
+		<RTRUE>)
+	       (<P? (TAKE TAKE-OFF) LASHING>
+		<PERFORM ,V?UNTIE ,WHEEL>
+		<RTRUE>)
+	       (<P? TIE WHEEL>
+		<COND (<FSET? ,WHEEL ,RMUNGBIT>
+		       <TELL G"It already is." CR>)
+		      (<AND <EQUAL? ,SHIP-Y 1> ;">=13"
+			    <G? ,SHIP-X 0>
+			    <L? ,SHIP-X 6>
+			    <NOT <FSET? ,WHEEL ,ONBIT>>>
+		       <TELL
+"The wheel is spinning too wildly to lash.  ">
+		       <YOULL-HAVE-TO "get it under control">)
+		      (ELSE
+		       <FSET ,WHEEL ,RMUNGBIT>
+		       <FCLEAR ,WHEEL ,ONBIT>
+		       <TELL
+"You loop the protective lashing around the spokes of the wheel.  It
+is now locked in place." CR>)>)
+	       (<P? UNTIE WHEEL>
+		<COND (<FSET? ,WHEEL ,RMUNGBIT>
+		       <FCLEAR ,HENDRIK ,TRYTAKEBIT>
+		       <FSET ,WHEEL ,ONBIT>
+		       <FCLEAR ,WHEEL ,RMUNGBIT>
+		       <TELL
+"You remove the protective lashing, and brace yourself in place against
+the force of the sea.  You can now turn the wheel freely." CR>)
+		      (ELSE
+		       <TELL
+G"It already is." CR>)>)
+	       (<P? TIE * WHEEL>
+		<COND (<PRSO? ,LASHING>
+		       <PERFORM ,V?TIE ,WHEEL>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"You can't tie " THE ,PRSO " to the wheel!" CR>)>)
+	       (<P? UNTIE LASHING WHEEL>
+		<PERFORM ,V?UNTIE ,WHEEL>)
+	       (<P? STRAIGHTEN WHEEL>
+		<SETG P-DIRECTION ,P?FORE>
+		<PERFORM ,V?TURN ,WHEEL ,INTDIR>
+		<RTRUE>)
+	       (<P? TURN WHEEL>
+		<COND (<NOT <FSET? ,WHEEL ,ONBIT>>
+		       <COND (<AND <EQUAL? ,SHIP-Y 1> ;">=13"
+				   <G? ,SHIP-X 0>
+				   <L? ,SHIP-X 6>>
+			      <TELL
+"You grab for the spinning, thrashing wheel, but the force of the
+storm is too strong, and the"G" wheel spins out of your hands!" CR>
+			      <RTRUE>)
+			     (ELSE
+			      <SET TOOK? T>
+			      <FCLEAR ,HENDRIK ,TRYTAKEBIT>
+			      <FSET ,WHEEL ,ONBIT>
+			      <TELL
+"You take the wheel">
+			      <COND (<FSET? ,WHEEL ,RMUNGBIT>
+				     <FCLEAR ,WHEEL ,RMUNGBIT>
+				     <TELL ", unlashing it first">)>)>)>
+		<COND (<FSET? ,LG-ERASMUS ,RMUNGBIT>
+		       <COND (.TOOK? <TELL ", but the">)
+			     (ELSE <TELL "The">)>
+		       <TELL
+" ship is pinned to the reef, so turning the wheel is futile!" CR>)
+		      (<FSET? ,WHEEL ,RMUNGBIT>
+		       <COND (.TOOK? <TELL ", but it's">)
+			     (ELSE <TELL "The wheel is">)>
+		       <TELL " lashed in place and won't turn." CR>)
+		      (<FSET? ,FORESAILS ,RMUNGBIT>
+		       <COND (.TOOK? <TELL " and turn it">)
+			     (ELSE
+			      <TELL "You turn the wheel">)>
+		       <TELL ", but there just isn't enough sail without the
+foresails, and the ship wallows like a pig!" CR>)
+		      (<PRSI? ,INTDIR>
+		       <COND (<OR <AND <EQUAL? ,P-DIRECTION ,P?STARBOARD>
+				       <EQUAL? ,SHIP-COURSE ,P?PORT>>
+				  <AND <EQUAL? ,P-DIRECTION ,P?PORT>
+				       <EQUAL? ,SHIP-COURSE ,P?STARBOARD>>>
+			      <SET ST? ,P-DIRECTION>
+			      <SETG P-DIRECTION ,P?FORE>)>
+		       <COND (<EQUAL? ,P-DIRECTION ,SHIP-COURSE>
+			      <COND (.TOOK? <TELL ".  ">)>
+			      <COND (<EQUAL? ,SHIP-COURSE ,P?FORE>
+				     <TELL "You maintain course ">
+				     <TELL-DIRECTION ,SHIP-DIRECTION>
+				     <TELL ", the wheel still ">)
+				    (ELSE
+				     <TELL "The wheel is already ">)>
+			      <COND (<EQUAL? ,SHIP-COURSE ,P?PORT>
+				     <TELL "turned to port">)
+				    (<EQUAL? ,SHIP-COURSE ,P?STARBOARD>
+				     <TELL "turned to starboard">)
+				    (<EQUAL? ,SHIP-COURSE ,P?FORE>
+				     <TELL "straight">)>
+			      <TELL "." CR>)
+			     (<EQUAL? ,P-DIRECTION ,P?PORT>
+			      <QUEUE I-BROADSIDE 2>
+			      <SET-COURSE ,P?PORT>
+			      <COND (.TOOK? <TELL ".  ">)>
+			      <TELL
+"Straining against the sea, you turn the wheel to port.">
+			      <COND (<AND ,REEF-FLAG ;"3,4"
+					  <EQUAL? ,REEF-X ,REEF-Y>>
+				     <TELL
+" The ship turns broadside to the reef, struggling against the
+wind which tries to drive it onto the spines." CR>)
+				    (<AND <EQUAL? ,SHIP-X 6> ;"11"
+					  <EQUAL? ,SHIP-Y 2>>
+				     <TELL
+" Fighting the wind, the ship slowly turns away from the reef." CR>)
+				    (<AND <EQUAL? ,SHIP-X 1> ;"15"
+					  <EQUAL? ,SHIP-Y 1>>
+				     <TELL
+" Struggling, the ship begins to turn to port, slowly, slowly as the
+swift currents are drawing you deeper into the maze of rocks." CR>)
+				    (ELSE
+				     <TELL
+" The ship struggles against the wind." CR>)>)
+			     (<EQUAL? ,P-DIRECTION ,P?STARBOARD>
+			      <QUEUE I-BROADSIDE 2>
+			      <SET-COURSE ,P?STARBOARD>
+			      <COND (.TOOK? <TELL " and turn it">)
+				    (ELSE <TELL "You turn the wheel">)>
+			      <TELL " to starboard.">
+			      <COND (<AND <EQUAL? ,SHIP-X 8> ;"10"
+					  <EQUAL? ,SHIP-Y 2>>
+				     <TELL
+" The wind snaps the sails full and the ship heads for the gap, but it
+means coming very close to the waiting reef!" CR>)
+				    (<AND <EQUAL? ,SHIP-X 5> ;"12"
+					  <EQUAL? ,SHIP-Y 1>>
+				     <TELL
+" With a crack the sails fill, shooting the "I"Erasmus"" into the gap!" CR>)
+				    (ELSE
+				     <TELL
+" The ship gains speed with the wind." CR>)>)
+			     (<EQUAL? ,P-DIRECTION ,P?FORE ,P?IN>
+			      <DEQUEUE I-BROADSIDE>
+			      <SET-COURSE ,P?FORE>
+			      <COND (.ST?
+				     <COND (.TOOK? <TELL " and haul it to ">)
+					   (ELSE <TELL "You haul the wheel to ">)>
+				     <TELL-DIRECTION .ST?>
+				     <TELL
+", centering it">)
+				    (ELSE
+				     <COND (.TOOK? <TELL " and straighten it">)
+					   (ELSE <TELL "You straighten the wheel">)>)>
+			      <COND (<AND <EQUAL? ,SHIP-Y 9>
+					  <EQUAL? ,SHIP-X 19>>
+				     <SETG SHIP-DIRECTION ,P?WEST>
+				     <TELL
+".  Helped by the following wind, the ship returns to its course." CR>
+				     <SCORE-OBJECT ,WHEEL>)
+				    (ELSE
+				     <TELL
+", trying to hold a steady course." CR>)>)
+			     (ELSE
+			      <COND (.TOOK? <TELL ".  ">)>
+			      <TELL
+"You can only turn the ship to port or starboard!" CR>)>)
+		      (ELSE
+		       <COND (.TOOK? <TELL ".  ">)>
+		       <TELL G"You must specify a direction!" CR>)>)>>
+
+<ROUTINE I-BROADSIDE ()
+	 <COND (<NOT <EQUAL? ,SHIP-COURSE ,P?FORE>>
+		<TELL CR
+"The "I"Erasmus"" continues to turn, further and further off the
+wind.  Soon she'll be broadside to the waves!" CR>)>>
+
+<ROUTINE I-SHIP-BROADSIDE ()
+	 <COND (<NOT <EQUAL? ,SHIP-COURSE ,P?FORE>>
+		<SHIP-BROADSIDE>)>>
+
+<ROUTINE SHIP-BROADSIDE ()
+	 <TELL CR "The ship continues turning to ">
+	 <TELL-DIRECTION ,SHIP-COURSE>
+	 <JIGS-UP
+".  It is now broadside to the waves, which spill torrents of water
+onto the deck, and below.  Soon she is foundering, the entire ocean seeming
+to want to fill her holds.">
+	 <RFATAL>>
+
+<ROUTINE SET-COURSE (DIR)
+	 <COND (<NOT <EQUAL? .DIR ,SHIP-COURSE ,P?FORE>>
+		<QUEUE I-STORM 1>)>
+	 <SETG SHIP-COURSE .DIR>
+	 <RTRUE>>
+
+<GLOBAL TIRED-TIME 0>
+
+<ROUTINE I-TIRED-WARNING ()
+	 <COND (<ZERO? <GETP ,BLACKTHORNE ,P?HEALTH>>
+		<TELL CR
+"Exhaustion is rapidly overcoming you, but you know you can't sleep
+now." CR>)>>
+
+<ROUTINE I-TIRED ()
+	 <COND (<ZERO? <GETP ,BLACKTHORNE ,P?HEALTH>>
+		<CRLF>
+		<JIGS-UP
+"Your exhausted body, pushed beyond its last reserves of strength,
+fails you.  You collapse, every fiber aching with months of
+deprivation.  It is not long after that the ship is driven against the
+rocks.">)>>
+
+<OBJECT SPILLBERGEN
+	(LOC CAPTAINS-CABIN)
+	(DESC "Captain-General Spillbergen")
+	(SYNONYM SPILLBERGEN CAPTAIN MAN)
+	(ADJECTIVE CAPTAIN-GENERAL CAPTAIN PAULUS)
+	(FLAGS PERSON DUTCHBIT OPENBIT CONTBIT SEARCHBIT NOABIT NOTHEBIT)
+	(DESCFCN SPILLBERGEN-DESC)
+	(GENERIC GENERIC-CAPTAIN-F)
+	(ACTION SPILLBERGEN-F)>
+
+<ROUTINE GENERIC-CAPTAIN-F (R F)
+	 <COND (<SCENE? ,S-ERASMUS ,S-ANJIRO ,S-YABU ,S-PIT>
+		,SPILLBERGEN)
+	       (<SCENE? ,S-NINJA>
+		,GRAY-CAPTAIN)
+	       (<SCENE? ,S-DEPARTURE>
+		<COND (<FSET? ,YAMAZAKI ,DEAD> ,KOJIMA)
+		      (ELSE <RFALSE>)>)>>
+
+<ROUTINE SPILLBERGEN-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?>
+		<COND (<SCENE? ,S-ERASMUS ,S-YABU ,S-PIT> <RTRUE>)
+		      (ELSE <RFALSE>)>)
+	       (<RARG? OBJDESC>
+		<TELL
+"Captain-General Paulus Spillbergen ">
+		<COND (<SCENE? ,S-ERASMUS>
+		       <TELL "lies half conscious in his bunk.">)
+		      (<SCENE? ,S-YABU>
+		       <TELL "lies nearly unconscious on a pallet.">)
+		      (<SCENE? ,S-PIT>
+		       <COND (<AND <LOC ,LONG-STRAW> <LOC ,SHORT-STRAW>>
+			      <TELL
+"lies delirious in the mud.">)
+			     (ELSE
+			      <TELL
+"sits in the mud, leaning back against a wall.">)>)>)>>
+
+<ROUTINE SPILLBERGEN-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<OR <VERB? STOP>
+			   <P? SHUT-UP ROOMS>>
+		       <TELL
+"He stops for a moment, looking at you pitifully." CR>)
+		      (ELSE
+		       <TELL
+"He stirs weakly, but otherwise doesn't respond." CR>)>)
+	       (<VERB? PISS>
+		<TELL
+"You have come to hate him, but to humilate him in his helpless,
+weakened condition would be too much." CR>)
+	       (<VERB? MOVE>
+		<TELL "He's too weak to be moved." CR>)
+	       (<HOSTILE-VERB?>
+		<TELL
+"You want to hit him, even as weak and helpless as he is.  He's to
+blame, it's true, but you can't do it."G" Almost exactly
+one year ago the fleet reached Tierra del Fuego, the winds favorable for
+the stab into the unknown of Magellan's Pass.  But the Captain-General had
+ordered a landing to search for gold and treasure.  The fleet had been
+forced to winter in the harsh southern wastes, and it was four months
+before they could sail.  By then, one hundred and fifty six men had died
+of starvation and cold." CR>)
+	       (<VERB? WHO>
+		<TELL
+"Paulus Spillbergen is the Captain-General of the fleet."G" Almost exactly
+one year ago the fleet reached Tierra del Fuego, the winds favorable for
+the stab into the unknown of Magellan's Pass.  But the Captain-General had
+ordered a landing to search for gold and treasure.  The fleet had been
+forced to winter in the harsh southern wastes, and it was four months
+before they could sail.  By then, one hundred and fifty six men had died
+of starvation and cold." CR>)
+	       (<VERB? EXAMINE>
+		<TELL "Spillbergen ">
+		<COND (<HERE? ,CAPTAINS-CABIN>
+		       <TELL
+"is lying half conscious in his bunk.  He ">)>
+		<TELL "is a short,
+florid man, normally very fat, now very thin, the skin of his
+paunch hanging slackly in folds.">
+		<COND (<AND <HERE? ,CAPTAINS-CABIN>
+			    <FSET? ,FLAGON ,SCOREBIT>>
+		       <TELL " He looks parched.">)>
+		<CRLF>)
+	       (<AND <VERB? FIND>
+		     <SCENE? ,S-ERASMUS>
+		     <NOT <HERE? ,CAPTAINS-CABIN>>>
+		<TELL "He's in his cabin." CR>)
+	       (<P? ASK-ABOUT * GLOBAL-WATER>
+		<TELL
+"\"I'm parched, Pilot!  Give me water!  You had some before!\"" CR>)
+	       (<P? SHOW * SPILLBERGEN>
+		<COND (<PRSO? FLAGON APPLE>
+		       <TELL
+"The captain reaches feebly for " THE ,PRSO "." CR>)>)
+	       (<P? GIVE * SPILLBERGEN>
+		<COND (<PRSO? FLAGON>
+		       <FSET ,FLAGON ,OPENBIT>
+		       <TELL
+"Weakly, Spillbergen drinks a little water.">
+		       <COND (<FSET? ,FLAGON ,SCOREBIT>
+			      <TELL
+" \"Thanks,\" he says.  \"Where's land -- where's land?\"|
+|
+\"Ahead\" is all you can say in reply." CR>
+			      <RESTART-STORM?>
+			      <SCORE-OBJECT ,FLAGON>)
+			     (ELSE <CRLF>)>)
+		      (<PRSO? APPLE>
+		       <REMOVE ,APPLE>
+		       <TELL
+"The captain greedily devours your last apple, the pulp dripping down
+his chin." CR>)>)
+	       (<VERB? SOOTHE>
+		<TELL
+"His whining continues unabated." CR>)
+	       (<VERB? HELP>
+		<TELL
+"He seems hungry and thirsty." CR>)
+	       (<VERB? SEARCH>
+		<TELL
+"He squirms and whines in a futile attempt to prevent you.  You find
+nothing interesting anyway." CR>)>>
+
+<OBJECT PIETERZOON
+	(LOC MATES-CABIN)
+	(DESC "Pieterzoon")
+	(SYNONYM PIETERZOON GUNNER)
+	(FLAGS PERSON DUTCHBIT NOABIT NOTHEBIT)
+	(ACTION PIETERZOON-F)>
+
+<ROUTINE PIETERZOON-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+	        <COND (<SEND-HIM-OUT?>
+		       <SETG WINNER ,PLAYER>
+		       <PERFORM ,V?SEND ,PIETERZOON ,ROOMS>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+CTHE ,WINNER G" responds with little enthusiasm." CR>)>)
+	       (<RARG? <>>
+		<COND (<AND <NOT <IN? ,PIETERZOON ,HERE>>
+			    <HERE? ,PIT>
+			    <NOT <ABSTRACT-VERB?>>>
+		       <TELL
+"Pieterzoon isn't here." CR>
+		       <COND (<VERB? TELL> <END-QUOTE>)
+			     (ELSE <RTRUE>)>)
+		      (<AND <VERB? EXAMINE>
+			    <FSET? ,PIETERZOON ,DEAD>>
+		       <TELL
+"He looks like a boiled roast of beef." CR>)
+		      (<P? SEND PIETERZOON>
+		       <TELL
+"\"I'm too weak, Pilot!  Go forward and send Ginsel out, or Maetsukker!  He's
+always shirking his watch!\"" CR>)>)>>
+
+<OBJECT ROPER
+	(LOC PASSAGEWAY)
+	(DESC "Jan Roper")
+	(SYNONYM JAN ROPER CALVINIST)
+	(ADJECTIVE JAN)
+	(FLAGS PERSON DUTCHBIT NOABIT NOTHEBIT SCOREBIT
+	       CONTBIT OPENBIT SEARCHBIT)
+	(CONTFCN ROPER-F)
+	(ACTION ROPER-F)>
+
+<ROUTINE ROPER-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<NOT <SCENE? ,S-ERASMUS>>
+		       <TELL "He responds with disdain." CR>)
+		      (<OR <P? ACCUSE ROPER>
+			   <P? TELL-ME-ABOUT APPLE>
+			   <AND <P? (BE BE?) ;WHY YOU INTPP>
+				<PP? ,W?IN ,PILOTS-CABIN>>>
+		       <FCLEAR ,APPLE ,NDESCBIT>
+		       <TELL
+"\"You've been in my cabin,\" you say tiredly.|
+|
+\"I didn't steal anything, Pilot.  Besides, alone in the wilderness
+we good Christians must share what little we have.\"  You recall how
+Roper and the rest didn't conserve their food, especially the fruit
+which has made your scurvy a matter of aching gums rather than lost
+teeth." CR>)
+		      (<HOSTILE-VERB?>
+		       <TELL
+"\"I'll turn the other cheek, as any good Christian would!\" says
+Roper.  You remember him shooting at the priests in Chile." CR>)
+		      (<P? GIVE APPLE (BLACKTHORNE ME)>
+		       <TELL
+"\"It's ours to share.  We ate one, shared it out, and we'll do the
+same with the other, as God is my witness!\"" CR>)
+		      (<SEND-HIM-OUT?>
+		       <SETG WINNER ,PLAYER>
+		       <PERFORM ,V?SEND ,ROPER ,ROOMS>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"He responds scornfully." CR>)>)
+	       (<RARG? CONTAINER>
+		<COND (<P? TAKE APPLE>
+		       <FCLEAR ,APPLE ,DONT-ALL>
+		       <FCLEAR ,APPLE ,NDESCBIT>
+		       <MOVE ,APPLE ,WINNER>
+		       <TELL
+"You grab Roper tightly, and twist his arm until he drops the apple
+into your hands." CR>
+		       <RESTART-STORM?>
+		       <SCORE-OBJECT ,ROPER>)>)
+	       (<VERB? WHO>
+		<TELL
+"Jan Roper is one of the merchant adventurers, and a fanatic
+Calvinist.  He nearly killed you in Chile in his haste to fire his musket at a
+priest." CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"He's a narrow-eyed young man with a high forehead and a thin nose.">
+		<COND (<HERE? ,MATES-CABIN>
+		       <TELL
+"His pale chin is marred by a drip of apple juice.">)>
+		<CRLF>)
+	       (<VERB? SEARCH>
+		<COND (<NOT <SCENE? ,S-ERASMUS>>
+		       <RFALSE>)
+		      (<IN? ,APPLE ,ROPER>
+		       <COND (<FSET? ,APPLE ,NDESCBIT>
+			      <FCLEAR ,APPLE ,NDESCBIT>
+			      <TELL
+"Roper twists away as best he can, then pulls an apple from his
+pocket.  \"Here it is!\" he screams, dancing away from you." CR>)
+			     (ELSE
+			      <TELL
+"\"Keep away from me!  What more do you want?\" Roper whines." CR>)>)
+		      (ELSE
+		       <TELL
+"\"What more do you want from me?  You've already stolen my apple, you
+hoarder!\"" CR>)>)
+	       (<P? GIVE APPLE ROPER>
+		<REMOVE ,APPLE>
+		<TELL
+"Roper grabs the apple and stuffs it into his mouth." CR>)
+	       (<HOSTILE-VERB?>
+		<TELL "You ">
+		<COND (<VERB? THROW>
+		       <COND (<NOT <HELD? ,PRSO>>
+			      <TELL "threaten to ">)>
+		       <MOVE ,PRSO ,HERE>
+		       <TELL "throw " THE ,PRSO " at him">)
+		      (<AND ,PRSI <FSET? ,PRSI ,WEAPONBIT>>
+		       <TELL "threaten him with " THE ,PRSI>)
+		      (<VERB? KICK>
+		       <TELL "kick at him as you would kick a dog">)
+		      (ELSE
+		       <TELL "raise your fists, threatening him">)>
+		<TELL ", and he backs fearfully away.">
+		<COND (<IN? ,APPLE ,ROPER>
+		       <COND (<FSET? ,APPLE ,NDESCBIT>
+			      <FCLEAR ,APPLE ,NDESCBIT>
+			      <TELL
+" \"It's mine, I tell you!  Share and share alike!\" he whines, pulling
+an apple out of his pocket.">)
+			     (ELSE
+			      <MOVE ,APPLE ,HERE>
+			      <TELL
+" \"Don't hit me!\" he screams, dropping the apple on the ground.">)>)>
+		<CRLF>)
+	       (<P? SEND ROPER>
+		<TELL
+"He refuses to go, scornfully suggesting you get the regular crewmen on
+deck instead.  He's so incompetent a seaman that you relent." CR>)>>
+
+<OBJECT SONK
+	(LOC BELOW-DECKS)
+	(DESC "Sonk")
+	(SYNONYM SONK COOK)
+	(FLAGS NDESCBIT PERSON DUTCHBIT NOABIT NOTHEBIT)
+	(ACTION SONK-F)>
+
+<ROUTINE SONK-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<TELL CTHE ,WINNER G" responds with little enthusiasm." CR>)>>
+
+<OBJECT SALAMON
+	(LOC BELOW-DECKS)
+	(DESC "Salamon")
+	(SYNONYM SALAMON MUTE)
+	(FLAGS NDESCBIT PERSON DUTCHBIT NOABIT NOTHEBIT)
+	(ACTION SALAMON-F)>
+
+<ROUTINE SALAMON-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<TELL
+CTHE ,WINNER " responds with gestures conveying little enthusiasm." CR>)
+	       (<VERB? WHO>
+		<TELL "Salamon is a mute." CR>)
+	       (<HOSTILE-VERB?>
+		<TELL
+"In the end, you can't actually bring yourself to do it." CR>)>>
+
+<OBJECT VAN-NEKK
+	(LOC MATES-CABIN)
+	(DESC "Baccus van Nekk")
+	(SYNONYM BACCUS NEKK)
+	(ADJECTIVE CHIEF MERCHANT BACCUS VAN)
+	(FLAGS PERSON DUTCHBIT NOABIT NOTHEBIT)
+	(ACTION VAN-NEKK-F)>
+
+<ROUTINE VAN-NEKK-F ("OPT" (RARG <>))
+	 <COND ;(<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<P? TELL-ME-ABOUT (APPLE ROPER)>
+		       <TELL
+"Van Nekk points angrily at Roper.  \"He took it, Pilot!  He said you
+were hoarding food!\"" CR>)
+		      (<P? (RAISE REPAIR LOWER) FORESAILS>
+		       <RFALSE>)
+		      (<SEND-HIM-OUT?>
+		       <SETG WINNER ,PLAYER>
+		       <PERFORM ,V?SEND ,VAN-NEKK ,ROOMS>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+G"The only responses are muttered curses in Dutch." CR>)>)
+	       (<RARG? <>>
+		<COND (<P? SEND VAN-NEKK>
+		       <TELL
+"\"I'd go, Pilot, but it's not my watch.  It's Vinck's watch, I think, and
+Ginsel's, and Maetsukker's, if I've not gone crazed.  He smiles wanly." CR>)>)>>
+
+<OBJECT CROOCQ
+	(LOC BELOW-DECKS)
+	(DESC "Croocq")
+	(SYNONYM CROOCQ BOY)
+	(ADJECTIVE MAXIMILIAN)
+	(FLAGS NDESCBIT PERSON DUTCHBIT NOABIT NOTHEBIT)
+	(ACTION CROOCQ-F)>
+
+<ROUTINE CROOCQ-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<P? TELL-ME-ABOUT (APPLE ROPER)>
+		       <TELL
+"Croocq says, \"I don't know anything about it, Pilot.\"" CR>)
+		      (<P? (RAISE REPAIR LOWER) FORESAILS>
+		       <RFALSE>)
+		      (<SEND-HIM-OUT?>
+		       <SETG WINNER ,PLAYER>
+		       <PERFORM ,V?SEND ,CROOCQ ,ROOMS>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+G"The only responses are muttered curses in Dutch." CR>)>)
+	       (<VERB? TELL>
+		<COND (<OR <IN? ,CROOCQ ,CAULDRON>
+			   <IN? ,CROOCQ ,VILLAGE-SQUARE>>
+		       <TELL
+"He's in no condition to respond." CR>
+		       <END-QUOTE>
+		       <RFATAL>)>)
+	       (<P? SEND CROOCQ>
+		<TELL
+"He's too far gone to go on deck; almost too tired to stand." CR>)>>
+
+<ROUTINE SEND-HIM-OUT? ()
+	 <COND (<SCENE? ,S-ERASMUS>
+		<OR <VERB? REPLACE>
+		    <P? FOLLOW ME>
+		    <P? WALK (P?UP P?OUT)>
+		    <P? (STEP-ON TAKE BOARD WALK-TO CLIMB-ON)
+			(DECK BRIDGE-OF-ERASMUS ON-DECK)>>)>>
+
+<END-SEGMENT>
diff --git a/globals.zil b/globals.zil
new file mode 100644
index 0000000..a3d240c
--- /dev/null
+++ b/globals.zil
@@ -0,0 +1,1515 @@
+"GLOBALS for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc.  All Rights Reserved."
+
+<FILE-FLAGS SENTENCE-ENDS?>
+
+<BEGIN-SEGMENT 0>
+
+<INCLUDE "PDEFS">
+
+"global objects and associated routines"
+
+<OBJECT GLOBAL-OBJECTS
+	(FLAGS AN
+	       BODY-PART
+	       CONTBIT
+	       DEAD
+	       DONT-ALL
+	       DONT-IT
+	       DOORBIT
+	       DUTCHBIT
+	       ENGLISHBIT
+	       FEMALE
+	       FOODBIT
+	       FURNITURE
+	       INVISIBLE
+	       JAPANESEBIT
+	       LIGHTBIT
+	       LOCKABLE
+	       LOCKED
+	       NDESCBIT
+	       NOABIT
+	       NOTHEBIT
+	       ONBIT
+	       OPENABLE
+	       OPENBIT
+	       OUTSIDE
+	       PERSON
+	       PLURAL
+	       PORTUGUESEBIT
+	       READBIT
+	       RLANDBIT
+	       RMUNGBIT
+	       SCOREBIT
+	       SEARCHBIT
+	       SITTING
+	       SPANISHBIT
+	       SURFACEBIT
+	       TAKEBIT
+	       THE
+	       TOOLBIT
+	       TOUCHBIT
+	       TRANSBIT
+	       TRYTAKEBIT
+	       VEHBIT
+	       WEAPONBIT
+	       WEARABLE
+	       WEARBIT)>
+
+<OBJECT LOCAL-GLOBALS
+	(LOC GLOBAL-OBJECTS)
+	(SYNONYM ZZMGCK) ;"Yes, this needs to exist."
+	(DESCFCN 0)
+        (CONTFCN 0)
+	(GLOBAL GLOBAL-OBJECTS)
+	(FDESC "F")
+	(LDESC "F")
+	(THINGS 0)
+	(COUNT 0)
+	(SIZE 0)
+	(TEXT "")
+	(VALUE 0)
+	(CAPACITY 0)>
+
+<OBJECT ROOMS
+	(IN TO ROOMS)>
+
+<OBJECT INTDIR
+	(LOC GLOBAL-OBJECTS)
+	(SYNONYM ;ADJECTIVE
+	 NORTH EAST WEST SOUTH
+	 FORE AFT PORT STARBOARD)
+	(DESC "direction")
+	(GENERIC GENERIC-NORTH-F)
+	;(ACTION INTDIR-F)>
+
+;<ROUTINE INTDIR-F ()
+	<SETG P-DIRECTION <WORD-DIR-ID <NP-NAME <GET-NP>>>>
+	<RFALSE>>
+
+<GLOBAL P-DIRECTION <>>
+
+<ROUTINE TELL-DIRECTION (DIR)
+	 <COND (<EQUAL? .DIR ,P?SOUTH>
+		<TELL "south">)
+	       (<EQUAL? .DIR ,P?NORTH>
+		<TELL "north">)
+	       (<EQUAL? .DIR ,P?WEST>
+		<TELL "west">)
+	       (<EQUAL? .DIR ,P?EAST>
+		<TELL "east">)
+	       (<EQUAL? .DIR ,P?SW>
+		<TELL "southwest">)
+	       (<EQUAL? .DIR ,P?NW>
+		<TELL "northwest">)
+	       (<EQUAL? .DIR ,P?SE>
+		<TELL "southeast">)
+	       (<EQUAL? .DIR ,P?NE>
+		<TELL "northeast">)
+	       (<EQUAL? .DIR ,P?PORT>
+		<TELL "port">)
+	       (<EQUAL? .DIR ,P?STARBOARD>
+		<TELL "starboard">)
+	       (<EQUAL? .DIR ,P?FORE>
+		<TELL "straight">)>>
+
+<SYNONYM NORTH N>
+<SYNONYM SOUTH S>
+<SYNONYM EAST E>
+<SYNONYM WEST W>
+<SYNONYM DOWN D>
+<SYNONYM UP U ALOFT>
+<SYNONYM NE NORTHEAST>
+<SYNONYM NW NORTHWEST>
+<SYNONYM SE SOUTHEAST>
+<SYNONYM SW SOUTHWEST>
+<SYNONYM IN AHEAD>
+<SYNONYM FORE FOREWARD FORWARD FORARD STRAIGHT>
+<DIR-SYNONYM FORE F>
+<SYNONYM STARBOARD SB RIGHT>
+<SYNONYM PORT P LEFT>
+
+<GLOBAL HERE:OBJECT <>>
+
+<GLOBAL LIT <>>
+
+<GLOBAL MOVES 0>
+<GLOBAL OMOVES 0>
+<GLOBAL SCORE 0>
+<GLOBAL OSCORE 0>
+
+<CONSTANT DIR-BIT 1>
+<CONSTANT DIR-DIR 2>
+<CONSTANT DIR-NAME 3>
+
+<GLOBAL P-DIRECTION <>>
+
+<OBJECT INTNUM
+	(LOC GLOBAL-OBJECTS)
+	(DESC "number")
+	(SYNONYM INT.NUM DEGREES NORTH)
+	(ADJECTIVE INT.NUM DEGREES NUMBER)
+	(GENERIC GENERIC-NORTH-F)
+	(ACTION INTNUM-F)>
+
+<ROUTINE GENERIC-NORTH-F (R F)
+	 ,INTDIR>
+
+<ROUTINE INTNUM-F ()
+	 <COND (<PRSO? ,INTNUM>
+		<COND (<VERB? PUSH>
+		       <TELL G "There's no number ""to push here." CR>)>)>>
+
+<OBJECT THIS
+	(LOC GLOBAL-OBJECTS)
+	(SYNONYM THIS THAT)
+	(DESC "this")
+	(FLAGS AN NOABIT NOTHEBIT NDESCBIT TOUCHBIT)>
+
+<OBJECT IT
+	(LOC GLOBAL-OBJECTS)
+	(SYNONYM IT ;THEM ;THEY OBJECT)
+	(DESC "it")
+	(FLAGS AN NOABIT NOTHEBIT NDESCBIT TOUCHBIT)>
+
+<OBJECT THEM
+	(LOC GLOBAL-OBJECTS)
+	(SYNONYM ;IT THEM THEY OBJECTS)
+	(DESC "them")
+	(FLAGS ;AN NOABIT NOTHEBIT NDESCBIT TOUCHBIT)>
+
+<OBJECT HIM
+	(LOC GLOBAL-OBJECTS)
+	(SYNONYM HIM HE)
+	(DESC "him")
+	(FLAGS PERSON NOABIT NOTHEBIT NDESCBIT TOUCHBIT)
+	(ACTION HIM-F)>
+
+<ROUTINE HIM-F ("OPT" (RARG <>) (O ,HIM) (H ,P-HIM-OBJECT))
+	 <COND (.RARG <RFALSE>)
+	       (.H
+		<COND (<AND <OR <VERB? TELL>
+				<P? (TELL-ABOUT ASK-ABOUT) .O>>
+			    <NOT <ACCESSIBLE? .H>>>
+		       <TELL CTHE .H " isn't here." CR>
+		       <COND (<VERB? TELL> <END-QUOTE> <RFATAL>)>)
+		      (ELSE
+		       <COND (<EQUAL? ,WINNER .O> <SETG WINNER .H>)>
+		       <COND (<EQUAL? ,PRSS .O> <SETG PRSS .H>)>
+		       <REDIRECT .O .H>
+		       <RTRUE>)>)
+	       (ELSE
+		<MORE-SPECIFIC>
+		<COND (<VERB? TELL> <END-QUOTE> <RFATAL>)>)>>
+
+<OBJECT HER
+	(LOC GLOBAL-OBJECTS)
+	(SYNONYM HER SHE)
+	(DESC "her")
+	(FLAGS FEMALE PERSON NOABIT NOTHEBIT NDESCBIT TOUCHBIT)
+	(ACTION HER-F)>
+
+<ROUTINE HER-F ("OPT" (RARG <>))
+	 <HIM-F .RARG ,HER ,P-HER-OBJECT>>
+
+<OBJECT LIGHT
+	(LOC GLOBAL-OBJECTS)
+	(DESC "light")
+	(SYNONYM LIGHT LIGHTS)
+        (ACTION LIGHT-F)>
+
+<ROUTINE LIGHT-F ()
+	 <COND (<VERB? THROUGH>
+		<DO-WALK ,P?OUT>)
+	       (<VERB? LAMP-ON>
+		<COND (,LIT
+		       <TELL ,IT-IS-ALREADY "light" ,PERIOD>)
+		      (T
+		       <TELL
+"You need a light source!" CR>)>)
+	       (<VERB? LAMP-OFF>
+		<TELL ,WASTE-OF-TIME>)>>
+
+<OBJECT LG-HOLE
+	(LOC LOCAL-GLOBALS)
+	(FLAGS NDESCBIT TOUCHBIT)
+	(DESC "hole")
+	(SYNONYM HOLE)
+	(ADJECTIVE MUDDY)
+	(ACTION LG-HOLE-F)>
+
+<ROUTINE LG-HOLE-F ()
+	 <COND (<P? DIG LG-HOLE *>
+		<PERFORM ,V?DIG ,PRSI>
+		<RTRUE>)
+	       (<VERB? REACH-IN>
+		<TELL ,YOU-FIND-NOTHING " of interest." CR>)>>
+
+<OBJECT CEILING
+	(LOC GLOBAL-OBJECTS)
+	(FLAGS NDESCBIT TOUCHBIT)
+	(DESC "ceiling")
+	(SYNONYM CEILING ROOF)
+	(ACTION CEILING-F)>
+
+<ROUTINE CEILING-F ()
+	 <COND (<VERB? LOOK-UNDER>
+		<NEW-VERB ,V?LOOK>
+		<RTRUE>)>>
+
+<OBJECT AIR
+	(LOC GLOBAL-OBJECTS)
+	(DESC "air")
+	(SYNONYM AIR COLD)
+	(FLAGS AN NOABIT)>
+
+<CONSTANT BODY-PARTS-OWNERS
+	<TABLE (LENGTH PURE)
+		BLACKTHORNE YABU CHIMMOKO ETSU ACHIKO KIRITSUBO MARIKO
+		GRAY-CAPTAIN GUARDS LG-NINJA NINJA-LEADER NINJA
+		BUNTARO SAZUKO HIRO-MATSU TORANAGA GRAYS ISHIDO
+		TORANAGAS-GUARDS ALVITO OARSMEN RODRIGUES SEARCH-PARTY
+		SEBASTIO-HENCHMEN SEBASTIO OMI MURA ONNA SAMURAI-GUARDS
+		LOSING-SAMURAI OMI-SAMURAI CREWMEN LG-CREWMEN HENDRIK VINCK
+		MAETSUKKER GINSEL MATES SPILLBERGEN PIETERZOON ROPER
+		SONK SALAMON VAN-NEKK CROOCQ>>
+
+<OBJECT FEET
+	(LOC GLOBAL-OBJECTS)
+	(SYNONYM FEET FOOT)
+	(OWNER BODY-PARTS-OWNERS)
+	(DESC ;"your " "feet")
+	(FLAGS NDESCBIT BODY-PART TOOLBIT TOUCHBIT NOABIT ;NOTHEBIT)>
+
+<OBJECT HANDS
+	(LOC GLOBAL-OBJECTS)
+	(SYNONYM HANDS HAND)
+	(ADJECTIVE BARE ;MY)
+	(OWNER BODY-PARTS-OWNERS)
+	(DESC ;"your " "hand")
+	(FLAGS NDESCBIT BODY-PART TOOLBIT TOUCHBIT NOABIT ;NOTHEBIT)>
+
+<OBJECT HEAD
+	(LOC GLOBAL-OBJECTS)
+	(OWNER BODY-PARTS-OWNERS)
+	(DESC ;"your " "head")
+	(SYNONYM HEAD FACE)
+	(FLAGS NOABIT BODY-PART ;NOTHEBIT)>
+
+<OBJECT COJONES
+	(LOC GLOBAL-OBJECTS)
+	(OWNER BODY-PARTS-OWNERS)
+	(DESC ;"your " "balls")
+	(SYNONYM COJONES TESTICLES BALLS NUTS)
+	(FLAGS BODY-PART NOABIT PLURAL ;NOTHEBIT)
+	(ACTION COJONES-F)>
+
+<ROUTINE COJONES-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<OR <AND <HELD? ,CLOTHES>
+				<FSET? ,CLOTHES ,WEARBIT>>
+			   <AND <HELD? ,KIMONO>
+				<FSET? ,KIMONO ,WEARBIT>>>
+		       <TELL
+"What an embarrassing idea!" CR>)
+		      (<HERE? ,BATH-HOUSE>
+		       <TELL
+"There are more than enough people doing that already.  The thought
+enough makes you blush." CR>)
+		      (ELSE
+		       <TELL
+"They're still there." CR>)>)
+	       (<VERB? WALK-TO>
+		<PERFORM ,V?ACT ,CRAZY>
+		<RTRUE>)
+	       (<VERB? WHAT>
+		<TELL
+"As your mother might have said, \"They are what a bull has that
+a steer hasn't.\"" CR>)>>
+
+<OBJECT STOMACH
+	(LOC GLOBAL-OBJECTS)
+	(OWNER BODY-PARTS-OWNERS)
+	(DESC ;"your " "stomach")
+	(SYNONYM STOMACH BELLY)
+	(FLAGS BODY-PART NOABIT ;NOTHEBIT)>
+
+<OBJECT FINGERS
+	(LOC GLOBAL-OBJECTS)
+	(OWNER BODY-PARTS-OWNERS)
+	(DESC ;"your " "fingers")
+	(SYNONYM FINGERS)
+	(FLAGS BODY-PART NOABIT ;NOTHEBIT)>
+
+<OBJECT MOUTH
+	(LOC GLOBAL-OBJECTS)
+	(OWNER BODY-PARTS-OWNERS)
+	(DESC ;"your " "mouth")
+	(SYNONYM MOUTH)
+	(FLAGS BODY-PART NOABIT ;NOTHEBIT)
+	(ACTION MOUTH-F)>
+
+<ROUTINE MOUTH-F ()
+	 <COND (<VERB? OPEN CLOSE>
+		<TELL "They say a closed mouth gathers no foot." CR>)>>
+
+<OBJECT EYES
+	(LOC GLOBAL-OBJECTS)
+	(OWNER BODY-PARTS-OWNERS)
+	(DESC ;"your " "eyes")
+	(SYNONYM EYE EYES)
+	(FLAGS BODY-PART NOABIT ;NOTHEBIT)
+	(ACTION EYES-F)>
+
+<ROUTINE EYES-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL "You have no mirror." CR>)
+	       (<VERB? OPEN>
+		<TELL "They are." CR>)
+	       (<VERB? CLOSE>
+		<TELL "That won't help." CR>)
+	       ;(<NOT ,LIT>
+		<TELL ,TOO-DARK>)>>
+
+<GLOBAL PLAYER <>>
+
+<ROUTINE LIST-PEOPLE (TEST SI PL "OPT" (RM ,HERE) (DESC <>))
+	 <REPEAT ((F <FIRST? .RM>) (LAST <>) (1ST? T))
+		 <COND (<NOT .F>
+			<COND (.LAST
+			       <COND (.1ST?
+				      <TELL "The only " .SI " ">
+				      <COND (<EQUAL? .RM ,HERE> <TELL "here">)
+					    (ELSE <TELL .DESC>)>
+				      <TELL " is ">)
+				     (ELSE
+				      <TELL " and ">)>
+			       <TELL D .LAST ".">)
+			      (ELSE
+			       <TELL G"There aren't any " .PL " ">
+			       <COND (<EQUAL? .RM ,HERE> <TELL "here">)
+				     (ELSE <TELL .DESC>)>
+			       <TELL ".">)>
+			<RETURN>)
+		       (<APPLY .TEST .F>
+			<COND (.LAST
+			       <COND (.1ST?
+				      <SET 1ST? <>>
+				      <TELL
+				       "The " .PL " ">
+				      <COND (<EQUAL? .RM ,HERE> <TELL "here">)
+					    (ELSE <TELL .DESC>)>
+				      <TELL " are">)>
+			       <TELL " " D .LAST ",">)>
+			<SET LAST .F>)>
+		 <SET F <NEXT? .F>>>>
+
+<OBJECT LG-MEN
+	(LOC LOCAL-GLOBALS)
+	(SYNONYM MAN MEN)
+	(DESC "men")
+	(FLAGS PERSON TOUCHBIT NOABIT PLURAL)
+	(ACTION LG-MEN-F)>
+
+<ROUTINE LG-MEN-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<TELL G"There is no response." CR>)
+	       (<RARG? <>>
+		<COND (<VERB? EXAMINE>
+		       <LIST-PEOPLE ,MAN? "man" "men">)
+		      (<OR <VERB? TELL>
+			   <P? TELL-ABOUT LG-MEN>>
+		       <TELL
+G"You'll have to address an individual to get a response." CR>
+		       <END-QUOTE>
+		       <RFATAL>)
+		      (<HOSTILE-VERB?>
+		       <MORE-SPECIFIC>)>)>>
+
+<ROUTINE MAN? (OBJ)
+	 <AND <NOT <EQUAL? .OBJ ,LG-MEN>>
+	      <FSET? .OBJ ,PERSON>
+	      <NOT <FSET? .OBJ ,FEMALE>>>>
+
+<OBJECT LG-WOMEN
+	(SCENE S-NINJA)
+	(LOC LOCAL-GLOBALS)
+	(SYNONYM WOMAN WOMEN)
+	(DESC "women")
+	(FLAGS PERSON FEMALE TOUCHBIT NOABIT PLURAL)
+	(ACTION LG-WOMEN-F)>
+
+<ROUTINE LG-WOMEN-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<TELL G"There is no response." CR>)
+	       (<RARG? <>>
+		<COND (<VERB? EXAMINE>
+		       <LIST-PEOPLE ,WOMAN? "woman" "women">)
+		      (<OR <VERB? TELL>
+			   <P? TELL-ABOUT LG-WOMEN>>
+		       <TELL
+G"You'll have to address an individual to get a response." CR>
+		       <END-QUOTE>
+		       <RFATAL>)
+		      (<HOSTILE-VERB?>
+		       <MORE-SPECIFIC>)>)>>
+
+<ROUTINE WOMAN? (OBJ)
+	 <AND <NOT <EQUAL? .OBJ ,LG-WOMEN>>
+	      <FSET? .OBJ ,PERSON>
+	      <FSET? .OBJ ,FEMALE>>>
+
+<OBJECT YOU
+	(LOC GLOBAL-OBJECTS)
+	(SYNONYM YOU YOURSELF)
+	(DESC "myself")
+	(FLAGS PERSON TOUCHBIT NOABIT NOTHEBIT)
+	(ACTION YOU-F)>
+
+<ROUTINE YOU-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<TELL G"There is no response." CR>)
+	       (<VERB? WHO>
+		<COND (<TRY-QCONTEXT?>
+		       <RTRUE>)
+		      (ELSE
+		       <MORE-SPECIFIC>)>)
+	       (<WINNER? ,PLAYER>
+		<REDIRECT ,YOU ,ME>)>>
+
+;<ROUTINE MORE-SPECIFIC ()
+	 <TELL ,YOU-HAVE-TO "be more specific." CR>>
+
+<OBJECT ME
+	(LOC GLOBAL-OBJECTS)
+	(SYNONYM ME MYSELF SELF I WE US)
+	(DESC "yourself")
+	(FLAGS PERSON TOUCHBIT NOABIT NOTHEBIT)
+	(ACTION ME-F)>
+
+<ROUTINE MENTAL-COLLAPSE ()
+	 <TELL
+"Talking to yourself is a sign of impending mental collapse." CR>>
+
+<ROUTINE ME-F ("OPT" (RARG <>) "AUX" OLIT)
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<VERB? HOW>
+		<PERFORM ,V?DIAGNOSE>
+		<RTRUE>)
+	       (<VERB? WEAR>
+		<COND (<ACCESSIBLE? ,CLOTHES>
+		       <PERFORM ,V?WEAR ,CLOTHES>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL "You can't see any clothes here." CR>)>)
+	       (<P? CROSS ME>
+		<PERFORM ,V?MAKE ,SIGN-OF-CROSS>
+		<RTRUE>)
+	       (<VERB? BE? BE WHERE HOW>
+		<COND (<AND <VERB? WHERE>
+			    <TRY-QCONTEXT?>>
+		       <RTRUE>)
+		      (ELSE
+		       <REDIRECT ,ME ,PLAYER>
+		       <RTRUE>)>)
+	       (<VERB? WHO WHAT>
+		<TELL
+"You are John Blackthorne, Pilot-Major of the "I"Erasmus"", a Dutch
+merchanter out of Rotterdam.  You are an Englishman chosen as Pilot
+because you speak Dutch, courtesy of your Dutch mother.  You also
+speak Spanish, Portuguese, and Latin." CR>)
+	       (<VERB? FIND ;WHERE>
+		<TELL "You are ">
+		<COND (<SCENE? ,S-ERASMUS>
+		       <TELL
+"aboard the "I"Erasmus""." CR>)
+		      (<SCENE? ,S-ANJIRO ,S-YABU ,S-PIT
+			       ,S-RODRIGUES>
+		       <TELL
+"in the Japanese fishing village of Anjiro." CR>)
+		      (<SCENE? ,S-VOYAGE>
+		       <TELL
+"on your way to Osaka, at the command of Lord Toranaga." CR>)
+		      (<SCENE? ,S-TORANAGA>
+		       <TELL
+"in Lord Toranaga's court in Osaka Castle." CR>)
+		      (<SCENE? ,S-PRISON>
+		       <TELL
+"in the prison of Osaka Castle." CR>)
+		      (<SCENE? ,S-ESCAPE>
+		       <TELL
+"in the great city and castle of Osaka." CR>)
+		      (<SCENE? ,S-OCHIBA ,S-DEPARTURE ,S-SEPPUKU
+			       ,S-NINJA>
+		       <TELL "in Osaka Castle." CR>)
+		      (ELSE
+		       <TELL "in Japan." CR>)>)
+	       (<P? EXAMINE ,ME>
+		<COND (<OR <FSET? ,KIMONO ,WEARBIT>
+			   <FSET? ,SOCKS ,WEARBIT>
+			   <FSET? ,SANDALS ,WEARBIT>
+			   <FSET? ,SLIPPERS ,WEARBIT>>
+		       <SETG D-BIT ,WEARBIT>
+		       <DESCRIBE-SENT ,WINNER>
+		       <SETG D-BIT <>>
+		       <RTRUE>)
+		      (<AND <HELD? ,CLOTHES> <FSET? ,CLOTHES ,WEARBIT>>
+		       <TELL "You are dressed in ">
+		       <COND (<SCENE? ,S-ERASMUS>
+			      <TELL "worn, dirty clothes">
+			      <COND (<AND <HELD? ,BOOTS>
+					  <FSET? ,BOOTS ,WEARBIT>>
+				     <TELL " and salt-stained boots">)>
+			      <TELL "." CR>)
+			     (ELSE
+			      <TELL
+"your old clothes, which have been cleaned and mended">
+			      <COND (<AND <HELD? ,BOOTS>
+					  <FSET? ,BOOTS ,WEARBIT>>
+				     <TELL ", and your newly polished boots">)>
+			      <TELL "." CR>)>)
+		      (<AND <HELD? ,BOOTS> <FSET? ,BOOTS ,WEARBIT>>
+		       <TELL
+"You are wearing your boots." CR>)
+		      (ELSE
+		       <TELL
+"You are naked." CR>)>)
+	       (<VERB? SMELL>
+		<COND (<SCENE? ,S-ERASMUS>
+		       <TELL
+"Your smell like anyone who's been at sea for six months would smell." CR>)
+		      (ELSE
+		       <TELL
+"You smell all right, considering." CR>)>)
+	       (<AND <P? SHOW * ME>
+		     <EQUAL? ,P-PRSA-WORD ,W?READ>>
+		<PERFORM ,V?READ ,PRSO>
+		<RTRUE>)
+	       (<VERB? EAT>
+		<TELL
+"This is the sort of behavior that most Japanese would find extremely
+uncivilized." CR>)
+	       (<VERB? HELP>
+		<TELL
+"It is said that the Lord helps those who help themselves." CR>)
+	       (<VERB? TELL>
+		<MENTAL-COLLAPSE>
+		<END-QUOTE>)
+	       (<VERB? LISTEN>
+		<TELL "Yes?" CR>)
+	       (<VERB? WAKE>
+		<TELL ,YOU-ARE>
+		<TELL ,PERIOD>)
+	       (<AND <RARG? WINNER>
+		     <VERB? GIVE>>
+		<COND (<PRSO? ,ME>
+		       <TELL ,WASTE-OF-TIME>)
+		      (<PRSI? ,ME>
+		       <COND (<IN? ,PRSO ,PLAYER>
+			      <PRE-TAKE>)
+			     (T
+			      <PERFORM ,V?TAKE ,PRSO>
+			      <RTRUE>)>)>)
+	       (<VERB? MOVE>
+		<V-WALK-AROUND>)
+	       (<VERB? SEARCH>
+		<V-INVENTORY>
+		<RTRUE>)
+	       (<OR <P? (TAKE ATTACK HIT SWING BOW) ME>
+		    <VERB? ENTER THROUGH TAKE-OFF HOLD>
+		    <P? THROW * ME>>
+		<TELL
+G"You are beginning to give way to madness, I see." CR>)
+	       (<VERB? KILL MUNG BURY SHOOT>
+		<TELL
+"Death is not to be entered into so lightly as that.  Death is a matter
+of great seriousness." CR>)
+	       (<VERB? FOLLOW>
+		<TELL
+"You're getting ahead of yourself." CR>)
+	       (<P? (THROW THROW-OFF DROP) ME>
+		<COND (,PRSI <PERFORM ,V?BOARD ,PRSI> <RTRUE>)
+		      (ELSE <TELL
+G"You are beginning to give way to madness, I see." CR>)>)>>
+
+<OBJECT GLOBAL-HERE
+	(LOC GLOBAL-OBJECTS)
+	(DESC "here")
+	(SYNONYM ROOM CHAMBER PLACE BASEMENT HERE AREA)
+	(ADJECTIVE AREA)
+	(FLAGS NOABIT NOTHEBIT)
+	(ACTION GLOBAL-HERE-F)>
+
+<ROUTINE GLOBAL-HERE-F ()
+	 <COND (<VERB? LOOK EXAMINE LOOK-INSIDE>
+		<V-LOOK>
+		<RTRUE>)
+	       (<P? PUT * ,GLOBAL-HERE>
+		<PERFORM ,V?DROP ,PRSO>
+		<RTRUE>)
+	       (<VERB? WHERE FIND>
+		<PERFORM ,V?FIND ,ME>
+		<RTRUE>)
+	       (<AND <VERB? THROUGH WALK-TO>
+		     <NOT <PAST-TENSE?>>>
+		<V-WALK-AROUND>)
+	       (<VERB? OPEN CLOSE>
+		<TELL "You should try a door instead." CR>)
+	       (<VERB? DROP LEAVE EXIT>
+		<DO-WALK ,P?OUT>)
+	       (<VERB? WALK-AROUND>
+		<TELL
+"Walking around the room reveals nothing new.  To move elsewhere, just type
+the desired direction." CR>)
+	       (<VERB? LAMP-ON>
+		<NEW-PRSO ,LIGHT>
+		<RTRUE>)
+	       (<VERB? SEARCH>
+		<TELL
+"You don't find anything." CR>)
+	       (<VERB? WAVE>
+		<TELL-YUKS>)>>
+
+<SETG C-NORTH 1>
+<SETG C-EAST 2>
+<SETG C-WEST 4>
+<SETG C-SOUTH 8>
+<SETG C-NE 16>
+<SETG C-NW 32>
+<SETG C-SE 64>
+<SETG C-SW 128>
+
+<CONSTANT C-NORTH 1>
+<CONSTANT C-EAST 2>
+<CONSTANT C-WEST 4>
+<CONSTANT C-SOUTH 8>
+<CONSTANT C-NE 16>
+<CONSTANT C-NW 32>
+<CONSTANT C-SE 64>
+<CONSTANT C-SW 128>
+
+<OBJECT NORTH-WALL
+	(LOC GLOBAL-OBJECTS)
+	(DESC "north wall")
+	(SYNONYM WALL)
+	(ADJECTIVE NORTH FORE)
+	(GENERIC GENERIC-WALL-F)
+	(ACTION WALL-F)>
+
+<OBJECT EAST-WALL
+	(LOC GLOBAL-OBJECTS)
+	(DESC "east wall")
+	(SYNONYM WALL)
+	(ADJECTIVE EAST STARBOARD)
+	(FLAGS AN)
+	(GENERIC GENERIC-WALL-F)
+	(ACTION WALL-F)>
+
+<OBJECT WEST-WALL
+	(LOC GLOBAL-OBJECTS)
+	(DESC "west wall")
+	(SYNONYM WALL)
+	(ADJECTIVE WEST PORT)
+	(GENERIC GENERIC-WALL-F)
+	(ACTION WALL-F)>
+
+<OBJECT SOUTH-WALL
+	(LOC GLOBAL-OBJECTS)
+	(DESC "south wall")
+	(SYNONYM WALL)
+	(ADJECTIVE SOUTH AFT)
+	(GENERIC GENERIC-WALL-F)
+	(ACTION WALL-F)>
+
+<OBJECT WALL
+	(LOC GLOBAL-OBJECTS)
+	(DESC "wall")
+	(SYNONYM WALL WALLS)
+	(GENERIC GENERIC-WALL-F)
+	(ACTION WALL-F)>
+
+<ROUTINE GENERIC-WALL-F (R F)
+	 ,WALL>
+
+<ROUTINE WALL-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL ,IT-LOOKS-LIKE "a wall." CR>)
+	       (<VERB? LOWER MUNG>
+		<TELL ,YOU-CANT "pull down a wall that easily." CR>)>>
+
+<OBJECT DIRT
+	(LOC GLOBAL-OBJECTS)
+	(DESC "dirt")
+	(SYNONYM RUBBLE DEBRIS DUST DIRT)
+	(FLAGS NOABIT)>
+
+<OBJECT GROUND
+	(LOC GLOBAL-OBJECTS)
+	(SYNONYM FLOOR GROUND FIELD EARTH DIRT)
+	(ADJECTIVE STONE SANDY TINY LEVEL)
+	(DESC "ground")
+	(FLAGS THE)
+	(ACTION GROUND-F)>
+
+<ROUTINE GROUND-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND ;(<FSET? ,HERE ,RAIRBIT>
+		       <TELL
+"It's a long way down." CR>)
+		      (ELSE
+		       <TELL
+"You see nothing of interest." CR>)>)
+	       (<P? PUT * ,GROUND>
+		<PERFORM ,V?BURY ,PRSO>
+		<RTRUE>)
+	       (<VERB? CLIMB-UP CLIMB-ON CLIMB-FOO BOARD HIT>
+		<TELL ,WASTE-OF-TIME>)
+	       (<VERB? LOOK-UNDER>
+		<TELL
+"You can't look under the ground, it's solid!" CR>)>>
+
+<OBJECT CORRIDOR
+	(LOC GLOBAL-OBJECTS)
+	(DESC "passage")
+	(SYNONYM PASSAGE CORRIDOR EXIT TUNNEL)
+	(ADJECTIVE LONG DARK STEAM)
+	(ACTION CORRIDOR-F)>
+
+<ROUTINE CORRIDOR-F ()
+	 <COND (<VERB? THROUGH WALK-TO>
+		<V-WALK-AROUND>)>>
+
+;<OBJECT LOCAL-WATER
+	(SYNONYM WATER)
+	(ADJECTIVE FRESH SALT SEA)
+	(DESC "water")
+	(FLAGS NOABIT)
+	(ACTION WATER-F)>
+
+;<OBJECT WATER
+	(LOC LOCAL-GLOBALS)
+	(SYNONYM WATER)
+	(DESC "water")
+	(FLAGS NDESCBIT NOABIT)
+	(ACTION WATER-F)>
+
+;<ROUTINE WATER-F ()
+	 <COND (<P? (POUR THROW) ,LOCAL-WATER>
+		<COND (<AND <LOC ,PRSO>
+			    <IN? <LOC ,PRSO> ,WINNER>>
+		       <PERFORM ,V?POUR <LOC ,PRSO>>
+		       <RTRUE>)
+		      (ELSE
+		       <DONT-HAVE-THAT>)>)
+	       (<VERB? EAT DRINK DRINK-FROM>
+	        <COND (<PRSO? ,LOCAL-WATER>
+		       <COND (<IN? <LOC ,PRSO> ,WINNER>
+			      <COND (<FSET? <LOC ,PRSO> ,OPENBIT>
+				     <REMOVE ,PRSO>)
+				    (ELSE
+				     <TELL-OPEN-CLOSED <LOC ,PRSO>>
+				     <RTRUE>)>)
+			     (<NOT <GLOBAL-IN? ,WATER ,HERE>>
+			      <TELL ,YOU-DONT-HAVE THE <LOC ,PRSO> ,PERIOD>
+			      <RTRUE>)>)>
+		<COND (<OR <AND <PRSO? ,LOCAL-WATER>
+				<FSET? ,PRSO ,RMUNGBIT>>
+			   ;<AND <PRSO? ,WATER>
+				<HERE? ;"ROOM WITH WATER">>>
+		       <TELL
+"It's bitter and you spit it out immediately.">)
+		      (ELSE
+		       <TELL
+"That was refreshing, but you shouldn't drink untested water.">)>
+		<CRLF>)
+	       (<VERB? REACH-IN RUB>
+		<TELL
+"It's wet." CR>)
+	       (<VERB? LOOK-INSIDE LOOK-UNDER>
+		<MAKE-OUT>)
+	       ;(<VERB? THROUGH LEAP>
+		<COND (<FSET? ,HERE ,RWATERBIT>
+		       <TELL ,YOU-ARE ,PERIOD>)>)>>
+
+;<ROUTINE RANDOM-PSEUDO ()
+	 <COND (<VERB? EXAMINE LOOK-INSIDE LOOK-BEHIND>
+		<TELL G "You see nothing special about " "it." CR>)
+	       (<VERB? TAKE>
+		<YOU-CANT-X-THAT "take">)>>
+
+"sleep, hunger, etc."
+
+;<GLOBAL LAST-SLEPT 40> ;"move when you last woke-up, for purposed of V-TIME"
+
+<OBJECT GLOBAL-SLEEP
+	(LOC GLOBAL-OBJECTS)
+	(DESC "sleep")
+	(SYNONYM SLEEP NAP)
+	(FLAGS ABSTRACTBIT NOABIT NOTHEBIT)
+	(ACTION GLOBAL-SLEEP-F)>
+
+<ROUTINE GLOBAL-SLEEP-F ()
+	 <COND (<VERB? WALK-TO TAKE>
+                <NEW-VERB ,V?SLEEP>
+		<RTRUE>)
+	       (<VERB? FIND>
+		<TELL "Sleep anywhere." CR>)>>
+
+<OBJECT NOISE
+	(LOC GLOBAL-OBJECTS)
+	(DESC "noise")
+	(SYNONYM NOISE SOUND WHINING CRYING COMMOTION)>
+
+<OBJECT SIGN-OF-CROSS
+	(LOC GLOBAL-OBJECTS)
+	(OWNER SIGN-OF-CROSS)
+	(DESC "cross")
+	(SYNONYM SIGN CROSS)
+	(ADJECTIVE SIGN)
+	(FLAGS ABSTRACTBIT)
+	(ACTION SIGN-OF-CROSS-F)>
+
+<ROUTINE SIGN-OF-CROSS-F ()
+	 <COND (<VERB? MAKE> <RFALSE>)
+	       (ELSE <TELL "There is no cross here." CR>)>>
+
+<OBJECT SANE
+	(LOC GENERIC-OBJECTS)
+	(DESC "sane")
+	(SYNONYM NORMAL SANE ORDINARY QUIET)
+	(ADJECTIVE ACTING)
+	(FLAGS DONT-IT)>
+
+<OBJECT CRAZY
+	(LOC GENERIC-OBJECTS)
+	(DESC "insane")
+	(SYNONYM KAMI INSANE MADMAN MAD
+	         CRAZY BONKERS BERSERK
+		 POSSESSED SILLY STUPID)
+	(ADJECTIVE ACTING)
+	(GENERIC GENERIC-CRAZY-F)
+	(FLAGS DONT-IT SCOREBIT NOABIT NOTHEBIT)>
+
+<OBJECT TRAITOR
+	(LOC GENERIC-OBJECTS)
+	(DESC "traitor")
+	(SYNONYM TRAITOR BETRAYER)
+	(FLAGS SCOREBIT)>
+
+<OBJECT STRAIT-OF-MAGELLAN
+	(LOC GENERIC-OBJECTS)
+	(OWNER STRAIT-OF-MAGELLAN)
+	(DESC "Magellan's Pass")
+	(SYNONYM MAGELLAN PASS STRAIT STRAITS)
+	(FLAGS NOABIT NOTHEBIT SCOREBIT)>
+
+<OBJECT PACIFIC
+	(LOC GENERIC-OBJECTS)
+	(DESC "Pacific Ocean")
+	(SYNONYM ATLANTIC PACIFIC OCEAN)
+	(ADJECTIVE ATLANTIC PACIFIC)
+	(FLAGS NOABIT NOTHEBIT)>
+
+<OBJECT PORTUGAL
+	(LOC GLOBAL-OBJECTS)
+	(DESC "Portugal")
+	(SYNONYM PORTUGAL)
+	(FLAGS ABSTRACTBIT NOABIT NOTHEBIT)>
+
+<OBJECT PORTUGUESE
+	(LOC GLOBAL-OBJECTS)
+	(DESC "Portuguese")
+	(SYNONYM PORTUGUESE)
+	(ADJECTIVE PORTUGUESE)
+	(FLAGS NOABIT NOTHEBIT)
+	(ACTION PORTUGUESE-F)>
+
+<ROUTINE PORTUGUESE-F ()
+	 <COND (<OR <P? (SPEAK LEARN SAY) PORTUGUESE>
+		    <P? TEACH * PORTUGUESE>
+		    <P? ASK-ABOUT * PORTUGUESE>>
+		<RFALSE>)
+	       (<VERB? BE BE?> <RFALSE>)
+	       (ELSE
+		<FIND-NATIONALITY ,PORTUGUESE ,PORTUGUESEBIT>)>>
+
+<ROUTINE PORTUGUESE? () 
+	 <OR <PRSI? PORTUGUESE>
+	     <ADJ? ,W?PORTUGUESE>
+	     <PP? ,W?FROM ,PORTUGAL>>>
+
+<OBJECT SPAIN
+	(LOC GLOBAL-OBJECTS)
+	(DESC "Spain")
+	(SYNONYM SPAIN)
+	(FLAGS ABSTRACTBIT NOABIT NOTHEBIT)>
+
+<OBJECT SPANISH
+	(LOC GLOBAL-OBJECTS)
+	(DESC "Spanish")
+	(SYNONYM SPANISH)
+	(ADJECTIVE SPANISH)
+	(FLAGS NOABIT NOTHEBIT)
+	(ACTION SPANISH-F)>
+
+<ROUTINE SPANISH? ()
+	 <OR <PRSI? SPANISH>
+	     <ADJ? ,W?SPANISH>
+	     <PP? ,W?FROM ,SPAIN>>>
+
+<ROUTINE SPANISH-F ()
+	 <COND (<OR <P? (SPEAK LEARN SAY) SPANISH>
+		    <P? TEACH * SPANISH>
+		    <P? ASK-ABOUT * SPANISH>>
+		<RFALSE>)
+	       (<VERB? BE BE?> <RFALSE>)
+	       (ELSE
+		<FIND-NATIONALITY ,SPANISH ,SPANISHBIT>)>>
+
+<OBJECT ENGLAND
+	(LOC GLOBAL-OBJECTS)
+	(DESC "England")
+	(SYNONYM ENGLAND BRITAIN LONDON)
+	(ADJECTIVE ENGLISHMAN BRITON)
+	(FLAGS ABSTRACTBIT NOABIT NOTHEBIT)>
+
+<OBJECT ENGLISH
+	(LOC GLOBAL-OBJECTS)
+	(DESC "English")
+	(SYNONYM ENGLISH BRITISH)
+	(ADJECTIVE ENGLISH BRITISH)
+	(FLAGS NOABIT NOTHEBIT)
+	(ACTION ENGLISH-F)>
+
+<ROUTINE ENGLISH? ()
+	 <OR <PRSI? ENGLISH>
+	     <ADJ? ,W?ENGLISH ,W?BRITISH
+		   ,W?ENGLISHMAN ,W?BRITON>
+	     <PP? ,W?FROM ,ENGLAND>>>
+
+<ROUTINE ENGLISH-F ()
+	 <COND (<OR <P? (SPEAK LEARN SAY) ENGLISH>
+		    <P? TEACH * ENGLISH>
+		    <P? ASK-ABOUT * ENGLISH>>
+		<RFALSE>)
+	       (<VERB? BE BE?> <RFALSE>)
+	       (ELSE
+		<FIND-NATIONALITY ,ENGLISH ,ENGLISHBIT>)>>
+
+<OBJECT HOLLAND
+	(LOC GLOBAL-OBJECTS)
+	(DESC "Holland")
+	(SYNONYM HOLLAND NETHERLANDS ROTTERDAM AMSTERDAM)
+	(FLAGS ABSTRACTBIT NOABIT NOTHEBIT)>
+
+<OBJECT DUTCH
+	(LOC GLOBAL-OBJECTS)
+	(DESC "Dutch")
+	(SYNONYM DUTCH)
+	(ADJECTIVE DUTCH)
+	(FLAGS ABSTRACTBIT NOABIT NOTHEBIT)
+	(ACTION DUTCH-F)>
+
+<ROUTINE DUTCH? ()
+	 <OR <PRSI? DUTCH>
+	     <ADJ? ,W?DUTCH>
+	     <PP? ,W?FROM ,HOLLAND>>>
+
+<ROUTINE DUTCH-F ()
+	 <COND (<OR <P? (SPEAK LEARN SAY) DUTCH>
+		    <P? TEACH * DUTCH>
+		    <P? ASK-ABOUT * DUTCH>>
+		<RFALSE>)
+	       (<VERB? BE BE?> <RFALSE>)
+	       (ELSE
+		<FIND-NATIONALITY ,DUTCH ,DUTCHBIT>)>>
+
+<OBJECT HANASE-MASEN
+	(LOC GLOBAL-OBJECTS)
+	(DESC "hanase-masen")
+	(SYNONYM HANASE-MASEN)
+	(FLAGS ABSTRACTBIT)>
+
+<OBJECT JAPAN
+	(LOC GLOBAL-OBJECTS)
+	(DESC "Japan")
+	(SYNONYM JAPAN JAPANS NIPPON NIHON)
+	(FLAGS NOABIT NOTHEBIT)
+	(ACTION JAPAN-F)>
+
+<ROUTINE JAPAN-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<SCENE? S-ERASMUS>
+		       <TELL
+"You aren't even sure you are near Japan." CR>)
+		      (ELSE
+		       <TELL
+"What you see is a place unlike any you've seen before.  It's like another
+world." CR>)>)>>
+
+<OBJECT JAPANESE
+	(LOC GLOBAL-OBJECTS)
+	(DESC "Japanese")
+	(SYNONYM JAPANESE)
+	(ADJECTIVE JAPANESE)
+	(COUNT 0)
+	(FLAGS NOABIT NOTHEBIT SCOREBIT)
+	(ACTION JAPANESE-F)>
+
+<ROUTINE JAPANESE-F ()
+	 <COND (<OR <P? (SPEAK LEARN SAY) JAPANESE>
+		    <P? TEACH * JAPANESE>
+		    <P? ASK-ABOUT * JAPANESE>>
+		<RFALSE>)
+	       (<VERB? BE BE?> <RFALSE>)
+	       (ELSE
+		<FIND-NATIONALITY ,JAPANESE ,JAPANESEBIT>)>>
+
+<ROUTINE FIND-NATIONALITY (OBJ BIT "AUX" (F <FIRST? ,HERE>)
+			   (BEST <>) (PBEST <>))
+	 <REPEAT ()
+		 <COND (<NOT .F> <RETURN>)
+		       (<FSET? .F .BIT>
+			<COND (<FSET? .F ,PLURAL>
+			       <COND (<NOT .PBEST> <SET PBEST .F>)
+				     (ELSE <SET PBEST -1>)>)
+			      (ELSE
+			       <COND (<NOT .BEST> <SET BEST .F>)
+				     (ELSE <SET BEST -1>)>)>)>
+		 <SET F <NEXT? .F>>>
+	 <COND (<G? .PBEST 0>
+		<REDIRECT .OBJ .PBEST>
+		<RTRUE>)
+	       (<G? .BEST 0>
+		<REDIRECT .OBJ .BEST>
+		<RTRUE>)
+	       (<OR <L? .PBEST 0> <L? .BEST 0>>
+		<TELL
+,YOU-HAVE-TO G"be more specific about ""which " D .OBJ " you mean." CR>)
+	       (ELSE
+		<TELL
+"It's hard to tell whom you mean; please be more specific." CR>)>>
+
+<OBJECT LATIN
+	(LOC GLOBAL-OBJECTS)
+	(DESC "Latin")
+	(SYNONYM LATIN)
+	(FLAGS ABSTRACTBIT NOABIT NOTHEBIT)>
+
+<OBJECT GLOBAL-FOOD
+	(LOC GLOBAL-OBJECTS)
+	(DESC "food")
+	(SYNONYM FOOD)
+	(ADJECTIVE MORE)
+	(ACTION GLOBAL-FOOD-F)>
+
+<ROUTINE GLOBAL-FOOD-F ("AUX" F)
+	 <COND (<SET F
+		     <OR <FIND-IN ,HERE ,FOODBIT>
+			 <FIND-IN ,WINNER ,FOODBIT>>>
+		<REDIRECT ,GLOBAL-FOOD .F>
+		<RTRUE>)
+	       (<VERB? EXAMINE EAT>
+		<TELL
+"There's no food here." CR>)>>
+
+<OBJECT GLOBAL-WATER
+	(LOC GLOBAL-OBJECTS)
+	(DESC "water")
+	(SYNONYM WATER DRINK WATER)
+	(FLAGS NOABIT)
+	(ACTION GLOBAL-WATER-F)>
+
+<ROUTINE GLOBAL-WATER-F ()
+	 <COND (<VERB? EXAMINE DRINK>
+		<COND (<HERE? ,BATH-HOUSE>
+		       <PERFORM ,PRSA ,BATHTUB>
+		       <RTRUE>)
+		      (<HERE? ,YOKOSE-BATH-HOUSE>
+		       <PERFORM ,PRSA ,YOKOSE-BATHTUB>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"There's no water here." CR>)>)>>
+
+<OBJECT CHURCH
+	(LOC GENERIC-OBJECTS)
+	(OWNER GOD)
+	(DESC "Church")
+	(SYNONYM CHURCH SOCIETY)
+	(ADJECTIVE CHRISTIAN CATHOLIC)
+	(FLAGS ABSTRACTBIT)>
+
+<OBJECT JESUITS
+	(LOC GENERIC-OBJECTS)
+	(DESC "Jesuits")
+	(SYNONYM JESUIT JESUITS)>
+
+<OBJECT GOD
+	(LOC GENERIC-OBJECTS)
+	(DESC "God")
+	(SYNONYM GOD JESUS)
+	(FLAGS ABSTRACTBIT)>
+
+<OBJECT SATAN
+	(LOC GENERIC-OBJECTS)
+	(DESC "Satan")
+	(SYNONYM SATAN DEVIL)
+	(FLAGS ABSTRACTBIT)>
+
+<OBJECT BLACK-SHIP
+	(LOC GLOBAL-OBJECTS)
+	(SCENE S-PRISON S-MARIKO S-AFTERMATH)
+	(DESC "Black Ship")
+	(SYNONYM SHIP)
+	(ADJECTIVE BLACK)
+	(FLAGS ABSTRACTBIT THE)
+	(GENERIC GENERIC-SHIP-F)>
+
+<OBJECT GORODA
+	(LOC GENERIC-OBJECTS)
+	(DESC "Goroda")
+	(SYNONYM GORODA)
+	(ADJECTIVE DICTATOR)
+	(FLAGS PERSON)>
+
+<OBJECT TAIKO
+	(LOC GENERIC-OBJECTS)
+	(DESC "Taiko")
+	(SYNONYM TAIKO KWAMPAKU NAKAMURA)
+	(FLAGS PERSON)>
+
+<OBJECT SHOGUN
+	(LOC GENERIC-OBJECTS)
+	(DESC "Shogun")
+	(SYNONYM SHOGUN)
+	(FLAGS PERSON)>
+
+<OBJECT KIYAMA
+	(LOC GENERIC-OBJECTS)
+	(DESC "Kiyama")
+	(SYNONYM KIYAMA)
+	(ADJECTIVE LORD)
+	(FLAGS PERSON)>
+
+<OBJECT POPE
+	(LOC GENERIC-OBJECTS)
+	(DESC "Pope")
+	(SYNONYM POPE)
+	(ADJECTIVE CHRISTIAN CATHOLIC)
+	(FLAGS PERSON)>
+
+<OBJECT GLOBAL-HATAMOTO
+	(LOC GENERIC-OBJECTS)
+	(DESC "hatamoto")
+	(SYNONYM HATAMOTO)
+	(FLAGS PERSON)
+	(ACTION GLOBAL-HATAMOTO-F)>
+
+<ROUTINE GLOBAL-HATAMOTO-F ()
+	 <COND (<VERB? WHO WHAT>
+		<TELL
+"A "I"hatamoto"" is literally a 'banner-man,' which formerly meant one who
+carried his lord's banner in battle.  Now it means a vassal who is a personal
+retainer, a highly trusted member of the lord's staff." CR>)>>
+
+<OBJECT GLOBAL-BARBARIAN
+	(LOC GENERIC-OBJECTS)
+	(DESC "barbarian")
+	(SYNONYM BARBARIAN)
+	(FLAGS PERSON SCOREBIT)>
+
+<OBJECT GLOBAL-SAMURAI
+	(LOC GENERIC-OBJECTS)
+	(DESC "samurai")
+	(SYNONYM SAMURAI)
+	(GENERIC GENERIC-SAMURAI-F)
+	(FLAGS PERSON)>
+
+<OBJECT GLOBAL-DAIMYO
+	(LOC GENERIC-OBJECTS)
+	(DESC "daimyo")
+	(SYNONYM DAIMYO LORD)
+	(FLAGS PERSON)>
+
+<OBJECT PIRATE
+	(LOC GENERIC-OBJECTS)
+	(DESC "pirate")
+	(SYNONYM PIRATE CORSAIR)>
+
+<OBJECT HERETIC
+	(LOC GENERIC-OBJECTS)
+	(DESC "heretic")
+	(SYNONYM HERETIC SATANIST WORSHIPPER)
+	(ADJECTIVE SATAN)>
+
+<OBJECT LEADER
+	(LOC GENERIC-OBJECTS)
+	(DESC "leader")
+	(SYNONYM LEADER PILOT-MAJOR)>
+
+<VOC "SORRY" ADJ>
+
+<OBJECT WIND
+	(LOC GLOBAL-OBJECTS)
+	(DESC "wind")
+	(SYNONYM WIND GALE STORM BREEZE)
+	(ACTION WIND-F)>
+
+<ROUTINE WIND-F ()
+	 <COND (<VERB? EXAMINE FIND RUB>
+		<COND (<AND <SCENE? ,S-ERASMUS>
+			    <FSET? ,HERE ,OUTSIDE>>
+		       <TELL
+"The storm is out of the east, humping up the waves and tide.  The
+"I"Erasmus"" is ">
+		       <COND (<EQUAL? ,SHIP-DIRECTION ,P?WEST>
+			      <TELL
+"running before the wind." CR>)
+			     (<EQUAL? ,SHIP-DIRECTION ,P?SW ,P?NW>
+			      <TELL
+"fighting to make way south and west." CR>)
+			     (<EQUAL? ,SHIP-DIRECTION ,P?SOUTH ,P?NORTH>
+			      <TELL
+"broadside to the gale." CR>)>)
+		      (<SCENE? ,S-VOYAGE>
+		       <COND (<HERE? ,GALLEY ,MAIN-DECK ,IN-THE-SEA>
+			      <TELL
+"The gale is blowing with merciless fury." CR>)
+			     (ELSE
+			      <TELL
+"Here in the lee of the cliffs, the wind is calmer." CR>)>)
+		      (<FSET? ,HERE ,OUTSIDE>
+		       <TELL
+"The wind is calm here." CR>)
+		      (ELSE
+		       <TELL "You're inside.  There's no wind here." CR>)>)
+	       (<VERB? LISTEN>
+		<COND (<SCENE? ,S-ERASMUS ,S-VOYAGE>
+		       <TELL
+"The wind whistles and groans." CR>)>)
+	       (<VERB? THROUGH TURN-TOWARD>
+		<COND (<AND <SCENE? ,S-ERASMUS ,S-VOYAGE>
+			    <FSET? ,HERE ,OUTSIDE>>
+		       <TELL
+"Facing into the storm helps to keep you awake." CR>)
+		      (ELSE
+		       <TELL
+"There's no wind here." CR>)>)>>
+
+<OBJECT HELP
+	(LOC GLOBAL-OBJECTS)
+	(DESC "help")
+	(SYNONYM HELP ASSISTANCE AID)
+	(FLAGS ABSTRACTBIT)
+	(ACTION HELP-F)>
+
+<ROUTINE HELP-F ()
+	 <COND (<VERB? ASK-FOR>
+		<TELL
+"No one seems able, or perhaps, willing to help." CR>)
+	       (<VERB? TAKE>
+		<TELL
+"There doesn't seem to be anyone around in a position to help you." CR>)>>
+
+<OBJECT SUICIDE
+	(LOC GENERIC-OBJECTS)
+	(DESC "suicide")
+	(SYNONYM SUICIDE SEPPUKU DEATH)>
+
+<ROUTINE PRINT-SPACES (CNT)
+	 <REPEAT ()
+		 <COND (<L? <SET CNT <- .CNT 1>> 0>
+			<RETURN>)
+		       (T
+			<PRINTC 32>)>>>
+
+<CONSTANT SLINE <ITABLE NONE 41 ;82>>
+
+<OBJECT TRINITY-HOUSE
+	(LOC GLOBAL-OBJECTS ;GENERIC-OBJECTS)
+	(DESC "Trinity House")
+	(SYNONYM HOUSE TRINITY)	;"try it again as a syn."
+	(ADJECTIVE TRINITY)
+	(FLAGS ABSTRACTBIT SCOREBIT)
+	(ACTION TRINITY-HOUSE-F)>
+
+<ROUTINE TRINITY-HOUSE-F ()
+	 <COND (<VERB? WHAT>
+		<TELL
+"Trinity House in London is where you learned piloting from your old
+teacher, Alban Caradoc." CR>)>>
+
+<OBJECT LATITUDE
+	(LOC GENERIC-OBJECTS)
+	(OWNER LIZARD)
+	(DESC "latitude")
+	(SYNONYM LATITUDE)>
+
+<OBJECT LIZARD
+	(LOC GENERIC-OBJECTS)
+	(OWNER LIZARD)
+	(DESC "The Lizard")
+	(SYNONYM LIZARD)
+	(FLAGS NOTHEBIT NOABIT SCOREBIT)
+	(ACTION LIZARD-F)>
+
+<ROUTINE LIZARD-F ()
+	 <COND (<VERB? WHAT WHERE>
+		<TELL
+"The Lizard is the southernmost point of Cornwall, a major landmark
+for pilots." CR>)>>
+
+<OBJECT ROPE
+	(LOC GENERIC-OBJECTS)
+	(DESC "rope")
+	(SYNONYM ROPE)
+	(ACTION ROPE-F)
+	(GENERIC GENERIC-ROPE-F)>
+
+<ROUTINE ROPE-F ()
+	 <COND (<VERB? FIND>
+		<COND (<SCENE? ,S-VOYAGE>
+		       <TELL
+"You don't see any near at hand." CR>)>)>>
+
+<ROUTINE GENERIC-ROPE-F (R F)
+	 <COND (<GETP ,YABU-KIMONO ,P?COUNT>
+		,YABU-KIMONO)
+	       (ELSE ,ROPE)>>
+
+;"Plural:
+	 SEARCH-PARTY SAMURAI-GUARDS OMI-SAMURAI GUARDS
+	 GLOBAL-SAMURAI BROWNS GRAYS TORANAGAS-GUARDS
+  Singular:
+	 OMI LOSING-SAMURAI"
+
+<ROUTINE GENERIC-SAMURAI-F (R F "AUX" (CT <FIND-RES-COUNT .R>) OBJ
+			    (V <REST-TO-SLOT .R FIND-RES-OBJ1>) (BEST <>))
+ <COND (<G? .CT <FIND-RES-SIZE .R>> <RFALSE>)
+       (<AND ,OPPONENT <INTBL? ,OPPONENT .V .CT>>
+	<RETURN ,OPPONENT>)
+       (<IN? ,LOSING-SAMURAI ,HERE> <RETURN ,LOSING-SAMURAI>)
+       (<IN? ,OMI-SAMURAI ,LADDER> <RETURN ,OMI-SAMURAI>)
+       (<SCENE? ,S-NINJA> <RETURN ,GUARDS>)>
+ <REPEAT ()
+	 <COND (<L? <SET CT <- .CT 1>> 0>
+		<RETURN .BEST>)
+	       (<ACCESSIBLE? <SET OBJ <ZGET .V 0>>>
+		<COND (.BEST <RFALSE>)
+		      (<FSET? .OBJ ,PLURAL> <SET BEST .OBJ>)>)
+	       (T
+		<SET V <ZREST .V 2>>)>>>
+
+<OBJECT LG-SHIP
+	(SCENE S-AFTERMATH)
+	(LOC LOCAL-GLOBALS)
+	(DESC "ship")
+	(SYNONYM SHIP BOAT ERASMUS)
+	(ADJECTIVE NEW ANOTHER)
+	(FLAGS NDESCBIT)>
+
+<OBJECT COURSE
+	(LOC GLOBAL-OBJECTS)
+	(DESC "course")
+	(SYNONYM COURSE)
+	(ACTION COURSE-F)>
+
+<ROUTINE COURSE-F ()
+	 <COND (<NOT <SCENE? ,S-ERASMUS ,S-VOYAGE>>
+		<TELL "What course?" CR>)
+	       (<VERB? EXAMINE READ>
+		<COND (<SCENE? ,S-ERASMUS>
+		       <REDIRECT ,COURSE ,COMPASS>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"It's hard to tell directions in this storm, but the galley's course
+is toward ">
+		       <COND (<EQUAL? ,SHIP-COURSE ,P?STARBOARD>
+			      <TELL "the bay." CR>)
+			     (ELSE <TELL "the open sea." CR>)>)>)
+	       (<VERB? HOLD>
+		<COND (<HERE? ,BRIDGE-OF-ERASMUS>
+		       <PERFORM ,V?STRAIGHTEN ,WHEEL>
+		       <RTRUE>)
+		      (<HERE? ,GALLEY>
+		       <PERFORM ,V?STRAIGHTEN ,GALLEY-WHEEL>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"You'd have to be on the ">
+		       <COND (<SCENE? ,S-ERASMUS>
+			      <TELL "bridge">)
+			     (ELSE <TELL "quarterdeck">)>
+		       <TELL " to do that." CR>)>)>>
+
+<OBJECT GLOBAL-RUTTERS
+	(LOC GENERIC-OBJECTS)
+	(OWNER BLACKTHORNE)
+	(DESC "rutters")
+	(SYNONYM RUTTERS MAPS)>
+
+<OBJECT QUEEN
+	(LOC GENERIC-OBJECTS)
+	(DESC "Queen Elizabeth")
+	(SYNONYM QUEEN ELIZABETH)
+	(ADJECTIVE QUEEN)>
+
+<OBJECT WORLD
+	(LOC GENERIC-OBJECTS)
+	(DESC "world")
+	(SYNONYM WORLD GLOBE EARTH MAP)>
+
+<OBJECT VOYAGE
+	(LOC GENERIC-OBJECTS)
+	(DESC "voyage")
+	(SYNONYM VOYAGE TRIP JOURNEY)>
+
+<OBJECT TEKI
+	(LOC GENERIC-OBJECTS)
+	(DESC "teki")
+	(SYNONYM TEKI)>
+
+<OBJECT ETA
+	(LOC GENERIC-OBJECTS)
+	(DESC "eta")
+	(SYNONYM ETA ETER ETERS)
+	(FLAGS AN)
+	(ACTION ETA-F)>
+
+<ROUTINE ETA-F ()
+	 <COND (<VERB? WHAT WHO>
+		<TELL
+"The "I"eta"" are the lowest class of society, those who are butchers and
+tanners, executioners and undertakers." CR>)>>
+
+<OBJECT ORDERS
+	(LOC GLOBAL-OBJECTS)
+	(DESC "request")
+	(SYNONYM REQUEST ORDER ORDERS)
+	(ACTION ORDERS-F)>
+
+<ROUTINE ORDERS-F ()
+	 <COND (<VERB? FOLLOW DO? COMMIT>
+		<COND (<SCENE? ,S-PIT>
+		       <COND (<AND ,ANSWER-HAI?
+				   <FSET? ,CROOCQ ,SCOREBIT>>
+			      <PERFORM ,V?LIE-DOWN>
+			      <RTRUE>)>)
+		      (<SCENE? ,S-TORANAGA>
+		       <COND (<B-STANDING?>
+			      <PERFORM ,V?KNEEL>
+			      <RTRUE>)
+			     (<AND <FSET? ,DAIS ,RMUNGBIT>
+				   <FSET? ,DAIS ,SCOREBIT>>
+			      <PERFORM ,V?WALK-TO ,ALVITO>
+			      <RTRUE>)>)
+		      (ELSE
+		       <TELL "You'll have to be more specific." CR>)>)>>
+
+<END-SEGMENT>
diff --git a/hints.zil b/hints.zil
new file mode 100644
index 0000000..837e756
--- /dev/null
+++ b/hints.zil
@@ -0,0 +1,722 @@
+"HINTS for
+
+			       SHOGUN
+	(c) Copyright 1988 Infocom, Inc.  All Rights Reserved."
+
+<FILE-FLAGS SENTENCE-ENDS?>
+
+<BEGIN-SEGMENT HINTS>
+
+;"longest hint topic can be 17 chars"
+;"longest question can be 36 chars."
+;"question can't have more than 32 answers"
+
+<CONSTANT HINTS
+  <CONSTRUCT-HINTS HINT-COUNTS ;"Put topics in Quotes - followed by PLTABLEs
+				 of Questions and Answers in quotes"
+       ;"17 character wide"
+	        ;"this set of quotes is 36 chars. wide"
+	"Erasmus"
+	<PLTABLE "What must I do to survive?"
+"You have to do everything you can to keep your ship from sinking before you
+get to Japan."
+"You should try to find something to eat as soon as possible."
+"You should help the sick men as best you can."
+"It would be a good idea to keep updating the record of your voyage in your
+rutter."
+"You must keep your demoralized crew in order and continue to assert your
+authority."
+"You must pilot the ship into a safe harbor in Japan.">
+	<PLTABLE "How do I steer the ship?"
+"To change direction, turn the wheel to PORT (left) or STARBOARD (right)."
+"Compass directions won't work, you're in the middle of a storm!"
+"If you turn the wheel to PORT or STARBOARD, the ship will continue
+turning in that direction and you will flounder."
+"STRAIGHTEN THE WHEEL once the ship has turned, to maintain course and to
+avoid capsizing.">
+	<PLTABLE "I'm tired!"
+"You're tired and hungry."
+"Better not lay down on your bunk, though.  You'll fall asleep."
+"Maybe you could find something to eat.">
+	<PLTABLE "I'm hungry!"
+"An experienced seaman like yourself would probably keep a secret stash of
+ emergency food somewhere."
+"Perhaps in your cabin?"
+"Check your desk."
+"That's right, they're gone. Someone must have taken them!"
+"Didn't you just see Jan Roper come out of your cabin?"
+"Roper took your apples! Why don't you go into the Mate's Cabin and get them?">
+	<PLTABLE "How can I get the crew on watch?"
+"Go to the crew's quarters, Below Decks."
+"LOOK AT THE CREWMEN to decide who's fit to take a watch."
+"Send those men out on watch."
+"Vinck, Ginsel and Maetsukker are strong enough to go out."
+"Show some authority if any of them balk!">
+	<PLTABLE "What about my rutters?"
+"They're valuable, so you keep them in your sea chest."
+"You'll need a key to unlock it. Have you seen one around?"
+"The key is in your desk, which also holds the quill pen you'll need to
+write in it.">
+	<PLTABLE "How can I help Spillbergen?"
+"He keeps asking for water, doesn't he?"
+"Try looking for water."
+"There's a flagon of water hidden in the cabin."
+"Did you search his desk?"
+"There's a secret compartment in the desk. The flagon is inside.">
+	<PLTABLE "What about my pet rat?"
+"Oh, do you mean Gerald?"
+"You don't have a pet rat named Gerald!"
+"It's a joke! Now, stop reading the hints and play the game!">
+	<PLTABLE "How do I get through the reef?"
+"Sail due west after straightening the wheel."
+"When the reef is sighted, turn to Port to avoid hitting it."
+"Soon after, you will see a gap to Starboard, so turn towards it."
+"You'll be aimed very close to the gap, but you've lost some speed, so
+turn to port to get a boost from the wind."
+"Once you've done that, turn to Starboard to enter the gap.">
+	<PLTABLE "We've lost our foresails!"
+"Is the crew on deck?"
+"If not, get them!  This is an emergency!"
+"Try ringing the bell.  That ought to wake them up."
+"Now that they're on deck, order them to repair the foresails.">
+	<PLTABLE "I can't hold onto the wheel!"
+"You're too weak to fight the waves and current."
+"Maybe you could use some help."
+"Is anyone nearby?"
+"Vinck should be nearby. Ask him to help you.">
+	"Anjiro"
+	<PLTABLE "I'm hungry!"
+"You won't live very long without getting something to eat."
+"So eat the food that's on the tray!"
+"After you do that, a woman will come in."
+"Indicate to her that you're still hungry."
+"POINT TO THE TRAY or POINT TO MY STOMACH will suffice."
+"She'll bring you more food and your clothes!"
+"Eat the second tray of food and you'll survive!">
+	<PLTABLE "I was clumsy and I'm sorry!"
+"Tell the woman that.  She'll appreciate it."
+"Just do your best to apologize.">
+           <PLTABLE "How can I fight off these henchmen?"
+"You can't beat them, but don't worry, you won't be killed."
+"At least not if you fight back.">
+	<PLTABLE "How can I avoid being killed by Omi?"
+"Be polite."
+"Answer his questions!"
+"Address your answers to the priest.  He's translating."
+"You should know the answers already."
+"Question 1: I AM ENGLISH"
+"Question 2: I AM FROM HOLLAND"
+"Question 3: I'M THE LEADER"
+"Once you've answered the questions and Omi kills the henchman,
+get out of there!"> 
+	<PLTABLE "Where are my rutters?"
+"Have you looked on your ship?"
+"It's at anchor in the harbor!"
+"There's a rowboat at the waterfront."
+"Just row out and climb aboard."
+"You're the pilot.  Just go aft towards your quarters."
+"Nope, the samurai guards won't let you in.  Maybe some other time.">
+	"Yabu"
+	<PLTABLE "What do I say to Yabu?"
+"Answer the questions he asks.  Some are the same as Omi's."
+"It's also very important to notice how Yabu and Father Sebastio
+are getting along with each other."
+"Question 1: I'M JOHN BLACKTHORNE."
+"Question 2: I SAILED FROM HOLLAND."
+"Question 3: I'M THE PILOT."
+"Question 4: I SAILED THROUGH THE STRAIT OF MAGELLAN.">
+	<PLTABLE "Yabu orders me killed!"
+"You need to show him there is a reason to keep you alive."
+"You can't tell him anything, because you don't speak Japanese
+and Sebastio would lie about anything really useful."
+"Demonstrate that you are not the same sort of 'barbarian' as
+Sebastio."
+"Sebastio is a Catholic, you are a Protestant.  In the year 1600,
+this is significant."
+"In the year 1600, crosses would be an abomination to a good English
+Protestant."
+"When Sebastio's crucifix dangles near you, grab it..."
+"Then break it or throw it on the ground."
+"Then remember that courtesy is very important in this culture."
+"Better bow to Yabu to show you didn't mean him any insult by
+that action.">
+	"Pit"
+	<PLTABLE "How can I get out of the pit?"
+"You might try yelling."
+"Oh, well, I guess that didn't work.">
+	<PLTABLE "Help, I've been picked!"
+"Relax, there was only a fifty percent chance you'd be picked."
+"Better to resist than be boiled, eh?"
+"Now they've taken poor Pieterzoon?"
+"There's nothing you can do -- someone is going to die.  Pragmatism
+argues it ought not be you.">
+	<PLTABLE "Help, Vinck's been picked!"
+"Relax, there was only a fifty percent chance he'd be picked."
+"On the other hand, you're the other fifty percent."
+"Prevent him from going."
+"Stop him or shake the ladder."
+"Fight the attacking samurai who descend!"
+"Now they've taken poor Pieterzoon?"
+"There's nothing you can do -- someone is going to die.">
+	<PLTABLE "Now Omi wants me to come up!"
+"You could fight, or refuse."
+"... but the right thing to do is come up.">
+	<PLTABLE "Should I agree?"
+"If you refuse, you will die."
+"If you agree, the results will be unpleasant."
+"... but you will survive."
+"'Better to be a live dog than a dead lion.'">
+	"Rodrigues"
+	<PLTABLE "How can I get Rodrigues' help?"
+"He asks you specific questions any English Pilot would know the
+answers to."
+"If you study the map that came in your game package, you will find
+the answers."
+"If you don't have a map, perhaps you really ARE a pirate!">
+	<PLTABLE "What can Rodrigues do for me?"
+"He's obviously a respected person, maybe he has privileges you don't."
+"Perhaps he can get you into your ship to search for your rutters."
+"First, you should engage his interest.  Talk to him about your ship."
+"Then just follow his lead!">
+        <PLTABLE "What about the archers?"
+"If you don't watch out, they'll think you're trying to escape, and shoot you!"
+"You could explain yourself...if you could speak Japanese."
+"Rodrigues could explain, but he can't watch the archers while he's rowing."
+"That's why he asked you to!"
+"Watch the archers, and when they act hostile, tell Rodrigues!">
+	<PLTABLE "We're back on the Erasmus."
+"This may be your ship, but the samurai are in charge now."
+"This is Rodrigues' show. Just follow his lead, and let him do the talking.">
+	<PLTABLE "How do I defeat the attacking guards?"
+"Find your pistol."
+"Then find your powder horn."
+"...and blow them away!"
+"Of course, they aren't attacking, there is no pistol, and no powder horn."
+"Hint-browsing is considered barbaric in Japan.">
+	"Voyage to Osaka"
+	<PLTABLE "I'm tied down!"
+"Just untie your safety line."
+"It's dangerous but necessary.">
+	<PLTABLE "Now I'm getting washed overboard!"
+"Grab something!"
+"What's near at hand?"
+"Grab the gunwale!">
+	<PLTABLE "The oarsmen are confused!"
+"Help them, or tell them to ship their oars.  Be useful!"
+"Once they're settled down and awaiting orders, tell them to row!">
+	<PLTABLE "I can't make it to the bay!"
+"Steer towards it."
+"Rodrigues will tell you to stop, but ignore him."
+"You'll die if you steer out to sea.">
+	<PLTABLE "Rodrigues went overboard!"
+"He can't swim!"
+"He needs something to cling to!"
+"There's a life ring nearby."
+"Throw it to him."
+"Damn!  Maybe there's something else..."
+"Throw the oar to him."
+"Maybe he has a chance, and maybe not.  You've done all you can.">
+	<PLTABLE "How can I secure the galley?"
+"Are you in the bay yet?"
+"It's being washed around by the current."
+"Dropping the anchor would help!">
+	<PLTABLE "Poor Rodrigues.  What can I do?"
+"You can at least try to recover his body."
+"You might be in for a surprise!">
+	<PLTABLE "They won't let me ashore!"
+"Lower the skiff, they'll permit that."
+"Get in it."
+"Keep trying!  Insist!  You'll get your way eventually.">
+	<PLTABLE "I can't find Rodrigues' body!"
+"Be persistent.  Keep searching."
+"Keep heading south from the beach."
+"You can go all the way around the headland, but then you can't
+go any further."
+"Keep searching on the way back."
+"He's in the rocks below the Cliff Path.">
+	<PLTABLE "How can I get to him?"
+"Try climbing down the cliff."
+"You can't get to him..."
+"But Yabu can!"
+"So get Yabu to climb down.">
+	<PLTABLE "How can I save Yabu?"
+"Are you sure you want to save that sadistic monster?"
+"Yes, you should -- besides, he has Rodrigues."
+"You need a rope."
+"You need a long rope!">
+	<PLTABLE "Where can I find a rope?"
+"There's rope back at the galley."
+"But there's no time to get it."
+"Kimonos might make a good rope."
+"They need to be torn up and tied together."
+"They're still too short!"
+"Look at the remaining members of the search party."
+"How about using their loincloths!">
+	<PLTABLE "Yabu won't pay attention!"
+"Everyone seems to think the situation is hopeless."
+"If only there were some way of getting Yabu and Rodrigues to higher ground!"
+"A ledge, perhaps?"
+"Try searching the cliff. There's a ledge just beyond Yabu's reach."
+"Point it out to the samurai. They'll get his attention."
+"Don't forget to keep the rope lowered!">
+	"Toranaga"
+	<PLTABLE "Why does Toranaga have me killed?"
+"Courtesy, respect, politeness.  You are lacking in these."
+"You could emulate Hiro-matsu, and kneel as he did."
+"Or you could show some courage.  Bow and then sit as an equal would!"
+"You can look at Toranaga, which is disrespectful: \"A cat can
+look at a king.\"  Beyond that, you are in grave danger.">
+	<PLTABLE "What should I do with Alvito?"
+"Choose a language in which to speak to Alvito."
+"Tell Toranaga that Alvito is your enemy."
+"And remember that while he is your enemy, he is also not a fool.">
+	<PLTABLE "Why should I obey Alvito?"
+"Because you were asked to."
+"Because you are in the way if a fight starts!"
+"Toranaga and Ishido hate each other, so you don't want to be
+between them.">
+	<PLTABLE "How do I prevent Ishido from killing Toranaga?"
+"You could try punching him out."
+"Or kicking him."
+"Or do nothing, since he isn't going to kill Toranaga."
+"Not now, at any rate.">
+	"Prison"
+	<PLTABLE "That guy stole my food!"
+"Take it back."
+"I'm afraid you'll have to fight him."
+"... but don't attack him first.  If you do, he'll win.">
+	<PLTABLE "Why won't the old friar talk to me?"
+"He's Spanish.  All the Europeans you've met so far are Portuguese."
+"He's a Dominican friar.  All the priests you've met so far are
+Portuguese Jesuits."
+"The Portuguese Jesuits threw him in prison.  He hates the Portuguese."
+"So speak Spanish to him.">
+	<PLTABLE "What use is Domingo?"
+"He's been here a long time and he speaks Japanese."
+"Ask him about things."
+"For example, ask him about Toranaga or Japan or the Jesuits."
+"Ask him to teach you Japanese.  He knows a lot."
+"He can't do much in a few days, but it's a start!">
+        <PLTABLE "I'm being attacked!"
+"You are unarmed, and cannot defend yourself."
+"Duck, you fool!">
+        <PLTABLE "Yabu wants me to go with him."
+"He's one of Toranaga's men."
+"It's either him or Ishido."
+"'Better the devil you know...'"
+"GET IN LITTER.">
+	"Mariko"
+	<PLTABLE "What do I do in this scene?"
+"Bow to Toranaga or greet Mariko."
+"Ask Mariko about the prophecy."
+"Try to amuse Yaemon.  Smile or wink or act silly.">
+
+	"Escape (Part I)"
+	<PLTABLE "What's going on in this scene?"
+"Kiritsubo is preparing to leave Osaka."
+"There is also a rather rancorous argument going on."
+"But maybe something else as well..."
+"Watch closely what happens as the cortege is preparing to move out.">
+	<PLTABLE "What about Ishido?"
+"Ignore him, he's just being a pest."
+"Hiro-matsu, Buntaro and Yabu will take care of him."
+"You might try wandering around as much as they'll let you."
+"The garden is particularly pretty this time of year...">
+	<PLTABLE "What happened to Sazuko?"
+"She seemed to fall and possibly endanger herself and her baby."
+"But then she seemed to be all right again."
+"But was that all that was going on?">
+	<PLTABLE "What's in the garden?"
+"A little cha-no-yu (tea house)."
+"There's someone inside."
+"A veiled figure: a woman?"
+"No, it's Toranaga!">
+	<PLTABLE "What did Kiri do?"
+"She yelled something, probably a warning about Sazuko."
+"And then she ran into the garden, and out again..."
+"...and when she came out she was Toranaga!">
+        <PLTABLE "Here's Ishido again!"
+"He only wants to give Kiri a parchment."
+"But if he does, he'll discover that Kiri is really Toranaga in disguise!"
+"Ishido will kill you all!"
+"If you want to live, you'd better stop him!">
+	<PLTABLE "How can I stop Ishido?"
+"Well, he wants to give Kiri the parchment."
+"If he didn't have it he couldn't give it to her."
+"Of course, he won't like it if you just take it."
+"The time must be right."
+"And you'd better come up with some way of mollifying him afterward."
+"You could apologize."
+"You could bow, since your Japanese is still rather weak."
+"Or you could try to convince him you've gone crazy.">
+	<PLTABLE "How crazy am I?"
+"You could babble."
+"Of course, your speech sounds like babbling to the Japanese already."
+"You could sing; that would worry them."
+"You could dance around."
+"You could just act crazy.">
+	<PLTABLE "How do I get out of here?"
+"Just walk south across the bridge."
+"Of course, you better let Ishido know you're under control."
+"He has strong views about madness."
+"Do exactly what Mariko tells you to!">
+	<PLTABLE "I can't move!"
+"You're pretty tired."
+"Maybe you should follow Mariko's advice."
+"Get in Mariko's litter.">
+	"Escape (Part II)"
+	<PLTABLE "Now I'm really lost!"
+"You have to find your way out of the maze of city streets."
+"You start at the castle, and are headed for the docks."
+"Use your mouse, arrow keys, or function keys to move the glyph representing
+the party."
+"Or you can just type directions, but that's more tedious."
+"The dock is at the right edge of the display of mazelike city streets.">
+	<PLTABLE "We're under attack!"
+"You can't fight, you have no weapons."
+"You can't see the archers anyways."
+"Better get out of the way."
+"There's a litter to hide behind.">
+	<PLTABLE "Mariko's dead!"
+"You should try to save her."
+"When the attack starts, try to get her behind the litter, too.">
+	<PLTABLE "We're at the dock, now what?"
+"Agree to Toranaga's plan."
+"Follow Mariko when she runs for the galley."
+"You ought to board the galley."
+"You have any better ideas?">
+	<PLTABLE "Mariko seems to be in trouble!"
+"You should help her."
+"She seems to have fainted."
+"Maybe she needs water..."
+"... or 'mizu' as they say here.">
+	<PLTABLE "Now I'm under attack."
+"You have two knives."
+"Fight back!"
+"Of course, their swords are a lot longer than your knives..."
+"...so you can't fight at close quarters."
+"Throw your knives at them!"
+"Don't forget Mariko- she'll need your help!"
+"Just get out of the way of those flashing swords."
+"...and keep those knives flying.">
+	"Earthquake"
+	<PLTABLE "Can I save myself?"
+"Just get out of the way of the fissure as it approaches."
+"MOVE or ROLL, for example.">
+	<PLTABLE "Can I save Toranaga?"
+"He's close by."
+"Try grabbing him.">
+	<PLTABLE "Can I save Mariko?"
+"She's close by."
+"Try grabbing her."
+"You didn't really think that would work twice, did you?"
+"You'll have to climb down into the fissure."
+"...and then lift her out to Toranaga."
+"...and then climb out yourself."
+"...and you should hurry!">
+	<PLTABLE "What should I do then?"
+"Well, you could emulate Toranaga."
+"He has sort of a coarse sense of humor, doesn't he?"
+"He's also lost something he values highly."
+"You have something almost as good."
+"Give Toranaga your swords!">
+
+	"Journey to Yedo"
+	<PLTABLE "What an embarassing situation!"
+"When in Rome..."
+"There is little taboo against nakedness here."
+"...and everyone around is a friend."
+"...so go with the situation."
+"Undress, and then get in the tub."
+"Have some fun, ask Mariko to help bathe you.">
+	<PLTABLE "How do I avoid the thief?"
+"Hide under the bed until he comes in."
+"What bed? What thief?"
+"Read your dictionary, not the fake hint questions!">
+	<PLTABLE "What can I do in the nighttime?"
+"You could sleep."
+"But it isn't very helpful."
+"You could read your dictionary."
+"You can try to visit Mariko."
+"Watch out, though. If Yoshi catches you with her, he'll kill you.">
+	<PLTABLE "How can I avoid getting caught?"
+"You need to avoid being seen going into Mariko's room."
+"Watch for and listen to Yoshinaka as he makes his rounds."
+"Then time your excursion to avoid him."
+"And do the same on the way back.">
+	<PLTABLE "What can I do with Mariko?"
+"Doesn't your imagination suggest something?"
+"You are in love, after all."
+"And no one is here to bother you."
+"Well, this is a family hint question."
+"You figure it out."
+"But don't take too long! Remember, Yoshi is still out there.">
+
+	"Ochiba"
+	<PLTABLE "How do I avoid embarassment?"
+"What were you worrying about mere seconds ago?"
+"Check your swords!">
+	<PLTABLE "How do I avoid offending?"
+"Ochiba is a very important person, so bow to her!"
+"Then greet her.">
+	<PLTABLE "How can I make her like me?"
+"It's her birthday."
+"What do people expect on their birthday?"
+"A gift!  Have you anything to give her?"
+"Give her the camellia blossom."
+"It's not the custom here, but she will understand and appreciate it.">
+	<PLTABLE "Ishido is certainly being nasty."
+"You, therefore, should be polite."
+"Correct his mistake."
+"You are no longer a barbarian, you are a samurai!"
+"Tell him so!"
+"It will expose his rudeness, and put him in an embarassing position.">
+
+	"Departure"
+	<PLTABLE "What can I do to help Mariko?"
+"When she directs you to fight, do so."
+"Kill the Captain of the Grays."
+"Just keep attacking him."
+"You will realize he doesn't want to kill you, although the Grays
+will kill everyone else in Mariko's escort.">
+        <PLTABLE "Now Mariko is fighting!"
+"She is samurai; it is her right."
+"Don't try to help her, or you'll bring great shame upon her.">
+	"Seppuku"
+	<PLTABLE "What do I do in the garden?"
+"Do what Chimmoko asks."
+"Go in the cha-no-yu house and see Mariko."
+"Kiss her, if you wish.">
+	<PLTABLE "How can I help Mariko?"
+"First, realize you can't stop her without shaming her even more than
+Ishido has shamed her."
+"Then realize you must just wait until Ishido gives in."
+"Then, when she has won, you can carry her away.">
+
+	"Ninja"
+	<PLTABLE "What should I do about Yabu?"
+"First, notice that he's nervous."
+"Ask him about the 'plan.'"
+"Maybe he's up to something!"
+"Perhaps you should follow him and find out."
+"Discretion, discretion!  Don't follow too close.">
+	<PLTABLE "How can I survive the ninja attack?"
+"You could try fighting them off."
+"Well, first you will need some weapons."
+"Your swords and powder horn are in your quarters."
+"The ninja haven't much experience with firearms, so your pistol will
+help a lot."
+"They will slow down, confused and scared, each time you fire the
+pistol."
+"But your pistol takes time to reload, so you're going to have to
+retreat and hope for help."
+"And each time you use it, they get less scared of it.">
+	<PLTABLE "They've taken Mariko!"
+"You can usually avoid this by telling Mariko to follow you."
+"If they have her, firing the pistol will give her a chance to
+escape.">
+	<PLTABLE "I can't get away from the ninja!"
+"You'll have to block them and slow them down."
+"Firing the pistol at them slows them down."
+"Closing and barring doors in their way slows them down."
+"The iron-bound door between the Audience Chamber and the Inner Corridor can be
+closed and barred."
+"You can also slow them down by shooting at them through the crack they
+make in that door."
+"But you'll be better off finding a safer place to retreat to."
+"Have you been back to the Private Quarters?"
+"When you go back, Kiritsubo will show you the way into a secret room."
+"Once you're in there with the women, you should close the bolts!">
+	<PLTABLE "How can I escape the explosion?"
+"You can go out onto the balcony."
+"First you have to open the catches on the balcony door."
+"They're rusty, so hit them with something."
+"...the pistol, for example.">
+	<PLTABLE "How can I prevent Mariko's death?"
+"Get her into the Secret Redoubt."
+"Then convince her to go onto the Balcony."
+"But she won't go, will she?"
+"She thinks her death is inevitable."
+"So force her!"
+"But if you do that the ninja will capture her."
+"She's right.  Your love is doomed, and if she's captured by Ishido,
+the hostages will never be freed."
+"It's tragic, but there is no way out for her."
+"Honor her faith, and bless her after she dies.">
+
+	"Yokohama"
+	<PLTABLE "Vinck certainly is acting weird!"
+"Humor him."
+"Don't get him too upset."
+"...as he's armed and dangerous."
+"Wait for him to die."
+"...and then carry him away.">
+	<PLTABLE "What can I do about the Erasmus?"
+"You can look at it."
+"...and that's about it.">
+
+	"Aftermath"
+	<PLTABLE "What's the scroll good for?"
+"It gives you something to read."
+"It also reminds you that you can get a new ship."
+"You should tell Toranaga that.">
+	<PLTABLE "What does Toranaga want?"
+"He wants you to tell him what you know."
+"What did you find out during the attack on the castle?"
+"What did Yabu do before the attack?"
+"Did you try to follow him?"
+"You ought to try that!"
+"Tell Toranaga that Yabu betrayed him."
+">TORANAGA, YABU BETRAYED YOU"
+"Tell Toranaga how Yabu betrayed him."
+">TORANAGA, YABU LET IN THE NINJA"
+"Tell Toranaga what Yabu said to the ninja."
+">TORANAGA, I AM KASIGI YABU">
+
+	"As a Last Resort (Part I)"
+	<PLTABLE "Read me first."
+"This section tells you how the points in each scene are scored.  You
+get five points for each correct action listed.  It is possible to
+finish some scenes without getting all the points.|
+|
+Think twice before reading further!  Don't spoil the game for yourself!">
+
+	<PLTABLE "Erasmus (11 actions)"
+;WHEEL		"Straightening the wheel."
+;ROPER		"Getting your apple back from Roper."
+;APPLE		"Eating the apple."
+;KEY		"Finding the key to the sea chest."
+;RUTTER		"Writing in your rutter."
+;CAPTAINS-DESK	"Finding the flagon in the Captain's desk."
+;FLAGON		"Giving the Captain water."
+;MAETSUKKER	"Sending Vinck, Ginsel, and Maetsukker out on watch."
+;BELL		"Ringing the bell to get the crew on deck."
+;FORESAILS	"Fixing the foresails."
+;REEF		"Getting through the reef into the harbor.">
+
+	<PLTABLE "Anjiro (4 actions)"
+;FOOD		"Eating both trays of food."
+;SEBASTIO-HENCHMEN "Fighting back against Sebastio's henchmen."
+;OMI		"Getting through Omi's interrogation."
+;SAMURAI-GUARDS "Trying to get your rutters back.">
+
+	<PLTABLE "Yabu (2 actions)"
+;SEBASTIO-CRUCIFIX "Breaking Sebastio's crucifix."
+;STRAIT-OF-MAGELLAN "Telling Yabu about your voyage.">
+
+	<PLTABLE "Pit (5 actions)"
+;LADDER		"Saving Vinck if he's the one picked to die, or saving
+yourself if you are picked."
+;LOSING-SAMURAI "Fighting the samurai, taking one as a hostage."
+;VILLAGE-SQUARE "Agreeing to behave."
+;CROOCQ		"Lying down."
+;BATHTUB	"Taking a bath.">
+
+	<PLTABLE "Rodrigues (4 actions)"
+;TRINITY-HOUSE	"Answering Rodrigues about where you trained."
+;LIZARD		"Answering Rodrigues about the Lizard."
+;LG-ERASMUS	"Telling Rodrigues about the Erasmus."
+;ARCHERS	"Warning Rodrigues about the archers.">
+
+	<PLTABLE "Voyage to Osaka (11 actions)"
+;GUNWALE	"Grabbing the gunwale."
+;MAIN-DECK	"Restoring order on the oar deck."
+;OARSMEN	"Getting the oarsmen to row again."
+;OAR		"Throwing oar to Rodrigues."
+;ANCHOR		"Dropping anchor once in the bay."
+;SKIFF		"Getting into the skiff."
+;LEDGE-4	"Finding Rodrigues."
+;YABU-KIMONO	"Making a rope of kimonos."
+;LOINCLOTH	"Adding loincloths to rope."
+;LEDGE		"Finding the ledge."
+;SEARCH-PARTY	"Getting Yabu's attention.">
+
+	<PLTABLE "Toranaga (3 actions)"
+;AUDIENCE-CHAMBER "Defying convention by bowing but not kneeling."
+;DAIS		"Moving to the dais when Ishido arrives."
+;ALVITO	"Telling Toranaga Alvito is your enemy.">
+
+	<PLTABLE "Prison (6 actions)"
+;THUG		"Defeating the thug."
+;DOMINGO	"Speaking Spanish to Domingo."
+;JAPANESE	"Asking Domingo to teach you Japanese."
+;LG-LINE	"Joining the line of prisoners."
+;BANDITS	"Avoiding the bandit's attack."
+;YABU-PALANQUIN "Getting in Yabu's palanquin.">
+
+	<PLTABLE "Mariko (3 actions)"
+;MAPLE-GLADE	"Greeting or bowing to Mariko or Toranaga."
+;YAEMON		"Smiling or winking at Yaemon."
+;PROPHECY	"Asking Mariko about the prophecy.">
+
+	"As a Last Resort (Part II)"
+	<PLTABLE "Escape (13 actions)"
+;TORANAGA-IN-DRAG "Seeing Toranaga in the hut."
+;KIRITSUBO	"Seeing Toranaga and Kiritsubo switch."
+;PARCHMENT	"Grabbing the parchment from Ishido."
+;CURTAINS	"Giving the parchment to 'Kiri.'"
+;CRAZY		"Distracting Ishido by acting nuts."
+;WOODS		"Reaching the woods successfully."
+;MARIKOS-LITTER "Saving Mariko during ambush."
+;FISH-GATE	"Finding the ronin."
+;MESSENGER	"Slowing down the messenger so Buntaro can kill him."
+;WHARF		"Helping Mariko when she 'faints.'"
+;GLOBAL-WATER	"Remembering the word for 'water.'"
+;GRAY-LEADER	"Killing the Gray leader."
+;SECOND-GRAY	"Killing the second Gray.">
+
+	<PLTABLE "Earthquake (4 actions)"
+;MAIN-FISSURE	"Saving Toranaga."
+;SIDE-FISSURE	"Saving Mariko."
+;PLATEAU	"Pissing in the fissure."
+;SWORDS		"Giving swords to Toranaga after his are lost.">
+
+	<PLTABLE "Journey to Yedo (3 actions)"
+;YOKOSE-BATHTUB "Bathing with Mariko."
+;YOKOSE-SPA-3	"Making love to Mariko."
+;YOKOSE-SPA-1	"Getting back to your room safely.">
+
+	<PLTABLE "Ochiba (3 actions)"
+;SWORDS		"Checking your swords."
+;CAMELLIA	"Giving the camellia to Ochiba."
+;GLOBAL-BARBARIAN "Telling Ishido you are not a barbarian.">
+
+	<PLTABLE "Departure (1 action)"
+;YAMAZAKI	"Killing Yamazaki.">
+
+	<PLTABLE "Seppuku (1 action)"
+;MARIKO		"Carrying Mariko away.">
+
+	<PLTABLE "Ninja (6 actions)"
+;PLAN		"Asking Yabu about the plan."
+;BARRELS	"Hiding from the ninja in the cellars."
+;CELLARS	"Seeing Yabu in the cellars let in the ninja."
+;NINJA		"Shooting the ninja leader."
+;MARIKO		"Telling Mariko to follow you."
+;MARIKO		"Blessing Mariko.">
+
+	<PLTABLE "Yokohama (1 action)"
+;YOKOHAMA	"Picking up Vinck.">
+
+	<PLTABLE "Aftermath (3 actions)"
+;SEALED-SCROLL	"Reading the sealed scroll."
+;TRAITOR	"Reporting that you saw Yabu."
+;YABU		"Reporting the password.">
+	"Have you tried?"
+	<PLTABLE "Amusing things to try..."
+">HUG VINCK (or any other of your crew)"
+">BOW TO VINCK (or any other Dutchman)"
+"Wandering around Anjiro naked."
+">KICK HEAD (of Sebastio's disrespectful henchman)"
+">WHAT ARE COJONES (since Rodrigues wonders if you have any)"
+">DRAW THE WORLD (for Yaemon)"
+">SING (other than during the escape)"
+"Find out the name of your sword (after the Earthquake scene)."
+">LOOK UP \"TSURU\" IN DICTIONARY">
+
+	<PLTABLE "To find out who worked on the game."
+"Type 'CREDITS' at any time in the story.">
+>>
+
+<END-SEGMENT>
+
diff --git a/mariko.zil b/mariko.zil
new file mode 100644
index 0000000..bc98aa7
--- /dev/null
+++ b/mariko.zil
@@ -0,0 +1,1026 @@
+"MARIKO for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc.  All Rights Reserved."
+
+<FILE-FLAGS SENTENCE-ENDS?>
+
+<BEGIN-SEGMENT OCHIBA>
+
+<ROOM OCHIBA-ROOM
+      (LOC ROOMS)
+      (SCENE S-OCHIBA)
+      (SCORE 3)
+      (DESC "Reception Room")
+      (SYNONYM ROOM)
+      (ADJECTIVE RECEPTION)
+      (FDESC
+"Your feet take you under the final portcullis and your escorts lead
+you up to the huge door.  Here they leave you alone.  Desperate for
+any distraction from the ordeal to come, you admire the camellia blossom
+Mariko took from a vase in your quarters and gave to you.  The flower is
+reassuring.  Not everyone here in Osaka is an enemy.|
+|
+You stand rigid for a moment, petrified with
+nervousness.  What if you disgrace yourself?  What if you slip or your
+swords fall or your limited Japanese fails you.  You take a deep breath
+and walk forward into the flare-lit maw.")
+      (LDESC
+"It is an immense, high-raftered room with a golden ornamented
+ceiling.  Gold-paneled columns support the rafters, which are made of rare and
+polished woods.  Five hundred samurai and their ladies are here, wearing
+all the colors of the rainbow.  To one side is a line of guests who wait
+to bow before the raised platform at the far end.")
+      (FLAGS ONBIT)
+      (ACTION OCHIBA-ROOM-F)>
+
+<ROUTINE OCHIBA-ROOM-F (RARG)
+	 <COND (<RARG? SCENE-SETUP>
+		<DRESS-BLACKTHORNE>
+		<MOVE ,CAMELLIA ,BLACKTHORNE>
+		<MOVE ,SWORDS ,BLACKTHORNE>
+		<FSET ,SWORDS ,WEARBIT>
+		<FSET ,SWORDS ,RMUNGBIT>
+		<MOVE ,ISHIDO ,OCHIBA-ROOM>
+		<MOVE ,OCHIBA ,OCHIBA-ROOM>
+		<QUEUE I-OCHIBA -1>)
+	       (<RARG? BEG>
+		<COND (<OR <P? (BOW HELLO KONNICHI-WA KONBANWA)
+			       (<> OCHIBA ISHIDO)>
+			   <VERB? KNEEL>>
+		       <COND (<FSET? ,BLACKTHORNE ,TRYTAKEBIT>
+			      <COND (<P? (HELLO KONNICHI-WA KONBANWA)
+					 (OCHIBA <>)>
+				     <SETG WINNER ,OCHIBA>
+				     <PERFORM ,V?HELLO>
+				     <SETG WINNER ,PLAYER>
+				     <RTRUE>)
+				    (ELSE
+				     <TELL
+"You have already bowed to the hosts." CR>)>)
+			     (<FSET? ,OCHIBA ,RMUNGBIT>
+			      <FSET ,BLACKTHORNE ,TRYTAKEBIT>
+			      <B-STAND>
+			      <TELL
+"In front of the platform, you kneel and bow formally as you have seen
+the others do, once to Ochiba and once to Ishido.  You then stand and
+walk forward.">
+			      <COND (<AND <FSET? ,SWORDS ,WEARBIT>
+					  <FSET? ,SWORDS ,RMUNGBIT>>
+				     <FCLEAR ,SWORDS ,RMUNGBIT>
+				     <FCLEAR ,SWORDS ,WEARBIT>
+				     <MOVE ,SWORDS ,HERE>
+				     <TELL
+" Suddenly, just as you had feared, your sword belt comes loose and
+your swords clatter to the floor.  You turn red, scrambling for them
+on the ground, and Ishido begins a swelling round of humiliating
+laughter.">)>
+			      <CRLF>)
+			     (ELSE
+			      <TELL
+"You must be very nervous: you aren't at the front of the line yet!" CR>)>)
+		      (<P? CURSE (ISHIDO OCHIBA)>
+		       <TELL
+"You insult " D ,PRSO ", forfeiting any gain you might have gotten
+from the exchange." CR>)
+		      (<ACT-CRAZY?>
+		       <COND (<EQUAL? ,QCONTEXT ,ISHIDO>
+			      <TELL
+"Ishido stares at you.  \"This is what I meant!\"" CR>)
+			     (ELSE
+			      <TELL "Ochiba looks disgusted." CR>)>)
+		      (<OR <HOSTILE-VERB?>
+			   <P? (DRAW PICK USE TAKE) SWORDS>>
+		       <TELL
+"Such a foolish action would surely lead to your immediate death." CR>)>)>>
+
+<OBJECT CAMELLIA
+	(DESC "camellia blossom")
+	(SYNONYM BLOSSOM FLOWER CAMELLIA)
+	(ADJECTIVE CAMELLIA PINK)
+	(FLAGS TAKEBIT SCOREBIT)
+	(ACTION CAMELLIA-F)>
+
+<ROUTINE CAMELLIA-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"This is a particularly beautiful pink camellia blossom that you cut from
+a tree in the garden.  It is at the peak of its beauty." CR>)
+	       (<P? GIVE CAMELLIA OCHIBA>
+		<COND (<NOT <FSET? ,BLACKTHORNE ,TRYTAKEBIT>>
+		       <TELL
+"Ochiba recoils from the unaccustomed familiarity.  You haven't even
+greeted her properly.  \"His manners are barbaric,\" she says to Ishido,
+with sadness." CR>)
+		      (ELSE
+		       <REMOVE ,CAMELLIA>
+		       <SCORE-OBJECT ,CAMELLIA>
+		       <TELL
+"\"In my land we are ruled by a Queen.  We have the custom to always give
+a Lady a birthday gift.  Even a Queen.  Please excuse if this is not good
+manners.\"  She looks at the flower.  Five hundred people wait to see how
+she will respond to your gallantry and daring.|
+|
+\"I am not a Queen, Anjin-san, only the mother of the Heir and widow of
+the Lord Taiko.  I cannot accept your gift as a Queen, but as a Lady on
+her birthday, perhaps I may ask everyone's permission to accept the
+gift?\"|
+|
+The room bursts into applause." CR>)>)>>
+
+<GLOBAL OCHIBA-QUESTION <>>
+
+<ROUTINE I-OCHIBA ()
+	 <ZLINES ,OCHIBA-CNT
+		 (<TELL CR
+"The procession of guests creeps forward, each politely bowing to
+Ochiba and greeting her on her birthday." CR>)
+		 (<FSET ,OCHIBA ,RMUNGBIT>
+		  <TELL CR
+"Ochiba is looking at you,
+and then Ishido is looking at you, too.  Soon all conversation dies
+and everyone is watching you.  The men and women ahead of you in
+line melt away and suddenly no one is between you and the platform." CR>)
+		 (DELAY
+		  <COND (<NOT <FSET? ,BLACKTHORNE ,TRYTAKEBIT>>
+			 <COND (<G? ,DELAY-CNT 4>
+				<TELL CR
+"Ishido stands, bows to Lady Ochiba, and asks, \"With your permission,
+Lady, I will remove this insult to your person.\"" CR>
+				<JIGS-UP>
+				<RFATAL>)
+			       (ELSE
+				<TELL CR
+"Every eye is on you as you stand before Ochiba.  Every breath is held." CR>
+				<RTRUE>)>)>)
+		 (1)
+		 (<SETG OCHIBA-QUESTION 1>
+		  <SETG QCONTEXT ,OCHIBA>
+		  <TELL CR
+"\"Please wait, Anjin-san,\" says Ochiba.  You feel the extraordinary
+sensuality that surrounds her, without conscious effort on her
+part.  \"">
+		  <COND (<FSET? ,HANASE-MASEN ,RMUNGBIT>
+			 <TELL
+"You speak our language, then?\"" CR>)
+			(ELSE
+			 <TELL
+"It is said that you speak our language?\"" CR>)>)
+		 (DELAY
+		  <COND (<EQUAL? ,OCHIBA-QUESTION 1>
+			 <COND (<G? ,DELAY-CNT 2>
+				<SETG OCHIBA-QUESTION <>>
+				<TELL CR
+"\"Ah, I suppose what we have heard is not true, then.  He must not
+truly speak our language.\"  She turns to Ishido and smiles." CR>)
+			       (ELSE
+				<TELL CR
+"\"Is it true that you speak our language, Anjin-san?\" she asks in a
+friendly way, using the Japanese that you can barely understand." CR>)>
+			 <RTRUE>)>)
+		 (1)
+		 (<SETG QCONTEXT ,ISHIDO>
+		  <TELL CR
+"Ishido rudely interrupts.  \"When we last met, you were a madman.  I
+hope you won't get mad tonight or any other night.\"" CR>)
+		 (<SETG QCONTEXT ,ISHIDO>
+		  <SETG OCHIBA-QUESTION 2>
+		  <TELL CR
+"\"Such madness is usual among you barbarians, "I"neh?""\"  He emphasizes
+the word 'barbarians.'  Such public rudeness to a guest is very
+bad.  Lady Ochiba seems surprised." CR>)
+		 (DELAY
+		  <COND (<EQUAL? ,OCHIBA-QUESTION 2>
+			 <COND (<G? ,DELAY-CNT 3>
+				<SETG OCHIBA-QUESTION 0>
+				<TELL CR
+"\"Bah!  It is clear he is a barbarian without honor!\"  Ishido turns
+away with a snort of dirision." CR>
+				<RTRUE>)
+			       (ELSE
+				<TELL CR
+"Ishido continues to taunt you.  \"You are a barbarian.  You "I"barbarians"
+" are prone to fits of madness, as I've been told?\"  The room is
+hushed, everyone waiting to see how you will respond." CR>
+				<RTRUE>)>)>)
+		 (<MOVE ,MARIKO ,HERE>
+		  <TELL CR
+"\"Mariko-san, your pupil does you credit, "I"neh?""\" calls out
+Ochiba.  Mariko is coming through the guests.  \"I have done little,
+Ochiba-sama.  It's all the Anjin-san's work and the word book that the
+Christian
+fathers gave him.\"" CR>)
+		 (<TELL CR
+"Ochiba turns to Mariko.  \"Now, Mariko-san, we must talk about the
+poetry competition!  It will
+be held in two days, when Lord Toranaga leaves his own borders to
+journey here.  What's the
+theme to be?  And the first line of the poem?\"  Mariko is renowned as
+a poetess.|
+|
+Mariko thinks a moment.  \"It should be about "I"today"", Lady Ochiba,
+and the first line: 'On a leafless branch.'\"|
+|
+Ishido compliments her on her choice.  \"Excellent, but we'll have to
+be very good to compete with you, Mariko-san!\"" CR>)
+		 (<TELL CR
+"Mariko continues, \"So sorry, Sire, but I will not be there.  I'm leaving Osaka tomorrow
+with the Lady Kiritsubo and the Lady Sazuko, to meet Lord Toranaga.\"|
+|
+\"Nonsense!\" replies Ishido.  \"He will be here so soon that to go to
+meet him isn't necessary.\"|
+|
+\"So sorry, Sire, but those are the orders of my liege Lord.  I must
+leave tomorrow.  Am I confined here?  And if so, on whose orders?\"|
+|
+Ishido keeps his eyes riveted on her.  \"No, you are not confined.\"" CR>)
+		 (<TELL CR
+"Many of the ladies in the room turn to their neighbors, and some
+whisper openly what all those held against their will in Osaka are
+thinking: 'If she can go, so can I, so can you!  I'll leave tomorrow,
+too!'" CR>)
+		 (<DEQUEUE I-OCHIBA>
+		  <TELL CR
+"Mariko makes a half-bow to the room and leaves.  Yabu steps forward
+with you and the two of you follow her out, very conscious that you
+are the only samurai present wearing Toranaga's uniform." CR>
+		  <NEXT-SCENE>)>>
+
+<OBJECT OCHIBA
+	(LOC OCHIBA-ROOM)
+	(DESC "Lady Ochiba")
+	(SYNONYM OCHIBA LADY)
+	(ADJECTIVE LADY)
+	(FLAGS PERSON JAPANESEBIT NOABIT FEMALE)
+	(DESCFCN OCHIBA-DESC)
+	(ACTION OCHIBA-F)>
+
+<ROUTINE OCHIBA-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (ELSE
+		<TELL
+"On the platform, alone, is the Lady Ochiba.">)>>
+
+<ROUTINE OCHIBA-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<OR <VERB? YES HAI NO IYE>
+			   <P? SAY JAPANESE>
+			   <P? NIHON-GO-GA HANASE-MASEN>>
+		       <COND (<OR <EQUAL? ,OCHIBA-QUESTION 1>
+				  <P? NIHON-GO-GA HANASE-MASEN>>
+			      <SETG OCHIBA-QUESTION <>>
+			      <COND (<VERB? HAI IYE SPEAK NIHON-GO-GA>
+				     <FSET ,HANASE-MASEN ,RMUNGBIT>)>
+			      <COND (<VERB? NO IYE>
+				     <TELL
+"\"No, Highness.  I have learned a few words and phrases, so that I may
+better be understood, however.">)
+				    (ELSE
+				     <TELL
+"\"Please excuse me, Highness.">)>
+			      <TELL
+"  I have to use short words and respectfully
+ask you to use simple words with me.\"" CR>)
+			     (ELSE
+			      <TELL
+"She doesn't seem to be listening." CR>)>)
+		      (<VERB? HELLO>
+		       <COND (<NOT <FSET? ,OCHIBA ,TRYTAKEBIT>>
+			      <FSET ,OCHIBA ,TRYTAKEBIT> ;"greeted her"
+			      <TELL
+"\"May I respectfully congratulate
+you on your birthday and pray that you live to enjoy a thousand more.\"" CR>)
+			     (ELSE
+			      <TELL
+"You have already congratulated her." CR>)>)
+		      (<P? THANK YOU>
+		       <TELL
+"\"Domo, Ochiba-sama.\"  She acknowledges your thanks." CR>)
+		      (<OR <P? NO>
+			   <NOT-A-BARBARIAN?>>
+		       <TELL
+"\"This may be true, Anjin-san, but your manners are less than perfect.\"" CR>)
+		      (ELSE
+		       <WAKARIMASEN>)>)
+	       (<VERB? EXAMINE>
+		<TELL
+"She is slight, almost girlish in build, with a luminous glow to her
+fair skin.  She is at the peak of her beauty.  Her sloe eyes are large
+under painted, arched brows, her
+hair set like a winged helmet.  Her kimono is exquisitely rich, gold
+threads on the rarest blue-black silk.  She sits comfortably on a
+cushion." CR>)
+	       (<VERB? WHO>
+		<TELL
+"The Lady Ochiba is the widow of the Taiko, and the mother of the
+Heir, Yaemon.  The rumors say that she is now the mistress of Lord
+Ishido.  All Japan wonders if the Taiko, who had never before sired
+a child, was truly the Yaemon's father, but only Ochiba knows for
+sure." CR>)>>
+
+<END-SEGMENT>
+
+
+
+"S-DEPARTURE"
+
+<BEGIN-SEGMENT DEPARTURE>
+
+<ROUTINE DEPARTURE-AFTER-F ()
+	 <TELL
+"Ishido and his supporters meet in Kiyama's opulent, overrich quarters.|
+|
+\"It's impossible, Lord General,\" Ochiba says.  \"You can't let a lady of her
+rank commit seppuku.  So sorry, but you've been trapped.  The hostages will have
+to be freed, and then there's nothing to stop Toranaga.\"|
+|
+\"I agree,\" Lord Kiyama says forcefully.|
+|
+\"With due humility, Lady,\" Ishido replies, \"whatever I said or didn't say,
+doesn't matter an "I"eta""'s turd to her.  She's already decided, at least
+Toranaga has.  We are at war, Toranaga's not yet in our hands, and until he's
+dead the Heir is in total danger.\"|
+|
+He walks over to the window.  \"Suppose she's disarmed?  Capture her!  Confine
+her until Toranaga's in our hands, then the hostages don't matter.  In eighteen
+days Toranaga has to be here!\"|
+|
+\"You really think Lady Toda could be captured?\" Kiyama says.|
+|
+\"Yes,\" replies Ishido." CR>>
+
+<ROUTINE I-DEPARTURE ()
+	 <ZLINES ,DEPARTURE-CNT
+		 (<MOVE ,YAMAZAKI ,FORECOURT>
+		  <THIS-IS-IT ,YAMAZAKI>
+		  <TELL CR
+"Twenty Browns form up as a vanguard and move off.  Porters pick up
+Mariko's palanquin and follow the Browns, Kiri and Lady
+Sazuko close behind.|
+|
+When Mariko's palanquin comes into the sunlight, a Captain of Grays
+steps forward, standing directly in her way.  \"May I see your
+papers?\" he inquires.|
+|
+Mariko says formally, \"We require none.  I am Toda Mariko-noh-Buntaro
+and I have been ordered by my leige Lord, Lord Toranaga, to escort his
+ladies to meet him.  Kindly let us pass.\"|
+|
+\"My name is Yamazaki Danzenji, Captain of the Fourth Legion, and my line
+is as ancient as your own, my Lady.  Please excuse me, but my leige Lord,
+Lord Ishido, says no one may
+leave Osaka Castle without papers.\"|
+|
+\"So sorry, Captain, but if you do not move out of the way I will order
+you killed.\"" CR>)
+		 (<QUEUE I-FIGHT -1>
+		  <SETG OPPONENT ,YAMAZAKI>
+		  <TELL CR
+G"\"You will not pass without papers!\""" the Gray Captain replies
+proudly.  Mariko nods sadly.  \"Please kill him,\" she orders quietly,
+and at once
+the battle is joined.  It is terrifyingly fair and formal, one Gray for
+each Brown and one for yourself." CR>)
+		 (DELAY
+		  <COND (<QUEUED? I-FIGHT> <RFALSE>)>)
+		 (<MOVE ,MARIKO ,HERE>
+		  <MOVE ,KOJIMA ,HERE>
+		  <SETG OPPONENT ,KOJIMA>
+		  <THIS-IS-IT ,KOJIMA>
+		  <TELL CR
+"Almost immediately, twenty more Browns run forward to form a new
+vanguard.  From up ahead twenty more Grays move silently out from the
+hundreds that are waiting.|
+|
+\"Wait,\" Mariko orders.  She steps out of her palanquin and picks up
+a sword, unsheaths it, and walks forward alone.  She approaches the
+officer.  \"You know who I am.  Please get out of my way.\"|
+|
+\"I am Kojima Harutomo, Captain of the Sixth Legion.  Please excuse me,
+you may not pass, Lady.\"" CR>)
+		 (<TELL CR
+"Mariko darts forward but her blow is contained.  The Gray stays on the
+defensive although he could kill her without effort.|
+|
+Again Mariko tries to bring the Gray to battle, but he slides away, allowing
+her to exhaust herself.  But he does this gravely, giving her every courtesy,
+giving her the honor that is her due.  She knows she cannot last much
+longer.  She sees how easy it would be for the massed Grays to cut them all
+off if
+they wish and leave them stranded and helpless.  She breaks off the fight." CR>)
+		 (<SETG OPPONENT <>>
+		  <MOVE ,ISHIDO ,HERE>
+		  <TELL CR
+"Lord Ishido emerges from the crowd of Grays.  \"Lady Toda, the castle
+orders must be obeyed.  But if you wish, I will call a meeting of the
+Regents and ask for a ruling.\"|
+|
+Mariko turns to Ishido and bows.  \"My orders are clear.  If I am not
+permitted to obey, I will not be able to live with that shame.\"" CR>)
+		 (<TELL CR
+"\"These men have prevented me from
+doing my duty, from obeying my leige Lord.  I cannot live with this
+shame, Sire.  Unless we are allowed to obey our leige Lord, as is our
+right, I will commit seppuku at sunset!\"|
+|
+She bows and walks toward the gateway.  All in the avenue and all on the
+battlements bow to her in homage.  She goes into the garden, her footsteps
+taking her to the secluded, rustic little tea house.  She goes inside and,
+once there, she weeps silently for all the men who have died." CR>
+		  <REMOVE ,KOJIMA>
+		  <REMOVE ,YAMAZAKI>
+		  <REMOVE ,MARIKOS-LITTER>
+		  <DEQUEUE I-DEPARTURE>
+		  <NEXT-SCENE>)>>
+
+<GLOBAL YAMAZAKI-ATTACK <>>
+
+<GLOBAL YAMAZAKI-ATTACKS
+	<LTABLE 0
+"The Captain leaps forward, his sword a whirling arc directed at your
+head!"
+"The Captain swings his sword, chopping viciously at your knees."
+"The Captain charges at you, his sword pointed straight at your belly."
+"The Captain screams \"Yaemon!\" and begins an overhand blow toward
+your head.">>
+
+<OBJECT YAMAZAKI
+	(SCENE S-DEPARTURE)
+	(DESC "Yamazaki")
+	(SYNONYM GRAY CAPTAIN LEADER YAMAZAKI DANZENJI)
+	(ADJECTIVE GRAY)
+	(FLAGS PERSON NOABIT NOTHEBIT SCOREBIT)
+	(HEALTH 4)
+	(GENERIC GENERIC-CAPTAIN-F)
+	(ACTION YAMAZAKI-F)>
+
+<ROUTINE YAMAZAKI-F ("OPT" (RARG <>) "AUX" H)
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<P? WHO (YAMAZAKI YOU)>
+		       <TELL
+"\"My name is Yamazaki Danzenji, Captain of the Fourth Legion!\"" CR>)
+		      (<VERB? STOP>
+		       <TELL
+G"\"You will not pass without papers!\"" CR>)
+		      (ELSE
+		       <WAKARIMASEN>)>)
+	       (<VERB? EXAMINE>
+		<COND (<FSET? ,PRSO ,DEAD>
+		       <TELL
+"He is dead.  You have killed him." CR>)
+		      (ELSE
+		       <TELL
+G"He is dressed in the Gray uniform." CR>)>)
+	       (<VERB? BOW>
+		<TELL
+"He looks you over carefully, considering his options." CR>)
+	       (<HOSTILE-VERB?>
+		<COND (<VERB? BITE PISS SPIT KICK>
+		       <TELL
+"He is clearly insulted that you would ever try such a barbaric action." CR>)
+		      (<OR <AND <PRSO? ,YAMAZAKI>
+				<NOT <PRSI? ,SWORDS <>>>>
+			   <AND <PRSI? ,YAMAZAKI>
+				<NOT <PRSO? ,SWORDS <>>>>>
+		       <TELL
+"You aren't taking him very seriously, are you?" CR>)
+		      (<FSET? ,YAMAZAKI ,DEAD>
+		       <TELL
+"You strike the already-dead Gray with your sword.  The onlookers are
+shocked at this insult to a worthy opponent!" CR>)
+		      (<NOT <FSET? ,YAMAZAKI ,RMUNGBIT>>
+		       <COND (<QUEUED? I-FIGHT>
+			      <FSET ,YAMAZAKI ,RMUNGBIT>
+			      <COND (<FSET? ,SWORDS ,WEARBIT>
+				     <FCLEAR ,SWORDS ,WEARBIT>
+				     <TELL
+"You draw your sword, and the Captain bows to you and does the same." CR>)
+				    (ELSE
+				     <SETG DELAYING-FIGHT? <>>
+				     <TELL
+"You strike at the Gray Captain, and he dodges expertly as he draws his
+sword.  He is clearly shocked that you would attack him before he had a
+chance to draw his sword." CR>)>)
+			     (ELSE
+			      <TELL
+"\"Not yet, Anjin-san!  Wait for my order!\"" CR>)>)
+		      (<ZERO? ,YAMAZAKI-ATTACK>
+		       <SETG DELAYING-FIGHT? <>>
+		       <TELL
+"You swing powerfully if somewhat inexpertly with your sword.  The
+Captain parries." CR>)
+		      (ELSE
+		       <SETG DELAYING-FIGHT? <>>
+		       <SETG YAMAZAKI-ATTACK <>>
+		       <SET H <GETP ,YAMAZAKI ,P?HEALTH>>
+		       <PUTP ,YAMAZAKI ,P?HEALTH <SET H <- .H 1>>>
+		       <TELL <PICK-ONE ,SWORD-ATTACKS> CR>
+		       <COND (<ZERO? .H>
+			      <FSET ,YAMAZAKI ,DEAD>
+			      <SETG OPPONENT <>>
+			      <COND (<ZERO? <GETP ,BROWNS ,P?COUNT>>
+				     <DEQUEUE I-FIGHT>)>
+			      <TELL CR
+"The captain stares at you silently for a moment, then his eyes glaze
+and he falls to the ground, dead." CR>
+			      <SCORE-OBJECT ,YAMAZAKI>)>
+		       <RTRUE>)>)>>
+
+<CONSTANT SWORD-ATTACKS
+	  <LTABLE 0
+"You swing, wishing for luck, for good karma, for a pistol, by
+God!  He parries, but the force of your blow is strong, and the tip
+manages to carve into his wrist."
+"You hold the blade before you, stabbing almost wildly with it, wondering
+why his attack is so formal.  You see an opening and plunge madly
+forward, wounding him in the chest."
+"You interpose your blade, and there is a ringing, almost bell-like
+crash as they meet.  You slide your blade around and manage to wound
+him.  He seems almost surprised."
+"Leaping and yelling, you charge him, and in an astonishing flurry he
+fights back, executing a daring turn and riposte, but he's off balance
+and you slice the back of his calf.">>
+
+<OBJECT KOJIMA
+	(SCENE S-DEPARTURE)
+	(DESC "Kojima")
+	(SYNONYM CAPTAIN LEADER KOJIMA)
+	(ADJECTIVE GRAY)
+	(FLAGS PERSON JAPANESEBIT NOABIT NOTHEBIT)
+	(HEALTH 4)
+	(GENERIC GENERIC-CAPTAIN-F)
+	(ACTION KOJIMA-F)>
+
+<ROUTINE KOJIMA-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<P? WHO (KOJIMA YOU)>
+		       <TELL
+"\"My name is Kojima Harumoto, Captain of the Sixth Legion!\"" CR>)
+		      (<VERB? STOP>
+		       <TELL
+G"\"You will not pass without papers!\"" CR>)
+		      (ELSE
+		       <WAKARIMASEN>)>)
+	       (<VERB? EXAMINE>
+		<COND (<FSET? ,PRSO ,DEAD>
+		       <TELL
+"He is dead.  Mariko has killed him." CR>)
+		      (ELSE
+		       <TELL
+G"He is dressed in the Gray uniform." CR>)>)
+	       (<HOSTILE-VERB?>
+		<COND (<FSET? ,KOJIMA ,DEAD>
+		       <TELL
+"You prepare to strike the already-dead Gray with your sword.  Mariko
+says, \"No, Anjin-san.  He was samurai.  He was doing his duty.\"" CR>)
+		      (ELSE
+		       <TELL
+"Mariko says, \"Anjin-san, this is my fight.  You must not
+shame me by fighting this man.  I am samurai, and this is my duty, and
+my honor.\"" CR>)>)>>
+
+<GLOBAL DELAYING-FIGHT? 0>
+
+<ROUTINE CAPTAIN-KILLS-YOU ()
+	 <CRLF>
+	 <JIGS-UP
+"The Captain, having decided you are a barbarian without honor, removes your
+head.">>
+
+<ROUTINE I-FIGHT ("AUX" (B <GETP ,BROWNS ,P?COUNT>))
+	 <COND (<NOT <FSET? ,YAMAZAKI ,DEAD>>
+		<SETG DELAYING-FIGHT? <+ ,DELAYING-FIGHT? 1>>
+		<COND (<B-NOT-STANDING?>
+		       <COND (<G? ,DELAYING-FIGHT? 4>
+			      <CAPTAIN-KILLS-YOU>)
+			     (ELSE
+			      <TELL CR
+"The Captain motions for you to stand and fight." CR>)>)
+		      (<OR <NOT <HELD? ,SWORDS>>
+			   <FSET? ,SWORDS ,WEARBIT>>
+		       <COND (<G? ,DELAYING-FIGHT? 4>
+			      <CAPTAIN-KILLS-YOU>
+			      <CRLF>
+			      <JIGS-UP
+"The Captain, having decided you are a barbarian without honor, removes your
+head.">)
+			     (ELSE
+			      <TELL CR
+"The Captain waits for you to draw your sword." CR>)>)
+		      (ELSE
+		       <COND (<NOT <FSET? ,YAMAZAKI ,RMUNGBIT>>
+			      <FSET ,YAMAZAKI ,RMUNGBIT>
+			      <THIS-IS-IT ,YAMAZAKI>
+			      <SETG OPPONENT ,YAMAZAKI>
+			      <TELL CR
+"The Captain bows formally, draws his sword, and prepares to attack you." CR>)
+			     (<NOT <ZERO? ,YAMAZAKI-ATTACK>>
+			      <TELL CR
+"The Captain swings his sword at you, but
+oddly, at the last second he seems to adjust his attack so that
+you are only slightly cut, rather than sliced in two." CR>)
+			     (ELSE
+			      <SETG YAMAZAKI-ATTACK T>
+			      <TELL CR <PICK-ONE ,YAMAZAKI-ATTACKS> CR>)>)>)>
+	 <COND (<NOT <ZERO? .B>>
+		<SET B <- .B <RANDOM 7>>>
+		<COND (<L=? .B 0> <SET B 0>)>
+		<PUTP ,BROWNS ,P?COUNT .B>
+		<COND (<ZERO? .B>
+		       <COND (<FSET? ,YAMAZAKI ,DEAD>
+			      <DEQUEUE I-FIGHT>)>
+		       <TELL CR
+"It is now one to one, the last Brown, blood-stained and wounded, already
+the victor of four duels.  The fresh Gray dispatches him easily and stands
+alone among the bodies." CR>)
+		      (ELSE
+		       <TELL CR
+"Each time a Gray falls, another calmy walks out of the waiting pack to
+join his comrades in the killing.  It is now " <GET ,NUMBERS .B> " Brown">
+		       <COND (<NOT <EQUAL? .B 1>>
+			      <TELL "s versus as many Grays." CR>)
+			     (ELSE
+			      <TELL " versus one Gray." CR>)>)>)>
+	 <RTRUE>>
+
+<END-SEGMENT>
+
+
+
+"S-SEPPUKU"
+
+<BEGIN-SEGMENT SEPPUKU>
+
+<ROOM FORMAL-GARDEN
+      (LOC ROOMS)
+      (SCENE S-SEPPUKU S-ESCAPE)
+      (DESC "Formal Garden")
+      (SYNONYM GARDEN)
+      (ADJECTIVE FORMAL)
+      (SCORE 1)
+      (FDESC
+"In a sudden hush, Mariko's maid Chimmoko comes out of the small gates
+to the garden and walks over to you and bows.  \"Anjin-san, please excuse
+me, my Mistress wishes to see you.  I will escort you.\"|
+|
+You get up, still deep in your reverie and your overpowering sense of
+doom.  The shadows are long now.|
+|
+Chimmoko goes over to Sumiyori.  \"Please excuse me, Captain, but my Lady
+asks you to please prepare everything.\"|
+|
+\"Where does she want it done?\"|
+|
+The maid points to the space in front of the arch.  \"There, Sire.\"|
+|
+Sumiyori is startled.  \"It's to be in public?  She's doing it for all
+to see?  But, well ... what about her second?\"|
+|
+\"She believes Lord Kiyama will honor her.\"|
+|
+\"And if he doesn't?\"|
+|
+\"I don't know, Captain.  She hasn't told me.\"  Chimmoko bows and then
+goes back to the gates and beckons you.  The Grays begin to follow but
+Chimmoko shakes her head and says her mistress had not bidden
+them.  They allow you to leave and you follow the servant into the garden.")
+      (LDESC
+"It is like a different world within the garden gates, verdant and serene,
+the sun on the treetops, birds chattering and insects foraging, the brook
+falling sweetly into the lily pond.  A tiny thatch-roofed tea house is
+beside the garden gate.  The courtyard of the keep, a world away, is to the
+east.")
+      (EAST TO COURTYARD IF GARDEN-GATE IS OPEN)
+      (OUT TO COURTYARD IF GARDEN-GATE IS OPEN)
+      (NORTH TO TEA-HOUSE)
+      (IN TO TEA-HOUSE)
+      (FLAGS ONBIT OUTSIDE)
+      (GLOBAL GARDEN-GATE TEA-HOUSE)
+      (ACTION FORMAL-GARDEN-F)>
+
+<ROUTINE FORMAL-GARDEN-F (RARG)
+	 <COND (<RARG? SCENE-SETUP>
+		<DRESS-BLACKTHORNE>
+		<QUEUE I-SEPPUKU -1>
+		<FSET ,FORTIFIED-GATE ,OPENBIT>
+		<MOVE ,MARIKO ,TEA-HOUSE>
+		<FCLEAR ,MARIKO ,SCOREBIT>
+		<FSET ,GARDEN-GATE ,OPENBIT>
+		<MOVE ,CHIMMOKO ,HERE>
+		<MOVE ,YABU ,FORECOURT>
+		<MOVE ,KIRITSUBO ,FORECOURT>
+		<MOVE ,SUMIYORI ,FORECOURT>
+		<MOVE ,ISHIDO ,GENERIC-OBJECTS>)
+	       (<RARG? ENTER>
+		<COND (<AND <SCENE? ,S-ESCAPE>
+			    <EQUAL? ,OHERE ,COURTYARD>
+			    <IN? ,MARIKO ,COURTYARD>>
+		       <QUEUE I-COME-BACK 6>
+		       <TELL
+"As you enter the garden, Mariko calls to you \"Anjin-san, we are leaving
+soon.  Come back!\"  You see her explain to Yabu what she said." CR CR>)>)>>
+
+<OBJECT GARDEN-GATE
+	(LOC LOCAL-GLOBALS)
+	(DESC "garden gate")
+	(SYNONYM GATE)
+	(ADJECTIVE GARDEN)
+	(FLAGS DOORBIT)>
+
+<OBJECT LILY-POND
+	(LOC FORMAL-GARDEN)
+	(DESC "lily pond")
+	(SYNONYM POND WATER)
+	(ADJECTIVE LILY)
+	(FLAGS NDESCBIT VEHBIT)
+	(ACTION LILY-POND-F)>
+
+<ROUTINE LILY-POND-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The lily pond glistens in the sun, its waters rippled by the
+gentle fall of water from the brook." CR>)
+	       (<VERB? BOARD THROUGH>
+		<TELL
+"To do so would disturb the serenity and peace of the garden and the
+pond." CR>)>>
+
+<ROOM TEA-HOUSE
+      (LOC ROOMS)
+      (SCENE S-SEPPUKU S-ESCAPE S-DEPARTURE S-MARIKO)
+      (DESC "Tea House")
+      (LDESC
+"The tea house is small, simple, and immaculate.  The doorway is small
+so that all will be humble, equal, the host and guest, the most high
+Lord and the merest samurai.")
+      (SYNONYM HOUSE)
+      (ADJECTIVE LITTLE TEA CHA-NO-YU)
+      (OUT TO FORMAL-GARDEN)
+      (SOUTH TO FORMAL-GARDEN)
+      (FLAGS ONBIT OUTSIDE)
+      (ACTION TEA-HOUSE-F)>
+
+<ROUTINE TEA-HOUSE-F (RARG)
+	 <COND (<RARG? BEG>
+		<COND (<P? KISS MARIKO>
+		       <TELL
+"You kiss her gently and tenderly." CR>)>)
+	       (<RARG? ENTER>
+		<COND (<SCENE? ,S-SEPPUKU>
+		       <THIS-IS-IT ,MARIKO>
+		       <SETG QCONTEXT ,MARIKO>
+		       <TELL
+"You go forward alone.  ">)>
+		<TELL "You ">
+		<COND (<FSET? ,SANDALS ,WEARBIT>
+		       <FCLEAR ,SANDALS ,WEARBIT>
+		       <MOVE ,SANDALS ,FORMAL-GARDEN>
+		       <TELL "slip your feet out of your thongs and ">)>
+		<TELL "walk
+up the three steps.  You have to stoop, almost to your knees, to go
+through the tiny screened doorway." CR CR>)>>
+
+<OBJECT GREEN-RIBBON
+	(OWNER MARIKO)
+	(DESC "green silk ribbon")
+	(SYNONYM RIBBON)
+	(ADJECTIVE GREEN SILK)
+	(FLAGS TAKEBIT)
+	(ACTION GREEN-RIBBON-F)>
+
+<ROUTINE GREEN-RIBBON-F ()
+	 <COND (<AND <VERB? DROP> <FSET? ,PRSO ,RMUNGBIT>>
+		<YOULL-HAVE-TO "untie it">)
+	       (<P? TIE RIBBON <>>
+		<COND (<NOT <HELD? ,PRSO>>
+		       <TELL G"You don't have it." CR>)
+		      (<NOT <FSET? ,PRSO ,RMUNGBIT>>
+		       <FSET ,PRSO ,RMUNGBIT>
+		       <TELL
+"You tie the ribbon to your sash in homage to Mariko's courage." CR>)
+		      (ELSE
+		       <TELL G"It already is." CR>)>)
+	       (<VERB? UNTIE>
+		<COND (<NOT <HELD? ,PRSO>>
+		       <TELL G"You don't have it." CR>)
+		      (<FSET? ,PRSO ,RMUNGBIT>
+		       <FCLEAR ,PRSO ,RMUNGBIT>
+		       <TELL
+"You untie the ribbon." CR>)
+		      (ELSE
+		       <TELL G"It already is." CR>)>)>>
+
+<OBJECT SUMIYORI
+	(SCENE S-SEPPUKU)
+	(DESC "Sumiyori")
+	(SYNONYM BROWN CAPTAIN LEADER SUMIYORI)
+	(ADJECTIVE CAPTAIN BROWN)
+	(FLAGS PERSON NOABIT NOTHEBIT)
+	(ACTION SUMIYORI-F)>
+
+<ROUTINE SUMIYORI-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<WAKARIMASEN>)
+	       (<VERB? WHO>
+		<TELL
+"Sumiyori is the senior officer of Toranaga's Browns in Osaka." CR>)>>
+
+<ROUTINE I-SEPPUKU ()
+	 <ZLINES ,SEPPUKU-CNT
+		 (DELAY
+		  <COND (<NOT <HERE? ,FORMAL-GARDEN ,TEA-HOUSE>>
+			 <MOVE ,CHIMMOKO ,HERE>
+			 <TELL CR
+"Mariko's servant Chimmoko urges you to return to the garden." CR>
+			 <RTRUE>)>)
+		 (<COND (<HERE? ,FORMAL-GARDEN>
+			 <MOVE ,CHIMMOKO ,HERE>
+			 <TELL CR
+"Chimmoko points to the little "I"cha-no-yu"" house." CR>)>)
+		 (DELAY
+		  <COND (<HERE? ,FORMAL-GARDEN>
+			 <MOVE ,CHIMMOKO ,HERE>
+			 <TELL CR
+"Chimmoko points imploringly at the tea house.  \"My mistress wishes
+to see you, please, Anjin-san,\" she says in the simplified Japanese
+that is all you can understand." CR>
+			 <RTRUE>)>)
+		 (<MOVE ,CHIMMOKO ,FORMAL-GARDEN>
+		  <COND (<HERE? ,TEA-HOUSE>
+			 <TELL CR
+"\"Thou,\" Mariko says in Latin, the language of love." CR>)>)
+		 (<MOVE ,MARIKO ,FORMAL-GARDEN>
+		  <COND (<HERE? ,TEA-HOUSE>
+			 <TELL CR
+"Chimmoko approaches.  \"It's time, Mistress.\"|
+|
+\"Is everything ready?\"  Mariko asks.|
+|
+\"Yes, Mistress.\"|
+|
+\"Wait for me beside the lily pond.\"  The footsteps go away.  Mariko
+turns back to you and kisses you gently.  She bows to you and goes
+through the doorway." CR>)
+			(<HERE? ,FORMAL-GARDEN>
+			 <TELL CR
+"Chimmoko enters the tea house, then re-emerges a moment
+later.  Mariko follows her, and bows to you as she goes by." CR>)>)
+		 (DELAY
+		  <COND (<HERE? ,TEA-HOUSE> <RTRUE>)>)
+		 (<MOVE ,GREEN-RIBBON ,FORMAL-GARDEN>
+		  <COND (<HERE? ,FORMAL-GARDEN>
+			 <TELL CR
+"Mariko stops by the lily pond and undoes her obi and lets it
+fall.  Chimmoko helps her out of her blue kimono.  Beneath it Mariko wears
+the most brilliant white kimono and obi you have ever seen.  It is
+a formal death kimono.  She
+unties the green ribbon from her hair and casts it aside." CR>)>)
+		 (<FCLEAR ,COURTYARD ,TOUCHBIT>
+		  <MOVE ,MARIKO ,COURTYARD>
+		  <MOVE ,CHIMMOKO ,COURTYARD>
+		  <COND (<HERE? ,FORMAL-GARDEN ,FORECOURT ,COURTYARD>
+			 <TELL CR
+"Clad completely in white, Mariko walks from the garden into the courtyard,
+never looking at you." CR>)>)
+		 (<FCLEAR ,FORECOURT ,TOUCHBIT>
+		  <MOVE ,MARIKO ,FORECOURT>
+		  <MOVE ,CHIMMOKO ,FORECOURT>
+		  <COND (<HERE? ,FORMAL-GARDEN ,FORECOURT ,COURTYARD>
+			 <TELL CR
+"Mariko walks to the gateway, where eight tatamis have been laid out in
+the center of the main gate." CR>)>)
+		 (<FSET ,MARIKO ,SITTING>
+		  <COND (<HERE? ,FORECOURT>
+			 <TELL CR
+"At a sign from Sumiyori everyone bows.  Mariko bows to them.  Four samurai
+come forward and spread a crimson coverlet over the tatamis.|
+|
+Mariko goes to the crimson square and kneels in the center, in front of
+the tiny white cushion.  Her right hand brings out her stiletto dagger
+from her white obi and she places it on the cushion in front of
+her.  Mariko arranges the skirts of her kimono perfectly, Chimmoko helping
+her, tying a small white blanket around her waist with the cord.  You
+know that this is to prevent her skirts being blooded and disarranged
+by her death throes." CR>)
+			(<HERE? ,COURTYARD>
+			 <TELL CR
+"Through the crowd to the south you can see Mariko in the forecourt preparing
+for her death." CR>)>)
+		 (<COND (<HERE? ,FORECOURT>
+			 <TELL CR
+"Serene and prepared, Mariko looks up at the castle donjon.  Sun still
+dominates the upper story, glittering off the golden tiles.  Rapidly
+the flaming light mounts the spire.  Then it disappears.|
+|
+Servants are lighting flares along the avenue.  When they finish, they
+flee as quickly and silently as they arrived.|
+|
+Mariko reaches forward and straightens the knife.  She looks through
+the gateway to the far end of the avenue.  It is as still and as empty
+as it had ever been." CR>)
+			(<HERE? ,COURTYARD>
+			 <TELL CR
+"The crowd is such that you can no longer see Mariko." CR>)>)
+		 (<COND (<HERE? ,FORECOURT>
+			 <TELL CR
+"Mariko looks once again at the knife.  She says \"Kasigi Yabu-sama!  It
+seems Lord Kiyama has declined to assist me.  Please, I would be honored
+if you would be my second.|
+|
+\"It is my honor,\" Yabu replies.  He bows, gets to his feet, and stands
+behind her to her left.  His sword sings as it slides from its
+scabbard.  \"I am ready, Lady,\" he says.|
+|
+\"Please wait until I make the second cut.\"" CR>)>)
+		 (<MOVE ,ISHIDO ,FORECOURT>
+		  <COND (<HERE? ,FORECOURT>
+			 <MARGINAL-PIC ,P-SEPPUKU>
+			 <TELL CR
+"With her right hand, Mariko makes the sign of the cross, then leans
+forward and takes the knife and touches it to her lips as though to
+taste the polished steel.  She changes her grip and holds the knife
+firmly with her right hand under the left side of her throat.|
+|
+Suddenly flares round the far end of the avenue.  A retinue
+approaches.  Ishido is at their head.|
+|
+Mariko does not move the knife.  Yabu is as still as a coiled
+spring.  \"Lady,\" he says, \"do you wait or are you continuing?  I wish to be
+perfect for you.\"" CR>)
+			(ELSE
+			 <TELL CR
+"You can hear a subdued whispering coming from all around." CR>)>)
+		 (<COND (<HERE? ,FORECOURT>
+			 <TELL CR
+"\"I wait ... we ... I\"  Her hand lowers the knife.  Yabu lowers his
+sword and it hisses back into his scabbard.|
+|
+Ishido stands at the gateway.  \"It's not sunset yet, Lady.  Are you
+so keen to die?\"|
+|
+\"No, Lord General.  Just to obey my Lord ... \" She holds her hands
+together to stop their shaking.  A rumble of anger goes through the
+Browns at Ishido's arrogant rudeness." CR CR
+"Ishido says loudly, \"The Lady Ochiba begged the Regents on behalf
+of the Heir to make an exception in your case.  Here are permits for
+you to leave at dawn tomorrow.\"  He shoves them into the hands of
+Sumiyori.|
+|
+\"Sire?\" Mariko says, without understanding, her voice threadbare." CR CR
+"\"You are free to leave.  At dawn,\" barks Ishido.|
+|
+\"And Kiritsubo-san and the Lady Sazuko?\"|
+|
+\"Isn't that also part of your 'duty?'  Their permits are there also.\"" CR CR
+"Ishido addresses the others.  \"Any ladies may apply, any samurai.  I've
+said before, it's stupid to leave for seventeen days, it's insulting to
+flout the Heir's welcome ...\" -- his ruthless gaze goes back to Mariko --
+\"or to pressure them with threats of seppuku!\"" CR>)
+			(ELSE
+			 <TELL CR
+"You can hear a building, burgeoning noise from all around the
+forecourt." CR CR
+"As suddenly as it started, the noise ceases." CR>)>)
+		 (<MOVE ,ISHIDO ,GENERIC-OBJECTS>
+		  <COND (<HERE? ,FORECOURT>
+			 <TELL CR
+"Ishido turns on his heel, shouts an order to the Grays, and walks off." CR>)
+			(ELSE
+			 <TELL CR
+"From the forecourt you can hear the sound of marching feet." CR>)>)
+		 (<FSET ,MARIKO ,SCOREBIT>
+		  <SETG MARIKO-WON-FLAG T>
+		  <FCLEAR ,MARIKO ,SITTING>
+		  <COND (<HERE? ,FORECOURT>
+			 <TELL CR
+"Yabu turns to Mariko.  \"Lady, it's over now.  You've ... you've won.  You've
+won.\"|
+|
+Mariko tries to grope to her feet.  She fails.  She tries a second
+time.  Again she fails.  Her hands go to the crimson again, and this time she
+forces herself upright.  She wavers and almost falls, then her feet
+move and slowly she totters across the crimson, reeling helplessly toward
+the main door." CR>)>)
+		 (<DEQUEUE I-SEPPUKU>
+		  <COND (<HERE? ,FORECOURT>
+			 <TELL CR
+"Mariko teeters helplessly, unable to move forward any further.  There is
+a hushed silence, everyone in the forecourt watching her.  She falls to
+the ground." CR>)
+			(ELSE
+			 <TELL CR
+"From the forecourt is hushed silence, as though all of Osaka is waiting
+for something, and then a sigh, just barely audible though thousands of
+throats make it, comes over the walls." CR>)>
+		  <NEXT-SCENE>)>>
+
+<GLOBAL MARIKO-WON-FLAG <>>
+
+<END-SEGMENT>
diff --git a/maze.zil b/maze.zil
new file mode 100644
index 0000000..9ba6a11
--- /dev/null
+++ b/maze.zil
@@ -0,0 +1,756 @@
+"MAZE for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc.  All Rights Reserved."
+
+<FILE-FLAGS SENTENCE-ENDS?>
+
+<BEGIN-SEGMENT MAZE>
+
+<CONSTANT MAZE-WINDOW 3>
+
+<CONSTANT MWALL 128>
+
+<DEFMAC MSTREET? ('VAL)
+   <FORM ZERO? <FORM BAND .VAL ,MWALL>>>
+
+<OBJECT HOUSE
+	(LOC LOCAL-GLOBALS)
+	(SYNONYM HOUSE HOUSES SHOP SHOPS)
+	(DESC "house")
+	(FLAGS NDESCBIT)
+	(ACTION HOUSE-F)>
+
+<ROUTINE HOUSE-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"Houses and shops crowd the street on all sides, some dark and some
+lit by oil lamps flickering through the paper panels of the shojis." CR>)
+	       (<VERB? ENTER BOARD THROUGH>
+		<TELL
+"As you start to move off from the cortege, Mariko calls you back,
+speaking in Latin.  \"No, Pilot, that is not the way.\"" CR>)>>
+
+<OBJECT RONIN
+	(SYNONYM RONIN DETACHMENT)
+	(DESC "detachment of ronin")
+	(FLAGS PERSON PLURAL JAPANESEBIT)
+	(ACTION RONIN-F)>
+
+<ROUTINE RONIN-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<TELL
+"The ronin take orders only from Toranaga." CR>
+		<END-QUOTE>)>>
+
+<OBJECT FISH-GATE
+	(SYNONYM GATE FISH)
+	(ADJECTIVE BATTERED ETCHED)
+	(DESC "gate")
+	(FLAGS NDESCBIT SCOREBIT)
+	(ACTION FISH-GATE-F)>
+
+<ROUTINE FISH-GATE-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"It's just a weathered old gate with a fish carved on it." CR>)>>
+
+<OBJECT AMBUSHERS
+	(SYNONYM AMBUSHER BOWMAN FIGURE SHAPE
+	 	 AMBUSHERS BOWMEN FIGURES SHAPES)
+	(ADJECTIVE SHADOWY DIM)
+	(DESC "dim figures")
+	(FLAGS PERSON JAPANESEBIT PLURAL)
+	(DESCFCN AMBUSHERS-DESC)
+	(ACTION AMBUSHERS-F)>
+
+<ROUTINE AMBUSHERS-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (ELSE
+		<TELL
+"Dim figures can be seen on one of the tiled roofs of a nearby house.">)>>
+
+<ROUTINE AMBUSHERS-F ("OPT" RARG)
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<TELL G"There is no response." CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"From here, in the dark, they are merely dim dark outlines." CR>)>>
+
+<OBJECT MESSENGER
+	(SYNONYM MESSENGER MAN SAMURAI GRAY)
+	(ADJECTIVE GRAY)
+	(DESC "messenger")
+	(FLAGS PERSON JAPANESEBIT INVISIBLE SCOREBIT)
+	(GENERIC GENERIC-MAN-F)
+	(ACTION MESSENGER-F)>
+
+<ROUTINE MESSENGER-F ("OPT" (RARG <>))
+	 <COND (<AND <IN? ,MESSENGER ,LOCAL-GLOBALS>
+		     <NOT <PASSIVE-VERB?>>>
+		<TELL "He's gone!" CR>)
+	       (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<WAKARIMASEN>)
+	       (<OR <VERB? STOP>
+		    <HOSTILE-VERB?>>
+		<COND (<FSET? ,MESSENGER ,DEAD>
+		       <TELL "Buntaro hacked him to pieces." CR>)
+		      (<NOT <FSET? ,MESSENGER ,RMUNGBIT>>
+		       <FSET ,MESSENGER ,RMUNGBIT>
+		       <TELL
+"You stretch to intercept the man, grabbing and nearly tackling him, and he
+tumbles to the ground." CR>)
+		      (ELSE
+		       <TELL
+"Desperately you struggle with the messenger and manage to knock him down
+a second time." CR>
+		       <SCORE-OBJECT ,MESSENGER>)>)>>
+
+<ROOM AMBUSH-SITE
+      (LOC ROOMS)
+      (DESC "City Street")
+      (LDESC
+"This is a dark, deserted street in the middle of Osaka.")
+      (SYNONYM STREET)
+      (ADJECTIVE CITY)
+      (FLAGS ONBIT OUTSIDE)
+      (GLOBAL MESSENGER)
+      (ACTION AMBUSH-SITE-F)>
+
+<ROUTINE AMBUSH-SITE-F ("OPT" (RARG <>))
+	 <COND (<RARG? BEG>
+		<COND (<VERB? WALK>
+		       <TELL
+"You are pinned down by the attack.  To run would be suicidal!" CR>)
+		      (<AND <P? (PUSH TAKE HELP PULL-BEHIND) MARIKO>
+			    <FSET? ,MARIKOS-LITTER ,SCOREBIT>>
+		       <B-LIE-DOWN>
+		       <TELL
+"You roll for cover, taking Mariko with you into the lee of the tumbled
+litter." CR>
+		       <SCORE-OBJECT ,MARIKOS-LITTER>)
+		      (<AND <OR <VERB? DODGE>
+				<P? (HIDE-BEHIND HIDE-UNDER) MARIKOS-LITTER>>
+			    <FSET? ,MARIKOS-LITTER ,SCOREBIT>>
+		       <B-LIE-DOWN>
+		       <TELL
+"You roll for cover into the lee of the tumbled litter." CR>)>)>>
+
+<GLOBAL AMBUSH-PROB 2>
+
+<GLOBAL XAMBUSH 0>
+<GLOBAL YAMBUSH 0>
+
+<ROUTINE I-AMBUSH-START ()
+	 <COND (<OR <G? ,AMBUSH-PROB 100>
+		    <PROB ,AMBUSH-PROB>>
+		<SETG XAMBUSH ,X>
+		<SETG YAMBUSH ,Y>
+		<MOVE-ALL ,MAZE ,AMBUSH-SITE>
+		<COND (<IN? ,BLACKTHORNE ,MARIKOS-LITTER>
+		       <MOVE ,MARIKOS-LITTER ,MAZE>)
+		      (ELSE
+		       <MOVE ,BLACKTHORNE ,MAZE>)>
+		<MOVE ,AMBUSHERS ,AMBUSH-SITE>
+		<QUEUE I-AMBUSH -1>
+		<TELL CR
+"The arrows come out of the night, the first impaling the captain
+through the throat.  His lungs fill with molten fire and death
+swallows him.  His last thought is one of wonder, for did not Lord
+Kiyama, his master, tell him the ambush was to be later, beside
+the wharves, and directed at the pirate?" CR CR>
+		<GOTO ,AMBUSH-SITE>)
+	       (ELSE
+		<QUEUE I-AMBUSH-START 5>
+		<SETG AMBUSH-PROB <+ ,AMBUSH-PROB 6>>
+		<RFALSE>)>>
+
+<ROUTINE I-AMBUSH ()
+	 <ZLINES ,AMBUSH-CNT
+		 (<TELL CR
+"An arrow slams into the litter post an inch from your head!  Two
+arrows pierce the curtains of Kiritsubo's litter, and another strikes
+one of the maids in the waist.  As she screams, the litter bearers
+take to their heels into the darkness.  Mariko ">
+		  <COND (<FSET? ,MARIKOS-LITTER ,SCOREBIT>
+			 <TELL "stands in the open">)
+			(ELSE
+			 <TELL "clings to you">)>
+		  <TELL ",
+staring in shock at the dying maid." CR>)
+		 (<TELL CR
+"A shower of arrows straddles both litters.">
+		  <COND (<FSET? ,MARIKOS-LITTER ,SCOREBIT>
+			 <FSET ,MARIKO ,DEAD>
+			 <TELL
+" One strikes Mariko in the back as she starts to run for cover.  She
+falls to the ground and is still." CR>
+			 <FAILED-SCENE>)
+			(ELSE
+			 <TELL
+" One thuds into the ground where Mariko was an instant ago." CR>)>)
+		 (<MOVE ,TORANAGA ,HERE>
+		  <REMOVE ,TORANAGA-IN-DRAG>
+		  <FSET ,CURTAINS ,OPENBIT>
+		  <MARGINAL-PIC ,P-IN-DRAG T ,P-IN-DRAG-CORNER T>
+		  <TELL CR
+"Buntaro shields Toranaga's litter with his body as best he can, then
+whips open the curtains.  Two arrows are imbedded in Toranaga's chest and
+side,
+and he jerks them out of the armor he wears beneath the kimono.  He
+fights his way out of the litter and stands in the street, sword
+drawn, an incongruous figure in kimono and hat." CR>)
+		 (<REMOVE ,AMBUSHERS>
+		  <TELL CR
+"Another volley of arrows comes out of the darkness, one missing you
+so narrowly that it takes skin off of your cheek, and then all is silent.|
+|
+Buntaro and some of his men are near the wall in pursuit but the
+ambushers vanish into the blackness.  A dozen men race in pursuit but
+all know it's hopeless." CR>)
+		 (<MOVE ,MESSENGER ,HERE>
+		  <FCLEAR ,MESSENGER ,INVISIBLE>
+		  <THIS-IS-IT ,MESSENGER>
+		  <SETG OPPONENT ,MESSENGER>
+		  <TELL CR
+"One of the officer Grays says, \"Toranaga!\" and though it is said
+quietly, everyone hears.  Here, incredibly, is the enemy of his
+master, free, outside the castle walls.  \"You will wait here, Lord
+Toranaga.  You,\" he snaps at one of his men, \"report to Lord Ishido
+at once!\"  The man races toward you, heading back toward the castle!" CR>)
+		 (DELAY
+		  <COND (<FSET? ,MESSENGER ,SCOREBIT>
+			 <COND (<AND <FSET? ,MESSENGER ,RMUNGBIT>
+				     <NOT <FSET? ,MESSENGER ,SURFACEBIT>>>
+				<FSET ,MESSENGER ,SURFACEBIT>
+				<TELL CR
+"Immediately he rolls and is on his feet again!" CR>)
+			       (ELSE
+				<MOVE ,MESSENGER ,LOCAL-GLOBALS>
+				<FCLEAR ,MESSENGER ,SCOREBIT>
+				<TELL CR
+"This time the messenger scuttles away from you and is off like a hare
+chased by hounds." CR>)>
+			 <RTRUE>)
+			(<AND <NOT <IN? ,MESSENGER ,LOCAL-GLOBALS>>
+			      <NOT <FSET? ,MESSENGER ,DEAD>>>
+			 <FSET ,MESSENGER ,DEAD>
+			 <TELL CR
+"This time Buntaro, with a vicious chop of his sword, cuts the man down." CR>
+			 <RTRUE>)>)
+		 (<REPLACE-SYNONYM ,CORTEGE ,W?GRAYS ,W?BROWNS>
+		  <MOVE ,GRAYS ,HERE>
+		  <THIS-IS-IT ,GRAYS>
+		  <TELL CR
+"The rest of the Grays attack, trying to reach Toranaga.  One officer
+whips out his two-handed sword and leaps for Toranaga but Buntaro
+parries.  The Browns and Grays, all intermixed, erupt into a swirling
+melee.|
+|
+The Grays fight courageously.  Four join in a suicidal charge at
+Toranaga.  The Browns break it and the Grays regroup and charge
+again.  Then a senior officer orders three to retreat for help and the
+rest to guard the retreat." CR>)
+		 (<DEQUEUE I-AMBUSH>
+		  <COND (<FSET? ,MESSENGER ,DEAD> <REMOVE ,MESSENGER>)
+			(ELSE <QUEUE I-CAUGHT 150>)>
+		  <REMOVE ,GRAYS>
+		  <MOVE-ALL ,AMBUSH-SITE ,MAZE>
+		  <MOVE ,BLACKTHORNE ,AMBUSH-SITE>
+		  <TELL CR
+"The three Grays tear off, and though Buntaro kills one, the other two
+are only wounded.  The rest die." CR CR>
+		  <GOTO ,MAZE>)>>
+
+<ROUTINE I-CAUGHT ()
+	 <COND (<HERE? MAZE>
+		<LEAVE-MAZE>
+		<TELL CR
+"Ahead of you, a mass of Gray archers materializes out of the night.  Above,
+a mass of fireworks blooms in warning from the castle.  Toranaga turns,
+ordering the cortege to retreat down an alley, but there are Grays there
+too.  The party is surrounded!" CR>
+		<JIGS-UP>
+		<RFATAL>)>>
+
+<ROOM MAZE
+      (LOC ROOMS)
+      (SYNONYM STREETS)
+      (ADJECTIVE CITY)
+      (DESC "City Streets")
+      (FLAGS OUTSIDE ONBIT)
+      (GLOBAL HOUSE)
+      (MOUSE MAZE-MOUSE-F)
+      (ACTION MAZE-F)>
+
+<ROUTINE MAZE-F (RARG "AUX" XX YY OXX OYY)
+	 <COND (<RARG? LOOK>
+		<TELL
+"This maze of streets and alleys extends from the great castle to the
+harbor.  At night, it is a nightmare of blind alleys, twisting overhung
+streets, and shadowy hurrying shapes." CR>)
+	       (<RARG? ENTER>
+		<PICSET ,MAZE-PICS>
+		<COND (<NOT <FSET? ,HERE ,TOUCHBIT>>
+		       <MOVE-ALL ,CITY ,MAZE>
+		       <TELL
+"The cortege continues through the winding, curling city streets,
+the pedestrians bowing and the very poor on their knees until you
+pass." CR CR>
+		       <QUEUE I-AMBUSH-START 5>
+		       <TELL "[Building Osaka.]" CR CR>
+		       <BUILDMAZE>)>
+		<COND (<EQUAL? ,OHERE ,WAREHOUSE>
+		       <SET XX ,XGOAL>
+		       <SET YY ,YGOAL>
+		       <TELL
+"You have returned to the"G" maze of back streets and alleys." CR>)
+		      (<EQUAL? ,OHERE ,AMBUSH-SITE>
+		       <SET XX ,XAMBUSH>
+		       <SET YY ,YAMBUSH>
+		       <TELL
+"The cortege re-forms and prepares to continue the escape.  The urgency is
+now great, as the escaped grays will spread the alarm." CR>)
+		      (ELSE
+		       <SET XX ,XSTART>
+		       <SET YY ,YSTART>
+		       <TELL
+"You have entered a"G" maze of back streets and alleys." CR>)>
+		<CRLF>
+		<TYPE-ANY-KEY>
+		<DISPLAY-MAZE>
+		<MAZE-MOVE .XX .YY>
+		<RTRUE>)
+	       (<RARG? LEAVE>
+		<LEAVE-MAZE>)
+	       (<RARG? BEG>
+		<COND (<VERB? DEFINE>
+		       <CLEAR ,MAZE-WINDOW>
+		       <RFALSE>)
+		      (<VERB? WALK>
+		       <REPEAT ((MOVED? <>))
+			  <SET XX ,X>
+			  <SET YY ,Y>
+			  <SET OXX ,X>
+			  <SET OYY ,Y>
+			  <COND (<AND <EQUAL? ,P-WALK-DIR ,P?NORTH>
+				      <G? .YY 0>>
+				 <SET YY <- .YY 1>>)
+				(<AND <EQUAL? ,P-WALK-DIR ,P?EAST>
+				      <L? .XX <- ,MAZE-WIDTH 1>>>
+				 <SET XX <+ .XX 1>>)
+				(<AND <EQUAL? ,P-WALK-DIR ,P?WEST>
+				      <G? .XX 0>>
+				 <SET XX <- .XX 1>>)
+				(<AND <EQUAL? ,P-WALK-DIR ,P?SOUTH>
+				      <L? .YY <- ,MAZE-HEIGHT 1>>>
+				 <SET YY <+ .YY 1>>)
+				(<AND <EQUAL? ,P-WALK-DIR ,P?NE>
+				      <L? .XX <- ,MAZE-WIDTH 1>>
+				      <G? .YY 0>>
+				 <SET XX <+ .XX 1>>
+				 <SET YY <- .YY 1>>)
+				(<AND <EQUAL? ,P-WALK-DIR ,P?SE>
+				      <L? .XX <- ,MAZE-WIDTH 1>>
+				      <L? .YY <- ,MAZE-HEIGHT 1>>>
+				 <SET XX <+ .XX 1>>
+				 <SET YY <+ .YY 1>>)
+				(<AND <EQUAL? ,P-WALK-DIR ,P?SW>
+				      <G? .XX 0>
+				      <L? .YY <- ,MAZE-HEIGHT 1>>>
+				 <SET XX <- .XX 1>>
+				 <SET YY <+ .YY 1>>)
+				(<AND <EQUAL? ,P-WALK-DIR ,P?NW>
+				      <G? .XX 0>
+				      <G? .YY 0>>
+				 <SET XX <- .XX 1>>
+				 <SET YY <- .YY 1>>)
+				(ELSE
+				 <TELL "You can't go that way." CR>
+				 <RTRUE>)>
+			  <COND (<AND <EQUAL? .XX ,XSTART>
+				      <EQUAL? .YY ,YSTART>>
+				 <GOTO ,CITY>
+				 <RTRUE>)
+				(<AND <EQUAL? .XX ,XGOAL>
+				      <EQUAL? .YY ,YGOAL>>
+				 <GOTO ,WAREHOUSE>
+				 <RTRUE>)
+				(<AND <MSTREET? <MGETB .XX .YY>>
+				      <OR <EQUAL? .XX .OXX>
+					  <EQUAL? .YY .OYY>
+					  <MSTREET? <MGETB .XX .OYY>>
+					  <MSTREET? <MGETB .OXX .YY>>>>
+				 <MAZE-MOVE .XX .YY>
+				 <COND (<AND <EQUAL? .XX ,XFISH>
+					     <EQUAL? .YY ,YFISH>
+					     <NOT <LOC ,FISH-GATE>>>
+					<MOVE ,FISH-GATE ,HERE>
+					<COND (<FSET? ,FISH-GATE ,SCOREBIT>
+					       <MOVE ,RONIN ,HERE>
+					       <SCORE-OBJECT ,FISH-GATE>
+					       <TELL
+G"You make your way through the deserted streets.">
+					       <TELL
+" Toranaga stops the cortege outside a battered gate.  A fish is etched
+into its timbers.  He knocks in code.  The door opens at once, and an
+ill-kempt samurai bows.  \"Bring your men and follow me,\" Toranaga
+says.  Fifteen men, dressed as "I"ronin"" follow him and slip into
+place as advance and rear guard.  Others spread the alarm to other
+secret cadres.  Soon there are fifty troops with you and a hundred
+guarding your flanks." CR>)>)
+				       (<AND <EQUAL? .OXX ,XFISH>
+					     <EQUAL? .OYY ,YFISH>>
+					<REMOVE ,FISH-GATE>)>
+				 <COND (<EQUAL? ,P-WALK-DIR ,P?NORTH ,P?SOUTH>
+					<COND (<OR <MSTREET?
+						    <MGETB <- .XX 1> .YY>>
+						   <MSTREET?
+						    <MGETB <+ .XX 1> .YY>>>
+					       <RETURN>)
+					      (ELSE
+					       <SET MOVED? T>)>)
+				       (<EQUAL? ,P-WALK-DIR ,P?EAST ,P?WEST>
+					<COND (<OR <MSTREET?
+						    <MGETB .XX <- .YY 1>>>
+						   <MSTREET?
+						    <MGETB .XX <+ .YY 1>>>>
+					       <RETURN>)
+					      (ELSE
+					       <SET MOVED? T>)>)>)
+				(.MOVED? <RETURN>)
+				(ELSE
+				 <TELL "There's a house there." CR>
+				 <RTRUE>)>>
+		       <TELL
+G"You make your way through the deserted streets." CR>)
+		      (<AND <VERB? DROP>
+			    <IN? ,WINNER ,MAZE>>
+		       <COND (<IDROP>
+			      <REMOVE ,PRSO>
+			      <TELL
+CTHE ,PRSO " drops to the ground and is lost from sight in the dark and
+confusion." CR>)
+			     (ELSE <RTRUE>)>)>)>>
+
+<ROUTINE LEAVE-MAZE ("AUX" YY)
+	 <SET YY <+ <WINGET ,S-TEXT ,WYPOS> <WINGET ,S-TEXT ,WTOP>>>
+	 <SETUP-TEXT-AND-STATUS>
+	 <SCREEN ,S-TEXT>
+	 <CURSET <- .YY <WINGET ,S-TEXT ,WTOP>> 1>>
+
+<CONSTANT MAZE-PICS
+	  <TABLE P-MAZE-WALL
+		 P-MAZE-STREET
+		 P-MAZE-PARTY
+		 P-MAZE-CASTLE
+		 P-MAZE-DOCK
+		 P-MAZE-FISH
+		 P-MAZE-BACKGROUND
+		 0>>
+
+<ROUTINE MAZE-MOUSE-F (TRM "AUX" (DIR <>) WX WY
+		       (BX <GET ,MAZE-BOX-TBL 1>) (BY <GET ,MAZE-BOX-TBL 0>))
+	 <SET WY
+	      <+ <WINGET ,MAZE-WINDOW ,WTOP>
+		 ,YOFFSET
+		 <* ,Y .BY>
+		 </ .BY 2>>>
+	 <SET WX
+	      <+ <WINGET ,MAZE-WINDOW ,WLEFT>
+		 ,XOFFSET
+		 <* ,X .BX>
+		 </ .BX 2>>>
+	 <SET WY <- ,MOUSE-LOC-Y .WY>>
+	 <SET WX <- ,MOUSE-LOC-X .WX>>
+	 <COND (<G=? .WX 0> ;"right side"
+		<COND (<L? .WY 0> ;"top right"
+		       <SET WY <- .WY>>
+		       <COND (<G? .WX <* .WY 3>>
+			      <SET DIR ,EAST-STR>)
+			     (<G? .WY <* .WX 3>>
+			      <SET DIR ,NORTH-STR>)
+			     (ELSE
+			      <SET DIR ,NE-STR>)>)
+		      (ELSE ;"bottom right"
+		       <COND (<G? .WX <* .WY 3>>
+			      <SET DIR ,EAST-STR>)
+			     (<G? .WY <* .WX 3>>
+			      <SET DIR ,SOUTH-STR>)
+			     (ELSE
+			      <SET DIR ,SE-STR>)>)>)
+	       (<L? .WY 0> ;"top left"
+		<SET WY <- .WY>>
+		<SET WX <- .WX>>
+		<COND (<G? .WX <* .WY 3>>
+		       <SET DIR ,WEST-STR>)
+		      (<G? .WY <* .WX 3>>
+		       <SET DIR ,NORTH-STR>)
+		      (ELSE
+		       <SET DIR ,NW-STR>)>)
+	       (ELSE ;"bottom left"
+		<SET WX <- .WX>>
+		<COND (<G? .WX <* .WY 3>>
+		       <SET DIR ,WEST-STR>)
+		      (<G? .WY <* .WX 3>>
+		       <SET DIR ,SOUTH-STR>)
+		      (ELSE
+		       <SET DIR ,SW-STR>)>)>
+	 <COND (<AND <L=? .WX </ .BX 2>> <L=? .WY </ .BY 2>>>
+		<RFALSE>)
+	       (.DIR
+		<ADD-TO-INPUT .DIR 13>
+		<RETURN 13>)
+	       (ELSE
+		<RFALSE>)>>
+
+<CONSTANT NORTH-STR <LTABLE (PURE STRING) "north">>
+<CONSTANT SOUTH-STR <LTABLE (PURE STRING) "south">>
+<CONSTANT EAST-STR <LTABLE (PURE STRING) "east">>
+<CONSTANT WEST-STR <LTABLE (PURE STRING) "west">>
+<CONSTANT SE-STR <LTABLE (PURE STRING) "se">>
+<CONSTANT SW-STR <LTABLE (PURE STRING) "sw">>
+<CONSTANT NE-STR <LTABLE (PURE STRING) "ne">>
+<CONSTANT NW-STR <LTABLE (PURE STRING) "nw">>
+
+<CONSTANT MAZE-BOX-TBL <TABLE 0 0>>
+
+"Mechanics of building and displaying maze."
+
+<ROUTINE MGETB (X Y)
+	 <GETB ,MAZE-MAP <+ <* .Y ,MAZE-WIDTH> .X>>>
+
+<ROUTINE MPUTB (X Y VAL)
+	 <PUTB ,MAZE-MAP <+ <* .Y ,MAZE-WIDTH> .X> .VAL>>
+
+<GLOBAL YOFFSET 0>
+<GLOBAL XOFFSET 0>
+
+<ROUTINE DISPLAY-MAZE-PIC (VAL Y X "AUX" BY BX OY OX)
+	 <COND (<NOT <ZERO? .VAL>> ;<EQUAL? .VAL ;!\#>
+		<SET BY <GET ,MAZE-BOX-TBL 0>>
+		<SET BX <GET ,MAZE-BOX-TBL 1>>
+		<DISPLAY .VAL ;<MAZE-PIC .VAL>
+			 <+ 1 ,YOFFSET <* .Y .BY>>
+			 <+ 1 ,XOFFSET <* .X .BX>>>)>>
+
+;<ROUTINE MAZE-PIC (VAL)
+	 <COND (<EQUAL? .VAL !\B> ,P-MAZE-PARTY)
+	       (<EQUAL? .VAL !\*> ,P-MAZE-WALL)
+	       (<EQUAL? .VAL !\ > ,P-MAZE-STREET)
+	       (<EQUAL? .VAL !\C> ,P-MAZE-CASTLE)
+	       (<EQUAL? .VAL !\D> ,P-MAZE-DOCK)
+	       (<EQUAL? .VAL !\F> ,P-MAZE-FISH)>>
+
+<ROUTINE MAZE-MOVE (X Y)
+	 <SCREEN ,MAZE-WINDOW>
+	 <SETG X .X>
+	 <SETG Y .Y>
+	 <MPUTC <- .X 1> <- .Y 1>>
+	 <MPUTC .X <- .Y 1>>
+	 <MPUTC <+ .X 1> <- .Y 1>>
+	 <MPUTC <- .X 1> .Y>
+	 <MPUTC <+ .X 1> .Y>
+	 <MPUTC <- .X 1> <+ .Y 1>>
+	 <MPUTC .X <+ .Y 1>>
+	 <MPUTC <+ .X 1> <+ .Y 1>>
+	 <MPUTC .X .Y ,P-MAZE-PARTY ;!\B>
+	 <SCREEN ,S-TEXT>>
+
+<ROUTINE MPUTC (X Y "OPT" (VAL <>) "AUX" OVAL)
+	 <COND (<VALID .X .Y>
+		<SET OVAL <MGETB .X .Y>>
+		<COND (<NOT .VAL>
+		       <SET VAL .OVAL>
+		       <COND (<MSTREET? .VAL>
+			      <COND (<AND <EQUAL? .X ,XSTART>
+					  <EQUAL? .Y ,YSTART>>
+				     <SET VAL ,P-MAZE-CASTLE ;!\C>)
+				    (<AND <EQUAL? .X ,XGOAL>
+					  <EQUAL? .Y ,YGOAL>>
+				     <SET VAL ,P-MAZE-DOCK ;!\D>)
+				    (<AND <EQUAL? .X ,XFISH>
+					  <EQUAL? .Y ,YFISH>>
+				     <SET VAL ,P-MAZE-FISH ;!\F>)
+				    (ELSE <SET VAL ,P-MAZE-STREET ;!\ >)>)
+			     (ELSE
+			      <SET VAL ,P-MAZE-WALL ;!\*>)>)>
+		<SET VAL <BOR .VAL <BAND .OVAL ,MWALL>>>
+		<COND (<NOT <EQUAL? .VAL .OVAL>>
+		       <MPUTB .X .Y .VAL>
+		       <DISPLAY-MAZE-PIC <BAND .VAL 127> .Y .X>)>)>>
+
+<ROUTINE DISPLAY-MAZE ("AUX" Y BY BX MH TH SH)
+	 <RESET-MARGIN>
+	 <CLEAR ,S-TEXT>
+	 <PICINF ,P-MAZE-BACKGROUND ,YX-TBL>
+	 <SET SH <WINGET ,S-STATUS ,WHIGH>>
+	 <WINDEF ,MAZE-WINDOW
+		 <SET Y <+ <WINGET ,S-STATUS ,WTOP> .SH>>
+		 <WINGET ,S-TEXT ,WLEFT>
+		 <SET MH <GET ,YX-TBL 0>>
+		 <GET ,YX-TBL 1>>
+	 <SET TH <- <WINGET ,S-FULL ,WHIGH> .SH>>
+	 <WINDEF ,S-TEXT
+		 <+ .Y .MH> <WINGET ,S-TEXT ,WLEFT>
+		 <- .TH .MH> <WINGET ,S-TEXT ,WWIDE>>
+	 <CLEAR ,S-TEXT>
+	 <SCREEN ,MAZE-WINDOW>
+	 <PICINF ,P-MAZE-BOX ,MAZE-BOX-TBL>
+	 <SET BY <GET ,MAZE-BOX-TBL 0>>
+	 <SET BX <GET ,MAZE-BOX-TBL 1>>
+	 <SETG YOFFSET
+	       </ <- <WINGET ,MAZE-WINDOW ,WHIGH>
+		     <* ,MAZE-HEIGHT .BY>>
+		  2>>
+	 <SETG XOFFSET
+	       </ <- <WINGET ,MAZE-WINDOW ,WWIDE>
+		     <* ,MAZE-WIDTH .BX>>
+		  2>>
+	 <PRINTM>
+	 <SCREEN ,S-TEXT>>
+
+<ROUTINE PRINTM ("AUX" M (OFFS 0))
+	 <DISPLAY ,P-MAZE-BACKGROUND 1 1>
+	 <FOR ((Y 0) <L? .Y ,MAZE-HEIGHT> <SET Y <+ .Y 1>>)
+	      <FOR ((X 0) <L? .X ,MAZE-WIDTH> <SET X <+ .X 1>>)
+		   <DISPLAY-MAZE-PIC <SET M <BAND <GETB ,MAZE-MAP .OFFS> 127>>
+				     .Y .X>
+		   <SET OFFS <+ .OFFS 1>>>>>
+
+<CONSTANT MAZE-WIDTH 37>
+<CONSTANT MAZE-HEIGHT 17>
+<GLOBAL SIZE 0>
+<GLOBAL PMAX 0>
+<GLOBAL MAZE-MAP <ITABLE <* ,MAZE-WIDTH ,MAZE-HEIGHT> (BYTE) 128>>
+
+<CONSTANT DIR
+	  <TABLE <TABLE (BYTE) 0 1 2 3> <TABLE (BYTE) 0 1 3 2>
+		 <TABLE (BYTE) 0 2 1 3> <TABLE (BYTE) 0 2 3 1>
+		 <TABLE (BYTE) 0 3 1 2> <TABLE (BYTE) 0 3 2 1>
+		 <TABLE (BYTE) 1 0 2 3> <TABLE (BYTE) 1 0 3 2>
+		 <TABLE (BYTE) 1 2 0 3> <TABLE (BYTE) 1 2 3 0>
+		 <TABLE (BYTE) 1 3 0 2> <TABLE (BYTE) 1 3 2 0>
+		 <TABLE (BYTE) 2 0 1 3> <TABLE (BYTE) 2 0 3 1>
+		 <TABLE (BYTE) 2 1 0 3> <TABLE (BYTE) 2 1 3 0>
+		 <TABLE (BYTE) 2 3 0 1> <TABLE (BYTE) 2 3 1 0>
+		 <TABLE (BYTE) 3 0 1 2> <TABLE (BYTE) 3 0 2 1>
+		 <TABLE (BYTE) 3 1 0 2> <TABLE (BYTE) 3 1 2 0>
+		 <TABLE (BYTE) 3 2 0 1> <TABLE (BYTE) 3 2 1 0>>>
+
+<CONSTANT XOFF1 <TABLE 0 0 1 -1>>
+<CONSTANT YOFF1 <TABLE -1 1 0 0>>
+<CONSTANT XOFF2 <TABLE 0 0 2 -2>>
+<CONSTANT YOFF2 <TABLE -2 2 0 0>>
+
+<GLOBAL X 0>
+<GLOBAL Y 0>
+<GLOBAL XSTART 0>
+<GLOBAL YSTART 0>
+<GLOBAL XGOAL 0>
+<GLOBAL YGOAL 0>
+<GLOBAL LEN 0>
+<GLOBAL LMAX 0>
+<GLOBAL FLEN 0>
+<GLOBAL XFISH 0>
+<GLOBAL YFISH 0>
+
+<ROUTINE BUILDMAZE ("AUX" LEFT PLEN D)
+	 <SETG SIZE <* </ ,MAZE-WIDTH 2> </ ,MAZE-HEIGHT 2>>>
+	 <SETG PMAX ,SIZE>
+	 <SET LEFT ,SIZE>
+	 <SETG FLEN <+ 10 <RANDOM 5>>>
+	 <FOR ((YY 0) <L? .YY ,MAZE-HEIGHT> <SET YY <+ .YY 1>>)
+	      <FOR ((XX 0) <L? .XX ,MAZE-WIDTH> <SET XX <+ .XX 1>>)
+		   <MPUTB .XX .YY ,MWALL>>>
+	 <FOR ((YY 1) <L? .YY ,MAZE-HEIGHT> <SET YY <+ .YY 2>>)
+	      <FOR ((XX 1) <L? .XX ,MAZE-WIDTH> <SET XX <+ .XX 2>>)
+		   <MPUTB .XX .YY 0>>>
+	 <SETG XGOAL <- ,MAZE-WIDTH 2>
+		    ;<+ <* <RANDOM <- </ ,MAZE-WIDTH 2> 1>> 2> 1>>
+	 <SETG XSTART ,XGOAL>
+	 <SETG X ,XGOAL>
+	 <SETG YGOAL <+ <* <RANDOM <- </ ,MAZE-HEIGHT 2> 1>> 2> 1>>
+	 <SETG YSTART ,YGOAL>
+	 <SETG Y ,YGOAL>
+	 <MPUTB ,X ,Y 1>
+	 <SETG LEN 1>
+	 <SETG LMAX 1>
+	 <FOR ((PLEN 0) <G? <SET LEFT <- .LEFT 1>> 0> <SET PLEN <+ .PLEN 1>>)
+	      <REPEAT ()
+		      <COND (<OR <ZERO? <MGETB ,X ,Y>>
+				 <G=? .PLEN ,PMAX>
+				 <L? <SET D <FINDMOVE ,X ,Y>> 0>>
+			     <BACKUP>
+			     <SET PLEN 0>)
+			    (ELSE <RETURN>)>>
+	      <REMOVEWALL .D>>
+	 <FOR ((YY 1) <L? .YY ,MAZE-HEIGHT> <SET YY <+ .YY 2>>)
+	      <FOR ((XX 1) <L? .XX ,MAZE-WIDTH> <SET XX <+ .XX 2>>)
+		   <MPUTB .XX .YY 0>>>
+	 <FOR ((XX 0) <L? .XX ,MAZE-WIDTH> <SET XX <+ .XX 1>>)
+	      <MPUTB .XX 0 ,MWALL>
+	      <MPUTB .XX <- ,MAZE-HEIGHT 1> ,MWALL>>
+	 <FOR ((YY 1) <L? .YY <- ,MAZE-HEIGHT 1>> <SET YY <+ .YY 1>>)
+	      <MPUTB 0 .YY ,MWALL>
+	      <MPUTB <- ,MAZE-WIDTH 1> .YY ,MWALL>>
+	 <SETG XGOAL <+ ,XGOAL 1>>
+	 ;<REPEAT ()
+		 <SETG XFISH <RANDOM ,MAZE-WIDTH>>
+		 <SETG YFISH <RANDOM ,MAZE-HEIGHT>>
+		 <COND (<ZERO? <BAND <MGETB ,XFISH ,YFISH> ,MWALL>>
+			<RETURN>)>>
+	 <MPUTB ,XGOAL ,YGOAL 0> ;"make the exit">
+
+<ROUTINE VISITED (XLOC YLOC)
+	 <COND (<NOT <VALID .XLOC .YLOC>>)
+	       (<N==? <MGETB .XLOC .YLOC> 0>)>>
+
+<ROUTINE VALID (XLOC YLOC)
+	 <COND (<OR <L? .XLOC 0> <G=? .XLOC ,MAZE-WIDTH>
+		    <L? .YLOC 0> <G=? .YLOC ,MAZE-HEIGHT>>
+		<>)
+	       (ELSE T)>>
+
+<ROUTINE FINDMOVE (XLOC YLOC "AUX" (DV <RANDOM 23>) D I)
+	 <FOR ((I 0) <L? .I 4> <SET I <+ .I 1>>)
+	      <SET D <GETB <GET ,DIR .DV> .I>>
+	      <COND (<NOT <VISITED <+ .XLOC <GET ,XOFF2 .D>>
+				   <+ .YLOC <GET ,YOFF2 .D>>>>
+		     <RETURN .D>)
+		    (ELSE <SET D -1>)>>
+	 .D>
+
+<ROUTINE BACKUP ("AUX" D XX YY)
+	 <SETG LEN <- ,LEN 1>>
+	 <FOR ((D 0) <L? .D 4> <SET D <+ .D 1>>)
+	      <SET XX <+ ,X <GET ,XOFF2 .D>>>
+	      <SET YY <+ ,Y <GET ,YOFF2 .D>>>
+	      <COND (<AND <VALID .XX .YY>
+			  <==? <MGETB .XX .YY> ,LEN>>
+		     <RETURN>)>>
+	 <SETG X .XX>
+	 <SETG Y .YY>
+	 <RTRUE>>
+
+<ROUTINE REMOVEWALL (D)
+	 <MPUTB <+ ,X <GET ,XOFF1 .D>>
+		<+ ,Y <GET ,YOFF1 .D>>
+		0>
+	 <SETG LEN <+ <MGETB ,X ,Y> 1>>
+	 <SETG X <+ ,X <GET ,XOFF2 .D>>>
+	 <SETG Y <+ ,Y <GET ,YOFF2 .D>>>
+	 <MPUTB ,X ,Y ,LEN>
+	 <COND (<EQUAL? ,LEN ,FLEN>
+		<SETG XFISH ,X>
+		<SETG YFISH ,Y>)>
+	 <COND (<G? ,LEN ,LMAX>
+		<SETG LMAX ,LEN>
+		<SETG XSTART ,X>
+		<SETG YSTART ,Y>)>
+	 <RTRUE>>
+
+<END-SEGMENT>
diff --git a/misc.zil b/misc.zil
new file mode 100644
index 0000000..e0520d5
--- /dev/null
+++ b/misc.zil
@@ -0,0 +1,1056 @@
+"MISC for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc. All Rights Reserved."
+
+<BEGIN-SEGMENT 0>
+
+<GLOBAL DEMO-VERSION? <>>	;"for swg"
+
+<PROPDEF SCENE <> (SCENE "MANY" S:FIX = <> "MANY" <BYTE .S>)>
+<PROPDEF SCORE <> (SCORE N:FIX = 2 <BYTE 0> <BYTE .N>)>
+
+;"tell macro and friends"
+
+;"moved tell-tokens to DEFS"
+
+<ROUTINE PRINT-HIM/HER (X)
+	 <COND (<FSET? .X ,PLURAL>
+		<TELL "them">)
+	       (<FSET? .X ,PERSON>
+		<COND (<EQUAL? .X ,ME ,WINNER>
+		       <TELL "yourself">)
+		      (<FSET? .X ,FEMALE>
+		       <TELL "her">)
+		      (ELSE <TELL "him">)>)
+	       (ELSE <TELL "it">)>>
+
+<ROUTINE CPRINT-HE/SHE (X)
+	 <COND (<FSET? .X ,PLURAL>
+		<TELL "They">)
+	       (<FSET? .X ,PERSON>
+		<COND (<EQUAL? .X ,ME ,WINNER>
+		       <TELL "You">)
+		      (<FSET? .X ,FEMALE>
+		       <TELL "She">)
+		      (ELSE <TELL "He">)>)
+	       (ELSE <TELL "It">)>>
+
+<ROUTINE PRINT-HE/SHE (X)
+	 <COND (<FSET? .X ,PLURAL>
+		<TELL "they">)
+	       (<FSET? .X ,PERSON>
+		<COND (<EQUAL? .X ,ME ,WINNER>
+		       <TELL "yourself">)
+		      (<FSET? .X ,FEMALE>
+		       <TELL "she">)
+		      (ELSE <TELL "he">)>)
+	       (ELSE <TELL "it">)>>
+
+<ROUTINE PRINT-HIS/HER (X)
+	 <COND (<FSET? .X ,PLURAL>
+		<TELL "their">)
+	       (<FSET? .X ,PERSON>
+		<COND (<EQUAL? .X ,ME ,WINNER>
+		       <TELL "your">)
+		      (<FSET? .X ,FEMALE>
+		       <TELL "her">)
+		      (ELSE <TELL "his">)>)
+	       (ELSE <TELL "its">)>>
+
+<ROUTINE PRINT-PLURAL (OBJ)
+	 <COND (<NOT <FSET? .OBJ ,PLURAL>>
+		<TELL "s">)>>
+
+<ROUTINE PRINTUNDER (X)
+	 <HLIGHT ,H-UNDER>
+	 <PRINT .X>
+	 <HLIGHT ,H-NORMAL>>
+
+<ROUTINE CTHE-PRINT-PRSO ()
+	 <THE-PRINT ,PRSO T>>
+
+<ROUTINE CTHE-PRINT-PRSI ()
+	 <THE-PRINT ,PRSI T>>
+
+<ROUTINE CTHE-PRINT (O)
+	 <THE-PRINT .O T>>
+
+<ROUTINE THE-PRINT-PRSO ()
+	 <THE-PRINT ,PRSO>>
+
+<ROUTINE THE-PRINT-PRSI ()
+	 <THE-PRINT ,PRSI>>
+
+<ROUTINE THE-PRINT (O "OPTIONAL" (CAP? <>))
+	 <DPRINT .O .CAP? <NOT <FSET? .O ,NOTHEBIT>>>>
+
+<ROUTINE CPRINTA-PRSO ()
+	 <PRINTA ,PRSO T>>
+
+;<ROUTINE CPRINTA-PRSI ()
+	 <PRINTA ,PRSI T>>
+
+;<ROUTINE CPRINTA (O)
+	 <PRINTA .O T>>
+
+<ROUTINE PRINTA-PRSO ()
+	 <PRINTA ,PRSO>>
+
+<ROUTINE PRINTA-PRSI ()
+	 <PRINTA ,PRSI>>
+
+<ROUTINE PRINTA (O "OPT" (CAP? <>))
+	 <COND (<FSET? .O ,THE>
+		<COND (.CAP? <PRINTI "The ">)
+		      (ELSE <PRINTI "the ">)>)
+	       (<NOT <FSET? .O ,NOABIT>>
+		<COND (<FSET? .O ,AN>
+		       <COND (.CAP? <PRINTI "An ">)
+			     (ELSE <PRINTI "an ">)>)
+		      (.CAP? <PRINTI "A ">)
+		      (ELSE <PRINTI "a ">)>)>
+	 <IPRINT .O>>
+
+<ROUTINE DPRINT-PRSO ()
+	 <DPRINT ,PRSO>>
+
+<ROUTINE DPRINT-PRSI ()
+	 <DPRINT ,PRSI>>
+
+;<ROUTINE CDPRINT-PRSO ()
+	 <DPRINT ,PRSO T>>
+
+;<ROUTINE CDPRINT-PRSI ()
+	 <DPRINT ,PRSI T>>
+
+;<ROUTINE CDPRINT (O)
+	 <DPRINT .O T>>
+
+<ROUTINE DPRINT (O "OPTIONAL" (CAP? <>) (THE? <>) "AUX" S)
+	 <COND (<EQUAL? .O ,PLAYER ,ME>
+		<COND (.CAP? <TELL "You">)
+		      (ELSE <TELL "you">)>)
+	       (<AND <EQUAL? .O ,RUTTER> .CAP?>
+		<TELL "Your rutter">)
+	       (ELSE
+		<COND (<AND <SET S <GET-OWNER .O>>
+			    <NOT <EQUAL? .S <GETP .O ,P?OWNER>>>>
+		       <COND (<EQUAL? .S ,PLAYER>
+			      <COND (.CAP? <TELL "Your ">)
+				    (T <TELL "your ">)>)
+			     (ELSE
+			      <DPRINT .S .CAP? ;.THE?>
+			      <TELL "'s ">)>)
+		      (<OR .THE? <FSET? .O ,THE>>
+		       <COND (.CAP? <PRINTI "The ">)
+			     (T <PRINTI "the ">)>)>
+		<IPRINT .O>)>>
+
+<ROUTINE IPRINT (O "AUX" TMP)
+	 <COND ;(<AND <EQUAL? .O ,PSEUDO-OBJECT>
+		     <NOT ,P-MERGED>
+		     <EQUAL? .O ,PRSO ,PRSI>>
+		<THING-PRINT ,PSEUDO-PRSO ;"<EQUAL? .O ,PRSO>">)
+	       (<SET TMP <GETP .O ,P?SDESC>>
+		<PRINT .TMP>)
+	       (ELSE
+		<PRINTD .O>)>>
+
+<COND (<GASSIGNED? ZILCH>
+<DEFINE PE (F I)
+	<COND (<TYPE? .I LIST>
+	       <FORM .F !.I>)
+	      (ELSE
+	       <FORM .F .I>)>>
+
+<DEFMAC P? ('V "OPT" ('O '*) ('I '*) ('W '*) "AUX" (L ()))
+	<COND (<N==? .I '*>
+	       <SET L (<PE PRSI? .I> !.L)>)>
+	<COND (<N==? .O '*>
+	       <COND (<OR <==? .V 'WALK>
+			  <==? .V ',V?WALK>>
+		      <SET L (<PE DIR? .O> !.L)>)
+		     (ELSE
+		      <SET L (<PE PRSO? .O> !.L)>)>)>
+	<COND (<N==? .V '*>
+	       <SET L (<PE VERB? .V> !.L)>)>
+	<COND (<N==? .W '*>
+	       <SET L (<PE WINNER? .W> !.L)>)>
+	<COND (<EMPTY? <REST .L>>
+	       <1 .L>)
+	      (ELSE <FORM AND !.L>)>>
+
+<DEFMAC NOT-SOLVED? ('OBJ)
+	<FORM FSET? .OBJ ',SCOREBIT>>
+
+<DEFMAC SOLVED? ('OBJ)
+	<FORM NOT <FORM FSET? .OBJ ',SCOREBIT>>>
+
+<DEFMAC VERB? ("ARGS" ATMS)
+	<MULTIFROB ',PRSA .ATMS>>
+
+<DEFMAC SCENE? ("ARGS" ATMS)
+	<MULTIFROB ',SCENE .ATMS>>
+
+<DEFMAC CONTEXT? ("ARGS" ATMS)
+	<MULTIFROB '.RARG .ATMS>>
+
+<DEFMAC ADJ? ("ARGS" ATMS)
+	<MULTIFROB '<PARSE-ADJ ,PARSE-RESULT> .ATMS>>
+
+<SETG RARG? ,CONTEXT?>
+
+<DEFMAC WINNER? ("ARGS" ATMS)
+	<MULTIFROB ',WINNER .ATMS>>
+
+<DEFMAC PRSO? ("ARGS" ATMS)
+	<MULTIFROB ',PRSO .ATMS>>
+
+<DEFMAC DIR? ("ARGS" ATMS)
+	<MULTIFROB ',P-WALK-DIR .ATMS>>
+
+<DEFMAC PRSI? ("ARGS" ATMS)
+	<MULTIFROB ',PRSI .ATMS>>
+
+<DEFMAC HERE? ("ARGS" ATMS)
+	<MULTIFROB ',HERE .ATMS>>
+
+<SETG ROOM? ,HERE?>
+
+<DEFINE MULTIFROB (X ATMS "AUX" (OO (OR)) (O .OO) (L ()) ATM SP) 
+	<REPEAT ()
+		<COND (<EMPTY? .ATMS>
+		       <RETURN!- <COND (<LENGTH? .OO 1> <ERROR .X>)
+				       (<LENGTH? .OO 2> <NTH .OO 2>)
+				       (ELSE <CHTYPE .OO FORM>)>>)>
+		<REST
+		 <PUTREST
+		  .O
+		  <SET O
+		       (<REPEAT
+			 ((LL <FORM EQUAL? .X>)
+			  (L <REST .LL>))
+			 <COND (<OR <EMPTY? .ATMS>
+				    <==? <LENGTH <REST .LL 2>> 3>>
+				<RETURN!- .LL>)>
+			 <SET ATM <NTH .ATMS 1>>
+			 <PUTREST
+			  .L
+			  <SET L
+			       (<COND
+				 (<TYPE? .ATM ATOM>
+				  <SET SP <SPNAME .ATM>>
+				  <MAKE-GVAL
+				   <COND (<==? .X ',PRSA>
+					  <PARSE <STRING "V?" .SP>>)
+					 (<==? .X ',P-WALK-DIR>
+					  <COND (<AND <G? <LENGTH .SP> 2>
+						      <==? <1 .SP> !\P>
+						      <==? <2 .SP> !\?>>
+						 .ATM)
+						(ELSE
+						 <PARSE
+						  <STRING "P?" .SP>>)>)
+					 (<==? .X '.RARG>
+					  <COND (<AND <G? <LENGTH .SP> 2>
+						      <==? <1 .SP> !\M>
+						      <==? <2 .SP> !\->>
+						 .ATM)
+						(ELSE
+						 <PARSE
+						  <STRING "M-" .SP>>)>)
+					 (ELSE .ATM)>>)
+				 (ELSE .ATM)>)>>
+			 <SET ATMS <REST .ATMS>>>)>>>>>)
+(ELSE
+ <DEFINE P? (V "OPT" (O '*) (I '*) (W '*) "AUX" (L <>))
+	 <AND <OR <==? .W '*> <WINNER? .W>>
+	      <OR <==? .V '*> <VERB? .V>>
+	      <OR <==? .O '*> <PRSO? .O>>
+	      <OR <==? .I '*> <PRSI? .I>>>>
+
+ <DEFINE VERB? ("TUPLE" ATMS)
+	 <MAPF <>
+	       <FUNCTION (A "AUX" ATM)
+		    <COND (<TYPE? .A ATOM>
+			   <COND (<SET ATM
+				       <LOOKUP <STRING "V?" <SPNAME .A>>
+					       <MOBLIST INITIAL>>>
+				  <COND (<EQUAL? ,PRSA ,.ATM>
+					 <MAPLEAVE T>)>)
+				 (ELSE
+				  <ERROR NOT-A-VERB? .A>)>)
+			  (<EQUAL? ,PRSA .A>
+			   <MAPLEAVE T>)>>
+	       .ATMS>>
+ <DEFINE CONTEXT? ("TUPLE" ATMS)
+ 	 <MAPF <>
+	       <FUNCTION (A "AUX" ATM)
+		    <COND (<TYPE? .A ATOM>
+			   <COND (<AND <G? <LENGTH <SET ATM <SPNAME .A>>> 2>
+				       <==? <1 .ATM> !\M>
+				       <==? <2 .ATM> !\->>
+				  <COND (<EQUAL? .RARG ,.ATM>
+					 <MAPLEAVE T>)>)
+				 (<SET ATM
+				       <LOOKUP <STRING "M-" <SPNAME .A>>
+					       <MOBLIST INITIAL>>>
+				  <COND (<EQUAL? .RARG ,.ATM>
+					 <MAPLEAVE T>)>)
+				 (ELSE
+				  <ERROR NOT-A-CONTEXT? .A>)>)
+			  (<EQUAL? .RARG .A>
+			   <MAPLEAVE T>)>>
+	       .ATMS>>
+ <SETG RARG? ,CONTEXT?>
+ <DEFINE WINNER? ("TUPLE" ATMS)
+	 <MULTIFROB ,WINNER .ATMS>>
+ <DEFINE PRSO? ("TUPLE" ATMS)
+	 <MULTIFROB ,PRSO .ATMS>>
+ <DEFINE PRSI? ("TUPLE" ATMS)
+	 <MULTIFROB ,PRSI .ATMS>>
+ <DEFINE HERE? ("TUPLE" ATMS)
+	 <MULTIFROB HERE .ATMS>>
+ <SETG ROOM? ,HERE?>
+ <DEFINE MULTIFROB (X ATMS) 
+	 <MAPF <>
+	       <FUNCTION (A)
+		    <COND (<TYPE? .A ATOM> <SET A ,.A>)>
+		    <COND (<EQUAL? .X .A>
+			   <MAPLEAVE T>)>>
+	       .ATMS>>)>
+
+<COND (<GASSIGNED? ZILCH>
+<DEFMAC BSET ('OBJ "ARGS" BITS)
+	<MULTIBITS FSET .OBJ .BITS>>
+
+<DEFMAC BCLEAR ('OBJ "ARGS" BITS)
+	<MULTIBITS FCLEAR .OBJ .BITS>>
+
+<DEFMAC BSET? ('OBJ "ARGS" BITS)
+	<MULTIBITS FSET? .OBJ .BITS>>
+
+<DEFINE MULTIBITS (X OBJ ATMS
+		   "AUX" (OT <COND (<==? .X FSET?> <FORM OR>)
+				   (ELSE <FORM PROG ()>)>)
+		         (OO <COND (<LENGTH? .OT 1> .OT)
+				   (ELSE <REST .OT>)>)
+			 (O .OO)
+			 ATM) 
+	<REPEAT ()
+		<COND (<EMPTY? .ATMS>
+		       <RETURN!- .OT>)>
+		<SET ATM <NTH .ATMS 1>>
+		<SET ATMS <REST .ATMS>>
+		<PUTREST .O
+			 <SET O
+			      (<FORM .X
+				     .OBJ
+				     <COND (<TYPE? .ATM FORM> .ATM)
+					   (ELSE <MAKE-GVAL .ATM>)>>)>>>>)
+(ELSE
+<DEFINE BSET (OBJ "TUPLE" BITS)
+	<MULTIBITS ,FSET .OBJ .BITS>>
+
+<DEFINE BCLEAR (OBJ "TUPLE" BITS)
+	<MULTIBITS ,FCLEAR .OBJ .BITS>>
+
+<DEFINE BSET? (OBJ "TUPLE" BITS)
+	<MAPF <>
+	      <FUNCTION (A)
+		   <COND (<FSET? .OBJ ,.A> <MAPLEAVE T>)>>
+	      .BITS>>
+
+<DEFINE MULTIBITS (X OBJ ATMS) 
+	<MAPF <>
+	      <FUNCTION (A)
+		   <APPLY!- .X .OBJ ,.A>>
+	      .ATMS>>)>
+
+<DEFMAC RFATAL ()
+	'<RETURN ,M-FATAL>>
+
+<COND (<GASSIGNED? ZILCH>
+       <DEFMAC PROB ('BASE?)
+	       <FORM NOT <FORM L? .BASE? '<RANDOM 100>>>>)
+      (ELSE
+       <DEFINE PROB (BASE?)
+	       <NOT <L? .BASE? <RANDOM 100>>>>)>
+
+<ROUTINE PICK-ONE (FROB
+		   "AUX" (L <GET .FROB 0>) (CNT <GET .FROB 1>) RND MSG RFROB)
+	 <SET L <- .L 1>>
+	 <SET FROB <REST .FROB 2>>
+	 <SET RFROB <REST .FROB <* .CNT 2>>>
+	 <SET RND <RANDOM <- .L .CNT>>>
+	 <SET MSG <GET .RFROB .RND>>
+	 <PUT .RFROB .RND <GET .RFROB 1>>
+	 <PUT .RFROB 1 .MSG>
+	 <SET CNT <+ .CNT 1>>
+	 <COND (<==? .CNT .L> <SET CNT 0>)>
+	 <PUT .FROB 0 .CNT>
+	 .MSG>
+
+;<ROUTINE RANDOM-ELEMENT (FROB)
+	 <GET .FROB <RANDOM <GET .FROB 0>>>>
+
+
+
+;"former MAIN.ZIL stuff"
+
+<GLOBAL P-WON <>>
+
+<GLOBAL SCENE 0>
+
+<ROUTINE SCENE-SELECT ("OPT" (FULL? <>) "AUX" TMP M WID WHICH)
+	 <REPEAT ()
+		 <SPLIT <- <WINGET ,S-FULL ,WHIGH>
+			   <* <+ <GET ,PART-MENU ;.MEN 0> 1> ,FONT-Y>>>
+		 <RESET-MARGIN>
+		 <CLEAR ,S-TEXT>
+		 <SCREEN ,S-TEXT>
+		 <SET WHICH
+		      <GET-FROM-MENU "You may choose to: "
+				     ,PART-MENU
+				     ,SCENE-SELECT-F
+				     1>>
+		 <COND (<EQUAL? .WHICH -1>
+			<SET FULL? <NOT .FULL?>>)
+		       (.WHICH <RTRUE>)>>>
+
+<ROUTINE SCENE-SELECT-F (TMP M)
+	 <COND (<EQUAL? .TMP 1>
+		<SPLIT <* ,FONT-Y ,STATUS-LINES>>
+		<SETG SCENE <GET ,SCENES 1>>)
+	       (<EQUAL? .TMP 2>
+		<CLEAR ,S-TEXT>
+		<V-RESTORE>
+		<RESET-MARGIN>
+		<CLEAR ,S-TEXT>
+		<RFALSE>)
+	       (<EQUAL? .TMP 3>
+		<CLEAR ,S-TEXT>
+		<V-QUIT T <>>
+		<RESET-MARGIN>
+		<CLEAR ,S-TEXT>
+		<RFALSE>)>>
+
+
+
+"SCENES AND PARTS"
+
+<CONSTANT PART-MENU
+	  <LTABLE <TABLE (PURE STRING LENGTH) "START the game ">
+		  <TABLE (PURE STRING LENGTH) "RESTORE a saved game ">
+		  <TABLE (PURE STRING LENGTH) "QUIT the game ">>>
+
+<CONSTANT SCENE-NAMES
+	  <PLTABLE "Erasmus"
+		   "Anjiro"
+		   "Yabu"
+		   "Pit"		;"omi & yabu"
+		   "Rodrigues"		;"crew out of pit"
+		   "Voyage to Osaka"	;"rod's advice"
+		   "Toranaga"		;"ishido vs. t."
+		   "Prison"		;"how to help"
+		   "Mariko"		;"alvito & ferriera"
+		   "Escape"		;"hatamoto"
+		   "Earthquake"		;"zataki"
+		   "Journey to Yedo"	;"delay, etc."
+		   "Ochiba"
+		   "Departure"		;"council"
+		   "Seppuku"
+		   "Ninja"		;"etsu's death"
+		   "Yokohama"
+		   "Aftermath"
+		   "Epilogue">>
+
+<DEFMAC SCENE-CONSTANTS ("TUPLE" SS "AUX" (CNT 0))
+	<MAPF ,LTABLE
+	      <FUNCTION (S)
+		   <EVAL <FORM CONSTANT .S <SET CNT <+ .CNT 1>>>>>
+	      .SS>>
+
+<CONSTANT SCENES
+	  <SCENE-CONSTANTS S-ERASMUS
+			   S-ANJIRO
+			   S-YABU
+			   S-PIT
+			   S-RODRIGUES
+			   S-VOYAGE
+			   S-TORANAGA
+			   S-PRISON
+			   S-MARIKO
+			   S-ESCAPE
+			   S-QUAKE
+			   S-JOURNEY
+			   S-OCHIBA
+			   S-DEPARTURE
+			   S-SEPPUKU
+			   S-NINJA
+			   S-YOKOHAMA
+			   S-AFTERMATH
+			   S-EPILOGUE>>
+
+<CONSTANT SCENE-LOCS
+	  <LTABLE BRIDGE-OF-ERASMUS 	;"S-ERASMUS"
+		  MURA-HOUSE		;"S-ANJIRO"
+		  VILLAGE-SQUARE	;"S-YABU"
+		  PIT			;"S-PIT"
+		  ANJIRO-WATERFRONT	;"S-RODRIGUES"
+		  GALLEY		;"S-VOYAGE"
+		  OUTER-CORRIDOR	;"S-TORANAGA"
+		  PRISON		;"S-PRISON"
+		  MAPLE-GLADE		;"S-MARIKO"
+		  COURTYARD		;"S-ESCAPE"
+		  PLATEAU		;"S-QUAKE"
+		  YOKOSE-BATH-HOUSE	;"S-JOURNEY"
+		  OCHIBA-ROOM		;"S-OCHIBA"
+		  FORECOURT		;"S-DEPARTURE"
+		  FORMAL-GARDEN		;"S-SEPPUKU"
+		  PRIVATE-QUARTERS	;"S-NINJA"
+		  YOKOHAMA		;"S-YOKOHAMA"
+		  STABLE		;"S-AFTERMATH"
+		  SEKIGAHARA		;"S-EPILOGUE">>
+
+<GLOBAL MACHINE <>>
+<GLOBAL WIDTH 0>
+
+<END-SEGMENT>
+
+<BEGIN-SEGMENT STARTUP>
+
+<ROUTINE GO () 
+	 <MOUSE-LIMIT -1>
+	 <SETG FG-COLOR <LOWCORE (CLRWRD 1)>>
+	 <SETG BG-COLOR <LOWCORE (CLRWRD 0)>>
+	 <SETG LIT T>
+	 <SETG CLOCK-HAND <REST ,C-TABLE ,C-TABLELEN>>
+	 <SETG MACHINE <LOWCORE INTID>>
+	 <SETG PLAYER ,BLACKTHORNE>
+	 <SETUP-FULL>
+	 <TITLE-SCREEN>
+	 <SETUP-DISPLAY>
+	 <SCENE-SELECT>
+	 <GOTO-SCENE ,SCENE <>>
+	 <MAIN-LOOP>>
+
+<END-SEGMENT>
+
+<BEGIN-SEGMENT 0>
+
+<CONSTANT S-FULL 7>
+
+<ROUTINE SETUP-FULL ("AUX" (HIGH <LOWCORE VWRD>) (WIDE <LOWCORE HWRD>))
+	 <WINDEF ,S-FULL 1 1 .HIGH .WIDE>>
+
+<ROUTINE SETUP-DISPLAY ("AUX" X (HIGH <LOWCORE VWRD>) (WIDE <LOWCORE HWRD>))
+	 <MOUSE-LIMIT -1>
+	 <SETUP-FULL>
+	 <SET X <WINGET ,S-TEXT ,WFSIZE>>
+	 <SETG FONT-Y <HIGH-BYTE .X>>
+	 <SETG FONT-X <LOW-BYTE .X>>
+	 <SETUP-TEXT-AND-STATUS>
+	 <SET WIDE <WINGET ,S-TEXT ,WWIDE>>
+	 <MARGIN ,TEXT-MARGIN ,TEXT-MARGIN ,S-TEXT>
+	 <SET WIDE <- .WIDE 4>>
+	 <SETG WIDTH <GETB ,P-INBUF 0>>
+	 <SET WIDE </ .WIDE ,FONT-X>>
+	 <COND (<L? .WIDE ,WIDTH>
+		<SETG WIDTH .WIDE>
+		<PUTB ,P-INBUF 0
+		      <COND (<G? .WIDE ,INBUF-LENGTH>
+			     ,INBUF-LENGTH)
+			    (T
+			     .WIDE)>>)>>
+
+<ROUTINE REPAINT-DISPLAY ("OPT" (NO-BORDER? <>))
+	 <RESET-MARGIN>
+	 <COLOR ,FG-COLOR ,BG-COLOR>
+	 <SETUP-DISPLAY>
+	 <COND (<NOT .NO-BORDER?> <DISPLAY-BORDER>)>
+	 <INIT-STATUS-LINE T>
+	 <COND (<HERE? ,MAZE>
+		<DISPLAY-MAZE>)>>
+
+<ROUTINE GOTO-SCENE (SC "OPT" (OSC ,SCENE))
+	 <END-QUOTE>
+	 <RESET-MARGIN>
+	 <DEQUEUE-ALL>
+	 <SETG SCENE .SC>
+	 <SETG HERE <GET ,SCENE-LOCS ,SCENE>>
+	 <FCLEAR ,HERE ,TOUCHBIT>
+	 <SETG QCONTEXT <>>
+	 <MOVE-ALL ,BLACKTHORNE>
+	 <MOVE ,BLACKTHORNE ,HERE>
+	 <FCLEAR ,BLACKTHORNE ,RMUNGBIT>
+	 <SETG P-IT-OBJECT <>>
+	 <SETG P-HIM-OBJECT <>>
+	 <SETG P-HER-OBJECT <>>
+	 <SETG P-THEM-OBJECT <>>
+	 <B-STAND>
+	 <SETG OPPONENT <>>
+	 <APPLY <GETP ,HERE ,P?ACTION> ,M-SCENE-SETUP>
+	 <SETG WINNER ,PLAYER>
+	 <CLEAR ,S-TEXT>
+	 <COND (<ZERO? .OSC>
+		<CLEAR ,S-STATUS>
+		<INIT-STATUS-LINE>)
+	       (ELSE <UPDATE-STATUS-LINE T>)>
+	 <GOTO ,HERE>
+	 <COND (<ZERO? .OSC>
+		<CLOCKER> ;"simulate a previous move..."
+		<SETG MOVES 0>)>
+	 <RTRUE>>
+
+;<GLOBAL WAS-IT? <>>
+;<GLOBAL WAS-THEM? <>>
+;<GLOBAL WAS-HIM? <>>
+;<GLOBAL WAS-HER? <>>
+
+;<GLOBAL PERFORM-DEPTH 0> ;"number recursive calls to perform"
+
+;<CONSTANT P-MATCHLEN 0>
+;<ROUTINE OBJECT-SUBSTITUTE (OBJ VAR "AUX" (TMP <>) (CNT 0) ICNT OCNT)
+	 <COND (<AND .VAR <ACCESSIBLE? .VAR>>
+		<SET ICNT <GET ,P-PRSI ,P-MATCHLEN>>
+		<SET OCNT <GET ,P-PRSO ,P-MATCHLEN>>
+		<REPEAT ()
+			<COND (<G? <SET CNT <+ .CNT 1>> .ICNT>
+			       <RETURN>)
+			      (T
+			       <COND (<EQUAL? <GET ,P-PRSI .CNT> .OBJ>
+				      <PUT ,P-PRSI .CNT .VAR>
+				      <SET TMP T>
+				      <RETURN>)>)>>
+		<SET CNT 0>
+		<REPEAT ()
+			<COND (<G? <SET CNT <+ .CNT 1>> .OCNT>
+			       <RETURN>)
+			      (T
+			       <COND (<EQUAL? <GET ,P-PRSO .CNT> .OBJ>
+				      <PUT ,P-PRSO .CNT .VAR>
+				      <SET TMP T>
+				      <RETURN>)>)>>
+		.TMP)>>
+
+;<GLOBAL PSEUDO-PRSO <>> ;"T IF ORIGINAL PRSO WAS PSEUDO-OBJECT"
+
+<ROUTINE GAME-VERB? ()
+	 <COND (<AND <VERB? TELL> ,P-CONT> <RTRUE>)
+	       (<AND <VERB? HELP>
+		     <NOT ,PRSO>>
+		<RTRUE>)
+	       (<VERB? QUIT VERSION BRIEF SUPER-BRIEF VERBOSE COLOR
+		       $VERIFY RESTART SAVE RESTORE SCRIPT UNSCRIPT UNDO
+		       SCORE TIME DEFINE $REFRESH NOTIFY HINT HINTS-OFF
+		       CREDITS>
+		<RTRUE>)
+	       (<VERB? $RANDOM $COMMAND $RECORD $UNRECORD
+		       ;$SCENE ;$SHOW ;$W ;$P ;$D ;$I ;$G ;$X ;$M>
+		<RTRUE>)>>
+
+"MULTIPLE-EXCEPTION? -- return true if an object found by all should not
+be included when the crunch comes."
+
+;<ROUTINE MULTIPLE-EXCEPTION? (OBJ1 "AUX" (L <LOC .OBJ1>))
+	 <COND (<EQUAL? .OBJ1 ,NOT-HERE-OBJECT>
+		<SETG P-NOT-HERE <+ ,P-NOT-HERE 1>>
+		<RTRUE>)
+	       (<AND <VERB? TAKE>
+		     ,PRSI
+		     <NOT <IN? ,PRSO ,PRSI>>>
+		;"TAKE X FROM Y and x not in y"
+		<RTRUE>)
+	       (<NOT <ACCESSIBLE? .OBJ1>>
+		;"can't get at object"
+		<RTRUE>)
+	       (<EQUAL? ,P-GETFLAGS ,P-ALL>
+		;"cases for ALL"
+		<COND (<AND ,PRSI
+			    <PRSO? ,PRSI>>
+		       ;"VERB ALL and prso = prsi"
+		       <RTRUE>)
+		      (<AND <VERB? TAKE> <NOT ,PRSI>>
+		       <COND (<OR <AND <NOT <EQUAL? .L ,WINNER ,HERE ,PRSI>>
+				       <NOT <EQUAL? .L <LOC ,WINNER>>>
+				       <NOT <FSET? .L ,SURFACEBIT>>
+				       <NOT <FSET? .L ,SEARCHBIT>>>
+				  <AND <NOT <FSET? .OBJ1 ,TAKEBIT>>
+				       <NOT <FSET? .OBJ1 ,TRYTAKEBIT>>>>
+			      ;"TAKE ALL and object not accessible or takeable"
+			      <RTRUE>)
+			     (<OR <FSET? .L ,PERSON>
+				  <FSET? <LOC .L> ,PERSON>>
+			      ;"TAKE ALL held by a person (use TAKE ALL FROM)"
+			      <RTRUE>)
+			     (<HELD? ,PRSO>
+			      ;"TAKE ALL and one object has others in it"
+			      <RTRUE>)>)
+		      (<VERB? DROP GIVE>
+		       <COND (<NOT <IN? .OBJ1 ,WINNER>>
+			      ;"GIVE/DROP ALL and object not held"
+			      <RTRUE>)
+			     (<FSET? .OBJ1 ,WEARBIT>
+			      ;"GIVE/DROP ALL and object worn"
+			      <RTRUE>)>)
+		      (<AND <VERB? PUT>
+			    <NOT <IN? ,PRSO ,WINNER>>
+			    <HELD? ,PRSO ,PRSI>>
+		       ;"PUT ALL IN X and object already in x"
+		       <RTRUE>)>)>>
+
+;<ROUTINE SAVE-INPUT (TBL "AUX" (OFFS 0) CNT TMP)
+	 <SET CNT <+ <GETB ,P-LEXV <SET TMP <* 4 ,P-INPUT-WORDS>>>
+		     <GETB ,P-LEXV <+ .TMP 1>>>>
+	 <COND (<EQUAL? .CNT 0> ;"failed"
+		<RFALSE>)>
+	 <SET CNT <- .CNT 1>>
+	 <REPEAT ()
+		 <COND (<EQUAL? .OFFS .CNT>
+			<PUTB .TBL .OFFS 0>
+			<RETURN>)
+		       (T
+			<PUTB .TBL .OFFS <GETB ,P-INBUF <+ .OFFS 1>>>)>
+		 <SET OFFS <+ .OFFS 1>>>
+	 <RTRUE>>
+
+;<ROUTINE RESTORE-INPUT (TBL "AUX" CHR)
+	 <REPEAT ()
+		 <COND (<EQUAL? <SET CHR <GETB .TBL 0>> 0>
+			<RETURN>)
+		       (T
+			<PRINTC .CHR>
+			<SET TBL <REST .TBL>>)>>>
+
+<GLOBAL P-MULT <>>
+
+<GLOBAL P-NOT-HERE 0>
+
+
+;<GLOBAL WHAT-DO-YOU-WANT-TO "What do you want to ">
+
+;<ROUTINE FAKE-ORPHAN ("AUX" TMP)
+	 <ORPHAN ,P-SYNTAX <>>
+	 <TELL ,WHAT-DO-YOU-WANT-TO>
+	 <SET TMP <GET ,P-OTBL ,P-VERBN>>
+	 <COND (<EQUAL? .TMP 0>
+		<TELL "tell">)
+	       (<ZERO? <GETB ,P-VTBL 2>>
+		<PRINTB <GET .TMP 0>>)
+	       (T
+		<WORD-PRINT <GETB .TMP 2> <GETB .TMP 3>>
+		<PUTB ,P-VTBL 2 0>)>
+	 <SETG P-OFLAG T>
+	 <SETG P-WON <>>
+	 <PREP-PRINT
+	     <GETB ,P-SYNTAX ,P-SPREP1>>
+	 <TELL "?" CR>>
+
+<ROUTINE END-QUOTE ()
+	 <SETG P-CONT <>>
+	 <RFATAL>>
+
+;"former CLOCK.ZIL stuff"
+
+<GLOBAL CLOCK-WAIT <>>
+
+<GLOBAL C-TABLE <ITABLE 13 <> <>>>
+
+<CONSTANT C-INTLEN 4>	;"length of an interrupt entry in bytes"
+<CONSTANT C-RTN 0>	;"word offset of routine name"
+<CONSTANT C-TICK 1>	;"word offset of count"
+
+<CONSTANT C-TABLELEN 52>	;"length of interrupt table in bytes"
+<GLOBAL C-INTS 52>		;"start of queued interrupts in bytes"
+
+<ROUTINE DEQUEUE (RTN "AUX" TIM)
+	 <COND (<SET RTN <QUEUED? .RTN>>
+		<SET TIM <GET .RTN ,C-TICK>>
+		<PUT .RTN ,C-RTN 0>
+		.TIM)>>
+
+<ROUTINE QUEUED? (RTN "AUX" C E)
+	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
+	 <SET C <REST ,C-TABLE ,C-INTS>>
+	 <REPEAT ()
+		 <COND (<EQUAL? .C .E> <RFALSE>)
+		       (<EQUAL? <GET .C ,C-RTN> .RTN>
+			<COND (<ZERO? <GET .C ,C-TICK>>
+			       <RFALSE>)
+			      (T <RETURN .C>)>)>
+		 <SET C <REST .C ,C-INTLEN>>>>
+
+"this version of QUEUE automatically enables as well"
+
+"QUEUE routine when fresh?:t means only queue if not currently queued"
+
+<ROUTINE QUEUE (RTN TICK "OPT" (I? <>) "AUX" C E (INT <>))
+	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
+	 <SET C <REST ,C-TABLE ,C-INTS>>
+	 <REPEAT ()
+		 <COND (<EQUAL? .C .E>
+			<COND (.INT
+			       <SET C .INT>)
+			      (ELSE
+			       <SETG C-INTS <- ,C-INTS ,C-INTLEN>>
+			       <SET INT <REST ,C-TABLE ,C-INTS>>)>
+			<PUT .INT ,C-RTN .RTN>
+			<RETURN>)
+		       (<EQUAL? <GET .C ,C-RTN> .RTN>
+			<COND (.I? <RFALSE>)
+			      (ELSE
+			       <SET INT .C>
+			       <RETURN>)>)
+		       (<ZERO? <GET .C ,C-RTN>>
+			<SET INT .C>)>
+		 <SET C <REST .C ,C-INTLEN>>>
+	 <COND (%<COND (<GASSIGNED? ZILCH>
+			'<G? .INT ,CLOCK-HAND>)
+		       (ELSE
+			'<L=? <LENGTH .INT> <LENGTH ,CLOCK-HAND>>)>
+		<SET TICK <- <+ .TICK 3>>>)>
+	 <PUT .INT ,C-TICK .TICK>
+	 .INT>
+
+<GLOBAL STATIONARY? <>>	;"winner not walking around?"
+<GLOBAL STATIONARY-CNT <>> ;"and for how long"
+
+<GLOBAL CLOCK-HAND <>>
+
+<ROUTINE CLOCKER ("AUX" E TICK RTN (FLG <>) (Q? <>) OWINNER TMP (OSC ,SCENE))
+	 <COND (,CLOCK-WAIT <SETG CLOCK-WAIT <>> <RFALSE>)>
+	 <COND (<EQUAL? ,HERE ,STATIONARY?>
+		<SETG STATIONARY-CNT <+ ,STATIONARY-CNT 1>>)
+	       (ELSE
+		<SETG STATIONARY? ,HERE>
+		<SETG STATIONARY-CNT 0>)>
+	 <SETG CLOCK-HAND <REST ,C-TABLE ,C-INTS>>
+	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
+	 <SET OWINNER ,WINNER>
+	 <SETG WINNER ,PLAYER>
+	 <REPEAT ()
+		 <COND (<EQUAL? ,CLOCK-HAND .E>
+			<SETG CLOCK-HAND .E>
+			<SETG MOVES <+ ,MOVES 1>>
+			<SETG WINNER .OWINNER>
+			<RETURN .FLG>)
+		       (<NOT <ZERO? <GET ,CLOCK-HAND ,C-RTN>>>
+			<SET TICK <GET ,CLOCK-HAND ,C-TICK>>
+			<COND (<L? .TICK -1>
+			       <PUT ,CLOCK-HAND ,C-TICK <- <- .TICK> 3>>
+			       <SET Q? ,CLOCK-HAND>)
+			      (<NOT <ZERO? .TICK>>
+			       <COND (<G? .TICK 0>
+				      <SET TICK <- .TICK 1>>
+				      <PUT ,CLOCK-HAND ,C-TICK .TICK>)>
+			       <COND (<NOT <ZERO? .TICK>>
+				      <SET Q? ,CLOCK-HAND>)>
+			       <COND (<NOT <G? .TICK 0>>
+				      <SET RTN
+					   %<COND (<GASSIGNED? ZILCH>
+						   '<GET ,CLOCK-HAND ,C-RTN>)
+						  (ELSE
+						   '<NTH ,CLOCK-HAND
+							 <+ <* ,C-RTN 2>
+							    1>>)>>
+				      <COND (<ZERO? .TICK>
+					     <PUT ,CLOCK-HAND ,C-RTN 0>)>
+				      <SET OSC ,SCENE>
+				      <COND (<SET TMP <APPLY .RTN>>
+					     <SET FLG .TMP>)>
+				      <COND (<AND <NOT .Q?>
+						  <NOT
+						   <ZERO?
+						    <GET ,CLOCK-HAND
+							 ,C-RTN>>>>
+					     <SET Q? T>)>)>)>)>
+		 <COND (<NOT <EQUAL? .OSC ,SCENE>> ;"new scene during int?"
+			<SETG CLOCK-HAND <REST ,C-TABLE ,C-INTS>>)
+		       (<EQUAL? .FLG ,M-FATAL>
+			<SETG CLOCK-HAND .E>)
+		       (<NOT <EQUAL? ,CLOCK-HAND .E>>
+			<SETG CLOCK-HAND <REST ,CLOCK-HAND ,C-INTLEN>>
+			<COND (<NOT .Q?>
+			       <SETG C-INTS <+ ,C-INTS ,C-INTLEN>>)>)>>>
+
+<ROUTINE DEQUEUE-ALL ("AUX" E TICK RTN (FLG <>) (Q? <>))
+	 <COND (,CLOCK-WAIT <SETG CLOCK-WAIT <>> <RFALSE>)>
+	 <SETG CLOCK-HAND <REST ,C-TABLE ,C-INTS>>
+	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
+	 <REPEAT ()
+		 <COND (<EQUAL? ,CLOCK-HAND .E>
+			<SETG CLOCK-HAND .E>
+			<RETURN>)
+		       (ELSE
+			<PUT ,CLOCK-HAND ,C-TICK 0>
+			<PUT ,CLOCK-HAND ,C-RTN 0>)>
+		 <SETG CLOCK-HAND <REST ,CLOCK-HAND ,C-INTLEN>>
+		 <SETG C-INTS <+ ,C-INTS ,C-INTLEN>>>>
+
+<DEFINE PSEUDO ("TUPLE" V)
+	<MAPF ,PLTABLE
+	      <FUNCTION (OBJ)
+		   <COND (<N==? <LENGTH .OBJ> 3>
+			  <ERROR BAD-THING .OBJ>)>
+		   <MAPRET <COND (<NTH .OBJ 1>
+				  <VOC <SPNAME <NTH .OBJ 1>> ADJECTIVE>)>
+			   <COND (<NTH .OBJ 2>
+				  <VOC <SPNAME <NTH .OBJ 2>> NOUN>)>
+			   ;<3 .OBJ>>>
+	      .V>>
+
+<ROUTINE PERFORM-PRSA ("OPT" (O <>) (I <>))
+	 <PERFORM ,PRSA .O .I>>
+
+<ROUTINE NEW-VERB (V)
+	 <PERFORM .V ,PRSO ,PRSI>>
+
+<ROUTINE SWAP-VERB (V)
+	 <PERFORM .V ,PRSI ,PRSO>>
+
+<ROUTINE NEW-PRSO (O)
+	 <PERFORM-PRSA .O ,PRSI>>
+
+;<ROUTINE NEW-PRSI (I)
+	 <PERFORM-PRSA ,PRSO .I>>
+
+<ROUTINE NEW-WINNER-PRSO (A "OPT" (O <>) (I <>) "AUX" OW)
+	 <SET OW ,WINNER>
+	 <SETG WINNER ,PRSO>
+	 <PERFORM .A .O .I>
+	 <SETG WINNER .OW>
+	 <RTRUE>>
+
+<ROUTINE REDIRECT (FROM TO "AUX" O I)
+	 <SET O <COND (<PRSO? .FROM> .TO) (ELSE ,PRSO)>>
+	 <SET I <COND (<PRSI? .FROM> .TO) (ELSE ,PRSI)>>
+	 <PERFORM-PRSA .O .I>
+	 <RTRUE>>
+
+<GLOBAL DELAY-CNT 0>
+
+<COND (<GASSIGNED? ZILCH>
+       <DEFMAC ZLINES ('VAR:<PRIMTYPE ATOM> "ARGS" LINES:LIST
+		       "AUX" (CNT:FIX 0) SETTER:ATOM
+		       (DELAYS:<OR FALSE LIST> <>))
+	       <COND (<TYPE? .VAR ATOM>
+		      <EVAL <FORM GLOBAL .VAR 0>>
+		      <SET SETTER <CHTYPE .VAR GVAL>>)
+		     (<TYPE? .VAR GVAL>
+		      <EVAL <FORM GLOBAL <CHTYPE .VAR ATOM> 0>>
+		      <SET SETTER 'SETG>)
+		     (<TYPE? .VAR LVAL>
+		      <EVAL <FORM GLOBAL <CHTYPE .VAR ATOM> 0>>
+		      <SET SETTER 'SET>)>
+	       <SET DELAYS
+		    <MAPF ,LIST
+			  <FUNCTION (LINE:LIST)
+			       <COND (<EMPTY? .LINE> <MAPRET>)
+				     (<==? <1 .LINE> DELAY>
+				      <MAPRET (<FORM EQUAL? .VAR .CNT>
+					       !<REST .LINE>)>)
+				     (ELSE
+				      <COND (<AND <NOT <EMPTY? .LINE>>
+						  <TYPE? <1 .LINE> FIX>>
+					     <SET CNT <+ .CNT <1 .LINE>>>
+					     <SET LINE <REST .LINE>>)
+					    (ELSE
+					     <SET CNT <+ .CNT 1>>)>
+				      <MAPRET>)>>
+			  .LINES>>
+	       <SET CNT 0>
+	       <COND (<NOT <EMPTY? .DELAYS>>
+		      <SET DELAYS
+			   ('<SETG DELAY-CNT <+ ,DELAY-CNT 1>>
+			    <FORM COND !.DELAYS>
+			    '<SETG DELAY-CNT 0>)>)>
+	       <FORM PROG ()
+		     !.DELAYS
+		     <FORM .SETTER <CHTYPE .VAR ATOM> <FORM + .VAR 1>>
+		     <FORM COND 
+			   !<MAPF ,LIST
+				  <FUNCTION (LINE:LIST)
+				       <COND (<NOT <EMPTY? .LINE>>
+					      <COND (<==? <1 .LINE> DELAY>
+						     <MAPRET>)
+						    (<TYPE? <1 .LINE> FIX>
+						     <SET CNT
+							  <+ .CNT <1 .LINE>>>
+						     <SET LINE <REST .LINE>>)
+						    (ELSE
+						     <SET CNT <+ .CNT 1>>)>
+					      <LIST <FORM EQUAL? .VAR .CNT>
+						    !.LINE>)
+					     (ELSE
+					      <ERROR BAD-ZLINES>)>>
+				  .LINES>>>>)
+      (ELSE
+       <DEFINE ZLINES (VAR "ARGS" LINES)
+	       <RFALSE>>)>
+
+<COND (<GASSIGNED? ZILCH>
+       <DEFMAC FOR ('X "ARGS" BODY)
+	       <FORM REPEAT (<1 .X>)
+		     <FORM COND (<FORM NOT <2 .X>> '<RETURN>)>
+		     !.BODY
+		     <3 .X>>>)>
+
+<ROUTINE CREWMAN? (OBJ)
+	 <AND <NOT <EQUAL? .OBJ ,CREWMEN ,LG-CREWMEN>>
+	      <FSET? .OBJ ,DUTCHBIT>>>
+
+
+
+"stuff for handling opcodes that want pixels"
+
+<ROUTINE WINDEF (W TOP LEFT HIGH WIDE)
+	 <WINPOS .W .TOP .LEFT>
+	 <WINSIZE .W .HIGH .WIDE>>
+
+<GLOBAL FONT-X 7>
+<GLOBAL FONT-Y 10>
+
+<ROUTINE C-PIXELS (X)
+	 <+ <* <- .X 1> ,FONT-X> 1>>
+
+<ROUTINE L-PIXELS (Y)
+	 <+ <* <- .Y 1> ,FONT-Y> 1>>
+
+<ROUTINE CCURSET (Y X)
+	 <CURSET <L-PIXELS .Y> <C-PIXELS .X>>>
+
+<ROUTINE IN-SCENE? (OBJ "AUX" SC PT)
+	 <COND (<NOT <SET SC <GETPT .OBJ ,P?SCENE>>>
+		<RTRUE>)
+	       (ELSE
+		<SET PT <PTSIZE .SC>>
+		<COND (<INTBL? ,SCENE .SC .PT 1> <RTRUE>)
+		      (ELSE <RFALSE>)>)>>
+
+<ROUTINE REPLACE-SYNONYM (OBJ OLD NEW "OPT" (DUP? <>) "AUX" TMP S L)
+	 <COND (<SET S <GETPT .OBJ ,P?SYNONYM>>
+		<SET L </ <PTSIZE .S> 2>>
+		<COND (<AND <NOT .DUP?> <INTBL? .NEW .S .L>>
+		       <RTRUE>)
+		      (<SET TMP <INTBL? .OLD .S .L>>
+		       <PUT .TMP 0 .NEW>)>)>>
+
+<ROUTINE REPLACE-ADJECTIVE (OBJ OLD NEW "OPT" (DUP? <>) "AUX" TMP S L)
+	 <COND (<SET S <GETPT .OBJ ,P?ADJECTIVE>>
+		<SET L </ <PTSIZE .S> 2>>
+		<COND (<AND <NOT .DUP?> <INTBL? .NEW .S .L>>
+		       <RTRUE>)
+		      (<SET TMP <INTBL? .OLD .S .L>>
+		       <PUT .TMP 0 .NEW>)>)>>
+
+<ROUTINE CURSOR-OFF ()
+	 <CURSET -1>>
+
+<ROUTINE CURSOR-ON ()
+	 <CURSET -2>>
+
+<DEFMAC APPLE? ()
+   '<EQUAL? ,MACHINE ,APPLE-2E ,APPLE-2C ,APPLE-2GS>>
+
+<END-SEGMENT>
diff --git a/osaka.zil b/osaka.zil
new file mode 100644
index 0000000..70066f0
--- /dev/null
+++ b/osaka.zil
@@ -0,0 +1,1842 @@
+		 
+"OSAKA for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc.  All Rights Reserved."
+
+<FILE-FLAGS SENTENCE-ENDS?>
+
+<BEGIN-SEGMENT ESCAPE>
+
+<CONSTANT J-DRAG 100>
+<CONSTANT J-VEIL 101>
+<CONSTANT J-FLEE 102>
+<CONSTANT J-MOAT 103>
+<CONSTANT J-ISHIDO 104>
+<CONSTANT J-PARCHMENT 105>
+
+<OBJECT CORTEGE
+	(DESC "cortege")
+	(SYNONYM CORTEGE PROCESSION PARTY COLUMN GRAYS BROWNS)
+	(FLAGS NDESCBIT)
+	(ACTION CORTEGE-F)>
+
+<ROUTINE CORTEGE-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The procession consists of Toranaga's retainers.  Most prominent are the
+litters carrying Kiritsubo and Mariko.  A force of Browns guards the column,
+and a force of Grays guards the Browns." CR>)
+	       (<VERB? FOLLOW>
+		<COND (<NOT <IN? ,CORTEGE ,HERE>>
+		       <DO-WALK ,P?SOUTH>)>)>>
+		 
+
+<OBJECT KIMONO
+	(OWNER BLACKTHORNE)
+	(DESC "kimono")
+	(SYNONYM KIMONO CLOTHES)
+	(ADJECTIVE SILK)
+	(FLAGS TAKEBIT WEARABLE)
+	(ACTION KIMONO-F)>
+
+<ROUTINE KIMONO-F ()
+	 <COND (<AND <VERB? TAKE-OFF> <FORMAL-SCENE?>>
+		<TELL
+"You would expose yourself to ridicule." CR>)
+	       (<AND <VERB? WEAR>
+		     <NOUN-USED? ,PRSO ,W?CLOTHES>
+		     <NOT <FSET? ,PRSO ,RMUNGBIT>>>
+		<PERFORM ,V?DRESS>
+		<RTRUE>)
+	       (<AND <VERB? TAKE-OFF>
+		     <NOUN-USED? ,PRSO ,W?CLOTHES>
+		     <NOT <FSET? ,PRSO ,RMUNGBIT>>>
+		<PERFORM ,V?STRIP>
+		<RTRUE>)
+	       (<VERB? TEAR>
+		<TELL
+"Your kimono would tear easily, but it would be silly to do so." CR>)>>
+
+<OBJECT SANDALS
+	(OWNER BLACKTHORNE)
+	(DESC "pair of sandals")
+	(SYNONYM SANDALS SLIPPERS THONG THONGS)
+	(FLAGS TAKEBIT WEARABLE PLURAL)>
+
+<OBJECT SOCKS
+	(OWNER BLACKTHORNE)
+	(DESC "socks")
+	(SYNONYM SOCKS TABIS)
+	(ADJECTIVE TABI)
+	(FLAGS TAKEBIT WEARABLE PLURAL NOABIT)
+	(ACTION SOCKS-F)>
+
+<ROUTINE SOCKS-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"These are tabi socks.  They are different from European socks in that
+there is a notch for the thong of a sandal.  They remind you of mittens." CR>)
+	       (<AND <VERB? TAKE-OFF WEAR>
+		     <FSET? ,SANDALS ,WEARBIT>>
+		<HAVE-TO-TAKE-OFF ,SANDALS>)>>
+
+<OBJECT BUNTARO
+	(DESC "Buntaro")
+	(SYNONYM BUNTARO)
+	(ADJECTIVE LORD TODA)
+	(FLAGS PERSON JAPANESEBIT NOABIT NOTHEBIT)
+	(ACTION BUNTARO-F)>
+
+<ROUTINE BUNTARO-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<TELL
+"Buntaro responds sharply and impatiently, but you can't understand
+what he says." CR>)
+	       (<VERB? EXAMINE>
+		<COND (<SCENE? ,S-ESCAPE>
+		       <TELL
+"Buntaro looks nervous, but alert and ready.  You feel he would like
+to kill someone, and wouldn't be too particular about who." CR>)>)
+	       (<VERB? WHO>
+		<TELL
+"Toda Buntaro, Lord of Sakura, is a short, bandy-legged, ugly man
+with a quick temper.  He is the only living son of Lord Hiro-matsu,
+and the husband of Lady Mariko." CR>)>>
+
+<OBJECT SAZUKO
+	(DESC "Sazuko")
+	(SYNONYM SAZUKO GIRL)
+	(ADJECTIVE LADY)
+	(FLAGS PERSON JAPANESEBIT FEMALE NOABIT NOTHEBIT)
+	(ACTION SAZUKO-F)>
+
+<ROUTINE SAZUKO-F ("OPT" RARG)
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<WAKARIMASEN>)
+	       (<VERB? WHO>
+		<TELL
+"Lady Sazuko is the seventh of Toranaga's official consorts, the youngest,
+and very pregnant." CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"Lady Sazuko is a short, square-faced girl of little beauty.  She is
+very pregnant." CR>)>>
+
+<OBJECT BROWNS
+	(DESC "Brown-uniformed samurai")
+	(SYNONYM BROWNS BROWN SAMURAI)
+	(ADJECTIVE BROWNS BROWN BROWN-UNIFORMED)
+	(FLAGS PERSON JAPANESEBIT NOABIT)
+	(COUNT 20)
+	(GENERIC GENERIC-SAMURAI-F)
+	(ACTION BROWNS-F)>
+
+<ROUTINE BROWNS-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<AND <HERE? ,MAIN-DECK>
+			    <SCENE? ,S-ESCAPE>>
+		       <SETG WINNER ,PLAYER>
+		       <PERFORM ,V?MIZU>
+		       <RTRUE>)
+		      (ELSE
+		<TELL
+"The Browns are not under your orders." CR>)>
+		<END-QUOTE>)
+	       (ELSE
+		<COND (<VERB? WHO>
+		       <TELL
+"The Browns are Toranaga's samurai." CR>)
+		      (<VERB? EXAMINE>
+		       <TELL
+"They are all dressed in the Brown uniform." CR>)>)>>
+
+<OBJECT GRAYS
+	(DESC "Gray-uniformed samurai")
+	(SYNONYM GRAYS GRAY SAMURAI ESCORT GUARDS GUARDSMEN)
+	(ADJECTIVE GRAY GRAY-UNIFORMED)
+	(FLAGS PERSON JAPANESEBIT NOABIT)
+	(GENERIC GENERIC-SAMURAI-F)
+	(ACTION GRAYS-F)>
+
+<ROUTINE GRAYS-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<TELL
+"The Grays ignore you." CR>
+		<END-QUOTE>)
+	       (ELSE
+		<COND (<VERB? WHO>
+		       <TELL
+"The Grays are Ishido's samurai." CR>)
+		      (<VERB? EXAMINE>
+		       <COND (<SCENE? ,S-PRISON>
+			      <TELL
+"They are behaving more like escorts than guards." CR>)
+			     (ELSE
+			      <TELL
+"They are all dressed in the Gray uniform." CR>)>)>)>>
+
+<ROUTINE NOT-A-BARBARIAN? ()
+	 <OR <AND <P? BE (BLACKTHORNE ME)
+		      (GLOBAL-BARBARIAN CRAZY)>
+		  <P-NEGATIVE?>>
+	     <P? BE (BLACKTHORNE ME)
+		 (GLOBAL-SAMURAI GLOBAL-HATAMOTO)>>>
+
+<ROUTINE I-ISHIDO ()
+	 <ZLINES ,ISHIDO-CNT
+		 (<QUEUE I-ISHIDO -1>
+		  <MOVE ,ISHIDO ,FORECOURT>
+		  <MOVE ,GRAYS ,FORECOURT>
+		  <MOVE ,BUNTARO ,FORECOURT>
+		  <MOVE ,YABU ,FORECOURT>
+		  <FSET ,FORTIFIED-GATE ,OPENBIT>
+		  <COND (<HERE? ,FORECOURT ,COURTYARD>
+			 <TELL CR
+"\"" I "Guards!" "\" The warning comes from the forecourt.  Ishido is
+approaching down the avenue at the head of two hundred Grays." CR CR
+"Buntaro and Yabu hurry to the fortified door as the guards open it." CR CR
+"Ishido bows to Yabu elaborately.  \"A fine evening, Lord Yabu.\"  Though no man
+seems hostile on either side, all are ready." CR CR
+"Ishido nods perfunctorily to Buntaro, who returns the minimum politeness
+allowable.  Buntaro had led one of the regiments in Korea when Ishido was
+in overall command.  Each had accused the other of treachery." CR>)
+			(ELSE
+			 <TELL CR
+"You hear a loud shout from the forecourt, and a great deal of commotion
+from that direction." CR>)>)
+		 (<COND (<HERE? ,FORECOURT>
+			 <TELL CR
+"Ishido says, \"You'd think you were all going into battle, Yabu-san,
+instead of just being a ceremonial escort for the Lady Kiritsubo.\"" CR CR
+"Buntaro stomps pugnaciously forward.  \"We're always ready for battle.  We
+can take on ten men for each one of yours.  We never turn our backs and
+run like snot-nosed cowards!\"" CR>)
+			(<HERE? ,COURTYARD>
+			 <TELL CR
+"Ishido is arguing with Buntaro.  You are too far away to hear any of
+what he is saying." CR>)>)
+		 (<COND (<HERE? ,FORECOURT>
+			 <TELL CR
+"Yabu moves carefully between Buntaro and Ishido, wanting desperately
+to avoid a clash that would lock them forever within the castle.  \"We're
+among friends, Buntaro-san.\"" CR CR
+"\"Friends?  Where?  In this manure pile?\" sneers Buntaro.  One of the Grays'
+hands flashes for his sword hilt, ten Browns follow, and in a moment,
+all are waiting for Ishido's sword to come out and signal the attack." CR>)
+			(<HERE? ,COURTYARD>
+			 <TELL CR
+"You can see Yabu hurriedly move between Ishido and Buntaro.  You can
+see even from here that there is going to be blood shed." CR>)>)
+		 (<MOVE ,HIRO-MATSU ,FORECOURT>
+		  <COND (<HERE? ,FORECOURT>
+			 <TELL CR
+"Quietly, Hiro-matsu walks out of the garden shadows into the forecourt. 
+\"You can find friends in manure, sometimes, my son,\" he says
+calmly.  Hands ease off sword hilts.  \"We have friends all over the castle.  All
+over Osaka.\"  He stares into Buntaro's eyes.  \"Isn't that so, my son?\""
+CR CR "With an enormous effort, Buntaro nods and steps back a pace." CR CR
+"Ishido says mildly, \"I came to pay my respects to Lady Kiritsubo.  I was
+not informed until a few moments ago that anyone was leaving.\"" CR>)
+			(<HERE? ,COURTYARD>
+			 <TELL CR
+"You can see Hiro-matsu approach the angry pair.  He says something which
+causes Buntaro to back off.  Tensions seem to ease." CR CR
+"Ishido asks something politely of Hiro-matsu." CR>)>)
+		 (<MOVE ,HIRO-MATSU ,COURTYARD>
+		  <MOVE ,YABU ,COURTYARD>
+		  <MOVE ,ISHIDO ,GENERIC-OBJECTS>
+		  <DEQUEUE I-ISHIDO>
+		  <QUEUE I-KIRI -1>
+		  <COND (<HERE? ,FORECOURT ,COURTYARD>
+			 <TELL CR
+"Ishido strides through the gateway into the courtyard, Hiro-matsu and Yabu
+accompanying him.  Five guards follow.  He bows politely and wishes Kiritsubo
+well." CR CR
+"Satisfied that all is as it should be, Ishido turns and leaves with all
+his men.  Hiro-matsu exhales and scratches his piles.">
+			 <COND (<HERE? ,COURTYARD>
+				<TELL " \"You'd better
+leave now, Yabu-san.  That rice maggot'll give you no more trouble.\"  Yabu
+replies, \"Yes, at once.\"" CR>)
+			       (ELSE
+				<TELL " He says something to Yabu, who bows
+and then begins to get the escort moving." CR>)>)>)>>	       
+
+<OBJECT TORANAGA-IN-DRAG
+	;(DESC "Toranaga")
+	(SDESC "veiled figure")
+	(SYNONYM FIGURE KIRI KIRITSUBO KIRITSUBO ;"TORANAGA")
+	(ADJECTIVE VEILED DISGUISED)
+	(FLAGS PERSON FEMALE JAPANESEBIT SCOREBIT OPENBIT CONTBIT SEARCHBIT)
+	(GENERIC GENERIC-TORANAGA-F)
+	(ACTION TORANAGA-IN-DRAG-F)>
+
+<ROUTINE TORANAGA-IN-DRAG-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<TELL
+CTHE ,TORANAGA-IN-DRAG " looks at you, but doesn't reply." CR>)
+	       (<VERB? EXAMINE>
+		<COND (<IN? ,PRSO ,KIRIS-LITTER>
+		       <TELL
+"You can't get a good look at " THE ,PRSO "." CR>)
+		      (<FSET? ,TORANAGA-IN-DRAG ,SCOREBIT>
+		       <REPLACE-SYNONYM ,TORANAGA-IN-DRAG
+					,W?KIRITSUBO
+					,W?TORANAGA>
+		       <FCLEAR ,TORANAGA-IN-DRAG ,FEMALE>
+		       <TELL
+"You look at the veiled figure.  She is dressed exactly like Kiri, and at
+first you assume that it must be her.  But if so, how did she get here?
+Then you look more carefully, and realize it's a man, not a woman --
+it's Toranaga, in disguise!  What can he be planning?  Escape!" CR>
+		       <SCORE-OBJECT ,TORANAGA-IN-DRAG>)
+		      (ELSE
+		       <TELL
+"Toranaga looks back at you and makes a gesture that you can clearly
+see means 'go away.'" CR>)>)
+	       (<HOSTILE-VERB?>
+		<COND (<JIGS-UP? ,J-DRAG
+"You reconsider your options.  If the Japanese want to hide in tea houses,
+what concern is it of yours?">
+		       <COND (<FSET? ,TORANAGA-IN-DRAG ,SCOREBIT>
+			      <TELL
+"You grapple with the veiled figure.  As you fight, her veil drops off"
+G", revealing Toranaga!  You are stunned, and back off, amazed, but it is
+too late.  The commotion has attracted others, and Toranaga has drawn
+his sword from beneath the incongruously feminine kimono.  His sword is
+as sharp as it needs to be, though." CR>)
+			     (ELSE
+			      <TELL
+"You grapple with Toranaga, whose feminine kimono conceals armor and
+swords.  He draws his killing sword and ends your life." CR>)>
+		       <JIGS-UP>)
+		      (ELSE <RTRUE>)>)>>
+
+<OBJECT VEIL
+	(LOC TORANAGA-IN-DRAG)
+	(DESC "veil")
+	(SYNONYM VEIL)
+	(FLAGS NDESCBIT TAKEBIT DONT-ALL)
+	(ACTION VEIL-F)>
+
+<ROUTINE VEIL-F ()
+	 <COND (<AND <VERB? EXAMINE LOOK-INSIDE LOOK-BEHIND LOOK-UNDER RAISE>
+		     <IN? ,VEIL ,TORANAGA-IN-DRAG>>
+		<PERFORM ,V?EXAMINE ,TORANAGA-IN-DRAG>
+		<RTRUE>)
+	       (<AND <VERB? TAKE>
+		     <IN? ,VEIL ,TORANAGA-IN-DRAG>>
+		<COND (<FSET? ,TORANAGA-IN-DRAG ,SCOREBIT>
+		       <COND (<JIGS-UP? ,J-VEIL
+"You recall how your countrymen would react to someone snatching a lady's
+clothing, and refrain.">
+			      <MOVE ,VEIL ,WINNER>
+			      <TELL
+"You snatch the veil"
+G", revealing Toranaga!  You are stunned, and back off, amazed, but it is
+too late.  The commotion has attracted others, and Toranaga has drawn
+his sword from beneath the incongruously feminine kimono.  His sword is
+as sharp as it needs to be, though." CR>
+			      <JIGS-UP>)
+			     (ELSE <RTRUE>)>)>)>>
+
+<ROOM COURTYARD
+      (LOC ROOMS)
+      (SCENE S-ESCAPE)
+      (DESC "Courtyard")
+      (SYNONYM COURTYARD)
+      (PICTURE P-PROCESSION)
+      (SCORE 13)
+      (AFTER HATAMOTO-AFTER-F)
+      (FDESC
+"Just after dusk Kiri waddled nervously down the steps.  She headed for
+her curtained litter that stood near the little tea house just inside
+the garden.  You are leaning
+against the wall near the fortified gate.  You are wearing a belted
+kimono of the Browns and tabi socks and military thongs.")
+      (SOUTH TO FORECOURT IF FORTIFIED-GATE IS OPEN)
+      (OUT TO FORECOURT IF FORTIFIED-GATE IS OPEN)
+      (WEST TO FORMAL-GARDEN IF GARDEN-GATE IS OPEN)
+      (FLAGS ONBIT OUTSIDE)
+      (GLOBAL FORTIFIED-GATE SAMURAI-GUARDS GARDEN-GATE
+       ISHIDO BUNTARO YABU HIRO-MATSU)
+      (ACTION COURTYARD-F)>
+
+<ROUTINE COURTYARD-F (RARG)
+	 <COND (<RARG? SCENE-SETUP>
+		<DRESS-BLACKTHORNE>
+		<QUEUE I-ISHIDO 2>
+		<MOVE ,TORANAGA-IN-DRAG ,TEA-HOUSE>
+		<MOVE ,MARIKO ,HERE>
+		<MOVE ,SAZUKO ,HERE>
+		<MOVE ,KIRITSUBO ,KIRIS-LITTER>
+		<MOVE-CORTEGE ,HERE>)
+	       (<RARG? LOOK>
+		<TELL
+"This is the courtyard of Toranaga's keep within Osaka castle.  The garden
+is through a gate to the west, and to the south is the forecourt and
+fortified gate that guards the keep.|
+|
+In the forecourt, outside the gate, ">
+		<COND (<SCENE? ,S-ESCAPE>
+		       <TELL "an escort of sixty heavily armed samurai
+is drawn up in neat lines, every third man carrying a flare." CR>)
+		      (<SCENE? ,S-SEPPUKU>
+		       <TELL "is a crowd of Grays, and mingling with
+them other samurai and their women." CR>)>)
+	       (<RARG? BEG>
+		<COND (<AND <OR <PRSO? ISHIDO BUNTARO YABU HIRO-MATSU>
+				<PRSI? ISHIDO BUNTARO YABU HIRO-MATSU>>
+			    <NOT <IN? ,PRSO ,HERE>>>
+		       <COND (<IN? ,PRSO ,FORECOURT>
+			      <TELL
+CTHE ,PRSO " seems to be talking with some others by the gate.  You are too
+far away to really tell what's going on." CR>)
+			     (ELSE
+			      <TELL
+CTHE ,PRSO " doesn't seem to be anywhere nearby." CR>)>) 
+		      (<AND <P? WALK (P?SOUTH P?OUT)>
+			    <NOT <FSET? ,FORTIFIED-GATE ,OPENBIT>>>
+		       <TELL
+"You must wait for the gate to be opened." CR>)
+		      (<AND <P? WALK P?WEST>
+			    <SCENE? ,S-ESCAPE>
+			    ,BEEN-IN-GARDEN?>
+		       <TELL
+"\"No, Anjin-san, stay here!\" Mariko says.  \"We are leaving soon.\"" CR>)>)>>
+
+<ROUTINE I-KIRI ()
+	 <ZLINES ,KIRI-CNT
+		 (<COND (<HERE? ,COURTYARD>
+			 <TELL CR
+"Kiritsubo begins to cry.  She obviously doesn't want to leave.  She tries
+to stifle her sobs and unlooses her thick veil.  She calls Yabu over to
+her litter and points to Lady Sazuko, Toranaga's pregnant consort, apparently
+giving him instructions.  All you can understand is the word "I"dozo"",
+'please.'  Yabu bows." CR>)
+			(ELSE
+			 <TELL CR
+"You can hear conversations and crying coming from the courtyard." CR>)>)
+		 (<COND (<HERE? ,COURTYARD>
+			 <FSET ,KIRITSUBO ,SCOREBIT>
+			 <TELL CR
+"Lady Sazuko bows and hurries off, Yabu following.  The girl runs up the
+steps.  As she nears the top she slips and falls.  Kiri screams something
+in Japanese.  All eyes flash to the prostrate girl." CR>)
+			(<HERE? ,FORMAL-GARDEN>
+			 <SETG SEEN-TORANAGA? T>
+			 <TELL CR
+"Kiritsubo hurries through the garden into the little tea house, then
+emerges again moments later.  As she passes you, your eyes meet.  ">
+			 <COND (<FSET? ,TORANAGA-IN-DRAG ,SCOREBIT>
+				<TELL
+"It is not Kiri, but Toranaga in disguise!" CR>
+				<SCORE-OBJECT ,TORANAGA-IN-DRAG>
+				<REPLACE-SYNONYM ,TORANAGA-IN-DRAG
+						 ,W?KIRITSUBO
+						 ,W?TORANAGA>)
+			       (ELSE
+				<TELL
+"It is Toranaga.  Kiritsubo and Toranaga have switched!" CR>)>
+			 <TELL CR
+"The figure slips into Kiri's litter, veil drawn." CR>
+			 <SCORE-OBJECT ,KIRITSUBO>)
+			(<HERE? ,TEA-HOUSE>
+			 <TELL CR
+"Suddenly, Kiritsubo dashes into the tea house.  When she sees you, she
+screams in surprise.  In moments, Yabu pokes his head into the tea house.  ">
+			 <JIGS-UP
+"He sees the veiled figure, who immediately draws a
+sword and surprisingly attacks you rather than Yabu.">
+			 <CRLF>)
+			(ELSE
+			 <TELL CR
+"There seems to be some commotion in the courtyard." CR>)>)
+		 (<MOVE ,TORANAGA-IN-DRAG ,KIRIS-LITTER>
+		  <MOVE ,KIRITSUBO ,TEA-HOUSE>
+		  <COND (<HERE? ,COURTYARD>
+			 <FCLEAR ,KIRITSUBO ,SCOREBIT>
+			 <COND (<EQUAL? ,OHERE ,FORMAL-GARDEN>
+				<TELL CR
+"You see that Sazuko, one of Toranaga's consorts, has fallen to the
+ground.  She is pregnant, and everyone is terrified for the safety of
+the child." CR>)>
+			 <TELL CR
+"Mariko and Yabu rush to aid the girl.  Yabu picks her up.  Sazuko is
+more startled than hurt.  She speaks to them, embarassed at her clumsiness,
+then stands.  Everyone relaxes.  Toranaga's unborn child is safe." CR>)
+			(ELSE
+			 <TELL CR
+"The commotion in the courtyard seems to have subsided." CR>)>)
+		 (<REMOVE ,SAZUKO>
+		  <COND (<HERE? FORMAL-GARDEN TEA-HOUSE>
+			 <I-COME-BACK>)>
+		  <MOVE ,MARIKO ,MARIKOS-LITTER>
+		  <COND (<HERE? ,COURTYARD>
+			 <TELL CR
+"Yabu shouts orders at the head of the column and sets off.  Mariko
+gets into her litter, leaving the curtains partially open.  Kiri's litter
+is closed." CR>)
+			(ELSE
+			 <TELL CR
+"You can hear the procession preparing to move out." CR>)>)
+		 (<MOVE-CORTEGE ,FORECOURT>
+		  <MOVE ,HIRO-MATSU ,GENERIC-OBJECTS>
+		  <COND (<HERE? ,COURTYARD ,FORECOURT>
+			 <TELL CR
+"The column begins to move out into the forecourt, the litter bearers
+carrying Mariko's and Kiritsubo's litters.  Samurai move to the great
+door and prepare to close it." CR>)
+			(ELSE
+			 <TELL CR
+"You can hear the procession moving off." CR>)>)
+		 (DELAY
+		  <COND (<IN? ,PLAYER ,COURTYARD>
+			 <TELL CR
+"The samurai eye you strangely, motioning you through the gate." CR>
+			 <RTRUE>)>)
+		 (<FCLEAR ,FORTIFIED-GATE ,OPENBIT>
+		  <TELL CR
+"The last of the column moves out into the forecourt, and the huge
+fortified door closes as the great wooden bar falls into place.  The head
+of the column is already moving on towards the gateway." CR>)
+		 (DELAY
+		  <COND (<HERE? ,FORECOURT>
+			 <TELL CR
+"You are urged along by the other members of the procession." CR>
+			 <RTRUE>)>)
+		 (<TELL-CHECKPOINTS>)>>
+
+<ROUTINE TELL-CHECKPOINTS ()
+	 <DEQUEUE I-KIRI>
+	 <MOVE-CORTEGE ,GATEWAY>
+	 <SETG ISHIDO-CNT 0>
+	 <QUEUE I-ISHIDO-2 -1>
+	 <TELL CR
+"The little cortege surrounding the two litters goes slowly through the maze
+of the castle and through the continual checkpoints.  Each time there are
+formal bows, the documents are meticulously examined afresh, a new captain
+and group of escorting Grays take over, and then you are passed.  At each
+checkpoint you watch with increasing misgivings as the captain of the
+guard comes close to scrutinize the drawn curtains of Kiritsubo's litter. 
+Each time the man bows politely to the half-seen figure, hears the muffled
+sobs, and in the course of time, waves you on again.|
+|
+Finally, you pass a checkpoint, turn a corner, and reach the last barrier."
+CR>>
+
+<OBJECT CURTAINS
+	(LOC KIRIS-LITTER)
+	(OWNER KIRITSUBO)
+	(DESC "curtains")
+	(SYNONYM CURTAIN CURTAINS)
+	(FLAGS NDESCBIT SCOREBIT OPENABLE)
+	(ACTION CURTAINS-F)>
+
+<ROUTINE CURTAINS-F ()
+	 <COND (<VERB? OPEN CLOSE>
+		<COND (<AND <VERB? OPEN>
+			    <NOT <FSET? ,CURTAINS ,OPENBIT>>
+			    <QUEUED? I-ISHIDO-2>
+			    <G=? ,ISHIDO-CNT 3>>
+		       <SETG ISHIDO-CNT 5>
+		       <SETG ISHIDO-DISTRACTED? <>>
+		       <FSET ,CURTAINS ,OPENBIT>
+		       <TELL
+"You shove the curtains open, revealing not Kiritsubo, but Toranaga!  He is
+veiled and dressed in a woman's kimono, but there's no mistaking him!" CR>)
+		      (ELSE
+		       <TELL
+"Kiritsubo's maids politely bar your approach." CR>)>)
+	       (<VERB? LOOK-INSIDE>
+		<TELL
+"All you can see is a shadowy, veiled figure." CR>)>>
+
+<GLOBAL BEEN-IN-GARDEN? <>>
+
+<ROUTINE I-COME-BACK ()
+	 <COND (<AND <FSET? ,KIRITSUBO ,SCOREBIT>
+		     <LOC ,SAZUKO>>
+		<QUEUE I-COME-BACK 2>
+		<RFALSE>)>
+	 <SETG BEEN-IN-GARDEN? T>
+	 <COND (<AND <HERE? FORMAL-GARDEN TEA-HOUSE>
+		     <EQUAL? <LOC ,MARIKO>
+			     ,COURTYARD ,MARIKOS-LITTER ,FORECOURT>>
+		<TELL CR
+"Mariko calls to you again, \"Anjin-san, come here!\"  She speaks
+briefly to Yabu, who bustles into the garden to get you.  ">
+		<COND (<AND <HERE? TEA-HOUSE>
+			    <OR <IN? ,TORANAGA-IN-DRAG ,HERE>
+				<IN? ,KIRITSUBO ,HERE>>>
+		       <TELL
+"Yabu calls for you, searching the garden, and then looks in the
+tea house.  ">
+		       <COND (<IN? ,TORANAGA-IN-DRAG ,HERE>
+			      <JIGS-UP
+"He sees the veiled figure, who immediately draws a
+sword and surprisingly attacks you rather than Yabu.">)
+			     (ELSE
+			      <JIGS-UP
+"He sees Kiritsubo, and emits a yelp of surprise.  In moments, others
+are drawn by the commotion, and as soon as the situation becomes clear,
+a battle erupts.">)>
+		       <RFATAL>)
+		      (ELSE
+		       <TELL
+"He hustles you unceremoniously back to the courtyard." CR CR>
+		       <GOTO ,COURTYARD>)>)>>
+
+<OBJECT KIRIS-LITTER
+	;(LOC COURTYARD)
+	(OWNER KIRITSUBO)
+	(DESC "Kiritsubo's curtained litter")
+	(SYNONYM LITTER PALANQUIN)
+	(ADJECTIVE KIRITSUBO KIRI CURTAINED)
+	(FLAGS SEARCHBIT NOTHEBIT NOABIT VEHBIT OPENBIT CONTBIT)
+	(DESCFCN KIRIS-LITTER-DESC)
+	(GENERIC GENERIC-LITTER-F)
+	(ACTION KIRIS-LITTER-F)>
+
+<ROUTINE KIRIS-LITTER-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (ELSE
+		<TELL
+"Kiritsubo's curtained litter ">
+		<COND (<HERE? ,COURTYARD>
+		       <TELL "sits near the garden gate">)
+		      (ELSE
+		       <TELL "is nearby">)>
+		<COND (<OR <IN? .OBJ ,KIRITSUBO>
+			   <IN? .OBJ ,TORANAGA-IN-DRAG>>
+		       <TELL ", and through the ">
+		       <COND (<FSET? ,CURTAINS ,OPENBIT>
+			      <TELL "open">)
+			     (ELSE
+			      <TELL "closed">)>
+		       <TELL
+" curtains you can see the shadowy figure of Kiritsubo.">)
+		      (ELSE <TELL ".">)>
+		<RFATAL>)>>
+
+<ROUTINE KIRIS-LITTER-F ("OPT" (RARG <>))
+	 <COND (.RARG <RFALSE>)
+	       (<VERB? EXAMINE>
+		<COND (<FSET? ,CURTAINS ,OPENBIT>
+		       <TELL
+"Through the open curtains of the litter you can see ">
+		       <COND (,SEEN-TORANAGA?
+			      <TELL "a disguised Toranaga." CR>)
+			     (ELSE
+			      <TELL "Kiritsubo." CR>)>)
+		      (ELSE
+		       <TELL
+"The litter is heavily curtained, and the curtains are closed." CR>)>)
+	       (<VERB? BOARD>
+		<TELL
+"Kiritsubo's maid prevents you." CR>)
+	       (<VERB? OPEN CLOSE LOOK-INSIDE>
+		<PERFORM ,PRSA ,CURTAINS>
+		<RTRUE>)>>
+
+<OBJECT MARIKOS-LITTER
+	;(LOC COURTYARD)
+	(OWNER MARIKO)
+	(DESC "Mariko's litter")
+	(SYNONYM LITTER PALANQUIN)
+	(ADJECTIVE MARIKO)
+	(FLAGS SEARCHBIT NOABIT NOTHEBIT VEHBIT OPENBIT CONTBIT SCOREBIT)
+	(DESCFCN MARIKOS-LITTER-DESC)
+	(GENERIC GENERIC-LITTER-F)
+	(ACTION MARIKOS-LITTER-F)>
+
+<ROUTINE GENERIC-LITTER-F (R F)
+	 <COND (<OR <HERE? ,WOODS>
+		    <IN? ,WINNER ,MARIKOS-LITTER>>
+		,MARIKOS-LITTER)
+	       (<IN? ,YABU-PALANQUIN ,HERE>
+		,YABU-PALANQUIN)>>
+
+<ROUTINE MARIKOS-LITTER-F ("OPT" (RARG <>))
+	 <COND (<RARG? BEG>
+		<COND (<AND <HERE? WOODS CITY>
+			    <P? WALK>
+			    <NOT <PRSO? ,P?EAST>>>
+		       <TELL
+"\"No, Anjin-san, the docks are to the east, through the city.\"  The kaga-men
+don't move." CR>)
+		      (<VERB? SIT>
+		       <TELL G"You are already sitting down." CR>)
+		      (<AND <VERB? SLEEP>
+			    <NOT ,OPPONENT>
+			    <NOT <QUEUED? I-AMBUSH>>>
+		       <TELL
+"You manage to doze a little, regaining some strength." CR>)>)
+	       (<RARG? <>>
+		<COND (<VERB? BOARD>
+		       <COND (<HERE? ,WOODS>
+			      <GET-IN-LITTER>)
+			     (ELSE
+			      <TELL
+"Mariko's maid prevents you." CR>)>)>)>>
+
+<ROUTINE GET-IN-LITTER ("OPT" (FORCE? <>))
+	 <DEQUEUE I-ESCAPE-CONTINUES>
+	 <MOVE ,PLAYER ,MARIKOS-LITTER>
+	 <COND (.FORCE?
+		<TELL CR
+"Mariko motions to the escort, and with great politeness but very
+insistently, they load you">)
+	       (ELSE
+		<TELL
+"You sway on your feet, and allow yourself to be helped">)>
+	 <TELL
+" into the litter.  At once the procession starts again.  The rolling gait
+is soothing and you lay back, depleted." CR CR>
+	 <MOVE ,KIRIS-LITTER ,CITY>
+	 <MOVE ,BUNTARO ,CITY>
+	 <MOVE ,YABU ,CITY>
+	 <GOTO ,CITY>>
+
+<ROUTINE MARIKOS-LITTER-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (ELSE
+		<TELL
+"Mariko's litter is here">
+		<COND (<IN? ,MARIKO .OBJ>
+		       <TELL ", and through
+the open curtains you can see Mariko.">)
+		      (ELSE <TELL ".">)>
+		<RFATAL>)>>
+
+<ROOM FORECOURT
+      (LOC ROOMS)
+      (SCENE S-DEPARTURE)
+      (SCORE 1)			;"these points aren't assigned yet"
+      (DESC "Forecourt")
+      (AFTER DEPARTURE-AFTER-F)
+      (FDESC
+"Mariko walks up the crowded sunlit avenue toward the gates in the
+cul-de-sac.  Behind her is a bodyguard of Browns.  Unlike the Grays
+lining the avenue and watching from the battlements, none have armor
+or carry bows.  Swords are their only weapons.|
+|
+Mariko gets into her palanquin and sits.  \"Yoshinaka-san!  Please begin.\"")
+      (SYNONYM FORECOURT)
+      (NORTH TO COURTYARD IF FORTIFIED-GATE IS OPEN)
+      (IN TO COURTYARD IF FORTIFIED-GATE IS OPEN)
+      (SOUTH TO GATEWAY)
+      (FLAGS ONBIT OUTSIDE)
+      (GLOBAL FORTIFIED-GATE GARDEN-GATE SAMURAI-GUARDS)
+      (ACTION FORECOURT-F)>
+
+<ROUTINE FORECOURT-F (RARG)
+	 <COND (<RARG? SCENE-SETUP>
+		<DRESS-BLACKTHORNE>
+		<MOVE ,SWORDS ,BLACKTHORNE>
+		<FSET ,SWORDS ,WEARBIT>
+		<MOVE ,SAZUKO ,FORECOURT>
+		<MOVE ,KIRITSUBO ,FORECOURT>
+		<MOVE ,GRAYS ,FORECOURT>
+		<MOVE ,BROWNS ,FORECOURT>
+		<MOVE ,MARIKOS-LITTER ,FORECOURT>
+		<MOVE ,MARIKO ,MARIKOS-LITTER>
+		<QUEUE I-DEPARTURE -1>)
+	       (<RARG? LOOK>
+		<TELL
+"This is the forecourt of Toranaga's keep.  To the south is the maze of
+paths and walls that makes up the rest of the castle.  To the north, through an
+arched gateway with a fortified gate, is a courtyard.">
+		<COND (<SCENE? ,S-DEPARTURE ,S-SEPPUKU>
+		       <TELL " The forecourt is crowded with Grays,
+other samurai and their women.">)>
+		<CRLF>)
+	       (<RARG? LEAVE>
+		<COND (<AND <SCENE? ,S-ESCAPE>
+			    <IN? ,KIRIS-LITTER ,FORECOURT>>
+		       <TELL-CHECKPOINTS>
+		       <CRLF>)>)
+	       (<RARG? BEG>
+		<COND (<P? WALK>
+		       <COND (<SCENE? ,S-DEPARTURE>
+			      <COND (<QUEUED? I-FIGHT>
+				     <COND (<JIGS-UP? ,J-FLEE
+"You'd never get away!  It's a fight to the finish.">
+					    <JIGS-UP
+"Your opponent, who until now has shown reluctance to do you real harm,
+sees you attempting to flee, and charges you.  He attacks viciously,
+overwhelming your inexpert defense.  In moments, you are cut down.">)
+					   (ELSE <RTRUE>)>)
+				    (ELSE
+				     <TELL
+"Mariko says, \"Please, Anjin-san, you cannot abandon me now.  I must
+fulfill my duty.\"" CR>)>)
+			     (<EQUAL? ,P-WALK-DIR ,P?NORTH>
+			      <COND (<AND <SCENE? ,S-ESCAPE>
+					  <IN? ,CORTEGE ,HERE>>
+				     <TELL
+"The guards won't let you back through the gate." CR>)>)
+			     (<EQUAL? ,P-WALK-DIR ,P?SOUTH>
+			      <COND (<SCENE? ,S-ESCAPE>
+				     <COND (<QUEUED? I-ISHIDO>
+					    <TELL
+"The Grays stop you, indicating that you must leave with Kiritsubo or
+not at all." CR>)
+					   (<QUEUED? I-KIRI>
+					    <COND (<IN? ,SAZUKO ,COURTYARD>
+						   <TELL
+"You start off into the maze of the castle, and then think better of
+it, deciding to wait for the rest of the cortege." CR>)
+						  (<OR <IN? ,KIRIS-LITTER ,GATEWAY>
+						       <IN? ,KIRIS-LITTER ,FORECOURT>>
+						   <RFALSE>)
+						  (ELSE
+						   <TELL
+"You decide it would be too dangerous to get ahead of the rest of the
+cortege." CR>)>)>)
+				    (<SCENE? ,S-DEPARTURE>
+				     <TELL
+"A near-solid mass of Gray samurai blocks the avenue." CR>)
+				    (<SCENE? ,S-SEPPUKU>
+				     <TELL
+"The avenue is blocked by the onlookers nervously anticipating the
+events to come." CR>)>)>)
+		      (<AND <VERB? PARRY STOP>
+			    <HELD? ,SWORDS>
+			    <QUEUED? I-FIGHT>>
+		       <TELL
+"You force your sword around, desperately trying to block the attack!" CR>)>)>>
+
+<OBJECT FORTIFIED-GATE
+	(LOC LOCAL-GLOBALS)
+	(DESC "fortified gate")
+	(SYNONYM GATE DOOR)
+	(ADJECTIVE FORTIFIED)
+	(FLAGS DOORBIT)
+	(ACTION FORTIFIED-GATE-F)>
+
+<ROUTINE FORTIFIED-GATE-F ()
+	 <COND (<VERB? OPEN CLOSE>
+		<TELL
+"You could no more open or close this gate by yourself than tear
+down Osaka Castle with your bare hands." CR>)>>
+
+<OBJECT PORTCULLIS
+	(LOC LOCAL-GLOBALS)
+	(DESC "portcullis")
+	(SYNONYM PORTCULLIS)
+	(ADJECTIVE IRON)
+	(FLAGS DOORBIT OPENBIT)>
+
+<ROOM GATEWAY
+      (LOC ROOMS)
+      (DESC "Gateway")
+      (SYNONYM GATEWAY)
+      (SOUTH TO ON-BRIDGE)
+      (FLAGS ONBIT OUTSIDE)
+      (GLOBAL SAMURAI-GUARDS)
+      (ACTION GATEWAY-F)>
+
+<ROUTINE GATEWAY-F (RARG "AUX" (MAD? <>))
+	 <COND (<RARG? LOOK>
+		<TELL
+"This is the last portcullis and last gateway of the castle, and beyond
+is the final drawbridge and the final moat.  To the south, on the far side
+of the bridge,
+is the ultimate strongpoint.">
+		<COND (<SCENE? ,S-ESCAPE>
+		       <TELL " A multitude of flares turn the night into
+crimson day.">)
+		      (ELSE
+		       <TELL
+" Crowds of curious onlookers clog the street.">)>
+		<CRLF>)
+	       (<RARG? ENTER>
+		<COND (<EQUAL? ,OHERE ,FORECOURT>
+		       <SETG ISHIDO-CNT 0>
+		       <QUEUE I-ISHIDO-2 -1>)>)
+	       (<RARG? BEG>
+		<COND (<SCENE? ,S-ESCAPE>
+		       <SET MAD?
+			    <OR <QUEUED? I-ISHIDO-2>
+				<QUEUED? I-MADNESS>>>
+		       <COND (<P? EXAMINE (MARIKO YABU BUNTARO)>
+			      <COND (.MAD?
+				     <TELL D ,PRSO " looks very ">
+				     <COND (<QUEUED? I-MADNESS>
+					    <TELL "scared." CR>)
+					   (ELSE
+					    <TELL "worried." CR>)>)>)
+			     (<P? HELP TORANAGA>
+			      <TELL
+"Precisely what you need to do, but how?" CR>)
+			     (<VERB? WALK>
+			      <COND (<QUEUED? I-MARIKO-FOLLOW>
+				     <SETG ISHIDO-DISTRACTED? ,PRSA>
+				     <RFALSE>)
+				    (<PRSO? P?SOUTH>
+				     <COND (.MAD?
+					    <COND (,SEEN-MAD-SCENE?
+						   <SETG ISHIDO-DISTRACTED?
+							 ,PRSA>
+						   <TELL
+"You bow to Ishido like a spastic puppet and half walk, half dance for
+the gateway.  \"Follow me, follow me!\" you shout, like a demented
+Pied Piper." CR>)>
+					    <TELL "The Grays bar the way." CR>
+					    <COND (,SEEN-MAD-SCENE?
+						   <TELL CR
+"You roar with feigned rage and imperiously order them out of the way,
+then immediately switch to hysterical laughter." CR>)>
+				     <RTRUE>)>)
+				    (<AND <PRSO? P?NORTH>
+					  .MAD?>
+				     <TELL
+"The narrow street is blocked by the litters, kaga-men, and escorts." CR>)>)
+			     (<AND <OR <P? STOP (<> CRAZY)>
+				       <P? ACT SANE>>
+				   <QUEUED? I-MARIKO-FOLLOW>>
+			      <COND (<NOT <FSET? ,BLACKTHORNE ,RMUNGBIT>>
+				     <FSET ,BLACKTHORNE ,RMUNGBIT>
+				     <SETG ISHIDO-DISTRACTED? ,PRSA>
+				     <TELL
+"You stop instantly, turn and walk quietly toward the bridge." CR>)
+				    (ELSE
+				     <TELL
+"You've already stopped." CR>)>)
+			     (<P? (TAKE STOP) ISHIDO>
+			      <PERFORM ,V?ATTACK ,ISHIDO>
+			      <RTRUE>)
+			     (<P? BOW ISHIDO>
+			      <TELL
+"He looks at you contemptuously." CR>)
+			     (<AND <HOSTILE-VERB?>
+				   <PRSO? ISHIDO>>
+			      <COND (<EQUAL? ,MADNESS-CNT 3>
+				     <SETG ISHIDO-DISTRACTED? ,PRSA>
+				     <TELL
+"You go berserk, bunching your fists and hurling yourself at
+Ishido.  It takes four Browns to haul you off, then Buntaro smashes you hard on
+the back of your neck, stunning you." CR>)
+				    (<JIGS-UP? ,J-ISHIDO
+"The moment for such an action has passed.  Now it would be fatal.">
+				     <JIGS-UP
+"Ishido is stunned by your ferocity, shocked by your madness, and amazed
+by your insolence.  His sword, unsurprisingly, is as sharp as it looks,
+and he uses it well.">)
+				    (ELSE <RTRUE>)>)
+			     (<OR <ACT-CRAZY?>
+				  <P? DISTRACT ISHIDO>>
+			      <COND (<OR <G=? ,ISHIDO-CNT 3>
+					 <QUEUED? I-MADNESS>>
+				     <COND (<L? ,JERK-CNT 2>
+					    <SETG ISHIDO-DISTRACTED? ,PRSA>)>
+				     <COND (<NOT ,SEEN-MAD-SCENE?>
+					    <SETG SEEN-MAD-SCENE? T>
+					    <MARGINAL-PIC ,P-MAD-SCENE>)>
+				     <COND (<EQUAL? ,ISHIDO-CNT 3 4 5>
+					    <COND (<L? ,JERK-CNT 2>
+						   <TELL
+"Ishido and the others whirl on you dumbfounded.">
+						   <TORANAGA-CLOSES-CURTAIN>
+						   <CRLF>
+						   <SCORE-OBJECT ,CRAZY>)
+						  (ELSE
+						   <TELL
+"Ishido starts briefly, but is more interested in Kiri's litter." CR>)>)
+					   (ELSE
+					    <TELL
+"Everyone continues to stare at you.  The tension is incredible, and your
+exhaustion is beginning to take its toll." CR>)>)>)>)>)>>
+
+<GLOBAL SEEN-MAD-SCENE? <>>
+
+<ROUTINE TORANAGA-CLOSES-CURTAIN ()
+	 <SETG ISHIDO-DISTRACTED? ,PRSA>
+	 <DEQUEUE I-ISHIDO-2>
+	 <SETG ISHIDO-CNT 0>
+	 <QUEUE I-MADNESS -1>
+	 <COND (<FSET? ,CURTAINS ,OPENBIT>
+		<FCLEAR ,CURTAINS ,OPENBIT>
+		<TELL " For an instant Toranaga
+is in full view behind Ishido.  In the never-ending second before Toranaga
+tugs the curtains closed again, you know that Yabu has recognized him,
+and Mariko, and probably Buntaro and some of the Brown samurai.">)>>
+
+<GLOBAL ISHIDO-DISTRACTED? <>>
+
+<GLOBAL JERK-CNT 0>
+
+<ROUTINE I-ISHIDO-2 ()
+	 <ZLINES ,ISHIDO-CNT
+		 (DELAY
+		  <COND (<OR <QUEUED? I-KIRI>
+			     <NOT <HERE? ,GATEWAY>>
+			     <NOT <IN? ,KIRIS-LITTER ,HERE>>>
+			 <RFALSE>)>)
+		 (;1
+		  <MOVE ,ISHIDO ,GATEWAY>
+		  <THIS-IS-IT ,ISHIDO>
+		  <TELL CR
+"Ishido steps from the shadows.  The Browns see him almost in the same
+instant.  Hostility whips though them.  Buntaro almost leaps past you to
+get nearer the head of the column." CR>)
+		 (;2
+		  <MOVE ,PARCHMENT ,ISHIDO>
+		  <THIS-IS-IT ,ISHIDO>
+		  <TELL CR
+"Ishido takes a roll of parchment out of his sleeve.  \"I wanted to ask
+Lady Kiritsubo if she'd take this with her to Yedo.  For my niece.  It's
+unlikely I'll go to Yedo for some time.\"|
+|
+\"Certainly.\"  Yabu puts out his hand to take the parchment.|
+|
+\"Don't trouble yourself, Yabu-san.  I'll ask her.\"  Ishido walks toward
+the litter." CR CR
+"The maids obsequiously intercept Ishido.  \"May I take the message,
+Lord.  My Mis--\"|
+|
+\"No.\"  To Ishido's surprise the maids do not move out of the way." CR>)
+		 (;3
+		  <TELL CR
+"\"Move!\" Buntaro snarls.  Both maids back off, frightened.|
+|
+Ishido bows to the curtain.  \"Kiritsubo-san, I wonder if you'd be kind
+enough to take this message for me to Yedo?  To my niece?\"|
+|
+There is a slight hesitation between the sobs and the figure bows an
+assent.|
+|
+\"Thank you.\"  Ishido offers up the slim roll of parchment an inch from
+the curtains." CR>)
+		 (;4
+		  <THIS-IS-IT ,ISHIDO>
+		  <TELL CR
+"Everyone is waiting for the hand to appear.">
+		  <COND (,SEEN-TORANAGA?
+			 <TELL
+" You realize Toranaga is trapped.  Politeness demands that he take the
+scroll and his hand will give him away!">)>
+		  <TELL CR CR
+"Ishido is getting impatient.  \"Kiritsubo-san?\" he calls." CR>)
+		 (;5
+		  <COND (<NOT ,ISHIDO-DISTRACTED?>
+			 <THIS-IS-IT ,ISHIDO>
+			 <COND (<IN? ,ISHIDO <LOC ,KIRIS-LITTER>>
+				<FSET ,CURTAINS ,OPENBIT>
+				<SETG JERK-CNT <+ ,JERK-CNT 1>>
+				<TELL CR
+"Ishido takes a quick pace forward and jerks the curtains of the
+litter apart." CR>)
+			       (ELSE
+				<TELL CR
+G"Ishido takes a few paces toward the retreating litter." CR>)>)>)
+		 (;6
+		  <COND (<NOT ,ISHIDO-DISTRACTED?>
+			 <COND (<IN? ,ISHIDO <LOC ,KIRIS-LITTER>>
+				<DEQUEUE I-ISHIDO-2>
+				<TELL CR
+"In shock, Ishido stares into the litter, recognizing Toranaga in
+spite of his disguise.  \"Guards!\" he yells, as Yabu, Mariko, and
+Buntaro all realize what is happening.  Buntaro begins to draw his
+sword, but before he can strike at Ishido a hail of arrows stitches
+him.  Within moments the column is a shambles as the Browns and Grays
+try to defend their masters." CR CR>
+				<JIGS-UP
+"Toranaga, encumbered by his disguise, is unable even to defend
+himself.  It is only seconds before both he and Ishido are cut down,
+and not long after, an arrow finds your heart.">
+				<RFATAL>)
+			       (ELSE
+				<TELL CR
+G"Ishido takes a few paces toward the retreating litter, then
+stops." CR>)>)>)
+		 (DELAY
+		  <COND (<AND <NOT ,ISHIDO-DISTRACTED?>
+			      <OR <IN? ,KIRIS-LITTER ,AT-PORTCULLIS>
+				  <IN? ,KIRIS-LITTER ,ON-BRIDGE>>>
+			 <COND (<G? ,DELAY-CNT 2>
+				<TELL CR
+"Ishido seems to come to a decision.  It appears to involve arrows." CR>
+				<JIGS-UP>
+				<RFATAL>)
+			       (ELSE
+				<TELL CR
+"Ishido watches the cortege, a strange expression on his face." CR>
+				<RTRUE>)>)>)
+		 (<DEQUEUE I-ISHIDO-2>
+		  <RFALSE>)>>
+
+<ROOM ON-BRIDGE
+      (SCENE S-ESCAPE)
+      (LOC ROOMS)
+      (DESC "Bridge")
+      (SYNONYM BRIDGE)
+      (ADJECTIVE LAST)
+      (LDESC
+"This is the last bridge.  It leads south over the moat from the last
+checkpoint.")
+      (NORTH TO GATEWAY)
+      (SOUTH TO AT-PORTCULLIS)
+      (FLAGS ONBIT OUTSIDE)
+      (ACTION ON-BRIDGE-F)>
+
+<ROUTINE ON-BRIDGE-F (RARG)
+	 <COND (<RARG? BEG>
+		<COND (<P? (LEAP DIVE) (ON-BRIDGE GLOBAL-HERE)>
+		       <COND (<JIGS-UP? ,J-MOAT>
+			      <JIGS-UP
+"You plunge into the moat and drown.">)
+			     (ELSE <RTRUE>)>)
+		      (<SCENE? ,S-SEPPUKU> <RFALSE>)
+		      (<AND <P? WALK P?SOUTH>
+			    <QUEUED? I-MARIKO-FOLLOW>>
+		       <SETG ISHIDO-DISTRACTED? ,PRSA>
+		       <RFALSE>)>)>>
+
+<ROOM AT-PORTCULLIS
+      (LOC ROOMS)
+      (DESC "Portcullis")
+      (SYNONYM PORTCULLIS)
+      (ADJECTIVE LAST)
+      (LDESC
+"This is the last portcullis.  To the north is the bridge over the
+moat.  Guards watch you curiously.")
+      (SOUTH TO WOODS)
+      (NORTH TO ON-BRIDGE)
+      (FLAGS ONBIT OUTSIDE)
+      (GLOBAL PORTCULLIS SAMURAI-GUARDS)
+      (ACTION AT-PORTCULLIS-F)>
+
+<ROUTINE AT-PORTCULLIS-F (RARG)
+	 <COND (<RARG? BEG>
+		<COND (<SCENE? ,S-SEPPUKU> <RFALSE>)
+		      (<P? WALK SOUTH>
+		       <COND (<QUEUED? I-MADNESS>
+			      <DEQUEUE I-MADNESS>
+			      <TELL
+"It requires all of your remaining will to stay erect.  You">
+			      <COND (<IN? ,SANDALS ,BLACKTHORNE>
+				     <MOVE ,SANDALS ,HERE>
+				     <FCLEAR ,SANDALS ,WEARBIT>
+				     <TELL " have lost
+your sandals, you">)>
+			      
+			      <TELL
+"r face burns from Ishido's blow, and your head
+pounds with pain.  The last guards let you through the portcullis
+and beyond.  They also let Mariko past without stopping, and then
+the litters.|
+|
+You lead the way down a slight hill, past some open ground and
+into a wooded area." CR CR>
+			      <GOTO ,WOODS>)>)
+		      (<P? WALK P?NORTH>
+		       <TELL
+"You are stopped and refused entry at the checkpoint." CR>)>)>>
+
+<ROOM WOODS
+      (LOC ROOMS)
+      (DESC "Wooded Area")
+      (SYNONYM AREA)
+      (ADJECTIVE WOODED)
+      (LDESC
+"This is a wooded area totally out of sight of the castle.  To the east
+is the city proper.")
+      (EAST TO CITY)
+      (NORTH TO AT-PORTCULLIS)
+      (FLAGS ONBIT OUTSIDE SCOREBIT)
+      (ACTION WOODS-F)>
+
+<ROUTINE WOODS-F (RARG)
+	 <COND (<RARG? BEG>
+		<COND (<AND <VERB? WALK>
+			    <NOT <IN? ,PLAYER ,MARIKOS-LITTER>>
+			    <NOT <FSET? ,MAZE ,TOUCHBIT>>>
+		       <TELL
+"You haven't the strength to walk: your performance has totally exhausted
+you.  You try to stand, but your body doesn't obey." CR>)>)
+	       (<RARG? END>
+		<COND (<SCENE? ,S-ESCAPE>
+		       <COND (<FSET? ,WOODS ,SCOREBIT>
+			      <MOVE-CORTEGE ,WOODS>
+			      <MOVE ,MARIKO ,WOODS>
+			      <QUEUE I-ESCAPE-CONTINUES 2>
+			      <B-SIT>
+			      <TELL CR
+"As you enter the wooded area and assure yourself that you are
+out of sight of the castle, you gratefully collapse." CR>
+			      <SCORE-OBJECT ,WOODS>)>)>)
+	       (<RARG? ENTER>
+		<DEQUEUE I-ISHIDO-2>
+		<DEQUEUE I-MARIKO-FOLLOW>)>>
+
+<ROUTINE I-ESCAPE-CONTINUES ()
+	 <ZLINES ,LITTER-CNT
+		 (<QUEUE I-ESCAPE-CONTINUES -1>
+		  <COND (<HERE? ,WOODS>
+			 <THIS-IS-IT ,MARIKO>
+			 <THIS-IS-IT ,MARIKOS-LITTER>
+			 <TELL CR
+"\"Anjin-san!\" Mariko calls to you, jarring you out of your stupor.  \"It's
+time to move on.\"  She glances significantly at the Gray captain,
+and adds, \"Kiritsubo feels we must hurry for the tide.  All the trouble
+you have caused has made her even more upset.  Please use my litter,
+I'm really very strong and you needn't worry.\"" CR>)>)
+		 (DELAY
+		  <COND (<AND <HERE? ,WOODS>
+			      <NOT <IN? ,PLAYER ,MARIKOS-LITTER>>>
+			 <COND (<G? ,DELAY-CNT 2>
+				<GET-IN-LITTER T>)
+			       (ELSE
+				<TELL CR
+"Mariko says, \"Please hurry, Anjin-san!\"" CR>
+				<RTRUE>)>)>)
+		 (<DEQUEUE I-ESCAPE-CONTINUES>
+		  <RFALSE>)>>
+
+<ROUTINE I-MADNESS ()
+	 <COND (,ISHIDO-DISTRACTED?
+		<SETG ISHIDO-DISTRACTED? <>>
+		<ZLINES ,MADNESS-CNT
+			(;1
+			 <MOVE ,MARIKO ,HERE>
+			 <THIS-IS-IT ,ISHIDO>
+			 <TELL CR
+"Ishido draws his sword." CR>)
+			(;2
+			 <THIS-IS-IT ,ISHIDO>
+			 <TELL CR
+"Ishido watches you, his sword raised high, ready to strike, but your
+actions have momentarily stunned him." CR>)
+			(;3
+			 <THIS-IS-IT ,ISHIDO>
+			 <TELL CR
+"Ishido's reflexes take over and he sends his sword slashing for your
+throat.  Mariko cries out.  The blade stops a hair's breadth from your
+neck.  She tries to ">
+			 <COND (<IN? ,PARCHMENT ,TORANAGA>
+				<TELL "explain what you said, and Ishido">)
+			       (ELSE
+				<TELL "soothe Ishido, and he">)>
+			 <SETG OPPONENT ,ISHIDO>
+			 <TELL " lowers his sword,
+listens for a moment, then shouts with increasing vehemence and hits
+you in the face with the back of his hand." CR>)
+			(;4
+			 <THIS-IS-IT ,ISHIDO>
+			 <TELL CR
+"Yabu begins placating Ishido, Mariko tearfully repeating over and
+over in forced semihysteria that the mad barbarian believed he was
+only trying to save Ishido from a bad " I "kami" ".">
+			 <COND (<EQUAL? ,ISHIDO-DISTRACTED?
+					,V?ATTACK ,V?HIT>
+				<TELL " \"It's the worst
+insult to touch their faces, just like with us!\"">)>
+			 <CRLF>)
+			(;5
+			 <SETG OPPONENT <>>
+			 <THIS-IS-IT ,ISHIDO>
+			 <TELL CR
+"Ishido grabs a bow and arrow.  \"He's a mad dog!  Mad dogs have to be
+dealt with!\"" CR>)
+			(;6
+			 <QUEUE I-MARIKO-FOLLOW -1>
+			 <TELL CR
+"Mariko leaps forward from her position near Toranaga's litter.  \"Don't
+worry, Lord Ishido.  It's a momentary madness.\"  She approaches
+you.  \"I can help now, Anjin-san.  We have to try to walk out.  I will follow
+you.  Please stop now.\"" CR>)
+			(DELAY
+			 <COND (<OR <P? STOP (<> CRAZY)>
+				    <P? ACT SANE>>
+				<TELL CR
+"Ishido stares at you, enraged but perplexed." CR>
+				<RTRUE>)>)
+			(;7
+			 <COND (<HERE? ,ON-BRIDGE>
+				<TELL CR
+"Yabu comes to life and says to Ishido, \"If you want him killed, let me
+do it.\"  Then he comes very close and drops his voice.  \"Leave him
+alive.  He's more valuable alive.  Trust me.  We need him alive.\"  Ishido
+puts the
+bow down." CR>)
+			       (ELSE
+				<DEQUEUE I-MADNESS>
+				<CRLF>
+				<JIGS-UP
+"Ishido aims the bow and lets fly.  It's a perfect shot.  As you die,
+Ishido says, \"Thus I deal with mad dogs ... and barbarians.\"">
+				<RFATAL>)>)
+			(;8
+			 <COND (<AND <HERE? ,ON-BRIDGE ,AT-PORTCULLIS>
+				     <IN? ,CORTEGE ,GATEWAY>>
+				<MOVE-CORTEGE ,ON-BRIDGE>
+				<TELL CR
+"Mariko looks back for an instant.  \"They're following, Anjin-san,
+both litters are through the gate and they're on the bridge now!\"" CR>)>)
+			(;9
+			 <COND (<AND <HERE? ,AT-PORTCULLIS ,WOODS>
+				     <IN? ,CORTEGE ,ON-BRIDGE>>
+				<MOVE-CORTEGE ,AT-PORTCULLIS>
+				<TELL CR
+"Quickly, the cortege follows to the portcullis.  Mariko urges you on." CR>)>)
+			(;10
+			 <COND (<AND <HERE? ,WOODS>
+				     <IN? ,CORTEGE ,PORTCULLIS>>
+				<MOVE-CORTEGE ,WOODS>
+				<TELL CR
+"Quickly, the cortege goes through the portcullis and towards the
+woods.  Mariko urges you on." CR>
+				<DEQUEUE I-MADNESS>)>)>)
+	       (<HERE? ,GATEWAY ,ON-BRIDGE ,AT-PORTCULLIS>
+		<QUEUE I-ISHIDO-2 -1>
+		<COND (<NOT <EQUAL? ,ISHIDO-CNT 5 6>>
+		       <SETG ISHIDO-CNT 4>)>
+		<COND (<AND <IN? ,MARIKO ,HERE>
+			    <HERE? ,ON-BRIDGE>>
+		       <TELL CR
+"Mariko looks back for an instant.  \"He's not letting them go!\"" CR>)>
+		<I-ISHIDO-2>)>>
+
+<ROUTINE MOVE-CORTEGE (L)
+	 <MOVE ,CORTEGE .L>
+	 <MOVE ,KIRIS-LITTER .L>
+	 <MOVE ,YABU .L>
+	 <MOVE ,BUNTARO .L>
+	 <MOVE ,MARIKOS-LITTER .L>>
+
+<OBJECT PARCHMENT
+	(DESC "roll of parchment")
+	(OWNER PARCHMENT)
+	(SYNONYM PARCHMENT ROLL MESSAGE SCROLL)
+	(ADJECTIVE SLIM)
+	(FLAGS TAKEBIT READBIT SCOREBIT)
+	(ACTION PARCHMENT-F)>
+
+<ROUTINE PARCHMENT-F ()
+	 <COND (<VERB? TAKE>
+		<COND (<IN? ,PARCHMENT ,ISHIDO>
+		       <COND (<OR <G=? ,ISHIDO-CNT 5>
+				  <QUEUED? I-MADNESS>>
+			      <SETG ISHIDO-DISTRACTED? ,PRSA>
+			      <MOVE ,PRSO ,WINNER>
+			      <TELL
+"You grab the parchment out of Ishido's fingers.  He stares at you,
+shocked.">
+			      <TORANAGA-CLOSES-CURTAIN>
+			      <CRLF>
+			      <SCORE-OBJECT ,PARCHMENT>)
+			     (<JIGS-UP? ,J-PARCHMENT
+"To take the parchment now would cost you your life!">
+			      <JIGS-UP
+"You snatch the roll of parchment from Ishido's grasp.  He turns,
+maddened by your insolence.  His sword is out of its sheath in no
+time, and swings toward you...">)
+			     (ELSE <RTRUE>)>)
+		      (<IN? ,PARCHMENT ,KIRIS-LITTER>
+		       <TELL
+"You can't reach the parchment any longer." CR>)>)
+	       (<OR <P? GIVE PARCHMENT TORANAGA-IN-DRAG>
+		    <P? PUT PARCHMENT KIRIS-LITTER>
+		    <P? THROW PARCHMENT KIRIS-LITTER>
+		    <P? PUT-ON PARCHMENT CURTAINS>>
+		<COND (<NOT <QUEUED? I-MADNESS>>
+		       <SETG ISHIDO-DISTRACTED? ,PRSA>
+		       <TELL
+"You shove the parchment into the closed curtains, looking for a crack
+or gap, but all you succeed into doing is getting the parchment
+entangled." CR>)
+		      (ELSE
+		       <MOVE ,PARCHMENT ,KIRIS-LITTER>
+		       <SCORE-OBJECT ,CURTAINS>
+		       <QUEUE I-ISHIDO-2 -1>
+		       <SETG ISHIDO-CNT 4>
+		       <SETG ISHIDO-DISTRACTED? ,PRSA>
+		       <TELL
+"You thrust the parchment through the curtains, babbling the
+first foolish thing that comes into your head.  \"It's bad luck in my
+country for a prince to give a message himself like a common bastard ...
+bad luck ...\" Everyone watches as you do this." CR>)>)
+	       (<P? (TEAR MUNG) PARCHMENT>
+		<SETG ISHIDO-DISTRACTED? ,PRSA>
+		<REMOVE ,PARCHMENT>
+		<TELL
+"You tear the parchment into pieces, scattering them on the
+ground.  Ishido stares at you in mingled surprise and hatred." CR>)
+	       (<P? READ PARCHMENT>
+		<TELL
+"You can't read Japanese." CR>)>>
+
+<GLOBAL SEEN-TORANAGA? <>>
+
+<ROOM CITY
+      (LOC ROOMS)
+      (DESC "City of Osaka")
+      (OWNER CITY)
+      (SYNONYM CITY OSAKA)
+      (LDESC
+"The city by night is a fairyland.  The rich houses have many colored
+lanterns, oil-lit and candle-lit, hanging over their gateways and in
+their gardens, the shoji screens giving off a delightful
+translucence.  Even the poor houses are mellowed by the shojis.  Lanterns
+light the way of pedestrians and kagas, and of samurai on horseback.|
+|
+The harbor is to the east.")
+      (EAST TO MAZE)
+      (WEST SORRY "You can't return to the castle now.")
+      (FLAGS ONBIT OUTSIDE)
+      (GLOBAL HOUSE)
+      (ACTION CITY-F)>
+
+<ROUTINE CITY-F ("OPT" (RARG <>))
+	 <COND (<RARG? ENTER>
+		<COND (<EQUAL? ,OHERE ,WOODS>
+		       <MOVE-ALL ,WOODS ,CITY>)>)
+	       (<RARG? <>>
+		<COND (<VERB? FIND>
+		       <COND (<G=? ,SCENE ,S-VOYAGE>
+			      <TELL
+"Osaka is the greatest and proudest city of Japan.  It is on the sea several
+days sail west of Anjiro." CR>)
+			     (ELSE
+			      <TELL
+"You have no idea where Osaka is." CR>)>)>)>>
+
+<ROOM WAREHOUSE
+      (LOC ROOMS)
+      (DESC "Warehouse")
+      (SYNONYM WAREHOUSE)
+      (LDESC
+"You are in a narrow and deserted back street near the dock.  The shadows
+of a nearby warehouse shield the party from the view of anyone on the
+wharf to the east.")
+      (WEST SORRY "There's no time for that now.")
+      (EAST TO WHARF)
+      (FLAGS ONBIT OUTSIDE)
+      (ACTION WAREHOUSE-F)>
+
+<ROUTINE WAREHOUSE-F ("OPT" (RARG <>))
+	 <COND (<RARG? BEG>
+		<COND (<P? WALK P?EAST>
+		       <COND (<IN? ,MARIKO ,WHARF>
+			      <TELL
+"You and the six samurai race after her.  Mariko is very fleet and you don't
+catch up with her as you round the corner
+and head across the open space.  You have never felt so naked.  The moment you
+appear, the Grays spot you and surge forward." CR CR>
+			      <GOTO ,WHARF>
+			      <MOVE ,BROWNS ,WHARF>
+			      <MOVE ,GRAYS ,WHARF>
+			      <MOVE ,GRAY-LEADER ,MAIN-DECK>
+			      <FSET ,GRAY-LEADER ,NDESCBIT>
+			      <RTRUE>)
+			     (<IN? ,MARIKO ,WAREHOUSE>
+			      <COND (<EQUAL? ,QCONTEXT ,MARIKO>
+				     <TELL
+"\"You must agree first, Anjin-san.">)
+				    (ELSE
+				     <TELL
+"\"Not yet, not yet!  The timing must be perfect!">)>
+			      <TELL "\" Mariko chides." CR>)>)>)
+	       (<RARG? ENTER>
+		<COND (<EQUAL? ,OHERE ,MAZE>
+		       <MOVE-ALL ,MAZE ,WAREHOUSE>
+		       <QUEUE I-RUSE -1>)>)>>
+
+<OBJECT LARGE-KNIFE
+	(DESC "large knife")
+	(SYNONYM KNIFE)
+	(ADJECTIVE LARGE)
+	(FLAGS TAKEBIT WEARABLE WEAPONBIT)
+	(GENERIC GENERIC-KNIFE-F)
+	(ACTION LARGE-KNIFE-F)>
+
+<ROUTINE LARGE-KNIFE-F ()
+	 <COND (<VERB? TAKE UNTIE TAKE-OFF USE DRAW PICK>
+		<COND (<FSET? ,PRSO ,WEARBIT>
+		       <FCLEAR ,PRSO ,WEARBIT>
+		       <TELL
+"You take the knife out from the sash and heft it.  It feels good." CR>)
+		      (<HELD? ,PRSO>
+		       <TELL G"You're already using it." CR>)>)
+	       (<VERB? TIE WEAR PUT-AWAY>
+		<COND (<NOT <HELD? ,PRSO>>
+		       <TELL "You don't have it." CR>)
+		      (<NOT <FSET? ,PRSO ,WEARBIT>>
+		       <FSET ,PRSO ,WEARBIT>
+		       <TELL
+"You thrust the knife back into your sash." CR>)
+		      (ELSE
+		       <TELL G"It already is." CR>)>)>>
+
+<ROUTINE GENERIC-KNIFE-F (R F)
+	 <COND (<AND <FSET? ,LARGE-KNIFE ,WEARBIT>
+		     <NOT <FSET? ,SMALL-KNIFE ,WEARBIT>>>
+		,SMALL-KNIFE)
+	       (<AND <NOT <FSET? ,LARGE-KNIFE ,WEARBIT>>
+		     <FSET? ,SMALL-KNIFE ,WEARBIT>>
+		,LARGE-KNIFE)>>
+
+<OBJECT SMALL-KNIFE
+	(DESC "small knife")
+	(SYNONYM KNIFE)
+	(ADJECTIVE SMALL)
+	(FLAGS TAKEBIT WEARABLE WEARBIT WEAPONBIT)
+	(GENERIC GENERIC-KNIFE-F)
+	(ACTION SMALL-KNIFE-F)>
+
+<ROUTINE SMALL-KNIFE-F ()
+	 <COND (<VERB? TAKE UNTIE TAKE-OFF USE DRAW PICK>
+		<COND (<FSET? ,PRSO ,WEARBIT>
+		       <FCLEAR ,PRSO ,WEARBIT>
+		       <TELL
+"You untie the silk ribbon and take the knife into your hand." CR>)
+		      (<HELD? ,PRSO>
+		       <TELL G"You're already using it." CR>)>)
+	       (<VERB? TIE WEAR PUT-AWAY>
+		<COND (<NOT <HELD? ,PRSO>>
+		       <TELL "You don't have it." CR>)
+		      (<NOT <FSET? ,PRSO ,WEARBIT>>
+		       <FSET ,PRSO ,WEARBIT>
+		       <TELL
+"You tie the knife to your arm again." CR>)
+		      (ELSE
+		       <TELL G"It already is." CR>)>)>>
+
+<GLOBAL OPPONENT <>>
+<GLOBAL DODGED? <>>
+
+<ROUTINE I-RUSE ()
+	 <ZLINES ,RUSE-CNT
+		 (<SETG QCONTEXT ,MARIKO>
+		  <TELL CR
+"Toranaga beckons to Mariko, and they converse.  Mariko nods.  \"Anjin-san,
+my Master orders that we, with six samurai, go to the galley.  We are to
+tell the Grays on board that we were ambushed, and that our Gray escort
+sent us ahead to get help, that the battle is still raging.  We will draw
+them away from the galley, and our Browns can recover it and we will be
+free.  Do you understand?\"" CR>)
+		 (DELAY
+		  <COND (<EQUAL? ,QCONTEXT ,MARIKO>
+			 <TELL CR
+"\"Please, Anjin-san, this is a good plan, it is my Master's plan.  Do you
+agree?\"" CR>
+			 <RTRUE>)>)
+		 (<MOVE ,MARIKO ,WHARF>
+		  <TELL CR
+"Mariko laughs, bows once to Toranaga, and runs off." CR>)
+		 (DELAY
+		  <COND (<NOT <IN? ,BLACKTHORNE ,WHARF>>
+			 <COND (<G? ,DELAY-CNT 2>
+				<TELL
+"Toranaga is disgusted by your cowardice.  He personally dispatches
+you.  As you die, you remember something about not keeping agreements." CR>
+				<JIGS-UP>
+				<RFATAL>)
+			       (<EQUAL? ,DELAY-CNT 1>
+				<TELL CR
+"The Grays have spotted Mariko.  They surge forward." CR>)
+			       (<EQUAL? ,DELAY-CNT 2>
+				<TELL CR
+"Toranaga urges you forward." CR>)>
+			 <RTRUE>)>)
+		 (<TELL CR
+"The Grays surround you, Mariko jabbering feverishly with the samurai and
+the Grays.  You add to the babel in a panting mixture of Portuguese, English,
+and Dutch, motioning for them to hurry.  You lean against the gangway, unable
+to see anything on the galley distinctly.  You can't tell if the samurai on
+deck are Grays or Browns or both." CR>)
+		 (<COND (<HERE? ,WHARF ,MAIN-DECK ,GALLEY>
+			 <TELL CR
+"Mariko is frantically haranguing the senior officer of the Grays.  He shouts
+orders, and suddenly a hundred samurai, all Grays, pour off the ship.|
+|
+Quickly, Mariko turns to you and asks, \"Does the ship seem all right to
+you?\"">
+			 <SETG QCONTEXT ,MARIKO>
+			 <COND (<HERE? ,WHARF>
+				<TELL " She motions you onto the galley.">)>
+			 <CRLF>)
+			(ELSE
+			 <TELL CR
+"Mariko is desperately calling you back to the wharf." CR>)>)
+		 (DELAY
+		  <COND (<AND <NOT <IN? ,BLACKTHORNE ,MAIN-DECK>>
+			      <NOT <IN? ,BLACKTHORNE ,GALLEY>>>
+			 <TELL CR
+"Mariko commands you urgently in Latin, \"Get aboard the galley,
+Anjin-san!  We must see if it is safe!\"" CR>
+			 <RTRUE>)
+			(<EQUAL? ,QCONTEXT ,MARIKO>
+			 <TELL CR
+"\"Please, Anjin-san, is the ship all right?\"" CR>
+			 <RTRUE>)>)
+		 (<FSET ,WHARF ,SCOREBIT>
+		  <TELL CR
+"Mariko looks around, as if assessing the situation.  You can see that there
+are still sixteen Grays on the wharf and the galley.  Suddenly, Mariko walks
+weakly to the head of the gangway and appears to faint!" CR>)
+		 (DELAY
+		  <COND (<OR <FSET? ,WHARF ,SCOREBIT>
+			     <FSET? ,GLOBAL-WATER ,SCOREBIT>>
+			 <COND (<L? ,DELAY-CNT 2> <RFALSE>)>)>)
+		 (<MOVE ,RONIN ,WHARF>
+		  <TELL CR
+"Ashore, thirty of Toranaga's ronin-disguised samurai lope out of an
+alleyway.  The Grays that had begun to leave the dock spin around on the
+gangway.  Abruptly one shouts orders.  \"Bandits!\" one of the Browns
+screams on
+cue.  The six Browns split up, intermingling with the Grays." CR>)
+		 (<TELL CR
+"Toranaga's ronin-samurai charge.  At the same time the Browns on board attack
+the remaining Grays on board.  The leader of the Grays on deck, a large tough
+grizzle-bearded man, confronts ">
+		  <FCLEAR ,GRAY-LEADER ,NDESCBIT>
+		  <THIS-IS-IT ,GRAY-LEADER>
+		  <SETG OPPONENT ,GRAY-LEADER>
+		  <SETG DODGED? <>>
+		  <COND (<NOT <FSET? ,WHARF ,SCOREBIT>> ;"helped her?"
+			 <TELL "you and ">)>
+		  <TELL "Mariko.  \"Kill the traitors!\" he bellows, and
+charges." CR>)
+		 (<COND (<NOT <FSET? ,GRAY-LEADER ,DEAD>>
+			 <TELL CR CTHE ,GRAY-LEADER " ">
+			 <COND (,DODGED?
+				<TELL
+"manages to match your maneuver, and ">)>
+			 <TELL
+"swings his sword in a vicious arc that cuts deeply into your
+side.  You fall, and the second blow is fatal." CR>
+			 <JIGS-UP>)
+			(ELSE
+			 <SETG DODGED? <>>
+			 <SETG OPPONENT ,RANDOM-GRAYS>
+			 <TELL CR
+"The other two Grays lunge for you, killing swords high.  You feel, more than
+see, the sword slashing for your throat!" CR>)>)
+		 (<COND (<NOT ,DODGED?>
+			 <TELL CR
+"The killing blow takes you, nearly severing your head." CR>
+			 <JIGS-UP>)
+			(ELSE
+			 <FCLEAR ,WHARF ,SCOREBIT>
+			 <MOVE ,SECOND-GRAY ,HERE>
+			 <SETG OPPONENT ,SECOND-GRAY>
+			 <THIS-IS-IT ,SECOND-GRAY>
+			 <TELL CR
+"A younger Gray halts over Mariko, sword raised.  Suddenly,
+Mariko comes alive.  She throws herself against the inexperienced young samurai's
+legs, crashing him to the deck.  Then, she scrambles across the dead Gray,
+grabs his sword out of his still-twitching hands, and prepares to defend
+herself as best she can." CR>)>)
+		 (<TELL CR
+"The young Gray that Mariko tripped regains his feet, and howling with rage,
+comes at
+her.  She backs and slashes bravely but you know she's lost, the man too
+strong." CR>)
+		 (<COND (<NOT <FSET? ,SECOND-GRAY ,DEAD>>
+			 <TELL CR
+"The young Gray's blow catches Mariko in the neck, and she drops to the
+deck, her
+wound bubbling.  You rush to her aid, but he cuts you down as well." CR>
+			 <JIGS-UP>)
+			(ELSE
+			 <MOVE ,RONIN ,HERE>
+			 <REMOVE ,GRAYS>
+			 <B-SIT>
+			 <TELL CR
+"Toranaga's ronin-samurai burst up the gangway, over the dead Grays.  They
+quickly dispose of the remaining Grays and dump their bodies into the sea.|
+|
+Wiping the blood off your face, you dimly see Mariko stretched out on the
+deck, ronin-samurai milling around her.  You shake off your helpers and
+stumble toward her, but your knees give out and you collapse." CR>)>)
+		 (<TELL CR
+"When all aboard has been checked and double-checked, the leader of the
+ronin-samurai cups his hands around his lips and halloos shoreward.  At once
+more ronin-disguised samurai under Yabu come out of the night, and fan into
+protective shields.  Then Toranaga appears and walks slowly toward the
+gangway alone.  He has discarded the woman's kimono and the dark travelling
+cloak.  Now he wears his armor, and over it a simple brown kimono, swords in
+his sash.  The phalanx moves with measured tread toward the galley.|
+|
+Bastard, you think.  You're a cruel, cold-gutted, heartless bastard but you've
+got majesty, no doubt about that." CR>
+		  <DEQUEUE I-RUSE>
+		  <NEXT-SCENE>)>>
+
+<ROOM WHARF
+      (LOC ROOMS)
+      (DESC "Wharf")
+      (SYNONYM WHARF)
+      (WEST TO WAREHOUSE)
+      (UP TO MAIN-DECK)
+      (EAST TO MAIN-DECK)
+      (GLOBAL LG-GALLEY GANGWAY)
+      (FLAGS ONBIT OUTSIDE ;SCOREBIT)
+      (ACTION WHARF-F)>
+
+<ROUTINE WHARF-F (RARG)
+	 <COND (<RARG? LOOK>
+		<TELL
+"You are near a gangway leading up to the galley.  The galley is to the
+east, moored to stanchions fixed into the stone wharf that extends
+a hundred yards out into the sea." CR>)
+	       (<RARG? ENTER>
+		<REMOVE ,ANCHOR>
+		<REMOVE ,SKIFF>)
+	       (<RARG? BEG>
+		<COND (<P? EXAMINE GRAYS>
+		       <TELL
+"You can only tell that they are dressed like samurai. You can't tell the
+color of their uniforms." CR>)
+		      (<AND <EQUAL? ,QCONTEXT ,MARIKO>
+			    <VERB? YES NO IYE HAI>>
+		       <TELL
+"\"Anjin-san, we must be sure.  We must look aboard for Grays.\"" CR>)
+		      (<P? (BOARD CLIMB-ON) (GALLEY LG-GALLEY ROOMS)>
+		       <DO-WALK ,P?EAST>)>)>>
+
+<OBJECT GRAY-LEADER
+	(DESC "Gray Leader")
+	(SYNONYM GRAY LEADER MAN SAMURAI)
+	(ADJECTIVE LARGE TOUGH GRIZZLED GRAY)
+	(FLAGS PERSON JAPANESEBIT THE SCOREBIT)
+	(ACTION GRAY-LEADER-F)>
+
+<ROUTINE GRAY-LEADER-F ("OPT" (RARG <>))
+	 <COND (<RARG? <>>
+		<COND (<FSET? ,GRAY-LEADER ,DEAD>
+		       <TELL
+G"Don't waste your effort; he's already dead." CR>)
+		      (<P? (KILL ATTACK) GRAY-LEADER (LARGE-KNIFE SMALL-KNIFE)>
+		       <TELL
+G"He's too far away to stab." CR>)
+		      (<P? THROW (LARGE-KNIFE SMALL-KNIFE)
+			   GRAY-LEADER>
+		       <MOVE ,PRSO ,HERE>
+		       <COND (<NOT <FSET? ,PRSO ,WEARBIT>>
+			      <TELL
+"You slide your " D ,PRSO " into your hand and hurl it in an arc.  It takes the
+samurai in the throat." CR>
+			      <SETG OPPONENT <>>
+			      <FSET ,GRAY-LEADER ,DEAD>
+			      <COND (<FSET? ,GRAY-LEADER ,NDESCBIT>
+				     <TELL CR
+"The remaining Grays scream \"Traitors!\"  They fall upon the Browns, and
+you are among the first to die." CR>
+				     <JIGS-UP>)
+				    (ELSE
+				     <SCORE-OBJECT ,GRAY-LEADER>)>)
+			     (ELSE
+			      <HANGS-UP-ON-SLEEVE>)>)>)>>
+
+<OBJECT RANDOM-GRAYS
+	(DESC "attacking Grays")
+	(SYNONYM GRAY GRAYS SAMURAI)
+	(ADJECTIVE ATTACKING GRAY)
+	(FLAGS PERSON JAPANESEBIT NOABIT NOTHEBIT SCOREBIT)
+	(ACTION RANDOM-GRAYS-F)>
+
+<ROUTINE RANDOM-GRAYS-F ("OPT" (RARG <>))
+	 <COND (<RARG? <>>
+		<COND (<P? (KILL ATTACK)
+			   RANDOM-GRAYS
+			   (LARGE-KNIFE SMALL-KNIFE)>
+		       <TELL
+G"They're too far away to stab." CR>)
+		      (<P? THROW (LARGE-KNIFE SMALL-KNIFE)
+			   RANDOM-GRAYS>
+		       <REMOVE ,PRSO>
+		       <COND (<NOT <FSET? ,PRSO ,WEARBIT>>
+			      <TELL
+"You throw your " D ,PRSO " at one of the Grays, and he spins away, but
+the other is still alive." CR>
+			      <SETG OPPONENT <>>
+			      <FSET ,RANDOM-GRAYS ,DEAD>)
+			     (ELSE
+			      <HANGS-UP-ON-SLEEVE>)>)>)>>
+
+<OBJECT SECOND-GRAY
+	(DESC "young Gray samurai")
+	(SYNONYM GRAY SAMURAI)
+	(ADJECTIVE SECOND YOUNG YOUNGER GRAY)
+	(FLAGS PERSON JAPANESEBIT NOABIT NOTHEBIT SCOREBIT)
+	(GENERIC GENERIC-GRAY-F)
+	(ACTION SECOND-GRAY-F)>
+
+<ROUTINE GENERIC-GRAY-F (R F)
+	 <COND (<FSET? ,SECOND-GRAY ,DEAD> ,RANDOM-GRAYS)
+	       (<FSET? ,GRAY-LEADER ,DEAD> ,SECOND-GRAY)
+	       (ELSE <RFALSE>)>>
+
+<ROUTINE SECOND-GRAY-F ("OPT" (RARG <>))
+	 <COND (<RARG? <>>
+		<COND (<P? (KILL ATTACK) SECOND-GRAY (LARGE-KNIFE SMALL-KNIFE)>
+		       <TELL
+G"He's too far away to stab." CR>)
+		      (<P? THROW (LARGE-KNIFE SMALL-KNIFE)
+			   SECOND-GRAY>
+		       <REMOVE ,PRSO>
+		       <COND (<NOT <FSET? ,PRSO ,WEARBIT>>
+			      <TELL
+"You throw your " D ,PRSO " at Mariko's assailant.  It strikes him in the back,
+causing his blow to go wild.  He slumps to the deck, his life ebbing fast." CR>
+			      <SETG OPPONENT <>>
+			      <FSET ,SECOND-GRAY ,DEAD>
+			      <SCORE-OBJECT ,SECOND-GRAY>)
+			     (ELSE
+			      <HANGS-UP-ON-SLEEVE>)>)>)>>
+
+<ROUTINE HANGS-UP-ON-SLEEVE ()
+	 <TELL
+"You fumble in your sleeve for the " D ,PRSO ", but it hangs up on the strip
+of silk you tied it with.  ">
+	 <COND (<FSET? ,PRSI ,DEAD>
+		<TELL "Fortunately, he's already dead, so you are safe from
+a counterattack." CR>)
+	       (ELSE
+		<TELL
+"You toss it at " THE ,PRSI " but it misses, and he turns on you!" CR>
+		<JIGS-UP>)>>
+
+;<ROOM WHARF-N
+      (LOC ROOMS)
+      (DESC "North Wharf")
+      (SYNONYM WHARF)
+      (ADJECTIVE NORTH)
+      (SOUTH TO WHARF)
+      (FLAGS ONBIT OUTSIDE)>
+
+;<ROOM WHARF-S
+      (LOC ROOMS)
+      (DESC "South Wharf")
+      (SYNONYM WHARF)
+      (ADJECTIVE SOUTH)
+      (NORTH TO WHARF)
+      (FLAGS ONBIT OUTSIDE)>
+
+<ROUTINE HATAMOTO-AFTER-F ()
+	 <TELL
+"The galley escapes from Osaka harbor, the rowers speeding it back towards
+Anjiro and Toranaga's capital, Yedo, beyond.|
+|
+For your services to him, Lord Toranaga gives you a rare honor.  He
+makes you a hatamoto, a high rank of samurai.  This is a position of a special retainer to his
+personal staff.  You have his absolute protection.  In return, you are
+instructed to learn Japanese, and train a regiment of troops in European
+tactics and the use of muskets.|
+|
+But best of all, he says he will return the "I"Erasmus"" to you, but he won't
+say when.">>
+
+<END-SEGMENT>
diff --git a/pic.zil b/pic.zil
new file mode 100644
index 0000000..ce1bc0f
--- /dev/null
+++ b/pic.zil
@@ -0,0 +1,205 @@
+"PIC for
+				Library
+	(c) Copyright 1988 Infocom, Inc. All Rights Reserved."
+
+<BEGIN-SEGMENT 0>
+
+<CONSTANT P-TITLE 1>	;"standard number for title pic"
+
+<CONSTANT YX-TBL <TABLE 0 0>>
+
+<ROUTINE YCEILING (Y)
+	 <SET Y <+ .Y ,FONT-Y -1>>
+	 <- .Y <MOD .Y ,FONT-Y>>>
+
+<ROUTINE XCEILING (X)
+	 <SET X <+ .X ,FONT-X -1>>
+	 <- .X <MOD .X ,FONT-X>>>
+
+<END-SEGMENT>
+
+<BEGIN-SEGMENT STARTUP>
+
+<ROUTINE TITLE-SCREEN ()
+	 <CLEAR ,S-FULL>
+	 <COND (<PICINF ,P-TITLE ,YX-TBL>
+		<CURSOR-OFF>
+		<SCREEN ,S-FULL>
+		<DISPLAY ,P-TITLE 1 1>
+		<CURSET <WINGET ,S-TEXT ,WHIGH> 1>
+		<INPUT 1>
+		<CLEAR ,S-FULL>
+		<CURSOR-ON>)>
+	 <DISPLAY-BORDER ,P-BORDER>
+	 <V-VERSION T>>
+
+<END-SEGMENT>
+
+<BEGIN-SEGMENT 0>
+
+<GLOBAL CURRENT-BORDER 0>
+
+<ROUTINE DISPLAY-BORDER ("OPT" (B ,CURRENT-BORDER))
+	 <COND (<APPLE?> <RFALSE>)
+	       (<PICINF .B ,YX-TBL>
+		<SCREEN ,S-FULL>
+		<DISPLAY .B 1 1>
+		<SETG CURRENT-BORDER .B>
+		<SCREEN ,S-TEXT>)>>
+
+<ROUTINE CENTER-PIC-X (P "AUX" X Y)
+	 <COND (<PICINF .P ,YX-TBL>
+		<FLUSH-OLD-PICTURE>
+		<MAKE-ROOM-FOR <SET Y <GET ,YX-TBL 0>>>
+		<SET X <- <WINGET -3 ,WWIDE> <GET ,YX-TBL 1>>>
+		<COND (<G? .X 1> <SET X </ .X 2>>)
+		      (ELSE <SET X 1>)>
+		<DISPLAY .P 0 .X>
+		<N-CRLF </ <+ .Y ,FONT-Y -1> ,FONT-Y>>
+		<RTRUE>)>>
+
+"display a picture centered in the current window"
+
+<ROUTINE CENTER-PIC (P "AUX" X Y)
+	 <COND (<PICINF .P ,YX-TBL>
+		<SET Y <- <WINGET -3 ,WHIGH> <GET ,YX-TBL 0>>>
+		<SET X <- <WINGET -3 ,WWIDE> <GET ,YX-TBL 1>>>
+		<COND (<G? .Y 1> <SET Y </ .Y 2>>)
+		      (ELSE <SET Y 1>)>
+		<COND (<G? .X 1> <SET X </ .X 2>>)
+		      (ELSE <SET X 1>)>
+		<DISPLAY .P .Y .X>)>>
+
+<CONSTANT TEXT-MARGIN 2>	;"left and right text margins in pixels"
+
+<ROUTINE FLUSH-OLD-PICTURE ("AUX" Y)
+	 <COND (<SET Y <WINGET ,S-TEXT ,WCRCNT>>
+		<N-CRLF .Y>
+		<RESET-MARGIN>)>>
+
+<ROUTINE N-CRLF (Y)
+	 <REPEAT ((CNT 0))
+		 <COND (<IGRTR? CNT .Y> <RETURN>)>
+		 <CRLF>>>
+
+<ROUTINE MARGINAL-PIC (P "OPT" (RIGHT? T) (C <>) (CTOP? <>)
+		       "AUX" TMP X Y YLEFT HIGH WIDE (CENTER? <>))
+	 <COND (<PICINF .P ,YX-TBL>
+		<SET HIGH <WINGET ,S-TEXT ,WHIGH>>
+		<SET WIDE <WINGET ,S-TEXT ,WWIDE>>
+		<FLUSH-OLD-PICTURE>
+		<SET Y <YCEILING <GET ,YX-TBL 0>>> ;"pic height rounded up"
+		<SET X <GET ,YX-TBL 1>> ;"pic width"
+		<COND (<AND .C <PICINF .C ,YX-TBL>>
+		       <SETG NEXT-PIC-CRCNT <GET ,YX-TBL 0>>
+		       <SETG NEXT-PIC-WIDTH <GET ,YX-TBL 1>>)
+		      (ELSE
+		       <SET C 0>
+		       <SETG NEXT-PIC-CRCNT 0>
+		       <SETG NEXT-PIC-WIDTH 0>)>
+		<SET YLEFT <MAKE-ROOM-FOR .Y>>
+		<COND (<G=? <+ .X <* ,FONT-X 10>> .WIDE>
+		       <SET CENTER? T>)>
+		<DISPLAY .P
+			 0
+			 <COND (.CENTER?
+				<+ 1 </ <- .WIDE .X> 2>>)
+			       (<AND .RIGHT?
+				     <L? .X .WIDE>>
+				<+ 1 <- .WIDE .X>>)
+			       (ELSE 1)>>
+		<COND (.CENTER?
+		       <CURSET .YLEFT 1>
+		       <CURSOR-OFF>
+		       <INPUT 1>
+		       <CURSOR-ON>
+		       <SET Y <- <YCEILING .HIGH> ,FONT-Y>>
+		       <COND (<L? <- .HIGH .Y> ,FONT-Y>
+			      <SET Y <- .Y ,FONT-Y>>)>
+		       <SET Y <+ .Y 1>>
+		       <COND (<G? .YLEFT .Y>
+			      <SCROLL ,S-TEXT <- .YLEFT .Y>>
+			      <CURSET .Y 1>)>
+		       <CRLF>)
+		      (ELSE
+		       <SET-MARGIN <COND (<AND .C .CTOP?> ,NEXT-PIC-WIDTH)
+					 (ELSE .X)>
+				   .RIGHT?>
+		       <SET Y </ .Y ,FONT-Y>>
+		       <COND (.C ;"does this picture have a corner?"
+			      <COND (.CTOP? <SETG NEXT-PIC-WIDTH .X>)>
+			      <SETG PIC-SIDE .RIGHT?>
+			      <SET TMP
+				   <- </ <YCEILING ,NEXT-PIC-CRCNT>
+					 ,FONT-Y>
+				      1>>
+			      <COND (.CTOP?
+				     <SETG NEXT-PIC-CRCNT <- .Y .TMP 1>>
+				     <WINPUT 0 ,WCRCNT <+ .TMP 1>>)
+				    (ELSE
+				     <SETG NEXT-PIC-CRCNT <+ .TMP 1>>
+				     <WINPUT 0 ,WCRCNT <- .Y .TMP 1>>)>
+			      <WINPUT 0 ,WCRFUNC ,NEXT-MARGIN>)
+			     (ELSE
+			      <WINPUT 0 ,WCRFUNC ,RESET-MARGIN>
+			      <COND (<EQUAL? .P ,P-OAR>
+				     <SET Y <+ .Y 1>>)>
+			      <WINPUT 0 ,WCRCNT .Y>)>)>)>>
+
+<ROUTINE SET-MARGIN (X RIGHT? "AUX" WIDE)
+	 <SET WIDE <WINGET ,S-TEXT ,WWIDE>>
+	 <SET X </ <XCEILING <+ .X 2>> ,FONT-X>>
+	 <COND (.RIGHT?
+		<MARGIN ,TEXT-MARGIN <* .X ,FONT-X>>)
+	       (ELSE
+		<MARGIN <* .X ,FONT-X> ,TEXT-MARGIN>)>
+	 <SET WIDE <- </ .WIDE ,FONT-X> .X>>
+	 <PUTB ,P-INBUF 0
+	       <COND (<G? .WIDE ,INBUF-LENGTH>
+		      ,INBUF-LENGTH)
+		     (T
+		      .WIDE)>>>
+
+<GLOBAL PIC-SIDE <>>
+<GLOBAL NEXT-PIC-WIDTH 0>
+<GLOBAL NEXT-PIC-CRCNT 0>
+
+<ROUTINE NEXT-MARGIN ()
+	 <COND (,NEXT-PIC-CRCNT
+		<SET-MARGIN ,NEXT-PIC-WIDTH ,PIC-SIDE>
+		<WINPUT ,S-TEXT ,WCRCNT ,NEXT-PIC-CRCNT>
+		<WINPUT ,S-TEXT ,WCRFUNC ,RESET-MARGIN>
+		<SETG NEXT-PIC-CRCNT 0>)>
+	 <RTRUE>>
+
+<ROUTINE RESET-MARGIN ()
+	 <WINPUT ,S-TEXT ,WCRCNT 0>
+	 <WINPUT ,S-TEXT ,WCRFUNC 0>
+	 <MARGIN ,TEXT-MARGIN ,TEXT-MARGIN>
+	 <PUTB ,P-INBUF 0 ,INBUF-LENGTH>>
+
+"make sure room for Y pixels, by scrolling and moreing if necessary"
+
+<ROUTINE MAKE-ROOM-FOR (Y "AUX" YLEFT LLEFT (HIGH <WINGET ,S-TEXT ,WHIGH>)
+			(YLOC <WINGET ,S-TEXT ,WYPOS>)
+			(XLOC <WINGET ,S-TEXT ,WXPOS>))
+	 <COND (<G? .Y .HIGH> <SET Y .HIGH>)>
+	 <SET YLEFT <+ 1 <- .HIGH .YLOC>>> ;"pixels left to eos"
+	 <COND (<G? .Y .YLEFT> ;"picture won't fit in rest of screen?"
+		<SET YLEFT <YCEILING <- .Y .YLEFT>>> ;"won't fit by this much"
+		<SET LLEFT ;"what yloc was when lncnt last was 1"
+		     <- .YLOC
+			<* <- <WINGET ,S-TEXT ,WLCNT> 1>
+			   ,FONT-Y>>>
+		<COND (<G? .YLEFT .LLEFT> ;"would lose info?"
+		       <WINPUT ,S-TEXT ,WLCNT </ .HIGH ,FONT-Y>>
+		       <CRLF>
+		       <CURSET <- <WINGET ,S-TEXT ,WYPOS> ,FONT-Y> 1>)>
+		<SCROLL ,S-TEXT .YLEFT>
+		<SET YLOC <- .YLOC .YLEFT>>
+		<COND (<L=? .YLOC 0> <SET YLOC 1>)>
+		<CURSET .YLOC .XLOC>)>
+	 <SET YLEFT <+ .Y <WINGET ,S-TEXT ,WYPOS>>>
+	 <RETURN .YLEFT>>
+
+<END-SEGMENT>
diff --git a/picdef.zil b/picdef.zil
new file mode 100644
index 0000000..f556f64
--- /dev/null
+++ b/picdef.zil
@@ -0,0 +1,51 @@
+
+<CONSTANT P-TITLE 1>
+<CONSTANT P-BORDER-LOC 2>
+<CONSTANT P-BORDER 3>
+<CONSTANT P-BORDER2 4>
+<CONSTANT P-TIME 5>
+<CONSTANT P-BORDER-3 6>
+<CONSTANT P-STORM 7>
+<CONSTANT P-BELOW-DECKS 8>
+<CONSTANT P-GARDEN 9>
+<CONSTANT P-ANJIRO 10>
+<CONSTANT P-OMI 11>
+<CONSTANT P-YABU 12>
+<CONSTANT P-PIT 13>
+<CONSTANT P-RODRIGUES 14>
+<CONSTANT P-CONFUSION 15>
+<CONSTANT P-OVERBOARD 16>
+<CONSTANT P-OAR 17>
+<CONSTANT P-CLIFF 18>
+<CONSTANT P-OSAKA 19>
+<CONSTANT P-FALCON 20>
+<CONSTANT P-ALVITO 21>
+<CONSTANT P-ISHIDO 22>
+<CONSTANT P-PROCESSION 23>
+<CONSTANT P-MAD-SCENE 24>
+<CONSTANT P-IN-DRAG 25>
+<CONSTANT P-QUAKE 26>
+<CONSTANT P-SWORDS 27>
+<CONSTANT P-SEPPUKU 28>
+<CONSTANT P-NINJA 29>
+<CONSTANT P-EXPLOSION 30>
+<CONSTANT P-CREST 31>
+<CONSTANT P-MARIKO 32>
+<CONSTANT P-BATH 33>
+<CONSTANT P-BEACH 34>
+<CONSTANT P-BURNED-ERASMUS 35>
+<CONSTANT P-VINCK 36>
+<CONSTANT P-WARRIOR 37>
+<CONSTANT P-MAZE-WALL 38>
+<CONSTANT P-MAZE-STREET 39>
+<CONSTANT P-MAZE-PARTY 40>
+<CONSTANT P-MAZE-CASTLE 41>
+<CONSTANT P-MAZE-DOCK 42>
+<CONSTANT P-MAZE-FISH 43>
+<CONSTANT P-MAZE-BACKGROUND 44>
+<CONSTANT P-MAZE-BOX 45>
+<CONSTANT P-IN-DRAG-CORNER 46>
+<CONSTANT P-EXPLOSION-CORNER 47>
+<CONSTANT P-WARRIOR-CORNER 48>
+<CONSTANT P-HINT-LOC 49>
+<CONSTANT P-HINT-BORDER 50>
\ No newline at end of file
diff --git a/quake.zil b/quake.zil
new file mode 100644
index 0000000..46bd75e
--- /dev/null
+++ b/quake.zil
@@ -0,0 +1,1740 @@
+"QUAKE for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc.  All Rights Reserved."
+
+<FILE-FLAGS SENTENCE-ENDS?>
+
+<BEGIN-SEGMENT QUAKE>
+
+<ROOM PLATEAU
+      (LOC ROOMS)
+      (SCENE S-QUAKE)
+      (DESC "Plateau")
+      (SYNONYM PLATEAU)
+      (SCORE 4)
+      (AFTER ZATAKI-AFTER-F)
+      (FDESC
+"You sit cross-legged in front of Toranaga, swords in his
+sash.  Mariko is explaining something to you.  \"War
+is coming,\" she says.  \"When?\" you ask.  \"Very soon, so you are to leave
+at once with me.  I'm going to Osaka, you are to accompany me part of
+the way, but you're going on to Yedo to prepare your ship for war.\"")
+      (FLAGS ONBIT OUTSIDE SCOREBIT)
+      (ACTION PLATEAU-F)>
+
+<ROUTINE PLATEAU-F (RARG)
+	 <COND (<RARG? SCENE-SETUP>
+		<DRESS-BLACKTHORNE>
+		<PUTP ,BLACKTHORNE ,P?HEALTH 5>
+		<MOVE ,SWORDS ,BLACKTHORNE>
+		<FSET ,SWORDS ,WEARBIT>
+		<FSET ,SWORDS ,SCOREBIT>
+		<B-SIT>
+		<MOVE ,MARIKO ,HERE>
+		<MOVE ,TORANAGA ,HERE>
+		<QUEUE I-QUAKE -1>)
+	       (<RARG? LOOK>
+		<COND (<IN? ,WINNER ,HERE>
+		       <TELL
+"This is a plateau on a hillside.  Beyond are the rising foothills of
+mountains that soar to a clouded sky.  Below in the valley is the
+samurai camp.  The day is sultry." CR>)
+		      (ELSE
+		       <TELL
+"You are in a fissure, below ground level in the shaking earth." CR>)>)
+	       (<RARG? BEG>
+		<COND (<NOT ,QUAKE-CNT> <RFALSE>)
+		      (<AND ,QUAKE?
+			    <OR <VERB? LIE-DOWN>
+				<P? (HOLD BOARD HOLD-ON HIT) GROUND>>>
+		       <TELL
+"You hold the ground like a baby holding its mother.  You want the
+noise and shaking to stop!" CR>)
+		      (<AND <P? YELL> ,QUAKE?>
+		       <TELL
+"Your lungs try to force a scream out, but nothing comes." CR>)
+		      (<AND <IN? ,MAIN-FISSURE ,HERE>
+			    <NOT <FSET? ,MAIN-FISSURE ,RMUNGBIT>>
+			    <NOT <VERB? CLIMB-DOWN BOARD>>
+			    <MOTION-VERB?>>
+		       <FSET ,MAIN-FISSURE ,RMUNGBIT>
+		       <TELL
+"Desperately you scramble away from the onrushing chasm, grabbing at the
+ground, forcing yourself to move, and it passes you by." CR>)
+		      (<AND <P? WALK P?DOWN>
+			    <IN? ,MARIKO ,SIDE-FISSURE>>
+		       <PERFORM ,V?THROUGH ,SIDE-FISSURE>
+		       <RTRUE>)
+		      (<AND <P? WALK P?DOWN>
+			    <IN? ,TORANAGA ,MAIN-FISSURE>>
+		       <PERFORM ,V?THROUGH ,MAIN-FISSURE>
+		       <RTRUE>)
+		      (<AND <OR ,QUAKE?
+				<QUEUED? I-CRAWL>>
+			    <OR <VERB? WALK>
+				<AND <VERB? STAND>
+				     <B-NOT-STANDING?>>>>
+		       <TELL
+"You can't stand up.  You can barely avoid panic." CR>)
+		      (<VERB? FOLLOW>
+		       <COND (<AND <PRSO? ,MARIKO>
+				   <IN? ,MARIKO ,SIDE-FISSURE>>
+			      <PERFORM ,V?THROUGH ,SIDE-FISSURE>)
+			     (<AND <PRSI? ,TORANAGA>
+				   <IN? ,TORANAGA ,MAIN-FISSURE>>
+			      <PERFORM ,V?THROUGH ,MAIN-FISSURE>
+			      <RTRUE>)>)
+		      (<AND <P? EXAMINE (TORANAGA MARIKO)>
+			    <NOT <IN? ,PRSO ,HERE>>>
+		       <PERFORM ,V?LOOK-INSIDE <LOC ,PRSO>>
+		       <RTRUE>)
+		      (<VERB? LOOK-DOWN>
+		       <COND (<AND <IN? ,SIDE-FISSURE ,HERE>
+				   <IN? ,MARIKO ,SIDE-FISSURE>>
+			      <PERFORM ,V?LOOK-INSIDE ,SIDE-FISSURE>
+			      <RTRUE>)
+			     (<AND <IN? ,MAIN-FISSURE ,HERE>
+				   <IN? ,TORANAGA ,MAIN-FISSURE>>
+			      <PERFORM ,V?LOOK-INSIDE ,MAIN-FISSURE>
+			      <RTRUE>)
+			     (,QUAKE?
+			      <TELL
+"The ground is trembling and rolling!" CR>)>)
+		      (<AND <P? LISTEN (<> GROUND)> ,QUAKE?>
+		       <TELL
+"Everything around you rumbles with a deep basso profundity that
+you can barely believe." CR>)
+		      (<VERB? FIND ;WHERE SAY YELL-AT>
+		       <COND (<AND <PRSO? TORANAGA>
+				   <IN? ,TORANAGA ,SIDE-FISSURE>>
+			      <COND (<FSET? ,TORANAGA ,DEAD>
+				     <TELL
+"He is dead." CR>)
+				    (ELSE
+				     <TELL
+"He has fallen into " THE ,SIDE-FISSURE "!" CR>)>)
+			     (<AND <PRSO? MARIKO>
+				   <IN? ,MARIKO ,SIDE-FISSURE>>
+			      <COND (<FSET? ,MARIKO ,DEAD>
+				     <TELL
+"She is dead." CR>)
+				    (ELSE
+				     <TELL
+"She has fallen into " THE ,SIDE-FISSURE "!" CR>)>)>)
+		      (<P? (TAKE HELP REACH-FOR) TORANAGA>
+		       <COND (<NOT <IN? ,MAIN-FISSURE ,HERE>>
+			      <TELL
+"You will yourself to crawl to Toranaga, but your body refuses,
+forcing you to hug the once-solid ground." CR>)
+			     (<IN? ,BLACKTHORNE ,SIDE-FISSURE>
+			      <DO-WALK ,P?UP>)
+			     (,TORANAGA-HELD-FLAG
+			      <TELL
+"You hold Toranaga in a death grip, unsure of how long you can hold
+him with the earth trembling like a leaf around you, but knowing it's
+his death if you let go." CR>)
+			     (<FSET? ,MAIN-FISSURE ,SCOREBIT>
+			      <COND (<IN? ,BLACKTHORNE ,MAIN-FISSURE>
+				     <JIGS-UP
+"You reach out for Toranaga as he begins to fall, and you grab his sash,
+but you've lost your precarious balance on the ledge.  Both of you tumble
+into the pit.">)
+				    (ELSE
+				     <MARGINAL-PIC ,P-QUAKE>
+				     <SETG TORANAGA-HELD-FLAG T>
+				     <TELL
+"You come out of your stupor and lunge forward.  Your left hand grabs
+Toranaga's sash." CR>)>)>)
+		      (<P? DROP TORANAGA>
+		       <COND (<AND ,TORANAGA-HELD-FLAG
+				   <FSET? ,MAIN-FISSURE ,SCOREBIT>>
+			      <SETG TORANAGA-HELD-FLAG <>>
+			      <MOVE ,TORANAGA ,MAIN-FISSURE>
+			      <TELL
+"You let go, and begins to lose his precarious balance." CR>)>)
+		      (<P? (TAKE HELP REACH-FOR) MARIKO>
+		       <COND (<AND ,TORANAGA-HELD-FLAG
+				   <FSET? ,MAIN-FISSURE ,SCOREBIT>>
+			      <MOVE ,TORANAGA ,MAIN-FISSURE>
+			      <SETG TORANAGA-HELD-FLAG <>>
+			      <TELL
+"You try to reach Mariko and hold on to Toranaga at the same time, but
+it's impossible.  Just as your fingers reach her, Toranaga's sash slips
+from your grasp and he tumbles into the abyss." CR>)
+			     (<IN? ,MARIKO ,SIDE-FISSURE>
+			      <TELL
+"She's too far away, too deep in the fissure." CR>)
+			     (ELSE
+			      <TELL
+"Crawling as fast as you can, you try to reach her,
+but there's no chance." CR>)>)
+		      (<P? GIVE SWORDS TORANAGA>
+		       <COND (<OR <NOT <IN? ,TORANAGA ,HERE>>
+				  <NOT <FSET? ,SIDE-FISSURE ,RMUNGBIT>>>
+			      <TELL
+"This is a strange time to be trying to give your swords away." CR>)
+			     (<FSET? ,MAIN-FISSURE ,SCOREBIT>
+			      <TELL
+"Toranaga refuses your gift.  \"I have perfectly good swords of my own,\"
+he says." CR>)
+			     (ELSE
+			      <SCORE-OBJECT ,SWORDS>
+			      <SETG DELAY-CNT 0>
+			      <MOVE ,SWORDS ,TORANAGA>
+			      <FSET ,SWORDS ,WEARBIT>
+			      <MARGINAL-PIC ,P-SWORDS <>>
+			      <TELL
+"You kneel in front of Toranaga and offer your sword as a sword should
+be offered.  \""I"Dozo"", Toranaga-sama,\" you say.  He accepts the sword
+and shoves it into his sash.  \""I"Domo"", Anjin-san.\"  He smiles, leans
+forward, and claps you once on the shoulder, hard.  \""I"Tomo, neh?""\"
+Friend, eh?" CR>)>)
+		      (<P? EXAMINE SWORDS>
+		       <COND (<NOT <FSET? ,MAIN-FISSURE ,SCOREBIT>>
+			      <TELL
+"The short stabbing sword is gone, but the killing sword is still
+scabbarded, though muddied and scarred." CR>)>)
+		      (<P? PISS (<> MAIN-FISSURE SIDE-FISSURE)>
+		       <COND (<AND <NOT <FSET? ,MAIN-FISSURE ,SCOREBIT>>
+				   <IN? ,TORANAGA ,HERE>>
+			      <TELL
+"Nothing comes, not even a dribble.">
+			      <COND (<AND <FSET? ,SIDE-FISSURE ,RMUNGBIT>
+					  <FSET? ,PLATEAU ,SCOREBIT>>
+				     <TELL
+" You and Toranaga laugh at the sheer
+joy of being alive, which blocks you even more.  At length you both
+succeed.  You relax and collect your strength." CR>
+				     <SETG DELAY-CNT 0>
+				     <SCORE-OBJECT ,PLATEAU>)
+				    (ELSE <CRLF>)>)>)>)>>
+
+<GLOBAL TORANAGA-HELD-FLAG <>>
+
+<GLOBAL QUAKE? <>>
+
+<ROUTINE I-QUAKE ()
+	 <ZLINES ,QUAKE-CNT
+		 (<SETG QUAKE? T>
+		  <TELL CR
+"Suddenly, the silence is colossal.  Then the earth begins to shake">
+		  <COND (<NOT <B-LYING?>>
+			 <B-LIE-DOWN>
+			 <TELL
+" and you are tumbled to the ground." CR>)
+			(ELSE
+			 <TELL "." CR>)>)
+		 (<SETG QUAKE? <>>
+		  <TELL CR
+"You feel your lungs about to burst, and every fiber of your being
+screams in panic.  Toranaga and Mariko hold onto the ground with their
+hands and feet.  The rumbling, catastrophic roar comes from earth and sky,
+surrounding you, building and building.|
+|
+An avalanche of rocks starts from the mountain to the north and howls down
+into the valley below.  Part of the samurai camp vanishes.|
+|
+Then the tremor stops." CR>)
+		 (<SETG QUAKE? T>
+		  <MOVE ,MAIN-FISSURE ,HERE>
+		  <TELL CR
+"Again the earth cries out.  The second quake begins">
+		  <COND (<NOT <B-LYING?>>
+			 <B-LIE-DOWN>
+			 <TELL
+", tossing you like a rag doll into the dust">)>
+		  <TELL ".  The earth rips open
+at the north end of the plateau.  A gaping fissure rushes toward you at an
+incredible speed." CR>)
+		 (DELAY
+		  <COND (<NOT <FSET? ,MAIN-FISSURE ,RMUNGBIT>>
+			 <COND (<OR <G? ,DELAY-CNT 1>
+				    <IN? ,WINNER ,MAIN-FISSURE>>
+				<CRLF>
+				<JIGS-UP
+"The fissure swallows you like a snake eating a bird.">)
+			       (ELSE
+				<TELL CR
+"You stare in horror as the fissure rumbles toward you!" CR>)>)>)
+		 (<THIS-IS-IT ,TORANAGA>
+		  <FSET ,MAIN-FISSURE ,SCOREBIT>
+		  <TELL CR
+"Toranaga and Mariko teeter on the brink of the cleft.  As though in a
+nightmare you see Toranaga, nearest the maw, begin to topple into it." CR>)
+		 (<CRLF>
+		  <COND (<NOT ,TORANAGA-HELD-FLAG>
+			 <MOVE ,TORANAGA ,MAIN-FISSURE>
+			 <FSET ,TORANAGA ,DEAD>
+			 <FSET ,TORANAGA ,NDESCBIT>
+			 <TELL
+"Toranaga plunges into the cleft and is lost from sight!" CR>)
+			(ELSE
+			 <SETG TORANAGA-HELD-FLAG <>>
+			 <TELL
+"Mud and rocks pour down, dragging you and Toranaga into the
+fissure.  You fight for a handhold and foothold, almost pulled down into the
+abyss.  Still partially stunned, Toranaga hacks his toes into the face of
+the wall and half-dragged, half-carried by you, claws his way out.  You
+both lay gasping on the ground." CR>
+			 <MOVE ,BLACKTHORNE ,HERE>
+			 <SCORE-OBJECT ,MAIN-FISSURE>)>
+		  <TELL CR
+"Suddenly, there is another shock." CR>)
+		 (<FSET ,MAIN-FISSURE ,RMUNGBIT>
+		  <REMOVE ,MAIN-FISSURE>
+		  <MOVE ,SIDE-FISSURE ,HERE>
+		  <MOVE ,MAIN-FISSURE ,HERE> ;"so it will list first"
+		  <MOVE ,MARIKO ,SIDE-FISSURE>
+		  <THIS-IS-IT ,MARIKO>
+		  <TELL CR
+"The earth splits again, opening a side fissure away from the main
+cleft.  Mariko screams as it swallows her." CR>)
+		 (<TELL CR
+"There is a new shock.">
+		  <COND (<IN? ,BLACKTHORNE ,SIDE-FISSURE>
+			 <TELL
+" The ledge you and Mariko are on mostly gives way, only a few tiny
+holds remaining as the rest falls downward.">)
+			(<IN? ,MARIKO ,SIDE-FISSURE>
+			 <TELL
+" Mariko screams for help from within the side fissure.">)>
+		  <CRLF>)
+		 (<TELL CR
+"The chasm howls and begins to close.">
+		  <COND (<AND <IN? ,BLACKTHORNE ,SIDE-FISSURE>
+			      <IN? ,MARIKO ,SIDE-FISSURE>>
+			 <TELL
+" You and Mariko fight for balance.">)
+			(<IN? ,BLACKTHORNE ,SIDE-FISSURE>
+			 <TELL
+" The far wall screeches sickeningly as it approaches.  Mud and
+stones tumble off it.">)
+			(<IN? ,MARIKO ,SIDE-FISSURE>
+			 <TELL
+" You can barely hear Mariko over the rumble of the earthquake.  \"Anjin-san!  Help me!\"">)>
+		  <CRLF>)
+		 (<SETG QUAKE? <>>
+		  <TELL CR
+"The gap is closing.">
+		  <COND (<IN? ,MARIKO ,SIDE-FISSURE>
+			 <FSET ,MARIKO ,DEAD>
+			 <FSET ,MARIKO ,NDESCBIT>
+			 <TELL
+" Mariko's ledge gives way, and she slides into the depths, clutching
+futilely at the mud walls, her last scream silenced.">)>
+		  <CRLF>)
+		 (<COND (<IN? ,BLACKTHORNE ,SIDE-FISSURE>
+			 <TELL CR
+"Part of the wall falls away, carrying you with it into the abyss." CR>
+			 <JIGS-UP>)
+			(ELSE
+			 <FSET ,SIDE-FISSURE ,RMUNGBIT>
+			 <TELL CR
+"The gap stops -- six paces across the mouth, eight deep.|
+|
+A bird screeches out of a tree and takes to the air screaming.  In the grass
+an ant moves." CR>)>)
+		 (<COND (<IN? ,TORANAGA ,HERE>
+			 <TELL CR
+"Toranaga points to the fissure that ">
+			 <COND (<IN? ,MARIKO ,HERE>
+				<TELL "almost swallowed him">)
+			       (ELSE
+				<TELL "swallowed Mariko">)>
+			 <TELL ", now only a
+narrow ditch.  He belches loudly, then hawks and spits.  A torrent of
+abuse pours over the ditch">
+			 <COND (<IN? ,MARIKO ,HERE>
+				<TELL
+", Mariko translating with increasing amusement: \"The pox on the karma, the pox on the
+quake, the pox on the ditch -- I've lost my ">
+				<COND (<IN? ,SWORDS ,TORANAGA>
+				       <TELL "best ">)>
+				<TELL "swords and the pox on that too!\"" CR>)
+			       (ELSE
+				<TELL "." CR CR
+"You are stunned.  Mariko would have said \"Karma,\" but you cannot
+understand such stoicism." CR>)>
+			 <RTRUE>)
+			(ELSE
+			 <TELL CR
+"You lie exhausted on the ground.  What will happen now, with Toranaga
+dead?  Ishido will win, for certain, and you will never survive.  Mariko ">
+			 <COND (<IN? ,MARIKO ,HERE>
+				<TELL "says">)
+			       (ELSE
+				<TELL "would have said">)>
+			 <TELL " \"Karma,\" but you cannot take it so
+philosophically." CR>
+			 <FAILED-SCENE>
+			 <RFATAL>)>)
+		 (DELAY
+		  <COND (<AND <FSET? ,SWORDS ,SCOREBIT>
+			      <L? ,DELAY-CNT 2>>
+			 <RFALSE>)>)
+		 (<COND (<FSET? ,PLATEAU ,SCOREBIT>
+			 <TELL CR
+"Toranaga rises, straddles the now narrow ditch, hitches up his kimono,
+and attempts to urinate into it.  Nothing comes, and he laughs, inviting
+you to join him." CR>)
+			(ELSE
+			 <TELL CR
+"Toranaga looks around, savoring life, stretching like a cat.  He is able to
+take a peasant's enjoyment in mere existence." CR>)>)
+		 (DELAY
+		  <COND (<AND <FSET? ,SWORDS ,SCOREBIT>
+			      <L? ,DELAY-CNT 2>>
+			 <RFALSE>)
+			(<AND <FSET? ,PLATEAU ,SCOREBIT>
+			      <L? ,DELAY-CNT 2>>
+			 <RFALSE>)>)
+		 (<DEQUEUE I-QUAKE>
+		  <COND (<IN? ,MARIKO ,HERE>
+			 <TELL CR
+G"You lay full length on the ground and look up at the sky.  A moment ago
+you were all ""almost dead, and all worry and heartache was wasted.  "I"Karma"
+", you understand karma now." CR>
+			 <REMOVE ,SWORDS>
+			 <NEXT-SCENE>)
+			(ELSE
+			 <TELL CR
+G"You lay full length on the ground and look up at the sky.  A moment ago
+you were all ""alive, and now Mariko is dead.  "I"Karma"", you understand
+karma now, but you can't accept it." CR>
+			 <FAILED-SCENE>)>)>>
+
+<OBJECT EARTHQUAKE
+	(DESC "earthquake")
+	(SYNONYM QUAKE EARTHQUAKE)
+	(ADJECTIVE EARTH)
+	(ACTION EARTHQUAKE-F)>
+
+<ROUTINE EARTHQUAKE-F ()
+	 <COND (<VERB? LISTEN>
+		<COND (,QUAKE?
+		       <TELL
+"There is a low rumbling noise all around you, coming from deep
+in the earth." CR>)
+		      (ELSE
+		       <TELL
+"Right now, all is quiet." CR>)>)>>
+
+<OBJECT MAIN-FISSURE
+	(DESC "main fissure")
+	(SYNONYM FISSURE CHASM CLEFT DITCH LEDGE)
+	(ADJECTIVE MAIN FIRST OLD MUDDY)
+	(FLAGS SEARCHBIT OPENBIT CONTBIT VEHBIT ;SCOREBIT)
+	(GENERIC GENERIC-FISSURE-F)
+	(DESCFCN FISSURE-DESC)
+	(ACTION MAIN-FISSURE-F)>
+
+<ROUTINE MAIN-FISSURE-F ("OPT" (RARG <>))
+	 <COND (<RARG? BEG>
+		<COND (<AND <FSET? ,TORANAGA ,DEAD>
+			    <OR <PRSO? ,TORANAGA>
+				<PRSI? ,TORANAGA>>>
+		       <TELL
+"Toranaga has fallen out of sight to the bottom of the abyss." CR>)
+		      (<P? TAKE MAIN-FISSURE>
+		       <TELL
+"You dig your fingers into the muddy walls of the cleft, your
+fingernails tearing from the effort." CR>) 
+		      (<P? LOOK-UP>
+		       <TELL
+"You can see the lip of the chasm and beyond, the blue sky." CR>)
+		      (<OR <VERB? DISEMBARK CLIMB-UP>
+			   <P? WALK (UP OUT)>
+			   <P? CLIMB-FOO WALL>>
+		       <MOVE ,WINNER ,HERE>
+		       <B-LIE-DOWN>
+		       <TELL
+"You pull yourself out of the fissure." CR>)>)
+	       (<RARG? <>>
+		<COND (<VERB? LISTEN>
+		       <PERFORM ,V?LISTEN ,EARTHQUAKE>
+		       <RTRUE>)
+		      (<VERB? EXAMINE LOOK-INSIDE>
+		       <TELL
+"The cleft is is twenty paces deep and ten across and stinks of death.">
+		       <COND (<IN? ,TORANAGA ,MAIN-FISSURE>
+			      <COND (<IN? ,WINNER ,MAIN-FISSURE>
+				     <TELL
+" You are only barely holding on beside Toranaga." CR>)
+				    (ELSE
+				     <TELL
+" Toranaga clings precariously to the wall a few feet below." CR>)>)
+			     (ELSE <CRLF>)>)
+		      (<VERB? ENTER BOARD CLIMB-DOWN>
+		       <COND (<NOT <FSET? ,MAIN-FISSURE ,RMUNGBIT>>
+			      <MOVE ,WINNER ,MAIN-FISSURE>
+			      <B-STAND>
+			      <TELL
+"You claw your way to the fissure and into it, fingers and toes fighting
+for a hold on the mud and rocks of the side wall." CR>)
+			     (ELSE
+			      <TELL
+G"There are no longer any footholds or ledges." CR>)>)>)>>
+
+<ROUTINE GENERIC-FISSURE-F (R F)
+	 <COND (<AND <FSET? ,MAIN-FISSURE ,SCOREBIT>
+		     <FSET? ,SIDE-FISSURE ,SCOREBIT>>
+		<RFALSE>)
+	       (<FSET? ,MAIN-FISSURE ,SCOREBIT>
+		,MAIN-FISSURE)
+	       (<FSET? ,SIDE-FISSURE ,SCOREBIT>
+		,SIDE-FISSURE)
+	       (<AND <NOT <FSET? ,MAIN-FISSURE ,RMUNGBIT>>
+		     <NOT <FSET? ,SIDE-FISSURE ,RMUNGBIT>>>
+		<RFALSE>)
+	       (<NOT <FSET? ,MAIN-FISSURE ,RMUNGBIT>>
+		,MAIN-FISSURE)
+	       (<NOT <FSET? ,SIDE-FISSURE ,RMUNGBIT>>
+		,SIDE-FISSURE)
+	       (ELSE
+		,MAIN-FISSURE)>>
+
+<OBJECT SIDE-FISSURE
+	(DESC "side fissure")
+	(SYNONYM FISSURE CHASM CLEFT DITCH GAP LEDGE)
+	(ADJECTIVE SIDE NEW SECOND MUDDY)
+	(FLAGS SEARCHBIT OPENBIT CONTBIT VEHBIT SCOREBIT)
+	(GENERIC GENERIC-FISSURE-F)
+	(DESCFCN FISSURE-DESC)
+	(ACTION SIDE-FISSURE-F)>
+
+<ROUTINE FISSURE-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (ELSE
+		<COND (<EQUAL? .OBJ ,SIDE-FISSURE>
+		       <TELL
+"A deep and narrow side fissure arcs off from the main fissure.">
+		       <COND (<AND <IN? ,MARIKO ,SIDE-FISSURE>
+				   <IN? ,BLACKTHORNE ,SIDE-FISSURE>>
+			      <TELL
+" You and Mariko are clinging">)
+			     (<IN? ,MARIKO ,SIDE-FISSURE>
+			      <TELL
+" Mariko clings">)
+			     (<IN? ,BLACKTHORNE ,SIDE-FISSURE>
+			      <TELL
+" You are clinging">)
+			     (ELSE <RFATAL>)>
+		       <TELL " desperately to the crumbling"G" wall, standing
+precariously on a narrow ledge.">
+		       <RFATAL>)
+		      (<EQUAL? .OBJ ,MAIN-FISSURE>
+		       <TELL
+"The main fissure snakes down from the hill, its muddy depths gaping.">
+		       <COND (<IN? ,BLACKTHORNE ,SIDE-FISSURE>
+			      <TELL
+" You are clinging desperately to the muddy"G" wall, standing
+precariously on a narrow ledge.">)>
+		       <RFATAL>)>)>>
+
+<ROUTINE SIDE-FISSURE-F ("OPT" (RARG <>))
+	 <COND (<RARG? BEG>
+		<COND (<AND <FSET? ,MARIKO ,DEAD>
+			    <OR <PRSO? ,MARIKO>
+				<PRSI? ,MARIKO>>>
+		       <TELL
+"Mariko has fallen into the depths." CR>)
+		      (<P? TAKE SIDE-FISSURE>
+		       <TELL
+"You try to grip the crumbling ledge with your feet, but it's
+giving way beneath you!" CR>)
+		      (<P? LOOK-UP>
+		       <TELL
+"You can see the crumbling mud of the chasm wall">
+		       <COND (<AND <IN? ,TORANAGA ,PLATEAU>
+				   <NOT <IN? ,MARIKO ,PLATEAU>>>
+			      <TELL ", and Toranaga reaching down towards
+you with his iron grip." CR>)
+			     (ELSE <TELL "." CR>)>)
+		      (<P? (TAKE REACH-FOR) MARIKO>
+		       <TELL
+"You pull her towards you as the ledge crumbles further." CR>)
+		      (<OR <P? (RAISE PUSH-UP PUSH-OUT PUSH HELP THROW-OFF)
+			       MARIKO
+			       (<> ROOMS SIDE-FISSURE)>
+			   <P? (PUSH-TO GIVE) MARIKO TORANAGA>>
+		       <TELL
+"Your terror lends you inhuman strength and somehow you manage to
+rip Mariko out of the tomb and shove her upward.">
+		       <COND (<IN? ,TORANAGA ,HERE>
+			      <MOVE ,MARIKO ,HERE>
+			      <TELL
+" Toranaga clutches her wrist and hauls her over the lip of the
+chasm." CR>
+			      <SCORE-OBJECT ,SIDE-FISSURE>)
+			     (ELSE
+			      <TELL
+" She tries to pull herself over the lip of the chasm but she can't
+get a grip on the mud and falls back." CR>)>)
+		      (<OR <VERB? DISEMBARK CLIMB-UP>
+			   <P? WALK (OUT UP)>
+			   <P? CLIMB-FOO WALL>>
+		       <MOVE ,WINNER ,HERE>
+		       <QUEUE I-CRAWL 2>
+		       <B-LIE-DOWN>
+		       <TELL
+"You tear yourself free of the mud and crumbling walls and grope half out
+of your grave.  You lie on
+the shuddering brink, your lungs gulping air, unable to crawl away." CR>)>)
+	       (<RARG? <>>
+		<COND (<VERB? LISTEN>
+		       <PERFORM ,V?LISTEN ,EARTHQUAKE>
+		       <RTRUE>)
+		      (<VERB? EXAMINE LOOK-INSIDE>
+		       <TELL
+"The fissure is ten paces wide and thirty paces deep.">
+		       <COND (<AND <IN? ,MARIKO ,SIDE-FISSURE>
+				   <NOT <FSET? ,MARIKO ,DEAD>>>
+			      <COND (<IN? ,WINNER ,SIDE-FISSURE>
+				     <TELL
+" You are standing beside Mariko on a small ledge.">)
+				    (ELSE
+				     <TELL
+" Mariko is shivering on a ledge a few feet below.">)>)>
+		       <CRLF>)
+		      (<VERB? REACH-IN>
+		       <PERFORM ,V?TAKE ,MARIKO>
+		       <RTRUE>)
+		      (<VERB? ENTER BOARD CLIMB-DOWN>
+		       <COND (<NOT <FSET? ,SIDE-FISSURE ,RMUNGBIT>>
+			      <MOVE ,WINNER ,SIDE-FISSURE>
+			      <B-STAND>
+			      <TELL
+"You let yourself slide down, mud and stones crumbling off of the wall
+and almost blinding you.">
+			      <COND (<IN? ,MARIKO ,SIDE-FISSURE>
+				     <TELL
+"  You reach the narrow ledge on which Mariko is standing." CR>)
+				    (ELSE
+				     <TELL
+"You reach a narrow crumbling ledge." CR>)>)
+			     (ELSE
+			      <TELL
+G"There are no longer any footholds or ledges." CR>)>)>)>>
+
+<ROUTINE I-CRAWL () <RFALSE>>
+
+<END-SEGMENT>
+
+"S-ZATAKI"
+
+<BEGIN-SEGMENT ZATAKI>
+
+<ROUTINE ZATAKI-AFTER-F ()
+	 <MARGINAL-PIC ,P-WARRIOR T ,P-WARRIOR-CORNER T>
+	 <TELL
+"At the Hour of the Goat the sentries on the bridge stand aside.  The
+cortege begins to cross.  First are the heralds carrying banners bedecked
+with the all-powerful cipher of the Regents, then the rich palanquin, and
+finally more guards." CR>
+	<TELL CR
+"Villagers bow.  All are on their knees, secretly agog at such richness and
+pomp." CR>
+	<TELL CR
+"Saigawa Zataki, Lord of Shinano and Toranaga's half brother, rides in
+the palanquin." CR>
+	<TELL CR
+"\"Welcome, brother.\"  Toranaga steps off the dais and bows.  He wears
+the simplest of kimonos and soldier's straw sandals.  And swords.  \"Please
+excuse me for receiving you so informally, but I came as quickly as I
+could.\"" CR>
+	<TELL CR
+"Zataki gets out of the palanquin and bows in return, beginning the
+interminable, meticulous formalities of the ceremonial that now rules
+both of them." CR>
+	<TELL CR
+"At length they are seated opposite each other on the dais, two swords
+lengths apart.  Mariko serves ceremonial cha.  Then Zataki says brusquely,
+\"I bring orders from the Council of Regents.\"" CR>
+	<TELL CR
+"A sudden hush falls on the square.  Everyone, even his own men, is aghast
+at Zataki's lack of manners, at the insolent way he said 'orders' and
+not 'message,' and at his failure to wait for Toranaga to ask, \"How can
+I be of service?\" as the ceremonial demanded." CR>
+	<TELL CR
+"Zataki rips two small scrolls out of his sleeve.  He breaks the seal on
+the first scroll and reads, in a loud, chilling voice: \"By order of
+the Council of Regents, in the name of the Emperor: We greet our vassal
+Yoshi Toranaga and invite him to make obeisance before us in Osaka
+forthwith, and invite him to inform our ambassador, the Regent Saigawa
+Zataki, if our invitation is accepted or refused -- forthwith.\"" CR>
+	<TELL CR
+"He places the scroll in front of him.  Toranaga signals to Buntaro,
+who bows low to Zataki, picks up the scroll, and brings it to Toranaga." CR>
+	<TELL CR
+"Toranaga studies the scroll interminably." CR>
+	<TELL CR
+"\"Give me your answer now.  You've no more time!  Forthwith, the message
+said.  Of course you refuse to obey, good, so it's done.  Here!\"  Zataki
+puts the second scroll on the tatamis.  \"Here's your formal impeachment
+and order to commit seppuku, which you'll treat with equal contempt!  The
+next time we meet will be on a battlefield!\"" CR>
+	<TELL CR
+"\"How can I prove I'm not trying to overthrow the heir?\"  Toranaga
+asks his brother." CR>
+	<TELL CR
+"\"Immediately abdicate all your titles and power to your son and heir,
+Lord Sudara, and commit seppuku today!  Then I and all my men will support
+him as Lord of the Kwanto!\"" CR>
+	<TELL CR
+"\"I'll consider what you've said.\"" CR>
+	<TELL CR
+"\"Is this another of your tricks?  Buntaro-san, give your master the
+second scroll!\"" CR>
+	<TELL CR
+"\"No!\"  Toranaga's voice reverberates around the square.  Then, with
+great ceremony, he adds loudly, \"I agree to go to Osaka and to submit
+to the will of the Council.\"  He bows formally." CR>
+	<TELL CR
+"\"You're going to submit?,\" Zataki begins, his face twisting with
+disbelief." CR>
+	<TELL CR
+"\"Listen!  I accept the invitation!  I will leave today!\"">>
+
+<OBJECT ZATAKI
+	(LOC GLOBAL-OBJECTS)
+	(DESC "Zataki")
+	(SYNONYM ZATAKI)
+	(ADJECTIVE SAIGAWA LORD)
+	(FLAGS PERSON JAPANESEBIT NOABIT NOTHEBIT OPENBIT CONTBIT SEARCHBIT)
+	(CONTFCN ZATAKI-F)
+	(ACTION ZATAKI-F)>
+
+<ROUTINE ZATAKI-F ("OPT" (RARG <>))
+	 <COND (<RARG? <>>
+		<COND ;(<VERB? EXAMINE>
+		       <TELL
+"Saigawa Zataki is taller than Toranaga, and younger by five years, with
+the same breadth of shoulders and prominent nose.  But his stomach is
+flat, the stubble of his beard black and heavy, his eyes mere slits in
+his face.  His kimono is rich, his armor glittering and ceremonial, and
+his swords well used." CR>)
+		      (<VERB? WHO>
+		       <TELL
+"Zataki is Lord of Shinano and half-brother of Toranaga.">
+		       <COND (<G=? ,SCENE ,S-QUAKE>
+			      <TELL
+" He is a member of the Council of Regents, replacing Lord Sugiyama,
+who was murdered by "I"ronin"" -- or assassinated by Ishido.">)>
+		       <CRLF>)>)>>
+
+<END-SEGMENT>
+
+"S-JOURNEY"
+
+<BEGIN-SEGMENT YOKOSE>
+
+<CONSTANT J-YOSHI 130>
+
+<ROOM YOKOSE-BATH-HOUSE
+      (LOC ROOMS)
+      (SCENE S-JOURNEY)
+      (SCORE 3)
+      (AFTER JOURNEY-AFTER-F)
+      (FDESC
+"Toranaga tells everyone he will head up the east road toward Atami
+and Odawara, thence over the mountains to Yedo.  Mariko is given
+permission to go to Osaka.  \"But first you'll go directly from here
+to Mishima, then continue on to Yedo with the Anjin-san.  You're
+responsible for him until you arrive.\"|
+|
+Buntaro turns to Mariko.  \"Sayonara -- until I see you at Osaka.  When
+we meet there or when you return from there, then we begin again.\"|
+|
+\"Sayonara, my Lord.\"  Mariko bows.  He swings into his saddle and
+is off toward the head of the column.|
+|
+\"Go with God,\" she says, and you watch her eyes following Buntaro.|
+|
+The journey to Mishima takes nine days, and every night, for part of
+the night, you are together.  Secretly.  Your escort, Captain Akira
+Yoshinaka, unwittingly makes it easier by placing you in adjoining rooms.|
+|
+Tonight the group arrives at Yokose Spa, road-weary and dirty from the
+journey.  Everyone is anxious for a bath and a night's sleep -- or
+other relaxation.")
+      (DESC "Bath House")
+      (LDESC
+"This is the bath house outside the inn at Yokose.  The first floor of
+the inn is to the west.")
+      (SYNONYM BATH HOUSE)
+      (ADJECTIVE BATH)
+      (WEST TO YOKOSE-FIRST-FLOOR)
+      (FLAGS ONBIT RMUNGBIT)
+      (ACTION YOKOSE-BATH-HOUSE-F)>
+
+<ROUTINE YOKOSE-BATH-HOUSE-F ("OPT" (RARG <>))
+	 <COND (<RARG? SCENE-SETUP>
+		<DRESS-BLACKTHORNE>
+		<MOVE ,MARIKO ,YOKOSE-BATH-HOUSE>
+		<MOVE ,ROBE ,MARIKO>
+		<FSET ,ROBE ,WEARBIT>
+		<MOVE ,CHIMMOKO ,YOKOSE-BATH-HOUSE>
+		<MOVE ,GYOKO ,YOKOSE-SPA-5>
+		<MOVE ,KIKU ,YOKOSE-SPA-5>
+		<MOVE ,YOSHINAKA ,YOKOSE-BATH-HOUSE>
+		<QUEUE I-YOKOSE-BATH -1>)
+	       (<RARG? BEG>
+		<COND (<AND <P? WALK P?WEST>
+			    <FSET? ,YOKOSE-BATHTUB ,SCOREBIT>>
+		       <TELL
+"\"Anjin-san, you must bathe before you go to your room!\" chides Mariko." CR>)
+		      (<P? EXAMINE MARIKO>
+		       <COND (<FSET? ,ROBE ,WEARBIT>
+			      <TELL
+"Mariko is standing near the tub, wearing a thick cotton bathing robe
+tied loosely about her waist." CR>)
+			     (ELSE
+			      <COND (<IN? ,MARIKO ,YOKOSE-BATHTUB>
+				     <COND (<IN? ,BLACKTHORNE ,YOKOSE-BATHTUB>
+					    <TELL
+"Mariko is next to you in the bathtub, washing unhurriedly.">)
+					   (ELSE
+					    <TELL
+"Mariko is in the bath tub, naked.">)>)
+				    (ELSE
+				     <TELL
+"She is naked, preparing to take her bath.">)>
+			      <TELL " The first time you saw her naked
+you were greatly affected.  Now her nakedness, of itself, does not touch
+you physically.  Living closely in Japanese style in a Japanese house
+where the walls are paper and the rooms multipurpose, you have seen her
+unclothed and partially clothed many times." CR>)>)
+		      (<P? THROW TOWEL MARIKO>
+		       <TELL
+"\"You are behaving like a child, Anjin-san!\"" CR>)
+		      (<AND <IN? ,PLAYER ,HERE>
+			    <TAKE-A-BATH?>>
+		       <PERFORM ,V?BOARD ,YOKOSE-BATHTUB>
+		       <RTRUE>)
+		      (<P? RINSE (ME BLACKTHORNE)>
+		       <COND (<FSET? ,BLACKTHORNE ,RMUNGBIT>
+			      <TELL "You already have!" CR>)
+			     (ELSE
+			      <PERFORM ,V?BOARD ,YOKOSE-BATHTUB>
+			      <RTRUE>)>)
+		      (<AND <P? BATHE MARIKO>
+			    <IN? ,MARIKO ,YOKOSE-BATHTUB>
+			    <NOT <IN? ,WINNER ,YOKOSE-BATHTUB>>>
+		       <YOULL-HAVE-TO "get in the tub">)
+		      (<AND <P? BATHE *> ,PRSO>
+		       <COND (<FSET? ,PRSO ,PERSON>
+			      <COND (<FSET? ,PRSO ,PLURAL>
+				     <TELL
+G"There wouldn't be room for so many!" CR>)
+				    (ELSE
+				     <TELL
+CTHE ,PRSO G" smiles at your invitation, but shakes " HIS/HER ,PRSO
+" head." CR>)>)
+			     (ELSE
+			      <TELL
+CTHE ,PRSO G" would probably be worse for the experience." CR>)>)>)
+	       (<RARG? END>
+		<COND (<AND <IN? ,TOWEL ,HERE>
+			    <NOT <FSET ,TOWEL ,TOUCHBIT>>
+			    <NOT <FIND-IN ,BLACKTHORNE ,WEARBIT>>>
+		       <MOVE ,TOWEL ,BLACKTHORNE>
+		       <TELL CR
+"Although your modesty is much reduced since you arrived in Japan, you
+grab a nearby towel anyway." CR>)>)>>
+
+<ROUTINE JOURNEY-AFTER-F ()
+	 <TELL
+"You continue on to Yedo, Toranaga's capital.  Toranaga has delayed his
+departure for Osaka for weeks, complaining of the weather one day, and
+the need for careful preparation another.  He tells Hiro-matsu, \"I never
+intended to go to Osaka.  Ishido took the bait.  With no real concession
+whatsoever I've gained a month, put Ishido and his filthy allies in
+turmoil!\"|
+|
+After several days of waiting, Mariko receives from Toranaga the travel
+documents she needs to go to Osaka, and you are given money to hire
+additional crew for the "I"Erasmus"" in Nagasaki.  The survivors of the
+"I"Erasmus"" have found a place for themselves among the "I"eta"" of Yedo
+and except for Vinck, are useless as crew and unwilling to accommodate to
+Japanese ways.|
+|
+You, Vinck, Mariko, and Yabu board a galley for Osaka.  When you arrive,
+you find the elaborate preparations for Toranaga's visit underway.|
+|
+\"Of course, the Council will have no objections if I check the
+arrangements?\" Yabu asks Prince Ogaki, an intermediary between the
+Council and the Emperor.  \"The ceremony must be worthy of the Council
+and occasion!\"|
+|
+\"Worthy of His Imperial Majesty!\" responds Ogaki.  \"It's his summons,
+now.  Here is your invitation to the ceremony.\"|
+|
+Yabu quails as he sees the Imperial seal.  No one, not even Toranaga, could
+refuse such a summons.  Nineteen days!  That's all the time that's
+left!  Feeling weak, Yabu hears Ogaki say, \"Tomorrow you are invited to a
+formal reception by Lord Ishido to honor the birthday of the Lady Ochiba.\"" CR>>
+
+<OBJECT ROBE
+	(LOC YOKOSE-BATH-HOUSE)
+	(OWNER MARIKO)
+	(DESC "robe")
+	(SYNONYM ROBE)
+	(ADJECTIVE THICK COTTON BATHING BATH)
+	(FLAGS TAKEBIT WEARABLE WEARBIT)
+	(ACTION ROBE-F)>
+
+<ROUTINE ROBE-F ()
+	 <COND (<VERB? WEAR>
+		<TELL "It's like a child's robe to you.  It wouldn't fit." CR>)
+	       (<AND <VERB? TAKE-OFF>
+		     <IN? ,ROBE ,MARIKO>
+		     <FSET? ,ROBE ,WEARBIT>>
+		<MOVE ,ROBE ,HERE>
+		<FCLEAR ,ROBE ,WEARBIT>
+		<TELL
+"You offer to take her robe, and she thanks you, unself-consciously letting
+you remove it.  You put it aside, neatly folded." CR>)>>
+
+<OBJECT TOWEL
+	(LOC YOKOSE-BATH-HOUSE)
+	(DESC "towel")
+	(SYNONYM TOWEL)
+	(ADJECTIVE SMALL BATH)
+	(FLAGS TAKEBIT TOOLBIT WEARABLE)
+	(ACTION TOWEL-F)>
+
+<ROUTINE TOWEL-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"This is an embarrassingly small towel." CR>)
+	       (<P? (DRY RUB) ME>
+		<COND (<IN? ,WINNER ,YOKOSE-BATHTUB>
+		       <TELL "You're still in the tub." CR>)
+		      (<NOT <FSET? ,YOKOSE-BATHTUB ,TOUCHBIT>>
+		       <TELL "You aren't wet." CR>)
+		      (ELSE
+		       <TELL "You dry off as best you can." CR>)>)
+	       (<VERB? WEAR HIDE-BEHIND HIDE-UNDER>
+		<TELL
+"The towel is nearly too small to cover the subject." CR>)>>
+
+<OBJECT YOKOSE-BATHTUB
+	(LOC YOKOSE-BATH-HOUSE)
+	(DESC "bath tub")
+	(SYNONYM TUB BATH POOL WATER)
+	(ADJECTIVE BATH WOODEN HOT)
+	(FLAGS NDESCBIT CANT-HOLD VEHBIT OPENBIT CONTBIT SEARCHBIT SCOREBIT)
+	(CAPACITY 300)
+	(DESCFCN YOKOSE-BATHTUB-DESC)
+	(ACTION YOKOSE-BATHTUB-F)>
+
+<ROUTINE YOKOSE-BATHTUB-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (ELSE
+		<TELL
+"A large wooden bathtub dominates the room.">
+		<COND (<IN? ,MARIKO ,BATHTUB>
+		       <TELL
+"  Mariko is bathing in the tub.">)>
+		<RFATAL>)>>
+
+<ROUTINE YOKOSE-BATHTUB-F ("OPT" (RARG <>) "AUX" RUIN)
+	 <COND (<RARG? BEG>
+		<COND (<VERB? WALK>
+		       <YOULL-HAVE-TO "get out of the tub">)
+		      (<AND <VERB? WEAR>
+			    <NOT <IN? ,PRSO ,BATHTUB>>>
+		       <TELL
+G"You'd get it wet!" CR>)
+		      (<VERB? LIE-DOWN KNEEL>
+		       <TELL G"You would drown." CR>)
+		      (<P? BATHE MARIKO>
+		       <COND (<IN? ,MARIKO ,YOKOSE-BATHTUB>
+			      <TELL
+"You beckon Mariko to your side of the tub, and begin soaping her back.">
+			      <EXHIBITION>)>)
+		      (<OR <VERB? LEAP DIVE>
+			   <TAKE-A-BATH?>>
+		       <COND (<IN? ,MARIKO ,YOKOSE-BATHTUB>
+			      <TELL
+"You begin soaping away the filth of the road, and Mariko moves over to
+soap your back.">
+			      <EXHIBITION>)
+			     (ELSE
+			      <TELL "You scrub yourself." CR>)>)
+		      (<P? EXIT GLOBAL-HERE>
+		       <PERFORM ,V?DISEMBARK>
+		       <RTRUE>)
+		      (<OUTSIDE-TUB? ,YOKOSE-BATHTUB>
+		       <TELL
+CTHE ,PRSO IS/ARE ,PRSO G" outside the tub and out of reach." CR>)>)
+	       (<RARG? <>>
+		<COND (<VERB? EXAMINE>
+		       <COND (<NOUN-USED? ,PRSO ,W?WATER>
+			      <TELL
+"It's very hot, despite Mariko's complaints, and very clean." CR>)
+			     (ELSE
+			      <TELL
+G"The tub is wooden, large enough for several people, and deep enough
+that they could sit in it with only their heads above water." CR>)>)
+		      (<P? (TAKE MOVE) YOKOSE-BATHTUB>
+		       <COND (<AND <EQUAL? ,P-PRSA-WORD ,W?TAKE>
+				   <NOUN-USED? ,PRSO ,W?BATH>>
+			      <PERFORM ,V?BATHE ,ME>
+			      <RTRUE>)
+			     (ELSE
+			      <TELL
+G"It's much too heavy!" CR>)>)
+		      (<VERB? POUR>
+		       <TELL G"And waste all that nice hot water?" CR>)
+		      (<VERB? CLIMB-FOO BOARD ENTER>
+		       <SET RUIN <RUINABLE? ,WINNER>>
+		       <COND (.RUIN
+			      <COND (<OR <IN? ,MARIKO ,HERE>
+					 <IN? ,MARIKO ,YOKOSE-BATHTUB>>
+				     <TELL
+"Mariko says, \"Please, Anjin-san, don't climb into the tub ">
+				     <COND (<FSET? .RUIN ,WEARBIT>
+					    <TELL
+"wearing your dirty " D .RUIN>)
+					   (ELSE
+					    <TELL
+"carrying " THE .RUIN ".  You'll get " HIM/HER .RUIN " wet">)>
+				     <TELL "!\"" CR>)
+				    (ELSE
+				     <TELL
+"You remember at the last second that you are still ">
+				     <COND (<FSET? .RUIN ,WEARBIT>
+					    <TELL "wear">)
+					   (ELSE <TELL "carry">)>
+				     <TELL "ing your "
+D .RUIN "." CR>)>)
+			     (<NOT <FSET? ,BLACKTHORNE ,RMUNGBIT>>
+			      <PUT-DOWN-TOWEL>
+			      <FSET ,BLACKTHORNE ,RMUNGBIT>
+			      <TELL
+"You soap yourself up and rinse off by pouring buckets of water over
+your head.  You never enter a bathtub dirty!  Now you are ready for
+the hot soak that makes a bath a true bath!" CR>) 
+			     (ELSE
+			      <PUT-DOWN-TOWEL>
+			      <MOVE ,WINNER ,YOKOSE-BATHTUB>
+			      <FSET ,YOKOSE-BATHTUB ,TOUCHBIT>
+			      <FCLEAR ,BLACKTHORNE ,RMUNGBIT>
+			      <TELL
+G"You climb gingerly up and over the side of the tub, and ease yourself
+in.  The water is scalding!" CR>)>)
+		      (<VERB? DRINK TASTE>
+		       <TELL
+G"You try to drink the scalding bathwater, but it's far too hot." CR>)>)>>
+
+<ROUTINE PUT-DOWN-TOWEL ()
+	 <COND (<IN? ,TOWEL ,WINNER>
+		<MOVE ,TOWEL ,HERE>
+		<TELL
+"First, you put down the towel so it won't get wet.  ">)>>
+
+<ROUTINE EXHIBITION ()
+	 <TELL " People are watching all around the room, undisturbed by
+a public exhibition that would lead to prison or worse in
+England.|
+|
+As the bath finishes and you climb out, you try to hide your anticipation
+of the night -- your anticipation and your fear of discovery." CR>
+	 <TIME-PASSES>
+	 <SCORE-OBJECT ,YOKOSE-BATHTUB>
+	 <DRESS-BLACKTHORNE>
+	 <MOVE ,DICTIONARY ,YOKOSE-SPA-1>
+	 <MOVE ,MARIKO ,YOKOSE-SPA-3>
+	 <MOVE ,CHIMMOKO ,YOKOSE-SPA-3>
+	 <MOVE ,GYOKO ,YOKOSE-SPA-5>
+	 <MOVE ,KIKU ,YOKOSE-SPA-5>
+	 <MOVE ,YOSHINAKA ,YOKOSE-SPA-6>
+	 <MOVE ,BLACKTHORNE ,HERE>
+	 <MOVE ,TOWEL ,HERE>
+	 <DRESS-BLACKTHORNE>
+	 <DEQUEUE I-YOKOSE-BATH>
+	 <QUEUE I-YOSHINAKA -1>
+	 <CRLF>
+	 <GOTO ,YOKOSE-SPA-1>>
+
+<ROUTINE I-YOKOSE-BATH ("AUX" (H? <HERE? ,YOKOSE-BATH-HOUSE>))
+	 <ZLINES ,BATH-CNT
+		 (<THIS-IS-IT ,MARIKO>
+		  <COND (.H?
+			 <TELL CR
+"Mariko calls to you, \"Come, Anjin-san, bathe thyself!  The water is
+nearly cold, as is to thy liking!\"  In fact, you still find the
+temperature of the baths near to scalding." CR>)>)
+		 (<COND (<IN? ,ROBE ,MARIKO>
+			 <MOVE ,ROBE ,HERE>
+			 <FCLEAR ,ROBE ,WEARBIT>
+			 <COND (.H?
+				<TELL CR
+"Mariko removes her thick cotton bathing robe">)>)
+			(ELSE
+			 <COND (.H?
+			 <TELL CR
+"Mariko finishes preparing for her bath">)>)>
+		  <COND (.H?
+		  <TELL " with the assistance of
+Chimmoko, her maid." CR>)>)
+		 (DELAY
+		  <COND (<AND <L? ,DELAY-CNT 4>
+			      <OR <HELD? ,KIMONO>
+				  <HELD? ,SANDALS>
+				  <HELD? ,SOCKS>>>
+			 <COND (<EQUAL? ,DELAY-CNT 1 2>
+				<COND (.H?
+				       <TELL CR
+"\"Come, Anjin-san, the water chills!\" Mariko laughs." CR>
+				       <RTRUE>)
+				      (ELSE <RFALSE>)>)
+			       (<EQUAL? ,DELAY-CNT 3>
+				<COND (.H?
+				       <TELL CR
+"\"I chill as well, Anjin-san, the air is cold!\" Mariko says." CR>
+				       <RTRUE>)
+				      (ELSE
+				       <RFALSE>)>)
+			       (ELSE
+				<COND (.H?
+				       <TELL CR
+"\"Well, I suppose I'll bathe without you,\" she says, disappointed at
+your prudishness." CR>
+				       <RTRUE>)
+				      (ELSE <RFALSE>)>)>)>)
+		 (<MOVE ,MARIKO ,YOKOSE-BATHTUB>
+		  <COND (.H?
+			 <COND (<AND <NOT <HELD? ,KIMONO>>
+				     <NOT <HELD? ,SANDALS>>
+				     <NOT <HELD? ,SOCKS>>>
+				<MARGINAL-PIC ,P-BATH <>>)>
+			 <TELL CR
+"Mariko climbs into the tub and begins bathing." CR>)>)
+		 (DELAY
+		  <COND (<IN? ,BLACKTHORNE ,YOKOSE-BATH-HOUSE>
+			 <COND (<EQUAL? ,DELAY-CNT 1>
+				<TELL CR
+"Mariko begins to soap herself." CR>)
+			       (<EQUAL? ,DELAY-CNT 2>
+				<TELL CR
+"Mariko is soaping herself and Chimmoko helps by scrubbing her back." CR>)
+			       (<EQUAL? ,DELAY-CNT 3>
+				<TELL CR
+"Mariko rinses off, water streaming down her long black hair." CR>)
+			       (<EQUAL? ,DELAY-CNT 4>
+				<MOVE ,MARIKO ,YOKOSE-SPA-3>
+				<MOVE ,CHIMMOKO ,YOKOSE-SPA-3>
+				<TELL CR
+"Mariko climbs out of the bath, puts on her robe, and with a slightly
+disappointed bow, heads inside." CR>
+				<DEQUEUE I-YOKOSE-BATH>
+				<FAILED-SCENE>)>
+			 <RTRUE>)>)
+		 (<REMOVE ,ROBE>
+		  <DEQUEUE I-YOKOSE-BATH>)>>
+
+<OBJECT SHOJI-1
+	(LOC LOCAL-GLOBALS)
+	(DESC "west shoji")
+	(SYNONYM SHOJI DOOR)
+	(FLAGS NDESCBIT DOORBIT)>
+
+<OBJECT SHOJI-2
+	(LOC LOCAL-GLOBALS)
+	(DESC "east shoji")
+	(SYNONYM SHOJI DOOR)
+	(FLAGS NDESCBIT DOORBIT)>
+
+<OBJECT SHOJI-3
+	(LOC LOCAL-GLOBALS)
+	(DESC "west shoji")
+	(SYNONYM SHOJI DOOR)
+	(FLAGS NDESCBIT DOORBIT)>
+
+<OBJECT SHOJI-4
+	(LOC LOCAL-GLOBALS)
+	(DESC "east shoji")
+	(SYNONYM SHOJI DOOR)
+	(FLAGS NDESCBIT DOORBIT)>
+
+<OBJECT SHOJI-5
+	(LOC LOCAL-GLOBALS)
+	(DESC "west shoji")
+	(SYNONYM SHOJI DOOR)
+	(FLAGS NDESCBIT DOORBIT)>
+
+<OBJECT SHOJI-6
+	(LOC LOCAL-GLOBALS)
+	(DESC "east shoji")
+	(SYNONYM SHOJI DOOR)
+	(FLAGS NDESCBIT DOORBIT)>
+
+<ROOM YOKOSE-SPA-1
+      (LOC ROOMS)
+      (SCENE S-JOURNEY)
+      (OWNER BLACKTHORNE)
+      (DESC "Blackthorne's Room")
+      (LDESC
+"This is your room at the spa at Yokose.  The corridor is outside, and
+Mariko's room is next to yours, but accessible only from the corridor.")
+      (SYNONYM YOKOSE SPA ROOM)
+      (ADJECTIVE YOKOSE)
+      (OUT TO YOKOSE-CORRIDOR-1)
+      (EAST TO YOKOSE-CORRIDOR-1)
+      (FLAGS ONBIT RMUNGBIT)
+      (GLOBAL LG-YOSHINAKA SHOJI-1)
+      (ACTION YOKOSE-SPA-1-F)>
+
+<ROUTINE YOKOSE-SPA-1-F ("OPT" (RARG <>))
+	 <COND (<RARG? BEG>
+		<COND (<VERB? SLEEP>
+		       <TELL
+"You can't sleep. You only want to be with Mariko. You know your time
+together will end soon." CR>)>)
+	       (<RARG? ENTER>
+		<COND (<FSET? ,HERE ,SCOREBIT>
+		       <SCORE-OBJECT ,HERE>
+		       <TELL
+"You return to the safety and loneliness of your own room, remembering
+Mariko's answer when you asked \"After Mishima, what then?\"|
+|
+\"There's a pass that curls up through the mountains.  After that the road falls
+away to the city of Odawara.  From there to Yedo is only a matter of time.\"|
+|
+\"How much time?\"|
+|
+\"Not enough,\" she answered.|
+|
+\"You're wrong, my love, so sorry,\" you said.  \"There's all the time in the
+world.\"" CR CR>
+		       <NEXT-SCENE>)>)>>
+
+<ROOM YOKOSE-SPA-2
+      (LOC ROOMS)
+      (SCENE S-JOURNEY)
+      (DESC "Room in the Inn")
+      (LDESC
+"This is a room at the spa at Yokose.  The corridor is outside.")
+      (SYNONYM YOKOSE SPA ROOM)
+      (ADJECTIVE YOKOSE)
+      (OUT TO YOKOSE-CORRIDOR-1)
+      (WEST TO YOKOSE-CORRIDOR-1)
+      (GLOBAL LG-YOSHINAKA SHOJI-2)
+      (FLAGS ONBIT RMUNGBIT)
+      (ACTION YOKOSE-SPA-F)>
+
+<ROUTINE YOKOSE-SPA-F (RARG)
+	 <COND (<RARG? BEG>
+		<COND (<VERB? SLEEP>
+		       <TELL
+"You should sleep in your own room. To sleep in someone else's would be
+impolite." CR>)>)>>
+
+<OBJECT YOKOSE-GUEST-1
+	(LOC YOKOSE-SPA-2)
+	(DESC "guest")
+	(SYNONYM GUEST)
+	(FLAGS PERSON JAPANESEBIT)
+	(ACTION YOKOSE-GUEST-F)>
+
+<ROOM YOKOSE-CORRIDOR-1
+      (LOC ROOMS)
+      (SCENE S-JOURNEY)
+      (DESC "South of Corridor")
+      (LDESC
+"This is the corridor outside the rooms.  It continues north and there
+are rooms to the east and west.")
+      (SYNONYM YOKOSE SPA CORRIDOR)
+      (ADJECTIVE YOKOSE)
+      (WEST TO YOKOSE-SPA-1)
+      (EAST TO YOKOSE-SPA-2)
+      (NORTH TO YOKOSE-CORRIDOR-2)
+      (GLOBAL LG-YOSHINAKA SHOJI-1 SHOJI-2)
+      (FLAGS ONBIT)>
+
+<ROOM YOKOSE-SPA-3
+      (LOC ROOMS)
+      (SCENE S-JOURNEY)
+      (DESC "Mariko's Room")
+      (OWNER MARIKO)
+      (LDESC
+"This is a room at the spa at Yokose.  The corridor is outside.")
+      (SYNONYM YOKOSE SPA ROOM)
+      (ADJECTIVE YOKOSE)
+      (OUT TO YOKOSE-CORRIDOR-2)
+      (EAST TO YOKOSE-CORRIDOR-2)
+      (FLAGS ONBIT RMUNGBIT SCOREBIT)
+      (GLOBAL LG-YOSHINAKA SHOJI-3)
+      (ACTION YOKOSE-SPA-3-F)>
+
+<ROUTINE YOKOSE-SPA-3-F ("OPT" (RARG <>))
+	 <COND (<RARG? ENTER>
+		<COND (<EQUAL? <LOC ,YOSHINAKA> ,YOKOSE-CORRIDOR-1
+			       ,YOKOSE-CORRIDOR-2 ,YOKOSE-CORRIDOR-3>
+		       <SETG YOSHI-GOAL ,YOKOSE-SPA-3>)>
+		<COND (<IN? ,CHIMMOKO ,HERE>
+		       <MOVE ,CHIMMOKO ,YOKOSE-CORRIDOR-2>
+		       <TELL
+"As you enter the room, Chimmoko slips silently out." CR CR>)>)
+	       (<RARG? BEG>
+		<COND (<P? WALK (P?OUT P?EAST)>
+		       <COND (<EQUAL? <LOC ,YOSHINAKA> ,YOKOSE-CORRIDOR-1
+				      ,YOKOSE-CORRIDOR-2 ,YOKOSE-CORRIDOR-3>
+			      <TELL
+"You open the shoji a crack, make a quick scan of the corridor looking
+for anyone who might be watching, and ">
+			      <COND (<JIGS-UP? ,J-YOSHI
+"catch a fleeting glimpse of Yoshinaka.  Heart pounding, you slip the
+shoji closed.">
+				     <JIGS-UP
+"seeing no one, slip out.  Suddenly,
+Yoshinaka appears out of nowhere.  Mariko screams, and Yoshinaka looks almost
+regretful as he takes your head.">
+				     <RFATAL>)
+				    (ELSE <RTRUE>)>)>)
+		      (<P? (KISS FUCK LOVE) MARIKO>
+		       <COND (<IN? ,YOSHINAKA ,HERE>
+			      <TELL
+"Such activity would be fatal with Yoshinaka here to see!" CR>)
+			     (<FSET? ,HERE ,SCOREBIT>
+			      <FSET ,YOKOSE-SPA-1 ,SCOREBIT>
+			      <SCORE-OBJECT ,HERE>
+			      <TELL
+"\"Thou!  At long last I know what love means,\" she murmurs in Latin, the
+language of lovers.  \"I love thee, so I'm
+afraid for thee.\" she whispers.  \"I've
+destroyed thee, my love, by beginning.  We're doomed now.  I've destroyed thee
+-- that is the truth.\"|
+|
+\"No, Mariko, somehow something will happen to make everything right.\"|
+|
+\"I should never have begun.  The fault is mine.\"|
+|
+\"Do not worry, I beg thee.  "I"Karma"" is "I"karma"".\"|
+|
+At length she is persuaded and melts into your arms." CR>)
+			     (ELSE
+			      <SETG YOSHI-GOAL ,YOKOSE-SPA-3>
+			      <TELL
+"\"Ah, Anjin-san, we tempt fate even now!  Danger is everywhere for
+us.  You must go.\"" CR>)>)
+		      (<VERB? SLEEP>
+		       <TELL
+"\"You can't sleep here, Anjin-san. We would be discovered for
+certain!\"" CR>)>)>>
+
+<ROOM YOKOSE-SPA-4
+      (LOC ROOMS)
+      (SCENE S-JOURNEY)
+      (DESC "Room at the Inn")
+      (LDESC
+"This is a room at the spa at Yokose.  The corridor is outside.")
+      (SYNONYM YOKOSE SPA ROOM)
+      (ADJECTIVE YOKOSE)
+      (OUT TO YOKOSE-CORRIDOR-2)
+      (WEST TO YOKOSE-CORRIDOR-2)
+      (GLOBAL LG-YOSHINAKA SHOJI-4)
+      (FLAGS ONBIT RMUNGBIT)
+      (ACTION YOKOSE-SPA-F)>
+
+<OBJECT YOKOSE-GUEST-2
+	(LOC YOKOSE-SPA-4)
+	(DESC "guest")
+	(SYNONYM GUEST)
+	(FLAGS PERSON JAPANESEBIT)
+	(ACTION YOKOSE-GUEST-F)>
+
+<ROUTINE YOKOSE-GUEST-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<WAKARIMASEN>)
+	       (<RARG? <>>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"What you can mostly see is that the guest is annoyed at having his sleep
+disturbed." CR>)>)>>
+
+<ROOM YOKOSE-CORRIDOR-2
+      (LOC ROOMS)
+      (SCENE S-JOURNEY)
+      (DESC "Middle of Corridor")
+      (LDESC
+"This is the corridor outside the rooms.  It continues north and south
+and there are rooms to the east and west.")
+      (SYNONYM YOKOSE SPA CORRIDOR)
+      (ADJECTIVE YOKOSE)
+      (WEST TO YOKOSE-SPA-3)
+      (EAST TO YOKOSE-SPA-4)
+      (NORTH TO YOKOSE-CORRIDOR-3)
+      (SOUTH TO YOKOSE-CORRIDOR-1)
+      (GLOBAL LG-YOSHINAKA SHOJI-3 SHOJI-4)
+      (FLAGS ONBIT)>
+
+<ROOM YOKOSE-SPA-5
+      (LOC ROOMS)
+      (SCENE S-JOURNEY)
+      (DESC "Gyoko's Room")
+      (OWNER GYOKO)
+      (LDESC
+"This is a room at the spa at Yokose.  The corridor is outside.")
+      (SYNONYM YOKOSE SPA ROOM)
+      (ADJECTIVE YOKOSE)
+      (OUT TO YOKOSE-CORRIDOR-3)
+      (EAST TO YOKOSE-CORRIDOR-3)
+      (GLOBAL LG-YOSHINAKA SHOJI-5)
+      (FLAGS ONBIT RMUNGBIT)
+      (ACTION YOKOSE-SPA-F)>
+
+<ROOM YOKOSE-SPA-6
+      (LOC ROOMS)
+      (SCENE S-JOURNEY)
+      (OWNER YOSHINAKA)
+      (DESC "Yoshinaka's Room")
+      (LDESC
+"This is a room at the spa at Yokose.  The corridor is outside.")
+      (SYNONYM YOKOSE SPA ROOM)
+      (ADJECTIVE YOKOSE)
+      (OUT TO YOKOSE-CORRIDOR-3)
+      (WEST TO YOKOSE-CORRIDOR-3)
+      (GLOBAL LG-YOSHINAKA SHOJI-6)
+      (FLAGS ONBIT RMUNGBIT)
+      (ACTION YOKOSE-SPA-F)>
+
+<ROOM YOKOSE-CORRIDOR-3
+      (LOC ROOMS)
+      (SCENE S-JOURNEY)
+      (DESC "North of Corridor")
+      (LDESC
+"This is the corridor outside the rooms.  It continues south and there
+are rooms to the east and west.  A stair leads down.")
+      (SYNONYM YOKOSE SPA CORRIDOR)
+      (ADJECTIVE YOKOSE)
+      (WEST TO YOKOSE-SPA-5)
+      (EAST TO YOKOSE-SPA-6)
+      (SOUTH TO YOKOSE-CORRIDOR-2)
+      (DOWN TO YOKOSE-FIRST-FLOOR)
+      (GLOBAL LG-YOSHINAKA SHOJI-5 SHOJI-6)
+      (FLAGS ONBIT)>
+
+<ROOM YOKOSE-FIRST-FLOOR
+      (LOC ROOMS)
+      (SCENE S-JOURNEY)
+      (DESC "First Floor")
+      (LDESC
+"This is the first floor of the spa at Yokose.  A stair leads up to
+the private rooms.  To the east is the bath house.")
+      (SYNONYM YOKOSE SPA)
+      (ADJECTIVE YOKOSE)
+      (EAST TO YOKOSE-BATH-HOUSE)
+      (UP TO YOKOSE-CORRIDOR-3)
+      (FLAGS ONBIT RMUNGBIT)>
+
+<OBJECT GYOKO
+	(DESC "Gyoko")
+	(SYNONYM GYOKO)
+	(FLAGS PERSON FEMALE NOABIT NOTHEBIT JAPANESEBIT)>
+
+<OBJECT KIKU
+	(DESC "Kiku")
+	(SYNONYM KIKU)
+	(FLAGS PERSON FEMALE NOABIT NOTHEBIT JAPANESEBIT)>
+
+<OBJECT LG-YOSHINAKA
+	(LOC LOCAL-GLOBALS)
+	(DESC "Yoshinaka")
+	(SYNONYM YOSHINAKA)
+	(FLAGS PERSON NOABIT NOTHEBIT JAPANESEBIT)
+	(ACTION LG-YOSHINAKA-F)>
+
+<ROUTINE LG-YOSHINAKA-F ("OPT" (RARG <>) "AUX" (L <LOC ,YOSHINAKA>))
+	 <COND (<OR <P? (TELL-ABOUT ASK-ABOUT) * YOSHINAKA>
+		    <VERB? FIND WHERE FOLLOW>>
+		<REDIRECT ,LG-YOSHINAKA ,YOSHINAKA>
+		<RTRUE>)
+	       (<AND <NOT <FSET? .L ,RMUNGBIT>>
+		     <NOT <FSET? ,HERE ,RMUNGBIT>>>
+	        <TELL
+"Yoshinaka is down the hall." CR>)
+	       (<VERB? LISTEN>
+		<TELL
+"He seems to be in ">
+		<TELL-WHOSE .L ,YOSHINAKA>
+		<TELL " room." CR>)
+	       (ELSE
+		<TELL "You don't see Yoshinaka right now." CR>)>>
+
+<OBJECT YOSHINAKA
+	(DESC "Yoshinaka")
+	(SYNONYM YOSHINAKA)
+	(FLAGS PERSON NOABIT NOTHEBIT JAPANESEBIT)
+	(ACTION YOSHINAKA-F)>
+
+<ROUTINE YOSHINAKA-F ("OPT" (RARG <>))
+	 <COND (<RARG? WINNER>
+		<WAKARIMASEN>)
+	       (<RARG? <>>
+		<COND (<VERB? LISTEN>
+		       <TELL
+"You can hear him making his rounds." CR>)>)>>
+
+<GLOBAL YOSHI-CHATS 0>
+
+<GLOBAL YOSHI-WAITS? 0>
+<GLOBAL YOSHI-GOAL <>>
+<GLOBAL YOSHI-TABLE
+	<LTABLE YOKOSE-SPA-1 YOKOSE-SPA-2 YOKOSE-SPA-3
+		YOKOSE-SPA-4 YOKOSE-SPA-5 YOKOSE-SPA-6>>
+
+;<ROUTINE DEBUG-YOSHI (L NL)
+	 <TELL "[Yoshi: ">
+	 <TELL-WHERE .L>
+	 <TELL " -> ">
+	 <TELL-WHERE .NL>
+	 <TELL "]" CR>>
+		
+<ROUTINE I-YOSHINAKA ("AUX" (L <LOC ,YOSHINAKA>) NL (P <RANDOM 4>) N TMP)
+	 <COND (<IN? ,YOSHINAKA ,YOKOSE-CORRIDOR-1>
+		<COND (<AND <HERE? .L>
+			    <L=? .P ,YOSHI-CHATS>>)
+		      (<EQUAL? ,YOSHI-GOAL ,YOKOSE-SPA-1 ,YOKOSE-SPA-2>
+		       <MOVE ,YOSHINAKA ,YOSHI-GOAL>)
+		      (ELSE
+		       <MOVE ,YOSHINAKA ,YOKOSE-CORRIDOR-2>)>)
+	       (<IN? ,YOSHINAKA ,YOKOSE-CORRIDOR-2>
+		<COND (<AND <HERE? .L>
+			    <L=? .P ,YOSHI-CHATS>>)
+		      (<EQUAL? ,YOSHI-GOAL ,YOKOSE-SPA-1 ,YOKOSE-SPA-2>
+		       <MOVE ,YOSHINAKA ,YOKOSE-CORRIDOR-1>)
+		      (<EQUAL? ,YOSHI-GOAL ,YOKOSE-SPA-3 ,YOKOSE-SPA-4>
+		       <MOVE ,YOSHINAKA ,YOSHI-GOAL>)
+		      (ELSE
+		       <MOVE ,YOSHINAKA ,YOKOSE-CORRIDOR-3>)>)
+	       (<IN? ,YOSHINAKA ,YOKOSE-CORRIDOR-3>
+		<COND (<AND <HERE? .L>
+			    <L=? .P ,YOSHI-CHATS>>)
+		      (<EQUAL? ,YOSHI-GOAL ,YOKOSE-SPA-5 ,YOKOSE-SPA-6>
+		       <MOVE ,YOSHINAKA ,YOSHI-GOAL>)
+		      (ELSE
+		       <MOVE ,YOSHINAKA ,YOKOSE-CORRIDOR-2>)>)
+	       (<EQUAL? .L ,YOKOSE-SPA-1 ,YOKOSE-SPA-2>
+		<COND (<OR <HERE? .L> <L=? .P ,YOSHI-CHATS>>
+		       <MOVE ,YOSHINAKA ,YOKOSE-CORRIDOR-1>)>)
+	       (<EQUAL? .L ,YOKOSE-SPA-3 ,YOKOSE-SPA-4>
+		<COND (<AND <EQUAL? .L ,YOKOSE-SPA-3>
+			    <HERE? ,YOKOSE-SPA-3>>
+		       <TELL CR
+"Yoshinaka seems reluctant to leave before you do.  He seems very
+nervous.  Mariko says, \"Perhaps you should leave, Anjin-san.\"" CR>
+		       <RTRUE>)
+		      (<OR <HERE? .L> <L=? .P ,YOSHI-CHATS>>
+		       <MOVE ,YOSHINAKA ,YOKOSE-CORRIDOR-2>)>)
+	       (<EQUAL? .L ,YOKOSE-SPA-5>
+		<COND (<OR <HERE? .L> <L=? .P ,YOSHI-CHATS>>
+		       <MOVE ,YOSHINAKA ,YOKOSE-CORRIDOR-3>)>)
+	       (<EQUAL? .L ,YOKOSE-SPA-6>
+		<COND (<ZERO? ,YOSHI-WAITS?>
+		       <REPEAT ((CNT 0))
+			       <COND (<EQUAL? .CNT 5> <RETURN>)>
+			       <SET N <+ .CNT <RANDOM <- 5 .CNT>>>>
+			       <SET CNT <+ .CNT 1>>
+			       <SET TMP <GET ,YOSHI-TABLE .CNT>>
+			       <PUT ,YOSHI-TABLE .CNT <GET ,YOSHI-TABLE .N>>
+			       <PUT ,YOSHI-TABLE .N .TMP>>
+		       <PUT ,YOSHI-TABLE 6 ,YOKOSE-SPA-6>
+		       <PUT ,YOSHI-TABLE 0 1>
+		       <SETG YOSHI-GOAL <GET ,YOSHI-TABLE 1>>
+		       <MOVE ,YOSHINAKA ,YOKOSE-CORRIDOR-3>)
+		      (ELSE <SETG YOSHI-WAITS? <- ,YOSHI-WAITS? 1>>)>)>
+	 <COND (<NOT <IN? ,YOSHINAKA .L>>
+		<SETG YOSHI-CHATS 0>)
+	       (ELSE
+		<SETG YOSHI-CHATS <+ ,YOSHI-CHATS 1>>)>
+	 <SET NL <LOC ,YOSHINAKA>>
+	 <COND (<AND <NOT <EQUAL? .L .NL>>
+		     <NOT <FSET? .L ,RMUNGBIT>> ;"was in corridor"
+		     <FSET? .NL ,RMUNGBIT>> ;"entered a room"
+		<COND (<NOT <EQUAL? .NL ,YOKOSE-SPA-6>>
+		       <PUT ,YOSHI-TABLE
+			    0
+			    <+ <GET ,YOSHI-TABLE 0> 1>>
+		       <SETG YOSHI-GOAL
+			     <GET ,YOSHI-TABLE
+				  <GET ,YOSHI-TABLE 0>>>)
+		      (ELSE
+		       <SETG YOSHI-WAITS? <+ 5 <RANDOM 5>>>)>)>
+	 <COND (<HERE? ,YOKOSE-FIRST-FLOOR ,YOKOSE-BATH-HOUSE>
+		<RFALSE>)
+	       (<NOT <EQUAL? .L .NL>> ;"Yoshi moved"
+		<COND (<FSET? .L ,RMUNGBIT> ;"was in someone's room"
+		       <COND (<NOT <FSET? .NL ,RMUNGBIT>>
+			      <COND (<FSET? ,HERE ,RMUNGBIT>
+				     <COND (<YOKOSE-NEIGHBOR? ,HERE .L>
+					    <TELL CR
+"You can hear Yoshinaka leaving ">
+					    <TELL-WHOSE .L ,YOSHINAKA>
+					    <TELL " room." CR>)
+					   (<HERE? .L>
+					    <TELL CR
+"Yoshinaka, very polite, bows and leaves the room." CR>)>)
+				    (ELSE
+				     <TELL CR
+"You see Yoshinaka emerge from ">
+				     <TELL-WHOSE .L ,YOSHINAKA>
+				     <TELL " room." CR>)>)>)
+		      (ELSE ;"was in corridor"
+		       <COND (<HERE? ,YOKOSE-SPA-3>
+			      <CRLF>
+			      <JIGS-UP
+"There is a moment of silence outside the door.  Then, with a burst, the shoji
+is thrown aside!  Yoshinaka charges into the room, sword drawn.  Mariko screams,
+knowing your fate is sealed.  Caught!  If only the two of you had been less
+love-besotted, more careful!  But it was a love doomed from the start, as Mariko
+always knew.">
+			      <RFATAL>)
+			     (<FSET? .NL ,RMUNGBIT> ;"entered a room"
+			      <COND (<EQUAL? .NL ,YOKOSE-SPA-1>
+				     <COND (<HERE? .NL>
+					    <TELL CR
+"Yoshinaka knocks politely on your door, and then enters the room.  \"So sorry,
+Anjin-san.  Must check rooms, must make sure all safe, "I"neh?""\"" CR>)
+					   (<HERE? ,YOKOSE-CORRIDOR-1
+						   ,YOKOSE-CORRIDOR-2
+						   ,YOKOSE-CORRIDOR-3>
+					    <TELL CR
+"Yoshinaka enters your room, checking to make sure all is as it should
+be." CR>)
+					   (<HERE? ,YOKOSE-SPA-3>
+					    <TELL CR
+"You can hear Yoshinaka entering your room." CR>)>)
+				    (<FSET? ,HERE ,RMUNGBIT>
+				     <COND (<HERE? .NL>
+					    <TELL 'YOSHINAKA>
+					    <COND (<HERE? ,YOKOSE-SPA-6>
+						   <TELL
+" comes into his room.">)
+						  (ELSE
+						   <TELL
+" knocks on the door, and ">
+						   <COND (<GETP .NL ,P?OWNER>
+							  <TELL-WHO .NL>)
+							 (ELSE
+							  <TELL "the guest">)>
+						   <TELL
+" equally politely, bids him enter.">)>
+					    <TELL 
+"Yoshinaka is somewhat surprised to find you there as well." CR>)
+					   (<YOKOSE-NEIGHBOR? ,HERE .NL>
+					    <TELL CR
+"You can hear Yoshinaka entering ">
+					    <TELL-WHOSE .NL ,YOSHINAKA>
+					    <TELL " room." CR>)>)
+				    (<EQUAL? .NL ,YOKOSE-SPA-6>
+				     <TELL CR
+"Yoshinaka returns to his room, evidently finished with this round of
+inspection." CR>)
+				    (ELSE
+				     <TELL CR
+"You see Yoshinaka knock politely on ">
+				     <TELL-WHOSE .NL ,YOSHINAKA>
+				     <TELL " door
+and then enter the room." CR>)>)
+			     (<NOT <FSET? ,HERE ,RMUNGBIT>>
+			      <TELL CR
+"Yoshinaka walks ">
+			      <COND (<OR <EQUAL? .L ,YOKOSE-CORRIDOR-1>
+					 <AND <EQUAL? .L ,YOKOSE-CORRIDOR-2>
+					      <EQUAL? .NL ,YOKOSE-CORRIDOR-3>>>
+				     <TELL "north up">)
+				    (ELSE
+				     <TELL "south down">)>
+			      <TELL " the corridor">
+			      <COND (<HERE? .NL>
+				     <TELL ", joining you">)>
+			      <TELL "." CR>)>)>)
+	       (ELSE ;"Yoshi didn't move"
+		<COND (<FSET? .L ,RMUNGBIT>
+		       <COND (<OR <NOT <FSET? ,HERE ,RMUNGBIT>>
+				  <YOKOSE-NEIGHBOR? ,HERE .L>>
+			      <COND (<EQUAL? .L ,YOKOSE-SPA-1>
+				     <TELL CR
+"Thanks to the thin shoji-screen walls, which are almost transparent to
+sound, you can tell that Yoshinaka is still in your room." CR>)
+				    (<EQUAL? .L ,YOKOSE-SPA-6>
+				     <TELL CR
+"Yoshinaka seems to still be in his room." CR>)
+				    (ELSE
+				     <TELL CR
+"You can hear Yoshinaka">
+				     <COND (<FSET? ,HERE ,RMUNGBIT>
+					    <TELL ", in the next room,">)>
+				     <TELL " talking to ">
+				     <TELL-WHO .NL ,YOSHINAKA>
+				     <TELL "." CR>)>)
+			     (<HERE? .L>
+			      <COND (<EQUAL? .L ,YOKOSE-SPA-6>
+				     <TELL CR
+"Between his rounds of inspection, Yoshinaka quietly meditates." CR>)
+				    (ELSE
+				     <TELL CR
+"Yoshinaka, very apologetic but determined to do his duty, looks over the
+room." CR>)>)>)
+		      (<HERE? .L>
+		       <COND (<NOT ,YOSHI-CHATS>
+			      <TELL CR
+"Yoshinaka bows and greets you in simple phrases so that you will
+understand.  \"Good evening, Anjin-san.\"  He seems unsure why you are
+up and about at this hour of the night." CR>)>)
+		      (ELSE
+		       <TELL CR
+"Yoshinaka, down the corridor to the ">
+		       <COND (<OR <HERE? ,YOKOSE-CORRIDOR-3>
+				  <AND <HERE? ,YOKOSE-CORRIDOR-2>
+				       <EQUAL? .L ,YOKOSE-CORRIDOR-1>>>
+			      <TELL "south">)
+			     (ELSE <TELL "north">)>
+		       <TELL ", is making his rounds." CR>)>)>>
+
+;<ROUTINE TELL-WHERE (RM)
+	 <COND (<EQUAL? .RM ,YOKOSE-SPA-1> <TELL "Room 1">)
+	       (<EQUAL? .RM ,YOKOSE-SPA-2> <TELL "Room 2">)
+	       (<EQUAL? .RM ,YOKOSE-SPA-3> <TELL "Room 3">)
+	       (<EQUAL? .RM ,YOKOSE-SPA-4> <TELL "Room 4">)
+	       (<EQUAL? .RM ,YOKOSE-SPA-5> <TELL "Room 5">)
+	       (<EQUAL? .RM ,YOKOSE-SPA-6> <TELL "Room 6">)
+	       (<EQUAL? .RM ,YOKOSE-CORRIDOR-1> <TELL "Corridor 1">)
+	       (<EQUAL? .RM ,YOKOSE-CORRIDOR-2> <TELL "Corridor 2">)
+	       (<EQUAL? .RM ,YOKOSE-CORRIDOR-3> <TELL "Corridor 3">)
+	       (ELSE <TELL "?">)>>
+
+<ROUTINE TELL-WHO (OBJ "OPT" (WHO ,BLACKTHORNE)
+		   "AUX" (O <GETP .OBJ ,P?OWNER>))
+	 <COND (<NOT .O> <TELL "a guest">)
+	       (<EQUAL? .O ,BLACKTHORNE> <TELL "you">)
+	       (<EQUAL? .O .WHO> <TELL HIM/HER .O>)
+	       (ELSE <TELL D .O>)>>
+
+<ROUTINE TELL-WHOSE (OBJ "OPT" (WHO ,BLACKTHORNE)
+		     "AUX" (O <GETP .OBJ ,P?OWNER>))
+	 <COND (<NOT .O> <TELL "a guest's">)
+	       (<EQUAL? .O ,BLACKTHORNE> <TELL "your">)
+	       (<EQUAL? .O .WHO> <TELL HIS/HER .O>)
+	       (ELSE <TELL D .O "'s">)>>
+
+<ROUTINE YOKOSE-NEIGHBOR? (H L)
+	 <COND (<EQUAL? .H ,YOKOSE-FIRST-FLOOR ,YOKOSE-BATH-HOUSE> <RFALSE>)
+	       (<EQUAL? .H ,YOKOSE-SPA-1>
+		<COND (<EQUAL? .L ,YOKOSE-SPA-3> <RTRUE>)>)
+	       (<EQUAL? .H ,YOKOSE-SPA-2>
+		<COND (<EQUAL? .L ,YOKOSE-SPA-4> <RTRUE>)>)
+	       (<EQUAL? .H ,YOKOSE-SPA-3>
+		<COND (<EQUAL? .L ,YOKOSE-SPA-1 ,YOKOSE-SPA-5> <RTRUE>)>)
+	       (<EQUAL? .H ,YOKOSE-SPA-4>
+		<COND (<EQUAL? .L ,YOKOSE-SPA-2 ,YOKOSE-SPA-6> <RTRUE>)>)
+	       (<EQUAL? .H ,YOKOSE-SPA-5>
+		<COND (<EQUAL? .L ,YOKOSE-SPA-3> <RTRUE>)>)
+	       (<EQUAL? .H ,YOKOSE-SPA-6>
+		<COND (<EQUAL? .L ,YOKOSE-SPA-4> <RTRUE>)>)>
+	 <RFALSE>>
+
+<END-SEGMENT>
diff --git a/qverbs.zil b/qverbs.zil
new file mode 100644
index 0000000..2fe4793
--- /dev/null
+++ b/qverbs.zil
@@ -0,0 +1,663 @@
+"QVERBS for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc. All Rights Reserved."
+
+<FILE-FLAGS MDL-ZIL?>
+
+<DEFAULTS-DEFINED
+	PRINT-IS/ARE>
+
+<BEGIN-SEGMENT 0>
+
+<OBJECT WHAT
+	(LOC GLOBAL-OBJECTS)
+	(DESC "what")
+	(SYNONYM WHAT WHO ;WHOM)
+	(FLAGS NOTHEBIT)
+	(ACTION WHAT-F)>
+
+<DEFINE WHAT-F ("AUX" OBJ TMP NOT? LOC?)
+	<SET NOT? <ANDB ,PARSE-NOT <PARSE-FLAGS ,PARSE-RESULT>>>
+	<SET LOC? <PARSE-LOC ,PARSE-RESULT>>
+	<COND (<VERB? BE?>
+	       <RFALSE>)
+	      (<EQUAL? <SET OBJ <PARSE-QW ,PARSE-RESULT>>
+		       ,W?WHO ,W?WHAT ,W?WHERE ,W?WHY ,W?WHEN ,W?HOW>
+	       <RFALSE>)
+	      (<NOT <EVERYWHERE-VERB?> ;<ABSTRACT-VERB?>>
+	       <TELL
+"That's precisely the sort of question you'll have to answer for
+yourself." CR>
+	       <RTRUE>)
+	      (<EQUAL? ,PRSI ,INTPP>
+	       <COND (<AND <SET OBJ <P-PP-OBJ>>
+			   <NOT .NOT?>>
+		      <SET TMP <OR <P-PP-PREP> <PP-PREP .LOC?>>>
+		      <COND (<EQUAL? .TMP ,W?BEHIND>
+			     <PERFORM ,V?LOOK-BEHIND .OBJ>
+			     <RTRUE>)
+			    (<EQUAL? .TMP ,W?DOWN>
+			     <PERFORM ,V?LOOK-DOWN .OBJ>
+			     <RTRUE>)
+			    (<EQUAL? .TMP ,W?IN ,W?ON ,W?THROUGH>
+			     <PERFORM ,V?LOOK-INSIDE .OBJ>
+			     <RTRUE>)
+			    (<EQUAL? .TMP ,W?UNDER>
+			     <PERFORM ,V?LOOK-UNDER .OBJ>
+			     <RTRUE>)>)>)
+	      ;(<EQUAL? ,PRSI ,INTADJ>
+	       <SET ADJ? <PARSE-ADJ ,PARSE-RESULT>>
+	       <COND (<IS-PRSO-ADJ? .ADJ?>
+		      <COND (.NOT? <TELL "Wrong,">)
+			    (ELSE <TELL "Right,">)>
+		      <PRSO-IS <>>)
+		     (ELSE
+		      <COND (.NOT? <TELL "Right,">)
+			    (ELSE <TELL "Wrong,">)>
+		      <PRSO-IS T>)>
+	       <TELL " ">
+	       <PRINTB .ADJ?>
+	       <TELL "." CR>)
+	      ;(ELSE
+	       <TELL "So you think">
+	       <PRSO-IS .NOT?>
+	       <COND (,PRSI <TELL " " A ,PRSI>)>
+	       <TELL "." CR>)>>
+
+<DEFINE TELL-Q-WORD ("AUX" WD)
+	 <COND (<VERB? BE?>
+		<TELL "if">)
+	       (<EQUAL? <SET WD <PARSE-QW ,PARSE-RESULT>>
+			,W?WHO ,W?WHAT ,W?WHERE ,W?WHY ,W?WHEN ,W?HOW>
+		<PRINTB .WD>)
+	       (T
+		<TELL "whether">)>>
+
+<DEFINE P-NEGATIVE? ()
+	 <ANDB ,PARSE-NOT <PARSE-FLAGS ,PARSE-RESULT>>>
+
+<DEFINE TRY-QCONTEXT? ("AUX" W)
+	 <COND (<AND ,QCONTEXT
+		     <IN? ,QCONTEXT ,HERE>
+		     <NOT <EQUAL? ,QCONTEXT ,WINNER>>
+		     <OR <PAST-TENSE?>
+			 <AND <NOT <EQUAL? ,QCONTEXT ,PRSO>>
+			      <NOT <VERB? ASK-ABOUT>>
+			      <NOT <AND <VERB? TELL-ABOUT>
+					<EQUAL? ,PRSO ,ME>>>>>>
+		<SET W ,WINNER>
+		<SETG WINNER ,QCONTEXT>
+		<PERFORM ,PRSA ,PRSO ,PRSI>
+		<SETG WINNER .W ;,PLAYER>
+		<RTRUE>)>>
+
+<DEFINE PRE-BE ()
+	<COND (<TRY-QCONTEXT?>
+	       <RTRUE>)>>
+
+<SYNTAX BE OBJECT (MOBY) = V-BE PRE-BE>
+<SYNTAX BE OBJECT (MOBY) OBJECT (MOBY) = V-BE PRE-BE>
+
+<SYNTAX BE? OBJECT (MOBY) = V-BE?>
+<SYNTAX BE? OBJECT (MOBY) OBJECT (MOBY) = V-BE?>
+
+<DEFINE V-BE ("AUX" TMP NOT? ADJ? LOC? OBJ PREP)
+ <SET NOT? <ANDB ,PARSE-NOT <PARSE-FLAGS ,PARSE-RESULT>>>
+ <SET ADJ? <PARSE-ADJ ,PARSE-RESULT>>
+ <SET LOC? <PARSE-LOC ,PARSE-RESULT>>
+ <COND (<OR <VERB? BE? WHO WHAT WHERE WHY WHEN HOW>
+	    <EQUAL? <SET TMP <PARSE-QW ,PARSE-RESULT>>
+		    ,W?WHO ,W?WHAT ,W?WHERE ,W?WHY ,W?WHEN ,W?HOW>>
+	<COND (<TRY-QCONTEXT?>
+	       <RTRUE>)>
+	<COND (<EQUAL? ,PRSI ,INTADJ>
+	       <COND (<EQUAL? ,PRSO ,ME ,PLAYER>
+		      <COND (<VERB? BE?>
+			     <TELL "You">)
+			    (T
+			     <PRINT ,WHO-KNOWS-STRING>
+			     <TELL-Q-WORD>
+			     <TELL " you">)>
+		      <COND (<IS-PRSO-ADJ? .ADJ?>
+			     <TELL " are ">)
+			    (ELSE <TELL " aren't ">)>)
+		     (ELSE
+		      <COND (<VERB? BE?>
+			     <TELL-CTHE ,PRSO>)
+			    (T
+			     <PRINT ,WHO-KNOWS-STRING>
+			     <TELL-Q-WORD>
+			     <TELL " ">
+			     <TELL-THE ,PRSO>)>
+		      <PRINT-IS/ARE ,PRSO>
+		      <COND (<NOT <IS-PRSO-ADJ? .ADJ?>>
+			     <TELL "n't">)>
+		      <TELL " ">)>
+	       <PRINTB .ADJ?>
+	       <TELL "." CR>)
+	      (<EQUAL? ,PRSI ,INTPP>
+	       <COND (<AND <SET PREP <P-PP-PREP>>
+			   <SET OBJ <P-PP-OBJ>>>
+		      <COND (<VERB? BE?>
+			     <PRSO-IS <NOT <RIGHT-PREP? .PREP ,PRSO .OBJ>>
+				      T>
+			     <TELL " ">
+			     <PRINTB .PREP>
+			     <TELL " ">
+			     <TELL-THE .OBJ>
+			     <TELL "." CR>)
+			    (ELSE
+			     <PRINT ,WHO-KNOWS-STRING>
+			     <TELL-Q-WORD>
+			     <PRSO-IS .NOT?>
+			     <TELL " ">
+			     <PRINTB .PREP>
+			     <TELL " ">
+			     <TELL-THE .OBJ>
+			     <TELL "." CR>)>)
+		     (ELSE
+		      <PRINT ,WHO-KNOWS-STRING>
+		      <TELL-Q-WORD>
+		      <PRSO-IS .NOT?>
+		      <TELL " ">
+		      <PRINTB <PP-PREP .LOC?>>
+		      <TELL " ">
+		      <NP-PRINT <PP-NOUN .LOC?>>
+		      <TELL "." CR>)>)
+	      (<PARSE-SUBJ ,PARSE-RESULT>
+	       <WHO-KNOWS>)
+	      (<AND <NOT ,PRSI> <EQUAL? <PARSE-QW ,PARSE-RESULT> ,W?WHERE>>
+	       <COND (<NOT <EQUAL? ,PRSO <> ,ROOMS>>
+		      <SET LOC? <LOC ,PRSO>>)
+		     (T <SET LOC? <>>)>
+	       <COND (<NOT .LOC?>
+		      <TELL "That's an excellent question." CR>)
+		     (<IN? ,PRSO ,HERE>
+		      <PRSO-IS <> T>
+		      <TELL " here." CR>)
+		     (<EQUAL? .LOC? ,GENERIC-OBJECTS>
+		      <TELL "You don't know where ">
+		      <TELL-THE ,PRSO>
+		      <PRINT-IS/ARE ,PRSO>
+		      <TELL "." CR>)
+		     (<EQUAL? .LOC? ,GLOBAL-OBJECTS>
+		      <TELL "No doubt ">
+		      <TELL-THE ,PRSO>
+		      <PRINT-IS/ARE ,PRSO>
+		      <TELL " around here somewhere." CR>)
+		     (<AND <EQUAL? .LOC? ,LOCAL-GLOBALS>
+			   <GLOBAL-IN? ,PRSO ,HERE>>
+		      <TELL-CTHE ,PRSO>
+		      <PRINT-IS/ARE ,PRSO>
+		      <TELL " nearby." CR>)
+		     (<FSET? .LOC? ,PERSONBIT>
+		      <TELL-CTHE .LOC?>
+		      <TELL " has ">
+		      <TELL-THE ,PRSO>
+		      <TELL "." CR>)
+		     (<EQUAL? <META-LOC ,PRSO> ,HERE>
+		      <TELL-CTHE ,PRSO>
+		      <PRINT-IS/ARE ,PRSO>
+		      <TELL " in ">
+		      <TELL-THE .LOC?>
+		      <TELL "." CR>)
+		     (<IN? .LOC? ,ROOMS>
+		      <TELL-CTHE ,PRSO>
+		      <PRINT-IS/ARE ,PRSO>
+		      <TELL " probably ">
+		      <COND (<FSET? ,PRSO ,TOUCHBIT>
+			     <TELL
+"still in the place called \"" D .LOC? ".\"" CR>)
+			    (ELSE
+			     <COND (<NOT <FSET? ,PRSO ,PERSONBIT>>
+				    <TELL "lying ">)>
+			     <TELL "around somewhere." CR>)>)
+		     (ELSE
+		      <PRINT ,WHO-KNOWS-STRING>
+		      <TELL "where ">
+		      <TELL-THE ,PRSO>
+		      <PRINT-IS/ARE ,PRSO>
+		      <TELL "." CR>)>)
+	      (ELSE
+	       <PRINT ,WHO-KNOWS-STRING>
+	       <TELL-Q-WORD>
+	       <COND (<NOT <EQUAL? ,PRSO <> ,ROOMS>>
+		      <PRSO-IS .NOT?>
+		      <COND (,PRSI <TELL " " A ,PRSI>)>)>
+	       <TELL "." CR>)>)
+       (ELSE
+	<COND (<EQUAL? ,PRSI ,INTADJ>
+	       <COND (<IS-PRSO-ADJ? .ADJ?>
+		      <COND (.NOT? <TELL "Wrong,">)
+			    (ELSE <TELL "Right,">)>
+		      <PRSO-IS <>>)
+		     (ELSE
+		      <COND (.NOT? <TELL "Right,">)
+			    (ELSE <TELL "Wrong,">)>
+		      <PRSO-IS T>)>
+	       <TELL " ">
+	       <PRINTB .ADJ?>
+	       <TELL "." CR>)
+	      (<EQUAL? ,PRSI ,INTPP>
+	       <TELL "So, you say">
+	       <PRSO-IS .NOT?>
+	       <TELL " ">
+	       <COND (<SET TMP <P-PP-PREP>>
+		      <PRINTB .TMP>)
+		     (ELSE
+		      <PRINTB <PP-PREP .LOC?>>)>
+	       <TELL " ">
+	       <COND (<SET TMP <P-PP-OBJ>>
+		      <TELL-THE .TMP>)
+		     (ELSE <NP-PRINT <PP-NOUN .LOC?>>)>
+	       <TELL "." CR>)
+	      (<EQUAL? ,P-PRSA-WORD ,W?BE>
+	       <COND (<EQUAL? ,PRSO ,WINNER>
+		      <TELL-CTHE ,PRSO>
+		      <TELL " is already " "that" "." CR>)
+		     (T <TELL "That would take a bit of magic." CR>)>)
+	      (ELSE
+	       <TELL "So you think">
+	       <PRSO-IS .NOT?>
+	       <COND (,PRSI <TELL " " A ,PRSI>)>
+	       <TELL "." CR>)>)>>
+
+<DEFINE RIGHT-PREP? (PREP OBJ CONT)
+	 <COND (<NOT <IN? .OBJ .CONT>> <RFALSE>)
+	       (<EQUAL? .PREP ,W?IN ,W?INSIDE>
+		<COND (<SEE-INSIDE? .CONT>
+		       <RTRUE>)
+		      (ELSE <RFALSE>)>)
+	       (<AND <EQUAL? .PREP ,W?ON>
+		     <OR <FSET? .CONT ,SURFACEBIT>
+			 ;<FSET? .CONT ,FURNITURE>>>
+		<RTRUE>)>>
+
+<DEFINE V-BE? ()
+	 <V-BE>>
+
+<SYNTAX HOW OBJECT (MOBY) (FIND RLANDBIT) = V-HOW>
+<SYNTAX HOW OBJECT (MOBY) OBJECT (MOBY) = V-HOW>
+
+<SYNTAX WHAT OBJECT (MOBY) (FIND RLANDBIT) = V-WHAT>
+<SYNTAX WHAT OBJECT (MOBY) OBJECT (MOBY) = V-WHAT>
+
+<SYNTAX WHEN OBJECT (MOBY) (FIND RLANDBIT) = V-WHEN>
+<SYNTAX WHEN OBJECT (MOBY) OBJECT (MOBY) = V-WHEN>
+
+<SYNTAX WHERE OBJECT (MOBY) (FIND RLANDBIT) = V-WHERE PRE-WHERE>
+<SYNTAX WHERE OBJECT (MOBY) OBJECT (MOBY) = V-WHERE PRE-WHERE>
+
+<SYNTAX WHO OBJECT (MOBY) (FIND RLANDBIT) = V-WHO>
+<SYNTAX WHO OBJECT (MOBY) OBJECT (MOBY) = V-WHO>
+<SYNONYM WHO WHOM>
+
+<SYNTAX WHY OBJECT (MOBY) (FIND RLANDBIT) = V-WHY>
+<SYNTAX WHY OBJECT (MOBY) OBJECT (MOBY) = V-WHY>
+
+<SYNTAX WILL OBJECT (MOBY) ;(FIND RLANDBIT) = V-WILL?>
+<SYNTAX WOULD OBJECT (MOBY) ;(FIND RLANDBIT) = V-WOULD?>
+
+<DEFINE V-WHO ()
+       <COND (<PRSO? ,ROOMS>
+	      <MORE-SPECIFIC>)
+	     (<NOT ,PRSI>
+	      <TELL
+"You don't know anything special about " THE ,PRSO "." CR>)
+	     (ELSE <V-BE>)>>
+
+<DEFINE V-WHAT ()
+	<V-WHO>>
+
+<DEFINE PRE-WHERE ()
+ <COND (<AND <ZERO? ,PRSS> <ZERO? ,PRSQ>>
+	<PERFORM ,V?FIND ,PRSO ,PRSI>
+	<RTRUE>)>>
+
+<DEFINE V-WHERE ()
+	<COND (<PRSO? ,ROOMS>
+	       <MORE-SPECIFIC>)
+	      (ELSE <V-BE>)>>
+
+<DEFINE V-WHEN ()
+	<COND (<PRSO? ,ROOMS>
+	       <MORE-SPECIFIC>)
+	      (ELSE <V-BE>)>>
+
+<DEFINE V-WHY ()
+	<COND (<PRSO? ,ROOMS>
+	       <MORE-SPECIFIC>)
+	      (ELSE <V-BE>)>>
+
+<DEFINE V-HOW ()
+	<COND (<PRSO? ,ROOMS>
+	       <MORE-SPECIFIC>)
+	      (ELSE <V-BE>)>>
+
+<CONSTANT ADJ-TABLE
+	  <LTABLE <VOC "OUTSIDE" <> ;ADJ>
+		  OUTSIDE?
+		  ;<VOC "INSIDE" ADJ>
+		  ;INSIDE?
+		  <VOC "OPEN" ADJ>
+		  OPEN?
+		  <VOC "CLOSED" ADJ>
+		  Q-CLOSED?
+		  <VOC "LOCKED" ADJ>
+		  LOCKED?
+		  <VOC "UNLOCKED" ADJ>
+		  UNLOCKED?
+		  <VOC "DEAD" ADJ>
+		  DEAD?
+		  <VOC "ALIVE" ADJ>
+		  ALIVE?
+		  <VOC "QUIET" ADJ>
+		  QUIET?>>
+
+<DEFINE QUIET? (OBJ)
+	 <RTRUE>>
+
+<DEFINE OUTSIDE? (OBJ)
+	 <FSET? ,HERE ,OUTSIDE>>
+
+;<DEFINE INSIDE? (OBJ)
+	 <NOT <FSET? ,HERE ,OUTSIDE>>>
+
+<DEFINE OPEN? (OBJ)
+	 <AND <OR <FSET? .OBJ ,OPENABLE>
+		  <FSET? .OBJ ,DOORBIT>>
+	      <FSET? .OBJ ,OPENBIT>>>
+
+<DEFINE Q-CLOSED? (OBJ)
+	 <AND <OR <FSET? .OBJ ,OPENABLE>
+		  <FSET? .OBJ ,DOORBIT>>
+	      <NOT <FSET? .OBJ ,OPENBIT>>>>
+
+<DEFINE LOCKED? (OBJ)
+	 <AND <FSET? .OBJ ,DOORBIT>
+	      <FSET? .OBJ ,LOCKED>>>
+
+<DEFINE UNLOCKED? (OBJ)
+	 <AND <FSET? .OBJ ,DOORBIT>
+	      <NOT <FSET? .OBJ ,LOCKED>>>>
+
+<DEFINE DEAD? (OBJ)
+	 <OR <NOT <FSET? .OBJ ,PERSONBIT>>
+	     <FSET? .OBJ ,DEAD>>>
+
+<DEFINE ALIVE? (OBJ)
+	 <AND <FSET? .OBJ ,PERSONBIT>
+	      <NOT <FSET? .OBJ ,DEAD>>>>
+
+<DEFINE PRSO-IS (NOT? "OPT" (CAP? <>))
+	 <COND (<EQUAL? ,PRSO ,ME ,PLAYER>
+		<COND (.CAP? <TELL "You">)
+		      (ELSE <TELL " you">)>
+		<TELL " are">
+		<COND (.NOT? <TELL "n't">)>)
+	       (ELSE
+		<COND (.CAP? <TELL-CTHE ,PRSO>)
+		      (T <TELL " "> <TELL-THE ,PRSO>)>
+		<PRINT-IS/ARE ,PRSO>
+		<COND (.NOT? <TELL "n't">)>)>>
+
+<DEFAULT-DEFINITION PRINT-IS/ARE
+<DEFINE PRINT-IS/ARE (OBJ)
+	<COND (<OR <FSET? .OBJ ,PLURAL>
+		   <EQUAL? .OBJ ,BLACKTHORNE ,ME ,YOU>>
+	       <TELL " are">)
+	      (ELSE <TELL " is">)>>>
+
+<DEFINE IS-PRSO-ADJ? (ADJ "AUX" TMP)
+	 <COND (<AND <SET TMP <GETPT ,PRSO ,P?ADJECTIVE>>
+		     <INTBL? .ADJ .TMP </ <PTSIZE .TMP> 2>>>
+		<RTRUE>)
+	       (<AND <SET TMP <INTBL? .ADJ ,ADJ-TABLE <GET ,ADJ-TABLE 0>>>
+		     <APPLY <GET .TMP 1> ,PRSO>>
+		<RTRUE>)>>
+
+<DEFINE PP? (P N "AUX" (TMP <PARSE-LOC ,PARSE-RESULT>))
+	 <COND (<NOT .TMP> <RFALSE>)
+	       (<NOT <AND .P <EQUAL? .P <P-PP-PREP>>>>
+		<RFALSE>)
+	       (<NOT <AND .N <EQUAL? .N <P-PP-OBJ>>>>
+		<RFALSE>)
+	       (ELSE <RTRUE>)>>
+
+"does a bear shit in the woods?"
+
+"RLANDBIT would allow single-word sentence!"
+<SYNTAX CAN OBJECT (MOBY) ;(FIND RLANDBIT) = V-CAN?>
+<SYNTAX COULD OBJECT (MOBY) ;(FIND RLANDBIT) = V-COULD?>
+<SYNTAX DO OBJECT (MOBY) ;(FIND RLANDBIT) = V-DO?>
+<SYNTAX MAY OBJECT (MOBY) ;(FIND RLANDBIT) = V-MAY?>
+<SYNTAX MIGHT OBJECT (MOBY) ;(FIND RLANDBIT) = V-MIGHT?>
+<SYNTAX MUST OBJECT (MOBY) ;(FIND RLANDBIT) = V-MUST?>
+<SYNTAX SHOULD OBJECT (MOBY) ;(FIND RLANDBIT) = V-SHOULD?>
+
+<DEFINE V-STATEMENT () <V-DO?>>
+
+<CONSTANT WHO-KNOWS-STRING "It's not easy to tell "
+			   ;"The \"narrator\" can't tell you ">
+
+<DEFINE WHO-KNOWS ("OPT" (WD <PARSE-QUERY ,PARSE-RESULT>) "AUX" OBJ SUBJ)
+ <COND (<AND <EQUAL? <PARSE-QW ,PARSE-RESULT> ,W?WHO ,W?WHAT>
+	     <SET OBJ <VERB-ONE <WORD-VERB-STUFF ,P-PRSA-WORD>>>
+	     <GET-SYNTAX .OBJ 1 0 T>
+	     <SET OBJ <DETERMINE-OBJ <> 1 T>>
+	     <SET OBJ <NOUN-PHRASE-OBJ1 .OBJ>>>
+	<TELL "Perhaps">)
+       (T
+	<SET OBJ <>>
+	<PRINT ,WHO-KNOWS-STRING>
+	<TELL-Q-WORD>)>
+ <SET SUBJ <PARSE-SUBJ ,PARSE-RESULT>>
+ <COND (<T? .SUBJ>
+	<SET SUBJ <NOUN-PHRASE-OBJ1 .SUBJ>>)
+       (<NOT <EQUAL? ,PRSO <> ,ROOMS>>
+	<SET SUBJ ,PRSO>)
+       (T
+	<TELL "." CR>
+	<RTRUE>)>
+ <TELL " ">
+ <COND (<EQUAL? .SUBJ ,ME ,PLAYER>
+	<TELL "you">)
+       (ELSE
+	<TELL-THE .SUBJ>)>
+ <COND (<T? .WD>
+	<COND (<OR <NOT <EQUAL? .WD ,W?DO ,W?DOES ,W?DID>>
+		   <NOT <PARSE-SUBJ ,PARSE-RESULT>>>
+	       <TELL " ">
+	       <PRINTB .WD>)>)>
+ <COND (<T? <PARSE-SUBJ ,PARSE-RESULT>>
+	<TELL " ">
+	;<PRINT-VOCAB-WORD ,P-PRSA-WORD>
+	<COND (<T? .WD>
+	       <COND (<EQUAL? .WD ,W?DID>
+		      ;<BAND ,PAST-TENSE <WORD-FLAGS .WD>>
+		      ;"Look for past-tense form in vocabulary:"
+		      <PROG ((V <ZREST ,VOCAB <+ 1 <GETB ,VOCAB 0>>>)
+			     (M <BOR *200* <GETB .V 0>>) N)
+			<COND (<EQUAL? ,P-PRSA-WORD ,W?GET>
+			       <TELL "got">)
+			      (<AND <SET N <INTBL? ,P-PRSA-WORD <ZREST .V 9 ;3>
+						   <ZGET <ZREST .V 1> 0> .M>>
+				    <BTST <ZGET .N 1> ,PAST-TENSE>>
+			       <PRINT-VOCAB-WORD .N>)
+			      (T
+			       <PRINT-VOCAB-WORD ,P-PRSA-WORD>
+			       <TELL "ed">)>>)
+		     (T
+		      <PRINT-VOCAB-WORD ,P-PRSA-WORD>
+		      <COND (<AND <EQUAL? .WD ,W?DO ,W?DOES>
+				  <NOT <EQUAL? .SUBJ ,ME ,PLAYER>>
+				  <NOT <FSET? .SUBJ ,PLURAL>>>
+			     <TELL "s">)>)>
+	       <COND (<T? .OBJ>
+		      <TELL " ">
+		      <COND (<EQUAL? .OBJ .SUBJ>
+			     <COND (<NOT <FSET? .OBJ ,PERSONBIT>>
+				    <TELL "it">)
+				   (<FSET? .OBJ ,FEMALE>
+				    <TELL "her">)
+				   (T
+				    <TELL "him">)>
+			     <TELL "self">)
+			    (T
+			     <TELL-THE .OBJ>)>)
+		     (T
+		      <ECHO-NOUNS>)>)
+	      (T <PRINT-VOCAB-WORD ,P-PRSA-WORD>)>)>
+ <TELL "." CR>>
+
+<DEFINE ECHO-NOUNS ("AUX" WD)
+ <COND (<NOT <EQUAL? ,PRSO 0 ,WHAT ,NOT-HERE-OBJECT>>
+	<COND (<SET WD <PARSE-PARTICLE1 ,PARSE-RESULT>>
+	       <TELL " ">
+	       <PRINTB .WD>)>
+	<TELL " ">
+	<TELL-THE ,PRSO>)>
+ <COND (<NOT <EQUAL? ,PRSI 0 ,WHAT ,NOT-HERE-OBJECT>>
+	<COND (<SET WD <PARSE-PARTICLE2 ,PARSE-RESULT>>
+	       <TELL " ">
+	       <PRINTB .WD>)>
+	<TELL " ">
+	<TELL-THE ,PRSI>)>>
+
+<DEFINE V-CAN? () <WHO-KNOWS ,W?CAN>>
+
+<DEFINE V-MAY? () <WHO-KNOWS ,W?MAY>>
+
+<DEFINE V-DO? ()
+ <COND (<TRY-QCONTEXT?>
+	<RTRUE>)
+       (<NOT <BTST <PARSE-FLAGS ,PARSE-RESULT> ,PARSE-QUESTION>>
+	<COND (<NOT ,PRSS>
+	       <MORE-SPECIFIC>
+	       <RTRUE>)
+	      (ELSE
+	       <TELL "So you think">
+	       <COND (<EQUAL? ,PRSS ,ME ,PLAYER>
+		      <TELL " you ">
+		      <COND (<ANDB ,PARSE-NOT <PARSE-FLAGS ,PARSE-RESULT>>
+			     <TELL "don't ">)>)
+		     (T
+		      <COND ;(.CAP? <TELL-CTHE ,PRSS>)
+			    (T <TELL " "> <TELL-THE ,PRSS> <TELL " ">)>
+		      <COND (<ANDB ,PARSE-NOT <PARSE-FLAGS ,PARSE-RESULT>>
+			     <TELL "doesn't ">)>)>
+	       <PRINT-VOCAB-WORD ,P-PRSA-WORD>
+	       <ECHO-NOUNS>
+	       <TELL "." CR>)>)
+       (T
+	<WHO-KNOWS ;<COND ;(<BAND ,PAST-TENSE <PARSE-FLAGS ,PARSE-RESULT>>
+			  ,W?DID)
+			 (T ,W?DOES)>>)>>
+
+<DEFINE V-COULD? () <WHO-KNOWS ,W?COULD>>
+
+<DEFINE V-WOULD? () <WHO-KNOWS ,W?WOULD>>
+
+<DEFINE V-SHOULD? () <WHO-KNOWS ,W?SHOULD>>
+
+<DEFINE V-MIGHT? () <WHO-KNOWS ,W?MIGHT>>
+
+<DEFINE V-WILL? () <WHO-KNOWS ,W?WILL>>
+
+<DEFINE V-MUST? () <WHO-KNOWS ,W?MUST>>
+
+<DEFINE QUESTION-VERB? ("AUX" TMP) ;"add more later..."
+    <OR <EQUAL? <SET TMP <PARSE-QW ,PARSE-RESULT>>
+		,W?WHO ,W?WHAT ,W?WHERE ,W?WHY ,W?WHEN ,W?HOW>
+	<VERB? BE? CAN? COULD? DO? MAY? MIGHT? MUST? SHOULD? WILL? WOULD?>>>
+
+"PERFORM uses two additional GLOBALs, 'q-verb' and subject, each of
+which can be false. Examples:
+
+	'IS THE POPE CATHOLIC'
+	becomes
+	<SETG PRSQ T>
+	<PERFORM ,V?BE ,POPE ,INTADJ ;T>
+
+	'DOES THE GOVERNMENT TAKE MONEY FROM ME'
+	becomes
+	<SETG PRSQ ,V?DO>
+	<SETG PRSS ,GOVERNMENT>
+	<PERFORM ,V?TAKE ,MONEY ,ME>
+
+	'WHY DOES THE GOVERNMENT TAKE MONEY FROM ME'
+	becomes
+	<SETG PRSQ ,V?WHY>
+	<SETG PRSS ,GOVERNMENT>
+	<PERFORM ,V?TAKE ,MONEY ,ME>
+
+When PERFORM notices the presence of a q-verb, it calls action routines
+in this order:
+	WINNER
+	SUBJECT
+	; M-BEG
+	Q-PREACTION (from the following table)
+	; OBJECT #2
+	; OBJECT #1
+	Q-ACTION (ditto) or V-STATEMENT
+
+PERFORM also handles statements, for example:
+
+	'MY NAME IS ARTHUR DENT'
+	becomes
+	<PERFORM ,V?IS ,NAME ,ARTHUR>
+"
+
+<CONSTANT QACTIONS <PLTABLE
+	V-BE V-BE? 0
+	V-DISEMBARK V-DISEMBARK? 0
+	V-DROP V-DROP? PRE-DROP?
+	V-TAKE V-TAKE? PRE-TAKE?
+	;"and so on">>
+
+<DEFINE PRE-DROP? ()
+	 <COND (<EQUAL? ,PRSO <LOC ,PRSS>>
+		;<SETG PRSQ ,V?DISEMBARK>
+		<PERFORM ,V?DISEMBARK ;,PRSA ,PRSO ,PRSI ;,V?DISEMBARK ;,PRSS>
+		<RTRUE>)>>
+
+<DEFINE V-DROP? ()
+	 <COND (<EQUAL? ,PRSO ,ROOMS>
+		<PRINT "You aren't ">
+		<TELL "hanging from anything." CR>)>>
+
+<DEFINE V-DISEMBARK? ("AUX" AV)
+	 <SET AV <LOC ,PRSS>>
+	 <COND (<EQUAL? ,PRSO <> ,ROOMS>
+		<COND (<AND .AV <NOT <IN? .AV ,ROOMS>>>
+		       <PERFORM ,PRSA .AV ,PRSI ;,PRSQ ;,PRSS>
+		       <RTRUE>)
+		      (ELSE
+		       <PRINT "You aren't ">
+		       <TELL "in anything." CR>)>)
+	       (<AND .AV <NOT <IN? .AV ,ROOMS>>>
+		<COND (<AND <NOT <EQUAL? .AV ,PRSO>>
+			    <NOT <HELD? .AV ,PRSO>>>
+		       <PRINT "You already are">
+		       <COND (<FSET? .AV ,SURFACEBIT> <TELL " on ">)
+			     (ELSE <TELL " in ">)>
+		       <TELL-THE .AV>
+		       <TELL "!" CR>
+		       <RTRUE>)>)
+	       (<LOC ,PRSO>
+		;<SETG PRSQ ,V?TAKE>
+		<PERFORM ,V?TAKE ;,PRSA ,PRSO ,PRSI ;,V?TAKE ;,PRSS>
+		<RTRUE>)
+	       (ELSE
+		<PRINT "It's not in anything.">
+		<CRLF>)>>
+
+<DEFINE PRE-TAKE? ()
+	<COND (<NOT ,PRSI>
+	       <PRE-TAKE>)>>
+
+<DEFINE V-TAKE? ()
+	<COND (<ZERO? <PARSE-QW ,PARSE-RESULT>>
+	       <TELL "Seems reasonable." CR>)>>
+
+<END-SEGMENT>
diff --git a/record.zil b/record.zil
new file mode 100644
index 0000000..04578cf
--- /dev/null
+++ b/record.zil
@@ -0,0 +1,277 @@
+"RECORD for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc. All Rights Reserved."
+
+<BEGIN-SEGMENT RECORD>
+
+<SYNTAX \#RANDOM OBJECT = V-$RANDOM>
+<SYNTAX \#COMMAND = V-$COMMAND>
+<SYNTAX \#RECORD = V-$RECORD>
+<SYNTAX \#UNRECORD = V-$UNRECORD>
+
+<ROUTINE V-$COMMAND ()
+	 <DIRIN ,D-COMMAND-FILE>
+	 <RTRUE>>
+
+<ROUTINE V-$RANDOM ()
+	 <COND (<NOT <PRSO? ,INTNUM>>
+		<TELL "Illegal call to #RANDOM." CR>)
+	       (T
+		<RANDOM <- 0 ,P-NUMBER>>
+		<RTRUE>)>>
+
+<ROUTINE V-$RECORD ()
+	 <DIROUT ,D-RECORD-ON> ;"all READS and INPUTS get sent to command file"
+	 <RTRUE>>
+
+<ROUTINE V-$UNRECORD ()
+	 <DIROUT ,D-RECORD-OFF>
+	 <RTRUE>>
+
+
+"debugging help"
+
+;<SYNTAX $P OBJECT = V-$P>
+
+;<ROUTINE V-$P ()
+	 <COND (<PICINF ,P-NUMBER ,YX-TBL>
+		<TELL N <GET ,YX-TBL 0> "x" N <GET ,YX-TBL 1> CR>)
+	       (ELSE <TELL "No such picture." CR>)>>
+
+;<SYNTAX $D OBJECT = V-$D>
+
+;<ROUTINE V-$D ()
+	 <COND (<PICINF ,P-NUMBER ,YX-TBL>
+		<RESET-MARGIN>
+		<CLEAR ,S-TEXT>
+		<CENTER-PIC ,P-NUMBER>
+		<INPUT 1>)
+	       (ELSE <TELL "No such picture." CR>)>>
+
+;<SYNTAX $W OBJECT = V-$W>
+
+;<ROUTINE V-$W ("AUX" WIN ATTRS TMP)
+	 <SET WIN ,P-NUMBER>
+	 <TELL "#" N .WIN
+	       " at " N <WINGET .WIN ,WTOP>
+	       "," N <WINGET .WIN ,WLEFT>
+	       "; size " N <WINGET .WIN ,WHIGH>
+	       "x" N <WINGET .WIN ,WWIDE>>
+	 <COND (<OR <NOT <ZERO? <WINGET .WIN ,WLMARGIN>>>
+		    <NOT <ZERO? <WINGET .WIN ,WRMARGIN>>>>
+		<TELL " (" N <WINGET .WIN ,WLMARGIN>
+		      "<->" N <WINGET .WIN ,WRMARGIN> ")">)>
+	 <COND (<NOT <ZERO? <SET TMP <WINGET .WIN ,WHLIGHT>>>>
+		<TELL "; HL=" N .TMP>)>
+	 <COND (<NOT <EQUAL? <SET TMP <WINGET .WIN ,WCOLOR>> 257>>
+		<TELL "; f,b=" N <LOW-BYTE .TMP> "," N <HIGH-BYTE .TMP>>)>
+	 <COND (<NOT <EQUAL? <SET TMP <WINGET .WIN ,WFONT>> 0>>
+		<TELL "; F=" N .TMP>)>
+	 <SET TMP <WINGET .WIN ,WFSIZE>>
+	 <COND (<OR <EQUAL? .WIN ,S-FULL>
+		    <NOT <EQUAL? <HIGH-BYTE .TMP> ,FONT-Y>>
+		    <NOT <EQUAL? <LOW-BYTE .TMP> ,FONT-X>>>
+		<TELL "; FS=" N <HIGH-BYTE .TMP> "x" N <HIGH-BYTE .TMP>>)>
+	 <TELL "; cursor " N <WINGET .WIN ,WYPOS>
+	       "," N <WINGET .WIN ,WXPOS>
+	       "; line " N <WINGET .WIN ,WLCNT>
+	       "; ">
+	 <COND (<AND <NOT <ZERO? <SET TMP <WINGET .WIN ,WCRCNT>>>>
+		     <NOT <ZERO? <WINGET .WIN ,WCRFUNC>>>>
+		<TELL " CR=" N .TMP>)>
+	 <SET ATTRS <WINGET .WIN ,WATTRS>>
+	 <COND (<ZERO? <BAND .ATTRS ,A-WRAP>> <TELL "-">)
+	       (ELSE <TELL "+">)>
+	 <TELL "W,">
+	 <COND (<ZERO? <BAND .ATTRS ,A-SCROLL>> <TELL "-">)
+	       (ELSE <TELL "+">)>
+	 <TELL "S,">
+	 <COND (<ZERO? <BAND .ATTRS ,A-SCRIPT>> <TELL "-">)
+	       (ELSE <TELL "+">)>
+	 <TELL "P,">
+	 <COND (<ZERO? <BAND .ATTRS ,A-BUFFER>> <TELL "-">)
+	       (ELSE <TELL "+">)>
+	 <TELL "B">
+	 <CRLF>>
+
+;<DEFMAC TELLBIT ('BIT)
+	<FORM COND (<FORM FSET? ',PRSO <CHTYPE .BIT GVAL>>
+		    <FORM TELL <STRING " " <SPNAME .BIT>>>)>>
+
+;<SYNTAX $X OBJECT (MOBY) = V-$X>
+
+;<ROUTINE V-$X ("AUX" TMP)
+	 <COND (<PRSO? INTNUM>
+		<TELL N ,P-NUMBER "/ " N <GETB ,P-NUMBER 0>>)
+	       (ELSE <TELL "??">)>
+	 <CRLF>>
+
+;<SYNTAX $G OBJECT (MOBY) = V-$G PRE-$G>
+
+;<ROUTINE PRE-$G ("AUX" TMP)
+	 <COND (<AND <PRSO? INTNUM>
+		     <G? ,P-NUMBER 15>
+		     <L? ,P-NUMBER 256>>
+		<TELL "Global " N ,P-NUMBER "/ " N <VALUE ,P-NUMBER>>)
+	       (ELSE <TELL "??">)>
+	 <CRLF>>
+
+;<ROUTINE V-$G () <RTRUE>>
+
+;<SYNTAX $I OBJECT (MOBY) = V-$I PRE-$I>
+
+;<ROUTINE PRE-$I ("AUX" TMP)
+	 <COND (<PRSO? INTNUM> <SETG PRSO ,P-NUMBER>)> 
+	 <TELL-OBJ ,PRSO>
+	 <TELL "; in ">
+	 <COND (<SET TMP <LOC ,PRSO>>
+		<TELL-OBJ .TMP>)
+	       (ELSE <TELL "limbo">)>
+	 <COND (<FIRST? ,PRSO>
+		<TELL "; contains">
+		<REPEAT ((F <FIRST? ,PRSO>))
+			<TELL " ">
+			<TELL-OBJ .F>
+			<COND (<NOT <SET F <NEXT? .F>>>
+			       <RETURN>)>>)>
+	 <TELL "; flags">
+	 <TELLBIT AN>
+	 <TELLBIT BODY-PART>
+	 <TELLBIT CANT-HOLD>
+	 <TELLBIT CONTBIT>
+	 <TELLBIT DEAD>
+	 <TELLBIT DONT-ALL>
+	 <TELLBIT DONT-IT>
+	 <TELLBIT DOORBIT>
+	 <TELLBIT DUTCHBIT>
+	 <TELLBIT ENGLISHBIT>
+	 <TELLBIT FEMALE>
+	 <TELLBIT FOODBIT>
+	 <TELLBIT FURNITURE>
+	 <TELLBIT INVISIBLE>
+	 <TELLBIT JAPANESEBIT>
+	 <TELLBIT LIGHTBIT>
+	 <TELLBIT LOCKABLE>
+	 <TELLBIT LOCKED>
+	 <TELLBIT NDESCBIT>
+	 <TELLBIT NOABIT>
+	 <TELLBIT NOTHEBIT>
+	 <TELLBIT ONBIT>
+	 <TELLBIT OPENABLE>
+	 <TELLBIT OPENBIT>
+	 <TELLBIT OUTSIDE>
+	 <TELLBIT PERSON>
+	 <TELLBIT PLURAL>
+	 <TELLBIT PORTUGUESEBIT>
+	 <TELLBIT READBIT>
+	 <TELLBIT RLANDBIT>
+	 <TELLBIT RMUNGBIT>
+	 <TELLBIT SCOREBIT>
+	 <TELLBIT SEARCHBIT>
+	 <TELLBIT SITTING>
+	 <TELLBIT SPANISHBIT>
+	 <TELLBIT SURFACEBIT>
+	 <TELLBIT TAKEBIT>
+	 <TELLBIT THE>
+	 <TELLBIT TOOLBIT>
+	 <TELLBIT TOUCHBIT>
+	 <TELLBIT TRANSBIT>
+	 <TELLBIT TRYTAKEBIT>
+	 <TELLBIT VEHBIT>
+	 <TELLBIT WEAPONBIT>
+	 <TELLBIT WEARABLE>
+	 <TELLBIT WEARBIT>
+	 <TELL ";">
+	 <REPEAT ((P 0))
+		 <COND (<ZERO? <SET P <NEXTP ,PRSO .P>>> <RETURN>)
+		       (ELSE
+			<TELL " ">
+			<TELLPROP .P>
+			<TELL "(" N <PTSIZE <GETPT ,PRSO .P>> ")">)>>
+	 <CRLF>>
+
+;<ROUTINE V-$I () <RTRUE>>
+
+;<ROUTINE TELL-OBJ (TMP)
+	 <TELL N .TMP ":\"">
+	 <COND (<EQUAL? .TMP ,ROOMS>
+		<TELL "ROOMS">)
+	       (<EQUAL? .TMP ,GLOBAL-OBJECTS>
+		<TELL "GLOBAL-OBJECTS">)
+	       (<EQUAL? .TMP ,LOCAL-GLOBALS>
+		<TELL "LOCAL-GLOBALS">)
+	       (<EQUAL? .TMP ,GENERIC-OBJECTS>
+		<TELL "GENERIC-OBJECTS">)
+	       (ELSE <TELL D .TMP>)>
+	 <TELL "\"">>
+
+;<ROUTINE TELLPROP (P)
+	 <COND (<EQUAL? .P ,P?NORTH> <TELL "NORTH">) ;63
+	       (<EQUAL? .P ,P?NE> <TELL "NE">) ;62
+	       (<EQUAL? .P ,P?EAST> <TELL "EAST">) ;61
+	       (<EQUAL? .P ,P?SE> <TELL "SE">) ;60
+	       (<EQUAL? .P ,P?SOUTH> <TELL "SOUTH">) ;59
+	       (<EQUAL? .P ,P?SW> <TELL "SW">) ;58
+	       (<EQUAL? .P ,P?WEST> <TELL "WEST">) ;57
+	       (<EQUAL? .P ,P?NW> <TELL "NW">) ;56
+	       (<EQUAL? .P ,P?UP> <TELL "UP">) ;55
+	       (<EQUAL? .P ,P?DOWN> <TELL "DOWN">) ;54
+	       (<EQUAL? .P ,P?IN> <TELL "IN">) ;53
+	       (<EQUAL? .P ,P?OUT> <TELL "OUT">) ;52
+	       (<EQUAL? .P ,P?FORE> <TELL "FORE">) ;51
+	       (<EQUAL? .P ,P?AFT> <TELL "AFT">) ;50
+	       (<EQUAL? .P ,P?PORT> <TELL "PORT">) ;49
+	       (<EQUAL? .P ,P?STARBOARD> <TELL "STARBOARD">) ;48
+	       (<EQUAL? .P ,P?ACTION> <TELL "ACTION">) ;47
+	       (<EQUAL? .P ,P?ADJACENT> <TELL "ADJACENT">) ;46
+	       (<EQUAL? .P ,P?SYNONYM> <TELL "SYNONYM">) ;45
+	       (<EQUAL? .P ,P?CONTFCN> <TELL "CONTFCN">) ;44
+	       (<EQUAL? .P ,P?THINGS> <TELL "THINGS">) ;43
+	       (<EQUAL? .P ,P?DESCFCN> <TELL "DESCFCN">) ;42
+	       (<EQUAL? .P ,P?GLOBAL> <TELL "GLOBAL">) ;41
+	       (<EQUAL? .P ,P?FDESC> <TELL "FDESC">) ;40
+	       (<EQUAL? .P ,P?LDESC> <TELL "LDESC">) ;39
+	       (<EQUAL? .P ,P?COUNT> <TELL "COUNT">) ;38
+	       (<EQUAL? .P ,P?SIZE> <TELL "SIZE">) ;37
+	       (<EQUAL? .P ,P?TEXT> <TELL "TEXT">) ;36
+	       (<EQUAL? .P ,P?VALUE> <TELL "VALUE">) ;35
+	       (<EQUAL? .P ,P?CAPACITY> <TELL "CAPACITY">) ;34
+	       (<EQUAL? .P ,P?ADJECTIVE> <TELL "ADJECTIVE">) ;33
+	       (<EQUAL? .P ,P?OWNER> <TELL "OWNER">) ;32
+	       (<EQUAL? .P ,P?GENERIC> <TELL "GENERIC">) ;31
+	       (<EQUAL? .P ,P?HEALTH> <TELL "HEALTH">) ;30
+	       (<EQUAL? .P ,P?PICTURE> <TELL "PICTURE">) ;29
+	       (<EQUAL? .P ,P?SCENE> <TELL "SCENE">) ;28
+	       (<EQUAL? .P ,P?SDESC> <TELL "SDESC">) ;27
+	       (<EQUAL? .P ,P?SCORE> <TELL "SCORE">) ;26
+	       (<EQUAL? .P ,P?MOUSE> <TELL "MOUSE">) ;25
+	       (<EQUAL? .P ,P?AFTER> <TELL "AFTER">) ;24
+	       (ELSE <TELL N .P>)>>
+
+;<SYNTAX $M = V-$M>
+
+;<ROUTINE V-$M ("AUX" S (X 0) (Y 0))
+	 <REPEAT ((N <GET ,SCENE-LOCS 0>) (CNT 0))
+		 <COND (<G? <SET CNT <+ .CNT 1>> .N> <RETURN>)
+		       (ELSE
+			<SET S <GETPT <GET ,SCENE-LOCS .CNT> ,P?SCORE>>
+			<PRINT <GET ,SCENE-NAMES .CNT>>
+			<SET X <+ .X <GETB .S 0>>>
+			<SET Y <+ .Y <GETB .S 1>>>
+			<TELL ": "
+			      N <* ,SCORE-FACTOR <GETB .S 0>>
+			      "/"
+			      N <* ,SCORE-FACTOR <GETB .S 1>>
+			      CR>)>>
+	 <TELL "Total: " N <* ,SCORE-FACTOR .X>
+	       "/"
+	       N <* ,SCORE-FACTOR .Y>
+	       CR CR
+	       "Missing">
+	 <REPEAT ((CNT 0))
+		 <COND (<G? <SET CNT <+ .CNT 1>> ,LAST-OBJECT> <RETURN>)
+		       (<FSET? .CNT ,SCOREBIT>
+			<TELL ", " D .CNT>)>>
+	 <CRLF>>
+
+<END-SEGMENT>
diff --git a/status.zil b/status.zil
new file mode 100644
index 0000000..5fee70e
--- /dev/null
+++ b/status.zil
@@ -0,0 +1,156 @@
+"STATUS for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc. All Rights Reserved."
+
+<BEGIN-SEGMENT 0>
+
+<CONSTANT S-STATUS 1>
+<CONSTANT STATUS-LINES 2>
+
+<ROUTINE SETUP-TEXT-AND-STATUS ("OPT" (P ,P-BORDER-LOC)
+				"AUX" X (HIGH <LOWCORE VWRD>)
+				(WIDE <LOWCORE HWRD>) (SLEFT 1)
+				(SHIGH <* ,STATUS-LINES ,FONT-Y>))
+	 <COND (<NOT <APPLE?>> ;"only apples have no borders"
+		<PICINF .P ,YX-TBL>
+		<SET X <GET ,YX-TBL 1>>
+		<SET SLEFT <+ .X .SLEFT>>
+		<COND (<NOT <EQUAL? .P ,P-BORDER-LOC>>
+		       <SET SHIGH <GET ,YX-TBL 0>>)>
+		<SET WIDE <- .WIDE <* .X 2>>>)>
+	 <WINDEF ,S-STATUS 1 .SLEFT .SHIGH .WIDE>
+	 <WINDEF ,S-TEXT
+		 <+ 1 .SHIGH> .SLEFT
+		 <- .HIGH .SHIGH> .WIDE>>
+
+<ROUTINE INIT-STATUS-LINE ("OPT" (NO-STS? <>))
+	 <RESET-MARGIN>
+	 <CLEAR ,S-TEXT>
+	 <COND (<NOT .NO-STS?> <SETUP-TEXT-AND-STATUS>)>
+	 <SCREEN ,S-STATUS>
+	 <DIROUT ,D-TABLE-ON ,DIROUT-TABLE>
+	 <PRINTI "0">
+	 <DIROUT ,D-TABLE-OFF>
+	 <SETG SCORE-WIDTH <LOWCORE TWID>>
+	 <COLOR ,BG-COLOR ,FG-COLOR>
+	 <CLEAR ,S-STATUS>
+	 <UPDATE-STATUS-LINE T>>
+
+<GLOBAL SCORE-WIDTH 0>
+
+<GLOBAL SHERE <>>
+
+<ROUTINE UPDATE-STATUS-LINE ("OPT" (REF? <>) "AUX" WIDE TMP)
+	 <COND (<FLAG-ON? ,F-REFRESH>
+		<DISPLAY-BORDER>)>
+	 <COND (<OR <FLAG-ON? ,F-REFRESH>
+		    <NOT <EQUAL? ,HERE ,SHERE>>>
+		<SET REF? T>)>
+	 <COND (<OR .REF?
+		    <NOT <EQUAL? ,SCORE ,OSCORE>>
+		    <NOT <EQUAL? ,MOVES ,OMOVES>>> 
+		<SCREEN ,S-STATUS>
+		<COLOR ,BG-COLOR ,FG-COLOR>
+		<SET WIDE </ <WINGET ,S-STATUS ,WWIDE> ,FONT-X>>
+		<COND (.REF?
+		       <CURSET 1 1>
+		       <ERASE 1>
+		       <COND (,SCENE
+			      <CURSET 1 1>
+			      <PRINT <GET ,SCENE-NAMES ,SCENE>>
+			      <TELL ":">)>
+		       <COND (<NOT <EQUAL? ,MACHINE
+					   ,DEBUGGING-ZIP ,MACINTOSH>>
+			      <CURSET 1
+				      <- </ <WINGET ,S-STATUS ,WWIDE> 2>
+					 <* ,SCORE-WIDTH 3>>>
+			      <TELL "SHOGUN">)>
+		       <LOWCORE FLAGS
+				<BAND <LOWCORE FLAGS> <BCOM ,F-REFRESH>>>)>
+		<COND (<OR .REF?
+			   <AND <SCENE? ,S-ERASMUS>
+				<HERE? ,BRIDGE-OF-ERASMUS>>
+			   <AND <SCENE? ,S-VOYAGE>
+				<HERE? ,GALLEY>>>
+		       <COND (.REF?
+			      <CCURSET 2 1>
+			      <ERASE 1>)>
+		       <COND (,HERE
+			      <CCURSET 2 1>
+			      <SETG SHERE ,HERE>
+			      <TELL 'HERE>
+			      <SET TMP <LOC ,WINNER>>
+			      <COND (<FSET? .TMP ,VEHBIT>
+				     <SETG SHERE .TMP>
+				     <COND (<FSET? .TMP ,SURFACEBIT>
+					    <TELL ", on ">)
+					   (ELSE
+					    <TELL ", in ">)>
+				     <TELL THE .TMP>)>
+			      <COND (<HERE? ,BRIDGE-OF-ERASMUS ,GALLEY>
+				     <ERASE-ALL-BUT 12>
+				     <COND (<OR <AND <HERE? ,BRIDGE-OF-ERASMUS>
+						     <FSET? ,WHEEL ,ONBIT>>
+						<AND <HERE? ,GALLEY>
+						     <FSET? ,GALLEY-WHEEL ,ONBIT>>>
+					    <TELL "; course ">
+					    <TELL-DIRECTION ,SHIP-DIRECTION>
+					    <TELL "; wheel ">
+					    <TELL-DIRECTION ,SHIP-COURSE>)>)>)>)>
+		<COND (<OR .REF? <NOT <EQUAL? ,SCORE ,OSCORE>>>
+		       <COND (.REF?
+			      <CCURSET 1 <- .WIDE 10>>
+			      <TELL "Score:">
+			      <ERASE 1>)>
+		       <SET TMP <* ,SCORE ,SCORE-FACTOR>>
+		       <RJNUM .TMP 1>
+		       <SETG OSCORE ,SCORE>)>
+		<COND (<OR .REF? <NOT <EQUAL? ,MOVES ,OMOVES>>>
+		       <COND (.REF?
+			      <CCURSET 2 <- .WIDE 10>>
+			      <TELL "Moves:">
+			      <ERASE 1>)>
+		       <RJNUM ,MOVES 2>
+		       <SETG OMOVES ,MOVES>)>
+		<SCREEN ,S-TEXT>)>>
+
+<ROUTINE ERASE-ALL-BUT (N)
+	 <ERASE <- <WINGET ,S-STATUS ,WWIDE>
+		   <WINGET ,S-STATUS ,WXPOS>
+		   <* .N ,FONT-X>>>>
+
+<ROUTINE INTERLUDE-STATUS-LINE ()
+	 <DISPLAY-BORDER ,P-BORDER2>
+	 <SETG SHERE <>>
+	 <SCREEN ,S-STATUS>
+	 <COLOR ,BG-COLOR ,FG-COLOR>
+	 <CURSET 1 1>
+	 <ERASE-ALL-BUT 12>
+	 <CURSET 1 1>
+	 <PRINT <GET ,SCENE-NAMES ,SCENE>>
+	 <TELL ":">
+	 <COND (<NOT <EQUAL? ,MACHINE ,DEBUGGING-ZIP ,MACINTOSH>>
+		<CURSET 1
+			<- </ <WINGET ,S-STATUS ,WWIDE> 2>
+			   <* ,SCORE-WIDTH 3>>>
+		<TELL "SHOGUN">)>
+	 <LOWCORE FLAGS <BAND <LOWCORE FLAGS> <BCOM ,F-REFRESH>>>
+	 <CCURSET 2 1>
+	 <ERASE-ALL-BUT 12>
+	 <CCURSET 2 1>
+	 <TELL "Interlude">
+	 <SCREEN ,S-TEXT>>
+
+<ROUTINE RJNUM (NUM LINE "AUX" (WIDE <WINGET ,S-STATUS ,WWIDE>) (N <>))
+	 <SET LINE <+ 1 <* <- .LINE 1> ,FONT-Y>>>
+	 <COND (<L? .NUM 10> <SET N 1>)
+	       (<L? .NUM 100> <SET N 2>)
+	       (<L? .NUM 1000> <SET N 3>)
+	       (<L? .NUM 10000> <SET N 4>)>
+	 <CURSET .LINE <- .WIDE <* ,SCORE-WIDTH 4>>>
+	 <ERASE 1>
+	 <CURSET .LINE <- .WIDE <* ,SCORE-WIDTH .N>>>
+	 <COND (.N <TELL N .NUM>)
+	       (ELSE <TELL "****">)>>
+
+<END-SEGMENT>
diff --git a/syntax.zil b/syntax.zil
new file mode 100644
index 0000000..8290422
--- /dev/null
+++ b/syntax.zil
@@ -0,0 +1,1176 @@
+"SYNTAX for
+				 SHOGUN
+	 (c) Copyright 1988 Infocom, Inc. All Rights Reserved."
+
+;"buzzwords"
+
+;<BUZZ THE OF THEN \. \, \">
+
+;<BUZZ A AN AND ALL ONE BUT EXCEPT AGAIN G OOPS O>
+
+;"synonyms for prepositions"
+
+<SYNONYM WITH USING>
+<SYNONYM THROUGH THRU>
+<SYNONYM ON ONTO>
+;<SYNONYM IN INSIDE>
+;<PREP-SYNONYM IN INSIDE INTO>
+<SYNONYM IN INSIDE INTO>
+<SYNONYM UNDER BELOW BENEATH UNDERNEATH>
+<SYNONYM AROUND ALONG>
+<SYNONYM TOWARD TOWARDS>
+
+<SYNONYM ALL BOTH EVERYTHING>
+<SYNONYM MY MINE>
+
+<SYNONYM GRAY GREY>
+
+\
+
+;"game commands"
+
+<SYNTAX $SCENE OBJECT = V-$SCENE>
+
+<SYNTAX $REFRESH = V-$REFRESH>
+<VERB-SYNONYM $REFRESH REFRESH>
+
+<SYNTAX $VERIFY = V-$VERIFY>
+<SYNTAX $VERIFY OBJECT = V-$VERIFY>
+
+<SYNTAX BRIEF = V-BRIEF>
+
+<SYNTAX CHOOSE = V-CHOOSE>
+<SYNTAX CHOOSE OBJECT = V-PICK>
+
+<SYNTAX COMMIT OBJECT = V-COMMIT>
+<VERB-SYNONYM COMMIT PERFORM>
+
+<SYNTAX CREDITS = V-CREDITS>
+
+<SYNTAX DIAGNOSE = V-DIAGNOSE>
+
+<SYNTAX HINT = V-HINT>
+<SYNTAX HINTS OFF OBJECT (FIND RLANDBIT) = V-HINTS-OFF>
+
+<SYNTAX I = V-INVENTORY>
+<VERB-SYNONYM I INVENTORY>
+
+<SYNTAX NOTIFY = V-NOTIFY>
+
+<SYNTAX QUIT = V-QUIT>
+<VERB-SYNONYM QUIT Q>
+
+<SYNTAX RESTART = V-RESTART>
+
+<SYNTAX RESTORE = V-RESTORE>
+
+<SYNTAX SAVE = V-SAVE>
+<SYNTAX SAVE OBJECT (FIND PERSON) = V-HELP>
+
+<SYNTAX SCORE = V-SCORE>
+
+<SYNTAX SCRIPT = V-SCRIPT>
+
+<SYNTAX SUPER = V-SUPER-BRIEF>
+<VERB-SYNONYM SUPER SUPERBRIEF>
+
+<SYNTAX UNDO = V-UNDO>
+
+<SYNTAX UNSCRIPT = V-UNSCRIPT>
+
+<SYNTAX VERBOSE = V-VERBOSE>
+
+<SYNTAX VERSION = V-VERSION>
+
+\
+
+;"subtitle real verbs"
+
+<SYNTAX ACT OBJECT (MOBY) = V-ACT>
+<SYNTAX ACT LIKE OBJECT (MOBY) = V-ACT>
+<VERB-SYNONYM ACT PRETEND FEIGN>
+
+<SYNTAX ACCUSE OBJECT = V-ACCUSE>
+
+<SYNTAX ADMIRE OBJECT (FIND PERSON) = V-ADMIRE>
+<VERB-SYNONYM ADMIRE COMPLIMENT>
+
+<SYNTAX AIM AT OBJECT = V-AIM>
+<SYNTAX AIM TO OBJECT = V-AIM>
+<SYNTAX AIM OBJECT (FIND WEAPONBIT) AT OBJECT = V-AIM>
+
+<SYNTAX ANSWER = V-ANSWER>
+<SYNTAX ANSWER OBJECT = V-REPLY>
+<VERB-SYNONYM ANSWER REPLY RESPOND>
+
+<SYNTAX APPLY OBJECT (HELD MANY HAVE) TO OBJECT = V-PUT PRE-PUT>
+
+<SYNTAX APPROACH OBJECT = V-WALK-TO>
+
+<SYNTAX ASK OBJECT (FIND PERSON) = V-TELL>
+<SYNTAX ASK FOR OBJECT = V-ASK-FOR PRE-ASK-FOR>
+<SYNTAX ASK OBJECT (FIND PERSON) FOR OBJECT = V-ASK-FOR PRE-ASK-FOR>
+<SYNTAX ASK ABOUT OBJECT (MOBY)
+	= V-ASK-ABOUT PRE-ASK-ABOUT>
+<SYNTAX ASK OBJECT (FIND PERSON) ABOUT OBJECT (MOBY)
+	= V-ASK-ABOUT PRE-ASK-ABOUT>
+<VERB-SYNONYM ASK QUIZ>
+
+<SYNTAX ATTACK OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) = V-ATTACK PRE-ATTACK>
+<SYNTAX ATTACK OBJECT (FIND PERSON) (ON-GROUND IN-ROOM)
+	WITH OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE) = V-ATTACK PRE-ATTACK>
+<SYNTAX ATTACK OBJECT (FIND PERSON) (ON-GROUND IN-ROOM)
+	BACK OBJECT (FIND RLANDBIT) = V-ATTACK PRE-ATTACK>
+<SYNTAX ATTACK BACK OBJECT (FIND RLANDBIT) = V-ATTACK PRE-ATTACK>
+<VERB-SYNONYM ATTACK FIGHT>
+
+<SYNTAX AVOID OBJECT = V-AVOID>
+
+<SYNTAX BABBLE = V-BABBLE>
+
+<SYNTAX BARGAIN WITH OBJECT (FIND PERSON) = V-BARGAIN>
+;<VERB-SYNONYM BARGAIN HAGGLE>
+
+<SYNTAX BATHE = V-BATHE>
+<SYNTAX BATHE OBJECT (FIND PERSON) = V-BATHE>
+<VERB-SYNONYM BATHE WASH CLEAN CLEANSE SCRUB>
+
+<NEW-ADD-WORD "BETRAYED" VERB <VOC "BETRAY"> ,PAST-TENSE>
+
+<SYNTAX BETRAY OBJECT (MOBY) = V-BETRAY>
+<SYNTAX BETRAY OBJECT (MOBY) TO OBJECT (FIND PERSON) = V-BETRAY>
+
+<SYNTAX BITE OBJECT = V-BITE>
+
+<SYNTAX BLESS OBJECT (FIND PERSON) = V-BLESS>
+
+<SYNTAX BLOW UP OBJECT = V-EXPLODE>
+<SYNTAX BLOW UP OBJECT WITH OBJECT = V-EXPLODE>
+<SYNTAX BLOW OUT OBJECT = V-LAMP-OFF>
+
+<SYNTAX BOARD OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-BOARD PRE-BOARD>
+<VERB-SYNONYM BOARD RIDE>
+
+<SYNTAX BOW = V-BOW>
+<SYNTAX BOW LOW OBJECT (FIND RLANDBIT) = V-BOW>
+<SYNTAX BOW TO OBJECT (FIND PERSON) = V-BOW>
+<SYNTAX BOW AT OBJECT (FIND PERSON) = V-BOW>
+<SYNTAX BOW OBJECT = V-BOW>
+
+<NEW-ADD-WORD "BROUGHT" VERB <VOC "BRING"> ,PAST-TENSE>
+
+<SYNTAX BRING OBJECT = V-LET-IN>
+
+<SYNTAX BURN OBJECT (HELD CARRIED ON-GROUND IN-ROOM)
+        WITH OBJECT (HELD CARRIED ON-GROUND IN-ROOM HAVE) = V-BURN>
+<SYNTAX BURN DOWN OBJECT (HELD CARRIED ON-GROUND IN-ROOM)
+	WITH OBJECT (HELD CARRIED ON-GROUND IN-ROOM HAVE) = V-BURN>
+<VERB-SYNONYM BURN IGNITE>
+
+<SYNTAX BURY OBJECT = V-BURY>
+<SYNTAX BURY OBJECT IN OBJECT = V-BURY>
+
+<SYNTAX BUY OBJECT FROM OBJECT (FIND PERSON) = V-BUY>
+<SYNTAX BUY OBJECT WITH OBJECT = V-BUY>
+<VERB-SYNONYM BUY PURCHASE>
+
+<SYNTAX CLEAR OBJECT (FIND FURNITURE) = V-CLEAR>
+
+<SYNTAX CLIMB OBJECT (ON-GROUND IN-ROOM) = V-CLIMB-FOO>
+<SYNTAX CLIMB ON OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-CLIMB-ON>
+<SYNTAX CLIMB UP OBJECT (FIND RLANDBIT) (ON-GROUND IN-ROOM) = V-CLIMB-UP>
+<SYNTAX CLIMB DOWN OBJECT (FIND RLANDBIT) (ON-GROUND IN-ROOM) = V-CLIMB-DOWN>
+<SYNTAX CLIMB OVER OBJECT (ON-GROUND IN-ROOM) = V-CLIMB-OVER>
+<SYNTAX CLIMB IN OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-BOARD PRE-BOARD>
+<SYNTAX CLIMB OFF OBJECT (FIND RLANDBIT) (ON-GROUND IN-ROOM) = V-DISEMBARK>
+<SYNTAX CLIMB OUT OBJECT (FIND RLANDBIT) (ON-GROUND IN-ROOM) = V-DISEMBARK>
+<SYNTAX CLIMB ABOARD OBJECT (FIND RLANDBIT) (ON-GROUND IN-ROOM) = V-BOARD PRE-BOARD>
+<VERB-SYNONYM CLIMB SCALE>
+
+<SYNTAX CLOSE OBJECT (FIND CONTBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-CLOSE>
+<SYNTAX CLOSE OBJECT (FIND CONTBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	WITH OBJECT (FIND WEAPONBIT) = V-CLOSE>
+<SYNTAX CLOSE UP OBJECT (FIND RLANDBIT) = V-SHUT-UP>
+<SYNTAX CLOSE OBJECT (FIND CONTBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	ON OBJECT (ON-GROUND IN-ROOM) = V-CLOSE>
+<VERB-SYNONYM CLOSE SHUT SEAL>
+
+<NEW-ADD-WORD "CAME" VERB <VOC "COME"> ,PAST-TENSE>
+
+<SYNTAX COME OBJECT = V-WALK-TO>
+<SYNTAX COME FROM OBJECT (MOBY) = V-COME-FROM>
+<SYNTAX COME ON OBJECT (MOBY) = V-COME-FROM>
+<SYNTAX COME THROUGH OBJECT (MOBY) = V-COME-FROM>
+<SYNTAX COME WITH OBJECT = V-FOLLOW>
+<SYNTAX COME OBJECT FROM OBJECT (MOBY) = V-COME-TO-FROM PRE-COME-TO-FROM>
+<SYNTAX COME OBJECT ON OBJECT (MOBY) = V-COME-TO-FROM PRE-COME-TO-FROM>
+<SYNTAX COME OBJECT THROUGH OBJECT (MOBY) = V-COME-TO-FROM PRE-COME-TO-FROM>
+<SYNTAX COME TO OBJECT FROM OBJECT (MOBY) = V-COME-TO-FROM PRE-COME-TO-FROM>
+<SYNTAX COME TO OBJECT ON OBJECT (MOBY) = V-COME-TO-FROM PRE-COME-TO-FROM>
+<SYNTAX COME TO OBJECT THROUGH OBJECT (MOBY) = V-COME-TO-FROM PRE-COME-TO-FROM>
+
+<SYNTAX COMPARE OBJECT (MANY) = V-COMPARE-MANY>
+<SYNTAX COMPARE OBJECT TO OBJECT = V-COMPARE>
+<SYNTAX COMPARE OBJECT WITH OBJECT = V-COMPARE>
+
+<SYNTAX COOK OBJECT = V-COOK>
+<VERB-SYNONYM COOK WARM HEAT>
+
+;<SYNTAX COPY OBJECT (FIND READBIT) WITH OBJECT (FIND TOOLBIT) = V-COPY>
+;<SYNTAX COPY OBJECT (FIND READBIT) ON OBJECT = V-COPY>
+;<SYNTAX COPY OBJECT (FIND READBIT) TO OBJECT = V-COPY>
+;<SYNTAX COPY OBJECT (FIND READBIT) = V-COPY>
+
+<SYNTAX COUNT OBJECT = V-WASTE-OF-TIME <> COUNT>
+<SYNTAX COUNT OBJECT IN OBJECT = V-WASTE-OF-TIME <> COUNT>
+;<VERB-SYNONYM COUNT>
+
+<SYNTAX COVER OBJECT WITH OBJECT (ON-GROUND IN-ROOM) = V-SPUT-ON PRE-SPUT-ON>
+
+<SYNTAX CRACK OBJECT (ON-GROUND IN-ROOM) = V-MUNG>
+<SYNTAX CRACK OBJECT (ON-GROUND IN-ROOM HELD CARRIED)
+	WITH OBJECT (HELD CARRIED TAKE HAVE) = V-MUNG>
+<SYNTAX CRACK OBJECT (ON-GROUND IN-ROOM HELD CARRIED)
+	OVER OBJECT (HELD CARRIED TAKE HAVE) = V-MUNG>
+<SYNTAX CRACK DOWN OBJECT (ON-GROUND IN-ROOM HELD CARRIED)
+	WITH OBJECT (HELD CARRIED TAKE HAVE) = V-MUNG>
+<VERB-SYNONYM CRACK DESTROY BREAK SMASH WRECK SCRATCH ;SCUFF SCRAPE>
+
+<SYNTAX CROSS OBJECT = V-CROSS>
+;<VERB-SYNONYM CROSS TRAVERSE>
+
+<SYNTAX CURSE = V-CURSE>
+<SYNTAX CURSE OBJECT = V-CURSE>
+<VERB-SYNONYM CURSE INSULT SHIT DAMN>
+
+<SYNTAX CUT OBJECT
+	WITH OBJECT (FIND WEAPONBIT) (CARRIED HELD HAVE) = V-CUT>
+<SYNTAX CUT THROUGH OBJECT
+	WITH OBJECT (FIND WEAPONBIT) (CARRIED HELD HAVE) = V-CUT>
+<VERB-SYNONYM CUT CHOP SLICE SLASH ;SEVER SPLIT ;DIVIDE PRUNE> 
+
+<SYNTAX DANCE = V-DANCE>
+<SYNTAX DANCE WITH OBJECT (FIND PERSON) = V-DANCE>
+<VERB-SYNONYM DANCE CAPER CAVORT>
+
+<SYNTAX DESCEND OBJECT (ON-GROUND IN-ROOM) = V-CLIMB-DOWN>
+
+<SYNTAX DIE = V-DIE>
+
+<SYNTAX DIG IN OBJECT = V-DIG>
+<SYNTAX DIG WITH OBJECT = V-DIG>
+<SYNTAX DIG THROUGH OBJECT = V-DIG>
+<SYNTAX DIG OBJECT (ON-GROUND IN-ROOM)
+	WITH OBJECT (FIND TOOLBIT) (HELD CARRIED HAVE)
+	= V-DIG>
+<SYNTAX DIG IN OBJECT (ON-GROUND IN-ROOM)
+	WITH OBJECT (FIND TOOLBIT) (HELD CARRIED HAVE)
+	= V-DIG>
+;<VERB-SYNONYM DIG EXCAVATE>
+
+<SYNTAX DISEMBARK = V-DISEMBARK>
+<SYNTAX DISEMBARK OBJECT (ON-GROUND IN-ROOM) = V-DISEMBARK>
+;<VERB-SYNONYM DISEMBARK DEBARK DISMOUNT>
+
+<SYNTAX DISTRACT OBJECT = V-DISTRACT>
+<VERB-SYNONYM DISTRACT DISTURB ANNOY>
+
+<SYNTAX DIVE = V-DIVE>
+<SYNTAX DIVE IN OBJECT = V-DIVE>
+<SYNTAX DIVE UNDER OBJECT = V-HIDE-UNDER>
+<SYNTAX DIVE BEHIND OBJECT = V-HIDE-BEHIND>
+<SYNTAX DIVE OFF OBJECT = V-LEAP>
+<SYNTAX DIVE THROUGH OBJECT = V-THROUGH PRE-THROUGH>
+
+<SYNTAX DODGE OBJECT (FIND RLANDBIT) = V-DODGE>
+<VERB-SYNONYM DODGE DUCK>
+
+<SYNTAX DRAW OBJECT (MOBY) = V-DRAW>
+<SYNTAX DRAW OBJECT (MOBY) ON OBJECT = V-DRAW>
+<VERB-SYNONYM DRAW SKETCH>
+
+<SYNTAX DRESS = V-DRESS>
+<SYNTAX DRESS IN OBJECT (FIND WEARABLE) = V-WEAR>
+
+<SYNTAX DRINK OBJECT (HELD CARRIED ON-GROUND IN-ROOM) = V-DRINK>
+<SYNTAX DRINK FROM OBJECT (HELD CARRIED) = V-DRINK-FROM>
+<VERB-SYNONYM DRINK SIP SWALLOW>
+
+<SYNTAX DROP OBJECT ;(FIND RLANDBIT) (HELD MANY ;HAVE) = V-DROP PRE-DROP>
+<SYNTAX DROP OBJECT (HELD MANY ;HAVE) DOWN OBJECT = V-PUT PRE-PUT>
+<SYNTAX DROP OBJECT (HELD MANY ;HAVE) OVER OBJECT = V-PUT PRE-PUT>
+<SYNTAX DROP OBJECT (HELD MANY ;HAVE) IN OBJECT = V-PUT PRE-PUT>
+<SYNTAX DROP OBJECT (HELD MANY ;HAVE) ON OBJECT = V-PUT PRE-PUT>
+<SYNTAX DROP OBJECT (HELD MANY ;HAVE) TO OBJECT = V-PUT PRE-PUT>
+<SYNTAX DROP FROM OBJECT = V-DROP PRE-DROP>
+<SYNTAX DROP DEAD OBJECT (FIND RLANDBIT) = V-CURSE>
+<VERB-SYNONYM DROP DUMP ABANDON>
+
+<SYNTAX DRY OBJECT WITH OBJECT (FIND TOOLBIT) = V-DRY>
+<SYNTAX DRY OFF OBJECT WITH OBJECT (FIND TOOLBIT) = V-DRY>
+
+<SYNTAX EAT OBJECT (FIND FOODBIT) (HELD CARRIED ON-GROUND IN-ROOM MANY)
+	= V-EAT>
+<SYNTAX EAT OBJECT (FIND FOODBIT) (HELD CARRIED ON-GROUND IN-ROOM MANY)
+	WITH OBJECT (FIND TOOLBIT) = V-EAT>
+<VERB-SYNONYM EAT CONSUME INGEST GOBBLE WOLF>
+
+;<SYNTAX EDIT OBJECT = V-EDIT>
+
+<SYNTAX ENTER = V-ENTER>
+<SYNTAX ENTER OBJECT (MOBY) = V-THROUGH PRE-THROUGH>
+
+<SYNTAX ERASE OBJECT = V-ERASE>
+
+<SYNTAX ESCAPE = V-ESCAPE>
+<SYNTAX ESCAPE FROM OBJECT = V-ESCAPE>
+
+<SYNTAX EXAMINE OBJECT (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-EXAMINE PRE-EXAMINE>
+<SYNTAX EXAMINE IN OBJECT (HELD CARRIED IN-ROOM ON-GROUND)
+	= V-LOOK-INSIDE>
+<SYNTAX EXAMINE ON OBJECT (HELD CARRIED IN-ROOM ON-GROUND)
+	= V-LOOK-INSIDE>
+<SYNTAX EXAMINE FOR OBJECT = V-FIND>
+<VERB-SYNONYM EXAMINE X ;INSPECT DESCRIBE CHECK ;OBSERVE WATCH>
+
+<SYNTAX EXIT = V-EXIT>
+<SYNTAX EXIT OBJECT = V-EXIT>
+<VERB-SYNONYM EXIT DEPART WITHDRAW>
+
+;<SYNTAX EXORCISE OBJECT = V-EXORCISE>
+;<SYNTAX EXORCISE OUT OBJECT (FIND PERSON) = V-EXORCISE>
+;<SYNTAX EXORCISE AWAY OBJECT (FIND PERSON) = V-EXORCISE>
+;<VERB-SYNONYM EXORCISE BANISH DRIVE>
+
+<SYNTAX EXPLODE OBJECT = V-EXPLODE>
+<SYNTAX EXPLODE OBJECT WITH OBJECT = V-EXPLODE>
+
+<SYNTAX EXTINGUISH OBJECT
+	(MANY HELD CARRIED ON-GROUND IN-ROOM TAKE HAVE)	= V-LAMP-OFF>
+;<VERB-SYNONYM EXTINGUISH DOUSE>
+
+<SYNTAX FILL OBJECT (FIND CONTBIT) (HELD TAKE HAVE) = V-FILL>
+<SYNTAX FILL OBJECT (FIND CONTBIT) (HELD TAKE HAVE) WITH OBJECT = V-FILL>
+<SYNTAX FILL OBJECT (FIND CONTBIT) (HELD TAKE HAVE) AT OBJECT = V-FILL>
+
+<SYNTAX FIND OBJECT (MOBY) = V-FIND>
+;<VERB-SYNONYM FIND SEEK SEE>
+
+;<SYNTAX FLY = V-FLY>
+;<SYNTAX FLY OBJECT = V-FLY>
+;<VERB-SYNONYM FLY LAUNCH>
+
+<SYNTAX FOLLOW = V-FOLLOW>
+<SYNTAX FOLLOW OBJECT (MOBY) = V-FOLLOW>
+<VERB-SYNONYM FOLLOW ;PURSUE CHASE>
+
+;<SYNTAX FORGET OBJECT = V-FORGET>
+;<VERB-SYNONYM FORGET UNLEARN ;UNMEMORIZE>
+
+<SYNTAX FUCK OBJECT (FIND PERSON) = V-FUCK>
+<SYNTAX FUCK OFF OBJECT (FIND RLANDBIT) = V-CURSE>
+<SYNTAX FUCK WITH OBJECT (FIND PERSON) = V-FUCK>
+<VERB-SYNONYM FUCK SCREW>
+
+<SYNTAX GIVE OBJECT (MANY HELD CARRIED HAVE)
+        TO OBJECT (FIND PERSON) (ON-GROUND) = V-GIVE PRE-GIVE>
+<SYNTAX GIVE OBJECT (FIND PERSON) (ON-GROUND) OBJECT (MANY HELD CARRIED HAVE)
+	= V-SGIVE PRE-SGIVE>
+<SYNTAX GIVE OBJECT (FIND PERSON) (ON-GROUND)
+	WITH OBJECT (MANY HELD CARRIED HAVE)
+	= V-SGIVE PRE-SGIVE>
+<SYNTAX GIVE OBJECT (HELD CARRIED HAVE) FOR OBJECT = V-TRADE>
+<VERB-SYNONYM GIVE OFFER FEED HAND ;PRESENT>
+
+<SYNTAX GOODBYE = V-GOODBYE>
+<VERB-SYNONYM GOODBYE SAYONARA>
+
+<SYNTAX HANG FROM OBJECT = V-BOARD PRE-BOARD>
+<SYNTAX HANG OBJECT ON OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX HANG OBJECT FROM OBJECT = V-PUT-ON PRE-PUT>
+
+<SYNTAX HELLO = V-HELLO>
+<SYNTAX HELLO OBJECT = V-HELLO>
+<VERB-SYNONYM HELLO HI GREET GREETINGS>
+
+<SYNTAX HELP = V-HELP>
+<SYNTAX HELP OBJECT = V-HELP>
+<SYNTAX HELP TO OBJECT = V-HELP>
+<VERB-SYNONYM HELP ATTEND DEFEND AID PROTECT RESCUE>
+
+<SYNTAX HIDE = V-HIDE>
+<SYNTAX HIDE OBJECT = V-HIDE>
+<SYNTAX HIDE UNDER OBJECT = V-HIDE-UNDER>
+<SYNTAX HIDE BEHIND OBJECT = V-HIDE-BEHIND>
+<SYNTAX HIDE OBJECT FROM OBJECT = V-HIDE>
+<SYNTAX HIDE OBJECT IN OBJECT = V-PUT PRE-PUT>
+<SYNTAX HIDE IN OBJECT = V-BOARD PRE-BOARD>
+<SYNTAX HIDE FROM OBJECT = V-HIDE-FROM>
+<VERB-SYNONYM HIDE CONCEAL ;STASH>
+
+<SYNTAX HIT OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) = V-HIT>
+<SYNTAX HIT OBJECT (FIND PERSON) (ON-GROUND IN-ROOM)
+	WITH OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE) = V-HIT>
+<SYNTAX HIT OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) IN OBJECT = V-HIT>
+<SYNTAX HIT OBJECT (FIND PERSON) (ON-GROUND IN-ROOM)
+	BACK OBJECT (FIND RLANDBIT) = V-HIT>
+<SYNTAX HIT BACK OBJECT (FIND RLANDBIT) = V-HIT>
+<VERB-SYNONYM HIT STRIKE PUNCH POUND HAMMER SMACK SLAP>
+
+<SYNTAX HOLD OBJECT (FIND TAKEBIT) (IN-ROOM CARRIED MANY) = V-HOLD>
+<SYNTAX HOLD OBJECT (FIND TAKEBIT) (IN-ROOM CARRIED MANY) OBJECT = V-TURN>
+<SYNTAX HOLD OBJECT (FIND TAKEBIT) (IN-ROOM CARRIED MANY) TO OBJECT = V-TURN>
+<SYNTAX HOLD OBJECT (FIND TAKEBIT) (IN-ROOM CARRIED MANY) OUT OBJECT = V-GIVE PRE-GIVE>
+<SYNTAX HOLD ON OBJECT (FIND RLANDBIT) = V-HOLD-ON>
+
+<SYNTAX HUG OBJECT (FIND PERSON) = V-HUG>
+<VERB-SYNONYM HUG EMBRACE>
+
+;<SYNTAX INFLATE OBJECT = V-INFLATE>
+
+<SYNTAX JOIN OBJECT = V-JOIN>
+
+<SYNTAX JUMP = V-LEAP>
+<SYNTAX JUMP UP OBJECT (FIND RLANDBIT) = V-LEAP>
+<SYNTAX JUMP OVER OBJECT = V-LEAP>
+<SYNTAX JUMP ACROSS OBJECT = V-LEAP>
+<SYNTAX JUMP IN OBJECT = V-BOARD PRE-BOARD>
+<SYNTAX JUMP FROM OBJECT = V-LEAP>
+<SYNTAX JUMP DOWN OBJECT (FIND RLANDBIT) = V-LEAP>
+<SYNTAX JUMP OFF OBJECT = V-LEAP>
+<SYNTAX JUMP ON OBJECT = V-CLIMB-ON>
+<SYNTAX JUMP TO OBJECT = V-CLIMB-ON>
+<VERB-SYNONYM JUMP LEAP>
+
+<SYNTAX KEEP AWAY OBJECT = V-AVOID>
+
+<SYNTAX KICK OBJECT = V-KICK>
+<SYNTAX KICK OBJECT IN OBJECT = V-KICK>
+<SYNTAX KICK OBJECT BACK OBJECT (FIND RLANDBIT) = V-KICK>
+<VERB-SYNONYM KICK PUNT>
+
+<NEW-ADD-WORD "KILLED" VERB <VOC "KILL"> ,PAST-TENSE>
+
+<SYNTAX KILL OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) = V-KILL>
+<SYNTAX KILL OBJECT (FIND PERSON) (ON-GROUND IN-ROOM)
+	WITH OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE) = V-KILL>
+<SYNTAX KILL OBJECT (FIND PERSON) (ON-GROUND IN-ROOM)
+	IN OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE) = V-ATTACK PRE-ATTACK>
+<VERB-SYNONYM KILL MURDER SLAY STAB>
+
+<SYNTAX KISS OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) = V-KISS>
+
+<SYNTAX KNEEL = V-KNEEL>
+<SYNTAX KNEEL TO OBJECT = V-KNEEL>
+<SYNTAX KNEEL ON OBJECT = V-KNEEL-ON>
+<VERB-SYNONYM KNEEL GROVEL>
+
+<SYNTAX KNOCK AT OBJECT = V-KNOCK>
+<SYNTAX KNOCK ON OBJECT = V-KNOCK>
+<SYNTAX KNOCK DOWN OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) = V-HIT>
+<VERB-SYNONYM KNOCK RAP BANG>
+
+<SYNTAX KNOW = V-KNOW>
+<SYNTAX KNOW OBJECT = V-KNOW>
+<SYNTAX KNOW ABOUT OBJECT = V-KNOW>
+
+;<SYNTAX LABEL OBJECT (HELD CARRIED) = V-SWRITE PRE-SWRITE>
+;<SYNTAX LABEL OBJECT (HELD CARRIED) WITH OBJECT = V-SWRITE PRE-SWRITE>
+
+;<SYNTAX LAND = V-LAND>
+
+<SYNTAX LAUGH AT OBJECT = V-LAUGH>
+<SYNTAX LAUGH = V-LAUGH>
+
+<SYNTAX LAUNCH OBJECT (FIND VEHBIT) = V-LAUNCH>
+
+<SYNTAX LEAN ON OBJECT (HELD HAVE) = V-LEAN-ON>
+<SYNTAX LEAN OBJECT ON OBJECT = V-RAISE>
+<SYNTAX LEAN OBJECT AGAINST OBJECT = V-RAISE>
+
+<NEW-ADD-WORD "LEARNED" VERB <VOC "LEARN"> ,PAST-TENSE>
+
+<SYNTAX LEARN OBJECT = V-LEARN>
+<SYNTAX LEARN FROM OBJECT = V-LEARN>
+<SYNTAX LEARN IN OBJECT = V-LEARN>
+
+<SYNTAX LEAVE = V-LEAVE>
+<SYNTAX LEAVE OBJECT = V-DROP PRE-DROP>
+
+<SYNTAX LET GO OBJECT (FIND RLANDBIT) = V-DROP PRE-DROP>
+<SYNTAX LET IN OBJECT = V-LET-IN>
+
+<SYNTAX LIE DOWN OBJECT (FIND RLANDBIT) = V-LIE-DOWN>
+<SYNTAX LIE ON OBJECT (FIND VEHBIT) = V-LIE-DOWN>
+<SYNTAX LIE TO OBJECT (FIND PERSON) = V-LIE>
+;<VERB-SYNONYM LIE LAY>
+
+<SYNTAX LIGHT OBJECT (FIND LIGHTBIT) = V-LAMP-ON>
+<SYNTAX LIGHT UP OBJECT (FIND LIGHTBIT) = V-LAMP-ON>
+
+<SYNTAX LISTEN = V-LISTEN>
+<SYNTAX LISTEN TO OBJECT = V-LISTEN>
+<SYNTAX LISTEN FOR OBJECT = V-LISTEN>
+<SYNTAX LISTEN ON OBJECT = V-LISTEN>
+<VERB-SYNONYM LISTEN EAVESDROP>
+
+<SYNTAX LOAD = V-LOAD>
+<SYNTAX LOAD OBJECT (FIND WEAPONBIT) (HELD HAVE) = V-LOAD>
+<SYNTAX LOAD OBJECT (FIND WEAPONBIT) (HELD HAVE)
+	WITH OBJECT (HELD CARRIED HAVE) = V-LOAD>
+<SYNTAX LOAD OBJECT (FIND WEAPONBIT) (HELD HAVE)
+	FROM OBJECT (HELD CARRIED HAVE) = V-LOAD>
+<VERB-SYNONYM LOAD RELOAD>
+
+<SYNTAX LOCK OBJECT (ON-GROUND IN-ROOM) = V-LOCK>
+<SYNTAX LOCK OBJECT (ON-GROUND IN-ROOM) WITH OBJECT = V-LOCK>
+<SYNTAX LOCK OBJECT (ON-GROUND IN-ROOM) TO OBJECT = V-LOCK>
+<VERB-SYNONYM LOCK BAR BOLT LATCH>
+
+<SYNTAX LOOK = V-LOOK>
+<SYNTAX LOOK AROUND OBJECT (FIND RLANDBIT) = V-LOOK>
+<SYNTAX LOOK DOWN OBJECT (FIND RLANDBIT) = V-LOOK-DOWN>
+<SYNTAX LOOK AT OBJECT (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-EXAMINE PRE-EXAMINE>
+<SYNTAX LOOK THROUGH OBJECT = V-LOOK-INSIDE>
+<SYNTAX LOOK UNDER OBJECT = V-LOOK-UNDER>
+<SYNTAX LOOK BEHIND OBJECT = V-LOOK-BEHIND>
+<SYNTAX LOOK ON OBJECT (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-LOOK-ON>
+<SYNTAX LOOK IN OBJECT (HELD CARRIED ON-GROUND IN-ROOM) = V-LOOK-INSIDE>
+<SYNTAX LOOK AT OBJECT (HELD CARRIED ON-GROUND IN-ROOM TAKE) THROUGH OBJECT
+	= V-READ PRE-READ>
+<SYNTAX LOOK UP OBJECT (FIND RLANDBIT) = V-LOOK-UP>
+<SYNTAX LOOK UP OBJECT IN OBJECT (FIND READBIT) = V-LOOK-UP>
+<SYNTAX LOOK FOR OBJECT = V-FIND>
+<SYNTAX LOOK OUT OBJECT (FIND RLANDBIT) = V-LOOK-OUT>
+<SYNTAX LOOK OBJECT = V-CHASTISE>
+<VERB-SYNONYM LOOK L STARE GAZE>
+
+<SYNTAX LOVE OBJECT (FIND PERSON) = V-LOVE>
+
+<SYNTAX LOWER OBJECT = V-LOWER>
+<SYNTAX LOWER OBJECT TO OBJECT = V-LOWER>
+<SYNTAX LOWER OBJECT IN OBJECT = V-PUT PRE-PUT>
+<SYNTAX LOWER OBJECT DOWN OBJECT = V-PUT PRE-PUT>
+<VERB-SYNONYM LOWER FURL>
+
+<SYNTAX MAKE OBJECT = V-MAKE>
+<SYNTAX MAKE OBJECT IN ;INTO OBJECT = V-MAKE>
+<SYNTAX MAKE OBJECT FROM OBJECT = V-TIE>
+<SYNTAX MAKE OBJECT OVER OBJECT (FIND PERSON) = V-MAKE>
+<VERB-SYNONYM MAKE BUILD CONSTRUCT>
+
+<SYNTAX MELT OBJECT WITH OBJECT (HELD CARRIED ON-GROUND IN-ROOM) = V-MELT>
+<VERB-SYNONYM MELT THAW>
+
+<SYNTAX MOVE = V-WALK-AROUND>
+<SYNTAX MOVE TO OBJECT (ON-GROUND IN-ROOM) = V-WALK-TO>
+<SYNTAX MOVE OBJECT (ON-GROUND IN-ROOM) = V-MOVE>
+<SYNTAX MOVE OBJECT (ON-GROUND IN-ROOM) WITH OBJECT = V-PRY PRE-PRY>
+<SYNTAX MOVE OBJECT (ON-GROUND IN-ROOM) TO OBJECT = V-PUSH-TO>
+<SYNTAX MOVE OBJECT (ON-GROUND IN-ROOM) ON OBJECT = V-PUSH-TO>
+<SYNTAX MOVE AWAY OBJECT = V-AVOID>
+<SYNTAX MOVE FROM OBJECT = V-AVOID>
+<VERB-SYNONYM MOVE SHIFT>
+
+<SYNTAX NO = V-NO>
+<SYNTAX NO OBJECT = V-NO>
+<VERB-SYNONYM NO NOPE DENY REFUSE>
+
+<SYNTAX NOD = V-YES>
+<SYNTAX NOD OBJECT = V-YES>
+
+<NEW-ADD-WORD "OPENED" VERB <VOC "OPEN"> ,PAST-TENSE>
+
+<SYNTAX OPEN OBJECT (FIND DOORBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-OPEN PRE-OPEN>
+<SYNTAX OPEN UP	OBJECT (FIND DOORBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-OPEN PRE-OPEN>
+<SYNTAX OPEN OBJECT (FIND DOORBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	WITH OBJECT (FIND TOOLBIT) (ON-GROUND IN-ROOM HELD CARRIED)
+	= V-OPEN PRE-OPEN>
+<VERB-SYNONYM OPEN UNSEAL>
+
+<SYNTAX PACE = V-WALK-AROUND>
+
+<SYNTAX PARRY = V-PARRY>
+<SYNTAX PARRY WITH OBJECT (HELD HAVE) (FIND WEAPONBIT) = V-PARRY>
+<SYNTAX PARRY OBJECT WITH OBJECT (HELD HAVE) (FIND WEAPONBIT) = V-PARRY>
+<VERB-SYNONYM PARRY RESIST>
+
+;<SYNTAX PAY OBJECT (MANY HELD HAVE) = V-PAY>
+;<SYNTAX PAY OBJECT (FIND PERSON) WITH OBJECT (MANY HELD HAVE) = V-PAY>
+;<SYNTAX PAY OBJECT (MANY HELD HAVE) TO OBJECT (FIND PERSON) = V-SPAY>
+;<SYNTAX PAY OBJECT (FIND PERSON) OBJECT (MANY HELD HAVE) = V-PAY>
+
+<SYNTAX PICK OBJECT = V-PICK>
+<SYNTAX PICK OBJECT WITH OBJECT = V-PICK>
+<SYNTAX PICK UP OBJECT (FIND TAKEBIT) (ON-GROUND MANY) = V-TAKE PRE-TAKE>
+<SYNTAX PICK UP OBJECT (FIND TAKEBIT) (ON-GROUND MANY)
+	WITH OBJECT (FIND TOOLBIT) = V-PICK-UP>
+
+<SYNTAX PISS = V-PISS>
+<SYNTAX PISS ON OBJECT = V-PISS>
+<SYNTAX PISS IN OBJECT = V-PISS>
+<VERB-SYNONYM PISS URINATE PEE>
+
+;<SYNTAX PLAY OBJECT = V-PLAY>
+
+<SYNTAX PLEAD = V-PLEAD>
+<SYNTAX PLEAD FOR OBJECT = V-ASK-FOR PRE-ASK-FOR>
+<SYNTAX PLEAD WITH OBJECT = V-PLEAD>
+<VERB-SYNONYM PLEAD BEG>
+
+<SYNTAX PLUG OBJECT WITH OBJECT = V-PLUG>
+<SYNTAX PLUG IN OBJECT = V-PLUG-IN>
+<SYNTAX PLUG OBJECT IN OBJECT = V-PLUG>
+<VERB-SYNONYM PLUG ;CLOG ;SCREW>
+
+<SYNTAX POINT AT OBJECT = V-POINT>
+<SYNTAX POINT TO OBJECT = V-POINT>
+<VERB-SYNONYM POINT GESTURE MOTION>
+
+<SYNTAX POKE OBJECT (FIND PERSON) (ON-GROUND IN-ROOM)
+	WITH OBJECT (FIND WEAPONBIT) (HELD CARRIED TAKE HAVE) = V-MUNG>
+<VERB-SYNONYM POKE JAB BLIND>
+
+<SYNTAX POUR OBJECT (HELD CARRIED) = V-POUR PRE-POUR>
+<SYNTAX POUR OBJECT (HELD CARRIED) IN OBJECT = V-PUT PRE-PUT>
+<SYNTAX POUR OBJECT (HELD CARRIED) ON OBJECT = V-POUR PRE-POUR>
+<SYNTAX POUR OBJECT (HELD CARRIED) OVER OBJECT = V-POUR PRE-POUR>
+<SYNTAX POUR OBJECT (HELD CARRIED) THROUGH OBJECT = V-POUR PRE-POUR>
+<SYNTAX POUR OBJECT (HELD CARRIED) FROM OBJECT = V-POUR-FROM>
+<VERB-SYNONYM POUR EMPTY SPILL>
+
+<SYNTAX PRAY = V-PRAY>
+<SYNTAX PRAY FOR OBJECT = V-PRAY>
+<SYNTAX PRAY WITH OBJECT = V-PRAY>
+<SYNTAX PRAY TO OBJECT = V-PRAY>
+
+<SYNTAX PRY OBJECT WITH OBJECT = V-PRY PRE-PRY>
+<SYNTAX PRY OUT OBJECT WITH OBJECT = V-PRY PRE-PRY>
+<VERB-SYNONYM PRY LEVER>
+
+<SYNTAX PULL OBJECT (ON-GROUND IN-ROOM) = V-MOVE>
+<SYNTAX PULL ON OBJECT (ON-GROUND IN-ROOM) = V-MOVE>
+<SYNTAX PULL OBJECT (ON-GROUND IN-ROOM) IN OBJECT = V-PUT PRE-PUT>
+<SYNTAX PULL OBJECT (ON-GROUND IN-ROOM) OUT OBJECT = V-TAKE PRE-TAKE>
+<SYNTAX PULL OBJECT UP OBJECT (FIND RLANDBIT) = V-RAISE>
+<SYNTAX PULL OBJECT BEHIND OBJECT = V-PULL-BEHIND>
+<SYNTAX PULL UP OBJECT = V-RAISE>
+<SYNTAX PULL DOWN OBJECT = V-LOWER>
+<VERB-SYNONYM PULL TUG DRAG>
+
+;<SYNTAX PUMP UP OBJECT = V-PUMP>
+;<SYNTAX PUMP UP OBJECT WITH OBJECT = V-PUMP>
+
+<SYNTAX PUSH OBJECT (IN-ROOM ON-GROUND) = V-PUSH>
+<SYNTAX PUSH OBJECT (IN-ROOM ON-GROUND) AWAY OBJECT (FIND RLANDBIT) = V-PUSH>
+<SYNTAX PUSH OBJECT (IN-ROOM ON-GROUND)
+	OVERBOARD OBJECT (FIND RLANDBIT) = V-THROW-OFF PRE-THROW>
+<SYNTAX PUSH ON OBJECT (IN-ROOM ON-GROUND) = V-PUSH>
+<SYNTAX PUSH OBJECT (IN-ROOM ON-GROUND) OBJECT = V-PUSH-TO>
+<SYNTAX PUSH OBJECT (IN-ROOM ON-GROUND) TO OBJECT = V-PUSH-TO>
+<SYNTAX PUSH OBJECT (IN-ROOM ON-GROUND) ON OBJECT = V-PUSH-TO>
+<SYNTAX PUSH OBJECT (IN-ROOM ON-GROUND) IN OBJECT = V-PUSH-TO>
+<SYNTAX PUSH OBJECT UNDER OBJECT = V-PUT-UNDER>
+<SYNTAX PUSH OBJECT DOWN OBJECT (FIND RLANDBIT) = V-PUSH-DOWN>
+<SYNTAX PUSH OBJECT UP OBJECT (FIND RLANDBIT) = V-PUSH-UP>
+<SYNTAX PUSH OBJECT OUT OBJECT (FIND RLANDBIT) = V-PUSH-OUT>
+<SYNTAX PUSH OBJECT BEHIND OBJECT = V-PULL-BEHIND>
+<SYNTAX PUSH OVER OBJECT = V-TRIP>
+<VERB-SYNONYM PUSH PRESS SHOVE>
+
+<SYNTAX PUT OBJECT (HELD MANY HAVE) IN OBJECT = V-PUT PRE-PUT>
+<SYNTAX PUT OBJECT (HELD MANY HAVE) DOWN OBJECT = V-PUT PRE-PUT>
+<SYNTAX PUT OBJECT (HELD MANY HAVE) ON OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX PUT OBJECT (HELD MANY HAVE) OVER OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX PUT OBJECT (HELD MANY HAVE) ACROSS OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX PUT OBJECT (HELD MANY HAVE) THROUGH OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX PUT DOWN OBJECT (HELD MANY) = V-DROP PRE-DROP>
+<SYNTAX PUT OBJECT (HELD MANY) AWAY OBJECT (FIND RLANDBIT) = V-PUT-AWAY>
+<SYNTAX PUT OBJECT (HELD MANY)
+	OVERBOARD OBJECT (FIND RLANDBIT) = V-THROW-OFF PRE-THROW>
+<SYNTAX PUT OBJECT (HELD MANY HAVE) UNDER OBJECT = V-PUT-UNDER> 
+<SYNTAX PUT ON OBJECT (HELD CARRIED ON-GROUND IN-ROOM HAVE TAKE MANY) = V-WEAR>
+<SYNTAX PUT OBJECT (HELD MANY HAVE) BEHIND OBJECT = V-PUT-BEHIND>
+<SYNTAX PUT OBJECT (HELD HAVE) BETWEEN OBJECT = V-PUT-BETWEEN>
+<SYNTAX PUT OBJECT (HELD HAVE) AROUND OBJECT = V-TIE>
+<SYNTAX PUT UP OBJECT = V-RAISE>
+<VERB-SYNONYM PUT ;STUFF INSERT PLACE LAY ;FIT>
+
+<SYNTAX QUIET = V-QUIET>
+<SYNTAX QUIET OBJECT = V-SOOTHE>
+
+<SYNTAX RAISE OBJECT = V-RAISE>
+<SYNTAX RAISE UP OBJECT = V-RAISE>
+<SYNTAX RAISE OBJECT WITH OBJECT = V-PRY PRE-PRY>
+<SYNTAX RAISE UP OBJECT WITH OBJECT = V-PRY PRE-PRY>
+<SYNTAX RAISE OBJECT OUT OBJECT (FIND RLANDBIT) = V-RAISE>
+<VERB-SYNONYM RAISE LIFT ERECT HOIST WEIGH BOOST UNFURL>
+
+<SYNTAX REACH IN OBJECT (ON-GROUND IN-ROOM) = V-REACH-IN>
+<SYNTAX REACH IN OBJECT (ON-GROUND IN-ROOM)
+	WITH OBJECT (HELD CARRIED HAVE) = V-REACH-IN>
+<SYNTAX REACH UNDER OBJECT (ON-GROUND IN-ROOM) = V-SEARCH>
+<SYNTAX REACH OBJECT WITH OBJECT = V-REACH-FOR>
+<SYNTAX REACH FOR OBJECT = V-TAKE PRE-TAKE>
+<SYNTAX REACH FOR OBJECT WITH OBJECT = V-REACH-FOR>
+
+<SYNTAX READ OBJECT (FIND READBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-READ PRE-READ>
+;<SYNTAX READ OBJECT (FIND READBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	THROUGH OBJECT = V-READ PRE-READ>
+<SYNTAX READ OBJECT (FIND READBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	TO OBJECT (FIND PERSON) = V-SHOW>
+<SYNTAX READ ABOUT OBJECT = V-WHAT>
+;<SYNTAX READ ABOUT OBJECT IN OBJECT = V-WHAT>
+
+<SYNTAX RELEASE OBJECT = V-RELEASE>
+<VERB-SYNONYM RELEASE RELIEVE>
+
+<SYNTAX REMOVE OBJECT = V-TAKE-OFF>
+<SYNTAX REMOVE OBJECT WITH OBJECT = V-PRY PRE-PRY>
+<SYNTAX REMOVE OBJECT FROM OBJECT = V-TAKE PRE-TAKE>
+<VERB-SYNONYM REMOVE SHED>
+
+<SYNTAX REPAIR OBJECT = V-REPAIR>
+<SYNTAX REPAIR OBJECT WITH OBJECT = V-REPAIR>
+<VERB-SYNONYM REPAIR PATCH FIX>
+
+<SYNTAX REPLACE OBJECT = V-REPLACE>
+
+<SYNTAX RING OBJECT = V-RING>
+
+<SYNTAX RINSE OBJECT = V-RINSE>
+
+<SYNTAX ROLL = V-MOVE>
+<SYNTAX ROLL UP OBJECT (ON-GROUND IN-ROOM) = V-MOVE>
+<SYNTAX ROLL AWAY OBJECT (FIND RLANDBIT) (ON-GROUND IN-ROOM) = V-MOVE>
+<SYNTAX ROLL OBJECT (ON-GROUND IN-ROOM) = V-MOVE>
+<SYNTAX ROLL OBJECT (ON-GROUND IN-ROOM) IN OBJECT = V-PUT PRE-PUT>
+
+<SYNTAX ROW = V-ROW>
+<SYNTAX ROW OBJECT = V-ROW>
+<SYNTAX ROW OBJECT OBJECT = V-ROW>
+<SYNTAX ROW OBJECT TO OBJECT = V-ROW>
+<SYNTAX ROW TO OBJECT = V-WALK-TO>
+<SYNTAX ROW FOR OBJECT = V-WALK-TO>
+<VERB-SYNONYM ROW STROKE PADDLE>
+
+<NEW-ADD-WORD "SAILED" VERB <VOC "SAIL"> ,PAST-TENSE>
+
+<SYNTAX SAIL OBJECT = V-WALK>
+<SYNTAX SAIL = V-WALK-AROUND>
+<SYNTAX SAIL OBJECT TO OBJECT = V-DRIVE-ON>
+<SYNTAX SAIL OBJECT ON OBJECT = V-WALK-TO>
+<SYNTAX SAIL TO OBJECT ON OBJECT = V-WALK-TO>
+<SYNTAX SAIL TO OBJECT IN OBJECT = V-WALK-TO>
+<SYNTAX SAIL OBJECT IN OBJECT = V-WALK-TO>
+<SYNTAX SAIL TO OBJECT = V-WALK-TO>
+<SYNTAX SAIL ON OBJECT = V-WALK-TO>
+<SYNTAX SAIL FROM OBJECT (MOBY) = V-COME-FROM>
+<SYNTAX SAIL BY OBJECT (MOBY) = V-COME-FROM>
+<SYNTAX SAIL THROUGH OBJECT (MOBY) = V-COME-FROM>
+<SYNTAX SAIL ACROSS OBJECT (MOBY) = V-COME-FROM>
+
+<SYNTAX SAY TO OBJECT (FIND PERSON) (MANY IN-ROOM) = V-TELL>
+<SYNTAX SAY OBJECT (MOBY) TO OBJECT (FIND PERSON) (IN-ROOM) = V-SAY>
+<SYNTAX SAY TO OBJECT IN OBJECT = V-SSPEAK PRE-SSPEAK>
+<SYNTAX SAY OBJECT (MOBY) = V-SAY>
+<SYNTAX SAY OUT OBJECT (FIND RLANDBIT) = V-YELL> 
+<VERB-SYNONYM SAY TALK CALL>
+
+<SYNTAX SCARE OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) = V-SCARE>
+<SYNTAX SCARE OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) WITH OBJECT = V-SCARE>
+<VERB-SYNONYM SCARE SURPRISE STARTLE CURDLE>
+
+<SYNTAX SEARCH OBJECT = V-SEARCH>
+<SYNTAX SEARCH IN OBJECT = V-SEARCH>
+<SYNTAX SEARCH OBJECT FOR OBJECT = V-SEARCH>
+<SYNTAX SEARCH IN OBJECT FOR OBJECT = SEARCH>
+<SYNTAX SEARCH FOR OBJECT = V-FIND>
+<VERB-SYNONYM SEARCH RUMMAGE ;FRISK>
+
+<SYNTAX SELL OBJECT TO OBJECT (FIND PERSON) = V-SELL>
+<SYNTAX SELL OBJECT OBJECT = V-SSELL PRE-SSELL>
+
+<NEW-ADD-WORD "SENT" VERB <VOC "SEND"> ,PAST-TENSE>
+
+<SYNTAX SEND OBJECT (FIND PERSON) OBJECT = V-SEND>
+<SYNTAX SEND OBJECT (FIND PERSON) TO OBJECT (MOBY) = V-SEND>
+<SYNTAX SEND OUT OBJECT (FIND PERSON) = V-SEND>
+<SYNTAX SEND OBJECT OUT OBJECT (FIND RLANDBIT) = V-SEND>
+<SYNTAX SEND OBJECT UP OBJECT (FIND RLANDBIT) = V-SEND>
+<SYNTAX SEND OBJECT ON OBJECT ;(MOBY) = V-SEND>
+<SYNTAX SEND OBJECT UNDER OBJECT ;(MOBY) = V-SEND-UNDER>
+<VERB-SYNONYM SEND ORDER>
+
+<SYNTAX SHAKE OBJECT = V-SHAKE>
+<SYNTAX SHAKE OBJECT AT OBJECT = V-WAVE-AT>
+<VERB-SYNONYM SHAKE ;JOSTLE RATTLE>
+
+<SYNTAX SHARPEN OBJECT WITH OBJECT = V-SHARPEN>
+<SYNTAX SHARPEN OBJECT ON OBJECT = V-SHARPEN>
+<VERB-SYNONYM SHARPEN HONE>
+
+<SYNTAX SHEATHE OBJECT (FIND WEAPONBIT) = V-PUT-AWAY>
+
+<SYNTAX SHIP OBJECT = V-SHIP>
+
+<SYNTAX SHOOT OBJECT = V-SHOOT PRE-SHOOT>
+<SYNTAX SHOOT OBJECT (FIND WEAPONBIT) AT OBJECT (FIND PERSON)
+	= V-SHOOT PRE-SHOOT>
+<SYNTAX SHOOT AT OBJECT (FIND PERSON)
+	WITH OBJECT (FIND WEAPONBIT) = V-SHOOT-WITH>
+<SYNTAX SHOOT OBJECT (FIND PERSON)
+	WITH OBJECT (FIND WEAPONBIT) = V-SHOOT-WITH>
+<SYNTAX SHOOT OBJECT (FIND WEAPONBIT)
+	THROUGH OBJECT = V-SHOOT PRE-SHOOT>
+<VERB-SYNONYM SHOOT FIRE>
+
+<SYNTAX SHOW OBJECT TO OBJECT (FIND PERSON) = V-SHOW>
+<SYNTAX SHOW OBJECT (FIND PERSON) OBJECT = V-SSHOW PRE-SSHOW>
+
+<SYNTAX SHRUG = V-SHRUG>
+
+<SYNTAX SING = V-SING>
+<SYNTAX SING OBJECT = V-SING>
+<SYNTAX SING TO OBJECT = V-SING>
+
+<SYNTAX SIT = V-SIT>
+<SYNTAX SIT ON OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-SIT>
+<SYNTAX SIT DOWN OBJECT (FIND RLANDBIT) = V-SIT>
+<SYNTAX SIT UP OBJECT (FIND RLANDBIT) = V-SIT>
+<SYNTAX SIT IN OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-BOARD PRE-BOARD>
+<SYNTAX SIT AT OBJECT = V-SIT <> SIT-AT>
+<VERB-SYNONYM SIT ;MEDITATE>
+
+<SYNTAX SKIP = V-SKIP>
+<VERB-SYNONYM SKIP HOP ;CAVORT ;GAMBOL>
+
+<SYNTAX SLEEP = V-SLEEP>
+<SYNTAX SLEEP IN OBJECT (IN-ROOM ON-GROUND) = V-BOARD PRE-BOARD>
+<SYNTAX SLEEP ON OBJECT (IN-ROOM ON-GROUND) = V-BOARD PRE-BOARD>
+<SYNTAX SLEEP WITH OBJECT (FIND PERSON) = V-FUCK>
+<VERB-SYNONYM SLEEP NAP REST ;SNOOZE>
+
+<SYNTAX SLIDE OBJECT = V-MOVE>
+<SYNTAX SLIDE ON OBJECT = V-BOARD PRE-BOARD>
+<SYNTAX SLIDE OBJECT UNDER OBJECT = V-PUT-UNDER>
+
+<SYNTAX SMELL = V-SMELL>
+<SYNTAX SMELL OBJECT = V-SMELL>
+<VERB-SYNONYM SMELL SNIFF>
+
+<SYNTAX SMILE AT OBJECT (FIND PERSON) = V-SMILE>
+<SYNTAX SMILE TO OBJECT (FIND PERSON) = V-SMILE>
+<SYNTAX SMILE = V-SMILE>
+<VERB-SYNONYM SMILE GRIN>
+
+<SYNTAX SOOTHE OBJECT (FIND PERSON) = V-SOOTHE>
+<VERB-SYNONYM SOOTHE CALM>
+
+<SYNTAX SORRY = V-SORRY>
+<SYNTAX SORRY TO OBJECT (FIND PERSON) = V-SORRY>
+<VERB-SYNONYM SORRY APOLOGIZE>
+
+<SYNTAX SORT OBJECT = V-SORT>
+<SYNTAX SORT OUT OBJECT = V-SORT>
+<VERB-SYNONYM SORT RESORT RE-SORT>
+
+<SYNTAX SPEAK OBJECT = V-SPEAK>
+<SYNTAX SPEAK IN OBJECT = V-SPEAK>
+<SYNTAX SPEAK OBJECT TO OBJECT (FIND PERSON) = V-SPEAK>
+<SYNTAX SPEAK IN OBJECT TO OBJECT (FIND PERSON) = V-SPEAK>
+
+;<SYNTAX SPIN OBJECT = V-SPIN>
+;<VERB-SYNONYM SPIN WHIRL ROTATE>
+
+<SYNTAX SPIT = V-SPIT>
+<SYNTAX SPIT AT OBJECT = V-SPIT>
+<SYNTAX SPIT ON OBJECT = V-SPIT>
+<VERB-SYNONYM SPIT RETCH VOMIT>
+
+<SYNTAX STAND = V-STAND>
+<SYNTAX STAND UP OBJECT (FIND RLANDBIT) = V-STAND>
+<SYNTAX STAND IN OBJECT = V-BOARD PRE-BOARD>
+<SYNTAX STAND ON OBJECT = V-WASTE-OF-TIME <> STAND-ON>
+<SYNTAX STAND OBJECT AGAINST OBJECT = V-RAISE>
+<VERB-SYNONYM STAND RISE>
+
+<SYNTAX START OBJECT = V-LAMP-ON>
+<SYNTAX START UP OBJECT = V-LAMP-ON>
+
+<SYNTAX STOP = V-STOP>
+<SYNTAX STOP OBJECT = V-STOP>
+<VERB-SYNONYM STOP BLOCK PREVENT STAY>
+
+<SYNTAX STRAIGHTEN OBJECT = V-STRAIGHTEN>
+<VERB-SYNONYM STRAIGHTEN CENTER>
+
+<SYNTAX STRIP = V-STRIP>
+<VERB-SYNONYM STRIP UNDRESS>
+
+<SYNTAX SWIM = V-SWIM>
+<SYNTAX SWIM OBJECT = V-SWIM>
+<SYNTAX SWIM IN OBJECT = V-SWIM>
+<SYNTAX SWIM TO OBJECT = V-SWIM-TO>
+<VERB-SYNONYM SWIM WADE>
+
+<SYNTAX SWING OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE) = V-SWING>
+<SYNTAX SWING OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE)
+	AT OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) = V-SWING>
+<VERB-SYNONYM SWING THRUST>
+
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (ON-GROUND IN-ROOM MANY) = V-TAKE PRE-TAKE>
+<SYNTAX TAKE IN OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-BOARD PRE-BOARD>
+<SYNTAX TAKE OUT OBJECT (FIND RLANDBIT) (ON-GROUND) = V-DISEMBARK>
+<SYNTAX TAKE ON OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-CLIMB-ON>
+<SYNTAX TAKE UP OBJECT (FIND RLANDBIT) = V-STAND>
+<SYNTAX TAKE FOR OBJECT (FIND TAKEBIT) (ON-GROUND IN-ROOM MANY)
+	= V-TAKE PRE-TAKE>
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (CARRIED IN-ROOM MANY)
+	OUT OBJECT = V-TAKE PRE-TAKE>
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (CARRIED IN-ROOM MANY)
+	OFF OBJECT = V-TAKE PRE-TAKE>
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (IN-ROOM CARRIED MANY)
+	FROM OBJECT = V-TAKE PRE-TAKE>
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (IN-ROOM CARRIED MANY)
+	IN OBJECT = V-TAKE PRE-TAKE>
+<SYNTAX TAKE OFF OBJECT = V-TAKE-OFF>
+<SYNTAX TAKE DOWN OBJECT (FIND RLANDBIT) = V-LOWER>
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (IN-ROOM CARRIED MANY)
+	WITH OBJECT = V-PICK-UP>
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (IN-ROOM CARRIED MANY)
+	BEHIND OBJECT = V-PULL-BEHIND>
+<SYNTAX TAKE OBJECT ON OBJECT = V-SEND>
+<SYNTAX TAKE OVER OBJECT (FIND RLANDBIT) = V-TAKE-OVER>
+<SYNTAX TAKE DRESSED OBJECT (FIND WEARABLE) = V-WEAR>
+<SYNTAX TAKE UNDRESSED OBJECT (FIND RLANDBIT) = V-STRIP>
+<VERB-SYNONYM TAKE GRAB CATCH GET ;HOLD CARRY SNATCH SELECT LUNGE TACKLE>
+
+<SYNTAX TASTE OBJECT (HELD CARRIED ON-GROUND IN-ROOM MANY) = V-TASTE>
+<VERB-SYNONYM TASTE SAMPLE>
+
+<NEW-ADD-WORD "TAUGHT" VERB <VOC "TEACH"> ,PAST-TENSE>
+
+<SYNTAX TEACH OBJECT = V-TEACH>
+<SYNTAX TEACH OBJECT OBJECT = V-TEACH>
+
+<SYNTAX TEAR OBJECT (FIND WEARABLE) (HELD CARRIED) = V-TEAR>
+<SYNTAX TEAR UP OBJECT (FIND WEARABLE) (HELD CARRIED) = V-TEAR>
+<SYNTAX TEAR OBJECT (FIND WEARABLE) (HELD CARRIED)
+	UP OBJECT (FIND RLANDBIT) = V-TEAR>
+<SYNTAX TEAR OBJECT (FIND WEARABLE) (HELD CARRIED) IN OBJECT = V-TEAR>
+<VERB-SYNONYM TEAR RIP SHRED REND>
+
+<SYNTAX TELL OBJECT (FIND PERSON) (IN-ROOM MANY) = V-TELL>
+<SYNTAX TELL OBJECT ABOUT OBJECT (MOBY) = V-TELL-ABOUT PRE-TELL-ABOUT>
+<SYNTAX TELL OBJECT OBJECT = V-REPLY>
+<SYNTAX TELL ABOUT OBJECT (MOBY) = V-TELL-ME-ABOUT>
+
+<SYNTAX THANK OBJECT = V-THANK>
+<SYNTAX THANK = V-THANK>
+<VERB-SYNONYM THANK THANKS>
+
+<SYNTAX THOU = V-THOU>
+
+<SYNTAX THROW OBJECT = V-THROW PRE-THROW>
+<SYNTAX THROW OBJECT AT OBJECT (ON-GROUND IN-ROOM) = V-THROW PRE-THROW>
+<SYNTAX THROW OBJECT TO OBJECT (ON-GROUND IN-ROOM) = V-THROW PRE-THROW>
+<SYNTAX THROW OBJECT OFF OBJECT = V-THROW-OFF PRE-THROW>
+<SYNTAX THROW OBJECT OVER OBJECT = V-THROW-OFF PRE-THROW>
+<SYNTAX THROW OBJECT OUT OBJECT = V-THROW-OFF PRE-THROW>
+<SYNTAX THROW OBJECT THROUGH OBJECT (ON-GROUND IN-ROOM) = V-THROW PRE-THROW>
+<SYNTAX THROW OBJECT DOWN OBJECT = V-THROW PRE-THROW>
+<SYNTAX THROW OBJECT IN OBJECT = V-THROW PRE-THROW>
+<SYNTAX THROW OBJECT ON OBJECT = V-THROW PRE-THROW>
+<SYNTAX THROW AWAY OBJECT = V-DROP PRE-DROP>
+<SYNTAX THROW OBJECT AWAY OBJECT (FIND RLANDBIT) = V-DROP PRE-DROP>
+<SYNTAX THROW OBJECT OVERBOARD OBJECT (FIND RLANDBIT) = V-THROW-OFF PRE-THROW>
+<VERB-SYNONYM THROW HURL TOSS PITCH>
+
+<SYNTAX TIE OBJECT = V-TIE>
+<SYNTAX TIE OBJECT TOGETHER OBJECT (FIND RLANDBIT) = V-TIE>
+<SYNTAX TIE OBJECT TO OBJECT = V-TIE>
+<SYNTAX TIE OBJECT AROUND OBJECT = V-TIE>
+<SYNTAX TIE OBJECT IN OBJECT = V-MAKE>
+<SYNTAX TIE OBJECT ON OBJECT = V-TIE>
+<SYNTAX TIE UP OBJECT (FIND PERSON) (ON-GROUND IN-ROOM) WITH OBJECT
+	(FIND TOOLBIT) (ON-GROUND IN-ROOM HELD CARRIED HAVE) = V-TIE-UP>
+<VERB-SYNONYM TIE LASH KNOT LOOP WRAP FASTEN ATTACH HOOK CONNECT STRAP>
+
+<SYNTAX TIME = V-TIME>
+<VERB-SYNONYM TIME T>
+
+<SYNTAX TORTURE OBJECT = V-TORTURE>
+
+<SYNTAX TOUCH OBJECT = V-RUB>
+<SYNTAX TOUCH OBJECT WITH OBJECT = V-RUB>
+<SYNTAX TOUCH OBJECT TO OBJECT = V-SRUB PRE-SRUB>
+<VERB-SYNONYM TOUCH FEEL PAT PET RUB SQUEEZE>
+
+<SYNTAX TRADE OBJECT (HELD CARRIED HAVE) WITH OBJECT (FIND PERSON) = V-TRADE>
+<SYNTAX TRADE OBJECT (HELD CARRIED HAVE) FOR OBJECT = V-TRADE>
+<SYNTAX TRADE OBJECT (HELD CARRIED HAVE) = V-TRADE>
+
+<NEW-ADD-WORD "TRAINED" VERB <VOC "TRAIN"> ,PAST-TENSE>
+<VOC "TRAINED" ADJ> ;"kludge per SWG"
+
+<SYNTAX TRAIN AT OBJECT = V-TRAIN>
+<SYNTAX TRAIN IN OBJECT = V-TRAIN>
+
+<SYNTAX TRANSLATE = V-TRANSLATE>
+<VERB-SYNONYM TRANSLATE INTERPRET>
+
+<SYNTAX TRIP OBJECT = V-TRIP>
+
+<SYNTAX TURN OBJECT TO OBJECT = V-TURN>
+<SYNTAX TURN OBJECT = V-TURN>
+<SYNTAX TURN TO OBJECT = V-TURN>
+<SYNTAX TURN OBJECT OBJECT = V-TURN>
+<SYNTAX TURN ON OBJECT (HELD CARRIED ON-GROUND IN-ROOM TAKE) = V-LAMP-ON>
+<SYNTAX TURN OFF OBJECT (HELD CARRIED ON-GROUND IN-ROOM TAKE) = V-LAMP-OFF>
+<SYNTAX TURN OVER OBJECT = V-TURN-OVER> 
+<SYNTAX TURN AROUND OBJECT (FIND RLANDBIT) = V-TURN-AROUND>
+<SYNTAX TURN UP OBJECT = V-LAMP-ON>
+<SYNTAX TURN OBJECT BY OBJECT = V-STEER-BY>
+<SYNTAX TURN BY OBJECT = V-STEER-BY>
+<SYNTAX TURN TOWARD OBJECT = V-TURN-TOWARD>
+<SYNTAX TURN FOR OBJECT = V-TURN-TOWARD>
+<SYNTAX TURN OBJECT TOWARD OBJECT = V-TURN-TOWARD>
+<SYNTAX TURN OBJECT AWAY OBJECT = V-TURN-AWAY>
+<SYNTAX TURN IN OBJECT = V-TURN-TOWARD>
+<SYNTAX TURN AWAY OBJECT = V-TURN-AWAY>
+<VERB-SYNONYM TURN TWIST FLIP STEER SET PILOT HEAD FACE>
+
+<NEW-ADD-WORD "UNLOCKED" VERB <VOC "UNLOCK"> ,PAST-TENSE>
+
+<SYNTAX UNLOCK OBJECT (ON-GROUND IN-ROOM) = V-UNLOCK>
+<SYNTAX UNLOCK OBJECT (ON-GROUND IN-ROOM)
+	WITH OBJECT (HELD CARRIED HAVE) = V-UNLOCK>
+<VERB-SYNONYM UNLOCK UNBAR UNBOLT>
+
+<SYNTAX UNPLUG OBJECT = V-UNPLUG>
+<SYNTAX UNPLUG OBJECT FROM OBJECT = V-UNTIE>
+<SYNTAX UNPLUG OBJECT WITH OBJECT = V-PRY PRE-PRY>
+<VERB-SYNONYM UNPLUG UNSCREW>
+
+<SYNTAX UNTIE OBJECT (ON-GROUND IN-ROOM HELD CARRIED) = V-UNTIE>
+<SYNTAX UNTIE OBJECT (ON-GROUND IN-ROOM HELD CARRIED) FROM OBJECT = V-UNTIE>
+<VERB-SYNONYM UNTIE UNLASH UNWRAP FREE UNFASTEN UNATTACH UNHOOK
+	      DISCONNECT DETACH>
+
+<SYNTAX USE OBJECT (HELD CARRIED HAVE) = V-USE>
+<VERB-SYNONYM USE EMPLOY WIELD>
+
+<SYNTAX WAIT = V-WAIT>
+<SYNTAX WAIT OBJECT = V-WAIT>
+<SYNTAX WAIT FOR OBJECT (MOBY) = V-WAIT-FOR>
+<VERB-SYNONYM WAIT Z>
+
+<SYNTAX WAKE OBJECT (FIND RLANDBIT) = V-WAKE>
+<SYNTAX WAKE UP OBJECT (FIND RLANDBIT) = V-WAKE>
+<VERB-SYNONYM WAKE AWAKE ROUSE REVIVE>
+
+<SYNTAX WALK OBJECT = V-WALK>
+<SYNTAX WALK = V-LEAVE>
+<SYNTAX WALK IN OBJECT (MOBY) (FIND RLANDBIT) = V-THROUGH PRE-THROUGH>
+<SYNTAX WALK ON OBJECT = V-STEP-ON>
+<SYNTAX WALK OVER OBJECT = V-LEAP>
+<SYNTAX WALK THROUGH OBJECT (MOBY) = V-THROUGH PRE-THROUGH>
+<SYNTAX WALK AROUND OBJECT = V-WALK-AROUND>
+<SYNTAX WALK UP OBJECT (ON-GROUND IN-ROOM) = V-CLIMB-UP>
+<SYNTAX WALK DOWN OBJECT (ON-GROUND IN-ROOM) = V-CLIMB-DOWN>
+<SYNTAX WALK TO OBJECT (MOBY) = V-WALK-TO>
+<SYNTAX WALK UNDER OBJECT (FIND RLANDBIT) = V-WALK-UNDER>
+<SYNTAX WALK AWAY OBJECT (FIND RLANDBIT) = V-LEAVE>
+<SYNTAX WALK OBJECT ON OBJECT = V-DRIVE-ON>
+<SYNTAX WALK OBJECT OVER OBJECT = V-DRIVE-ON>
+<SYNTAX WALK OBJECT OBJECT = V-DRIVE-TO>
+<SYNTAX WALK BEHIND OBJECT = V-HIDE-BEHIND>
+<VERB-SYNONYM WALK GO RUN PROCEED STEP>
+
+<SYNTAX WARN OBJECT = V-WARN>
+<SYNTAX WARN OBJECT ABOUT OBJECT = V-WARN>
+<VERB-SYNONYM WARN CAUTION>
+
+<SYNTAX WAVE OBJECT (HELD CARRIED) = V-WAVE>
+<SYNTAX WAVE AT OBJECT = V-WAVE-AT>
+<SYNTAX WAVE TO OBJECT = V-WAVE-AT>
+<SYNTAX WAVE OBJECT (HELD CARRIED) AT OBJECT = V-WAVE>
+<VERB-SYNONYM WAVE ;MOTION BECKON>
+
+<SYNTAX WEAR OBJECT (FIND WEARABLE)
+	(HELD CARRIED ON-GROUND IN-ROOM HAVE TAKE MANY)
+	 = V-WEAR>
+
+<SYNTAX WEDGE OBJECT WITH OBJECT = V-WEDGE>
+<SYNTAX WEDGE OBJECT IN OBJECT = V-SWEDGE PRE-SWEDGE>
+<SYNTAX WEDGE OBJECT BETWEEN OBJECT = V-SWEDGE PRE-SWEDGE>
+<VERB-SYNONYM WEDGE PROP>
+
+<SYNTAX WINK AT OBJECT (FIND PERSON) = V-WINK>
+
+;<SYNTAX WRITE OBJECT = V-WRITE PRE-WRITE>
+;<SYNTAX WRITE OBJECT ON OBJECT (HELD CARRIED) = V-WRITE PRE-WRITE>
+;<SYNTAX WRITE OBJECT IN OBJECT (HELD CARRIED) = V-WRITE PRE-WRITE>
+;<SYNTAX WRITE ON OBJECT (HELD CARRIED) = V-WRITE-ON PRE-WRITE-ON>
+
+<SYNTAX WRITE IN OBJECT (HELD CARRIED) = V-WRITE>
+<SYNTAX WRITE ON OBJECT (HELD CARRIED)
+	WITH OBJECT (FIND TOOLBIT) = V-WRITE>
+<SYNTAX WRITE IN OBJECT (HELD CARRIED)
+	WITH OBJECT (FIND TOOLBIT) = V-WRITE>
+<VERB-SYNONYM WRITE PRINT INSCRIBE SCRIBE>
+
+<SYNTAX YAWN = V-YAWN>
+
+<SYNTAX YELL AT OBJECT = V-YELL-AT>
+<SYNTAX YELL TO OBJECT = V-YELL-AT>
+<SYNTAX YELL FOR OBJECT = V-ASK-FOR PRE-ASK-FOR>
+<SYNTAX YELL = V-YELL>
+<SYNTAX YELL OBJECT = V-YELL>
+<VERB-SYNONYM YELL SCREAM SHOUT>
+
+<SYNTAX YES = V-YES>
+<VERB-SYNONYM YES Y OKAY OK>
+
+"JAPANESE VOCABULARY"
+
+<SYNTAX DOMO = V-DOMO>	;"thank you"
+<SYNTAX DOMO ARIGATO OBJECT (FIND RLANDBIT) = V-DOMO>
+
+<SYNTAX DOZO = V-DOZO>	;"please"
+
+<SYNTAX GENKI DESU OBJECT (FIND RLANDBIT) = V-GENKI-DESU>
+
+<SYNTAX GOMEN NASAI OBJECT (FIND RLANDBIT) = V-GOMEN-NASAI>
+
+<SYNTAX HAI = V-HAI>	;"yes"
+
+<SYNTAX ISOGI = V-ISOGI>	;"hurry"
+
+<SYNTAX IYE = V-IYE>	;"no"
+
+<SYNTAX KINJIRU = V-KINJIRU>	;"forbidden/stop"
+
+<SYNTAX KONNICHI WA OBJECT (FIND RLANDBIT) = V-KONNICHI-WA> ;"good day"
+<SYNTAX KONBANWA = V-KONBANWA> ;"good evening"
+
+<SYNTAX MIZU = V-MIZU>	;"water"
+
+<SYNTAX NEH = V-NEH> ;"mumble"
+
+<SYNTAX NIHON GO OBJECT = V-NIHON-GO-GA>	;"i don't speak j. very well"
+<SYNTAX NIHON GA OBJECT = V-NIHON-GO-GA>
+
+<SYNTAX TEKI = V-TEKI>	;"enemy"
+
+<SYNTAX TOMO = V-TOMO>	;"friend"
+
+<SYNTAX WAKARIMASU = V-WAKARIMASU>	;"i understand"
diff --git a/verbs.zil b/verbs.zil
new file mode 100644
index 0000000..80ed766
--- /dev/null
+++ b/verbs.zil
@@ -0,0 +1,4180 @@
+"VERBS for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc.  All Rights Reserved."
+
+<FILE-FLAGS SENTENCE-ENDS?>
+
+<BEGIN-SEGMENT 0>
+
+<CONSTANT J-SHOOT-FRIEND 255>
+
+<DEFMAC B-NOT-STANDING? ()
+	'<FSET? ,BLACKTHORNE ,SITTING>>
+
+<DEFMAC B-STANDING? ()
+	'<NOT <FSET? ,BLACKTHORNE ,SITTING>>>
+
+;<GLOBAL LOAD-MAX 150>
+<GLOBAL LOAD-ALLOWED 150>
+
+;"stuff to try to save space"
+
+<GLOBAL PERIOD		".|">
+<GLOBAL I-DONT-THINK-THAT "I don't think that ">
+<GLOBAL IT-LOOKS-LIKE	"It looks like ">
+<GLOBAL IT-IS-ALREADY	"It's already ">
+<GLOBAL TOO-DARK	"It's too dark to see!|">
+<GLOBAL NOTHING-HAPPENS "Nothing happens.|">
+<GLOBAL GOOD-TRICK	"That would be a good trick.|">
+<GLOBAL WASTE-OF-TIME	"That would be a waste of time.|">
+<GLOBAL THERE-IS-NOTHING "There is nothing ">
+<GLOBAL NO-ROOM		"There's no room.">
+<GLOBAL THERES-NOTHING-TO "There's nothing to ">
+<GLOBAL YOU-ARE		"You already are">
+<GLOBAL YOU-HAVE	"You already have ">
+<GLOBAL YOU-ARE-NOW	"You are now ">
+<GLOBAL YOU-CANT	"You can't ">
+<GLOBAL YOU-FIND-NOTHING "You find nothing">
+<GLOBAL YOU-HAVE-TO	"You'll have to ">
+
+;<ROUTINE DONT-HAVE-THAT ()
+	 <TELL ,YOU-DONT-HAVE "that" ,PERIOD>>
+
+<ROUTINE YOULL-HAVE-TO (STR)
+	 <TELL ,YOU-HAVE-TO .STR " first!" CR>>
+
+<ROUTINE TO-A-PRSO? ()
+	 <HOW-DO-YOU> <A-PRSO?>>
+
+<ROUTINE CANT-GO ()
+	 <TELL ,YOU-CANT "go that way." CR>>
+
+<ROUTINE NOT-HOLDING (OBJ)
+	 <THIS-IS-IT .OBJ>
+	 <TELL G"You aren't ""holding " THE .OBJ ,PERIOD>>
+
+<ROUTINE ITS-EMPTY ()
+	 <TELL CTHE ,PRSO " is empty" ,PERIOD>>
+
+<ROUTINE ITS-ALREADY-X (X)
+	 <TELL CTHE ,PRSO " is already " .X ,PERIOD>>
+
+<ROUTINE ALREADY-OPEN ()
+	 <ITS-ALREADY-X "open">>
+
+<ROUTINE ALREADY-CLOSED ()
+	 <ITS-ALREADY-X "closed">>
+
+<ROUTINE WITH-PRSI? ()
+	 <TELL "With "><A-PRSI?>>
+
+<ROUTINE TELL-OPEN-CLOSED ("OPTIONAL" (OBJ <>))
+	 <COND (.OBJ <TELL CTHE .OBJ>)
+	       (ELSE
+		<SET OBJ ,PRSO>
+		<TELL THE ,PRSO>)>
+	 <TELL IS/ARE .OBJ " ">
+	 <OPEN-CLOSED .OBJ>>
+
+<ROUTINE OPEN-CLOSED (OBJ)
+	 <COND (<FSET? .OBJ ,OPENBIT>
+		<TELL "open">)
+	       (ELSE
+		<TELL "closed">)>
+	 <TELL ,PERIOD>>
+
+<ROUTINE THE-PRSO () <TELL THE ,PRSO ,PERIOD>>
+
+<ROUTINE A-PRSO () <TELL A ,PRSO ,PERIOD>>
+
+<ROUTINE A-PRSO? () <TELL A ,PRSO "?" CR>>
+
+<ROUTINE THE-PRSI () <TELL THE ,PRSI ,PERIOD>>
+
+;<ROUTINE A-PRSI () <TELL A ,PRSI ,PERIOD>>
+
+<ROUTINE A-PRSI? () <TELL A ,PRSI "?" CR>>
+
+<ROUTINE YOU-CANT-X-THAT ("OPT" (STR <>))
+	 <TELL ,YOU-CANT <COND (.STR .STR) (ELSE "do")> " ">
+	 <COND (<OR <NOT .STR> <NOT ,PRSO> <NOT <FSET? ,PRSO ,PERSON>>>
+		<TELL "that!" CR>)
+	       (ELSE
+		<TELL HIM/HER ,PRSO "!" CR>)>>
+
+<ROUTINE YOU-CANT-X-PRSO (STR)
+	 <TELL ,YOU-CANT .STR " ">
+	 <COND (,PRSO <TELL THE ,PRSO>)
+	       (ELSE <TELL "that">)>
+	 <TELL ,PERIOD>>
+
+;<ROUTINE YOU-CANT-X-PRSI (STR)
+	 <TELL ,YOU-CANT .STR " ">
+	 <COND (,PRSI <TELL THE ,PRSI>)
+	       (ELSE <TELL "that">)>
+	 <TELL ,PERIOD>>
+
+<ROUTINE UNINTERESTED (OBJ)
+	 <COND (<FSET? .OBJ ,DEAD>
+		<TELL
+,YOU-CANT G"expect a response from a dead person!" CR>)
+	       (<EQUAL? .OBJ ,ME>
+		<TELL-YUKS>)
+	       (ELSE
+		<TELL CTHE .OBJ IS/ARE .OBJ " uninterested." CR>)>>
+
+<ROUTINE PLURAL? (OBJ)
+	 <COND (<FSET? .OBJ ,PLURAL> <RTRUE>)
+	       (ELSE <RFALSE>)>>
+
+<ROUTINE CANT-REACH-THAT ()
+	 <YOU-CANT-X-THAT "reach">>
+
+;"end of space saving stuff"
+
+;"subtitle game commands"
+
+<GLOBAL VERBOSITY 1>
+
+<GLOBAL DESCRIPTIONS " descriptions">
+
+<ROUTINE V-VERBOSE ()
+	 <SETG VERBOSITY 2>
+	 <TELL "Verbose" ,DESCRIPTIONS ,PERIOD CR>
+	 <V-LOOK>>
+
+<ROUTINE V-BRIEF ()
+	 <SETG VERBOSITY 1>
+	 <TELL "Brief" ,DESCRIPTIONS ,PERIOD>>
+
+<ROUTINE V-SUPER-BRIEF ()
+	 <SETG VERBOSITY <>>
+	 <TELL "Super-brief" ,DESCRIPTIONS ,PERIOD>>
+
+<ROUTINE V-DIAGNOSE ()
+	 <COND (<FSET? ,MARIKO ,RMUNGBIT>
+		<TELL
+"You are still in shock, your ears ringing, eyes hardly seeing, your
+face a mass of bruises and powder burns." CR>)
+	       (ELSE
+		<TELL
+"You are " <GET ,HEALTH-TELL <GETP ,BLACKTHORNE ,P?HEALTH>> ,PERIOD>)>>
+
+<GLOBAL HEALTH-TELL
+       <PTABLE
+	"suffering from scurvy, weak, and exhausted.  You are on your last
+reserves of strength"
+	"suffering from a mild case of scurvy, and very tired.  You are
+near the end of your strength"
+	"feeling better from having eaten, but still exhausted.  You are
+near the end of your strength"
+	"recovering from scurvy, but still weak"
+	"still very weak"
+	"in excellent health">>
+
+<ROUTINE V-INVENTORY ()
+	 <SETG D-BIT <- ,WEARBIT>>
+	 <COND (<NOT <DESCRIBE-CONTENTS ,WINNER
+					<>
+					<+ ,D-ALL? ,D-PARA?>>>
+		<TELL "You are empty-handed.">)>
+	 <SETG D-BIT ,WEARBIT>
+	 <DESCRIBE-CONTENTS ,WINNER
+			    <>
+			    <+ ,D-ALL? ,D-PARA?>>
+	 <SETG D-BIT <>>
+	 <CRLF>>
+
+<ROUTINE V-QUIT ("OPT" (ASK? T) (SCORE? T) "AUX" SCOR)
+	 <COND (.SCORE? <V-SCORE>)>
+	 ;<PARSER-REPORT>
+	 <COND (<OR <AND .ASK?
+			 <TELL
+G "Do you wish to ""leave the game">
+			 <YES?>>
+		    <NOT .ASK?>>
+		<QUIT>)
+	       (T
+		<TELL ,OKAY>)>>
+
+<ROUTINE V-$SCENE ()
+	 <COND (<AND <PRSO? INTNUM>
+		     <NOT <ZERO? ,P-NUMBER>>
+		     <NOT <G? ,P-NUMBER <GET ,SCENE-NAMES 0>>>>
+		<GOTO-SCENE ,P-NUMBER>)
+	       (ELSE <TELL G"Failed." CR>)>>
+
+<ROUTINE V-CHOOSE ()
+	 <COND (<ACCESSIBLE? ,STRAW>
+		<PERFORM ,V?PICK ,STRAW>
+		<RTRUE>) 
+	       (ELSE
+		<TELL "There's nothing to draw here." CR>)>>
+
+<ROUTINE V-RESTART ()
+	 <V-SCORE T>
+	 <TELL G "Do you wish to ""restart">
+	 <COND (<YES?>
+		<TELL "Restarting." CR>
+		<RESTART>
+		<TELL ,FAILED>)>>
+
+<GLOBAL OKAY "Okay.|">
+
+<GLOBAL FAILED "Failed.|">
+
+<ROUTINE FINISH ("OPT" (EOG? <>))
+	 <UPDATE-STATUS-LINE>
+	 <V-SCORE>
+	 <COND (<NOT .EOG?>
+		<SETUP-TEXT-AND-STATUS> ;"guarantee status line okay")>
+	 <CRLF>
+	 <GET-FROM-MENU "What now?"
+			<COND (.EOG? ,EOG-MENU)
+			      (ELSE ,FINISH-MENU)>
+			,FINISH-MENU-F>>
+
+<CONSTANT FINISH-MENU ;"menu when undo exists"
+	  <LTABLE
+<TABLE (PURE STRING LENGTH) "RESTORE a saved game position ">
+<TABLE (PURE STRING LENGTH) "RESTART the game from the beginning ">
+<TABLE (PURE STRING LENGTH) "QUIT this session of the game ">
+<TABLE (PURE STRING LENGTH) "HINT for something confusing ">
+<TABLE (PURE STRING LENGTH) "UNDO the last move ">>>
+
+<CONSTANT EOG-MENU ;"menu when undo exists"
+	  <LTABLE
+<TABLE (PURE STRING LENGTH) "RESTORE a saved game position ">
+<TABLE (PURE STRING LENGTH) "RESTART the game from the beginning ">
+<TABLE (PURE STRING LENGTH) "QUIT this session of the game ">
+<TABLE (PURE STRING LENGTH) "HINT for something confusing ">>>
+
+<ROUTINE FINISH-MENU-F (WHICH MENU)
+	 <COND (<EQUAL? .WHICH 1 ;RESTORE>
+		<COND (<RESTORE>
+		       <TELL ,OKAY>)
+		      (T
+		       <RESET-MARGIN>
+		       <CLEAR ,S-TEXT>
+		       <TELL ,FAILED>)>)
+	       (<EQUAL? .WHICH 2 ;RESTART>
+		<RESTART>
+		<RESET-MARGIN>
+		<CLEAR ,S-TEXT>
+		<TELL ,FAILED>)
+	       (<EQUAL? .WHICH 3 ;QUIT>
+		<COND (<EQUAL? .MENU ,EOG-MENU>
+		       <QUIT>)
+		      (ELSE
+		       <V-QUIT>)>
+		<RESET-MARGIN>
+		<CLEAR ,S-TEXT>)
+	       (<EQUAL? .WHICH 4 ;HINT>
+		<V-HINT>)
+	       (<EQUAL? .WHICH 5 ;UNDO>
+		<V-UNDO>
+		<RESET-MARGIN>
+		<CLEAR ,S-TEXT>)>
+	 <RFALSE>>
+
+<ROUTINE V-RESTORE ()
+	 <COND (<RESTORE> <RTRUE>)
+	       (T
+		<TELL ,FAILED>)>>
+
+<GLOBAL RESTORED? <>>	;"result of last RESTORE"
+
+<ROUTINE V-SAVE ("AUX" X)
+	 <PUTB ,G-INBUF 2 0>	;"make sure AGAIN gets fooled"
+	 <SET X <SAVE>>
+	 <SETG RESTORED? <>>
+	 <COND (<QUEUED? I-SETUP-ANSWER>
+		<I-SETUP-ANSWER> ;"because interrupts won't run")>
+	 <COND (<ZERO? .X>
+		<TELL ,FAILED>)
+	       (<EQUAL? .X 1>
+		<TELL ,OKAY>)
+	       (<EQUAL? .X 2 3>
+		<COND (<ZERO? <WINGET ,S-FULL ,WHIGH>>
+		       <SET X 3>)>
+		<SETG RESTORED? .X>
+		<REPAINT-DISPLAY <COND (<EQUAL? .X 2> T)>>
+		<CRLF>
+		<V-FIRST-LOOK>)>>
+
+<ROUTINE V-UNDO ("AUX" VAL)
+	 <COND (<SET VAL <IRESTORE>>
+		<INIT-STATUS-LINE>)
+	       (ELSE ,FAILED)>>
+
+<CONSTANT TOTAL-SCORE 84>
+<CONSTANT SCORE-FACTOR 5>
+
+<ROUTINE V-SCORE ("OPTIONAL" (ASK? T) "AUX" S)
+	 <SET S <GETPT <GET ,SCENE-LOCS ,SCENE> ,P?SCORE>>
+	 <TELL
+"Your score is " N <* ,SCORE-FACTOR <GETB .S 0>> " of a possible "
+N <* ,SCORE-FACTOR <GETB .S 1>> " in this scene, and "
+N <* ,SCORE-FACTOR ,SCORE> " out of " N <* ,SCORE-FACTOR ,TOTAL-SCORE>
+" overall, in " N ,MOVES " move">
+	 <COND (<NOT <1? ,MOVES>> <TELL "s">)>
+	 <TELL ". You have now achieved a rank of "
+	       <GET ,RANKINGS <+ 1 </ ,SCORE <GET ,RANKINGS 0>>>>>
+	 <TELL ,PERIOD>
+	 <RTRUE>>
+
+<GLOBAL RANKINGS
+	<PLTABLE
+	 "barbarian"		;"0"
+	 "peasant"		;"10"
+	 "samurai"		;"20"
+	 "daimyo"		;"30"
+	 "hatamoto"		;"40"
+	 "hatamoto"		;"50"
+	 "hatamoto"		;"60"
+	 "Regent"		;"70"
+	 "Kwampaku"		;"80"
+	 "Taiko"		;"90"
+	 "Shogun"		;"100">>
+
+<ROUTINE V-SCRIPT ()
+	<DIROUT ,D-PRINTER-ON>
+	<COND (<FLAG-ON? ,F-SCRIPT>
+	       <DIROUT ,D-SCREEN-OFF>
+	       <TELL CR
+"Start of a transcript of " ,SHOGUN-NAME ,PERIOD>
+	       <V-VERSION>
+	       <DIROUT ,D-SCREEN-ON>)>>
+
+<ROUTINE V-UNSCRIPT ()
+	<COND (<FLAG-ON? ,F-SCRIPT>
+	       <DIROUT ,D-SCREEN-OFF>
+	       <TELL "End of transcript" ,PERIOD>
+	       <DIROUT ,D-SCREEN-ON>)>
+	<DIROUT ,D-PRINTER-OFF>
+	<RTRUE>>
+
+<CONSTANT SHOGUN-NAME "SHOGUN">
+
+<ROUTINE V-VERSION ("OPT" (C? <>))
+	 <COND (.C? <CURSET <+ 1 <* 2 ,FONT-Y>> 1>)>
+	 <HLIGHT ,H-BOLD>
+	 <COND (.C? <DIROUT ,D-TABLE-ON ,DIROUT-TABLE>)>
+	 <TELL ,SHOGUN-NAME>
+	 <COND (.C? <PRINT-CENTER-TABLE>)>
+	 <HLIGHT ,H-NORMAL>
+	 <CRLF>
+	 <COND (.C? <DIROUT ,D-TABLE-ON ,DIROUT-TABLE>)>
+	 <TELL "A Story of Japan">
+	 <COND (.C? <PRINT-CENTER-TABLE>)>
+	 <CRLF>
+	 <COND (.C? <DIROUT ,D-TABLE-ON ,DIROUT-TABLE>)>
+	 <TELL "Copyright (c) 1988 by Infocom">
+	 <COND (.C? <PRINT-CENTER-TABLE>)>
+	 <CRLF>
+	 <COND (.C? <DIROUT ,D-TABLE-ON ,DIROUT-TABLE>)>
+	 <TELL "All rights reserved.">
+	 <COND (.C? <PRINT-CENTER-TABLE>)>
+	 <CRLF>
+	 <COND (.C? <DIROUT ,D-TABLE-ON ,DIROUT-TABLE>)>
+	 <TELL ,SHOGUN-NAME " is a trademark of James Clavell">
+	 <COND (.C? <PRINT-CENTER-TABLE>)>
+	 <CRLF>
+	 <COND (.C? <DIROUT ,D-TABLE-ON ,DIROUT-TABLE>)>
+	 <TELL "Original Literary Work Copyright 1975 by James Clavell">
+	 <COND (.C? <PRINT-CENTER-TABLE>)>
+	 <CRLF>
+	 <COND (.C? <DIROUT ,D-TABLE-ON ,DIROUT-TABLE>)>
+	 <TELL "Licensed by Noble House Trading Limited, London.">
+	 <COND (.C? <PRINT-CENTER-TABLE>)>
+	 <CRLF>
+	 <COND (.C? <DIROUT ,D-TABLE-ON ,DIROUT-TABLE>)>
+	 <TELL "Release ">
+	 <PRINTN <LOWCORE ZORKID>>
+	 <TELL " / Serial number ">
+	 <LOWCORE-TABLE SERIAL 6 PRINTC>
+	 <COND (.C? <PRINT-CENTER-TABLE>)>
+	 <CRLF>
+	 <COND (.C? <DIROUT ,D-TABLE-ON ,DIROUT-TABLE>)>
+	 <TELL <GET ,MACHINES ,MACHINE> " Interpreter version "
+	       N <LOWCORE (ZVERSION 0)> "." N <LOWCORE INTVR>>
+	 <COND (.C? <PRINT-CENTER-TABLE>)>
+	 <CRLF>>
+
+<CONSTANT MACHINES
+	  <LTABLE "Debugging"
+		  "Apple IIe"
+		  "Macintosh"
+		  "Amiga"
+		  "Atari ST"
+		  "IBM"
+		  "Commodore 128"
+		  "Commodore 64"
+		  "Apple IIc"
+		  "Apple IIgs">>
+
+<ROUTINE PCENTER (STR "OPT" (STR1 <>) (STR2 <>))
+	 <DIROUT ,D-TABLE-ON ,DIROUT-TABLE>
+	 <TELL .STR>
+	 <COND (.STR1 <TELL .STR1>)>
+	 <COND (.STR2 <TELL .STR2>)>
+	 <PRINT-CENTER-TABLE>
+	 <CRLF>>	 
+
+<ROUTINE V-CREDITS ()
+	 <HLIGHT ,H-BOLD>
+	 <PCENTER ,SHOGUN-NAME>
+	 <HLIGHT ,H-NORMAL>
+	 <PCENTER "A Story of Japan">
+	 <CRLF>
+	 <PCENTER "Adapted by Dave Lebling">
+	 <CRLF>
+	 <PCENTER "Original Illustrations by Donald Langosy">
+	 <COND (<APPLE?>
+		<PCENTER "Translated by Tanya Allan">)
+	       (<EQUAL? ,MACHINE ,IBM>
+		<PCENTER "Translated by Donna Dennison">)>
+	 <CRLF>
+	 <PCENTER "Interpreters by Tim Anderson, Duncan Blanchard,">
+	 <PCENTER "J. D. Arnold, and Scott Fray">
+	 <CRLF>
+	 <PCENTER "English Parser by Stu Galley and Tim Anderson">
+	 <CRLF>
+	 <PCENTER "Quality control by Patti Pizer, Shaun Kelly,">
+	 <PCENTER "Steve Watkins, Adam Levesque, Christian Anthony,">
+	 <PCENTER "Liz Jones, Adam Glass, and many others">
+	 <CRLF>>
+
+<ROUTINE V-$VERIFY ()
+	 <COND (<AND <PRSO? ,INTNUM>
+		     <EQUAL? ,P-NUMBER 1564>>
+		<TELL N ,SERIAL CR>)
+	       (,PRSO
+		<DONT-UNDERSTAND>
+		;<TELL ,NOT-RECOGNIZED CR>)
+	       (ELSE
+		<TELL "Verifying..." CR>
+		<COND (<VERIFY> <TELL "The disk is correct." CR>)
+		      (T <TELL CR "** Disk Failure **" CR>)>)>>
+
+;"subtitle real verbs"
+
+<ROUTINE V-WAKE ()
+	 <COND (<PRSO? ,ROOMS>
+		<NEW-PRSO ,ME>
+		<RTRUE>)
+	       (T
+		<TELL
+,I-DONT-THINK-THAT THE ,PRSO IS/ARE ,PRSO " sleeping." CR>)>>
+
+<ROUTINE V-ANSWER ()
+	 <COND (<OR ,OMI-QUESTION
+		    ,YABU-QUESTION
+		    <AND ,QCONTEXT
+			 <ACCESSIBLE? ,QCONTEXT>>>
+		<COND (,OMI-QUESTION <TELL CTHE ,OMI>)
+		      (,YABU-QUESTION <TELL CTHE ,YABU>)
+		      (ELSE <TELL CTHE ,QCONTEXT>)>
+		<TELL
+" seems to be expecting a more responsive answer." CR>)
+	       (ELSE
+		<TELL "Nobody is awaiting your answer." CR>
+		<END-QUOTE>)>>
+
+"V-ASK-ABOUT -- transform into PRSO, TELL ME ABOUT PRSI"
+
+<ROUTINE PRE-ASK-ABOUT ("AUX" P)
+	 <COND (<AND ,QCONTEXT
+		     <IN? ,QCONTEXT ,HERE>
+		     <NOT <PRSO? ,QCONTEXT>>
+		     <NOT ,PRSI>>
+		<PERFORM ,PRSA ,QCONTEXT ,PRSO>
+		<RTRUE>)
+	       (<AND <NOT ,PRSI>
+		     <SET P <FIND-IN ,HERE ,PERSON>>
+		     <NOT <EQUAL? .P ,WINNER>>>
+		<PERFORM-PRSA .P ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-ASK-ABOUT ()
+	 <COND (<TRY-QCONTEXT?>
+		<RTRUE>)
+	       (<PRSO? ,ME>
+		<NEW-VERB ,V?TELL>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,PERSON>
+		<NEW-WINNER-PRSO ,V?TELL-ME-ABOUT ,PRSI>
+		<RTRUE>)
+	       (T
+		<NEW-VERB ,V?TELL>
+		<RTRUE>)>>
+
+<ROUTINE FIND-IN (WHERE WHAT "OPT" (WHAT-NOT <>) "AUX" W)
+	 <MAP-CONTENTS (W .WHERE)
+		       (END <RFALSE>)
+		 <COND (<AND <FSET? .W .WHAT>
+			     <VISIBLE? .W>>
+			<COND (<AND <EQUAL? .WHAT ,PERSON>
+				    <EQUAL? .W ,WINNER>>)
+			      (<OR <NOT .WHAT-NOT>
+				   <NOT <FSET? .W .WHAT-NOT>>>
+			       <RETURN .W>)>)>>>
+
+"V-ASK-FOR -- transform into PRSO, GIVE PRSI TO ME"
+
+<ROUTINE PRE-ASK-FOR ()
+	 <PRE-ASK-ABOUT>>
+
+<ROUTINE V-ASK-FOR ()
+	 <COND (<TRY-QCONTEXT?>
+		<RTRUE>)
+	       (<PRSO? ,ME ,PLAYER>
+		<PERFORM ,V?TAKE ,PRSI>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,PERSON>
+		<NEW-WINNER-PRSO ,V?GIVE ,PRSI ,ME>
+		<RTRUE>)
+	       (T
+		<TELL
+"It's unlikely that " THE ,PRSO " will oblige." CR>)>>
+
+<ROUTINE PRE-ATTACK ("AUX" W)
+	 <COND (,PRSI <RFALSE>)
+	       (<SET W <FIND-IN ,WINNER ,WEAPONBIT ,WEARBIT>>
+		<PERFORM ,PRSA ,PRSO .W>
+		<RTRUE>)
+	       (ELSE <RFALSE>)>>
+
+<ROUTINE V-ATTACK ()
+	 <IKILL "attack">>
+
+<ROUTINE V-HIT ()
+	 <IKILL "hit">>
+
+<ROUTINE V-BITE ()
+	 <HACK-HACK "Biting">>
+
+<ROUTINE PRE-BOARD ("AUX" AV DIR)
+	 <SET AV <LOC ,WINNER>>
+	 <COND (<PRSO? ,ROOMS> <RFALSE>)
+	       (<FSET? ,PRSO ,VEHBIT>
+		<COND (<HELD? ,PRSO>
+		       <TELL
+,YOU-HAVE-TO "put " THE ,PRSO " down first." CR>)
+		      (<EQUAL? .AV ,PRSO>
+		       <YOU-ARE-IN .AV>)
+		      (<AND <FSET? .AV ,VEHBIT>
+			    <HELD? ,PRSO .AV>>
+		       <TELL ,YOU-HAVE-TO "leave " THE .AV " first" ,PERIOD>)
+		      (T
+		       <RFALSE>)>)
+	       (<AND <IN? ,PRSO ,ROOMS>
+		     <SET DIR <NEXT-ROOM? ,PRSO>>>
+		<DO-WALK .DIR>
+		<RTRUE>)
+	       (T
+		<TELL ,YOU-CANT "get ">
+		<COND (<FSET? ,PRSO ,PERSON> <TELL "onto ">)
+		      (ELSE <TELL "into ">)>
+		<TELL THE ,PRSO "!" CR>)>
+	 <RFATAL>>
+
+<ROUTINE YOU-ARE-IN (AV)
+	 <TELL ,YOU-ARE
+	       <COND (<FSET? .AV ,SURFACEBIT> " on ")
+		     (ELSE " in ")>
+	       THE .AV "!" CR>>
+
+<ROUTINE V-BOARD ("AUX" AV)
+	 <TELL ,YOU-ARE-NOW>
+	 <COND (<FSET? ,PRSO ,SURFACEBIT> <TELL "on ">)
+	       (ELSE <TELL "in ">)>
+	 <THE-PRSO>
+	 <MOVE ,WINNER ,PRSO>
+	 <APPLY <GETP ,PRSO ,P?ACTION> ,M-ENTER>
+	 <RTRUE>>
+
+<ROUTINE V-BURN ()
+	 <COND (<NOT ,PRSI>
+		<TELL "Your gaze is insufficient." CR>)
+	       (T
+		<WITH-PRSI?>)>>
+
+<ROUTINE V-CHASTISE ()
+	 <TELL
+"Use prepositions instead: LOOK AT the object, LOOK INSIDE it,
+LOOK UNDER it, etc." CR>>
+
+<ROUTINE V-CLIMB-DOWN ()
+	 <COND (<PRSO? ,ROOMS>
+		<DO-WALK ,P?DOWN>)
+	       (T
+		<TELL ,WASTE-OF-TIME>)>>
+
+<ROUTINE V-CLIMB-FOO ()
+	 <COND (<PRSO? ,ROOMS>
+		<DO-WALK ,P?UP>)
+	       (T
+		<TELL ,WASTE-OF-TIME>)>>
+
+<ROUTINE V-CLIMB-ON ()
+	 <COND (<AND <FSET? ,PRSO ,VEHBIT>
+		     <FSET? ,PRSO ,SURFACEBIT>>
+		<NEW-VERB ,V?BOARD>
+		<RTRUE>)
+	       (T
+		<TELL ,YOU-CANT "climb onto "><A-PRSO>)>>
+
+<ROUTINE V-CLIMB-OVER ()
+	 <YOU-CANT-X-THAT>>
+
+<ROUTINE V-CLIMB-UP ()
+	 <COND (<PRSO? ,ROOMS>
+		<DO-WALK ,P?UP>)
+	       (T
+		<TELL ,WASTE-OF-TIME>)>>
+
+<ROUTINE V-CLOSE ()
+	 <COND (<AND <NOT <FSET? ,PRSO ,OPENBIT>>
+		     <FSET? ,PRSO ,OPENABLE>>
+		<ALREADY-CLOSED>
+		;<TELL CTHE ,PRSO " is already closed." CR>)
+	       (<OR <FSET? ,PRSO ,SURFACEBIT>
+		    <AND <NOT <FSET? ,PRSO ,CONTBIT>>
+			 <NOT <FSET? ,PRSO ,DOORBIT>>>>
+		<TELL "There's no way to close "><THE-PRSO>)
+	       (<FSET? ,PRSO ,PERSON>
+		<TELL "Huh?" CR>)
+	       (<NOT <EQUAL? <GETP ,PRSO ,P?CAPACITY> 0>>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <FCLEAR ,PRSO ,OPENBIT>
+		       <TELL "Closed">
+		       <IN-DARK?>)
+		      (T
+		       <ALREADY-CLOSED>)>)
+	       (<FSET? ,PRSO ,DOORBIT>
+		<CLOSE-A-DOOR>)
+	       (T
+		<YOU-CANT-X-THAT "close">)>>
+
+<ROUTINE CLOSE-A-DOOR ()
+	 <COND (<FSET? ,PRSO ,OPENBIT>
+		<OKAY-THE-PRSO-IS-NOW "closed">
+		<FCLEAR ,PRSO ,OPENBIT>)
+	       (T
+		<ALREADY-CLOSED>)>>
+
+<ROUTINE IN-DARK? ("OPT" (DIE? <>) "AUX" OLIT)
+	 <SET OLIT ,LIT>
+	 <SETG LIT <LIT? ,HERE>>
+	 <COND (<AND .OLIT <NOT ,LIT>>
+		<TELL
+", leaving you in the dark." CR>
+		<COND (.DIE?
+		       <CRLF>
+		       <TELL "Not alone, however. ">
+		       <JIGS-UP ;"this string is a duplicate of one in GOTO"
+"This is a civilized country, but nonetheless one should never assume
+the dark is safe.  Someone just grabbed you from behind and strangled
+you with a silken cord.">)
+		      (ELSE <RTRUE>)>)
+	       (ELSE <TELL ,PERIOD>)>>
+
+<ROUTINE OKAY-THE-PRSO-IS-NOW (STR)
+	 <TELL CTHE ,PRSO " is now " .STR ,PERIOD>>
+
+<ROUTINE V-COMPARE-MANY ()
+	 <COND (<EQUAL? <GET ,P-PRSO 0> 2>
+		<SETG P-MULT <>>
+		<PERFORM ,V?COMPARE <GET ,P-PRSO 1> <GET ,P-PRSO 2>>
+		<RFATAL>)
+	       (ELSE
+		<TELL "You can only compare two things." CR>)>>
+
+<ROUTINE V-WASTE-OF-TIME ()
+	 <TELL ,WASTE-OF-TIME>>
+
+<ROUTINE V-COMPARE ()
+	 <COND (ELSE
+		<TELL ,WASTE-OF-TIME>)>>
+
+;<ROUTINE V-COUNT ()
+	 <TELL ,WASTE-OF-TIME>>
+
+<ROUTINE V-CROSS ()
+	 <YOU-CANT-X-THAT "cross">>
+
+<ROUTINE V-CURSE ()
+	 <COND (<AND <PRSO? <> ROOMS YOU>
+		     <TRY-QCONTEXT?>>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,DUTCHBIT>
+		<TELL
+'PRSO " makes an anatomically impossible suggestion." CR>)
+	       (ELSE
+		<TELL
+"Fortunately, your swearing is incomprehensible.  Your manners are
+very bad, even for a barbarian." CR>)>>
+
+<ROUTINE V-CUT ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<NEW-VERB ,V?KILL>
+		<RTRUE>)
+	       (<OR <NOT ,PRSI> <NOT <FSET? ,PRSI ,WEAPONBIT>>>
+		<COND (<OR <NOT ,PRSI> <INTRINSIC? ,PRSI>>
+		       <TELL "Your body">)
+		      (ELSE
+		       <TELL CTHE ,PRSI>)>
+		<TELL
+" has an inadequate \"cutting edge.\"" CR>)
+	       (T
+		<TO-A-PRSO?>)>>
+
+<ROUTINE V-DIG ()
+	 <COND (<AND ,PRSI <FSET? ,PRSI ,TOOLBIT>>
+		<TELL
+"Digging with " THE ,PRSI " would be slow, tiring, and tedious." CR>)
+	       (<PRSO? ,GROUND>
+		<TELL "You don't have anything to dig with." CR>)
+	       (ELSE
+		<TELL ,WASTE-OF-TIME>)>>
+
+<ROUTINE V-DISEMBARK ("AUX" AV)
+	 <SET AV <LOC ,WINNER>>
+	 <COND (<OR <NOT ,PRSO>
+		    <PRSO? ,ROOMS>>
+		<COND (<AND .AV <FSET? .AV ,VEHBIT>>
+		       <NEW-PRSO .AV>
+		       <RTRUE>)
+		      ;(<FSET? ,HERE ,RWATERBIT>
+		       <DO-WALK ,P?UP>)
+		      (ELSE
+		       <TELL G"You aren't ""in anything." CR>)>)
+	       (<NOT <IN? ,WINNER ,PRSO>>
+		<TELL "You aren't in " THE ,PRSO "." CR>)
+	       (<AND .AV
+		     <FSET? .AV ,VEHBIT>>
+		<COND (<AND <NOT <EQUAL? .AV ,PRSO>>
+			    <NOT <HELD? .AV ,PRSO>>>
+		       <YOU-ARE-IN .AV>
+		       <RFATAL>)
+		      (T
+		       <MOVE ,WINNER <LOC ,PRSO>> ;"for vehicle in vehicle"
+		       <B-STAND>
+		       <TELL ,YOU-ARE-NOW "on your feet." CR>)>)
+	       (<IN? ,PRSO ,ROOMS>
+		<DO-WALK ,P?OUT>
+		<RTRUE>)
+	       (<LOC ,PRSO>
+		<NEW-VERB ,V?TAKE>
+		<RTRUE>)
+	       (ELSE
+		<TELL G"It's not in anything." CR>)>>
+
+<ROUTINE V-DRINK ("AUX" S)
+	 <YOU-CANT-X-THAT "drink">>
+
+<ROUTINE V-DRINK-FROM ("AUX" X)
+	 <COND ;(<PRSO? ,WATER>
+		<PERFORM ,V?DRINK ,PRSO>
+		<RTRUE>)
+	       (T
+		<TO-A-PRSO?>)>>
+
+<ROUTINE PRE-DROP ()
+	 <COND (<PRSO? <LOC ,WINNER>>
+		<NEW-VERB ,V?DISEMBARK>
+		<RTRUE>)>>
+
+<ROUTINE V-DROP ()
+	 <COND (<PRSO? ,ROOMS>
+		<TELL G"You aren't "G"hanging from anything." CR>)
+	       (<IDROP>
+		<TELL "Dropped." CR>)
+	       (ELSE <RTRUE>)>>
+
+<ROUTINE V-EAT ("AUX" H)
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<TELL
+"Cannibalism is not the solution." CR>)
+	       (ELSE
+		<TELL
+"Much as you may miss meat, bread, and grog, there is little
+likelihood that " A ,PRSO " will satisfy you." CR>)>>
+
+<ROUTINE V-ENTER ()
+	 <COND (<GETPT ,HERE ,P?IN>
+		<DO-WALK ,P?IN>)
+	       (ELSE
+		<V-WALK-AROUND>)>>
+
+<ROUTINE PRE-EXAMINE ("AUX" P)
+	 <COND (<NOT ,LIT> <TELL ,TOO-DARK>)
+	       (<OR <HERE? ,MAZE>
+		    <AND <HERE? ,SECRET-REDOUBT>
+			 <PRSO? MARIKO>>
+		    <AND <HERE? ,CLIFF-PATH>
+			 <PRSO? YABU RODRIGUES>
+			 <NOT <IN? ,PRSO ,HERE>>>>
+		<RFALSE>)
+	       (<SET P <GETP ,PRSO ,P?PICTURE>>
+		<MARGINAL-PIC .P>
+		<RFALSE>)>>
+
+<ROUTINE V-EXAMINE ("AUX" H)
+	 <COND (<EQUAL? ,PRSO ,HERE>
+		<PERFORM ,V?LOOK>
+		<RTRUE>)
+	       (<AND <FSET? ,PRSO ,READBIT>
+		     <GETP ,PRSO ,P?TEXT>>
+		<NEW-VERB ,V?READ>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,DOORBIT>
+		<V-LOOK-INSIDE>)
+	       (<FSET? ,PRSO ,CONTBIT>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <V-LOOK-INSIDE>)
+		      (T
+		       <THIS-IS-IT ,PRSO>
+		       <TELL G "It's closed.|">)>)
+	       (<FSET? ,PRSO ,DEAD>
+		<TELL CTHE ,PRSO " is dead." CR>)
+	       (<FSET? ,PRSO ,ABSTRACTBIT>
+		<TELL "You can't see that from here!" CR>)
+	       (T
+		<PRSO-NOTHING-SPECIAL>)>>
+
+<ROUTINE PRSO-NOTHING-SPECIAL ()
+	 <TELL G "You see nothing special about ">
+	 <THE-PRSO>>
+
+<ROUTINE V-EXIT ()
+	 <COND (,PRSO
+		<COND (<FSET? ,PRSO ,VEHBIT>
+		       <NEW-VERB ,V?DISEMBARK>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL ,YOU-CANT "exit " THE ,PRSO "." CR>)>)
+	       (<FSET? <LOC ,WINNER> ,VEHBIT>
+		<PERFORM ,V?DISEMBARK <LOC ,WINNER>>
+		<RTRUE>)
+	       (<GETPT ,HERE ,P?OUT>
+		<DO-WALK ,P?OUT>)
+	       (ELSE
+		<V-WALK-AROUND>)>>
+
+<ROUTINE V-FILL ()
+	 <COND (<NOT ,PRSI>
+		<TELL
+,THERES-NOTHING-TO "fill it with" ,PERIOD>)
+	       (T
+		<TELL-YUKS>)>>
+
+<ROUTINE V-FIND ("OPT" (WHERE <>) "AUX" L)
+	 <COND (<PRSO? ,PLAYER>
+		<TELL
+"As close as the hairs of your beard">)
+	       (<INTRINSIC? ,PRSO>
+		<TELL
+"Nearby, I'm sure">)
+	       (<IN? ,PRSO ,PLAYER>
+		<TELL "You have it">)
+	       (<OR <IN? ,PRSO ,HERE>
+		    <PRSO? ,PSEUDO-OBJECT>>
+		<TELL "Right in front of you">)
+	       (<OR <IN? ,PRSO ,LOCAL-GLOBALS>
+		    <IN? ,PRSO ,GLOBAL-OBJECTS>>
+		<CPRINT-HE/SHE ,PRSO>
+		<TELL " could be nearby">)
+	       (<SET L <LOC ,PRSO>>
+		<COND (<AND <FSET? .L ,PERSON>
+			    <VISIBLE? .L>>
+		       <TELL "I think " THE .L " has it">)
+		      (<ACCESSIBLE? ,PRSO>
+		       <TELL "It's in " THE .L>)
+		      (.WHERE
+		       <TELL "Beats me">)
+		      (T
+		       <TELL ,YOU-HAVE-TO "find " HIM/HER ,PRSO " yourself">)>)
+	       (ELSE
+		<TELL "You have no idea where to find " THE ,PRSO>)>
+	 <TELL ,PERIOD>>
+
+<ROUTINE V-FOLLOW ("AUX" TMP LP DIR)
+	 <COND (<NOT ,PRSO>
+		<TELL
+,YOU-HAVE-TO " be more specific about whom you want to follow." CR>)
+	       (<AND <SET LP <LOC ,PRSO>>
+		     <IN? .LP ,ROOMS>
+		     <SET DIR <NEXT-ROOM? .LP>>>
+		<DO-WALK .DIR>)
+	       (<IN? ,WINNER .LP>
+		<COND (ELSE
+		       <TELL
+,YOU-CANT "follow " THE ,PRSO ", because " HE/SHE ,PRSO IS/ARE ,PRSO
+" right here!" CR>)>)
+	       (<AND <IN? ,WINNER ,HERE>
+		     <IN? .LP ,HERE>
+		     <FSET? .LP ,VEHBIT>>
+		<PERFORM ,V?BOARD .LP>
+		<RTRUE>)
+	       (T
+		<TELL ,WASTE-OF-TIME>)>>
+
+<ROUTINE PRE-GIVE ()
+	 <COND (<AND <WINNER? ,PLAYER>
+		     <NOT <HELD? ,PRSO>>
+		     <NOT <FSET? ,PRSO ,PERSON>>>
+		<YOULL-HAVE-TO "get it">)>>
+
+<ROUTINE V-GIVE ()
+	 <COND (<OR <NOT <FSET? ,PRSI ,PERSON>>
+		    <FSET? ,PRSO ,PERSON>>
+		<TELL ,YOU-CANT "give " A ,PRSO " to " A ,PRSI "!" CR>)
+	       (T
+		<UNINTERESTED ,PRSI>)>>
+
+<ROUTINE V-GOODBYE ("AUX" OWINNER)
+	 <COND (,PRSO
+		<COND (<FSET? ,PRSO ,DEAD>
+		       <TELL
+,YOU-CANT G"expect a response from a dead person!" CR>)
+		      (<FSET? ,PRSO ,PERSON>
+		       <NEW-WINNER-PRSO ,PRSA>
+		       <RTRUE>)
+		      (T
+		       <TELL
+G"In this country, people who say ""\"Goodbye\" to " A ,PRSO " are
+considered barbarians." CR>)>)
+	       (T
+		<TELL "Leaving so soon?" CR>)>>
+
+<ROUTINE V-HELLO ("AUX" OWINNER)
+	 <COND (,PRSO
+		<COND (<FSET? ,PRSO ,DEAD>
+		       <TELL
+,YOU-CANT G"expect a response from a dead person!" CR>)
+		      (<FSET? ,PRSO ,PERSON>
+		       <NEW-WINNER-PRSO ,PRSA>
+		       <RTRUE>)
+		      (T
+		       <TELL
+G"In this country, people who say ""\"Hello\" to " A ,PRSO " are
+considered crazed." CR>)>)
+	       (<TRY-QCONTEXT?>
+		<RTRUE>)
+	       (T
+		<TELL "In good spirits, aren't you?" CR>)>>
+
+<ROUTINE V-HELP ()
+	 <COND (,PRSO
+		<COND (<FSET? ,PRSO ,PERSON>
+		       <TELL
+CTHE ,PRSO G " doesn't appear to ""need help." CR>)
+		      (ELSE
+		       <TELL
+"There doesn't seem to be any way to help " THE ,PRSO "." CR>)>)
+	       (<NOT <EQUAL? ,P-PRSA-WORD ,W?HINT>>
+		<TELL
+,YOU-HAVE-TO G"be more specific about ""whom you want to help." CR>)
+	       (ELSE
+		<V-HINT>)>>
+
+<ROUTINE V-HIDE ()
+	 <COND (<NOT ,PRSO>
+		<TELL "There's no place to hide here." CR>
+		<RFATAL>)
+	       (<FSET? ,PRSO ,PERSON>
+		<TELL
+"There doesn't seem any way to hide " THE ,PRSO "." CR>)
+	       (<AND ,PRSI <FSET? ,PRSI ,PERSON>>
+		<UNINTERESTED ,PRSI>)
+	       (<NOT ,PRSI>
+		<TELL ,WASTE-OF-TIME> ;"useless")>>
+
+<ROUTINE V-HIDE-BEHIND ("OPT" (STR <>))
+	 <TELL
+"There doesn't seem to be enough room ">
+	 <COND (.STR <TELL .STR>)(ELSE <TELL "behind">)>
+	 <TELL " " THE ,PRSO "." CR>>
+
+<ROUTINE V-HIDE-UNDER ()
+	 <V-HIDE-BEHIND "under">>
+
+<ROUTINE V-HIDE-FROM ()
+	 <TELL ,YOU-HAVE-TO "decide where." CR>>
+
+<ROUTINE V-KICK ()
+	 <COND (<OR <NOT <FSET? ,PRSO ,PERSON>>
+		    <FSET? ,PRSO ,DEAD>>
+		<TELL "Kicking " A ,PRSO " seems a waste of time." CR>)
+	       (<FSET? ,PRSO ,FEMALE>
+		<TELL
+G"Only a motherless coward would attack a woman!" CR>)
+	       (ELSE
+		<TELL
+"A potentially dangerous course of action!" CR>)>>
+
+<ROUTINE V-KILL ()
+	 <COND (<AND <PAST-TENSE?>
+		     <TRY-QCONTEXT?>>
+		<RTRUE>)
+	       (ELSE <IKILL "kill">)>>
+
+<ROUTINE IKILL (STR)
+	 <COND (<AND <PRSO? ,ROOMS> ,OPPONENT>
+		<PERFORM ,PRSA ,OPPONENT>
+		<RTRUE>)
+	       (<PRSO? <> ,ROOMS>
+		<TELL ,THERES-NOTHING-TO .STR " here." CR>)
+	       (<FSET? ,PRSO ,DOORBIT>
+		<TELL
+"Pounding on a door is of little use." CR>)
+	       (<OR <NOT <FSET? ,PRSO ,PERSON>>
+		    <FSET? ,PRSO ,DEAD>>
+		<TELL "Attacking " A ,PRSO " seems a waste of time." CR>)
+	       (<FSET? ,PRSO ,FEMALE>
+		<TELL
+G"Only a motherless coward would attack a woman!" CR>)
+	       (<OR <PRSI? <> ,HANDS>
+		    <NOT <FSET? ,PRSI ,WEAPONBIT>>>
+		<COND (<HELD? ,SWORDS>
+		       <PERFORM ,V?ATTACK ,PRSO ,SWORDS>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"Trying to " .STR " " THE ,PRSO " with ">
+		       <COND (<NOT <PRSI? <> ,HANDS>>
+			      <TELL A ,PRSI>)
+			     (ELSE <TELL "your bare hands">)>
+		       <TELL " is suicidal." CR>)>)
+	       (<NOT <IN? ,PRSI ,WINNER>>
+		<NOT-HOLDING ,PRSI>)
+	       (<PRSI? ,PISTOL>
+		<PERFORM ,V?SHOOT ,PRSI ,PRSO>
+		<RTRUE>)
+	       (<PRSI? ,SWORDS>
+		<TELL
+"You swing your sword at " THE ,PRSO>
+		<COND (<PRSO? ,GRAY-LEADER ,GRAY-CAPTAIN ,SECOND-GRAY
+			      ,GRAYS ,BROWNS>
+		       <TELL
+", but he parries your attack with little difficulty." CR>)
+		      (ELSE
+		       <TELL
+", but " HE/SHE ,PRSI " dodge" S ,PRSI "." CR>)>)
+	       (T
+		<NOT-TRAINED>)>>
+
+<ROUTINE NOT-TRAINED ("OPT" (WHO ,PRSO))
+	 <TELL
+"Your lack of training prevents you from successfully hitting
+" THE .WHO "." CR>>
+
+<ROUTINE V-KNOCK ()
+	 <COND (<FSET? ,PRSO ,DOORBIT>
+		<COND (<B-NOT-STANDING?>
+		       <YOULL-HAVE-TO "stand up">)
+		      (ELSE
+		       <TELL "Nobody's home." CR>)>)
+	       (T
+		<TELL "Why knock on "> <A-PRSO?>)>>
+
+<ROUTINE V-KISS ()
+	 <COND (<CREWMAN? ,PRSO>
+		<TELL
+"You've heard that sort of tale about some of the crew, but you've
+never been tempted to find out the truth." CR>)
+	       (<FSET? ,PRSO ,PERSON>
+		<TELL
+"In Japan, kissing is not commonly practiced.  It is considered somewhat
+unclean and barbaric." CR>)
+	       (ELSE <TELL-YUKS>)>>
+
+<ROUTINE V-LAMP-OFF ()
+	 <TO-A-PRSO?> ;"flashlight is only light source">
+
+<ROUTINE V-LAMP-ON ()
+	 <TO-A-PRSO?>>
+
+<ROUTINE V-LEAN-ON ()
+	 <TELL "Tired?" CR>>
+
+<ROUTINE V-LEAP ()
+	 <COND (<B-NOT-STANDING?>
+		<YOULL-HAVE-TO "stand up">)
+	       (<AND ,PRSO <IN? ,PRSO ,HERE>>
+		<COND (<EQUAL? ,PRSO ,OPPONENT>
+		       <PERFORM ,V?KICK ,PRSO>
+		       <RTRUE>)
+		      (ELSE
+		       <V-SKIP>)>)
+	       (<AND <NOT ,PRSO> ,OPPONENT>
+		<PERFORM ,V?DODGE>
+		<RTRUE>)
+	       (T
+		<TELL
+"You jump a little ways, but then fall back to the ground." CR>)>>
+
+<ROUTINE V-LEAVE ()
+	 <COND (<EQUAL? ,P-PRSA-WORD ,W?WALK>
+		<TELL
+"Please specify which way you want to walk.  Use compass directions." CR>)
+	       (ELSE
+		<DO-WALK ,P?OUT>)>>
+
+<ROUTINE V-LISTEN ()
+	 <COND (<AND ,PRSO <FSET? ,PRSO ,PERSON>>
+		<TELL
+"Right now, " THE ,PRSO IS/ARE ,PRSO "n't saying anything." CR>)
+	       (<AND ,PRSO <NOT <PRSO? ,NOISE>>>
+		<TELL
+"At the moment, " THE ,PRSO IS/ARE ,PRSO " quiet and peaceful." CR>)
+	       (ELSE
+		<TELL
+"You hear nothing unusual." CR>)>>
+
+<ROUTINE CANT-X-WITH-PRSI (STR)
+	 <TELL "You can't " .STR " anything with " A ,PRSI "." CR>>
+
+<ROUTINE V-LOCK ()
+	 <COND (<NOT <PRSI? <> ,KEY>>
+		<CANT-X-WITH-PRSI "lock">)
+	       (<FSET? ,PRSO ,LOCKED>
+		<TELL G"It already is." CR>)
+	       (<FSET? ,PRSO ,LOCKABLE>
+		<COND (<IN? ,KEY ,WINNER>
+		       <FSET ,PRSO ,LOCKED>
+		       <TELL "Done." CR>)
+		      (ELSE
+		       <TELL G"You need a key to do that." CR>)>)
+	       (ELSE 
+		<NO-LOCK>)>>
+
+<ROUTINE NO-LOCK ()
+	 <TELL CTHE ,PRSO " doesn't have a lock." CR>>
+
+<ROUTINE V-INTRODUCE ("AUX" TMP)
+	 <COND (<AND <NOT <FSET? ,HERE ,TOUCHBIT>>
+		     <OR <FSET? ,HERE ,RMUNGBIT>
+			 <AND <SET TMP <GETPT ,HERE ,P?SCENE>>
+			      <EQUAL? ,SCENE <GETB .TMP 0>>>>>
+		<COND (<SET TMP <GETP ,HERE ,P?PICTURE>>
+		       <MARGINAL-PIC .TMP>)>
+		<COND (<SET TMP <GETP ,HERE ,P?FDESC>>
+		       <TELL .TMP CR CR>)>
+		<RTRUE>)>>
+
+<ROUTINE V-AFTER ("AUX" TMP RM)
+	 <COND (<AND ,SCENE
+		     <SET TMP <GETP <GET ,SCENE-LOCS ,SCENE> ,P?AFTER>>>
+		<CRLF>
+		<TYPE-ANY-KEY>
+		<INTERLUDE-STATUS-LINE>
+		<TIME-PASSES>
+		<APPLY .TMP>
+		<TIME-PASSES>)>>
+
+<ROUTINE TIME-PASSES ()
+	 <CRLF>
+	 <CENTER-PIC-X ,P-TIME>
+	 <CRLF>>
+
+<ROUTINE NEXT-SCENE ()
+	 <NEW-SCENE <+ ,SCENE 1>>>
+
+<ROUTINE FAILED-SCENE ()
+	 <NEW-SCENE <>>>
+
+<ROUTINE NEW-SCENE ("OPT" (SC <>) "AUX" S SA SP)
+	 <UPDATE-STATUS-LINE>
+	 <TELL CR
+"[">
+	 <SET S <GETPT <GET ,SCENE-LOCS ,SCENE> ,P?SCORE>>
+	 <SET SA <GETB .S 0>>
+	 <SET SP <GETB .S 1>>
+	 <COND (.SC
+		<TELL
+"Congratulations, you have finished this scene with a score of "
+N <* ,SCORE-FACTOR .SA> " out of a possible " N <* ,SCORE-FACTOR .SP>>)
+	       (ELSE
+		<TELL
+"Sorry, this scene is no longer winnable">)>
+	 <TELL ".]" CR CR>
+	 <COND (.SC
+		<V-AFTER>
+		<CONTINUE-TO-NEXT-SCENE <- .SP .SA>>
+		<RESET-MARGIN>
+		<CLEAR ,S-TEXT>
+		<COND (<NOT <EQUAL? ,CURRENT-BORDER ,P-BORDER>>
+		       <DISPLAY-BORDER ,P-BORDER>)>
+		<GOTO-SCENE .SC>)
+	       (ELSE <FINISH>)>>
+
+<ROUTINE SCORE-HAVE ()
+	 <GETB <GETPT <GET ,SCENE-LOCS ,SCENE> ,P?SCORE> 0>>
+
+;<ROUTINE SCORE-MAX ()
+	 <GETB <GETPT <GET ,SCENE-LOCS ,SCENE> ,P?SCORE> 1>>
+
+<CONSTANT CONTINUE-MENU
+	  <LTABLE
+<TABLE (PURE STRING LENGTH) "CONTINUE to next scene ">
+<TABLE (PURE STRING LENGTH) "SAVE this game position ">
+<TABLE (PURE STRING LENGTH) "QUIT this session of the game ">>>
+
+<CONSTANT CONTINUE-AND-HINT-MENU
+	  <LTABLE
+<TABLE (PURE STRING LENGTH) "CONTINUE to next scene ">
+<TABLE (PURE STRING LENGTH) "SAVE this game position ">
+<TABLE (PURE STRING LENGTH) "QUIT this session of the game ">
+<TABLE (PURE STRING LENGTH) "HINT for something confusing ">>>
+
+<ROUTINE CONTINUE-TO-NEXT-SCENE (HINT?)
+	 ;<UPDATE-STATUS-LINE>
+	 ;<SETUP-TEXT-AND-STATUS> ;"guarantee status line okay"
+	 <GET-FROM-MENU "What now?"
+			<COND (.HINT? ,CONTINUE-AND-HINT-MENU)
+			      (ELSE ,CONTINUE-MENU)>
+			,CONTINUE-MENU-F>>
+
+<ROUTINE CONTINUE-MENU-F (WHICH MENU)
+	 <COND (<EQUAL? .WHICH 1 ;CONTINUE>
+		<RTRUE>)
+	       (<EQUAL? .WHICH 2 ;SAVE>
+		<V-SAVE>
+		<RFALSE>)
+	       (<EQUAL? .WHICH 3 ;QUIT>
+		<V-QUIT>
+		<RFALSE>)
+	       (<EQUAL? .WHICH 4 ;HINT>
+		<V-HINT>
+		<RFALSE>)>>
+
+<ROUTINE V-FIRST-LOOK ()
+	 <COND (<DESCRIBE-ROOM <G? ,VERBOSITY 1>>
+		<COND (,VERBOSITY <DESCRIBE-OBJECTS>)>)>>
+
+<ROUTINE V-LOOK ()
+	 <COND (<DESCRIBE-ROOM T>
+		<DESCRIBE-OBJECTS>)>>
+
+<ROUTINE V-LOOK-BEHIND ()
+	 <COND (<PRSO? ME>
+		<TELL
+"You look back over your shoulder.  "G"There's nothing ""there." CR>)
+	       (<AND <NOT <FSET? ,PRSO ,OPENBIT>>
+		     <NOT <FSET? ,PRSO ,SURFACEBIT>>
+		     <OR <FSET? ,PRSO ,CONTBIT>
+			 <FSET? ,PRSO ,DOORBIT>>>
+		<INSPECTION-REVEALS ,PRSO>)
+	       (ELSE
+		<TELL ,THERE-IS-NOTHING "behind "><THE-PRSO>)>>
+
+<ROUTINE V-LOOK-DOWN ()
+	 <COND (<NOT ,LIT>
+		<TELL ,TOO-DARK>)
+	       (<PRSO? <> ,ROOMS ,LG-HOLE>
+		<COND (<GLOBAL-IN? ,LG-HOLE ,HERE>
+		       <PERFORM ,V?LOOK-INSIDE ,LG-HOLE>)
+		      (ELSE
+		       <PERFORM ,V?EXAMINE ,GROUND>)>
+		<RTRUE>)
+	       (ELSE
+		<PRSO-NOTHING-SPECIAL>)>>
+
+<ROUTINE WHAT-CONTENTS ()
+	 <COND (<NOT <DESCRIBE-CONTENTS ,PRSO>>
+		<TELL "nothing">
+		<COND (<IN? ,PLAYER ,PRSO>
+		       <TELL " (other than you)">)>)>
+	 <TELL ,PERIOD>>
+
+<ROUTINE V-LOOK-INSIDE ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<PRSO-NOTHING-SPECIAL>)
+	       (<FSET? ,PRSO ,DOORBIT>
+		<THIS-IS-IT ,PRSO>
+		<TELL "All you can tell is that ">
+		<TELL-OPEN-CLOSED>)
+	       (<FSET? ,PRSO ,CONTBIT>
+		<COND (<PRSO? <LOC ,WINNER>>
+		       <MOVE ,PLAYER ,ROOMS>
+		       <TELL "Aside from you, there's ">
+		       <WHAT-CONTENTS>
+		       <MOVE ,PLAYER ,PRSO>)
+		      (<SEE-INSIDE? ,PRSO>
+		       <TELL CTHE ,PRSO " contains ">
+		       <WHAT-CONTENTS>)
+		      (<AND <NOT <FSET? ,PRSO ,OPENBIT>>
+			    <FIRST? ,PRSO>>
+		       <NEW-VERB ,V?OPEN>
+		       <RTRUE>)
+		      (T
+		       <THIS-IS-IT ,PRSO>
+		       <TELL "It seems ">
+		       <TELL-OPEN-CLOSED>)>)
+	       (T
+		<YOU-CANT-X-PRSO "look inside">)>>
+
+<ROUTINE V-LOOK-ON ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<PRSO-NOTHING-SPECIAL>)
+	       (<OR <FSET? ,PRSO ,SURFACEBIT>
+		    <FSET? ,PRSO ,FURNITURE>>
+		<TELL "On " THE ,PRSO " is ">
+		<WHAT-CONTENTS>)
+	       (T
+		<TELL "You don't see anything on " THE ,PRSO "." CR>)>>
+
+<ROUTINE V-LOOK-UNDER ()
+	 <COND (<HELD? ,PRSO>
+		<TELL "You see your hand." CR>)
+	       (T
+		<TELL ,THERE-IS-NOTHING "there." CR>)>>
+
+<ROUTINE V-LOWER ()
+	 <COND (<PRSO? ,ROOMS>
+		<PERFORM ,V?SIT>
+		<RTRUE>)
+	       (<NOT <FSET? ,PRSO ,TAKEBIT>>
+		<YOU-CANT-X-THAT "lower">)
+	       (ELSE
+		<HACK-HACK "Lowering">)>>
+
+<ROUTINE V-MELT ()
+	 <WITH-PRSI?>>
+
+<ROUTINE V-MOVE ()
+	 <COND (<PRSO? <> ROOMS>
+		<TELL "What moves!" CR>)
+	       (<AND <HELD? ,PRSO>
+		     <NOT <FSET? ,PRSO ,BODY-PART>>>
+		<TELL
+"You're holding " HIM/HER ,PRSO ".  Are you planning to juggle " HIM/HER ,PRSO
+"?" CR>)
+	       (<AND <FSET? ,PRSO ,TAKEBIT>
+		     <DEAD? ,PRSO>>
+		<V-TURN-OVER>)
+	       (<FSET? ,PRSO ,DOORBIT>
+		<PERFORM ,V?OPEN ,PRSO>
+		<RTRUE>)
+	       (T
+		<YOU-CANT-X-PRSO "move">)>>
+
+<ROUTINE MOTION-VERB? ()
+	 <VERB? WALK WALK-TO WALK-AROUND
+		ENTER EXIT
+		DODGE AVOID
+		LEAP DIVE DANCE
+		TURN-AROUND
+		HIDE HIDE-BEHIND HIDE-UNDER
+		MOVE BOARD CLIMB-DOWN CLIMB-FOO CLIMB-UP>>
+
+<ROUTINE HOSTILE-VERB? ()
+	 <COND (<VERB? ATTACK BITE CUT HIT KICK KILL
+		       MOVE MUNG PISS PUSH PUSH-OUT RUB
+		       SHAKE SHOOT SPIT SWING THROW TRIP>
+		<RTRUE>)
+	       (<AND <VERB? TAKE>
+		     <EQUAL? ,P-PRSA-WORD ,W?GRAB ,W?TACKLE ,W?LUNGE>
+		     <FSET? ,PRSO ,PERSON>>
+		<RTRUE>)
+	       (<AND <VERB? FUCK>
+		     <FSET? ,PRSO ,PERSON>
+		     <NOT <FSET? ,PERSON ,FEMALE>>>
+		<RTRUE>)>>
+
+<ROUTINE JAPANESE-VERB? ()
+	 <COND (<VERB? DOMO DOZO GENKI-DESU
+		       GOMEN-NASAI HAI ISOGI IYE 
+		       KINJIRU KONNICHI-WA KONBANWA MIZU
+		       NIHON-GO-GA TEKI WAKARIMASU>)>>
+
+<ROUTINE ACT-CRAZY? ()
+	 <OR <VERB? YELL YELL-AT DANCE SING LAUGH BABBLE>
+	     <P? ACT CRAZY>>>
+
+"verbs which don't require object to exist/be nearby"
+
+<ROUTINE ABSTRACT-VERB? ()
+	 <OR <EVERYWHERE-VERB?>
+	     <PAST-TENSE?>>>
+
+"verbs with no object or which don't require touching their object."
+
+<ROUTINE PASSIVE-VERB? ()
+	 <OR <ABSTRACT-VERB?>
+	     <VERB? ASK-ABOUT BOW COMPARE COUNT CURSE DIE DISEMBARK
+		    EXAMINE HELLO LAUGH LISTEN LOOK LOOK-BEHIND
+		    LOOK-DOWN LOOK-INSIDE LOOK-UNDER POINT READ
+		    REPLY SAY SCARE SHOW SPEAK TELL TELL-ABOUT
+		    THANK THOU WAIT WAIT-FOR WALK WAVE-AT
+		    YAWN YELL YELL-AT>>>
+
+<ROUTINE V-MUNG ()
+	 <HACK-HACK "Trying to break">>
+
+<ROUTINE PRE-OPEN ()
+	 <COND (<AND <PAST-TENSE?>
+		     <TRY-QCONTEXT?>>
+		<RTRUE>)
+	       (<AND ,PRSI
+		     <NOT <HELD? ,PRSI>>>
+		<NOT-HOLDING ,PRSI>)>>
+
+<ROUTINE V-OPEN ("AUX" F STR)
+	 <COND (<FSET? ,PRSO ,DOORBIT>
+		<SETG P-LAST-OPEN ,PRSO>)>
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<TELL
+,YOU-CANT "open a person, at least not without making a mess." CR>)
+	       (<FSET? ,PRSO ,OPENBIT>
+		<COND (<FSET? ,PRSO ,OPENABLE>
+		       <ALREADY-OPEN>)
+		      (ELSE
+		       <TELL "It looks open from here." CR>)>)
+	       (<OR <AND <NOT <FSET? ,PRSO ,CONTBIT>>
+		         <NOT <FSET? ,PRSO ,DOORBIT>>>
+		    <FSET? ,PRSO ,SURFACEBIT>>
+		<COND (<IN? ,PRSO ,ROOMS>
+		       <TELL
+,YOU-HAVE-TO "specify a door to open." CR>)
+		      (ELSE <TO-A-PRSO?>)>)
+	       (<NOT <EQUAL? <GETP ,PRSO ,P?CAPACITY> 0>>
+		<COND (<NOT <FSET? ,PRSO ,OPENBIT>>
+		       <FSET ,PRSO ,OPENBIT>
+		       <FSET ,PRSO ,TOUCHBIT>
+		       <COND (<OR <NOT <FIRST? ,PRSO>>
+				  <FSET? ,PRSO ,TRANSBIT>>
+			      <TELL "Opened." CR>)
+			     (<AND <SET F <FIRST? ,PRSO>>
+				   <NOT <NEXT? .F>>
+				   <SET STR <GETP .F ,P?FDESC>>>
+			      <OKAY-THE-PRSO-IS-NOW "open">
+			      <TELL .STR CR>)
+			     (T
+			      <TELL "Opening ">
+			      <TELL THE ,PRSO " reveals ">
+			      <WHAT-CONTENTS>)>)>)
+	       (T ;"door"
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <ALREADY-OPEN>)
+		      (<FSET? ,PRSO ,LOCKED>
+		       <TELL "It's locked." CR>)
+		      (T
+		       <FSET ,PRSO ,OPENBIT>
+		       <OKAY-THE-PRSO-IS-NOW "open">)>)>>
+
+;<ROUTINE V-PAY ()
+	 <COND (<NOT ,PRSI>
+		<TELL "Pay with what?" CR>
+		<RTRUE>)
+	       (T
+		<WITH-PRSI?>)>>
+
+<ROUTINE V-PICK ()
+	 <YOU-CANT-X-THAT "pick">>
+
+;<ROUTINE V-PLAY ()
+         <TELL "How peculiar!" CR>>
+
+<ROUTINE V-PLUG ()
+	 <NO-EFFECT> ;"no effect">
+
+<ROUTINE V-POINT ()
+	 <COND (<AND <SCENE? ,S-ANJIRO>
+		     <IN? ,ONNA ,HERE>
+		     <NOT <PRSO? ,ONNA>>>
+		<PERFORM ,V?SHOW ,PRSO ,ONNA>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,PERSON>
+		<TELL "It is considered impolite to point." CR>)
+	       (ELSE
+		<TELL "You are now pointing at " A ,PRSO "." CR>)>>
+
+<ROUTINE V-POUR-FROM ()
+	 <COND (<IN? ,PRSO ,PRSI>
+		<PERFORM ,V?POUR ,PRSO>
+		<RTRUE>)
+	       (ELSE
+		<TELL "It's not in that!" CR>)>>
+
+<ROUTINE PRE-POUR ()
+	 <COND (<EQUAL? ,PRSO ,PRSI>
+		<TELL-YUKS>)>>
+
+<ROUTINE V-POUR ()
+	 <COND (<AND <FSET? ,PRSO ,CONTBIT>
+		     <HELD? ,PRSO>>
+		<EMPTY-ALL ,PRSO ,PRSI>)
+	       (ELSE
+		<YOU-CANT-X-THAT "pour">)>>
+
+<ROUTINE EMPTY-ALL (FROM TO "AUX" F N R (1ST? <>))
+	 <MAP-CONTENTS (F N .FROM)
+		       <COND (<FSET? .F ,TAKEBIT>
+			      <SET 1ST? T>
+			      <TELL D .F ": ">
+			      <SET R
+				   <COND (.TO
+					  <PERFORM ,V?PUT .F .TO>)
+					 (ELSE
+					  <PERFORM ,V?DROP .F>)>>
+			      <COND (<EQUAL? .R ,M-FATAL> <RTRUE>)>)>>
+	 <COND (<NOT .1ST?> <TELL CTHE .FROM " is empty." CR>)>
+	 <RTRUE>>
+
+;<ROUTINE V-PUMP ()
+	 <TELL "It's not clear how." CR>>
+
+<ROUTINE V-PUSH ()
+	 <HACK-HACK "Pushing">>
+
+<ROUTINE V-PUSH-TO ()
+	 <COND (<PRSI? INTDIR>
+		<PERFORM ,V?MOVE ,PRSO>
+		<RTRUE>)
+	       (ELSE
+		<TELL
+,YOU-CANT "push " THE ,PRSO " into " THE ,PRSI "!" CR>)>>
+
+<ROUTINE PRE-PUT ("AUX" (L <LOC ,PRSO>))
+	 <COND (<OR <IN? ,PRSO ,GLOBAL-OBJECTS>
+		    <NOT <FSET? ,PRSO ,TAKEBIT>>>
+		<TELL "Nice try." CR>)
+	       (<AND <VERB? PUT>
+		     <FSET? ,PRSO ,WEAPONBIT>
+		     <FSET? ,PRSI ,PERSON>>
+		<SWAP-VERB ,V?ATTACK>
+		<RTRUE>)
+	       (<IN? ,PRSO ,PRSI>
+		<TAKE-OUT-FIRST ,PRSO ,PRSI>)
+	       (<IN? ,PRSI ,PRSO>
+		<TAKE-OUT-FIRST ,PRSI ,PRSO>)
+	       (<FSET? .L ,PERSON> <RFALSE>)
+	       (<AND <FSET? .L ,CONTBIT>
+		     <NOT <FSET? .L ,OPENBIT>>>
+		<TAKE-OUT-FIRST ,PRSO .L>)>>
+
+<ROUTINE TAKE-OUT-FIRST (OBJ CONT)
+	 <TELL
+"You should take " THE .OBJ " out of " THE .CONT " first." CR>>
+
+<ROUTINE V-PUT ("AUX" W)
+	 <COND (<AND <NOT <FSET? ,PRSI ,OPENBIT>>
+		     <NOT <FSET? ,PRSI ,DOORBIT>>
+		     <NOT <FSET? ,PRSI ,CONTBIT>>
+		     <NOT <FSET? ,PRSI ,SURFACEBIT>>
+		     <NOT <FSET? ,PRSI ,VEHBIT>>>
+		<YOU-CANT-X-THAT>
+		<RTRUE>)
+	       (<AND <NOT <FSET? ,PRSI ,OPENBIT>>
+		     <NOT <FSET? ,PRSI ,SURFACEBIT>>>
+		<INSPECTION-REVEALS ,PRSI>)
+	       (<PRSI? ,PRSO>
+		<TO-A-PRSO?>)
+	       (<IN? ,PRSO ,PRSI>
+		<TELL "I think ">
+		<TELL THE ,PRSO " is already in ">
+		<THE-PRSI>)
+	       (<OR <FSET? ,PRSI ,PERSON>
+		    <AND <FSET? <SET W <LOC ,PRSI>> ,PERSON>
+			 <NOT <EQUAL? .W ,WINNER>>>>
+		<COND (<NOT .W> <SET W ,PRSI>)>
+		<TELL
+"Don't you think you should ask " THE .W " first?" CR>)
+	       (<PRSO-TOO-BIG?>
+		<TELL ,NO-ROOM CR>)
+	       (<AND <NOT <HELD? ,PRSO>>
+		     <NOT <EQUAL? <ITAKE> T>>>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,WEARBIT>
+		<HAVE-TO-TAKE-OFF>)
+	       (T
+		<FCLEAR ,PRSO ,WEARBIT>
+		<MOVE ,PRSO ,PRSI>
+		<FSET ,PRSO ,TOUCHBIT>
+		<TELL "Done." CR>)>>
+
+<ROUTINE PRSO-TOO-BIG? ()
+	 <COND (<G? <- <+ <WEIGHT ,PRSI> <WEIGHT ,PRSO>>
+		       <GETP ,PRSI ,P?SIZE>>
+		    <GETP ,PRSI ,P?CAPACITY>>
+		<RTRUE>)
+	       (ELSE <RFALSE>)>>
+
+<ROUTINE INSPECTION-REVEALS (OBJ)
+	 <THIS-IS-IT .OBJ>
+	 <TELL "Inspection reveals that " THE .OBJ " isn't open." CR>>
+
+<ROUTINE V-PUT-BEHIND ()
+	 <TELL ,YOU-CANT "be sure what's behind there already." CR>>
+
+<ROUTINE V-PUT-ON ()
+	 <COND (<PRSI? ,ME>
+		<COND (<FSET? ,PRSO ,WEARBIT>
+		       <TELL "You already have " THE ,PRSO " on." CR>)
+		      (ELSE
+		       <PERFORM ,V?WEAR ,PRSO>
+		       <RTRUE>)>)
+	       (<PRSI? ,GROUND>
+		<PERFORM ,V?DROP ,PRSO>
+		<RTRUE>)
+	       (<FSET? ,PRSI ,SURFACEBIT>
+		<V-PUT>)
+	       (<AND <FSET? ,PRSI ,PERSON>
+		     <NOT <FSET? ,PRSO ,DEAD>>>
+		<COND (<FSET? ,PRSO ,WEARABLE>
+		       <TELL
+"Presumably, " THE ,PRSI " would prefer to dress " HIM/HER ,PRSO "self." CR>)
+		      (ELSE
+		       <TELL
+CTHE ,PRSI " doesn't look like a table to me." CR>)>)
+	       (T
+		<NO-GOOD-SURFACE>)>>
+
+<ROUTINE NO-GOOD-SURFACE ()
+	 <TELL "There's no good surface on ">
+	 <THE-PRSI>>
+
+<ROUTINE V-PUT-UNDER ()
+         <YOU-CANT-X-THAT "put anything under">>
+
+<ROUTINE V-RAISE ()
+	 <COND (<AND <FSET? ,PRSO ,PERSON>
+		     <NOT <PRSO? ,WINNER ,ME>>>
+		<PERFORM ,V?TAKE ,PRSO>
+		<RTRUE>)
+	       (<NOT <FSET? ,PRSO ,TAKEBIT>>
+		<TELL ,YOU-CANT "raise that." CR>)
+	       (<AND <NOT <IN? <LOC ,PRSO> ,WINNER>>
+		     <G? <+ <WEIGHT ,PRSO> <WEIGHT ,WINNER>> ,LOAD-ALLOWED>>
+		<TELL CTHE ,PRSO " is too heavy." CR>)
+	       (ELSE <HACK-HACK "Lifting">)>>
+
+<ROUTINE V-REACH-IN ("AUX" OBJ)
+	 <COND (<OR <NOT <FSET? ,PRSO ,CONTBIT>>
+		    <FSET? ,PRSO ,PERSON>>
+		<TO-A-PRSO?>)
+	       (<NOT <FSET? ,PRSO ,OPENBIT>>
+		<TELL "It's not open." CR>)
+	       (<OR <NOT <SET OBJ <FIRST? ,PRSO>>>
+		    <FSET? .OBJ ,INVISIBLE>
+		    <NOT <FSET? .OBJ ,TAKEBIT>>>
+		<ITS-EMPTY>)
+	       (T
+		<TELL
+G "You feel something " "in " THE ,PRSO "!" CR>
+		<RTRUE>)>>
+
+<ROUTINE PRE-READ ()
+	 <COND (<NOT ,LIT>
+		<TELL ,YOU-CANT "read in the dark." CR>)
+	       (<AND ,PRSI <NOT <FSET? ,PRSI ,TRANSBIT>>>
+		<HOW-DO-YOU> <A-PRSI?>)>>
+
+<ROUTINE HOW-DO-YOU ()
+	 <TELL "How do you do that with ">>
+
+<ROUTINE V-READ ()
+	 <COND (<AND <FSET? ,PRSO ,READBIT>
+		     <GETP ,PRSO ,P?TEXT>>
+		<TELL <GETP ,PRSO ,P?TEXT> CR>)
+               (T
+                <TO-A-PRSO?>)>>
+
+<ROUTINE V-REPLY ()
+	 <END-QUOTE>
+	 <COND (<PRSO? INTQUOTE>
+		<TELL
+"[Please answer without using quotes.]" CR>)
+	       (<PRSO? ,QCONTEXT>
+		<COND (<NOT ,PRSI>
+		       <PERFORM ,V?ANSWER>
+		       <RTRUE>)
+		      (ELSE
+		       <PERFORM ,V?REPLY ,PRSI>
+		       <RTRUE>)>)
+	       (<AND <NOT ,PRSI>
+		     <TRY-QCONTEXT?>>
+		<RTRUE>)
+	       (ELSE
+		<TELL "You are ignored." CR>)>>
+
+<ROUTINE PRE-SRUB ()
+	 <SWAP-VERB ,V?RUB>
+	 <RTRUE>>
+
+<ROUTINE V-SRUB ()
+	 <RTRUE>>
+
+<ROUTINE V-RUB ("AUX" H)
+	 <COND (<PRSO? ,AIR>
+		<TELL "It's ">
+		<COND (<FSET? ,HERE ,OUTSIDE>
+		       <TELL "cold." CR>)
+		      (ELSE
+		       <TELL "warm." CR>)>)
+	       (ELSE
+		<HACK-HACK "Touching">)>>
+
+<ROUTINE V-SAY ("AUX" V)
+	 <COND (<AND <PRSO? INTQUOTE>
+		     <OR ,OMI-QUESTION
+			 ,YABU-QUESTION
+			 ,RODRIGUES-QUESTION
+			 ,AFTERMATH-QUESTION>>
+		<HOW-TO-USE-TELL ,PRSI>)
+	       (<TRY-QCONTEXT?> <RTRUE>)
+	       (<PRSO? ,ENGLISH ,PORTUGUESE ,SPANISH
+		       ,DUTCH ,LATIN ,JAPANESE>
+		<PERFORM ,V?SPEAK ,PRSO ,PRSI>
+		<RTRUE>)
+	       (<NOT ,PRSI>
+		<TELL
+"If you wish to speak to someone, you should say (for example) \"">
+		<COND (<SET V <FIND-IN ,HERE ,PERSON>>
+		       <TELL D .V>)
+		      (ELSE <TELL I"person">)>
+		<TELL ", "I"what you want to say""\"" CR>
+		<END-QUOTE>)>>
+
+<ROUTINE HOW-TO-USE-TELL (WHO)
+	 <TELL
+"[The correct way to speak to others is to use their name followed by a comma,
+and then what you want to say to them.  For example:|
+>">
+	 <COND (.WHO <TELL D .WHO>)
+	       (<AND ,QCONTEXT <IN? ,QCONTEXT ,HERE>>
+		<TELL D ,QCONTEXT>)
+	       (ELSE <TELL I"person">)>
+	 <TELL ", ">
+	 <PRINT-INTQUOTE>
+	 <TELL CR "]" CR>
+	 <END-QUOTE>>
+
+<ROUTINE V-SEARCH ()
+	 <COND (<AND ,PRSI <FSET? ,PRSI ,PERSON>>
+		<PERFORM ,V?FIND ,PRSI>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,DEAD>
+		<TELL
+CTHE ,PRSO " can't object, being dead, but you find nothing interesting." CR>)
+	       (<FSET? ,PRSO ,PERSON>
+		<TELL
+CTHE ,PRSO " refuse"S ,PRSO "." CR>)
+	       (<NOT <DESCRIBE-CONTENTS ,PRSO
+					<>
+					<+ ,D-ALL? ,D-PARA?>>>
+		<TELL ,THERE-IS-NOTHING "there" ,PERIOD>)>>
+
+<ROUTINE V-SEND ()
+	 <COND (<AND <PAST-TENSE?>
+		     <TRY-QCONTEXT?>>
+		<RTRUE>)
+	       (<AND <FSET? ,PRSO ,PERSON>
+		     ,PRSI
+		     <FSET? ,PRSI ,PERSON>>
+		<TELL
+D ,PRSO " isn't interested in seeing " D ,PRSI "." CR>)
+	       (<AND <FSET? ,PRSO ,PERSON>
+		     <PRSI? <> ,INTDIR>>
+		<TELL
+D ,PRSO G" doesn't seem to want to go." CR>)
+	       (<AND ,PRSI
+		     <FSET? ,PRSI ,PERSON>
+		     <PRSO? ,INTDIR>>
+		<TELL
+D ,PRSI G" doesn't seem to want to go." CR>)
+	       (T
+		<TELL-YUKS>)>>
+
+<ROUTINE V-SEND-UNDER ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<TELL CTHE ,PRSO " refuses." CR>)
+	       (ELSE
+		<TELL "Look again, you're giving orders to " A ,PRSO "!" CR>)>>
+
+<ROUTINE PRE-SGIVE ()
+	 <SWAP-VERB ,V?GIVE>
+	 <RTRUE>>
+
+<ROUTINE V-SGIVE ()
+	 <RTRUE>>
+
+<ROUTINE V-SHAKE ("AUX" X)
+	 <COND (<PRSO? ,HEAD>
+		<PERFORM ,V?NO>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,PERSON>
+		<TELL "Be real." CR>)
+	       ;(<NOT <FSET? ,PRSO ,TAKEBIT>>
+		<TELL ,YOU-CANT "take it; thus, you can't shake it!" CR>)
+	       (T
+		<TELL "There's no point in shaking ">
+		<THAT/THEM ,PRSO>
+		<TELL "." CR>)>>
+
+<ROUTINE THAT/THEM (OBJ)
+	 <COND (<FSET? .OBJ ,PLURAL> <TELL "them">)
+	       (ELSE <TELL "that">)>>
+
+<ROUTINE V-SHARPEN ()
+	 <TELL "You'll never sharpen anything with ">
+	 <THAT/THEM ,PRSI>
+	 <TELL "!" CR>>
+
+<ROUTINE V-SHOOT-WITH ()
+	 <PERFORM ,V?SHOOT ,PRSI ,PRSO>
+	 <RTRUE>>
+
+<ROUTINE PRE-SHOOT ()
+	 <COND (<AND <PRSO? ,PISTOL>
+		     <FSET? ,PISTOL ,RMUNGBIT>>
+		<TELL
+"You fire, but the pistol just goes \"click!\"  It isn't loaded!" CR>)
+	       (<NOT ,PRSI>
+		<COND (<PRSO? ,PISTOL>
+		       <FSET ,PISTOL ,RMUNGBIT>
+		       <TELL
+"You fire " THE ,PRSO " into the air, to little effect." CR>)
+		      (<HELD? ,PISTOL>
+		       <PERFORM ,V?SHOOT ,PISTOL ,PRSO>
+		       <RTRUE>)
+		      (<HELD? ,PRSO>
+		       <TELL
+"Few would consider " A ,PRSO " to be an adequate firearm." CR>)
+		      (ELSE
+		       <TELL
+"You don't have a weapon to shoot " THE ,PRSO " with." CR>)>)>>
+
+<ROUTINE V-SHOOT ()
+	 <COND (<PRSO? ,PISTOL>
+		<COND (<PRSI? ,PISTOL>
+		       <TELL
+"A difficult maneuver, in fact an impossible one." CR>
+		       <RTRUE>)>
+		<COND (<OR <NOT <PRSI? MARIKO ETSU CHIMMOKO ACHIKO YABU
+				       KIRITSUBO>>
+			   <FSET? ,PRSI ,DEAD>
+			   <JIGS-UP? ,J-SHOOT-FRIEND
+"Why would you want to shoot a friend?">>
+		       <FSET ,PISTOL ,RMUNGBIT>
+		       <TELL
+"You fire the pistol at " THE ,PRSI>
+		       <COND (<FSET? ,PRSI ,DEAD>
+			      <TELL ", who was already dead." CR>)
+			     (<FSET? ,PRSI ,PERSON>
+			      <COND (<GETPT ,PRSI ,P?OWNER>
+				     <PUTP ,PRSI ,P?OWNER ,BLACKTHORNE>)>
+			      <TELL ", killing ">
+			      <COND (<NOT <FSET? ,PRSI ,PLURAL>>
+				     <FSET ,PRSI ,DEAD>
+				     <TELL HIM/HER ,PRSI>)
+				    (ELSE
+				     <TELL "one of them">)>
+			      <TELL " instantly." CR>)
+			     (<PRSI? ,GROUND ,WALL>
+			      <TELL ", to no useful effect." CR>)
+			     (ELSE
+			      <TELL ", missing by a mile." CR>)>
+		       <COND (<PRSI? MARIKO ETSU CHIMMOKO ACHIKO YABU>
+			      <CRLF>
+			      <JIGS-UP
+"You hear a scream from the others.  \"The Anjin-san has gone mad!\" they
+yell.  You are quickly overcome and dispatched, as a mad dog would be.">)
+			     (ELSE <RTRUE>)>)
+		      (ELSE <RTRUE>)>)
+	       (ELSE
+		<TELL
+"If you had a weapon, you might be able to shoot it.  Alas, you don't." CR>)>>
+
+<ROUTINE V-SHOW ()
+	 <COND (<FSET? ,PRSI ,PERSON>
+		<UNINTERESTED ,PRSI>)
+	       (ELSE <TELL-YUKS>)>>
+
+<ROUTINE V-SKIP ()
+	 <TELL "Anyone who saw you would be unfavorably impressed." CR>>
+
+<ROUTINE V-SLEEP ()
+	 <COND (,OPPONENT
+		<TELL
+"If you can sleep at a time like this, you have nerves of steel!" CR>)
+	       (ELSE
+		<TELL
+"You try to sleep, but you can't let yourself relax now." CR>)>>
+
+<ROUTINE LIKE-A-PRSO (V)
+	 <TELL CHE/SHE ,PRSO " " .V " just like " A ,PRSO "." CR>>
+
+<ROUTINE V-SMELL ()
+	 <COND (,PRSO
+		<LIKE-A-PRSO "smells">)
+	       (<FSET? <LOC ,WINNER> ,VEHBIT>
+		<PERFORM-PRSA <LOC ,WINNER>>
+		<RTRUE>)
+	       (ELSE
+		<TELL
+"There's no noticeable smell here." CR>)>>
+
+;<ROUTINE V-SPAY ()
+	 <SWAP-VERB ,V?PAY>
+	 <RTRUE>>
+
+;<ROUTINE V-SPIN ()
+	 <YOU-CANT-X-THAT "spin">>
+
+<ROUTINE PRE-SSHOW ()
+	 <SWAP-VERB ,V?SHOW>
+	 <RTRUE>>
+
+<ROUTINE V-SSHOW ()
+	 <RTRUE>>
+
+<ROUTINE V-SWING ()
+	 <COND (<NOT ,PRSI>
+		<TELL "Whoosh!" CR>)
+	       (T
+		<PERFORM ,V?HIT ,PRSI ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-SWIM ()
+	 <TELL-YUKS>>
+
+<ROUTINE V-SWIM-TO ()
+	 <PERFORM ,V?WALK-TO ,PRSO>
+	 <RTRUE>>
+
+<ROUTINE PRE-TAKE ()
+	 <COND (<AND <IN? ,PRSO ,WINNER>
+		     <FSET? ,PRSO ,WEARBIT>>
+		<RFALSE>)
+	       (<AND <IN? ,PRSO ,WINNER>
+		     <NOT <NOUN-USED? ,PRSO ,W?WATER>>>
+		<TELL ,YOU-HAVE THE ,PRSO "." CR>)
+	       (<AND <NOT <FSET? <LOC ,WINNER> ,VEHBIT>>
+		     <LOC ,PRSO>
+		     <FSET? <LOC ,PRSO> ,CONTBIT>
+		     <NOT <FSET? <LOC ,PRSO> ,OPENBIT>>>
+		<CANT-REACH-THAT>
+		<RTRUE>)
+	       (,PRSI
+		<COND (<PRSO? ,ME>
+		       <PERFORM ,V?DROP ,PRSI>
+		       <RTRUE>)
+		      (<OR <HELD? ,PRSO ,PRSI>
+			   <EQUAL? ,PRSI <GETP ,PRSO ,P?OWNER>>>
+		       <SETG PRSI <>>
+		       <RFALSE>)
+		      (<FSET? ,PRSI ,PERSON>
+		       <TELL
+CTHE ,PRSI " doesn't seem to have " THE ,PRSO "." CR>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL CTHE ,PRSO " isn't there." CR>
+		       <RTRUE>)>)
+	       (<PRSO? <LOC ,WINNER>>
+		<TELL "You are ">
+		<COND (<FSET? ,PRSO ,PERSON> <TELL "being carried by">)
+		      (<FSET? ,PRSO ,SURFACEBIT> <TELL "on">)
+		      (ELSE <TELL "in">)>
+		<TELL " it!" CR>)>>
+
+"return true if prso or prsi is inaccessible from vehicle and verb requires
+access to it.  e.g.,
+  >EXAMINE obj-outside-vehicle => rfalse
+  >TAKE obj-outside-vehicle => rtrue"
+
+;<ROUTINE NOT-REACHABLE? ()
+	 <COND (<PASSIVE-VERB?> <RFALSE>)>
+	 <COND (<NOT-IN-VEHICLE? ,PRSO> <RETURN ,PRSO>)
+	       (<NOT-IN-VEHICLE? ,PRSI> <RETURN ,PRSI>)>>
+
+;<ROUTINE CANT-REACH-FROM-VEHICLE (O)
+	 <TELL
+,YOU-CANT "reach " THE .O " from within " THE <LOC ,WINNER> "." CR>>
+
+;<ROUTINE NOT-IN-VEHICLE? (PP "AUX" (V <LOC ,WINNER>))
+	 <COND (<OR <NOT .PP>
+		    <EQUAL? .PP .V ,ROOMS>
+		    <INTRINSIC? .PP>
+		    <HELD? .PP>
+		    <EQUAL? <META-LOC .PP> .V>>
+		<RFALSE>)
+	       (ELSE <RTRUE>)>>
+
+<ROUTINE V-TAKE ("AUX" SIZ)
+	 <COND (<EQUAL? <ITAKE> T>
+		<SET SIZ <GETP ,PRSO ,P?SIZE>>
+		<TELL "Taken">
+		<COND (<G=? .SIZ 20>
+		       <TELL ", but it's ">
+		       <COND (<G=? .SIZ 100>
+			      <TELL "extremely">)
+			     (<G=? .SIZ 50>
+			      <TELL "very">)>
+		       <TELL " heavy">)>
+		<TELL "." CR>)>>
+
+<ROUTINE PUT-ON (OBJ "OPT" (WHO ,WINNER))
+	 <MOVE .OBJ .WHO>
+	 <FSET .OBJ ,WEARBIT>>
+
+<ROUTINE TAKE-OFF (OBJ)
+	 <MOVE .OBJ ,HERE>
+	 <FCLEAR .OBJ ,WEARBIT>>
+
+<ROUTINE V-TAKE-OFF ()
+	 <COND (<FSET? ,PRSO ,VEHBIT>
+		<NEW-VERB ,V?DISEMBARK>
+		<RTRUE>)
+	       (<AND <FSET? ,PRSO ,WEARBIT>
+		     <IN? ,PRSO ,WINNER>>
+		<FCLEAR ,PRSO ,WEARBIT>
+		<TELL
+"You're no longer wearing " THE ,PRSO ,PERIOD>)
+	       (ELSE
+		<NEW-VERB ,V?TAKE>
+		<RTRUE>)>>
+
+<ROUTINE V-HOLD ("AUX" O)
+	 <COND (<FSET? ,PRSO ,BODY-PART>
+		<SET O <GET-OWNER ,PRSO>>
+		<COND (<NOT <EQUAL? .O ,ME ,BLACKTHORNE <>>>
+		       <TELL
+"It seems unavailable at the moment." CR>)
+		      (<PRSO? ,HEAD>
+		       <TELL "Do you have a headache?" CR>)
+		      (ELSE
+		       <TELL
+"You hold your " D ,PRSO " as best you can." CR>)>)
+	       (<HELD? ,PRSO>
+		<COND (<IN? ,PRSO ,WINNER>
+		       <COND (<AND <FSET? ,PRSO ,WEARBIT>
+				   <FSET? ,PRSO ,WEAPONBIT>>
+			      <FCLEAR ,PRSO ,WEARBIT>
+			      <TELL
+"You take " THE ,PRSO " and prepare to use " HIM/HER ,PRSO "." CR>)
+			     (ELSE
+			      <TELL
+"You hold " HIM/HER ,PRSO " tightly." CR>)>)
+		      (ELSE
+		       <TELL
+"You take " THE ,PRSO " out of " THE <LOC ,PRSO> " and hold "
+HIM/HER ,PRSO "." CR>
+		       <MOVE ,PRSO ,WINNER>
+		       <RTRUE>)>)
+	       (ELSE
+		<TELL "You don't have " THE ,PRSO "." CR>)>>
+
+<ROUTINE V-TELL ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<COND (<AND <FSET? ,PRSO ,DEAD>
+			    <NOT <PRSO? ,MARIKO>>>
+		       <TELL
+,YOU-CANT G"expect a response from a dead person!" CR>
+		       <END-QUOTE>
+		       <RFATAL>)
+		      (,P-CONT
+		       <SETG WINNER ,PRSO>
+		       <RTRUE>)
+		      (T
+		       <TELL
+CTHE ,PRSO " wait">
+		       <COND (<NOT <FSET? ,PRSO ,PLURAL>>
+			      <TELL "s">)>
+		       <TELL " for you to say something." CR>
+		       <END-QUOTE>
+		       <RFATAL>)>)
+	       (T
+		<YOU-CANT-X-PRSO "talk to">
+		<END-QUOTE>
+		<RFATAL>)>>
+
+<ROUTINE V-THANK ()
+	 <COND (<TRY-QCONTEXT?> <RTRUE>)
+	       (<OR <NOT ,PRSO> <PRSO? ,YOU ,ME>>
+		<COND (<FSET? ,JAPANESE ,SCOREBIT>
+		       <TELL "You're welcome." CR>)
+		      (ELSE
+		       <TELL "Domo." CR>)>)
+	       (<FSET? ,PRSO ,PERSON>
+		<COND (<FSET? ,PRSO ,DEAD>
+		       <TELL
+CTHE ,PRSO " is beyond all politeness now." CR>)
+		      (<PRSO? ,RODRIGUES>
+		       <TELL
+"\"You're welcome, Ingeles.\"" CR>)
+		      (<PRSO? ,SEBASTIO ,OPPONENT>
+		       <TELL
+"He ignores your politeness." CR>)
+		      (<NOT <FSET? ,PRSO ,JAPANESEBIT>>
+		       <TELL
+CTHE ,PRSO " is surprised by your politeness." CR>)
+		      (ELSE
+		       <COND (<FSET? ,PRSO ,PLURAL>
+			      <TELL CA ,PRSO>)
+			     (ELSE
+			      <TELL CTHE ,PRSO>)>
+		       <TELL " bows and responds \"Domo.\"" CR>)>)
+	       (T
+		<TO-A-PRSO?>)>>
+
+<ROUTINE V-DOMO ()
+	 <COND (<TRY-QCONTEXT?> <RTRUE>)
+	       (ELSE
+		<TELL "How very kind!" CR>)>>
+
+<ROUTINE V-DOZO ()
+	 <COND (<TRY-QCONTEXT?> <RTRUE>)
+	       (ELSE
+		<TELL "There is no response." CR>)>>
+
+<ROUTINE PRE-THROUGH ()
+	 <COND (<OR <PRSO? ,ROOMS>
+		    <IN? ,PRSO ,ROOMS>
+		    <ACCESSIBLE? ,PRSO>>
+		<RFALSE>)
+	       (ELSE
+		<TELL "You can't see any " D ,PRSO " here." CR>)>>
+
+<ROUTINE V-THROUGH ("AUX" M)
+	<COND (<IN? ,PRSO ,ROOMS>
+	       <PERFORM ,V?WALK-TO ,PRSO>
+	       <RTRUE>)
+	      (<PRSO? ,ROOMS>
+	       <DO-WALK ,P?IN>)
+	      (<FSET? ,PRSO ,VEHBIT>
+	       <NEW-VERB ,V?BOARD>
+	       <RTRUE>)
+	      (<FSET? ,PRSO ,DOORBIT>
+	       <COND (<SET M <FIND-DOOR ,PRSO>>
+		      <DO-WALK .M>)
+		     (ELSE
+		      <TELL
+,YOU-HAVE-TO G"be more specific about ""the direction you are going." CR>)>)
+	      (<FSET? ,PRSO ,PERSON>
+	       <TELL ,GOOD-TRICK>)
+	      (<NOT <FSET? ,PRSO ,TAKEBIT>>
+	       <TELL
+"You hit your head against " THE ,PRSO " as you attempt this feat." CR>)
+	      (<IN? ,PRSO ,WINNER>
+	       <TELL "That would involve quite a contortion!" CR>)
+	      (T
+	       <TELL-YUKS>)>>
+
+<ROUTINE FIND-DOOR (DOOR "AUX" DIR PT PTS)
+	 <MAP-DIRECTIONS (DIR PT ,HERE)
+		<COND (<AND <EQUAL? <PTSIZE .PT> ,DEXIT>
+			    <EQUAL? <GET .PT ,DEXITOBJ> .DOOR>>
+		       <RETURN .DIR>)>>>
+
+<ROUTINE PRE-THROW ()
+	 <COND (<PRSO? ,ANCHOR ,ERASMUS-ANCHOR ,MARIKO ,SAFETY-LINE
+		       ,OAR ,LIFE-RING>
+		<RFALSE>)
+	       (<NOT <HELD? ,PRSO>>
+		<TELL "You're not carrying " THE ,PRSO "." CR>)
+	       (<PRSO? ,LARGE-KNIFE ,SMALL-KNIFE>
+		<RFALSE>)
+	       (<FSET? ,PRSO ,WEARBIT>
+		<YOULL-HAVE-TO "take them off">)>>
+
+<ROUTINE V-THROW ()
+	 <COND (<AND ,PRSI <FSET? ,PRSI ,PERSON>>
+	        <COND (<IN? ,PRSO ,WINNER>
+		       <COND (<IDROP>
+			      <NOT-TRAINED ,PRSI>)>)
+		      (ELSE
+		       <SWAP-VERB ,V?HIT>
+		       <RTRUE>)>)
+	       (<AND ,PRSI
+		     <NOT <PRSI? PSEUDO-OBJECT>>
+		     <FSET? ,PRSO ,WEAPONBIT>>
+		<SWAP-VERB ,V?HIT>
+		<RTRUE>)
+	       (<AND ,PRSI
+		     <NOT <FSET? ,PRSI ,DOORBIT>>
+		     <FSET? ,PRSI ,CONTBIT>
+		     <GETP ,PRSI ,P?CAPACITY>>
+		<NEW-VERB ,V?PUT>
+		<RTRUE>)
+	       (<IDROP>
+		<TELL "Thrown." CR>)>>
+
+<ROUTINE V-THROW-OFF ()
+	 <COND (<GLOBAL-IN? ,LG-SEA ,HERE>
+		<REMOVE ,PRSO>
+		<TELL
+"Splash! " CTHE ,PRSO " is gone for good now!" CR>)
+	       (ELSE
+		<YOU-CANT-X-THAT "throw anything off">)>>
+
+<ROUTINE V-TIE ()
+	 <COND (<AND <NOT ,PRSI>
+		     <NOT <PRSO? ,YABU-KIMONO>>
+		     <HELD? ,YABU-KIMONO>>
+		<PERFORM ,V?TIE ,PRSO ,YABU-KIMONO>
+		<RTRUE>)
+	       (<PRSO? ,MURA-ROPE>
+		<TELL "You can't get it away from Mura." CR>)
+	       (ELSE
+		<TO-A-PRSO?>)>>
+
+<ROUTINE V-TIE-UP ()
+	 <TO-A-PRSO?>>
+
+<ROUTINE V-TIME ("AUX" X)
+	 <TELL "You have no easy way to tell time." CR>>
+
+<ROUTINE V-TORTURE ()
+	 <TELL "An appalling idea!" CR>>
+
+<ROUTINE NO-EFFECT () ;"used by others"
+	 <TELL "This has no effect." CR>>
+
+<ROUTINE V-TURN () ;"used by others"
+	 <COND (<AND <PRSO? INTDIR>
+		     <SCENE? ,S-ERASMUS ,S-VOYAGE>>
+		<TELL "You must be on the bridge to steer!" CR>)
+	       (ELSE
+		<NO-EFFECT>)>>
+
+<ROUTINE V-TURN-OVER ()
+	 <TELL "Moving " THE ,PRSO " reveals nothing." CR>>
+
+<ROUTINE V-TURN-AROUND ()
+	 <COND (<PRSO? ,ROOMS>
+		<PERFORM ,V?LOOK-BEHIND ,ME>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,PERSON>
+		<TELL
+"I wouldn't do that, " THE ,PRSO " might get dizzy." CR>)
+	       (<NOT <FSET? ,PRSO ,TAKEBIT>>
+		<TELL
+,YOU-CANT "turn " THE ,PRSO " around." CR>)
+	       (ELSE
+		<TELL
+"Turning " THE ,PRSO " around gives you a new perspective on it, but
+reveals no new information." CR>)>>
+
+<ROUTINE V-UNLOCK ()
+	 <COND (<AND <PAST-TENSE?>
+		     <TRY-QCONTEXT?>>
+		<RTRUE>)
+	       (<NOT <PRSI? <> ,KEY>>
+		<CANT-X-WITH-PRSI "unlock">)
+	       (<FSET? ,PRSO ,LOCKABLE>
+		<COND (<NOT <FSET? ,PRSO ,LOCKED>>
+		       <TELL G"It already is." CR>)
+		      (<IN? ,KEY ,WINNER>
+		       <FCLEAR ,PRSO ,LOCKED>
+		       <TELL "Done." CR>)
+		      (ELSE <TELL G"You need a key to do that." CR>)>)
+	       (ELSE 
+		<NO-LOCK>)>>
+
+<ROUTINE V-UNTIE ()
+	 <TO-A-PRSO?>>
+
+<ROUTINE V-WALK ("AUX" PT PTS STR OBJ RM)
+	 <COND (<AND ,QCONTEXT
+		     <PAST-TENSE?>
+		     <TRY-QCONTEXT?>>
+		<RTRUE>)
+	       (<PAST-TENSE?>
+		<TELL
+"An interesting fact, indeed." CR>)
+	       (<NOT ,P-WALK-DIR>
+		<NEW-VERB ,V?WALK-TO>
+		<RTRUE>)
+	       (<B-NOT-STANDING?>
+		<YOULL-HAVE-TO "stand up">)
+	       (<SET PT <GETPT ,HERE ,PRSO>>
+		<SET PTS <PTSIZE .PT>>
+		<COND (<EQUAL? .PTS ,NEXIT>
+		       <TELL <GET .PT ,NEXITSTR> CR>
+		       <RFATAL>)
+		      (<EQUAL? .PTS ,UEXIT>
+		       <SET RM <GETB .PT ,REXIT>>)
+		      (<EQUAL? .PTS ,FEXIT>
+		       <COND (<NOT <SET RM <APPLY <GET .PT ,FEXITFCN>>>>
+			      <RFATAL>)>)
+		      (<EQUAL? .PTS ,CEXIT>
+		       <COND (<VALUE <GETB .PT ,CEXITFLAG>>
+			      <SET RM <GETB .PT ,REXIT>>)
+			     (<SET STR <GET .PT ,CEXITSTR>>
+			      <TELL .STR CR>
+			      <RFATAL>)
+			     (T
+			      <CANT-GO>
+			      <RFATAL>)>)
+		      (<EQUAL? .PTS ,DEXIT>
+		       <SET OBJ <GET .PT ,DEXITOBJ>>
+		       <COND (<FSET? .OBJ ,INVISIBLE>
+			      <CANT-GO>
+			      <RFATAL>)
+			     (<OR <FSET? .OBJ ,OPENBIT>
+				  <AND <NOT <FSET? .OBJ ,LOCKED>>
+				       <NOT <FSET? .OBJ ,TRYTAKEBIT>>>>
+			      <SET RM <GETB .PT ,DEXITRM>>
+			      <COND (<NOT <FSET? .OBJ ,OPENBIT>>
+				     <FSET .OBJ ,OPENBIT>
+				     <TELL
+"You open " THE .OBJ " and go through." CR CR>)>)
+			     (<SET STR <GET .PT ,DEXITSTR>>
+			      <TELL .STR CR>
+			      <THIS-IS-IT .OBJ>
+			      <RFATAL>)
+			     (T
+			      <TELL-OPEN-CLOSED .OBJ>
+			      <THIS-IS-IT .OBJ>
+			      <RFATAL>)>)>
+		<COND (<SCENE? ,S-NINJA>
+		       <COND (<AND <NOT ,AVOID-CALTROPS?>
+				   <IN? ,CALTROPS ,HERE>>
+			      <COND (<PROB 35>
+				     <JIGS-UP
+"The tiny metal balls on the floor have needle spikes.  You step on one in
+your hurry, and find that they are poisoned!  The fiery pain shoots up your
+leg, and in no time you fall to the floor in agony.">
+				     <RFATAL>)
+				    (ELSE
+				     <TELL
+"As you hurry along, you narrowly miss stepping on a caltrop!" CR CR>)>)
+			     (<IN? ,SMOKE-BOMB ,HERE>
+			      <TELL
+"You try to advance, but the acrid, choking smoke prevents you." CR>
+			      <RFATAL>)
+			     (<IN? ,FIRE-BOMB ,HERE>
+			      <TELL
+"The floor is covering with burning pitch which sticks to your feet and
+drives you back." CR>
+			      <RFATAL>)>)>
+		<GOTO .RM>)
+	       (<AND <EQUAL? ,PRSO ,P?IN ,P?OUT>
+		     ,P-LAST-OPEN
+		     <GLOBAL-IN? ,P-LAST-OPEN ,HERE>>
+		<PERFORM ,V?THROUGH ,P-LAST-OPEN>
+		<RTRUE>)
+	       (T
+		<CANT-GO>
+		<RFATAL>)>>
+
+<GLOBAL P-LAST-OPEN <>>
+
+<ROUTINE V-WALK-AROUND ()
+	 <TELL "Please use compass directions instead." CR>>
+
+<ROUTINE V-WALK-TO ("AUX" DIR TMP)
+	 <COND (,PRSO
+		<COND (<AND ,QCONTEXT
+			    <PAST-TENSE?>
+			    <TRY-QCONTEXT?>>
+		       <RTRUE>)
+		      (<PRSO? ,INTDIR>
+		       <DO-WALK ,P-DIRECTION>
+		       <RTRUE>)
+		      (<IN? ,PRSO ,ROOMS>
+		       ;"do this first because rooms can be in GLOBALS"
+		       <COND (<SET DIR <NEXT-ROOM? ,PRSO>>
+			      <DO-WALK .DIR>)
+			     (ELSE
+			      <TELL
+,YOU-HAVE-TO G"specify a direction." CR>)>)
+		      (<OR <IN? ,PRSO ,HERE>
+			   <GLOBAL-IN? ,PRSO ,HERE>>
+		       <COND (<FSET? ,PRSO ,PERSON>
+			      <COND (<FSET? ,PRSO ,PLURAL>
+				     <TELL "They're">)
+				    (<FSET? ,PRSO ,FEMALE>
+				     <TELL "She's">)
+				    (ELSE <TELL "He's">)>)
+			     (ELSE <TELL "It's">)>
+		       <TELL " here!" CR>)
+		      (<AND <SET TMP <META-LOC ,PRSO>> 
+			    <IN? .TMP ,ROOMS>>
+		       <PERFORM ,PRSA .TMP>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"I'm not sure how to get to ">
+		       <COND (<FSET? ,PRSO ,PERSON>
+			      <COND (<FSET? ,PRSO ,PLURAL>
+				     <TELL "them">)
+				    (<FSET? ,PRSO ,FEMALE>
+				     <TELL "her">)
+				    (ELSE <TELL "him">)>)
+			     (ELSE
+			      <TELL "that">)>
+		       <TELL "." CR>)>)
+	       (T
+		<V-WALK-AROUND>)>>
+
+<ROUTINE NEXT-ROOM? (RM "OPT" (STRICT? <>) "AUX" DIR PT PTS OBJ)
+	 <MAP-DIRECTIONS (DIR PT ,HERE)
+		<SET PTS <PTSIZE .PT>>
+		<COND (<EQUAL? .PTS ,NEXIT>)
+		      (<AND <EQUAL? .PTS ,UEXIT>
+			    <EQUAL? <GETB .PT ,REXIT> .RM>>
+		       <RETURN .DIR>)
+		      (<AND <EQUAL? .PTS ,CEXIT>
+			    <EQUAL? <GETB .PT ,REXIT> .RM>>
+		       <COND (<OR <NOT .STRICT?>
+				  <VALUE <GETB .PT ,CEXITFLAG>>>
+			      <RETURN .DIR>)>)
+		      (<AND <EQUAL? .PTS ,DEXIT>
+			    <EQUAL? <GETB .PT ,DEXITRM> .RM>>
+		       <SET OBJ <GET .PT ,DEXITOBJ>>
+		       <COND (<OR <NOT .STRICT?>
+				  <AND <NOT <FSET? .OBJ ,INVISIBLE>>
+				       <FSET? .OBJ ,OPENBIT>>>
+			      <RETURN .DIR>)>)
+		      (<AND <EQUAL? .PTS ,FEXIT>
+			    <EQUAL? <APPLY <GET .PT ,FEXITFCN>
+					   ,M-ENTER
+					   .STRICT?>
+				    .RM>>
+		       <RETURN .DIR>)>>
+	 <RFALSE>>
+
+<ROUTINE V-WAIT ("AUX" (NUM 3))
+	 <COND (<PRSO? ,INTNUM>
+		<COND (<G? ,P-NUMBER 100>
+		       <TELL "Too long!" CR>)
+		      (T
+		       <SET NUM ,P-NUMBER>)>)>
+	 <TELL "Time passes..." CR>
+	 <REPEAT ()
+		 <COND (<L? <SET NUM <- .NUM 1>> 0>
+			<RETURN>)
+		       (<CLOCKER>
+			<RETURN>)>>
+	 <SETG CLOCK-WAIT T>
+	 <RTRUE>>
+
+<ROUTINE V-WAIT-FOR ()
+	 <COND (<PRSO? INTNUM>
+		<NEW-VERB ,V?WAIT>
+		<RTRUE>)
+	       (<EQUAL? <LOC ,PRSO> ,HERE ,WINNER>
+		<CPRINT-HE/SHE ,PRSO>
+		<TELL "'s already here!" CR>)
+	       (T
+		<TELL "You may well wait quite a while." CR>)>>
+
+<ROUTINE V-WAVE ()
+	 <COND (<AND <NOT <HELD? ,PRSO>>
+		     <FSET? ,PRSO ,BODY-PART>>
+		<YOU-ARENT-HOLDING>)
+	       (ELSE
+		<HACK-HACK "Waving">)>>
+
+<ROUTINE YOU-ARENT-HOLDING ()
+	 <TELL "You aren't holding " THE ,PRSO "." CR>>
+
+<ROUTINE V-WAVE-AT ()
+	 <COND (<AND <NOT <HELD? ,PRSO>>
+		     <FSET? ,PRSO ,BODY-PART>>
+		<YOU-ARENT-HOLDING>)
+	       (<PRSO? ,HEAD>
+		<COND (<NOT ,PRSI>
+		       <PERFORM ,V?NO>
+		       <RTRUE>)
+		      (<FSET? ,PRSI ,PERSON>
+		       <SETG WINNER ,PRSI>
+		       <PERFORM ,V?NO>
+		       <SETG WINNER ,PLAYER>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"Shaking one's head at " A ,PRSI " accomplishes little." CR>)>)
+	       (<AND ,PRSI <FSET? ,PRSI ,PERSON>>
+		<PERFORM ,V?WAVE-AT ,PRSI>
+		<RTRUE>)
+	       (<PRSO? ,ME>
+		<TELL "What a peculiar idea!" CR>)
+	       (ELSE
+		<TELL CTHE ,PRSO IS/ARE ,PRSO "n't likely to respond." CR>)>>
+
+<ROUTINE V-DRESS ("AUX" (OBJ <>) LAST)
+	 <REPEAT ()
+	    <SET LAST .OBJ>
+	    <SET OBJ <>>
+	    <COND (<AND <HELD? ,CLOTHES>
+			<NOT <FSET? ,CLOTHES ,WEARBIT>>>
+		   <SET OBJ ,CLOTHES>)
+		  (<AND <HELD? ,BOOTS>
+			<NOT <FSET? ,BOOTS ,WEARBIT>>>
+		   <SET OBJ ,BOOTS>)
+		  (<AND <HELD? ,KIMONO>
+			<NOT <FSET? ,KIMONO ,WEARBIT>>>
+		   <SET OBJ ,KIMONO>)
+		  (<AND <HELD? ,SOCKS>
+			<NOT <FSET? ,SOCKS ,WEARBIT>>>
+		   <SET OBJ ,SOCKS>)
+		  (<AND <ACCESSIBLE? ,SANDALS>
+			<NOT <FSET? ,SANDALS ,WEARBIT>>>
+		   <SET OBJ ,SANDALS>)>
+	 <COND (.OBJ
+		<FSET .OBJ ,RMUNGBIT> ;"prevents recursion"
+		<PERFORM ,V?WEAR .OBJ>
+		<FCLEAR .OBJ ,RMUNGBIT>
+		<COND (<NOT <FSET? .OBJ ,WEARBIT>>
+		       <RTRUE>)>)
+	       (<NOT .LAST>
+		<TELL "You don't have anything to wear!" CR>
+		<RTRUE>)
+	       (ELSE <RTRUE>)>>>
+
+<ROUTINE V-WEAR ()
+	 <COND (<FSET? ,PRSO ,WEARBIT>
+		<TELL ,YOU-ARE ,PERIOD>)
+	       (<FSET? ,PRSO ,WEARABLE>
+		<COND (<EQUAL? ,PLAYER <GETP ,PRSO ,P?OWNER>>
+		       <COND (<AND <NOT <HELD? ,PRSO>>
+				   <NOT <ITAKE T>>>
+			      <RTRUE>)
+			     (ELSE
+			      <FSET ,PRSO ,WEARBIT>
+			      <TELL
+"You put on " THE ,PRSO "." CR>)>)
+		      (ELSE
+		       <TELL "They don't fit you." CR>)>)
+	       (ELSE
+		<YOU-CANT-X-PRSO "wear">)>>
+
+;<ROUTINE V-WHAT ()
+	 <TELL "An excellent question." CR>>
+
+;<ROUTINE V-WHERE ()
+	 <COND (<NOT ,PRSO>
+		<COND (,P-IT-OBJECT
+		       <NEW-PRSO ,P-IT-OBJECT>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL "Why?" CR>)>)
+	       (ELSE
+		<V-FIND T>)>>
+
+;<ROUTINE PRE-WHO ("AUX" P)
+	 <COND (<AND ,PRSO
+		     <SET P <GETP ,PRSO ,P?PICTURE>>>
+		<MARGINAL-PIC .P>
+		<RFALSE>)>>
+
+;<ROUTINE V-WHO ()
+	 <COND (<NOT ,PRSO> <V-WHAT>)
+	       (<FSET? ,PRSO ,PERSON>
+		<NEW-VERB ,V?WHAT>
+		<RTRUE>)
+	       (T
+		<TELL "That's not a person!" CR>)>>
+
+<ROUTINE V-YAWN ()
+	 <V-LEAN-ON>>
+
+<ROUTINE V-YELL-AT ()
+	 <COND (<AND <FSET? ,PRSO ,PERSON>
+		     <NOT <FSET? ,PRSO ,DEAD>>>
+		<TELL
+"You yell at " D ,PRSO " for a while, which improves your disposition,
+but not " HIS/HER ,PRSO "." CR>)>>
+
+<ROUTINE V-YELL ()
+	 <COND (<PRSO? ,INTQUOTE>
+		<TELL
+"You yell at out, loud and strong.  ">)>
+	 <TELL
+"Raising one's voice is very bad manners and very unsettling
+to the harmony of those around you." CR>>
+
+<ROUTINE V-LAUGH ()
+	 <COND (<NOT ,PRSO> <TELL "Very funny." CR>)
+	       (<AND <FSET? ,PRSO ,PERSON>
+		     <NOT <FSET? ,PRSO ,DEAD>>>
+		<TELL CTHE ,PRSO " doesn't seem to get the joke." CR>)
+	       (ELSE
+		<TELL "Your brand of humor is unusual." CR>)>>
+
+;"subtitle object manipulation"
+
+<CONSTANT FUMBLE-MAX 9>
+
+<GLOBAL FUMBLE-NUMBER 9>
+
+<ROUTINE ITAKE ("OPTIONAL" (VB T) (OBJ 0) "AUX" CNT)
+	 <COND (<ZERO? .OBJ>
+		<SET OBJ ,PRSO>)>
+	 <COND (<AND <B-NOT-STANDING?>
+		     <FSET? ,PRSO ,TAKEBIT>
+		     <NOT <PRSO? ,CLOTHES ,QUILT ,TRAY ,FOOD ,CHOPSTICKS
+				 ,CUP ,GRUEL ,GROUND ,SWORDS>>>
+		<COND (.VB
+		       <TELL "You are ">
+		       <COND (<FSET? ,WINNER ,SURFACEBIT> <TELL "lying">)
+			     (ELSE <TELL "sitting">)>
+		       <TELL
+" down, and " THE ,PRSO IS/ARE ,PRSO " out of reach." CR>)>
+		<RFALSE>)
+	       (<NOT <FSET? .OBJ ,TAKEBIT>>
+		<COND (.VB
+		       <COND (<AND <FSET? .OBJ ,PERSON>
+				   <NOT <FSET? .OBJ ,DEAD>>>
+			      <TELL
+CHE/SHE .OBJ " twist" S .OBJ " away from you." CR>)
+			     (ELSE
+			      <TELL-YUKS>)>)>
+		<RFALSE>)
+	       (<IN? .OBJ ,WINNER>
+		<TELL ,YOU-HAVE THE .OBJ ,PERIOD>
+		<RFALSE>)
+	       (<IN? ,WINNER .OBJ>
+		<TELL "You are ">
+		<COND (<FSET? .OBJ ,SURFACEBIT> <TELL "on">)
+		      (ELSE <TELL "in">)>
+		<TELL " it." CR>)
+	       (<AND <NOT <IN? <LOC .OBJ> ,WINNER>>
+		     <G? <+ <WEIGHT .OBJ> <WEIGHT ,WINNER>> ,LOAD-ALLOWED>>
+		<COND (.VB
+		       <COND (<ZERO? <CCOUNT ,WINNER>>
+			      <TELL "It's too heavy to carry">)
+			     (T
+			      <TELL "Your load is too heavy">)>
+		       <COND (<L? <GETP ,WINNER ,P?HEALTH> 4>
+			      <TELL
+", especially in light of your exhaustion.">)
+			     (T
+			      <TELL ".">)>
+		       <CRLF>)>
+		<RFATAL>)
+	       (<G? <SET CNT <CCOUNT ,WINNER>> ,FUMBLE-NUMBER>
+		<COND (.VB
+		       <TELL
+"You're holding too many things and can't quite get them all arranged
+to take it as well." CR>)>
+		<RFATAL>)
+	       (T
+		<MOVE .OBJ ,WINNER>
+		<FSET .OBJ ,TOUCHBIT>
+		<FCLEAR .OBJ ,WEARBIT>
+		<FCLEAR .OBJ ,NDESCBIT>
+		<RTRUE>)>>
+
+<GLOBAL NOTIFY-FLAG <>>
+
+<ROUTINE V-NOTIFY ()
+	 <SETG NOTIFY-FLAG <NOT ,NOTIFY-FLAG>>
+	 <COND (,NOTIFY-FLAG
+		<TELL "Notifying when points are scored." CR>)
+	       (ELSE
+		<TELL "Keeping quiet when points are scored." CR>)>>
+
+<ROUTINE SCORE-OBJECT ("OPTIONAL" (OBJ <>))
+	 <COND (<FSET? .OBJ ,SCOREBIT>
+		<SETG SCORE <+ ,SCORE 1>>
+		<FCLEAR .OBJ ,SCOREBIT>
+		<COND (<AND <SET OBJ <GET ,SCENE-LOCS ,SCENE>>
+			    <SET OBJ <GETPT .OBJ ,P?SCORE>>>
+		       <PUTB .OBJ 0 <+ 1 <GETB .OBJ 0>>>)
+		      ;(ELSE
+		       <TELL
+"[Problem with scoring in scene " N ,SCENE ", please report as bug!]" CR>)>
+		<COND (,NOTIFY-FLAG
+		       <TELL CR
+"[Your score just went up.]" CR>)>
+		<RTRUE>)>
+	 <RTRUE>>
+
+<ROUTINE IDROP ()
+	 <COND (<OR <FSET? ,PRSO ,BODY-PART>
+		    <NOT <HELD? ,PRSO>>>
+		<TELL G"You aren't ""carrying ">
+		<THE-PRSO>
+		<RFALSE>)
+	       (<AND <NOT <IN? ,PRSO ,WINNER>>
+		     <NOT <FSET? <LOC ,PRSO> ,OPENBIT>>>
+		<THIS-IS-IT ,PRSO>
+		<TELL-OPEN-CLOSED <LOC ,PRSO>>
+		<RFALSE>)
+	       (<FSET? ,PRSO ,WEARBIT>
+		<HAVE-TO-TAKE-OFF>
+		<RFALSE>)
+	       (T
+		<FCLEAR ,PRSO ,WEARBIT>
+		<MOVE ,PRSO <LOC ,WINNER>>
+		<RTRUE>)>>
+
+<ROUTINE HAVE-TO-TAKE-OFF ("OPT" (OBJ ,PRSO))
+	 <TELL ,YOU-HAVE-TO G"take off " THE .OBJ " first." CR>>
+
+<ROUTINE CCOUNT (OBJ "AUX" (CNT 0) X)
+	 <MAP-CONTENTS (X .OBJ)
+		       (END <RETURN .CNT>)
+	      <COND (<NOT <FSET? .X ,WEARBIT>>
+		     <SET CNT <+ .CNT 1>>)>>>
+
+;"WEIGHT: Gets sum of SIZEs of supplied object, recursing to nth level."
+
+<ROUTINE WEIGHT (OBJ "AUX" CONT (WT 0))
+	 <COND (<NOT <FSET? .OBJ ,WEARBIT>>
+		<MAP-CONTENTS (CONT .OBJ)
+			      <SET WT <+ .WT <WEIGHT .CONT>>>>
+		<+ .WT <GETP .OBJ ,P?SIZE>>)>>
+
+;"subtitle movement"
+
+;<ROUTINE LKP (ITM TBL "AUX" (CNT 0) (LEN <GET .TBL 0>))
+	 <REPEAT ()
+		 <COND (<G? <SET CNT <+ .CNT 1>> .LEN>
+			<RFALSE>)
+		       (<EQUAL? <GET .TBL .CNT> .ITM>
+			<COND (<EQUAL? .CNT .LEN> <RFALSE>)
+			      (T
+			       <RETURN <GET .TBL <+ .CNT 1>>>)>)>>>
+
+<GLOBAL OHERE <>>
+
+<ROUTINE GOTO (RM "OPTIONAL" (V? T) "AUX" OLIT)
+	 <SETG OHERE .RM>
+	 <COND (,HERE <APPLY <GETP ,HERE ,P?ACTION> ,M-LEAVE>)>
+	 <SETG OHERE ,HERE>
+	 <SET OLIT ,LIT>
+	 <COND (<NOT <EQUAL? ,OHERE .RM>>
+		<B-STAND>)>
+	 <COND (<NOT <IN? <LOC ,WINNER> ,ROOMS>>
+		<MOVE <LOC ,WINNER> .RM>)
+	       (ELSE
+		<MOVE ,WINNER .RM>)>
+	 <SETG HERE .RM>
+	 <SETG LIT <LIT? ,HERE>>
+	 <COND (<AND <NOT .OLIT>
+		     <NOT ,LIT>
+		     <PROB 80>>
+		<JIGS-UP ;"this string is a duplicate of one in FLASHLIGHT-F"
+"This is a civilized country, but nonetheless one should never assume
+the dark is safe.  Someone just grabbed you from behind and strangled
+you with a silken cord.">
+		<RTRUE>)>
+	 <V-INTRODUCE>
+	 <APPLY <GETP ,HERE ,P?ACTION> ,M-ENTER>
+	 <COND (<NOT <EQUAL? ,HERE .RM>>
+		<RTRUE>)
+	       (.V?
+		<V-FIRST-LOOK>)>
+	 ;<COND (,LIT <SCORE-OBJECT .RM>)>
+	 <RTRUE>>
+
+\
+
+;"subtitle death and stuff"
+
+<GLOBAL STUPID-MOVE <>>
+
+<ROUTINE I-STUPID-MOVE () <SETG STUPID-MOVE <>>>
+
+<ROUTINE JIGS-UP? (N "OPT" (DESC <>))
+	 <COND (<NOT <EQUAL? ,STUPID-MOVE .N>>
+		<QUEUE I-STUPID-MOVE 2>
+		<SETG STUPID-MOVE .N>
+		<COND (.DESC <TELL .DESC CR>)
+		      (ELSE
+		       <TELL
+"At the last second, you stop and try to think of something to do that's
+less likely to be fatal." CR>)>
+		<RFALSE>)
+	       (ELSE <RTRUE>)>>
+
+<ROUTINE JIGS-UP ("OPT" (DESC <>))
+	 <SETG MOVES <+ ,MOVES 1>> ;"lie to update-status-line"
+	 <SETG WINNER ,PLAYER>
+	 <COND (.DESC <TELL .DESC>)>
+	 <TELL "|
+|
+    ****  You have died  ****|
+|">
+	 <COND (<SCENE? ,S-ERASMUS>
+		<TELL
+"Are the Japans ahead?  Now you will never know.  All pilots fear death
+by drowning more than any other death, and most die by drowning.  A
+terrible fate." CR>)
+	       (ELSE
+		<TELL
+"Perhaps in a future existence you will be reborn samurai.  Perhaps,
+as Father Sebastio would predict, you will burn in hell.  Perhaps you
+will ascend to heaven.  Perhaps none of these things will happen. "I"Karma,
+neh?" CR>)>
+	 <CRLF>
+	 <FINISH>>
+
+;<ROUTINE ROB (FROM "OPT" (TO <>) (BIT -1)
+	      "AUX" (F <FIRST? .FROM>) N (1ST? <>))
+	 <REPEAT ()
+		 <COND (.F
+			<SET N <NEXT? .F>>
+			<COND (<OR <AND <G=? .BIT 0>
+					<FSET? .F .BIT>>
+				   <AND <FSET? .F ,TAKEBIT>
+					<FSET? .F ,TOUCHBIT>>>
+			       <SET 1ST? .F>
+			       <COND (.TO <MOVE .F .TO>)
+				     (ELSE <REMOVE .F>)>)>
+			<SET F .N>)
+		       (T
+			<RETURN>)>>
+	 .1ST?>
+
+<ROUTINE MOVE-ALL (FROM "OPT" (TO <>) "AUX" (F <FIRST? .FROM>) N (1ST? <>))
+	 <REPEAT ()
+		 <COND (.F
+			<SET N <NEXT? .F>>
+			<SET 1ST? .F>
+			<COND (.TO <MOVE .F .TO>)
+			      (ELSE <REMOVE .F>)>
+			<FCLEAR .F ,WEARBIT>
+			<SET F .N>)
+		       (T
+			<RETURN>)>>
+	 .1ST?>
+
+;"subtitle useful utility routines"
+
+<ROUTINE THIS-IS-IT (OBJ)
+	 <COND (<FSET? .OBJ ,DONT-IT> <RFALSE>)
+	       (<NOT <EQUAL? .OBJ ,IT ,HIM ,HER ,WHAT ,ROOMS>>
+		<COND (<OR <FSET? .OBJ ,PERSON>
+			   <EQUAL? .OBJ ,LG-ERASMUS>>
+		       <COND (<OR <AND <EQUAL? .OBJ ,LG-RODRIGUES>
+				       <IN? ,RODRIGUES ,IN-THE-SEA>>
+				  <FSET? .OBJ ,DEAD>>
+			      <COND (<NOT <EQUAL? ,P-IT-OBJECT .OBJ>>
+				     <FCLEAR ,IT ,TOUCHBIT>)>
+			      <SETG P-IT-OBJECT .OBJ>)>
+		       <COND (<OR <FSET? .OBJ ,PLURAL>
+				  <EQUAL? .OBJ ,GRAYS ,BROWNS>>
+			      <COND (<NOT <EQUAL? ,P-THEM-OBJECT .OBJ>>
+				     <FCLEAR ,THEM ,TOUCHBIT>)>
+			      <SETG P-THEM-OBJECT .OBJ>)
+			     (<FSET? .OBJ ,FEMALE>
+			      <COND (<NOT <EQUAL? ,P-HER-OBJECT .OBJ>>
+				     <FCLEAR ,HER ,TOUCHBIT>)>
+			      <SETG P-HER-OBJECT .OBJ>)
+			     (ELSE
+			      <COND (<NOT <EQUAL? ,P-HIM-OBJECT .OBJ>>
+				     <FCLEAR ,HIM ,TOUCHBIT>)>
+			      <SETG P-HIM-OBJECT .OBJ>)>)
+		      (<FSET? .OBJ ,PLURAL>
+		       <COND (<NOT <EQUAL? ,P-THEM-OBJECT .OBJ>>
+			      <FCLEAR ,THEM ,TOUCHBIT>)>
+		       <SETG P-THEM-OBJECT .OBJ>)
+		      (ELSE
+		       <COND (<NOT <EQUAL? ,P-IT-OBJECT .OBJ>>
+			      <FCLEAR ,IT ,TOUCHBIT>)>
+		       <SETG P-IT-OBJECT .OBJ>)>)>
+	 <RTRUE>>
+
+<ROUTINE INTRINSIC? (OBJ)
+	 <EQUAL? .OBJ ,ME ,HANDS ,HEAD ,EYES ,FEET>>
+
+<ROUTINE ACCESSIBLE? (OBJ "AUX" (L <LOC .OBJ>)) ;"can player TOUCH object?"
+	 ;"revised 5/2/84 by SEM and SWG"
+	 <COND (<FSET? .OBJ ,INVISIBLE>
+		<RFALSE>)
+	       (<EQUAL? .OBJ ,PSEUDO-OBJECT>
+		<COND (<EQUAL? ,LAST-PSEUDO-LOC ,HERE>
+		       <RTRUE>)
+		      (T
+		       <RFALSE>)>)
+	       (<NOT .L>
+		<RFALSE>)
+	       (<EQUAL? .L ,GLOBAL-OBJECTS>
+		<RTRUE>)
+	       (<AND <EQUAL? .L ,LOCAL-GLOBALS>
+		     <GLOBAL-IN? .OBJ ,HERE>>
+		<RTRUE>)
+	       (<NOT <EQUAL? <META-LOC .OBJ> ,HERE <LOC ,WINNER>>>
+		<RFALSE>)
+	       (<EQUAL? .L ,WINNER ,HERE <LOC ,WINNER>>
+		<RTRUE>)
+	       (<AND <FSET? .L ,OPENBIT>
+		     <ACCESSIBLE? .L>>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE VISIBLE? (OBJ "AUX" (L <LOC .OBJ>)) ;"can player SEE object"
+	 ;"revised 5/2/84 by SEM and SWG"
+	 <COND (<ACCESSIBLE? .OBJ>
+		<RTRUE>)
+	       (<AND <SEE-INSIDE? .L>
+		     <VISIBLE? .L>>
+		<RTRUE>)(T
+		<RFALSE>)>>
+
+<ROUTINE HELD? (OBJ "OPTIONAL" (WHO <>))
+	 ;"is object carried, or in something carried, by player?"
+	 <COND (<NOT .WHO> <SET WHO ,PLAYER>)>
+	 <COND (<NOT .OBJ> <RFALSE>)
+	       (<AND <VERB? GIVE>
+		     <FSET? .OBJ ,CANT-HOLD>> ;"can't hold but can give"
+		<RTRUE>)
+	       (<EQUAL? .OBJ .WHO ,ME> <RTRUE>)
+	       (<FSET? .OBJ ,BODY-PART> <RTRUE>)
+	       (<IN? .OBJ .WHO>
+		<RTRUE>)
+	       (<IN? .OBJ ,ROOMS>
+		<RFALSE>)
+	       (<IN? .OBJ ,GLOBAL-OBJECTS>
+		<RFALSE>)
+	       (T
+		<HELD? <LOC .OBJ> .WHO>)>>
+
+<ROUTINE SEE-INSIDE? (OBJ)
+	 <AND .OBJ
+	      <NOT <FSET? .OBJ ,INVISIBLE>>
+	      <OR <FSET? .OBJ ,TRANSBIT>
+	          <FSET? .OBJ ,OPENBIT>>>>
+
+<ROUTINE GLOBAL-IN? (OBJ1 OBJ2 "AUX" TEE)
+	 <COND (<AND .OBJ2
+		     <SET TEE <GETPT .OBJ2 ,P?GLOBAL>>>
+		<ZMEMQ .OBJ1 .TEE </ <PTSIZE .TEE> 2>>)>>
+
+<ROUTINE DO-WALK (DIR)
+	 <SETG P-WALK-DIR .DIR>
+	 <PERFORM ,V?WALK .DIR>>
+
+;<ROUTINE SOAK-STUFF (OBJ "OPTIONAL" (RECURSE? T)
+		     "AUX" (F <FIRST? .OBJ>) (1ST? T))
+	 <REPEAT ()
+		 <COND (<NOT .F> <RETURN <NOT .1ST?>>)
+		       (<SOAK-OBJ? .F>
+			<SET 1ST? <>>)
+		       (<AND <NOT .RECURSE?>
+			     <EQUAL? .F ,PLAYER>>
+			T)
+		       (<AND <FSET? .F ,CONTBIT>
+			     <FSET? .F ,OPENBIT>
+			     <FIRST? .F>>
+			<COND (<SOAK-STUFF .F>
+			       <SET 1ST? <>>)>)>
+		 <SET F <NEXT? .F>>>>
+
+;<ROUTINE SOAK-OBJ? (F)
+	 <COND (<FSET? .F ,RMUNGBIT> <RFALSE>)>>
+
+<ROUTINE HACK-HACK (STR)
+	 <TELL .STR " " THE ,PRSO " has no effect." CR>>
+
+<ROUTINE TELL-YUKS ()
+	 <TELL <PICK-ONE ,YUKS> CR>>
+
+<CONSTANT YUKS
+	  <LTABLE 0
+		  "Not likely!"
+		  "That would never work!"
+		  "You can't be serious.">>
+
+<ROUTINE PRE-PRY ()
+	 <COND (<AND ,PRSI
+		     <NOT <INTRINSIC? ,PRSI>>
+		     <NOT <HELD? ,PRSI>>
+		     <NOT <IN? ,WINNER ,PRSI>>
+		     <NOT <FSET? ,PRSI ,VEHBIT>>>
+		<NOT-HOLDING ,PRSI>)>>
+
+<ROUTINE V-PRY ()
+	 <NO-EFFECT>>
+
+<ROUTINE V-BURY ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<COND (<FSET? ,PRSO ,DEAD>
+		       <TELL "Cremation is more normal here." CR>)
+		      (ELSE
+		       <TELL
+"Bury " HIM/HER ,PRSO " alive?  How barbaric." CR>)>)
+	       (ELSE
+		<TELL "You might not be able to find it again." CR>)>>
+
+<ROUTINE V-YES ()
+	 <COND (<TRY-QCONTEXT?>
+		<RTRUE>)
+	       (<AND ,PRSO <NOT <PRSO? ,HEAD>>>
+		<TELL "You aren't making much sense." CR>)
+	       (ELSE
+		<TELL "No question was asked that required an answer." CR>)>>
+
+<ROUTINE V-NO ()
+	 <V-YES>>
+
+<ROUTINE V-BUY ()
+	 <UNINTERESTED ,PRSI>>
+
+<ROUTINE PRE-SSELL ()
+	 <SWAP-VERB ,V?SELL>
+	 <RTRUE>>
+
+<ROUTINE V-SSELL () <RTRUE>>
+
+<ROUTINE V-SELL ()
+	 <UNINTERESTED ,PRSI>>
+
+<ROUTINE PRE-TELL-ABOUT ()
+	 <COND (<PRSO? ,ME>
+		<PERFORM ,V?TELL-ME-ABOUT ,PRSI>
+		<RTRUE>)>>
+
+<ROUTINE V-TELL-ABOUT ()
+	 <COND (<HELD? ,PRSI>
+		<SWAP-VERB ,V?SHOW>
+		<RTRUE>)
+	       (<AND <FSET? ,PRSO ,JAPANESEBIT>
+		     <NOT <PRSO? ,MARIKO>>>
+		<DIFFICULTY ,PRSO>)
+	       (ELSE
+		<UNINTERESTED ,PRSO>)>>
+
+<ROUTINE DIFFICULTY (WHO)
+	 <TELL
+"You have a great deal of difficulty making yourself understood. " CTHE .WHO
+" doesn't seem to understand you very well." CR>>
+
+<ROUTINE V-TELL-ME-ABOUT ()
+	 <COND (<TRY-QCONTEXT?> <RTRUE>)
+	       (<WINNER? ,PLAYER>
+		<PERFORM ,V?WHAT ,PRSO>
+		<RTRUE>)
+	       (<AND <FSET? ,WINNER ,JAPANESEBIT>
+		     <NOT <WINNER? ,MARIKO>>>
+		<DIFFICULTY ,WINNER>)
+	       (ELSE
+		<TELL CTHE ,WINNER " doesn't seem to have anything to say
+about that." CR>)>>
+
+<ROUTINE V-TRADE ()
+	 <COND (<AND ,PRSI <FSET? ,PRSI ,PERSON>>
+		<UNINTERESTED ,PRSI>)
+	       (<AND <WINNER? ,PLAYER>
+		     ,PRSI
+		     <NOT <FSET? ,PRSO ,PERSON>>>
+		<COND ;(<IN? ,HACKER ,HERE>
+		       <SETG WINNER ,HACKER>
+		       <NEW-VERB ,PRSA>
+		       <SETG WINNER ,PLAYER>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"No one here is interested in trading." CR>)>)
+	       (ELSE
+		<V-BARGAIN>)>>
+
+<ROUTINE V-ERASE ()
+	 <TELL-YUKS>>
+
+<ROUTINE V-ADMIRE ()
+	 <TELL "Your taste is unusual." CR>>
+
+<ROUTINE V-BARGAIN ()
+	 <TELL "A preoccupation with money and trading is inappropriate
+in this society, very uncultured." CR>>
+
+<ROUTINE V-REPAIR ()
+	 <COND (<FSET? ,PRSO ,RMUNGBIT>
+		<TELL "You don't know how." CR>)
+	       (<FSET? ,PRSO ,PERSON>
+		<TELL "You're a pilot, not a doctor." CR>)
+	       (ELSE
+		<TELL CTHE ,PRSO " isn't broken." CR>)>>
+
+<ROUTINE V-LOOK-UP ()
+	 <COND (<PRSO? ,ROOMS>
+		<TELL "Don't get a sore neck." CR>)
+	       (<AND <PRSO? INTQUOTE>
+		     <ACCESSIBLE? ,DICTIONARY>>
+		<PERFORM ,PRSA ,PRSO ,DICTIONARY>
+		<RTRUE>)
+	       (ELSE
+		<NEW-VERB ,V?WHAT>
+		<RTRUE>)>>
+
+<ROUTINE V-PLUG-IN ()
+	 <YOU-CANT-X-THAT "plug in">>
+
+<ROUTINE V-UNPLUG ()
+	 <YOU-CANT-X-THAT "unplug">>
+
+;<ROUTINE V-EDIT ()
+	 <YOU-CANT-X-THAT "edit">>
+
+;<ROUTINE V-CLICK ()
+	 <TELL ,NOTHING-HAPPENS>>
+
+<ROUTINE V-WALK-UNDER ()
+	 <COND (<PRSO? ,ROOMS>
+		<DO-WALK ,P?DOWN>)
+	       (ELSE
+		<TELL "Only a snake could get under " A ,PRSO "!" CR>)>>
+
+<ROUTINE V-SCARE ()
+	 <TELL "I don't think you scared " THE ,PRSO " very much." CR>>
+
+<ROUTINE V-WEDGE ()
+	 <TELL ,YOU-CANT "wedge open " A ,PRSO " with " A ,PRSI ,PERIOD>>
+
+<ROUTINE PRE-SWEDGE ()
+	 <SWAP-VERB ,V?WEDGE>
+	 <RTRUE>>
+
+<ROUTINE V-SWEDGE ()
+	 <RTRUE>>
+
+<ROUTINE V-PUT-BETWEEN ()
+	 <TELL ,YOU-CANT "put " A ,PRSO " between " A ,PRSI ,PERIOD>>
+
+<ROUTINE V-TASTE ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<TELL
+"You have got to be kidding." CR>)
+	       (ELSE
+		<TELL "It tastes exactly as you'd expect " A ,PRSO " to taste,
+only worse." CR>)>>
+
+<ROUTINE V-DIE ()
+	 <PERFORM ,V?KILL ,ME>
+	 <RTRUE>>
+
+<ROUTINE V-COOK ()
+	 <TELL
+"Most people cook things in ovens." CR>>
+
+<ROUTINE V-DRIVE-ON ()
+	 <COND (<FSET? ,PRSI ,PERSON>
+		<TELL CTHE ,PRSI " moves out of the way." CR>)
+	       (ELSE
+		<TELL ,GOOD-TRICK>)>>
+
+<ROUTINE V-DRIVE-TO ()
+	 <COND (<AND <IN? ,WINNER ,PRSO>
+		     <PRSI? INTDIR>>
+		<DO-WALK ,P-DIRECTION>)
+	       (ELSE
+		<TELL ,GOOD-TRICK>)>>
+
+<ROUTINE V-STEP-ON ()
+	 <COND (<FSET? ,PRSO ,VEHBIT>
+		<NEW-VERB ,V?BOARD>
+		<RTRUE>)
+	       (ELSE
+		<TELL ,WASTE-OF-TIME>)>>
+
+<ROUTINE V-STOP ()
+	 <TELL ,NOTHING-HAPPENS>>
+
+<ROUTINE V-RELEASE ()
+	 <NEW-VERB ,V?DROP>
+	 <RTRUE>>
+
+<ROUTINE V-PUSH-DOWN ()
+	 <PUSH-FOO "down">>
+
+<ROUTINE V-PUSH-UP ()
+	 <PUSH-FOO "up">>
+
+<ROUTINE V-PUSH-OUT ()
+	 <PUSH-FOO "out">>
+
+<ROUTINE PUSH-FOO (DIR)
+	 <COND (<PRSI? ,ROOMS>
+		<TELL
+"You push " THE ,PRSO ", but nothing happens." CR>)
+	       (ELSE
+		<TELL
+,YOU-CANT "push " THE ,PRSO " " .DIR " " THE ,PRSI "." CR>)>>
+
+<ROUTINE V-PRAY ()
+	 <TELL
+"You know that in any Catholic court in the world you would have been
+damned long since for heresy.  And in most, if not all, Protestant
+courts.  But you pray anyway." CR>>
+
+<ROUTINE PRE-SPUT-ON ()
+	 <SWAP-VERB ,V?PUT-ON>
+	 <RTRUE>>
+
+<ROUTINE V-SPUT-ON ()
+	 <RTRUE>>
+
+<ROUTINE V-LOVE ()
+	 <TELL "Your feelings aren't reciprocated." CR>>
+
+<ROUTINE V-THOU ()
+	 <COND (<TRY-QCONTEXT?> <RTRUE>)
+	       (ELSE
+		<TELL "How formal." CR>)>>
+
+<ROUTINE V-WRITE ()
+	 <YOU-CANT-X-THAT "write on">>
+
+<ROUTINE V-RING ()
+	 <YOU-CANT-X-THAT "ring">>
+
+<ROUTINE V-BOW ("AUX" WHO)
+	 <COND (<B-LYING?>
+		<TELL "You can't bow while lying down!" CR>)
+	       (<PRSO? <> ,ROOMS ,HEAD>
+		<COND (<AND ,OPPONENT <IN? ,OPPONENT ,HERE>>
+		       <SET .WHO ,OPPONENT>)
+		      (<AND ,QCONTEXT <IN? ,QCONTEXT ,HERE>>
+		       <SET .WHO ,QCONTEXT>)
+		      (ELSE
+		       <SET WHO <FIND-IN ,HERE ,JAPANESEBIT>>)>
+		<COND (.WHO
+		       <PERFORM ,V?BOW .WHO>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"Good practice!" CR>)>)
+	       (<PRSO? ME>
+		<TELL
+"An action not unlike clapping with one hand." CR>)
+	       (<FSET? ,PRSO ,PERSON>
+		<COND (<FSET? ,PRSO ,DEAD>
+		       <TELL
+"You show your respect for the dead " D ,PRSO "." CR>)
+		      (<FSET? ,PRSO ,DUTCHBIT>
+		       <TELL
+"\"What are you, Pilot?  Some kind of God-cursed courtier?\" grumbles "
+THE ,PRSO "." CR>)
+		      (ELSE
+		       <TELL
+CTHE ,PRSO " returns your bow, instinctively knowing exactly the correct
+degree of deference to show." CR>)>)
+	       (ELSE
+		<TELL
+"You show " THE ,PRSO " all due respect." CR>)>>
+
+<ROUTINE V-SORRY ()
+	 <COND (<AND ,PRSO <FSET? ,PRSO ,PERSON>>
+		<NEW-WINNER-PRSO ,PRSA>
+		<RTRUE>)
+	       (ELSE
+		<TELL
+"I'd be sorry, too." CR>)>>
+
+<ROUTINE V-PISS ()
+	 <COND (<AND ,PRSO
+		     <OR <FSET? ,PRSO ,PERSON>
+			 <FSET? ,PRSO ,BODY-PART>>>
+		<TELL
+"You decide not to do that to " THE ,PRSO ". It's very bad manners." CR>)
+	       (<OR <FSET? ,PRSO ,FOODBIT>
+		    <PRSO? ,FLAGON ,CUP>>
+		<TELL "What a disgusting idea." CR>)
+	       (<SCENE? ,S-ERASMUS>
+		<TELL
+"You feel much better, now." CR>)
+	       (<FSET? ,HERE ,OUTSIDE>
+		<TELL
+"As you have seen the Japanese do, you turn politely away from any possible
+watchers and then do your business." CR>)
+	       (ELSE
+		<TELL
+"What a barbaric idea!  You decide to hold on a little longer." CR>)>>
+
+<ROUTINE V-LOAD ()
+	 <COND (<AND <NOT ,PRSO>
+		     <HELD? ,PISTOL>>
+		<PERFORM ,V?LOAD ,PISTOL>
+		<RTRUE>)
+	       (ELSE
+		<TELL "You can't load that." CR>)>>
+
+<ROUTINE V-STRAIGHTEN ()
+	 <TELL "You can't straighten that!" CR>>
+
+<ROUTINE V-LAUNCH ()
+	 <TELL "You can't launch anything here." CR>>
+
+<ROUTINE V-BLESS ()
+	 <COND (<FSET? ,PRSO ,DEAD>
+		<TELL
+"You can't be sure it does any good, but you pray that it's at least
+the right thing to do." CR>)
+	       (ELSE
+		<TELL "What an odd thing to do." CR>)>>
+
+<ROUTINE V-MAKE ()
+	 <COND (<PRSO? ,SIGN-OF-CROSS>
+		<COND (<NOT ,PRSI>
+		       <TELL
+"An unusual gesture for someone of your religious beliefs." CR>)
+		      (<FSET? ,PRSI ,PERSON>
+		       <PERFORM ,V?BLESS ,PRSI>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"It's generally considered blasphemous to make the sign of the cross
+over " A ,PRSI "." CR>)>)
+	       (ELSE
+		<TELL "You can't make " A ,PRSO "!" CR>)>>
+
+<ROUTINE V-ACT ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<TELL
+"Your imitation is unconvincing." CR>)
+	       (ELSE
+		<TELL
+"You will never make it in " I "noh" " plays, that's certain." CR>)>>
+
+<ROUTINE V-DANCE ()
+	 <COND (,PRSO
+		<TELL CTHE ,PRSO " doesn't seem to want to dance." CR>)
+	       (ELSE
+		<TELL
+"You dance foolishly for a while, then stop, embarrassed." CR>)>>
+
+<ROUTINE V-TEAR ()
+	 <YOU-CANT-X-THAT "tear">>
+
+<ROUTINE V-SHIP ()
+	 <YOU-CANT-X-THAT "ship">>
+
+<ROUTINE V-SORT ()
+	 <TELL CTHE ,PRSO " seems pretty well sorted already." CR>>
+
+<ROUTINE V-ROW ()
+	 <COND (<EQUAL? ,HERE ,MAIN-DECK ,GALLEY>
+		<TELL
+"You could as easily sail the "I"Erasmus"" by blowing on the sails." CR>)
+	       (<NOT <FSET? <LOC ,WINNER> ,VEHBIT>>
+		<TELL
+"You aren't in a boat!" CR>)
+	       (<PRSI? INTDIR>
+		<COND (<IN? ,WINNER ,PRSO>
+		       <DO-WALK ,P-DIRECTION>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL "You aren't in " THE ,PRSO "!" CR>)>)
+	       (<PRSO? INTDIR>
+		<DO-WALK ,P-DIRECTION>
+		<RTRUE>)
+	       (,PRSI
+		<COND (<IN? ,WINNER ,PRSO>
+		       <PERFORM ,V?WALK-TO ,PRSI>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL "You aren't in " THE ,PRSO "!" CR>)>)
+	       (<NOT ,PRSO>
+		<TELL
+"Gently down the stream..." CR>)
+	       (<FSET? ,PRSO ,VEHBIT>
+		<COND (<NOT <IN? ,WINNER ,PRSO>>
+		       <TELL
+"You aren't in " THE ,PRSO "!" CR>)
+		      (ELSE
+		       <TELL
+,YOU-HAVE-TO G"specify a direction." CR>)>)
+	       (,PRSO
+		<TELL "You can't row that!" CR>)>>
+
+<ROUTINE V-TAKE-OVER ()
+	 <TELL "There's nothing to take over here!" CR>>
+
+<ROUTINE V-SHUT-UP ()
+	 <COND (<PRSO? ROOMS>
+		<TELL "You stifle yourself." CR>)
+	       (ELSE
+		<TELL CTHE ,PRSO " doesn't respond." CR>)>>
+
+<ROUTINE V-USE ()
+	 <TELL ,YOU-HAVE-TO G"be more specific about ""how you want
+to use " THE ,PRSO "." CR>>
+
+<ROUTINE V-STEER-BY ()
+	 <TELL "You'll get nowhere that way!" CR>>
+
+<ROUTINE FORMAL-SCENE? ()
+	 <COND (<SCENE? S-TORANAGA S-MARIKO S-ESCAPE S-OCHIBA
+			S-DEPARTURE S-SEPPUKU S-AFTERMATH>
+		<RTRUE>)>>
+
+<ROUTINE V-STRIP ("AUX" (F <FIRST? ,WINNER>) N (1ST? T) (LAST <>))
+	 <COND (<FORMAL-SCENE?>
+		<TELL
+"You would expose yourself to ridicule." CR>)
+	       (ELSE
+		<REPEAT ()
+		 <COND (.F
+			<SET N <NEXT? .F>>
+			<COND (<FSET? .F ,WEARBIT>
+			       <COND (.LAST
+				      <COND (.1ST?
+					     <SET 1ST? <>>
+					     <TELL G"You have removed">)
+					    (ELSE
+					     <TELL ",">)>
+				      <TELL " " THE .LAST>)>
+			       <SET LAST .F>
+			       <FCLEAR .F ,WEARBIT>
+			       ;<MOVE .F ,HERE>)>
+			<SET F .N>)
+		       (T
+			<COND (.LAST
+			       <COND (.1ST?
+				      <SET 1ST? <>>
+				      <TELL G"You have removed">)
+				     (ELSE
+				      <TELL ", and">)>
+			       <TELL " " THE .LAST "." CR>)
+			      (ELSE
+			       <TELL
+"You aren't wearing anything." CR>)>
+			<RETURN>)>>)>>
+
+<ROUTINE V-TRANSLATE ()
+	 <COND (<HELD? ,DICTIONARY>
+		<PERFORM ,V?LOOK-UP ,PRSO ,DICTIONARY>
+		<RTRUE>)
+	       (<LOC ,DICTIONARY>
+		<TELL "You should use the dictionary." CR>)
+	       (ELSE
+		<TELL "It's still unintelligible." CR>)>>
+
+<ROUTINE SETUP-ANSWER (STR)
+	 <COND (<NOT <EQUAL? .STR ,ORPHAN-ANSWER>>
+		<SETG ORPHAN-ANSWER .STR>
+		<COND (.STR
+		       <SETUP-ORPHAN ,ORPHAN-ANSWER>)>)>
+	 <COND (.STR
+		<QUEUE I-SETUP-ANSWER -1 T>)
+	       (ELSE <DEQUEUE I-SETUP-ANSWER>)>>
+
+<GLOBAL ORPHAN-ANSWER <>>
+
+<ROUTINE I-SETUP-ANSWER ()
+	 <COND (,ORPHAN-ANSWER
+		<SETUP-ORPHAN ,ORPHAN-ANSWER>)
+	       (ELSE
+		<DEQUEUE I-SETUP-ANSWER>)>
+	 <RFALSE>>
+
+<ROUTINE V-SMILE ()
+	 <TELL "You smile">
+	 <COND (,PRSO <TELL " at " THE ,PRSO>)>
+	 <TELL ", showing your bad teeth and rotten gums." CR>>
+
+<ROUTINE V-WINK ()
+	 <TELL "You wink">
+	 <COND (,PRSO <TELL " at " THE ,PRSO>)>
+	 <TELL ", but get no reaction." CR>>
+
+<ROUTINE V-CLEAR ()
+	 <COND (<AND <FSET? ,PRSO ,FURNITURE>
+		     <FSET? ,PRSO ,SURFACEBIT>>
+		<EMPTY-ALL ,PRSO <LOC ,WINNER>>)
+	       (ELSE
+		<TELL
+"I don't see how you propose to do that." CR>)>>
+
+<ROUTINE V-TURN-TOWARD ()
+	 <V-TURN-AWAY>>
+
+<ROUTINE V-TURN-AWAY ()
+	 <TELL ,YOU-HAVE-TO G"supply a direction, instead." CR>>
+
+<ROUTINE V-REACH-FOR ()
+	 <TELL G"You can't reach " THE ,PRSO " with " THE ,PRSI "." CR>>
+
+<ROUTINE V-HUG ()
+	 <COND (<AND <FSET? ,PRSO ,PERSON>
+		     <NOT <FSET? ,PRSO ,DEAD>>>
+		<COND (<FSET? ,PRSO ,DUTCHBIT>
+		       <TELL
+"\"I'm no god-cursed sodomite!\" growls " THE ,PRSO "." CR>)
+		      (ELSE
+		       <TELL
+"Such public displays of affection are considered barbaric in Japan." CR>)>)
+	       (ELSE
+		<TELL
+"Only a barbarian would try to hug " A ,PRSO "!" CR>)>>
+
+<ROUTINE V-SOOTHE ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<TELL
+"Your efforts don't seem to have much effect." CR>)
+	       (ELSE
+		<TELL
+"You can't soothe " A ,PRSO "." CR>)>>
+
+<ROUTINE V-HAI ()
+	 <V-IYE>>
+
+<ROUTINE V-IYE ()
+	 <COND (<TRY-QCONTEXT?>
+		<RTRUE>)
+	       (ELSE
+		<TELL "Your accent is atrocious." CR>)>>
+
+<ROUTINE V-HOLD-ON ()
+	 <COND (<PRSO? ROOMS>
+		<TELL "There's nothing to hold onto here!" CR>)
+	       (ELSE
+		<PERFORM ,V?TAKE ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-RINSE ()
+	 <V-BATHE>>
+
+<ROUTINE V-BATHE ()
+	 <TELL "A fine idea, but there are no facilities here." CR>>
+
+<ROUTINE V-REPLACE ()
+	 <COND (<HELD? ,PRSO>
+		<PERFORM ,V?DROP ,PRSO>
+		<RTRUE>)
+	       (ELSE
+		<TELL
+CTHE ,PRSO " is irreplaceable." CR>)>>
+
+<ROUTINE V-ESCAPE ()
+	 <TELL
+"A fine idea, but the details of your plan seem rather sketchy." CR>>
+
+<ROUTINE V-PLEAD ()
+	 <COND (,PRSO 
+		<TELL CTHE ,PRSO " ignores your pleas." CR>)
+	       (ELSE
+		<TELL "Your pleas seem to fall on deaf ears." CR>)>>
+
+<ROUTINE V-COMMIT ()
+	 <COND (<PRSO? SUICIDE>
+		<PERFORM ,V?KILL ,ME>
+		<RTRUE>)
+	       (ELSE
+		<TELL
+"It's you that should be committed." CR>)>>
+
+<ROUTINE V-ACCUSE ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<TELL "\"Never!\"" CR>)
+	       (ELSE
+		<TELL "You are obviously going a bit paranoid." CR>)>>
+
+<ROUTINE V-SPIT ()
+	 <TELL "What an uncouth idea." CR>>
+
+<ROUTINE V-TEKI ()
+	 <COND (<FSET? ,TEKI ,RMUNGBIT>
+		<TELL "In Japanese, "I"teki"" means 'enemy.'" CR>)
+	       (ELSE
+		<TELL "That's not a word you know." CR>)>>
+
+<ROUTINE GET-INTQUOTE (N "AUX" (NP <GET-NP ,INTQUOTE>) LEN)
+	 <SET LEN
+	      <- </ <- <NP-LEXEND .NP> <NP-LEXBEG .NP>>
+		    ,LEXV-ELEMENT-SIZE-BYTES>
+		 1>>
+	 <SET N <* .N 2>>
+	 <COND (<G? .N .LEN> <RFALSE>)
+	       (ELSE
+		<ZGET <ZREST <NP-LEXBEG .NP> ,LEXV-ELEMENT-SIZE-BYTES>
+		      .N>)>>
+
+<ROUTINE PRE-SSPEAK ()
+	 <SWAP-VERB ,V?SPEAK>
+	 <RTRUE>>
+
+<ROUTINE V-SSPEAK ()
+	 <RTRUE>>
+
+<ROUTINE V-SPEAK ()
+	 <COND (<PRSO? ENGLISH>
+		<TELL
+"English is your native tongue.  You speak the English of London,
+and have fond memories of the plays of Jonson and Shakespeare." CR>)
+	       (<PRSO? DUTCH>
+		<TELL
+"Your mother was Dutch, and your men are mostly Dutch, so you speak
+it fluently.  Holland is England's only ally against the treacherous
+Spanish." CR>)
+	       (<PRSO? PORTUGUESE>
+		<TELL
+"Your Portuguese is excellent." CR>)
+	       (<PRSO? SPANISH>
+		<TELL
+"You can speak the language of the hated Spaniards like a native." CR>)
+	       (<PRSO? LATIN>
+		<TELL
+"Like all educated men, you speak Latin." CR>)
+	       (<PRSO? JAPANESE>
+		<COND (<SCENE? ,S-ERASMUS ,S-ANJIRO>
+		       <TELL "You don't know any Japanese." CR>)
+		      (ELSE
+		       <TELL
+"Your accent is atrocious, and your vocabulary small, but you are
+learning fast." CR>)>)
+	       (ELSE
+		<TELL
+"That's not a language you know." CR>)>>
+
+<ROUTINE V-AIM ("AUX" W)
+	 <COND (<NOT ,PRSI>
+		<COND (<FSET? ,PRSO ,PERSON>
+		       <COND (<SET W <FIND-IN ,WINNER ,WEAPONBIT>>
+			      <PERFORM ,PRSA .W ,PRSO>
+			      <RTRUE>)
+			     (ELSE
+			      <TELL
+"You sight carefully along your finger..." CR>)>)
+		      (ELSE
+		       <TELL "How strange." CR>)>)
+	       (ELSE
+		<TELL "You aim " THE ,PRSO " at " THE ,PRSI "." CR>)>>
+
+<ROUTINE V-EXPLODE ()
+	 <COND (,PRSI
+		<TELL
+"A " ,PRSI " doesn't make a very good explosive!" CR>)
+	       (ELSE
+		<TELL ,YOU-HAVE-TO "use an explosive." CR>)>>
+
+
+<GLOBAL HINTS-OFF:NUMBER -1>
+
+<REPLACE-DEFINITION INIT-HINT-SCREEN
+<ROUTINE INIT-HINT-SCREEN ()
+  <SCREEN ,S-FULL>
+  <CLEAR ,S-FULL>
+  <RESET-MARGIN>
+  <DISPLAY ,P-HINT-BORDER 1 1>
+  <SETUP-TEXT-AND-STATUS ,P-HINT-LOC>
+  <WINDEF ,S-STATUS 1 1 <* 4 ,FONT-Y> <LOWCORE HWRD>>
+  <SCREEN ,S-TEXT>
+  <MARGIN 0 0>
+  ,S-STATUS>>
+
+<REPLACE-DEFINITION LEAVE-HINT-SCREEN
+ <ROUTINE LEAVE-HINT-SCREEN ()
+	  <REPAINT-DISPLAY>>>
+
+<ROUTINE V-HINT ()
+	 <COND (<EQUAL? ,HINTS-OFF -1>
+		<SETG HINTS-OFF 0>
+		<TELL
+"Warning: We strongly recommend that you not use hints unless you're definitely
+stuck.  Peeking at hints prematurely will invariably make you enjoy
+the story less.  If you want to avoid reading any hints for the rest of this
+session, you may at any time during the story type HINTS OFF.|
+|
+Do you still want a hint">
+		<COND (<NOT <YES?>>
+		       <RFATAL>)>)
+	       (,HINTS-OFF
+		<PERFORM ,V?HINTS-OFF ,ROOMS>
+		<RFATAL>)>
+	 <COND (<G? ,SCENE ,S-ESCAPE> ;"default chapter is current scene"
+		<SETG H-CHAPT-NUM <+ ,SCENE 1>>)
+	       (ELSE <SETG H-CHAPT-NUM ,SCENE>)>
+	 <DO-HINTS>>
+
+<ROUTINE V-HINTS-OFF ()
+	 <COND (<NOT <PRSO? ,ROOMS>>
+		<TELL "[Sorry, I don't understand.]" CR>
+		<RTRUE>)
+	       (,HINTS-OFF
+		<TELL "[You've already deactivated">)
+	       (T
+		<SETG HINTS-OFF T>
+		<TELL "[Okay, you will no longer have access to">)>
+	 <TELL " help in this session.]" CR>>
+
+<ROUTINE V-PICK-UP ()
+	 <TELL
+CTHE ,PRSI " doesn't seem to be much help in getting " THE ,PRSO "." CR>>
+
+<ROUTINE V-COME-FROM ()
+	 <COND (<TRY-QCONTEXT?>
+		<RTRUE>)
+	       (ELSE
+		<TELL "So, you c">
+		<COND (<PAST-TENSE?>
+		       <TELL !\a>)
+		      (T
+		       <TELL !\o>)>
+		<TELL "me from " D ,PRSO "." CR>)>>
+
+<ROUTINE PAST-TENSE? ()
+	 <BAND ,PAST-TENSE <WORD-FLAGS ,P-PRSA-WORD>>>
+
+<ROUTINE PRE-COME-TO-FROM ()
+	 <COND (<PRSO? ,GLOBAL-HERE ,JAPAN>
+		<PERFORM ,V?COME-FROM ,PRSI>
+		<RTRUE>)>>
+
+<ROUTINE V-COME-TO-FROM ()
+	 <TELL "That's very interesting." CR>>
+
+<ROUTINE V-PARRY ()
+	 <TELL "There doesn't seem to be anything to parry." CR>>
+
+<ROUTINE V-TEACH ()
+	 <COND (<TRY-QCONTEXT?> <RTRUE>)
+	       (<FSET? ,PRSO ,PERSON>
+		<TELL "You do your best to teach " THE ,PRSO "." CR>)
+	       (ELSE
+		<TELL "You can't teach " A ,PRSO "!" CR>)>>
+
+<ROUTINE V-LEARN ()
+	 <COND (<TRY-QCONTEXT?>
+		<RTRUE>)
+	       (ELSE
+		<TELL "Perhaps you should ask someone to teach you." CR>)>>
+
+<ROUTINE V-LOOK-OUT ()
+	 <COND (<PRSO? ,ROOMS>
+		<COND (<FSET? ,HERE ,OUTSIDE>
+		       <TELL
+"You are outside already!" CR>)
+		      (ELSE
+		       <TELL
+,YOU-HAVE-TO "go outside to look outside." CR>)>)
+	       (ELSE
+		<PERFORM ,V?EXAMINE ,PRSO>
+		<RTRUE>)>>
+
+
+
+"standing, sitting, kneeling, and lying down"
+
+<ROUTINE B-STAND ()
+         <FCLEAR ,BLACKTHORNE ,SITTING>
+	 <FCLEAR ,BLACKTHORNE ,TRANSBIT>
+	 <FCLEAR ,BLACKTHORNE ,SURFACEBIT>>
+
+<ROUTINE B-SITTING? ()
+	 <AND <FSET? ,BLACKTHORNE ,SITTING>
+	      <NOT <FSET? ,BLACKTHORNE ,TRANSBIT>>
+	      <NOT <FSET? ,BLACKTHORNE ,SURFACEBIT>>>>
+
+<ROUTINE B-SIT ()
+	 <FSET ,BLACKTHORNE ,SITTING>
+	 <FCLEAR ,BLACKTHORNE ,TRANSBIT>
+	 <FCLEAR ,BLACKTHORNE ,SURFACEBIT>>
+
+<ROUTINE B-KNEELING? ()
+	 <AND <FSET? ,BLACKTHORNE ,SITTING>
+	      <FSET? ,BLACKTHORNE ,TRANSBIT>>>
+
+<ROUTINE B-KNEEL ()
+	 <FSET ,BLACKTHORNE ,SITTING>
+	 <FSET ,BLACKTHORNE ,TRANSBIT>
+	 <FCLEAR ,BLACKTHORNE ,SURFACEBIT>>	 
+
+<ROUTINE B-LYING? ()
+	 <AND <FSET? ,BLACKTHORNE ,SITTING>
+	      <FSET? ,BLACKTHORNE ,SURFACEBIT>>>
+
+<ROUTINE B-LIE-DOWN ()
+	 <FSET ,BLACKTHORNE ,SITTING>
+	 <FCLEAR ,BLACKTHORNE ,TRANSBIT>
+	 <FSET ,BLACKTHORNE ,SURFACEBIT>>
+
+<ROUTINE V-STAND ("AUX" AV)
+	 <COND (<PRSO? <> ,ROOMS>
+		<SET AV <LOC ,WINNER>>
+		<COND (<AND <FSET? .AV ,VEHBIT>
+			    <NOT <EQUAL? .AV ,QUILT>>>
+		       <TELL
+"You shouldn't stand up inside " A .AV "." CR>)
+		      (<B-NOT-STANDING?>
+		       <B-STAND>
+		       <TELL
+"You stand up." CR>)
+		      (T
+		       <TELL ,YOU-ARE " standing." CR>)>)
+	       (ELSE 
+		<HACK-HACK "Holding up">)>>
+
+<ROUTINE V-SIT ()
+	 <COND (<NOT <PRSO? <> ,ROOMS>>
+		<TELL ,WASTE-OF-TIME>)
+	       (<B-NOT-STANDING?>
+		<COND (<B-SITTING?>
+		       <TELL G"You already are." CR>)
+		      (ELSE
+		       <B-SIT>
+		       <TELL "You sit up." CR>)>)
+	       (ELSE
+		<B-SIT>
+		<TELL "You sit down." CR>)>>
+
+<ROUTINE V-KNEEL ()
+	 <COND (<B-KNEELING?>
+		<TELL G"You already are." CR>)
+	       (ELSE
+		<B-KNEEL>
+		<TELL G"You kneel abjectly." CR>)>>
+
+<ROUTINE V-KNEEL-ON ()
+	 <COND (<OR <PRSO? ,GROUND>
+		    <FSET? ,PRSO ,FURNITURE>>
+		<PERFORM ,V?KNEEL>
+		<RTRUE>)
+	       (ELSE
+		<TELL "You can't kneel on that!" CR>)>>
+
+<ROUTINE V-LIE-DOWN ()
+	 <COND (<PRSO? ,ROOMS ,GROUND>
+		<COND (<B-LYING?>
+		       <TELL G"You already are." CR>)
+		      (ELSE
+		       <B-LIE-DOWN>
+		       <TELL "You lie down." CR>)>)
+	       (<FSET? ,PRSO ,VEHBIT>
+		<PERFORM ,V?BOARD ,PRSO>
+		<RTRUE>)>>
+
+
+
+<ROUTINE V-LIE ()
+	 <TELL
+"A duplicitous idea, but you'll have to be more specific." CR>>
+
+<ROUTINE V-AVOID ()
+	 <COND (<PRSO? OPPONENT>
+		<PERFORM ,V?DODGE>
+		<RTRUE>)
+	       (ELSE <TELL "You're doing the best you can." CR>)>>
+
+<ROUTINE V-FUCK ()
+	 <COND (<AND <PRSO? YOU>
+		     <TRY-QCONTEXT?>>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,PERSON>
+		<COND (<FSET? ,PRSO ,FEMALE>
+		       <TELL
+"What an indelicate, even coarse, suggestion!" CR>)
+		      (ELSE
+		       <TELL
+"Your predelictions are unusual, even given the local attitudes on
+these matters." CR>)>)
+	       (ELSE
+		<TELL "An unusual idea." CR>)>>
+
+<ROUTINE V-KNOW ()
+	 <TELL "I don't know." CR>>
+
+<ROUTINE V-TRAIN ()
+	 <COND (<TRY-QCONTEXT?>
+		<RTRUE>)
+	       (ELSE
+	 <TELL "It'll take a lot of training." CR>)>>
+
+<ROUTINE V-BETRAY ()
+	 <COND (<AND <PAST-TENSE?> <TRY-QCONTEXT?>>
+		<RTRUE>)
+	       (ELSE
+		<TELL
+"There's no one to betray " THE ,PRSO " to." CR>)>>
+
+<ROUTINE V-LET-IN ()
+	 <COND (<TRY-QCONTEXT?>
+		<RTRUE>)
+	       (ELSE
+		<TELL
+,YOU-HAVE-TO G"be more specific about ""how you are doing that." CR>)>>
+
+<ROUTINE V-PUT-AWAY ()
+	 <COND (<PRSI? ,ROOMS>
+		<TELL ,YOU-HAVE-TO G"be more specific about ""where you want
+to put " THE ,PRSO "." CR>)
+	       (ELSE
+		<PERFORM ,V?PUT ,PRSO ,PRSI>
+		<RTRUE>)>>
+
+<ROUTINE V-DODGE ()
+	 <COND (<AND <PRSO? ROOMS <> OPPONENT> ,OPPONENT>
+		<TELL
+"You try to get out of the way of " THE ,OPPONENT "'s attack." CR>)
+	       (<PRSO? ROOMS <>>
+		<TELL "There's nothing to duck." CR>)
+	       (ELSE
+		<TELL "You don't need to dodge " THE ,PRSO "." CR>)>>
+
+<ROUTINE V-WAKARIMASU ()
+	 <TELL "That's nice." CR>>
+
+;<ROUTINE V-WAKARIMASEN ()
+	 <TELL "That's too bad." CR>>
+
+<ROUTINE V-MIZU ()
+	 <COND (<G=? ,SCENE ,S-PRISON>
+		<TELL "That's Japanese for 'water.'" CR>)
+	       (ELSE
+		<TELL "What's that mean?" CR>)>>
+
+<ROUTINE V-QUIET ()
+	 <TELL "There doesn't seem to be anyone paying attention." CR>>
+
+
+
+"changing color"
+
+<SYNTAX COLOR = V-COLOR>
+
+<GLOBAL COLOR-NOTE <>>
+
+<GLOBAL FG-COLOR 1>
+
+<GLOBAL BG-COLOR 1>
+
+<ROUTINE V-COLOR ("AUX" (DEFAULT <>) FG BG)
+	 <COND (<APPLE?>
+		<TELL
+"[Sorry, the Apple II doesn't support color selection.]" CR>
+		<RTRUE>)
+	       (<AND <NOT ,COLOR-NOTE>
+		     <EQUAL? ,MACHINE ,MACINTOSH>
+		     <MAC-II?>>
+		<SETG COLOR-NOTE T>
+		<TELL
+"If your Mac II displays fewer than 256 colors, you probably won't get
+the color you ask for.  Do you still want to go ahead">
+		<COND (<NOT <YES?>> <RTRUE>)>)>
+	 <CRLF>
+	 <SET FG ,FG-COLOR>
+	 <SET BG ,BG-COLOR>
+	 <REPEAT ()
+	    <DO-COLOR>
+	    <TELL
+"You will get " <GET ,COLOR-TABLE ,FG-COLOR> " text on a "
+<GET ,COLOR-TABLE ,BG-COLOR> " background.|
+Is that what you want">
+	    <COND (<YES?>
+		   <COLOR ,FG-COLOR ,BG-COLOR>
+		   <V-$REFRESH>
+		   <RTRUE>)
+		  (ELSE
+		   <SETG FG-COLOR .FG>
+		   <SETG BG-COLOR .BG>
+		   <TELL CR "Do you want to pick again">
+		   <COND (<YES?> <CRLF>)
+			 (ELSE <RTRUE>)>)>>>
+
+<ROUTINE MAC-II? ()
+	 <COND (<AND <EQUAL? ,MACHINE ,MACINTOSH>
+		     <EQUAL? <WINGET ,S-FULL ,WWIDE> 640>>)>>
+
+<ROUTINE DO-COLOR ()
+	 <COND (<AND <EQUAL? ,MACHINE ,MACINTOSH>
+		     <NOT <MAC-II?>>> ;"b&w Mac"
+		<COND (<EQUAL? ,BG-COLOR ,C-BLACK>
+		       <SETG BG-COLOR ,C-WHITE>
+		       <SETG FG-COLOR ,C-BLACK>)
+		      (T
+		       <SETG BG-COLOR ,C-BLACK>
+		       <SETG FG-COLOR ,C-WHITE>)>)
+	       (T
+		<SETG FG-COLOR <PICK-COLOR ,FG-COLOR "text" T>>
+		<SETG BG-COLOR <PICK-COLOR ,BG-COLOR "background">>)>
+	 <RTRUE>>
+
+<ROUTINE PICK-COLOR (WHICH STRING "OPTIONAL" (SETTING-FG <>) "AUX" CHAR)
+	 <TELL
+"The current " .STRING " color is " <GET ,COLOR-TABLE .WHICH> "." CR>
+	 <COND (<EQUAL? .WHICH 1>
+		<COND (.SETTING-FG <SET WHICH ,C-BLACK>)
+		      (ELSE <SET WHICH ,C-WHITE>)>)>
+	 <REPEAT ()
+		 <SET CHAR
+		      <GET-FROM-MENU "Pick a color:"
+				     ,COLOR-MENU
+				     ,COLOR-MENU-F
+				     <COLOR-OFFSET .WHICH>>>
+		 <COND (<AND <NOT .SETTING-FG>
+			     <EQUAL? .CHAR ,FG-COLOR>>
+			<TELL CR
+"You can't make the background the same
+color as the text!  Pick another color." CR>)
+		       (T
+			<RETURN>)>>
+	 <CRLF>
+	 <CRLF>
+	 <RETURN .CHAR>>
+
+<ROUTINE COLOR-OFFSET (TMP)
+	 <COND (<EQUAL? .TMP ,C-WHITE> <SET TMP 1>)>
+	 .TMP>
+
+<ROUTINE COLOR-MENU-F (TMP M)
+	 <COND (<EQUAL? .TMP 1> ;"white is really 9, not 1"
+		<SET TMP ,C-WHITE>)>
+	 .TMP>
+
+<CONSTANT COLOR-MENU
+	  <LTABLE <TABLE (PURE STRING LENGTH) "White ">
+		  <TABLE (PURE STRING LENGTH) "Black ">
+		  <TABLE (PURE STRING LENGTH) "Red ">
+		  <TABLE (PURE STRING LENGTH) "Green ">
+		  <TABLE (PURE STRING LENGTH) "Yellow ">
+		  <TABLE (PURE STRING LENGTH) "Blue ">
+		  <TABLE (PURE STRING LENGTH) "Magenta ">
+		  <TABLE (PURE STRING LENGTH) "Cyan ">>>
+
+<CONSTANT COLOR-TABLE
+	  <TABLE ;0 "no change"
+		 ;1 "the default color"
+		 ;2 "black"
+		 ;3 "red"
+		 ;4 "green"
+		 ;5 "yellow"
+		 ;6 "blue"
+		 ;7 "magenta"
+		 ;8 "cyan"
+		 ;9 "white">>
+
+<ROUTINE V-SHRUG ()
+	 <TELL "An eloquent gesture." CR>>
+
+<ROUTINE V-SING ()
+	 <COND (<PRSO? <> ,ME>
+		<TELL
+"You sing an old sea chanty.">
+		<COND (<G? ,SCENE 1>
+		       <TELL " It's a good thing no Japanese understand
+English.">)>
+		<CRLF>)
+	       (<FSET? ,PRSO ,PERSON>
+		<TELL
+CTHE ,PRSO " doesn't seem impressed." CR>)
+	       (ELSE
+		<TELL "You can't sing that." CR>)>>
+
+<ROUTINE V-DISTRACT ()
+	 <TELL "You are unsuccessful." CR>>
+
+<ROUTINE V-JOIN ()
+	 <COND (<FSET? ,PRSO ,PERSON>
+		<PERFORM ,V?WALK-TO ,PRSO>
+		<RTRUE>)
+	       (ELSE
+		<PERFORM ,V?BOARD ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE OUTSIDE-TUB? (TUB)
+	 <AND <NOT <GAME-VERB?>>
+	      <NOT <PASSIVE-VERB?>>
+	      ,PRSO
+	      <NOT <HELD? ,PRSO>>
+	      <NOT <PRSO? .TUB ,ME ,ROOMS>>
+	      <NOT <IN? ,PRSO .TUB>>
+	      <NOT <FSET? ,PRSO ,BODY-PART>>
+	      <NOT <PRSO? LATIN SPANISH PORTUGUESE DUTCH>>>>
+
+<ROUTINE V-DRAW ()
+	 <COND (<AND <FSET? ,PRSO ,WEAPONBIT>
+		     <HELD? ,PRSO>>
+		<PERFORM ,V?USE ,PRSO>
+		<RTRUE>)
+	       (ELSE
+		<TELL
+"The result reveals that it's a good thing you became a Pilot
+instead of an artist." CR>)>>
+
+<ROUTINE V-DIVE ()
+	 <COND (,PRSO
+		<COND (<FSET? ,PRSO ,VEHBIT>
+		       <PERFORM ,V?BOARD ,PRSO>
+		       <RTRUE>)
+		      (<FSET? ,PRSO ,DOORBIT>
+		       <PERFORM ,V?THROUGH ,PRSO>
+		       <RTRUE>)
+		      (<IN? ,PRSO ,ROOMS>
+		       <PERFORM ,V?WALK-TO ,PRSO>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL "You can't dive into " THE ,PRSO "." CR>)>)
+	       (ELSE
+		<TELL "Taking a dive, eh?" CR>)>>
+
+<ROUTINE V-BABBLE ()
+	 <TELL "You babble nonsense for a while." CR>>
+
+<ROUTINE V-TRIP ()
+	 <TELL "You are unsuccessful." CR>>
+
+<ROUTINE V-NIHON-GO-GA ()
+	 <COND (<TRY-QCONTEXT?> <RTRUE>)
+	       (<PRSO? ,HANASE-MASEN>
+		<TELL "True enough, but you're getting better." CR>)
+	       (ELSE
+		<TELL G"You are making little sense." CR>)>>
+
+<ROUTINE V-GENKI-DESU ()
+	 <COND (<TRY-QCONTEXT?> <RTRUE>)
+	       (<PRSO? ,ROOMS>
+		<TELL "It's good to know you're feeling well." CR>)
+	       (ELSE
+		<TELL G"You are making little sense." CR>)>>
+
+<ROUTINE V-GOMEN-NASAI ()
+	 <COND (<TRY-QCONTEXT?> <RTRUE>)
+	       (<PRSO? ,ROOMS>
+		<TELL "No one seems to be expecting an apology." CR>)
+	       (ELSE
+		<TELL G"You are making little sense." CR>)>>
+
+<ROUTINE V-ISOGI ()
+	 <COND (<TRY-QCONTEXT?> <RTRUE>)
+	       (ELSE
+		<TELL "No one seems to be listening." CR>)>>
+
+<ROUTINE V-KONBANWA ()
+	 <PERFORM ,V?KONNICHI-WA ,ROOMS>
+	 <RTRUE>>
+
+<ROUTINE V-KONNICHI-WA ()
+	 <COND (<TRY-QCONTEXT?> <RTRUE>)
+	       (<PRSO? ,ROOMS>
+		<TELL "Good practice!  Your accent is getting better." CR>)
+	       (ELSE
+		<TELL G"You are making little sense." CR>)>>
+
+<ROUTINE V-KINJIRU ()
+	 <COND (<TRY-QCONTEXT?> <RTRUE>)
+	       (ELSE
+		<TELL G"It's not clear what you are getting at." CR>)>>
+
+<ROUTINE V-DRY ()
+	 <TELL CTHE ,PRSO " doesn't seem to want to be dried." CR>>
+
+<ROUTINE V-WARN ()
+	 <COND (<NOT <FSET? ,PRSO ,PERSON>>
+		<YOU-CANT-X-PRSO "warn">)
+	       (<FSET? ,PRSO ,DEAD>
+		<TELL
+,YOU-CANT G"expect a response from a dead person!" CR>)
+	       (,PRSI
+		<TELL
+CTHE ,PRSO " doesn't seem worried about " THE ,PRSI "." CR>)
+	       (,OPPONENT
+		<PERFORM ,V?WARN ,PRSO ,OPPONENT>
+		<RTRUE>)
+	       (ELSE
+		<TELL
+CTHE ,PRSO " doesn't seem worried." CR>)>>
+
+<ROUTINE V-PULL-BEHIND ()
+	 <YOU-CANT-X-PRSO "pull">>
+
+<ROUTINE V-TOMO ()
+	 <COND (<TRY-QCONTEXT?> <RTRUE>)
+	       (ELSE
+		<TELL G"It's not clear what you are getting at." CR>)>>
+
+<ROUTINE V-NEH ()
+	 <TELL "\"Neh.\"" CR>>
+
+<END-SEGMENT>
\ No newline at end of file
diff --git a/voyage.zil b/voyage.zil
new file mode 100644
index 0000000..952c3b6
--- /dev/null
+++ b/voyage.zil
@@ -0,0 +1,2303 @@
+"VOYAGE for
+				 SHOGUN
+	(c) Copyright 1988 Infocom, Inc.  All Rights Reserved."
+
+<FILE-FLAGS SENTENCE-ENDS?>
+
+<BEGIN-SEGMENT VOYAGE>
+
+<CONSTANT J-PILING 60>
+
+<OBJECT LG-BAY
+	(LOC LOCAL-GLOBALS)
+	(DESC "bay")
+	(SYNONYM BAY HARBOR POINT)
+	(FLAGS NDESCBIT)
+	(ACTION LG-BAY-F)>
+
+<ROUTINE LG-BAY-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<SCENE? ,S-VOYAGE>
+		       <TELL
+"The bay looks like an island of relative calm." CR>)
+		      (ELSE
+		       <TELL
+"The harbor is a small bay protected by reefs almost out of sight to the
+east." CR>)>)
+	       (<P? (PUT THROW) * LG-BAY>
+		<PERFORM ,PRSA ,PRSO ,LG-SEA>
+		<RTRUE>)>>
+
+<OBJECT LG-LAND
+	(LOC LOCAL-GLOBALS)
+	(DESC "land")
+	(SYNONYM LAND SHORE ROCK ROCKS CLIFF CLIFFS HEADLAND WATERFRONT WHARF)
+	(ADJECTIVE DRY)
+	(FLAGS NDESCBIT)
+	(ACTION LG-LAND-F)>
+
+<ROUTINE LG-LAND-F ("AUX" TRIES)
+	 <COND (<AND <SCENE? ,S-ANJIRO ,S-RODRIGUES>
+		     <VERB? WALK-TO>>
+		<DO-WALK ,P?WEST>)
+	       (<AND <SCENE? ,S-VOYAGE>
+		     <VERB? POINT>
+		     <NOT <FSET? ,ANCHOR ,SCOREBIT>>>
+		<COND (<FSET? ,SKIFF ,RMUNGBIT>
+		       <SET TRIES <GETP ,SKIFF ,P?COUNT>>
+		       <PUTP ,SKIFF ,P?COUNT <+ .TRIES 1>>
+		       <COND (<ZERO? .TRIES>
+			      <TELL
+"Hiro-matsu is here, with Yabu beside him.  They eventually realize
+you are proposing to go ashore, and Hiro-matsu responds harshly.  ">
+			      <HIRO-MATSU-REFUSES>)
+			     (<EQUAL? .TRIES 1>
+			      <YABU-BOARDS-SKIFF>)>)
+		      (ELSE
+		       <TELL
+G"It would be a good trick, and somewhat amusing, to get into a boat
+while it's still on deck, but not a good idea." CR>)>)
+	       (<VERB? RUB CLIMB-ON>
+		<COND (<OR <SCENE? ,S-ERASMUS>
+			   <AND <SCENE? ,S-VOYAGE>
+				<HERE? ,IN-THE-SEA ,GALLEY ,MAIN-DECK>>>
+		       <TELL
+"It's too far away." CR>)
+		      (ELSE
+		       <TELL
+"It feels like you would expect land to feel." CR>)>)>>
+
+<ROUTINE HIRO-MATSU-REFUSES ()
+	 <TELL
+"\""I"Iye!""\" Hiro-matsu shakes his head, and speaks at length clearly
+refusing permission because of the danger." CR>>
+
+<ROUTINE YABU-BOARDS-SKIFF ()
+	 <QUEUE I-SKIFF -1>
+	 <MOVE ,HIRO-MATSU ,GENERIC-OBJECTS>
+	 <MOVE ,YABU ,SKIFF>
+	 <MOVE ,SEARCH-PARTY ,SKIFF>
+	 <MOVE ,OARS ,SKIFF>
+	 <TELL
+"This time the old man points his sword at the skiff and shakes his
+head.  He and Yabu begin an animated discussion in Japanese, motioning
+the mate over to join them.  Hiro-matsu studies the coast for a
+while.  Finally, he beckons a samurai, points to you, and gives some apparent
+instructions.  The samurai and six other warriors clamber nimbly into
+the skiff, and to your surprise, so does Yabu!|
+|
+Hiro-matsu points to the skiff, bows politely to you, and then goes
+below." CR>
+	 <SCORE-OBJECT ,SKIFF>>
+
+<ROUTINE I-SKIFF ()
+	 <ZLINES ,SKIFF-CNT
+		 (DELAY
+		  <COND (<NOT <IN? ,BLACKTHORNE ,SKIFF>>
+			 <COND (<G? ,DELAY-CNT 2>
+				<MOVE ,BLACKTHORNE ,SKIFF>
+				<TELL CR
+"Yabu barks orders, and you are pitched headlong into the skiff." CR>)
+			       (ELSE			      
+				<TELL CR
+"Yabu motions for you to get in the skiff." CR>)>)>)
+		 (<DEQUEUE I-SKIFF>
+		  <RFALSE>)>>
+
+<OBJECT LG-VILLAGE
+	(LOC LOCAL-GLOBALS)
+	(DESC "fishing village")
+	(SYNONYM VILLAGE)
+	(ADJECTIVE SMALL FISHING)
+	(FLAGS NDESCBIT)
+	(ACTION LG-VILLAGE-F)>
+
+<ROUTINE LG-VILLAGE-F ()
+	 <COND (<SCENE? S-ANJIRO>
+		<COND (<VERB? THROUGH>
+		       <COND (<HERE? ,GARDEN ,MURA-HOUSE> <DO-WALK ,P?EAST>)
+			     (<HERE? ,ANJIRO-WATERFRONT> <DO-WALK ,P?NORTH>)
+			     (ELSE
+			      <TELL "The village is right here." CR>)>)
+		      (<VERB? EXIT>
+		       <COND (<HERE? ,GARDEN ,MURA-HOUSE>
+			      <TELL
+"You can't tell from here how to leave the village." CR>)
+			     (<HERE? ,ANJIRO ,ANJIRO-WATERFRONT>
+			      <DO-WALK ,P?NORTH>)>)>)
+	       (<SCENE? S-VOYAGE>
+		<TELL "The village is too far away, considering your condition." CR>)>>
+
+<OBJECT LG-SEA
+	(LOC LOCAL-GLOBALS)
+	(DESC "sea")
+	(SYNONYM SEA OCEAN WATER WAVES WAVE FOAM
+	         TIDE COMBER COMBERS CURRENT CURRENTS)
+	(ADJECTIVE RAGING FROTHY FOAMY)
+	(FLAGS NDESCBIT VEHBIT)
+	(GENERIC GENERIC-SEA-F)
+	(ACTION LG-SEA-F)>
+
+<ROUTINE GENERIC-SEA-F (R F)
+	 ,LG-SEA>
+
+<ROUTINE LG-SEA-F ("OPT" (RARG <>))
+	 <COND (<RARG? <>>
+		<COND (<VERB? EXAMINE LOOK-INSIDE>
+		       <COND (<SCENE? ,S-ERASMUS>
+			      <TELL
+"The sea is a maze of mountainous waves and razor-spined reef-tops." CR>)
+			     (<SCENE? ,S-VOYAGE>
+			      <TELL
+"The gale-driven surf is thrown high in the air, hurled by the wind
+against the rocky shore.">
+			      <COND (<AND <NOT <HERE? ,GALLEY ,MAIN-DECK
+						      ,IN-THE-SEA>>
+					  <NOT <IN? ,YABU ,HERE>>>
+				     <TELL
+" You can see that the tide is coming in.">)>
+			      <CRLF>)
+			     (ELSE
+			      <TELL "It's full of water." CR>)>)
+		      (<VERB? POINT>
+		       <COND (<IN? ,YABU ,HERE>
+			      <TELL
+"Yabu looks at the sea, and you can tell he hates and perhaps fears
+it." CR>)>) 
+		      (<OR <VERB? BOARD THROUGH SWIM LEAP DIVE>
+			   <P? THROW ME>>
+		       <COND (<HERE? ,ON-DECK ,BRIDGE-OF-ERASMUS>
+			      <COND (<SCENE? S-ANJIRO S-RODRIGUES>
+				     <TELL
+"Wouldn't it be safer to just climb back into the boat?" CR>)
+				    (ELSE
+				     <PERFORM ,V?LEAP ,LG-ERASMUS>
+				     <RTRUE>)>)
+			     (<HERE? ANJIRO-WATERFRONT>
+			      <DO-WALK ,P?EAST>
+			      <RTRUE>)
+			     (<HERE? GALLEY MAIN-DECK>
+			      <COND (<SCENE? ,S-VOYAGE>
+				     <GOTO ,IN-THE-SEA>)
+				    (<JIGS-UP? ,J-PILING>
+				     <JIGS-UP
+"You hit your head on a piling as you attempt this feat.">)
+				    (ELSE <RTRUE>)>)
+			     (<HERE? IN-THE-SEA>
+			      <COND (<IN? ,WINNER ,SKIFF>
+				     <TELL
+"As you try to leap into the sea, the samurai grab you.  They hold you
+tightly as Yabu scowls." CR>)
+				    (ELSE
+				     <TELL G"You already are." CR>)>)
+			     (<IN? ,WINNER ,SMALL-BOAT>
+			      <TELL
+"Why do that when you're in a nice boat?" CR>)
+			     (ELSE
+			      <TELL "You wouldn't like it.  It's wet." CR>)>)
+		      (<P? (PUT THROW) * LG-SEA>
+		       <COND (<HELD? ,PRSO>
+			      <REMOVE ,PRSO>
+			      <TELL
+CTHE ,PRSO " drop">
+			      <COND (<NOT <PLURAL? ,PRSO>> <TELL "s">)>
+			      <TELL " into the water and ">
+			      <COND (<PRSO? ,OARS ,BOAT-OAR ,LIFE-RING>
+				     <TELL "float">)
+				    (ELSE <TELL "sink">)>
+			      <COND (<NOT <PLURAL? ,PRSO>> <TELL "s">)>
+			      <TELL " out of sight." CR>)>)
+		      (<VERB? DRINK>
+		       <TELL
+"Seawater will drive you mad, as every sailor knows." CR>)>)>>
+
+<ROOM IN-THE-SEA
+      (LOC ROOMS)
+      (DESC "In the Sea")
+      (SYNONYM SEA)
+      (LDESC
+"You are in the raging sea between the galley and the rocky,
+wave-tormented shore.")
+      (FLAGS ONBIT OUTSIDE)
+      (GLOBAL LG-SEA LG-LAND LG-BAY LG-RODRIGUES)
+      (GENERIC GENERIC-SEA-F)
+      (ACTION IN-THE-SEA-F)>
+
+<ROUTINE IN-THE-SEA-F (RARG)
+	 <COND (<RARG? ENTER>
+		<COND (<NOT <IN? ,WINNER ,SKIFF>>
+		       <QUEUE I-DROWN 5>
+		       <TELL
+"You execute a perfect dive into the sea." CR CR>)
+		      (ELSE
+		       <COND (<IN? ,YABU ,SKIFF> <FSET ,YABU ,NDESCBIT>)>
+		       <COND (<IN? ,SEARCH-PARTY ,SKIFF>
+			      <FSET ,SEARCH-PARTY ,NDESCBIT>)>
+		       <RFALSE>)>)
+	       (<RARG? LEAVE>
+		<COND (<IN? ,YABU ,SKIFF> <FCLEAR ,YABU ,NDESCBIT>)>
+		<COND (<IN? ,SEARCH-PARTY ,SKIFF>
+		       <FCLEAR ,SEARCH-PARTY ,NDESCBIT>)>
+		<RFALSE>)
+	       (<RARG? BEG>
+		<COND (<AND <P? (HELLO ASK-ABOUT TELL) RODRIGUES>
+			    <IN? ,RODRIGUES ,HERE>>
+		       <COND (<IN? ,OAR ,RODRIGUES>
+			      <TELL
+"\"Are you crazy, Ingeles?\"" CR>)
+			     (ELSE
+			      <TELL "He's drowning!" CR>)>
+		       <COND (<VERB? TELL> <END-QUOTE> <RFATAL>)
+			     (ELSE <RTRUE>)>)
+		      (<VERB? DIVE>
+		       <TELL
+"You dive beneath the surface, but find nothing of interest." CR>)
+		      (<AND <VERB? DROP>
+			    <HELD? ,PRSO>>
+		       <REMOVE ,PRSO>
+		       <TELL "Gone forever, beneath the waves." CR>)
+		      (<VERB? SWIM DANCE HIDE-BEHIND HIDE-UNDER>
+		       <TELL "You try desperately to stay afloat." CR>)
+		      (<P? (THROUGH WALK-TO) LG-LAND>
+		       <TELL
+"That would be suicide. You would be pulped on the rocks!" CR>)
+		      (<AND <OR <P? (WALK-TO BOARD CLIMB-ON CLIMB-FOO)
+				    (LG-GALLEY ROOMS)>
+				<P? (DROP EXIT) LG-SEA>>
+			    <NOT <IN? ,WINNER ,SKIFF>>>
+		       <TELL
+"The storm has carried you further towards the rocks, and you fight
+the current, trying to get back, but it's hopeless.  They'll have to
+fend for themselves." CR>)
+		      (<AND <P? (HELP TAKE WALK-TO) (LG-RODRIGUES RODRIGUES)>
+			    <IN? ,RODRIGUES ,HERE>>
+		       <TELL
+"Here among the waves it's not as obvious where Rodrigues is, but
+you swim toward where you last saw him.  ">
+		       <COND (<NOT <FSET? ,OAR ,SCOREBIT>>
+			      <FCLEAR ,RODRIGUES ,INVISIBLE>
+			      <TELL
+"There he is!  He's clinging to a broken oar!  You stroke towards him
+and at last, fighting the sea, you reach him.  He's wet but alive.  \"By
+the Virgin, Ingeles!\" he chokes.  \"Who's conning the galley!\"" CR>)
+			     (ELSE
+			      <TELL
+"You search for as long as your strength holds, but you find no sign
+of him." CR>)>)>)>>
+
+<ROUTINE I-DROWN ()
+	 <TELL CR
+"At last, your strength gives out.  You are still not fully recovered
+from the voyage to Japan.  You can swim but not forever.  You sink beneath
+the waves." CR>
+	 <JIGS-UP>>
+
+<OBJECT LG-GALLEY
+	(LOC IN-THE-SEA)
+	(DESC "galley")
+	(OWNER TORANAGA)
+	(SYNONYM GALLEY BOAT SHIP)
+	(FLAGS VEHBIT)
+	(DESCFCN LG-GALLEY-DESC)
+	(GENERIC GENERIC-GALLEY-F)
+	(ACTION LG-GALLEY-F)>
+
+<ROUTINE GENERIC-GALLEY-F (R F)
+	 <COND (<SCENE? ,S-YABU ,S-ANJIRO ,S-ERASMUS>
+		,LG-ERASMUS)
+	       (<SCENE? ,S-RODRIGUES>
+		,SLAVER)
+	       (ELSE
+		,LG-GALLEY)>>
+
+<ROUTINE LG-GALLEY-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (ELSE
+		<COND (,GALLEY-IN-BAY?
+		       <TELL
+"The galley rides heavily ">
+		       <COND (<NOT <FSET? ,ANCHOR ,SCOREBIT>>
+			      <TELL "at anchor ">)>
+		       <TELL "on the relatively gentle swells
+of the bay.">)
+		      (ELSE
+		       <TELL
+"Riding the waves like a fat-bellied pig, the overladen galley appears
+and disappears in the troughs of the waves.">)>)>>
+
+<ROUTINE LG-GALLEY-F ()
+	 <COND (<VERB? ENTER BOARD CLIMB-FOO CLIMB-ON>
+		<COND (<HERE? ,WHARF>
+		       <DO-WALK ,P?EAST>)
+		      (<HERE? ,GALLEY ,MAIN-DECK>
+		       <TELL G"You already are." CR>)
+		      (ELSE
+		       <TELL
+"The galley isn't here." CR>)>)
+	       (<VERB? TURN>
+		<COND (<HERE? ,GALLEY>
+		       <PERFORM ,V?TURN ,WHEEL ,PRSI>
+		       <RTRUE>)
+		      (<AND <HERE? ,MAIN-DECK>
+			    <SCENE? ,S-VOYAGE>>
+		       <ARENT-WHERE-PRSO-IS>
+		       <COND (<IN? ,RODRIGUES ,GALLEY>
+			      <FRUSTRATED ,RODRIGUES>)>
+		       <CRLF>)
+		      (ELSE
+		       <TELL "You aren't on the galley." CR>)>)>>
+
+<ROUTINE FRUSTRATED (WHO)
+	 <TELL " Frustrated, you yell
+the command to " D .WHO ", but realize that he can't hear you above the
+storm." CR>>
+
+<ROUTINE DRESS-BLACKTHORNE ("OPT" (EUROPEAN? <>))
+	 <COND (.EUROPEAN?
+		<MOVE ,CLOTHES ,BLACKTHORNE>
+		<FSET ,CLOTHES ,WEARBIT>
+		<MOVE ,BOOTS ,BLACKTHORNE>
+		<FSET ,BOOTS ,WEARBIT>)
+	       (ELSE
+		<COND (<AND <G? ,SCENE ,S-JOURNEY>
+			    <LOC ,DICTIONARY>>
+		       <MOVE ,DICTIONARY ,BLACKTHORNE>)>
+		<MOVE ,SOCKS ,BLACKTHORNE>
+		<FSET ,SOCKS ,WEARBIT>
+		<MOVE ,SANDALS ,BLACKTHORNE>
+		<FSET ,SANDALS ,WEARBIT>
+		<MOVE ,KIMONO ,BLACKTHORNE>
+		<FSET ,KIMONO ,WEARBIT>)>>
+
+<ROOM GALLEY
+      (LOC ROOMS)
+      (SCENE S-VOYAGE S-ESCAPE)
+      (DESC "Toranaga's Galley")
+      (SYNONYM GALLEY)
+      (OWNER TORANAGA)
+      (SCORE 11)
+      (FDESC
+"It is near noon and you are standing on the quarterdeck of the galley
+under an overcast sky.  During the first night the galley had sped
+southward down the east coast of the Izu peninsula.  When it came abreast
+of the southmost cape, Cape Ito, Rodrigues had set the course West South
+West and had left the safety of the coast for the open sea, heading for
+a landfall at Cape Shinto two hundred miles away.|
+|
+\"What do you think, Ingeles?\" asks Rodrigues.|
+\"I think there'll be a storm,\" you reply.|
+\"When?\"|
+\"Before sunset\" you answer.|
+|
+The storm comes before sunset and catches you out to sea.  Land is
+ten miles away.")
+      (AFTER VOYAGE-AFTER-F)
+      (FORE TO MAIN-DECK)
+      (DOWN TO MAIN-DECK)
+      (FLAGS ONBIT OUTSIDE)
+      (GLOBAL LG-GALLEY CREWMEN LG-RODRIGUES LG-SEA
+       LG-LAND LG-BAY ANCHOR)
+      (GENERIC GENERIC-GALLEY-F)
+      (ACTION GALLEY-F)>
+
+<ROUTINE GALLEY-F (RARG)
+	 <COND (<RARG? SCENE-SETUP>
+		<DRESS-BLACKTHORNE T>
+		<PUTP ,BLACKTHORNE ,P?HEALTH 4>
+		<PUT-ON ,SLIPPERS ,YABU>
+		<PUT-ON ,YABU-KIMONO ,YABU>
+		<PUT-ON ,YABU-SWORDS ,YABU>
+		<MOVE ,SAFETY-LINE ,BLACKTHORNE>
+		<FSET ,SAFETY-LINE ,WEARBIT>
+		<MOVE ,RODRIGUES ,HERE>
+		<NEW-SDESC ,RODRIGUES "Rodrigues">
+		<QUEUE I-RODRIGUES -1>)
+	       (<RARG? LOOK>
+		<TELL
+"You are standing on the quarterdeck of Toranaga's galley, with a good
+view forward to the oar deck." CR>)
+	       (<RARG? LEAVE>
+		<FCLEAR ,GALLEY-WHEEL ,ONBIT>)
+	       (<RARG? BEG>
+		<COND (<VERB? WALK>
+		       <COND (<FSET? ,SAFETY-LINE ,WEARBIT>
+			      <TELL
+,YOU-HAVE-TO G"untie your safety line first">
+			      <COND (<SCENE? ,S-VOYAGE>
+				     <TELL ", even though you know that
+without it you could easily be carried overboard." CR>)
+				    (ELSE <TELL "." CR>)>)>)
+		      (<P? UNTIE ME>
+		       <PERFORM ,V?UNTIE ,SAFETY-LINE>
+		       <RTRUE>)
+		      (<P? ROW <>>
+		       <TELL "The oars aren't here.  They're forward on
+the main deck." CR>)
+		      (<P? TURN INTDIR>
+		       <PERFORM ,V?TURN ,GALLEY-WHEEL ,INTDIR>
+		       <RTRUE>)
+		      (<AND <VERB? TURN-TOWARD TURN-AWAY>
+			    <NOT <PRSO? ,GALLEY-WHEEL>>>
+		       <PERFORM ,PRSA ,GALLEY-WHEEL ,PRSO>
+		       <RTRUE>)
+		      (<P? POINT (LG-BAY LG-LAND)>
+		       <SETG WINNER ,OARSMEN>
+		       <PERFORM ,V?POINT ,PRSO>
+		       <SETG WINNER ,PLAYER>
+		       <RTRUE>)
+		      (<P? BOARD LG-SEA>
+		       <COND (<FSET? ,SAFETY-LINE ,WEARBIT>
+			      <TELL
+,YOU-HAVE-TO G"untie your safety line first""." CR>)
+			     (<NOT <FSET? ,LIFE-RING ,WEARBIT>>
+			      <TELL
+G"You would surely drown." CR>)>)>)>>
+
+<OBJECT GALLEY-WHEEL
+	(LOC GALLEY)
+	(SCENE S-VOYAGE S-ESCAPE)
+	(OWNER GALLEY)
+	(DESC "helm")
+	(SYNONYM WHEEL RUDDER HELM TILLER)
+	(ADJECTIVE SHIPS)
+	(FLAGS CANT-HOLD)
+	(DESCFCN GALLEY-WHEEL-DESC)
+	(ACTION GALLEY-WHEEL-F)>
+
+<ROUTINE GALLEY-WHEEL-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (<RARG? OBJDESC>
+		<TELL "The helm is here, turned ">
+		<COND (<EQUAL? ,SHIP-COURSE ,P?PORT> <TELL "to port">)
+		      (<EQUAL? ,SHIP-COURSE ,P?STARBOARD>
+		       <TELL "to starboard">)
+		      (ELSE <TELL "straight">)>
+		<TELL " now.">
+		<COND (<OR <FSET? ,SAFETY-LINE ,WEARBIT>
+			   <FSET? ,GALLEY-WHEEL ,ONBIT>>
+		       <COND (<FSET? ,GALLEY-WHEEL ,ONBIT>
+			      <TELL " You have the helm">
+			      <COND (<FSET? ,SAFETY-LINE ,WEARBIT>
+				     <TELL " and a ">)>)
+			     (<FSET? ,SAFETY-LINE ,WEARBIT>
+			      <TELL " The ">)>
+		       <COND (<FSET? ,SAFETY-LINE ,WEARBIT>
+			      <TELL "life line secures you">
+			      <COND (<SCENE? ,S-VOYAGE>
+				     <TELL " as the deck pitches and rolls.">)
+				    (ELSE <TELL "." CR>)>)
+			     (ELSE
+			      <TELL
+". There is a life line lashed to the binnacle.">)>)>)>>
+
+<ROUTINE GALLEY-WHEEL-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The helm steers the ship.  The galley is steering ">
+		<COND (<EQUAL? ,SHIP-COURSE ,P?PORT>
+		       <TELL "south toward the open sea." CR>)
+		      (ELSE <TELL "toward the bay." CR>)>)
+	       (<VERB? TAKE>
+		<COND (<FSET? ,GALLEY-WHEEL ,ONBIT>
+		       <TELL "You already have it!" CR>)
+		      (ELSE
+		       <FSET ,GALLEY-WHEEL ,ONBIT>
+		       <TELL
+"You take the helm." CR>)>)
+	       (<VERB? DROP>
+		<COND (<NOT <FSET? ,GALLEY-WHEEL ,ONBIT>>
+		       <YOU-ARENT-HOLDING>)
+		      (ELSE
+		       <FCLEAR ,GALLEY-WHEEL ,ONBIT>
+		       <TELL
+"You release the helm.">
+		       <COND (<IN? ,RODRIGUES ,HERE>
+			      <TELL
+" Rodrigues takes it.">)>
+		       <CRLF>)>)
+	       (<P? STRAIGHTEN GALLEY-WHEEL>
+		<SETG P-DIRECTION ,P?FORE>
+		<PERFORM ,V?TURN ,GALLEY-WHEEL ,INTDIR>
+		<RTRUE>)
+	       (<P? TURN-TOWARD GALLEY-WHEEL>
+		<COND (<PRSI? ,LG-BAY ,LG-LAND>
+		       <SETG P-DIRECTION ,P?STARBOARD>
+		       <PERFORM ,V?TURN ,PRSO ,INTDIR>
+		       <RTRUE>)
+		      (<PRSI? ,LG-SEA>
+		       <SETG P-DIRECTION ,P?PORT>
+		       <PERFORM ,V?TURN ,PRSO ,INTDIR>
+		       <RTRUE>)>)
+	       (<P? TURN-AWAY GALLEY-WHEEL>
+		<COND (<PRSI? ,LG-BAY ,LG-LAND>
+		       <SETG P-DIRECTION ,P?PORT>
+		       <PERFORM ,V?TURN ,PRSO ,INTDIR>
+		       <RTRUE>)
+		      (<PRSI? ,LG-SEA>
+		       <SETG P-DIRECTION ,P?STARBOARD>
+		       <PERFORM ,V?TURN ,PRSO ,INTDIR>
+		       <RTRUE>)>)
+	       (<P? TURN GALLEY-WHEEL>
+		<COND (<NOT <FSET? ,ANCHOR ,SCOREBIT>>
+		       <TELL
+"The galley is anchored safely in the bay.  Turning the wheel is a
+waste of time." CR>)
+		      (<NOT <FSET? ,GALLEY-WHEEL ,ONBIT>>
+		       <YOU-ARENT-HOLDING>)
+		      (<PRSI? ,INTDIR> 
+		       <COND (<EQUAL? ,P-DIRECTION ,P?PORT ,P?SOUTH>
+			      <SETG SHIP-COURSE ,P?PORT>
+			      <SETG SHIP-DIRECTION ,P?SOUTH>
+			      <TELL
+"You turn to wheel to port, steering the galley out to sea, running
+with the wind." CR>)
+			     (<EQUAL? ,P-DIRECTION ,P?STARBOARD ,P?WEST>
+			      <SETG SHIP-COURSE ,P?STARBOARD>
+			      <SETG SHIP-DIRECTION ,P?WEST>
+			      <TELL
+"You turn the wheel to starboard, steering for the bay." CR>)
+			     (<EQUAL? ,P-DIRECTION ,P?FORE ,P?IN>
+			      <SETG SHIP-COURSE ,P?FORE>
+			      <TELL
+"You try to hold a steady course." CR>)
+			     (ELSE
+			      <TELL
+"You can't steer the galley in that direction!" CR>)>)
+		      (ELSE
+		       <TELL G"You must specify a direction!" CR>)>)>>
+
+<OBJECT SAFETY-LINE
+	(LOC GALLEY)
+	(SCENE S-VOYAGE S-ESCAPE)
+	(DESC "safety line")
+	(SYNONYM LINE LIFELINE ROPE)
+	(ADJECTIVE SAFETY LIFE)
+	(FLAGS OPENABLE WEARABLE)
+	(ACTION SAFETY-LINE-F)>
+
+<ROUTINE SAFETY-LINE-F ()
+	 <COND (<OR <P? (THROW GIVE) * LG-RODRIGUES>
+		    <P? TURN * LG-RODRIGUES>
+		    <P? REACH-FOR LG-RODRIGUES>>
+		<TELL
+"It's much too short." CR>)
+	       (<AND <P? TIE * SAFETY-LINE>
+		     <NOT <PRSO? ,SAFETY-LINE>>>
+		<PERFORM ,PRSA ,SAFETY-LINE ,PRSO>
+		<RTRUE>)
+	       (<AND <P? TIE SAFETY-LINE>
+		     <NOT <PRSI? <> ,ME ,BLACKTHORNE>>>
+		<COND (<PRSI? ,RODRIGUES>
+		       <TELL
+"\"Lifelines, Ingeles?  Have you no "I"cojones""?\"" CR>)
+		      (<PRSI? ,SAFETY-LINE>
+		       <TELL
+"Tying the safety line to itself would be foolish." CR>)
+		      (ELSE
+		       <TELL
+"You can't tie the safety line to that." CR>)>)
+	       (<VERB? UNTIE TAKE-OFF DROP>
+		<COND (<FSET? ,SAFETY-LINE ,WEARBIT>
+		       <MOVE ,SAFETY-LINE ,GALLEY>
+		       <FCLEAR ,SAFETY-LINE ,WEARBIT>
+		       <TELL
+"You untie the line.">
+		       <COND (<FSET? ,ANCHOR ,SCOREBIT>
+			      <TELL
+" You know that without your lifeline you can easily be carried overboard.">
+			      <COND (<FSET? ,OARSMEN ,SCOREBIT>
+				     <TELL
+" But the oars have to be shipped or you are lost.">)>)>
+		       <CRLF>)
+		      (ELSE
+		       <TELL
+"You're already untied!" CR>)>)
+	       (<VERB? TIE WEAR TAKE>
+		<COND (<NOT <FSET? ,SAFETY-LINE ,WEARBIT>>
+		       <MOVE ,SAFETY-LINE ,WINNER>
+		       <FSET ,SAFETY-LINE ,WEARBIT>
+		       <COND (<SCENE? ,S-VOYAGE>
+			      <TELL
+"You gratefully return to the safety of the line." CR>)
+			     (ELSE
+			      <TELL
+"You are now tied." CR>)>)
+		      (ELSE
+		       <TELL
+"You're already tied as securely as possible." CR>)>)>>
+
+<ROOM MAIN-DECK
+      (SCENE S-VOYAGE S-ESCAPE)
+      (LOC ROOMS)
+      (DESC "Main Deck")
+      (SYNONYM DECK)
+      (ADJECTIVE MAIN)
+      (AFT TO GALLEY)
+      (UP TO GALLEY)
+      (WEST PER MAIN-DECK-EXIT)
+      (DOWN SORRY "There's nothing of interest below decks.")
+      (FLAGS ONBIT OUTSIDE SCOREBIT)
+      (GLOBAL LG-GALLEY LG-SEA LG-LAND LG-BAY LG-RODRIGUES)
+      (GENERIC GENERIC-DECK-F)
+      (ACTION MAIN-DECK-F)>
+
+<ROUTINE GENERIC-DECK-F (R F)
+	 ,DECK>
+
+<ROUTINE MAIN-DECK-EXIT ("OPT" (RARG <>) (STRICT? <>))
+	 <COND (<SCENE? ,S-ESCAPE> ,WHARF)
+	       (ELSE
+		<COND (<NOT .RARG> <TELL "You can't go that way." CR>)>
+		<RFALSE>)>>
+
+<ROUTINE MAIN-DECK-F (RARG)
+	 <COND (<RARG? LOOK>
+		<TELL
+"This is the oar deck of the galley, forward of the quarterdeck.  ">
+		<COND (<SCENE? ,S-ESCAPE>
+		       <TELL
+"Gray guardsmen crowd the deck." CR>)
+		      (<NOT <FSET? ,ANCHOR ,SCOREBIT>>
+		       <TELL
+"The rowers are resting after their ordeal, exhausted but proud of
+their victory over the sea." CR>)
+		      (<NOT <FSET? ,MAIN-DECK ,SCOREBIT>>
+		       <TELL
+"Banks of twenty rowers are to each side, disciplined, trained samurai.  ">
+		       <COND (<NOT <FSET? ,OARSMEN ,SCOREBIT>>
+			      <TELL "They row steadily, urged on by the
+beat of a drum." CR>)
+			     (ELSE
+			      <TELL
+"They wait patiently for their next order." CR>)>)
+		      (ELSE
+		       <TELL "The chaos here is incredible.  Half the
+oars are flailing in the air, some of the oarsmen have been washed
+overboard, and some have slipped their safety lines to try to fight
+order into their oars." CR>)>)
+	       (<RARG? ENTER>
+		<COND (<SCENE? ,S-ESCAPE>
+		       <COND (<EQUAL? ,OHERE ,WHARF>
+			      <MOVE ,MARIKO ,MAIN-DECK>
+			      <MOVE ,BROWNS ,MAIN-DECK>
+			      <TELL
+"You pull yourself up the gangway using the ropes for support.  Your dash
+across the wharf has tired you more than you realized at first.  Mariko and
+two Browns follow after.">)>)
+		      (<SCENE? ,S-VOYAGE>
+		       <COND (<NOT <FSET? ,ANCHOR ,SCOREBIT>>
+			      <TELL
+"You make your way forward">)
+			     (ELSE
+			      <TELL
+"You fight your way forward along the heaving, greasy deck,">)>
+		       <TELL " down the short gangway to the main deck.">)>
+		<CRLF> <CRLF>)
+	       (<RARG? BEG>
+		<COND (<SCENE? ,S-ESCAPE>
+		       <COND (<P? WALK (P?AFT P?UP)>
+			      <TELL
+"The gangway aft is blocked by Grays and crewmen." CR>)
+			     (<P? TAKE-OFF LG-GALLEY>
+			      <DO-WALK ,P?WEST>)
+			     (<AND <EQUAL? ,QCONTEXT ,MARIKO>
+				   <VERB? YES HAI>>
+			      <SETG QCONTEXT <>>
+			      <TELL
+"\"Well, she's floating, at least,\" you reply, and then notice one of the
+crewmen from the voyage to Osaka.  With Mariko's help, you ask him if the
+galley is ready, and if there are still Grays aboard.  \"Anjin-san, he thanks
+you for the life of his ship, and says they are ready.  As for the other, he
+doesn't know.\"  Mariko seems very worried as she says this." CR>)
+			     (<P? (HELP WAKE TAKE) MARIKO>
+			      <COND (<AND <FSET? ,WHARF ,SCOREBIT>
+					  <NOT <FSET? ,GLOBAL-WATER ,SCOREBIT>>>
+				     <FSET ,GLOBAL-WATER ,SCOREBIT>
+				     <TELL
+"You make your way over to Mariko.  \"Get some water -- water, by God!\"  What's
+the word for water?  Desperately you search your mind for the Japanese
+word.  The old monk had told it to you a thousand times." CR>
+				     <SCORE-OBJECT ,WHARF>)
+				    (,OPPONENT
+				     <TELL
+"You'll have to try something more specific." CR>)
+				    (<NOT <B-STANDING?>>
+				     <TELL
+"You try to crawl to her, but you are too fatigued." CR>)>)
+			     (<OR <VERB? MIZU>
+				  <AND <P? SAY INTQUOTE>
+				       <EQUAL? ,W?MIZU
+					       <GET-INTQUOTE 0>
+					       <GET-INTQUOTE 1>>>
+				  <AND <P? SAY GLOBAL-WATER>
+				       <NOUN-USED? ,PRSO ,W?MIZU>>>
+			      <COND (<FSET? ,GLOBAL-WATER ,SCOREBIT>
+				     <TELL
+"\""I"Mizu, mizu!  Hai!  Wakarimas?""\" you yell.  A man nods, and begins to hurry
+away.  You stand protectively over Mariko." CR>
+				     <SCORE-OBJECT ,GLOBAL-WATER>)
+				    (ELSE
+				     <TELL
+"You continue yelling, for no apparent reason." CR>)>)
+			     (<AND <EQUAL? ,OPPONENT ,GRAY-LEADER
+					   ,RANDOM-GRAYS ,SECOND-GRAY>
+				   <OR <MOTION-VERB?>
+				       <VERB? PARRY STOP>>>
+			      <SETG DODGED? T>
+			      <COND (<FSET? ,GRAY-LEADER ,DEAD>
+				     <TELL
+"You leap out of the way, and the blow misses." CR>)
+				    (ELSE
+				     <TELL
+"You try desperately to dodge out of the way, trying to avoid the leader's
+attack." CR>)>)>)
+		      (<SCENE? ,S-VOYAGE>
+		       <COND (<P? (CLIMB-FOO HOLD-ON) ROOMS>
+			      <COND (<NOT ,GOT-GUNWALE?>
+				     <PERFORM ,V?TAKE ,GUNWALE>
+				     <RTRUE>)
+				    (ELSE
+				     <TELL
+"You have returned to the relative security of the deck." CR>)>)
+			     (<AND <FSET? ,GUNWALE ,RMUNGBIT>
+				   <NOT ,GOT-GUNWALE?>>
+			      <COND (<VERB? WALK WALK-TO>
+				     <TELL
+"You can't walk while being swept overboard!" CR>)
+				    (<AND <NOT <GAME-VERB?>>
+					  <NOT <VERB? TAKE BOARD SWIM HOLD HOLD-ON>>>
+				     <TELL
+"Your preoccupations are unusual for someone who is being swept
+overboard in the middle of the ocean." CR>)>)
+			     (<P? TAKE-OFF LG-GALLEY>
+			      <DO-WALK ,P?DOWN>)
+			     (<AND <P? WALK DOWN>
+				   <FSET? ,SKIFF ,RMUNGBIT>>
+			      <PERFORM ,V?BOARD ,SKIFF>
+			      <RTRUE>)
+			     (<P? BOARD LG-SEA>
+			      <TELL
+G"You would surely drown." CR>)
+			     (<P? (ROW WALK-TO) <>>
+			      <COND (<FSET? ,MAIN-DECK ,SCOREBIT>
+				     <PERFORM ,V?HELP ,OARSMEN>
+				     <RTRUE>)
+				    (ELSE
+				     <SETG WINNER ,OARSMEN>
+				     <PERFORM ,PRSA ,PRSO ,PRSI>
+				     <SETG WINNER ,PLAYER>
+				     <RTRUE>)>)>)>)>>
+
+<OBJECT SKIFF
+	(LOC MAIN-DECK)
+	(SCENE S-VOYAGE)
+	(DESC "skiff")
+	(SYNONYM SKIFF BOAT)
+	(FLAGS TAKEBIT VEHBIT OPENBIT CONTBIT SEARCHBIT SCOREBIT)
+	(COUNT 0)
+	(SIZE 200)
+	(CAPACITY 200)
+	(DESCFCN SKIFF-DESC)
+	(ACTION SKIFF-F)>
+
+<ROUTINE SKIFF-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?> <RTRUE>)
+	       (<RARG? OBJDESC>
+		<COND (<FSET? ,SKIFF ,RMUNGBIT>
+		       <TELL "The skiff ">
+		       <COND (<HERE? ,PEBBLED-BEACH>
+			      <TELL
+"has been pulled up onto the rocky beach.">)
+			     (ELSE
+			      <TELL
+"rides lightly beside the galley.">)>)
+		      (<HERE? ,PEBBLED-BEACH>
+		       <TELL
+"The skiff rests on its side on the rocky beach.">)
+		      (ELSE
+		       <TELL
+"A skiff is tied to the deck near the centerline of the galley.">)>
+		<RFATAL>)>>
+
+<ROUTINE SKIFF-F ("OPT" (RARG <>) "AUX" TRIES)
+	 <COND (<RARG? LOOK>
+		<COND (<HERE? ,IN-THE-SEA>
+		       <TELL
+"The skiff rides lightly in the relatively gentle swells of the bay.">
+		       <COND (<AND <IN? ,YABU ,SKIFF>
+				   <IN? ,SEARCH-PARTY ,SKIFF>>
+			      <TELL
+" Yabu sits imperiously in the bow, and the search party mans the oars.">)>
+		       <CRLF>
+		       <RTRUE>)>)
+	       (<RARG? BEG>
+		<COND (<HERE? IN-THE-SEA>
+		       <COND (<AND <VERB? BOARD WALK-TO CLIMB-FOO>
+				   <PRSO? ,GALLEY>>
+			      <MOVE ,WINNER ,HERE>
+			      <GOTO ,MAIN-DECK>)
+			     (<VERB? DISEMBARK>
+			      <PERFORM ,V?LEAP ,LG-SEA>
+			      <RTRUE>)
+			     (<OR <VERB? WALK>
+				  <P? WALK-TO (LG-LAND LG-BAY LG-GALLEY)>>
+			      <COND (<OR <P? WALK ,P?EAST>
+					 <P? WALK-TO ,LG-LAND>>
+				     <TELL
+"The rowers look to Yabu for confirmation, and he nods impatiently.">)
+				    (ELSE
+				     <TELL
+"Yabu points to the shore instead, indicating the direction for the
+rowers to go.">)>
+			      <CRLF>
+			      <CRLF>
+			      <GOTO ,PEBBLED-BEACH>)>)
+		      (<HERE? PEBBLED-BEACH>
+		       <COND (<OR <VERB? DISEMBARK>
+				  <P? WALK P?OUT>>
+			      <COND (<NOT ,SEARCHED?>
+				     <SETG SEARCHED? T>
+				     <MOVE ,BLACKTHORNE ,HERE>
+				     <MOVE ,YABU ,HERE>
+				     <TELL
+"You disembark quickly, intending to lead the search party, but Yabu
+usurps that position and will not yield it." CR>)
+				    (ELSE
+				     <TELL
+"The samurai hold you back; it's apparent that Yabu feels you've had
+your chance to find Rodrigues, and now it's time to head back to the
+galley." CR>)>)
+			     (<OR <P? WALK ,P?WEST>
+				  <P? WALK-TO (GALLEY LG-GALLEY)>>
+			      <TELL
+"You are rowed back to the galley, having failed to find Rodrigues." CR>
+			      <FAILED-SCENE>)
+			     (<VERB? WALK WALK-TO>
+			      <PERFORM ,V?DISEMBARK>
+			      <RTRUE>)>)>)
+	       (<RARG? <>>
+		<COND (<VERB? EXAMINE>
+		       <TELL
+"It's a wooden skiff, pointed at bow and stern.  ">
+		       <COND (<IN? ,SEARCH-PARTY ,SKIFF>
+			      <TELL "In the skiff are ">
+			      <WHAT-CONTENTS>)
+			     (ELSE
+			      <TELL "It's big enough to
+hold quite a few men." CR>)>)
+		      (<VERB? TAKE>
+		       <TELL
+"It's much to heavy for you to carry." CR>)
+		      (<VERB? BOARD>
+		       <COND (<HERE? ,PEBBLED-BEACH>
+			      <MOVE ,YABU ,SKIFF>
+			      <MOVE ,SEARCH-PARTY ,SKIFF>
+			      <MOVE ,PLAYER ,SKIFF>
+			      <TELL
+"You board the skiff, and the rest of the shore party follows." CR>)
+			     (<FSET? ,SKIFF ,RMUNGBIT>
+			      <SET TRIES <GETP ,SKIFF ,P?COUNT>>
+			      <PUTP ,SKIFF ,P?COUNT <+ .TRIES 1>>
+			      <COND (<ZERO? .TRIES>
+				     <TELL
+"You go to the gunwale and begin to scale down the side but a harsh
+voice stops you.  Hiro-matsu is here, with Yabu beside him.  ">
+				     <HIRO-MATSU-REFUSES>)
+				    (<EQUAL? .TRIES 1>
+				     <YABU-BOARDS-SKIFF>)
+				    (ELSE
+				     <MOVE ,BLACKTHORNE ,SKIFF>
+				     <TELL
+"You climb down the side of the galley, joining the others in the
+skiff." CR CR>
+				     <GOTO ,IN-THE-SEA>)>)
+			     (ELSE
+			      <TELL
+G"It would be a good trick, and somewhat amusing, to get into a boat
+while it's still on deck, but not a good idea." CR>)>)
+		      (<VERB? LOOK-INSIDE>
+		       <COND (<AND <IN? ,YABU ,SKIFF>
+				   <IN? ,SEARCH-PARTY ,SKIFF>>
+			      <TELL
+"In the skiff is the search party of seven samurai, ready at the oars, and
+Yabu, who looks very pleased with himself." CR>)>)
+		      (<VERB? UNTIE>
+		       <COND (<NOT <FSET? ,ANCHOR ,SCOREBIT>>
+			      <COND (<NOT <FSET? ,SKIFF ,RMUNGBIT>>
+				     <FSET ,SKIFF ,RMUNGBIT>
+				     <MOVE ,BOAT-OAR ,SKIFF>
+				     <TELL
+"You untie the skiff, preparing to launch it." CR>)
+				    (ELSE
+				     <TELL
+"It's already untied." CR>)>)
+			     (ELSE
+			      <TELL
+"In this gale, any object that isn't tied down is a deadly
+missile." CR>)>)
+		      (<VERB? LAUNCH LOWER>
+		       <COND (,GALLEY-IN-BAY? ;<NOT <FSET? ,ANCHOR ,SCOREBIT>>
+			      <COND (<NOT <FSET? ,SKIFF ,RMUNGBIT>>
+				     <FSET ,SKIFF ,RMUNGBIT>
+				     <MOVE ,BOAT-OAR ,SKIFF>
+				     <TELL "The skiff is ">
+				     <COND (<HERE? ,MAIN-DECK ,GALLEY>
+					    <TELL
+"lowered into the water." CR>)
+					   (ELSE
+					    <TELL
+"pushed out into the surf." CR>)>)
+				    (ELSE
+				     <TELL "It's already ">
+				     <COND (<HERE? ,MAIN-DECK ,GALLEY>
+					    <TELL
+"riding the waves beside the galley." CR>)
+					   (ELSE
+					    <TELL
+"waiting in the nearby surf." CR>)>)>)
+			     (ELSE
+			      <TELL
+"You can't launch it alone, and in this gale, no one is going to
+help you." CR>)>)>)>>
+
+<GLOBAL SEARCHED? <>>
+
+<OBJECT ANCHOR
+	(LOC MAIN-DECK)
+	(SCENE S-VOYAGE)
+	(DESC "anchor")
+	(SYNONYM ANCHOR)
+	(SIZE 200)
+	(FLAGS AN TAKEBIT SCOREBIT)
+	(ACTION ANCHOR-F)>
+
+<ROUTINE ANCHOR-F ()
+	 <COND (<AND <VERB? TAKE>
+		     <FSET? ,GUNWALE ,RMUNGBIT>>
+		<TELL "It's too far away." CR>)
+	       (<VERB? DROP THROW THROW-OFF PUT LOWER PUSH MOVE>
+		<COND (<NOT ,GALLEY-IN-BAY?>
+		       <TELL
+"You can't drop anchor until you are safely in the bay!" CR>)
+		      (<FSET? ,ANCHOR ,SCOREBIT>
+		       <FSET ,ANCHOR ,NDESCBIT>
+		       <QUEUE I-ALL-ON-DECK 1>
+		       <TELL
+"\"Let go the anchor!\"  No one understands your words but they all know
+what you want.  The anchor splashes over the side.  You let the ship fall
+off the wind slightly to test the firmness of the seabed.  The ship is
+safe." CR>
+		       <SCORE-OBJECT ,ANCHOR>)
+		      (ELSE
+		       <TELL G"It already is." CR>)>)
+	       (<VERB? RAISE>
+		<COND (<FSET? ,ANCHOR ,SCOREBIT>
+		       <TELL G"It already is." CR>)
+		      (<FSET? ,ANCHOR ,NDESCBIT>
+		       <TELL
+"What a dangerous idea!  You would be swept onto the rocks." CR>)>)>>
+
+<ROUTINE I-ALL-ON-DECK ()
+	 <MOVE ,HIRO-MATSU ,MAIN-DECK>
+	 <MOVE ,YABU ,MAIN-DECK>
+	 <TELL CR
+"Hiro-matsu and Yabu climb shakily up from below decks, both somewhat
+seasick, but once there, both "I"daimyos"" stand erect." CR>>
+
+<OBJECT OARS
+	(LOC MAIN-DECK)
+	(DESC "oars")
+	(SYNONYM OARS OAR)
+	(FLAGS NDESCBIT)
+	(ACTION OARS-F)>
+
+<ROUTINE OARS-F ()
+	 <COND (<AND <VERB? SHIP SORT POINT TAKE ROW WALK-TO>
+		     <NOT <IN? ,WINNER ,SKIFF>>>
+		<PERFORM ,V?HELP ,OARSMEN>
+		<RTRUE>)>>
+
+<OBJECT OARSMEN
+	(SCENE S-VOYAGE)
+	(LOC MAIN-DECK)
+	(DESC "oarsmen")
+	(SYNONYM OARSMEN OARSMAN MEN MAN ROWER ROWERS CREW CREWMEN)
+	(ADJECTIVE OARS)
+	(FLAGS NDESCBIT PERSON JAPANESEBIT PLURAL OPENBIT SEARCHBIT
+	  CONTBIT ;SCOREBIT)
+	(ACTION OARSMEN-F)>
+
+<ROUTINE OARSMEN-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<P? PUT OARS (GLOBAL-WATER LG-SEA)>
+		       <PERFORM ,V?ROW>
+		       <RTRUE>)
+		      (<AND <FSET? ,MAIN-DECK ,SCOREBIT>
+			    <P? (SHIP SORT POINT TAKE ROW WALK-TO)
+				(<> OARSMEN OARS LG-BAY LG-LAND)>>
+		       <SETG WINNER ,PLAYER>
+		       <PERFORM ,V?HELP ,OARSMEN>
+		       <RTRUE>)
+		      (<P? (POINT TAKE ROW WALK-TO)
+			   (<> OARS OARSMEN LG-BAY LG-LAND)>
+		       <COND (<NOT <FSET? ,ANCHOR ,SCOREBIT>>
+			      <TELL
+"The galley is anchored.  There's no reason to row." CR>)
+			     (ELSE
+		       <TELL "The oarsmen don't understand you, but they ">
+		       <COND (<FSET? ,OARSMEN ,SCOREBIT>
+			      <TELL "get the idea, and begin rowing again." CR>
+			      <SCORE-OBJECT ,OARSMEN>)
+			     (ELSE
+			      <TELL "try to row faster." CR>)>)>)
+		      (<P? (DROP THROW THROW-OFF PUT LOWER PUSH MOVE) ANCHOR>
+		       <RFALSE>)
+		      (ELSE
+		       <TELL
+"They don't seem to understand what you want." CR>)>)
+	       (<VERB? EXAMINE>
+		<COND (<FSET? ,MAIN-DECK ,SCOREBIT>
+		       <TELL
+"The oarsmen are in a state of confusion." CR>)
+		      (<FSET? ,OARSMEN ,SCOREBIT>
+		       <TELL
+"The oarsmen are settled again at their benches, but not yet rowing
+again." CR>)
+		      (ELSE
+		       <TELL
+"The oarsmen, unlike those you have seen in Europe, aren't slaves.  Each
+is a samurai warrior, and what they lack in deep water sailing
+ability they make up in strength and stamina." CR>)>)
+	       (<VERB? BOW>
+		<COND (<NOT <FSET? ,OARSMEN ,SCOREBIT>>
+		       <TELL
+"The oarsmen acknowledge your gesture of respect." CR>)
+		      (ELSE
+		       <TELL
+"The oarsmen are taken aback by your formality, given the
+circumstances." CR>)>)
+	       (<P? THROW LIFE-RING>
+		<REMOVE ,LIFE-RING>
+		<TELL
+"You heave the life ring to the rower, who tries to reach it, but the surge
+of the sea is too strong and he's swept away." CR>)
+	       (<VERB? HELP SORT>
+		<COND (<FSET? ,MAIN-DECK ,SCOREBIT>
+		       <TELL
+"You hurl yourself into the work of resorting the rowers.  All rowing
+has stopped except for the two oars most forward, which are keeping the
+galley tidily into the wind.  With signs and yelling, you get the oars
+shipped, double up the men on the working ones, and generally restore
+order." CR>
+		       <SCORE-OBJECT ,MAIN-DECK>)
+		      (ELSE
+		       <TELL
+"The oars are already back in some sort of order." CR>)>)>>
+
+<OBJECT GUNWALE
+	(LOC MAIN-DECK)
+	(DESC "gunwale")
+	(SYNONYM GUNWALE GUNWALES RAIL RAILS)
+	(FLAGS NDESCBIT TAKEBIT SCOREBIT)
+	(ACTION GUNWALE-F)>
+
+<GLOBAL GOT-GUNWALE? <>>
+
+<ROUTINE GUNWALE-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The gunwales are nearly awash, as the galley is heavily laden and
+low in the water.  In the "I"Erasmus"" you would ride out a storm
+like this easily, but this galley isn't built and rigged for weather." CR>)
+	       (<VERB? TAKE HOLD HOLD-ON>
+		<COND (<FSET? ,GUNWALE ,RMUNGBIT>
+		       <FCLEAR ,GUNWALE ,RMUNGBIT>
+		       <SETG GOT-GUNWALE? T>
+		       <TELL
+"You grab desperately for the gunwale, and you catch it, your tendons
+stretching but your grip holds!  Then your other hand reaches the rail
+and, choking, you pull yourself back." CR>
+		       <SCORE-OBJECT ,GUNWALE>)
+		      (ELSE
+		       <TELL
+"You hang onto the gunwales as you go forward." CR>)>)>>
+
+<GLOBAL GALLEY-IN-BAY? <>>
+
+<ROUTINE I-RODRIGUES ()
+	 <COND (<AND <HERE? IN-THE-SEA>
+		     <NOT <IN? ,RODRIGUES ,IN-THE-SEA>>>
+		<RFALSE>)>
+	 <ZLINES ,RODRIGUES-CNT
+		 (;1
+		  <SETG SHIP-COURSE ,P?PORT>
+		  <SETG SHIP-DIRECTION ,P?SOUTH>
+		  <MARGINAL-PIC ,P-CONFUSION <>>
+		  <TELL CR
+"\"Watch out forward!\" Rodrigues shouts.  The galley rolls sickeningly,
+twenty oars pulling at air instead of sea and there is chaos aboard.  The
+first comber has struck and the port gunwale is awash.  The galley
+is floundering." CR>)
+		 (;2
+		  <THIS-IS-IT ,OARSMEN>
+		  <FSET ,OARSMEN ,SCOREBIT>
+		  <COND (<HERE? ,GALLEY>
+			 <TELL CR
+"\"Go forward,\" Rodrigues orders.  ">)
+			(ELSE
+			 <TELL CR
+"Rodrigues yells to you.  ">)>
+		  <TELL "\"Get 'em to ship the oars, get 'em back
+in order, and then
+get 'em rowing again before we all drown!  Hurry, hurry, hurry!\"" CR>)
+		 (DELAY
+		  <COND (<IN? ,BLACKTHORNE ,GALLEY>
+			 <COND (<G? ,DELAY-CNT 2>
+				<CRLF>
+				<JIGS-UP
+"\"Filthy heretic pig!  You're no pilot, you're the son of a motherless
+sow!\"  Rodrigues smashes you in the head for your cowardice.">
+				<RFATAL>)
+			       (ELSE
+				<TELL CR
+"\"Hurry, Ingeles!  Where are your "I"cojones""?\" curses Rodrigues." CR>
+				<RTRUE>)>)>)
+		 (;3
+		  <MOVE ,OAR ,GALLEY>
+		  <FSET ,GUNWALE ,RMUNGBIT>
+		  <THIS-IS-IT ,GUNWALE>
+		  <TELL CR
+"Abruptly the galley swerves and you are carried to the down side, tripped
+by the flailing bodies of rowers who have lost their own footing.|
+|
+The gunwale is under water and one man goes overboard!  You feel the rush
+of water carrying you over the gunwale as well!" CR>)
+		 (;4
+		  <COND (,GOT-GUNWALE?
+			 <THIS-IS-IT ,OARSMEN>
+			 <TELL CR
+"A man is at your feet and he drags you from the grip of the sea." CR>)
+			(ELSE
+			 <CRLF>
+			 <TELL
+"You are swept into the raging torrent of the sea, and although you ">
+			 <COND (<IN? ,LIFE-RING ,PLAYER>
+				<TELL "are wearing a life ring">)
+			       (ELSE <TELL "can swim">)>
+			 <TELL ", there is no hope." CR>
+			 <JIGS-UP>)>)
+		 (DELAY
+		  <COND (<OR <FSET? ,MAIN-DECK ,SCOREBIT>
+			     <FSET? ,OARSMEN ,SCOREBIT>>
+			 <THIS-IS-IT ,OARSMEN>
+			 <COND (<G? ,DELAY-CNT 6>
+				<CRLF>
+				<JIGS-UP
+"The galley is smashed against the rocks of the headland.">
+				<RFATAL>)
+			       (ELSE
+				<COND (<FSET? ,MAIN-DECK ,SCOREBIT>
+				       <TELL CR
+"The chaos continues, the oarsmen inexperienced with storms so far out
+to sea, and they can't seem to get sorted out on their own.">
+				       <COND (<IN? ,RODRIGUES ,HERE>
+					      <TELL
+G" Rodrigues yells at you, \"Ingeles, ""I told you to help the
+oarsmen!  Are you afraid just because you got a little wet?\"">)>
+				       <CRLF>)
+				      (<FSET? ,OARSMEN ,SCOREBIT>
+				       <TELL CR
+"The oarsmen, spent by their fight against the waves, and unsure what
+to do next, wait for the next order.">
+				       <COND (<IN? ,RODRIGUES ,HERE>
+					      <TELL
+G" Rodrigues yells at you, \"Ingeles, ""get those bastard-sans rowing
+again!  They don't know what to do so far from shore.\"">)>
+				       <CRLF>)>
+				<TELL CR
+"The storm continues to rage, and the galley is getting no closer to the
+bay." CR>
+				<RTRUE>)>)>)
+		 (;5
+		  <MOVE ,RODRIGUES ,MAIN-DECK>
+		  <CRLF>
+		  <COND (<HERE? ,MAIN-DECK>
+			 <TELL
+"Rodrigues picks his way forward and claps you on the shoulder.  He points
+aft.">)
+			(ELSE
+			 <TELL
+"Rodrigues says,">)>
+			
+		  <TELL
+" \"You take the helm.  When I signal, steer west
+for that point.  You see it?  I'm going">
+		  <COND (<HERE? ,GALLEY> <TELL " forward">)>
+		  <TELL " to help the captain with the oarsmen.\"">
+		  <COND (<HERE? ,GALLEY>
+			 <TELL " He unties his lifeline and goes forward.">)>
+		  <CRLF>)
+		 (DELAY
+		  <COND (<NOT <FSET? ,GALLEY-WHEEL ,ONBIT>>
+			 <COND (<G? ,DELAY-CNT 1>
+				<TELL CR
+"Rodrigues curses, \"By your mother, Ingeles!  Take the helm!\"" CR>
+				<RTRUE>)
+			       (ELSE <RFALSE>)>)>)
+		 (;6
+		  <TELL CR
+"The wind and tide are carrying you close to the rocks.  Rodrigues stares,
+terrified, at the approaching shore." CR>)
+		 (;7
+		  <TELL CR
+"Rodrigues stares in horror at the jagged rocks of the headland.  It's
+clear he's lost his nerve.  \"">
+		  <COND (<EQUAL? ,SHIP-COURSE ,P?PORT>
+			 <TELL "That's right, Pilot!  ">)>
+		  <TELL "Steer south for the open sea!\" Rodrigues
+screams.  \"Turn and run
+before the wind!  We'll never make it safe to the bay!\"" CR>)
+		 (;8
+		  <COND (<EQUAL? ,SHIP-COURSE ,P?PORT>
+			 <TELL CR
+"The galley heads for the open sea, trying to run before the wind, but
+she's too heavily laden, and has already taken on too much water.  You
+try, and the oarsmen try, but it's hopeless.  She flounders and you and
+all aboard drown like rats.">
+			 <JIGS-UP>
+			 <RFATAL>)
+			(ELSE
+			 <TELL CR
+"You hold course toward the bay.  Rodrigues shouts, \"God curse you,
+you'll kill us all!\"" CR>)>)
+		 (;9
+		  <MOVE ,RODRIGUES ,IN-THE-SEA>
+		  <FSET ,RODRIGUES ,INVISIBLE>
+		  <THIS-IS-IT ,LG-RODRIGUES>
+		  <MARGINAL-PIC ,P-OVERBOARD>
+		  <TELL CR
+"A great wave comes out of the north.  The galley has taken much water
+previously, now you're awash and being driven backward towards the
+rock-infested shore.|
+|
+You see the wave take Rodrigues, and you watch him, gasping and struggling
+in the churning sea.  You remember that he can't swim." CR>)
+		 (DELAY
+		  <COND (<FSET? ,OAR ,SCOREBIT>
+			 <COND (<EQUAL? ,DELAY-CNT 1>
+				<TELL CR
+"Rodrigues splashes to the surface, but the current is carrying him further
+away." CR>
+				<RTRUE>)
+			       (<EQUAL? ,DELAY-CNT 2>
+				<TELL CR
+"The rain slashes down and you see that Rodrigues is being carried further
+from the galley." CR>
+				<RTRUE>) 
+			       (<EQUAL? ,DELAY-CNT 3>
+				<TELL CR
+"Rodrigues is almost lost in the waves and wind-driven spray." CR>
+				<RTRUE>)>)>)
+		 (<FSET ,OAR ,RMUNGBIT>
+		  <TELL CR
+"The last you see of Rodrigues is an arm ">
+		  <COND (<FSET? ,OAR ,SCOREBIT>
+			 <TELL
+"waving helplessly through the driving rain." CR>)
+			(ELSE
+			 <TELL
+"gripping a broken oar." CR>)>)
+		 (DELAY
+		  <COND (<OR <NOT <HERE? ,GALLEY>>
+			     <NOT <FSET? ,GALLEY-WHEEL ,ONBIT>>>
+			 <COND (<EQUAL? ,DELAY-CNT 1>
+				<TELL CR
+"There's no one conning the galley!" CR>
+				<RTRUE>)
+			       (<EQUAL? ,DELAY-CNT 2>
+				<SETG SHIP-COURSE ,P?PORT>
+				<TELL CR
+"The Japanese captain grabs the wheel, and immediately steers for
+the open sea!" CR>
+				<RTRUE>)
+			       (ELSE <RFALSE>)>)
+			(<EQUAL? ,SHIP-COURSE ,P?PORT>
+			 <COND (<L? ,DELAY-CNT 3>
+				<TELL CR
+"The galley continues out to sea, into the teeth of the storm." CR>
+				<RTRUE>)>)>)
+		 (<COND (<EQUAL? ,SHIP-COURSE ,P?PORT>
+			 <CRLF>
+			 <JIGS-UP
+"The galley is now full in the jaws of the storm.  The waves toss
+the galley about, and one huge comber crashes over the port gunwale,
+and she's sinking!">
+			 <RFATAL>)
+			(ELSE
+			 <SETG GALLEY-IN-BAY? T>
+			 <TELL CR
+"The ship moves away from the rocks, and you hold course for the lee
+shore.  Soon you are in calmer waters.  There is still a gale but it's
+overhead.  There is still a tempest but it's out to sea." CR>)>)
+		 (DELAY
+		  <COND (<FSET? ,ANCHOR ,SCOREBIT>
+			 <COND (<G? ,DELAY-CNT 3>
+				<CRLF>
+				<JIGS-UP
+"The ship smashes onto the rocks!  If only you'd dropped anchor in time,
+she might have survived.  How humiliating.">
+				<RFATAL>)
+			       (ELSE
+				<TELL CR
+"The current is swinging the ship around and towards the rocks, away
+from the safe anchorage." CR>
+				<RTRUE>)>)>)
+		 (<DEQUEUE I-RODRIGUES>
+		  <TELL CR
+"Somewhere out there is Rodrigues' body.  You know ">
+		  <COND (<FSET? ,OAR ,SCOREBIT>
+			 <FSET ,RODRIGUES ,DEAD>
+			 <TELL "in your heart that with nothing to
+keep him above the waves, he must have drowned, and ">)>
+		  <TELL
+"there is minimal
+hope of finding his body, but you feel you owe it to him to try." CR>)>>
+
+<OBJECT LIFE-RING
+	(LOC GALLEY)
+	(DESC "wooden life ring")
+	(FDESC "A wooden life ring hangs nearby.")
+	(SYNONYM RING)
+	(ADJECTIVE WOODEN LIFE)
+	(FLAGS TAKEBIT)
+	(ACTION LIFE-RING-F)>
+
+<ROUTINE LIFE-RING-F ()
+	 <COND (<P? THROW * LG-RODRIGUES>
+		<COND (<NOT <FSET? ,OAR ,RMUNGBIT>>
+		       <TELL "You ">
+		       <COND (<IN? ,LIFE-RING ,HERE>
+			      <TELL
+"snatch the wooden life ring and throw it">)
+			     (ELSE
+			      <TELL
+"throw the wooden life ring">)>
+		       <REMOVE ,LIFE-RING>
+		       <TELL " overboard.  Rodrigues tries to reach it, but
+an ill-timed wave sweeps it out of his reach." CR>)
+		      (ELSE
+		       <TELL G"You can't see Rodrigues anywhere nearby." CR>)>)
+	       (<P? THROW * RODRIGUES>
+		<MOVE ,LIFE-RING <LOC ,RODRIGUES>>
+		<TELL
+"You throw " THE ,PRSO " to Rodrigues.  He drops it beside him, not
+having any use for it at the moment." CR>)
+	       (<AND <VERB? WEAR BOARD>
+		     <NOT <FSET? ,LIFE-RING ,WEARBIT>>>
+		<COND (<AND <NOT <HELD? ,PRSO>>
+			    <NOT <EQUAL? <ITAKE> T>>>
+		       <RTRUE>)
+		      (ELSE
+		       <FSET ,LIFE-RING ,WEARBIT>
+		       <TELL
+"You pull the life ring over your shoulders.  It makes you very awkward
+but you feel safer." CR>)>)
+	       (<AND <VERB? TAKE-OFF>
+		     <FSET? ,LIFE-RING ,WEARBIT>>
+		<FCLEAR ,LIFE-RING ,WEARBIT>
+		<TELL
+"You remove the life ring, pulling it off over your shoulders." CR>)>>
+
+<OBJECT OAR
+	(DESC "broken oar")
+	(SYNONYM OAR)
+	(ADJECTIVE BROKEN)
+	(FLAGS TAKEBIT SCOREBIT)
+	(ACTION OAR-F)>
+
+<ROUTINE OAR-F ()
+	 <COND (<OR <P? (THROW GIVE) * LG-RODRIGUES>
+		    <P? TURN * LG-RODRIGUES>
+		    <P? REACH-FOR LG-RODRIGUES>>
+		<COND (<NOT <FSET? ,OAR ,RMUNGBIT>>
+		       <FSET ,OAR ,NDESCBIT>
+		       <MARGINAL-PIC ,P-OAR <>>
+		       <TELL "You ">
+		       <COND (<IN? ,OAR ,HERE>
+			      <TELL "grab the oar and throw it">)
+			     (ELSE
+			      <TELL "throw the oar">)>
+		       <TELL
+" toward Rodrigues.  It crashes into the water near him
+and he lunges for it." CR>
+		       <MOVE ,OAR ,RODRIGUES>
+		       <SCORE-OBJECT ,OAR>)
+		      (ELSE
+		       <TELL G"You can't see Rodrigues anywhere nearby." CR>)>)
+	       (<P? (THROW GIVE) * RODRIGUES>
+		<TELL
+"He doesn't seem to have much use for the oar right now." CR>)
+	       (<VERB? REPAIR>
+		<TELL "That's beyond your abilities right now." CR>)>>
+
+<ROOM PEBBLED-BEACH
+      (LOC ROOMS)
+      (DESC "Pebbled Beach")
+      (SYNONYM BEACH)
+      (ADJECTIVE PEBBLED)
+      (LDESC
+"The beach here consists of small, rounded pebbles.  To the south the
+cliff rises behind a field of larger rocks.  Riding at anchor in the bay
+is Toranaga's galley.")
+      (SOUTH TO ROCKY-SHORE)
+      (FLAGS RLANDBIT ONBIT)
+      (GLOBAL LG-GALLEY LG-CLIFF LG-SEA LG-LAND
+              LG-BAY LG-RODRIGUES)
+      (ACTION PEBBLED-BEACH-F)>
+
+<CONSTANT NUMBERS
+	  <LTABLE "one" "two" "three" "four" "five" "six"
+		  "seven" "eight" "nine" "ten" "eleven" "twelve"
+		  "thirteen" "fourteen" "fifteen" "sixteen"
+		  "seventeen" "eighteen" "nineteen" "twenty">>
+
+<ROUTINE SEARCH-PARTY-FOLLOWS ()
+	 <MOVE ,YABU ,HERE>
+	 <MOVE ,SEARCH-PARTY ,HERE>
+	 <TELL
+"Yabu sets a strong pace, which you are hard put to keep up with.  The other "
+<GET ,NUMBERS <GETP ,SEARCH-PARTY ,P?COUNT>> " samurai watch you carefully." CR CR>>
+
+<ROUTINE PEBBLED-BEACH-F (RARG)
+	 <COND (<RARG? ENTER>
+		<COND (<AND <EQUAL? ,OHERE ,IN-THE-SEA>
+			    <IN? ,WINNER ,SKIFF>>
+		       <FCLEAR ,SKIFF ,RMUNGBIT>
+		       <MOVE ,SEARCH-PARTY ,HERE>
+		       <TELL
+"The rowers row the skiff east to the shore, jump out,
+and pull it up on the beach." CR CR>)
+		      (<EQUAL? ,OHERE ,ROCKY-SHORE>
+		       <SEARCH-PARTY-FOLLOWS>)>)
+	       (<RARG? BEG>
+		<COND (<AND <P? WALK P?SOUTH>
+			    <FSET? ,ROCKY-SHORE ,TOUCHBIT>>
+		       <YABU-PREVENTS>)
+		      (<P? WALK P?NORTH>
+		       <TELL
+"\"No, Anjin-san,\" says Yabu.  He points south.  He knows as well as you
+that that's where the body will be, if anywhere." CR>)
+		      (<OR <P? FIND (RODRIGUES LG-RODRIGUES)>
+			   <P? SEARCH GLOBAL-HERE>
+			   <VERB? LOOK-DOWN>>
+		       <TELL ,SEARCH-FORESHORE
+G"There is no sign of Rodrigues." CR>)>)>>
+
+<OBJECT LG-PATH
+	(LOC LOCAL-GLOBALS)
+	(SCENE S-VOYAGE)
+	(DESC "path")
+	(SYNONYM PATH FORESHORE SHORE)
+	(FLAGS NDESCBIT)
+	(ACTION LG-PATH-F)>
+
+<ROUTINE LG-PATH-F ()
+	 <COND (<VERB? FOLLOW>
+		<TELL
+"The path runs north and south.  " ,YOU-HAVE-TO G"specify a direction." CR>)>>
+
+<OBJECT ROCK
+	(DESC "rock")
+	(SYNONYM ROCK STONE PEBBLE)
+	(ADJECTIVE SMALL)
+	(FLAGS TAKEBIT)>
+
+<OBJECT LG-CLIFF
+	(LOC LOCAL-GLOBALS)
+	(OWNER YABU)
+	(DESC "cliff")
+	(SYNONYM CLIFF CLIFFS ROCK ROCKS CREVICE CLEFT GULLEY CAVE CAVES)
+	(ADJECTIVE SHEER LOOSE HIDDEN)
+	(FLAGS NDESCBIT TRYTAKEBIT TAKEBIT)
+	(ACTION LG-CLIFF-F)>
+
+<ROUTINE LG-CLIFF-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The cliff soars two hundred feet above you, and drops fifty feet to
+the water below." CR>)
+	       (<VERB? TAKE MOVE>
+		<MOVE ,ROCK ,WINNER>
+		<TELL
+"You take one of the many rocks from the soaking ground." CR>)
+	       (<VERB? CLIMB-DOWN CLIMB-FOO>
+		<DO-WALK ,P?DOWN>
+		<RTRUE>)
+	       (<VERB? CLIMB-UP>
+		<DO-WALK ,P?UP>
+		<RTRUE>)
+	       (<P? SEARCH>
+		<PERFORM ,V?FIND ,LG-RODRIGUES>
+		<RTRUE>)>>
+
+<OBJECT SEARCH-PARTY
+	(OWNER SEARCH-PARTY)
+	(SCENE S-VOYAGE)
+	(DESC "party of samurai")
+	(SYNONYM SAMURAI GUARD GUARDS PARTY MEN)
+	(ADJECTIVE SEARCH)
+	(FLAGS PERSON JAPANESEBIT OPENBIT CONTBIT SEARCHBIT
+	  PLURAL SCOREBIT)
+	(COUNT 7)
+	(DESCFCN SEARCH-PARTY-DESC)
+	(GENERIC GENERIC-SAMURAI-F)
+	(ACTION SEARCH-PARTY-F)>
+
+<ROUTINE SEARCH-PARTY-DESC (RARG OBJ)
+	 <COND (<RARG? OBJDESC?>
+		<COND (<IN? ,SEARCH-PARTY ,SKIFF> <RFALSE>)
+		      (ELSE <RTRUE>)>)
+	       (<RARG? OBJDESC>
+		<TELL
+"There are " <GET ,NUMBERS <GETP ,SEARCH-PARTY ,P?COUNT>> " ">
+		<COND (<HERE? ,CLIFF-PATH>
+		       <COND (<IN? ,LOINCLOTH ,SEARCH-PARTY>
+			      <TELL
+"samurai here, stripped to their loincloths and">)
+			     (<EQUAL? <GETP ,YABU-KIMONO ,P?COUNT> 8>
+			      <TELL
+"naked samurai here,">)
+			     (ELSE
+			      <TELL
+"samurai in soaking wet kimonos here,">)>)
+		      (ELSE
+		       <TELL "samurai here,">)>
+		<TELL " watching you intently.">)>>
+
+<ROUTINE SEARCH-PARTY-F ("OPT" (RARG <>))
+	 <COND (<RARG? SUBJ>
+		<RFALSE>)
+	       (<RARG? WINNER>
+		<COND (<AND <P? (RAISE LOWER) YABU-KIMONO>
+			    <IN? ,YABU-KIMONO ,SEARCH-PARTY>>
+		       <SETG WINNER ,PLAYER>
+		       <PERFORM ,PRSA ,PRSO>
+		       <RTRUE>)
+		      (ELSE
+		       <WAKARIMASEN>)>)
+	       (<VERB? COUNT>
+		<TELL
+"There are " <GET ,NUMBERS <GETP ,SEARCH-PARTY ,P?COUNT>> " samurai here." CR>)
+	       (<VERB? EXAMINE>
+		<COND (<IN? ,LOINCLOTH ,PRSO>
+		       <TELL
+"The samurai are stripped to their loincloths." CR>)
+		      (<EQUAL? <GETP ,YABU-KIMONO ,P?COUNT> 8>
+		       <TELL
+"They are naked." CR>)
+		      (ELSE
+		       <TELL
+"They are dressed in rather wet kimonos." CR>)>)>>
+
+<OBJECT PARTY-KIMONO
+	(OWNER SEARCH-PARTY)
+	(LOC SEARCH-PARTY)
+	(DESC "kimonos")
+	(SYNONYM KIMONOS CLOTHES)
+	(ADJECTIVE SILK SOAKING WET)
+	(FLAGS NOABIT DONT-ALL NDESCBIT TAKEBIT WEARABLE PLURAL)
+	(GENERIC GENERIC-KIMONO-F)
+	(ACTION PARTY-KIMONO-F)>
+
+<ROUTINE GENERIC-KIMONO-F (R F)
+	 <COND (<IN? ,YABU-KIMONO ,HERE>
+		,YABU-KIMONO)
+	       (ELSE ,PARTY-KIMONO)>>
+
+<ROUTINE PARTY-KIMONO-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"These are uniform kimonos in a muddy brown color." CR>)
+	       (<VERB? TAKE POINT RUB TEAR TIE>
+		<COND (<AND <FSET? ,YABU-KIMONO ,RMUNGBIT>
+			    <ACCESSIBLE? ,YABU-KIMONO>>
+		       <COND (<IN? ,YABU-KIMONO ,HERE>
+			      <MOVE ,YABU-KIMONO ,WINNER>)>
+		       <PERFORM ,V?TIE ,YABU-KIMONO>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"No one seems to understand what you are trying to do." CR>)>)
+	       (<VERB? TAKE>
+		<TELL
+"The samurai are reluctant to give up their kimonos." CR>)>>
+
+<ROOM ROCKY-SHORE
+      (LOC ROOMS)
+      (DESC "Rocky Shore")
+      (SYNONYM SHORE)
+      (ADJECTIVE ROCKY)
+      (LDESC
+"Inland from the shore the pebbles become sea-smoothed rocks.  To the
+south is a path leading along the cliffs and around the headland.  To
+the north is the bay where the galley rides at anchor.")
+      (NORTH TO PEBBLED-BEACH)
+      (SOUTH TO CLIFF-PATH)
+      (FLAGS RLANDBIT ONBIT)
+      (GLOBAL LG-CLIFF LG-SEA LG-RODRIGUES)
+      (ACTION ROCKY-SHORE-F)>
+
+<ROUTINE ROCKY-SHORE-F (RARG)
+	 <COND (<RARG? ENTER>
+		<SEARCH-PARTY-FOLLOWS>)
+	       (<RARG? BEG>
+		<COND (<AND <P? WALK P?SOUTH>
+			    <FSET? ,CLIFF-PATH ,TOUCHBIT>>
+		       <YABU-PREVENTS>)>)>>
+
+<ROUTINE YABU-PREVENTS ()
+	 <TELL
+"\"No, Anjin-san,\" says Yabu.  It's clear he thinks you've wasted
+enough time searching for the body." CR>>
+
+<ROOM CLIFF-PATH
+      (LOC ROOMS)
+      (DESC "Cliff Path")
+      (SYNONYM PATH)
+      (ADJECTIVE CLIFF)
+      (LDESC
+"Above you the cliff soars two hundred feet.  The white-frothed sea is
+fifty feet below.  All around are mountains, not a house or hut in the
+whole bay area.  The path dips and rises along the cliff face, very
+unsafe, the surface loose.")
+      (NORTH TO ROCKY-SHORE)
+      (SOUTH TO AROUND-HEADLAND)
+      (DOWN TO LEDGE-1)
+      (FLAGS RLANDBIT ONBIT)
+      (GLOBAL LG-CLIFF LG-SEA LG-RODRIGUES LG-YABU)
+      (ACTION CLIFF-PATH-F)>
+
+<ROUTINE CLIFF-PATH-F (RARG)
+	 <COND (<RARG? ENTER>
+		<SEARCH-PARTY-FOLLOWS>)
+	       (<RARG? BEG>
+		<COND (<AND <P? WALK P?SOUTH>
+			    <FSET? ,LEDGE-4 ,SCOREBIT>
+			    <FSET? ,AROUND-HEADLAND ,TOUCHBIT>>
+		       <YABU-PREVENTS>)
+		      (<AND <P? WALK (P?NORTH P?SOUTH)>
+			    <NOT <FSET? ,LEDGE-4 ,SCOREBIT>>>
+		       <TELL
+"The samurai watch you like hawks, preventing you from leaving." CR>)
+		      (<VERB? LEAP BOARD DIVE>
+		       <TELL
+"The samurai prevent you." CR>)
+		      (<OR <P? FIND (RODRIGUES LG-RODRIGUES)>
+			   <P? SEARCH GLOBAL-HERE>
+			   <VERB? LOOK-DOWN>>
+		       <COND (<FSET? ,LEDGE-4 ,SCOREBIT>
+			      <TELL ,SEARCH-FORESHORE>
+			      <COND (<AND <NOT <FSET? ,OAR ,SCOREBIT>>
+					  <FSET? ,AROUND-HEADLAND ,TOUCHBIT>>
+				     <DEQUEUE I-SEARCH>
+				     <MOVE ,RODRIGUES ,LEDGE-4>
+				     <FCLEAR ,RODRIGUES ,INVISIBLE>
+				     <THIS-IS-IT ,LG-RODRIGUES>
+				     <TELL "But halfway back along the
+path, you see Rodrigues!  The body is caught in a cleft between two great
+rocks, above the surf but washed by part of it.  One arm is still locked
+to a broken oar which moves slightly with the ebb and flow." CR>
+				     <SCORE-OBJECT ,LEDGE-4>)
+				    (ELSE
+				     <TELL
+G"There is no sign of Rodrigues." CR>)>)
+			     (<AND <FSET? ,LEDGE ,SCOREBIT>
+				   ,YABU-RESIGNED?>
+			      <PERFORM ,V?FIND ,LEDGE>
+			      <RTRUE>)
+			     (ELSE
+			      <TELL
+"You have already found him.  Is your memory that short?" CR>)>)
+		      (<OR <P? POINT (RODRIGUES LG-RODRIGUES)>
+			   <P? SHOW (RODRIGUES LG-RODRIGUES) YABU>>
+		       <TELL
+"Yabu peers over the cliff and finally sees Rodrigues.  He shrugs as if
+if to say, \"He's dead.\"  He doesn't seem inclined to do anything else." CR>)
+		      (<P? (HELP TAKE WALK-TO)
+			   (YABU RODRIGUES LG-RODRIGUES)>
+		       <COND (<FSET? ,RODRIGUES ,INVISIBLE>
+			      <RFALSE>)
+			     (<NOT <QUEUED? I-YABU-CLIMBS>>
+			      <SETG YABU-CNT 0>
+			      <QUEUE I-YABU-CLIMBS -1>
+			      <TELL
+"You start for the cliff edge, and immediately the samurai restrain you.  Yabu
+shakes his head.  \"Iye!\"|
+|
+You stare at Yabu, towering over him.  \"If you won't let me go, Yabu-san,
+then send one of your men.  Or go yourself.  You!\"" CR>)
+			     (<IN? ,YABU ,HERE>
+			      <TELL
+"You've hooked him!  He's preparing to climb!" CR>)
+			     (ELSE
+			      <TELL
+"Yabu doesn't see you." CR>)>)
+		      (<P? WALK DOWN>
+		       <COND (<AND <NOT <FSET? ,RODRIGUES ,INVISIBLE>>
+				   <NOT <QUEUED? I-YABU-CLIMBS>>>
+			      <PERFORM ,V?WALK-TO ,RODRIGUES>
+			      <RTRUE>)
+			     (<IN? ,YABU ,HERE>
+			      <TELL
+"Quickly, Yabu moves in your way and the samurai surround you.  \""I"Iye"",
+Anjin-san,\" Yabu says." CR>)
+			     (ELSE
+			      <TELL
+"The samurai prevent you from climbing down." CR>)>)
+		      (<AND <VERB? THROW>
+			    <NOT <PRSO? ,YABU-KIMONO>>
+			    <EQUAL? <LOC ,YABU>
+				    ,LEDGE-1 ,LEDGE-2
+				    ,LEDGE-3 ,LEDGE-4>>
+		       <REMOVE ,PRSO>
+		       <TELL
+"You throw " THE ,PRSO " but " HE/SHE ,PRSO " fall" S ,PRSO " unnoticed into
+the water.">
+		       <COND (<FSET? ,LEDGE ,SCOREBIT>
+			      <TELL " The samurai murmur amongst
+themselves.  Yabu has composed himself for death.  It is extremely bad
+manners to
+disturb him, as they can see no way for him to climb the cliff.">)>
+		       <CRLF>)
+		      (<AND <VERB? YELL YELL-AT ASK-FOR WAVE-AT POINT SHOW
+				   CLIMB-DOWN>
+			    <PRSO? <> YABU LG-YABU LEDGE SEARCH-PARTY
+				   LG-RODRIGUES>
+			    <PRSI? <> SEARCH-PARTY>>
+		       <COND (<AND <NOT ,YABU-WARNED?>
+				   <NOT <FSET? ,LEDGE ,SCOREBIT>>
+				   <GETP ,YABU-KIMONO ,P?COUNT>>
+			      <SETG YABU-WARNED? T>
+			      <PUTP ,SEARCH-PARTY ,P?COUNT
+				    <- <GETP ,SEARCH-PARTY ,P?COUNT> 1>>
+			      <DEQUEUE I-YABU-CLIMBS>
+			      <SETG YABU-CNT 0>
+			      <QUEUE I-YABU-RETURNS -1>
+			      <TELL
+"You shout, pointing at the ledge, pantomiming a man standing on it carrying
+a burden:  Yabu carrying Rodrigues, standing above the waves, if only you
+can get his attention somehow.  The samurai talk rapidly to each
+other and then they too begin to shout.  There is still no movement from
+Yabu.  He seems like a stone.|
+|
+One of the samurai speaks to the others briefly and they all nod and
+bow.  He bows back.  Then, with a sudden screaming shout of \""I"Bansaiiii!""\"
+he casts himself off the cliff and falls to his death.  Yabu comes violently
+out of his trance, whirls around and scrambles up.  He follows the pointing
+fingers and shouts of his men and sees the ledge!  Within seconds he
+has scrambled up to it, dragging the unconscious Rodrigues behind him." CR>
+			      <SCORE-OBJECT ,SEARCH-PARTY>)
+			     (ELSE
+			      <TELL
+"You point, screaming at the top of your lungs.  The samurai stare at you,
+but there is no other result." CR>)>)>)>>
+
+<CONSTANT SEARCH-FORESHORE
+"You search the foreshore, every crevice and cleft and gulley.  The spume
+wind is gusting, tearing tears from your eyes.  ">
+
+<OBJECT LEDGE
+	(LOC CLIFF-PATH)
+	(DESC "narrow ledge")
+	(SYNONYM LEDGE)
+	(ADJECTIVE TINY NARROW)
+	(FLAGS NDESCBIT SCOREBIT)
+	(ACTION LEDGE-F)>
+
+<ROUTINE LEDGE-F ()
+	 <COND (<AND <VERB? FIND>
+		     ,YABU-RESIGNED?>
+		<TELL
+"You stick your head out over the cliff edge as far as you dare, while
+the samurai hold your ankles for safety.  You begin to search as you
+would at sea, quarter by quarter.  Using every part of your vision but
+mostly the sides.  A complete sweep.  Nothing!|
+|
+Once more.  Nothing!|
+|
+Again.  What's that?  Just above the tide line?  Is it a crack in the
+cliff?  You shift position.  Now you can see better:  there is clearly
+a narrow ledge!" CR>
+		<SCORE-OBJECT ,LEDGE>)
+	       (<AND <VERB? EXAMINE>
+		     ,YABU-RESIGNED?>
+		<COND (<NOT <FSET? ,PRSO ,SCOREBIT>>
+		       <TELL
+"It's nearly a foot wide and still just accessible, the rocks between it
+and Yabu just barely poking above the surf." CR>)
+		      (ELSE
+		       <TELL
+"You don't see any ledges that would help Yabu." CR>)>)>>
+
+<ROOM LEDGE-1
+      (LOC ROOMS)
+      (DESC "Ledge")
+      (SYNONYM LEDGE)
+      (UP TO CLIFF-PATH)
+      (DOWN TO LEDGE-2)
+      (FLAGS RLANDBIT ONBIT)>
+
+<ROOM LEDGE-2
+      (LOC ROOMS)
+      (DESC "Ledge")
+      (SYNONYM LEDGE)
+      (UP TO LEDGE-1)
+      (DOWN TO LEDGE-3)
+      (FLAGS RLANDBIT ONBIT)>
+
+<ROOM LEDGE-3
+      (LOC ROOMS)
+      (DESC "Ledge")
+      (SYNONYM LEDGE)
+      (UP TO LEDGE-2)
+      (DOWN TO LEDGE-4)
+      (FLAGS RLANDBIT ONBIT)>
+
+<ROOM LEDGE-4
+      (LOC ROOMS)
+      (DESC "Ledge")
+      (SYNONYM LEDGE)
+      (UP TO LEDGE-3)
+      (FLAGS RLANDBIT ONBIT SCOREBIT)>
+
+<ROOM AROUND-HEADLAND
+      (LOC ROOMS)
+      (DESC "Around the Headland")
+      (SYNONYM HEADLAND)
+      (LDESC
+"This side of the headland is in the lee of the wind, for which you
+are very grateful.  Half a mile away a small fishing village nestles
+on the white-frothed shore.")
+      (NORTH TO CLIFF-PATH)
+      (FLAGS RLANDBIT ONBIT)
+      (ACTION AROUND-HEADLAND-F)
+      (GLOBAL LG-CLIFF LG-SEA LG-RODRIGUES LG-YABU
+       LG-VILLAGE)>
+
+<ROUTINE AROUND-HEADLAND-F (RARG)
+	 <COND (<RARG? ENTER>
+		<SEARCH-PARTY-FOLLOWS>
+		<COND (<NOT <QUEUED? I-SEARCH>>
+		       <SETG YABU-CNT 0>
+		       <QUEUE I-SEARCH -1>)>)
+	       (<RARG? BEG>
+		<COND (<OR <P? FIND (RODRIGUES LG-RODRIGUES)>
+			   <P? SEARCH GLOBAL-HERE>
+			   <VERB? LOOK-DOWN>>
+		       <TELL ,SEARCH-FORESHORE
+G"There is no sign of Rodrigues.""  You realize that if the body is beyond
+this point it is hidden or swallowed up or already carried out to
+sea." CR>)>)>>
+
+<ROUTINE I-SEARCH ()
+	 <ZLINES ,YABU-CNT
+		 (<PUTP ,SEARCH-PARTY ,P?COUNT
+			<- <GETP ,SEARCH-PARTY ,P?COUNT> 2>>
+		  <TELL CR
+"Yabu motions to two of the samurai, who immediately bow and then lope
+off toward the fishing village." CR>)
+		 (<TELL CR
+"Yabu wipes the rain off of his face, glances up at you, and motions for
+you to return to the galley." CR>)
+		 (DELAY
+		  <COND (<BLACKTHORNE-DALLIES? ,AROUND-HEADLAND ,CLIFF-PATH>
+			 <RTRUE>)>)
+		 (<TELL CR
+"Yabu takes a quick look around, anxious to return to the galley." CR>)
+		 (DELAY
+		  <COND (<BLACKTHORNE-DALLIES? ,CLIFF-PATH ,ROCKY-SHORE>
+			 <RTRUE>)>)
+		 (<TELL CR
+"Yabu glances around impatiently, obviously anxious to return to the
+galley." CR>)
+		 (DELAY
+		  <COND (<BLACKTHORNE-DALLIES? ,ROCKY-SHORE ,PEBBLED-BEACH>
+			 <RTRUE>)>)
+		 (<DEQUEUE I-SEARCH>
+		  <TELL CR
+"Quickly, Yabu orders you put in the skiff, and you are rowed back
+to the galley.  You comply with ill grace, angry at your failure to
+find Rodrigues." CR CR>
+		  <FAILED-SCENE>)>>
+
+<ROUTINE BLACKTHORNE-DALLIES? (RM NRM)
+	 <COND (<IN? ,BLACKTHORNE .RM>
+		<COND (<EQUAL? ,DELAY-CNT 1 2>
+		       <TELL CR
+"Yabu motions to you to return.  \""I"Isogi!""\" he yells." CR>
+		       <RTRUE>)
+		      (<EQUAL? ,DELAY-CNT 3>
+		       <TELL CR
+"Yabu signals to the samurai, barks a few words in Japanese, and
+the samurai quickly subdue you and begin to carry you back." CR CR>
+		       <MOVE ,YABU .NRM>
+		       <MOVE ,SEARCH-PARTY .NRM>
+		       <GOTO .NRM>
+		       <RTRUE>)>)>>
+
+<GLOBAL YABU-WARNED? <>>
+<GLOBAL YABU-RESIGNED? <>>
+
+<ROUTINE I-YABU-CLIMBS ()
+	 <ZLINES ,YABU-CNT
+		 (<PUTP ,SEARCH-PARTY ,P?COUNT 
+			<- <GETP ,SEARCH-PARTY ,P?COUNT> 1>>
+		  <TAKE-OFF ,SLIPPERS>
+		  <TAKE-OFF ,YABU-KIMONO>
+		  <TAKE-OFF ,YABU-SWORDS>
+		  <TELL CR
+"The wind tears around you, whining off the cliff face.  Yabu looks down,
+weighing the climb and the falling light, and you know Yabu is hooked.  A
+samurai begins to climb down but Yabu orders him back.|
+|
+Yabu gives orders to one of the samurai, pointing back toward the
+beach.  The man runs off.|
+|
+Yabu kicks off his thong slippers.  He takes the swords out of his belt
+and puts them safely under cover.  He barks some orders at one of the
+samurai, then takes off his soaking kimono, and clad only in his loincloth,
+goes to the cliff edge, testing it carefully with his toes and feet." CR>)
+		 (<MARGINAL-PIC ,P-CLIFF>
+		  <MOVE ,YABU ,LEDGE-2>
+		  <TELL CR
+"Yabu climbs down the side of the cliff with great skill.|
+|
+Suddenly, Yabu slips!  He grips an outcrop with his left hand, stopping
+his fall.  He grinds his toes in a crevice, fighting for another hold,
+but his left hand rips away.  His toes find a cleft and he hugs the
+cliff desperately.  Then the toehold gives way!  He falls the last twenty
+feet." CR>)
+		 (<MOVE ,YABU ,LEDGE-3>
+		  <TELL CR
+"Yabu lands on his feet like a cat, and comes to rest in a wheezing
+ball.  One ankle is twisted, but unbroken." CR>)
+		 (<MOVE ,YABU ,LEDGE-4>
+		  <TELL CR
+"Yabu reaches Rodrigues, then shouts something.  ">
+		  <COND (<FSET? ,RODRIGUES ,DEAD>
+			 <TELL "He shakes his head, confirming that
+Rodrigues has drowned." CR>
+			 <FAILED-SCENE>
+			 <RFATAL>)
+			(ELSE
+			 <PUTP ,SEARCH-PARTY ,P?COUNT
+			       <- <GETP ,SEARCH-PARTY ,P?COUNT> 1>>
+			 <TELL "He is signalling that
+the pilot is still alive!  One of the samurai runs off toward the galley
+to fetch a stretcher and a doctor.|
+|
+Yabu pulls Rodrigues up onto the rocks, out of the surf." CR>)>)
+		 (<SETG YABU-RESIGNED? T>
+		  <TELL CR
+"Yabu scrambles up and winces at a shaft of pain from his ankle.  He
+manages to climb a few feet up, but then stops, his eyes searching
+the area diligently for a ledge or a crack within his reach.  He sees
+no way to get further up the cliff." CR>)
+		 (<TELL CR
+"Yabu looks out to sea, then looks up at you briefly.  He composes himself
+and sits down on his rocky perch.  With a sudden shock you realize that
+he has resigned himself to death." CR>)
+		 (DELAY
+		  <COND (<AND <NOT ,YABU-WARNED?>
+			      <L? ,DELAY-CNT 5>>
+			 <TELL CR
+"The tide is coming in fast, washing closer and closer to the
+rock Yabu is perched on!" CR>
+			 <RTRUE>)>)
+		 (<TELL CR
+"The tide continues to rise." CR>)
+		 (DELAY
+		  <COND (<AND <NOT ,YABU-WARNED?>
+			      <L? ,DELAY-CNT 5>>
+			 <TELL CR
+"The tide is rising, more and more of Yabu's rock is covered." CR>
+			 <RTRUE>)>) 
+		 (<TELL CR
+"The tide is now breaking over Yabu's rock.  He does not move." CR>)
+		 (<DEQUEUE I-YABU-CLIMBS>
+		  <TELL CR
+"A huge comber crashes over the rock.  Yabu and Rodrigues are swept
+away.  Rodrigues goes under almost immediately.  Yabu cannot swim.  He
+thrashes briefly then goes under and you see him
+no more.  Your feelings are torn.  You are glad to see the son of a whore
+die, but you respect his courage." CR>
+		  <FAILED-SCENE>
+		  <RFATAL>)>>
+
+<GLOBAL ROPE-LOWERED? <>>
+
+<OBJECT YABU-KIMONO
+	(OWNER YABU)
+	(SDESC "kimono")
+	(DESC "kimono")
+	(SYNONYM KIMONO ROPE STRIP STRIPS CLOTHES)
+	(ADJECTIVE SILK SOAKING)
+	(FLAGS TAKEBIT WEARABLE SCOREBIT)
+	(COUNT 0)
+	(GENERIC GENERIC-KIMONO-F)
+	(ACTION YABU-KIMONO-F)>
+
+<ROUTINE YABU-KIMONO-F ("AUX" (ROPE? <GETP ,YABU-KIMONO ,P?COUNT>))
+	 <COND (<AND <NOT <VERB? MAKE>>
+		     <NOT .ROPE?>>
+		<COND (<OR <NOUN-USED? ,PRSO ,W?ROPE>
+			   <NOUN-USED? ,PRSI ,W?ROPE>>
+		       <TELL "You can't see any rope here." CR>
+		       <RTRUE>)>)>
+	 <COND (<VERB? RUB>
+		<TELL "It feels like silk." CR>)
+	       (<VERB? WEAR>
+		<COND (<OR .ROPE? <FSET? ,YABU-KIMONO ,RMUNGBIT>>
+		       <TELL
+"The kimono is no longer in any condition to wear!" CR>)
+		      (<FSET? ,CLOTHES ,WEARBIT>
+		       <TELL
+"You're already wearing your own clothes." CR>)
+		      (ELSE
+		       <FSET ,YABU-KIMONO ,WEARBIT>
+		       <TELL
+"You put on Yabu's kimono.  It doesn't fit very well." CR>)>)
+	       (<AND <VERB? CLIMB-FOO CLIMB-DOWN>
+		     .ROPE?>
+		<DO-WALK ,P?DOWN>
+		<RTRUE>)
+	       (<VERB? TEAR>
+		<COND (<FSET? ,YABU-KIMONO ,WEARBIT>
+		       <HAVE-TO-TAKE-OFF>)
+		      (<NOT <FSET? ,YABU-KIMONO ,RMUNGBIT>>
+		       <FSET ,YABU-KIMONO ,RMUNGBIT>
+		       <TELL
+"You tear the silk kimono into strips, testing them for strength.  The
+silk is very strong." CR>)
+		      (ELSE
+		       <TELL
+"If you tear the silk any more, it will be useless." CR>)>)
+	       (<P? (TIE MAKE) YABU-KIMONO (YABU-KIMONO PARTY-KIMONO <> ROOMS)>
+		<COND (<FSET? ,YABU-KIMONO ,RMUNGBIT>
+		       <COND (<FSET? ,YABU-KIMONO ,SCOREBIT>
+			      <REMOVE ,PARTY-KIMONO>
+			      <MOVE ,LOINCLOTH ,SEARCH-PARTY>
+			      <PUTP ,YABU-KIMONO ,P?SDESC "rope">
+			      <PUTP ,YABU-KIMONO ,P?COUNT
+				    <+ <GETP ,YABU-KIMONO ,P?COUNT> 5>>
+			      <TELL
+"You tie the strips together, making a rope.  The samurai emulate you,
+removing their own kimonos and leaving them clad only in loincloths.  You
+now have a rope of some length." CR>
+			      <SCORE-OBJECT ,YABU-KIMONO>)
+			     (ELSE
+			      <TELL
+"You have already made a rope of some length.  All the kimonos are now
+part of it." CR>)>)
+		      (<FSET? ,YABU-KIMONO ,WEARBIT>
+		       <HAVE-TO-TAKE-OFF>)
+		      (ELSE
+		       <TELL
+"You have succeeded in tying the kimono in knots." CR>)>)
+	       (<P? UNTIE YABU-KIMONO>
+		<COND (<FSET? ,YABU-KIMONO ,SCOREBIT>
+		       <TELL
+"You haven't tied it yet." CR>)
+		      (ELSE
+		       <TELL
+"Your knots are too tight to untie." CR>)>)
+	       (<AND <P? GIVE YABU-KIMONO SEARCH-PARTY>
+		     .ROPE?>
+		<COND (<NOT ,ROPE-LOWERED?>
+		       <TELL
+"You hand the rope over the samurai." CR CR>
+		       <MOVE ,YABU-KIMONO ,SEARCH-PARTY>
+		       <PERFORM ,V?LOWER ,YABU-KIMONO>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL
+"They already are holding the rope." CR>)>)
+	       (<AND <P? TIE YABU-KIMONO> .ROPE?>
+		<COND (<PRSI? ,LG-CLIFF>
+		       <TELL
+"There are no good places here to tie the rope.  The rock is loose
+and crumbly with no really large boulders." CR>)
+		      (<PRSI? ,SEARCH-PARTY>
+		       <TELL
+"The samurai are more than strong enough to hold the rope without tying
+it to them." CR>)
+		      (<PRSI? ME CLOTHES>
+		       <TELL
+"Tying the rope to yourself won't give enough leverage if Yabu ever
+reaches it." CR>)
+		      (,PRSI
+		       <TELL
+"Tying the rope to " THE ,PRSI " isn't very helpful." CR>)>)
+	       (<OR <VERB? LOWER>
+		    <P? (THROW GIVE PUT) * (LG-YABU LG-CLIFF)>>
+		<COND (,ROPE-LOWERED?
+		       <TELL
+"You can't lower the rope any further." CR>)
+		      (<NOT .ROPE?>
+		       <TELL
+"You lower the kimono.  It's nowhere long enough to reach Yabu." CR>)
+		      (ELSE
+		       <COND (<IN? ,YABU-KIMONO ,SEARCH-PARTY>
+			      <TELL
+"You pantomime the action, and the samurai lower the rope towards Yabu.  ">)
+			     (<IN? ,YABU-KIMONO ,WINNER>
+			      <TELL
+"With the help of the samurai, you lower the rope towards Yabu.  ">)
+			     (ELSE
+			      <TELL
+"No one has the rope." CR>
+			      <RTRUE>)>
+		       <SETG ROPE-LOWERED? T>
+		       <COND (<L? <GETP ,YABU-KIMONO ,P?COUNT> 8>
+			      <TELL
+"It's too short, about twenty feet too short." CR>)
+			     (<NOT ,YABU-WARNED?>
+			      <TELL
+"It's just a little short.  If you could find some way for him to climb a
+little higher, just a few feet, he could reach the rope.  But it's hopeless,
+even if there were a way, because he's sitting quietly, composed and waiting
+for death.  The fool won't even pay attention, and the rest of the search
+party has given up too, believing he can't reach the rope, no matter
+what.  Fools!  There must be a way!" CR>)
+			     (ELSE
+			      <TELL
+"It's inches too short, but stretching and scrambling just a little
+higher, Yabu reaches it!" CR>)>)>)
+	       (<VERB? RAISE MOVE>
+		<COND (,ROPE-LOWERED?
+		       <SETG ROPE-LOWERED? <>>
+		       <COND (<IN? ,YABU-KIMONO ,SEARCH-PARTY>
+			      <TELL
+"You signal the search party, and they raise the rope." CR>)
+			     (<IN? ,YABU-KIMONO ,WINNER>
+			      <TELL
+"You raise the rope." CR>)
+			     (ELSE
+			      <TELL "No one is holding the rope." CR>)>)
+		      (<NOT .ROPE?>
+		       <TELL "You lift the kimono." CR>)
+		      (ELSE
+		       <TELL G"It already is." CR>)>)>>
+
+<OBJECT SLIPPERS
+	(DESC "slippers")
+	(SYNONYM SLIPPERS SLIPPER)
+	(ADJECTIVE THONG)
+	(FLAGS TAKEBIT WEARABLE NOABIT PLURAL)>
+
+<OBJECT LOINCLOTH
+	(DESC "loincloth")
+	(SYNONYM LOINCLOTH CLOTH CLOTHS)
+	(ADJECTIVE LOIN)
+	(FLAGS NDESCBIT TAKEBIT WEARABLE PLURAL SCOREBIT)
+	(ACTION LOINCLOTH-F)>
+
+<ROUTINE LOINCLOTH-F ()
+	 <COND (<OR <VERB? POINT TAKE>
+		    <P? TIE LOINCLOTH YABU-KIMONO>
+		    <P? TIE YABU-KIMONO LOINCLOTH>>
+		<REMOVE ,LOINCLOTH>
+		<PUTP ,YABU-KIMONO ,P?COUNT 8>
+		<TELL
+"You point to the loincloths, and the samurai immediately understand.  They
+remove them and tie them together, adding them to the rope.  It is
+now significantly longer.">
+		<COND (,ROPE-LOWERED?
+		       <TELL
+" The rope now reaches almost to Yabu.  If he would just ">
+		       <COND (<QUEUED? I-YABU-RETURNS> <TELL "stretch">)
+			     (ELSE <TELL "stand">)>
+		       <TELL ", he could probably reach it.">)>
+		<CRLF>
+		<SCORE-OBJECT ,LOINCLOTH>)>>
+
+<OBJECT YABU-SWORDS
+	(DESC "swords")
+	(OWNER YABU)
+	(SYNONYM SWORDS SWORD)
+	(FLAGS TAKEBIT TRYTAKEBIT WEARABLE WEAPONBIT NOABIT PLURAL)
+	(GENERIC GENERIC-SWORD-F)
+	(ACTION YABU-SWORDS-F)>
+
+<ROUTINE YABU-SWORDS-F ()
+	 <COND (<VERB? TAKE THROW USE>
+		<TELL
+"The samurai won't let you take Yabu's swords.  A samurai's swords are his
+most precious possession." CR>)>>
+
+<ROUTINE I-YABU-RETURNS ()
+	 <ZLINES ,YABU-CNT
+		 (<TELL CR
+"Yabu staggers up.  He half slides, half crawls, dragging the unconscious
+Rodrigues with him through the surf-disturbed shallows to the bottom of
+the cliff.  He finds the ledge.  It's barely a foot wide.  Painfully he
+shoves Rodrigues onto it, almost losing him once, then hauls himself up." CR>)
+		 (DELAY
+		  <COND (<NOT ,ROPE-LOWERED?>
+			 <COND (<G? ,DELAY-CNT 2>
+				<SETG ROPE-LOWERED? T>
+				<TELL CR
+"The samurai lower the rope to Yabu." CR CR>)
+			       (ELSE
+				<TELL CR
+"The rope isn't lowered!  Yabu can't reach it, even from the ledge." CR>
+				<RTRUE>)>)
+			(<L? <GETP ,YABU-KIMONO ,P?COUNT> 8>
+			 <TELL CR
+"Yabu reaches for the rope, but it's twenty feet short." CR>
+			 <RTRUE>)>)
+		 (<MOVE ,YABU ,LEDGE-3>
+		  <MOVE ,RODRIGUES ,LEDGE-3>
+		  <TELL CR
+"Yabu stretches for the rope, pulling himself partway up the cliff, carrying
+Rodrigues.  Twice he loses the pilot, but each time Yabu drags him back.  His
+position is precarious, but you can see that the bottom of the cliff is now
+completely under water." CR>)
+		 (<DEQUEUE I-YABU-RETURNS>
+		  <MOVE ,YABU ,GENERIC-OBJECTS>
+		  <MOVE ,RODRIGUES ,GENERIC-OBJECTS>
+		  <TELL CR
+"For almost an hour Yabu sets himself against the sea and against his
+failing body, and then, in the dusk, he reaches wide ledge where he's safe
+from the sea and he can rest and not hang from the makeshift, fraying rope.|
+|
+Just then, the samurai Yabu sent to the galley returns with coils of
+strong rope.  They make a cradle and shin down the cliff with a skill that
+you have never seen ashore.  Quickly Rodrigues is brought aloft, and then
+Yabu.  You look at him.|
+|
+\"Thank you,\" you say finally, pointing at Rodrigues.  \"Thank you,
+Yabu-san.\"  You bow.  That's for your courage, you black-eyed son of a
+whore.|
+|
+Yabu bows back, stiffly.  But inside, he smiles." CR>
+		  <NEXT-SCENE>)>>
+
+<ROUTINE VOYAGE-AFTER-F ()
+	 <TELL
+"The rest of the voyage to Osaka is uneventful.|
+|
+Rodrigues is tended by a Japanese doctor with strange ideas, such as
+keeping the air in the cabin fresh, but begins to recover anyway.|
+|
+\"Ah, Ingeles,\" he sighs.  \"If I live, it is because of a heretic and a
+Japman.\"  Then he turns serious.  \"Japan's an upside-down
+world.  They have a saying, that a man has a false heart in his mouth for
+all the world to see, another in his breast to show his very special
+friends and family, and the real one, the true one, the secret one,
+which is never known to anyone except himself alone.  So never forget
+they're six-faced and have three hearts!\"">>
+
+<END-SEGMENT>