commit fa9390b02cfc7a96281587b254b9239d2eed0659
Author: historicalsource <historicalsoftware@textfiles.com>
Date:   Sat Apr 13 23:50:54 2019 -0400

    Revision 22 (Original Source)

diff --git a/README.md b/README.md
new file mode 100644
index 0000000..d58a418
--- /dev/null
+++ b/README.md
@@ -0,0 +1 @@
+# infidel
diff --git a/ante.zil b/ante.zil
new file mode 100644
index 0000000..08048f3
--- /dev/null
+++ b/ante.zil
@@ -0,0 +1,1441 @@
+;"		ANTECHAMBER for INFIDEL"
+
+<ROOM NORTH-ANTECHAMBER
+      (IN ROOMS)
+      (DESC "Antechamber")
+      (LDESC 
+"You are in the north end of the Chamber of Eternal Royalty. On the eastern
+and western walls are scenes carved in high relief depicting a royal figure,
+possibly meant to represent a new ruler, performing the ritual of the
+\"opening of the mouth and eyes\", the ceremony of restoring to the mummy
+of the departed Queen the use of its senses. The north wall of this area is
+a thick, solid wall of stone. In the center of this wall is a timber lintel
+on top of a doorway.")
+      (FLAGS RLANDBIT)
+      (SOUTH TO MID-ANTECHAMBER)
+      (NORTH TO BURIAL-CHAMBER IF NORTH-ANTE-DOOR IS OPEN ELSE
+"There's no way you can walk through the door.")
+      (IN TO BURIAL-CHAMBER IF NORTH-ANTE-DOOR IS OPEN ELSE
+"There's no way you can walk through the door.")
+      (GLOBAL NORTH-ANTE-DOOR DOORWAY HIEROGLYPHS)
+      (ACTION NORTH-ANTE-FCN)>
+
+<OBJECT T-LINTEL
+	(IN NORTH-ANTECHAMBER)
+	(FLAGS NDESCBIT DONTTAKE)
+	(DESC "timber lintel")
+	(SYNONYM LINTEL)
+	(ADJECTIVE TIMBER)>
+
+<ROUTINE NORTH-ANTE-FCN (RARG)
+	 <COND (<EQUAL? .RARG ,M-BEG ,M-ENTER ,M-LOOK>
+		<COND (<EQUAL? ,BEAM-PLACED 4>
+		       <MOVE ,BEAM ,HERE>)>)>
+	 <RFALSE>>
+
+<ROOM MID-ANTECHAMBER
+      (IN ROOMS)
+      (DESC "Antechamber")
+      (LDESC 
+"You are in the middle of the Chamber of Eternal Royalty, the antechamber. The
+walls in this section of the antechamber are covered with beveled tiles of deep
+blue lapis lazuli and pink alabaster. At ceiling height, on the west wall, are
+paintings depicting the marriage of the goddess Isis and the god Osiris. The
+Antechamber stretches out to the north and the south. There's just enough light
+cast for you to see the outline of the bottomless pit in the passage to the
+east.")
+      (FLAGS RLANDBIT)
+      (NORTH TO NORTH-ANTECHAMBER)
+      (SOUTH TO SOUTH-ANTECHAMBER)
+      (EAST PER WALK-BEAM-FCN)
+      (OUT PER WALK-BEAM-FCN)
+      (GLOBAL DOORWAY PIT PICTURE-PANELS GEMS)
+      (ACTION MOVE-PLANK-FCN)>
+
+<OBJECT TILES
+	(IN MID-ANTECHAMBER)
+	(DESC "tiles")
+	(FLAGS DONTTAKE TRYTAKEBIT NDESCBIT)
+	(SYNONYM TILES IVORY)
+	(TEXT "Quite beautiful, no?")>
+
+<OBJECT PIT
+	(IN LOCAL-GLOBALS)
+	(DESC "deep pit")
+	(FLAGS NDESCBIT INVISIBLE)
+	(SYNONYM PIT)
+	(ADJECTIVE DEEP)
+	(ACTION PIT-FCN)>
+
+<ROUTINE PIT-FCN ()
+	 <COND (<VERB? THROUGH>
+		<DO-WALK ,P?DOWN>)
+	       (<VERB? LOOK-INSIDE LOOK-DOWN EXAMINE>
+		<TELL "It's too deep and dark to see much of anything." CR>
+		<RTRUE>)
+	       (<VERB? LISTEN>
+		<TELL "You hear the squealing of rats. Hungry rats." CR>
+		<RTRUE>)>>
+
+<ROUTINE MOVE-PLANK-FCN (RARG)
+	 <COND (<EQUAL? .RARG ,M-BEG ,M-ENTER ,M-LOOK>
+		<COND (<EQUAL? ,BEAM-PLACED 1 5>
+		       <MOVE ,BEAM ,HERE>)>
+		<COND (<EQUAL? ,HERE ,MID-ANTECHAMBER ,MID-PASSAGE>
+		       <SETG ON-BEAM <>>)>
+		<COND (<NOT <EQUAL? .RARG ,M-BEG>>
+		       <RFALSE>)
+		      (<NOT <VERB? DROP THROW PUT>>
+		       <RFALSE>)
+		      (<AND <VERB? PUT>
+			    <NOT <PRSI? ,PIT>>>
+		       <RFALSE>)
+		      (<FSET? ,PIT ,INVISIBLE>
+		       <RFALSE>)
+		      (<AND <EQUAL? ,HERE ,WEST-END-OF-PASSAGE>
+			    <AND <NOT <EQUAL? ,PRSO ,WINNER ,ME ,ADVENTURER>>
+				 <NOT <EQUAL? ,PRSO ,NOT-HERE-OBJECT>>
+				 <IN? ,PRSO ,WINNER>>
+			    <EQUAL? .RARG ,M-BEG>>
+		       <REMOVE ,PRSO>
+		       <TELL "You hear the " D ,PRSO
+			     " hit the bottom of the deep pit." CR>
+		       <SETG P-IT-LOC <>>
+		       <COND (<PRSO? ,TORCH>
+			      <KILL-TORCH>)>
+		       <RTRUE>)>
+		<RFALSE>)>>
+	 
+<ROUTINE WALK-BEAM-FCN ()
+	 <COND (<NOT <EQUAL? ,BEAM-PLACED 1 5>>
+		<JIGS-UP
+"You step into air then plummet into a deep pit, the home of a rat pack.">)
+	       (T 
+		<SETG ON-BEAM T>
+		<MOVE ,BEAM ,WEST-END-OF-PASSAGE>
+		,WEST-END-OF-PASSAGE)>>
+
+<OBJECT LINTEL
+	(IN WEST-END-OF-PASSAGE)
+	(FLAGS NDESCBIT CONTBIT OPENBIT DONTTAKE)
+	(DESC "timber frame")
+	(SYNONYM FRAME)
+	(ADJECTIVE TIMBER)
+	(TEXT
+"The timber frame surrounds the doorway.")
+	(ACTION BURN-FRAME-FCN)>
+
+<ROUTINE BURN-FRAME-FCN ()
+	 <COND (<VERB? BURN>
+		<TELL
+"You light the timber frame surrounding the door. The wood is slow to catch,
+but then, in a bursting flash, the entire frame is consumed. You shield your
+eyes and move back to keep from being burned, but as you take a step back, ">
+		<COND (<NOT ,ON-BEAM>
+		       <JIGS-UP
+"your foot lands on empty space and you plummet downward to darkness.">)
+		      (T
+		       <JIGS-UP
+"you lose your balance on the mast. Your foot misses the mast and you slip,
+falling into the darkness below.">)>)>> 
+
+<ROOM SOUTH-ANTECHAMBER
+      (IN ROOMS)
+      (DESC "Antechamber")
+      (LDESC
+"You are in the southern end of the Chamber of Eternal Royalty. From here you
+can see the room stretching out towards the north. The south wall is painted to
+resemble large baskets of lotus flowers with their blue petals framing an image
+of the Sun God, Amun Ra. The west wall has a timber doorway, inset several feet
+into the rocks, outlining a door.")
+      (FLAGS RLANDBIT)
+      (NORTH TO MID-ANTECHAMBER)
+      (WEST TO ANNEX IF ANNEX-DOOR IS OPEN ELSE
+"The way to the west is blocked by a closed door.")
+      (IN TO ANNEX IF ANNEX-DOOR IS OPEN ELSE
+"The way to the west is blocked by a closed door.")
+      (GLOBAL HIEROGLYPHS DOORWAY ANNEX-DOOR)
+      (ACTION ANNEX-BEAM-MOVER)>
+
+<OBJECT ROCKS
+	(IN SOUTH-ANTECHAMBER)
+	(FLAGS NDESCBIT DONTTAKE CONTBIT OPENBIT SURFACEBIT)
+	(DESC "rocks")
+	(CAPACITY 35)
+	(SYNONYM ROCKS)
+	(ACTION ROCKS-FCN)>
+
+<ROUTINE ROCKS-FCN ()
+	 <COND (<AND <VERB? PUT-UNDER PUT-AGAINST PUT>
+		     <EQUAL? ,PRSI ,ROCKS>
+		     <NOT <EQUAL? ,PRSO ,BEAM>>>
+		<TELL "Weird!" CR>
+		<RTRUE>)
+	       (<VERB? EXAMINE LOOK-INSIDE>
+		<COND (<EQUAL? ,BEAM-PLACED 2 3>
+		       <TELL "The rocks support the beam." CR>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL "I see nothing special about the rocks." CR>
+		       <RTRUE>)>)
+	       (<VERB? OPEN CLOSE>
+		<TELL
+"Huh? The rocks? Come on! They're on either side of the doorway!" CR>
+		<RTRUE>)>
+	 <RFALSE>>
+
+<OBJECT CHIPS1
+	(FLAGS NDESCBIT TAKEBIT DONTTAKE TOUCHBIT)
+	(DESC "plaster dust")
+	(SYNONYM DUST CHIP CHIPS)
+	(TEXT
+"The dust and chips are just remnants of your incessant tapping, tapping at the
+chamber door. Only this and nothing more.")
+	(ACTION TAKE-A-CHIP-FCN)>
+
+<OBJECT CHIPS2
+	(FLAGS NDESCBIT TAKEBIT DONTTAKE TOUCHBIT)
+	(DESC "plaster dust")
+	(SYNONYM DUST CHIP CHIPS)
+	(TEXT
+"The dust and chips are just remnants of your incessant tapping, tapping at the
+chamber door. Only this and nothing more.")
+	(ACTION TAKE-A-CHIP-FCN)>
+
+<ROUTINE TAKE-A-CHIP-FCN ()
+	 <COND (<VERB? TAKE PUT MOVE RAISE
+		       PULL-UP MUNG PUT>
+		<TELL
+"Be serious. Have you any acquaintance with particle physics? How about quarks?
+Know anything about quarks? Let me put it to you this way: There are more
+pieces of plaster dust and chips here than you have seconds in your life." CR>
+		<RTRUE>)>>
+
+<ROOM ANNEX
+      (IN ROOMS)
+      (DESC "Annex")
+      (LDESC
+"You are in the Chamber of Rebirth, the Annex. As you gaze about this small
+room, strange kohl-rimmed eyes gaze back at you from the painted figures
+which cover all of the walls. There are scenes of a great procession, with
+white-clad princesses offering gifts of precious oils and papyri to the
+mummified figure of the Queen. Bastet, the cat goddess, holds the mummy
+erect. Above you, painted on the ceiling, is the image of Tueris, the
+hippopotamus goddess. The only way out is through the doorway to the east.")
+      (FLAGS RLANDBIT)
+      (EAST TO SOUTH-ANTECHAMBER IF ANNEX-DOOR IS OPEN)
+      (OUT TO SOUTH-ANTECHAMBER IF ANNEX-DOOR IS OPEN)
+      (GLOBAL ANNEX-DOOR DOORWAY PICTURES)
+      (ACTION ANNEX-BEAM-MOVER)>
+
+<ROUTINE ANNEX-BEAM-MOVER (RARG)
+	 <COND (<EQUAL? .RARG ,M-BEG ,M-ENTER ,M-LOOK>
+		<COND (<EQUAL? ,BEAM-PLACED 2 3>
+		       <MOVE ,BEAM ,HERE>)>)>
+	 <RFALSE>>
+
+<OBJECT SLAB
+	(IN ANNEX)
+	(FLAGS DONTTAKE CONTBIT SURFACEBIT OPENBIT)
+	(DESC "slab")
+	(SYNONYM SLAB)
+	(ADJECTIVE HUGE STONE)
+	(CAPACITY 200)
+	(DESCFCN DESCRIBE-SLAB-FCN) 
+	(ACTION OPEN-SLAB-FCN)>
+
+<OBJECT SLAB-SEAM
+	(IN ANNEX)
+	(FLAGS NDESCBIT DONTTAKE CONTBIT)
+	(DESC "thin seam")
+	(CAPACITY 1)
+	(SYNONYM SEAM)
+	(ADJECTIVE THIN)
+	(ACTION SEAM-FCN)>
+
+<ROUTINE SEAM-FCN ()
+	 <COND (<AND <EQUAL? ,PRSO ,SLAB-SEAM>
+		     <NOT <FSET? ,SLAB ,SURFACEBIT>>>
+		<TELL "I see no seam here." CR>
+		<RTRUE>)
+	       (<VERB? EXAMINE LOOK-INSIDE>
+		<TELL
+"The seam is barely visible. It goes into the edge of the slab no more than an
+eighth of an inch." CR>)
+	       (<AND <VERB? PUT PUT-ACROSS PUT-ON>
+		     <PRSI? ,SLAB-SEAM>>
+		<TELL "It's not deep enough to wedge anything into it." CR>
+		<RTRUE>)
+	       (<VERB? OPEN CLOSE>
+		<HOW? ,SLAB-SEAM>
+		<RTRUE>)>>
+	       
+<ROUTINE OPEN-SLAB-FCN ("AUX" (FLG <>))
+	 <COND (<VERB? OPEN RAISE MOVE>
+		<COND (<NOT <FSET? ,SLAB ,SURFACEBIT>>
+		       <TELL "It's already open." CR>
+		       <RTRUE>)
+		      (<AND <IN? ,ISIS-JEWEL ,HOLE-3>
+			    <IN? ,NEPHTH-JEWEL ,HOLE-1>
+			    <IN? ,SELKIS-JEWEL ,HOLE-2>
+			    <IN? ,NEITH-JEWEL ,HOLE-4>>
+		       <TBL-TO-INSIDE ,SLAB ,SLAB-TBL
+"The slab opens slowly and gracefully as if some internal mechanism balanced
+its huge weight.">
+		       <RTRUE>)
+		      (T
+		       <TELL "It won't budge." CR>
+		       <RTRUE>)>)
+	       (<AND <VERB? CLOSE>
+		     <NOT <FSET? ,SLAB ,SURFACEBIT>>>
+		<COND (<AND <IN? ,TORCH ,SLAB>
+			    <FLAMING? ,TORCH>>
+		       <SET FLG T>)>
+	        <INSIDE-OBJ-TO ,SLAB-TBL ,SLAB>
+		<COND (.FLG
+		       <KILL-TORCH T>)>
+		<RTRUE>)
+	       (<VERB? EXAMINE LOOK-INSIDE>
+		<DESCRIBE-SLAB-FCN ,M-OBJDESC>
+		<RTRUE>)>>
+
+<GLOBAL SLAB-TBL ;"Thirt (30) slots to hold objects in the slab"
+	<LTABLE DEAD-BOOK SPATULA 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0>>
+
+<ROUTINE HOLEY (H "OPTIONAL" (X? <>) "AUX" OBJ)
+	 <SET OBJ <FIRST? .H>>
+	 <COND (<NOT .OBJ>
+		<COND (<EQUAL? .X? T>
+		       <TELL " The " D .H " is empty.">
+		       <RTRUE>)
+		      (T
+		       <RTRUE>)>)>
+	 <TELL " Sitting in the " D .H " is a">
+	 <VOWEL? .OBJ>
+	 <TELL D .OBJ ".">>
+
+<ROUTINE DESCRIBE-SLAB-FCN (RARG)
+	 <COND (<EQUAL? .RARG ,M-OBJDESC>
+		<TELL
+"Sitting in the middle of this room is a huge stone slab.">
+	 <COND (<FSET? ,SLAB ,SURFACEBIT>
+		<TELL
+" Around its side runs a seam which is barely detectable. On top of the slab
+are four round holes, one in each corner.">
+		<HOLEY ,HOLE-1>
+		<HOLEY ,HOLE-2>
+		<HOLEY ,HOLE-3>
+		<HOLEY ,HOLE-4>
+		<COND (<FIRST? ,SLAB>
+		       <TELL " Sitting on the top of the slab ">
+		       <COND (<G? <CCOUNT ,SLAB> 1>
+			      <TELL "are ">)
+			     (T <TELL "is ">)>
+		       <PRINT-CONTENTS ,SLAB>
+		       <TELL ".">)>
+		<CRLF>
+		<RTRUE>)
+	       (T <TELL " The slab is open">
+		<COND (<FIRST? ,SLAB>
+		       <TELL " and holds ">
+		       <PRINT-CONTENTS ,SLAB>)
+		      (T <TELL " and quite empty">)>
+		<TELL "." CR>
+		<RTRUE>)>)>>
+
+<OBJECT HOLE-4
+	(IN ANNEX)
+	(FLAGS NDESCBIT CONTBIT DONTTAKE OPENBIT)
+	(DESC "fourth hole")
+	(SYNONYM HOLE HOLES)
+	(ADJECTIVE FOURTH)
+	(CAPACITY 2)
+	(MAP 2)
+	(CONTFCN D-HOLE-FCN)
+	(ACTION DIAMOND-HOLE-FCN)>
+
+<OBJECT HOLE-3
+	(IN ANNEX)
+	(FLAGS NDESCBIT CONTBIT DONTTAKE OPENBIT)
+	(DESC "third hole")
+	(SYNONYM HOLE HOLES)
+	(ADJECTIVE THIRD)
+	(CAPACITY 2)
+	(MAP 2)
+	(CONTFCN D-HOLE-FCN)
+	(ACTION DIAMOND-HOLE-FCN)>
+
+<OBJECT HOLE-2
+	(IN ANNEX)
+	(FLAGS NDESCBIT CONTBIT DONTTAKE OPENBIT)
+	(DESC "second hole")
+	(SYNONYM HOLE HOLES)
+	(ADJECTIVE SECOND)
+	(CAPACITY 2)
+	(MAP 2)
+	(CONTFCN D-HOLE-FCN)
+	(ACTION DIAMOND-HOLE-FCN)>
+
+<OBJECT HOLE-1
+	(IN ANNEX)
+	(FLAGS NDESCBIT CONTBIT DONTTAKE OPENBIT)
+	(DESC "first hole")
+	(SYNONYM HOLE HOLES)
+	(ADJECTIVE FIRST)
+	(CAPACITY 2)
+	(MAP 2)
+	(CONTFCN D-HOLE-FCN)
+	(ACTION DIAMOND-HOLE-FCN)>
+
+<ROUTINE D-HOLE-FCN ()
+	 <COND (<AND <VERB? TAKE>
+		     <OR <EQUAL? <LOC ,PRSO> ,HOLE-1 ,HOLE-2>
+			 <EQUAL? <LOC ,PRSO> ,HOLE-3 ,HOLE-4>>>
+		<COND (<ITAKE>
+		       <FCLEAR ,PRSO ,NDESCBIT>
+		       <TELL "Taken." CR>
+		       <RTRUE>)
+		      (T
+		       <RTRUE>)>)>>
+
+<ROUTINE DIAMOND-HOLE-FCN ("AUX" (FLG <>))
+	 <COND (<AND <VERB? EXAMINE LOOK-INSIDE>
+		     <OR <PRSO? ,HOLE-1 ,HOLE-2 ,HOLE-3>
+			 <PRSO? ,HOLE-4>>>
+		<TELL "The hole sits in the ">
+		<COND (<EQUAL? ,PRSO ,HOLE-1>
+		       <TELL "northwest">)
+		      (<EQUAL? ,PRSO ,HOLE-2>
+		       <TELL "northeast">)
+		      (<EQUAL? ,PRSO ,HOLE-3>
+		       <TELL "southwest">)
+		      (T <TELL "southeast">)>
+		<TELL " corner of the slab.">
+		<HOLEY ,PRSO T>
+		<CRLF>
+		<RTRUE>)
+	       (<AND <VERB? PUT>
+		     <OR <PRSI? ,HOLE-1 ,HOLE-2 ,HOLE-3>
+			 <PRSI? ,HOLE-4>>>
+		<COND (<FIRST? ,PRSI>
+		       <TELL "The hole is already filled." CR>
+		       <RTRUE>)
+		      (<AND <PRSI? ,HOLE-1>
+			    <PRSO? ,NEPHTH-JEWEL>>
+		       <SET FLG T>)
+		      (<AND <PRSI? ,HOLE-2>
+			    <PRSO? ,SELKIS-JEWEL>>
+		       <SET FLG T>)
+		      (<AND <PRSI? ,HOLE-3>
+			    <PRSO? ,ISIS-JEWEL>>
+		       <SET FLG T>)
+		      (<AND <PRSI? ,HOLE-4>
+			    <PRSO? ,NEITH-JEWEL>>
+		       <SET FLG T>)>
+		<FSET ,PRSO ,NDESCBIT>
+		<COND (<NOT .FLG>
+		       <RFALSE>)
+		      (T
+		       <TELL 
+"Done. A light click comes from beneath the corner." CR>
+		       <MOVE ,PRSO ,PRSI>
+		       <RTRUE>)>)>>
+	
+<ROOM BURIAL-CHAMBER
+      (IN ROOMS)
+      (DESC "Burial Chamber")
+      (SOUTH TO NORTH-ANTECHAMBER IF NORTH-ANTE-DOOR IS OPEN)
+      (EAST TO TREASURY)
+      (FLAGS RLANDBIT)
+      (ACTION BURIAL-CHAMBER-DESC)
+      (LDESC "LDESC")
+      (GLOBAL NORTH-ANTE-DOOR DOORWAY)>
+
+<ROUTINE BURIAL-CHAMBER-DESC (RARG "AUX" (OFFSET -1) (HOLDING 0) TEMP-HOLD)
+	 <COND (<EQUAL? .RARG ,M-BEG ,M-LOOK ,M-ENTER>
+		<COND (<AND <EQUAL? <LOC ,BEAM> ,BURIAL-CHAMBER 
+				    ,NORTH-ANTECHAMBER>
+			    ,BEAM-PLACED>
+		       <MOVE ,BEAM ,HERE>)>)>
+	 <COND (<NOT <EQUAL? .RARG ,M-LOOK>>
+		<RFALSE>)>
+	 <TELL
+"You have entered the Chamber of Departure Towards the Funeral Destinies, the
+Burial Chamber. There is a doorway leading into a small room off to the east.
+In the middle of the chamber, stretching almost from wall to wall, is a huge,
+ancient sarcophagus. Its cover is composed of pure quartz and through the
+shining light you can see the golden, gleaming mummiform coffin. ">
+	 <DESCRIBE-COVER>
+	 <REPEAT ()
+		 <SET OFFSET <+ .OFFSET 1>>
+		 <COND (<G? .OFFSET 3>
+			<RETURN>)
+		       (<FSET? <GET ,STATUE-TBL .OFFSET> ,CLAMPBIT>
+			<SET HOLDING <+ .HOLDING 1>>)>>
+	 <TELL
+" Four statues surround the sarcophagus, one in each corner: Isis, Nephthys,
+Neith and Selkis. ">
+	 <COND (<EQUAL? .HOLDING 4>
+		<TELL 
+"Their outstretched arms clamp down tightly on the quartz cover." CR>
+		<RTRUE>)
+	       (<0? .HOLDING>
+		<TELL
+"All four statues face away from the quartz cover, their grip on it released." CR>
+		<RTRUE>)>
+	 <SET OFFSET -1>
+	 <SET TEMP-HOLD .HOLDING>
+	 <REPEAT ()
+		 <COND (<0? .HOLDING>
+			<RETURN>)
+		       (ELSE
+			<SET OFFSET <+ .OFFSET 1>>
+			<COND (<FSET? <GET ,STATUE-TBL .OFFSET> ,CLAMPBIT>
+			       <TELL <GET ,STATUE-NAME-TBL .OFFSET>>
+			       <COND (<G? .HOLDING 2>
+				      <TELL ", ">)
+				     (<G? .HOLDING 1>
+				      <TELL " and ">)>
+			       <SET HOLDING <- .HOLDING 1>>)>)>>
+	 <COND (<G? .TEMP-HOLD 1>
+		<TELL " are ">)
+	       (T <TELL " is ">)>
+	 <TELL "facing inward, ">
+	 <COND (<G? .TEMP-HOLD 1>
+		<TELL "their">)
+	       (T <TELL "its">)>
+	 <TELL 
+" heavy arms clamping down tightly over the quartz cover of the
+sarcophagus." CR>>
+
+<ROOM TREASURY
+      (IN ROOMS)
+      (DESC "Treasury")
+      (LDESC
+"You are in the Chamber of Reconstitution of the Body, the Treasury. To the
+west is a doorway leading back into the Burial Chamber.")
+      (FLAGS RLANDBIT)
+      (WEST TO BURIAL-CHAMBER)
+      (OUT TO BURIAL-CHAMBER)>
+
+<OBJECT SCARAB-TABLE
+	(IN TREASURY)
+	(FLAGS CONTBIT OPENBIT DONTTAKE)
+	(DESC "granite table")
+	(SYNONYM TABLE)
+	(ADJECTIVE GRANITE)
+	(CAPACITY 100)
+	(DESCFCN PROB-DESC)
+	(ACTION SCARAB-TABLE-F)>
+
+<ROUTINE SCARAB-TABLE-F ()
+	 <COND (<VERB? EXAMINE LOOK-INSIDE>
+		<PROB-DESC 15>
+		<RTRUE>)>>
+
+<ROUTINE DISC-CONTFCN ()
+	 <COND (<AND <VERB? TAKE>
+		     <EQUAL? <LOC ,PRSO> ,LEFT-DISC ,RIGHT-DISC>
+		     <NOT <IN? ,SCARAB ,MID-DISC>>>
+		<JIGS-UP
+"You should have left well enough alone. As you pick it up, the discs go wildly
+out of balance and, before you realize what you've done, the ceiling comes down
+to meet the floor. Unfortunately, you were between them at the time.">
+		<RFATAL>)>>
+
+<OBJECT LEFT-DISC
+	(IN SCARAB-TABLE)
+	(DESC "left disc")
+	(FLAGS NDESCBIT CONTBIT OPENBIT SURFACEBIT DONTTAKE TRANSBIT)
+	(CAPACITY 30)
+	(SYNONYM DISC)
+	(ADJECTIVE LEFT)
+	(CONTFCN DISC-CONTFCN)
+	(ACTION PUSH-DISC-FCN)>
+ 
+<OBJECT RIGHT-DISC
+	(IN SCARAB-TABLE)
+	(DESC "right disc")
+	(FLAGS NDESCBIT CONTBIT OPENBIT SURFACEBIT DONTTAKE TRANSBIT)
+	(CAPACITY 30)
+	(SYNONYM DISC)
+	(ADJECTIVE RIGHT)
+	(CONTFCN DISC-CONTFCN)
+	(ACTION PUSH-DISC-FCN)>
+
+<OBJECT MID-DISC
+	(IN SCARAB-TABLE)
+	(DESC "middle disc")
+	(FLAGS NDESCBIT CONTBIT OPENBIT SURFACEBIT DONTTAKE TRANSBIT)
+	(CAPACITY 30)
+	(SYNONYM DISC)
+	(ADJECTIVE MIDDLE)
+	(ACTION PUSH-DISC-FCN)>
+
+<ROUTINE PUSH-DISC-FCN ("AUX" LEFT-STATUS RIGHT-STATUS L-WEIGHT R-WEIGHT)
+	 <COND (<NOT <EQUAL? ,PRSO ,LEFT-DISC ,RIGHT-DISC ,MID-DISC>>
+		<RFALSE>)
+	       (<VERB? PUSH MOVE>
+		<TELL 
+"The discs float up and down several times until they come back into balance."
+		      CR>
+		<RTRUE>)
+	       (<VERB? OPEN CLOSE>
+		<HOW? ,PRSO>
+		<RTRUE>)
+	       (<VERB? EXAMINE LOOK-INSIDE>
+		<SET LEFT-STATUS <FIRST? ,LEFT-DISC>>
+		<SET RIGHT-STATUS <FIRST? ,RIGHT-DISC>>
+		<COND (.LEFT-STATUS
+		       <SET L-WEIGHT <WEIGHT .LEFT-STATUS>>)>
+		<COND (.RIGHT-STATUS
+		       <SET R-WEIGHT <WEIGHT .RIGHT-STATUS>>)>
+		<COND (<PRSO? ,LEFT-DISC>
+		       <TELL-ABOUT ,LEFT-DISC .L-WEIGHT .R-WEIGHT>
+		       <CRLF>)
+		      (<PRSO? ,MID-DISC>
+		       <TELL-ABOUT ,MID-DISC .L-WEIGHT .R-WEIGHT>
+		       <CRLF>)
+		      (T
+		       <TELL-ABOUT ,RIGHT-DISC .R-WEIGHT .L-WEIGHT>)>
+		<RTRUE>)>>
+
+<ROUTINE PROB-DESC
+	 (RARG "AUX" LEFT-STATUS RIGHT-STATUS (L-WEIGHT 0) (R-WEIGHT 0))
+	 <COND (<NOT <EQUAL? .RARG ,M-OBJDESC 15>>
+		<RFALSE>)>
+	 <SET LEFT-STATUS <FIRST? ,LEFT-DISC>>
+	 <SET RIGHT-STATUS <FIRST? ,RIGHT-DISC>>
+	 <COND (.LEFT-STATUS
+		<SET L-WEIGHT <WEIGHT .LEFT-STATUS>>)>
+	 <COND (.RIGHT-STATUS
+		<SET R-WEIGHT <WEIGHT .RIGHT-STATUS>>)>
+	 <COND (<EQUAL? .RARG ,M-OBJDESC>
+		<TELL
+"In the room is a large, granite table. Cut out from the top of this table are
+three circles of polished granite. ">)>
+	 <TELL-ABOUT ,LEFT-DISC .L-WEIGHT .R-WEIGHT>
+	 <TELL " ">
+	 <TELL-ABOUT ,MID-DISC .L-WEIGHT .R-WEIGHT>
+	 <TELL " ">
+	 <TELL-ABOUT ,RIGHT-DISC .R-WEIGHT .L-WEIGHT>>
+	 
+<ROUTINE TELL-ABOUT (DISC W-1 W-2 "AUX" (BALANCED <>) (SAFE <>) (EMPTY <>)
+		     OBJ OFFSET POSITION INCHES)
+	 <SET POSITION "even with">
+	 <COND (<AND <0? .W-1>
+		     <0? .W-2>>
+		<SET EMPTY T>)>
+	 <COND (<NOT <FIRST? .DISC>>
+		<TELL "The " D .DISC " is empty, and it is ">)
+	       (T
+		<SET OBJ <FIRST? .DISC>>
+		<TELL "Sitting on the " D .DISC " is a">
+		<VOWEL? .OBJ>
+		<TELL D .OBJ ", and the " D .DISC " is ">)>
+	 <COND (<AND <EQUAL? .W-2 .W-1>
+		     <NOT .EMPTY>>
+		<SET BALANCED T>)>
+	 <COND (.BALANCED
+		<COND (<EQUAL? .W-1 8>
+		       <SET SAFE T>)>)>
+	 <COND (<G? .W-1 .W-2>
+		<SET POSITION "below">)
+	       (<G? .W-2 .W-1>
+		<SET POSITION "above">)
+	       (.EMPTY
+		<SET POSITION "above">)
+	       (<AND .BALANCED
+		     <NOT .SAFE>>
+		<SET POSITION "below">)>
+	 <COND (<AND <NOT .BALANCED>
+		     <NOT .EMPTY>>
+		<SET OFFSET <ABS <- .W-1 .W-2>>>)
+	       (.EMPTY
+		<SET OFFSET 1>)
+	       (<NOT .SAFE>
+		<SET OFFSET <ABS <- .W-1 8>>>)>
+	 <COND (.SAFE
+		<SET INCHES "exactly">)
+	       (<G? .OFFSET 8>
+		<SET INCHES "9 inches">)
+	       (T
+		<SET INCHES <GET ,INCH-LTBL .OFFSET>>)>
+	 <COND (<EQUAL? .DISC ,MID-DISC>
+		<COND (<AND .SAFE
+			    <FIRST? .DISC>>
+		       <TELL "slightly above">)
+		      (<FIRST? .DISC>
+		       <TELL "slightly below">)
+		      (T
+		       <TELL "exactly even with">)>)
+	       (<EQUAL? .DISC ,LEFT-DISC ,RIGHT-DISC>
+		<TELL .INCHES " " .POSITION>)>
+	 <TELL " the top of the table.">
+	 <COND (<EQUAL? .DISC ,RIGHT-DISC>
+		<CRLF>)>>
+
+<GLOBAL INCH-LTBL
+	<LTABLE "one inch" "two inches" "three inches" "four inches"
+		"five inches" "six inches" "seven inches" "eight inches">>
+
+<ROOM TOP-OF-STAIRS
+      (IN ROOMS)
+      (DESC "Top of Stairway")
+      (LDESC 
+"You are at the top of a sixteen-step stairway. It leads west and down. The
+strange passageway into the cube rooms lies to the south. The walls here are
+painted in somber colors -- deep ochres, browns and blacks, but the scenes the
+paintings depict are oddly gay. Priests smile, their hands lifted up high to
+Amun Ra, offering flower petals in their palms, while a young girl, bedecked
+in black, stands by watching, a twisted smile on her face.")
+      (FLAGS RLANDBIT)
+      (WEST TO STAIRS-BOTTOM)
+      (DOWN TO STAIRS-BOTTOM)
+      (SOUTH TO SECRET-PASSAGE)
+      (UP TO SECRET-PASSAGE)
+      (GLOBAL PICTURES STAIRS)>
+      
+
+<ROOM STAIRS-BOTTOM 
+      (IN ROOMS)
+      (DESC "Bottom of Stairs")
+      (LDESC
+"You are at the bottom of the sixteen-step stairway. The stairway goes up to
+the east, while to the west is solid plaster. Painted on the plaster
+are some hieroglyphs.") 
+       (FLAGS RLANDBIT)
+       (WEST TO EAST-END-OF-PASSAGE IF PLASTER-GONE ELSE
+"Solid plaster is blocking your way.")
+       (EAST TO TOP-OF-STAIRS)
+       (UP TO TOP-OF-STAIRS)
+       (GLOBAL HIEROGLYPHS STAIRS DOORWAY)>
+
+<ROOM EAST-END-OF-PASSAGE
+      (IN ROOMS)
+      (DESC "Narrow Passageway")
+      (LDESC 
+"You are at the east end of what seems like a long, straight passageway. After
+carefully looking over the walls, stones and floor, you determine that it is
+safe to proceed.")
+      (EAST TO STAIRS-BOTTOM)
+      (WEST TO MID-PASSAGE)
+      (FLAGS RLANDBIT)>
+
+<ROOM MID-PASSAGE
+      (IN ROOMS)
+      (DESC "Narrow Passageway")
+      (LDESC
+"You are in the middle of a long, east/west passage. The passage is narrow and
+seems to be little more than a hallway hewn out of stone.")
+      (FLAGS RLANDBIT)
+      (WEST TO WEST-END-OF-PASSAGE)
+      (EAST TO EAST-END-OF-PASSAGE)>
+
+<ROOM WEST-END-OF-PASSAGE
+      (IN ROOMS)
+      (DESC "Narrow Passageway")
+      (LDESC 
+"You have reached the west end of the passage. Before you is a door surrounded
+by a heavy timber frame. The door is entirely blocked up with plaster. Toward
+the bottom of the north wall and the south wall, about three inches off the
+floor, are two small niches. There are some hieroglyphs on the plaster.")
+      (FLAGS RLANDBIT)
+      (EAST TO MID-PASSAGE)
+      (WEST PER JERRY-HACK-F)
+      (GLOBAL DOORWAY HIEROGLYPHS PIT)
+      (ACTION MOVE-PLANK-FCN)>
+
+<ROUTINE JERRY-HACK-F ()
+	 <COND (<FSET? ,INNER-DOOR ,OPENBIT>
+		<RETURN ,MID-ANTECHAMBER>)
+	       (T
+		<TELL "You can't walk through a closed door." CR>
+		<THIS-IS-IT ,INNER-DOOR>
+		<RFALSE>)>>
+
+<OBJECT NICHES
+	(IN WEST-END-OF-PASSAGE)
+	(FLAGS NDESCBIT DONTTAKE CONTBIT OPENBIT)
+	(DESC "small niche")
+	(TEXT
+"Each small niche rests about three inches off the floor. They are recessed
+into the walls, one on either side of the passageway.")
+	(SYNONYM NICHE NICHES)
+	(ADJECTIVE SMALL)
+	(CAPACITY 1)
+	(ACTION NICHE-F)>
+
+<ROUTINE NICHE-F ()
+	 <COND (<VERB? EXAMINE LOOK-INSIDE>
+		<TELL <GETP ,NICHES ,P?TEXT>>
+		<COND (<EQUAL? ,BEAM-PLACED 1>
+		       <TELL " Resting in the niches is the wooden beam.">)>
+		<CRLF>
+		<RTRUE>)
+	       (<VERB? OPEN CLOSE>
+		<HOW? ,PRSO>)>>
+
+<OBJECT PLASTER1
+	(IN STAIRS-BOTTOM)
+	(FLAGS NDESCBIT TAKEBIT TRYTAKEBIT DONTTAKE)
+	(DESC "plaster")
+	(SYNONYM PLASTE)
+	(SIZE 5)
+	(TEXT
+"Some hieroglyphics on the plaster say:|
+|
+   *->  #  !!!  ::  ...>  .-")
+	(ACTION PLASTER1-FCN)>
+
+<ROUTINE PLASTER1-FCN ()
+	 <COND (<VERB? TAKE MUNG ATTACK>
+		<COND (<NOT ,PRSI>
+		       <COND (<IN? ,PICK-AXE ,WINNER>
+			      <SETG PRSI ,PICK-AXE>)
+			     (<IN? ,SHOVEL ,WINNER>
+			      <SETG PRSI ,SHOVEL>)
+			     (ELSE
+			      <SETG PRSI ,HANDS>)>
+		       <TELL "(with your " D ,PRSI ")" CR>)>
+		<COND (<PRSI? ,PICK-AXE>
+		       <REMOVE ,PLASTER1>
+		       <SETG P-IT-LOC <>>
+		       <MOVE ,PLASTER ,WEST-END-OF-PASSAGE>
+		       <SETG SCORE <+ ,SCORE 10>>
+		       <TELL
+"The chips fly where they may as you relentlessly flail at the plaster with
+your trusty pick axe. In just a few minutes you manage to clear all the
+plaster from the doorway." CR>
+		       <SETG PLASTER-GONE T>
+		       <PUTP ,STAIRS-BOTTOM ,P?LDESC
+"You are at the bottom of the sixteen-step stairway. The stairway goes up to
+the east, while the way to the west has been cleared.">
+		       <MOVE ,CHIPS1 ,HERE>
+		       <RTRUE>)
+		      (T <TELL
+"You scratch at the plaster but accomplish little."
+                          CR>)>)>>
+
+<OBJECT INNER-DOOR
+	(IN WEST-END-OF-PASSAGE)
+	(FLAGS NDESCBIT DOORBIT VOWELBIT DONTTAKE)
+	(SYNONYM DOOR)
+	(ADJECTIVE INNER)
+	(DESC "inner door")
+	(ACTION INNER-DOOR-FCN)>
+
+<ROUTINE INNER-DOOR-FCN ()
+	 <COND (<AND <VERB? EXAMINE LOOK-INSIDE>
+		     <IN? ,PLASTER ,HERE>>
+		<TELL 
+"The door is surrounded by a heavy timber frame and is entirely blocked up
+with plaster. There are some hieroglyphs on the plaster." CR>
+		<RTRUE>)
+	       (<VERB? OPEN>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <TELL "It's already open." CR>
+		       <RTRUE>)
+		      (,INNER-DOOR-SEALED
+		       <TELL "The door is covered with plaster, which is in turn covered with hieroglyphs." CR>)
+		      (T
+		       <TELL
+"The door opens and you are overwhelmed by a musky odor." CR>
+		       <FSET ,INNER-DOOR ,OPENBIT>
+		       <RTRUE>)>)
+	       (<VERB? CLOSE>
+		<COND (<NOT <FSET? ,INNER-DOOR ,OPENBIT>>
+		       <TELL "It isn't open." CR>)
+		      (T <TELL
+"Okay. The door is closed." CR>
+		       <FCLEAR ,INNER-DOOR ,OPENBIT>)>)>>
+
+<OBJECT PLASTER
+	(FLAGS NDESCBIT TAKEBIT DONTTAKE TRYTAKEBIT)
+	(SYNONYM PLASTE)
+	(DESC "plaster")
+	(TEXT
+"The plaster is ancient, applied to the door behind it to prevent people from
+entering the resting place of the Queen. Some hieroglyphs are etched into the
+plaster.")
+	(SIZE 5)
+	(ACTION PLASTER-FCN)>
+
+<GLOBAL DEATH-BEAM-STR
+"The plaster starts to chip away beneath the incessant tapping of your pick
+axe. You quickly realize, however, that the tapping has started some sand
+flowing out of the bottom of the doorway. Just as you realize the seriousness
+of your situation, the floor gives out beneath you and you plummet down, down,
+down into a den of voracious rats...">
+
+<ROUTINE PLASTER-FCN ("AUX" (FLG <>))
+	 <COND (<VERB? TAKE MUNG ATTACK>
+		<COND (<NOT ,PRSI>
+		       <SET FLG T>
+		       <COND (<IN? ,PICK-AXE ,WINNER>
+			      <SETG PRSI ,PICK-AXE>)
+			     (<IN? ,SHOVEL ,WINNER>
+			      <SETG PRSI ,SHOVEL>)
+			     (T
+			      <SETG PRSI ,HANDS>)>)>
+		<COND (.FLG
+		       <TELL "(with your " D ,PRSI ")" CR>)>
+		<COND (<EQUAL? ,PRSI ,PICK-AXE>
+		       <COND (<NOT ,BEAM-PLACED>
+			      <JIGS-UP ,DEATH-BEAM-STR>)
+			     (<NOT ,ON-BEAM>
+			      <TELL ,DEATH-BEAM-STR>
+			      <JIGS-UP
+			       " You wave to the beam stretching across the gap as you hurtle past it.">) 
+			     (T
+			      <TELL
+"The plaster chips fly from the door as the incessant tapping of your pick
+axe does its work. The tapping has started some sand flowing out of
+the bottom of the doorway and the floor starts to give away. In a few
+short moments, the floor has disappeared, but thankfully you're safe while
+standing on the beam." CR>
+			      <SETG INNER-DOOR-SEALED <>>
+			      <REMOVE ,PLASTER>
+			      <SETG P-IT-LOC <>>
+			      <FCLEAR ,PIT ,INVISIBLE>
+			      <DUMP-ALL-ON-GROUND>
+			      <SETG SCORE <+ ,SCORE 25>>
+			      <PUTP ,HERE ,P?LDESC
+"You are in the west end of the passage. The plaster has been cleared, allowing
+passage to the west.">
+			      <THIS-IS-IT ,INNER-DOOR>
+			      <MOVE ,CHIPS2 ,HERE>
+			      <RTRUE>)>)
+		      (T <TELL
+			  "You scratch at the plaster but accomplish little."
+			  CR>)>)>>
+
+<OBJECT NORTH-ANTE-DOOR
+	(IN LOCAL-GLOBALS)
+	(FLAGS NDESCBIT DOORBIT)
+	(SYNONYM DOOR)
+	(ADJECTIVE BURIAL)
+	(DESC "burial door")
+	(ACTION NORTH-ANTE-DOOR-FCN)>
+
+<ROUTINE NORTH-ANTE-DOOR-FCN ()
+	 <COND (<VERB? EXAMINE LOOK-INSIDE>
+		<COND (<FSET? ,BURIAL-CHAMBER ,RMUNGBIT>
+		       <TELL
+"It's buried behind 3 tons of stones. Forget it." CR>)
+		      (T <TELL 
+"The door is surrounded by small seals and has a hieroglyph on it." CR>)>)
+	       (<VERB? OPEN>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <TELL "It's already open." CR>
+		       <RTRUE>)
+		      (<FSET? ,BURIAL-CHAMBER ,RMUNGBIT>
+		       <TELL
+"With all the stones which fell in the doorway, there's not a chance of ever
+getting through again." CR>
+		       <RTRUE>)
+		      (,ANTE-SEAL
+		       <TELL
+"I don't think it's that simple. Not only isn't there a doorknob, but the door
+is also covered with a seal." CR>)
+		      (T
+		       <TELL
+"The door creaks open and you are assaulted by a deep, musty dead smell." CR>
+		       <FSET ,NORTH-ANTE-DOOR ,OPENBIT>
+		       <SETG SCORE <+ ,SCORE 40>>
+		       <RTRUE>)>)
+	       (<VERB? CLOSE>
+		<COND (<NOT <FSET? ,NORTH-ANTE-DOOR ,OPENBIT>>
+		       <TELL "It isn't open." CR>)
+		      (T <TELL
+"Closing the door isn't the best of ideas." CR>)>)
+	       (<AND <VERB? READ>
+		     <NOT <FSET? ,NORTH-ANTE-DOOR ,OPENBIT>>>
+		<PERFORM ,V?READ ,HIEROGLYPHS>
+		<RTRUE>)>>
+
+<OBJECT N-ANTE-SEAL
+	(IN NORTH-ANTECHAMBER)
+	(FLAGS NDESCBIT)
+	(DESC "seal")
+	(SYNONYM SEALS SEAL)>
+
+<OBJECT ANNEX-DOOR
+	(IN LOCAL-GLOBALS)
+	(FLAGS NDESCBIT DOORBIT VOWELBIT)
+	(SYNONYM DOOR)
+	(ADJECTIVE ANNEX)
+	(DESC "annex door")
+	(ACTION ANNEX-DOOR-FCN)>
+
+<ROUTINE ANNEX-DOOR-FCN ()
+	 <COND (<VERB? OPEN>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <TELL "It's already open." CR>
+		       <RTRUE>)
+		      (<AND ,BEAM-PLACED
+			    <IN? ,BEAM ,SOUTH-ANTECHAMBER>>
+		       <TELL
+"You open the door and two huge stones start to close in on you from either
+side. Thankfully, you had the foresight to wedge the beam in the doorway to
+prevent a flattening experience." CR>
+		       <FSET ,ANNEX-DOOR ,OPENBIT>)
+		      (ELSE
+		       <JIGS-UP
+"You open the door but before you can react, two huge stones close in on you --
+one from the left side and one from the right side. Needless to say, you didn't
+quite make it...">)>)
+	       (<AND <VERB? EXAMINE LOOK-INSIDE>
+		     <NOT <FSET? ,ANNEX-DOOR ,OPENBIT>>>
+		<TELL
+"This door seems to present no difficulty in opening. Lightly etched into it
+are some faint symbols." CR>)
+	       (<AND <VERB? READ>
+		     <NOT <FSET? ,ANNEX-DOOR ,OPENBIT>>>
+		<PERFORM ,V?READ ,HIEROGLYPHS>
+		<RTRUE>)
+	       (<AND <VERB? CLOSE>
+		     <FSET? ,ANNEX-DOOR ,OPENBIT>>
+		<TELL "Closing this door isn't a very good idea." CR>
+		<RTRUE>)>>
+
+<OBJECT ISIS
+	(IN BURIAL-CHAMBER)
+	(DESC "Isis statue")
+	(SYNONYM STATUE)
+	(ADJECTIVE ISIS)
+	(FLAGS CLAMPBIT TURNBIT NDESCBIT)
+	(ACTION TURN-STATUES-FCN)>
+
+<OBJECT NEPHTHYS
+	(IN BURIAL-CHAMBER)
+	(DESC "Nephthys statue")
+	(SYNONYM STATUE)
+	(ADJECTIVE NEPHTH)
+	(FLAGS NDESCBIT CLAMPBIT TURNBIT)
+	(ACTION TURN-STATUES-FCN)>
+
+<OBJECT NEITH
+	(IN BURIAL-CHAMBER)
+	(DESC "Neith statue")
+	(SYNONYM STATUE)
+	(ADJECTIVE NEITH)
+	(FLAGS NDESCBIT CLAMPBIT TURNBIT)
+	(ACTION TURN-STATUES-FCN)>
+
+<OBJECT SELKIS
+	(IN BURIAL-CHAMBER)
+	(DESC "Selkis statue")
+	(FLAGS NDESCBIT CLAMPBIT TURNBIT)
+	(SYNONYM STATUE)
+	(ADJECTIVE SELKIS)
+	(ACTION TURN-STATUES-FCN)>
+
+<OBJECT ARMS
+	(IN BURIAL-CHAMBER)
+	(DESC "arms")
+	(SYNONYM ARM ARMS)
+	(FLAGS NDESCBIT DONTTAKE)>
+
+<ROUTINE TURN-STATUES-FCN ("AUX" (OFFSET 0))
+	 <COND (<VERB? TURN>
+		<COND (<NOT ,CAN-TURN-STATUES>
+		       <TELL 
+"Nothing happens. These statues seem to be beyond all hope." CR>
+		       <RTRUE>)
+		      (T
+		       <TELL
+"The " D ,PRSO " moves slowly, pivoting about its base, ">
+		       <COND (<FSET? ,PRSO ,CLAMPBIT>
+			      <FCLEAR ,PRSO ,CLAMPBIT>
+			      <DO-THE-OFFSET>
+			      <TELL
+ "releasing its hold on the quartz cover." CR>)
+			     (T
+			      <FSET ,PRSO ,CLAMPBIT>
+			      <TELL
+"once more clamping down on the quartz cover." CR>)>
+		       <RTRUE>)>)>>
+		      
+<ROUTINE DO-THE-OFFSET ("AUX" (OFFSET 0))
+	 <REPEAT ()
+		 <COND (<EQUAL? .OFFSET 4>
+			<RETURN>)
+		       (T
+			<SET OFFSET <+ .OFFSET 1>>
+			<COND (<EQUAL? <GET ,TURNED-LTBL .OFFSET> ,PRSO>
+			       <RTRUE>)>)>>
+	  <SETG TURN-OFFSET <+ ,TURN-OFFSET 1>>
+	  <PUT ,TURNED-LTBL ,TURN-OFFSET ,PRSO>
+	  <COND (<EQUAL? ,TURN-OFFSET 4>
+		 <ENABLE <QUEUE I-RESET-STATUES 1>>)>>
+
+<OBJECT SARCOPH
+	(IN BURIAL-CHAMBER)
+	(DESC "sarcophagus")
+	(FLAGS CONTBIT NDESCBIT DONTTAKE)
+	(CAPACITY 1000)
+	(SIZE 500)
+	(SYNONYM SARCOP COFFIN)
+	(ACTION SARCOPH-FCN)>
+
+<ROUTINE SARCOPH-FCN ()
+	 <COND (<VERB? OPEN>
+		<PERFORM ,V?OPEN ,SARCOPH-COVER>
+		<RTRUE>)
+	       (<AND <VERB? PUT PUT-ON>
+		     <EQUAL? ,PRSI ,SARCOPH>>
+		<TELL "The " D ,PRSO " sits on the sarcophagus for a moment, but it quickly slides off its rounded top." CR>
+		<MOVE ,PRSO ,HERE>
+		<FSET ,PRSO ,TOUCHBIT>
+		<FCLEAR ,PRSO ,NDESCBIT>
+		<RTRUE>)
+	       (ELSE
+		<RFALSE>)>>
+
+<OBJECT SARCOPH-COVER
+	(IN BURIAL-CHAMBER)
+	(SIZE 150)
+	(FLAGS NDESCBIT CONTBIT SURFACEBIT OPENBIT DONTTAKE)
+	(SYNONYM COVER QUARTZ)
+	(ADJECTIVE QUARTZ)
+	(DESC "quartz cover")
+	(CAPACITY 200)
+	(ACTION SARCOPH-COVER-FCN)>
+
+<OBJECT S-AREA
+	(IN SARCOPH-COVER)
+	(FLAGS CONTBIT SURFACEBIT OPENBIT NDESCBIT DONTTAKE)
+	(DESC "smaller recess")
+	(SYNONYM RECESS AREA AREAS)
+	(ADJECTIVE SMALLE SMALL)
+	(CAPACITY 100)
+	(MAP 3)
+	(CONTFCN RECESS-CONTFCN)
+	(ACTION SETBIT-FCN)
+	(SIZE 1)>
+
+<OBJECT L-AREA
+	(IN SARCOPH-COVER)
+	(FLAGS CONTBIT SURFACEBIT OPENBIT NDESCBIT DONTTAKE)
+	(DESC "larger recess")
+	(SYNONYM RECESS AREA AREAS)
+	(ADJECTIVE LARGE LARGER)
+	(CAPACITY 100)
+	(CONTFCN RECESS-CONTFCN)
+	(ACTION SETBIT-FCN)
+	(SIZE 1)
+	(MAP 4)>
+
+<ROUTINE SETBIT-FCN ("AUX" OBJ)
+	 <COND (<AND <VERB? PUT PUT-ON>
+		     <PRSI? ,L-AREA ,S-AREA>
+		     <FIRST? ,PRSI>>
+		<TELL "There's already something on it." CR>
+		<RTRUE>)
+	       (<AND <VERB? PUT PUT-ON>
+		     <PRSI? ,L-AREA ,S-AREA>
+		     <EQUAL? ,PRSO ,BEAM>>
+		<TELL
+"I don't think the beam would fit in there. It's a little too long." CR>
+		<RTRUE>)
+	       (<AND <VERB? PUT PUT-ON>
+		     <PRSI? ,L-AREA ,S-AREA>>
+		<FSET ,PRSO ,NDESCBIT>
+		<RFALSE>)
+	       (<VERB? OPEN CLOSE>
+		<HOW? ,PRSO>
+		<RTRUE>)
+	       (<VERB? EXAMINE LOOK-INSIDE>
+		<TELL 
+"The area is recessed about an inch below the quartz cover."
+CR>
+		<COND (<SET OBJ <FIRST? ,PRSO>>
+		       <TELL "Sitting in the " D ,PRSO " is a">
+		       <VOWEL? .OBJ>
+		       <TELL D .OBJ "." CR>)
+		      (T
+		       <TELL "The " D ,PRSO " is empty." CR>)>
+		<RTRUE>)>>
+
+<ROUTINE RECESS-CONTFCN ()
+	 <COND (<AND <VERB? TAKE>
+		     <EQUAL? <LOC ,PRSO> ,S-AREA ,L-AREA>>
+		<FCLEAR ,PRSO ,NDESCBIT>
+		<RFALSE>)>>
+
+<ROUTINE DESCRIBE-COVER ("AUX" S-OBJ L-OBJ)
+	 <TELL 
+"There is a small recess and a large recess on the top of the cover which you
+can make out as thin, outlined areas.">
+	 <SET S-OBJ <FIRST? ,S-AREA>>
+	 <SET L-OBJ <FIRST? ,L-AREA>>
+	 <COND (.S-OBJ
+		<TELL " Resting in the smaller recess is a">
+		<VOWEL? .S-OBJ>
+		<TELL D .S-OBJ ".">)>
+	 <COND (.L-OBJ
+		<TELL " Sitting in the larger recess is the " D .L-OBJ ".">)>>
+
+<ROUTINE SARCOPH-COVER-FCN ("AUX" STR (COUNTER 0) (OFFS -1))
+	 <COND (<VERB? EXAMINE LOOK-INSIDE>
+		<DESCRIBE-COVER>
+		<CRLF>
+		<RTRUE>)
+	       (<AND <VERB? PUT PUT-ON>
+		     <PRSI? ,SARCOPH-COVER>>
+		<TELL "You place the " D ,PRSO " on the cover, but it slides
+right off onto the ground." CR>
+		<MOVE ,PRSO ,HERE>
+		<FSET ,PRSO ,TOUCHBIT>
+		<FCLEAR ,PRSO ,NDESCBIT>
+		<RTRUE>)
+	       (<AND <VERB? OPEN MOVE>
+		     <NOT ,STATUES-SET>>
+		<SET STR "a single statue.">
+		<REPEAT ()
+			<SET OFFS <+ .OFFS 1>>
+			<COND (<G? .OFFS 3>
+			       <RETURN>)
+			      (<FSET? <GET ,STATUE-TBL .OFFS> ,CLAMPBIT>
+			       <SET COUNTER <+ .COUNTER 1>>)>>
+		<COND (<G? .COUNTER 1>
+		       <SET STR "the statues.">)>
+		<TELL
+"You tug, push, pull, yank and generally tire yourself out trying to open the
+cover until you take a moment, wipe your brow, and look around. You notice that
+the cover is being held in place by " .STR CR>
+		<RTRUE>)
+	       (<AND <VERB? OPEN MOVE>
+		     ,STATUES-SET>
+		<ENDING>
+		<CRLF>
+		<FINISH>)>>
+
+<GLOBAL SCARAB-DEATH-STR
+"As soon as you lift the scarab from the disc, the left and right discs rise
+far enough above the surface of the table to activate a mechanism. You hear it
+click just before the ceiling comes down to meet the floor.">
+
+<ROUTINE SCARAB-CHECK-FCN ("AUX" L-W R-W (L-OBJ <>) (R-OBJ <>))
+	 <COND (<VERB? TAKE>
+		<SETG CAN-TURN-STATUES <>>
+		<SET L-OBJ <FIRST? ,LEFT-DISC>>
+		<SET R-OBJ <FIRST? ,RIGHT-DISC>>
+		<COND (<IN? ,SCARAB ,MID-DISC>
+		       <COND (<OR <NOT .L-OBJ>
+				  <NOT .R-OBJ>>
+			      <JIGS-UP ,SCARAB-DEATH-STR>
+			      <RFATAL>)
+			     (T
+			      <SET L-W <WEIGHT .L-OBJ>>
+			      <SET R-W <WEIGHT .R-OBJ>>
+			      <COND (<AND <EQUAL? .L-W 8>
+					  <EQUAL? .R-W 8>>
+				     <RFALSE>)
+				    (T
+				     <JIGS-UP ,SCARAB-DEATH-STR>)>)>)
+		      (T
+		       <RFALSE>)>)
+	       (<AND <VERB? PUT PUT-ON>
+		     <IN? ,SCARAB ,MID-DISC>>
+		<PERFORM ,V?TAKE ,PRSO>
+		<RTRUE>)
+	       (<AND <VERB? PUT PUT-ON>
+		     <PRSI? ,S-AREA ,L-AREA>
+		     <FIRST? ,PRSI>>
+		<TELL "There's already something on it." CR>
+		<RTRUE>)
+	       (<VERB? MOVE>
+		<TELL
+"You'd better not. Not until you know what's going on here." CR>
+		<RTRUE>)
+	       (<AND <VERB? PUT PUT-ON>
+		     <PRSI? ,S-AREA>>
+		<MOVE ,SCARAB ,S-AREA>
+		<TELL "Done." CR>
+		<FSET ,SCARAB ,NDESCBIT>
+		<COND (<IN? ,DEAD-BOOK ,L-AREA>
+		       <SETG CAN-TURN-STATUES T>
+		       <TELL
+"You hear a clicking sound come from beneath all of the statues as you place
+the scarab within the smaller outlined area on the cover." CR>)>
+		<RTRUE>)>>
+ 
+<OBJECT SCARAB
+	(IN MID-DISC)
+	(FLAGS TAKEBIT TRYTAKEBIT READBIT)
+	(DESC "scarab")
+	(VALUE 10)
+	(SYNONYM SCARAB)
+	(TEXT
+"Etched onto its back is the following:|
+|
+              >*>")
+	(SIZE 8)
+	(MAP 3)
+	(ACTION SCARAB-CHECK-FCN)>
+	
+<OBJECT DEAD-BOOK
+	(FLAGS READBIT CONTBIT TAKEBIT VOWELBIT)
+	(DESC "ancient book")
+	(SYNONYM BOOK)
+	(ADJECTIVE ANCIEN)
+	(ACTION DEAD-BOOK-FCN)
+	(SIZE 5)
+	(MAP 4)
+	(CAPACITY 1)
+	(VALUE 10)>
+
+<OBJECT PAGE
+	(IN DEAD-BOOK)
+	(DESC "page")
+	(SYNONYM PAGE)
+	(FLAGS NDESCBIT READBIT BURNBIT TURNBIT DONTTAKE TRYTAKEBIT)
+	(ACTION PAGE-FCN)
+	(SIZE 1)
+	(TEXT
+"Hieroglyphs can be seen as follows:|
+|
+        =  .           !   !|
+<-*  #  =  -  #  !@!  !---!|
+|
+            .           !  !|
+::  #  >*>  -  #  !@!  !--!")>
+
+<ROUTINE PAGE-FCN ()
+	 <COND (<VERB? TURN>
+		<TELL "Unnecessary page turning may destroy the book." CR>
+		<RTRUE>)
+	       (<VERB? BURN>
+		<PERFORM ,V?BURN ,DEAD-BOOK>)
+	       >>
+
+<OBJECT CRUMBLED-BOOK
+	(FLAGS INVISIBLE BURNBIT TAKEBIT CONTBIT READBIT VOWELBIT OPENBIT)
+	(DESC "ancient book")
+	(SYNONYM BOOK DEAD)
+	(SIZE 5)
+	(TEXT
+"This is what is left of the ancient Book of the Dead. Like the Queen it once
+referred to, it too has seen better days.")
+	(VALUE -20)
+	(MAP 4)>
+
+<ROUTINE DEAD-BOOK-FCN ()
+	 <COND (<VERB? TAKE>
+		<FCLEAR ,DEAD-BOOK ,NDESCBIT>
+		<SETG CAN-TURN-STATUES <>>
+		<RFALSE>)
+	       (<AND <VERB? PUT>
+		     <PRSI? ,DEAD-BOOK ,CRUMBLED-BOOK>>
+		<TELL "You'd do more damage putting things on the " D ,PRSI 
+		      " than it would be worth." CR>
+		<RTRUE>)
+	       (<VERB? READ EXAMINE>
+		<COND (<NOT <FSET? ,DEAD-BOOK ,OPENBIT>>
+		       <TELL 
+"The book isn't open. On the cover is the following, though:|
+|
+       =|
+       =" CR>)
+		      (T
+		       <PERFORM ,V?READ ,PAGE>)>
+		<RTRUE>)
+	       (<VERB? OPEN>
+		<COND (<AND ,PRSI
+			    <PRSI? ,SPATULA>>
+		       <TELL
+"You open the book carefully using the spatula. You can see some faint
+writing on the page." CR>
+		       <FSET ,PRSO ,OPENBIT>
+		       <RTRUE>)
+		      (T
+		       <TELL 
+"Oops! The ancient papyrus pages crumble due to your less-than-delicate touch." CR>
+		       <MOVE ,CRUMBLED-BOOK <LOC ,DEAD-BOOK>>
+		       <REMOVE ,DEAD-BOOK>
+		       <THIS-IS-IT ,CRUMBLED-BOOK>
+		       <FCLEAR ,CRUMBLED-BOOK ,INVISIBLE>
+		       <RTRUE>)>)
+	       (<AND <VERB? READ>
+		     <FSET? ,DEAD-BOOK ,OPENBIT>>
+		<PERFORM ,V?READ ,PAGE>
+		<RTRUE>)
+	       (<AND <VERB? PUT PUT-ON>
+		     <PRSI? ,S-AREA ,L-AREA>
+		     <FIRST? ,PRSI>>
+		<TELL "There's already something on it." CR>
+		<RTRUE>)
+	       (<AND <VERB? PUT PUT-ON>
+		     <PRSI? ,L-AREA>>
+		<MOVE ,DEAD-BOOK ,L-AREA>
+		<FSET ,DEAD-BOOK ,NDESCBIT>
+		<TELL
+"The book now rests in the larger area on the cover of the sarcophagus." CR>
+		<COND (<IN? ,SCARAB ,S-AREA>
+		       <SETG CAN-TURN-STATUES T>
+		       <TELL
+"From beneath each of the four statues there comes a loud click." CR>)>
+		<RTRUE>)>>
+	
+
+<OBJECT SPATULA
+	(FLAGS TAKEBIT TOOLBIT TOUCHBIT)
+	(DESC "small spatula")
+	(SYNONYM SPATUL)
+	(ADJECTIVE SMALL)
+	(TEXT
+"This spatula was originally used for opening books and turning their pages.")>
+
+<ROUTINE ENDING ()
+	 <TELL
+"You lift the cover with great care, and in an instant you see all your dreams
+come true. The interior of the sarcophagus is lined with gold, inset with
+jewels, glistening in your torchlight. The riches and their dazzling beauty
+overwhelm you. You take a deep breath, amazed that all of this is yours. You
+tremble with excitement, then realize the ground beneath your feet is
+trembling, too.|
+|
+As a knife cuts through butter, this realization cuts through your mind,
+makes your hands shake and cold sweat appear on your forehead. The Burial
+Chamber is collapsing, the walls closing in. You will never get out of this
+pyramid alive. You earned this treasure. But it cost you your life.|
+|
+And as you sit there, gazing into the glistening wealth of the inner
+sarcophagus, you can't help but feel a little empty, a little foolish.
+If someone were on the other side of the quickly-collapsing wall, they could
+have dug you out. If only you'd treated the workers better. If only you'd cut
+Craige in on the find. If only you'd hired a reliable guide.|
+|
+Well, someday, someone will discover your bones here. And then you
+will get your fame." CR>>
+
+<ROUTINE DUMP-ALL-ON-GROUND ("AUX" L LOCB N F (FLG <>))
+	 <SET L <LOC ,WINNER>>
+	 <REMOVE ,WINNER>
+	 <REMOVE ,INNER-DOOR>
+	 <REMOVE ,NICHES>
+	 <REMOVE ,LINTEL>
+	 <COND (,BEAM-PLACED
+		<SET LOCB <LOC ,BEAM>>
+		<REMOVE ,BEAM>)>
+	 <SET F <FIRST? ,HERE>>
+	 <REPEAT ()
+		 <COND (<NOT .F>
+			<RETURN>)
+		       (T
+			<SET N .F>
+			<SET F <NEXT? .N>>
+			<REMOVE .N>
+			<SET FLG T>)>>
+	 <COND (.FLG
+		<TELL CR "Everything on the floor falls into the pit." CR>)>
+	 <MOVE ,WINNER .L>
+	 <COND (.LOCB
+		<MOVE ,BEAM .LOCB>)>
+	 <MOVE ,INNER-DOOR ,WEST-END-OF-PASSAGE>
+	 <MOVE ,NICHES ,WEST-END-OF-PASSAGE>
+	 <MOVE ,LINTEL ,WEST-END-OF-PASSAGE>>
+
diff --git a/barge.zil b/barge.zil
new file mode 100644
index 0000000..b0122a1
--- /dev/null
+++ b/barge.zil
@@ -0,0 +1,674 @@
+"BARGE for
+			      INFIDEL
+	(c) Copyright 1983 Infocom, Inc.  All Rights Reserved.
+"
+
+<ROOM LANDING-TWO
+      (IN ROOMS)
+      (DESC "South Landing")
+      (FLAGS RLANDBIT)
+      (LDESC
+"You are on a landing in the middle of a set of stairs. The staircase goes down
+to the south and up to the north. The walls here are undistinguished, formed by
+the stones of which the pyramid was built.")
+      (UP TO CHAMBER-OF-RA)
+      (NORTH TO CHAMBER-OF-RA)
+      (DOWN TO NARROW-HALL)
+      (SOUTH TO NARROW-HALL)
+      (GLOBAL SOUTH-STAIRS)
+      (ACTION MOVE-ROPE-HERE)>
+
+<ROOM NARROW-HALL
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Narrow Hallway")
+      (LDESC
+"You are at the entrance of a narrow hallway which goes to the northeast. A
+staircase goes up to the north.")
+      (UP TO LANDING-TWO)
+      (NE TO BEND-HALL)
+      (NORTH TO LANDING-TWO)>
+
+<ROOM BEND-HALL
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Narrow Hallway")
+      (LDESC
+"You are at a bend in the Narrow Hallway. The hallway continues to the
+northwest and to the southwest. Inscribed on the wall are some hieroglyphs.")
+      (NW TO BARGE-ENTRANCE)
+      (SW TO NARROW-HALL)
+      (GLOBAL HIEROGLYPHS)> 
+      
+<ROOM BARGE-ENTRANCE
+      (IN ROOMS)
+      (DESC "Barge Chamber")
+      (FLAGS RLANDBIT)
+      (LDESC
+"You are in the southern section of a huge room which holds the royal barge.
+Before you, to the north, is a plank which provides entrance to the barge.
+There is room to move around the barge to the east and west, while a doorway
+to the southeast leads into a darkened corridor.")
+      (UP TO BARGE-CENTER)
+      (NORTH TO BARGE-CENTER)
+      (WEST TO SW-CORNER)
+      (EAST TO SE-CORNER)
+      (SE TO BEND-HALL)
+      (GLOBAL BOAT)
+      (ACTION MOVE-THE-PLANK-FCN)>
+
+<ROUTINE MOVE-THE-PLANK-FCN (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<COND (<OR <NOT <FSET? ,PLANK ,TOUCHBIT>>
+			   <IN? ,PLANK ,BARGE-CENTER>> 
+		       <MOVE ,PLANK ,HERE>)>
+		<RFALSE>)>>
+
+<ROOM SE-CORNER
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Barge Chamber")
+      (LDESC
+"You are in the southeast corner of the Barge Chamber. There's enough room to
+bypass the stern of the barge and continue to the north. To the west you can
+see the entrance to the barge.")
+      (WEST TO BARGE-ENTRANCE)
+      (NORTH TO NE-CORNER)
+      (GLOBAL BOAT)>
+
+<ROOM NE-CORNER
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Barge Chamber")
+      (LDESC
+"You're standing in the northeast corner of the Barge Chamber. You can get
+around the stern of the barge to the south, while there's enough room to
+continue around the barge to the west.")
+      (WEST TO BARGE-EXIT)
+      (SOUTH TO SE-CORNER)
+      (GLOBAL BOAT)>
+
+<ROOM SW-CORNER
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Barge Chamber")
+      (LDESC
+"You're in the southwest corner of the Barge Chamber. You can still see the
+barge entrance to the east, while there's enough room to continue to the north,
+around the barge.")
+      (NORTH TO NW-CORNER)
+      (EAST TO BARGE-ENTRANCE)
+      (GLOBAL BOAT)>
+
+<ROOM NW-CORNER
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Barge Chamber")
+      (LDESC
+"You're in the northwest corner of the Barge Chamber. You can see by your light
+that there's room enough to continue around the back of the barge by going to
+the east, while you can bypass the bow of the boat by going south.")
+      (SOUTH TO SW-CORNER)
+      (EAST TO BARGE-EXIT)
+      (GLOBAL BOAT)>
+
+<ROOM BARGE-EXIT
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Barge Chamber")
+      (LDESC
+"You're at the start of a hallway which goes off to the north. To the south,
+directly behind you, is the back side of the barge. There's enough room to get
+around it to the east and west.")
+      (EAST TO NE-CORNER)
+      (WEST TO NW-CORNER)
+      (NORTH TO IN-THE-HALL)
+      (GLOBAL BOAT)> 
+
+;"These rooms are actually part of the barge itself."
+<ROOM BARGE-CENTER
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Center of Barge")
+      (LDESC
+"You are standing on the deck of an ancient wooden barge. Before you, cut into
+the deck, is a hole. To the south is a plank which leads down off the barge.
+You can see two cabins on the deck, one to the west and the other to the east.")
+      (WEST TO FORE-CABIN)
+      (EAST TO AFT-CABIN)
+      (DOWN TO BARGE-ENTRANCE)
+      (SOUTH TO BARGE-ENTRANCE)
+      (GLOBAL HOLE BOAT DECK)
+      (ACTION BURN-THE-BARGE)>
+
+<ROOM FORE-CABIN
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (EAST TO BARGE-CENTER)
+      (DESC "Fore Cabin")
+      (LDESC
+"You are in the forward cabin aboard the barge. The cabin is bare with none of
+the luxuries you expected to see. You close your eyes for a moment, picturing
+the barge you'll someday own, the yacht fully rigged and crewed. You open your
+eyes and shake your head, anxious to make your dream reality. There's a doorway
+to the east leading out onto the deck.")
+      (GLOBAL BOAT DECK)
+      (ACTION BURN-THE-BARGE)>
+
+<ROOM AFT-CABIN
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Aft Cabin")
+      (LDESC
+"You are in the aft cabin aboard the barge. There's a door to the west which
+leads out to the deck, and a short ladder, permanently mounted to the deck,
+going down into the depths of the barge itself.")
+      (WEST TO BARGE-CENTER)
+      (DOWN TO BELOW-DECK)
+      (GLOBAL STAIRS BOAT DECK)
+      (ACTION BURN-THE-BARGE)>
+
+<ROOM BELOW-DECK
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Below Deck")
+      (LDESC
+"You are below the deck of the barge in what looks like a huge hold. To the
+west you can see the hold continuing, while a ladder leads up and out from
+here.")
+      (UP TO AFT-CABIN)
+      (OUT TO AFT-CABIN)
+      (WEST TO BELOW-MAST)
+      (ACTION BURN-THE-BARGE)
+      (GLOBAL BOAT STAIRS DECK)>
+
+<ROOM BELOW-MAST
+      (IN ROOMS)
+      (DESC "West End of Hold")
+      (FLAGS RLANDBIT)
+      (LDESC
+"You are in the westmost portion of the hold, below the deck of the barge.
+On the north side of the hull is a small knothole about three feet off the
+deck. Overhead you can see a hole going through the deck while, directly
+below this hole, on the deck by your feet, is a slot.")
+      (ACTION BURN-THE-BARGE)
+      (EAST TO BELOW-DECK)
+      (GLOBAL BOAT HOLE DECK)> 
+
+<GLOBAL PUSHED-BEAM <>>
+
+<OBJECT PLANK
+	(IN BARGE-CENTER)
+	(SYNONYM LADDER PLANK)
+	(DESC "plank")
+	(FDESC
+"A long wooden plank connects the barge and the entry area.")
+	(FLAGS NDESCBIT CLIMBBIT DONTTAKE TRYTAKEBIT)
+	(ACTION PLANK-FCN)>
+
+<ROUTINE PLANK-FCN ()
+	 <COND (<VERB? TAKE MOVE>
+		<TELL
+"The plank is a permanent part of the barge. To remove it might create far more
+destruction than you think." CR>
+		<RTRUE>)>>
+
+<GLOBAL BARGE-BURN-STR
+"The barge immediately catches fire in a tremendous flash and, before you know
+it, you're heated to a toasty 1000 degrees. Not being made of asbestos has its
+disadvantages, as you quickly realize....">
+
+<ROUTINE BURN-THE-BARGE (RARG)
+	 <COND (<EQUAL? .RARG ,M-END>
+		<COND (<AND <VERB? DROP THROW>
+			    <FLAMING? ,PRSO>>
+		       <JIGS-UP ,BARGE-BURN-STR>
+		       <RFATAL>)
+		      (<AND <VERB? PUT>
+			    <FLAMING? ,PRSO>
+			    <EQUAL? <LOC ,PRSI> ,HERE>
+			    <NOT <EQUAL? ,PRSI ,TORCH-HOLDER>>>
+		       <JIGS-UP ,BARGE-BURN-STR>
+		       <RFATAL>)>)
+	       (<AND <EQUAL? .RARG ,M-ENTER>
+		     <EQUAL? ,HERE ,BELOW-MAST>>
+		<MOVE ,MAST-HOLE ,HERE>
+		<COND (<NOT <FSET? ,BEAM ,TOUCHBIT>>
+		       <PUTP ,BEAM ,P?FDESC
+"Coming down through the hole above your head and ending in the slot at your
+feet is the beam which served as a mast.">
+		       <COND (<NOT ,PUSHED-BEAM>
+			      <MOVE ,BEAM ,SLOT>)>)>
+		<RFALSE>)
+	       (<AND <EQUAL? .RARG ,M-ENTER>
+		     <EQUAL? ,HERE ,BARGE-CENTER>>
+		<COND (<OR <NOT <FSET? ,PLANK ,TOUCHBIT>>
+			   <IN? ,PLANK ,BARGE-ENTRANCE>> 
+		       <MOVE ,PLANK ,HERE>)>
+		<MOVE ,MAST-HOLE ,HERE>
+		<COND (<AND ,PUSHED-BEAM
+			    <NOT <FSET? ,BEAM ,TOUCHBIT>>>
+		       <PUTP ,BEAM ,P?FDESC
+"Lying on the deck of the barge is a long wooden beam.">)>
+		<COND (<NOT ,PUSHED-BEAM>
+		       <MOVE ,BEAM ,HERE>
+		       <PUTP ,BEAM ,P?FDESC
+"Before you, running down through a hole in the deck, is a sturdy beam made of
+wood. Although only a few feet of it rise above the deck, it was probably used
+at one time as a mast.">)>)>>
+			   
+<OBJECT MAST-HOLE
+	(IN BARGE-CENTER)
+	(DESC "mast hole")
+	(FLAGS NDESCBIT OPENBIT CONTBIT TRANSBIT DONTTAKE TRYTAKEBIT VEHBIT)
+	(CAPACITY 34)
+	(SYNONYM HOLE)
+	(ADJECTIVE MAST)
+	(ACTION MAST-HOLE-FCN)>
+
+<ROUTINE MAST-HOLE-FCN ()
+	 <COND (<VERB? OPEN CLOSE>
+		<HOW? ,PRSO>
+		<RTRUE>)
+	       (<VERB? CLIMB-DOWN CLIMB-UP THROUGH>
+		<COND (<NOT ,PUSHED-BEAM>
+		       <TELL "I think the mast hole is already being used." CR>)
+		      (T
+		       <TELL "You'd never squeeze through it." CR>)>
+		<RTRUE>)
+	       (<AND <VERB? EXAMINE LOOK-INSIDE>
+		     <NOT ,PUSHED-BEAM>>
+		<TELL "The mast is going through the hole." CR>
+		<RTRUE>)
+	       (<AND <VERB? PUT>
+		     <PRSI? ,MAST-HOLE>
+		     <NOT ,PUSHED-BEAM>>
+		<TELL
+"There isn't room for the " D ,PRSO " and the mast, too." CR>
+		<RTRUE>)
+	       (<AND <PRSI? ,MAST-HOLE>
+		     <VERB? PUT>>
+		<COND (<EQUAL? ,HERE ,BARGE-CENTER>
+		       <TELL "The " D ,PRSO " drops through the hole." CR>)
+		      (T
+		       <TELL "You try to reach up that high, but fail. The "
+			     D ,PRSO " falls to the deck." CR>)>
+		<MOVE ,PRSO ,BELOW-MAST>
+		<FSET ,PRSO ,TOUCHBIT>
+		<COND (<FLAMING? ,PRSO>
+		       <JIGS-UP ,BARGE-BURN-STR>)>
+		<RTRUE>)>>
+
+<OBJECT TORCH-HOLDER
+	(IN BELOW-MAST)
+	(DESC "knothole")
+	(FLAGS NDESCBIT CONTBIT TRANSBIT OPENBIT DONTTAKE TRYTAKEBIT)
+	(CAPACITY 5)
+	(ACTION TORCH-HOLDER-FCN)
+	(SYNONYM KNOTHO HOLE)
+	(ADJECTIVE KNOT)>
+
+<ROUTINE TORCH-HOLDER-FCN ("AUX" FROB)
+	 <COND (<VERB? OPEN CLOSE>
+		<HOW? ,TORCH-HOLDER>)
+	       (<VERB? EXAMINE LOOK-INSIDE>
+		<COND (<SET FROB <FIRST? ,PRSO>>
+		       <TELL "All I can see is a " D .FROB " in there." CR>)
+		      (T
+		       <TELL "Through the knothole is inky blackness." CR>)>)>>
+
+<OBJECT SLOT
+	(IN BELOW-MAST)
+	(FLAGS NDESCBIT CONTBIT OPENBIT DONTTAKE TRYTAKEBIT)
+	(CAPACITY 9)
+	(DESC "slot")
+	(SYNONYM SLOT)
+	(ADJECTIVE SMALL)
+	(ACTION SLOT-FCN)>
+
+<ROUTINE SLOT-FCN ()
+	 <COND (<VERB? EXAMINE LOOK-INSIDE>
+		<COND (<AND <IN? ,BEAM ,SLOT>
+			    <FSET? ,SHIM ,NDESCBIT>>
+		       <TELL
+"A shim is wedged between the slot and the beam." CR>
+		       <RTRUE>)
+		      (<IN? ,BEAM ,SLOT>
+		       <TELL "The beam is resting in the slot." CR>
+		       <RTRUE>)
+		      (ELSE
+		       <RFALSE>)>)
+	       (<VERB? OPEN CLOSE>
+		<HOW? ,SLOT>)>>
+
+<OBJECT SHIM
+	(IN BELOW-MAST)
+	(FLAGS TAKEBIT DONTTAKE NDESCBIT BURNBIT TRYTAKEBIT)
+	(DESC "shim")
+	(SIZE 4)
+	(SYNONYM SHIM WEDGE)
+	(ADJECTIVE WOOD)
+	(TEXT
+"It's a small piece of wood, used as a wedge.")
+	(ACTION SHIM-FCN)>
+
+<ROUTINE SHIM-FCN ()
+	 <COND (<AND <VERB? TAKE>
+		     <FSET? ,SHIM ,NDESCBIT>>
+		<COND (<ITAKE>
+		       <TELL "Taken." CR>
+		       <FCLEAR ,SHIM ,NDESCBIT>
+		       <FCLEAR ,SHIM ,DONTTAKE>)>
+		<RTRUE>)>>
+
+<OBJECT BEAM
+	(IN BARGE-CENTER)
+	(FLAGS BURNBIT TAKEBIT VEHBIT TRYTAKEBIT SURFACEBIT CONTBIT OPENBIT)
+	(DESC "wooden beam")
+	(FDESC
+"Before you, running down through a hole in the deck, is a sturdy beam made of
+wood. Although only a few feet of it rise above the deck, it was probably used
+at one time as a mast.")
+	(SYNONYM BEAM MAST)
+	(ADJECTIVE WOODEN STURDY)
+	(TEXT
+"This wooden beam is made of an extremely hard wood. It's 10 feet long and has
+a diameter of 12 inches. Scratched into it is the following symbol:|
+|
+     /!\\")
+	(SIZE 10)
+	(VALUE 15)
+	(ACTION BEAM-FCN)
+	(CAPACITY 30)
+	(DESCFCN DESCRIBE-BEAM-FCN)>
+
+<GLOBAL AIR-WALK
+"Well, despite your \"angelic\" qualities, you aren't very good at walking on
+air and so, with a scream on your lips, you plunge to a horrible death in a pit
+of voracious rats.">
+
+<GLOBAL BURIAL-BEAM-STR
+"How fitting -- to be trapped forever in the Burial Chamber, waiting slowly,
+painfully, for your oxygen to run out -- a true testimony to the brilliance of
+the Queen and her protection.">
+
+<GLOBAL ANNEX-BEAM-STR
+"The doorway suddenly closes as heavy, immovable stones crush in from both
+sides. You slowly and painfully suffocate in the Annex, cursing the gods for
+ever revealing this horrible place to you. You wish you had told Craige about
+this place -- that way, it could have been he instead of you.">
+
+<ROUTINE DROP-THE-BLOCKS ()
+	 <TELL
+"When you remove the beam, you remove the only thing between you and three
+tons of solid rock, poised over your head. Knowing the situation, though, has
+saved your life: you leap out of the way just in time." CR>
+	 <SETG BEAM-PLACED <>>
+	 <MUNG-ROOM ,BURIAL-CHAMBER
+"The way into the Burial Chamber has been forever blocked by massive stones.">
+	 <REMOVE ,NORTH-ANTE-DOOR>
+	 <SETG P-IT-LOC <>>
+	 <SETG ANTE-SEAL T>
+	 <REMOVE ,N-ANTE-SEAL>>
+
+<ROUTINE CLOSE-THE-ANNEX ()
+	 <MUNG-ROOM ,ANNEX
+"The way into the Annex is forever blocked by huge, immovable stones.">
+	 <TELL
+"The doorway disappears behind two huge stones which slide horizontally from
+the doorway. Luckily, you stepped out of their way just in time." CR>
+	 <SETG BEAM-PLACED <>>
+	 <REMOVE ,ROCKS>
+	 <PUTP ,SOUTH-ANTECHAMBER ,P?LDESC
+"You are in the southern end of the Chamber of Eternal Royalty. From here you
+can see the room stretching out towards the north. The south wall is painted to
+resemble large baskets of lotus flowers with their blue petals framing an image
+of the Sun God, Amun Ra. The west wall once held a door but is now forever
+blocked.">>
+
+<ROUTINE SET-THE-BEAM (CASE)
+	 <COND (,BEAM-PLACED
+		<COND (<EQUAL? ,BEAM-PLACED .CASE>
+		       <TELL "It's already been done." CR>
+		       <RTRUE>)
+		      (<NOT <ITAKE>>
+		       <RTRUE>)
+		      (T <TELL "(taken)" CR>)>)>
+	 <TELL "Consider it done." CR>
+	 <SETG BEAM-PLACED .CASE>
+	 <DESCRIBE-BEAM-FCN ,M-OBJDESC>
+	 <MOVE ,BEAM ,HERE>
+	 <COND (<EQUAL? ,HERE ,SOUTH-ANTECHAMBER>
+		<THIS-IS-IT ,ANNEX-DOOR>)>>
+
+<ROUTINE BEAM-FCN ()
+	 <COND (<EQUAL? ,BEAM ,PRSI>
+		<COND (<VERB? PUT PUT-ON>
+		       <COND (<EQUAL? ,PRSO ,ME ,WINNER ,ADVENTURER>
+			      <TELL "Why not just stand on it?" CR>)
+			     (<HELD? ,BEAM>
+			      <TELL "Better drop the " D ,PRSI " first." CR>
+			      <RTRUE>)
+			     (<PRSO? ,BEAM>
+			      <TELL "How recursive!" CR>
+			      <RTRUE>)
+			     (T
+			      <TELL
+"Done. But the " D ,PRSO " falls off the beam and lands">
+			      <COND (<AND <NOT <FSET? ,PIT ,INVISIBLE>>
+					  <ROOM? ,WEST-END-OF-PASSAGE
+						 ,MID-ANTECHAMBER>
+					  ,BEAM-PLACED>
+				     <TELL " in the pit." CR>
+				     <REMOVE ,PRSO>)
+				    (T <TELL " on the ground." CR>
+				     <MOVE ,PRSO ,HERE>
+				     <RTRUE>)>)>)>)
+	       (<VERB? TAKE>
+		<COND (<AND <EQUAL? ,HERE ,NORTH-ANTECHAMBER>
+			    <FSET? ,NORTH-ANTE-DOOR ,OPENBIT>
+			    <ITAKE>>
+		       <DROP-THE-BLOCKS>
+		       <RTRUE>)
+		      (<EQUAL? ,HERE ,BURIAL-CHAMBER>
+		       <COND (<ITAKE>
+			      <TELL "Taken. Oh oh...." CR>
+			      <JIGS-UP ,BURIAL-BEAM-STR>)>)
+		      (<EQUAL? ,HERE ,ANNEX>
+		       <COND (<ITAKE>
+			      <JIGS-UP ,ANNEX-BEAM-STR>
+			      <RFATAL>)>)
+		      (<AND <EQUAL? ,HERE ,SOUTH-ANTECHAMBER>
+			    <NOT <FSET? ,ANNEX ,RMUNGBIT>>
+			    <FSET? ,ANNEX-DOOR ,OPENBIT>>
+		       <COND (<ITAKE>
+			      <CLOSE-THE-ANNEX>)>
+		       <RTRUE>)
+		      (<AND <EQUAL? ,HERE ,BARGE-CENTER>
+			    <FSET? ,SHIM ,NDESCBIT>
+			    <IN? ,BEAM ,HERE>>
+		       <TELL
+"It seems to be securely wedged in the mast hole." CR>
+		       <RTRUE>)
+		      ;(<AND <EQUAL? ,HERE ,BARGE-CENTER>
+			    <NOT ,PUSHED-BEAM>
+			    <IN? ,BEAM ,HERE>>
+		       <TELL 
+"You can't lift it that high over your head to get it out of the deck." CR>
+		       <RTRUE>)
+		      (<AND <EQUAL? ,HERE ,BELOW-MAST>
+			    <FSET? ,SHIM ,NDESCBIT>
+			    <IN? ,BEAM ,SLOT>>
+		       <TELL "It's wedged into the slot." CR>
+		       <RTRUE>)
+		      (<AND <EQUAL? ,HERE ,BELOW-MAST>
+			    <IN? ,BEAM ,SLOT>>
+		       <TELL 
+"The mast hole won't allow a steep enough angle for removing it." CR>
+		       <RTRUE>)
+		      (,ON-BEAM
+		       <COND (<ITAKE>
+			      <SETG ON-BEAM <>>
+			      <TELL "(getting off the beam first)" CR "Taken."
+				    CR>
+			      <COND (<NOT <IN? ,PLASTER ,HERE>>
+				     <JIGS-UP
+"Well, you were never very good walking on air and so, with a scream on your
+lips, you plunge to a horrible death in a pit of voracious rats.">)>
+			      <SETG BEAM-PLACED <>>
+			      <RTRUE>)>)
+		      (T
+		       <SETG BEAM-PLACED <>>
+		       <RFALSE>)>)
+	       (<AND <VERB? PUT PUT-ACROSS PUT-ON PUT-AGAINST>
+		     <PRSI? ,NICHES>
+		     <EQUAL? ,HERE ,WEST-END-OF-PASSAGE>
+		     <NOT <IN? ,PIT ,HERE>>>
+		<SET-THE-BEAM 1>
+		<RTRUE>)
+	       (<AND <VERB? PUT-ON>
+		     <EQUAL? ,PRSI ,ROCKS>
+		     <EQUAL? ,HERE ,SOUTH-ANTECHAMBER>>
+		<SET-THE-BEAM 2>
+		<RTRUE>)
+	       (<AND <VERB? PUT>
+		     <EQUAL? ,PRSI ,ROCKS>
+		     <EQUAL? ,HERE ,SOUTH-ANTECHAMBER>>
+		<TELL
+"Done. The beam immediately falls to the floor, though." CR>
+		<MOVE ,BEAM ,HERE>
+		<RTRUE>)
+	       (<AND <VERB? PUT-ACROSS PUT>
+		     <EQUAL? ,PRSI ,DOORWAY ,ANNEX-DOOR>
+		     <EQUAL? ,HERE ,SOUTH-ANTECHAMBER>
+		     <IN? ,ROCKS ,HERE>>
+		<SET-THE-BEAM 3>
+		<RTRUE>)
+	       (<AND <VERB? PUT-UNDER>
+		     <EQUAL? ,PRSI ,T-LINTEL ,DOORWAY>
+		     <EQUAL? ,HERE ,NORTH-ANTECHAMBER>>
+		<SET-THE-BEAM 4>
+		<RTRUE>)
+	       (<AND <VERB? PUT-ACROSS PUT>
+		     <EQUAL? ,PRSI ,PIT>
+		     <EQUAL? ,HERE ,MID-ANTECHAMBER>>
+		<SET-THE-BEAM 5>
+		<RTRUE>)
+	       (<AND ,ON-BEAM <VERB? DISEMBARK CLIMB-DOWN>>
+		<SETG ON-BEAM <>>
+		<COND (<AND <IN? ,PLASTER ,WEST-END-OF-PASSAGE>
+			    <EQUAL? ,HERE ,WEST-END-OF-PASSAGE>>
+		       <TELL
+"You're now standing on the ground." CR>)
+		      (T
+		       <JIGS-UP ,AIR-WALK>
+		       <RTRUE>)>)
+	       (<AND <VERB? RAISE PULL-UP PUSH-THROUGH>
+		     <EQUAL? ,HERE ,BELOW-MAST ,BARGE-CENTER>
+		     <FSET? ,SHIM ,NDESCBIT>>
+		<TELL 
+"You try to raise the mast but it seems to be wedged into something." CR>
+		<RTRUE>)
+	       (<AND <VERB? PUSH-THROUGH RAISE PULL-UP>
+		     <EQUAL? ,HERE ,BELOW-MAST ,BARGE-CENTER>
+		     <NOT <FSET? ,SHIM ,NDESCBIT>>>
+		<COND (<NOT <EQUAL? <CCOUNT ,WINNER> 0>>
+		       <TELL 
+"You'll need two hands to do that. Better put everything down." CR>
+		       <RTRUE>)
+		      (ELSE
+		       <MOVE ,BEAM ,BARGE-CENTER>
+		       <SETG PUSHED-BEAM T>
+		       <PUTP ,BEAM ,P?FDESC
+"Lying on the deck of the barge is a long wooden beam.">
+		       <TELL
+"You have managed to lift the beam up through the hole and you hear it land on
+the deck with a thud." CR>)>)
+	       (<AND <VERB? PUSH-THROUGH>
+		     <EQUAL? ,PRSI ,MAST-HOLE>
+		     <EQUAL? ,HERE ,BELOW-MAST>>
+		<TELL "It's wedged too tightly in the slot." CR>
+		<RTRUE>)
+	       (<AND <VERB? PUSH>
+		     <NOT <FSET? ,BEAM ,TOUCHBIT>>>
+		<TELL "Nice try." CR>)
+	       (<VERB? MUNG>
+		<TELL 
+"This piece of wood is virtually petrified due to its age and original strength." CR>)
+	       >>
+
+<ROUTINE DESCRIBE-BEAM-FCN (RARG "AUX" STR)
+	 <COND (<OR <NOT <EQUAL? .RARG ,M-OBJDESC>>
+		    <NOT ,BEAM-PLACED>>
+		<RFALSE>)
+	       (<EQUAL? ,BEAM-PLACED 4> ;"CASE: In N. Ante, beam wedged"
+		<TELL
+"Wedged under the top of the doorway, perpendicular to the floor, is the wooden
+beam." CR>
+		<RTRUE>)
+	       (<EQUAL? ,BEAM-PLACED 5 1>
+		<COND (<EQUAL? ,HERE ,MID-ANTECHAMBER>
+		       <TELL
+"Through the doorway you can see the beam spanning the pit." CR>)
+		      (<EQUAL? ,HERE ,WEST-END-OF-PASSAGE>
+		       <TELL "Stretching across the floor">
+		       <COND (<EQUAL? ,BEAM-PLACED 1>
+			      <TELL " from niche to niche">)>
+		       <COND (<NOT ,INNER-DOOR-SEALED>
+			      <TELL ", spanning a deep pit,">)>
+		       <TELL " is the wooden beam.">
+		       <COND (,ON-BEAM
+			      <TELL " You are standing on the beam.">)>
+		       <CRLF>)>
+		<RTRUE>)
+	       (<EQUAL? ,BEAM-PLACED 2 3> ;"Case: S. Ante, wedged beam"
+		<COND (<EQUAL? ,BEAM-PLACED 2>
+		       <SET STR "rocks">)
+		      (T <SET STR "doorway">)>
+		<TELL
+"Wedged between the " .STR ", from side to side, is the stout beam." CR>
+		<RTRUE>)>>
+
+<OBJECT SCROLL
+	(IN FORE-CABIN)
+	(FLAGS TAKEBIT READBIT BURNBIT)
+	(DESC "papyrus scroll")
+	(FDESC
+"Sitting on the deck is a papyrus scroll.")
+	(SIZE 1)
+	(TEXT
+"This scroll was placed here for the Queen's passage to the afterlife.")
+	(SYNONYM SCROLL)
+	(ADJECTIVE PAPYRU)
+	(ACTION READ-SCROLL-FCN)>
+	
+<ROUTINE READ-SCROLL-FCN ()
+	 <COND (<NOT <VERB? READ>>
+		<RFALSE>)>
+	 <TELL
+"The scroll reads as follows:|
+|
+*->  <.>  <:.>  ...  <::.>|
+|
+::  :  **  --->>  -)  (*)" CR>
+	 <RTRUE>>
+
+;<ROUTINE CLEAR-THE-BEAM ("AUX" F N (FLG <>) STR)
+	 <SET F <FIRST? ,BEAM>>
+	 <REPEAT ()
+		 <COND (<NOT .F>
+			<RETURN>)
+		       (T
+			<SET N .F>
+			<SET F <NEXT? .N>>
+			<COND (<AND <EQUAL? ,HERE ,MID-ANTECHAMBER>
+				    <NOT <FSET? ,PIT ,INVISIBLE>>
+				    <EQUAL? ,BEAM-PLACED 1>>
+			       <REMOVE .N>
+			       <SET STR "into the pit">)
+			      (T
+			       <MOVE .N ,HERE>
+			       <SET STR "onto the floor">)>
+			<SET FLG T>)>>
+	 <COND (.FLG
+		<TELL "Everything on the beam falls " .STR "." CR>)>>
\ No newline at end of file
diff --git a/camp.zil b/camp.zil
new file mode 100644
index 0000000..9bd1f61
--- /dev/null
+++ b/camp.zil
@@ -0,0 +1,2323 @@
+"CAMP"
+
+<ROUTINE GET-LOST-FCN ("AUX" (OFFS -3))
+	 <COND (<NOT <GETP ,HERE ,P?ENDLESS>>
+		<RFALSE>)>
+	 <REPEAT ()
+		 <SET OFFS <+ .OFFS 3>>
+		 <COND (<G? .OFFS 54>
+			<RETURN>)
+		       (T
+			<COND (<EQUAL? ,HERE <GET ,MAP-TBL .OFFS>>
+			       <SETG SECS-LON <GET ,MAP-TBL <+ .OFFS 1>>>
+			       <SETG SECS-LAT <GET ,MAP-TBL <+ .OFFS 2>>>)>)>>
+	 <SETG DEGS-LON 32>
+	 <SETG DEGS-LAT 24>
+	 <SETG MINS-LON 12>
+	 <SETG MINS-LAT 11>
+	 <SETG DESERT-LOC <GETP ,HERE ,P?ENDLESS>>
+	 <CHANGE-DESERT-POSITION>
+	 <FCLEAR ,ENDLESS-DESERT ,TOUCHBIT>
+	 <RETURN ,ENDLESS-DESERT>>
+
+<OBJECT NASTY-CROC
+	(IN RIVER-BANK)
+	(DESC "crocodile")
+	(FLAGS NDESCBIT TOUCHBIT DONTTAKE)
+	(SYNONYM CROC CROCS CROCOD REPTIL)
+	(ACTION CROC-FCN)>
+
+<ROUTINE CROC-FCN ()
+	 <COND (<AND <EQUAL? ,PRSI ,NASTY-CROC>
+		     <VERB? THROW>>
+		<PERFORM ,V?PUT ,PRSO ,NILE-RIBBAH>
+		<RTRUE>)>> 
+
+<OBJECT NILE-RIBBAH
+	(IN RIVER-BANK)
+	(DESC "Nile")
+	(FLAGS NDESCBIT TOUCHBIT CONTBIT OPENBIT DONTTAKE)
+	(CAPACITY 1000)
+	(SYNONYM RIVER NILE)
+	(ACTION GET-WET-FCN)>
+
+<ROUTINE GET-WET-FCN ()
+	 <COND (<VERB? THROUGH>
+		<PERFORM ,V?SWIM ,NILE-RIBBAH>
+		<RTRUE>)
+	       (<VERB? DROP>
+		<PERFORM ,V?LEAVE>
+		<RTRUE>)
+	       (<VERB? LOOK-INSIDE EXAMINE>
+		<TELL "Hmmm. Looks potable. And dangerous." CR>
+		<RTRUE>)
+	       (<VERB? OPEN CLOSE>
+		<HOW? ,PRSO>
+		<RTRUE>)
+	       (<AND <PRSO? ,NILE-RIBBAH>
+		     <VERB? DRINK>>
+		<PERFORM ,V?DRINK-FROM ,PRSO>
+		<RTRUE>)
+	       (<AND <EQUAL? ,PRSI ,NILE-RIBBAH>
+		     <VERB? PUT>>
+		<COND (<EQUAL? ,PRSO ,WINNER>
+		       <PERFORM ,V?SWIM>
+		       <RFATAL>)
+		      (T
+		       <REMOVE ,PRSO>
+		       <SETG P-IT-LOC <>>
+		       <TELL "The " D ,PRSO " quickly ">
+		       <COND (<HEAVY?>
+			      <TELL "sinks">)
+			     (T <TELL "floats away on the current">)>
+		       <TELL
+". Another example of your fine management abilities." CR>
+		       <RTRUE>)>)>>
+
+<ROUTINE HEAVY? ("OPTIONAL" (OBJ <>))
+	 <COND (<NOT .OBJ>
+		<SET OBJ ,PRSO>)>
+	 <COND (<OR <EQUAL? .OBJ ,FOLDED-COT ,BROKEN-LOCK ,ROCK>
+		    <EQUAL? .OBJ ,STONE-KEY ,PICK-AXE ,SHOVEL>
+		    <EQUAL? .OBJ ,ROPE ,CRATE ,BLACK-BOX>
+		    <EQUAL? .OBJ ,TORCH ,OIL-JAR>
+		    <GETP .OBJ ,P?BRICK>>
+		<RTRUE>)
+	       (<AND <EQUAL? .OBJ ,KNAPSACK>
+		     <G? <WEIGHT ,KNAPSACK> 15>>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+		    
+<OBJECT THICKETS
+	(IN LOCAL-GLOBALS)
+	(DESC "thicket")
+	(FLAGS NDESCBIT DONTTAKE)
+	(SYNONYM THICKE)
+	(TEXT
+"They're about as yielding as you were with your helpers. What else can I say
+about them?")>
+	 
+<OBJECT FIREPIT
+	(IN FIRE)
+	(FLAGS NDESCBIT TOUCHBIT CONTBIT OPENBIT DONTTAKE TRANSBIT)
+	(DESC "pit")
+	(SYNONYM PIT)
+	(ADJECTIVE CHARRE)
+	(CAPACITY 200)
+	(ACTION FIREPIT-FCN)>
+
+<OBJECT ROCK
+	(IN FIRE)
+	(FLAGS NDESCBIT TAKEBIT)
+	(DESC "blackened rock")
+	(SYNONYM ROCK STONE)
+	(ADJECTIVE BLACKE)
+	(ACTION TAKE-ROCK-FCN)>
+
+<ROUTINE TAKE-ROCK-FCN ()
+	 <COND (<VERB? TAKE>
+		<FCLEAR ,ROCK ,NDESCBIT>
+		<PUTP ,MATCHES ,P?FDESC
+"Sitting by the firepit is a matchbook.">
+		<RFALSE>)>>
+
+<ROUTINE FIREPIT-FCN ()
+	 <COND (<VERB? OPEN CLOSE>
+		<HOW? ,PRSO>)
+	       (<VERB? THROUGH>
+		<TELL "There's no need to get yourself all dirty." CR>
+		<RTRUE>)
+	       (<VERB? EXAMINE LOOK-INSIDE>
+		<TELL "The pit's just a pit. Nothing more. ">
+		<COND (<FIRST? ,PIT>
+		       <TELL "Sitting in the pit is ">
+		       <PRINT-CONTENTS ,PIT>)
+		      (T
+		       <TELL "The pit is empty">)>
+		<TELL "." CR>
+		<RTRUE>)>>
+
+<OBJECT TENT-OBJ
+	(IN LOCAL-GLOBALS)
+	(FLAGS NDESCBIT TOUCHBIT DONTTAKE)
+	(DESC "tent")
+	(SYNONYM TENT)
+	(ADJECTIVE YOUR SUPPLY WORK)
+	(ACTION ENTER-TENT-FCN)>
+
+<ROUTINE ENTER-TENT-FCN ()
+	 <COND (<AND <VERB? DROP DISEMBARK>
+		     <PRSO? ,TENT-OBJ>
+		     <IN-A-TENT?>>
+		<PERFORM ,V?LEAVE>
+		<RTRUE>)
+	       (<VERB? EXAMINE>
+		<COND (<EQUAL? ,HERE ,P2 ,P4 ,P7>
+		       <RFALSE>)
+		      (<IN-A-TENT?>
+		       <TELL
+"Looks like a canvas tent to me." CR>
+		       <RTRUE>)
+		      (<NOT <GETP ,HERE ,P?MAP>>
+		       <TELL "Get serious." CR>
+		       <RTRUE>)
+		      (T <TELL "I can't see it from here!" CR>)>)
+	       (<VERB? LOOK-INSIDE>
+		<PERFORM ,V?LOOK-INSIDE ,FLAPS>
+		<RTRUE>)
+	       (<VERB? LAMP-ON>
+		<TELL "I don't think that striking the tent would do any good." CR>
+		<RTRUE>)
+	       (<NOT <VERB? THROUGH BOARD>>
+		<RFALSE>)
+	       (<NOT <GETP ,HERE ,P?MAP>>
+		<TELL "Get serious." CR>
+		<RTRUE>)
+	       (<IN-A-TENT?>
+		<TELL 
+"What are those canvas walls around you? Just where do you think you are? Maybe
+I should send for Craige, eh?" CR>
+		<RTRUE>)
+	       (<EQUAL? ,HERE ,P2 ,P7 ,P4>
+		<PERFORM ,V?ENTER>
+		<RTRUE>)
+	       (ELSE
+		<TELL "You can't enter the tent from here." CR>
+		<RTRUE>)>>
+
+<OBJECT PYRAMID
+	(FLAGS NDESCBIT TOUCHBIT)
+	(DESC "pyramid")
+	(SYNONYM PYRAMI)
+	(ACTION ENTER-PYRAMID-FCN)>
+
+<ROUTINE ENTER-PYRAMID-FCN ()
+	 <COND (<AND <VERB? DROP>
+		     <EQUAL? ,HERE ,CHAMBER-OF-RA>>
+		<PERFORM ,V?LEAVE>
+		<RTRUE>)
+	       (<VERB? EXAMINE LOOK-INSIDE>
+		<COND (<AND <NOT ,PYRAMID-OPENED>
+			    <IN? ,ROCK-LOCK ,HERE>>
+		       <TELL
+"There's not much to see of it yet -- just the tip of it is exposed showing the
+block and its small opening." CR>)
+		      (<AND ,PYRAMID-OPENED
+			    <EQUAL? ,HERE ,EX8>>
+		       <TELL 
+"You can see down into what looks like a large chamber." CR>)
+		      (<GETP ,HERE ,P?MAP>
+		       <TELL "You can't see any pyramid here." CR>)
+		      (T
+		       <TELL "Where do you think you are, Times Square?" CR>)>
+		<RTRUE>)
+	       (<AND <VERB? OPEN> <NOT ,PYRAMID-OPENED> <IN? ,ROCK-LOCK ,HERE>>
+		<TELL "The stone blocks don't move." CR> <RTRUE>)
+	       (<VERB? OPEN> <TELL "It looks open to me." CR> <RTRUE>)
+	       (<AND <EQUAL? ,PYRAMID ,PRSI>
+		     <EQUAL? ,HERE ,EX8>
+		     <VERB? PUT THROW>
+		     ,PYRAMID-OPENED>
+		<TELL "You hear the " D ,PRSO " fall down below." CR>
+		<FSET ,PRSO ,TOUCHBIT>
+		<FCLEAR ,PRSO ,NDESCBIT>
+		<COND (<EQUAL? ,PRSO ,KNAPSACK>
+		       <FCLEAR ,PRSO ,WEARBIT>
+		       <FSET ,PRSO ,OPENBIT>)>
+		<MOVE ,PRSO ,CHAMBER-OF-RA>
+		<RTRUE>) 
+	       (<NOT <VERB? THROUGH>>
+		<RFALSE>)
+	       (<NOT <GETP ,HERE ,P?MAP>>
+		<TELL "Get serious. Let's find it first." CR>
+		<RTRUE>)
+	       (<EQUAL? ,HERE ,EX8>
+		<PERFORM ,V?ENTER>
+		<RTRUE>)
+	       (ELSE
+		<TELL "You can't enter the pyramid from here." CR>
+		<RTRUE>)>>
+
+<ROOM RIVER-BANK
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "River Bank")
+      (LDESC
+"You are on the bank of the river Nile. The shoreline is sandy and cool, and
+reeds wave in a light but warm breeze. Directly to the north and the south
+thickets make strolling along the bank impossible. You're hot, and the cool
+rippling water to the west looks inviting, but you're not alone in that
+thought -- crocodiles bask on the west bank, eyeing you hungrily, just
+waiting for you to enter their watery domain. Things were never like this when
+Craige was around.")
+      (EAST TO P1)
+      (NORTH "The thickets chew on your skin as you attempt to make a path through them. You finally give up.")
+      (SOUTH "The thickets chew on your skin as you attempt to make a path through them. You finally give up.")
+      (WEST "Can't you see the crocs? If you insist on entering the water, you'll have to swim.")
+      (NW "Can't you see the crocs? If you insist on entering the water, you'll have to swim.")
+      (SW "Can't you see the crocs? If you insist on entering the water, you'll have to swim.")
+      (OUT TO P1)
+      (MAP 1)
+      (GLOBAL TENT-OBJ SAND HOLE GLOBAL-WATER THICKETS)
+      (CAPACITY 0)
+      (ACTION DESCRIBE-HOLE-FCN)>
+
+<ROOM P1
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Near the Nile")
+      (LDESC
+"You are on an east/west path on the north side of the encampment. A path to
+the south starts here, and you can see the riverbank clearly to the west. A
+warm, light breeze reaches your face, drying your sweat into a thin mask of
+salt. You glance to the north and are greeted by a disheartening sight: an
+endless stretch of searing desert.")
+      (NORTH PER GET-LOST-FCN)
+      (NE PER GET-LOST-FCN)
+      (NW PER GET-LOST-FCN)
+      (WEST TO RIVER-BANK)
+      (EAST TO P2)
+      (SOUTH TO P4)
+      (SE TO FIRE)
+      (SW "Some thickets near the river chew on your skin as you attempt to make a path through them. You finally give up.")
+      (MAP 2)
+      (GLOBAL TENT-OBJ SAND HOLE)
+      (CAPACITY 1)
+      (ENDLESS 651)
+      (ACTION CREATE-THIRST-FCN)>
+
+<ROOM P2
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Outside Your Tent")
+      (LDESC
+"You are on an east/west path on the north side of the encampment. To the south
+you can see a firepit and to the north is the entrance to your tent. Everything
+is oddly quiet, unsettling, creating a feeling of floating anxiety. The
+stillness seems to enhance the eerie quality of the desert, the feeling of
+being truly alone.")
+      (NORTH TO TENT)
+      (IN TO TENT)
+      (WEST TO P1)
+      (EAST TO P3)
+      (NW PER GET-LOST-FCN)
+      (NE PER GET-LOST-FCN)
+      (SW TO P4)
+      (SE TO P5)
+      (SOUTH TO FIRE)
+      (MAP 3)
+      (GLOBAL TENT-OBJ SAND HOLE FLAPS)
+      (CAPACITY 3)
+      (ENDLESS 652)
+      (ACTION CREATE-THIRST-FCN)>
+
+<ROOM TENT
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Your Tent")
+      (LDESC
+"You are in your tent. Golden rays of the sun filter through the open tent
+flaps on the southern wall, but no breeze makes its way through. The dry,
+searing heat in the tent would be bearable if only the air stirred, even a
+little.")
+      (SOUTH TO P2)
+      (OUT TO P2)
+      (MAP 4)
+      (GLOBAL TENT-OBJ SAND HOLE FLAPS)
+      (CAPACITY 0)
+      (ACTION DESCRIBE-HOLE-FCN)>
+
+<ROOM P3
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Northern Path")
+      (LDESC
+"You are on an east/west path on the northern side of the encampment. To the
+east you can see the sites of previous excavations your workers had
+begun before they deserted you. Low, gentle sand dunes roll out of sight to
+the north, but your camp's eastern border has a path, heading off to the south,
+which starts here.")
+      (NORTH PER GET-LOST-FCN)
+      (NW PER GET-LOST-FCN)
+      (NE PER GET-LOST-FCN)
+      (EAST TO EX1)
+      (SE TO EX4)
+      (SOUTH TO P5)
+      (SW TO FIRE)
+      (WEST TO P2)
+      (MAP 1)
+      (ACTION CREATE-THIRST-FCN)
+      (GLOBAL TENT-OBJ SAND HOLE)
+      (ENDLESS 653)
+      (CAPACITY 2)>
+
+<ROOM SUPPLY-TENT
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Supply Tent")
+      (LDESC
+"You are in a tent, very much like your own -- a tent which had originally
+contained the supplies for your expedition. You notice, however, that most of
+the items which were here just yesterday have vanished with your workers. The
+tent looks as if it's been cleaned out and, as your stomach growls, the empty
+tent ironically reminds you of a turkey carcass picked clean after a huge
+Thanksgiving meal. Through the open tent flaps to the east you can see the
+firepit. If only one of the workers had remained behind, you would make him
+pay.")
+      (EAST TO P4)
+      (OUT TO P4)
+      (MAP 1)
+      (GLOBAL TENT-OBJ SAND HOLE FLAPS)
+      (CAPACITY 0)
+      (ACTION DESCRIBE-HOLE-FCN)>
+
+<ROOM P4
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Outside Supply Tent")
+      (LDESC
+"You're on a north/south path on the west edge of the encampment. Directly to
+the west is the supply tent, its flaps open, still in the hot, quiet air. To
+the east you can see the central firepit, a reminder of your being alone. A row
+of thickets, impossible to make any progress through even with a machete,
+grows along the western edge of the camp directly to the north and south of the
+tent.")
+      (NORTH TO P1)
+      (NE TO P2)
+      (NW "The thickets chew on your skin as you attempt to make a path through them. You finally give up.")
+      (SW "The thickets chew on your skin as you attempt to make a path through them. You finally give up.")
+      (WEST TO SUPPLY-TENT)
+      (IN TO SUPPLY-TENT)
+      (SOUTH TO P6)
+      (EAST TO FIRE)
+      (SE TO P7)
+      (MAP 1)
+      (ACTION CREATE-THIRST-FCN)
+      (GLOBAL TENT-OBJ SAND HOLE FLAPS THICKETS)
+      (CAPACITY 1)>
+      
+<ROOM FIRE
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Fire Pit")
+      (LDESC
+"You are in the center of the encampment, standing before a charred pit, a hole
+dug in the sand surrounded by blackened rocks. The night breezes have already
+started the reclamation work of the desert, covering most of the pit's bottom.
+You can see your tent to the north, the work tent to the south, and the supply
+tent to the west. Far off to the east, through the heat waves rising off the
+shifting sands, you can see gentle, rolling dunes.")
+      (NORTH TO P2)
+      (NE TO P3)
+      (EAST TO P5)
+      (SE TO P8)
+      (SOUTH TO P7)
+      (SW TO P6)
+      (WEST TO P4)
+      (NW TO P1)
+      (MAP 1)
+      (ACTION CREATE-THIRST-FCN)
+      (GLOBAL TENT-OBJ SAND HOLE)
+      (CAPACITY 0)>
+
+<OBJECT ROCK-S
+	(IN FIRE)
+	(FLAGS DONTTAKE NDESCBIT TRYTAKEBIT)
+	(DESC "blackened rocks")
+	(SYNONYM ROCKS)
+	(ADJECTIVE BLACKE)
+	(TEXT "They form a ring around the firepit.")>
+
+<ROOM P5
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Middle Path")
+      (LDESC
+"You are at the eastern edge of an east/west path in the middle of the camp.
+To the west you can see the firepit and beyond that the supply tent. To the
+east you can see the desert -- a vista difficult to avoid seeing from just
+about anywhere in the camp. A north/south path intersects here, traveling along
+the eastern border of the camp.")
+      (NORTH TO P3)
+      (NE TO EX1)
+      (EAST TO EX4)
+      (SE TO EX7)
+      (SOUTH TO P8)
+      (SW TO P7)
+      (WEST TO FIRE)
+      (NW TO P2)
+      (MAP 2)
+      (ACTION CREATE-THIRST-FCN)
+      (ENDLESS 706)
+      (GLOBAL TENT-OBJ SAND HOLE)
+      (CAPACITY 4)>
+
+<ROOM P6
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Southern Path")
+      (LDESC
+"You are at the west edge of an east/west path on the southern side of the
+encampment. Directly to the west is a heavy growth of thickets, making any
+attempt at western movement a painful and futile task. Through the thickets you
+can hear the sound of water running gently by.")
+      (NORTH TO P4)
+      (NE TO FIRE)
+      (EAST TO P7)
+      (SE PER GET-LOST-FCN)
+      (SOUTH PER GET-LOST-FCN)
+      (SW PER GET-LOST-FCN)
+      (WEST "You scratch yourself on the thickets as you attempt this.")
+      (NW "You scratch yourself on the thickets as you attempt this.")
+      (MAP 2)
+      (ACTION CREATE-THIRST-FCN)
+      (GLOBAL TENT-OBJ SAND HOLE THICKETS)
+      (ENDLESS 751)
+      (CAPACITY 0)>
+
+<ROOM P7
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Outside Work Tent")
+      (LDESC
+"You are on an east/west path, directly to the north of the work tent. To the
+north you can see the firepit and, beyond that, your tent. The work tent
+borders an endless vista of fine, burning sand stretching out to the south.")
+      (NORTH TO FIRE)
+      (NE TO P5)
+      (EAST TO P8)
+      (SE PER GET-LOST-FCN)
+      (SOUTH TO TENT2)
+      (SW PER GET-LOST-FCN)
+      (WEST TO P6)
+      (NW TO P4)
+      (IN TO TENT2)
+      (MAP 2)
+      (ACTION CREATE-THIRST-FCN)
+      (GLOBAL TENT-OBJ SAND HOLE FLAPS)
+      (ENDLESS 752)
+      (CAPACITY 1)>
+
+<ROOM P8
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Southern Path")
+      (LDESC
+"You are at the start of a path which heads north along the eastern border of
+the encampment. To the east you can see the horror and the beauty which brought
+you here, the desert sand and its hidden treasure. The firepit is visible to
+the northwest.")
+      (NORTH TO P5)
+      (NE TO EX4)
+      (EAST TO EX7)
+      (SE PER GET-LOST-FCN)
+      (SOUTH PER GET-LOST-FCN)
+      (SW PER GET-LOST-FCN)
+      (WEST TO P7)
+      (NW TO FIRE)
+      (MAP 2)
+      (GLOBAL TENT-OBJ SAND HOLE)
+      (CAPACITY 2)
+      (ENDLESS 753)
+      (ACTION CREATE-THIRST-FCN)>
+
+<ROOM TENT2
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Work Tent")
+      (LDESC "You are in a tent which used to house the workers and
+their personal effects. Looking around, taking in the stripped and bare
+surroundings, you feel surprised that they even left the canvas walls.
+You quickly realize that they took what they needed -- taking everything
+would have been more trouble than it was worth. From the looks of things
+they cleared out quickly but quietly.")
+      (NORTH TO P7)
+      (OUT TO P7)
+      (GLOBAL TENT-OBJ SAND HOLE FLAPS)
+      (CAPACITY 0)
+      (MAP 2)
+      (ACTION DESCRIBE-HOLE-FCN)>
+
+<ROUTINE CREATE-THIRST-FCN (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<SETG THIRST <+ ,THIRST 6>>
+		<RFALSE>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<SETG THIRST <+ ,THIRST 1>>
+		<RFALSE>)
+	       (<EQUAL? .RARG ,M-LOOK>
+		<DESCRIBE-HOLE-FCN ,M-LOOK>)>>
+
+<ROOM EX1             
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Desert")
+      (LDESC
+"You are in the broiling sands of the desert, a short distance from the camp.
+Off to the west you can just make out a slight discoloration in the sand, the
+start of an east/west path which borders the northern edge of the camp.")
+      (NORTH PER GET-LOST-FCN)
+      (NE PER GET-LOST-FCN)
+      (EAST TO EX2)
+      (SE TO EX5)
+      (SOUTH TO EX4)
+      (SW TO P5)
+      (WEST TO P3)
+      (NW PER GET-LOST-FCN)
+      (GLOBAL TENT-OBJ SAND HOLE)
+      (CAPACITY 3)
+      (MAP 2)
+      (DESERT 1)
+      (ENDLESS 654)
+      (ACTION DESCRIBE-HOLE-FCN)>
+
+<ROOM EX2
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Desert")
+      (LDESC
+"You are in the desert, almost out of sight of the encampment, your only link
+with civilization. You are just close enough to make out a tiny dot on the
+western horizon which could be one of the tents. The searing sand is making
+walking a difficult and painful experience, something alien to you.")
+      (NORTH PER GET-LOST-FCN)
+      (NE PER GET-LOST-FCN)
+      (EAST TO EX3)
+      (SE TO EX6)
+      (SOUTH TO EX5)
+      (SW TO EX4)
+      (WEST TO EX1)
+      (NW PER GET-LOST-FCN)
+      (GLOBAL TENT-OBJ SAND HOLE)
+      (CAPACITY 2)
+      (MAP 1)
+      (DESERT 1)
+      (ENDLESS 655)
+      (ACTION DESCRIBE-HOLE-FCN)>
+
+<ROOM EX3
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Desert")
+      (LDESC
+"You are deep in desert, the encampment little more than a memory. You think
+for a moment, closing your eyes, trying to picture the coolness of the Nile,
+the comfort of your cot, and are overcome with doubts. When you open your eyes
+again you are greeted with the same nightmare: All around you, all you can see
+for mile after mile is sand and more sand.")
+      (NORTH PER GET-LOST-FCN)
+      (NE PER GET-LOST-FCN)
+      (EAST PER GET-LOST-FCN)
+      (SE PER GET-LOST-FCN)
+      (SOUTH TO EX6)
+      (SW TO EX5)
+      (WEST TO EX2)
+      (NW PER GET-LOST-FCN)
+      (GLOBAL TENT-OBJ SAND HOLE)
+      (CAPACITY 1)
+      (MAP 2)
+      (DESERT 1)
+      (ENDLESS 656)
+      (ACTION DESCRIBE-HOLE-FCN)>
+
+<ROOM EX4
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Desert")
+      (LDESC
+"You are in the desert, still within sight of the encampment, just a tiny
+oasis to the west. The tents, shimmering behind the heat waves rising from the
+sand, seem to be calling you back, beckoning, offering safety and refuge.")
+      (NORTH TO EX1)
+      (NE TO EX2)
+      (EAST TO EX5)
+      (SE TO EX8)
+      (SOUTH TO EX7)
+      (SW TO P8)
+      (WEST TO P5)
+      (NW TO P3)
+      (GLOBAL TENT-OBJ SAND HOLE)
+      (CAPACITY 1)
+      (MAP 1)
+      (DESERT 1)
+      (ACTION DESCRIBE-HOLE-FCN)>
+
+<ROOM EX5
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Desert")
+      (LDESC
+"You are standing on the top of a sand dune, looking all around at a place on
+Earth where man was never meant to be. That is the only conclusion you can draw
+as you force yourself to breathe the hot, arid air of the desert through your
+nose. Breathing through your mouth makes you instantly thirsty, a dangerous
+state to find yourself in while surrounded by sand. You curse Craige, then
+find yourself cursing Ellingsworth, too.")
+      (NORTH TO EX2)
+      (NE TO EX3)
+      (EAST TO EX6)
+      (SE TO EX9)
+      (SOUTH TO EX8)
+      (SW TO EX7)
+      (WEST TO EX4)
+      (NW TO EX1)
+      (GLOBAL TENT-OBJ SAND HOLE)
+      (CAPACITY 2)
+      (MAP 2)
+      (DESERT 1)
+      (ACTION DESCRIBE-HOLE-FCN)>
+
+<ROOM EX6
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Desert")
+      (LDESC
+"You are deep into the desert, as deep as anyone in his right mind would ever
+care to venture. A small but strong gust of wind reaches your face, pelting you
+with grains of sand so small they remind you of fine sugar. Even with your lips
+tightly closed, the wind manages to drive a few grains into your mouth. You are
+thankful that none got into your eyes.")
+      (NORTH TO EX3)
+      (NE PER GET-LOST-FCN)
+      (EAST PER GET-LOST-FCN)
+      (SE PER GET-LOST-FCN)
+      (SOUTH TO EX9)
+      (SW TO EX8)
+      (WEST TO EX5)
+      (NW TO EX2)
+      (GLOBAL TENT-OBJ SAND HOLE)
+      (CAPACITY 3)
+      (MAP 2)
+      (DESERT 1)
+      (ENDLESS 706)
+      (ACTION DESCRIBE-HOLE-FCN)>
+
+<ROOM EX7
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Desert")
+      (LDESC
+"You are in the desert, east of the encampment. From this distance the camp
+seems little more than a mirage, an image of another reality which has little
+to do with the brutal, searing reality of the desert, your quickly dehydrating
+body, or your painfully broiling feet.")
+      (NORTH TO EX4)
+      (NE TO EX5)
+      (EAST TO EX8)
+      (SE PER GET-LOST-FCN)
+      (SOUTH PER GET-LOST-FCN)
+      (SW PER GET-LOST-FCN)
+      (WEST TO P8)
+      (NW TO P5)
+      (GLOBAL TENT-OBJ SAND HOLE)
+      (CAPACITY 1)
+      (MAP 2)
+      (DESERT 1)
+      (ENDLESS 754)
+      (ACTION DESCRIBE-HOLE-FCN)>
+
+<ROOM EX8
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Desert")
+      (LDESC
+"You are in the desert, out of sight of the encampment. You are thankful
+there's no wind, even though a cooling breeze would be welcomed, since the
+fine sand particles would sting your face and hands. All around is the desert,
+a sweeping expanse of disheartening sand.")
+      (NORTH TO EX5)
+      (NE TO EX6)
+      (EAST TO EX9)
+      (SE PER GET-LOST-FCN)
+      (SOUTH PER GET-LOST-FCN)
+      (SW PER GET-LOST-FCN)
+      (WEST TO EX7)
+      (NW TO EX4)
+      (DOWN TO CHAMBER-OF-RA IF PYRAMID-OPENED)
+      (IN TO CHAMBER-OF-RA IF PYRAMID-OPENED)
+      (GLOBAL TENT-OBJ SAND HOLE)
+      (CAPACITY 1)
+      (MAP 2)
+      (DESERT 1)
+      (ENDLESS 755)
+      (ACTION DESCRIBE-HOLE-FCN)>
+
+<ROOM EX9
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Desert")
+      (LDESC
+"You are far into the desert, sand and more sand stretching out endlessly
+around you in all directions. You think of going back, of giving up this
+attempt at riches, but what awaits you back in the States? What is there worth
+going back to, with nothing to show for this quest? And how could you go back
+now, after the things you'd said to Craige? You glance around
+at the rolling dunes and force back the fear eating away your confidence.")
+      (NORTH TO EX6)
+      (NE PER GET-LOST-FCN)
+      (EAST PER GET-LOST-FCN)
+      (SE PER GET-LOST-FCN)
+      (SOUTH PER GET-LOST-FCN)
+      (SW PER GET-LOST-FCN)
+      (WEST TO EX8)
+      (NW TO EX5)
+      (GLOBAL TENT-OBJ SAND HOLE)
+      (CAPACITY 1)
+      (MAP 1)
+      (DESERT 1)
+      (ENDLESS 756)
+      (ACTION DESCRIBE-HOLE-FCN)>
+
+<ROUTINE DESCRIBE-HOLE-FCN (RARG "AUX" DEPTH)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL <GETP ,HERE ,P?LDESC>>
+		<SET DEPTH <GETP ,HERE ,P?CAPACITY>>
+		<COND (<AND <G? .DEPTH 5>
+			    <EQUAL? ,HERE ,EX8>>
+		       <CRLF>
+		       <RTRUE>)
+		      (<G? .DEPTH 0>
+		       <TELL " There's a" <GET ,DESC-HOLE-LTBL .DEPTH>
+" in the sand, a remnant of your excavation attempts.">)>
+		<COND (<EQUAL? ,HERE ,ENDLESS-DESERT>
+		       <COND (<G? ,THIRST 300>
+			      <TELL " " <PICK-ONE ,SPACE-TALES-LTBL>>)
+			     (ELSE
+			      <COND (<PROB 50>
+				     <COND (<PROB 35>
+					    <TELL " "
+					        <PICK-ONE ,SPACE-TALES-LTBL>>)
+					   (T <TELL " "
+						<PICK-ONE ,MIRAGE-LTBL>>)>)>)>)
+		      (<GETP ,HERE ,P?DESERT>
+		       <COND (<G? ,THIRST 300>
+			      <TELL " " <PICK-ONE ,MIRAGE-LTBL>>)
+			     (ELSE
+			      <COND (<PROB 20>
+				     <TELL " " <PICK-ONE ,MIRAGE-LTBL>>)>)>)>
+		<CRLF>
+		<RTRUE>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<SETG THIRST <+ ,THIRST 15>>
+		<RFALSE>)
+	       (<EQUAL? .RARG ,M-BEG>
+		<SETG THIRST <+ ,THIRST 3>>
+		<RFALSE>)>>
+		       
+<GLOBAL DESC-HOLE-LTBL
+	<LTABLE " small hole"
+		"n enlarged hole"
+		" sizable hole"
+		" knee-deep hole"
+		" deep hole">>
+
+<GLOBAL SPACE-TALES-LTBL
+	<LTABLE
+"You hear a whirring overhead and look up in time to see a gyrocopter settling
+to the sand on the horizon."
+"You think you see a spaceship settling on the horizon and, as you strain your
+eyes through the wafting waves of heat, you see a man and a huge robot. You can
+almost hear them saying \"Gort, Klaatu Barada Nikto.\""
+"A small lizard pokes its head up from the sands and asks the shortest route to
+Times Square. You scratch your head for a moment and when you remember the
+proper subway line to recommend to it, you notice it's disappeared."
+"Five maids amilking sit on sandy stools before you, grinning maniacally."
+"A large rainbow trout walks by, holding a pet snail on a leash."
+"A strong gust of wind kicks up a herd of buffalo on the horizon. You think it
+strange that the buffalo are riding sidesaddle.">>
+
+<GLOBAL MIRAGE-LTBL
+	<LTABLE
+"Far off in the distance, dancing on the horizon, you see a shimmering oasis.
+Standing by the oasis are a team of Egyptian workers, waving for you to
+approach."
+"A cool pool of water seems to dance in the heat waves just a mile away. You
+can almost hear Rankin and Craige arguing over the spoils."
+"A caravan of camels, led by a nomadic tribe, wanders a few miles off."
+"You wipe your sweating brow, gazing off into the distance, and notice a cool,
+crystal-clear lake glimmering on the horizon, just to the north.">>
+
+<OBJECT ROCK-LOCK
+	(IN EX8)
+	(FLAGS INVISIBLE NDESCBIT CONTBIT OPENBIT DONTTAKE VOWELBIT)
+	(DESC "opening")
+	(SYNONYM OPENIN BLOCK HOLE)
+	(ADJECTIVE SQUARE)
+	(CAPACITY 5)
+	(MAP 3)
+	(TEXT
+"The opening sits in the upper right-hand corner of the block. It's a small
+square opening, about four inches square, far too small for you
+to enter, and rather shallow. Some hieroglyphs travel across the block,
+cut off by the opening:|
+|
+       !-!        !-!|
+->  #.  ! !  -  #  ! !  /")
+	(ACTION ENTER-OPENING-FCN)>
+
+<ROUTINE ENTER-OPENING-FCN ()
+	 <COND (<VERB? OPEN CLOSE>
+		<HOW? ,PRSO>)
+	       (<VERB? THROUGH>
+		<TELL
+"I think the opening is a little too small to get through. Unless your ethics
+and morals are an accurate representation of your stature." CR>
+		<RTRUE>)>>
+
+<OBJECT COT
+	(IN TENT)
+	(FLAGS TAKEBIT TRYTAKEBIT CONTBIT OPENBIT SURFACEBIT VEHBIT VOWELBIT
+	       TRANSBIT)
+	(DESC "army cot")
+	(ACTION COT-FCN)
+	(CAPACITY 100)
+	(SYNONYM COT)
+	(ADJECTIVE ARMY)>
+
+<OBJECT FOLDED-COT
+	(FLAGS TAKEBIT)
+	(DESC "folded cot")
+	(ACTION COT-FCN)
+	(SIZE 9)
+	(SYNONYM COT)
+	(ADJECTIVE ARMY FOLDED)>
+
+<ROUTINE COT-FCN ("OPTIONAL" (RARG ,M-OBJECT) "AUX" F)
+	 <COND (<NOT <EQUAL? .RARG ,M-OBJECT>> <RFALSE>)
+	       (<PRSO? ,COT>
+		<SET F <FIRST? ,COT>>
+		<COND (<VERB? TAKE PUT PUT-ON>
+		       <TELL
+"It's too bulky and unstable a structure to be carrying around." CR>
+		       <RTRUE>)
+		      (<VERB? CLIMB-ON CLIMB-UP>
+		       <COND (<IN? ,WINNER ,COT>
+			      <TELL "Where do you think you are?" CR>)
+			     (T
+			      <TELL
+"This is no time for sitting down on the job, especially after what you've been
+through to get here!" CR>)>
+		       <RTRUE>)
+		      (<VERB? EXAMINE LOOK-INSIDE>
+		       <TELL "It's just an army cot.">
+		       <COND (<AND .F
+				   <EQUAL? .F ,WINNER>>
+			      <TELL " And you're in it!">)
+			     (.F
+			      <TELL " Sitting on the cot ">
+			      <COND (<G? <CCOUNT ,COT> 1>
+				     <TELL "are ">)
+				    (T <TELL "is ">)>
+			      <PRINT-CONTENTS ,COT>
+			      <TELL ".">)>
+		       <CRLF>
+		       <RTRUE>)
+		      (<VERB? FOLD CLOSE>
+		       <COND (<NOT .F>
+			      <TELL "Folded." CR>
+			      <MOVE ,FOLDED-COT <LOC ,COT>>
+			      <REMOVE ,COT>
+			      <THIS-IS-IT ,FOLDED-COT>
+			      <RTRUE>)
+			     (<EQUAL? .F ,WINNER>
+			      <TELL
+"Don't you think it would be wise to get out of the cot first? Or are you
+waiting for a valet to help?" CR>
+			      <RTRUE>)
+			     (.F
+			      <TELL
+"You'd better take everything off of it first." CR>
+			      <RTRUE>)>)
+		      (<VERB? OPEN UNFOLD>
+		       <TELL "It's already unfolded." CR>
+		       <RTRUE>)
+		      (<AND <VERB? DROP>
+			    <EQUAL? <LOC ,WINNER> ,COT>>
+		       <PERFORM ,V?DISEMBARK ,COT>
+		       <RTRUE>)
+		      (<AND <VERB? WALK THROUGH>
+			    <EQUAL? <LOC ,WINNER> ,COT>>
+		       <TELL "You'd better get out of the cot first." CR>
+		       <RFATAL>)>)
+	       (<PRSO? ,FOLDED-COT>
+		<COND (<VERB? OPEN UNFOLD>
+		       <COND (<NOT <IN? ,FOLDED-COT ,HERE>>
+			      <TELL
+"Better put it down on the ground first." CR>)
+			     (T
+			      <TELL "Unfolded." CR>
+			      <MOVE ,COT <LOC ,FOLDED-COT>>
+			      <REMOVE ,FOLDED-COT>
+			      <THIS-IS-IT ,COT>
+			      <RTRUE>)>)
+		      (<VERB? FOLD CLOSE>
+		       <TELL 
+"Hmmm. Looks like you beat yourself to it. It's already folded up." CR>
+		       <RTRUE>)>)>>
+		      
+
+<OBJECT MATCHES
+	(IN FIRE)
+	(DESC "matchbook")
+	(FDESC
+"Sitting by a rock is what looks like a matchbook.")
+	(SYNONYM MATCHB MATCHE COVER)
+	(FLAGS BURNBIT TAKEBIT READBIT CONTBIT)
+	(SIZE 1)
+	(CAPACITY 1)
+	(GENERIC DIASMBIGUATE-FCN)
+	(ACTION READ-MATCHES-FCN)>
+
+<ROUTINE READ-MATCHES-FCN ("OPTIONAL" OBJ)
+	 <COND (<NOT .OBJ>
+		<SET OBJ ,MATCHES>)>
+	 <COND (<VERB? READ-INSIDE>
+		<COND (<NOT <FSET? .OBJ ,OPENBIT>>
+		       <TELL "You'd better open the matchbook first." CR>
+		       <RTRUE>)
+		      (ELSE
+		       <PERFORM ,V?READ .OBJ>
+		       <RTRUE>)>)
+	       (<VERB? READ LOOK-BEHIND>
+		<COND (<FSET? .OBJ ,OPENBIT>
+		       <TELL
+"The inside says: Send away now!! Mushrooms can be taught a foreign
+language, and make fine pets! Easy to feed and they can be walked on a leash!
+Read and fill out the enclosed coupon now!" CR>)
+		      (ELSE
+		       <TELL
+"Printed on the outside is a small coupon for an instruction manual,
+\"GROW MUSHROOMS IN YOUR BASEMENT FOR FUN & PROFIT\". Close Before
+Striking." CR>)>)
+	       (<VERB? LAMP-ON>
+		<TELL "One match at a time, eh?" CR>
+		<RTRUE>)>>
+
+<OBJECT MANY-MATCHES
+	(IN MATCHES)
+	(FLAGS TAKEBIT BURNBIT TRYTAKEBIT)
+	(DESC "few matches")
+	(SYNONYM MATCH)
+	(GENERIC DIASMBIGUATE-FCN)
+	(ADJECTIVE ONE SINGLE)
+	(SIZE 1)
+	(ACTION TAKE-ONE-MATCH-FCN)>
+
+<OBJECT SINGLE-MATCH
+	(FLAGS TAKEBIT BURNBIT TRYTAKEBIT)
+	(DESC "single match")
+	(SYNONYM MATCH)
+	(GENERIC DIASMBIGUATE-FCN)
+	(ADJECTIVE ONE SINGLE)
+	(SIZE 1)
+	(ACTION TAKE-ONE-MATCH-FCN)>
+
+<OBJECT ONE-MATCH
+	(IN GLOBAL-OBJECTS)
+	(FLAGS BURNBIT)
+	(DESC "match")
+	(GENERIC DIASMBIGUATE-FCN)
+	(SYNONYM MATCH)
+	(SIZE 1)
+	(ACTION DROP-ONE-FCN)>
+
+<OBJECT BURNED-MATCHBOOK
+	(FLAGS CONTBIT TAKEBIT)
+	(DESC "burned matchbook")
+	(SYNONYM MATCHB)
+	(ADJECTIVE BURNED)
+	(CAPACITY 1)>
+
+<OBJECT EMPTY-MATCHES
+	(FLAGS CONTBIT OPENBIT BURNBIT READBIT TAKEBIT)
+	(DESC "matchbook")
+	(SYNONYM MATCHB MATCHE)
+	(GENERIC DIASMBIGUATE-FCN)
+	(ADJECTIVE EMPTY)
+	(CAPACITY 1)
+	(ACTION LAST-MATCH-FCN)>
+
+<ROUTINE LAST-MATCH-FCN ()
+	 <COND (<AND <VERB? DROP>
+		     <IN? ,ONE-MATCH ,WINNER>>
+		<DROP-ONE-FCN>
+		<RTRUE>)
+	       (<VERB? TAKE>
+		<TELL "Why? There's no match left in the matchbook." CR>
+		<RTRUE>)
+	       (<VERB? LAMP-ON>
+		<COND (<IN? ,ONE-MATCH ,WINNER>
+		       <RFALSE>)
+		      (ELSE
+		       <TELL "There's no match to light!" CR>
+		       <RTRUE>)>)
+	       (<VERB? READ>
+		<READ-MATCHES-FCN ,EMPTY-MATCHES>
+		<RTRUE>)>>
+
+<ROUTINE DROP-ONE-FCN ()
+	 <COND (<VERB? DROP PUT>
+		<COND (<NOT <IN? ,ONE-MATCH ,WINNER>>
+		       <TELL "Better take one first." CR>
+		       <RTRUE>)>
+		<MOVE ,ONE-MATCH ,GLOBAL-OBJECTS>
+		<TELL "Dropped. ">
+		<BUT-WHERE?>
+		<TELL " ">
+		<I-MATCH-OUT>
+		<DISABLE <INT I-MATCH-OUT>>
+		<RTRUE>)
+	       (<VERB? TAKE>
+		<COND (<IN? ,MATCHES ,WINNER>
+		       <MATCH-MOVER <>>
+		       <RTRUE>)
+		      (T
+		       <TELL "I see no match here." CR>
+		       <RTRUE>)>)
+	       (<EQUAL? ,ONE-MATCH ,PRSI>
+		<COND (<AND <NOT <IN? ,MATCHES ,WINNER>>
+			    <NOT <IN? ,ONE-MATCH ,WINNER>>>
+		       <TELL "You're not holding the match." CR>
+		       <RTRUE>)
+		      (T
+		       <MATCH-MOVER T>
+		       <RFALSE>)>)>>
+
+<ROUTINE BUT-WHERE? ()
+	 <COND (<IN? ,WINNER ,COT>
+		<TELL
+		 "The match disappears somewhere beneath the cot.">)
+	       (<EQUAL? ,HERE ,RIVER-BANK>
+		<TELL
+		 "The current of the river sweeps it away.">)
+	       (<GETP ,HERE ,P?MAP>
+		<TELL 
+		 "The match, however, is quickly covered by the sand.">)
+	       (<EQUAL? <GETP ,HERE ,P?ACTION> ,BURN-THE-BARGE>
+		<TELL 
+		 "The match, however, falls between the wooden decking.">)
+	       (<AND <NOT <FSET? ,PIT ,INVISIBLE>>
+		     <EQUAL? ,HERE ,WEST-END-OF-PASSAGE>>
+		<TELL
+		 "The match flutters down into the abyss.">)
+	       (T
+		<TELL "The match falls into a crack in the stone floor.">)>
+	 <COND (<NOT <FLAMING? ,ONE-MATCH>>
+		<CRLF>)>>
+
+<ROUTINE TAKE-ONE-MATCH-FCN ()
+	 <COND (<VERB? TAKE>
+		<COND (<NOT <IN? ,ONE-MATCH ,WINNER>>
+		       <MATCH-MOVER <>>)
+		      (ELSE
+		       <TELL "You're already holding one." CR>)>
+		<RTRUE>) 
+	       (<VERB? DROP>
+		<PERFORM ,V?DROP ,ONE-MATCH>
+		<RTRUE>)
+	       (<OR <VERB? PUT PUT-ON PUT-UNDER>
+		    <VERB? PUT-BEHIND PUT-AGAINST PUT-ACROSS>>
+		<COND (<IN? ,ONE-MATCH ,WINNER>
+		       <MOVE ,ONE-MATCH ,GLOBAL-OBJECTS>
+		       <TELL 
+"Well, I tried, but the match seems to have missed the mark entirely." CR>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL "One match at a time!" CR>
+		       <RTRUE>)>)>>
+
+<ROUTINE MATCH-MOVER ("OPTIONAL" (SUPPRESS? T))
+	 <COND (<G? ,MATCH-COUNT 0>
+		<SETG MATCH-COUNT <- ,MATCH-COUNT 1>>)>
+	 <COND (<L? ,MATCH-COUNT 1>
+		<SETG MATCH-COUNT 0>
+		<REMOVE ,SINGLE-MATCH>
+		<RFALSE>)
+	       (<EQUAL? ,MATCH-COUNT 1>
+		<MOVE ,EMPTY-MATCHES <LOC ,MATCHES>>
+		<REMOVE ,MATCHES>
+		<REMOVE ,MANY-MATCHES>
+		<FSET ,SINGLE-MATCH ,NDESCBIT>)
+	       (<EQUAL? ,MATCH-COUNT 2>
+		<MOVE ,SINGLE-MATCH <LOC ,MANY-MATCHES>>
+		<REMOVE ,MANY-MATCHES>)>
+	 <MOVE ,ONE-MATCH ,WINNER>
+	 <COND (<NOT .SUPPRESS?>
+		<TELL "Taken." CR>)>
+	 <RTRUE>>
+
+<OBJECT MANUAL
+	(IN GLOBAL-OBJECTS)
+	(DESC "manual")
+	(FLAGS READBIT DONTTAKE)
+	(ADJECTIVE INSTRU)
+	(SYNONYM MANUAL COUPON)
+	(ACTION SEND-FOR-IT-FCN)>
+
+<ROUTINE SEND-FOR-IT-FCN ()
+	 <COND (<AND <VERB? SEND>
+		     <IN? ,MATCHES ,WINNER>>
+		<TELL
+"Sure. As soon as a postman walks by, I'd be glad to give the coupon to him." CR>
+		<RTRUE>)
+	       (<AND <VERB? READ>
+		     <IN? ,MATCHES ,WINNER>>
+		<TELL
+"The coupon for the manual is as clear as any coupon ever was:|
+|
+Fill in Last Name first, unless First Name is Last. Check the box beside
+the dotted line unless you want the manual shipped via alternate shipping.
+Include your address unless your mailing address and shipping address differ
+from your postal delivery route. If you are having the manual air-freighted,
+fill in your airport's zip code unless you're within thirty miles of a large
+corn field. After checking whether that box has been checked, check it.
+|
+Before you mail this, be certain you've read the instructions and have filled
+out all three sides of the form. In case of doubt, contact the Coupon
+Customer Service Department, 122 East Accardi Street, Youknow, Alaska.
+If you live west of the Atlantic or the Pacific, this offer is
+null and void except where prohibited by law." CR >)
+	       (<VERB? READ>
+		<TELL
+"There's not much to read unless you're holding the matchbook." CR>
+		<RTRUE>)>>
+
+<ROUTINE BURN-FOO-FCN ()
+	 <COND (<AND <VERB? BURN LAMP-ON>
+		     <PRSO? ,CIG-WRAPPER>
+		     <OR <IN? ,MATCHES ,WINNER>
+			 <AND <IN? ,ONE-MATCH ,WINNER>
+			      <FLAMING? ,ONE-MATCH>>>>
+		<TELL 
+"It tries valiantly to burn, but the inside of it is made of foil, and you
+manage to burn your fingertips instead of the package." CR>
+		<MOVE ,BURNED-PACK <LOC ,CIG-WRAPPER>>
+		<FCLEAR ,BURNED-PACK ,INVISIBLE>
+		<FCLEAR ,BURNED-PACK ,NDESCBIT>
+		<REMOVE ,CIG-WRAPPER>
+		<THIS-IS-IT ,BURNED-PACK>
+		<RTRUE>)
+	       (<VERB? READ>
+		<TELL <GETP ,CIG-WRAPPER ,P?TEXT> CR>)>>
+
+<OBJECT BURNED-PACK
+	(FLAGS INVISIBLE TAKEBIT READBIT NDESCBIT)
+	(DESC "burned wrapper")
+	(SYNONYM WRAPPE PACK)
+	(ADJECTIVE BURNED)
+	(TEXT
+"There's not much left to the outside of this package that's distinguishable.")
+	(ACTION HUH?)>
+
+<OBJECT CIG-WRAPPER
+	(IN FIRE)
+	(FLAGS TAKEBIT READBIT BURNBIT CONTBIT OPENBIT)
+	(DESC "cigarette pack")
+	(FDESC
+"Half covered with sand is a bright piece of foil which catches your eye.")
+	(SYNONYM PACK FOIL)
+	(ADJECTIVE CIGARE BRIGHT)
+	(TEXT
+"It's an empty pack of Camel cigarettes.")
+	(SIZE 3)
+	(CAPACITY 2)
+	(ACTION BURN-FOO-FCN)>
+
+<OBJECT BROKEN-LOCK
+	(IN TENT)
+	(FLAGS INVISIBLE TAKEBIT TRYTAKEBIT NDESCBIT)
+	(DESC "broken lock")
+	(SYNONYM LOCK PADLOC)
+	(ADJECTIVE BROKEN)
+	(TEXT
+"This is a slightly messed-up lock which once functioned. Alas, like your
+personality, it has seen better days.")>
+
+<OBJECT TRUNK
+	(IN TENT)
+	(FLAGS CONTBIT TRANSBIT SURFACEBIT OPENBIT)
+	(DESC "trunk")
+	(DESCFCN DESCRIBE-TRUNK-FCN)
+	(SYNONYM TRUNK)
+	(ADJECTIVE LARGE UNWIEL)
+	(CAPACITY 100)
+	(ACTION TRUNK-FCN)>
+
+<GLOBAL TRUNK-TBL ;"Thirty (30) slots to hold objects in the trunk"
+	<LTABLE MAP FOOD SMALL-SLIP 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0>>
+
+<ROUTINE DESCRIBE-TRUNK-FCN (RARG)
+	 <COND (<EQUAL? .RARG ,M-OBJDESC>
+		<COND (<IN? ,COT ,HERE>
+		       <TELL
+"At the foot of the cot is a large, unwieldy trunk.">)
+		      (T
+		       <TELL "A large, unwieldy trunk sits on the sand.">)>
+		<COND (<FSET? ,BROKEN-LOCK ,INVISIBLE>
+		       <TELL
+" The trunk is closed and locked with a padlock.">)
+		      (<NOT <FSET? ,BROKEN-LOCK ,TOUCHBIT>>
+		       <TELL
+" The trunk is closed with a broken padlock.">)>
+		<CRLF>
+		<COND (<FIRST? ,TRUNK>
+		       <PRINT-CONT ,TRUNK>)>
+		<RTRUE>)>>
+
+<ROUTINE TRUNK-FCN ("AUX" (FLG <>))
+	 <COND (<VERB? OPEN>
+		<COND (<IN? ,LOCK ,TENT>
+		       <TELL "A padlock holds it shut." CR>)
+		      (<NOT <FSET? ,BROKEN-LOCK ,TOUCHBIT>>
+		       <TELL
+"You'd better remove the broken lock first." CR>)
+		      (ELSE
+		       <TBL-TO-INSIDE ,TRUNK ,TRUNK-TBL>
+		       <RTRUE>)>)
+	       (<VERB? UNLOCK>
+		<COND (<NOT <FSET? ,TRUNK ,SURFACEBIT>>
+		       <TELL "Better have your eyes checked." CR>)
+		      (T <TELL "You don't have a key." CR>)>
+		<RTRUE>)
+	       (<AND <VERB? EXAMINE LOOK-INSIDE>
+		     <FSET? ,TRUNK ,SURFACEBIT>>
+		<TELL
+"It's an old steamer trunk, very heavy and too clumsy for one person to carry."CR>
+		<COND (<FIRST? ,TRUNK>
+		       <PRINT-CONT ,TRUNK>)>
+		<RTRUE>)
+	       (<AND <VERB? CLOSE>
+		     <NOT <FSET? ,TRUNK ,SURFACEBIT>>>
+		<COND (<AND <IN? ,TORCH ,TRUNK>
+			    <FLAMING? ,TORCH>>
+		       <SET FLG T>)>
+		<INSIDE-OBJ-TO ,TRUNK-TBL ,TRUNK>
+		<COND (.FLG
+		       <KILL-TORCH T>)>
+		<RTRUE>)>>
+
+<OBJECT LOCK
+	(IN TENT)
+	(DESC "padlock")
+	(SYNONYM PADLOC LOCK)
+	(FLAGS NDESCBIT CONTBIT)
+	(ACTION LOCK-FCN)>
+
+<ROUTINE LOCK-FCN ()
+	 <COND (<VERB? OPEN>
+		<COND (,PRSI
+		       <PERFORM ,V?MUNG ,PRSO ,PRSI>
+		       <RTRUE>)
+		      (T
+		       <TELL"You can't. It's locked." CR>
+		       <RTRUE>)>)
+	       (<AND <VERB? MUNG>
+		     <PRSI? ,PICK-AXE 
+			    ,SHOVEL ,ROCK>>
+		<TELL "The padlock breaks open." CR>
+		<FCLEAR ,BROKEN-LOCK ,INVISIBLE>
+		<REMOVE ,LOCK>
+		<THIS-IS-IT ,BROKEN-LOCK>
+		<SETG SCORE <+ ,SCORE 5>>)
+	       (<VERB? MUNG>
+		<TELL"You'll have to hit the lock with something stronger." CR>
+		<RTRUE>)
+	       (<VERB? TAKE DISEMBARK>
+		<TELL "It's locked." CR>)
+	       (<AND <VERB? EXAMINE LOOK-INSIDE>
+		     <IN? ,LOCK ,HERE>>
+		<TELL
+"It's made of hardened steel and is very sturdy. It's also very locked." CR>)>>
+
+<OBJECT PICK-AXE
+	(IN SUPPLY-TENT)
+	(FLAGS TOOLBIT TAKEBIT)
+	(DESC "pick axe")
+	(FDESC
+"Stuck in the sand, handle down, is a small pick axe.")
+	(SYNONYM AXE PICKAX AX)
+	(ADJECTIVE PICK)
+	(TEXT
+"It's a small hand axe, similar to those used in mountain climbing.")
+	(SIZE 10)>
+
+<OBJECT STONE-KEY
+	(IN MAP)
+	(FLAGS TAKEBIT READBIT)
+	(DESC "stone cube")
+	(TEXT
+"This is a small stone cube, almost four inches on a side, with ancient
+markings on it. The markings look like this:|
+|
+#  !@!  ::  (())  !@!  //\\\\")
+	(SYNONYM CUBE)
+	(MAP 3)
+	(ADJECTIVE SMALL STONE)
+	(ACTION STONE-KEY-FCN)>
+
+<GLOBAL PYRAMID-OPENED <>>
+
+<ROUTINE STONE-KEY-FCN ()
+	 <COND (<AND <VERB? PUT>
+		     <EQUAL? ,PRSI ,ROCK-LOCK>>
+		<TELL "The ancient stones beneath your feet shake and
+tremble as they move the sands. You leap out of the way and manage to
+avoid being sucked down into the vortex. Through the sands, an entrance
+down into the pyramid is revealed. The entire experience sends a jolt of
+adrenaline through your body as your lips form a sneer. You've found it.
+And without any help from those idiots."CR>
+		<SETG PYRAMID-OPENED T>
+		<REMOVE ,STONE-KEY>
+		<REMOVE ,ROCK-LOCK>
+		<SETG P-IT-LOC <>>
+		<PUTP ,HERE ,P?LDESC
+"You are in the desert at a site of successful excavation. Beneath you lies the
+pyramid, its stone door at last open. The desert is all around you, but
+down there lie the secrets of the ages.">
+		<SETG SCORE <+ ,SCORE 20>>)>>
+
+<OBJECT FOOD
+	(FLAGS FOODBIT TAKEBIT TOUCHBIT TRYTAKEBIT)
+	(DESC "piece of dried beef")
+	(SYNONYM BEEF FOOD MEAT)
+	(ADJECTIVE DRIED PIECE)
+	(ACTION EDIBLE-FCN)>
+
+<ROUTINE EDIBLE-FCN ()
+	 <COND (<NOT <EQUAL? ,PRSO ,FOOD>>
+		<RFALSE>)
+	       (<VERB? SMELL TASTE>
+		<TELL "Mmmm good!" CR>
+		<RTRUE>)>>
+	       
+<OBJECT MAP
+	(FLAGS CONTBIT TAKEBIT VOWELBIT BURNBIT)
+	(DESC "ancient map")
+	(SYNONYM MAP)
+	(ADJECTIVE ANCIEN)
+	(CAPACITY 5)
+	(ACTION MAP-FCN)>
+
+<ROUTINE MAP-FCN ()
+	 <COND (<AND <NOT <IN? ,MAP ,WINNER>>
+		     <VERB? OPEN READ EXAMINE>> 
+		<TELL "You're not carrying the map." CR>
+		<RTRUE>)
+	       (<AND <VERB? READ EXAMINE>
+		     <NOT <FSET? ,MAP ,OPENBIT>>>
+		<TELL "You'd better unfold it first." CR>
+		<RTRUE>)
+	       (<VERB? READ EXAMINE>
+		<TELL
+"This is a reproduction of the map the Professor made while on his expedition.
+It indicates where he hoped to find the lost pyramid. It is included in your
+game package." CR>)
+	       (<AND <VERB? TAKE>
+		     <NOT <FSET? ,MAP ,TOUCHBIT>>>
+		<COND (<ITAKE>
+		       <TELL
+"Taken. It feels fairly heavy, though, as though it were folded around
+something solid." CR>)>
+		<RTRUE>)>>
+
+<OBJECT SHOVEL
+	(IN SUPPLY-TENT)
+	(FLAGS TOOLBIT TAKEBIT)
+	(DESC "shovel")
+	(FDESC
+"Half buried in the sand, in the corner of the tent, is a shovel.")
+	(TEXT
+"It's a standard-issue garden shovel.")
+	(SYNONYM SHOVEL)>
+
+<OBJECT ROPE
+	(IN KNAPSACK)
+	(DESC "rope")
+	(FLAGS TAKEBIT CLIMBBIT BURNBIT TOUCHBIT)
+	(SYNONYM ROPE COIL ASP)
+	(SIZE 4)
+	(ADJECTIVE BUNCH)
+	(TEXT
+"This rope is made of the finest Manila hemp and guaranteed to hold at least
+250 pounds of weight. There's about thirty feet of it. Be glad the workers
+didn't hang you with it.")
+	(ACTION ROPE-FCN)
+	(DESCFCN DESCRIBE-ROPE-FCN)>
+
+<ROUTINE DESCRIBE-ROPE-FCN (RARG)
+	 <COND (<AND <EQUAL? .RARG ,M-OBJDESC>
+		     <OR <EQUAL? ,HERE ,LANDING-ZERO ,LANDING-ONE ,LANDING-TWO>
+			 <EQUAL? ,HERE ,LANDING-THREE ,TINY-LANDING>>
+		     ,ROPE-PLACED>
+		<TELL "Descending from above is the end of a long rope.">
+		<COND (<ROOM? ,TINY-LANDING>
+		       <TELL " It travels down into the darkness.">)>
+		<CRLF>
+		<RTRUE>)>>
+
+<ROUTINE ROPE-FCN ()
+	 <COND (<AND <VERB? TIE>
+		     <PRSI? ,ALTAR>>
+		<COND (,ROPE-TIED
+		       <TELL "It's already tied to the " D ,ROPE-TIED "." CR>
+		       <RTRUE>)
+		      (<EQUAL? ,PRSI ,ALTAR>
+		       <TELL "The rope has been tied to the " D ,PRSI "." CR>
+		       <SETG ROPE-TIED ,PRSI>
+		       <FSET ,ROPE ,TRYTAKEBIT>)
+		      (T <RFALSE>)>)
+	       (<VERB? UNTIE>
+		<COND (<NOT ,ROPE-TIED>
+		       <TELL "That's cute. It's not tied!" CR>
+		       <RTRUE>)
+		      (<NOT <EQUAL? ,HERE ,CHAMBER-OF-RA>>
+		       <TELL "Your arms aren't quite that long." CR>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL "Untied.">
+		       <SETG ROPE-TIED <>>
+		       <FCLEAR ,ROPE ,TRYTAKEBIT>
+		       <COND (,ROPE-PLACED
+			      <MOVE ,ROPE ,LANDING>
+			      <TELL " You hear it fall down below.">
+			      <SETG LANDING <>>
+			      <SETG ROPE-PLACED <>>)>
+		       <CRLF>
+		       <RTRUE>)>)
+	       (<AND <VERB? TAKE PUT>
+		     ,ROPE-PLACED
+		     <EQUAL? ,HERE ,CHAMBER-OF-RA>>
+		<SETG ROPE-PLACED <>>
+		<FCLEAR ,ROPE ,NDESCBIT>
+		<TELL "(free end of rope)" CR>
+		<RFALSE>)
+	       (<AND <VERB? TAKE>
+		     ,ROPE-PLACED
+		     <OR <EQUAL? ,HERE ,LANDING-ZERO ,LANDING-ONE 
+				 ,TINY-LANDING>
+			 <EQUAL? ,HERE ,LANDING-TWO ,LANDING-THREE>>>
+		<TELL "It seems to be tied to something up overhead." CR>
+		<RTRUE>)
+	       (<AND <VERB? MOVE>
+		     ,ROPE-PLACED>
+		<TELL "The rope is securely fastened to the altar." CR>
+		<RTRUE>)
+	       (<VERB? PUT>
+		<COND (<AND ,PRSI
+			    <FSET? ,PRSI ,CLIMBBIT>>
+		       <COND (<EQUAL? ,PRSI ,FEW-STEPS>
+			      <SETG PRSI ,NORTH-STAIRS>)>
+		       <SETG ROPE-PLACED ,PRSI>
+		       <TELL "The rope descends into the " D ,PRSI "." CR>
+		       <MOVE ,ROPE ,HERE>
+		       <COND (<EQUAL? ,PRSI ,NORTH-STAIRS>
+			      <SETG LANDING ,LANDING-ZERO>)
+			     (<EQUAL? ,PRSI ,SOUTH-STAIRS>
+			      <SETG LANDING ,LANDING-TWO>)
+			     (<EQUAL? ,PRSI ,EAST-STAIRS>
+			      <SETG LANDING ,LANDING-ONE>)
+			     (<EQUAL? ,PRSI ,WEST-STAIRS>
+			      <SETG LANDING ,LANDING-THREE>)
+			     (T
+			      <SETG LANDING ,LANDING-ZERO>)>
+		       <RTRUE>)
+		      (ELSE
+		       <RFALSE>)>)
+	       (<VERB? TAKE>
+		<FCLEAR ,ROPE ,NDESCBIT>
+		<RFALSE>)
+	       (<VERB? CLIMB-UP CLIMB-DOWN CLIMB-FOO>
+		<COND (<AND <VERB? CLIMB-UP>
+			    <ROOM? ,CHAMBER-OF-RA>>
+		       <TELL "The rope doesn't go up." CR>
+		       <RFATAL>)>
+		<SETG ROPE-HACK T>
+		<RFALSE>)>>
+
+<OBJECT NOTE
+	(IN TENT2)
+	(FLAGS READBIT BURNBIT TAKEBIT)
+	(DESC "farewell note")
+	(FDESC
+"Tacked up to the inside of one of the tent flaps is a note.")
+	(TEXT
+"The note reads:|
+|
+Fi aman Allah!
+|
+Hereafter you shall pursue your fool dream of the hidden pyramid and its riches
+alone. May the jackals feed well on your bones. We have left you what you need
+to get back, though we hope you do not. We put several things you treasure
+above life itself inside your trunk, locked with your precious padlock, but we
+could not bear to part with the key. Especially after what you said of our
+rites. We hope the drug we placed in your drink did you harm. If not, we are at
+least satisfied you slept especially soundly while we cleaned out the camp.|
+|
+Farewell")
+	(SYNONYM NOTE)
+	(ADJECTIVE FAREWE)
+	(SIZE 1)>
+
+<OBJECT GLOBAL-WATER
+	(IN LOCAL-GLOBALS)
+	(FLAGS DRINKBIT NDESCBIT)
+	(DESC "quantity of water")
+	(SYNONYM WATER)
+	>
+
+<OBJECT WATER
+	(IN CANTEEN)
+	(FLAGS DRINKBIT)
+	(DESC "quantity of water")
+	(SYNONYM WATER)
+	(SIZE 3)>
+
+<OBJECT CANTEEN
+	(IN KNAPSACK)
+	(FLAGS CONTBIT TAKEBIT TOUCHBIT)
+	(DESC "canteen")
+	(SYNONYM CANTEE)
+	(ADJECTIVE SMALL)
+	(CAPACITY 5)
+	(SIZE 6)
+	(ACTION CANTEEN-FCN)>
+	
+<GLOBAL SANDY-CANTEEN <>>
+<GLOBAL SAND-FILLED <>>
+
+<ROUTINE CANTEEN-FCN ()
+	 <COND (<VERB? SHAKE>
+		<COND (<NOT <FSET? ,CANTEEN ,OPENBIT>>
+		       <COND (<AND <IN? ,WATER ,CANTEEN>
+				   <G? ,WATER-LEFT 9>>
+			      <TELL "Some water sloshes around inside." CR>
+			      <RTRUE>)
+			     (,SAND-FILLED
+			      <TELL "Some sand shakes around inside." CR>
+			      <RTRUE>)
+			     (T
+			      <TELL "It's empty." CR>)>)
+		      (<IN? ,WATER ,CANTEEN>
+		       <TELL
+"All the water spills out and quickly evaporates. Another smart move."
+			     CR>
+		       <REMOVE ,WATER>
+		       <SETG WATER-LEFT 0>
+		       <RTRUE>)
+		      (,SAND-FILLED
+		       <TELL "You empty the canteen of most of the sand." CR>
+		       <SETG SAND-FILLED <>>
+		       <REMOVE ,C-SAND>
+		       <FSET ,C-SAND ,NDESCBIT>
+		       <RTRUE>)
+		      (T
+		       <TELL 
+"Okay, but shaking an empty canteen will get you nowhere fast." CR>
+		       <RTRUE>)>)
+	       (<AND <VERB? FILL>
+		     <EQUAL? ,PRSI ,SAND>>
+		<COND (<NOT <GETP ,HERE ,P?MAP>>
+		       <TELL "I see no sand here." CR>)
+		      (<NOT <FSET? ,CANTEEN ,OPENBIT>>
+		     <TELL "It would help if you opened the canteen first." CR>
+		       <RTRUE>)
+		      (T
+		       <TELL "Okay. The canteen has been filled with sand.">
+		       <COND (,WATER-LEFT
+			      <SETG WATER-LEFT 0>
+			      <REMOVE ,WATER>
+			      <TELL
+" So much for the water that was left in it.">)>
+		       <CRLF>
+		       <SETG SANDY-CANTEEN T>
+		       <SETG SAND-FILLED T>
+		       <MOVE ,C-SAND ,CANTEEN>
+		       <FCLEAR ,C-SAND ,NDESCBIT>)>
+		<RTRUE>)
+	       (<AND <PRSI? ,CANTEEN>
+		     <VERB? PUT>
+		     <NOT <EQUAL? ,PRSO ,SAND ,GLOBAL-WATER ,C-SAND>>>
+	        <TELL
+"That would void the manufacturer's warranty on the canteen." CR>)>>
+
+<OBJECT SMALL-SLIP
+	(FLAGS READBIT TAKEBIT BURNBIT VOWELBIT)
+	(DESC "inspection sticker")
+	(TEXT
+"The small inspection sticker says:
+|
+This trunk inspected by numbers 8 and 6.5. This reality was manufactured by
+tiny elves from the Bozbar Pyramid Construction Company, a jointly-owned
+subsidiary of the FrobozzCo Magic Village Industries, Michael Berlyn and
+Patricia Fogleman, Chief Engineers.")
+	(SYNONYM STICKE)
+	(ADJECTIVE INSPEC)>
+
+<ROOM ENDLESS-DESERT
+      (IN ROOMS)
+      (DESC "Desert")
+      (FLAGS RLANDBIT ONBIT)
+      (LDESC
+"You are in the desert, a vast wasteland of sand and heat.")
+      (UP "Without a helicopter?")
+      (DOWN "Let's not rush things.")
+      (ACTION DESERT-EXIT-FCN)
+      (CAPACITY 0)
+      (GLOBAL SAND MIRAGES)>
+
+<OBJECT MIRAGES
+	(IN LOCAL-GLOBALS)
+	(DESC "mirage")
+	(FLAGS NDESCBIT)
+	(SYNONYM GORT KLAATU FISH BUFFAL)
+	(ADJECTIVE LIZARD MAIDS SNAIL GYROCO)
+	(ACTION MIRAGES-F)>
+
+<ROUTINE MIRAGES-F ()
+	 <TELL
+"Come on! This life you're leading is bad enough -- don't waste your life on
+illusions." CR>
+	 <RTRUE>>
+
+<GLOBAL TOLD-IT <>>
+
+<ROUTINE DESERT-EXIT-FCN (RARG "AUX" (END-OF-TBL 26) (OFFS 0) (NEW-ROOM <>)
+			  OLD-DESERT)
+	 <COND (<EQUAL? .RARG ,M-END>
+		<COND (<AND <VERB? DROP>
+			    <PROB 33>
+			    <NOT ,TOLD-IT>>
+		       <TABLE-TO-DESERT ,DESERT-LOC>
+		       <REMOVE ,PRSO>
+		       <TELL
+"A brief but strong gust of wind comes up off a dune, whipping sand in your
+face, blinding you for long enough to lose track of the " D ,PRSO "." CR>
+		       <SETG TOLD-IT T>)>
+		<RTRUE>)
+	       (<EQUAL? .RARG ,M-LOOK>
+		<DESCRIBE-HOLE-FCN ,M-LOOK>
+		<SETG TOLD-IT <>>
+		<RTRUE>)
+	       (<NOT <EQUAL? .RARG ,M-BEG>>
+		<RFALSE>)
+	       (<OR <NOT <VERB? WALK>>
+		    <EQUAL? ,PRSO ,P?UP ,P?DOWN>>
+		<SETG TOLD-IT <>>
+		<RFALSE>)>
+	 <SETG TOLD-IT <>>
+	 <SETG THIRST <+ ,THIRST 15>>
+	 <SET OLD-DESERT ,DESERT-LOC>
+	 <CHANGE-DESERT-POSITION>
+	 <REPEAT ()
+		 <COND (<EQUAL? .OFFS .END-OF-TBL>
+			<RETURN>)
+		       (ELSE
+			<COND (<EQUAL? ,DESERT-LOC <GET ,REENTRY-TBL .OFFS>>
+			       <SET NEW-ROOM <GET ,REENTRY-TBL <+ .OFFS 1>>>
+			       <RETURN>)
+			      (ELSE
+			       <SET OFFS <+ .OFFS 2>>)>)>>
+	 <DESERT-TO-TABLE .OLD-DESERT>
+	 <PROP-TO-TBL .OLD-DESERT>
+	 <COND (<NOT .NEW-ROOM>
+		<FCLEAR ,HERE ,TOUCHBIT>
+		<SET NEW-ROOM ,ENDLESS-DESERT>
+		<TABLE-TO-DESERT ,DESERT-LOC>
+		<TBL-TO-PROP ,DESERT-LOC>)
+	       (ELSE
+		<TBL-TO-PROP .OLD-DESERT>)>
+	 <GOTO .NEW-ROOM>
+	 <RTRUE>>
+	 
+<GLOBAL REENTRY-TBL
+	<TABLE 651 P1 652 P2 653 P3 654 EX1 655 EX2
+	       656 EX3 706 EX6 751 P6 752 P7 753 P8
+	       754 EX7 755 EX8 756 EX9>>
+
+<ROUTINE DESERT-TO-TABLE (SLOC "AUX" (TBL ,DESERT-TABLE) (CNT 0)
+			  (F <FIRST? ,ENDLESS-DESERT>) N)
+	 <REPEAT ()
+		 <COND (.F <SET N <NEXT? .F>>)
+		       (ELSE <RETURN>)>
+		 <COND (<EQUAL? .F ,WINNER>)
+		       (<FSET? .F ,TAKEBIT>
+			<REPEAT ()
+				<COND (<==? <GET .TBL .CNT> 0>
+				       <PUT .TBL .CNT .SLOC>
+				       <PUT .TBL <+ .CNT 1> .F>
+				       <SET CNT <+ .CNT 2>>
+				       <REMOVE .F>
+				       <RETURN>)
+				      (ELSE
+				       <SET CNT <+ .CNT 2>>)>>)>
+		 <SET F .N>>>
+
+<ROUTINE TABLE-TO-DESERT (SLOC
+			 "AUX" (TBL ,DESERT-TABLE) (CNT 0))
+	 <REPEAT ()
+		 <COND (<NOT <L? .CNT 100>>
+			<RETURN>)
+		       (<==? <GET .TBL .CNT> .SLOC>
+			<PUT .TBL .CNT 0>
+			<MOVE <GET .TBL <+ .CNT 1>> ,ENDLESS-DESERT>)>
+		 <SET CNT <+ .CNT 2>>>>
+
+<GLOBAL DESERT-LOC 0>
+<CONSTANT DESERT-START 10000>
+
+<GLOBAL DESERT-TABLE ;"length should be 2*number of takeable objects"
+	<TABLE 0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0>>
+
+<GLOBAL DESERT-HACK 0>
+
+<ROUTINE CHANGE-DESERT-POSITION ()
+	 <SETG DESERT-HACK <+ ,DESERT-HACK 1>>
+	 <COND (<EQUAL? ,DESERT-HACK 10>
+		<TELL 
+"WARNING: The Surgeon General has determined that wandering about like this is
+dangerous to your health." CR>
+		<CRLF>)
+	       (<EQUAL? ,DESERT-HACK 20>
+		<COND (<ROB-HIM-BLIND>
+		       <TELL
+"You start dropping things to lighten your load. Before you know it, you're
+empty-handed. A gust of wind comes up off the dune before you, covering over
+what you've dropped. So much for that." CR>
+		       <CRLF>)>)>
+	 <COND (<EQUAL? ,PRSO ,P?NORTH>
+		<SETG DESERT-LOC <- ,DESERT-LOC 50>>
+		<FIX-LON-LAT 0 2>)
+	       (<EQUAL? ,PRSO ,P?NE>
+		<SETG DESERT-LOC <- ,DESERT-LOC 49>>
+		<FIX-LON-LAT 2 2>)
+	       (<EQUAL? ,PRSO ,P?EAST>
+		<SETG DESERT-LOC <+ ,DESERT-LOC 1>>
+		<FIX-LON-LAT 2 0>)
+	       (<EQUAL? ,PRSO ,P?SE>
+		<SETG DESERT-LOC <+ ,DESERT-LOC 51>>
+		<FIX-LON-LAT 2 -2>)
+	       (<EQUAL? ,PRSO ,P?SOUTH>
+		<SETG DESERT-LOC <+ ,DESERT-LOC 50>>
+		<FIX-LON-LAT 0 -2>)
+	       (<EQUAL? ,PRSO ,P?SW>
+		<SETG DESERT-LOC <+ ,DESERT-LOC 49>>
+		<FIX-LON-LAT -2 -2>)
+	       (<EQUAL? ,PRSO ,P?WEST>
+		<SETG DESERT-LOC <- ,DESERT-LOC 1>>
+		<FIX-LON-LAT -2 0>)
+	       (<EQUAL? ,PRSO ,P?NW>
+		<SETG DESERT-LOC <- ,DESERT-LOC 51>>
+		<FIX-LON-LAT -2 2>)>>
+
+<ROUTINE FIX-LON-LAT (INC-LON INC-LAT)
+	 <COND (.INC-LON
+		<SETG SECS-LON <+ ,SECS-LON .INC-LON>>
+		<COND (<G? ,SECS-LON 60>
+		       <SETG SECS-LON 1>
+		       <SETG MINS-LON <+ ,MINS-LON 1>>
+		       <COND (<G? ,MINS-LON 59>
+			      <SETG MINS-LON 0>
+			      <SETG DEGS-LON <+ ,DEGS-LON 1>>)>)
+		      (<L? ,SECS-LON 1>
+		       <SETG SECS-LON 59>
+		       <SETG MINS-LON <- ,MINS-LON 1>>
+		       <COND (<L? ,MINS-LON 0>
+			      <SETG MINS-LON 59>
+			      <SETG DEGS-LON <- ,DEGS-LON 1>>)>)>)>
+	 <COND (.INC-LAT
+		<SETG SECS-LAT <+ ,SECS-LAT .INC-LAT>>
+		<COND (<G? ,SECS-LAT 60>
+		       <SETG SECS-LAT 1>
+		       <SETG MINS-LAT <+ ,MINS-LAT 1>>
+		       <COND (<G? ,MINS-LAT 59>
+			      <SETG MINS-LAT 0>
+			      <SETG DEGS-LAT <+ ,DEGS-LAT 1>>)>)
+		      (<L? ,SECS-LAT 1>
+		       <SETG SECS-LAT 59>
+		       <SETG MINS-LAT <- ,MINS-LAT 1>>
+		       <COND (<L? ,MINS-LAT 0>
+			      <SETG MINS-LAT 59>
+			      <SETG DEGS-LAT <- ,DEGS-LAT 1>>)>)>)>>
+
+<ROUTINE ROB-HIM-BLIND ("AUX" F N (FLG <>))
+	 <SET F <FIRST? ,WINNER>>
+	 <REPEAT ()
+		 <COND (<NOT .F>
+			<RETURN>)
+		       (T
+			<SET N .F>
+			<SET F <NEXT? .N>>
+			<REMOVE .N>
+			<SET FLG T>)>>
+	 .FLG>
+	 
+
+<GLOBAL SECS-LAT 0>
+<GLOBAL SECS-LON 0>
+<GLOBAL MINS-LAT 0>
+<GLOBAL MINS-LON 0>
+<GLOBAL DEGS-LAT 0>
+<GLOBAL DEGS-LON 0>
+
+<GLOBAL PROP-TBL
+	<TABLE 0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0>>
+
+<ROUTINE PROP-TO-TBL (SLOC "AUX" (TBL ,PROP-TBL) (CNT 0) DUG)
+	 <SET DUG <GETP ,HERE ,P?CAPACITY>>
+	 <COND (<EQUAL? .DUG 0>
+		<RFALSE>)>
+	 <REPEAT ()
+		 <COND (<==? <GET .TBL .CNT> 0>
+			<PUT .TBL .CNT .SLOC>
+			<PUT .TBL <+ .CNT 1> .DUG>
+			<PUTP ,HERE ,P?CAPACITY 0> ;"Huh?"
+			<SET CNT <+ .CNT 2>>
+			<RETURN>)
+		       (ELSE
+			<SET CNT <+ .CNT 2>>)>>>
+
+<ROUTINE TBL-TO-PROP (SLOC "AUX" (TBL ,PROP-TBL) (CNT 0))
+	 <REPEAT ()
+		 <COND (<NOT <L? .CNT 120>>
+			<RETURN>)
+		       (<==? <GET .TBL .CNT> .SLOC>
+			<PUT .TBL .CNT 0>
+			<PUTP ,HERE ,P?CAPACITY <GET .TBL <+ .CNT 1>>>)>
+		 <SET CNT <+ .CNT 2>>>>
+
+<OBJECT C-SAND
+	(FLAGS NDESCBIT)
+	(DESC "quantity of sand")
+	(SYNONYM SAND)>
+		       
+<OBJECT KNAPSACK
+	(IN TENT2)
+	(DESC "knapsack")
+	(FLAGS TRYTAKEBIT TAKEBIT CONTBIT SEARCHBIT)
+	(SIZE 5)
+	(CAPACITY 60)
+	(SYNONYM SACK KNAPSA)
+	(ADJECTIVE KNAP)
+	(FDESC
+"Sitting in the sand, bulging a little, is a beaten-up knapsack.")
+	(ACTION WEAR-THE-SACK)>
+
+<ROUTINE WEAR-THE-SACK ("AUX" ON-IN?)
+	 <SET ON-IN? "in">
+	 <COND (<EQUAL? ,KNAPSACK ,PRSO>
+		<COND (<VERB? WEAR>
+		       <COND (<NOT <IN? ,KNAPSACK ,WINNER>>
+			      <COND (<NOT <ITAKE>>
+				     <RTRUE>)
+				    (T
+				     <COND (<NOT <EQUAL? ,PRSI ,NASTY-CROC>>
+					    <TELL "(taken)" CR>)
+					   (T
+					    <TELL "(wearing it)" CR>)>)>)>
+		       <TELL 
+"You swing the knapsack over your shoulders and it settles on your back as its
+cover flap closes." CR>
+		       <FCLEAR ,KNAPSACK ,OPENBIT>
+		       <FSET ,KNAPSACK ,WEARBIT>
+		       <THIS-IS-IT ,KNAPSACK>)
+		      (<AND <VERB? PUT PUT-ON>
+			    <EQUAL? ,PRSI ,ME>>
+		       <PERFORM ,V?WEAR ,KNAPSACK>
+		       <THIS-IS-IT ,KNAPSACK>
+		       <RTRUE>)
+		      (<AND <VERB? PUT PUT-ON>
+			    ,PRSI>
+		       <COND (<EQUAL? ,PRSI ,KNAPSACK>
+			      <TELL "Sure. Just like a Klein Bottle, eh?" CR>
+			      <RTRUE>)
+			     (<EQUAL? ,PRSI ,CRACK>
+			      <PERFORM ,PRSA ,PRSO ,GROUND>
+			      <RTRUE>)
+			     (<PRSI? ,FOLDED-COT>
+			      <TELL "Bizarre!" CR>
+			      <RTRUE>)
+			     (<NOT <FSET? ,KNAPSACK ,WEARBIT>>
+			      <RFALSE>)
+			     (T
+			      <COND (<AND <EQUAL? ,PRSI ,GROUND>
+					  <GETP ,HERE ,P?MAP>
+					  <NOT <IN-A-TENT?>>>
+				     <SETG PRSI ,SAND>)>
+			      <COND (<FSET? ,PRSI ,SURFACEBIT>
+				     <SET ON-IN? "on">)>
+			      <COND (<AND <EQUAL? ,HERE ,WEST-END-OF-PASSAGE>
+					  <NOT <FSET? ,PIT ,INVISIBLE>>
+					  <EQUAL? ,PRSI ,PIT ,GROUND>>
+				     <TELL "Dropped." CR>
+				     <SETG P-IT-LOC <>>)
+				    (T <TELL
+"You take the knapsack off and place it " .ON-IN? " the " D ,PRSI
+". As it settles " .ON-IN? " the " D ,PRSI ", the cover flaps open." CR>)>
+			      <FCLEAR ,KNAPSACK ,WEARBIT>
+			      <FSET ,KNAPSACK ,OPENBIT>
+			      <COND (<EQUAL? ,PRSI ,GROUND ,SAND>
+				     <IDROP>)
+				    (T
+				     <MOVE ,KNAPSACK ,PRSI>)>
+			      <THIS-IS-IT ,KNAPSACK>
+			      <RTRUE>)>)
+		      (<AND <VERB? OPEN>
+			    <FSET? ,KNAPSACK ,WEARBIT>>
+		       <TELL 
+"You reach around behind to lift the flap on the top of the knapsack, but it
+keeps falling back down." CR>
+		       <THIS-IS-IT ,KNAPSACK>
+		       <RTRUE>)
+		      (<AND <VERB? SHAKE>
+			    <FSET? ,KNAPSACK ,WEARBIT>>
+		       <TELL
+"Better take it off first. Unless you want to do a few headstands." CR>
+		       <THIS-IS-IT ,KNAPSACK>
+		       <RTRUE>)
+		      (<VERB? FIND>
+		       <COND (<FSET? ,KNAPSACK ,WEARBIT>
+			      <TELL "It's on your back!" CR>
+			      <RTRUE>)
+			     (T
+			      <RFALSE>)>)
+		      (<AND <VERB? LOOK-INSIDE EXAMINE>
+			    <FSET? ,KNAPSACK ,WEARBIT>>
+		       <TELL
+"Your neck doesn't crane back that far. Better take it off first." CR>
+		       <THIS-IS-IT ,KNAPSACK>
+		       <RTRUE>)
+		      (<VERB? DISEMBARK DROP>
+		       <COND (<NOT <FSET? ,KNAPSACK ,WEARBIT>>
+			      <TELL "You aren't wearing it!" CR>
+			      <RTRUE>)
+			     (T
+			      <COND (<AND <EQUAL? ,HERE ,WEST-END-OF-PASSAGE>
+					  <NOT <FSET? ,PIT ,INVISIBLE>>>
+				     <TELL "Dropped." CR>
+				     <SETG P-IT-LOC <>>)
+				    (T <TELL
+"You take the knapsack off and place it down. As it settles, the cover flaps
+open." CR>)>
+			      <FCLEAR ,KNAPSACK ,WEARBIT>
+			      <FSET ,KNAPSACK ,OPENBIT>
+			      <IDROP>
+			      <THIS-IS-IT ,KNAPSACK>
+			      <RTRUE>)>)
+		      (<VERB? TAKE>
+		       <COND (<AND <FSET? ,PRSO ,WEARBIT>
+			           <OR <EQUAL? <GET ,P-VTBL 0> ,W?REMOVE>
+				       <EQUAL? ,PRSI ,ME>>>
+			      <PERFORM ,V?DISEMBARK ,PRSO>
+			      <RTRUE>)
+			     (T
+			      <COND (<NOT <FSET? ,PRSO ,WEARBIT>>
+				     <PERFORM ,V?WEAR ,PRSO ,NASTY-CROC>
+				     <RTRUE>)
+				    (T <TELL "You already have it." CR>
+				     <RTRUE>)>)>)>)
+	       (<EQUAL? ,KNAPSACK ,PRSI>
+		<COND (<VERB? PUT>
+		       <COND (<FLAMING? ,PRSO>
+			      <TELL
+"Don't you think you should put out the " D ,PRSO " first?" CR>
+			      <RTRUE>)
+			     (<PRSO? ,SHOVEL ,BEAM ,CRATE>
+			      <TELL
+"That's like trying to fit a Beethoven Symphony into a music box." CR>
+			      <RTRUE>)
+			     (<PRSO? ,SAND ,WATER ,GLOBAL-WATER>
+			      <TELL 
+"It would only seep through the roughly-stitched seams, so why bother?" CR>
+			      <RTRUE>)
+			     (T
+			      <FSET ,PRSO ,TOUCHBIT>
+			      <RFALSE>)>)
+		      (<VERB? TAKE>
+		       <COND (<FSET? ,KNAPSACK ,OPENBIT>
+			      <RFALSE>)
+			     (<FSET? ,KNAPSACK ,WEARBIT>
+			      <TELL 
+"Your arms don't reach back that far, and groping around in the sack isn't the
+best of ideas. It would help if you took it off first." CR>
+			      <THIS-IS-IT ,KNAPSACK>
+			      <RTRUE>)
+			     (T
+			      <TELL "The knapsack isn't open." CR>
+			      <THIS-IS-IT ,KNAPSACK>
+			      <RTRUE>)>)
+		      (ELSE
+		       <RFALSE>)>)
+	       (T
+		<RFALSE>)>>
+
+<OBJECT CRATE
+	(IN GLOBAL-OBJECTS)
+	(DESC "packing crate")
+	(FLAGS CONTBIT TRANSBIT TAKEBIT BURNBIT SEARCHBIT READBIT SURFACEBIT
+	       OPENBIT)
+	(CAPACITY 10)
+	(SIZE 10)
+	(SYNONYM CRATE LABEL)
+	(ADJECTIVE PACKIN)
+	(FDESC
+"Lying in the sand is a wooden packing crate.")
+	(ACTION CRATE-FCN)>
+
+<ROUTINE CRATE-FCN ("AUX" (FLG <>))
+	 <COND (<AND <VERB? READ EXAMINE>
+		     <OR <IN? ,CRATE <LOC ,WINNER>>
+			 <IN? ,CRATE ,HERE>
+			 <IN? ,CRATE ,WINNER>
+			 <EQUAL? <LOC ,CRATE> <LOC ,WINNER>>
+			 <EQUAL? <LOC ,CRATE> ,WINNER>
+			 <AND <IN? ,CRATE ,KNAPSACK>
+			      <EQUAL? <LOC ,KNAPSACK> ,HERE>>>>
+		<TELL
+"The crate is slightly beaten up from the landing, but it seems to have held
+together fairly well. There's a small label on it that says \"This crate
+contains 1 (one) black box (tm).\"" CR>
+		<RTRUE>)
+	       (<AND <VERB? EXAMINE>
+		     <IN? ,CRATE ,GLOBAL-OBJECTS>
+		     <NOT <IN-A-TENT?>>
+		     <G? ,MOVES 4>>
+		<TELL 
+		 "It's coming down, and it looks like it should land near you!" CR>)
+	       (<AND <VERB? EXAMINE>
+		     <IN? ,CRATE ,GLOBAL-OBJECTS>
+		     <IN-A-TENT?>>
+		<TELL "I think you've got crates on the mind!" CR>)
+	       (<AND <VERB? MUNG>
+		     <NOT <IN? ,CRATE ,GLOBAL-OBJECTS>>>
+		<COND (<PRSI? ,SHOVEL ,PICK-AXE>
+		       <TELL 
+"Wood chips fly from the crate, hurtling into the sand all around, as the crate
+suffers your frenzied attack. The defenseless packing crate looks as if to flee
+but before it can react (growing legs is a time-consuming task) there is
+nothing left of it but a mere memory. (You really should seek some
+psychological counselling.)" CR>
+		       <COND (<NOT <FSET? ,BLACK-BOX ,TOUCHBIT>>
+			      <MOVE ,BLACK-BOX ,HERE>
+			      <FSET ,BLACK-BOX ,RMUNGBIT>)>
+		       <REMOVE ,PRSO>
+		       <SETG P-IT-LOC <>>
+		       <RTRUE>)>)
+	       (<AND <NOT <IN? ,CRATE ,GLOBAL-OBJECTS>>
+		     <OR <VERB? BURN>
+			 <AND <VERB? DROP>
+			      <PRSI? ,CRATE>
+			      <FLAMING? ,PRSO>>>>
+		<TELL
+"Well, who would have thought it? The crate catches fire quickly, the flames
+leaping about in mad abandon, gaily changing color as the heat becomes more and
+more intense. You hear a sizzling">
+		<COND (<NOT <FSET? ,BLACK-BOX ,TOUCHBIT>>
+		       <JIGS-UP 
+"... followed by an explosion which takes place right before your face.
+Needless to say, your body didn't appreciate it.">)
+		      (T
+		       <TELL
+" as the crate consumes itself in gleeful merriment." CR>
+		       <REMOVE ,CRATE>
+		       <SETG P-IT-LOC <>>)>
+		<RTRUE>)
+	       (<VERB? STAND-UNDER>
+		<RFALSE>)
+	       (<AND <VERB? BOARD>
+		     <NOT <IN? ,CRATE GLOBAL-OBJECTS>>>
+		<TELL
+"You couldn't fit in there unless you put yourself through a trash compacter." CR> <RTRUE>)
+	       (<IN? ,CRATE ,GLOBAL-OBJECTS>
+		<TELL 
+"Hey, give it a chance to get here. I know you're impatient to get on with
+this, but be reasonable!" CR>
+		<RTRUE>)
+	       (<VERB? OPEN>
+		<TBL-TO-INSIDE ,CRATE ,CRATE-TBL
+"The crate opens slowly, the boards creaking with the strain.">
+		<RTRUE>)
+	       (<AND <VERB? CLOSE>
+		     <NOT <FSET? ,CRATE ,SURFACEBIT>>>
+		<COND (<AND <IN? ,TORCH ,CRATE>
+			    <FLAMING? ,TORCH>>
+		       <SET FLG T>)>
+		<INSIDE-OBJ-TO ,CRATE-TBL ,CRATE>
+		<COND (.FLG
+		       <KILL-TORCH T>)>
+		<RTRUE>)
+	       (<VERB? SHAKE>
+		<COND (<NOT <0? <GET ,CRATE-TBL 1>>>
+		       <TELL "Hmm. Something's in there." CR>
+		       <RTRUE>)>)>>
+		
+<GLOBAL CRATE-TBL ;"Thirty (30) slots to hold objects in the crate"
+	<LTABLE BLACK-BOX 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0 0
+	       0 0 0 0 0 0 0 0 0 0>>
+
+<OBJECT BLACK-BOX
+	(FLAGS TAKEBIT TRYTAKEBIT CONTBIT OPENBIT SURFACEBIT)
+	(DESC "navigation box")
+	(SYNONYM BOX)
+	(ADJECTIVE NAVIGA BLACK)
+	(CAPACITY 10)
+	(TEXT
+"This is an expensive, state-of-the-art piece of electronic equipment. It was
+designed to automatically determine longitude and latitude when the button on
+it is pressed. Thankfully, it has at last arrived.")
+	(ACTION BOX-OPENER-FCN)>
+
+<ROUTINE BOX-OPENER-FCN ()
+	 <COND (<VERB? OPEN>
+		<TELL "To do that to the " D ,BLACK-BOX " would most probably
+ruin the delicate equipment inside." CR>
+		<RTRUE>)
+	       (<VERB? CLOSE>
+		<TELL "I didn't know it was open." CR>
+		<RTRUE>)
+	       (<VERB? EXAMINE LOOK-INSIDE>
+		<TELL <GETP ,PRSO ,P?TEXT> CR>
+		<RTRUE>)
+	       (<VERB? LAMP-ON>
+		<PERFORM ,V?PUSH ,BUTTON>
+		<RTRUE>)
+	       (<VERB? LAMP-OFF>
+		<TELL "It turns itself off after each button press." CR>
+		<RTRUE>)
+	       (<AND <VERB? THROW THROW-DOWN MUNG ATTACK SHAKE>
+		     <EQUAL? ,PRSO ,BLACK-BOX>>
+		<TELL "Rattle, rattle, jostle, crunch. Oh oh..." CR>
+		<FSET ,BLACK-BOX ,RMUNGBIT>
+		<COND (<VERB? THROW THROW-DOWN>
+		       <MOVE ,PRSO ,HERE>)>
+		<RTRUE>)>>
+
+<OBJECT BUTTON
+	(IN BLACK-BOX)
+	(FLAGS NDESCBIT)
+	(DESC "button")
+	(SYNONYM BUTTON)
+	(ADJECTIVE NAVIGA)
+	(ACTION PRESS-BUTTON-FCN)>
+
+<GLOBAL NOISES-LTBL
+	<LTABLE "Crinkle fweep" "Bleeeeeeeeeep" "Sproing" "Screetchle frop"
+		"Breeble grungle">>
+
+<ROUTINE PRESS-BUTTON-FCN ("AUX" (OFFS -3) LAT-S LON-S H-CK)
+	 <COND (<VERB? PUSH>
+	        <COND (<FSET? ,BLACK-BOX ,RMUNGBIT>
+		       <TELL <PICK-ONE ,NOISES-LTBL> "!" CR>
+		       <RTRUE>)
+		      (<EQUAL? ,HERE ,ENDLESS-DESERT>
+		       <TELL 
+"The box comes to life, its L.E.D.s lighting, and then flashes " N ,DEGS-LAT>
+		       <TELL " degree">
+		       <COND (<NOT <EQUAL? ,DEGS-LAT 1>>
+			      <TELL "s">)>
+		       <TELL " " N ,MINS-LAT " minute">
+		       <COND (<NOT <EQUAL? ,MINS-LAT 1>>
+			      <TELL "s">)>
+		       <TELL " " N ,SECS-LAT " seconds N latitude, ">
+		       <TELL N ,DEGS-LON>
+		       <TELL " degree">
+		       <COND (<NOT <EQUAL? ,DEGS-LON 1>>
+			      <TELL "s">)>
+		       <TELL " " N ,MINS-LON " minute">
+		       <COND (<NOT <EQUAL? ,MINS-LON 1>>
+			      <TELL "s">)>
+		       <TELL " " N ,SECS-LON " seconds E longitude."  CR>)
+		      (<NOT <GETP ,HERE ,P?MAP>>
+		       <TELL 
+"There's no need for that here. It's obvious where you are." CR>
+		       <RTRUE>)
+		      (T
+		       <COND (<EQUAL? ,HERE ,TENT>
+			      <SET H-CK ,P2>)
+			     (<EQUAL? ,HERE ,TENT2>
+			      <SET H-CK ,P7>)
+			     (<EQUAL? ,HERE ,SUPPLY-TENT>
+			      <SET H-CK ,P4>)
+			     (ELSE
+			      <SET H-CK ,HERE>)>
+		        <REPEAT ()
+			       <SET OFFS <+ .OFFS 3>>
+			       <COND (<G? .OFFS 54>
+				      <RETURN>)
+				     (T
+				      <COND (<EQUAL? .H-CK
+						     <GET ,MAP-TBL .OFFS>>
+					     <SET LON-S
+						  <GET ,MAP-TBL <+ .OFFS 1>>>
+					     <SET LAT-S
+						  <GET ,MAP-TBL <+ .OFFS 2>>>
+					     <RETURN>)>)>>
+		       <TELL 
+"The box comes to life, its L.E.D.s lighting, and then flashes 24 degrees 11
+minutes "
+			 N .LAT-S
+" seconds N latitude, 32 degrees 12 minutes "
+			 N .LON-S " seconds E longitude." CR>)>)
+	       (<VERB? FIND>
+		<TELL "It's on the top of the box." CR>
+		<RTRUE>)>>
+
+<ROUTINE DIASMBIGUATE-FCN (OBJECT)
+	 <COND (<IN? ,ONE-MATCH ,WINNER>
+		<RETURN ,ONE-MATCH>)
+	       (<IN? ,MATCHES ,WINNER>
+		<COND (<NOT <FSET? ,MATCHES ,OPENBIT>>
+		       <TELL "(opening matchbook first)" CR>
+		       <FSET ,MATCHES ,OPENBIT>)>
+		<COND (<G? ,MATCH-COUNT 1>
+		       <RETURN ,MANY-MATCHES>)
+		      (<EQUAL? ,MATCH-COUNT 1>
+		       <RETURN ,SINGLE-MATCH>)
+		      (ELSE
+		       <RETURN ,EMPTY-MATCHES>)>)
+	       (ELSE
+		<RETURN ,ONE-MATCH>)>>
+
+<GLOBAL MAP-TBL      ;" Loc    Long   Lat    seconds only!"
+	<TABLE    RIVER-BANK	33 	7
+		  	P1	35	7
+			P2	37	7
+			P3	39	7
+			EX1	41	7
+			EX2	43	7
+			EX3	45	7
+			P4	35	5
+			FIRE	37	5
+			P5 	39	5
+			EX4	41	5
+			EX5	43	5
+			EX6	45	5
+			P6	35	3 	
+			P7	37 	3 
+			P8	39 	3
+			EX7	41 	3 
+			EX8     43 	3 
+			EX9	45 	3>>
+
+
diff --git a/clock.zil b/clock.zil
new file mode 100644
index 0000000..af6fcc5
--- /dev/null
+++ b/clock.zil
@@ -0,0 +1,66 @@
+"CLOCK for
+			      INFIDEL
+	(c) Copyright 1983 Infocom, Inc.  All Rights Reserved.
+"
+
+<CONSTANT C-TABLELEN 180>
+
+<GLOBAL C-TABLE <ITABLE NONE 180>>
+
+<GLOBAL C-DEMONS 180>
+
+<GLOBAL C-INTS 180>
+
+<CONSTANT C-INTLEN 6>
+
+<CONSTANT C-ENABLED? 0>
+
+<CONSTANT C-TICK 1>
+
+<CONSTANT C-RTN 2>
+
+<ROUTINE DEMON (RTN TICK "AUX" CINT)
+	 #DECL ((RTN) ATOM (TICK) FIX (CINT) <PRIMTYPE VECTOR>)
+	 <PUT <SET CINT <INT .RTN T>> ,C-TICK .TICK>
+	 .CINT>
+
+<ROUTINE QUEUE (RTN TICK "AUX" CINT)
+	 #DECL ((RTN) ATOM (TICK) FIX (CINT) <PRIMTYPE VECTOR>)
+	 <PUT <SET CINT <INT .RTN>> ,C-TICK .TICK>
+	 .CINT>
+
+<ROUTINE INT (RTN "OPTIONAL" (DEMON <>) E C INT)
+	 #DECL ((RTN) ATOM (DEMON) <OR ATOM FALSE> (E C INT) <PRIMTYPE
+							      VECTOR>)
+	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
+	 <SET C <REST ,C-TABLE ,C-INTS>>
+	 <REPEAT ()
+		 <COND (<==? .C .E>
+			<SETG C-INTS <- ,C-INTS ,C-INTLEN>>
+			<AND .DEMON <SETG C-DEMONS <- ,C-DEMONS ,C-INTLEN>>>
+			<SET INT <REST ,C-TABLE ,C-INTS>>
+			<PUT .INT ,C-RTN .RTN>
+			<RETURN .INT>)
+		       (<EQUAL? <GET .C ,C-RTN> .RTN> <RETURN .C>)>
+		 <SET C <REST .C ,C-INTLEN>>>>
+
+<GLOBAL CLOCK-WAIT <>>
+
+<ROUTINE CLOCKER ("AUX" C E TICK (FLG <>))
+	 #DECL ((C E) <PRIMTYPE VECTOR> (TICK) FIX (FLG) <OR FALSE ATOM>)
+	 <COND (,CLOCK-WAIT <SETG CLOCK-WAIT <>> <RFALSE>)>
+	 <SET C <REST ,C-TABLE <COND (,P-WON ,C-INTS) (T ,C-DEMONS)>>>
+	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
+	 <REPEAT ()
+		 <COND (<==? .C .E>
+			<SETG MOVES <+ ,MOVES 1>>
+			<RETURN .FLG>)
+		       (<NOT <0? <GET .C ,C-ENABLED?>>>
+			<SET TICK <GET .C ,C-TICK>>
+			<COND (<0? .TICK>)
+			      (T
+			       <PUT .C ,C-TICK <- .TICK 1>>
+			       <COND (<AND <NOT <G? .TICK 1>>
+					   <APPLY <GET .C ,C-RTN>>>
+				      <SET FLG T>)>)>)>
+		 <SET C <REST .C ,C-INTLEN>>>>
diff --git a/crufty.zil b/crufty.zil
new file mode 100644
index 0000000..4a3cd00
--- /dev/null
+++ b/crufty.zil
@@ -0,0 +1,16 @@
+"(c) Copyright 1983 Infocom, Inc.  All Rights Reserved."
+
+<ROUTINE THIS-IT? (OBJ TBL "AUX" SYNS) 
+ <COND (<FSET? .OBJ ,INVISIBLE> <RFALSE>)
+       (<AND ,P-NAM
+	     <NOT <ZMEMQ ,P-NAM
+			 <SET SYNS <GETPT .OBJ ,P?SYNONYM>>
+			 <- </ <PTSIZE .SYNS> 2> 1>>>>
+	<RFALSE>)
+       (<AND ,P-ADJ
+	     <OR <NOT <SET SYNS <GETPT .OBJ ,P?ADJECTIVE>>>
+		 <NOT <ZMEMQB ,P-ADJ .SYNS <- <PTSIZE .SYNS> 1>>>>>
+	<RFALSE>)
+       (<AND <NOT <0? ,P-GWIMBIT>> <NOT <FSET? .OBJ ,P-GWIMBIT>>>
+	<RFALSE>)>
+ <RTRUE>>
diff --git a/cube.zil b/cube.zil
new file mode 100644
index 0000000..d31f114
--- /dev/null
+++ b/cube.zil
@@ -0,0 +1,395 @@
+"CUBE for
+			      INFIDEL
+	(c) Copyright 1983 Infocom, Inc.  All Rights Reserved.
+"
+
+<ROOM LANDING-ONE
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Cube")
+      (LDESC
+"You are in a room whose symmetry is uncanny, at least to the unaided eye: the
+dimensions of the room seem to form a perfect cube. There are three square
+doorways cut into the walls -- one to the north, and another to the west. A
+wide staircase leads up through the square doorway to the east.")
+      (UP TO CHAMBER-OF-RA)
+      (NORTH TO NE-BEND)
+      (WEST TO CENTRAL-ROOM)
+      (EAST TO CHAMBER-OF-RA)
+      (GLOBAL EAST-STAIRS)
+      (ACTION MOVE-PANEL-HERE)>
+
+<ROOM LANDING-THREE
+      (IN ROOMS)
+      (DESC "Cube")
+      (FLAGS RLANDBIT)
+      (LDESC
+"You are in a room whose walls, floor and ceiling seem to form a perfect cube.
+There are four square doorways cut into the walls -- to the north, the south,
+the east and the west. Through the west doorway you can see a flight of stairs
+heading up.")
+      (UP TO CHAMBER-OF-RA)
+      (WEST TO CHAMBER-OF-RA)
+      (NORTH TO NW-BEND)
+      (SOUTH TO SW-BEND)
+      (EAST TO CENTRAL-ROOM)
+      (GLOBAL WEST-STAIRS)
+      (ACTION MOVE-PANEL-HERE)>
+
+<ROOM CENTRAL-ROOM
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Cube")
+      (LDESC
+"You are in a room whose dimensions seem to measure a perfect cube. On the
+floor of this room is a series of symbols, inscribed in the stone. The walls
+bear strange pictures of a Queen, one of which shows her being wrapped in
+linen, another one showing her being lowered into what appears to be a solid
+gold sarcophagus. Four identical square doorways lead out of this chamber to
+the north, south, east and west.")
+      (NORTH TO NORTH-CENTER)
+      (SOUTH TO SOUTH-CENTER)
+      (EAST TO LANDING-ONE)
+      (WEST TO LANDING-THREE)
+      (GLOBAL HIEROGLYPHS PICTURES)>
+
+<ROOM NORTH-CENTER
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Cube")
+      (LDESC
+"You are in a room in the shape of a perfect cube. There are three square
+doorways cut into the walls -- one to the west, one to the east, and another
+to the south.")
+      (EAST TO NE-BEND)
+      (WEST TO NW-BEND)
+      (SOUTH TO CENTRAL-ROOM)>
+
+<ROOM SOUTH-CENTER
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Cube")
+      (LDESC
+"You are in a room whose symmetry is uncanny, at least to the unaided eye: the
+dimensions of the room seem to form a perfect cube. There are two square
+doorways cut into the walls -- one to the north, and another to the west.
+A panel, recessed into a wall, glows softly in your reflected light,
+while some hieroglyphs are visible above it.")
+      (NORTH TO CENTRAL-ROOM)
+      (WEST TO SW-BEND)
+      (EAST TO SECRET-PASSAGE IF BRICKS-PRESSED
+       ELSE "You can't go that way.")
+      (GLOBAL HIEROGLYPHS)
+      (ACTION SOUTH-CENTER-F)>
+
+<GLOBAL BRICKS-TBL
+	<TABLE BRICK-ONE BRICK-TWO BRICK-THREE BRICK-FOUR BRICK-FIVE
+	       BRICK-SIX BRICK-SEVEN BRICK-EIGHT BRICK-NINE>>
+
+<ROUTINE SOUTH-CENTER-F (RARG "AUX" (OFFS -1) BK)
+	 <COND (<NOT <EQUAL? .RARG ,M-END>>
+		<RFALSE>)>
+	 <REPEAT ()
+		 <SET OFFS <+ .OFFS 1>>
+		 <COND (<G? .OFFS 8>
+			<RFALSE>)
+		       (T
+			<SET BK <GET ,BRICKS-TBL .OFFS>>
+			<COND (<IN? .BK ,PUNCH-PANEL>
+			       <FSET .BK ,NDESCBIT>)>)>>>
+	 
+
+<GLOBAL BRICKS-PRESSED <>>
+
+<ROOM SW-BEND
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Cube")
+      (LDESC
+"You are in a room whose symmetry is uncanny, at least to the unaided eye: the
+dimensions of the room seem to form a perfect cube. There are two square
+doorways cut into the walls -- one to the north, and another to the east. The
+uncannily-shaped room seems to form a corner for this entire area.")
+      (NORTH TO LANDING-THREE)
+      (EAST TO SOUTH-CENTER)>
+
+<ROOM NE-BEND
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Cube")
+      (LDESC
+"You are in a room whose dimensions seem to form a perfect cube. There are two
+square doorways cut into the walls -- one to the south, and another to the
+west. This room seems to form a corner for this entire area.")
+      (WEST TO NORTH-CENTER)
+      (SOUTH TO LANDING-ONE)>
+       
+<ROOM NW-BEND
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Cube")
+      (LDESC
+"You are in a room whose shape is that of a perfect cube. There are two square
+doorways cut into the walls -- one to the south, and another to the east.")
+      (SOUTH TO LANDING-THREE)
+      (EAST TO NORTH-CENTER)>
+
+<ROUTINE MOVE-PANEL-HERE (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<COND (<EQUAL? ,HERE ,LANDING-ONE ,LANDING-THREE ,TINY-LANDING>
+		       <MOVE-ROPE-HERE ,M-ENTER>
+		       <FCLEAR ,ROPE ,NDESCBIT>)>)>
+	 <RFALSE>>
+
+<ROOM SECRET-PASSAGE
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Turning Passage")
+      (LDESC
+"You are in a strange, turning passageway. The floor here descends, reminding
+you of a ramp Craige once told you about -- a deep entrance into the depths of
+an Incan tomb. The ramp turns off toward the north. Judging from what you
+remember of the cube rooms, the ramp most probably passes beneath the
+ascending east staircase. Through the open doorway to the west you can still
+see one of the cube rooms.")
+      (NORTH TO TOP-OF-STAIRS) ;"Connection to ANTE"
+      (WEST TO SOUTH-CENTER)
+      (DOWN TO TOP-OF-STAIRS)
+      (OUT TO SOUTH-CENTER)>
+
+<OBJECT PUNCH-PANEL
+	(IN SOUTH-CENTER)
+	(DESC "recessed panel")
+	(FLAGS NDESCBIT OPENBIT CONTBIT DONTTAKE)
+	(SYNONYM PANEL)
+	(ADJECTIVE RECESS)
+	(CAPACITY 45)
+	(ACTION PUNCH-PANEL-FCN)>
+
+<GLOBAL NUM-TBL
+	<TABLE "no" "one" "two" "three" "four" "five" "six" "seven" "eight"
+	       "nine">>
+
+<GLOBAL DASH-STR
+ "-----------------------------">
+
+<GLOBAL EX-SP-EX-STR
+"!                           !">
+
+<ROUTINE PUNCH-PANEL-FCN ("AUX" NUM)
+	 <COND (<AND <VERB? PUT>
+		     <PRSI? ,PUNCH-PANEL>
+		     <NOT <GETP ,PRSO ,P?BRICK>>>
+		<TELL "It won't fit in there." CR>
+		<RTRUE>)
+	       (<VERB? EXAMINE LOOK-INSIDE READ>
+		<SET NUM <- 9 ,BRICKS-TAKEN>>
+		<TELL "There ">
+		<COND (<EQUAL? .NUM 1>
+		       <TELL "is ">)
+		      (ELSE <TELL "are ">)>
+		<TELL <GET ,NUM-TBL .NUM> " brick">
+		<COND (<NOT <EQUAL? .NUM 1>>
+		       <TELL "s">)>
+		<TELL " recessed into the panel">
+		<COND (<EQUAL? .NUM 0 1>
+		       <TELL "." CR>)
+		      (ELSE <TELL
+", three rows by three columns. These bricks look as if they could be easily
+removed and are marked with numerical symbols." CR>)>
+		<CRLF>
+		<TELL ,DASH-STR CR>
+		<TELL ,EX-SP-EX-STR CR>
+		<TELL "!  ">
+		<COND (<IN? ,BRICK-ONE ,PUNCH-PANEL>
+		       <TELL "<.>">)
+		      (T <TELL "   ">)>
+		<TELL "     ">
+		<COND (<IN? ,BRICK-TWO ,PUNCH-PANEL>
+		       <TELL "<:>">)
+		      (T <TELL "   ">)>
+		<TELL "     ">
+		<COND (<IN? ,BRICK-THREE ,PUNCH-PANEL>
+		       <TELL "<:.>">)
+		      (T <TELL "    ">)>
+		<TELL "     !" CR>
+		<TELL ,EX-SP-EX-STR CR>
+		<TELL "!  ">
+		<COND (<IN? ,BRICK-FOUR ,PUNCH-PANEL>
+		       <TELL "<::>">)
+		      (T <TELL "    ">)>
+		<TELL "    ">
+		<COND (<IN? ,BRICK-FIVE ,PUNCH-PANEL>
+		       <TELL "<::.>">)
+		      (T <TELL "     ">)>
+		<TELL "   ">
+		<COND (<IN? ,BRICK-SIX ,PUNCH-PANEL>
+		       <TELL "<:::>">)
+		      (T <TELL "     ">)>
+		<TELL "    !" CR>
+		<TELL ,EX-SP-EX-STR CR>
+		<TELL "!  ">
+		<COND (<IN? ,BRICK-SEVEN ,PUNCH-PANEL>
+		       <TELL "<:::.>">)
+		      (T <TELL "      ">)>
+		<TELL "  ">
+		<COND (<IN? ,BRICK-EIGHT ,PUNCH-PANEL>
+		       <TELL "<::::>">)
+		      (T <TELL"      ">)>
+		<TELL "  ">
+		<COND (<IN? ,BRICK-NINE ,PUNCH-PANEL>
+		       <TELL "<::::.>">)
+		      (T <TELL "       ">)>
+		<TELL "  !" CR>
+		<TELL ,EX-SP-EX-STR CR>
+		<TELL ,DASH-STR CR>
+		<RTRUE>)
+	       (<VERB? OPEN CLOSE>
+		<HOW? ,PUNCH-PANEL>
+		<RTRUE>)>>
+
+<OBJECT BRICK-ONE
+	(IN PUNCH-PANEL)
+	(FLAGS TAKEBIT NDESCBIT TOUCHBIT TRYTAKEBIT)
+	(DESC "first brick")
+	(SYNONYM BRICK BRICKS)
+	(ADJECTIVE FIRST)
+	(BRICK 1)
+	(TEXT
+"<.>")
+	(ACTION TAKE-BRICK-FCN)>
+
+<OBJECT BRICK-NINE
+	(IN PUNCH-PANEL)
+	(FLAGS TAKEBIT NDESCBIT TOUCHBIT TRYTAKEBIT)
+	(DESC "ninth brick")
+	(SYNONYM BRICK BRICKS)
+	(ADJECTIVE NINTH)
+	(TEXT
+"<::::.>")
+	(BRICK 9)
+	(ACTION TAKE-BRICK-FCN)>
+
+<OBJECT BRICK-EIGHT
+	(IN PUNCH-PANEL)
+	(FLAGS TAKEBIT NDESCBIT TOUCHBIT VOWELBIT TRYTAKEBIT)
+	(DESC "eighth brick")
+	(SYNONYM BRICK BRICKS)
+	(ADJECTIVE EIGHTH)
+	(TEXT
+"<::::>")
+	(BRICK 8)
+	(ACTION TAKE-BRICK-FCN)>
+
+<OBJECT BRICK-SEVEN
+	(IN PUNCH-PANEL)
+	(FLAGS TAKEBIT NDESCBIT TOUCHBIT TRYTAKEBIT)
+	(DESC "seventh brick")
+	(SYNONYM BRICK BRICKS)
+	(ADJECTIVE SEVENTH)
+	(TEXT
+"<:::.>")
+	(BRICK 7)
+	(ACTION TAKE-BRICK-FCN)>
+
+<OBJECT BRICK-SIX
+	(IN PUNCH-PANEL)
+	(FLAGS TAKEBIT NDESCBIT TOUCHBIT TRYTAKEBIT)
+	(DESC "sixth brick")
+	(SYNONYM BRICK BRICKS)
+	(ADJECTIVE SIXTH)
+	(TEXT
+"<:::>")
+	(BRICK 6)
+	(ACTION TAKE-BRICK-FCN)>
+	
+<OBJECT BRICK-FIVE
+	(IN PUNCH-PANEL)
+	(FLAGS TAKEBIT NDESCBIT TOUCHBIT TRYTAKEBIT)
+	(DESC "fifth brick")
+	(SYNONYM BRICK BRICKS)
+	(ADJECTIVE FIFTH)
+	(TEXT
+"<::.>")
+	(BRICK 5)
+	(ACTION TAKE-BRICK-FCN)>
+
+<OBJECT BRICK-FOUR
+	(IN PUNCH-PANEL)
+	(FLAGS TAKEBIT NDESCBIT TOUCHBIT TRYTAKEBIT)
+	(DESC "fourth brick")
+	(SYNONYM BRICK BRICKS)
+	(ADJECTIVE FOURTH)
+	(TEXT
+"<::>")
+	(BRICK 4)
+	(ACTION TAKE-BRICK-FCN)>
+
+<OBJECT BRICK-THREE
+	(IN PUNCH-PANEL)
+	(FLAGS TAKEBIT NDESCBIT TOUCHBIT TRYTAKEBIT)
+	(DESC "third brick")
+	(SYNONYM BRICK BRICKS)
+	(ADJECTIVE THIRD)
+	(TEXT
+"<:.>")
+	(BRICK 3)
+	(ACTION TAKE-BRICK-FCN)>
+
+<OBJECT BRICK-TWO
+	(IN PUNCH-PANEL)
+	(FLAGS TAKEBIT NDESCBIT TOUCHBIT TRYTAKEBIT)
+	(DESC "second brick")
+	(SYNONYM BRICK BRICKS)
+	(ADJECTIVE SECOND)
+	(TEXT
+"<:>")
+	(BRICK 2)
+	(ACTION TAKE-BRICK-FCN)>
+
+<GLOBAL BRICKS-TAKEN 0>
+<GLOBAL WRONG-BRICK <>>
+
+<ROUTINE TAKE-BRICK-FCN ()
+	 <COND (<AND <VERB? PUT>
+		     <EQUAL? ,PRSI ,PUNCH-PANEL>>
+		<FSET ,PRSO ,NDESCBIT>
+		<SETG BRICKS-TAKEN <- ,BRICKS-TAKEN 1>>
+		<RFALSE>)
+	       (<OR <NOT <VERB? TAKE>>
+		    <NOT <IN? ,PRSO ,PUNCH-PANEL>>>
+		<RFALSE>)>
+	 <COND (<EQUAL? <ITAKE> <>>
+		<RFATAL>)
+	       (T
+		<COND (<AND <EQUAL? ,BRICKS-TAKEN 0>
+			    <NOT <EQUAL? ,PRSO ,BRICK-ONE>>>
+		       <SETG WRONG-BRICK T>)
+		      (<AND <EQUAL? ,BRICKS-TAKEN 1>
+			    <NOT <EQUAL? ,PRSO ,BRICK-THREE>>>
+		       <SETG WRONG-BRICK T>)
+		      (<AND <EQUAL? ,BRICKS-TAKEN 2>
+			    <NOT <EQUAL? ,PRSO ,BRICK-FIVE>>>
+		       <SETG WRONG-BRICK T>)>
+		<SETG BRICKS-TAKEN <+ ,BRICKS-TAKEN 1>>
+		<COND (<NOT <IN? ,PRSO ,PUNCH-PANEL>>
+		       <FCLEAR ,PRSO ,NDESCBIT>)>
+		<COND (<AND <EQUAL? ,BRICKS-TAKEN 3>
+			    <NOT ,BRICKS-PRESSED>
+			    <NOT ,WRONG-BRICK>>
+		       <TELL
+"As soon as you grasp this brick a square doorway swings open. You leap back,
+unsure of what might happen, but quickly realize you've discovered a hidden
+passageway, making eastern movement from this cube room possible." CR>
+		       <SETG BRICKS-PRESSED T>
+		       <SETG SCORE <+ ,SCORE 25>>
+		       <PUTP ,SOUTH-CENTER ,P?LDESC
+"You are in a cubical-room whose walls, floor and ceiling are of an
+identical size. There are three square doorways cut into the walls --
+to the north, to the west, and a newly opened one to the east. Engraved
+on a wall are some hieroglyphs, while a panel, recessed in the same wall,
+glows softly in your reflected light.">
+		       <RTRUE>)
+		      (T
+		       <TELL "Taken." CR>
+		       <RTRUE>)>)>>
\ No newline at end of file
diff --git a/diamond.zil b/diamond.zil
new file mode 100644
index 0000000..4123361
--- /dev/null
+++ b/diamond.zil
@@ -0,0 +1,448 @@
+"DIAMOND for
+			      INFIDEL
+	(c) Copyright 1983 Infocom, Inc.  All Rights Reserved.
+"
+
+;"DIAMOND AREA"
+  
+<ROOM ROOM-OF-NEPHTHYS
+      (IN ROOMS)
+      (DESC "Room of Nephthys")
+      (FLAGS RLANDBIT)
+      (LDESC 
+"You have entered the room of the protective goddess Nephthys. The walls here
+are cut from pink granite, elaborately decorated with bright red carnelian and
+pale yellow feldspar. Along the northeast wall are panels of beaten gold, and
+midway up this wall, under the winged symbol of Nephthys, you can see some
+hieroglyphs. To the southeast, an opening has been cut in the thick granite
+wall.") 
+      (SE TO A-PRIME)
+      (OUT TO A-PRIME)
+      (GLOBAL HIEROGLYPHS DOORWAY PICTURE-PANELS GEMS-2)
+      (ACTION SCORE-RMS)>
+
+<OBJECT NEPHTH-JEWEL
+	(IN ROOM-OF-NEPHTHYS)
+	(FLAGS TAKEBIT)
+	(DESC "diamond cluster")
+	(VALUE 5)
+	(SIZE 2)
+	(FDESC
+"A large diamond cluster, glittering in your light, sits on the floor directly
+under the hieroglyphs.")
+	(SYNONYM CLUSTE)
+	(MAP 2)
+	(ADJECTIVE DIAMON)>
+
+<OBJECT HERRING-JEWEL
+	(IN LANDING-ZERO)
+	(FLAGS TAKEBIT)
+	(DESC "golden cluster")
+	(SIZE 2)
+	(FDESC
+"A large golden cluster sits on the floor.")
+	(SYNONYM CLUSTE)
+	(MAP 2)
+	(ADJECTIVE GOLDEN GOLD)>
+
+<OBJECT SELKIS-JEWEL
+	(IN ROOM-OF-SELKIS)
+	(FLAGS TAKEBIT)
+	(VALUE 5)
+	(SIZE 2)
+	(DESC "ruby cluster")
+	(FDESC
+"A beautiful ruby cluster, sparkling like fire, sits on the floor.")
+	(MAP 2)
+	(SYNONYM CLUSTE)
+	(ADJECTIVE RUBY)>
+
+<OBJECT ISIS-JEWEL
+	(IN ROOM-OF-ISIS)
+	(FLAGS TAKEBIT VOWELBIT)
+	(VALUE 5)
+	(SIZE 2)
+	(DESC "emerald cluster")
+	(FDESC
+"Lying on the ground is a brilliant, glowing emerald cluster.")
+	(MAP 2)
+	(SYNONYM CLUSTE)
+	(ADJECTIVE EMERAL)>
+
+<OBJECT NEITH-JEWEL
+	(IN ROOM-OF-NEITH)
+	(FLAGS TAKEBIT VOWELBIT)
+	(DESC "opal cluster")
+	(FDESC
+"An opal cluster, glistening with the light of a thousand fires, lies on the
+floor.")
+	(SYNONYM CLUSTE)
+	(ADJECTIVE OPAL)
+	(VALUE 5)
+	(MAP 2)
+	(SIZE 2)>
+
+<ROOM ROOM-OF-SELKIS
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Room of Selkis")
+      (LDESC 
+"You are standing in a small room, that of the protective goddess Selkis.
+There are red, blue and green patterns on the walls formed from small glazed
+tiles that have been carefully arranged in order of shade. The darkest tiles
+border the floor, and become lightest near the ceiling. On one wall,
+inscribed in a beaten gold panel, is the symbol of Selkis, under which you can
+see some hieroglyphic text. An opening through the southwest wall leads out
+of this room.")
+      (SW TO B-PRIME)
+      (OUT TO B-PRIME)
+      (GLOBAL HIEROGLYPHS DOORWAY GEMS-2 PICTURE-PANELS)
+      (ACTION SCORE-RMS)>
+
+<OBJECT TWINKLERS
+	(IN ROOM-OF-ISIS)
+	(FLAGS NDESCBIT DONTTAKE)
+	(DESC "quartz")
+	(SYNONYM LIGHTS QUARTZ CHIPS PATTER)
+	(ADJECTIVE THOUSA TINY)
+	(TEXT
+"They twinkle in the light, making beautiful patterns.")>
+
+<ROOM ROOM-OF-ISIS
+      (IN ROOMS)
+      (DESC "Room of Isis")
+      (FLAGS RLANDBIT)
+      (LDESC
+"This is the room of the protective goddess Isis. You stand in amazement
+in the center of the room as thousands of tiny lights twinkle around you.
+With great surprise you realize that the light from your torch is being
+reflected by the mirror-like surfaces of innumerable quartzite chips.
+These are set artfully into red clay panels in the walls, and are surrounded
+by shiny red jasper fragments. On the southwest wall, under the winged symbol
+of Isis, some hieroglyphic text is inscribed in a gold panel. To the northeast
+is an arched opening, and, looking through it, you can barely make out a
+hallway.")
+      (NE TO D-PRIME)
+      (OUT TO D-PRIME)
+      (GLOBAL HIEROGLYPHS PICTURE-PANELS GEMS DOORWAY)
+      (ACTION SCORE-RMS)>
+
+<ROOM ROOM-OF-NEITH
+      (IN ROOMS)
+      (DESC "Room of Neith")
+      (FLAGS RLANDBIT)
+      (LDESC
+"You are standing in the room of the protective goddess Neith. This room
+seems dark and mysterious with its decorations of inky-blue lapis lazuli
+and jet-black obsidian. Gold scrollwork defines an area on one of the
+walls, in the center of which is the symbol of Neith. Below this you can
+see some hieroglyphs etched into a beaten gold panel. There is a door in
+the northwest wall leading out of the room.")
+      (NW TO E-PRIME)
+      (OUT TO E-PRIME)
+      (GLOBAL HIEROGLYPHS PICTURE-PANELS PICTURES GEMS)
+      (ACTION SCORE-RMS)>
+
+<OBJECT GEMS
+	(IN LOCAL-GLOBALS)
+	(DESC "gem")
+	(FLAGS NDESCBIT)
+	(SYNONYM LAZULI OBSIDI JASPER GEMS)
+	(ADJECTIVE LAPIS RED INKY- BLUE JET-B)
+	(TEXT
+"The gems are quite remarkable, forming a delicate piece of art. To remove
+any of them would be beyond thinking. Even for you.")>
+
+<OBJECT GEMS-2 
+	(IN LOCAL-GLOBALS)
+	(DESC "tile")
+	(FLAGS NDESCBIT)
+	(SYNONYM CARNEL FELDSP GEMS TILES)
+	(ADJECTIVE RED YELLOW BLUE GREEN BRIGHT)
+	(TEXT
+"They are quite remarkable, forming a delicate piece of art. To remove
+any of them would be beyond thinking. Even for you.")> 
+
+<ROUTINE SCORE-RMS (RARG)
+	 <COND (<AND <EQUAL? .RARG ,M-ENTER>
+		     <NOT <FSET? ,HERE ,TOUCHBIT>>>
+		<SETG SCORE <+ ,SCORE 25>>)>
+	 <RFALSE>>
+		
+<ROOM LANDING-ZERO
+      (IN ROOMS)
+      (DESC "Circular Room")
+      (LDESC 
+"You are in a strange, round room which sits in the center of four hallways.
+These hallways lead off to the northeast, southeast, southwest and northwest
+like the spokes of a wheel. Above your head is a long tunnel which stretches up
+and out of sight.")
+      (FLAGS RLANDBIT)
+      (NW TO A-PRIME)
+      (NE TO B-PRIME)
+      (SW TO D-PRIME)
+      (SE TO E-PRIME)
+      (UP TO CHAMBER-OF-RA IF ROPE-TIED ELSE
+"There's no way to get back up there.")
+      (ACTION CIRCULAR-ROOM-FCN)>
+
+<ROUTINE LOOK-DOWN-HALLS ()
+	 <TELL "As you peer down the dimly-lit hallways, you ">
+	 <COND (<NOT <STATUE-OPPOSITE?>>
+		<TELL "see that the doors in all four hallways are
+balanced halfway open." CR>)
+	       (ELSE
+		<TELL "notice that the door to the ">
+		<TELL ,HALL-DIR>
+		<TELL 
+" is closed, while the one in the opposite hallway is all the way open. The
+other two are halfway open." CR>)>
+	 <FSET ,ROPE ,NDESCBIT>>
+
+<GLOBAL CIRCLE-SCORED <>>
+
+<ROUTINE CIRCULAR-ROOM-FCN (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<MOVE ,ROPE ,HERE>
+		<FCLEAR ,ROPE ,NDESCBIT>
+		<REMOVE ,ISIS-DOOR>
+		<REMOVE ,NEPHTH-DOOR>
+		<REMOVE ,NEITH-DOOR>
+		<REMOVE ,SELKIS-DOOR>
+		<COND (<NOT ,CIRCLE-SCORED>
+		       <SETG SCORE <+ ,SCORE 30>>
+		       <SETG CIRCLE-SCORED T>)>
+		<COND (<AND <NOT ,VERBOSE>
+			    <FSET? ,HERE ,TOUCHBIT>>
+		       <LOOK-DOWN-HALLS>
+		       <CRLF>)>)
+	       (<EQUAL? .RARG ,M-LOOK>
+		<FCLEAR ,ROPE ,NDESCBIT>
+		<TELL <GETP ,LANDING-ZERO ,P?LDESC> CR>
+		<DESCRIBE-ROPE-FCN ,M-OBJDESC>
+		<LOOK-DOWN-HALLS>)>>
+
+<OBJECT HUGE-STATUE
+	(IN LANDING-ZERO)
+	(DESC "large statue")
+	(FDESC
+"Sitting in the middle of the floor is a large statue, about two feet shorter
+than you. It reminds you a little of Miss Ellingsworth.")
+	(FLAGS TAKEBIT TRYTAKEBIT)
+	(SIZE 281)
+	(SYNONYM STATUE)
+	(ADJECTIVE HUGE)
+	(ACTION HUGE-STATUE-FCN)
+	(TEXT
+"It is carved out of dark gray basalt and its features resemble a woman at the
+height of her beauty, most probably the ancient Queen. The statue itself must
+weigh more than you do.")>
+
+<OBJECT HEAD
+	(IN HUGE-STATUE)
+	(FLAGS INVISIBLE TAKEBIT)
+	(DESC "broken head")
+	(SYNONYM HEAD)
+	(SIZE 20)
+	(ADJECTIVE BROKEN)
+	(TEXT
+"This head was once part of the magnificent statue of the Queen.")
+	(ACTION HEAD-FCN)>
+
+<ROUTINE HEAD-FCN ()
+	 <COND (<VERB? RAISE>
+		<PERFORM ,V?TAKE ,PRSO>
+		<RTRUE>)
+	       (<VERB? SHAKE>
+		<TELL "It's as empty as yours." CR>
+		<RTRUE>)
+	       (<VERB? CLIMB-ON>
+		<TELL "Next you'll be asking for tumbling lessons." CR>
+		<RTRUE>)>>
+
+<ROUTINE HUGE-STATUE-FCN ()
+	 <COND (<AND <VERB? MOVE TAKE PUSH PUSH-TO>
+		     <FSET? ,HEAD ,INVISIBLE>>
+		<TELL
+"The statue teeters, swaying and rocking back and forth, then falls over,
+its top-heavy structure striking the floor with a dull, loud thud. As you
+look over the damage, you see the head has separated from the statue." CR>
+		<MOVE ,HEAD ,HERE>
+		<FCLEAR ,HEAD ,INVISIBLE>
+		<FSET ,HUGE-STATUE ,TOUCHBIT>
+		<RTRUE>)
+	       (<VERB? TAKE RAISE>
+		<TELL "It's far too heavy." CR>
+		<RTRUE>)
+	       (<VERB? PUSH RAISE MOVE>
+		<TELL
+"The statue rocks over and back on its back. Looks like it's headed nowhere
+fast." CR>
+		<RTRUE>)
+	       (<VERB? MUNG>
+		<COND (<FSET? ,HEAD ,INVISIBLE>
+		       <PERFORM ,V?PUSH ,HUGE-STATUE>
+		       <RTRUE>)
+		      (T
+		       <TELL
+"Haven't you done enough damage to that beautiful relic?" CR>)>)
+	       (<VERB? EXAMINE>
+		<COND (<FSET? ,HEAD ,INVISIBLE>
+		       <RFALSE>)
+		      (T
+		       <TELL
+"The statue lies on the floor, its head broken off. In this state, the statue
+weighs a little less than you but it's still far too heavy to carry." CR>
+		       <RTRUE>)>)>>
+
+<ROOM A-PRIME
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Northwest Hallway")
+      (LDESC
+"You are standing in the middle of the Northwest Hallway. The walls here are
+smooth and undecorated, carved out of granite. The hallway continues to the
+northwest and to the southeast.") 
+      (SE TO LANDING-ZERO)
+      (NW TO ROOM-OF-NEPHTHYS IF NEPHTH-DOOR IS OPEN ELSE
+"There's no way to get through the stone door.")
+      (ACTION CLOSE-DEM-DOOAHS)>
+
+<OBJECT NEPHTH-DOOR
+	(IN A-PRIME)
+	(FLAGS DOORBIT NDESCBIT)
+	(DESC "stone door")
+	(SYNONYM DOOR)
+	(ADJECTIVE STONE)
+	(ACTION STONE-DOOR-FCN)>
+
+<ROUTINE STONE-DOOR-FCN ()
+	 <COND (<VERB? OPEN RAISE>
+		<TELL "You can't. It's got to weigh 50 tons." CR>
+		<RTRUE>)>>
+
+<ROOM B-PRIME
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Northeast Hallway")
+      (LDESC
+"You are standing midway down the long Northeast Hallway. The high walls
+are undecorated, but bear the marks of the stonecarver's tool. The hallway
+continues to the northeast and the southwest.")
+      (SW TO LANDING-ZERO)
+      (NE TO ROOM-OF-SELKIS IF SELKIS-DOOR IS OPEN ELSE
+"There's no way to get through the stone door.")
+      (ACTION CLOSE-DEM-DOOAHS)>
+
+<OBJECT SELKIS-DOOR
+	(FLAGS DOORBIT NDESCBIT)
+	(DESC "stone door")
+	(SYNONYM DOOR)
+	(ADJECTIVE STONE)
+	(ACTION STONE-DOOR-FCN)>
+
+<ROOM D-PRIME
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Southwest Hallway")
+      (LDESC
+"You are midway down the Southwest Hallway. The walls of this narrow passage
+are unadorned and smooth. The hallway continues to the southwest and the
+northeast.")
+      (NE TO LANDING-ZERO)
+      (SW TO ROOM-OF-ISIS IF ISIS-DOOR IS OPEN ELSE
+"There's no way to get through the stone door.")
+      (ACTION CLOSE-DEM-DOOAHS)>
+
+<OBJECT ISIS-DOOR
+	(FLAGS DOORBIT NDESCBIT)
+	(DESC "stone door")
+	(SYNONYM DOOR)
+	(ADJECTIVE STONE)
+	(ACTION STONE-DOOR-FCN)>
+
+<ROOM E-PRIME
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Southeast Hallway")
+      (LDESC
+"You are midway down the Southeast Hallway. This corridor is undecorated and
+the walls are polished to a smooth lustre. The hallway continues to the
+southeast and the northwest.")
+      (NW TO LANDING-ZERO)
+      (SE TO ROOM-OF-NEITH IF NEITH-DOOR IS OPEN ELSE
+"There's no way to get through the stone door.")
+      (ACTION CLOSE-DEM-DOOAHS)>
+
+<OBJECT NEITH-DOOR
+	(FLAGS DOORBIT NDESCBIT)
+	(DESC "stone door")
+	(SYNONYM DOOR)
+	(ADJECTIVE STONE)
+	(ACTION STONE-DOOR-FCN)>
+
+<GLOBAL HALL-DIR <>>
+
+<GLOBAL STATUE-CHK-TBL ;"starts @ 0, inc by 3"
+	<TABLE A-PRIME E-PRIME "southeast"
+	       E-PRIME A-PRIME "northwest"
+	       B-PRIME D-PRIME "southwest"
+	       D-PRIME B-PRIME "northeast">>
+
+<ROUTINE STATUE-OPPOSITE? ("AUX" (OFFS -3) H-CHK T-CHK (FLG <>))
+	 <REPEAT ()
+		 <SET OFFS <+ .OFFS 3>>
+		 <COND (<G? .OFFS 9>
+			<RETURN>)
+		       (T
+			<SET H-CHK <GET ,STATUE-CHK-TBL .OFFS>>
+			<SET T-CHK <GET ,STATUE-CHK-TBL <+ .OFFS 1>>>
+			<COND (<AND <EQUAL? ,HERE .H-CHK ,LANDING-ZERO>
+				    <G? <WEIGHT .T-CHK> 300>>
+			       <SET FLG T>
+			       <SETG HALL-DIR <GET ,STATUE-CHK-TBL
+						   <+ .OFFS 2>>>)>)>>
+	 <RETURN .FLG>>
+
+<GLOBAL KLUDGE-FLG <>>
+
+<ROUTINE CLOSE-DEM-DOOAHS (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<SET KLUDGE-FLG <>>
+		<COND (<STATUE-OPPOSITE?>
+		       <COND (<EQUAL? ,HERE ,A-PRIME>
+			      <FSET ,NEPHTH-DOOR ,OPENBIT>)
+			     (<EQUAL? ,HERE ,B-PRIME>
+			      <FSET ,SELKIS-DOOR ,OPENBIT>)
+			     (<EQUAL? ,HERE ,D-PRIME>
+			      <FSET ,ISIS-DOOR ,OPENBIT>)
+			     (ELSE
+			      <FSET ,NEITH-DOOR ,OPENBIT>)>)
+		      (<G? <WEIGHT ,HERE> 300>
+		       <RFALSE>)
+		      (T <TELL 
+"As you enter the corridor, a huge stone door begins to slide down from the
+ceiling closing off any further progress. The closer you come to the door, the
+further down the door descends until, eventually, it is close to the floor.
+When you turn around, you can barely see beyond the Circular Room where an
+identical door has risen off the floor an equal amount." CR>
+		       <CRLF>
+		       <COND (<EQUAL? ,HERE ,A-PRIME ,E-PRIME>
+			      <MOVE ,NEPHTH-DOOR ,A-PRIME>
+			      <FCLEAR ,NEPHTH-DOOR ,OPENBIT>
+			      <MOVE ,NEITH-DOOR ,E-PRIME>
+			      <FCLEAR ,NEITH-DOOR ,OPENBIT>)
+			     (<EQUAL? ,HERE ,B-PRIME ,D-PRIME>
+			      <MOVE ,SELKIS-DOOR ,B-PRIME>
+			      <MOVE ,ISIS-DOOR ,D-PRIME>
+			      <FCLEAR ,SELKIS-DOOR ,OPENBIT>
+			      <FCLEAR ,ISIS-DOOR ,OPENBIT>)>
+		       <SET KLUDGE-FLG T>)>)
+	       (<AND <EQUAL? .RARG ,M-END>
+		     <STATUE-OPPOSITE?>
+		     <NOT ,KLUDGE-FLG>>
+		<TELL
+"The path before you remains open, the stone door having risen to the ceiling,
+counterbalanced by the door in the opposite corridor." CR>
+		<SET KLUDGE-FLG T>
+		<RTRUE>)>>
\ No newline at end of file
diff --git a/globals.zil b/globals.zil
new file mode 100644
index 0000000..ac8a1a6
--- /dev/null
+++ b/globals.zil
@@ -0,0 +1,878 @@
+"GLOBALS for
+			      INFIDEL
+	(c) Copyright 1983 Infocom, Inc.  All Rights Reserved.
+"
+
+<DIRECTIONS NORTH EAST WEST SOUTH UP DOWN IN OUT SE SW NE NW>
+
+"SUBTITLE GLOBAL OBJECTS"
+
+<OBJECT GLOBAL-OBJECTS
+	(FLAGS RMUNGBIT INVISIBLE TOUCHBIT SURFACEBIT TRYTAKEBIT
+	       VOWELBIT OPENBIT SEARCHBIT TRANSBIT WEARBIT ONBIT)>
+
+<OBJECT LOCAL-GLOBALS
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM ZZMGCK)
+	(DESCFCN 0)
+        (GLOBAL GLOBAL-OBJECTS)
+	(PSEUDO "FOOBAR" V-WAIT)
+	(CONTFCN 0)
+	(SIZE 0)>
+;"Yes, this synonym for LOCAL-GLOBALS needs to exist... sigh"
+
+<OBJECT ROOMS>
+
+<OBJECT BASIE
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM BASIE)
+	(DESC "Basie")>
+
+<OBJECT PETROL
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM GASOLI PETROL)
+	(DESC "gasoline")>
+
+<OBJECT FOO-TOOL
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM HAMMER CROWBA EXPLOS MACHET)
+	(DESC "such thing")>
+
+<OBJECT DRACULA
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM DRACULA)
+	(DESC "Dracula")>
+
+<OBJECT FINGER
+	(IN GLOBAL-OBJECTS)
+	(FLAGS SURFACEBIT OPENBIT CONTBIT TOUCHBIT)
+	(CAPACITY 1)
+	(SYNONYM FINGER)
+	(DESC "finger")
+	(ACTION FINGER-FCN)>
+
+<ROUTINE FINGER-FCN ()
+	 <COND (<AND <VERB? PUT-ON>
+		     <PRSI? ,FINGER>>
+		<PERFORM ,V?WEAR ,PRSO>
+		<RTRUE>)
+	       (<VERB? EXAMINE LOOK-INSIDE>
+		<COND (<FSET? ,RING ,WEARBIT>
+		       <TELL "Sitting on your finger is a ring." CR>
+		       <RTRUE>)
+		      (T
+		       <TELL "It's part of your hands." CR>
+		       <RTRUE>)>)>>
+
+<OBJECT BLESSINGS
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM BLESSI)
+	(DESC "blessings")>
+
+<OBJECT INTNUM
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM INTNUM)
+	(DESC "number")>
+
+<OBJECT INTDIR
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM INTDIR)
+	(ADJECTIVE NORTH EAST SOUTH WEST NE NW SE SW)
+	(FLAGS TOOLBIT)
+	(DESC "direction")>
+
+<OBJECT PSEUDO-OBJECT
+	(DESC "pseudo")
+	(ACTION CRETIN)>
+
+<OBJECT IT	;"was IT"
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM IT THAT)
+	(DESC "random object")
+	(FLAGS NDESCBIT TOUCHBIT)>
+
+<OBJECT AIR
+	(IN GLOBAL-OBJECTS)
+	(DESC "air")
+	(FLAGS VOWELBIT CONTBIT OPENBIT)
+	(SYNONYM AIR OXYGEN SKY)
+	(TEXT
+"The air is as clear as any Egyptian air can be.")
+	(ACTION AIR-FCN)>
+
+<ROUTINE AIR-FCN ()
+	 <COND (<VERB? EXAMINE SMELL TASTE>
+		<COND (<GETP ,HERE ,P?MAP>
+		       <RFALSE>)
+		      (T
+		       <TELL "It's stale and musty" CR>
+		       <RTRUE>)>)
+	       (<VERB? OPEN CLOSE>
+		<TELL "I think you're an air head." CR>)
+	       (<AND <PRSI? AIR>
+		     <VERB? EXAMINE LOOK-INSIDE>>
+		<PERFORM ,V?LOOK-UP>
+		<RTRUE>)
+	       (<AND <EQUAL? ,PRSI ,AIR>
+		     <VERB? THROW DROP>>
+		<PERFORM ,PRSA ,PRSO ,GROUND>
+		<RTRUE>)
+	       (<AND <VERB? WAVE>
+		     <PRSO? ,AIR>>
+		<TELL "Don't expect me to tell you the sky waves back." CR>
+		<RTRUE>)>>
+
+<OBJECT GROUND	;"was GROUND"
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM FLOOR GROUND)
+	(DESC "floor")
+	(ACTION READ-FLOOR-F)>
+
+<ROUTINE READ-FLOOR-F ()
+	 <COND (<AND <VERB? EXAMINE READ>
+		     <EQUAL? ,HERE ,CENTRAL-ROOM>>
+		<PERFORM ,V?READ ,HIEROGLYPHS>
+		<RTRUE>)>>
+
+<OBJECT CRACK
+	(IN GLOBAL-OBJECTS)
+	(FLAGS NDESCBIT CONTBIT OPENBIT)
+	(DESC "crack")
+	(SYNONYM CRACK)
+	(TEXT
+"It's just a crack in the floor where the stones meet.")
+	(ACTION CRACK-FCN)>
+
+<ROUTINE CRACK-FCN ()
+	 <COND (<OR <GETP ,HERE ,P?MAP>
+		    <EQUAL? <GETP ,HERE ,P?ACTION> ,BURN-THE-BARGE>
+		    <AND <EQUAL? ,HERE ,WEST-END-OF-PASSAGE>
+			 <NOT <FSET? ,PIT ,INVISIBLE>>>>
+		<TELL "I see no crack here." CR>
+		<RTRUE>)
+	       (<VERB? OPEN CLOSE>
+		<HOW? ,PRSO>
+		<RTRUE>)
+	       (<VERB? LOOK-INSIDE>
+		<TELL
+"Get real. There's nothing worth looking at in there." CR>
+		<RTRUE>)>>
+
+<OBJECT SAND
+	(IN LOCAL-GLOBALS)
+	(FLAGS NDESCBIT)
+	(DESC "sand")
+	(SYNONYM DESERT SAND GROUND)>
+
+<OBJECT HOLE
+	(IN LOCAL-GLOBALS)
+	(FLAGS NDESCBIT)
+	(DESC "hole")
+	(SYNONYM HOLE)
+	(ADJECTIVE SMALL ENLARG SIZABL KNEE- DEEP)
+	(ACTION HOLE-FCN)>
+
+<ROUTINE HOLE-FCN ()
+	 <COND (<VERB? EXAMINE LOOK-INSIDE>
+		<COND (<AND <EQUAL? ,HERE ,P8>
+			    <IN? ,PYRAMID ,HERE>>
+		       <TELL
+"You can see the block and the opening in there." CR>)
+		      (<G? <GETP ,HERE ,P?CAPACITY> 0>
+		       <TELL "Never mind that -- Here's a better
+problem: You dig a hole 52 feet by 20 feet by .105 yards. It takes you 5
+hours, 11 minutes and 2 seconds. You sweat off thirty grams of water
+per hour. And your best friend just ran off with the rent money. Now:
+How much sand is in the hole you dug?" CR>)
+		      (T
+		       <TELL "I don't see any hole here." CR>)>)
+	       (<VERB? FIND>
+		<COND (<GETP ,HERE ,P?CAPACITY>
+		       <TELL "It's right here." CR>
+		       <RTRUE>)>)
+	       (<AND <EQUAL? ,PRSI ,HOLE>
+		     <VERB? PUT>
+		     <GETP ,HERE ,P?CAPACITY>>
+		<TELL 
+"It's just a hole in the sand from your excavation attempts. There's no need to
+put anything into it." CR>)>>
+
+<OBJECT PEN-PENCIL
+	(IN GLOBAL-OBJECTS)
+	(DESC "writing implement")
+	(SYNONYM PEN PENCIL)>
+
+<OBJECT STONES
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM STONES BLOCKS)
+	(DESC "stones")>
+
+<OBJECT KEY
+	(IN GLOBALS)
+	(FLAGS NDESCBIT)
+	(DESC "key")
+	(SYNONYM KEY)
+	(ADJECTIVE TRUNK)>
+
+<OBJECT BULKHEADS
+	(IN GLOBAL-OBJECTS)
+	(FLAGS NDESCBIT TOUCHBIT)
+	(DESC "bulkhead")
+	(SYNONYM BULKHE)>
+
+<OBJECT WALLS
+	(IN GLOBAL-OBJECTS)
+	(FLAGS NDESCBIT TOUCHBIT)
+	(DESC "wall")
+	(SYNONYM WALL WALLS)
+	(ADJECTIVE STONE)
+	(ACTION WALL-FCN)>
+
+<ROUTINE WALL-FCN ("AUX" RMG RMGL)
+	 <COND (<AND <EQUAL? ,HERE ,STAIRS-BOTTOM>
+		     <VERB? EXAMINE READ>>
+		<COND (<IN? ,PLASTER1 ,STAIRS-BOTTOM>
+		       <PERFORM ,V?EXAMINE ,PLASTER1>
+		       <RTRUE>)
+		      (T <TELL "I see nothing special about the wall." CR>
+		       <RTRUE>)>)
+	       (<VERB? EXAMINE READ>
+		<COND (<AND <GLOBAL-IN? ,HIEROGLYPHS ,HERE>
+			    <NOT <EQUAL? ,HERE ,CENTRAL-ROOM>>>
+		       <PERFORM ,V?READ ,HIEROGLYPHS>
+		       <RTRUE>)
+		      (ELSE
+		       <RFALSE>)>)>>
+		
+<OBJECT CEILING
+	(IN GLOBAL-OBJECTS)
+	(FLAGS NDESCBIT TOUCHBIT)
+	(DESC "ceiling")
+	(SYNONYM CEILIN)>
+
+<OBJECT HANDS	;"was HANDS"
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM HANDS)
+	(DESC "empty hands")
+	(FLAGS NDESCBIT TOOLBIT TOUCHBIT VOWELBIT)
+	(ACTION READ-PALMS-F)>
+
+<ROUTINE READ-PALMS-F ()
+	 <COND (<VERB? READ>
+		<TELL "I don't read palms." CR>
+		<RTRUE>)>>
+
+<OBJECT ADVENTURER
+	(IN TOP-OF-STAIRWAY)
+	(SYNONYM PLAYER ADVENT CRETIN)
+	(DESC "cretin")
+        (FLAGS ACTORBIT NDESCBIT INVISIBLE)>
+
+<OBJECT ME
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM ME MYSELF SELF BACK)
+	(DESC "you")
+	(FLAGS ACTORBIT)
+	(ACTION CRETIN)>
+
+<ROUTINE CRETIN ()
+	 <COND (<NOT <EQUAL? ,PRSO ,WINNER ,ME>>
+		<RFALSE>)>
+	 <COND (<VERB? EAT>
+		<TELL
+"I've heard of biting one's knuckles, chewing one's fingernails, but don't you
+think that's a little extreme?" CR>)
+	       (<VERB? DRINK>
+		<TELL
+"Find me a blender, jump in it, and once you're liquified, we'll talk." CR>)
+	       (<VERB? ALARM>
+		<TELL 
+"Good morning!" CR>)
+	       (<VERB? MUNG ATTACK KILL>
+		<TELL
+"Hey, I know just how you feel. And I'm sure you think you deserve it -- I've
+been there myself. But take heart -- let nature take care of you. I'm sure it
+will, in time." CR>)
+	       (<VERB? PRAY>
+		<TELL "Save yourself. Don't look to me, man." CR>)
+	       (<VERB? FIND>
+		<TELL "Take a course in Zen." CR>)
+	       (<VERB? TAKE>
+		<TELL "Auto-eroticism is not the answer." CR>)
+	       (<VERB? BURN>
+		<TELL "Come on. Don't you have enough troubles?" CR>)
+	       (<VERB? EXAMINE LOOK-INSIDE THROW>
+		<TELL
+"Hmmm. How do you propose I accomplish that? (And they told me in AI school
+the intelligent creatures were on the other side of the keyboard!)" CR>)
+	       (<VERB? RUB>
+		<TELL 
+"Go rub yourself. You're starting to rub me the wrong way." CR>)
+	       (<VERB? PLAY>
+		<TELL "Who do you think you're playing around with?" CR>)
+	       (<VERB? CLIMB-ON BOARD>
+		<TELL "I'll get on your case is what I'll do, turkey." CR>)
+	       (<VERB? CLEAN>
+		<TELL "Take a bath. Leave me out of this." CR>)
+	       (<VERB? CLOSE>
+		<TELL "Better yet, close your mouth." CR>)
+	       (<VERB? CROSS>
+		<TELL "Crossed and double-crossed, sucker." CR>)
+	       (<VERB? DISEMBARK>
+		<TELL "What makes you think you deserve it?" CR>)
+	       (<VERB? DROP>
+		<TELL "Like a hot potato." CR>)
+	       (<VERB? LEAN-ON OPEN>
+		<TELL "I think you've got enough troubles." CR>)
+	       (<VERB? FOLLOW>
+		<TELL "What makes you think you know where you're going?" CR>)
+	       (<VERB? LISTEN>
+		<TELL "Do I have a choice?" CR>)
+	       (<VERB? SEARCH>
+		<TELL "Okay. I found one empty head but a strong heart." CR>)
+	       (<VERB? MAKE>
+		<TELL "I doubt anyone could make you do anything with that attitude." CR>)
+	       (<VERB? SHAKE>
+		<TELL "Shake, rattle and roll." CR>)
+	       (<VERB? SMELL>
+		<TELL "Phew! When was the last time you bathed?" CR>)
+	       (<VERB? SQUEEZE>
+		<TELL "Like a python, eh?" CR>)
+	       (<VERB? THROW>
+		<TELL "For a loop?" CR>)
+	       (<VERB? WEAR>
+		<TELL "How many layers of skin does one human need?" CR>)
+	       (ELSE
+		<RFALSE>)>
+	 <RTRUE>>
+
+<OBJECT DOORWAY
+	(IN LOCAL-GLOBALS)
+	(FLAGS NDESCBIT CONTBIT OPENBIT)
+	(DESC "doorway")
+	(SYNONYM DOORWAY OPENIN)
+	(ADJECTIVE ARCHED TIMBER)
+	(ACTION DOORWAY-FCN)>
+
+<ROUTINE DOORWAY-FCN ()
+	 <COND (<VERB? EXAMINE LOOK-INSIDE>
+		<COND (<AND <EQUAL? ,HERE ,NORTH-ANTECHAMBER ,BURIAL-CHAMBER>
+			    <EQUAL? ,BEAM-PLACED 4>>
+		       <TELL
+"The mast is in the doorway, running from top to bottom." CR>
+		       <RTRUE>)
+		      (<AND <EQUAL? ,HERE ,SOUTH-ANTECHAMBER ,ANNEX>
+			    <EQUAL? ,BEAM-PLACED 2 3>>
+		       <TELL 
+"The beam is wedged in the doorway from side to side." CR>
+		       <RTRUE>)>)>>
+
+<OBJECT PICTURE-PANELS
+	(IN LOCAL-GLOBALS)
+	(DESC "panel")
+	(FLAGS NDESCBIT)
+	(SYNONYM PANEL PANELS)
+	(ADJECTIVE GOLD RED CLAY BEATEN)
+	(ACTION PANEL-ON-WALL-FCN)>
+
+<ROUTINE PANEL-ON-WALL-FCN ()
+	 <COND (<VERB? EXAMINE READ>
+		<TELL 
+"The panels are beautiful pieces of art, to be appreciated by the Queen on her
+journey through the Netherworld." CR>
+		<COND (<GLOBAL-IN? ,HIEROGLYPHS ,HERE>
+		       <PERFORM ,V?READ ,HIEROGLYPHS>
+		       <RTRUE>)>
+		<RTRUE>)>>
+		
+
+<OBJECT STAIRS
+	(IN LOCAL-GLOBALS)
+	(SYNONYM STAIRS STEPS LADDER STAIRWAY)
+	(DESC "stairs")
+	(FLAGS NDESCBIT CLIMBBIT TOUCHBIT)
+	(ACTION DESC-STAIRS-F)>
+
+<ROUTINE DESC-STAIRS-F ()
+	 <COND (<AND <VERB? EXAMINE>
+		     <EQUAL? ,HERE ,AFT-CABIN ,BELOW-DECK>>
+		<TELL "The ladder is made of wood, and it looks fairly sturdy."
+		      CR>
+		<RTRUE>)>>
+
+<OBJECT PARACHUTE
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM PARACH CHUTE)
+	(DESC "parachute")
+	(ACTION GOOD-LUCK-FCN)>
+
+<OBJECT PLANE
+	(IN GLOBAL-OBJECTS)
+	(DESC "airplane")
+	(SYNONYM PLANE AIRPLA PILOT)
+	(TEXT
+"Its a small, one-engine plane, similar in shape to the old Piper Cubs.")
+	(ACTION PLANE-FCN)>
+
+<ROUTINE PLANE-FCN ()
+	 <COND (<VERB? WAVE>
+		<COND (<AND <L? ,MOVES 8>
+			    <NOT <IN-A-TENT?>>>
+		       <TELL "The plane dips its wings in salute." CR>)
+		      (<L? ,MOVES 8>
+		       <TELL 
+"You wave at the plane through the top of the tent. Somehow, I doubt it
+noticed." CR>)
+		      (T
+		       <TELL "The plane's returned to its home base." CR>)>)
+	       (<VERB? FIND>
+		<COND (<G? ,MOVES 8>
+		       <TELL "I suppose it's up in the air, somewhere." CR>)
+		      (T
+		       <TELL "It's somewhere up over your head." CR>)>)
+	       (<VERB? EXAMINE>
+		<COND (<AND <NOT <IN-A-TENT?>>
+			    <L? ,MOVES 8>>
+		       <RFALSE>)
+		      (<L? ,MOVES 8>
+		       <TELL 
+"All I can tell you about it is that it's out there." CR>)
+		      (T
+		       <TELL "The plane's far gone, amigo." CR>)>)
+	       (<AND <VERB? LISTEN>
+		     <L? ,MOVES 9>>
+		<TELL "RRRRRRRrrrrrrr r r r r r   r    r     r." CR>
+		<RTRUE>)
+	       (T
+		<COND (<G? ,MOVES 8>
+		       <TELL "What plane? It's gone!" CR>)
+		      (T
+		       <TELL
+"Leave the plane alone. It's not bothering you." CR>)>
+		<RTRUE>)>>
+
+<ROUTINE GOOD-LUCK-FCN ()
+	 <COND (<VERB? FIND>
+		<COND (<L? ,MOVES 8>
+		       <TELL "Look up!" CR>)
+		      (T
+		       <TELL
+"It's gone with the wind, never to be seen again." CR>)>)
+	       (<VERB? EXAMINE>
+		<COND (<AND <G? ,MOVES 4>
+			    <L? ,MOVES 8>>
+		       <TELL "It's white." CR>)
+		      (<L? ,MOVES 5>
+		       <TELL "What parachute?" CR>)
+		      (T
+		       <TELL
+"The most I can tell you is that it was white." CR>)>)
+	       (<VERB? STAND-UNDER>
+		<RFALSE>)
+	       (T
+		<COND (<G? ,MOVES 7>
+		       <TELL 
+"Forget the chute, amigo. It's history. And if you don't get on with this, you
+will be too." CR>)
+		      (T
+		       <TELL "Leave the parachute alone." CR>)>
+		<RTRUE>)>>
+
+<OBJECT SIP
+	(IN GLOBAL-OBJECTS)
+	(FLAGS TAKEBIT)
+	(DESC "sip of water")
+	(SYNONYM SIP)
+	(ACTION SIP-FCN)>
+
+<ROUTINE SIP-FCN ()
+	 <COND (<AND <EQUAL? ,PRSO ,SIP>
+		     <VERB? TAKE>>
+		<COND (<OR <NOT ,PRSI>
+			   <PRSI? ,WATER>>
+		       <PERFORM ,V?DRINK ,WATER>
+		       <RTRUE>)
+		      (<EQUAL? ,PRSI ,LIQUID>
+		       <PERFORM ,V?DRINK ,LIQUID>)
+		      (ELSE
+		       <TELL "No, I don't think I quite understand." CR>)>)
+	       (ELSE
+		<TELL "Now that's an interesting thought." CR>)>>
+
+;"GLOBAL VARIABLES"
+
+<GLOBAL HERE <>>
+
+<GLOBAL LOAD-ALLOWED 100>
+
+<GLOBAL LOAD-MAX 0>
+
+<GLOBAL LIT T>
+
+<GLOBAL MOVES 0>
+
+<GLOBAL SCORE 0>
+
+<GLOBAL INDENTS
+	<TABLE ""
+	       "  "
+	       "    "
+	       "      "
+	       "        "
+	       "          ">>
+
+;"******************************************
+	Here come the globals
+********************************************"
+
+<GLOBAL STATUE-TBL
+	<TABLE ISIS NEPHTHYS NEITH SELKIS>>
+<GLOBAL STATUE-NAME-TBL
+	<TABLE "Isis" "Nephthys" "Neith" "Selkis">>
+<GLOBAL ORDER-LTBL
+	<LTABLE NEITH SELKIS ISIS NEPHTHYS>>
+<GLOBAL TURNED-LTBL
+	<LTABLE <> <> <> <>>>
+<GLOBAL DOWN-LTBL
+	<LTABLE LANDING-ZERO LANDING-ONE LANDING-TWO LANDING-THREE>>
+
+<GLOBAL SOMETHING-DROPPED <>>
+<GLOBAL WHAT-WAS-DROPPED <>>
+<GLOBAL ROPE-PLACED <>>
+;<GLOBAL ROPE-LANDING <>>
+<GLOBAL ROPE-TIED <>>
+<GLOBAL MATCH-COUNT 20>
+<GLOBAL SCARAB-SET <>>
+<GLOBAL OIL-SOAKED <>>
+<GLOBAL OILED-TORCH <>>
+<GLOBAL OIL-LEFT 100>
+<GLOBAL TORCH-TURNS 0>
+<GLOBAL TURN-OFFSET 0>
+<GLOBAL CAN-TURN-STATUES <>>
+<GLOBAL STATUES-SET <>>
+<GLOBAL ANTE-SEAL T>
+<GLOBAL BEAM-PLACED <>>
+<GLOBAL ON-BEAM <>>
+<GLOBAL INNER-DOOR-SEALED T>
+<GLOBAL PLASTER-GONE <>>
+<GLOBAL FIRST-ENTRY T>
+
+<OBJECT HIEROGLYPHS
+	(IN LOCAL-GLOBALS)
+	(DESC "hieroglyphs")
+	(FLAGS NDESCBIT)
+	(SYNONYM SYMBOL HIEROG GLYPHS)
+	(ADJECTIVE STRANGE)
+	(ACTION HIERO-FCN)>
+
+<ROUTINE HIERO-FCN ("AUX" TEMP (COUNTER 0) OFFSET)
+	 <COND (<NOT <VERB? READ EXAMINE>>
+		<RFALSE>)>
+	 <COND (<AND <IN? ,WINNER ,STAIRS-BOTTOM>
+		     <IN? ,PLASTER1 ,STAIRS-BOTTOM>>
+		<TELL CR
+"*->  #  !!!  ::  ...>  .-" CR>)
+	       (<IN? ,WINNER ,WEST-END-OF-PASSAGE>
+		<COND (<FSET? ,PIT ,INVISIBLE>
+		       <TELL CR
+"             .|
+<-*  #  /!\\  -  #  (=  =)|
+|
+::  *->  #  !!!" CR>)
+		      (T
+		       <TELL "They're gone with the plaster." CR>)>)
+	       (<AND <ROOM? ,NORTH-ANTECHAMBER>
+		     <NOT <FSET? ,BURIAL-CHAMBER ,RMUNGBIT>>>
+		<TELL CR
+"             -     !=!|
+<-*  #  /!\\  .   #  ! !|
+|
+::  *->  #  !!!" CR>)
+	       (<AND <ROOM? SOUTH-ANTECHAMBER>
+		     <NOT <FSET? ,ANNEX-DOOR ,OPENBIT>>>
+		<TELL CR
+"                      -|
+<-*  #  /!\\  (.)  #  ! !|
+                      -|
+|
+           -|
+::  (  #  ! !|
+           -" CR>)
+	       (<ROOM? ,ROOM-OF-NEPHTHYS ,ROOM-OF-ISIS
+		       ,ROOM-OF-SELKIS ,ROOM-OF-NEITH>
+		<COND (<EQUAL? ,HERE ,ROOM-OF-NEPHTHYS>
+		       <SET TEMP ,NEPHTHYS>
+		       <SET OFFSET 4>)
+		      (<EQUAL? ,HERE ,ROOM-OF-NEITH>
+		       <SET TEMP ,NEITH>
+		       <SET OFFSET 2>)
+		      (<EQUAL? ,HERE ,ROOM-OF-SELKIS>
+		       <SET TEMP ,SELKIS>
+		       <SET OFFSET 1>)
+		      (T <SET TEMP ,ISIS>
+		       <SET OFFSET 3>)>
+		<REPEAT ()
+			<SET COUNTER <+ .COUNTER 1>>
+			<COND (<EQUAL? .TEMP
+				       <GET ,ORDER-LTBL .COUNTER>>
+			       <RETURN>)>>
+		<TELL CR "       " <GET ,STAR-LTBL .COUNTER> CR>
+		<TELL CR
+"          " <GET ,COMPASS-POINTS-LTBL .OFFSET> CR>
+		<TELL
+"))  /  #  " <GET ,COMPASS-TAILS-LTBL .OFFSET> "  ::|
+|
+<-*  "
+	     <GET ,STAR-LTBL .COUNTER> "  =!=  /  *" CR>)
+	       (<IN? ,WINNER ,BEND-HALL>
+		<TELL
+"
+          .      =  - -|
+!@!  ...>  -  #  *   =   ::  <...  ;|
+|
+#  *|
+   =" CR>)
+	       (<IN? ,WINNER ,CENTRAL-ROOM>
+		<TELL
+"The hieroglyphs look like this:|
+|
+                    !-!|
+...>  -.  >...  #  !  ! !|
+                    !-!|
+|
+/  ...>  /  #  !@!" CR>)
+	       (<EQUAL? ,HERE ,SOUTH-CENTER>
+		<TELL
+"The hieroglyphs look like this:
+|
+|
+ <.>     <:>     <:.>|
+|
+ <::>    <::.>   <:::>|
+|
+ <:::.>  <::::>  <::::.>" CR>)
+	       (<EQUAL? <LOC ,WINNER> ,SKELETON-ROOM ,SILVER-ROOM ,GOLDEN-ROOM>
+		<TELL
+"The hieroglyphs look like this:|
+|
+-!-  #  !*  ::  #  *!  ::|
+|
+*->  #  !@!  >*>" CR>)
+	       (T
+		<TELL "I don't see them here." CR>)>
+	 <RTRUE>>
+
+<GLOBAL STAR-LTBL
+	<LTABLE "(@)"
+		"(@@)"
+		"(@@@)"
+		"(@@@@)">>
+
+<GLOBAL COMPASS-POINTS-LTBL
+	<LTABLE
+" ."
+"\\"
+" /"
+". ">>
+
+<GLOBAL COMPASS-TAILS-LTBL
+	<LTABLE
+"/"
+" ."
+". "
+" \\">>
+
+<GLOBAL WATER-LEFT 0>
+
+<OBJECT PICTURES
+	(IN LOCAL-GLOBALS)
+	(FLAGS NDESCBIT)
+	(DESC "decorations")
+	(SYNONYM PAINTI PICTUR SCROLL)
+	(ADJECTIVE SMALL LARGE)
+	(TEXT
+"Quite beautiful, no?")>
+
+<OBJECT PILLARS
+	(IN LOCAL-GLOBALS)
+	(FLAGS NDESCBIT)
+	(DESC "pillars")
+	(SYNONYM PILLARS)
+	(TEXT
+"They're quite huge, aren't they?")>
+
+<OBJECT BOAT
+	(IN LOCAL-GLOBALS)
+	(FLAGS VEHBIT)
+	(DESC "barge")
+	(SYNONYM BARGE BOAT SHIP WOOD)
+	(ADJECTIVE WOODEN WOOD)
+	(ACTION BOARD-BARGE-F)>
+
+<ROUTINE BOARD-BARGE-F ()
+	 <COND (<VERB? BOARD>
+		<COND (<EQUAL? ,HERE ,BARGE-ENTRANCE>
+		       <DO-WALK ,P?UP>
+		       <RTRUE>)
+		      (<OR <EQUAL? ,HERE ,NW-CORNER ,NE-CORNER>
+			   <EQUAL? ,HERE ,SW-CORNER ,SE-CORNER>>
+		       <TELL "There's no way to do that from here." CR>
+		       <RTRUE>)
+		      (<OR <EQUAL? ,HERE ,FORE-CABIN ,AFT-CABIN ,BELOW-DECK>
+			   <EQUAL? ,HERE ,BELOW-MAST ,BARGE-CENTER>>
+		       <TELL "Just where do you think you are?" CR>
+		       <RTRUE>)>)
+	       (<VERB? DISEMBARK>
+		<COND (<EQUAL? ,HERE ,BARGE-CENTER>
+		       <DO-WALK ,P?DOWN>
+		       <RTRUE>)
+		      (<OR <EQUAL? ,HERE ,NW-CORNER ,NE-CORNER>
+			   <EQUAL? ,HERE ,SW-CORNER ,SE-CORNER>>
+		       <TELL "You're not on the barge!" CR>
+		       <RTRUE>)
+		      (<OR <EQUAL? ,HERE ,FORE-CABIN ,AFT-CABIN ,BELOW-DECK>
+			   <EQUAL? ,HERE ,BELOW-MAST ,BARGE-CENTER>>
+		       <TELL "I can't do that from here." CR>
+		       <RTRUE>)>)>>
+		      
+
+<OBJECT DECK
+	(IN LOCAL-GLOBALS)
+	(DESC "deck")
+	(SYNONYM DECK DECKIN)
+	(ACTION JUMP-OFF-FCN)>
+
+<ROUTINE JUMP-OFF-FCN ()
+	 <COND (<AND <EQUAL? ,HERE ,BARGE-CENTER>
+		     <VERB? LEAP>>
+		<TELL "Don't you think using the plank would be safer?" CR>
+		<RTRUE>)
+	       (<VERB? LEAP>
+		<TELL "It might be easier without these bulkheads around." CR>)
+	       (<VERB? LOOK-INSIDE EXAMINE>
+		<COND (<FIRST? ,HERE>
+		       <DESCRIBE-OBJECTS T>
+		       <RTRUE>)
+		      (ELSE
+			<TELL "There's nothing on the deck." CR>
+			<RTRUE>)>)
+	       (<VERB? COUNT>
+		<TELL "What a cahd! (52 to be exact!)" CR>
+		<RTRUE>)>>
+	
+<OBJECT FLAPS
+	(IN LOCAL-GLOBALS)
+	(DESC "flap")
+	(SYNONYM FLAP FLAPS)
+	(ACTION FLAP-FCN)>
+
+<ROUTINE FLAP-FCN ()
+	 <COND (<NOT <VERB? LOOK-INSIDE>>
+		<RFALSE>)
+	       (<EQUAL? ,HERE ,TENT ,TENT2 ,SUPPLY-TENT>
+		<TELL
+"You can make out a lot of sand and a small firepit." CR>)
+	       (<EQUAL? ,HERE ,P2>
+		<TELL 
+"You can make out your cot and the trunk inside the tent." CR>)
+	       (<EQUAL? ,HERE ,P7 ,P4>
+		<TELL 
+"You can see nothing distinguishable by trying to look in through the bright
+sunlight." CR>)>
+	 <RTRUE>>
+
+<OBJECT THICKET
+	(IN GLOBAL-OBJECTS)
+	(DESC "thicket")
+	(SYNONYM THICKE)
+	(ACTION THICKET-FCN)> 
+				
+<ROUTINE THICKET-FCN ()
+	 <COND (<NOT <EQUAL? ,HERE ,RIVER-BANK ,P4 ,P6>>
+		<TELL "I see no thickets here." CR>
+		<RTRUE>)
+	       (<VERB? EXAMINE LOOK-INSIDE>
+		<TELL "Thicker thickets have never been thicker." CR>
+		<RTRUE>)>>
+
+;"Parser-related stuff"
+	 
+<OBJECT NOT-HERE-OBJECT
+	(DESC "such thing" ;"[not here]")
+	(ACTION NOT-HERE-OBJECT-F)>
+
+<ROUTINE NOT-HERE-OBJECT-F ("AUX" TBL (PRSO? T) OBJ)
+	 ;"This COND is game independent (except the TELL)"
+	 <COND (<AND <EQUAL? ,PRSO ,NOT-HERE-OBJECT>
+		     <EQUAL? ,PRSI ,NOT-HERE-OBJECT>>
+		<TELL "Those things aren't here!" CR>
+		<RTRUE>)
+	       (<EQUAL? ,PRSO ,NOT-HERE-OBJECT>
+		<SET TBL ,P-PRSO>)
+	       (T
+		<SET TBL ,P-PRSI>
+		<SET PRSO? <>>)>
+	 <COND (.PRSO?
+		<COND (<VERB? LAMP-ON BURN LAMP-OFF>
+		       <COND (<SET OBJ <FIND-NOT-HERE .TBL .PRSO?>>
+			      <COND (<NOT <==? .OBJ ,NOT-HERE-OBJECT>>
+				     <RTRUE>)>)
+			     (T
+			      <RFALSE>)>)>)
+	       (T
+		<COND (<VERB? LAMP-ON BURN LAMP-OFF>
+		       <COND (<SET OBJ <FIND-NOT-HERE .TBL .PRSO?>>
+			      <COND (<NOT <==? .OBJ ,NOT-HERE-OBJECT>>
+				     <RTRUE>)>)
+			     (T
+			      <RFALSE>)>)>)>
+        ;"Here is the default 'cant see any' printer"
+	 <COND (<EQUAL? ,WINNER ,ADVENTURER>
+		<TELL "You can't see any">
+		<NOT-HERE-PRINT .PRSO?>
+		<TELL " here!" CR>)
+	       (T
+		<TELL "The " D ,WINNER " seems confused. \"I don't see any">
+		<NOT-HERE-PRINT .PRSO?>
+		<TELL " here!\"" CR>)>
+	 <RTRUE>>
+
+<ROUTINE FIND-NOT-HERE (TBL PRSO? "AUX" M-F OBJ)
+	;"Here is where special-case code goes. <MOBY-FIND .TBL> returns
+	   number of matches. If 1, then P-MOBY-FOUND is it. One may treat
+	   the 0 and >1 cases alike or different. It doesn't matter. Always
+	   return RFALSE (not handled) if you have resolved the problem."
+	<SET M-F <MOBY-FIND .TBL>>
+	<COND (<AND <G? .M-F 1>
+		    <SET OBJ <GETP <1 .TBL> ,P?GLOBAL>>>
+	       <SET M-F 1>
+	       <SETG P-MOBY-FOUND .OBJ>)>
+	<COND (<==? 1 .M-F>
+	       <COND (.PRSO? <SETG PRSO ,P-MOBY-FOUND>)
+		     (T <SETG PRSI ,P-MOBY-FOUND>)>
+	       <RFALSE>)
+	      (<NOT .PRSO?>
+	       <TELL "You wouldn't find any">
+	       <NOT-HERE-PRINT .PRSO?>
+	       <TELL " there." CR>
+	       <RTRUE>)
+	      (T ,NOT-HERE-OBJECT)>>
+
+<ROUTINE GLOBAL-NOT-HERE-PRINT (OBJ)
+	 <COND (,P-MULT <SETG P-NOT-HERE <+ ,P-NOT-HERE 1>>)
+	       (T
+		<TELL "You can't see any">
+		<COND (<EQUAL? .OBJ ,PRSO> <PRSO-PRINT>)
+		      (T <PRSI-PRINT>)>
+		<TELL " here." CR>)>
+	 <SETG P-WON <>>>
+
+<ROUTINE NOT-HERE-PRINT (PRSO?)
+ <COND (,P-OFLAG
+	<COND (,P-XADJ <TELL " "> <PRINTB ,P-XADJN>)>
+	<COND (,P-XNAM <TELL " "> <PRINTB ,P-XNAM>)>)
+       (.PRSO?
+	<BUFFER-PRINT <GET ,P-ITBL ,P-NC1> <GET ,P-ITBL ,P-NC1L> <>>)
+       (T
+	<BUFFER-PRINT <GET ,P-ITBL ,P-NC2> <GET ,P-ITBL ,P-NC2L> <>>)>
+ <SETG P-WON <>>>
\ No newline at end of file
diff --git a/infidel.zil b/infidel.zil
new file mode 100644
index 0000000..6d31465
--- /dev/null
+++ b/infidel.zil
@@ -0,0 +1,73 @@
+"
+			      INFIDEL
+	(c) Copyright 1983 Infocom, Inc.  All Rights Reserved.
+"
+
+<SNAME "INFIDEL">
+
+<GC-MON <>>
+;<COND (<GASSIGNED? ZILCH> <GC 0 T>)
+      (T <GC 0 T 5>)>
+<GC 0 T 5>
+
+<BLOAT 90000 0 0 3500 0 0 0 0 0 512>
+
+;<SETG SHORT-STRINGS 2>
+
+<SET REDEFINE T>
+
+<GLOBAL BIGFIX 10000>
+
+<OR <GASSIGNED? ZILCH>
+    <SETG WBREAKS <STRING !\" !\= !,WBREAKS>>>
+
+<OR <GASSIGNED? INSERT-CRUFTY>
+    <DEFINE INSERT-CRUFTY (STR) <IFILE .STR T>>>
+
+<DEFINE IFILE (STR "OPTIONAL" (FLOAD? <>) "AUX" (TIM <TIME>))
+	<INSERT-FILE .STR .FLOAD?>>
+
+<PRINC "INFIDEL: Interlogic Adventure Fiction
+">
+
+<COND (<GASSIGNED? PREDGEN>
+       <ID 0>)>
+
+<IFILE "MACROS" T>
+
+<IFILE "GLOBALS" T>
+<PROPDEF SIZE 5>
+<PROPDEF CAPACITY 0>
+<PROPDEF VALUE 0>
+
+<IFILE "SYNTAX" T>
+<ENDLOAD>
+
+<IFILE "CLOCK" T>
+<IFILE "MAIN" T>
+<IFILE "PARSER" T>
+<INSERT-CRUFTY "CRUFTY">
+<IFILE "VERBS" T>
+
+
+
+;"MIKE: Add your files here, as with ROBOTS"
+
+<IFILE "INTERRUPTS" T>
+<IFILE "RA" T>
+<IFILE "ANTE" T>
+<IFILE "DIAMOND" T>
+<IFILE "BARGE" T>
+<IFILE "CUBE" T>
+<IFILE "CAMP" T>
+<IFILE "TEMPLE" T>
+
+<PRINC "INFIDEL: Interlogic Adventure Fiction
+
+
+
+
+
+
+
+Get ready!">
\ No newline at end of file
diff --git a/infidel.zip b/infidel.zip
new file mode 100644
index 0000000..c31b145
Binary files /dev/null and b/infidel.zip differ
diff --git a/interrupts.zil b/interrupts.zil
new file mode 100644
index 0000000..36d2b7b
--- /dev/null
+++ b/interrupts.zil
@@ -0,0 +1,273 @@
+"INTERRUPTS for
+			      INFIDEL
+	(c) Copyright 1983 Infocom, Inc.  All Rights Reserved.
+"
+
+;"		
+		Interrupt Routines for
+			PYRAMID"
+
+<GLOBAL RING-COUNTER 0>
+
+<ROUTINE I-RING-KILL ()
+	 <SETG RING-COUNTER <+ ,RING-COUNTER 1>>
+	 <COND (<EQUAL? ,RING-COUNTER 3>
+		<TELL 
+"You're starting to feel a little woozy. You blink your eyes, but can't seem
+to focus correctly. You think you see Craige standing by a wall." CR>)
+	       (<EQUAL? ,RING-COUNTER 5>
+		<TELL
+"Your ring finger is starting to throb painfully." CR>)
+	       (<G? ,RING-COUNTER 7>
+		<JIGS-UP
+"You fall over on your face as a quick-acting poison from the ring makes its
+way to your heart. Bye!">)>>
+
+<ROUTINE I-GINANDTONIC ()
+	 <COND (<G? ,THIRST 400>
+		<JIGS-UP
+"Like a grape, left out in the sun too long, you turn into a raisin for lack of
+water.">)
+	       (<AND <G? ,THIRST 380>
+		     <L? ,THIRST 387>>
+		<SETG NILE-DRINKS 0>
+		<TELL
+"If you don't drink something, and now, you're gonna be history." CR>)
+	       (<AND <G? ,THIRST 300>
+		     <L? ,THIRST 317>>
+		<SETG NILE-DRINKS 0>
+		<COND (<NOT <ROOM? ,TENT ,TENT2 ,SUPPLY-TENT>>
+		       <TELL "You'd better drink something, and soon!" CR>)
+		      (T
+		       <TELL "You wipe your fevered brow." CR>)>)
+	       (<AND <G? ,THIRST 200>
+		     <L? ,THIRST 217>>
+		<SETG NILE-DRINKS 0>
+		<COND (<NOT <ROOM? ,TENT ,TENT2 ,SUPPLY-TENT>>
+		       <TELL 
+"You scowl at the sun, cursing its searing heat." CR>)
+		      (T
+		       <TELL 
+"Even in the tent the heat starts to get to you." CR>)>)>>
+
+<ROUTINE I-MATCH-OUT ("OPTIONAL" BLOWN? "AUX" (FLG <>))
+	 <COND (<FSET? ,ONE-MATCH ,FLAMEBIT>
+		<COND (<NOT .BLOWN?>
+		       <TELL "Your match went out.">)
+		      (.BLOWN?
+		       <TELL "You blow out the match and toss it aside.">)>
+		<SET FLG T>)>
+	 <FCLEAR ,ONE-MATCH ,ONBIT>
+	 <FCLEAR ,ONE-MATCH ,FLAMEBIT>
+	 <FCLEAR ,MANY-MATCHES ,FLAMEBIT>
+	 <COND (<AND <IN? ,ONE-MATCH ,WINNER>
+		     <NOT .BLOWN?>>
+		<TELL " And it burned your fingers, too! You drop it. ">
+		<BUT-WHERE?>
+		<SET FLG <>>)>
+	 <MOVE ,ONE-MATCH ,GLOBAL-OBJECTS>
+	 <COND (,LIT
+		<SETG LIT <LIT? ,HERE>>)>
+	 <COND (<NOT <SETG LIT <LIT? ,HERE>>>
+		<TELL " It is now pitch black.">
+		<SET FLG T>)>
+	 <COND (.FLG
+		<CRLF>)>>
+
+<ROUTINE I-TORCH ("AUX" (FLG <>))
+	 <SETG TORCH-TURNS <+ ,TORCH-TURNS 1>>
+	 <COND (<NOT ,OILED-TORCH>
+		<TELL "Your torch is too dry and burns itself out quickly." CR>
+		<KILL-TORCH>
+		<SET FLG T>)>
+	 <COND (<OR <IN? ,TORCH ,WINNER>
+		    <EQUAL? <LOC ,TORCH> <LOC ,WINNER>>>
+		<COND (<EQUAL? ,TORCH-TURNS 150>
+		       <TELL "Your torch is beginning to sputter." CR>
+		       <SET FLG T>)
+		      (<EQUAL? ,TORCH-TURNS 162>
+		       <TELL "Your torch is getting very, very dim." CR>
+		       <SET FLG T>)
+		      (<EQUAL? ,TORCH-TURNS 175>
+		<TELL "With a final blaze of glory, your torch goes out." CR>
+		       <KILL-TORCH>
+		       <SET FLG T>)>)
+	       (<G? ,TORCH-TURNS 174>
+		<KILL-TORCH>)>
+	 .FLG>
+
+<ROUTINE KILL-TORCH ("OPTIONAL" (IN-SLAB? <>))
+	 <FCLEAR ,TORCH ,ONBIT>
+	 <FCLEAR ,TORCH ,FLAMEBIT>
+	 <COND (<NOT .IN-SLAB?>
+		<SETG OIL-SOAKED <>>
+		<SETG OILED-TORCH <>>
+		<SETG TORCH-TURNS 0>)>
+	 <COND (,LIT
+		<SETG LIT <LIT? ,HERE>>)>
+	 <COND (<NOT <SETG LIT <LIT? ,HERE>>>
+		<TELL "It is now pitch black." CR>)>
+	 <DISABLE <INT I-TORCH>>>
+
+<ROUTINE I-RESET-STATUES ("AUX" (CHECK-OFF 0) (COUNTER 0)
+			   (CLEAR-OFF 0) (FLG <>) STR)
+	 <REPEAT ()
+		 <COND (<EQUAL? .CHECK-OFF 4>
+			<RETURN>)
+		       (T
+			<SET CHECK-OFF <+ .CHECK-OFF 1>>
+			<COND (<OR <NOT <EQUAL? <GET ,ORDER-LTBL .CHECK-OFF>
+					    <GET ,TURNED-LTBL .CHECK-OFF>>>
+				   <FSET? <GET ,TURNED-LTBL .CHECK-OFF>
+					  ,CLAMPBIT>> 
+			       <SETG TURN-OFFSET 0>
+			       <REPEAT ()
+				       <SET CLEAR-OFF <+ .CLEAR-OFF 1>>
+				       <COND (<EQUAL? .CLEAR-OFF 5>
+					      <RETURN>)>
+				       <PUT ,TURNED-LTBL .CLEAR-OFF <>>
+				       <COND (<NOT <FSET? <GET ,STATUE-TBL
+							  <- .CLEAR-OFF 1>>
+						     ,CLAMPBIT>>
+					      <SET COUNTER <+ .COUNTER 1>>)>
+				       <FSET <GET ,STATUE-TBL <- .CLEAR-OFF 1>>
+					     ,CLAMPBIT>>
+			       <SET STR <GET ,NUM-TBL .COUNTER>>
+			       <COND (<NOT .COUNTER>
+				      <TELL
+"A loud click comes from beneath the four statues as they clamp down on the
+cover again." CR>)
+				     (T
+				      <TELL "The " .STR " statue">
+				      <COND (<G? .COUNTER 1>
+					     <TELL
+"s, heavy though they are, effortlessly swing back in unison to clamp down on the quartz cover again." CR>)
+					    (T
+					     <TELL
+", heavy though it is, effortlessly swings back to clamp down on the quartz cover again." CR>)>)>
+			       <SET FLG T>
+			       <RETURN>)>)>>
+	 <COND (<NOT .FLG> ;"order was correct"
+		<TELL 
+"The statues freeze in their current positions and you hear a light click come
+from the cover of the sarcophagus." CR>
+		<SETG CAN-TURN-STATUES <>>
+	        <SETG STATUES-SET T>
+		<SETG SCORE <+ ,SCORE 35>>)>>
+		
+<GLOBAL HUNGER 0>
+
+<ROUTINE I-GROWL ()
+	 <SETG HUNGER <+ ,HUNGER 1>>
+	 <COND (<AND <G? ,HUNGER 70>
+		     <L? ,HUNGER 73>>
+		<TELL "Your stomach growls in hunger." CR>)
+	       (<AND <G? ,HUNGER 100>
+		     <L? ,HUNGER 103>>
+		<TELL 
+"You feel yourself growing weaker. Without nourishment, this is a losing
+cause!" CR>)
+	       (<G? ,HUNGER 140>
+		<JIGS-UP
+"You fall over on your face, dreaming of Thanksgiving dinner. Needless to say,
+it was you against hunger. And hunger won.">)>> 
+
+<ROUTINE I-PARACHUTE ()
+	 <COND (<L? ,MOVES 3>
+		<COND (<IN-A-TENT?>
+		       <TELL CR 
+"You hear a plane flying high overhead, outside the tent." CR>)
+		      (T
+		       <TELL CR 
+"You crane your neck and see a plane, high overhead, circling the encampment." CR>)>
+		<RTRUE>)
+	       (<L? ,MOVES 5>
+		<COND (<IN-A-TENT?>
+		       <TELL CR "It sounds as if the plane is circling." CR>)
+		      (T
+		       <TELL CR 
+"The plane seems to be circling right overhead." CR>)>
+		<RTRUE>)
+	       (<EQUAL? ,MOVES 5>
+		<COND (<NOT <IN-A-TENT?>>
+		       <TELL CR 
+"You look up to see a small speck appear right beneath the plane -- probably a
+parachute. The plane heads off far to the northwest, dipping its wings in a
+salute." CR>)
+		      (T
+		       <TELL CR "It sounds as if the plane is flying off." CR>)>
+		<RTRUE>)
+	       (<EQUAL? ,MOVES 6>
+		<COND (<NOT <IN-A-TENT?>>
+		       <TELL CR 
+"A small speck descending from the plane overhead gets larger until you see a
+crate, dangling from a parachute." CR>)
+		      (T
+		       <TELL CR "You can barely hear the plane." CR>)>
+		<RTRUE>)
+	       (<EQUAL? ,MOVES 7>
+		<COND (<IN-A-TENT?>
+		       <MOVE ,CRATE <PICK-ONE ,ROOM-LTBL>>
+		       <TELL CR
+"The sound of something heavy landing comes from nearby." CR>)
+		      (T
+		       <TELL CR 
+"At last, your luck seems to be changing. A large crate lands right before you,
+its parachute flapping in the breeze. The parachute breaks away from the crate
+and drifts off in the wind." CR>
+		       <MOVE ,CRATE ,HERE>)>
+		<FSET ,CRATE ,VEHBIT>
+		<DISABLE <INT I-PARACHUTE>>
+		<RTRUE>)>>
+		 
+<ROUTINE IN-A-TENT? ("OPTIONAL" (COT-TOO? T))
+	 <COND (.COT-TOO?
+		<COND (<OR <EQUAL? <LOC ,WINNER> ,TENT ,TENT2 ,SUPPLY-TENT>
+			   <EQUAL? <LOC ,WINNER> ,COT>>
+		       <RTRUE>)
+		      (T <RFALSE>)>)
+	       (<NOT .COT-TOO?>
+		<COND (<EQUAL? <LOC ,WINNER> ,TENT ,TENT2 ,SUPPLY-TENT>
+		       <RTRUE>)
+		      (ELSE <RFALSE>)>)
+	       (ELSE
+		<RFALSE>)>>
+
+<GLOBAL RANDOM-ROOM-LTBL
+	<LTABLE P1 P2 P3 P4 P5 P6 P7 P8 EX1 EX3 EX5 EX7 EX9
+		FIRE>>
+
+<GLOBAL ROOM-LTBL
+	<LTABLE P1 P2 P3 P4 P5 P6 P7 P8 FIRE>> 
+
+<ROUTINE RANDOMIZE-HOLES ("AUX" (OFFS 0) MAX)
+	 <SET MAX <GET ,RANDOM-ROOM-LTBL 0>>
+	 <REPEAT ()
+		 <SET OFFS <+ .OFFS 1>>
+		 <COND (<G? .OFFS .MAX>
+			<RETURN>)
+		       (T
+			<PUTP <GET ,RANDOM-ROOM-LTBL .OFFS>
+			      ,P?CAPACITY <RANDOM 2>>)>>>
+
+<GLOBAL PYR-THIRST 0>
+
+<ROUTINE I-PYRAMID-DRINK ()
+	 <COND (<GETP ,HERE ,P?MAP>
+		<DISABLE <INT I-PYRAMID-DRINK>>
+		<RFALSE>)>
+	 <SETG PYR-THIRST <+ ,PYR-THIRST 1>>
+	 <SETG NILE-DRINKS 0>
+	 <COND (<EQUAL? ,PYR-THIRST 1>
+		<TELL
+"Even in this pyramid, you need to drink something, and soon." CR>)
+	       (<EQUAL? ,PYR-THIRST 10>
+		<TELL
+"Your throat feels as if it's coated with razor blades. Some water would be in
+order." CR>)
+	       (<EQUAL? ,PYR-THIRST 19>
+		<TELL "Better drink something. NOW!" CR>)
+	       (<EQUAL? ,PYR-THIRST 25>
+		<JIGS-UP
+"Well, your body could only take so much of this heat. Like a car, idling on a
+crowded highway, your body decides it's time to overheat. Such is death.">)>>
\ No newline at end of file
diff --git a/macros.zil b/macros.zil
new file mode 100644
index 0000000..c434575
--- /dev/null
+++ b/macros.zil
@@ -0,0 +1,136 @@
+"MACROS for
+			      INFIDEL
+	(c) Copyright 1983 Infocom, Inc.  All Rights Reserved.
+"
+
+<SETG C-ENABLED? 0>
+<SETG C-ENABLED 1>
+<SETG C-DISABLED 0>
+
+<DEFMAC TELL ("ARGS" A)
+	<FORM PROG ()
+	      !<MAPF ,LIST
+		     <FUNCTION ("AUX" E P O)
+			  <COND (<EMPTY? .A> <MAPSTOP>)
+				(<SET E <NTH .A 1>>
+				 <SET A <REST .A>>)>
+			  <COND (<TYPE? .E ATOM>
+				 <COND (<OR <=? <SET P <SPNAME .E>>
+						"CRLF">
+					    <=? .P "CR">>
+					<MAPRET '<CRLF>>)
+				       (<EMPTY? .A>
+					<ERROR INDICATOR-AT-END? .E>)
+				       (ELSE
+					<SET O <NTH .A 1>>
+					<SET A <REST .A>>
+					<COND (<OR <=? <SET P <SPNAME .E>>
+						       "DESC">
+						   <=? .P "D">
+						   <=? .P "OBJ">
+						   <=? .P "O">>
+					       <MAPRET <FORM PRINTD .O>>)
+					      (<OR <=? .P "NUM">
+						   <=? .P "N">>
+					       <MAPRET <FORM PRINTN .O>>)
+					      (<OR <=? .P "CHAR">
+						   <=? .P "CHR">
+						   <=? .P "C">>
+					       <MAPRET <FORM PRINTC .O>>)
+					      (ELSE
+					       <MAPRET
+						 <FORM PRINT
+						       <FORM GETP .O .E>>>)>)>)
+				(<TYPE? .E STRING ZSTRING>
+				 <MAPRET <FORM PRINTI .E>>)
+				(<TYPE? .E FORM>
+				 <MAPRET <FORM PRINT .E>>)
+				(ELSE <ERROR UNKNOWN-TYPE .E>)>>>>>
+
+<DEFMAC VERB? ("ARGS" ATMS)
+	<MULTIFROB PRSA .ATMS>>
+
+<DEFMAC PRSO? ("ARGS" ATMS)
+	<MULTIFROB PRSO .ATMS>>
+
+<DEFMAC PRSI? ("ARGS" ATMS)
+	<MULTIFROB PRSI .ATMS>>
+
+<DEFMAC ROOM? ("ARGS" ATMS)
+	<MULTIFROB HERE .ATMS>>
+
+<DEFINE MULTIFROB (X ATMS "AUX" (OO (OR)) (O .OO) (L ()) ATM) 
+	<REPEAT ()
+		<COND (<EMPTY? .ATMS>
+		       <RETURN!- <COND (<LENGTH? .OO 1> <ERROR .X>)
+				       (<LENGTH? .OO 2> <NTH .OO 2>)
+				       (ELSE <CHTYPE .OO FORM>)>>)>
+		<REPEAT ()
+			<COND (<EMPTY? .ATMS> <RETURN!->)>
+			<SET ATM <NTH .ATMS 1>>
+			<SET L
+			     (<COND (<TYPE? .ATM ATOM>
+				     <FORM GVAL
+					   <COND (<==? .X PRSA>
+						  <PARSE
+						    <STRING "V?"
+							    <SPNAME .ATM>>>)
+						 (ELSE .ATM)>>)
+				    (ELSE .ATM)>
+			      !.L)>
+			<SET ATMS <REST .ATMS>>
+			<COND (<==? <LENGTH .L> 3> <RETURN!->)>>
+		<SET O <REST <PUTREST .O (<FORM EQUAL? <FORM GVAL .X> !.L>)>>>
+		<SET L ()>>>
+
+<DEFMAC BLT ("ARGS" X "AUX" (TO <MEMQ TO .X>) (LL (())) (L .LL) ATM)
+	<COND (<AND .TO <1? <LENGTH <REST .TO>>>>
+	       <SET DEST <NTH .TO 2>>)
+	      (ELSE <SET DEST <>>)>
+	<REPEAT ()
+		<COND (<OR <EMPTY? .X> <==? <NTH .X 1> TO>>
+		       <RETURN <COND (<LENGTH? .LL 1> <ERROR BLT>)
+				     (<LENGTH? .LL 2> <NTH .LL 2>)
+				     (ELSE
+				      <FORM PROG !.LL>)>>)
+		      (ELSE
+		       <SET ATM <NTH .X 1>>
+		       <COND (<TYPE? .ATM ATOM>
+			      <SET ATM <FORM GVAL .ATM>>)>
+		       <SET L
+			    <REST
+			     <PUTREST .L
+				      (<COND (.DEST
+					      <FORM MOVE .ATM .DEST>)
+					     (ELSE
+					      <FORM REMOVE .ATM>)>)>>>
+		       <SET X <REST .X>>)>>>
+
+<DEFMAC RFATAL ()
+	'<PROG () <PUSH 2> <RSTACK>>>
+
+<DEFMAC PROB ('BASE? "OPTIONAL" 'LOSER?)
+	<COND (<ASSIGNED? LOSER?> <FORM ZPROB .BASE?>)
+	      (ELSE <FORM G? .BASE? '<RANDOM 100>>)>>
+
+<ROUTINE ZPROB
+	 (BASE)
+	 <COND (,LUCKY <G? .BASE <RANDOM 100>>)
+	       (ELSE <G? .BASE <RANDOM 300>>)>>
+
+<ROUTINE PICK-ONE (FROB)
+	 <GET .FROB <RANDOM <GET .FROB 0>>>>
+
+<DEFMAC ENABLE ('INT) <FORM PUT .INT ,C-ENABLED? 1>>
+
+<DEFMAC DISABLE ('INT) <FORM PUT .INT ,C-ENABLED? 0>>
+
+<DEFMAC OPENABLE? ('OBJ)
+	<FORM OR <FORM FSET? .OBJ ',DOORBIT>
+	         <FORM FSET? .OBJ ',CONTBIT>>> 
+
+<ROUTINE ABS (NUM)
+	 <COND (<G? .NUM 0>
+		<RETURN .NUM>)
+	       (ELSE
+		<RETURN <- 0 .NUM>>)>>
\ No newline at end of file
diff --git a/main.zil b/main.zil
new file mode 100644
index 0000000..9b780cd
--- /dev/null
+++ b/main.zil
@@ -0,0 +1,364 @@
+"MAIN for
+		           INFIDEL
+	Copyright 1983 Infocom, Inc.  All Rights Reserved.
+"
+
+<GLOBAL PLAYER <>>
+
+<GLOBAL P-WON <>>
+
+<CONSTANT M-FATAL 2>
+ 
+<CONSTANT M-HANDLED 1>   
+ 
+<CONSTANT M-NOT-HANDLED <>>   
+ 
+<CONSTANT M-OBJECT <>>
+
+<CONSTANT M-BEG 1>  
+ 
+<CONSTANT M-END 6> 
+ 
+<CONSTANT M-ENTER 2>
+ 
+<CONSTANT M-LOOK 3> 
+ 
+<CONSTANT M-FLASH 4>
+
+<CONSTANT M-OBJDESC 5>
+
+<ROUTINE GO () 
+;"put interrupts on clock chain"
+	 <RANDOMIZE-HOLES>
+	 <ENABLE <QUEUE I-GINANDTONIC -1>>
+	 <ENABLE <QUEUE I-PARACHUTE -1>>
+	 <ENABLE <QUEUE I-GROWL -1>>
+	 <REMOVE ,WATER>
+;"set up and go"
+	 <SETG LIT T>
+	 <SETG WINNER ,ADVENTURER>
+	 <SETG PLAYER ,WINNER>
+	 <SETG HERE ,TENT>
+	 <SETG P-IT-LOC ,HERE>
+	 <SETG P-IT-OBJECT <>>
+	 <COND (<NOT <FSET? ,HERE ,TOUCHBIT>>
+		<TELL ,START-STR CR>
+		<CRLF>
+		<V-VERSION>
+		<CRLF>)>
+	 <MOVE ,WINNER ,COT>
+	 <V-LOOK>
+	 <MAIN-LOOP>
+	 <AGAIN>>    
+
+
+<ROUTINE MAIN-LOOP ("AUX" ICNT OCNT NUM CNT OBJ TBL V PTBL OBJ1 TMP) 
+   #DECL ((CNT OCNT ICNT NUM) FIX (V) <OR 'T FIX FALSE> (OBJ) <OR FALSE OBJECT>
+	  (OBJ1) OBJECT (TBL) TABLE (PTBL) <OR FALSE ATOM>)
+   <REPEAT ()
+     <SET CNT 0>
+     <SET OBJ <>>
+     <SET PTBL T>
+     <COND (<SETG P-WON <PARSER>>
+	    <SET ICNT <GET ,P-PRSI ,P-MATCHLEN>>
+	    <SET NUM
+		 <COND (<0? <SET OCNT <GET ,P-PRSO ,P-MATCHLEN>>> .OCNT)
+		       (<G? .OCNT 1>
+			<SET TBL ,P-PRSO>
+			<COND (<0? .ICNT> <SET OBJ <>>)
+			      (T <SET OBJ <GET ,P-PRSI 1>>)>
+			.OCNT)
+		       (<G? .ICNT 1>
+			<SET PTBL <>>
+			<SET TBL ,P-PRSI>
+			<SET OBJ <GET ,P-PRSO 1>>
+			.ICNT)
+		       (T 1)>>
+	    <COND (<AND <NOT .OBJ> <1? .ICNT>> <SET OBJ <GET ,P-PRSI 1>>)>
+	    <COND (<==? ,PRSA ,V?WALK> <SET V <PERFORM ,PRSA ,PRSO>>)
+		  (<0? .NUM>
+		   <COND (<0? <BAND <GETB ,P-SYNTAX ,P-SBITS> ,P-SONUMS>>
+			  <SET V <PERFORM ,PRSA>>
+			  <SETG PRSO <>>)
+			 (<NOT ,LIT>
+			  <TELL "It's too dark to see." CR>)
+			 (T
+;"** M"			  <COND (.OBJ
+				 <COND (<AND <FSET? .OBJ ,CONTBIT>
+					     <NOT <FSET? .OBJ ,OPENBIT>>>
+					<TELL "Better open the " D .OBJ
+					      " first." CR>
+					<THIS-IS-IT .OBJ>
+					<SET V <>>)
+				       (<NOT <FSET? .OBJ ,CONTBIT>>
+					<TELL "There's nothing in that." CR>
+					<SET V <>>)
+				       (T
+					<TELL "It's not in that." CR>
+					<SET V <>>)>) 
+			        (T
+				 <TELL "There isn't anything to ">
+				 <SET TMP <GET ,P-ITBL ,P-VERBN>>
+				 <COND (,P-OFLAG
+					<PRINTB <GET .TMP 0>>)
+				       (T
+					<WORD-PRINT <GETB .TMP 2>
+						    <GETB .TMP 3>>)>
+				 <TELL "!" CR>
+				 <SET V <>>)>)>)
+		  (T
+		   <SETG P-NOT-HERE 0>
+		   <SETG P-MULT <>>
+		   <COND (<G? .NUM 1> <SETG P-MULT T>)>
+		   <SET TMP <>>
+		   <REPEAT ()
+			   <COND (<G? <SET CNT <+ .CNT 1>> .NUM>
+				  <COND (<G? ,P-NOT-HERE 0>
+					 <TELL "The ">
+					 <COND (<NOT <EQUAL? ,P-NOT-HERE .NUM>>
+						<TELL "other ">)>
+					 <TELL "object">
+					 <COND (<NOT <EQUAL? ,P-NOT-HERE 1>>
+						<TELL "s">)>
+					 <TELL " that you mentioned ">
+					 <COND (<NOT <EQUAL? ,P-NOT-HERE 1>>
+						<TELL "are">)
+					       (T <TELL "is">)>
+					 <TELL "n't here." CR>)
+					(<NOT .TMP>
+					 <TELL 
+"I don't know what you're referring to." CR>)>
+				  <RETURN>)
+				 (T
+				  <COND (.PTBL <SET OBJ1 <GET ,P-PRSO .CNT>>)
+					(T <SET OBJ1 <GET ,P-PRSI .CNT>>)>
+				  <SETG PRSO <COND (.PTBL .OBJ1) (T .OBJ)>>
+				  <SETG PRSI <COND (.PTBL .OBJ) (T .OBJ1)>>
+				  <COND (<VERB? COMPARE> T)
+					(<G? .NUM 1>
+					 <COND (<EQUAL? .OBJ1
+							 ,NOT-HERE-OBJECT>
+						 <SETG P-NOT-HERE
+						       <+ ,P-NOT-HERE 1>>
+						 <AGAIN>)
+						(<AND <VERB? TAKE>
+						      ,PRSI
+						      <EQUAL? <GET <GET ,P-ITBL
+									,P-NC1>
+								   0>
+							      ,W?ALL>
+						      <NOT <IN? ,PRSO ,PRSI>>>
+						 <AGAIN>)
+						(<AND <EQUAL? ,P-GETFLAGS
+							      ,P-ALL>
+						      <VERB? TAKE>
+						      <OR <AND <NOT <EQUAL?
+								    <LOC .OBJ1>
+								     ,WINNER
+								     ,HERE>>
+							       <NOT <FSET?
+								    <LOC .OBJ1>
+								   ,TRANSBIT>>>
+							  <FSET? .OBJ1
+								 ,DONTTAKE>
+							  <EQUAL? .OBJ1
+								  ,PLASTER
+								  ,PLASTER1>>>
+						 <AGAIN>)
+						(<AND <EQUAL? ,P-GETFLAGS
+							      ,P-ALL>
+						      <VERB? DROP>
+						      <NOT <IN? .OBJ1 ,WINNER>>
+						      <NOT <IN? ,P-IT-OBJECT
+								,WINNER>>>
+						 <AGAIN>)
+						(T
+						 <COND (<EQUAL? .OBJ1 ,IT>
+							<PRINTD ,P-IT-OBJECT>)
+						       (T <PRINTD .OBJ1>)>
+						 <TELL ": ">)>)>
+				  <SET TMP T>
+				  <SET V <PERFORM ,PRSA ,PRSO ,PRSI>>
+				  <COND (<==? .V ,M-FATAL> <RETURN>)>)>>)>
+	    <COND (<NOT <==? .V ,M-FATAL>>
+		   ;<COND (<==? <LOC ,WINNER> ,PRSO>
+			  <SETG PRSO <>>)>
+		   ;"Removing this code should fix the problem that AGAIN
+		     loses when in a vehicle and it is the PRSO."
+		   <SET V <APPLY <GETP <LOC ,WINNER> ,P?ACTION> ,M-END>>)>
+	    <COND (<VERB? AGAIN WALK SAVE RESTORE SCORE VERSION WAIT> T)
+		  (T
+		   <SETG L-PRSA ,PRSA>
+		   <SETG L-PRSO ,PRSO>
+		   <SETG L-PRSI ,PRSI>)>
+	    <COND (<==? .V ,M-FATAL> <SETG P-CONT <>>)>)
+	   (T
+	    <SETG P-CONT <>>)>
+     <COND (,P-WON
+	    <COND (<VERB? TELL BRIEF SUPER-BRIEF VERBOSE SAVE VERSION> T)
+		  (T <SET V <CLOCKER>>)>)>>>
+ 
+<GLOBAL P-MULT <>>
+
+<GLOBAL P-NOT-HERE 0>
+
+<GLOBAL L-PRSA <>>  
+ 
+<GLOBAL L-PRSO <>>  
+ 
+<GLOBAL L-PRSI <>>  
+
+%<COND (<GASSIGNED? PREDGEN>
+
+'<ROUTINE PERFORM (A "OPTIONAL" (O <>) (I <>) "AUX" V OA OO OI) 
+	#DECL ((A) FIX (O) <OR FALSE OBJECT FIX> (I) <OR FALSE OBJECT> (V) ANY)
+	<SET OA ,PRSA>
+	<SET OO ,PRSO>
+	<SET OI ,PRSI>
+	<COND (<AND <EQUAL? ,IT .I .O>
+		    <NOT <EQUAL? ,P-IT-LOC ,HERE>>>
+	       <TELL "I don't see what you are referring to." CR>
+	       <RFATAL>)>
+	<COND (<==? .O ,IT> <SET O ,P-IT-OBJECT>)>
+	<COND (<==? .I ,IT> <SET I ,P-IT-OBJECT>)>
+	<SETG PRSA .A>
+	<SETG PRSO .O>
+	<COND (<AND ,PRSO <NOT <EQUAL? ,PRSI ,IT>> <NOT <VERB? WALK>>>
+	       <SETG P-IT-OBJECT ,PRSO>
+	       <SETG P-IT-LOC ,HERE>)>
+	<SETG PRSI .I>
+	<COND (<AND <EQUAL? ,NOT-HERE-OBJECT ,PRSO ,PRSI>
+		    <SET V <NOT-HERE-OBJECT-F>>>
+	       <SETG P-WON <>>
+	       .V)
+	      (T
+	       <SET O ,PRSO>
+	       <SET I ,PRSI>
+	       <COND
+		(<SET V <APPLY <GETP ,WINNER ,P?ACTION>>> .V)
+		(<SET V <APPLY <GETP <LOC ,WINNER> ,P?ACTION> ,M-BEG>> .V)
+		(<SET V <APPLY <GET ,PREACTIONS .A>>> .V)
+		(<AND .I <SET V <APPLY <GETP .I ,P?ACTION>>>> .V)
+		(<AND .O
+		      <NOT <==? .A ,V?WALK>>
+		      <LOC .O>
+		      <SET V <APPLY <GETP <LOC .O> ,P?CONTFCN>>>>
+		 .V)
+		(<AND .O
+		      <NOT <==? .A ,V?WALK>>
+		      <SET V <APPLY <GETP .O ,P?ACTION>>>>
+		 .V)
+		(<SET V <APPLY <GET ,ACTIONS .A>>> .V)>)>
+	<COND (<NOT <==? .V ,M-FATAL>>
+	       <COND (<==? <LOC ,WINNER> ,PRSO>
+		      <SETG PRSO <>>)>
+	       <SET V <APPLY <GETP <LOC ,WINNER> ,P?ACTION> ,M-END>>)>
+	<SETG PRSA .OA>
+	<SETG PRSO .OO>
+	<SETG PRSI .OI>
+	.V>)
+       (T
+	
+'<PROG ()
+
+<SETG PDEBUG <>>
+
+<ROUTINE PERFORM (A "OPTIONAL" (O <>) (I <>) "AUX" V OA OO OI) 
+	#DECL ((A) FIX (O) <OR FALSE OBJECT FIX> (I) <OR FALSE OBJECT> (V) ANY)
+	<COND (,PDEBUG
+	       <TELL "** PERFORM: PRSA = ">
+	       <PRINC <NTH ,ACTIONS <+ <* .A 2> 1>>>
+	       <COND (<AND .O <NOT <==? .A ,V?WALK>>>
+		      <TELL " | PRSO = " D .O>)>
+	       <COND (.I <TELL " | PRSI = " D .I>)>)>
+	<SET OA ,PRSA>
+	<SET OO ,PRSO>
+	<SET OI ,PRSI>
+	<COND (<AND <EQUAL? ,IT .I .O>
+		    <NOT <EQUAL? ,P-IT-LOC ,HERE>>>
+	       <TELL "I don't see what you are referring to." CR>
+	       <RFATAL>)>
+	<COND (<==? .O ,IT> <SET O ,P-IT-OBJECT>)>
+	<COND (<==? .I ,IT> <SET I ,P-IT-OBJECT>)>
+	<SETG PRSA .A>
+	<SETG PRSO .O>
+	<COND (<AND ,PRSO <NOT <EQUAL? ,PRSI ,IT>> <NOT <VERB? WALK>>>
+	       <SETG P-IT-OBJECT ,PRSO>
+	       <SETG P-IT-LOC ,HERE>)>
+	<SETG PRSI .I>
+	<COND (<AND <EQUAL? ,NOT-HERE-OBJECT ,PRSO ,PRSI>
+		    <SET V <D-APPLY "Not Here" ,NOT-HERE-OBJECT-F>>>
+	       <SETG P-WON <>>
+	       .V)
+	      (T
+	       <SET O ,PRSO>
+	       <SET I ,PRSI>
+	       <COND (<SET V <D-APPLY "Actor"
+				      <GETP ,WINNER ,P?ACTION>>> .V)
+		     (<SET V <D-APPLY "Room (M-BEG)"
+				      <GETP <LOC ,WINNER> ,P?ACTION>
+				      ,M-BEG>> .V)
+		     (<SET V <D-APPLY "Preaction"
+				      <GET ,PREACTIONS .A>>> .V)
+		     (<AND .I <SET V <D-APPLY "PRSI"
+					      <GETP .I ,P?ACTION>>>> .V)
+		     (<AND .O
+			   <NOT <==? .A ,V?WALK>>
+			   <LOC .O>
+			   <SET V <D-APPLY "Container"
+					   <GETP <LOC .O> ,P?CONTFCN>>>>
+		      .V)
+		     (<AND .O
+			   <NOT <==? .A ,V?WALK>>
+			   <SET V <D-APPLY "PRSO"
+					   <GETP .O ,P?ACTION>>>>
+		      .V)
+		     (<SET V <D-APPLY <>
+				      <GET ,ACTIONS .A>>> .V)>)>
+	<COND (<NOT <==? .V ,M-FATAL>>
+	       <COND (<==? <LOC ,WINNER> ,PRSO>
+		      <SETG PRSO <>>)>
+	       <SET V <D-APPLY "Room (M-END)"
+			       <GETP <LOC ,WINNER> ,P?ACTION> ,M-END>>)>
+	<SETG PRSA .OA>
+	<SETG PRSO .OO>
+	<SETG PRSI .OI>
+	.V>
+
+<DEFINE D-APPLY (STR FCN "OPTIONAL" FOO "AUX" RES)
+	<COND (<NOT .FCN> <>)
+	      (T
+	       <COND (,PDEBUG
+		      <COND (<NOT .STR>
+			     <TELL CR "  Default ->" CR>)
+			    (T <TELL CR "  " .STR " -> ">)>)>
+	       <SET RES
+		    <COND (<ASSIGNED? FOO>
+			   <APPLY .FCN .FOO>)
+			  (T <APPLY .FCN>)>>
+	       <COND (<AND ,PDEBUG .STR>
+		      <COND (<==? .RES 2>
+			     <TELL "Fatal" CR>)
+			    (<NOT .RES>
+			     <TELL "Not handled">)
+			    (T <TELL "Handled" CR>)>)>
+	       .RES)>>
+
+>)>  
+ 
+<GLOBAL START-STR
+"You wake slowly, sit up in your bunk, look around the tent, and try to ignore
+the pounding in your head, the cottony taste in your mouth, and the ache in
+your stomach. The droning of a plane's engine breaks the stillness and you
+realize that things outside are quiet -- too quiet. You know that this can
+mean only one thing: your workmen have deserted you. They complained over the
+last few weeks, grumbling about the small pay and lack of food, and your
+inability to locate the pyramid. And after what you stupidly did yesterday,
+trying to make them work on a holy day, their leaving is understandable.|
+|
+The Professor's map was just an ancient map -- as worthless as an ice cube in
+the Arctic without an instrument fine enough to accurately measure longitude
+and latitude. You knew that the site was nearby. You dug, and you ordered the
+workers to dig, even without the box. As you listen to the plane and rub your
+aching eyes, you pray they left you supplies enough to find the pyramid and to
+survive, and that the plane's carrying the long-overdue box.">
\ No newline at end of file
diff --git a/parser.zil b/parser.zil
new file mode 100644
index 0000000..a944570
--- /dev/null
+++ b/parser.zil
@@ -0,0 +1,1150 @@
+"PARSER for
+			      INFIDEL
+	(c) Copyright 1983 Infocom, Inc.  All Rights Reserved.
+"
+
+"Parser global variable convention:  All parser globals will 
+  begin with 'P-'.  Local variables are not restricted in any
+  way.
+" 
+ 
+<GLOBAL P-XNAM <>>
+<GLOBAL P-XADJ <>>
+<GLOBAL P-XADJN <>>
+
+<SETG SIBREAKS ".,\"">
+ 
+<GLOBAL GWIM-DISABLE <>> 
+ 
+<GLOBAL PRSA 0>
+ 
+<GLOBAL PRSI 0>
+
+<GLOBAL PRSO 0>
+
+<GLOBAL P-TABLE 0>  
+ 
+<GLOBAL P-ONEOBJ 0> 
+ 
+<GLOBAL P-SYNTAX 0> 
+ 
+<GLOBAL P-CCSRC 0>  
+ 
+<GLOBAL P-LEN 0>    
+ 
+<GLOBAL P-DIR 0>    
+ 
+<GLOBAL HERE 0>
+ 
+<GLOBAL WINNER 0>   
+ 
+<GLOBAL P-LEXV <ITABLE BYTE 120>>
+;"INBUF - Input buffer for READ"   
+ 
+<GLOBAL P-INBUF <ITABLE BYTE 100>>
+;"Parse-cont variable"  
+ 
+<GLOBAL P-CONT <>>  
+ 
+<GLOBAL P-IT-OBJECT <>>
+<GLOBAL P-IT-LOC <>>
+
+;"Orphan flag" 
+ 
+<GLOBAL P-OFLAG <>> 
+ 
+<GLOBAL P-MERGED <>>
+
+<GLOBAL P-ACLAUSE <>>    
+ 
+<GLOBAL P-ANAM <>>  
+ 
+<GLOBAL P-AADJ <>>
+;"Parser variables and temporaries"
+ 
+<CONSTANT P-PHRLEN 3>    
+ 
+<CONSTANT P-ORPHLEN 7>   
+ 
+<CONSTANT P-RTLEN 3>
+;"Byte offset to # of entries in LEXV"
+
+<CONSTANT P-LEXWORDS 1>
+;"Word offset to start of LEXV entries" 
+ 
+<CONSTANT P-LEXSTART 1>
+;"Number of words per LEXV entry"  
+ 
+<CONSTANT P-LEXELEN 2>   
+ 
+<CONSTANT P-WORDLEN 4>
+;"Offset to parts of speech byte"   
+ 
+<CONSTANT P-PSOFF 4>
+;"Offset to first part of speech"
+ 
+<CONSTANT P-P1OFF 5>
+;"First part of speech bit mask in PSOFF byte"  
+ 
+<CONSTANT P-P1BITS 3>    
+ 
+<CONSTANT P-ITBLLEN 9>   
+ 
+<GLOBAL P-ITBL <TABLE 0 0 0 0 0 0 0 0 0 0>>  
+ 
+<GLOBAL P-OTBL <TABLE 0 0 0 0 0 0 0 0 0 0>>  
+ 
+<GLOBAL P-VTBL <TABLE 0 0 0 0>>
+
+<GLOBAL P-NCN 0>    
+ 
+<CONSTANT P-VERB 0> 
+ 
+<CONSTANT P-VERBN 1>
+ 
+<CONSTANT P-PREP1 2>
+ 
+<CONSTANT P-PREP1N 3>    
+ 
+<CONSTANT P-PREP2 4>
+ 
+<CONSTANT P-PREP2N 5>    
+ 
+<CONSTANT P-NC1 6>  
+ 
+<CONSTANT P-NC1L 7> 
+ 
+<CONSTANT P-NC2 8>  
+ 
+<CONSTANT P-NC2L 9> 
+ 
+<GLOBAL QUOTE-FLAG <>>
+
+" Grovel down the input finding the verb, prepositions, and noun clauses.
+   If the input is <direction> or <walk> <direction>, fall out immediately
+   setting PRSA to ,V?WALK and PRSO to <direction>.  Otherwise, perform
+   all required orphaning, syntax checking, and noun clause lookup."   
+
+<ROUTINE PARSER ("AUX" (PTR ,P-LEXSTART) WRD (VAL 0) (VERB <>)
+		       LEN (DIR <>) (NW 0) (LW 0) NUM SCNT (CNT -1)) 
+	<REPEAT ()
+		<COND (<G? <SET CNT <+ .CNT 1>> ,P-ITBLLEN> <RETURN>)
+		      (T <PUT ,P-ITBL .CNT 0>)>>
+	<SETG P-ADVERB <>>
+	<SETG P-MERGED <>>
+	<PUT ,P-PRSO ,P-MATCHLEN 0>
+	<PUT ,P-PRSI ,P-MATCHLEN 0>
+	<PUT ,P-BUTS ,P-MATCHLEN 0>
+	<COND (<AND <NOT ,QUOTE-FLAG> <N==? ,WINNER ,ADVENTURER>>
+	       <SETG WINNER ,ADVENTURER>
+	       <COND (<NOT <FSET? <LOC ,WINNER> ,VEHBIT>>
+		      <SETG HERE <LOC ,WINNER>>)>)>
+	<COND (,P-CONT
+	       <SET PTR ,P-CONT>
+	       <COND (<AND <NOT ,SUPER-BRIEF> <==? ,PLAYER ,WINNER>>
+		      <CRLF>)>
+	       <SETG P-CONT <>>)
+	      (T
+	       <SETG WINNER ,ADVENTURER>
+	       <SETG QUOTE-FLAG <>>
+	       <COND (<NOT <FSET? <LOC ,WINNER> ,VEHBIT>>
+		      <SETG HERE <LOC ,WINNER>>)>
+	       <COND (<NOT ,SUPER-BRIEF> <CRLF>)>
+	       <TELL ">">
+	       <READ ,P-INBUF ,P-LEXV>)>
+	<SETG P-LEN <GETB ,P-LEXV ,P-LEXWORDS>>
+	<COND (<0? ,P-LEN> <TELL "I beg your pardon?" CR> <RFALSE>)>
+	<SET LEN ,P-LEN>
+	<SETG P-DIR <>>
+	<SETG P-NCN 0>
+	<SETG P-GETFLAGS 0>
+	<REPEAT ()
+		<COND (<L? <SETG P-LEN <- ,P-LEN 1>> 0>
+		       <SETG QUOTE-FLAG <>>
+		       <RETURN>)
+		      (<OR <SET WRD <GET ,P-LEXV .PTR>>
+			   <SET WRD <NUMBER? .PTR>>>
+		       <COND (<AND <==? .WRD ,W?TO>
+				   <EQUAL? .VERB ,ACT?TELL ;,ACT?ASK>>
+			      <SET WRD ,W?QUOTE>)
+			     (<AND <==? .WRD ,W?THEN>
+				   <NOT .VERB>>
+			      <PUT ,P-ITBL ,P-VERB ,ACT?TELL>
+			      <PUT ,P-ITBL ,P-VERBN 0>
+			      <SET WRD ,W?QUOTE>)>
+		       <COND ;(<AND <EQUAL? .WRD ,W?.>
+				   <EQUAL? .LW ,W?MRS ,W?MR ,W?MS>>
+			      <SET LW 0>)
+			     (<OR <EQUAL? .WRD ,W?THEN ,W?.>
+				  <EQUAL? .WRD ,W?QUOTE>> 
+			      <COND (<EQUAL? .WRD ,W?QUOTE>
+				     <COND (,QUOTE-FLAG
+					    <SETG QUOTE-FLAG <>>)
+					   (T <SETG QUOTE-FLAG T>)>)>
+			      <OR <0? ,P-LEN>
+				  <SETG P-CONT <+ .PTR ,P-LEXELEN>>>
+			      <PUTB ,P-LEXV ,P-LEXWORDS ,P-LEN>
+			      <RETURN>)
+			     (<AND <SET VAL
+					<WT? .WRD
+					     ,PS?DIRECTION
+					     ,P1?DIRECTION>>
+				   <EQUAL? .VERB <> ,ACT?WALK>
+				   <OR <==? .LEN 1>
+				       <AND <==? .LEN 2> <==? .VERB ,ACT?WALK>>
+				       <AND <EQUAL? <SET NW
+						     <GET ,P-LEXV
+							  <+ .PTR ,P-LEXELEN>>>
+					            ,W?THEN
+					            ,W?.
+					            ,W?QUOTE>
+					    <NOT <L? .LEN 2>>>
+				       <AND ,QUOTE-FLAG
+					    <==? .LEN 2>
+					    <EQUAL? .NW ,W?QUOTE>>
+				       <AND <G? .LEN 2>
+					    <EQUAL? .NW ,W?COMMA ,W?AND>>>>
+			      <SET DIR .VAL>
+			      <COND (<EQUAL? .NW ,W?COMMA ,W?AND>
+				     <PUT ,P-LEXV
+					  <+ .PTR ,P-LEXELEN>
+					  ,W?THEN>)>
+			      <COND (<NOT <G? .LEN 2>>
+				     <SETG QUOTE-FLAG <>>
+				     <RETURN>)>)
+			     (<AND <SET VAL <WT? .WRD ,PS?VERB ,P1?VERB>>
+				   <NOT .VERB> ;<OR <NOT .VERB>
+				       <EQUAL? .VERB ,ACT?WHAT>>>
+			      <SET VERB .VAL>
+			      <PUT ,P-ITBL ,P-VERB .VAL>
+			      <PUT ,P-ITBL ,P-VERBN ,P-VTBL>
+			      <PUT ,P-VTBL 0 .WRD>
+			      <PUTB ,P-VTBL 2 <GETB ,P-LEXV
+						    <SET NUM
+							 <+ <* .PTR 2> 2>>>>
+			      <PUTB ,P-VTBL 3 <GETB ,P-LEXV <+ .NUM 1>>>)
+			     (<OR <SET VAL <WT? .WRD ,PS?PREPOSITION 0>>
+				  <AND <OR <EQUAL? .WRD ,W?ALL ,W?ONE ,W?A>
+					   <WT? .WRD ,PS?ADJECTIVE>
+					   <WT? .WRD ,PS?OBJECT>>
+				       <SET VAL 0>>>
+			      <COND (<AND <G? ,P-LEN 0>
+					  <==? <GET ,P-LEXV
+						    <+ .PTR ,P-LEXELEN>>
+					       ,W?OF>
+					  ;<NOT <EQUAL? .VERB ,ACT?ACCUSE>>
+					  <0? .VAL>
+					  <NOT
+					   <EQUAL? .WRD ,W?ALL ,W?ONE ,W?A>>>)
+				    (<AND <NOT <0? .VAL>>
+				          <OR <0? ,P-LEN>
+					      <EQUAL? <GET ,P-LEXV <+ .PTR 2>>
+						      ,W?THEN ,W?.>>>
+				     <COND (<L? ,P-NCN 2>
+					    <PUT ,P-ITBL ,P-PREP1 .VAL>
+					    <PUT ,P-ITBL ,P-PREP1N .WRD>)>)
+				    (<==? ,P-NCN 2>
+				     <TELL
+"I found too many nouns in that sentence." CR>
+				     <RFALSE>)
+				    (T
+				     <SETG P-NCN <+ ,P-NCN 1>>
+				     <OR <SET PTR <CLAUSE .PTR .VAL .WRD>>
+					 <RFALSE>>
+				     <COND (<L? .PTR 0>
+					    <SETG QUOTE-FLAG <>>
+					    <RETURN>)>)>)
+			     ;(<OR <EQUAL? .WRD ,W?CAREFULLY ,W?QUIETLY>
+				  <EQUAL? .WRD ,W?SLOWLY ,W?QUICKLY
+					        ,W?BRIEFLY>>
+			      <SETG P-ADVERB .WRD>)
+			     (<WT? .WRD ,PS?BUZZ-WORD>)
+			     (T
+			      <CANT-USE .PTR>
+			      <RFALSE>)>)
+		      (T
+		       <UNKNOWN-WORD .PTR>
+		       <RFALSE>)>
+		<SET LW .WRD>
+		<SET PTR <+ .PTR ,P-LEXELEN>>>
+	<COND (.DIR
+	       <SETG PRSA ,V?WALK>
+	       <SETG PRSO .DIR>
+	       <SETG P-WALK-DIR .DIR>
+	       <RETURN T>)>
+	<SETG P-WALK-DIR <>>
+	<COND (,P-OFLAG <ORPHAN-MERGE>)>
+	;<COND (<==? <GET ,P-ITBL ,P-VERB> 0> <PUT ,P-ITBL ,P-VERB ,ACT?CALL>)>
+	<COND (<AND <SYNTAX-CHECK> <SNARF-OBJECTS> <TAKE-CHECK> <MANY-CHECK>>
+	       T)>>
+
+
+<GLOBAL P-WALK-DIR <>>
+
+;"Check whether word pointed at by PTR is the correct part of speech.
+   The second argument is the part of speech (,PS?<part of speech>).  The
+   3rd argument (,P1?<part of speech>), if given, causes the value
+   for that part of speech to be returned." 
+
+<ROUTINE WT? (PTR BIT "OPTIONAL" (B1 5) "AUX" (OFFS ,P-P1OFF) TYP) 
+	<COND (<BTST <SET TYP <GETB .PTR ,P-PSOFF>> .BIT>
+	       <COND (<G? .B1 4> <RTRUE>)
+		     (T
+		      <SET TYP <BAND .TYP ,P-P1BITS>>
+		      <COND (<NOT <==? .TYP .B1>> <SET OFFS <+ .OFFS 1>>)>
+		      <GETB .PTR .OFFS>)>)>>
+;" Scan through a noun clause, leave a pointer to its starting location"
+ 
+<ROUTINE CLAUSE (PTR VAL WRD "AUX" OFF NUM (ANDFLG <>) (FIRST?? T) NW (LW 0)) 
+	#DECL ((PTR VAL OFF NUM) FIX (WRD NW) <OR FALSE FIX TABLE>
+	       (ANDFLG FIRST??) <OR ATOM FALSE>)
+	<SET OFF <* <- ,P-NCN 1> 2>>
+	<COND (<NOT <==? .VAL 0>>
+	       <PUT ,P-ITBL <SET NUM <+ ,P-PREP1 .OFF>> .VAL>
+	       <PUT ,P-ITBL <+ .NUM 1> .WRD>
+	       <SET PTR <+ .PTR ,P-LEXELEN>>)
+	      (T <SETG P-LEN <+ ,P-LEN 1>>)>
+	<COND (<0? ,P-LEN> <SETG P-NCN <- ,P-NCN 1>> <RETURN -1>)>
+	<PUT ,P-ITBL <SET NUM <+ ,P-NC1 .OFF>> <REST ,P-LEXV <* .PTR 2>>>
+	<COND (<EQUAL? <GET ,P-LEXV .PTR> ,W?THE ,W?A ,W?AN>
+	       <PUT ,P-ITBL .NUM <REST <GET ,P-ITBL .NUM> 4>>)>
+	<REPEAT ()
+		<COND (<L? <SETG P-LEN <- ,P-LEN 1>> 0>
+		       <PUT ,P-ITBL <+ .NUM 1> <REST ,P-LEXV <* .PTR 2>>>
+		       <RETURN -1>)>
+		<COND (<OR <SET WRD <GET ,P-LEXV .PTR>>
+			   <SET WRD <NUMBER? .PTR>>>
+		       <COND (<0? ,P-LEN> <SET NW 0>)
+			     (T <SET NW <GET ,P-LEXV <+ .PTR ,P-LEXELEN>>>)>
+		       ;<COND (<AND <==? .WRD ,W?OF>
+				   <==? <GET ,P-ITBL ,P-VERB> ,ACT?ACCUSE>>
+			      <PUT ,P-LEXV .PTR ,W?WITH>
+			      <SET WRD ,W?WITH>)>
+		       <COND ;(<AND <EQUAL? .WRD ,W?.>
+				   <EQUAL? .LW ,W?MRS ,W?MR ,W?MS>>
+			      <SET LW 0>)
+			     (<EQUAL? .WRD ,W?AND ,W?COMMA> <SET ANDFLG T>)
+			     (<EQUAL? .WRD ,W?ALL ,W?ONE>
+			      <COND (<==? .NW ,W?OF>
+				     <SETG P-LEN <- ,P-LEN 1>>
+				     <SET PTR <+ .PTR ,P-LEXELEN>>)>)
+			     (<OR <EQUAL? .WRD ,W?THEN ,W?.>
+				  <AND <WT? .WRD ,PS?PREPOSITION>
+				       <NOT .FIRST??>>>
+			      <SETG P-LEN <+ ,P-LEN 1>>
+			      <PUT ,P-ITBL
+				   <+ .NUM 1>
+				   <REST ,P-LEXV <* .PTR 2>>>
+			      <RETURN <- .PTR ,P-LEXELEN>>)
+			     (<WT? .WRD ,PS?OBJECT>
+			      <COND (<AND <WT? .WRD
+					       ,PS?ADJECTIVE
+					       ,P1?ADJECTIVE>
+					  <NOT <==? .NW 0>>
+					  <WT? .NW ,PS?OBJECT>>)
+				    (<AND <NOT .ANDFLG>
+					  <NOT <EQUAL? .NW ,W?BUT ,W?EXCEPT>>
+					  <NOT <EQUAL? .NW ,W?AND ,W?COMMA>>>
+				     <PUT ,P-ITBL
+					  <+ .NUM 1>
+					  <REST ,P-LEXV <* <+ .PTR 2> 2>>>
+				     <RETURN .PTR>)
+				    (T <SET ANDFLG <>>)>)
+			     (<OR <WT? .WRD ,PS?ADJECTIVE>
+				  <WT? .WRD ,PS?BUZZ-WORD>>)
+			     (<AND .ANDFLG
+				   <OR <WT? .WRD ,PS?DIRECTION>
+				       <WT? .WRD ,PS?VERB>>>
+			      <SET PTR <- .PTR 4>>
+			      <PUT ,P-LEXV <+ .PTR 2> ,W?THEN>
+			      <SETG P-LEN <+ ,P-LEN 2>>)
+			     (<WT? .WRD ,PS?PREPOSITION> T)
+			     (T
+			      <CANT-USE .PTR>
+			      <RFALSE>)>)
+		      (T <UNKNOWN-WORD .PTR> <RFALSE>)>
+		<SET LW .WRD>
+		<SET FIRST?? <>>
+		<SET PTR <+ .PTR ,P-LEXELEN>>>> 
+
+<ROUTINE NUMBER? (PTR "AUX" CNT BPTR CHR (SUM 0) (TIM <>))
+	 <SET CNT <GETB <REST ,P-LEXV <* .PTR 2>> 2>>
+	 <SET BPTR <GETB <REST ,P-LEXV <* .PTR 2>> 3>>
+	 <REPEAT ()
+		 <COND (<L? <SET CNT <- .CNT 1>> 0> <RETURN>)
+		       (T
+			<SET CHR <GETB ,P-INBUF .BPTR>>
+			<COND (<==? .CHR 58>
+			       <SET TIM .SUM>
+			       <SET SUM 0>)
+			      (<G? .SUM 10000> <RFALSE>)
+			      (<AND <L? .CHR 58> <G? .CHR 47>>
+			       <SET SUM <+ <* .SUM 10> <- .CHR 48>>>)
+			      (T <RFALSE>)>
+			<SET BPTR <+ .BPTR 1>>)>>
+	 <PUT ,P-LEXV .PTR ,W?INTNUM>
+	 <COND (<G? .SUM 1000> <RFALSE>)
+	       (.TIM
+		<COND (<L? .TIM 8> <SET TIM <+ .TIM 12>>)
+		      (<G? .TIM 23> <RFALSE>)>
+		<SET SUM <+ .SUM <* .TIM 60>>>)>
+	 <SETG P-NUMBER .SUM>
+	 ,W?INTNUM>
+
+<GLOBAL P-NUMBER 0>
+<GLOBAL P-DIRECTION 0>
+
+
+<ROUTINE ORPHAN-MERGE ("AUX" (CNT -1) TEMP VERB BEG END (ADJ <>) WRD) 
+   #DECL ((CNT TEMP VERB) FIX (BEG END) <PRIMTYPE VECTOR> (WRD) TABLE)
+   <SETG P-OFLAG <>>
+   <COND
+    (<AND <NOT <0? <SET VERB <GET ,P-ITBL ,P-VERB>>>>
+	  <NOT <==? .VERB <GET ,P-OTBL ,P-VERB>>>>
+     <RFALSE>)
+    (<==? ,P-NCN 2>
+     <RFALSE>)
+    (<==? <GET ,P-OTBL ,P-NC1> 1>
+     <COND (<OR <==? <SET TEMP <GET ,P-ITBL ,P-PREP1>> <GET ,P-OTBL ,P-PREP1>>
+		<0? .TEMP>>
+	    <PUT ,P-OTBL ,P-NC1 <GET ,P-ITBL ,P-NC1>>
+	    <PUT ,P-OTBL ,P-NC1L <GET ,P-ITBL ,P-NC1L>>)
+	   (T <RFALSE>)>)
+    (<==? <GET ,P-OTBL ,P-NC2> 1>
+     <COND (<OR <==? <SET TEMP <GET ,P-ITBL ,P-PREP1>> <GET ,P-OTBL ,P-PREP2>>
+		<0? .TEMP>>
+	    <PUT ,P-OTBL ,P-NC2 <GET ,P-ITBL ,P-NC1>>
+	    <PUT ,P-OTBL ,P-NC2L <GET ,P-ITBL ,P-NC1L>>
+	    <SETG P-NCN 2>)
+	   (T <RFALSE>)>)
+    (,P-ACLAUSE
+     <COND
+      (<NOT <==? ,P-NCN 1>> <SETG P-ACLAUSE <>> <RFALSE>)
+      (T
+       <SET BEG <GET ,P-ITBL ,P-NC1>>
+       <SET END <GET ,P-ITBL ,P-NC1L>>
+       <REPEAT ()
+	       <COND (<==? .BEG .END>
+		      <COND (.ADJ
+			     <ACLAUSE-WIN .ADJ>
+			     <RETURN>)
+			    (T
+			     <SETG P-ACLAUSE <>>
+			     <RFALSE>)>)
+		     (<AND <NOT .ADJ>
+			   <BTST <GETB <SET WRD <GET .BEG 0>> ,P-PSOFF>
+			         ,PS?ADJECTIVE>>
+		      <SET ADJ .WRD>)
+		     (<OR <BTST <GETB .WRD ,P-PSOFF> ,PS?OBJECT>
+			  <==? .WRD ,W?ONE>>
+		      <COND (<NOT <EQUAL? .WRD ,P-ANAM ,W?ONE>> <RFALSE>)
+			    (T
+			     <ACLAUSE-WIN .ADJ>
+			     <RETURN>)>)>
+	       <SET BEG <REST .BEG ,P-WORDLEN>>>)>)>
+   <REPEAT ()
+	   <COND (<G? <SET CNT <+ .CNT 1>> ,P-ITBLLEN>
+		  <SETG P-MERGED T>
+		  <RTRUE>)
+		 (T <PUT ,P-ITBL .CNT <GET ,P-OTBL .CNT>>)>>
+   T>
+
+<ROUTINE ACLAUSE-WIN (ADJ)
+	 <SETG P-CCSRC ,P-OTBL>
+	 <CLAUSE-COPY ,P-ACLAUSE <+ ,P-ACLAUSE 1> .ADJ>
+	 <AND <NOT <==? <GET ,P-OTBL ,P-NC2> 0>>
+	      <SETG P-NCN 2>>
+	 <SETG P-ACLAUSE <>>
+	 <RTRUE>>
+
+;"Print undefined word in input.
+   PTR points to the unknown word in P-LEXV"   
+
+<ROUTINE WORD-PRINT (CNT BUF)
+	 <REPEAT ()
+		 <COND (<DLESS? CNT 0> <RETURN>)
+		       (ELSE
+			<PRINTC <GETB ,P-INBUF .BUF>>
+			<SET BUF <+ .BUF 1>>)>>>
+
+<ROUTINE UNKNOWN-WORD (PTR "AUX" BUF) 
+	#DECL ((PTR BUF) FIX)
+	<TELL "I don't know the word \"">
+	<WORD-PRINT <GETB <REST ,P-LEXV <SET BUF <* .PTR 2>>> 2>
+		    <GETB <REST ,P-LEXV .BUF> 3>>
+	<TELL "\"." CR>
+	<SETG QUOTE-FLAG <>>
+	<SETG P-OFLAG <>>>
+
+<ROUTINE CANT-USE (PTR "AUX" BUF) 
+	#DECL ((PTR BUF) FIX)
+	<TELL "I can't use the word \"">
+	<WORD-PRINT <GETB <REST ,P-LEXV <SET BUF <* .PTR 2>>> 2>
+		    <GETB <REST ,P-LEXV .BUF> 3>>
+	<TELL "\" here." CR>
+	<SETG QUOTE-FLAG <>>
+	<SETG P-OFLAG <>>>
+
+;" Perform syntax matching operations, using P-ITBL as the source of
+   the verb and adjectives for this input.  Returns false if no
+   syntax matches, and does it's own orphaning.  If return is true,
+   the syntax is saved in P-SYNTAX."   
+ 
+<GLOBAL P-SLOCBITS 0>    
+ 
+<CONSTANT P-SYNLEN 8>    
+ 
+<CONSTANT P-SBITS 0>
+ 
+<CONSTANT P-SPREP1 1>    
+ 
+<CONSTANT P-SPREP2 2>    
+ 
+<CONSTANT P-SFWIM1 3>    
+ 
+<CONSTANT P-SFWIM2 4>    
+ 
+<CONSTANT P-SLOC1 5>
+ 
+<CONSTANT P-SLOC2 6>
+ 
+<CONSTANT P-SACTION 7>   
+ 
+<CONSTANT P-SONUMS 3>    
+
+<ROUTINE SYNTAX-CHECK ("AUX" SYN LEN NUM OBJ (DRIVE1 <>) (DRIVE2 <>) PREP VERB TMP) 
+	#DECL ((DRIVE1 DRIVE2) <OR FALSE <PRIMTYPE VECTOR>>
+	       (SYN) <PRIMTYPE VECTOR> (LEN NUM VERB PREP) FIX
+	       (OBJ) <OR FALSE OBJECT>)
+	<COND (<0? <SET VERB <GET ,P-ITBL ,P-VERB>>>
+	       <TELL "I can't find a verb in that sentence!" CR>
+	       <RFALSE>)>
+	<SET SYN <GET ,VERBS <- 255 .VERB>>>
+	<SET LEN <GETB .SYN 0>>
+	<SET SYN <REST .SYN>>
+	<REPEAT ()
+		<SET NUM <BAND <GETB .SYN ,P-SBITS> ,P-SONUMS>>
+		<COND (<G? ,P-NCN .NUM> T)
+		      (<AND <NOT <L? .NUM 1>>
+			    <0? ,P-NCN>
+			    <OR <0? <SET PREP <GET ,P-ITBL ,P-PREP1>>>
+				<==? .PREP <GETB .SYN ,P-SPREP1>>>>
+		       <SET DRIVE1 .SYN>)
+		      (<==? <GETB .SYN ,P-SPREP1> <GET ,P-ITBL ,P-PREP1>>
+		       <COND (<AND <==? .NUM 2> <==? ,P-NCN 1>>
+			      <SET DRIVE2 .SYN>)
+			     (<==? <GETB .SYN ,P-SPREP2> <GET ,P-ITBL ,P-PREP2>>
+			      <SYNTAX-FOUND .SYN>
+			      <RTRUE>)>)>
+		<COND (<DLESS? LEN 1>
+		       <COND (<OR .DRIVE1 .DRIVE2> <RETURN>)
+			     (T
+			      <TELL "I don't understand that sentence." CR>
+			      <RFALSE>)>)
+		      (T <SET SYN <REST .SYN ,P-SYNLEN>>)>>
+	<COND (<AND .DRIVE1
+		    <SET OBJ
+			 <GWIM <GETB .DRIVE1 ,P-SFWIM1>
+			       <GETB .DRIVE1 ,P-SLOC1>
+			       <GETB .DRIVE1 ,P-SPREP1>>>>
+	       <PUT ,P-PRSO ,P-MATCHLEN 1>
+	       <PUT ,P-PRSO 1 .OBJ>
+	       <SYNTAX-FOUND .DRIVE1>)
+	      (<AND .DRIVE2
+		    <SET OBJ
+			 <GWIM <GETB .DRIVE2 ,P-SFWIM2>
+			       <GETB .DRIVE2 ,P-SLOC2>
+			       <GETB .DRIVE2 ,P-SPREP2>>>>
+	       <PUT ,P-PRSI ,P-MATCHLEN 1>
+	       <PUT ,P-PRSI 1 .OBJ>
+	       <SYNTAX-FOUND .DRIVE2>)
+	      (<EQUAL? .VERB ,ACT?FIND ;,ACT?WHAT>
+	       <TELL "I can't answer that question." CR>
+	       <RFALSE>)
+	      (T
+	       <ORPHAN .DRIVE1 .DRIVE2>
+	       <TELL "What do you want to ">
+	       <SET TMP <GET ,P-OTBL ,P-VERBN>>
+	       <COND (<==? .TMP 0> <TELL "tell">)
+		     (<0? <GETB ,P-VTBL 2>>
+		      <PRINTB <GET .TMP 0>>)
+		     (T
+		      <WORD-PRINT <GETB .TMP 2> <GETB .TMP 3>>
+		      <PUTB ,P-VTBL 2 0>)>
+	       <COND (.DRIVE2
+		      <CLAUSE-PRINT ,P-NC1 ,P-NC1L>)>
+	       <SETG P-OFLAG T>
+	       <PREP-PRINT <COND (.DRIVE1 <GETB .DRIVE1 ,P-SPREP1>)
+				 (T <GETB .DRIVE2 ,P-SPREP2>)>>
+	       <TELL "?" CR>
+	       <RFALSE>)>> 
+
+<ROUTINE ORPHAN (D1 D2 "AUX" (CNT -1)) 
+	#DECL ((D1 D2) <OR FALSE <PRIMTYPE VECTOR>>)
+	<PUT ,P-OCLAUSE ,P-MATCHLEN 0>
+	<SETG P-CCSRC ,P-ITBL>
+	<REPEAT ()
+		<COND (<IGRTR? CNT ,P-ITBLLEN> <RETURN>)
+		      (T <PUT ,P-OTBL .CNT <GET ,P-ITBL .CNT>>)>>
+	<COND (<==? ,P-NCN 2> <CLAUSE-COPY ,P-NC2 ,P-NC2L>)>
+	<COND (<NOT <L? ,P-NCN 1>> <CLAUSE-COPY ,P-NC1 ,P-NC1L>)>
+	<COND (.D1
+	       <PUT ,P-OTBL ,P-PREP1 <GETB .D1 ,P-SPREP1>>
+	       <PUT ,P-OTBL ,P-NC1 1>)
+	      (.D2
+	       <PUT ,P-OTBL ,P-PREP2 <GETB .D2 ,P-SPREP2>>
+	       <PUT ,P-OTBL ,P-NC2 1>)>> 
+ 
+<ROUTINE CLAUSE-PRINT (BPTR EPTR "OPTIONAL" (THE? T)) 
+	<BUFFER-PRINT <GET ,P-ITBL .BPTR> <GET ,P-ITBL .EPTR> .THE?>>    
+ 
+<ROUTINE BUFFER-PRINT (BEG END CP "AUX" (NOSP <>) WRD (FIRST?? T) (PN <>))
+	 #DECL ((BEG END) <PRIMTYPE VECTOR> (CP) <OR FALSE ATOM>)
+	 <REPEAT ()
+		<COND (<==? .BEG .END> <RETURN>)
+		      (T
+		       <COND (.NOSP <SET NOSP <>>)
+			     (T <TELL " ">)>
+		       <COND (<==? <SET WRD <GET .BEG 0>> ,W?.> <SET NOSP T>)
+			     (T
+			      <COND (<AND .FIRST?? <NOT .PN> .CP>
+				     <TELL "the ">)>
+			      <COND (,P-OFLAG <PRINTB .WRD>)
+				    (<AND <==? .WRD ,W?IT>
+					  <==? ,P-IT-LOC ,HERE>>
+				     <PRINTD ,P-IT-OBJECT>)
+				    (T
+				     <WORD-PRINT <GETB .BEG 2>
+						 <GETB .BEG 3>>)>
+			      <SET FIRST?? <>>)>)>
+		<SET BEG <REST .BEG ,P-WORDLEN>>>>
+
+<ROUTINE CAPITALIZE (PTR)
+	 <PRINTC <- <GETB ,P-INBUF <GETB .PTR 3>> 32>>
+	 <WORD-PRINT <- <GETB .PTR 2> 1> <+ <GETB .PTR 3> 1>>>
+
+<ROUTINE PREP-PRINT (PREP "AUX" WRD) 
+	#DECL ((PREP) FIX)
+	<COND (<NOT <0? .PREP>>
+	       <TELL " ">
+	       <SET WRD <PREP-FIND .PREP>>
+	       <PRINTB .WRD>)>>    
+ 
+<ROUTINE CLAUSE-COPY (BPTR EPTR "OPTIONAL" (INSRT <>) "AUX" BEG END) 
+	#DECL ((BPTR EPTR) FIX (BEG END) <PRIMTYPE VECTOR>
+	       (INSRT) <OR FALSE TABLE>)
+	<SET BEG <GET ,P-CCSRC .BPTR>>
+	<SET END <GET ,P-CCSRC .EPTR>>
+	<PUT ,P-OTBL
+	     .BPTR
+	     <REST ,P-OCLAUSE
+		   <+ <* <GET ,P-OCLAUSE ,P-MATCHLEN> ,P-LEXELEN> 2>>>
+	<REPEAT ()
+		<COND (<==? .BEG .END>
+		       <PUT ,P-OTBL
+			    .EPTR
+			    <REST ,P-OCLAUSE
+				  <+ <* <GET ,P-OCLAUSE ,P-MATCHLEN> ,P-LEXELEN>
+				     2>>>
+		       <RETURN>)
+		      (T
+		       <COND (<AND .INSRT <==? ,P-ANAM <GET .BEG 0>>>
+			      <CLAUSE-ADD .INSRT>)>
+		       <CLAUSE-ADD <GET .BEG 0>>)>
+		<SET BEG <REST .BEG ,P-WORDLEN>>>>  
+
+
+<ROUTINE CLAUSE-ADD (WRD "AUX" PTR) 
+	#DECL ((WRD) TABLE (PTR) FIX)
+	<SET PTR <+ <GET ,P-OCLAUSE ,P-MATCHLEN> 2>>
+	<PUT ,P-OCLAUSE <- .PTR 1> .WRD>
+	<PUT ,P-OCLAUSE .PTR 0>
+	<PUT ,P-OCLAUSE ,P-MATCHLEN .PTR>>   
+ 
+<ROUTINE PREP-FIND (PREP "AUX" (CNT 0) SIZE) 
+	#DECL ((PREP CNT SIZE) FIX)
+	<SET SIZE <* <GET ,PREPOSITIONS 0> 2>>
+	<REPEAT ()
+		<COND (<IGRTR? CNT .SIZE> <RFALSE>)
+		      (<==? <GET ,PREPOSITIONS .CNT> .PREP>
+		       <RETURN <GET ,PREPOSITIONS <- .CNT 1>>>)>>>  
+ 
+<ROUTINE SYNTAX-FOUND (SYN) 
+	#DECL ((SYN) <PRIMTYPE VECTOR>)
+	<SETG P-SYNTAX .SYN>
+	<SETG PRSA <GETB .SYN ,P-SACTION>>>   
+ 
+<GLOBAL P-GWIMBIT 0>
+ 
+<ROUTINE GWIM (GBIT LBIT PREP "AUX" OBJ) 
+	#DECL ((GBIT LBIT) FIX (OBJ) OBJECT)
+	<COND (<==? .GBIT ,RMUNGBIT>
+	       <RETURN ,ROOMS>)>
+	<SETG P-GWIMBIT .GBIT>
+	<SETG P-SLOCBITS .LBIT>
+	<PUT ,P-MERGE ,P-MATCHLEN 0>
+	<COND (<GET-OBJECT ,P-MERGE <>>
+	       <SETG P-GWIMBIT 0>
+	       <COND (<==? <GET ,P-MERGE ,P-MATCHLEN> 1>
+		      <SET OBJ <GET ,P-MERGE 1>>
+		      <TELL "(">
+		      <COND (<NOT <0? .PREP>>
+			     <PRINTB <PREP-FIND .PREP>>
+			     <COND ;(<==? .OBJ ,HANDS>
+				    <TELL " your hands)" CR>)
+				   (T
+				    <TELL " the ">)>)>
+		      <TELL D .OBJ ")" CR>
+		      .OBJ)>)
+	      (T <SETG P-GWIMBIT 0> <RFALSE>)>>   
+ 
+<ROUTINE SNARF-OBJECTS ("AUX" PTR) 
+	#DECL ((PTR) <OR FIX <PRIMTYPE VECTOR>>)
+	<COND (<NOT <==? <SET PTR <GET ,P-ITBL ,P-NC1>> 0>>
+	       <SETG P-SLOCBITS <GETB ,P-SYNTAX ,P-SLOC1>>
+	       <OR <SNARFEM .PTR <GET ,P-ITBL ,P-NC1L> ,P-PRSO> <RFALSE>>
+	       <OR <0? <GET ,P-BUTS ,P-MATCHLEN>>
+		   <SETG P-PRSO <BUT-MERGE ,P-PRSO>>>)>
+	<COND (<NOT <==? <SET PTR <GET ,P-ITBL ,P-NC2>> 0>>
+	       <SETG P-SLOCBITS <GETB ,P-SYNTAX ,P-SLOC2>>
+	       <OR <SNARFEM .PTR <GET ,P-ITBL ,P-NC2L> ,P-PRSI> <RFALSE>>
+	       <COND (<NOT <0? <GET ,P-BUTS ,P-MATCHLEN>>>
+		      <COND (<==? <GET ,P-PRSI ,P-MATCHLEN> 1>
+			     <SETG P-PRSO <BUT-MERGE ,P-PRSO>>)
+			    (T <SETG P-PRSI <BUT-MERGE ,P-PRSI>>)>)>)>
+	<RTRUE>>  
+
+<ROUTINE BUT-MERGE (TBL "AUX" LEN BUTLEN (CNT 1) (MATCHES 0) OBJ NTBL) 
+	#DECL ((TBL NTBL) TABLE (LEN BUTLEN MATCHES) FIX (OBJ) OBJECT)
+	<SET LEN <GET .TBL ,P-MATCHLEN>>
+	<PUT ,P-MERGE ,P-MATCHLEN 0>
+	<REPEAT ()
+		<COND (<DLESS? LEN 0> <RETURN>)
+		      (<ZMEMQ <SET OBJ <GET .TBL .CNT>> ,P-BUTS>)
+		      (T
+		       <PUT ,P-MERGE <+ .MATCHES 1> .OBJ>
+		       <SET MATCHES <+ .MATCHES 1>>)>
+		<SET CNT <+ .CNT 1>>>
+	<PUT ,P-MERGE ,P-MATCHLEN .MATCHES>
+	<SET NTBL ,P-MERGE>
+	<SETG P-MERGE .TBL>
+	.NTBL>    
+ 
+<GLOBAL P-NAM <>>   
+ 
+<GLOBAL P-ADJ <>>   
+ 
+<GLOBAL P-ADVERB <>>
+
+<GLOBAL P-ADJN <>>  
+ 
+<GLOBAL P-PRSO <ITABLE NONE 50>>   
+ 
+<GLOBAL P-PRSI <ITABLE NONE 50>>   
+ 
+<GLOBAL P-BUTS <ITABLE NONE 50>>   
+ 
+<GLOBAL P-MERGE <ITABLE NONE 50>>  
+ 
+<GLOBAL P-OCLAUSE <ITABLE NONE 50>>
+ 
+<GLOBAL P-MATCHLEN 0>    
+ 
+<GLOBAL P-GETFLAGS 0>    
+ 
+<CONSTANT P-ALL 1>  
+ 
+<CONSTANT P-ONE 2>  
+ 
+<CONSTANT P-INHIBIT 4>   
+
+<GLOBAL P-CSPTR <>>
+<GLOBAL P-CEPTR <>>
+
+<ROUTINE SNARFEM (PTR EPTR TBL "AUX" (BUT <>) LEN WV WRD NW) 
+   #DECL ((TBL) TABLE (PTR EPTR) <PRIMTYPE VECTOR>
+	  (BUT) <OR FALSE TABLE> (WV) <OR FALSE FIX>)
+   <SETG P-GETFLAGS 0>
+   <SETG P-CSPTR .PTR>
+   <SETG P-CEPTR .EPTR>
+   <PUT ,P-BUTS ,P-MATCHLEN 0>
+   <PUT .TBL ,P-MATCHLEN 0>
+   <SET WRD <GET .PTR 0>>
+   <REPEAT ()
+	   <COND (<==? .PTR .EPTR> <RETURN <GET-OBJECT <OR .BUT .TBL>>>)
+		 (T
+		  <SET NW <GET .PTR ,P-LEXELEN>>
+		  <COND (<==? .WRD ,W?ALL>
+			 <SETG P-GETFLAGS ,P-ALL>
+			 <COND (<==? .NW ,W?OF>
+				<SET PTR <REST .PTR ,P-WORDLEN>>)>)
+			(<EQUAL? .WRD ,W?BUT ,W?EXCEPT>
+			 <OR <GET-OBJECT <OR .BUT .TBL>> <RFALSE>>
+			 <SET BUT ,P-BUTS>
+			 <PUT .BUT ,P-MATCHLEN 0>)
+			(<EQUAL? .WRD ,W?A ,W?ONE>
+			 <COND (<NOT ,P-ADJ>
+				<SETG P-GETFLAGS ,P-ONE>
+				<COND (<==? .NW ,W?OF>
+				       <SET PTR <REST .PTR ,P-WORDLEN>>)>)
+			       (T
+				<SETG P-NAM ,P-ONEOBJ>
+				<OR <GET-OBJECT <OR .BUT .TBL>> <RFALSE>>
+				<AND <0? .NW> <RTRUE>>)>)
+			(<AND <EQUAL? .WRD ,W?AND ,W?COMMA>
+			      <NOT <EQUAL? .NW ,W?AND ,W?COMMA>>>
+			 <OR <GET-OBJECT <OR .BUT .TBL>> <RFALSE>>
+			 T)
+			(<WT? .WRD ,PS?BUZZ-WORD>)
+			(<EQUAL? .WRD ,W?AND ,W?COMMA>)
+			(<==? .WRD ,W?OF>
+			 <COND (<0? ,P-GETFLAGS>
+				<SETG P-GETFLAGS ,P-INHIBIT>)>)
+			(<AND <SET WV <WT? .WRD ,PS?ADJECTIVE ,P1?ADJECTIVE>>
+			      <NOT ,P-ADJ>>
+			 <SETG P-ADJ .WV>
+			 <SETG P-ADJN .WRD>)
+			(<WT? .WRD ,PS?OBJECT ,P1?OBJECT>
+			 <SETG P-NAM .WRD>
+			 <SETG P-ONEOBJ .WRD>)>)>
+	   <COND (<NOT <==? .PTR .EPTR>>
+		  <SET PTR <REST .PTR ,P-WORDLEN>>
+		  <SET WRD .NW>)>>>   
+ 
+<CONSTANT SH 128>   
+ 
+<CONSTANT SC 64>    
+ 
+<CONSTANT SIR 32>   
+ 
+<CONSTANT SOG 16>   
+ 
+<CONSTANT STAKE 8>  
+ 
+<CONSTANT SMANY 4>  
+ 
+<CONSTANT SHAVE 2>  
+
+<ROUTINE GET-OBJECT (TBL
+		     "OPTIONAL" (VRB T)
+		     "AUX" BTS LEN XBITS TLEN (GCHECK <>) (OLEN 0) OBJ)
+	 #DECL ((TBL) TABLE (XBTS BTS TLEN LEN) FIX (GWIM) <OR FALSE FIX>
+		(VRB GCHECK) <OR ATOM FALSE>)
+	 <SET XBITS ,P-SLOCBITS>
+	 <SET TLEN <GET .TBL ,P-MATCHLEN>>
+	 <COND (<BTST ,P-GETFLAGS ,P-INHIBIT> <RTRUE>)>
+	 <COND (<AND <NOT ,P-NAM> ,P-ADJ>
+		<COND (<WT? ,P-ADJN ,PS?OBJECT ,P1?OBJECT>
+		       <SETG P-NAM ,P-ADJN>
+		       <SETG P-ADJ <>>)
+		      (<SET BTS <WT? ,P-ADJN ,PS?DIRECTION ,P1?DIRECTION>>
+		       <SETG P-ADJ <>>
+		       <PUT .TBL ,P-MATCHLEN 1>
+		       <PUT .TBL 1 ,INTDIR>
+		       <SETG P-DIRECTION .BTS>
+		       <RTRUE>)>)>
+	 <COND (<AND <NOT ,P-NAM>
+		     <NOT ,P-ADJ>
+		     <NOT <==? ,P-GETFLAGS ,P-ALL>>
+		     <0? ,P-GWIMBIT>>
+		<COND (.VRB
+		       <TELL "I think that sentence was missing a noun." CR>)>
+		<RFALSE>)>
+	 <COND (<OR <NOT <==? ,P-GETFLAGS ,P-ALL>> <0? ,P-SLOCBITS>>
+		<SETG P-SLOCBITS -1>)>
+	 <SETG P-TABLE .TBL>
+	 <PROG ()
+	       <COND (.GCHECK <GLOBAL-CHECK .TBL>)
+		     (T
+		      <COND (,LIT <DO-SL ,HERE ,SOG ,SIR>)>
+		      <DO-SL ,WINNER ,SH ,SC>
+		      <COND (<NOT <EQUAL? ,WINNER ,PLAYER>>
+			     <DO-SL ,PLAYER ,SH ,SC>)>)>
+	       <SET LEN <- <GET .TBL ,P-MATCHLEN> .TLEN>>
+	       <COND (<BTST ,P-GETFLAGS ,P-ALL>)
+		     (<AND <BTST ,P-GETFLAGS ,P-ONE>
+			   <NOT <0? .LEN>>>
+		      <COND (<NOT <==? .LEN 1>>
+			     <PUT .TBL 1 <GET .TBL <RANDOM .LEN>>>
+			     <TELL "(How about the ">
+			     <PRINTD <GET .TBL 1>>
+			     <TELL "?)" CR>)>
+		      <PUT .TBL ,P-MATCHLEN 1>)
+		     (<OR <G? .LEN 1>
+			  <AND <0? .LEN> <NOT <==? ,P-SLOCBITS -1>>>>
+		      <COND (<==? ,P-SLOCBITS -1>
+			     <SETG P-SLOCBITS .XBITS>
+			     <SET OLEN .LEN>
+			     <PUT .TBL ,P-MATCHLEN
+				  <- <GET .TBL ,P-MATCHLEN> .LEN>>
+			     <AGAIN>)
+			    (T
+			     <COND (<0? .LEN> <SET LEN .OLEN>)>
+			     <COND (<AND ,P-NAM
+			                 <VERB? EXAMINE TAKE LAMP-ON
+					        BURN DROP FIND>
+					 <SET OBJ <GET .TBL <+ .TLEN 1>>>
+					 <SET OBJ
+					      <APPLY
+					       <GETP .OBJ ,P?GENERIC> .OBJ>>>
+				    <PUT .TBL 1 .OBJ>
+				    <PUT .TBL ,P-MATCHLEN 1>
+				    <SETG P-NAM <>>
+				    <SETG P-ADJ <>>
+				    <RTRUE>)
+				   (<AND .VRB ,P-NAM>
+				    <WHICH-PRINT .TLEN .LEN .TBL>
+				    <SETG P-ACLAUSE
+					  <COND (<==? .TBL ,P-PRSO> ,P-NC1)
+						(T ,P-NC2)>>
+				    <SETG P-AADJ ,P-ADJ>
+				    <SETG P-ANAM ,P-NAM>
+				    <ORPHAN <> <>>
+				    <SETG P-OFLAG T>)
+				   (.VRB
+				    <TELL
+				     "I couldn't find enough nouns in that sentence!" CR>)>
+			     <SETG P-NAM <>>
+			     <SETG P-ADJ <>>
+			     <RFALSE>)>)
+		     (<AND <0? .LEN> .GCHECK>
+		      <COND (.VRB
+			     <COND (<NOT <==? ,WINNER ,PLAYER>>
+				    <TELL "\"I can't see that here!\"" CR>) 
+				   (,LIT
+				    <OBJ-FOUND ,NOT-HERE-OBJECT .TBL>
+				    <SETG P-XNAM ,P-NAM>
+				    <SETG P-XADJ ,P-ADJ>
+				    <SETG P-XADJN ,P-ADJN>
+				    <SETG P-NAM <>>
+				    <SETG P-ADJ <>>
+				    <SETG P-ADJN <>>
+				    <RTRUE>)
+				   (T <TELL "It's too dark to see!" CR>)>)>
+		      <SETG P-NAM <>>
+		      <SETG P-ADJ <>>
+		      <RFALSE>)
+		     (<0? .LEN> <SET GCHECK T> <AGAIN>)>
+	       <SETG P-ADJ <>>
+	       <SETG P-NAM <>>
+	       <SETG P-SLOCBITS .XBITS>
+	       <RTRUE>>>   
+
+<ROUTINE MOBY-FIND (TBL "AUX" FOO LEN)
+	 <SETG P-SLOCBITS -1>
+	 <SETG P-NAM ,P-XNAM>
+	 <SETG P-ADJ ,P-XADJ>
+	 <PUT .TBL ,P-MATCHLEN 0>
+	 <SET FOO <FIRST? ,ROOMS>>
+	 <REPEAT ()
+		 <COND (<NOT .FOO> <RETURN>)
+		       (T
+			<SEARCH-LIST .FOO .TBL ,P-SRCALL>
+			<SET FOO <NEXT? .FOO>>)>>
+	 <COND (<EQUAL? <SET LEN <GET .TBL ,P-MATCHLEN>> 0>
+		<DO-SL ,LOCAL-GLOBALS 1 1>)>
+	 <COND (<EQUAL? <SET LEN <GET .TBL ,P-MATCHLEN>> 0>
+		<DO-SL ,ROOMS 1 1>)>
+	 <COND (<EQUAL? <SET LEN <GET .TBL ,P-MATCHLEN>> 1>
+		<SETG P-MOBY-FOUND <GET .TBL 1>>)>
+	 <SETG P-NAM <>>
+	 <SETG P-ADJ <>>
+	 .LEN>
+
+<GLOBAL P-MOBY-FOUND <>>   
+<GLOBAL P-XNAM <>>
+<GLOBAL P-XADJ <>>
+<GLOBAL P-XADJN <>>
+
+<ROUTINE WHICH-PRINT (TLEN LEN TBL "AUX" OBJ RLEN)
+	 <SET RLEN .LEN>
+	 <TELL "Which">
+         <COND (<OR ,P-OFLAG ,P-MERGED> <TELL " "> <PRINTB ,P-NAM>)
+	       (<==? .TBL ,P-PRSO>
+		<CLAUSE-PRINT ,P-NC1 ,P-NC1L <>>)
+	       (T <CLAUSE-PRINT ,P-NC2 ,P-NC2L <>>)>
+	 <TELL " do you mean, ">
+	 <REPEAT ()
+		 <SET TLEN <+ .TLEN 1>>
+		 <SET OBJ <GET .TBL .TLEN>>
+		 <TELL "the " D .OBJ>
+		 <COND (<==? .LEN 2>
+		        <COND (<NOT <==? .RLEN 2>> <TELL ",">)>
+		        <TELL " or ">)
+		       (<G? .LEN 2> <TELL ", ">)>
+		 <COND (<L? <SET LEN <- .LEN 1>> 1>
+		        <TELL "?" CR>
+		        <RETURN>)>>>
+
+
+<ROUTINE GLOBAL-CHECK (TBL "AUX" LEN RMG RMGL (CNT 0) OBJ OBITS FOO) 
+	#DECL ((TBL) TABLE (RMG) <OR FALSE TABLE> (RMGL CNT) FIX (OBJ) OBJECT)
+	<SET LEN <GET .TBL ,P-MATCHLEN>>
+	<SET OBITS ,P-SLOCBITS>
+	<COND (<SET RMG <GETPT ,HERE ,P?GLOBAL>>
+	       <SET RMGL <- <PTSIZE .RMG> 1>>
+	       <REPEAT ()
+		       <COND (<THIS-IT? <SET OBJ <GETB .RMG .CNT>> .TBL>
+			      <OBJ-FOUND .OBJ .TBL>)>
+		       <COND (<IGRTR? CNT .RMGL> <RETURN>)>>)>
+	<COND (<SET RMG <GETPT ,HERE ,P?PSEUDO>>
+	       <SET RMGL <- </ <PTSIZE .RMG> 4> 1>>
+	       <SET CNT 0>
+	       <REPEAT ()
+		       <COND (<==? ,P-NAM <GET .RMG <* .CNT 2>>>
+			      <PUTP ,PSEUDO-OBJECT
+				    ,P?ACTION
+				    <GET .RMG <+ <* .CNT 2> 1>>>
+			      <SET FOO
+				   <BACK <GETPT ,PSEUDO-OBJECT ,P?ACTION> 5>>
+			      <PUT .FOO 0 <GET ,P-NAM 0>>
+			      <PUT .FOO 1 <GET ,P-NAM 1>>
+			      <OBJ-FOUND ,PSEUDO-OBJECT .TBL>
+			      <RETURN>)
+		             (<IGRTR? CNT .RMGL> <RETURN>)>>)>
+	<COND (<==? <GET .TBL ,P-MATCHLEN> .LEN>
+	       <SETG P-SLOCBITS -1>
+	       <SETG P-TABLE .TBL>
+	       <DO-SL ,GLOBAL-OBJECTS 1 1>
+	       <SETG P-SLOCBITS .OBITS>
+	       <COND (<AND <0? <GET .TBL ,P-MATCHLEN>>
+			   <EQUAL? ,PRSA ,V?LOOK-INSIDE ,V?SEARCH ,V?EXAMINE>>
+		      <DO-SL ,ROOMS 1 1>)>)>>
+ 
+<ROUTINE DO-SL (OBJ BIT1 BIT2 "AUX" BTS) 
+	#DECL ((OBJ) OBJECT (BIT1 BIT2 BTS) FIX)
+	<COND (<BTST ,P-SLOCBITS <+ .BIT1 .BIT2>>
+	       <SEARCH-LIST .OBJ ,P-TABLE ,P-SRCALL>)
+	      (T
+	       <COND (<BTST ,P-SLOCBITS .BIT1>
+		      <SEARCH-LIST .OBJ ,P-TABLE ,P-SRCTOP>)
+		     (<BTST ,P-SLOCBITS .BIT2>
+		      <SEARCH-LIST .OBJ ,P-TABLE ,P-SRCBOT>)
+		     (T <RTRUE>)>)>>  
+ 
+<CONSTANT P-SRCBOT 2>    
+ 
+<CONSTANT P-SRCTOP 0>    
+ 
+<CONSTANT P-SRCALL 1>    
+ 
+<ROUTINE SEARCH-LIST (OBJ TBL LVL "AUX" FLS NOBJ) 
+	#DECL ((OBJ NOBJ) <OR FALSE OBJECT> (TBL) TABLE (LVL) FIX (FLS) ANY)
+	<COND (<SET OBJ <FIRST? .OBJ>>
+	       <REPEAT ()
+		       <COND (<AND <NOT <==? .LVL ,P-SRCBOT>>
+				   <GETPT .OBJ ,P?SYNONYM>
+				   <THIS-IT? .OBJ .TBL>>
+			      <OBJ-FOUND .OBJ .TBL>)>
+		       <COND (<AND <OR <NOT <==? .LVL ,P-SRCTOP>>
+				       <FSET? .OBJ ,SEARCHBIT>
+				       <FSET? .OBJ ,SURFACEBIT>>
+				   <SET NOBJ <FIRST? .OBJ>>
+				   <FSET? .OBJ ,OPENBIT>>
+			      <SET FLS
+				   <SEARCH-LIST .OBJ
+						.TBL
+						<COND (<FSET? .OBJ ,SURFACEBIT>
+						       ,P-SRCALL)
+						      (<FSET? .OBJ ,SEARCHBIT>
+						       ,P-SRCALL)
+						      (T ,P-SRCTOP)>>>)>
+		       <COND (<SET OBJ <NEXT? .OBJ>>) (T <RETURN>)>>)>> 
+ 
+<ROUTINE OBJ-FOUND (OBJ TBL "AUX" PTR) 
+	#DECL ((OBJ) OBJECT (TBL) TABLE (PTR) FIX)
+	<SET PTR <GET .TBL ,P-MATCHLEN>>
+	<PUT .TBL <+ .PTR 1> .OBJ>
+	<PUT .TBL ,P-MATCHLEN <+ .PTR 1>>> 
+ 
+<ROUTINE TAKE-CHECK () 
+	<AND <ITAKE-CHECK ,P-PRSO <GETB ,P-SYNTAX ,P-SLOC1>>
+	     <ITAKE-CHECK ,P-PRSI <GETB ,P-SYNTAX ,P-SLOC2>>>> 
+
+<ROUTINE ITAKE-CHECK (TBL BTS "AUX" PTR OBJ TAKEN) 
+	 #DECL ((TBL) TABLE (BTS PTR) FIX (OBJ) OBJECT
+		(TAKEN) <OR FALSE FIX ATOM>)
+	 <COND (<AND <SET PTR <GET .TBL ,P-MATCHLEN>> <BTST .BTS ,STAKE>>
+		<REPEAT ()
+			<COND (<L? <SET PTR <- .PTR 1>> 0> <RETURN>)
+			      (T
+			       <SET OBJ <GET .TBL <+ .PTR 1>>>
+			       <COND (<==? .OBJ ,IT> <SET OBJ ,P-IT-OBJECT>)>
+			       <COND (<NOT <IN? .OBJ ,WINNER>>
+				      <SETG PRSO .OBJ>
+				      <COND (<FSET? .OBJ ,TRYTAKEBIT>
+					     <SET TAKEN T>)
+					    (<==? <ITAKE <>> T>
+					     <SET TAKEN <>>)
+					    (T <SET TAKEN T>)>
+				      <COND (<AND .TAKEN <BTST .BTS ,SHAVE>>
+					     <TELL "You don't have that." CR>
+					     <RFALSE>)
+					    (<NOT .TAKEN>
+					     <TELL "(Taken)" CR>)>)>)>>)
+	       (T)>>  
+ 
+<ROUTINE MANY-CHECK ("AUX" (LOSS <>) TMP) 
+	#DECL ((LOSS) <OR FALSE FIX>)
+	<COND (<AND <G? <GET ,P-PRSO ,P-MATCHLEN> 1>
+		    <NOT <BTST <GETB ,P-SYNTAX ,P-SLOC1> ,SMANY>>>
+	       <SET LOSS 1>)
+	      (<AND <G? <GET ,P-PRSI ,P-MATCHLEN> 1>
+		    <NOT <BTST <GETB ,P-SYNTAX ,P-SLOC2> ,SMANY>>>
+	       <SET LOSS 2>)>
+	<COND (.LOSS
+	       <TELL "I can't use multiple ">
+	       <COND (<==? .LOSS 2> <TELL "in">)>
+	       <TELL "direct objects with \"">
+	       <SET TMP <GET ,P-ITBL ,P-VERBN>>
+	       <COND (<0? .TMP> <TELL "tell">)
+		     (,P-OFLAG
+		      <PRINTB <GET .TMP 0>>)
+		     (T
+		      <WORD-PRINT <GETB .TMP 2> <GETB .TMP 3>>)>
+	       <TELL "\"." CR>
+	       <RFALSE>)
+	      (T)>>  
+ 
+<ROUTINE ZMEMQ (ITM TBL "OPTIONAL" (SIZE -1) "AUX" (CNT 1)) 
+	<COND (<NOT .TBL> <RFALSE>)>
+	<COND (<NOT <L? .SIZE 0>> <SET CNT 0>)
+	      (ELSE <SET SIZE <GET .TBL 0>>)>
+	<REPEAT ()
+		<COND (<==? .ITM <GET .TBL .CNT>> <RTRUE>)
+		      (<IGRTR? CNT .SIZE> <RFALSE>)>>>    
+
+<ROUTINE ZMEMQB (ITM TBL SIZE "AUX" (CNT 0)) 
+	#DECL ((ITM) ANY (TBL) TABLE (SIZE CNT) FIX)
+	<REPEAT ()
+		<COND (<==? .ITM <GETB .TBL .CNT>> <RTRUE>)
+		      (<IGRTR? CNT .SIZE> <RFALSE>)>>>  
+ 
+<ROUTINE LIT? (RM "AUX" OHERE (LIT <>)) 
+	#DECL ((RM OHERE) OBJECT (LIT) <OR ATOM FALSE>)
+	<SETG P-GWIMBIT ,ONBIT>
+	<SET OHERE ,HERE>
+	<SETG HERE .RM>
+	<COND (<FSET? .RM ,ONBIT> <SET LIT T>)
+	      (T
+	       <PUT ,P-MERGE ,P-MATCHLEN 0>
+	       <SETG P-TABLE ,P-MERGE>
+	       <SETG P-SLOCBITS -1>
+	       <COND (<==? .OHERE .RM> <DO-SL ,WINNER 1 1>)>
+	       <DO-SL .RM 1 1>
+	       <COND (<G? <GET ,P-TABLE ,P-MATCHLEN> 0> <SET LIT T>)>)>
+	<SETG HERE .OHERE>
+	<SETG P-GWIMBIT 0>
+	.LIT> 
+  
+<ROUTINE PRSO-PRINT ("AUX" PTR)
+	 <COND (<OR ,P-MERGED
+		    <==? <GET <SET PTR <GET ,P-ITBL ,P-NC1>> 0> ,W?IT>>
+		<TELL " " D ,PRSO>)
+	       (T <BUFFER-PRINT .PTR <GET ,P-ITBL ,P-NC1L> <>>)>>
+
+<ROUTINE PRSI-PRINT ("AUX" PTR)
+	 <COND (<OR ,P-MERGED
+		    <==? <GET <SET PTR <GET ,P-ITBL ,P-NC2>> 0> ,W?IT>>
+		<TELL " " D ,PRSI>)
+	       (T <BUFFER-PRINT .PTR <GET ,P-ITBL ,P-NC2L> <>>)>>
\ No newline at end of file
diff --git a/ra.zil b/ra.zil
new file mode 100644
index 0000000..baad6dc
--- /dev/null
+++ b/ra.zil
@@ -0,0 +1,398 @@
+"RA for
+			      INFIDEL
+	(c) Copyright 1983 Infocom, Inc.  All Rights Reserved.
+"
+
+;"RA-This is a file of all rooms and objects found in the upper part of the
+pyramid; the Chamber of Ra."
+
+<ROOM CHAMBER-OF-RA
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "Chamber of Ra")
+      (NORTH PER ROPE-HOOK-FCN)
+      (EAST PER TELL-STAIRS-FCN)
+      (SOUTH PER TELL-STAIRS-FCN)
+      (WEST PER TELL-STAIRS-FCN)
+      (DOWN PER ROPE-DOWN-FCN)
+      (UP PER RE-ENABLE-FCN)
+      (OUT PER RE-ENABLE-FCN)
+      (GLOBAL NORTH-STAIRS EAST-STAIRS SOUTH-STAIRS WEST-STAIRS FEW-STEPS)
+      (ACTION MOVE-ROPE-RA)>
+
+<ROUTINE TELL-STAIRS-FCN ("AUX" PLACE (FLG <>) (R-FLG <>))
+	 <COND (<IN? ,WINNER ,ALTAR>
+		<RETURN ,LANDING-ONE>)>
+	 <TELL "(down the ">
+	 <COND (<AND ,ROPE-TIED
+		     <IN? ,ROPE ,WINNER>>
+		<MOVE ,ROPE ,HERE>
+		<SET R-FLG T>)>
+	 <COND (<PRSO? ,P?EAST>
+		<TELL "wide staircase)" CR>
+		<SET PLACE ,LANDING-ONE>
+		<SET FLG T>)
+	       (<PRSO? ,P?WEST>
+		<TELL "narrow staircase)" CR>
+		<SET PLACE ,LANDING-THREE>
+		<SET FLG T>)
+	       (<PRSO? ,P?NORTH>
+		<TELL "steep staircase)" CR>
+		<SET PLACE ,LANDING-ZERO>)
+	       (<PRSO? ,P?SOUTH>
+		<TELL "winding staircase)" CR>
+		<SET PLACE ,LANDING-TWO>)>
+	 <COND (.R-FLG
+		<TELL "You release the free end of the rope as you walk." CR>)>
+	 <COND (.FLG
+		<TELL "The staircase winds as you walk down, turning you around
+so you face in the opposite direction." CR>
+		<CRLF>)>
+	 .PLACE>
+	 
+<ROUTINE RE-ENABLE-FCN ()
+	 <COND (<NOT <IN? ,WINNER ,ALTAR>>
+		<ENABLE <QUEUE I-GINANDTONIC -1>>)>
+	 <COND (<AND ,ROPE-TIED
+		     <IN? ,ROPE ,WINNER>>
+		<MOVE ,ROPE ,CHAMBER-OF-RA>
+		<TELL "You release the free end of the rope as you walk." CR>)>
+	 ,EX8>
+
+<GLOBAL PLUNGE-STR
+"You take a few steps down the steep staircase when suddenly you lose your
+footing as you try to walk on air. You fall a mere 25 feet straight
+down and, landing on your head, regret your attempt.">
+
+<ROUTINE ROPE-HOOK-FCN ()
+	 <COND (<IN? ,WINNER ,ALTAR>
+		<RETURN ,LANDING-ONE>)
+	       (<AND ,ROPE-TIED
+		     <EQUAL? ,LANDING ,LANDING-ZERO>>
+		<TELL "(down the rope)" CR>
+		<RETURN ,LANDING-ZERO>)
+	       (<AND ,ROPE-TIED ,LANDING>
+		<TELL "(down the steep staircase)" CR>
+		<JIGS-UP ,PLUNGE-STR>)
+	       (,ROPE-TIED
+		<JIGS-UP
+"You grasp the rope firmly in your hands, but the fall is shorter than you
+thought. You reach the bottom with a resounding splat accompanied by a chorus
+of pain led by ganglions you never knew you had. Just before you (thankfully)
+black out, you release your grip from the rope.">)
+	       (ELSE
+		<JIGS-UP ,PLUNGE-STR>)>>
+		
+
+<ROUTINE ROPE-DOWN-FCN ()
+	 <COND (<OR <NOT ,ROPE-TIED>
+		    <NOT ,ROPE-PLACED>>
+		<COND (<IN? ,WINNER ,ALTAR>
+		       <RETURN ,LANDING-TWO>)
+		      (<EQUAL? ,HERE ,CHAMBER-OF-RA>
+		       <TELL
+"Since there are four staircases going down, you'd better say which staircase."
+ CR>)
+		      (T
+		       <JIGS-UP ,PLUNGE-STR>)>
+		<RFALSE>)
+	       (ELSE
+		<COND (<NOT ,ROPE-HACK>
+		       <TELL "(down the rope)" CR>)>
+		<RETURN ,LANDING>)>>
+		     
+<GLOBAL ROPE-HACK <>>
+
+<ROUTINE MOVE-ROPE-RA (RARG)
+	 <COND (<AND <EQUAL? .RARG ,M-ENTER>
+		     <EQUAL? ,ROPE-TIED ,ALTAR>>
+		<DISABLE <INT I-GINANDTONIC>>
+		<MOVE ,ROPE ,HERE>
+		<FCLEAR ,ROPE ,NDESCBIT>
+		<RFALSE>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<DISABLE <INT I-GINANDTONIC>>)
+	       (<EQUAL? .RARG ,M-LOOK>
+		<TELL ,RA-STR>
+		<COND (,ROPE-PLACED
+		       <FSET ,ROPE ,NDESCBIT>
+		       <TELL
+" Descending the " D ,ROPE-PLACED " is one end of the rope.">)>
+		<TELL 
+" In the center of the room is a large red sandstone altar mounted solidly in
+the floor.">
+		<COND (,ROPE-TIED
+		       <TELL " The rope is tied to the " D ,ROPE-TIED ".">
+		       <COND (<AND <IN? ,ROPE ,CHAMBER-OF-RA>
+				   <NOT ,ROPE-PLACED>>
+			      <TELL 
+" The other end of the rope rests on the floor.">)
+			     (<IN? ,ROPE ,ALTAR>
+			      <TELL
+" The other end rests on the altar.">)>)>
+		<CRLF>)
+	       (<EQUAL? .RARG ,M-END>
+		<FCLEAR ,ROPE ,NDESCBIT>
+		<SETG ROPE-HACK <>>
+		<RFALSE>)
+	       (<AND <EQUAL? .RARG ,M-BEG>
+		     <OR ,ROPE-TIED ,ROPE-PLACED>
+		     <NOT <IN? ,ROPE ,WINNER>>>
+		<FSET ,ROPE ,NDESCBIT>
+		<RFALSE>)>>
+
+<GLOBAL RA-STR
+"You are standing in the Chamber of Ra, a tribute to the Sun God. Even though
+the only natural light enters through the opening above, the room is
+brilliantly lit as though the walls themselves generated light. The room
+slopes inward and the walls meet at an open point, over your head. The heat of
+the desert filters down through the opening and, as the air slowly circulates,
+the deep, long-dead musty odors from the depths of the pyramid assault your
+senses. Four staircases descend from here: a steep one to the north, a winding
+one to the south, a wide one to the east, and a narrow one to the west.">
+
+<OBJECT NORTH-STAIRS
+	(IN LOCAL-GLOBALS)
+	(FLAGS NDESCBIT CLIMBBIT)
+	(DESC "steep staircase")
+	(SYNONYM STAIRC STAIRS STEPS STAIR)
+	(ADJECTIVE STEEP NORTH)
+	(ACTION RA-STAIRS-FCN)>
+
+<OBJECT EAST-STAIRS
+	(IN LOCAL-GLOBALS)
+	(FLAGS NDESCBIT CLIMBBIT)
+	(DESC "wide staircase")
+	(SYNONYM STAIRC STAIRS STEPS STAIR)
+	(ADJECTIVE WIDE EAST)
+	(ACTION RA-STAIRS-FCN)>
+
+<OBJECT SOUTH-STAIRS
+	(IN LOCAL-GLOBALS)
+	(FLAGS NDESCBIT CLIMBBIT)
+	(DESC "winding staircase")
+	(SYNONYM STAIRC STAIRS STEPS STAIR)
+	(ADJECTIVE WINDIN SOUTH)
+	(ACTION RA-STAIRS-FCN)>
+
+<OBJECT WEST-STAIRS
+	(IN LOCAL-GLOBALS)
+	(FLAGS NDESCBIT CLIMBBIT)
+	(DESC "narrow staircase")
+	(SYNONYM STAIRC STAIRS STEPS STAIR)
+	(ADJECTIVE NARROW WEST)
+	(ACTION RA-STAIRS-FCN)>
+
+<ROUTINE RA-STAIRS-FCN ()
+	 <COND (<VERB? LOOK-DOWN EXAMINE>
+		<COND (<AND <NOT <FLAMING? ,TORCH>>
+			    <NOT <FLAMING? ,MATCHES>>>
+		       <TELL
+"There's just enough light to see the first few steps." CR>)
+		      (<OR <FLAMING? ,TORCH>
+			   <FLAMING? ,MATCHES>>
+		       <COND (<NOT <PRSO? ,NORTH-STAIRS>>
+			      <TELL
+"You can see far enough down the stairs to make out a landing below." CR>)
+			     (ELSE
+			      <TELL
+"You can see the first few steps and then what could only be a sheer dropoff,
+going down into total darkness." CR>)>)>
+		<RTRUE>)
+	       (<VERB? CLIMB-DOWN>
+		<COND (<PRSO? ,NORTH-STAIRS>
+		       <COND (<EQUAL? ,ROPE-PLACED ,NORTH-STAIRS>
+			      <PERFORM ,V?CLIMB-DOWN ,ROPE>
+			      <RTRUE>)
+			     (ELSE
+			      <JIGS-UP ,PLUNGE-STR>
+			      <RFATAL>)>)
+		      (<PRSO? ,EAST-STAIRS>
+		       <GOTO ,LANDING-ONE>)
+		      (<PRSO? ,SOUTH-STAIRS>
+		       <GOTO ,LANDING-TWO>)
+		      (<PRSO? ,WEST-STAIRS>
+		       <GOTO ,LANDING-THREE>)>)>>
+
+<OBJECT FEW-STEPS
+	(IN LOCAL-GLOBALS)
+	(FLAGS NDESCBIT CLIMBBIT)
+	(DESC "few steps")
+	(SYNONYM STEPS STAIRS)
+	(ADJECTIVE FEW FIRST)
+	(ACTION FEW-STEPS-FCN)>
+
+<ROUTINE FEW-STEPS-FCN ()
+	 <COND (<VERB? CLIMB-DOWN BOARD CLIMB-ON>
+		;<COND (<AND ,ROPE-TIED
+			    <IN? ,ROPE ,WINNER>>
+		       <TELL "You release the rope as you walk." CR>)>
+		<GOTO ,TINY-LANDING>
+		<MOVE-ROPE-HERE ,M-ENTER>
+		<COND (<IN? ,ROPE ,HERE>
+		       <FCLEAR ,ROPE ,NDESCBIT>
+		       <DESCRIBE-ROPE-FCN ,M-OBJDESC>)>
+		<RFATAL>)>>
+
+<ROOM TINY-LANDING
+      (IN ROOMS)
+      (FLAGS RLANDBIT ONBIT)
+      (DESC "On the Steep Stairs")
+      (LDESC
+"You are two steps down the steep staircase when you see before you a deep
+dropoff going down into nothingness. To go down any further would be suicide.")
+      (DOWN PER ROPE-DOWN-FCN)
+      (UP TO CHAMBER-OF-RA)
+      (GLOBAL NORTH-STAIRS)
+      ;(ACTION TINY-LANDING-F)>
+
+;<ROUTINE TINY-LANDING-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-END>
+		<MOVE-ROPE-HERE ,M-ENTER>)>>
+
+<OBJECT ALTAR
+	(IN CHAMBER-OF-RA)
+	(DESC "stone altar")
+	(FLAGS NDESCBIT CONTBIT OPENBIT SURFACEBIT VEHBIT DONTTAKE TRANSBIT
+	       TRYTAKEBIT)
+	(CAPACITY 1000)
+	(SYNONYM ALTAR)
+	(ADJECTIVE LARGE STONE)
+	(TEXT
+"The altar is three feet by five feet and is mounted firmly in the solid floor.")
+	(ACTION ALTAR-FCN)>
+
+<ROUTINE ALTAR-FCN ("OPTIONAL" (RARG ,M-OBJECT))
+	 <COND (<NOT <EQUAL? .RARG ,M-OBJECT>> <RFALSE>)
+	       (<AND <VERB? EXAMINE LOOK-INSIDE>
+		     <OR <NOT <FIRST? ,ALTAR>>
+			 <EQUAL? <FIRST? ,ALTAR> ,WINNER ,ADVENTURER>>
+		     <PRSO? ,ALTAR>>
+		<TELL
+		 <GETP ,ALTAR ,P?TEXT> " There is nothing on the altar." CR>
+		<RTRUE>)
+	       (<AND <VERB? EXAMINE LOOK-INSIDE>
+		     <IN? ,WINNER ,ALTAR>
+		     <PRSO? ,ALTAR>
+		     <L? <CCOUNT ,ALTAR> 2>>
+		<TELL <GETP ,ALTAR ,P?TEXT> CR>
+		<RTRUE>)
+	       (<AND <VERB? EXAMINE LOOK-INSIDE>
+		     <PRSO? ,ALTAR>>
+		<PRINT-CONT ,ALTAR>
+		<RTRUE>)
+	       (<AND <VERB? OPEN CLOSE>
+		     <PRSO? ,ALTAR>>
+		<HOW? ,ALTAR>
+		<RTRUE>)>>
+
+<GLOBAL LANDING <>>
+
+<ROUTINE MOVE-ROPE-HERE (RARG)
+	 <COND (<AND <EQUAL? .RARG ,M-ENTER>
+		     <OR <EQUAL? ,LANDING ,HERE>
+			 <AND <EQUAL? ,LANDING ,LANDING-ZERO>
+			      <EQUAL? ,HERE ,TINY-LANDING>>>>
+		<MOVE ,ROPE ,HERE>
+		<FCLEAR ,ROPE ,NDESCBIT>
+		<RFALSE>)>>
+
+<OBJECT TORCH
+	(IN CHAMBER-OF-RA)
+	(FLAGS BURNBIT TAKEBIT)
+	(DESC "bronze torch")
+	(SYNONYM TORCH WICK)
+	(ADJECTIVE BRONZE)
+	(FDESC
+"Leaning against the altar is a bronze torch.")
+	(TEXT
+"The torch has a tapered tip, much like a wick, which should be able to hold
+a large amount of oil.")
+	(ACTION TORCH-FCN)>
+
+<ROUTINE TORCH-FCN ()
+	 <COND (<AND <PRSI? ,TORCH>
+		     <FLAMING? ,TORCH>
+		     <IN? ,TORCH ,HERE>
+		     <VERB? DROP THROW>
+		     <IN? ,PRSO ,WINNER>
+		     <FSET? ,PRSO ,BURNBIT>>
+		<COND (<VERB? DROP>
+		       <TELL "Dropped. ">)
+		      (T <TELL "Thrown. ">)>
+	        <V-BURN>
+		<RTRUE>)
+	       (<VERB? EXAMINE>
+		<TELL <GETP ,TORCH ,P?TEXT> " The torch is ">
+		<COND (<NOT <FLAMING? ,TORCH>>
+		       <TELL "not lit">)
+		      (<L? ,TORCH-TURNS 125>
+		       <TELL "burning brightly">)
+		      (<L? ,TORCH-TURNS 160>
+		       <TELL "burning dimly">)
+		      (<L? ,TORCH-TURNS 175>
+		       <TELL "barely lit">)>
+		<TELL "." CR>
+		<RTRUE>)>>
+
+<OBJECT OIL-JAR
+	(IN CHAMBER-OF-RA)
+	(SYNONYM JAR)
+	(ADJECTIVE PINK SMALL ALABAS)
+	(DESC "pink jar")
+	(FLAGS CONTBIT TAKEBIT BURNBIT)
+	(CAPACITY 4)
+	(FDESC
+"Lying on the floor, partially covered with dust, is a small pink alabaster
+jar.")
+       	(ACTION OIL-FCN)>
+
+<ROUTINE OIL-FCN ()
+	 <COND (<VERB? EXAMINE LOOK-INSIDE>
+		<COND (<NOT <FSET? ,OIL-JAR ,OPENBIT>>
+		       <RFALSE>)
+		      (T
+		       <COND (<G? ,OIL-LEFT 0>
+		       <TELL "Inside the small pink jar is some liquid." CR>)
+		      (ELSE
+		       <TELL "The jar is empty." CR>)>)>)
+	       (<AND <VERB? OPEN>
+		     <NOT <FSET? ,OIL-JAR ,OPENBIT>>>
+		<COND (<G? ,OIL-LEFT 0>
+		       <TELL 
+"Opening the jar reveals a small amount of liquid." CR >)
+		      (T
+		       <TELL "Opened." CR>)>
+		<FSET ,OIL-JAR ,OPENBIT>
+		<RTRUE>)>>
+
+<OBJECT LIQUID
+	(IN OIL-JAR)
+	(FLAGS DONTTAKE)
+	(DESC "liquid")
+	(TEXT 
+"The liquid is oily to the touch and smells as if it could be highly volatile.")
+	(SYNONYM LIQUID OIL)
+	(ACTION LIQUID-FCN)>
+	
+<ROUTINE LIQUID-FCN ()
+	 <COND (<VERB? EXAMINE>
+		<RFALSE>)
+	       (<VERB? POUR POUR-ON>
+		<COND (<NOT <IN? ,OIL-JAR ,WINNER>>
+		       <COND (<ITAKE>
+			      <TELL "(taken)" CR>
+			      <PERFORM ,PRSA ,OIL-JAR>
+			      <RTRUE>)
+			     (T
+			      <TELL 
+"Hmm. It would be easier if you were holding it." CR>
+			      <RTRUE>)>)
+		      (T
+		       <PERFORM ,PRSA ,OIL-JAR>
+		       <RTRUE>)>)
+	       (<AND <VERB? TASTE>
+		     <FSET? ,OIL-JAR ,OPENBIT>>
+		<TELL "It tastes horrible." CR>)>>
+ 
+
diff --git a/syntax.zil b/syntax.zil
new file mode 100644
index 0000000..1b29817
--- /dev/null
+++ b/syntax.zil
@@ -0,0 +1,710 @@
+"SYNTAX for
+			      INFIDEL
+	(c) Copyright 1983 Infocom, Inc.  All Rights Reserved.
+"
+
+"SUBTITLE VOCABULARY"
+
+<BUZZ A AN THE IS AND SOME OF THEN ALL ONE BUT EXCEPT \. \, \" 
+      YES NO Y HERE MY>
+
+;<SYNONYM WITH USING THROUGH>
+<SYNONYM ON ONTO>
+<SYNONYM IN INSIDE INTO>
+<SYNONYM UNDER BELOW BENEATH UNDERNEATH>
+
+<SYNONYM NORTH N>
+<SYNONYM SOUTH S>
+<SYNONYM EAST E>
+<SYNONYM WEST W>
+<SYNONYM DOWN D>
+<SYNONYM UP U>
+<SYNONYM NW NORTHWEST>
+<SYNONYM NE NORTHE>
+<SYNONYM SW SOUTHWEST>
+<SYNONYM SE SOUTHE>
+
+\
+
+"ZORK game commands"
+
+<SYNTAX BRIEF = V-BRIEF>
+
+<SYNTAX SUPER = V-SUPER-BRIEF>
+<SYNONYM SUPER SUPERBRIEF>
+
+;<SYNTAX DIAGNOSE = V-DIAGNOSE>
+
+<SYNTAX INVENTORY = V-INVENTORY>
+<SYNONYM INVENTORY I>
+
+<SYNTAX QUIT = V-QUIT>
+<SYNONYM QUIT Q>
+
+<SYNTAX RESTART = V-RESTART>
+
+<SYNTAX RESTORE = V-RESTORE>
+
+<SYNTAX SAVE = V-SAVE>
+
+<SYNTAX SCORE = V-SCORE>
+
+<SYNTAX $VERIFY = V-$VERIFY>
+
+<SYNTAX VERSION = V-VERSION>
+
+<SYNTAX VERBOSE = V-VERBOSE>
+
+\
+
+"SUBTITLE REAL VERBS"
+
+<SYNTAX AGAIN = V-AGAIN>
+<SYNONYM AGAIN G>
+
+<SYNTAX ANSWER = V-ANSWER>
+<SYNTAX ANSWER OBJECT = V-REPLY>
+<SYNONYM ANSWER REPLY>
+
+<SYNTAX APPLY OBJECT TO OBJECT = V-PUT PRE-PUT>
+
+<SYNTAX ATTACK
+	OBJECT (FIND VILLAIN) (ON-GROUND IN-ROOM)
+	WITH
+	OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE)
+	= V-ATTACK>
+<SYNONYM ATTACK FIGHT HURT INJURE>
+
+<SYNTAX BACK = V-BACK>
+
+<SYNTAX BLAST = V-BLAST>
+
+<SYNTAX BOARD OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM)
+	= V-BOARD PRE-BOARD>
+
+<SYNTAX BUG = V-BUG>
+
+<SYNTAX BURN
+	OBJECT (FIND BURNBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	WITH
+	OBJECT (FIND FLAMEBIT) (HELD CARRIED ON-GROUND IN-ROOM HAVE)
+	= V-BURN PRE-BURN>
+<SYNTAX BURN
+	DOWN
+	OBJECT (FIND BURNBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	WITH
+	OBJECT (FIND FLAMEBIT) (HELD CARRIED ON-GROUND IN-ROOM HAVE)
+	= V-BURN PRE-BURN>
+<SYNONYM BURN INCINERATE IGNITE>
+
+<SYNTAX CHOMP = V-CHOMP>
+<SYNONYM CHOMP LOSE BARF>
+
+<SYNTAX CLEAN OBJECT = V-CLEAN>
+<SYNONYM CLEAN SCRUB POLISH>
+
+<SYNTAX CLEAR OBJECT FROM OBJECT = V-PLASTER-REMOVE>
+
+<SYNTAX CLIMB DOWN OBJECT (FIND CLIMBBIT) (ON-GROUND IN-ROOM) = V-CLIMB-DOWN>
+<SYNTAX CLIMB UP OBJECT (FIND CLIMBBIT) (ON-GROUND IN-ROOM) = V-CLIMB-UP>
+<SYNTAX CLIMB OBJECT (FIND CLIMBBIT) (ON-GROUND IN-ROOM) = V-CLIMB-FOO>
+<SYNTAX CLIMB IN OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-BOARD PRE-BOARD>
+<SYNTAX CLIMB ON OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-CLIMB-ON>
+<SYNONYM CLIMB>
+
+;<SYNTAX SIT ON OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-CLIMB-ON>
+<SYNTAX SIT ON OBJECT (ON-GROUND IN-ROOM) = V-SIT-ON>
+
+<SYNTAX CLOSE
+	OBJECT (FIND DOORBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-CLOSE>
+
+<SYNTAX COMPARE OBJECT TO OBJECT = V-COMPARE PRE-COMPARE>
+<SYNTAX COMPARE OBJECT WITH OBJECT = V-COMPARE PRE-COMPARE>
+<SYNTAX COMPARE OBJECT (HELD CARRIED MANY) = V-FOO-COMPARE>
+
+<SYNTAX COUNT OBJECT = V-COUNT>
+<SYNONYM COUNT>
+
+<SYNTAX CROSS OBJECT = V-CROSS>
+<SYNONYM CROSS FORD>
+
+<SYNTAX CUT OBJECT WITH OBJECT (FIND WEAPONBIT) (CARRIED HELD) = V-CUT>
+<SYNONYM CUT SLICE PIERCE> 
+
+<SYNTAX CURSE = V-CURSES>
+<SYNTAX CURSE OBJECT (FIND VILLAIN) = V-CURSES>
+<SYNONYM CURSE DAMN FUCK SHIT HELL>
+
+<SYNTAX DEFLATE OBJECT = V-DEFLATE>
+
+<SYNTAX DIG IN OBJECT = V-DIG PRE-DIG>
+<SYNTAX DIG
+	OBJECT (ON-GROUND IN-ROOM)
+	WITH
+	OBJECT (FIND TOOLBIT) (HELD CARRIED HAVE)
+	= V-DIG PRE-DIG ;*>
+<SYNTAX DIG
+	IN
+	OBJECT (ON-GROUND IN-ROOM)
+	WITH
+	OBJECT (FIND TOOLBIT) (HELD CARRIED HAVE)
+	= V-DIG PRE-DIG>
+<SYNTAX DIG OBJECT IN OBJECT = V-HOLE-DIG>
+<SYNTAX DIG WITH OBJECT = V-DIG-WITH>
+
+<SYNTAX DIP OBJECT (FIND BURNBIT) (HELD CARRIED HAVE)
+	IN OBJECT (ON-GROUND HAVE) = V-DIP-IN>
+<SYNONYM DIP IMMERSE SUBMERGE DUNK>
+
+<SYNTAX DISEMBARK OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM)
+	= V-DISEMBARK>
+
+<SYNTAX DRINK
+	OBJECT (FIND DRINKBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-DRINK>
+<SYNTAX DRINK FROM OBJECT (HELD CARRIED) = V-DRINK-FROM>
+<SYNTAX DRINK OBJECT (FIND DRINKBIT) 
+	IN OBJECT (FIND CONTBIT) (HELD CARRIED ON-GROUND) = V-DRINK-FROM>
+<SYNTAX DRINK OBJECT (FIND DRINKBIT) 
+	FROM OBJECT (FIND CONTBIT) (HELD CARRIED ON-GROUND) = V-DRINK-FROM>
+<SYNONYM DRINK IMBIBE SWALLOW SIP>
+
+<SYNTAX DROP OBJECT (HELD MANY HAVE) = V-DROP ;*>
+<SYNTAX DROP OBJECT (HELD MANY HAVE) DOWN OBJECT = V-PUT PRE-PUT>
+<SYNTAX DROP OBJECT (HELD MANY HAVE) IN OBJECT = V-PUT PRE-PUT>
+<SYNTAX DROP OBJECT (HELD MANY HAVE) ON OBJECT = V-PUT PRE-PUT>
+<SYNONYM DROP RELEASE>
+
+<SYNTAX LEAN ON OBJECT (HELD HAVE) = V-LEAN-ON>
+
+<SYNTAX EAT
+	OBJECT (FIND FOODBIT) (HELD CARRIED ON-GROUND IN-ROOM MANY)
+	= V-EAT PRE-EAT>
+<SYNONYM EAT CONSUME BITE CHEW>
+
+<SYNTAX TASTE OBJECT (HELD CARRIED ON-GROUND IN-ROOM MANY) = V-TASTE>
+
+<SYNTAX ENTER = V-ENTER>
+<SYNTAX ENTER OBJECT = V-THROUGH>
+<SYNTAX EXIT = V-EXIT>
+<SYNTAX EXIT OBJECT = V-EXIT>
+
+<SYNTAX EXAMINE OBJECT (HELD CARRIED ON-GROUND IN-ROOM MANY) = V-EXAMINE>
+<SYNTAX EXAMINE IN OBJECT (HELD CARRIED IN-ROOM ON-GROUND MANY) 
+		= V-LOOK-INSIDE>
+<SYNTAX EXAMINE ON OBJECT (HELD CARRIED IN-ROOM ON-GROUND MANY)
+		= V-LOOK-INSIDE>
+<SYNONYM EXAMINE DESCRIBE WHAT WHATS>
+
+<SYNTAX EXORCISE OBJECT = V-EXORCISE>
+<SYNTAX EXORCISE OUT OBJECT (FIND VILLAIN) = V-EXORCISE>
+<SYNTAX EXORCISE AWAY OBJECT (FIND VILLAIN) = V-EXORCISE>
+<SYNONYM EXORCISE BANISH CAST DRIVE BEGONE>
+
+<SYNTAX EXTINGUISH
+	OBJECT 
+	(FIND FLAMEBIT) (MANY HELD CARRIED ON-GROUND IN-ROOM TAKE HAVE)
+	= V-LAMP-OFF>
+<SYNONYM EXTINGUISH DOUSE>
+
+<SYNTAX FILL
+	OBJECT (FIND CONTBIT) (HELD CARRIED ON-GROUND TAKE HAVE)
+	WITH
+	OBJECT
+	= V-FILL>
+<SYNTAX FILL IN OBJECT (ON-GROUND IN-ROOM) = V-FILL-IN>
+<SYNTAX FILL
+	OBJECT (FIND CONTBIT) (HELD CARRIED ON-GROUND TAKE HAVE)
+	= V-FILL>
+<SYNTAX FILL OUT OBJECT = V-FILL-OUT>
+
+<SYNTAX FIND OBJECT
+	= V-FIND>
+<SYNONYM FIND WHERE SEEK SEE>
+
+<SYNTAX FOLLOW = V-FOLLOW>
+<SYNTAX FOLLOW OBJECT = V-FOLLOW>
+<SYNONYM FOLLOW PURSUE CHASE COME>
+
+<SYNTAX GIVE
+	OBJECT (MANY HELD HAVE ;CARRIED ;ON-GROUND ;IN-ROOM)
+	TO
+	OBJECT (FIND VICBIT) (ON-GROUND)
+	= V-GIVE PRE-GIVE>
+<SYNTAX GIVE
+	OBJECT (FIND VICBIT) (ON-GROUND)
+	OBJECT (MANY HELD HAVE)
+	= V-SGIVE PRE-SGIVE>
+<SYNONYM GIVE HAND DONATE OFFER FEED>
+
+<SYNTAX HELLO = V-HELLO ;*>
+<SYNTAX HELLO OBJECT = V-HELLO>
+<SYNONYM HELLO HI>
+
+<SYNTAX HELP = V-HELP>
+<SYNTAX HELP OBJECT = V-HELP>
+
+<SYNTAX BLOW OUT OBJECT (HELD CARRIED ON-GROUND HAVE) = V-LAMP-OFF>
+<SYNTAX BLOW UP
+	OBJECT
+	WITH
+	OBJECT (FIND TOOLBIT) (ON-GROUND IN-ROOM HELD CARRIED)
+	= V-INFLATE ;*>
+<SYNTAX BLOW UP OBJECT = V-BLAST>
+
+<SYNTAX INFLAT
+	OBJECT
+	WITH
+	OBJECT (FIND TOOLBIT) (ON-GROUND IN-ROOM HELD CARRIED)
+	= V-INFLATE>
+
+<SYNTAX JUMP = V-LEAP>
+<SYNTAX JUMP OVER OBJECT = V-LEAP>
+<SYNTAX JUMP ACROSS OBJECT = V-LEAP>
+<SYNTAX JUMP IN OBJECT = V-LEAP>
+<SYNTAX JUMP FROM OBJECT = V-LEAP>
+<SYNTAX JUMP OFF OBJECT = V-DISEMBARK>
+<SYNTAX JUMP OBJECT = V-JUMP-ROPE>
+<SYNONYM JUMP LEAP DIVE>
+
+<SYNTAX KICK OBJECT = V-KICK>
+<SYNONYM KICK>
+
+<SYNTAX KILL
+	OBJECT (FIND VILLAIN) (ON-GROUND IN-ROOM)
+	WITH
+	OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE)
+	= V-KILL>
+<SYNONYM KILL MURDER SLAY DISPATCH STAB>
+
+<SYNTAX KISS OBJECT (FIND VILLAIN) (ON-GROUND IN-ROOM) = V-KISS>
+
+<SYNTAX KNOCK AT OBJECT = V-KNOCK ;*>
+<SYNTAX KNOCK ON OBJECT = V-KNOCK>
+<SYNTAX KNOCK OVER OBJECT = V-PUSH>
+<SYNTAX KNOCK DOWN OBJECT (FIND VICBIT) (ON-GROUND IN-ROOM) = V-ATTACK>
+<SYNONYM KNOCK RAP>
+
+<SYNTAX LAUNCH OBJECT (FIND VEHBIT) = V-LAUNCH>
+
+<SYNTAX LEAVE = V-LEAVE>
+<SYNTAX LEAVE OBJECT = V-DROP>
+
+<SYNTAX LIGHT
+	OBJECT ;(FIND LIGHTBIT) (FIND BURNBIT)
+	(CARRIED ON-GROUND IN-ROOM)
+	= V-LAMP-ON ;*>
+<SYNTAX LIGHT
+	OBJECT ;(FIND LIGHTBIT) (FIND BURNBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	WITH
+	OBJECT (FIND FLAMEBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-BURN PRE-BURN>
+
+<SYNTAX LISTEN TO OBJECT = V-LISTEN>
+<SYNTAX LISTEN FOR OBJECT = V-LISTEN>
+
+<SYNTAX LOCK
+	OBJECT (ON-GROUND IN-ROOM)
+	WITH
+	OBJECT (FIND TOOLBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-LOCK>
+
+<SYNTAX LOOK = V-LOOK>
+<SYNTAX LOOK AROUND OBJECT (FIND RMUNGBIT) = V-LOOK>
+<SYNTAX LOOK UP OBJECT (FIND RMUNGBIT) = V-LOOK-UP>
+<SYNTAX LOOK UP OBJECT = V-LOOK-UP>
+<SYNTAX LOOK AT OBJECT (HELD CARRIED ON-GROUND IN-ROOM MANY) = V-EXAMINE>
+<SYNTAX LOOK WITH OBJECT = V-LOOK-INSIDE>
+<SYNTAX LOOK THROUGH OBJECT = V-LOOK-INSIDE>
+<SYNTAX LOOK UNDER OBJECT = V-LOOK-UNDER>
+<SYNTAX LOOK BEHIND OBJECT = V-LOOK-BEHIND>
+<SYNTAX LOOK DOWN OBJECT = V-LOOK-DOWN>
+<SYNTAX LOOK IN OBJECT (HELD CARRIED ON-GROUND IN-ROOM MANY) = V-LOOK-INSIDE>
+<SYNTAX LOOK ON OBJECT (HELD CARRIED ON-GROUND IN-ROOM MANY) = V-LOOK-INSIDE>
+<SYNTAX LOOK AT OBJECT (HELD CARRIED ON-GROUND IN-ROOM MANY) WITH OBJECT = 
+	V-READ PRE-READ>
+<SYNTAX LOOK FOR OBJECT = V-FIND>
+<SYNTAX LOOK OBJECT = V-CHASTISE>
+<SYNONYM LOOK L STARE GAZE>
+
+<SYNTAX SEARCH OBJECT = V-SEARCH>
+<SYNTAX SEARCH IN OBJECT = V-SEARCH>
+<SYNTAX SEARCH FOR OBJECT = V-FIND>
+
+<SYNTAX LOWER OBJECT = V-LOWER>
+<SYNTAX LOWER OBJECT DOWN OBJECT = V-PUT PRE-PUT>
+
+<SYNTAX MAKE OBJECT = V-MAKE>
+
+<SYNTAX MELT
+	OBJECT
+	WITH
+	OBJECT (FIND FLAMEBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-MELT>
+<SYNONYM MELT LIQUIFY>
+
+<SYNTAX MOVE OBJECT (ON-GROUND IN-ROOM) = V-MOVE PRE-MOVE>
+<SYNTAX MOVE OBJECT (ON-GROUND IN-ROOM) OBJECT = V-PUSH-TO PRE-PUSH-TO>
+<SYNTAX ROLL UP OBJECT (ON-GROUND IN-ROOM) = V-MOVE PRE-MOVE>
+
+<SYNTAX PLAY OBJECT = V-PLAY>
+
+<SYNTAX PULL OBJECT (ON-GROUND IN-ROOM) = V-MOVE PRE-MOVE ; *>
+<SYNTAX PULL ON OBJECT (ON-GROUND IN-ROOM) = V-MOVE PRE-MOVE>
+<SYNTAX PULL UP OBJECT (ON-GROUND IN-ROOM) = V-PULL-UP PRE-PULL-UP>
+<SYNTAX PULL OBJECT THROUGH OBJECT (ON-GROUND IN-ROOM) = V-PULL-UP PRE-PULL-UP>
+<SYNTAX PULL OBJECT (ON-GROUND IN-ROOM) OBJECT = V-PUSH-TO PRE-PUSH-TO>
+<SYNONYM PULL TUG YANK>
+
+<SYNTAX MUMBLE = V-MUMBLE>
+<SYNONYM MUMBLE SIGH>
+
+<SYNTAX DESTROY
+	OBJECT (ON-GROUND IN-ROOM HELD CARRIED)
+	WITH
+	OBJECT (HELD CARRIED HAVE)
+	= V-MUNG PRE-MUNG>
+<SYNTAX DESTROY IN OBJECT (ON-GROUND IN-ROOM)
+		WITH
+		OBJECT (HELD CARRIED HAVE) = V-MUNG PRE-MUNG>
+<SYNTAX DESTROY
+	DOWN
+	OBJECT (ON-GROUND IN-ROOM HELD CARRIED)
+	WITH
+	OBJECT (HELD CARRIED HAVE)
+	= V-MUNG PRE-MUNG>
+<SYNONYM DESTROY DAMAGE BREAK SMASH CHOP CHIP HIT>
+
+<SYNTAX LUBRICATE OBJECT WITH OBJECT (HELD CARRIED) = V-OIL PRE-OIL>
+<SYNONYM LUBRICATE GREASE>
+
+<SYNTAX OPEN
+	OBJECT (FIND DOORBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-OPEN ;*>
+<SYNTAX OPEN
+	UP
+	OBJECT (FIND DOORBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-OPEN ;*>
+<SYNTAX OPEN
+	OBJECT (FIND DOORBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	WITH
+	OBJECT (FIND TOOLBIT) (ON-GROUND IN-ROOM HELD CARRIED HAVE)
+	= V-OPEN>
+
+<SYNTAX PICK OBJECT = V-PICK>
+<SYNTAX PICK OBJECT WITH OBJECT (HELD CARRIED HAVE) = V-PICK>
+
+<SYNTAX PICK UP
+	OBJECT (FIND TAKEBIT)
+	       (ON-GROUND MANY)
+	= V-TAKE PRE-TAKE>
+
+<SYNTAX PLUG OBJECT WITH OBJECT (HELD CARRIED HAVE) = V-PLUG>
+<SYNONYM PLUG GLUE PATCH REPAIR FIX>
+
+<SYNTAX PLUGH = V-ADVENTURE>
+<SYNONYM PLUGH XYZZY>
+
+<SYNTAX POKE
+	OBJECT (FIND VILLAIN) (ON-GROUND IN-ROOM)
+	WITH
+	OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE)
+	= V-MUNG PRE-MUNG>
+<SYNONYM POKE JAB BLIND>
+
+<SYNTAX POUR OBJECT (HELD CARRIED) = V-POUR ;*>
+<SYNTAX POUR OBJECT (HELD CARRIED) IN OBJECT = V-POUR-IN>
+<SYNTAX POUR OBJECT (HELD CARRIED HAVE) ON OBJECT = V-POUR-ON PRE-POUR-ON>
+<SYNTAX POUR OBJECT (HELD CARRIED) FROM OBJECT = V-POUR>
+<SYNONYM POUR SPILL>
+
+<SYNTAX PRAY = V-PRAY>
+<SYNTAX PRAY FOR OBJECT = V-PRAY>
+
+<SYNTAX PUMP UP OBJECT = V-PUMP>
+<SYNTAX PUMP UP OBJECT WITH OBJECT = V-PUMP>
+
+<SYNTAX PUSH OBJECT (IN-ROOM ON-GROUND MANY) = V-PUSH>
+<SYNTAX PUSH ON OBJECT (IN-ROOM ON-GROUND MANY) = V-PUSH>
+<SYNTAX PUSH OBJECT (ON-GROUND IN-ROOM) OBJECT = V-PUSH-TO PRE-PUSH-TO>
+<SYNTAX PUSH OBJECT (ON-GROUND IN-ROOM) TO OBJECT = V-PUSH-TO PRE-PUSH-TO>
+<SYNTAX PUSH OBJECT (HELD CARRIED HAVE) UNDER OBJECT = V-PUT-UNDER>
+<SYNTAX PUSH OBJECT (HELD CARRIED HAVE) THROUGH OBJECT = V-PUSH-THROUGH>
+<SYNTAX PUSH UP OBJECT = V-RAISE>
+<SYNONYM PUSH PRESS>
+
+<SYNTAX PUT OBJECT (ON-GROUND HELD MANY HAVE)
+	IN OBJECT = V-PUT PRE-PUT ;*>
+<SYNTAX PUT OBJECT (ON-GROUND HELD MANY HAVE)
+	ON OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX PUT DOWN OBJECT (HELD MANY) = V-DROP>
+<SYNTAX PUT OBJECT (HELD MANY HAVE) UNDER OBJECT = V-PUT-UNDER> 
+<SYNTAX PUT ON OBJECT (IN-ROOM ON-GROUND CARRIED MANY) = V-WEAR>
+<SYNTAX PUT OBJECT (HELD MANY HAVE) BEHIND OBJECT = V-PUT-BEHIND>
+<SYNTAX PUT OBJECT (HELD HAVE) AGAINST OBJECT = V-PUT-AGAINST>
+<SYNTAX PUT OBJECT (HELD HAVE) BY OBJECT = V-PUT-AGAINST>
+<SYNTAX PUT OBJECT (HELD HAVE) AT OBJECT = V-PUT-AGAINST>
+<SYNTAX PUT OBJECT (HELD HAVE) ACROSS OBJECT = V-PUT-ACROSS>
+<SYNTAX PUT OBJECT (HELD HAVE) OVER OBJECT = V-PUT-ACROSS>
+<SYNTAX PUT OBJECT (HELD HAVE) BETWEEN OBJECT = V-PUT-ON PRE-PUT>
+<SYNONYM PUT STUFF INSERT PLACE HIDE WEDGE>
+
+<SYNTAX RAISE OBJECT = V-RAISE ;*>
+<SYNTAX RAISE UP OBJECT = V-RAISE>
+<SYNONYM RAISE LIFT>
+
+<SYNTAX RAPE OBJECT (FIND VICBIT) = V-RAPE>
+<SYNONYM RAPE MOLEST>
+
+<SYNTAX REACH IN OBJECT (FIND OPENBIT) = V-REACH-IN PRE-REACH-IN>
+
+<SYNTAX READ
+	OBJECT (FIND READBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-READ PRE-READ ; *>
+<SYNTAX READ IN OBJECT (HELD CARRIED HAVE) = V-READ-INSIDE>
+<SYNTAX READ
+	OBJECT (FIND READBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	WITH
+	OBJECT (HELD CARRIED HAVE)
+	= V-READ PRE-READ>
+<SYNONYM READ SKIM>
+
+<SYNTAX REPENT = V-REPENT>
+
+<SYNTAX ROLL OBJECT = V-ROLL>
+<SYNTAX ROLL OBJECT (ON-GROUND IN-ROOM) OBJECT = V-PUSH-TO PRE-PUSH-TO>
+<SYNTAX ROLL OBJECT (ON-GROUND IN-ROOM) TO OBJECT = V-PUSH-TO PRE-PUSH-TO>
+
+<SYNTAX RUB OBJECT = V-RUB>
+<SYNTAX RUB OBJECT WITH OBJECT = V-RUB>
+<SYNONYM RUB TOUCH FEEL PAT PET>
+
+<SYNTAX SCRIPT = V-SCRIPT>
+<SYNTAX UNSCRIPT = V-UNSCRIPT>
+
+<SYNTAX SEND OBJECT = V-SEND>
+<SYNTAX SEND FOR OBJECT = V-SEND>
+
+<SYNTAX SHAKE OBJECT = V-SHAKE>
+<SYNONYM SHAKE EMPTY>
+
+<SYNTAX SLIDE OBJECT = V-PUSH>
+<SYNTAX SLIDE OBJECT UNDER OBJECT = V-PUT-UNDER>
+<SYNTAX SLIDE OBJECT (IN-ROOM ON-GROUND) OBJECT = V-PUSH-TO>
+<SYNTAX SLIDE OBJECT (IN-ROOM ON-GROUND) TO OBJECT = V-PUSH-TO>
+
+<SYNTAX SKIP = V-SKIP>
+<SYNONYM SKIP HOP>
+
+<SYNTAX SMELL OBJECT = V-SMELL>
+<SYNONYM SMELL SNIFF>
+
+<SYNTAX SMOKE OBJECT = V-SMOKE>
+
+<SYNTAX SPIN OBJECT = V-SPIN>
+
+<SYNTAX SPRAY OBJECT ON OBJECT = V-SPRAY>
+<SYNTAX SPRAY OBJECT WITH OBJECT = V-SSPRAY>
+
+<SYNTAX SQUEEZE OBJECT = V-SQUEEZE>
+<SYNTAX SQUEEZE OBJECT ON OBJECT = V-PUT PRE-PUT>
+
+<SYNTAX STAND = V-STAND>
+<SYNTAX STAND UP OBJECT (FIND RMUNGBIT) = V-STAND>
+<SYNTAX STAND ON OBJECT (FIND VEHBIT) = V-CLIMB-ON>
+<SYNTAX STAND UNDER OBJECT = V-STAND-UNDER>
+
+<SYNTAX STAY = V-STAY>
+
+<SYNTAX STRIKE
+	OBJECT (FIND VICBIT) (ON-GROUND IN-ROOM)
+	WITH
+	OBJECT (FIND WEAPONBIT) (HELD CARRIED ON-GROUND IN-ROOM HAVE)
+	= V-ATTACK>
+<SYNTAX STRIKE
+	OBJECT (FIND VICBIT) (ON-GROUND IN-ROOM)
+	= V-ATTACK ;*>
+<SYNTAX STRIKE OBJECT (CARRIED ON-GROUND IN-ROOM) = V-LAMP-ON>
+
+<SYNTAX SWIM = V-SWIM>
+<SYNTAX SWIM IN OBJECT = V-SWIM>
+<SYNONYM SWIM BATHE WADE>
+
+<SYNTAX SWING
+	OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE)
+	= V-SWING>
+<SYNTAX SWING
+	OBJECT (FIND WEAPONBIT) (HELD CARRIED HAVE)
+	AT
+	OBJECT (FIND VILLAIN) (ON-GROUND IN-ROOM)
+	= V-SWING>
+<SYNONYM SWING THRUST>
+
+<SYNTAX TAKE
+	OBJECT (FIND TAKEBIT)
+	(ON-GROUND IN-ROOM MANY)
+	= V-TAKE PRE-TAKE ;*>
+<SYNTAX TAKE IN OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-BOARD PRE-BOARD>
+<SYNTAX TAKE OUT OBJECT (FIND VEHBIT) (ON-GROUND) = V-DISEMBARK>
+<SYNTAX TAKE OFF OBJECT (FIND VEHBIT) (ON-GROUND) = V-DISEMBARK>
+<SYNTAX TAKE ON OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-CLIMB-ON>
+<SYNTAX TAKE UNDER OBJECT = V-STAND-UNDER>
+<SYNTAX TAKE UP OBJECT (FIND RMUNGBIT) = V-STAND>
+<SYNTAX TAKE
+	OBJECT (FIND TAKEBIT) (CARRIED IN-ROOM MANY)
+	OUT
+	OBJECT
+	= V-TAKE PRE-TAKE>
+<SYNTAX TAKE
+	OBJECT (FIND TAKEBIT) (CARRIED IN-ROOM MANY)
+	OFF
+	OBJECT
+	= V-TAKE PRE-TAKE>
+<SYNTAX TAKE
+	OBJECT (FIND TAKEBIT) (IN-ROOM CARRIED MANY)
+	FROM
+	OBJECT
+	= V-TAKE PRE-TAKE>
+<SYNTAX TAKE
+	OBJECT (FIND TAKEBIT) (IN-ROOM CARRIED MANY)
+	OF
+	OBJECT
+	= V-TAKE PRE-TAKE> ;"Take a sip of water"
+<SYNTAX TAKE OBJECT (FIND TAKEBIT)
+	WITH OBJECT (FIND TOOLBIT) = V-TAKE PRE-TAKE>
+<SYNONYM TAKE GRAB GET HOLD CARRY REMOVE>
+
+<SYNTAX TELL OBJECT (FIND VICBIT) (IN-ROOM) = V-TELL>
+<SYNONYM TELL ASK>
+
+<SYNTAX SAY TO OBJECT (FIND VICBIT) (IN-ROOM) = V-TELL>
+<SYNTAX SAY = V-SAY>
+<SYNONYM SAY TALK>
+
+<SYNTAX SLEEP = V-SLEEP>
+<SYNTAX SLEEP IN OBJECT = V-SLEEP>
+<SYNTAX SLEEP ON OBJECT = V-SLEEP>
+<SYNTAX SLEEP DOWN ON OBJECT = V-SLEEP> ;"lie down"
+<SYNTAX SLEEP DOWN OBJECT (FIND RMUNGBIT) = V-SLEEP>
+<SYNONYM SLEEP LIE REST>
+
+<SYNTAX INCANT = V-INCANT>
+<SYNONYM INCANT CHANT>
+
+<SYNTAX THROW OBJECT (HELD CARRIED TAKE HAVE) = V-THROW>
+<SYNTAX THROW OBJECT (HELD CARRIED TAKE HAVE) OBJECT = V-THROW-DOWN>
+<SYNTAX THROW OBJECT (HELD CARRIED TAKE HAVE) DOWN OBJECT = V-THROW>
+<SYNTAX THROW OBJECT (HELD CARRIED TAKE HAVE) AT OBJECT = V-THROW>
+<SYNTAX THROW OBJECT (HELD CARRIED TAKE HAVE) OFF OBJECT = V-THROW-OFF>
+<SYNTAX THROW OBJECT (HELD CARRIED TAKE HAVE) OVER OBJECT = V-THROW-OFF>
+<SYNTAX THROW OBJECT (HELD CARRIED TAKE HAVE)
+	WITH  OBJECT (ON-GROUND IN-ROOM)
+	= V-THROW>
+<SYNTAX THROW OBJECT (HELD CARRIED TAKE HAVE) IN OBJECT = V-THROW>
+<SYNTAX THROW OBJECT (HELD CARRIED TAKE HAVE) ON OBJECT = V-THROW>
+<SYNTAX THROW OBJECT (HELD CARRIED TAKE HAVE) TO OBJECT = V-THROW-DOWN>
+<SYNONYM THROW HURL CHUCK TOSS>
+
+<SYNTAX TIE OBJECT (ON-GROUND HELD CARRIED TAKE HAVE)
+	TO OBJECT = V-TIE PRE-TIE>
+<SYNTAX TIE OBJECT (ON-GROUND HELD CARRIED TAKE HAVE)
+	AROUND OBJECT = V-TIE PRE-TIE>
+<SYNTAX TIE UP
+	OBJECT (FIND VICBIT) (ON-GROUND IN-ROOM)
+	WITH
+	OBJECT (ON-GROUND IN-ROOM HELD CARRIED TAKE HAVE)
+	= V-TIE-UP>
+<SYNONYM TIE FASTEN SECURE ATTACH>
+
+<SYNTAX TIME = V-TIME>
+
+<SYNTAX TURN OVER OBJECT = V-TURN-OVER>
+<SYNTAX TURN OBJECT (FIND TURNBIT) TO OBJECT = V-TURN PRE-TURN>
+<SYNTAX TURN OBJECT (FIND TURNBIT) FOR OBJECT = V-TURN PRE-TURN>
+<SYNTAX TURN OBJECT (FIND TURNBIT) = V-TURN PRE-TURN>
+<SYNTAX TURN
+	OBJECT (FIND TURNBIT) ( HELD CARRIED ON-GROUND IN-ROOM)
+	WITH
+	OBJECT (FIND TOOLBIT) (ON-GROUND IN-ROOM HELD CARRIED HAVE)
+	= V-TURN PRE-TURN ;*>
+<SYNTAX TURN ON
+	OBJECT ;(FIND LIGHTBIT) (HELD CARRIED ON-GROUND IN-ROOM TAKE HAVE)
+	= V-LAMP-ON>
+<SYNTAX TURN OFF
+	OBJECT ;(FIND LIGHTBIT) (HELD CARRIED ON-GROUND IN-ROOM TAKE HAVE)
+	= V-LAMP-OFF>
+<SYNONYM TURN FLIP SHUT SET>
+
+<SYNTAX UNFOLD OBJECT = V-UNFOLD>
+<SYNTAX FOLD OBJECT = V-FOLD>
+<SYNTAX FOLD UP OBJECT = V-FOLD>
+
+<SYNTAX UNLOCK
+	OBJECT (ON-GROUND IN-ROOM)
+	WITH
+	OBJECT (FIND TOOLBIT) (HELD CARRIED ON-GROUND IN-ROOM HAVE)
+	= V-UNLOCK>
+
+<SYNTAX UNTIE
+	OBJECT (ON-GROUND IN-ROOM HELD CARRIED)
+	= V-UNTIE ;*>
+<SYNTAX UNTIE
+	OBJECT (ON-GROUND IN-ROOM HELD CARRIED)
+	FROM
+	OBJECT
+	= V-UNTIE>
+<SYNONYM UNTIE FREE UNFASTEN UNATTACH UNHOOK>
+
+<SYNTAX WAIT = V-WAIT>
+<SYNONYM WAIT Z>
+
+<SYNTAX WAKE OBJECT (FIND VICBIT) (ON-GROUND IN-ROOM) = V-ALARM ;*>
+<SYNTAX WAKE UP OBJECT (FIND VICBIT) (ON-GROUND IN-ROOM) = V-ALARM>
+<SYNONYM WAKE AWAKE SURPRISE STARTLE>
+
+<SYNTAX WALK OBJECT = V-WALK>
+<SYNTAX WALK IN OBJECT = V-THROUGH>
+<SYNTAX WALK ON OBJECT = V-THROUGH>
+<SYNTAX WALK OVER OBJECT = V-LEAP>
+<SYNTAX WALK WITH OBJECT = V-THROUGH>
+<SYNTAX WALK AROUND OBJECT = V-WALK-AROUND>
+<SYNTAX WALK UP OBJECT (FIND CLIMBBIT) (ON-GROUND IN-ROOM) = V-CLIMB-UP>
+<SYNTAX WALK DOWN OBJECT (FIND CLIMBBIT) (ON-GROUND IN-ROOM) = V-CLIMB-DOWN>
+<SYNTAX WALK TO OBJECT = V-WALK-TO>
+<SYNONYM WALK GO RUN PROCEED STEP>
+
+<SYNTAX WAVE AT OBJECT = V-WAVE>
+<SYNTAX WAVE TO OBJECT = V-WAVE>
+<SYNTAX WAVE OBJECT (HELD CARRIED) = V-WAVE>
+<SYNTAX WAVE OBJECT (HELD CARRIED) AT OBJECT = V-WAVE>
+<SYNONYM WAVE BRANDISH SIGNAL>
+
+<SYNTAX WEAR OBJECT = V-WEAR>
+
+<SYNTAX WEIGH OBJECT = V-WEIGH>
+
+<SYNTAX WET OBJECT (ON-GROUND IN-ROOM HELD CARRIED HAVE)
+	WITH OBJECT = V-WET>
+
+<SYNTAX WIN = V-WIN>
+<SYNONYM WIN WINNAGE>
+
+<SYNTAX WIND OBJECT = V-WIND>
+<SYNTAX WIND UP OBJECT = V-WIND>
+
+<SYNTAX YELL = V-YELL>
+<SYNONYM YELL SCREAM SHOUT>
+
+<SYNTAX ZORK = V-ZORK>
+
+;"Simple questions"
+
+;"<SYNTAX WHAT ...> WHAT is a synonym of EXAMINE"
+
+;"<SYNTAX WHERE ...> WHERE is a synonym of FIND"
+
+<SYNTAX IS OBJECT IN OBJECT = V-IS-IN>
+<SYNTAX IS OBJECT ON OBJECT = V-IS-IN>
+
+
diff --git a/temple.zil b/temple.zil
new file mode 100644
index 0000000..0ae1431
--- /dev/null
+++ b/temple.zil
@@ -0,0 +1,378 @@
+"TEMPLE for
+			      INFIDEL
+	(c) Copyright 1983 Infocom, Inc.  All Rights Reserved.
+"
+
+;"TEMPLE--This is the file for the Temple area, the passage(s) leading
+to it, and any objects found there. TEMPLE will articulate with the
+BARGE area."
+
+<ROOM IN-THE-HALL
+      (IN ROOMS)
+      (DESC "Steep Passageway")
+      (FLAGS RLANDBIT)
+      (LDESC
+"You are at the top of a steep, descending passage that plunges down to the
+north. Although the angle is steep, it looks as if you should have firm enough
+footing to travel safely. From the angle, it appears as though the passage
+is actually leaving the pyramid, cutting down through the sand high overhead
+to an adjoining building.")
+      (SOUTH TO BARGE-EXIT) ;"Articulates with BARGE area here"
+      (DOWN TO S-END)
+      (NORTH TO S-END)
+      (OUT TO BARGE-EXIT)>
+
+<ROOM S-END
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Steep Passageway")
+      (LDESC
+"You are about midway down a steep, descending, north/south passageway which
+seems to lead out of the pyramid to the north. The walls of stone are polished
+and as smooth as glass, glistening in your light, lighting the passage far to
+the north and the south.")
+      (SOUTH TO IN-THE-HALL)
+      (UP TO IN-THE-HALL)
+      (DOWN TO N-END)
+      (NORTH TO N-END)>
+
+<ROOM N-END
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Steep Passageway")
+      (LDESC
+"You are at the north end of a descending passageway. You can see the smoothly
+polished passageway rising up and out of sight to the south, heading back into
+the pyramid. A large doorway cut into the stone walls lies to the north and,
+through it, you can see an immense chamber.")
+      (SOUTH TO S-END)
+      (UP TO S-END)
+      (NORTH TO TEMPLE-ENTER)
+      (IN TO TEMPLE-ENTER)
+      (GLOBAL DOORWAY)>
+
+<ROOM TEMPLE-ENTER
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Temple Chamber")
+      (LDESC
+"You are in a huge chamber, immense in its size and scope, especially since it
+is far underground. Your light seems to climb and fall from the high walls,
+making their top boundaries undefined as they melt into inky darkness,
+flickering into the unknown reaches high overhead. There is a huge doorway
+carved out of the south wall, the arch at its top barely discernible in your
+light. To the north is a similar doorway, slightly scaled down, with pillars on
+either side of it, their shadows playing strange tricks on the wall behind
+them. You can just barely make out the paintings on the walls, pictures of the
+ancient Queen, her servants, and the priests in attendance.")
+      (SOUTH TO N-END)
+      (NORTH TO SKELETON-ROOM)
+      (OUT TO N-END)
+      (IN TO SKELETON-ROOM)
+      (GLOBAL PICTURES PILLARS)>
+
+<ROOM SKELETON-ROOM
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Inner Chamber")
+      (LDESC
+"You are in the temple's inner chamber. The ceiling here is lower, low enough
+for your light to reach it. There are openings in the east and west walls, and
+a large, arched doorway to the south. The walls are covered with paintings,
+most of which depict the Queen in different stages of preparation for her trip
+on the royal barge. One in particular, larger than any of the others, shows the
+Queen and all of her attendants aboard the barge, floating through the air on
+their way to the netherworld. There are some detailed hieroglyphs on one of the
+walls.")
+      (OUT TO TEMPLE-ENTER)
+      (SOUTH TO TEMPLE-ENTER)
+      (WEST TO GOLDEN-ROOM)
+      (EAST TO SILVER-ROOM)
+      (GLOBAL HIEROGLYPHS PICTURES DOORWAY)>
+
+<ROOM GOLDEN-ROOM
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Golden Room")
+      (LDESC
+"You are in a room whose walls are covered with gold leaf. Your light reflects
+off the walls with a rich, warm tone and reveals the outlines of hieroglyphics
+engraved in the gold itself. There is a doorway cut into the south wall and,
+through the reflected light, you can tell it leads into a small chamber. There
+is another doorway leading out to the east.")
+      (EAST TO SKELETON-ROOM)
+      (SOUTH TO GCUP-ROOM)
+      (OUT TO SKELETON-ROOM)
+      (IN TO GCUP-ROOM)
+      (GLOBAL HIEROGLYPHS GOLD-LEAF)>
+
+<OBJECT GOLD-LEAF
+	(IN LOCAL-GLOBALS)
+	(FLAGS NDESCBIT DONTTAKE TOUCHBIT)
+	(DESC "glittering leaf")
+	(SYNONYM LEAF)
+	(ADJECTIVE GOLD SILVER)
+	(TEXT
+"The walls are covered with it. And it's very beautiful.")>
+
+<ROOM GCUP-ROOM
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Golden Alcove")
+      (LDESC
+"You are in a small alcove off the Golden Room. Sitting in the middle of this
+small room is a roughly-hewn slab of granite, much like a legless table.")
+      (OUT TO GOLDEN-ROOM)
+      (NORTH TO GOLDEN-ROOM)
+      (GLOBAL TABLE)>
+
+<ROOM SILVER-ROOM
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Silver Room")
+      (LDESC 
+"You are in the Silver Chamber, a room whose walls reflect your light
+brilliantly due to their silver surface. A doorway leads west and out, while
+another doorway leads into a smaller room to the south.")
+      (OUT TO SKELETON-ROOM)
+      (WEST TO SKELETON-ROOM)
+      (IN TO SCUP-ROOM)
+      (SOUTH TO SCUP-ROOM)
+      (GLOBAL HIEROGLYPHS GOLD-LEAF)>
+
+<ROOM SCUP-ROOM
+      (IN ROOMS)
+      (FLAGS RLANDBIT)
+      (DESC "Silver Alcove")
+      (LDESC
+"You are in a small alcove off the Silver Room. Sitting in the middle of this
+small room is a roughly-hewn slab of granite, much like a legless table.")
+      (OUT TO SILVER-ROOM)
+      (NORTH TO SILVER-ROOM)
+      (GLOBAL TABLE)>
+
+<OBJECT GOLD-TABLE
+	(IN GCUP-ROOM)
+	(FLAGS CONTBIT SURFACEBIT OPENBIT NDESCBIT TRANSBIT DONTTAKE)
+	(DESC "granite table") 
+	(SYNONYM TABLE SLAB)
+	(ADJECTIVE GRANITE)
+	(CAPACITY 100)
+	(ACTION HUH?)>
+
+<OBJECT GOLD-CUP
+	(IN GOLD-TABLE)
+	(FLAGS CONTBIT OPENBIT TAKEBIT SEARCHBIT)
+	(DESC "golden chalice")
+	(FDESC
+"Sitting in the middle of the granite table is a gleaming chalice made
+of gold.")
+	(TEXT
+"The cup is heavier than you thought it might be. The outside of it is
+beautifully etched with scenes of the Queen and her handmaidens.")
+	(SYNONYM CUP CHALIC)
+	(ADJECTIVE GOLD GOLDEN)
+	(VALUE 15)
+	(CAPACITY 5)
+	(SIZE 8)
+	(MAP 1)
+	(ACTION CUP-FCN)>
+
+<OBJECT SILVER-CUP
+	(IN SILVER-TABLE)
+	(FLAGS CONTBIT OPENBIT TAKEBIT SEARCHBIT)
+	(DESC "silver chalice")
+	(TEXT
+"There's a thin line etched inside the chalice which travels all the way
+around it. The chalice is not very heavy.")
+	(FDESC
+"Sitting in the middle of the granite table is a chalice made of gleaming silver.")
+	(SYNONYM CUP CHALIC)
+	(ADJECTIVE SILVER)
+	(VALUE 15)
+	(SIZE 5)
+	(CAPACITY 5)
+	(MAP 1)
+	(ACTION CUP-FCN)>
+
+<OBJECT LINE
+	(IN GLOBAL-OBJECTS)
+	(FLAGS NDESCBIT TOUCHBIT)
+	(DESC "line")
+	(SYNONYM LINE)
+	(ADJECTIVE THIN)
+	(TEXT
+"The line goes around the interior of the silver cup.")
+	(ACTION LINE-FCN)>
+
+<ROUTINE LINE-FCN ()
+	 <COND (<NOT <OR <HELD? ,SILVER-CUP>
+		    <IN? ,SILVER-CUP ,HERE>>>
+		<TELL "I can't see any " D ,PRSO " here." CR>
+		<RTRUE>)>>
+
+<ROUTINE CUP-FCN ()
+	 <COND (<AND <PRSO? ,SILVER-CUP>
+		     <VERB? EXAMINE LOOK-INSIDE>
+		     <OR <IN? ,WATER ,SILVER-CUP>
+			 <IN? ,LIQUID ,SILVER-CUP>>>
+		<TELL "The ">
+		<COND (<IN? ,WATER ,SILVER-CUP>
+		       <TELL "water">)
+		      (T
+		       <TELL "oily liquid">)>
+		<TELL " fills the cup up to the line." CR>
+		<RTRUE>)
+	       (<VERB? OPEN CLOSE>
+		<HOW? ,PRSO>
+		<RTRUE>)>>
+
+<OBJECT SILVER-TABLE
+	(IN SCUP-ROOM)
+	(FLAGS CONTBIT SURFACEBIT TRANSBIT OPENBIT NDESCBIT DONTTAKE)
+	(DESC "granite table") 
+	(SYNONYM TABLE SLAB)
+	(ADJECTIVE GRANITE)
+	(CAPACITY 100)
+	(ACTION HUH?)>
+
+<OBJECT SKELETON
+	(IN SKELETON-ROOM)
+        (DESC "skeleton")        
+	(FDESC 
+"Lying before you in tortured repose are the bony remains of a former
+adventurer, someone who tried looting the pyramid long, long ago. As you bend
+over to pay your respects, something glitters, catching your eye as you move
+your head.")
+	(SYNONYM SKELET REMAIN BONES ADVENT)
+	(ADJECTIVE BONY)
+	(FLAGS TRYTAKEBIT TAKEBIT CONTBIT OPENBIT SEARCHBIT)
+	(CAPACITY 15)
+	(ACTION SKELETON-FCN)>
+
+<ROUTINE SKELETON-FCN ()
+	 <COND (<OR <VERB? TAKE SHAKE MOVE>
+		    <AND <VERB? PUT>
+			 <EQUAL? ,PRSO ,SKELETON>>>
+		<TELL
+"If you tried that, the skeleton would fall apart, bone by bone." CR>
+		<RTRUE>)
+	       (<VERB? OPEN CLOSE>
+		<HOW? ,PRSO>
+		<RTRUE>)
+	       (<VERB? ALARM>
+		<TELL "Let the dead rest." CR>
+		<RTRUE>)
+	       (<VERB? EXAMINE LOOK-INSIDE>
+		<COND (<IN? ,RING ,DIGITS>
+		       <TELL
+"On the bony digits of one hand is a jeweled ring." CR>)
+		      (T
+		       <TELL
+"I see nothing special about the " D ,PRSO "." CR>)>
+		<RTRUE>)
+	       (<VERB? LOOK-INSIDE>
+		<HOW? ,PRSO>
+		<RTRUE>)>>
+
+<OBJECT DIGITS
+	(IN SKELETON)
+	(DESC "calcified hand")
+	(FLAGS NDESCBIT CONTBIT OPENBIT SEARCHBIT)
+	(SYNONYM DIGITS HAND)
+	(ADJECTIVE BONY CALCIF)
+	(ACTION DIGIT-FCN)>
+
+<ROUTINE DIGIT-FCN ()
+	 <COND (<VERB? OPEN CLOSE>
+		<HOW? ,PRSO>
+		<RTRUE>)
+	       (<VERB? EXAMINE>
+		<PERFORM ,V?EXAMINE ,SKELETON>
+		<RTRUE>)>>
+
+<OBJECT RING
+	(IN DIGITS)
+	(FLAGS TAKEBIT DONTTAKE NDESCBIT CONTBIT OPENBIT SEARCHBIT)
+	(DESC "jeweled ring")
+	(SYNONYM RING)
+	(ADJECTIVE JEWELE)
+	(TEXT
+"At first glance, you are overwhelmed with the beauty and richness of the ring.
+On close examination you notice the ring has a tiny needle on the inside of
+the band.")
+	(SIZE 1)
+	(ACTION WEAR-RING-FCN)>
+
+<ROUTINE WEAR-RING-FCN ()
+	 <COND (<AND <VERB? WEAR>
+		     <IN? ,RING ,WINNER>>
+		<TELL
+"Ouch! It seems you've pricked your finger while putting on the ring."
+		CR>
+		<ENABLE <QUEUE I-RING-KILL -1>>
+		<FSET ,RING ,WEARBIT>
+		<RTRUE>)
+	       (<VERB? WEAR>
+		<TELL "(Taken)" CR>
+		<MOVE ,RING ,WINNER>
+		<PERFORM ,V?WEAR ,RING>
+		<RTRUE>)
+	       (<VERB? TAKE>
+		<COND (<ITAKE>
+		       <TELL "Taken." CR>
+		       <FCLEAR ,RING ,NDESCBIT>
+		       <FCLEAR ,NEEDLE ,INVISIBLE>
+		       <FCLEAR ,RING ,DONTTAKE>
+		       <PUTP ,SKELETON ,P?FDESC
+"Lying before you in tortured repose are the bony remains of a former adventurer.">)>
+		<RTRUE>)
+	       (<AND <VERB? PUT>
+		     <FSET? ,RING ,NDESCBIT>>
+		<FCLEAR ,NEEDLE ,INVISIBLE>
+		<FCLEAR ,RING ,NDESCBIT>
+		<FCLEAR ,RING ,DONTTAKE>
+		<PUTP ,SKELETON ,P?FDESC
+"Lying before you in tortured repose are the bony remains of a former adventurer.">
+		<RFALSE>)
+	       (<VERB? OPEN CLOSE>
+		<HOW? ,PRSO>
+		<RTRUE>)
+	       (<VERB? DISEMBARK>
+		<TELL "It's stuck on your finger." CR>)
+	       (<VERB? EXAMINE LOOK-INSIDE>
+		<TELL <GETP ,RING ,P?TEXT> CR>
+		<FCLEAR ,NEEDLE ,INVISIBLE>
+		<FCLEAR ,RING ,DONTTAKE>
+		<RTRUE>)>>
+
+<OBJECT NEEDLE
+	(IN RING)
+	(FLAGS NDESCBIT INVISIBLE DONTTAKE TRYTAKEBIT)
+	(DESC "tiny needle")
+	(SYNONYM NEEDLE)
+	(ADJECTIVE TINY)
+	(SIZE 1)
+	(TEXT
+"Inside the band is a small needle set at an angle designed to pierce the skin.")
+	(ACTION TOUCH-NEEDLE-FCN)>
+
+<ROUTINE TOUCH-NEEDLE-FCN ()
+	 <COND (<VERB? RUB>
+		<TELL
+"You prick your finger on the tiny needle sticking out from the inside of the
+ring." CR>
+		<ENABLE <QUEUE I-RING-KILL -1>>
+		<RTRUE>)
+	       (<VERB? DROP THROW PUT PUT-ON>
+		<TELL "Better find a haystack first." CR>)
+	       (<VERB? SMELL>
+		<TELL "It smells very faintly of almonds." CR>)
+	       (<VERB? TASTE>
+		<JIGS-UP
+"Ugh! It tastes terrible!|
+|
+You stand there in horrified amazement, feeling the poison creeping down your
+throat and acting on your body almost instantaneously. Time to shuffle off...">
+		<RFATAL>)>>
+
diff --git a/verbs.zil b/verbs.zil
new file mode 100644
index 0000000..91f79d5
--- /dev/null
+++ b/verbs.zil
@@ -0,0 +1,2723 @@
+"VERBS for
+			      INFIDEL
+	(c) Copyright 1983 Infocom, Inc.  All Rights Reserved.
+"
+
+"SUBTITLE DESCRIBE THE UNIVERSE"
+
+"SUBTITLE SETTINGS FOR VARIOUS LEVELS OF DESCRIPTION"
+
+<GLOBAL VERBOSE <>>
+<GLOBAL SUPER-BRIEF <>>
+<GDECL (VERBOSE SUPER-BRIEF) <OR ATOM FALSE>>
+
+<ROUTINE V-VERBOSE ()
+	 <SETG VERBOSE T>
+	 <SETG SUPER-BRIEF <>>
+	 <TELL "Maximum verbosity." CR>>
+
+<ROUTINE V-BRIEF ()
+	 <SETG VERBOSE <>>
+	 <SETG SUPER-BRIEF <>>
+	 <TELL "Brief descriptions." CR>>
+
+<ROUTINE V-SUPER-BRIEF ()
+	 <SETG SUPER-BRIEF T>
+	 <TELL "Super-brief descriptions." CR>>
+
+\
+
+"SUBTITLE DESCRIBERS"
+
+;<ROUTINE V-RNAME ()
+	 <TELL D ,HERE CR>>
+
+;<ROUTINE V-OBJECTS ()
+	 <DESCRIBE-OBJECTS T>>
+
+;<ROUTINE V-ROOM ()
+	 <DESCRIBE-ROOM T>>
+
+<ROUTINE V-LOOK ()
+	 <COND (<DESCRIBE-ROOM T>
+		<DESCRIBE-OBJECTS T>)>>
+
+<ROUTINE V-FIRST-LOOK ()
+	 <COND (<DESCRIBE-ROOM>
+		<COND (<NOT ,SUPER-BRIEF> <DESCRIBE-OBJECTS>)>)>>
+
+<ROUTINE V-EXAMINE ()
+	 <COND (<GETP ,PRSO ,P?TEXT>
+		<TELL <GETP ,PRSO ,P?TEXT> CR>)
+	       (<OR <FSET? ,PRSO ,CONTBIT>
+		    <FSET? ,PRSO ,DOORBIT>>
+		<PERFORM ,V?LOOK-INSIDE ,PRSO>
+		<RTRUE>)
+	       (ELSE
+		<TELL "I see nothing special about the "
+		      D ,PRSO "." CR>)>>
+
+<GLOBAL LIT <>>
+
+<ROUTINE DESCRIBE-ROOM ("OPTIONAL" (LOOK? <>) "AUX" V? STR AV)
+	 <SET V? <OR .LOOK? ,VERBOSE>>
+	 <COND (<NOT ,LIT>
+		<TELL
+"It is pitch black. Off in the distance you hear hideous squealing and what can
+only be the sound of thousands of tiny, clawed feet coming closer." CR>
+		<RETURN <>>)>
+	 <COND (<NOT <FSET? ,HERE ,TOUCHBIT>>
+		<FSET ,HERE ,TOUCHBIT>
+		<SET V? T>)>
+	 <COND (<IN? ,HERE ,ROOMS> <TELL D ,HERE CR>)>
+	 <COND (<OR .LOOK? <NOT ,SUPER-BRIEF>>
+		<SET AV <LOC ,WINNER>>
+		<COND (<FSET? .AV ,VEHBIT>
+		       <TELL "(You are ">
+		       <COND (<EQUAL? .AV ,ALTAR>
+			      <TELL "on">)
+			     (T <TELL "in">)>
+		       <TELL " the " D .AV ".)" CR>)>
+		<COND (<AND .V? <APPLY <GETP ,HERE ,P?ACTION> ,M-LOOK>>
+		       <RTRUE>)
+		      (<AND .V? <SET STR <GETP ,HERE ,P?LDESC>>>
+		       <TELL .STR CR>)
+		      (T <APPLY <GETP ,HERE ,P?ACTION> ,M-FLASH>)>
+		<COND (<AND <NOT <==? ,HERE .AV>> <FSET .AV ,VEHBIT>>
+		       <APPLY <GETP .AV ,P?ACTION> ,M-LOOK>)>)>
+	 T>
+
+<ROUTINE DESCRIBE-OBJECTS ("OPTIONAL" (V? <>))
+	 <COND (,LIT
+		<COND (<FIRST? ,HERE>
+		       <PRINT-CONT ,HERE <SET V? <OR .V? ,VERBOSE>> -1>)>)
+	       (ELSE
+		<TELL "I can't see anything in the dark." CR>)>>
+
+"DESCRIBE-OBJECT -- takes object and flag.  if flag is true will print a
+long description (fdesc or ldesc), otherwise will print short."
+
+<GLOBAL DESC-OBJECT <>>
+
+<ROUTINE DESCRIBE-OBJECT (OBJ V? LEVEL "AUX" (STR <>) AV)
+	 <SETG DESC-OBJECT .OBJ>
+	 <COND (<AND <0? .LEVEL>
+		     <APPLY <GETP .OBJ ,P?DESCFCN> ,M-OBJDESC>>
+		<RTRUE>)
+	       (<AND <0? .LEVEL>
+		     <OR <AND <NOT <FSET? .OBJ ,TOUCHBIT>>
+			      <SET STR <GETP .OBJ ,P?FDESC>>>
+			 <SET STR <GETP .OBJ ,P?LDESC>>>>
+		<TELL .STR>)
+	       (<0? .LEVEL>
+		<TELL "There is a">
+		<VOWEL? .OBJ>
+		<TELL D .OBJ>
+		<COND (<AND <FLAMING? .OBJ>
+			    <NOT <EQUAL? .OBJ ,MANY-MATCHES>>>
+		       <TELL " (lit and burning)">)
+		      (<AND <EQUAL? .OBJ ,ROPE>
+			    ,ROPE-TIED
+			    <EQUAL? ,HERE ,CHAMBER-OF-RA>>
+		       <TELL " (tied to the altar)">)>
+		<TELL " here.">)
+	       (ELSE
+		<TELL <GET ,INDENTS .LEVEL>>
+		<TELL "A">
+		<VOWEL? .OBJ>
+		<TELL D .OBJ>
+		<COND (<FSET? .OBJ ,WEARBIT> <TELL " (being worn)">)>
+		<COND (<AND <FLAMING? .OBJ>
+			    <NOT <EQUAL? .OBJ ,MANY-MATCHES>>>
+		       <TELL " (lit and burning)">)>
+		<COND (<AND <EQUAL? .OBJ ,ROPE> ,ROPE-TIED>
+		       <TELL " (tied to the " D ,ROPE-TIED ")">)>)>
+	 <COND (<AND <0? .LEVEL>
+		     <SET AV <LOC ,WINNER>>
+		     <FSET? .AV ,VEHBIT>>
+		<TELL " (outside the " D .AV ")">)>
+	 <CRLF>
+	 <COND (<AND <SEE-INSIDE? .OBJ> <FIRST? .OBJ>>
+		<PRINT-CONT .OBJ .V? .LEVEL>)>>
+
+<ROUTINE PRINT-CONT (OBJ "OPTIONAL" (V? <>) (LEVEL 0) "AUX" Y 1ST? AV STR
+		     (PV? <>) (INV? <>) (FLG <>))
+	 <COND (<NOT <SET Y <FIRST? .OBJ>>> <RTRUE>)>
+	 <COND (<AND <SET AV <LOC ,WINNER>> <FSET? .AV ,VEHBIT>>
+		T)
+	       (ELSE <SET AV <>>)>
+	 <SET 1ST? T>
+	 <COND (<EQUAL? ,WINNER .OBJ <LOC .OBJ>>
+		<SET INV? T>)
+	       (ELSE
+		<REPEAT ()
+			<COND (<NOT .Y> <RETURN <NOT .1ST?>>)
+			      (<==? .Y .AV> <SET PV? T>)
+			      (<==? .Y ,WINNER>)
+			      (<AND <NOT <FSET? .Y ,INVISIBLE>>
+				    <NOT <FSET? .Y ,TOUCHBIT>>
+				    <SET STR <GETP .Y ,P?FDESC>>>
+			       <COND (<NOT <FSET? .Y ,NDESCBIT>>
+				      <TELL .STR CR>
+				      <SET FLG T>)>
+			       <COND (<AND <SEE-INSIDE? .Y>
+					   <NOT <GETP <LOC .Y> ,P?DESCFCN>>
+					   <FIRST? .Y>>
+				      <PRINT-CONT .Y .V? 0>)>)>
+			<SET Y <NEXT? .Y>>>)>
+	 <SET Y <FIRST? .OBJ>>
+	 <REPEAT ()
+		 <COND (<NOT .Y>
+			<COND (<AND .PV? .AV <FIRST? .AV>>
+			       <PRINT-CONT .AV .V? .LEVEL>)>
+			<RETURN <NOT .1ST?>>)
+		       (<EQUAL? .Y .AV ,ADVENTURER>)
+		       (<AND <NOT <FSET? .Y ,INVISIBLE>>
+			     <OR .INV?
+				 <FSET? .Y ,TOUCHBIT>
+				 <NOT <GETP .Y ,P?FDESC>>>>
+			<COND (<NOT <FSET? .Y ,NDESCBIT>>
+			       <COND (.1ST?
+				      <COND (<FIRSTER .OBJ .LEVEL>
+					     <SET FLG T>
+					     <COND (<L? .LEVEL 0>
+						    <SET LEVEL 0>)>)>
+				      <SET LEVEL <+ 1 .LEVEL>>
+				      <SET 1ST? <>>)>
+			       <DESCRIBE-OBJECT .Y .V? .LEVEL>)
+			      (<AND <FIRST? .Y> <SEE-INSIDE? .Y>>
+			       <PRINT-CONT .Y .V? .LEVEL>)>)>
+		 <SET Y <NEXT? .Y>>>
+	 .FLG>
+
+<ROUTINE FIRSTER (OBJ LEVEL)
+	 <COND (<==? .OBJ ,WINNER>
+		<TELL "You are carrying:" CR>)
+	       (<NOT <IN? .OBJ ,ROOMS>>
+		<COND (<G? .LEVEL 0>
+		       <TELL <GET ,INDENTS .LEVEL>>)>
+		<COND (<FSET? .OBJ ,SURFACEBIT>
+		       <TELL "Sitting on the " D .OBJ
+			     " is:" CR>)
+		      (ELSE
+		       <TELL "The " D .OBJ " contains:" CR>)>)>>
+
+"SUBTITLE SCORING"
+
+<GLOBAL MOVES 0>
+<GLOBAL SCORE 0>
+<GLOBAL BASE-SCORE 0>
+
+<GLOBAL WON-FLAG <>>
+
+<GLOBAL SCORE-MAX 400>
+
+<ROUTINE SCORE-UPD (NUM)
+	 #DECL ((NUM) FIX)
+	 <SETG BASE-SCORE <+ ,BASE-SCORE .NUM>>
+	 <SETG SCORE <+ ,SCORE .NUM>>
+	 T>
+
+<ROUTINE SCORE-OBJ (OBJ "AUX" TEMP)
+	 #DECL ((OBJ) OBJECT (TEMP) FIX)
+	 <COND (<GETP .OBJ ,P?VALUE>
+		<COND (<G? <SET TEMP <GETP .OBJ ,P?VALUE>> 0>
+		       <SCORE-UPD .TEMP>
+		       <PUTP .OBJ ,P?VALUE 0>)>)>>
+
+<ROUTINE V-SCORE ("OPTIONAL" (ASK? T))
+	 #DECL ((ASK?) <OR ATOM FALSE>)
+	 <TELL "Your score is " N ,SCORE>
+	 <TELL " out of a possible " N ,SCORE-MAX ", in ">
+	 <TELL N ,MOVES>
+	 <COND (<1? ,MOVES> <TELL " move.">) (ELSE <TELL " moves.">)>
+	 <CRLF>
+	 <TELL
+"This score gives you the rank of a ">
+	 <COND (<G? ,SCORE 390>
+		<TELL "master adventurer">)
+	       (<G? ,SCORE 320>
+		<TELL "very good adventurer">)
+	       (<G? ,SCORE 200>
+		<TELL "fairly good looter">)
+	       (<G? ,SCORE 100>
+		<TELL "poor professor">)
+	       (ELSE
+		<TELL "fumbling beginner">)>
+	 <TELL "." CR>
+	 ,SCORE>
+
+<ROUTINE FINISH ()
+	 <V-SCORE>
+	 <QUIT>>
+
+<ROUTINE V-QUIT ("OPTIONAL" (ASK? T) "AUX" SCOR)
+	 #DECL ((ASK?) <OR ATOM <PRIMTYPE LIST>> (SCOR) FIX)
+	 <V-SCORE>
+	 <COND (<OR <AND .ASK?
+			 <TELL
+"Do you wish to leave the game? (Y is affirmative): ">
+			 <YES?>>
+		    <NOT .ASK?>>
+		<QUIT>)
+	       (ELSE <TELL "Ok." CR>)>>
+
+<ROUTINE PRE-FINISH ()
+	 <V-SCORE>
+	 <TELL
+"Do you wish to start the game again? (Y is affirmative): ">
+	 <COND (<YES?>
+		<TELL "Okay. Restarting..." CR>
+		<RESTART>
+		<TELL "Failed. Please reboot your system." CR>
+		<QUIT>)
+	       (ELSE <TELL "Ok. See you next time!" CR>
+		<QUIT>)>>
+
+<ROUTINE YES? ()
+	 <PRINTI ">">
+	 <READ ,P-INBUF ,P-LEXV>
+	 <COND (<EQUAL? <GET ,P-LEXV 1> ,W?YES ,W?Y>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE V-VERSION ("AUX" (CNT 17))
+	 <TELL
+"INFIDEL|
+Copyright 1983 by Infocom, Inc.  All rights reserved.|
+INFIDEL is a trademark of Infocom, Inc.|
+Release ">
+	 <PRINTN <BAND <GET 0 1> *3777*>>
+	 <TELL " / Serial number ">
+	 <REPEAT ()
+		 <COND (<G? <SET CNT <+ .CNT 1>> 23>
+			<RETURN>)
+		       (T
+			<PRINTC <GETB 0 .CNT>>)>>
+	 <CRLF>>
+
+<ROUTINE IN-HERE? (OBJ)
+	 <OR <IN? .OBJ ,HERE>
+	     <GLOBAL-IN? .OBJ ,HERE>>>
+
+<ROUTINE V-AGAIN ("AUX" OBJ)
+	 <COND (<==? ,L-PRSA ,V?WALK>
+		<PERFORM ,L-PRSA ,L-PRSO>)
+	       (T
+		<SET OBJ
+		     <COND (<AND ,L-PRSO <NOT <LOC ,L-PRSO>>>
+			    ,L-PRSO)
+			   (<AND ,L-PRSI <NOT <LOC ,L-PRSO>>>
+			    ,L-PRSI)>>
+		<COND (<AND .OBJ 
+			    <NOT <EQUAL? .OBJ ,PSEUDO-OBJECT ,ROOMS>>>
+		       <TELL "I can't see the " D .OBJ " anymore." CR>
+		       <RFATAL>)
+		      (T
+		       <PERFORM ,L-PRSA ,L-PRSO ,L-PRSI>)>)>>
+
+"SUBTITLE DEATH AND TRANSFIGURATION"
+
+<GLOBAL DEAD <>>
+<GLOBAL DEATHS 0>
+<GLOBAL LUCKY 1>
+
+<ROUTINE JIGS-UP (DESC "OPTIONAL" (PLAYER? <>))
+ 	 #DECL ((DESC) ZSTRING (PLAYER?) <OR ATOM FALSE>)
+ 	 <TELL .DESC CR>
+	 <TELL "
+|    ****  You have died  ****
+|
+|">
+	 <COND (<NOT ,PYRAMID-OPENED>
+		<TELL
+"You feel yourself disembodied in a deep blackness. A voice from the void, or
+perhaps it's just your dying thoughts, rings in your ears.|
+|
+\"Obsessions are the torment of men's souls, reaching out for something greater
+than life has offered. Perhaps this is what makes the difference between an
+ordinary mortal and an adventurer!\" It is the last thing you hear." CR>)
+	       (T
+		<TELL
+"The great mysteries of the ancient pyramid remain unsolved. Although your
+desperation has served you well in getting this far, to get farther requires a
+wisdom, tempered by experience." CR>)>
+	 <CRLF>
+	 <PRE-FINISH>>
+
+<ROUTINE V-RESTORE ()
+	 <COND (<RESTORE>
+		<TELL "Ok." CR>
+		<V-FIRST-LOOK>)
+	       (T
+		<TELL "Failed." CR>)>>
+
+<ROUTINE V-SAVE ()
+	 <COND (<SAVE>
+	        <TELL "Ok." CR>)
+	       (T
+		<TELL "Failed." CR>)>>
+
+<ROUTINE V-RESTART ()
+	 <V-SCORE T>
+	 <TELL "Do you wish to restart? (Y is affirmative): ">
+	 <COND (<YES?>
+		<TELL "Restarting." CR>
+		<RESTART>
+		<TELL "Failed." CR>)>>
+
+<CONSTANT REXIT 0>
+<CONSTANT UEXIT 1>
+<CONSTANT NEXIT 2>
+<CONSTANT FEXIT 3>
+<CONSTANT CEXIT 4>
+<CONSTANT DEXIT 5>
+
+<CONSTANT NEXITSTR 0>
+<CONSTANT FEXITFCN 0>
+<CONSTANT CEXITFLAG 1>
+<CONSTANT CEXITSTR 1>
+<CONSTANT DEXITOBJ 1>
+<CONSTANT DEXITSTR 1>
+
+<ROUTINE V-WALK-AROUND ()
+	 <TELL "Use directions for movement here." CR>>
+
+<ROUTINE V-LAUNCH ()
+	  <TELL "How in blazes does one launch that?" CR>>
+
+<ROUTINE GO-NEXT (TBL "AUX" VAL)
+	 #DECL ((TBL) TABLE (VAL) ANY)
+	 <COND (<SET VAL <LKP ,HERE .TBL>>
+		<GOTO .VAL>)>>
+
+<ROUTINE LKP (ITM TBL "AUX" (CNT 0) (LEN <GET .TBL 0>))
+	 #DECL ((ITM) ANY (TBL) TABLE (CNT LEN) FIX)
+	 <REPEAT ()
+		 <COND (<G? <SET CNT <+ .CNT 1>> .LEN>
+			<RFALSE>)
+		       (<==? <GET .TBL .CNT> .ITM>
+			<COND (<==? .CNT .LEN> <RFALSE>)
+			      (T
+			       <RETURN <GET .TBL <+ .CNT 1>>>)>)>>>
+
+<ROUTINE V-WALK ("AUX" PT PTS STR OBJ RM)
+	 #DECL ((PT) <OR FALSE TABLE> (PTS) FIX (STR) <OR ZSTRING FALSE>
+		(OBJ) OBJECT (RM) <OR FALSE OBJECT>)
+	 <COND (<NOT ,P-WALK-DIR>
+		<PERFORM ,V?WALK-TO ,PRSO>
+		<RTRUE>)
+	       (<SET PT <GETPT ,HERE ,PRSO>>
+		<COND (<==? <SET PTS <PTSIZE .PT>> ,UEXIT>
+		       <GOTO <GETB .PT ,REXIT>>)
+		      (<==? .PTS ,NEXIT>
+		       <TELL <GET .PT ,NEXITSTR> CR>
+		       <RFATAL>)
+		      (<==? .PTS ,FEXIT>
+		       <COND (<SET RM <APPLY <GET .PT ,FEXITFCN>>>
+			      <GOTO .RM>)
+			     (T
+			      <RFATAL>)>)
+		      (<==? .PTS ,CEXIT>
+		       <COND (<VALUE <GETB .PT ,CEXITFLAG>>
+			      <GOTO <GETB .PT ,REXIT>>)
+			     (<SET STR <GET .PT ,CEXITSTR>>
+			      <TELL .STR CR>
+			      <RFATAL>)
+			     (T
+			      <TELL "You can't go that way." CR>
+			      <RFATAL>)>)
+		      (<==? .PTS ,DEXIT>
+		       <COND (<FSET? <SET OBJ <GETB .PT ,DEXITOBJ>> ,OPENBIT>
+			      <GOTO <GETB .PT ,REXIT>>)
+			     (<SET STR <GET .PT ,DEXITSTR>>
+			      <TELL .STR CR>
+			      <THIS-IS-IT .OBJ>
+			      <RFATAL>)
+			     (T
+			      <TELL "The " D .OBJ " is closed." CR>
+			      <THIS-IS-IT .OBJ>
+			      <RFATAL>)>)>)
+	       (<AND <NOT ,LIT> <PROB 90>>
+		<JIGS-UP
+"Oh, no! You have been devoured by 6,502 rats!">)
+	       (T
+		<TELL "You can't go that way." CR>
+		<RFATAL>)>>
+
+<ROUTINE THIS-IS-IT (OBJ)
+	 <SETG P-IT-OBJECT .OBJ>
+	 <SETG P-IT-LOC ,HERE>>
+
+<ROUTINE V-INVENTORY ()
+	 <COND (<FIRST? ,WINNER> <PRINT-CONT ,WINNER>)
+	       (T <TELL "You are empty-handed." CR>)>>
+
+<GLOBAL INDENTS
+	<TABLE ""
+	       "  "
+	       "    "
+	       "      "
+	       "        "
+	       "          ">>
+
+\
+
+<ROUTINE PRE-TAKE ()
+	 <COND (<PRSO? ,NOT-HERE-OBJECT>
+		<RFALSE>)>
+	 <COND (<IN? ,PRSO ,WINNER>
+		<COND (<FSET? ,PRSO ,WEARBIT>
+		       <COND (<EQUAL? ,PRSO ,KNAPSACK>
+			      <RFALSE>)
+			     (T <TELL "You are already wearing it." CR>)>)
+		      (<EQUAL? ,PRSO ,ONE-MATCH>
+		       <TELL "You already have one. One at a time, now!" CR>)
+		      (T <TELL "You already have it." CR>)>)
+	       (<AND <FSET? <LOC ,PRSO> ,CONTBIT>
+		     <NOT <FSET? <LOC ,PRSO> ,OPENBIT>>>
+		<TELL "You can't reach that." CR>
+		<RTRUE>)
+	       (,PRSI
+		<COND (<NOT <==? ,PRSI <LOC ,PRSO>>>
+		       <COND (<AND <EQUAL? ,PRSO ,NOT-HERE-OBJECT>
+				   <FSET? ,PRSI ,CONTBIT>
+				   <NOT <FSET? ,PRSI ,OPENBIT>>>
+			      <TELL "You'd better open the " D ,PRSI 
+				    " first." CR>
+			      <THIS-IS-IT ,PRSI>
+			      <RTRUE>)
+			     (<EQUAL? ,PRSO ,LOCK>
+			      <RFALSE>)
+			     (<AND <EQUAL? ,PRSO ,SHOVEL>
+				   <EQUAL? ,PRSI ,SAND>>
+			      <SETG PRSI <>>
+			      <RFALSE>)
+			     (ELSE
+			      <TELL "The " D ,PRSO
+				    " isn't in the " D ,PRSI "." CR>)>)
+		      (T
+		       <SETG PRSI <>>
+		       <RFALSE>)>)
+	       (<==? ,PRSO <LOC ,WINNER>> <TELL "You are in it, loser!" CR>)>>
+
+<ROUTINE V-TAKE ()
+	 <COND (<==? <ITAKE> T>
+		<COND (<FSET? ,PRSO ,WEARBIT>
+		       <TELL "You are now wearing the " D ,PRSO "." CR>)
+		      (T <TELL "Taken." CR>)>)>>
+
+<GLOBAL FUMBLE-NUMBER 7>
+
+<ROUTINE ITAKE ("OPTIONAL" (VB T) "AUX" CNT OBJ TEMP)
+	 #DECL ((VB) <OR ATOM FALSE> (CNT) FIX (OBJ) OBJECT)
+	 <COND (<NOT <FSET? ,PRSO ,TAKEBIT>>
+		<COND (.VB
+		       <TELL <PICK-ONE ,YUKS> CR>)>
+		<RFALSE>)
+	       (<AND <NOT <IN? <LOC ,PRSO> ,WINNER>>
+		     <G? <+ <WEIGHT ,PRSO> <WEIGHT ,WINNER>> ,LOAD-ALLOWED>>
+		<COND (.VB
+		       <TELL "Your load is too heavy." CR>
+		       <CRLF>)>
+		<RFALSE>)
+	       (<G? <SET CNT <CCOUNT ,WINNER>> ,FUMBLE-NUMBER>
+		<TELL "You're carrying too many individual items already!" CR>
+		<RFALSE>)
+	       (T
+		<MOVE ,PRSO ,WINNER>
+		<FSET ,PRSO ,TOUCHBIT>
+		<FCLEAR ,PRSO ,NDESCBIT>
+		<SCORE-OBJ ,PRSO>
+	        <RTRUE>)>>
+
+<ROUTINE V-PUT-ACROSS ()
+	  <TELL "You can't do that." CR>>
+
+<ROUTINE V-PUT-ON ()
+	 <COND (<FSET? ,PRSI ,SURFACEBIT>
+		<V-PUT>
+		<RTRUE>)
+	       (T <TELL "There's no good surface on the " D ,PRSI "." CR>)>>
+
+<ROUTINE PRE-PUT ("AUX" OBJ)
+	 <COND (<PRSO? ,NOT-HERE-OBJECT>
+		<RFALSE>)
+	       (<PRSO? ,PLASTER ,PLASTER1 ,LINTEL>
+		<TELL "That's weird." CR>
+		<RTRUE>)
+	       (<EQUAL? ,PRSI ,GROUND ,SAND>
+		<PERFORM ,V?DROP ,PRSO>
+		<RTRUE>)
+	       (<EQUAL? ,PRSO ,ONE-MATCH>
+		<RFALSE>)
+	       (<OR <IN? ,PRSO ,GLOBAL-OBJECTS>
+		    <NOT <FSET? ,PRSO ,TAKEBIT>>>
+		<TELL "Nice try." CR>)
+	       (<AND <PRSI? ,LEFT-DISC ,RIGHT-DISC ,MID-DISC>
+		     <FIRST? ,PRSI>>
+		<SET OBJ <FIRST? ,PRSI>>
+		<COND (<EQUAL? .OBJ ,PRSO>
+		       <TELL "Better have your eyes checked." CR>)
+		      (T <TELL "There's no room. The " D .OBJ 
+		      " is already on the " D ,PRSI "." CR>)>
+		<RTRUE>)
+	       (<STAIRWAY-CHECK?>
+		<RTRUE>)
+	       (<PRSI? ,TORCH>
+		<PERFORM ,V?DROP ,PRSO ,PRSI>
+		<RTRUE>)>>
+
+<ROUTINE STAIRWAY-CHECK? ()
+	 <COND (<AND <PRSO? ,ROPE>
+		     ,ROPE-TIED>
+		<RFALSE>)
+	       (<AND <OR <EQUAL? ,PRSI ,NORTH-STAIRS ,SOUTH-STAIRS>
+			 <EQUAL? ,PRSI ,WEST-STAIRS ,EAST-STAIRS>>
+		     <EQUAL? <LOC ,WINNER> ,CHAMBER-OF-RA ,TINY-LANDING>>
+		<TELL "You hear the " D ,PRSO " crash below." CR>
+		<COND (<NOT <IN? ,PRSO ,WINNER>>
+		       <TELL "You're not holding the " D ,PRSO "." CR>
+		       <RTRUE>)
+		      (<PRSI? ,NORTH-STAIRS>
+		       <MOVE ,PRSO ,LANDING-ZERO>
+		       <RTRUE>)
+		      (<PRSI? ,EAST-STAIRS>
+		       <MOVE ,PRSO ,LANDING-ONE>
+		       <RTRUE>)
+		      (<PRSI? ,WEST-STAIRS>
+		       <MOVE ,PRSO ,LANDING-THREE>
+		       <RTRUE>)
+		      (<PRSI? ,SOUTH-STAIRS>
+		       <MOVE ,PRSO ,LANDING-TWO>
+		       <RTRUE>)
+		      (ELSE <RFALSE>)>)>>
+
+<ROUTINE V-PUT ()
+	 <COND (<OR <FSET? ,PRSI ,OPENBIT>
+		    <OPENABLE? ,PRSI>
+		    <FSET? ,PRSI ,VEHBIT>>)
+	       (T
+		<TELL "You can't do that." CR>
+		<RTRUE>)>
+	 <COND (<NOT <FSET? ,PRSI ,OPENBIT>>
+		<TELL "The " D ,PRSI " isn't open." CR>)
+	       (<==? ,PRSI ,PRSO>
+		<TELL "How can you do that?" CR>)
+	       (<IN? ,PRSO ,PRSI>
+		<TELL "The " D ,PRSO " is already in the " D ,PRSI "." CR>)
+	       (<G? <- <+ <WEIGHT ,PRSI> <WEIGHT ,PRSO>>
+		       <GETP ,PRSI ,P?SIZE>>
+		    <GETP ,PRSI ,P?CAPACITY>>
+		<TELL "There's no room." CR>)
+	       (<AND <NOT <HELD? ,PRSO>>
+		     <NOT <ITAKE>>>
+		<RTRUE>)
+	       (T
+		<MOVE ,PRSO ,PRSI>
+		<FSET ,PRSO ,TOUCHBIT>
+		<COND (<AND <NOT <EQUAL? ,PRSI ,PUNCH-PANEL>>
+			    <FSET? ,PRSO ,NDESCBIT>>
+		       <FCLEAR ,PRSO ,NDESCBIT>)>
+		<TELL "Done." CR>)>
+	 <COND (<AND <EQUAL? ,PRSO ,BEAM>
+		     ,BEAM-PLACED
+		     <NOT <EQUAL? ,PRSI ,NICHES>>>
+		<SETG BEAM-PLACED <>>
+		<SETG ON-BEAM <>>
+		<RTRUE>)
+	       (<AND <EQUAL? ,PRSO ,DEAD-BOOK ,SCARAB>
+		     <NOT <PRSI? ,S-AREA ,L-AREA>>>
+		<SETG CAN-TURN-STATUES <>>)>>
+
+<ROUTINE PRE-DROP ()
+	 <COND (<==? ,PRSO <LOC ,WINNER>>
+		<PERFORM ,V?DISEMBARK ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE PRE-GIVE ()
+	 <COND (<PRSO? ,NOT-HERE-OBJECT>
+		<RFALSE>)
+	       (<NOT <HELD? ,PRSO>>
+		<TELL 
+"That's easy for you to say since you don't even have it." CR>)>>
+
+<ROUTINE PRE-SGIVE ()
+	 <PERFORM ,V?GIVE ,PRSI ,PRSO>
+	 <RTRUE>>
+
+<ROUTINE HELD? (OBJ)
+	 <COND (<NOT .OBJ> <RFALSE>)
+	       (<IN? .OBJ ,WINNER> <RTRUE>)
+	       (T <HELD? <LOC .OBJ>>)>>
+
+<ROUTINE V-GIVE ()
+	 <TELL "You can't give the " D ,PRSO " to a">
+	 <VOWEL? ,PRSI>
+	 <TELL D ,PRSI "!" CR>>
+
+<ROUTINE V-SGIVE ()
+	 <TELL "FOOOO!!" CR>>
+
+<ROUTINE V-DROP ("OPTIONAL" (SUPPRESS <>))
+	 <COND (<IDROP>
+		<COND (<NOT SUPPRESS>
+		       <TELL "Dropped." CR>)>)>>
+
+;<ROUTINE PRE-THROW ()
+	 <COND (<PRSO? ,NOT-HERE-OBJECT>
+		<RFALSE>)
+	       (<NOT <IN? ,PRSO ,WINNER>>
+		<TELL "You're not carrying the " D ,PRSO "." CR>
+		<RTRUE>)>>
+
+<ROUTINE V-THROW ()
+	 <COND (<AND ,PRSI
+		     <OR <FSET? ,PRSI ,CONTBIT>
+			 <FSET? ,PRSI ,CLIMBBIT>>>
+		<PERFORM ,V?PUT ,PRSO ,PRSI>
+		<RTRUE>)
+	       (ELSE
+		<IDROP>
+		<TELL "Thrown." CR>
+		<RTRUE>)>>
+
+<ROUTINE IDROP ()
+	 <COND (<AND <NOT <IN? ,PRSO ,WINNER>> <NOT <IN? <LOC ,PRSO> ,WINNER>>>
+		<TELL "You're not carrying the " D ,PRSO "." CR>
+		<RFALSE>)
+	       (<AND <NOT <IN? ,PRSO ,WINNER>>
+		     <NOT <FSET? <LOC ,PRSO> ,OPENBIT>>>
+		<TELL "The " D ,PRSO " is closed." CR>
+		<RFALSE>)
+	       (T <MOVE ,PRSO <LOC ,WINNER>> <RTRUE>)>>
+
+<ROUTINE V-OPEN ("AUX" F STR)
+	 <COND (<NOT <FSET? ,PRSO ,CONTBIT>>
+		<TELL "You must tell me how to do that to the " D ,PRSO "." CR>
+		)
+	       (<NOT <==? <GETP ,PRSO ,P?CAPACITY> 0>>
+		<COND (<FSET? ,PRSO ,OPENBIT> <TELL "It is already open." CR>)
+		      (T
+		       <FSET ,PRSO ,OPENBIT>
+		       <COND (<NOT <FIRST? ,PRSO>>
+			      <TELL "Opened." CR>)
+			     (<AND <SET F <FIRST? ,PRSO>>
+				   <NOT <NEXT? .F>>
+				   <SET STR <GETP .F ,P?FDESC>>>
+			      <TELL "The " D ,PRSO " opens." CR>
+			      <TELL .STR CR>)
+			     (T
+			      <COND (<NOT <PRSO? ,MAP>>
+				     <TELL "Opening">)
+				    (T
+				     <TELL "Unfolding">)>
+			      <TELL " the " D ,PRSO " reveals ">
+			      <PRINT-CONTENTS ,PRSO>
+			      <TELL "." CR>)>)>)
+	       (<FSET? ,PRSO ,DOORBIT>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <TELL "It is already open." CR>)
+		      (T
+		       <TELL "The " D ,PRSO " opens." CR>
+		       <FSET ,PRSO ,OPENBIT>)>)
+	       (T <TELL "The " D ,PRSO " fails to open." CR>)>>
+
+<ROUTINE PRINT-CONTENTS (OBJ "AUX" F N (1ST? T))
+	 #DECL ((OBJ) OBJECT (F N) <OR FALSE OBJECT>)
+	 <COND (<SET F <FIRST? .OBJ>>
+		<REPEAT ()
+			<SET N <NEXT? .F>>
+			<COND (.1ST? <SET 1ST? <>>)
+			      (ELSE
+			       <TELL ", ">
+			       <COND (<NOT .N> <TELL "and ">)>)>
+			<TELL "a">
+			<VOWEL? .F>
+			<TELL D .F>
+			<SET F .N>
+			<COND (<NOT .F> <RETURN>)>>)>>
+
+<ROUTINE V-CLOSE ()
+	 <COND (<NOT <FSET? ,PRSO ,CONTBIT>>
+		<TELL "You must tell me how to do that to the " D ,PRSO "." CR>)
+	       (<AND <NOT <FSET? ,PRSO ,SURFACEBIT>>
+		     <NOT <==? <GETP ,PRSO ,P?CAPACITY> 0>>>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <FCLEAR ,PRSO ,OPENBIT>
+		       <TELL "Closed." CR>)
+		      (T <TELL "It is already closed." CR>)>)
+	       (<FSET? ,PRSO ,DOORBIT>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <TELL "The " D ,PRSO " is now closed." CR>
+		       <FCLEAR ,PRSO ,OPENBIT>)
+		      (T <TELL "It is already closed." CR>)>)
+	       (ELSE
+		<TELL "You cannot close that." CR>)>>
+
+<ROUTINE CCOUNT (OBJ "AUX" (CNT 0) X)
+	 <COND (<SET X <FIRST? .OBJ>>
+		<REPEAT ()
+			<COND (<NOT <FSET? .X ,WEARBIT>>
+			       <SET CNT <+ .CNT 1>>)>
+			<COND (<NOT <SET X <NEXT? .X>>>
+			       <RETURN>)>>)>
+	 .CNT>
+
+"WEIGHT:  Get sum of SIZEs of supplied object, recursing to the nth level."
+
+<ROUTINE WEIGHT
+	 (OBJ "AUX" CONT (WT 0))
+	 #DECL ((OBJ) OBJECT (CONT) <OR FALSE OBJECT> (WT) FIX)
+	 <COND (<SET CONT <FIRST? .OBJ>>
+		<REPEAT ()
+			<COND (<AND <==? .OBJ ,WINNER> <FSET? .CONT ,WEARBIT>>
+			       <SET WT <+ .WT 1>>)
+			      (T <SET WT <+ .WT <WEIGHT .CONT>>>)>
+			<COND (<NOT <SET CONT <NEXT? .CONT>>> <RETURN>)>>)>
+	 <+ .WT <GETP .OBJ ,P?SIZE>>>
+
+<ROUTINE V-BUG ()
+	 <TELL
+"If there is a problem here, it is unintentional. You may report
+your problem to the address provided in your documentation." CR>>
+
+<GLOBAL COPR-NOTICE
+" a transcript of interaction with INFIDEL.|
+INFIDEL is a trademark of Infocom, Inc.|
+Copyright (c) 1983 Infocom, Inc.  All rights reserved.|">
+
+<ROUTINE V-SCRIPT ()
+	<PUT 0 8 <BOR <GET 0 8> 1>>
+	<TELL "Here begins" ,COPR-NOTICE CR>>
+
+<ROUTINE V-UNSCRIPT ()
+	<TELL "Here ends" ,COPR-NOTICE CR>
+	<PUT 0 8 <BAND <GET 0 8> -2>>
+	<RTRUE>>
+
+<ROUTINE PRE-MOVE ()
+	 <COND (<HELD? ,PRSO> <TELL "I don't juggle objects!" CR>)>>
+
+<ROUTINE V-MOVE ()
+	 <COND (<AND <EQUAL? ,PRSO ,BEAM>
+		     <NOT <FSET? ,BEAM ,TOUCHBIT>>>
+		<TELL
+"Sure. But it might be better to be a little more specific in how you want it
+moved." CR>)
+	       (<FSET? ,PRSO ,TAKEBIT>
+		<TELL "Moving the " D ,PRSO " reveals nothing." CR>)
+	       (T <TELL "You can't move the " D ,PRSO "." CR>)>>
+
+<ROUTINE V-LAMP-ON ()
+	 <COND (<FSET? ,PRSO ,BURNBIT>
+		<COND (<FLAMING? ,PRSO>
+		       <COND (<EQUAL? ,PRSO ,ONE-MATCH>
+			      <TELL "One">)
+			     (T <TELL "It">)>
+		       <TELL " is already lit." CR>)
+		      (<AND <EQUAL? ,PRSO ,TORCH>
+			    <NOT ,PRSI>
+			    <NOT <IN? ,ONE-MATCH ,WINNER>>>
+		       <TELL 
+"You expect to light the torch with your glowing intellect?" CR>
+		       <RTRUE>)
+		      (<AND <OR <EQUAL? ,PRSI ,MATCHES
+					,ONE-MATCH ,SINGLE-MATCH>
+				<IN? ,ONE-MATCH ,WINNER>>
+			    <EQUAL? ,PRSO ,TORCH>>
+		       <ENABLE <QUEUE I-TORCH -1>>
+		       <LIGHT-THE ,TORCH <>>
+		       <FSET ,TORCH ,TOUCHBIT>)
+		      (<AND <OR <EQUAL? ,PRSO ,MANY-MATCHES ,SINGLE-MATCH 
+					,EMPTY-MATCHES>
+				<EQUAL? ,PRSO ,ONE-MATCH>>
+			    <AND <NOT <IN? ,ONE-MATCH ,WINNER>>
+				 <NOT <IN? ,MATCHES ,WINNER>>>>
+		       <TELL "I see no match here." CR>
+		       <RTRUE>)
+		      (<OR <EQUAL? ,PRSO ,MANY-MATCHES ,SINGLE-MATCH 
+					,EMPTY-MATCHES>
+				<EQUAL? ,PRSO ,ONE-MATCH>>
+		       <COND (<L? ,MATCH-COUNT 1>
+			      <TELL 
+"That's a little tough to do with an empty book of matches." CR>
+			      <RTRUE>)
+			     (T
+			      <COND (<NOT <IN? ,ONE-MATCH ,WINNER>>
+				     <MATCH-MOVER>)>
+			      <TELL "You have now lit a match." CR>
+			      <LIGHT-THE ,ONE-MATCH T>
+			      <ENABLE <QUEUE I-MATCH-OUT 3>>)>)
+		      (ELSE
+		       <TELL "I don't know how to light the " D ,PRSO"." CR>)>)
+	       (T
+		<TELL "You can't light that." CR>)>
+	 <RTRUE>>
+
+<ROUTINE FLAMING? (OBJ)
+	 <COND (<FSET? .OBJ ,FLAMEBIT>
+		<RTRUE>)>>
+
+<ROUTINE LIGHT-THE (OBJECT SUPPRESS?)
+	 <FSET .OBJECT ,ONBIT>
+	 <FSET .OBJECT ,FLAMEBIT>
+	 <COND (<EQUAL? .OBJECT ,ONE-MATCH>
+		<COND (<FSET? ,MATCHES ,OPENBIT>
+		       <COND (<PROB 10>
+			      <TELL
+"Ooops! You didn't remember to close the cover before striking! The matchbook
+bursts into flames, burning your fingertips." CR>
+			      <MOVE ,BURNED-MATCHBOOK <LOC ,MATCHES>>
+			      <FSET ,BURNED-MATCHBOOK ,OPENBIT>
+			      <REMOVE ,MATCHES>
+			      <REMOVE ,MANUAL>
+			      <REMOVE ,ONE-MATCH>
+			      <SETG MATCH-COUNT 0>
+			      <SET SUPPRESS? T>)>)>)>
+	 <COND (<NOT .SUPPRESS?>
+		<TELL "The " D .OBJECT " is now lit." CR>)>
+	 <COND (<NOT ,LIT>
+		<SETG LIT <LIT? ,HERE>>
+		<CRLF>
+		<V-LOOK>)>>
+
+<ROUTINE V-LAMP-OFF ()
+	 <COND (<FSET? ,PRSO ,BURNBIT>
+		<COND (<NOT <FLAMING? ,PRSO>>
+		       <TELL "It is already out." CR>)
+		      (<EQUAL? ,PRSO ,MATCHES ,ONE-MATCH>
+		       <DISABLE <INT I-MATCH-OUT>>
+		       <I-MATCH-OUT T>
+		       <RTRUE>)
+		      (ELSE
+		       <TELL "The " D ,PRSO " is now out." CR>
+		       <KILL-TORCH>)>)
+	       (ELSE <TELL "You can't extinguish that." CR>)>
+	 <RTRUE>>
+
+<ROUTINE V-WAIT ("OPTIONAL" (NUM 3))
+	 #DECL ((NUM) FIX)
+	 <TELL "Time passes..." CR>
+	 <REPEAT ()
+		 <COND (<L? <SET NUM <- .NUM 1>> 0> <RETURN>)
+		       (<CLOCKER> <RETURN>)>
+		 <SETG MOVES <+ ,MOVES 1>>>
+	 <SETG CLOCK-WAIT T>>
+
+<ROUTINE PRE-BOARD ("AUX" AV)
+	 <SET AV <LOC ,WINNER>>
+	 <COND (<EQUAL? ,PRSO ,TENT-OBJ>
+		<RFALSE>)
+	       (<EQUAL? ,PRSO ,BOAT>
+		<RFALSE>)
+	       (<EQUAL? ,PRSO ,BEAM>
+		<PERFORM ,V?CLIMB-ON ,BEAM>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,VEHBIT>
+		<COND (<FSET? .AV ,VEHBIT>
+		       <TELL "You are already on the " D .AV ", cretin!" CR>)
+		      (T <RFALSE>)>)
+	       (<PRSO? ,NOT-HERE-OBJECT>
+		<RFALSE>)
+	       (T
+		<TELL "I suppose you have a theory on getting into the "
+		      D ,PRSO "." CR>)>
+	 <RFATAL>>
+
+<ROUTINE V-BOARD ("OPTIONAL" OBJ "AUX" AV)
+	 #DECL ((AV) OBJECT)
+	 <TELL "You are now ">
+	 <COND (<EQUAL? ,PRSO ,ALTAR>
+		<TELL "on">)
+	       (T <TELL "in">)>
+	 <TELL " the " D ,PRSO "." CR>
+	 <MOVE ,WINNER ,PRSO>
+	 <COND (<NOT <EQUAL? ,PRSO ,ALTAR ,CRATE ,SLAB>>
+		<APPLY <GETP ,PRSO ,P?ACTION> ,M-ENTER>)>
+	 <RTRUE>>
+
+<GLOBAL STOOD-UP <>>
+
+<ROUTINE V-DISEMBARK ()
+	 <COND (<NOT <==? <LOC ,WINNER> ,PRSO>>
+		<TELL "You're not in that!" CR>
+		<RFATAL>)
+	       (<FSET? ,HERE ,RLANDBIT>
+		<COND (<NOT ,STOOD-UP>
+		       <TELL 
+"You push yourself up and manage to get out of the cot. Your legs are a little
+wobbly, though, and your head swims." CR>
+		       <SETG STOOD-UP T>)
+		      (T
+		       <TELL "You are on your feet again." CR>)>
+		<MOVE ,WINNER ,HERE>)
+	       (T
+		<TELL
+"You realize, just in time, that getting out here would probably be fatal." CR>
+		<RFATAL>)>>
+
+<ROUTINE V-BLAST ()
+	 <TELL "You can't blast anything by using words." CR>>
+
+<ROUTINE GOTO (RM "OPTIONAL" (V? T)
+	       "AUX" (LB <FSET? .RM ,RLANDBIT>) (WLOC <LOC ,WINNER>)
+	             (AV <>) OLIT)
+	 #DECL ((RM WLOC) OBJECT (LB) <OR ATOM FALSE> (AV) <OR FALSE FIX>)
+	 <SET OLIT ,LIT>
+	 <COND (<FSET? .WLOC ,VEHBIT>
+		<TELL "You'd better get ">
+		<COND (<EQUAL? .WLOC ,ALTAR>
+		       <TELL "off">)
+		      (T <TELL "out">)>
+		<TELL " of the " D .WLOC " first." CR>
+		<RTRUE>
+		;<SET AV <GETP .WLOC ,P?VTYPE>>)>
+	 <COND (<OR <AND <NOT .LB> <OR <NOT .AV> <NOT <FSET? .RM .AV>>>>
+		    <AND <FSET? ,HERE ,RLANDBIT>
+			 .LB
+			 .AV
+			 <NOT <==? .AV ,RLANDBIT>>
+			 <NOT <FSET? .RM .AV>>>>
+		<COND (.AV <TELL "You can't go there in a">
+		       <VOWEL? .WLOC>
+		       <TELL D .WLOC ".">)
+		      (T <TELL "You can't go there without a vehicle.">)>
+		<CRLF>
+		<RFALSE>)
+	       (<FSET? .RM ,RMUNGBIT> <TELL <GETP .RM ,P?LDESC> CR> <RFALSE>)
+	       (T
+		<COND (.AV <MOVE .WLOC .RM>)
+		      (T
+		       <MOVE ,WINNER .RM>)>
+		<SETG HERE .RM>
+		<SETG LIT <LIT? ,HERE>>
+		<COND (<AND <NOT .OLIT>
+			    <NOT ,LIT>
+			    <PROB 85>>
+		       <JIGS-UP
+"Oh, no! An army of eleventy-seven rats, starved for affection (and food),
+leapt upon your body in a show of rodentine appreciation and devoured you!">)>
+		<APPLY <GETP ,HERE ,P?ACTION> ,M-ENTER>
+		<COND (<NOT <==? ,HERE .RM>> <RTRUE>)
+		      (<NOT <==? ,ADVENTURER ,WINNER>>
+		       <TELL "The " D ,WINNER " leaves the room." CR>)
+		      (.V? <V-FIRST-LOOK>)>
+		<RTRUE>)>>
+
+<ROUTINE V-BACK
+	 ()
+	 <TELL
+"Sorry, my memory isn't that good. You'll have to give a direction." CR>>
+
+<ROUTINE V-POUR ()
+	 <COND (<NOT <OR <EQUAL? ,PRSO ,OIL-JAR ,LIQUID ,WATER>
+			 <EQUAL? ,PRSO ,C-SAND>>>
+		<TELL "You can't pour that." CR>
+		<RTRUE>)
+	       (T
+		<TELL "Poured." CR>
+		<COND (<EQUAL? ,PRSO ,OIL-JAR ,LIQUID>
+		       <SETG OIL-LEFT 0>
+		       <REMOVE ,LIQUID>)
+		      (<EQUAL? ,PRSO ,C-SAND>
+		       <SETG SAND-FILLED <>>
+		       <REMOVE ,C-SAND>)
+		      (T
+		       <REMOVE ,WATER>
+		       <SETG WATER-LEFT 0>)>)>>
+
+<ROUTINE V-POUR-IN ("AUX" L)
+	 <COND (<NOT <OR <EQUAL? ,PRSO ,OIL-JAR ,LIQUID ,WATER>
+			 <EQUAL? ,PRSO ,C-SAND>>>
+		<TELL "You can't pour that into anything." CR><RTRUE>)
+	       (<NOT <FSET? ,PRSI ,CONTBIT>>
+		<TELL "You'd have a lot of trouble pouring the " D ,PRSO
+		      " into the " D ,PRSI "." CR>
+		<RTRUE>)
+	       (<EQUAL? ,PRSI ,GOLD-CUP ,SILVER-CUP>
+		<COND (<OR <AND <EQUAL? ,PRSO ,WATER>
+				<EQUAL? <LOC ,LIQUID> ,PRSI>>
+			   <AND <EQUAL? ,PRSO ,LIQUID>
+				<EQUAL? <LOC ,WATER> ,PRSI>>>
+		       <TELL "Oil and water never mixed together well." CR>
+		       <RTRUE>)>
+		<SET L <LOC ,PRSO>>
+		<TELL "Okay. The " D ,PRSI " has been filled, but the "
+		      D .L " is now empty." CR>
+		<MOVE ,PRSO ,PRSI>
+		<COND (<EQUAL? ,PRSO ,WATER>
+		       <SETG WATER-LEFT 0>)
+		      (<EQUAL? ,PRSO ,C-SAND>
+		       <SETG SAND-FILLED <>>)>)
+	       (T
+		<TELL "Why bother?" CR>)>>
+	        
+
+<ROUTINE PRE-POUR-ON ("AUX" LIQ)
+	 <COND (<EQUAL? ,PRSO ,NOT-HERE-OBJECT>
+		<RFALSE>)
+	       (<EQUAL? ,PRSO ,WATER ,C-SAND>
+		<SET LIQ ,PRSO>
+		<COND (<NOT <FSET? <LOC .LIQ> ,OPENBIT>>
+		       <TELL "You'd better open the " D <LOC .LIQ> " first."
+			     CR>
+		       <RTRUE>)
+		      (<FLAMING? ,PRSI>
+		       <TELL "Poured." CR>
+		       <COND (,LIT
+			      <SETG LIT <LIT? ,HERE>>)>
+		       <COND (<NOT <SETG LIT <LIT? ,HERE>>>
+			      <TELL " It is now pitch black.">)>
+		       <COND (<EQUAL? .LIQ ,WATER>
+			      <SETG WATER-LEFT <- ,WATER-LEFT 10>>
+			      <COND (<L? ,WATER-LEFT 10>
+				     <REMOVE ,WATER>)>)
+			     (T
+			      <SETG SAND-FILLED <>>
+			      <REMOVE ,C-SAND>)>
+		       <FCLEAR ,PRSI ,FLAMEBIT>
+		       <FCLEAR ,PRSI ,ONBIT>
+		       <RTRUE>)
+		      (T
+		       <TELL "Poured." CR>
+		       <COND (<EQUAL? .LIQ ,WATER>
+			      <SETG WATER-LEFT <- ,WATER-LEFT 10>>
+			      <COND (<L? ,WATER-LEFT 10>
+				     <REMOVE ,WATER>)>
+			      <TELL "The " D ,PRSI
+				     " gets wet, but quickly dries." CR>)
+			     (T
+			      <COND (<GETP ,HERE ,P?MAP>
+				     <TELL "The sand is gone with the wind." CR>)
+				    (T <TELL 
+"The sand falls through the cracks in the stone floor." CR>)>
+			      <SETG SAND-FILLED <>>)>
+		       <RTRUE>)>)
+	       (<NOT <EQUAL? ,PRSO ,OIL-JAR ,LIQUID>>
+		<TELL "You can't pour that on anything." CR><RTRUE>)
+               (<0? ,OIL-LEFT>
+		<TELL "Why bother? The jar is empty." CR>
+		<RTRUE>)
+	       (<NOT <EQUAL? ,PRSI ,TORCH>>
+		<TELL
+"Why waste precious liquid? But, if you insist, done! The liquid evaporates in
+a few moments." CR>
+		<SETG OIL-LEFT 0>
+		<REMOVE ,LIQUID>
+		<RTRUE>)
+	       (<NOT <FSET? ,OIL-JAR ,OPENBIT>>
+		<TELL 
+"A little tough to get that wick through the closed jar, eh?" CR>
+		<RTRUE>)
+	       (T
+		<TELL "The tip of the torch has been covered with the liquid.">
+		<COND (<FLAMING? ,TORCH>
+		       <TELL 
+" The torch flares up, singeing your eyebrows. Phew! Close call, there!">
+		       <SETG TORCH-TURNS 0>)>
+		<CRLF>
+		<SETG OIL-LEFT <- ,OIL-LEFT 20>>
+		<SETG OIL-SOAKED T>
+		<SETG OILED-TORCH T>)>>
+
+<ROUTINE V-POUR-ON () <TELL "Foo!" CR>>
+
+<ROUTINE V-SPRAY () <V-SQUEEZE>>
+<ROUTINE V-SSPRAY () <PERFORM ,V?SPRAY ,PRSI ,PRSO>>
+
+<ROUTINE V-SQUEEZE ()
+	  <TELL "How singularly useless." CR>>
+
+<ROUTINE PRE-OIL ()
+	 <TELL "You probably put spinach in your gas tank, too." CR>>
+
+<ROUTINE V-OIL () <TELL "That's not very useful." CR>>
+
+<ROUTINE PRE-FILL ("AUX" T)
+	 #DECL ((T) <OR FALSE TABLE>)
+	 <COND (<PRSO? ,NOT-HERE-OBJECT>
+		<RFALSE>)
+	       (<AND <NOT ,PRSI>
+		     <SET T <GETPT ,HERE ,P?GLOBAL>>>
+		<COND (<ZMEMQB ,GLOBAL-WATER .T <PTSIZE .T>>
+		       <SETG PRSI ,GLOBAL-WATER>
+		       <RFALSE>)
+		      (T
+		       <TELL "There is nothing to fill it with.">
+		       <COND (<GETP ,HERE ,P?MAP>
+			      <TELL " Except for some sand.">)>
+		       <CRLF>
+		       <RTRUE>)>)>
+	 <COND (<NOT <EQUAL? ,PRSI ,GLOBAL-WATER>>
+		<PERFORM ,V?PUT ,PRSI ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-FILL ()
+	 <COND (<NOT ,PRSI>
+		<COND (<GLOBAL-IN? ,GLOBAL-WATER ,HERE>
+		       <PERFORM ,V?FILL ,PRSO ,GLOBAL-WATER>)
+		      (T
+		       <TELL "There's nothing to fill it with.">
+		       <COND (<GETP ,HERE ,P?MAP>
+			      <TELL " Except for maybe some sand.">)>
+		       <CRLF>)>)
+	       (<EQUAL? ,PRSI ,GLOBAL-WATER>
+		<COND (<OR <EQUAL? ,WATER-LEFT 40>
+			   <IN? ,C-SAND ,PRSO>>
+		       <TELL "It's already full." CR>)
+		      (<NOT <FSET? ,PRSO ,CONTBIT>>
+		       <HOW? ,PRSO>
+		       <RTRUE>)
+		      (<NOT <FSET? ,PRSO ,OPENBIT>>
+		       <TELL "Tough to do when the " D ,PRSO " is closed." CR>)
+		      (<NOT <PRSO? ,CANTEEN ,GOLD-CUP ,SILVER-CUP>>
+		       <TELL <PICK-ONE ,YUKS> CR>)
+		      (<IN? ,LIQUID ,PRSO>
+		       <TELL "Oil and water don't mix." CR>)
+		      (T
+		       <MOVE ,WATER ,PRSO>
+		       <COND (<EQUAL? ,HERE ,RIVER-BANK>
+			      <SETG WATER-LEFT 40>)
+			     (T
+			      <SETG WATER-LEFT 0>)>
+		       <TELL "Okay, you have filled the " D ,PRSO "." CR>)>)
+	       (<EQUAL? ,PRSI ,WATER>
+		<COND (<IN? ,LIQUID ,PRSO>
+		       <TELL "Oil and water don't mix." CR>
+		       <RTRUE>)
+		      (T
+		       <PERFORM ,V?POUR-IN ,WATER ,PRSO>
+		       <THIS-IS-IT ,PRSO>
+		       <RTRUE>)>)
+	       (<EQUAL? ,PRSI ,LIQUID ,OIL-JAR>
+		<COND (<IN? ,WATER ,PRSO>
+		       <TELL "Water and oil don't mix." CR>
+		       <RTRUE>)
+		      (T
+		       <PERFORM ,V?POUR-IN ,LIQUID ,PRSO>
+		       <RTRUE>)>)
+	       (T <TELL "You may know how to do that, but I don't." CR>)>>
+
+<ROUTINE V-ADVENTURE () <TELL "A hollow voice says \"Fool.\"" CR>>
+
+<ROUTINE V-DRINK ()
+	 <COND (<PRE-EAT>
+		<RTRUE>)
+	       (T
+		<V-EAT>)>>
+
+<ROUTINE PRE-EAT ()
+	 <COND (<AND <NOT <IN? ,PRSO ,WINNER>>
+		     <FSET? ,PRSO ,FOODBIT>>
+		<COND (<EQUAL? <ITAKE <>> T>
+		       <TELL "(Taken)" CR>
+		       <RFALSE>)
+		      (T <RTRUE>)>)
+	       (<AND <NOT <IN? ,PRSO ,WINNER>>
+		     <NOT <EQUAL? ,PRSO ,ME ,WINNER ,ADVENTURER>>
+		     <FSET? ,PRSO ,FOODBIT>>
+		<TELL "You're not holding the " D ,PRSO "." CR>
+		<RTRUE>)>>
+
+<GLOBAL NILE-DRINKS 0>
+
+<ROUTINE V-EAT ("AUX" (EAT? <>) (DRINK? <>) (NOBJ <>))
+	 #DECL ((NOBJ) <OR OBJECT FALSE> (EAT? DRINK?) <OR ATOM FALSE>)
+	 <COND (<AND <SET EAT? <FSET? ,PRSO ,FOODBIT>> <IN? ,PRSO ,WINNER>>
+		<COND (<VERB? DRINK> <TELL "How can you drink that?">)
+		      (ELSE
+		       <TELL 
+"That really hit the spot. It did make you a little thirstier, though.">
+		       <REMOVE ,PRSO>
+		       <SETG THIRST <+ ,THIRST 10>>
+		       <DISABLE <INT I-GROWL>>
+		       <COND (<NOT <GETP ,HERE ,P?MAP>>
+			      <ENABLE <QUEUE I-PYRAMID-DRINK -1>>)>)>
+		<CRLF>)
+	       (<SET DRINK? <FSET? ,PRSO ,DRINKBIT>>
+		<COND (<OR <IN? ,PRSO ,GLOBAL-OBJECTS>
+			   <AND <SET NOBJ <LOC ,PRSO>>
+				<IN? .NOBJ ,WINNER>
+				<FSET? .NOBJ ,OPENBIT>>>
+		       <TELL "You feel much refreshed.">
+		       <COND (,SANDY-CANTEEN
+			      <TELL 
+" Some sand from the bottom of the canteen is gritty in your mouth, though.">)>
+		       <CRLF>
+		       <SETG WATER-LEFT <- ,WATER-LEFT 10>>
+		       <COND (<L? ,WATER-LEFT 10>
+			      <REMOVE ,PRSO>)>
+		       <SETG THIRST 0>
+		       <SETG PYR-THIRST 0>
+		       <DISABLE <INT I-PYRAMID-DRINK>>)
+		      (<IN? ,PRSO ,LOCAL-GLOBALS>
+		       <COND (<G? ,NILE-DRINKS 3>
+			      <TELL 
+"You're going to start sloshing around soon." CR>
+			      <RTRUE>)>
+		       <TELL
+"You kneel down and drink deeply from the Nile and feel refreshed." CR>
+		       <SETG NILE-DRINKS <+ ,NILE-DRINKS 1>>
+		       <SETG THIRST 0>
+		       <SETG PYR-THIRST 0>
+		       <DISABLE <INT I-PYRAMID-DRINK>>)
+		      (T <TELL 
+"I'd like to oblige, but it's not within easy reach." CR>)>)
+	       (<NOT <OR .EAT? .DRINK?>>
+		<TELL "I don't think that the "
+		      D
+		      ,PRSO
+		      " would agree with you." CR>)>>
+
+<ROUTINE V-CURSES ()
+	 <COND (,PRSO
+		<COND (<FSET? ,PRSO ,VILLAIN>
+		       <TELL "Insults of this nature won't help you." CR>)
+		      (T
+		       <TELL "What a loony!" CR>)>)
+	       (T
+		<TELL
+"Such language in a high-class establishment like this!" CR>)>>
+
+<ROUTINE V-LISTEN ()
+	 <TELL "The " D ,PRSO " makes no sound." CR>>
+
+<ROUTINE V-FOLLOW ()
+	 <TELL "Give me a break!" CR>>
+
+<ROUTINE V-STAY ()
+	 <TELL "You will be lost without me!" CR>>
+
+<GLOBAL PRAYER-HACK 0>
+
+<ROUTINE V-PRAY ()
+	 <SETG PRAYER-HACK <+ ,PRAYER-HACK 1>>
+	 <COND (<L? ,PRAYER-HACK 3>
+		<TELL "If you pray enough, your prayers may be answered." CR>)
+	       (T
+		<TELL "No one is listening..." CR>)>>
+
+<ROUTINE V-LEAP ("AUX" T S) #DECL ((T) <OR FALSE TABLE>)
+	 <COND (<AND ,PRSO
+		     <NOT <PRSO? ,INTDIR>>>
+		<PERFORM V?BOARD ,PRSO>
+		<RTRUE>)
+	       (<SET T <GETPT ,HERE ,P?DOWN>>
+		<SET S <PTSIZE .T>>
+		<COND (<OR <==? .S 2>					 ;NEXIT
+			   <AND <==? .S 4>				 ;CEXIT
+				<NOT <VALUE <GETB .T 1>>>>>
+		       <TELL
+"This was not a very safe place to try jumping." CR>
+		       <JIGS-UP <PICK-ONE ,JUMPLOSS>>)
+		      (T <V-SKIP>)>)
+	       (ELSE <V-SKIP>)>>
+
+<ROUTINE V-SKIP () <TELL <PICK-ONE ,WHEEEEE> CR>>
+
+<ROUTINE V-LEAVE () <DO-WALK ,P?OUT>>
+
+<GLOBAL HS 0>
+
+<ROUTINE V-HELLO ()
+	 <COND (,PRSO
+		<TELL
+		 "I think that only schizophrenics say \"Hello\" to a">
+		<VOWEL? ,PRSO>
+		<TELL D ,PRSO "." CR>)
+	       (ELSE <TELL <PICK-ONE ,HELLOS> CR>)>>
+
+<GLOBAL HELLOS
+	<LTABLE "Hello."
+	       "Good day."
+	       "Nice weather we've been having lately."
+	       "Goodbye.">>
+
+<GLOBAL WHEEEEE
+	<LTABLE "Very good. Now you can go to the second grade."
+	       "Have you tried hopping around, too?"
+	       "Are you enjoying yourself?"
+	       "Wheeeeeeeeee!!!!!"
+	       "Do you expect me to applaud?">>
+
+<GLOBAL JUMPLOSS
+	<LTABLE "You should have looked before you leaped."
+	       "I'm afraid that leap was a bit much for your weak frame."
+	       "In the movies, your life would be passing in front of your eyes."
+	       "Geronimo.....">>
+
+<ROUTINE PRE-READ ()
+	 <COND (<NOT ,LIT> <TELL "It is impossible to read in the dark." CR>)
+	       (,PRSI 
+		<TELL "How does one look through a">
+		<VOWEL? ,PRSI>
+		<TELL D ,PRSI "?" CR>)>>
+
+<ROUTINE V-READ ()
+	 <COND (<AND <NOT <FSET? ,PRSO ,READBIT>>
+		     <NOT <EQUAL? ,PRSO ,WALLS>>>
+		<TELL "How can I read a">
+		<VOWEL? ,PRSO>
+		<TELL D ,PRSO "?" CR>)
+	       (<EQUAL? ,PRSO ,WALLS>
+		<TELL "There's nothing on the walls worth reading." CR>)
+	       (ELSE <TELL <GETP ,PRSO ,P?TEXT> CR>)>>
+
+<ROUTINE V-LOOK-UNDER ()
+	 <COND (<GETP ,HERE ,P?MAP>
+		<TELL "There is nothing but sand there." CR>)
+	       (ELSE
+		<TELL "There is nothing but dust there." CR>)>>
+
+<ROUTINE V-LOOK-DOWN () <TELL "You can't see anything down there." CR>>
+
+<ROUTINE V-LOOK-BEHIND () <TELL "There is nothing behind the " D ,PRSO "." CR>>
+
+<ROUTINE V-LOOK-INSIDE ("OPTIONAL" (REACH? <>))
+	 <COND (<FSET? ,PRSO ,DOORBIT>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <TELL "The "
+			     D
+			     ,PRSO
+			     " is open.">)
+		      (ELSE <TELL "The " D ,PRSO " is closed.">)>
+		<CRLF>)
+	       (<FSET? ,PRSO ,CONTBIT>
+		<COND (<FSET? ,PRSO ,VICBIT>
+		       <TELL "There is nothing special to be ">
+		       <COND (.REACH?
+			      <TELL "felt">)
+			     (T
+			      <TELL "seen">)>
+		       <TELL "." CR>)
+		      (<SEE-INSIDE? ,PRSO>
+		       <COND (<AND <FIRST? ,PRSO> <PRINT-CONT ,PRSO>>
+			      <RTRUE>)
+			     (<FSET? ,PRSO ,SURFACEBIT>
+			      <COND (<IN? ,WINNER ,PRSO>
+				     <TELL "You're on it!" CR>
+				     <RTRUE>)
+				    (T
+				     <TELL "There is nothing on the "
+					    D ,PRSO "." CR>
+				     <RTRUE>)>)
+			     (T
+			      <TELL "The " D ,PRSO " is empty." CR>
+			      <RTRUE>)>)
+		      (ELSE <TELL "The " D ,PRSO " is closed." CR>)>)
+	       (ELSE
+		<TELL "I don't know how to ">
+		<COND (<NOT .REACH?>
+		       <TELL "look inside a">)
+		      (ELSE <TELL "feel inside a">)>
+		<VOWEL? ,PRSO>
+		<TELL D ,PRSO "." CR>)>>
+
+<ROUTINE SEE-INSIDE? (OBJ)
+	 <AND <NOT <FSET? .OBJ ,INVISIBLE>>
+	       <FSET? .OBJ ,OPENBIT>>>
+
+<ROUTINE V-REPENT () <TELL "It could very well be too late!" CR>>
+
+<ROUTINE PRE-BURN ()
+	 <COND (<AND <EQUAL? ,PRSO ,TORCH>
+		     <EQUAL? ,PRSI ,ONE-MATCH ,MANY-MATCHES>
+		     <OR <IN? ,ONE-MATCH ,WINNER>
+			 <IN? ,MATCHES ,WINNER>>>
+		<COND (<NOT <FLAMING? ,PRSI>>
+		       <COND (<L? ,MATCH-COUNT 1>
+			      <TELL "You're out of matches. Sorry." CR>
+			      <RTRUE>)
+			     (ELSE
+			      <COND (<NOT <IN? ,ONE-MATCH ,WINNER>>
+				     <TELL "(lighting a match first)" CR>
+				     <MATCH-MOVER>)
+				    (T
+				     <TELL "(lighting the match first)" CR>)>
+			      <LIGHT-THE ,ONE-MATCH T>
+			      <ENABLE <QUEUE I-MATCH-OUT 3>>)>)>
+		<PERFORM ,V?LAMP-ON ,TORCH ,ONE-MATCH>
+		<RTRUE>)
+	       (<AND <EQUAL? ,PRSO ,TORCH>
+		     <IN? ,PRSI ,WINNER>
+		     <FLAMING? ,PRSI>> 
+		<PERFORM ,V?LAMP-ON ,PRSO ,PRSI>
+		<RTRUE>)
+	       (<AND <NOT <IN? ,PRSI ,WINNER>>
+		     <NOT <IN? ,PRSI ,HERE>>
+		     <NOT <EQUAL? <LOC <LOC ,PRSI>> ,HERE>>>
+		<TELL "I see no " D ,PRSI " here." CR>
+		<RTRUE>)
+	       (<FLAMING? ,PRSI> <RFALSE>)
+	       (<FSET? ,PRSI ,BURNBIT>
+		<TELL "You'd better light ">
+		<COND (<EQUAL? ,PRSI ,MANY-MATCHES>
+		       <TELL "a match">)
+		      (ELSE <TELL "the " D ,PRSI>)>
+		<TELL " first." CR>
+		<RTRUE>)
+	       (T <TELL "With a">
+		<VOWEL? ,PRSI>
+		<TELL D ,PRSI "??!?" CR>)>>
+
+<ROUTINE V-BURN ()
+	 <COND (<EQUAL? ,PRSO ,BOAT ,DECK>
+		<JIGS-UP ,BARGE-BURN-STR>
+		<RFATAL>)
+	       (<FSET? ,PRSO ,BURNBIT>
+		<COND (<IN? ,PRSO ,WINNER>
+		       <TELL "The " D ,PRSO " catches fire and is consumed.">
+		       <EMPTY-THE ,PRSO>
+		       <REMOVE ,PRSO>
+		       <SETG P-IT-LOC <>>
+		       <COND (<PRSO? ,ROPE>
+			      <SETG ROPE-TIED <>>
+			      <SETG ROPE-PLACED <>>)>)
+		      (<AND <PRSO? ,SHIM ,BEAM>
+			    <EQUAL? <LOC ,PRSO> ,HERE ,BELOW-MAST>
+			    <OR <EQUAL? ,HERE ,BARGE-CENTER ,FORE-CABIN
+					,AFT-CABIN>
+				<EQUAL? ,HERE ,BELOW-DECK ,BELOW-MAST>>>
+		       <TELL "The " D ,PRSO
+" catches fire, but before you have a chance to react, the fire spreads." CR>
+		       <JIGS-UP ,BARGE-BURN-STR>)
+		      (<PRSO? ,SHIM ,BEAM>
+		       <REMOVE ,PRSO>
+		       <SETG P-IT-LOC <>>
+		       <TELL "The " D ,PRSO
+" catches fire and is consumed." CR>
+		       <COND (<PRSO? ,BEAM>
+			      <COND (<AND ,ON-BEAM
+					  <EQUAL? ,HERE ,WEST-END-OF-PASSAGE>
+					  <NOT <IN? ,PLASTER ,HERE>>>
+				     <JIGS-UP ,AIR-WALK>)
+				    (,BEAM-PLACED
+				     <COND (<IN? ,WINNER ,ANNEX>
+					    <JIGS-UP ,ANNEX-BEAM-STR>
+					    <RFATAL>)
+					   (<IN? ,WINNER ,BURIAL-CHAMBER>
+					    <JIGS-UP ,BURIAL-BEAM-STR>)
+					   (<IN? ,WINNER ,NORTH-ANTECHAMBER>
+					    <DROP-THE-BLOCKS>
+					    <RTRUE>)
+					   (<IN? ,WINNER ,SOUTH-ANTECHAMBER>
+					    <CLOSE-THE-ANNEX>
+					    <RTRUE>)>)>)>
+		       <RTRUE>)
+		      (ELSE <TELL "You don't have the " D ,PRSO "." CR>)>)
+	       (<AND <EQUAL? ,PRSO ,OIL-JAR ,LIQUID>
+		     <FLAMING? ,PRSI>>
+		<PERFORM ,V?DIP-IN ,PRSI ,OIL-JAR>
+		<RTRUE>)
+	       (T <TELL "I don't think you can burn the " D ,PRSO "." CR>)>>
+
+<ROUTINE PRE-TURN ()
+	 <COND (<PRSO? ,NOT-HERE-OBJECT>
+		<RFALSE>)
+	       (<NOT <FSET? ,PRSO ,TURNBIT>>
+		<TELL "You can't turn that!" CR>)
+	       (<AND ,PRSI
+		     <EQUAL? ,PRSI ,INTDIR>>
+		<TELL "You can't turn things to a specific direction." CR>
+		<RTRUE>)>>
+
+<ROUTINE V-TURN () <TELL "This has no effect." CR>>
+
+<ROUTINE V-PUMP ()
+	 <TELL "I really don't see how." CR>>
+
+<ROUTINE V-INFLATE () <TELL "How can you inflate that?" CR>>
+
+<ROUTINE V-DEFLATE () <TELL "Come on, now!" CR>>
+
+<ROUTINE V-LOCK () <TELL "It doesn't seem to work." CR>>
+
+<ROUTINE V-PICK () <TELL "You can't pick that." CR>>
+
+<ROUTINE V-UNLOCK () <V-LOCK>>
+
+<ROUTINE V-CUT ()
+	 <COND (<NOT <FSET? ,PRSI ,WEAPONBIT>>
+		<COND (<EQUAL? ,PRSI ,HANDS>
+		       <TELL "Be serious. Karate chop it? Come on!" CR>)
+		      (ELSE
+		       <TELL
+			"I doubt that the \"cutting edge\" of a">
+		       <VOWEL? ,PRSI>
+		       <TELL D ,PRSI " is adequate." CR>)>)
+	       (T
+		<TELL "Strange concept, cutting the " D ,PRSO "...." CR>)>>
+
+<ROUTINE V-KILL ()
+	 <IKILL "kill">>
+
+<ROUTINE IKILL (STR)
+	 #DECL ((STR) ZSTRING)
+	 <COND (<NOT ,PRSO> <TELL "There is nothing here to " .STR "." CR>)
+	       (<AND <NOT <FSET? ,PRSO ,VILLAIN>>
+		     <NOT <FSET? ,PRSO ,VICBIT>>>
+		<TELL "I've known strange people, but fighting a">
+		<VOWEL? ,PRSO>
+		<TELL D ,PRSO "?" CR>)
+	       (<OR <NOT ,PRSI> <==? ,PRSI ,HANDS>>
+		<TELL "Trying to "
+		      .STR
+		      " a">
+		<VOWEL? ,PRSO>
+		<TELL D ,PRSO
+		      " with your bare hands is suicidal." CR>)
+	       (<NOT <IN? ,PRSI ,WINNER>>
+		<TELL "You aren't even holding the " D ,PRSI "." CR>)
+	       (<NOT <FSET? ,PRSI ,WEAPONBIT>>
+		<TELL "Trying to "
+		      .STR
+		      " the "
+		      D
+		      ,PRSO
+		      " with a">
+		<VOWEL? ,PRSI>
+		<TELL
+		      D
+		      ,PRSI
+		      " is suicidal." CR>)
+	       (ELSE <TELL "You can't." CR>)>>
+
+<ROUTINE V-ATTACK () <IKILL "attack">>
+
+<ROUTINE V-SWING ()
+	 <COND (<NOT <HELD? ,PRSO>>
+		<TELL "Who do you think you are, Benny Goodman?" CR>)
+	       (T
+		<TELL "Whoosh!" CR>)>>
+
+<ROUTINE V-KICK () <HACK-HACK "Kicking the ">>
+
+<ROUTINE V-WAVE () <HACK-HACK "Waving the ">>
+
+<ROUTINE V-RAISE () <HACK-HACK "Playing in this way with the ">>
+
+<ROUTINE V-LOWER () <HACK-HACK "Playing in this way with the ">>
+
+<ROUTINE V-RUB () <HACK-HACK "Fiddling with the ">>
+
+<ROUTINE V-PUSH () <HACK-HACK "Pushing the ">>
+
+<ROUTINE PRE-PUSH-TO ()
+	 <COND (<OR <IN? ,PRSO ,GLOBAL-OBJECTS>
+		    <IN? ,PRSO ,LOCAL-GLOBALS>>
+		<TELL "Nice try." CR>)
+	       (<PRSO? ,NOT-HERE-OBJECT>
+		<RFALSE>)
+	       (<PRSO? ,SARCOPH>
+		<TELL "Be serious. Any idea what that must weigh?" CR>
+		<RTRUE>)
+	       (<AND <NOT <IN? ,PRSO <LOC ,WINNER>>>
+		     <NOT <IN? ,PRSO ,WINNER>>
+		     <NOT <EQUAL? ,PRSO ,NOT-HERE-OBJECT>>>
+		<TELL "Huh? The " D ,PRSO "? Get serious." CR>)>>
+
+<GLOBAL PUSH-TBL
+	<TABLE A-PRIME P?NW P?SE
+	       B-PRIME P?NE P?SW
+	       D-PRIME P?SW P?NE
+	       E-PRIME P?SE P?NW>> 
+
+<ROUTINE V-PUSH-TO ("AUX" (OFFS -3) (FLG 0))
+	 <COND (<AND <NOT <EQUAL? ,PRSO ,HUGE-STATUE>>
+		     <FSET? ,PRSO ,TAKEBIT>>
+		<TELL 
+"There's no need for that. Why not just pick it up and then carry it there?" 
+			CR>
+		<RTRUE>)
+	       (<NOT <FSET? ,PRSO ,TAKEBIT>>
+		<TELL "You push and strain, but can't budge the " D ,PRSO "."
+		      CR>)
+	       (<NOT <EQUAL? ,PRSI ,INTDIR>>
+		<TELL "You can't push things to that." CR>
+		<RTRUE>)
+	       (<EQUAL? ,HERE ,LANDING-ZERO>
+		<COND (<AND <NOT <EQUAL? ,P-DIRECTION ,P?NE ,P?NW>>
+			    <NOT <EQUAL? ,P-DIRECTION ,P?SE ,P?SW>>>
+		       <SET FLG 1>)
+		      (ELSE
+		       <SET FLG 3>)>)>
+	 <COND (<EQUAL? .FLG 0>
+		<REPEAT ()
+			<SET OFFS <+ .OFFS 3>>
+			<COND (<G? .OFFS 9>
+			       <RETURN>)
+			      (<EQUAL? ,HERE <GET ,PUSH-TBL .OFFS>>
+			       <COND (<EQUAL? ,P-DIRECTION 
+					      <GET ,PUSH-TBL <+ .OFFS 1>>>
+				      <SET FLG 2>)
+				     (<NOT 
+				       <EQUAL? ,P-DIRECTION
+					       <GET ,PUSH-TBL <+ .OFFS 2>>>>
+				      <SET FLG 1>)
+				     (ELSE
+				      <SET FLG 3>)>)>>)>
+	 <COND (<EQUAL? .FLG 1>
+		<TELL "The statue bumps into a wall." CR>)
+	       (<EQUAL? .FLG 2>
+		<TELL "It won't fit through the door." CR>)
+	       (<EQUAL? .FLG 3>
+		<DO-WALK ,P-DIRECTION>
+		<MOVE ,HUGE-STATUE ,HERE>
+		<THIS-IS-IT ,HUGE-STATUE>
+		<TELL "The pushed statue rests on the floor." CR>)>>
+
+<ROUTINE PRE-MUNG ()
+	 <COND (<PRSO? ,NOT-HERE-OBJECT ,ME ,WINNER ,ADVENTURER>
+		<RFALSE>)
+	       (<EQUAL? ,PRSO ,N-ANTE-SEAL>
+		<COND (<BREAK-SEAL>
+		       <RTRUE>)
+		      (T
+		       <TELL
+"You scratch at the seals but accomplish little." CR>
+		       <RTRUE>)>)
+	       (<OR <PRSO? ,PLASTER ,PLASTER1 ,LOCK>
+		    <PRSO? ,HUGE-STATUE ,HEAD ,CRATE>
+		    <PRSO? ,BLACK-BOX ,BEAM>>
+	        <RFALSE>)
+	       (<NOT <FSET? ,PRSO ,VICBIT>>
+		<HACK-HACK "Trying to destroy the ">)
+	       (<NOT ,PRSI>
+		<TELL "Trying to destroy the " D ,PRSO 
+		      " with your bare hands is suicidal." CR>)
+	       (<NOT <FSET? ,PRSI ,WEAPONBIT>>
+		<TELL "Trying to destroy the " D ,PRSO " with a">
+		<VOWEL? ,PRSI>
+		<TELL D ,PRSI
+		      " is quite self-destructive." CR>)>>
+
+<ROUTINE V-MUNG () <TELL "Nothing much happens." CR>>
+
+<ROUTINE HACK-HACK
+	 (STR)
+	 #DECL ((STR) ZSTRING)
+	 <COND (<AND <IN? ,PRSO ,GLOBAL-OBJECTS> <VERB? WAVE RAISE LOWER>>
+		<TELL "The " D ,PRSO " isn't here!" CR>)
+	       (T <TELL .STR D ,PRSO <PICK-ONE ,HO-HUM> CR>)>>
+
+<GLOBAL HO-HUM
+	<LTABLE
+	 " doesn't seem to work."
+	 " isn't notably helpful."
+	 " doesn't work."
+	 " has no effect.">>
+
+<ROUTINE WORD-TYPE
+	 (OBJ WORD "AUX" SYNS)
+	 #DECL ((OBJ) OBJECT (WORD SYNS) TABLE)
+	 <ZMEMQ .WORD
+		<SET SYNS <GETPT .OBJ ,P?SYNONYM>>
+		<- </ <PTSIZE .SYNS> 2> 1>>>
+
+<ROUTINE V-KNOCK ()
+	 <TELL "Why knock on a">
+	 <VOWEL? ,PRSO>
+	 <TELL D ,PRSO "?" CR>>
+
+<ROUTINE V-CHOMP ()
+	 <TELL "I don't know how to do that. I win in all cases!" CR>>
+
+<ROUTINE V-FROBOZZ
+	 ()
+	 <TELL
+"The FROBOZZ Corporation created, owns, and operates this programmer." CR>>
+
+<ROUTINE V-WIN () <TELL "Naturally!" CR>>
+
+<ROUTINE V-YELL () <TELL "Aarrrrrgggggggghhhhhhhhhhh!" CR>>
+
+<ROUTINE V-PLUG () <TELL "This has no effect." CR>>
+
+<ROUTINE V-EXORCISE () <TELL "What a bizarre concept!" CR>>
+
+\
+
+<ROUTINE V-SHAKE ("AUX" X)
+	 <COND (<FSET? ,PRSO ,VILLAIN>
+		<TELL "This seems to have no effect." CR>)
+	       (<EQUAL? ,PRSO ,HANDS>
+		<TELL
+"Nice to meet me. Funny, you think I look like myself." CR>)
+	       (<NOT <FSET? ,PRSO ,TAKEBIT>>
+		<TELL "You can't take it; thus, you can't shake it!" CR>)
+	       (<AND <NOT <FSET? ,PRSO ,OPENBIT>>
+		     <FIRST? ,PRSO>>
+		<TELL "It sounds as if there is something inside the "
+		      D
+		      ,PRSO
+		      "."
+		      CR>)
+	       (<AND <EQUAL? ,PRSO ,LIQUID ,OIL-JAR>
+		     <IN? ,LIQUID ,OIL-JAR>>
+		<TELL "The liquid sloshes around." CR>)
+	       (<AND <FSET? ,PRSO ,OPENBIT> <FIRST? ,PRSO>>
+		<REPEAT ()
+			<COND (<SET X <FIRST? ,PRSO>> <MOVE .X ,HERE>)
+			      (ELSE <RETURN>)>>
+	        <TELL "All of the objects spill onto the ">
+		<SPILL-WHERE?>)
+	       (T <TELL "There's nothing in the " D ,PRSO "." CR>)>>
+
+<ROUTINE SPILL-WHERE? ()
+	 <COND (<IN? ,WINNER ,COT>
+		<TELL
+		 "ground by the cot.">)
+	       (<EQUAL? ,HERE ,RIVER-BANK>
+		<TELL
+		 "river bank.">)
+	       (<GETP ,HERE ,P?MAP>
+		<TELL 
+		 "sand.">)
+	       (<EQUAL? <GETP ,HERE ,P?ACTION> ,BURN-THE-BARGE>
+		<TELL 
+		 "wooden decking.">)
+	       (T
+		<TELL "stone floor.">)>
+	 <CRLF>>
+
+<ROUTINE PRE-DIG () 
+	 <COND (<PRSO? ,NOT-HERE-OBJECT>
+		<RFALSE>)
+	       (<NOT ,PRSI>
+		<COND (<IN? ,SHOVEL ,WINNER>
+		       <SETG PRSI ,SHOVEL>
+		       <TELL "(with the shovel)" CR>)
+		      (<IN? ,PICK-AXE ,WINNER>
+		       <SETG PRSI ,PICK-AXE>
+		       <TELL "(with the axe)" CR>)
+		      (T <SETG PRSI ,HANDS>
+		       <TELL "(with your hands)" CR>)>)>
+	 <COND (<FSET? ,PRSI ,TOOLBIT> <RFALSE>)
+	       (ELSE
+		<TELL "Digging with the " D ,PRSI " is very silly." CR>)>>
+
+<GLOBAL THIRST 0>
+
+<ROUTINE V-DIG ("AUX" COUNTER)
+	 <COND (<EQUAL? ,PRSO ,PLASTER1 ,PLASTER ,WALLS>
+		<PERFORM ,V?MUNG ,PRSO ,PRSI>
+		<RTRUE>)
+	       (<NOT <EQUAL? ,PRSO ,SAND ,GROUND ,HOLE>>
+		<TELL "You can't dig in that." CR>)
+	       (<EQUAL? ,HERE ,RIVER-BANK>
+		<TELL 
+"You dig a small hole, but it quickly fills in with water and sand, almost
+immediately disappearing." CR>)
+	       (<NOT <GETP ,HERE ,P?CAPACITY>>
+		<TELL "The ground is too hard here." CR>)
+	       (<PRSI? ,HANDS>
+		<TELL
+"I suppose you also excavate tunnels with a teaspoon?!" CR>)
+	       (<PRSI? ,PICK-AXE>
+	        <TELL
+"Let's face it, for digging in the sand, the axe is cute but ineffective." CR>)
+	       (T
+		<SET COUNTER <GETP ,HERE ,P?CAPACITY>>
+		<SET COUNTER <+ .COUNTER 1>>
+		<SETG THIRST <+ ,THIRST 4>>
+		<COND (<AND <G? .COUNTER 5>
+			    <NOT <EQUAL? ,HERE ,EX8>>>
+		       <JIGS-UP
+"The walls of the hole collapse around you, smothering you in the shifting
+sands.">
+		       <RFATAL>)
+		      (T
+		       <PUTP ,HERE ,P?CAPACITY .COUNTER>
+		       <COND (<AND <EQUAL? .COUNTER 6>
+				   <EQUAL? ,HERE ,EX8>>
+			      <TELL
+"You've uncovered what could only be the top of a pyramid. After clearing it
+away with your hands, you notice a square opening in the top of it." CR>
+			      <PUTP ,HERE ,P?CAPACITY 6>
+			      <PUTP ,HERE ,P?LDESC
+"You are in the desert, almost out of sight of the encampment to the west. At
+last, though, you've found the ancient pyramid. The top of the pyramid is
+clearly exposed and on one of its sides is a square opening.">
+			      <FCLEAR ,ROCK-LOCK ,INVISIBLE>
+			      <MOVE ,PYRAMID ,HERE>
+			      <SETG SCORE <+ ,SCORE 25>>)
+			     (T
+			      <TELL <GET ,DIGGER-LTBL .COUNTER> CR>)>)>)>>
+
+<GLOBAL DIGGER-LTBL
+	<LTABLE 
+"You've dug a small hole. As you stand there and watch it, the sand starts to
+fill it in a little."
+"You've enlarged the hole a little, taking out two shovelsfull for every one
+that collapses back in from the walls."
+"You've made the hole quite sizable, though it's not very deep. The deeper you
+dig, the more the walls collapse and so you widen the base of the hole."
+"You're knee-deep in the hole, digging away, taking out more and more sand. You
+silently curse those workers for having deserted you."
+"You've dug yourself into a deep hole. You're actually several feet below the
+surrounding sand. The walls look very unstable.">>
+
+<ROUTINE V-SMELL ()
+	 <COND (<EQUAL? ,PRSO ,LIQUID>
+		<TELL 
+"It smells like a mixture of gasoline and embalming fluid. Yum Yum." CR>)
+	       (<FLAMING? ,PRSO>
+		<TELL "Nice way to singe your nostrils!" CR>)
+	       (<PRSO? ,SKELETON>
+		<TELL "It smells quite dead." CR>)
+	       (<PRSO? ,MAP>
+		<TELL "It smells a little musty." CR>)
+	       (T <TELL "It smells just like a">
+		<VOWEL? ,PRSO>
+		<TELL D ,PRSO "." CR>)>>
+
+<ROUTINE GLOBAL-IN? (OBJ1 OBJ2 "AUX" T)
+	 #DECL ((OBJ1 OBJ2) OBJECT (T) <OR FALSE TABLE>)
+	 <COND (<SET T <GETPT .OBJ2 ,P?GLOBAL>>
+		<ZMEMQB .OBJ1 .T <- <PTSIZE .T> 1>>)>>
+
+<ROUTINE V-SWIM ()
+	 <COND (<EQUAL? ,HERE ,RIVER-BANK>
+		<JIGS-UP .CROC-STR>
+		<RFATAL>)
+	       (<NOT <EQUAL? ,PRSO ,NILE-RIBBAH>>
+		<TELL "Now that's a cute idea. Maybe I'll try it next century."
+		      CR>)
+	       (T <TELL "Go jump in a lake!" CR>)>>
+
+<ROUTINE V-UNTIE () <TELL "This cannot be tied, so it cannot be untied!" CR>>
+
+<ROUTINE PRE-TIE ()
+	 <COND (<==? ,PRSI ,WINNER>
+		<TELL "You can't tie it to yourself." CR>)>>
+
+<ROUTINE V-TIE ()
+	 <COND (<EQUAL? ,PRSI ,SCARAB>
+		<TELL "The rope's too clumsy to tie to that." CR>)
+	       (<NOT <EQUAL? ,PRSI ,BEAM>>
+		<TELL "You can't tie the " D ,PRSO " to that." CR>)
+	       (ELSE
+		<TELL "Don't bother." CR>)>>
+
+<ROUTINE V-TIE-UP () <TELL "You could certainly never tie it with that!" CR>>
+
+<ROUTINE V-MELT () <TELL "I'm not sure that a">
+	 <VOWEL? ,PRSO>
+	 <TELL D ,PRSO " can be melted." CR>>
+
+<ROUTINE V-MUMBLE
+	 ()
+	 <TELL "You'll have to speak up if you expect me to hear you!" CR>>
+
+<ROUTINE V-ALARM ()
+	 <COND (<FSET? ,PRSO ,VILLAIN>
+		<TELL "He's wide awake, or haven't you noticed..." CR>)
+	       (ELSE
+		<TELL "The " D ,PRSO " isn't sleeping." CR>)>>
+
+<ROUTINE V-ZORK () <TELL "Who?" CR>>
+
+\
+
+<ROUTINE MUNG-ROOM (RM STR)
+	 #DECL ((STR) ZSTRING)
+	 <FSET .RM ,RMUNGBIT>
+	 <PUTP .RM ,P?LDESC .STR>>
+
+<ROUTINE V-COMMAND ()
+	 <COND (<FSET? ,PRSO ,VICBIT>
+		<TELL "The " D ,PRSO " pays no attention." CR>)
+	       (ELSE
+		<TELL "You cannot talk to that!" CR>)>>
+
+<ROUTINE V-CLIMB-ON ()
+	 <COND (<EQUAL? ,PRSO ,ALTAR>
+		<PERFORM ,V?BOARD ,ALTAR>
+		<RTRUE>)
+	       (<OR <FSET? ,PRSO ,VEHBIT>
+		    <PRSO? ,BEAM>>
+		<V-CLIMB-UP ,P?UP T>)
+	       (<EQUAL? ,PRSO ,ROPE>
+		<PERFORM ,V?TAKE ,ROPE>
+		<RTRUE>)
+	       (T
+		<TELL "You can't climb onto the " D ,PRSO "." CR>)>>
+
+<ROUTINE V-CLIMB-FOO ()
+	 <COND (<AND <OR <EQUAL? ,PRSO ,ROPE>
+			 <EQUAL? ,PRSI ,ROPE>>
+		     <IN? ,ROPE ,WINNER>>
+		<TELL "You can't do that while you're holding the rope." CR>
+		<RFATAL>)
+	       (<EQUAL? ,PRSO ,ALTAR>
+		<PERFORM ,V?BOARD ,PRSO>
+		<RTRUE>)
+	       (<EQUAL? ,PRSO ,INTDIR>
+		<TELL "You can't climb a direction!" CR>
+		<RFATAL>)
+	       (<AND <NOT <FSET? ,PRSO ,CLIMBBIT>>
+		     <NOT <FSET? ,PRSO ,VEHBIT>>>
+		<TELL "You can't climb that!" CR>
+		<RFATAL>)
+	       (T
+		<V-CLIMB-UP <COND (<EQUAL? ,HERE ,CHAMBER-OF-RA> ,P?DOWN)
+				  (<EQUAL? ,PRSO ,PLANK> ,P?NORTH)
+				  (T ,P?UP)> T>)>>
+
+<ROUTINE V-CLIMB-UP ("OPTIONAL" (DIR ,P?UP) (OBJ <>) "AUX" X)
+	 <COND (<AND .OBJ
+		     <ZMEMQ ,W?BEAM
+			    <SET X <GETPT ,PRSO ,P?SYNONYM>> <PTSIZE .X>>
+		     >
+		<COND (<AND ,ON-BEAM
+			    <IN? ,BEAM ,WEST-END-OF-PASSAGE>>
+		       <TELL "You're already on the beam." CR>)
+		      (<IN? ,BEAM ,WEST-END-OF-PASSAGE>
+		       <TELL "You are now standing on the beam." CR>)
+		      (<AND <FSET? ,BEAM ,TOUCHBIT>
+			    <IN? ,BEAM ,HERE>
+			    <NOT ,BEAM-PLACED>>
+		       <TELL
+"You step onto it, see no sense in remaining on it, then step off it." CR>
+		       <RTRUE>)
+		      (T <TELL "Get real. You don't have fly feet." CR>
+		       <RTRUE>)>
+		<SETG ON-BEAM T>)
+	       (<GETPT ,HERE .DIR>
+		<DO-WALK .DIR>
+		<RTRUE>)
+	       (<NOT .OBJ>
+		<TELL "You can't go that way." CR>)
+	       (<AND .OBJ
+		     <ZMEMQ ,W?WALLS
+			    <SET X <GETPT ,PRSO ,P?SYNONYM>> <PTSIZE .X>>>
+		<TELL "Climbing the walls is to no avail." CR>)
+	       
+	       (ELSE <TELL "Bizarre!" CR>)>>
+
+<ROUTINE V-CLIMB-DOWN ()
+	 <COND (<AND <EQUAL? ,PRSO ,ROPE ,P?NORTH ,P?DOWN>
+		     <NOT ,LANDING>>
+		<TELL "It would help if the rope led someplace." CR>
+		<RTRUE>)
+	       (ELSE <V-CLIMB-UP ,P?DOWN>)>>
+
+<ROUTINE V-SEND ()
+	 <COND (<FSET? ,PRSO ,VILLAIN>
+		<TELL "Why would you send for the " D ,PRSO "?" CR>)
+	       (ELSE <TELL "That doesn't make sends." CR>)>>
+
+<ROUTINE V-WIND ()
+	 <TELL "You cannot wind up a">
+	 <VOWEL? ,PRSO>
+	 <TELL D ,PRSO "." CR>>
+
+<ROUTINE V-COUNT ("AUX" OBJS CNT)
+	 <COND (<==? ,PRSO ,STONES>
+		<TELL 
+"There are a lot of stones in the pyramid (about 90,000,000 cubic feet)." CR>)
+	       (<OR <EQUAL? ,PRSO ,DRACULA ,BLESSINGS ,FINGER>
+		    <EQUAL? ,PRSO ,BASIE>>
+		<TELL "What a maroon! What a cahd!" CR>)
+	       (T
+		<TELL "You have ">
+		<COND (<==? ,PRSO ,MATCHES ,MANY-MATCHES>
+		       <SET CNT <-  ,MATCH-COUNT 1>>
+		       <TELL N .CNT " match">
+		       <COND (<NOT <1? .CNT>> <TELL "es.">) (ELSE <TELL ".">)>
+		       <CRLF>)
+		      (ELSE <TELL "a weird sense of counting!" CR>)>)>>
+
+<ROUTINE V-PUT-UNDER ()
+         <TELL "You can't do that." CR>>
+
+<ROUTINE V-PLAY ()
+         <COND (<FSET? ,PRSO ,VILLAIN>
+	        <TELL
+"You are so engrossed in the role of the " D ,PRSO " that
+you kill yourself, just as he would have done!" CR>
+	        <JIGS-UP "">)
+	       (T <TELL "How peculiar!" CR>)>>
+
+<ROUTINE V-MAKE ()
+    	<TELL "You can't do that." CR>>
+
+<ROUTINE V-ENTER ()
+	 <DO-WALK ,P?IN>>
+
+<ROUTINE V-EXIT ()
+	 <DO-WALK ,P?OUT>>
+
+<ROUTINE V-CROSS ()
+	 <TELL "You can't cross that!" CR>>
+
+<ROUTINE V-SEARCH ()
+	 <TELL "You find nothing unusual." CR>>
+
+<ROUTINE V-FIND ("AUX" (L <LOC ,PRSO>))
+	 <COND (<EQUAL? ,PRSO ,HANDS>
+		<TELL
+"Within six feet of your head, assuming you haven't left that somewhere." CR>)
+	       (<EQUAL? .L ,GLOBAL-OBJECTS>
+		<TELL "Why don't you try finding it yourself?" CR>)
+	       (<IN? ,PRSO ,WINNER>
+		<TELL "You have it." CR>)
+	       (<IN? ,PRSO ,ENDLESS-DESERT>
+		<TELL "With all this sand around here? Give me a break!" CR>)
+	       (<OR <IN? ,PRSO ,HERE>
+		    <==? ,PRSO ,PSEUDO-OBJECT>>
+		<TELL "It's right here." CR>)
+	       (<FSET? .L ,VILLAIN>
+		<TELL "The " D .L " has it." CR>)
+	       (<FSET? .L ,CONTBIT>
+		<TELL "It's ">
+		<COND (<FSET? .L ,SURFACEBIT>
+		       <TELL "on">)
+		      (T <TELL "in">)>
+		<TELL " the " D .L "." CR>)
+	       (ELSE
+		<TELL "Beats me." CR>)>>
+
+<ROUTINE V-TELL ()
+	 <COND (<FSET? ,PRSO ,VICBIT>
+		<SETG WINNER ,PRSO>
+		<SETG HERE <LOC ,WINNER>>)
+	       (<EQUAL? ,PRSO ,ME ,WINNER>
+		<TELL "Talking to yourself is diverting, but unnecessary." CR>
+		<RFATAL>)
+	       (T
+		<TELL "You can't talk to the " D ,PRSO "!" CR>
+		<SETG QUOTE-FLAG <>>
+		<SETG P-CONT <>>
+		<RFATAL>)>>
+
+<ROUTINE V-ANSWER ()
+	 <TELL "Nobody seems to be awaiting your answer." CR>
+	 <SETG P-CONT <>>
+	 <SETG QUOTE-FLAG <>>
+	 <RTRUE>>
+
+<ROUTINE V-REPLY ()
+	 <TELL "It is hardly likely that the " D ,PRSO " is interested." CR>
+	 <SETG P-CONT <>>
+	 <SETG QUOTE-FLAG <>>
+	 <RTRUE>>
+
+<ROUTINE V-IS-IN ()
+	 <COND (<IN? ,PRSO ,PRSI>
+		<TELL "Yes, it is ">
+		<COND (<FSET? ,PRSI ,SURFACEBIT>
+		       <TELL "on">)
+		      (T <TELL "in">)>
+		<TELL " the " D ,PRSI "." CR>)
+	       (T <TELL "No, it isn't." CR>)>>
+
+<ROUTINE V-KISS ()
+	 <TELL "I'd sooner kiss a pig." CR>>
+
+<ROUTINE V-RAPE ()
+	 <TELL "An ugly idea from an ugly human." CR>>
+
+<ROUTINE FIND-IN (WHERE WHAT "AUX" W)
+	 <SET W <FIRST? .WHERE>>
+	 <COND (<NOT .W> <RFALSE>)>
+	 <REPEAT ()
+		 <COND (<FSET? .W .WHAT> <RETURN .W>)
+		       (<NOT <SET W <NEXT? .W>>> <RETURN <>>)>>>
+
+<ROUTINE V-SAY ("AUX" V)
+	 <COND (<SET V <FIND-IN ,HERE ,VICBIT>>
+		<TELL "You must address the " D .V " directly." CR>)
+	       (<==? <GET ,P-LEXV ,P-CONT> ,W?HELLO>
+		<SETG QUOTE-FLAG <>>
+		<RTRUE>)
+	       (ELSE
+		<SETG QUOTE-FLAG <>>
+		<SETG P-CONT <>>
+		<TELL
+"Talking to yourself is said to be a sign of impending mental collapse." CR>)>>
+
+<ROUTINE V-INCANT ()
+	 <TELL
+"The incantation echoes back faintly, but nothing else happens." CR>
+	 <SETG QUOTE-FLAG <>>
+	 <SETG P-CONT <>>
+	 <RTRUE>>
+
+<ROUTINE V-SPIN ()
+	 <TELL "You can't spin that!" CR>>
+
+<ROUTINE V-THROUGH ("AUX" M)
+	<COND (<FSET? ,PRSO ,DOORBIT>
+	       <DO-WALK <OTHER-SIDE ,PRSO>>
+	       <RTRUE>)
+	      (<FSET? ,PRSO ,VEHBIT>
+	       <PERFORM ,V?BOARD ,PRSO>
+	       <RTRUE>)
+	      (<NOT <FSET? ,PRSO ,TAKEBIT>>
+	       <TELL "You hit your head against the "
+			    D ,PRSO
+			    " as you attempt this feat." CR>)
+	      (<IN? ,PRSO ,WINNER>
+	       <TELL "That would involve quite a contortion!" CR>)
+	      (ELSE <TELL <PICK-ONE ,YUKS> CR>)>>
+
+
+<GLOBAL YUKS
+	<LTABLE "Not within this life cycle."
+		"With this kind of wisdom, be glad you're not in a Sphinx."
+		"A totally bizarre concept. For sure."
+		"Totally different head, man. Like, untubular."
+		"Kookie, man."
+		"I've heard better ideas from politicians."
+		"A truly amazing concept, that."
+		"Bizarre barely describes that desire."
+		"Let's face it -- that isn't going to happen.">>
+
+<ROUTINE V-WEAR ()
+	 <COND (<NOT <FSET? ,PRSO ,WEARBIT>>
+		<TELL "You can't wear the " D ,PRSO "." CR>)
+	       (T <PERFORM ,V?TAKE ,PRSO> <RTRUE>)>>
+
+<ROUTINE V-THROW-OFF ()
+	 <COND (<NOT <EQUAL? ,PRSI ,BOAT ,ALTAR ,DECK>>
+		<TELL "You can't throw anything off of that!" CR>)
+	       (<PRSI? ,BOAT ,DECK>
+		<COND (<NOT <EQUAL? ,HERE ,BARGE-CENTER>>
+		       <TELL "From where you are now? Get serious." CR>
+		       <RTRUE>)
+		      (T <TELL
+"Thrown. You hear it land in the darkness to the south." CR> 
+		       <MOVE ,PRSO ,BARGE-ENTRANCE>
+		       <FSET ,PRSO ,TOUCHBIT>
+		       <FCLEAR ,PRSO ,NDESCBIT>
+		       <RTRUE>)>)
+	       (<PRSI? ,ALTAR>
+		<COND (<NOT <IN? ,WINNER ,ALTAR>>
+		       <TELL
+"Don't you think you should be standing on the altar first?" CR>)
+		      (T
+		       <PERFORM ,V?THROW ,PRSO>
+		       <RTRUE>)>)>>
+		       
+<ROUTINE V-$VERIFY ()
+	 <TELL "Verifying game..." CR>
+	 <COND (<VERIFY> <TELL "Game correct. Don't panic yet." CR>)
+	       (T <TELL CR "** Game File Failure ** (Panic)" CR>)>>
+
+<ROUTINE V-STAND ()
+	 <COND (<FSET? <LOC ,WINNER> ,VEHBIT>
+		<PERFORM ,V?DISEMBARK <LOC ,WINNER>>
+		<RTRUE>)
+	       (ELSE
+		<TELL "You are already standing, I think." CR>)>>
+
+<ROUTINE V-PUT-BEHIND ()
+	 <TELL "That hiding place is too obvious." CR>>
+
+<ROUTINE DO-WALK (DIR)
+	 <SETG P-WALK-DIR .DIR>
+	 <PERFORM ,V?WALK .DIR>>
+
+<ROUTINE V-WALK-TO ()
+	 <COND (<AND <EQUAL? ,PRSO ,PLANK>
+		     <IN? ,PRSO ,HERE>>
+		<TELL "Yo ho." CR>
+		<COND (<EQUAL? ,HERE ,BARGE-ENTRANCE>
+		       <DO-WALK ,P?UP>
+		       <RTRUE>)
+		      (T <DO-WALK ,P?DOWN>)>
+		<RTRUE>)
+	       (<OR <IN? ,PRSO ,HERE>
+		    <GLOBAL-IN? ,PRSO ,HERE>>
+		<TELL "It's here!" CR>)
+	       (T <TELL "You should supply a direction!" CR>)>>
+
+;"Finds the room on the other side of a door"
+
+<ROUTINE OTHER-SIDE (DOBJ "AUX" (P 0) T)
+	 <REPEAT ()
+		 <COND (<L? <SET P <NEXTP ,HERE .P>> ,LOW-DIRECTION>
+			<RETURN <>>)
+		       (ELSE
+			<SET T <GETPT ,HERE .P>>
+			<COND (<AND <EQUAL? <PTSIZE .T> ,DEXIT>
+				    <EQUAL? <GETB .T ,DEXITOBJ> .DOBJ>>
+			       <RETURN .P>)>)>>>
+
+<ROUTINE V-DRINK-FROM ("AUX" OBJ)
+	 <COND (<NOT ,PRSI>
+		<COND (<EQUAL? ,PRSO ,NILE-RIBBAH>
+		       <SET OBJ ,GLOBAL-WATER>)
+		      (<EQUAL? ,PRSO ,CANTEEN>
+		       <SET OBJ ,WATER>)
+		      (<EQUAL? ,PRSO ,OIL-JAR>
+		       <SET OBJ ,LIQUID>)
+		      (T
+		       <COND (<NOT <FSET? ,PRSO ,CONTBIT>>
+			      <TELL "How peculiar!" CR>
+			      <RTRUE>)
+			     (<NOT <FIRST? ,PRSO>>
+			      <TELL "There's nothing to drink in the " D ,PRSO
+				    "." CR>
+			      <RTRUE>)
+			     (T
+			      <SET OBJ <FIRST? ,PRSO>>
+			      <COND (<NOT <FSET? .OBJ ,DRINKBIT>>
+				     <TELL
+"I don't think there's anything worth drinking in the " D ,PRSO "." CR>
+				     <RTRUE>)>)>)>
+		<PERFORM ,V?DRINK .OBJ>
+		<RTRUE>)
+	       (<AND <EQUAL? ,PRSO ,GLOBAL-WATER ,WATER>
+		     <EQUAL? ,PRSI ,NILE-RIBBAH>>
+		<COND (<NOT <EQUAL? ,HERE ,RIVER-BANK>>
+		       <TELL "I see no " D ,PRSO " here." CR>
+		       <RTRUE>)
+		      (ELSE
+		       <PERFORM ,V?DRINK ,PRSO>
+		       <RTRUE>)>)
+	       (<NOT <FSET? ,PRSI ,OPENBIT>>
+		<TELL "Better open the " D ,PRSI " first." CR>)
+	       (<NOT <IN? ,PRSO ,PRSI>>
+		<TELL "I can't see any " D ,PRSO " in the " D ,PRSI "." CR>)
+	       (T
+		<PERFORM ,V?DRINK ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-LEAN-ON ()
+	 <TELL "Are you so very tired, then?" CR>>
+
+<ROUTINE V-DIP-IN ()
+	 <COND (<AND <EQUAL? ,PRSI ,GLOBAL-WATER ,NILE-RIBBAH>
+		     <EQUAL? ,PRSO ,CANTEEN>>
+		<PERFORM ,V?FILL ,PRSO ,GLOBAL-WATER>
+		<RTRUE>)
+	       (<NOT <EQUAL? ,PRSI ,OIL-JAR ,LIQUID>>
+		<TELL "You can't dip the " D ,PRSO " in that!" CR>)
+	       (<OR <FLAMING? ,PRSO>
+		    <FLAMING? ,PRSI>>
+		<JIGS-UP
+"Poof. There's no need to get burned up about it though...">)
+	       (<NOT <EQUAL? ,PRSO ,TORCH>>
+		<TELL "Huh? Dip the " D ,PRSO "!?" CR>
+		<RTRUE>)
+	       (T
+		<PERFORM ,V?POUR-ON ,OIL-JAR ,TORCH>
+		<RTRUE>)>>
+
+<ROUTINE V-PUT-AGAINST ()
+	 <TELL "You can't do that." CR>>
+
+<ROUTINE BREAK-SEAL ()
+	 <COND (<AND <NOT <EQUAL? ,PRSI ,PICK-AXE>>
+		     <NOT <IN? ,WINNER ,PICK-AXE>>>
+		<RFALSE>)>
+	 <COND (<EQUAL? ,BEAM-PLACED 4>
+		 <TELL
+"You manage to destroy the seal. You glance to the right and see fine sand
+running from a crack in the stone. The beam creaks and groans under tremendous
+pressure as the 3 ton stone block above your head starts to lower.  The beam
+holds the weight, saving you from a flattening fate."CR>
+                <SETG ANTE-SEAL <>>
+		<THIS-IS-IT ,NORTH-ANTE-DOOR>
+		<RTRUE>)
+	       (<OR <NOT <IN? ,BEAM ,NORTH-ANTECHAMBER>>
+		    <NOT ,BEAM-PLACED>>
+		<JIGS-UP 
+"You manage to destroy the seal, but as you stand in the doorway, you hear the
+distinct sound of grinding stone. You glance to your right and see fine sand
+running from a crack in the wall. You're totally unaware of the 3 tons of
+carved stone block falling onto your head from directly above.">)>>
+
+<ROUTINE V-TASTE ()
+	 <TELL "It tastes just like a">
+	 <VOWEL? ,PRSO>
+	 <TELL D ,PRSO "!" CR>>
+
+<ROUTINE V-ROLL ()
+	 <COND (<NOT <EQUAL? ,PRSO ,HUGE-STATUE>>
+		<TELL "Why bother?" CR>)
+	       (T
+		<TELL "The statue bumps into a wall." CR>)>>
+	       
+<ROUTINE V-PUSH-THROUGH ()
+	 <TELL
+"Pushing the " D ,PRSO " in that way isn't particularly helpful." CR>>
+
+<ROUTINE HOW? (OBJ)
+	 <TELL "I don't know how to do that to a">
+	 <VOWEL? .OBJ>
+	 <TELL D .OBJ "." CR>>
+
+<ROUTINE VOWEL? (OBJ)
+	 <COND (<FSET? .OBJ ,VOWELBIT>
+		<TELL "n">)>
+	 <TELL " ">>
+
+<ROUTINE HUH? ("OPTIONAL" (RARG <>))
+	 <COND (<VERB? OPEN CLOSE>
+		<HOW? ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-SMOKE ()
+	 <TELL "Smoking is bad for your health." CR>>
+
+<ROUTINE V-UNFOLD ()
+	 <COND (<NOT <EQUAL? ,PRSO ,MAP>>
+		<HOW? ,PRSO>)
+	       (T
+		<PERFORM ,V?OPEN ,MAP>
+		<RTRUE>)>>
+
+<ROUTINE V-FOLD ()
+	 <COND (<NOT <EQUAL? ,PRSO ,MAP>>
+		<HOW? ,PRSO>)
+	       (<NOT <FSET? ,PRSO ,OPENBIT>>
+		<TELL "It's already folded up." CR>
+		<RTRUE>)
+	       (T
+		<TELL "Okay. The map has been folded." CR>
+		<FCLEAR ,MAP ,OPENBIT>
+		<RTRUE>)>>
+
+<GLOBAL CROC-STR
+"You manage to wade a few feet into the river, but this makes the crocodiles
+spring into action -- they advance far more quickly than you thought possible.
+You panic and turn to the bank, attempting to flee. Your splashing about makes
+the beasts double their efforts and reach you just as you are about to step on
+shore. The last thought you have is a slight amazement at how many teeth a
+crocodile has and just how sharp they are.">
+
+<ROUTINE V-HOLE-DIG ()
+	 <COND (<NOT <EQUAL? ,PRSO ,HOLE>>
+		<TELL "I don't know how to dig a">
+		<VOWEL? ,PRSO>
+		<TELL D ,PRSO "." CR>)
+	       (<EQUAL? ,PRSI ,SAND>
+		<PERFORM ,V?DIG ,SAND>
+		<RTRUE>)
+	       (ELSE
+		<TELL "I can't dig in the " D ,PRSI "." CR>
+		<RTRUE>)>>
+
+<ROUTINE V-DIG-WITH ()
+	 <PERFORM ,V?DIG ,SAND ,PRSO>
+	 <RTRUE>>
+
+<ROUTINE V-TURN-OVER ()
+	 <COND (<IN? ,PRSO ,WINNER>
+		<TELL "Okay. There's nothing of interest there." CR>)
+	       (<FSET? ,PRSO ,TAKEBIT>
+		<TELL "You'd better pick it up first." CR>)
+	       (ELSE
+		<TELL "Good luck!" CR>)>>
+		
+<ROUTINE V-READ-INSIDE ()
+	 <TELL "There's nothing to read there." CR>>
+
+<ROUTINE PRE-REACH-IN ()
+	 <COND (<PRSO? ,NOT-HERE-OBJECT>
+		<RFALSE>)
+	       (<NOT <FSET? ,PRSO ,CONTBIT>>
+		<TELL "You can't reach into that." CR>
+		<RTRUE>)>
+	 <COND (<NOT <FSET? ,PRSO ,OPENBIT>>
+		<TELL "The " D ,PRSO " is closed." CR>)>>
+
+<ROUTINE V-REACH-IN ()
+	 <PERFORM ,V?LOOK-INSIDE ,PRSO>>
+
+<ROUTINE V-CLEAN ()
+	 <TELL
+"Cleanliness may be next to godliness, but there are limits." CR>>
+
+<ROUTINE PRE-PULL-UP ()
+	 <COND (<NOT <EQUAL? ,PRSO ,BEAM>>
+		<PERFORM ,V?MOVE ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-PULL-UP ()
+	 <COND (<FSET? ,BEAM ,TOUCHBIT>
+		<TELL "Why bother?" CR>)
+	       (<NOT <EQUAL? ,HERE ,BARGE-CENTER>>
+		<TELL "That's a little tough to do from here." CR>)
+	       (ELSE
+		<PERFORM ,V?PUSH-THROUGH ,BEAM ,MAST-HOLE>)>>
+
+<ROUTINE V-THROW-DOWN ("AUX" FOO)
+	 <COND (<STAIRWAY-CHECK?>
+		<RTRUE>)
+	       (<NOT <EQUAL? ,PRSO ,ROPE>>
+		<PERFORM ,V?DROP ,PRSO>
+		<RTRUE>)
+	       (<AND <EQUAL? ,PRSI ,INTDIR>
+		     <EQUAL? ,P-DIRECTION ,P?NORTH>>
+		<SET FOO ,NORTH-STAIRS>)
+	       (<AND <EQUAL? ,PRSI ,INTDIR>
+		     <EQUAL? ,P-DIRECTION ,P?SOUTH>>
+		<SET FOO ,SOUTH-STAIRS>)
+	       (<AND <EQUAL? ,PRSI ,INTDIR>
+		     <EQUAL? ,P-DIRECTION ,P?EAST>>
+		<SET FOO ,EAST-STAIRS>)
+	       (<AND <EQUAL? ,PRSI ,INTDIR>
+		     <EQUAL? ,P-DIRECTION ,P?WEST>>
+		<SET FOO ,WEST-STAIRS>)
+	       (ELSE
+		<SET FOO ,GROUND>)>
+	 <PERFORM ,V?PUT ,PRSO .FOO>
+	 <RTRUE>>
+
+<ROUTINE V-TIME ()
+	 <TELL "Tickity tockity, sprickity sprockety." CR>>
+
+<ROUTINE PRE-COMPARE ("AUX" (FLG <>))
+	 <COND (<PRSO? ,NOT-HERE-OBJECT>
+		<RFALSE>)
+	       (<NOT <GETP ,PRSO ,P?MAP>>
+		<SET FLG T>)
+	       (<NOT <EQUAL? <GETP ,PRSO ,P?MAP>
+			     <GETP ,PRSI ,P?MAP>>>
+		<SET FLG T>)>
+	 <COND (.FLG
+		<TELL "Comparisons between the " D ,PRSO " and the " D ,PRSI
+		      " would not really help." CR>
+		<RTRUE>)
+	       (ELSE
+		<RFALSE>)>>
+
+<ROUTINE V-COMPARE ()
+	 <COND (<PRSO? ,ROCK-LOCK ,STONE-KEY>
+		<TELL 
+"It looks as if the small cube would fit into the opening almost exactly." CR>)
+	       (<EQUAL? <GETP ,PRSO ,P?MAP> 1> ;"CUPS"
+		<TELL
+"The two chalices are of exactly the same size and dimensions, though empty
+they have different weights." CR>)
+	       (<AND <EQUAL? <GETP ,PRSO ,P?MAP> 3 4> ;"Book & L AREA"
+		     <EQUAL? <GETP ,PRSO ,P?MAP> <GETP ,PRSI ,P?MAP>>>
+		<TELL "Looks as if the area is just big enough to hold it." CR>)
+	       (<AND <EQUAL? <GETP ,PRSO ,P?MAP> 3 4> ;"Book & L AREA"
+		     <NOT <EQUAL? <GETP ,PRSO ,P?MAP> <GETP ,PRSI ,P?MAP>>>>
+		<TELL "Well, the match up between them wasn't made in heaven."
+		      CR>)
+	       (T
+		<TELL "The " D ,PRSO " and the " D ,PRSI " are the same size."
+		      CR>)>>
+
+<ROUTINE V-FOO-COMPARE ()
+	 <COND (<L? <GET ,P-PRSO 0> 2>
+		<TELL "You have to compare the " D ,PRSO " to something else."
+		      CR>
+		<RTRUE>)
+	       (T
+	        <PERFORM ,V?COMPARE <GET ,P-PRSO 1> <GET ,P-PRSO 2>>
+		<RFATAL>)>>
+
+<ROUTINE V-WEIGH ()
+	 <COND (<FSET? ,PRSO ,TAKEBIT>
+		<TELL "Tough to do without a scale." CR>)
+	       (T
+		<TELL "Now that's bizarre!" CR>)>>
+
+<ROUTINE V-FILL-OUT ()
+	 <COND (<NOT <EQUAL? ,PRSO ,MANUAL>>
+		<TELL "There's no need for filling that out." CR>)
+	       (T
+		<TELL
+"Okay. Find me a pen or a pencil and I'll do the best I can." CR>)>>
+		     
+<ROUTINE V-PLASTER-REMOVE ()
+	 <COND (<AND <EQUAL? ,PRSO ,PLASTER1 ,PLASTER ,N-ANTE-SEAL>
+		     <OR <EQUAL? ,PRSI ,DOORWAY ,ANNEX-DOOR ,WALLS>
+			 <PRSI? ,NORTH-ANTE-DOOR ,INNER-DOOR>>>
+		<PERFORM ,V?TAKE ,PRSO>
+		<RTRUE>)
+	       (ELSE
+		<PERFORM ,V?CLEAN ,PRSO>)>>
+
+<ROUTINE V-CHASTISE ()
+	 <TELL 
+"Please be more specific. LOOKing AT, BEHIND, UNDER, THROUGH, INSIDE, ON, DOWN,
+FOR, or any other method of LOOKing mean different things to me. Please
+specify which preposition you'd like to use next time, like LOOK AT THE " D ,PRSO ", or LOOK INSIDE THE " D ,PRSO "." CR>>
+
+<ROUTINE V-LOOK-UP ()
+	 <COND (<AND <L? ,MOVES 8>
+		     <NOT <IN-A-TENT?>>>
+		<TELL "You see a pretty plane. Oh boy!" CR>)
+	       (<EQUAL? <LOC ,WINNER> ,COT>
+		<MOVE ,WINNER ,HERE>
+		<PERFORM ,V?LOOK-UP>
+		<MOVE ,WINNER ,COT>
+		<RTRUE>)
+	       (<IN-A-TENT?>
+		<TELL "You see canvas. What else?" CR>)
+	       (<OR <GETP ,HERE ,P?MAP>
+		    <EQUAL? ,HERE ,CHAMBER-OF-RA>>
+		<TELL "You see a blue sky with wisps of billowy clouds." CR>)
+	       (<OR <EQUAL? ,HERE ,BELOW-MAST ,BELOW-DECK ,AFT-CABIN>
+		    <EQUAL? ,HERE ,FORE-CABIN>>
+		<TELL "You see wood. What else?" CR>)
+	       (<EQUAL? ,HERE ,TEMPLE-ENTER>
+		<TELL "You see inky blackness." CR>)
+	       (T
+		<TELL "You see stones. What else?" CR>)>>
+
+<ROUTINE V-HELP ()
+	 <COND (,PRSO
+		<COND (<NOT <EQUAL? ,PRSO ,WINNER>>
+		       <TELL "The " D ,PRSO " doesn't need any help." CR>
+		       <RTRUE>)>)>
+	 <TELL "You got yourself into this -- now get yourself out of it." CR>>
+
+<ROUTINE V-STAND-UNDER ()
+	 <COND (<AND <EQUAL? ,PRSO ,CRATE ,PLANE ,PARACHUTE>
+		     <IN? ,PRSO ,GLOBAL-OBJECTS>>
+		<COND (<NOT <IN-A-TENT?>>
+		       <TELL "It looks like that's just where you are." CR>)
+		      (T
+		       <TELL "Better get out of the tent first." CR>)>)
+	       (T
+		<TELL "You can't stand under that!" CR>)>>
+
+<ROUTINE V-SLEEP ()
+	 <COND (<IN? ,WINNER ,COT>
+		<TELL 
+"You close your eyes, but your mind is too active to let you sleep." CR>)
+	       (<IN? ,COT ,HERE>
+		<MOVE ,WINNER ,COT>
+		<TELL "You get into the cot and try to get comfy. ">
+		<V-SLEEP>
+		<RTRUE>)
+	       (,PRSO
+		<TELL "That doesn't sound too comfortable to me." CR>)
+	       (T
+		<TELL "Better find a good place to lie down." CR>)>>
+
+<ROUTINE V-FILL-IN ()
+	 <COND (<NOT <EQUAL? ,PRSO ,HOLE ,MANUAL>>
+		<TELL "I don't know how to fill in the " D ,PRSO "." CR>)
+	       (<PRSO? ,HOLE>
+		<TELL "Let time and Mother Nature take care of that." CR>)
+	       (T
+		<PERFORM ,V?FILL-OUT ,MANUAL>
+		<RTRUE>)>>
+
+<ROUTINE V-WET ()
+	  <PERFORM ,V?POUR-ON ,PRSI ,PRSO>
+	  <RTRUE>>
+
+<ROUTINE V-SIT-ON ()
+	 <COND (<EQUAL? ,PRSO ,CRATE>
+		<TELL
+"You easily weigh enough to make the crate's life-cycle far shorter than it
+would have liked. Needless to say, after having been crushed flat by your
+heartless attempt, it decides to move on, find what the next life-cycle has in
+store for it, and vanishes into the mystical unknown." CR>
+		<REMOVE ,CRATE>
+		<SETG P-IT-LOC <>>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,VEHBIT>
+		<PERFORM ,V?CLIMB-ON ,PRSO>
+		<RTRUE>)
+	       
+	       (<EQUAL? ,PRSO ,GROUND ,SAND ,DECK>
+		<TELL "No sitting down on the job, now." CR>)
+	       (T
+		<TELL <PICK-ONE ,YUKS> CR>)>>
+
+<ROUTINE TBL-TO-INSIDE (OBJ TBL "OPTIONAL" STR "AUX" (OFFS 0) MAX)
+	 <COND (<NOT <FSET? .OBJ ,SURFACEBIT>>
+		<TELL "The " D .OBJ " is already open." CR>
+		<RTRUE>)>
+	 <COND (<FIRST? .OBJ>
+		<OBJS-SLIDE-OFF .OBJ>)>
+	 <SET MAX <GET .TBL 0>>
+	 <COND (<NOT .STR>
+		<TELL "Opened.">)
+	       (T <TELL .STR>)>
+	 <FCLEAR .OBJ ,SURFACEBIT>
+	 <REPEAT ()
+		 <SET OFFS <+ .OFFS 1>>
+		 <COND (<G? .OFFS .MAX>
+			<RETURN>)
+		       (<NOT <EQUAL? <GET .TBL .OFFS> 0>>
+			<MOVE <GET .TBL .OFFS> .OBJ>
+			<PUT .TBL .OFFS 0>)>>
+	 <COND (<FIRST? .OBJ>
+		<TELL " Opening the " D .OBJ " reveals ">
+		<PRINT-CONTENTS .OBJ>
+		<TELL ".">)>
+	 <CRLF>>
+
+<ROUTINE INSIDE-OBJ-TO (TBL OBJ "AUX" (OFFS 0) F N)
+	 <COND (<FSET? .OBJ ,SURFACEBIT>
+		<TELL "The " D .OBJ " is already closed." CR>
+		<RTRUE>)>
+	 <FSET .OBJ ,SURFACEBIT>
+	 <TELL "Closed." CR>
+	 <COND (<NOT <FIRST? .OBJ>>
+		<RTRUE>)>
+	 <SET F <FIRST? .OBJ>>
+	 <REPEAT ()
+		 <COND (<NOT .F>
+			<RETURN>)
+		       (T
+			<SET N .F>
+			<SET F <NEXT? .N>>
+			<REMOVE .N>
+			<REPEAT ()
+				<SET OFFS <+ .OFFS 1>>
+				<COND (<EQUAL? <GET .TBL .OFFS> 0>
+				       <PUT .TBL .OFFS .N>
+				       <RETURN>)>>)>>>
+	       
+<ROUTINE OBJS-SLIDE-OFF (OBJ "AUX" F N THERE)
+	 <SET THERE <LOC .OBJ>>
+	 <COND (<EQUAL? .THERE ,WINNER>
+		<SET THERE ,HERE>)>
+	 <SET F <FIRST? .OBJ>>
+	 <REPEAT ()
+		 <COND (<NOT .F>
+			<RETURN>)
+		       (T
+			<SET N .F>
+			<SET F <NEXT? .N>>
+			<MOVE .N .THERE>)>>
+	 <TELL "Everything on the " D .OBJ " slides off its top." CR>
+	 <CRLF>>
+
+<ROUTINE V-JUMP-ROPE ()
+	 <COND (<NOT <EQUAL? ,PRSO ,ROPE>>
+		<TELL "I can jump rope, and that's about all." CR>)
+	       (T
+		<TELL "Well, it takes all kinds of weirdos..." CR>)>>
+
+<ROUTINE EMPTY-THE (OBJ "OPTIONAL" (BURN? T) "AUX" F N (FLG <>))
+	 <SET F <FIRST? .OBJ>>
+	 <REPEAT ()
+		 <COND (<NOT .F>
+			<RETURN>)
+		       (T
+			<SET N .F>
+			<SET F <NEXT? .N>>
+			<COND (<AND <EQUAL? ,HERE ,WEST-END-OF-PASSAGE>
+				    <NOT <FSET? ,PIT ,INVISIBLE>>>
+			       <REMOVE .N>
+			       <SET FLG 1>)
+			      (T
+			       <MOVE .N ,HERE>
+			       <SET FLG 2>)>)>>
+	 <COND (<NOT .FLG>
+		<RTRUE>)
+	       (T
+		<TELL " Whatever was inside the " D .OBJ>
+		<COND (<EQUAL? .FLG 1>
+		       <TELL " has fallen out." CR>)
+		      (<EQUAL? .FLG 2>
+		       <TELL " falls into the pit." CR>)>)>>
+		
+		
\ No newline at end of file