commit c55088a7df0675d67e159eebc35410d41e445dbc
Author: historicalsource <historicalsoftware@textfiles.com>
Date:   Sun Apr 14 02:17:21 2019 -0400

    Revision 58 (Original Source)

diff --git a/README.md b/README.md
new file mode 100644
index 0000000..23b46f5
--- /dev/null
+++ b/README.md
@@ -0,0 +1 @@
+# hitchhikersguide
diff --git a/earth.zil b/earth.zil
new file mode 100644
index 0000000..fed0ce1
--- /dev/null
+++ b/earth.zil
@@ -0,0 +1,2454 @@
+"EARTH for
+		  THE HITCHHIKER'S GUIDE TO THE GALAXY
+	(c) Copyright 1984 Infocom, Inc.  All Rights Reserved."
+
+<OBJECT HOME
+	(IN LOCAL-GLOBALS)
+	(DESC "your home")
+	(SYNONYM HOME)
+	(ADJECTIVE MY YOUR)
+	(FLAGS NARTICLEBIT)
+	(ACTION HOME-F)>
+
+<ROUTINE HOME-F ()
+	 <COND (<AND ,HOUSE-DEMOLISHED
+		     <VERB? ENJOY>>
+		<TELL
+,ZEN " You can't enjoy a " D ,RUBBLE " properly till it's at least a hundred
+years old. Also, you are haunted by the tragic vision of your favourite teapot
+lying shattered among the dust.|
+There is also the matter of all your clothes." CR>)
+	       (<VERB? THROUGH WALK-TO BOARD>
+		<COND (<EQUAL? ,HERE ,FRONT-OF-HOUSE ,FRONT-PORCH>
+		       <DO-WALK ,P?NORTH>)
+		      (<EQUAL? ,HERE ,BEDROOM>
+		       <TELL ,LOOK-AROUND CR>)
+		      (T
+		       <V-WALK-AROUND>)>)
+	       (<VERB? LEAVE EXIT DISEMBARK>
+		<COND (<EQUAL? ,HERE ,FRONT-PORCH>
+		       <DO-WALK ,P?SOUTH>)
+		      (<EQUAL? ,HERE ,BEDROOM>
+		       <V-WALK-AROUND>)
+		      (T
+		       <TELL ,LOOK-AROUND CR>)>)
+	       (<AND <VERB? LIE-DOWN>
+		     <EQUAL? ,HERE ,FRONT-OF-HOUSE>
+		     ,IN-FRONT-FLAG>
+		<PERFORM ,V?LIE-DOWN ,GROUND>
+		<RTRUE>)
+	       (<AND <VERB? EXAMINE>
+		     ,HOUSE-DEMOLISHED>
+		<TELL "It is now a " D ,RUBBLE "." CR>)
+	       (<EQUAL? ,IDENTITY-FLAG ,FORD> ;"since DESC is YOUR HOME"
+		<UNIMPORTANT-THING-F>)>>
+
+<OBJECT HOUSE
+	(IN LOCAL-GLOBALS)
+	(DESC "it")
+	(SYNONYM HOUSE)
+	(ADJECTIVE MY YOUR)
+	(FLAGS NARTICLEBIT)
+	(ACTION HOUSE-F)>
+
+<ROUTINE HOUSE-F ()
+	 <COND (<PRSO? ,HOUSE>
+		<PERFORM ,PRSA ,HOME ,PRSI>
+		<RTRUE>)
+	       (T
+		<PERFORM ,PRSA ,PRSO ,HOME>
+		<RTRUE>)>>
+
+<OBJECT RUBBLE
+	(IN LOCAL-GLOBALS)
+	(DESC "pile of rubble")
+	(SYNONYM PILE RUBBLE DEBRIS)
+	(FLAGS NDESCBIT)
+	(ACTION HOME-F)>
+
+<ROUTINE I-HOUSEWRECK ()
+	 <COND (<EQUAL? ,HERE ,BEDROOM ,FRONT-PORCH>
+		<TELL CR
+"Astoundingly, a " D ,BULLDOZER " pokes through your wall. However, you have
+no time for surprise because the ceiling is collapsing on you as">
+		<BETTER-LUCK>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE BETTER-LUCK ()
+	 <TELL
+" your home is unexpectedly demolished to make way for a new bypass. You are
+seriously injured in the process, but on your way to the hospital">
+	 <MAKE-WAY-FOR>
+	 <CRLF>
+	 <COND (<NOT <FSET? ,BEDROOM ,ONBIT>>
+		<TELL "Next time, try turning on the light." CR>)
+	       (<AND <NOT <FSET? ,GOWN ,OPENBIT>>
+		     ,HEADACHE> 
+		<TELL
+"Too bad you never found an aspirin for your hangover." CR>)
+	       (T
+		<TELL "Better luck next life." CR>)>
+	 <FINISH>>
+
+<GLOBAL HOUSE-DEMOLISHED <>>
+
+<GLOBAL HEADACHE T>
+
+<GLOBAL SLEEVE-TIED <>>
+
+<OBJECT HANGOVER
+	(IN GLOBAL-OBJECTS)
+	(DESC "splitting headache")
+	(SYNONYM HEADAC HANGOV THROBB)
+	(ADJECTIVE SPLITT BIG BLINDI)
+	(ACTION HANGOVER-F)>
+
+<ROUTINE HANGOVER-F ()
+	 <COND (<AND <VERB? ASK-ABOUT>
+		     <PRSI? ,HANGOVER>>
+		<RFALSE>)
+	       (<AND <NOT ,HEADACHE>
+		     <NOT <EQUAL? ,IDENTITY-FLAG ,ZAPHOD>>>
+		<TELL "You can't feel any">
+		<COND (<EQUAL? ,HANGOVER ,PRSO>
+		       <PRSO-PRINT>)
+		      (T
+		       <PRSI-PRINT>)>
+		<TELL " here." CR>)
+	       (<VERB? EXAMINE>
+		<V-DIAGNOSE>)
+	       (<VERB? GIVE THROW DROP>
+		<V-COUNT>)>>
+
+<ROOM BEDROOM
+      (IN ROOMS)
+      (SYNONYM TRAVEL)
+      (ADJECTIVE TIME)
+      (DESC "Bedroom")
+      (SOUTH PER BEDROOM-EXIT-F)
+      (OUT PER BEDROOM-EXIT-F)
+      (DOWN PER BEDROOM-EXIT-F)
+      (FLAGS RLANDBIT)
+      (GLOBAL HOUSE HOME GLOBAL-BED BULLDOZER WINDOW STAIRS
+       	      BEDROOM-DOOR THIRD-PLANET)
+      (PSEUDO "WATER" UNIMPORTANT-THING-F "BEDROO" GLOBAL-ROOM-F)
+      (ACTION BEDROOM-F)>
+
+<ROUTINE BEDROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"The bedroom is a mess.|
+It is a small bedroom with a faded carpet and old wallpaper. There is a
+washbasin, a chair">
+		<COND (<FSET? ,GOWN ,NDESCBIT>
+		       <TELL " with a tatty dressing gown slung over it">)>
+		<TELL
+", and a window with the curtains drawn. Near the exit leading south is a
+phone." CR>)>>
+
+<ROUTINE BEDROOM-EXIT-F ()
+	 <COND (<NOT <FSET? ,BEDROOM-DOOR ,OPENBIT>>
+		<TELL "The door is closed." CR>
+		<SETG P-IT-OBJECT ,BEDROOM-DOOR>
+		<RFALSE>)
+	       (,HEADACHE
+		<TELL
+"You miss the doorway by a good eighteen inches. The wall jostles you
+rather rudely." CR>
+		<RFALSE>)
+	       (<FSET? ,BULLDOZER ,INVISIBLE>
+		<TELL "You make your way down to the front porch." CR CR>)
+	       (T
+		<TELL "You rush down the stairs in panic." CR CR>)>
+	 <FCLEAR ,LIGHT ,LIGHTBIT>
+	 ,FRONT-PORCH>
+
+<OBJECT PHONE
+	(IN BEDROOM)
+	(DESC "telephone")
+	(SYNONYM PHONE TELEPH RECEIV)
+	(FLAGS NDESCBIT TAKEBIT TRYTAKEBIT)
+	(ACTION PHONE-F)>
+
+<ROUTINE PHONE-F ()
+	 <COND (<VERB? TAKE>
+		<COND (<FSET? ,PHONE ,TOUCHBIT>
+		       <PERFORM ,V?CALL ,DAIS>
+		       <RTRUE>)
+		      (T
+		       <FSET ,PHONE ,TOUCHBIT>
+		       <TELL "You pick up the receiver." ,DIALLING-TONE>
+		       <COND (<FSET? ,TOOTHBRUSH ,TOUCHBIT>
+		              <TWO-TREES>)>
+		       <CRLF>)>)
+	       (<VERB? REPLY>
+		<TELL "It isn't ringing." CR>)>>
+
+<OBJECT BEDROOM-DOOR
+	(IN LOCAL-GLOBALS)
+	(DESC "door")
+	(SYNONYM DOOR)
+	(FLAGS DOORBIT OPENBIT NDESCBIT)>
+
+<OBJECT GLOBAL-BED
+	(IN LOCAL-GLOBALS)
+	(DESC "bed")
+	(SYNONYM BED)
+	(FLAGS VEHBIT)
+	(ACTION GLOBAL-BED-F)>
+
+<ROUTINE GLOBAL-BED-F ()
+	 <COND (<EQUAL? ,GLOBAL-BED ,PRSO>
+		<PERFORM ,PRSA ,BED ,PRSI>
+		<RTRUE>)
+	       (T
+		<PERFORM ,PRSA ,PRSO ,BED>
+		<RTRUE>)>>
+
+<OBJECT BED
+	(IN BEDROOM)
+	(DESC "bed")
+	(SYNONYM BED)
+	(FLAGS VEHBIT CONTBIT SURFACEBIT SEARCHBIT OPENBIT NDESCBIT)
+	(ACTION BED-F)>
+
+<ROUTINE BED-F ("OPTIONAL" (RARG <>))
+	 <COND (<EQUAL? .RARG ,M-BEG>
+		<COND (<AND <VERB? TAKE>
+		            <FSET? ,PRSO ,TAKEBIT>
+			    <NOT <IN? ,PRSO ,BED>>
+			    <NOT <HELD? ,PRSO>>>
+		       <TELL "You can't reach it from the bed.">
+		       <COND (,HEADACHE
+			      <TELL " The effort almost kills you.">)>
+		       <CRLF>)
+		      (<AND <VERB? OPEN LOOK-INSIDE>
+			    <PRSO? ,CURTAINS>>
+		       <PERFORM ,V?TAKE ,PHONE>
+		       <SETG P-IT-OBJECT ,CURTAINS>
+		       <RTRUE>)
+		      (<AND <VERB? OPEN CLOSE>
+			    <PRSO? ,BEDROOM-DOOR>>
+		       <PERFORM ,V?TAKE ,PHONE>
+		       <SETG P-IT-OBJECT ,BEDROOM-DOOR>
+		       <RTRUE>)
+		      (<VERB? WALK>
+		       <OUT-OF-FIRST ,BED>)>)
+	       (.RARG
+		<RFALSE>)
+	       (<AND <VERB? DISEMBARK>
+		     ,HEADACHE
+		     <EQUAL? <LOC ,PROTAGONIST> ,BED>>
+		<MOVE ,PROTAGONIST ,HERE>
+		<SETG LYING-DOWN <>>
+		<TELL
+"Very difficult, but you manage it. The room is still spinning.
+It dips and sways a little." CR>)
+	       (<VERB? LOOK-UNDER>
+		<MOVE ,STUFF-UNDER-BED ,HERE>
+		<TELL
+"There's nothing there. Well, there are a few soiled handkerchiefs, a book you
+thought you'd lost, a couple of foreign coins, and something else which can't
+be fully described in a family game, but nothing you'd actually want." CR>)
+	       (<AND <VERB? OPEN CLOSE>
+		     <PRSO? ,BED>>
+		<TELL-ME-HOW>)>>
+
+<OBJECT STUFF-UNDER-BED
+	(IN LOCAL-GLOBALS) ;"for purposes of MOBY-FIND"
+	(DESC "it")
+	(SYNONYM BOOK COIN HANDKE COINS)
+	(ADJECTIVE SOILED FOREIG)
+	(FLAGS NDESCBIT NARTICLEBIT)
+	(ACTION UNIMPORTANT-THING-F)>
+
+<OBJECT CURTAINS
+	(IN BEDROOM)
+	(DESC "your curtains")
+	(SYNONYM CURTAI SHADE SHADES)
+	(ADJECTIVE YOUR)
+	(FLAGS NDESCBIT NARTICLEBIT)
+	(ACTION CURTAINS-F)>
+
+<ROUTINE CURTAINS-F ()
+	 <COND (<VERB? OPEN LOOK-INSIDE>
+		<FCLEAR ,BULLDOZER ,INVISIBLE>
+		<TELL
+"As you part " D ,CURTAINS " you see that i" ,NICE-DAY ", and a large yellow "
+D ,BULLDOZER " is advancing on " D ,HOME "." CR>)>>
+
+<OBJECT GOWN
+	(IN BEDROOM)
+	(DESC "your gown")
+	(LDESC "Your gown is here.")
+	(SYNONYM GOWN POCKET ROBE LOOP)
+	(ADJECTIVE MY YOUR DRESSI TATTY FADED BATTER)
+        (FLAGS
+	 WEARBIT TRYTAKEBIT TAKEBIT CONTBIT NDESCBIT NARTICLEBIT SEARCHBIT)
+	(SIZE 15)
+	(CAPACITY 14)
+	(ACTION GOWN-F)>
+
+<ROUTINE GOWN-F ()
+	 <COND (<AND <VERB? OPEN CLOSE>
+		     <NOT <FSET? ,GOWN ,WORNBIT>>>
+		<TELL
+"It's hard to open or close the pocket unless you're wearing the gown." CR>)
+	       (<VERB? EXAMINE>
+		<TELL "The dressing gown is faded and battered, and is
+clearly a garment which has seen better decades. It has a pocket which is ">
+		<COND (<FSET? ,GOWN ,OPENBIT>
+		       <TELL "open">)
+		      (T
+		       <TELL "closed">)>
+		<COND (,GOWN-HUNG
+		       <TELL ". It is hanging from a " D ,HOOK ".">)
+		      (T
+		       <TELL ", and a small loop at the back of the collar.">)>
+		<COND (,SLEEVE-TIED
+		       <TELL " The sleeves are tied closed.">)>
+		<CRLF>)
+	       (<AND <VERB? TAKE>
+		     <EQUAL? ,GOWN ,PRSO>
+		     ,HEADACHE>
+		<FCLEAR ,GOWN ,TRYTAKEBIT>
+		<FCLEAR ,GOWN ,NDESCBIT>
+		<MOVE ,GOWN ,PROTAGONIST>
+		<TELL
+"Luckily, this is large enough for you to get hold of. You notice something
+in the pocket." CR>)
+	       (<AND <VERB? WEAR>
+		     ,SLEEVE-TIED>
+		<TELL "You'll have to untie the sleeve first." CR>)
+	       (<VERB? TIE UNTIE>
+		<PERFORM ,PRSA ,SLEEVES>
+		<RTRUE>)>>
+
+<OBJECT SLEEVES
+	(IN GLOBAL-OBJECTS)
+	(DESC "sleeve")
+	(SYNONYM SLEEVE)
+	(ACTION SLEEVES-F)>
+
+<ROUTINE SLEEVES-F ()
+	 <COND (<NOT <VISIBLE? ,GOWN>>
+		<CANT-SEE ,SLEEVES>)
+	       (<VERB? WEAR TAKE>
+		<PERFORM ,PRSA ,GOWN>
+		<RTRUE>)
+	       (<VERB? TIE CLOSE>
+		<SETG PRSO ,GOWN>
+		<COND (<IDROP>
+		       <RTRUE>)
+		      (,SLEEVE-TIED
+		       <TELL "It is." CR>)
+		      (T
+		       <SETG SLEEVE-TIED T>
+		       <TELL "The sleeves are now tied closed." CR>)>)
+	       (<VERB? UNTIE OPEN>
+		<COND (,SLEEVE-TIED
+		       <SETG SLEEVE-TIED <>>
+		       <TELL "Untied." CR>)
+		      (T
+		       <TELL "It isn't tied!" CR>)>)>>
+
+<ROUTINE TWO-TREES ()
+	 <SETG AWAITING-REPLY 9>
+	 <ENABLE <QUEUE I-REPLY 2>>
+	 <TELL
+" Shouldn't you be taking more interest in events in the world around you?
+While you've got it...?">>
+
+<OBJECT THING
+	(IN GOWN)
+	(DESC "thing your aunt gave you which you don't know what it is")
+	(SYNONYM THING GIFT)
+	(ADJECTIVE AUNT\'S)
+	(FLAGS TAKEBIT CONTBIT SEARCHBIT OPENBIT)
+	(SIZE 6)
+	(CAPACITY 90)
+	(ACTION THING-F)>
+
+<ROUTINE THING-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"Apart from a label on the bottom saying \"Made in Ibiza\" it furnishes you
+with no clue as to its purpose, if indeed it has one. You are surprised to see
+it because you thought you'd thrown it away. Like most gifts from your aunt,"
+,GET-RID CR>)
+	       (<AND <VERB? DROP>
+		     <NOT <EQUAL? ,HERE ,MAZE ,ACCESS-SPACE>>>
+		<MOVE ,THING ,HERE>
+		<TELL
+"It falls to the ground with a light \"thunk.\" It doesn't do anything
+else at all." CR>)
+	       (<VERB? CLOSE>
+		<TELL
+"Come to think of it, you vaguely remember an instruction booklet with
+directions for that. You never read it and lost it months ago." CR>)>>
+
+<ROUTINE I-THING ()
+	 <ENABLE <QUEUE I-THING <+ 4 <RANDOM 4>>>>
+	 <COND (<OR <NOT <EQUAL? ,IDENTITY-FLAG ,ARTHUR>>
+		    <AND <EQUAL? ,HERE ,ENGINE-ROOM>
+			 <L? ,LOOK-COUNTER 3>>
+		    <EQUAL? ,HERE ,DARK ,ACCESS-SPACE ,MAZE>
+		    <VISIBLE? ,THING>
+		    <HELD? ,THING ,PROTAGONIST>
+		    <IN? ,FLEET ,HERE>>
+		<RFALSE>)>
+	 <COND (<PROB 40>
+		<MOVE ,THING ,HERE>)
+	       (<AND <FSET? ,GOWN ,WORNBIT>
+		     <FSET? ,GOWN ,OPENBIT>
+		     <PROB 65>>
+		<MOVE ,THING ,GOWN>)
+	       (T
+		<MOVE ,THING ,PROTAGONIST>)>
+	 <RFALSE>>
+
+<OBJECT POCKET-FLUFF
+	(IN GOWN)
+	(DESC "pocket fluff")
+	(SYNONYM FLUFF LINT)
+	(ADJECTIVE POCKET)
+	(FLAGS TAKEBIT NARTICLEBIT)
+	(SIZE 1)
+	(GENERIC POCKET-FLUFF)>
+
+<OBJECT TABLET
+	(IN GOWN)
+	(DESC "buffered analgesic")
+	(SYNONYM ANALGE TABLET ASPIRI PILL)
+	(ADJECTIVE LARGE BUFFER)
+	(FLAGS TAKEBIT EATBIT)
+        (SIZE 2)
+	(ACTION TABLET-F)>
+
+<ROUTINE TABLET-F ()
+	 <COND (<VERB? EAT TAKE DRINK> ;"SWALLOW is synonym of DRINK"
+		<MOVE ,TABLET ,LOCAL-GLOBALS>
+		<FCLEAR ,SCREWDRIVER ,TRYTAKEBIT>
+		<FCLEAR ,TOOTHBRUSH ,TRYTAKEBIT>
+		<SETG HEADACHE <>>
+		<SETG SCORE <+ ,SCORE 10>>
+		<TELL
+"You swallow the tablet. After a few seconds the room begins to calm
+down and behave in an orderly manner. Your terrible headache goes." CR>)>>
+
+<OBJECT SINK
+	(IN BEDROOM)
+	(DESC "it")
+	(SYNONYM BASIN WASHBA SINK)
+	(ADJECTIVE WASH)
+	(FLAGS NDESCBIT NARTICLEBIT)
+	(ACTION UNIMPORTANT-THING-F)>
+
+<OBJECT BEDROOM-FURNISHINGS
+	(IN BEDROOM)
+	(DESC "it")
+	(SYNONYM CARPET WALLPA PAPER CHAIR)
+	(ADJECTIVE WALL FADED OLD)
+	(FLAGS NDESCBIT NARTICLEBIT)
+	(ACTION UNIMPORTANT-THING-F)>
+
+<ROOM FRONT-PORCH
+      (IN ROOMS)
+      (SYNONYM BEAM BEAMS)
+      (ADJECTIVE MATTER TRANSF)
+      (DESC "Front Porch")
+      (LDESC
+"This is the enclosed front porch of your home. Your front garden lies to
+the south, and you can re-enter your home to the north.")
+      (UP TO BEDROOM)
+      (NORTH TO BEDROOM)
+      (SOUTH PER CLOTHES-EXIT-F)
+      (OUT PER CLOTHES-EXIT-F)
+      (FLAGS RLANDBIT ONBIT)
+      (PSEUDO "DOORMA" UNIMPORTANT-THING-F "MAT" UNIMPORTANT-THING-F)
+      (GLOBAL HOUSE HOME STAIRS THIRD-PLANET BEDROOM-DOOR)>
+
+<ROUTINE CLOTHES-EXIT-F ()
+	 <COND (<FSET? ,GOWN ,WORNBIT>
+		,FRONT-OF-HOUSE)
+	       (T
+		<SETG AWAITING-REPLY 10>
+		<ENABLE <QUEUE I-REPLY 2>>
+		<TELL ,ARRESTED CR>
+		<RFALSE>)>>
+
+<OBJECT MAIL
+	(IN FRONT-PORCH)
+	(DESC "loose pile of junk mail")
+	(FDESC "On the doormat is a pile of junk mail.")
+	(SYNONYM ORDER MAIL PILE LETTER)
+	(ADJECTIVE DEMOLI JUNK MY OFFICI LOOSE)
+	(FLAGS TAKEBIT READBIT TRYTAKEBIT)
+	(SIZE 4)
+	(TEXT
+"There are many pieces of mail. Most are from some computer company called
+Infocom which wants you to buy their games. Hidden underneath is an official
+letter from the local council, dated some two years ago and inexplicably not
+delivered till now, explaining that a demolition order has been served on your
+home. The date of demolition is today's date.")
+	(ACTION MAIL-F)>
+
+<ROUTINE MAIL-F ()
+	 <COND (<AND <VERB? TAKE>
+		     <NOT <FSET? ,MAIL ,TOUCHBIT>>>
+		<FSET ,MAIL ,TOUCHBIT>
+		<FCLEAR ,MAIL ,TRYTAKEBIT>
+		<MOVE ,MAIL ,PROTAGONIST>
+		<TELL "You gather up the pile of mail." CR>)
+	       (<VERB? OPEN>
+		<PERFORM ,V?READ ,MAIL>
+		<RTRUE>)>>
+
+<ROOM FRONT-OF-HOUSE
+      (IN ROOMS)
+      (SYNONYM WOONBE)
+      (ADJECTIVE GALAXI)
+      (DESC "Front of House")
+      (NORTH PER HOUSE-ENTER-F)
+      (SOUTH TO COUNTRY-LANE)
+      (NE TO BACK-OF-HOUSE)
+      (NW TO BACK-OF-HOUSE)
+      (FLAGS RLANDBIT ONBIT OUTSIDEBIT)
+      (GLOBAL HOUSE HOME BULLDOZER CONVERSATION THIRD-PLANET RUBBLE)
+      (PSEUDO "TREE" TREE-PSEUDO)
+      (ACTION FRONT-OF-HOUSE-F)>
+
+<ROUTINE HOUSE-ENTER-F ()
+	 <COND (,HOUSE-DEMOLISHED
+		<TELL "You can't enter a " D ,RUBBLE "." CR>
+		<RFALSE>)
+	       (<EQUAL? ,IDENTITY-FLAG ,FORD>
+		<COND (<NOT <VERB? THROUGH>>
+		       <TELL "Enter the house? ">)>
+		<PRIVATE "Arthur">
+		<RFALSE>)
+	       (<NOT ,PROSSER-LYING>
+		<TELL "The " D ,BULLDOZER>
+		<JIGS-UP
+", which you may have noticed outside, just pushed your home down
+on top of you.">
+		<RFALSE>)
+	       (T
+		<ENABLE <QUEUE I-HOUSEWRECK 5>>
+		,FRONT-PORCH)>>
+
+<ROUTINE FRONT-OF-HOUSE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<FCLEAR ,BULLDOZER ,INVISIBLE>
+		<COND (<IN? ,DOG ,COUNTRY-LANE>
+		       <COND (<NOT ,DOG-FED>
+			      <I-DOG>)>
+	               <ENABLE <QUEUE I-VOGONS 3>>
+		       <TELL "You reach the site of what was ">
+		       <COND (<EQUAL? ,IDENTITY-FLAG ,FORD>
+			      <TELL "Arthur's">)
+			     (T
+			      <TELL "your">)>
+		       <TELL
+" home. It is now a " D ,RUBBLE ". " D ,PROSSER " looks sheepishly
+triumphant, a trick few people can do, as it requires a lot of
+technically complex deltoid muscle work." CR CR>)
+		      (<AND <NOT <EQUAL? ,IDENTITY-FLAG ,FORD>>
+			    <NOT ,PROSSER-LYING>>
+		       <ENABLE <QUEUE I-BULLDOZER -1>>
+		       <RFALSE>)>)
+	       (<EQUAL? .RARG ,M-LOOK>
+		<COND (<AND <EQUAL? ,IDENTITY-FLAG ,FORD>
+			    <NOT <FSET? ,FRONT-OF-HOUSE ,NDESCBIT>>>
+		       <FSET ,BEER ,NDESCBIT>
+		       <SETG DRUNK-LEVEL 0>
+		       <FSET ,ARTHUR ,NDESCBIT>
+		       <FSET ,FRONT-OF-HOUSE ,NDESCBIT>
+		       <TELL
+"Before you is the house of your friend, " D ,ARTHUR ", who is lying in front
+of a " D ,BULLDOZER "; you have no idea why. You have no idea about most things
+about Arthur, even why you regard him as a friend, but you do, and must
+therefore return his towel before you leave.">)
+		      (T
+		       <COND (,HOUSE-DEMOLISHED
+			      <TELL "There is a huge " D ,RUBBLE>)
+			     (<EQUAL? ,IDENTITY-FLAG ,FORD>
+			      <TELL "Arthur's house is">)
+			     (T
+			      <TELL "You can enter your home">)>
+		       <TELL
+" to the north. A path leads around it to the northeast and northwest,
+and a country lane is visible to the south.">)>
+		<COND (<AND <NOT <FSET? ,FRONT-OF-HOUSE ,NDESCBIT>>
+			    <EQUAL? ,IDENTITY-FLAG ,ARTHUR>>
+		       <FSET ,FRONT-OF-HOUSE ,NDESCBIT>
+		       <TELL
+" All that lies between your home and the huge yellow " D ,BULLDOZER " bearing
+down on it is a few yards of mud.">)>
+		<CRLF> <CRLF>)
+	       (<AND <EQUAL? .RARG ,M-END>
+		     <EQUAL? ,IDENTITY-FLAG ,FORD>
+		     <FSET? ,ARTHUR ,NDESCBIT>>
+		<FCLEAR ,ARTHUR ,NDESCBIT>
+		<RFALSE>)>>
+
+<OBJECT ROSES
+	(IN FRONT-OF-HOUSE)
+	(DESC "it")
+	(SYNONYM ROSE ROSES ROSEBE BED)
+	(ADJECTIVE ROSE)
+	(FLAGS NDESCBIT NARTICLEBIT)
+	(ACTION UNIMPORTANT-THING-F)>
+
+<GLOBAL BULLDOZER-COUNTER 0>
+
+<ROUTINE I-BULLDOZER ()
+	 <COND (<OR ,LYING-DOWN
+		    ,HOUSE-DEMOLISHED>
+		<DISABLE <INT I-BULLDOZER>>
+		<RFALSE>)>
+	 <FSET ,PROSSER ,TOUCHBIT>
+	 <SETG BULLDOZER-COUNTER <+ ,BULLDOZER-COUNTER 1>>
+	 <COND (<G? ,BULLDOZER-COUNTER 4>
+	        <DISABLE <INT I-BULLDOZER>>
+		<TELL ,BULLDOZER-PILES CR>
+		<BRICK-DEATH>)
+	       (<EQUAL? ,HERE ,FRONT-OF-HOUSE>
+		<TELL
+"The " D ,BULLDOZER " rumbles slowly toward your home." CR>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE BRICK-DEATH ()
+	 <TELL CR
+"Your home collapses in a cloud of dust, and a stray flying brick hits you
+squarely on the back of the head. You try to think of some suitable last words,
+but what with the confusion of the moment and the spinning of your head, you
+are unable to compose anything pithy and expire in silence.">
+	 <REPEAT ()
+		 <CRLF> <CRLF>
+	         <PRINTI ">">
+	         <READ ,P-INBUF ,P-LEXV>
+	         <SETG DEAD-COUNTER <+ ,DEAD-COUNTER 1>>
+	         <COND (<EQUAL? ,DEAD-COUNTER 1 2>
+			<TELL "You keep out of this, you're dead">
+			<COND (<EQUAL? ,DEAD-COUNTER 1>
+			       <TELL ". An ambulance arrives.">)
+			      (T
+			       <TELL
+" and should be concentrating on developing a good firm rigor mortis. You
+are put in the ambulance, which drives away.">)>)
+	              (<EQUAL? ,DEAD-COUNTER 3>
+		       <TELL
+"For a dead person you are talking too much.
+As the ambulance reaches the mortuary">
+		       <MAKE-WAY-FOR>
+		       <FINISH>)>>>
+
+<GLOBAL DEAD-COUNTER 0>
+
+<OBJECT BULLDOZER-DRIVER
+	(IN FRONT-OF-HOUSE)
+	(DESC "bulldozer driver")
+	(SYNONYM DRIVER)
+	(ADJECTIVE BULLDO DOZER)
+	(FLAGS NDESCBIT ACTORBIT)
+	(ACTION BULLDOZER-DRIVER-F)>
+
+<ROUTINE BULLDOZER-DRIVER-F ()
+	 <COND (<VERB? TELL HELLO>
+		<TELL "The " D ,BULLDOZER-DRIVER
+", perusing a booklet of union rules, ignores you." CR>
+		<FUCKING-CLEAR>)>>
+
+<OBJECT BULLDOZER
+	(IN LOCAL-GLOBALS)
+	(DESC "bulldozer")
+	(SYNONYM BULLDO DOZER)
+	(ADJECTIVE LARGE YELLOW BULL HUGE)
+	(FLAGS NDESCBIT INVISIBLE)
+	(ACTION BULLDOZER-F)>
+
+<ROUTINE BULLDOZER-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"It's one of those really big " D ,BULLDOZER "s that can actually crush other "
+D ,BULLDOZER "s, let alone houses." CR>)
+	       (<AND <NOT <EQUAL? ,HERE ,FRONT-OF-HOUSE>>
+		     <VERB? RUB PUSH MOVE TAKE KICK BLOCK WALK-AROUND>>
+		<TELL "The " D ,BULLDOZER " isn't here." CR>)
+	       (<VERB? LIE-DOWN>
+		<PERFORM ,V?BLOCK ,BULLDOZER>
+		<RTRUE>)
+	       (<AND <VERB? BLOCK>
+		     <EQUAL? ,IDENTITY-FLAG ,ARTHUR>>
+		<COND (,HOUSE-DEMOLISHED
+		       <TELL "Too late now." CR>)
+		      (,LYING-DOWN
+		       <PERFORM ,V?LIE-DOWN ,GROUND>
+		       <RTRUE>)
+		      (,PROSSER-LYING
+		       <TELL "Prosser's doing that for you." CR>)
+		      (T
+		       <SETG LYING-DOWN T>
+		       <ENABLE <QUEUE I-PROSSER 2>>
+		       <TELL
+"You lie down in the path of the advancing " D ,BULLDOZER ". Prosser yells
+at you to for crissake move!!!" CR>)>)
+	       (<VERB? WALK-AROUND>
+		<COND (<EQUAL? ,IDENTITY-FLAG ,ARTHUR>
+		       <V-DIG>)
+		      (<NOT ,TOWEL-OFFERED>
+		       <TELL
+"Didn't you come here for a purpose? Something about a towel?" CR>)
+		      (,GONE-AROUND
+		       <TELL "You already did. It's not a merry-go-round." CR>)
+		      (T
+		       <SETG GONE-AROUND T>
+		       <TELL
+"You walk around the " D ,BULLDOZER ". Prosser is standing here, looking cross
+and frustrated. Realising that you are a friend of Arthur's he starts to talk
+at you. He says that this sort of protest is all very well, but what Mr. Dent
+must realise is that he's had plenty of time to make a formal protest at the
+proper time and place, and that spending months going through the appropriate
+official channels, filling in the appropriate official forms, and going to the
+appropriate official public hearings is the right way of going about it, and
+lying around whimsically in the mud is not. He says that he personally hates
+mud and despises the sort of people who lie in it." CR>)>)
+	       (<AND <VERB? LISTEN>
+		     <RUNNING? ,I-PROSSER>>
+		<TELL "\"Rumble...rumble...\"" CR>)>>
+
+<GLOBAL PROSSER-COUNTER 0>
+
+<GLOBAL PROSSER-LYING <>>
+
+<GLOBAL GONE-AROUND <>>
+
+<ROUTINE I-PROSSER ()
+	 <COND (<NOT ,LYING-DOWN>
+		<DISABLE <INT I-PROSSER>>
+		<I-BULLDOZER>
+		<RTRUE>)>
+	 <ENABLE <QUEUE I-PROSSER -1>>
+	 <SETG PROSSER-COUNTER <+ ,PROSSER-COUNTER 1>>
+	 <CRLF>
+	 <COND (<EQUAL? ,PROSSER-COUNTER 1>
+		<TELL
+"The " D ,BULLDOZER " thunders toward you. The ground is shaking beneath you
+as you lie in the mud." CR>)
+	       (<EQUAL? ,PROSSER-COUNTER 2>
+		<TELL
+"The noise of the giant " D ,BULLDOZER " is now so violently loud that you
+can't even hear Prosser yelling to warn you that you will be killed if you
+don't get the hell out of the way. You just see him gesticulating wildly." CR>)
+	       (<EQUAL? ,PROSSER-COUNTER 3>
+		<DISABLE <INT I-PROSSER>>
+		<ENABLE <QUEUE I-FORD -1>>
+		<MOVE ,FORD ,HERE>
+		<SETG P-IT-OBJECT ,TOWEL>
+		<TELL
+"With a terrible grinding of gears the " D ,BULLDOZER" comes to an abrupt halt
+just in front of you. It shakes, shudders, and emits noxious substances all
+over your rose bed. Prosser is incoherent with rage.|
+|
+Moments later, your friend " D ,FORD " arrives. He hardly seems to notice
+your predicament, but keeps glancing nervously at the sky. He says \"Hello,
+Arthur,\" takes a towel from his battered leather satchel, and offers it to
+you." CR>)>>
+
+<OBJECT PROSSER
+	(IN FRONT-OF-HOUSE)
+	(DESC "Mr. Prosser")
+	(DESCFCN PROSSER-DESCFCN)
+	(SYNONYM PROSSE FOREMA CREW)
+	(ADJECTIVE WRECKI MR MISTER)
+	(FLAGS NARTICLEBIT ACTORBIT CONTBIT OPENBIT)
+	(ACTION PROSSER-F)>
+
+<ROUTINE PROSSER-DESCFCN ("OPTIONAL" X)
+	 <COND (<AND <EQUAL? ,IDENTITY-FLAG ,FORD>
+		     <NOT <FSET? ,PROSSER ,TOUCHBIT>>>
+		<FSET ,PROSSER ,TOUCHBIT>
+		<TELL
+"Nearby stands an impatient man. There seems to be a bit of an atmosphere.">)
+	       (T
+		<TELL D ,PROSSER ", from the local council, is ">
+	 	<COND (,PROSSER-LYING
+		       <TELL "lying in front">)
+		      (,GONE-AROUND
+		       <TELL "standing at the side">)
+		      (T
+		       <TELL ,ON-OTHER-SIDE>)>
+		<TELL
+" of the " D ,BULLDOZER ". He seems to be wearing a " D ,DIGITAL-WATCH ".">
+	        <COND (<NOT <FSET? ,PROSSER ,TOUCHBIT>>
+		       <FSET ,PROSSER ,TOUCHBIT>
+		       <TELL
+" He looks startled to see you emerge, and yells at you to get out of
+the way.">)>)>
+	 <CRLF>>
+
+<ROUTINE PROSSER-F ()
+	 <COND (<EQUAL? ,PROSSER ,WINNER>
+		<COND (<IN? ,FLEET ,HERE>
+		       <TELL
+"Prosser is too preoccupied with recent events to give your remarks much
+consideration. He is running off and saying a number of things about his
+mother in a high voice." CR>
+		       <FUCKING-CLEAR>)
+		      (<AND <VERB? TELL-ABOUT>
+			    <PRSO? ,ME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,PROSSER ,PRSI>
+		       <SETG WINNER ,PROSSER>
+		       <RTRUE>)
+		      (<VERB? HELLO>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?HELLO ,PROSSER>
+		       <SETG WINNER ,PROSSER>
+		       <RTRUE>)
+		      (<AND <VERB? WHAT>
+			    <PRSO? ,OBJECT-OF-GAME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,PROSSER ,OBJECT-OF-GAME>
+		       <SETG WINNER ,PROSSER>
+		       <RTRUE>)
+		      (<OR <AND <VERB? WHAT>
+			        <PRSO? ,TIME>>
+			   <AND <VERB? TELL-TIME>
+				<PRSO? ,ME>
+				<PRSI? ,TIME>>
+			   <AND <VERB? WHAT-TIME>
+				<PRSO? ,TIME>>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-FOR ,PROSSER ,TIME>
+		       <SETG WINNER ,PROSSER>
+		       <RTRUE>)
+		      (<AND <VERB? WHAT>
+			    <PRSO? ,OBJECT-OF-GAME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,PROSSER ,PRSO>
+		       <SETG WINNER ,PROSSER>
+		       <RTRUE>)
+		      (<EQUAL? ,IDENTITY-FLAG ,FORD>
+		       <COND (<OR <AND <VERB? LIE-DOWN>
+				       <PRSO? ,BULLDOZER>
+				       ,IN-FRONT-FLAG>
+			          <AND <VERB? LIE-DOWN>
+				       <PRSO? ,GROUND ,ROOMS>
+				       <NOT ,HOUSE-DEMOLISHED>>
+				  <AND <VERB? REPLACE>
+				       <PRSO? ,ARTHUR>
+				       <NOT ,HOUSE-DEMOLISHED>>>
+			      <COND (,PROSSER-LYING
+				     <TELL "He's already lying there!" CR>
+				     <RTRUE>)>
+			      <SETG PROSSER-LYING T>
+			      <ENABLE <QUEUE I-ARTHUR -1>>
+			      <TELL
+"Prosser blinks in astonishment. \"You mean, go and lie in the mud in his
+place...?\" You explain that Arthur will only move if someone else takes over
+for him. Prosser shakes his head in such a manner as to suggest that he is very
+weary of the world, and you tactfully forebear from mentioning that it won't be
+troubling him much longer. Reluctantly, he follows you back toward Arthur.|
+|
+You rapidly conclude the business. Prosser lies in the mud. Arthur, bewildered,
+nevertheless stands up and appears ready to follow you to the Pub." CR>)
+			     (T
+			      <STAND-ASIDE>
+			      <FUCKING-CLEAR>)>)
+			    (<AND <VERB? WHAT-ABOUT>
+				  <PRSO? ,HOUSE ,HOME>
+				  ,HOUSE-DEMOLISHED>
+			     <TELL
+"Prosser explains the local planning regulations and says, by way of
+reassurance, that you will probably be rehoused within a couple of years." CR>)
+			    (<AND <VERB? BLOCK>
+				  <PRSO? ,BULLDOZER>
+				  <RUNNING? ,I-BULLDOZER>>
+			     <V-PROTEST>)
+			    (T
+			     <STAND-ASIDE>
+			     <FUCKING-CLEAR>)>)
+	       (<AND <NOT ,GONE-AROUND>
+		     <EQUAL? ,IDENTITY-FLAG ,FORD>
+		     <VERB? TELL HELLO ASK-FOR ASK-ABOUT TELL-ABOUT>
+		     <PRSO? ,PROSSER>
+		     <NOT <IN? ,FLEET ,HERE>>>
+		<TELL "Prosser can't hear you from here." CR>
+		<FUCKING-CLEAR>)
+	       (<VERB? GIVE SHOW>
+		<COND (<PRSO? ,THING>
+		       <TELL
+"He is much impressed and says, \"You must have the same aunt I have.\"" CR>)
+		      (<PRSO? ,TOWEL>
+		       <SETG TOWEL-MUDDY T>
+		       <TELL
+"Prosser thanks you, wipes the mud off his boots, and hands it back." CR>)
+		      (<PRSO? ,GUIDE>
+		       <TELL
+"Prosser takes a quick look at " D ,GUIDE ", says he doesn't read that kind of
+rubbish, and hands it back." CR>)
+		      (<PRSO? ,SATCHEL>
+		       <TELL
+"Prosser says he wouldn't be seen dead with that kind of thing slung over his
+shoulder." CR>)>)
+	       (<AND <VERB? WALK-TO>
+		     <EQUAL? ,HERE ,FRONT-OF-HOUSE>>
+		<COND (<AND <EQUAL? ,IDENTITY-FLAG ,FORD>
+			    <NOT ,GONE-AROUND>>
+		       <PERFORM ,V?WALK-AROUND ,BULLDOZER>
+		       <RTRUE>)
+		      (T
+		       <TELL
+"You're already as close as any reasonable person would want to get." CR>)>)
+	       (<AND <VERB? KILL KICK>
+		     ,LYING-DOWN>
+		<TELL ,WHILE-LYING CR>)
+	       (<AND <VERB? KILL>
+		     <PRSO? ,PROSSER>
+		     ,HOUSE-DEMOLISHED>
+		<TELL
+"You muck up all his fancy facial work. This is the last moment of
+satisfaction you will experience for some time." CR>)
+	       (<AND <VERB? KILL KICK>
+		     <PRSO? ,PROSSER>>
+		<TELL
+"He dodges, insisting that this is incorrect procedure." CR>)
+	       (<AND <VERB? THROW>
+		     <PRSI? ,PROSSER>>
+		<MOVE ,PRSO ,HERE>
+		<PERFORM ,V?KILL ,PROSSER>
+		<RTRUE>)
+	       (<VERB? EXAMINE>
+		<PROSSER-DESCFCN>)
+	       (<AND <VERB? LISTEN>
+		     <NOT <FSET? ,CONVERSATION ,INVISIBLE>>>
+		<PERFORM ,V?LISTEN ,CONVERSATION>
+		<RTRUE>)
+	       (<AND <VERB? ASK-ABOUT>
+		     <PRSI? ,OBJECT-OF-GAME>>
+		<TELL
+"Prosser pulls a booklet out of his back pocket. \"My game manual says that the
+goal is getting this here house knocked down.\"" CR>)
+	       (<AND <VERB? ASK-ABOUT>
+		     <PRSI? ,DIGITAL-WATCH>>
+		<PERFORM ,V?ASK-FOR ,PROSSER ,TIME>
+		<RTRUE>)
+	       (<AND <VERB? ASK-FOR>
+		     <PRSI? ,TIME>>
+		<TELL
+"Prosser shakes the " D ,DIGITAL-WATCH ". \"Hasn't worked for months. I keep
+wearing it only because I think " D ,DIGITAL-WATCH "es are neat.\"" CR>)>>
+
+<ROUTINE STAND-ASIDE ()
+	 <COND (,PROSSER-LYING
+		<TELL "\"Leave me alone,\" Prosser whimpers miserably." CR>
+		<RTRUE>)>
+	 <TELL "\"Please step aside as I need to be able to ">
+	 <COND (,HOUSE-DEMOLISHED
+		<TELL "clear this " D ,RUBBLE " away.\"" CR>)
+	       (T
+		<TELL "knock ">
+		<COND (<EQUAL? ,IDENTITY-FLAG ,ARTHUR>
+		       <TELL "your">)
+		      (T
+		       <TELL "that">)>
+		<TELL " house down.\"" CR>)>>
+
+<OBJECT DIGITAL-WATCH
+	(IN PROSSER)
+	(DESC "digital watch")
+	(SYNONYM WATCH WATCHE)
+	(ADJECTIVE DIGITA)
+	(FLAGS NDESCBIT TRYTAKEBIT)
+	(ACTION DIGITAL-WATCH-F)>
+
+<ROUTINE DIGITAL-WATCH-F ()
+	 <COND (<VERB? TAKE READ>
+		<PRIVATE "Prosser">)>>
+
+<OBJECT TIME
+	(IN GLOBAL-OBJECTS)
+	(DESC "time")
+	(SYNONYM TIME)>
+
+<OBJECT FORD
+	(IN LOCAL-GLOBALS) ;"just for the purpose of MOBY-FIND"
+	(DESC "Ford Prefect")
+	(DESCFCN FORD-DESCFCN)
+	(SYNONYM FORD PREFEC)
+	(ADJECTIVE FORD)
+	(FLAGS ACTORBIT CONTBIT SEARCHBIT OPENBIT NARTICLEBIT)
+	(ACTION FORD-F)>
+
+<ROUTINE FORD-DESCFCN ("OPTIONAL" X)
+	 <COND (,FORD-SLEEPING
+		<TELL "Ford is in the corner, snoring loudly." CR>)
+	       (T
+		<TELL D ,FORD " is here." CR>)>>
+
+<ROUTINE FORD-F ()
+	 <COND (<EQUAL? ,IDENTITY-FLAG ,FORD>
+		<COND (<EQUAL? ,FORD ,PRSO>
+		       <PERFORM ,PRSA ,ME ,PRSI>
+		       <RTRUE>)
+		      (T
+		       <PERFORM ,PRSA ,PRSO ,ME>
+		       <RTRUE>)>)
+	       (<EQUAL? ,FORD ,WINNER>
+		<COND (<IN? ,FLEET ,HERE>
+		       <TELL ,ABOVE-NOISE CR>
+		       <FUCKING-CLEAR>)
+		      (<OR <PRSI? ,HOUSE>
+			   <PRSO? ,HOUSE>>
+		       <TELL
+"\"It's not a house, it's a home.\" (Footnote 2)" CR>
+		       <FUCKING-CLEAR>)
+		      (<AND <VERB? TELL-ABOUT>
+			    <PRSO? ,ME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,FORD ,PRSI>
+		       <SETG WINNER ,FORD>
+		       <RTRUE>)
+		      (<VERB? HELLO>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?HELLO ,FORD>
+		       <SETG WINNER ,FORD>
+		       <RTRUE>)
+		      (<AND <VERB? WHAT>
+			    <PRSO? ,OBJECT-OF-GAME>>
+		       <TELL ,ASK-ABOUT-OBJECT CR>)
+		      (<AND <VERB? WHAT-ABOUT>
+			    <L? ,FORD-COUNTER 2>
+			    <EQUAL? ,HERE ,FRONT-OF-HOUSE>
+			    <PRSO? ,HOME>>
+		       <TELL "Ford">
+		       <FORD-DECIDES>)
+		      (<AND <VERB? WHAT-ABOUT>
+			    <PRSO? ,HOME ,THIRD-PLANET>
+			    ,EARTH-DEMOLISHED>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,FORD ,THIRD-PLANET>
+		       <SETG WINNER ,FORD>
+		       <RTRUE>)
+		      (<NOT ,EARTH-DEMOLISHED>
+		       <COND (<AND <L? ,DRUNK-LEVEL 3>
+				   <EQUAL? ,HERE ,PUB>>
+			      <TELL
+"\"Shut up and drink your beer. You're going to need it.\"" CR>)
+			     (T
+			      <TELL "Ford, busy ">
+			      <COND (<EQUAL? ,FORD-COUNTER 2>
+				     <TELL "talking to Prosser">)
+				    (T
+				     <TELL "scanning the sky ">)>
+			      <COND (<EQUAL? ,HERE ,PUB>
+				     <TELL "through the window">)
+				    (<NOT <EQUAL? ,FORD-COUNTER 2>>
+				     <TELL "for something">)>
+			      <TELL ", ignores you." CR>)>
+		       <ENABLE <QUEUE I-FORD 2>>)
+		      (T
+		       <TELL "Ford seems deep in thought." CR>
+		       <FUCKING-CLEAR>)>)
+	       (<AND <VERB? TELL TELL-ABOUT HELLO ASK-FOR ASK-ABOUT>
+		     <PRSO? ,FORD>
+		     ,FORD-SLEEPING>
+		<TELL "Ford is sleeping!" CR>
+		<FUCKING-CLEAR>)
+	       (<AND <VERB? GIVE>
+		     <PRSI? ,FORD>
+		     ,FORD-SLEEPING>
+		<PERFORM ,V?HELLO ,FORD>
+		<RTRUE>)
+	       (<AND <EQUAL? ,FOLLOW-FLAG 1>
+		     <NOT <IN? ,FORD ,HERE>>
+		     <VERB? FOLLOW>>
+		<TELL
+"In a state of anxiety and confusion you follow Ford down the lane..." CR CR>
+		<GOTO <LOC ,FORD>>)
+	       (<AND <EQUAL? ,FOLLOW-FLAG 3>
+		     <VERB? FOLLOW>>
+		<DO-WALK ,P?WEST>)
+	       (<AND <VERB? FOLLOW>
+		     <EQUAL? ,FOLLOW-FLAG 5>>
+		<DO-WALK ,P?SOUTH>)
+	       (<AND <VERB? ALARM SHAKE>
+		     ,FORD-SLEEPING>
+		<TELL "Rather like trying to wake the dead." CR>)
+	       (<AND <VERB? ASK-ABOUT>
+		     <PRSI? ,OBJECT-OF-GAME>>
+		<TELL ,ASK-ABOUT-OBJECT CR>)
+	       (<AND <VERB? ASK-ABOUT>
+		     <PRSI? ,THIRD-PLANET>>
+		<TELL
+"Ford explains that the Earth has been demolished. To cheer you up, he points
+out that there are an awful lot of little planets like that around, and the
+Earth wasn't even a particularly nice one." CR>)
+	       (<AND <VERB? GIVE>
+		     <PRSO? ,THUMB>
+		     <IN? ,FLEET ,HERE>>
+		<TELL "You can't reach him in this wind." CR>)
+	       (<VERB? LISTEN>
+		<COND (<NOT <FSET? ,CONVERSATION ,INVISIBLE>>
+		       <PERFORM ,V?LISTEN ,CONVERSATION>
+		       <RTRUE>)
+		      (,FORD-SLEEPING
+		       <TELL "\"Zzzzzzz...\"" CR>)>)
+	       (<AND <VERB? EXAMINE>
+		     ,FORD-SLEEPING>
+		<TELL "He's sleeping." CR>)
+	       (<AND <VERB? ASK-FOR>
+		     <PRSI? ,TOWEL>
+		     <EQUAL? ,FORD-COUNTER 0 1>>
+		<PERFORM ,V?TAKE ,TOWEL>
+		<RTRUE>)>>
+
+<ROUTINE FORD-DECIDES ()
+	 <FCLEAR ,CONVERSATION ,INVISIBLE>
+	 <ENABLE <QUEUE I-FORD 2>>
+	 <SETG FORD-COUNTER 2>
+	 <TELL
+" looks startled, then guilty. He starts to say something and stops.
+He starts to say something else and stops. Suddenly he seems to see the "
+D ,BULLDOZER " for the first time, stops starting to say things and starts.|
+|
+He seems to come to a momentous decision, says he has something of
+Earth-shattering importance to tell you, and stresses the importance
+of a quick drink at the Horse 'n Groom.||">
+	 <BUT-THAT-MAN "you exclaim">
+	 <TELL
+" Ford goes off for a quiet word with Prosser. From where you're lying,
+you cannot hear what's happening, although they seem deeply engrossed in "
+D ,CONVERSATION "." CR>>
+
+<GLOBAL FORD-COUNTER 0>
+
+<GLOBAL FORD-SLEEPING <>>
+
+<GLOBAL GUARDS-COUNTER 0>
+
+<GLOBAL HEART-COUNTER 0>
+
+<ROUTINE I-FORD ()
+	 <ENABLE <QUEUE I-FORD -1>>
+	 <COND (<IN-HEART? ,PROTAGONIST>
+		<SETG HEART-COUNTER <+ ,HEART-COUNTER 1>>
+		<COND (<EQUAL? ,HEART-COUNTER 1>
+		       <MOVE ,FORD ,HERE>
+		       <TELL CR
+"\"This looks like that incredible new" ,IID " spaceship, " D ,HEART-OF-GOLD
+"!\" says Ford, with growing excitement." CR CR ,ANNOUNCEMENT D ,EDDIE ". We
+have just picked up two hitchhikers">
+		       <FACTOR "21,914">
+		       <TELL "\"" CR>)
+		      (<EQUAL? ,HEART-COUNTER 2>
+		       <TELL CR
+"\"Come on, let's look for the Bridge.\" You follow Ford, and eventually
+come to the..." CR CR>
+		       <GOTO ,BRIDGE>
+		       <MOVE ,FORD ,HERE>)
+		      (<EQUAL? ,HEART-COUNTER 3>
+		       <COND (<NOT <EQUAL? ,HERE ,BRIDGE>>
+				   <RFALSE>)>
+		       <TELL CR
+"\"Hey, Zaphod, how ya doing?\" says Ford. He's cool. \"Not bad, Ford. Great to
+see you,\" replies Zaphod. He's cooler. You suddenly realise that the woman is
+Tricia MacMillan (\"Call me " D ,TRILLIAN "\"), whom you were trying to pick up
+at a party in Islington just a few weeks ago, and that Zaphod is the guy she
+eventually left the party with! Odd." CR>)
+		      (<EQUAL? ,HEART-COUNTER 4>
+		       <MOVE ,FORD ,LOCAL-GLOBALS>
+		       <MOVE ,ZAPHOD ,LOCAL-GLOBALS>
+		       <MOVE ,TRILLIAN ,LOCAL-GLOBALS>
+		       <MOVE ,HANDBAG ,BRIDGE>
+		       <MOVE ,SATCHEL ,BRIDGE>
+		       <FCLEAR ,HANDBAG ,NDESCBIT>
+		       <FCLEAR ,HANDBAG ,TRYTAKEBIT>
+		       <DISABLE <INT I-FORD>>
+		       <ENABLE <QUEUE I-MARVIN -1>>
+		       <COND (<EQUAL? ,HERE ,BRIDGE>
+			      <SETG FOLLOW-FLAG 3>
+			      <ENABLE <QUEUE I-FOLLOW 2>>
+			      <TELL CR
+"\"Like my spaceship, Ford?\" Zaphod asks. \"YOUR spaceship?\" says Ford,
+losing his cool for a second. \"Yeah, I stole it,\" Zaphod admits. \"I'm gonna
+use it to find" ,LOST-PLANET ". Let's go sit in the sauna while I explain.\"
+Zaphod, Ford, and " D ,TRILLIAN " all head off to port." CR>)
+			     (T
+			      <RFALSE>)>)>)
+	       (<EQUAL? ,HERE ,HOLD>
+		<COND (<FSET? ,CAPTAINS-QUARTERS ,TOUCHBIT>
+		       <SETG GUARDS-COUNTER <+ ,GUARDS-COUNTER 1>>
+		       <COND (<EQUAL? ,GUARDS-COUNTER 1>
+			      <TELL CR
+"The guard releases you and Ford and begins cycling the air in the
+airlock. \"Hey, guard!\" shouts Ford, \"do you really enjoy this sort
+of thing? Shouting, stomping around, shooting people, is it really a
+fulfilling career?\"" CR>)
+			     (<EQUAL? ,GUARDS-COUNTER 6>
+			      <DISABLE <INT I-FORD>>
+			      <MOVE ,SATCHEL ,FORD>
+			      <FCLEAR ,SATCHEL ,NDESCBIT>
+			      <SETG PANEL-BLOCKER <>>
+			      <FSET ,HOLD ,REVISITBIT>
+			      <TELL CR "The guard says, \"">
+			      <COND (<HELD? ,BABEL-FISH ,PROTAGONIST>
+				     <TELL
+"Well, all things considered, I guess I like being a guard. Especially
+the shouting. Resistance is useless!\"">)
+				    (T
+				     <TELL "I">
+				     <PRODUCE-GIBBERISH 3>)>
+			      <TELL
+" He throws you and Ford into the airlock and closes the door." CR CR>
+			      <GOTO ,AIRLOCK>
+			      <MOVE ,FORD ,AIRLOCK>)
+			     (T
+			      <TELL CR
+"Ford continues trying to talk the guard into a sudden career change." CR>)>)
+		      (T
+		       <MOVE ,GUIDE ,PROTAGONIST>
+		       <DISABLE <INT I-FORD>>
+		       <SETG FORD-SLEEPING T>
+		       <COND (<IN? ,MINERAL-WATER ,FORD>
+			      <MOVE ,MINERAL-WATER ,SATCHEL>)>
+		       <COND (<IN? ,TOWEL ,FORD>
+			      <MOVE ,TOWEL ,HERE>)>
+		       <MOVE ,SATCHEL ,HERE>
+		       <FCLEAR ,SATCHEL ,TRYTAKEBIT>
+		       <TELL CR
+"Ford yawns. \"Matter transference always tires me out. I'm going to take a
+nap.\" He places something on top of his satchel. \"If you have any questions,
+here's " ,GUIDE-NAME "\" (Footnote 14). Ford lowers his voice to a whisper.
+\"I'm not supposed to tell you this, but you'll never be able to finish the
+game without consulting the Guide about lots of stuff.\" As he curls up in a
+corner and begins snoring, you pick up " D ,GUIDE "." CR>)>)
+	       (<EQUAL? ,FORD-COUNTER 0>
+		<SETG FORD-COUNTER 1>
+		<TELL CR
+"Ford glances uncomfortably at the sky. He offers you the towel again." CR>)
+	       (<EQUAL? ,FORD-COUNTER 1>
+		<TELL CR "Ford seems oblivious to your trouble, so you ask
+\"Ford, what about my home?\" He">
+		<FORD-DECIDES>)
+	       (<EQUAL? ,FORD-COUNTER 2>
+		<SETG FORD-COUNTER 3>
+	        <SETG LYING-DOWN <>>
+		<SETG PROSSER-LYING T>
+	        <ENABLE <QUEUE I-FORD 2>>
+		<FSET ,CONVERSATION ,INVISIBLE>
+	        <TELL CR
+"Ford and Prosser stop talking and approach you. Ford says that Prosser has
+agreed to lie in your place so that the two of you can go off to the Pub.
+Reluctantly, Prosser steps forward and lies down in front of the " D ,BULLDOZER
+". You stand up." CR>)
+	       (<EQUAL? ,FORD-COUNTER 3>
+		<MOVE ,FORD ,COUNTRY-LANE>
+		<SETG FORD-COUNTER 4>
+		<COND (<EQUAL? ,HERE ,FRONT-OF-HOUSE>
+		       <SETG FOLLOW-FLAG 1>
+		       <ENABLE <QUEUE I-FOLLOW 2>>
+		       <TELL
+"Ford, urging you to follow, hurries toward the country lane." CR>)
+		      (<EQUAL? ,HERE ,COUNTRY-LANE>
+		       <TELL "Ford enters from the north." CR>)
+		      (T
+		       <RFALSE>)>)
+	       (<AND <EQUAL? ,FORD-COUNTER 4>
+		     <EQUAL? ,HERE ,COUNTRY-LANE>
+		     <NOT <FSET? ,PUB ,TOUCHBIT>>>
+		<SETG FORD-COUNTER 5>
+		<SETG FOLLOW-FLAG 1>
+		<ENABLE <QUEUE I-FOLLOW 2>>
+		<MOVE ,FORD ,PUB>
+		<TELL CR
+"\"Come along, Arthur,\" says Ford impatiently, and enters the Pub." CR>)
+	       (<AND <NOT <IN? ,FORD ,HERE>>
+		     <FSET? ,PUB ,TOUCHBIT>>
+		<MOVE ,FORD ,HERE>
+		<TELL CR "Ford hurries after you." CR>)
+	       (<L? ,DRUNK-LEVEL 3>
+		<COND (<AND <PRSO? ,BEER>
+			    <VERB? DRINK ENJOY>>
+		       <RFALSE>)
+		      (<AND <EQUAL? ,L-PRSO ,BEER>
+			    <VERB? AGAIN>
+			    <EQUAL? ,L-PRSA ,V?DRINK ,V?ENJOY>>
+		       <RFALSE>)
+		      (<NOT <EQUAL? ,HERE ,PUB>>
+		       <RFALSE>)
+		      (<FSET? ,BEER ,NDESCBIT>
+		       <RFALSE>)>
+		<TELL CR "\"Drink the beer,\" urges Ford. \"It will help">
+		<CUSHION>
+		<TELL "\"" CR>)
+	       (T
+		<RFALSE>)>>
+
+<OBJECT SATCHEL
+	(IN FORD)
+	(DESC "satchel")
+	(DESCFCN SATCHEL-DESCFCN)
+	(SYNONYM SATCHE)
+	(ADJECTIVE BATTER LEATHE BULKY)
+	(FLAGS CONTBIT SEARCHBIT TAKEBIT TRYTAKEBIT)
+	(CAPACITY 30)
+	(SIZE 20)
+	(ACTION SATCHEL-F)>
+
+<ROUTINE SATCHEL-DESCFCN ("OPTIONAL" X)
+	 <TELL "There is a satchel here">
+	 <COND (<EQUAL? ,PANEL-BLOCKER ,SATCHEL>
+		<TELL ", resting in front of the " D ,ROBOT-PANEL>)>
+	 <TELL ".">
+	 <ITEM-ON-SATCHEL-DESCRIPTION>
+	 <CRLF>
+	 <RTRUE>>
+
+<ROUTINE ITEM-ON-SATCHEL-DESCRIPTION ()
+	 <COND (,ITEM-ON-SATCHEL
+		<TELL " Sitting on top of it is">
+		<ARTICLE ,ITEM-ON-SATCHEL>
+		<TELL ".">)>>
+
+<ROUTINE SATCHEL-F ()
+	 <COND (<AND <VERB? OPEN>
+		     <NOT <EQUAL? ,IDENTITY-FLAG ,FORD>>>
+		<PRIVATE "Ford">)
+	       (<AND <VERB? PUT-ON>
+		     <EQUAL? ,SATCHEL ,PRSI>>
+		<COND (<HELD? ,SATCHEL>
+		       <TELL "Put down the satchel first." CR>)
+		      (,ITEM-ON-SATCHEL
+		       <TELL "But">
+		       <ARTICLE ,ITEM-ON-SATCHEL T>
+		       <TELL " is already on the satchel." CR>)
+		      (T
+		       <SETG ITEM-ON-SATCHEL ,PRSO>
+		       <MOVE ,PRSO ,HERE>
+		       <FSET ,PRSO ,NDESCBIT>
+		       <FSET ,PRSO ,TRYTAKEBIT>
+		       <TELL "Okay,">
+		       <ARTICLE ,PRSO T>
+		       <TELL " is now sitting on the satchel." CR>)>)
+	       (<VERB? EXAMINE>
+		<TELL "The satchel, which is ">
+		<COND (<FSET? ,SATCHEL ,OPENBIT>
+		       <TELL "open">)
+		      (T
+		       <TELL "closed">)>
+		<TELL ", is fairly bulky.">
+		<ITEM-ON-SATCHEL-DESCRIPTION>
+		<CRLF>)
+	       (<AND <VERB? TAKE>
+		     <IN? ,SATCHEL ,FORD>>
+		<TELL
+"Ford says, \"Hey, Arthur, keep " D ,HANDS "s off my satchel!\"" CR>)>>
+
+<OBJECT SATCHEL-FLUFF
+	(IN SATCHEL)
+	(DESC "satchel fluff")
+	(SYNONYM FLUFF LINT)
+	(ADJECTIVE SATCHE)
+	(FLAGS TAKEBIT NARTICLEBIT)
+	(SIZE 1)
+	(GENERIC POCKET-FLUFF)>
+
+<GLOBAL FLUFF-TO-GOWN <>>
+
+<GLOBAL TOWEL-MUDDY <>>
+
+<GLOBAL TOWEL-OFFERED <>>
+
+<OBJECT TOWEL
+	(IN FORD)
+	(DESC "towel")
+        (SYNONYM TOWEL TOWELS)
+	(FLAGS TAKEBIT TRYTAKEBIT)
+	(SIZE 7)
+	(CAPACITY 40)
+	(ACTION TOWEL-F)>
+
+<ROUTINE TOWEL-F ()
+	 <COND (<AND <VERB? TAKE>
+		     <FSET? ,TOWEL ,TRYTAKEBIT>
+		     <EQUAL? ,HERE ,FRONT-OF-HOUSE>
+		     ,LYING-DOWN>
+		<FCLEAR ,TOWEL ,TRYTAKEBIT>
+		<MOVE ,TOWEL ,PROTAGONIST>
+		<MOVE ,FORD ,LOCAL-GLOBALS>
+		<SETG FORD-GONE T>
+		<SETG FOLLOW-FLAG 5>
+		<ENABLE <QUEUE I-FOLLOW 2>>
+		<DISABLE <INT I-FORD>>
+		<TELL
+"As you take it, Ford says \"Er, look, thanks for lending me the towel...
+been nice knowing you... got to go now...\" He smiles oddly and walks down
+the " D ,COUNTRY-LANE "." CR>)
+	       (<AND <VERB? TAKE MOVE>
+		     <PRSO? ,TOWEL>
+		     <FSET? ,TOWEL ,SURFACEBIT>>
+		<FCLEAR ,TOWEL ,TRYTAKEBIT>
+		<FCLEAR ,TOWEL ,SURFACEBIT>
+		<ROB ,TOWEL ,HERE>
+		<FCLEAR ,TOWEL ,CONTBIT>
+		<FCLEAR ,TOWEL ,OPENBIT>
+		<FCLEAR ,TOWEL ,NDESCBIT>
+		<COND (<VERB? MOVE>
+		       <TELL "Okay, it's no longer covering the drain." CR>)
+		      (T
+		       <RFALSE>)>)
+	       (<AND <VERB? PUT-ON TIE>
+		     <PRSI? ,BEAST>>
+		<TELL "The effect is decorative rather than helpful." CR>)
+	       (<AND <VERB? PUT-ON TIE>
+		     <PRSI? ,HEAD ,EYES>>
+		<COND (<FSET? ,TOWEL ,WORNBIT>
+		       <TELL "It already is." CR>)
+		      (<IN? ,BEAST ,HERE>
+		       <FSET ,TOWEL ,WORNBIT>
+		       <MOVE ,TOWEL ,PROTAGONIST>
+		       <ENABLE <QUEUE I-BEAST 11>>
+		       <TELL
+"The " D ,BEAST " is completely bewildered. It is so dim it thinks that
+if you can't see it, it can't see you. You have a few seconds before it
+realises its mistake." CR>)
+		      (T
+		       <TELL
+"There's no need for that. It's not like there's a " D ,BEAST " around,
+or something." CR>)>)
+	       (<AND <FSET? ,TOWEL ,WORNBIT>
+		     <VERB? TAKE-OFF REMOVE UNTIE>>
+		<FCLEAR ,TOWEL ,WORNBIT>
+		<TELL "You unwrap the towel from your head.">
+		<COND (<FSET? ,BEAST ,MUNGEDBIT>
+		       <CRLF> <CRLF>
+		       <V-LOOK>
+		       <RTRUE>)>
+		<COND (,BEARINGS-LOST
+		       <TELL " You see that you have wandered in circles">
+		       <COND (<EQUAL? ,HERE ,OUTER-LAIR>
+			      <TELL
+" and ended right beside the " D ,MEMORIAL>)>
+		       <TELL ".">)>
+		<TELL
+" Unfortunately, the Beast has also caught sight of you again. All this
+fooling around has made it doubly angry and hungry. ">
+		<BEAST-DEATH>
+		<RTRUE>)
+	       (<VERB? EXAMINE>
+		<COND (<FSET? ,TOWEL ,SURFACEBIT>
+		       <PERFORM ,V?EXAMINE ,DRAIN>
+		       <COND (<FIRST? ,TOWEL>
+			      <RFALSE>)>
+		       <RTRUE>)
+		      (,TOWEL-MUDDY
+		       <TELL "It is caked with mud." CR>)
+		      (T
+		       <TELL
+"It's covered with little pink and blue flowers." CR>)>)
+	       (<AND <VERB? LIE-DOWN>
+		     <FSET? ,TOWEL ,SURFACEBIT>>
+		<PERFORM ,V?STAND-BEFORE ,HOOK>
+		<RTRUE>)>>
+
+<ROOM BACK-OF-HOUSE
+      (IN ROOMS)
+      (SYNONYM LIST QUESTI)
+      (ADJECTIVE GREAT UNANSW)
+      (DESC "Back of House")
+      (SE TO FRONT-OF-HOUSE)
+      (SW TO FRONT-OF-HOUSE)
+      (FLAGS RLANDBIT ONBIT OUTSIDEBIT)
+      (GLOBAL HOUSE HOME THIRD-PLANET RUBBLE)
+      (PSEUDO "TREE" TREE-PSEUDO "BIRDS" UNIMPORTANT-THING-F)
+      (ACTION BACK-OF-HOUSE-F)>
+
+<ROUTINE BACK-OF-HOUSE-F (RARG)
+	 <COND (<AND <EQUAL? .RARG ,M-END>
+		     <NOT <RUNNING? ,I-VOGONS>>
+ 		     ,HOUSE-DEMOLISHED>
+		<I-VOGONS>
+		<ENABLE <QUEUE I-VOGONS 2>>)
+	       (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"The rear garden is a pleasant place. I" ,NICE-DAY ", and it's a lovely day for
+a walk. A path leads around the house to the southeast and southwest." CR>)>>
+
+<ROUTINE TREE-PSEUDO ()
+	 <COND (<VERB? CLIMB-UP CLIMB-FOO>
+		<TELL "You were never very good at that." CR>)>>
+
+<ROOM COUNTRY-LANE
+      (IN ROOMS)
+      (SYNONYM SPACE)
+      (DESC "Country Lane")
+      (NORTH TO FRONT-OF-HOUSE)
+      (WEST TO PUB)
+      (IN TO PUB)
+      (FLAGS RLANDBIT ONBIT OUTSIDEBIT)
+      (GLOBAL HOUSE HOME PUB-OBJECT BULLDOZER THIRD-PLANET)
+      (PSEUDO "TREE" TREE-PSEUDO)
+      (ACTION COUNTRY-LANE-F)>
+
+<ROUTINE COUNTRY-LANE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<COND (<AND <NOT ,PROSSER-LYING>
+			    <NOT ,HOUSE-DEMOLISHED>
+			    <NOT <FSET? ,HOLD ,TOUCHBIT>>>
+		       <SETG BULLDOZER-COUNTER 3>
+		       <I-BULLDOZER>)
+		      (<AND <EQUAL? ,IDENTITY-FLAG ,FORD>
+			    ,HOUSE-DEMOLISHED>
+		       <ENABLE <QUEUE I-DOG 1>>
+		       <RFALSE>)
+		      (<AND <EQUAL? ,DRUNK-LEVEL 3>
+			    <EQUAL? ,IDENTITY-FLAG ,ARTHUR>>
+		       <ENABLE <QUEUE I-DOG 1>>
+		       <RFALSE>)
+		      (<AND <FSET? ,HOLD ,TOUCHBIT>
+			    <NOT <FSET? ,COUNTRY-LANE ,NDESCBIT>>>
+		       <PUT ,FORD-TABLE 0 <LOC ,SATCHEL>>
+		       <PUT ,FORD-TABLE 1 <LOC ,THUMB>>
+		       <PUT ,FORD-TABLE 2 <LOC ,GUIDE>>
+		       <PUT ,FORD-TABLE 3 <LOC ,TOWEL>>
+		       <PUT ,FORD-TABLE 5 <LOC ,MINERAL-WATER>>
+		       <COND (<FSET? ,THUMB ,MUNGEDBIT>
+			      <PUT ,FORD-TABLE 4 T>
+			      <FCLEAR ,THUMB ,MUNGEDBIT>)>
+		       <FSET ,COUNTRY-LANE ,NDESCBIT>
+		       <ROB ,PROTAGONIST ,MEMORIAL>
+		       <MOVE ,SATCHEL ,PROTAGONIST>
+		       <MOVE ,THUMB ,SATCHEL>
+		       <MOVE ,GUIDE ,SATCHEL>
+		       <MOVE ,TOWEL ,SATCHEL>
+		       <MOVE ,MINERAL-WATER ,SATCHEL>
+		       <MOVE ,ARTHUR ,FRONT-OF-HOUSE>
+		       <SETG IDENTITY-FLAG ,FORD>
+		       <MOVE ,FORD ,GLOBAL-OBJECTS>
+		       <MOVE ,PEANUTS ,PUB>
+		       <FSET ,PEANUTS ,TRYTAKEBIT>
+		       <FSET ,PEANUTS ,NDESCBIT>
+		       <SETG PEANUTS-BOUGHT <>>
+		       <SETG DREAMING T>
+		       <ENABLE <QUEUE I-VOGONS 38>>
+		       <TELL
+"You are hurrying up a country lane. The sky is light and clear, but you keep
+glancing at it with apprehension because you know that it will shortly be torn
+apart by Vogon ships, and that the hills and trees around you will just burn
+up and blow away, and you hope there's time for a quick drink beforehand.|
+|
+You want to hitch a ride aboard the Vogon fleet, but are anxious because it's
+so long since you were through a" ,BEAM "." CR CR>)>)
+	       (<AND <EQUAL? .RARG ,M-END>
+		     <FSET? ,COUNTRY-LANE ,REVISITBIT>>
+		<SETG DREAMING T>
+		<TELL
+"Suddenly a shadow passes in front of the sun. You look up. The shadow is a "
+D ,FLEET ". You fumble for ">
+		<JIGS-UP
+"your Thumb, but before you can hitch a ride the planet is destroyed.">
+		<RTRUE>)
+	       (<EQUAL? .RARG ,M-LOOK>
+		<TELL "The road runs from ">
+		<COND (<EQUAL? ,IDENTITY-FLAG ,ARTHUR>
+		       <TELL "your">)
+		      (T
+		       <TELL "Arthur's">)>
+		<TELL
+" home, to the north, toward the village Pub, to the west." CR>)>>
+
+<ROUTINE I-DOG ()
+	 <COND (<EQUAL? ,HERE ,WAR-CHAMBER>
+		<SETG DOG-COUNTER <+ ,DOG-COUNTER 1>>
+		<COND (<AND <L? ,DOG-COUNTER 13>
+			    <VERB? WAIT>>
+		       <RFALSE>)>
+		<CRLF>
+		<COND (<L? ,DOG-COUNTER 13>
+		       <TELL "The fleet continues to hurtle sunwards." CR>)
+		      (,DOG-FED
+		       <SETG LYING-DOWN <>>
+		       <TELL
+"Your simple act of kindness at a moment of great personal anxiety (you fed
+the dog, remember?) now brings rich rewards. " ,FLEET-PLUNGES " spots the dog
+(which appears to them as a gigantic monster) cheerfully tucking into a
+" D ,SANDWICH ".|
+|
+The Vl'Hurgs and the G'Gugvunts are moved by this simple picture of happiness,
+compared with the furious savagery of their own lives. They think back to a day
+when they used to relax over an odd " D ,SANDWICH " themselves, often at sunset
+after a hearty day working in the fields back in Vl'Hurgon and G'Gugvia, and
+decide to return and rebuild their homes in a new spirit of harmony and
+cooperation.|
+|
+Grateful, they offer to drop you at " D ,HEART-OF-GOLD " on the way home.
+After a brief 900 parsec trip, you are escorted into the Transporter Chamber
+of the warship. The transporter glows, and your surroundings change..." CR CR>
+		       <GOTO ,MAZE>)
+		      (T
+		       <TELL ,FLEET-PLUNGES>
+		       <JIGS-UP 
+", due to a terrible miscalculation in scale, is swallowed by a small dog.">
+		       <RTRUE>)>)
+	       (<EQUAL? ,IDENTITY-FLAG ,FORD>
+		<MOVE ,DOG ,HERE>
+		<DISABLE <INT I-DOG>>
+	 	<TELL "You run up the lane after Arthur. You pass a">
+	 	<COND (,DOG-FED
+		       <TELL
+" serene dog. Fate cannot harm him, he has dined today." CR>)
+	       	      (T
+		       <TELL "n irritable dog who yaps at you." CR>)>)
+	       (<AND <NOT <IN? ,DOG ,HERE>>
+		     <NOT <IN? ,FLEET ,HERE>>
+		     <EQUAL? ,HERE ,COUNTRY-LANE>>
+		<MOVE ,DOG ,HERE>
+		<ENABLE <QUEUE I-DOG 2>>
+	        <TELL
+"You see the huge " D ,BULLDOZER " heaving itself among the cloud of brick dust
+which is all that remains of " D ,HOME ". As you start up the lane, a small dog
+runs up to you, yapping." CR>)
+	       (<AND <NOT ,DOG-FED>
+		     <IN? ,DOG ,HERE>
+		     <NOT <FSET? ,DOG ,TOUCHBIT>>>
+		<FSET ,DOG ,TOUCHBIT>
+		<TELL
+"The dog carries on yapping for a moment and then gulps uncomfortably." CR>)
+	       (T
+		<RFALSE>)>>
+
+<OBJECT DOG
+	(IN LOCAL-GLOBALS) ;"just for the purpose of MOBY-FIND"
+	(DESC "dog")
+	(SYNONYM DOG MONGRE)
+	(ADJECTIVE SMALL SERENE IRRITA)
+        (ACTION DOG-F)>
+
+<ROUTINE DOG-F ()
+	 <COND (<VERB? GIVE THROW>
+		<COND (<PRSO? ,SANDWICH>
+		       <COND (<EQUAL? ,IDENTITY-FLAG ,FORD>
+			      <MOVE ,SANDWICH ,HERE>
+			      <TELL
+"The dog is in a bad mood and tries to bite " D ,HANDS ". The " D ,SANDWICH
+" lies ignored in the roadside dust." CR>)
+			     (<FSET? ,DOG ,TOUCHBIT> ;"already swallowed fleet"
+			      <TELL
+"The dog, which seems to have a slight case of indigestion,
+ignores the " D ,SANDWICH "." CR>)
+			     (T
+			      <MOVE ,SANDWICH ,LOCAL-GLOBALS>
+			      <SETG DOG-FED T>
+			      <TELL
+"The dog is deeply moved. With powerful sweeps of its tail it indicates that
+it regards this " D ,SANDWICH " as one of the great " D ,SANDWICH "es. Nine
+out of ten pet owners could happen by at this point expressing any preference
+they pleased, but this dog would spurn both them and all their tins. This is
+a dog which has met its main sandwich. It eats" ,WITH-PASSION CR>)>)
+		      (<PRSO? ,PEANUTS>
+		       <TELL "This is a dog, not an elephant." CR>)>)
+	       (<AND <VERB? EXAMINE>
+		     <NOT ,DOG-FED>>
+		<TELL "The mongrel looks hungry." CR>)
+	       (<VERB? RUB KICK PUSH>
+		<TELL "The dog tries to bite your ">
+		<COND (<VERB? KICK>
+		       <TELL "foot">)
+		      (T
+		       <TELL "hand">)>
+		<TELL "." CR>)>>
+
+<OBJECT PUB-OBJECT
+	(IN LOCAL-GLOBALS)
+	(DESC "Pub")
+	(SYNONYM PUB GROOM)
+	(ADJECTIVE HORSE \'N)
+	(ACTION PUB-OBJECT-F)>
+
+<ROUTINE PUB-OBJECT-F ()
+	 <COND (<VERB? WALK-TO THROUGH>
+		<COND (<EQUAL? ,HERE ,PUB>
+		       <TELL ,LOOK-AROUND CR>)
+		      (<EQUAL? ,HERE ,COUNTRY-LANE>
+		       <DO-WALK ,P?WEST>)
+		      (T
+		       <V-WALK-AROUND>)>)
+	       (<VERB? EXIT LEAVE DISEMBARK>
+		<COND (<EQUAL? ,HERE ,PUB>
+		       <DO-WALK ,P?EAST>)
+		      (T
+		       <TELL ,LOOK-AROUND CR>)>)>>
+
+<ROOM PUB
+      (IN ROOMS)
+      (SYNONYM ALCOHO)
+      (DESC "Pub")
+      (EAST TO COUNTRY-LANE)
+      (OUT TO COUNTRY-LANE)
+      (FLAGS RLANDBIT ONBIT OUTSIDEBIT)
+      (GLOBAL PUB-OBJECT WINDOW THIRD-PLANET PUB-FURNISHINGS)
+      (PSEUDO "PEOPLE" UNIMPORTANT-THING-F)
+      (ACTION PUB-F)>
+
+<ROUTINE PUB-F (RARG)
+	 <COND (<AND <EQUAL? .RARG ,M-ENTER>
+		     <NOT ,TOWEL-OFFERED>
+		     <AND <EQUAL? ,IDENTITY-FLAG ,FORD>>>
+		<ENABLE <QUEUE I-UNEASY -1>>
+		<RFALSE>)
+	       (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"The Pub is pleasant and cheerful and full of pleasant and cheerful people who
+don't know they've got about twelve minutes to live and are therefore having a
+spot of lunch. Some music is playing on an old jukebox. The exit is east." CR>)
+	       (<AND <EQUAL? .RARG ,M-END>
+		     <FSET? ,BEER ,NDESCBIT>
+		     <IN? ,FORD ,HERE>
+		     <NOT <EQUAL? ,IDENTITY-FLAG ,FORD>>>
+		<FCLEAR ,BEER ,NDESCBIT>
+		<ENABLE <QUEUE I-FORD 2>>
+		<SETG FORD-COUNTER 5>
+		<CRLF>
+		<TELL
+"Ford buys " D ,BEER " and offers half to you. \"Muscle relaxant...\" he
+says, impenetrably." CR>)>>
+
+<OBJECT BAR
+	(IN PUB)
+	(DESC "bar")
+	(SYNONYM BAR COUNTE)
+	(FLAGS NDESCBIT CONTBIT SURFACEBIT OPENBIT)
+	(CAPACITY 60)
+	(ACTION BAR-F)>
+
+<ROUTINE BAR-F ()
+	 <COND (<VERB? LOOK-BEHIND>
+		<PERFORM ,V?EXAMINE ,PUB-SHELF>
+		<RTRUE>)>>
+
+<OBJECT PUB-SHELF
+	(IN PUB)
+	(DESC "shelf of items")
+	(LDESC
+"Behind the bar is a shelf. It is full of the sort of items you find on shelves
+behind bars in pubs.")
+	(SYNONYM SHELF ITEMS SHELVE)
+	(ACTION PUB-SHELF-F)>
+
+<ROUTINE PUB-SHELF-F ()
+	 <COND (<VERB? EXAMINE>
+		<FSET ,PUB-SHELF ,NDESCBIT>
+		<TELL
+"On the shelf behind the bar is the usual array of bottles, glasses
+and soggy beermats">
+		<COND (<NOT ,PEANUTS-BOUGHT>
+		       <FSET ,PEANUTS ,TAKEBIT>
+		       <FSET ,PEANUTS ,TRYTAKEBIT>
+		       <COND (,SANDWICH-BOUGHT
+			      <TELL ", and">)
+			     (T
+			      <TELL ",">)>
+		       <TELL " some packets of peanuts">)>
+		<COND (<NOT ,SANDWICH-BOUGHT>
+		       <FSET ,SANDWICH ,TAKEBIT>
+		       <FSET ,SANDWICH ,TRYTAKEBIT>
+		       <TELL ", and a plate of uninviting " D ,SANDWICH "es">)>
+		<TELL "." CR>)>>
+
+<OBJECT MUSIC
+	(IN PUB)
+	(DESC "music")
+	(SYNONYM MUSIC SONG SONGS)
+	(FLAGS NARTICLEBIT NDESCBIT)
+	(ACTION MUSIC-F)>
+
+<ROUTINE MUSIC-F ()
+	 <COND (<VERB? LISTEN ENJOY>
+		<PERFORM ,V?LISTEN ,JUKEBOX>
+		<RTRUE>)>>
+
+<OBJECT JUKEBOX
+	(IN PUB)
+	(DESC "jukebox")
+	(SYNONYM JUKEBO BOX)
+	(ADJECTIVE JUKE OLD)
+	(FLAGS NDESCBIT LIGHTBIT ONBIT)
+	(ACTION JUKEBOX-F)>
+
+<ROUTINE JUKEBOX-F ()
+	 <COND (<VERB? LISTEN>
+		<TELL "The song is ">
+		<COND (<PROB 25>
+		       <TELL
+"a Walker Brothers single, \"The Sun Ain't Gonna Shine Anymore.\"" CR>)
+		      (<PROB 33>
+		       <TELL
+"\"Get Back\" by the Beatles." CR>)
+		      (<PROB 50>
+		       <TELL
+"\"Hey Jude\" by the Beatles (Footnote 4). It's a particular favourite, and
+listening to it calms you down, and cheers you up." CR>)
+		      (T
+		       <TELL "\"Tie a Yellow Ribbon.\"">
+		       <COND (<EQUAL? ,IDENTITY-FLAG ,FORD>
+			      <TELL
+" You can't stand it, and are pleased to think that this is probably the
+last time it will ever be heard.">)>
+		       <CRLF>)>)
+	       (<VERB? LAMP-OFF>
+		<PRIVATE "the Pub">)>>
+
+<OBJECT PUB-FURNISHINGS
+	(IN LOCAL-GLOBALS)
+	(DESC "it")
+	(SYNONYM BEERMA GLASSE BOTTLE GLASS)
+	(ADJECTIVE USUAL SOGGY)
+	(FLAGS NDESCBIT NARTICLEBIT)
+	(GENERIC MINERAL-WATER)
+	(ACTION UNIMPORTANT-THING-F)>
+
+<OBJECT BARMAN
+	(IN PUB)
+	(DESC "barman")
+	(LDESC "There is a barman serving at the bar.")
+	(SYNONYM BARMAN BARTEN)
+	(FLAGS ACTORBIT)
+	(ACTION BARMAN-F)>
+
+<ROUTINE BARMAN-F ()
+	 <COND (<EQUAL? ,BARMAN ,WINNER>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <PRSO? ,ME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,BARMAN ,PRSI>
+		       <SETG WINNER ,BARMAN>
+		       <RTRUE>)
+		      (<VERB? HELLO>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?HELLO ,BARMAN>
+		       <SETG WINNER ,BARMAN>
+		       <RTRUE>)
+		      (<AND <VERB? GIVE>
+			    <PRSO? ,ME>
+			    <PRSI? ,SANDWICH ,BEER ,PEANUTS>>
+		       <PERFORM ,V?BUY ,PRSI>
+		       <RTRUE>)
+		      (T
+		       <TELL
+"The barman ignores you and keeps polishing the other end of the bar." CR>)>)
+	       (<AND <VERB? ASK-FOR>
+		     <PRSI? ,SANDWICH ,BEER ,PEANUTS>>
+		<PERFORM ,V?BUY ,PRSI>
+		<RTRUE>)>>
+
+<OBJECT BEER
+	(IN PUB)
+	(DESC "lots of beer")
+	(SYNONYM LOTS BITTER PINT BEER)
+	(FLAGS DRINKBIT NARTICLEBIT NDESCBIT)
+	(ACTION BEER-F)>
+
+<GLOBAL DRUNK-LEVEL 0>
+
+<GLOBAL FORD-POINT 15>
+
+<ROUTINE BEER-F ()
+	 <COND (<AND <VERB? DRINK ENJOY COUNT SMELL RUB TAKE>
+		     <FSET? ,BEER ,NDESCBIT>>
+		<TELL "You'd better buy some first." CR>)
+	       (<VERB? COUNT>
+		<TELL "Lots." CR>)
+	       (<VERB? TAKE>
+		<TELL "Just drink it!" CR>)
+	       (<EQUAL? ,IDENTITY-FLAG ,FORD>
+		<COND (<VERB? BUY>
+		       <COND (<NOT <FSET? ,BEER ,NDESCBIT>>
+			      <TELL "You already did!" CR>
+			      <RTRUE>)>
+		       <FCLEAR ,BEER ,NDESCBIT>
+		       <COND (<IN? ,ARTHUR ,HERE>
+			      <TELL
+"You order six pints of bitter -- three for you, three for Arthur. According
+to " D ,GUIDE " this should">
+			      <CUSHION>
+			      <TELL CR CR
+"As you drink the first pint, you mention to Arthur that you are from a
+different planet, but it makes little impression. This surprises you, because
+you thought it was the sort of thing that would interest people." CR>)
+			     (T
+			      <TELL
+"You buy yourself three pints, which you calculate you will need to">
+			      <CUSHION>
+			      <TELL
+" This is a tip you picked up from " D ,GUIDE "." CR>)>)
+		      (<VERB? DRINK ENJOY>
+		       <SETG DRUNK-LEVEL <+ ,DRUNK-LEVEL 1>>
+		       <COND (<NOT <IN? ,ARTHUR ,HERE>>
+			      <TELL ,DOWN-WELL>
+			      <CRLF>)
+			     (<EQUAL? ,DRUNK-LEVEL 1>
+			      <SETG SCORE <+ ,SCORE ,FORD-POINT>>
+			      <SETG FORD-POINT 0>
+			      <TELL
+,DOWN-WELL " At least they managed to get something right on this benighted
+planet. You decide it's time to tell Arthur that the world is about to end.
+You tell him. Arthur is completely unperturbed. Curious. You wonder what sort
+of news it would take to disturb him." CR>)
+			     (<EQUAL? ,DRUNK-LEVEL 2>
+			      <TELL ,DOWN-WELL>
+			      <SCENE-THROUGH-WINDOW>)
+			     (T
+			      <TELL "You've had enough." CR>)>)>)
+	       (T
+		<COND (<VERB? DRINK ENJOY>
+		       <SETG SCORE <+ ,SCORE 5>>
+		       <SETG DRUNK-LEVEL <+ ,DRUNK-LEVEL 1>>
+		       <COND (<EQUAL? ,DRUNK-LEVEL 4>
+			      <TELL
+"You can hear the muffled noise of your home being demolished, and the
+taste of the beer sours in your mouth." CR CR>
+		              <PERFORM ,V?GET-DRUNK ,ROOMS>
+			      <RTRUE>)
+			     (<EQUAL? ,DRUNK-LEVEL 3>
+			      <ENABLE <QUEUE I-FORD -1>>
+			      <SETG HOUSE-DEMOLISHED T>
+			      <SETG PROSSER-LYING <>>
+			      <TELL
+"There is a distant crash which Ford explains is nothing to worry about,
+probably just your house being knocked down." CR>)
+			     (<EQUAL? ,DRUNK-LEVEL 2>
+			      <TELL
+"It is really very pleasant stuff, with a very good dry, nutty flavour, some
+light froth on top, and a deep colour. It is at exactly room temperature. You
+reflect that the world cannot be all bad when there are such pleasures in it.|
+|
+Ford mentions that the world is going to end in about twelve minutes." CR>)
+			     (<EQUAL? ,DRUNK-LEVEL 1>
+			      <TELL
+"It's very good beer, brewed by a small local company. You particularly like
+its flavour, which is why you woke up feeling so wretched this morning. You
+were at somebody's birthday party here in the Pub last night.|
+|
+You begin to relax and enjoy yourself, so when Ford mentions that he's from a
+small planet in the vicinity of Betelgeuse, not from Guildford as he usually
+claims, you take it in your stride, and say \"Oh yes, which part?\"" CR>)>)
+		      (<VERB? BUY>
+		       <COND (<FSET? ,BEER ,NDESCBIT>
+			      <PERFORM ,V?BUY ,PEANUTS>
+			      <RTRUE>)
+			     (T
+			      <TELL
+D ,FORD " has already bought an enormous quantity for you!" CR>)>)>)>>
+
+<OBJECT PEANUTS
+	(IN PUB)
+	(DESC "peanuts")
+	(SYNONYM PACKET PEANUT NUT NUTS)
+	(FLAGS TRYTAKEBIT NDESCBIT NARTICLEBIT EATBIT)
+	(ACTION PEANUTS-F)>
+
+<ROUTINE PEANUTS-F ()
+	 <COND (<AND <EQUAL? ,IDENTITY-FLAG ,FORD>
+		     <VERB? BUY>>
+		<COND (,PEANUTS-BOUGHT
+		       <TELL "You did!" CR>
+		       <RTRUE>)>
+		<SETG PEANUTS-BOUGHT T>
+		<MOVE ,PEANUTS ,PROTAGONIST>
+		<FCLEAR ,PEANUTS ,TRYTAKEBIT>
+		<FCLEAR ,PEANUTS ,NDESCBIT>
+		<TELL
+"You buy some peanuts, which you'll need to replace protein loss from the"
+,BEAM ", a tip you picked up from " D ,GUIDE "." CR>)
+	       (<VERB? OPEN>
+		<TELL "Just eat 'em." CR>)
+	       (<AND <VERB? EAT ENJOY>
+		     ,EARTH-DEMOLISHED
+		     ,GROGGY>
+		<SETG GROGGY <>>
+		<MOVE ,PEANUTS ,PUB>
+		<FSET ,PEANUTS ,TRYTAKEBIT>
+		<FSET ,PEANUTS ,NDESCBIT>
+		<TELL
+"You feel stronger as the peanuts replace some of the protein you lost
+in the" ,BEAM "." CR>)
+	       (<AND <VERB? BUY>
+		     <EQUAL? ,HERE ,PUB>>
+		<TELL
+"However much you clear your throat, wave your forefinger, or wiggle your
+eyebrows, the barman pays no attention, but carries on wiping another part
+of the bar." CR>)
+	       (<AND <VERB? TAKE EAT>
+		     <FSET? ,PEANUTS ,TRYTAKEBIT>
+		     <EQUAL? ,HERE ,PUB>>
+		<TELL ,HANDS-OFF CR>)>>
+
+<OBJECT SANDWICH
+	(IN PUB)
+	(DESC "cheese sandwich")
+	(SYNONYM PLATE SANDWI)
+	(ADJECTIVE CHEESE UNINVI)
+	(FLAGS NDESCBIT EATBIT TRYTAKEBIT)
+	(SIZE 10)
+	(ACTION SANDWICH-F)>
+
+<ROUTINE SANDWICH-F ()
+	 <COND (<AND <VERB? BUY>
+		     <NOT ,SANDWICH-BOUGHT>>
+	        <MOVE ,SANDWICH ,PROTAGONIST>
+		<FSET ,SANDWICH ,TAKEBIT>
+	        <FCLEAR ,SANDWICH ,TRYTAKEBIT>
+		<FCLEAR ,SANDWICH ,NDESCBIT>
+		<SETG SANDWICH-BOUGHT T>
+		<TELL
+"The barman gives you a " D ,SANDWICH ". The bread is like the stuff that
+stereos come packed in, the cheese would be great for rubbing out spelling
+mistakes, and margarine and pickle have performed an unedifying chemical
+reaction to produce something that shouldn't be, but is, turquoise. Since
+it is clearly unfit for human consumption you are grateful to be charged
+only a pound for it." CR>)
+	       (<VERB? BUY>
+		<TELL "You already did." CR>)
+	       (<AND <VERB? TAKE EAT ENJOY>
+		     <FSET? ,SANDWICH ,TRYTAKEBIT>
+		     <EQUAL? ,HERE ,PUB>>
+		<TELL ,HANDS-OFF CR>)
+	       (<VERB? EAT ENJOY>
+		<MOVE ,SANDWICH ,LOCAL-GLOBALS>
+		<SETG SCORE <- ,SCORE 30>>
+		<COND (<EQUAL? ,IDENTITY-FLAG ,FORD>
+		       <TELL
+"You swallow with revulsion, astonished that life forms which have spent 4.6
+billion years evolving cannot produce a better " D ,SANDWICH " than this." CR>)
+		      (T
+		       <TELL
+"It is one of the least rewarding taste experiences you can recall." CR>)>)>>
+
+<GLOBAL DOG-FED <>>
+
+<GLOBAL PEANUTS-BOUGHT <>>
+
+<GLOBAL SANDWICH-BOUGHT <>>
+
+<GLOBAL VOGON-COUNTER 0>
+
+<GLOBAL FORD-GONE <>>
+
+<ROUTINE I-VOGONS ()
+	 <ENABLE <QUEUE I-VOGONS -1>>
+	 <SETG VOGON-COUNTER <+ ,VOGON-COUNTER 1>>
+	 <COND (<EQUAL? ,VOGON-COUNTER 1>
+		<COND (<EQUAL? ,HERE ,PUB>
+			      <GO-TO-LANE>)>
+		<MOVE ,FLEET ,HERE>
+		<CRLF>
+		<COND (<EQUAL? ,IDENTITY-FLAG ,FORD>
+		       <MOVE ,ARTHUR ,HERE>
+		       <TELL
+"Right on schedule (according to the news you picked up last night on your
+Sub-Etha Sens-O-Matic), a huge " D ,FLEET " hurtles noisily through the sky.
+Time is very, very short. Storms break in the wake of the ships, the wind
+whips at you and makes it difficult to stand. You grab hold of a tree." CR>)
+		      (T
+		       <TELL
+"With a noise like a cross between Led Zeppelin's farewell concert and the
+eruption of Krakatoa, a huge " D ,FLEET " flies overhead and announces that
+the Earth will be demolished to make way for a new hyperspace bypass in \"two
+of your Earth minutes.\"" CR>
+		       <COND (<AND <IN? ,FORD ,HERE>
+				   <EQUAL? ,FORD-COUNTER 0>>
+			      <MOVE ,FORD ,LOCAL-GLOBALS>
+			      <DISABLE <INT I-FORD>>
+			      <SETG FORD-GONE T>
+			      <MOVE ,TOWEL ,HERE>
+			      <FCLEAR ,TOWEL ,TRYTAKEBIT>
+			      <TELL CR
+"Ford drops the towel and dashes away." CR>)>
+		       <COND (<HELD? ,THING>
+			      <MOVE ,THING ,LOCAL-GLOBALS>
+			      <TELL CR "In all the turmoil, ">
+			      <COND (<IN? ,THING ,GOWN>
+				     <TELL
+"the " D ,THING " drops out of your pocket and rolls away.">)
+				    (T
+				     <TELL
+"you drop the " D ,THING " and it rolls away.">)>
+			      <TELL
+" It is the least of your worries. Anyway," ,GET-RID CR>)>)>)
+	       (<EQUAL? ,VOGON-COUNTER 2>
+		<CRLF>
+		<TELL
+"The vast yellow ships thunder across the sky, spreading waves of terror and
+panic in their wake. The voice of the " D ,VOGON-CAPTAIN " slams across the
+country, insisting that the planning charts and demolition orders have been
+available at the local planning office in Alpha Centauri for fifty years and
+it's too late to start making a fuss about it now.">
+		<CRLF>
+		<COND (,FORD-GONE
+		       <RTRUE>)>
+		<CRLF>
+		<COND (<EQUAL? ,IDENTITY-FLAG ,FORD>
+		       <COND (<HELD? ,THUMB ,PROTAGONIST>
+			      <COND (<IN? ,THUMB ,PROTAGONIST>
+				     <TELL
+"The " D ,THUMB " in " D ,HANDS " begins to whine.">)
+				    (T
+				     <TELL
+"You remove the " D ,THUMB " from your satchel.">)>
+			      <TELL
+" Lights pulsate across its surface. " ,THUMB-FUMBLE>
+			      <MOVE ,THUMB ,HERE>
+			      <SETG P-IT-OBJECT ,THUMB>)
+			     (T
+			      <TELL
+"You wish you were holding your " D ,THUMB ".">)>
+		       <TELL
+" Arthur is struggling desperately towards you. The end of this planet is
+now only seconds away." CR>)
+		      (T
+		       <MOVE ,THUMB ,HERE>
+		       <SETG P-IT-OBJECT ,THUMB>
+		       <TELL 
+"Throughout the noise, Ford is shouting at you. He removes a small black
+device from his satchel, but accidentally drops it at your feet." CR>)>)
+	       (<EQUAL? ,VOGON-COUNTER 3>
+		<CRLF>
+		<TELL
+"Fierce gales whip across the land, and thunder bangs continuously through
+the air in the wake of the giant ships. ">
+		<COND (<AND <EQUAL? ,IDENTITY-FLAG ,ARTHUR>
+			    <NOT ,FORD-GONE>>
+		       <TELL
+"Ford fights to reach you, but the wind is too fierce. Further announcements
+from the " D ,VOGON-CAPTAIN " make it clear that demolition will begin in
+just a few seconds.|
+|
+Through the blinding rain, you see lights flickering on the small device." CR>)
+		      (<AND <EQUAL? ,IDENTITY-FLAG ,FORD>
+			    <IN? ,THUMB ,HERE>>
+		       <COND (,FLUFF-TO-GOWN
+			      <FSET ,COUNTRY-LANE ,REVISITBIT>)>
+		       <TELL ,DRIVEN-BACK>
+		       <TELL
+" Fortunately, at this point, Arthur picks up the Thumb, and somehow
+manages to push the right button">
+		       <COND (<FSET? ,THUMB ,MUNGEDBIT>
+			      <TELL ". Unfortunately, the" ,THUMB-CLICKS>
+			      <SETG VOGON-COUNTER 4>
+			      <TELL " ">
+			      <I-VOGONS>
+			      <RTRUE>)
+			     (T
+			      <TELL "." CR CR>
+			      <JIGS-UP
+"However often you do it, you are still stunned by the shock of
+dematerialisation. The scene around is ripped away like a flimsy backcloth.">
+			      <RTRUE>)>)
+		      (T
+		       <CRLF>)>)
+	       (<EQUAL? ,VOGON-COUNTER 5>
+		<TELL "The Earth is destroyed by the " D ,FLEET>
+		<COND (,FLUFF-TO-GOWN
+		       <FSET ,COUNTRY-LANE ,REVISITBIT>)>
+		<JIGS-UP ".">
+		<RTRUE>)>>
+
+<ROUTINE GO-TO-LANE ()
+	 <SETG LYING-DOWN <>>
+	 <TELL CR "You hear sounds of panic from the street. You ">
+	 <COND (<AND <EQUAL? ,IDENTITY-FLAG ,FORD>
+		     <NOT <IN? ,ARTHUR ,HERE>>>
+		<TELL "leave the Pub and run into Arthur..." CR CR>)
+	       (T
+		<COND (<EQUAL? ,IDENTITY-FLAG ,FORD>
+		       <TELL "and Arthur">)
+		      (T
+		       <TELL "and Ford">)>
+		<TELL " rush outside..." CR CR>)>
+	 <GOTO ,COUNTRY-LANE>
+	 <COND (<EQUAL? ,IDENTITY-FLAG ,FORD>
+		<MOVE ,ARTHUR ,COUNTRY-LANE>)
+	       (T
+		<MOVE ,FORD ,COUNTRY-LANE>)>>
+
+<GLOBAL FORD-TABLE
+	<TABLE 0 0 0 0 0>>
+
+<OBJECT FLEET
+	(IN LOCAL-GLOBALS) ;"just for the purpose of MOBY-FIND"
+	(DESC "fleet of Vogon Constructor ships")
+	(SYNONYM FLEET SHIP SHIPS SPACES)
+	(ADJECTIVE VOGON CONSTR HUGE UGLY YELLOW)
+	(FLAGS NDESCBIT)
+	(ACTION FLEET-F)>
+
+<ROUTINE FLEET-F ()
+	 <COND (<VERB? ENJOY>
+		<TELL ,ZEN CR>)
+	       (<VERB? WALK-TO THROUGH>
+		<SETG AWAITING-REPLY 11>
+		<ENABLE <QUEUE I-REPLY 2>>
+		<TELL "From here?" CR>)
+	       (<AND <VERB? EXAMINE>
+		     <NOT <EQUAL? ,HERE ,HOLD ,AIRLOCK ,CAPTAINS-QUARTERS>>>
+		<TELL
+"The fleet consists of terrifying numbers of huge, ugly, yellow ships, all
+scarred with the results of many such past demolition jobs. Chicago's John
+Hancock tower, knocked about a bit and painted yellow, is what they each look
+like. That is, knocked about a bit, painted yellow, and flying." CR>)>>
+
+<GLOBAL EARTH-DEMOLISHED <>>
+
+<ROUTINE LEAVE-EARTH ()
+	 <DISABLE <INT I-HOUSEWRECK>>
+	 <DISABLE <INT I-BULLDOZER>>
+	 <DISABLE <INT I-PROSSER>>
+	 <DISABLE <INT I-FORD>>
+	 <DISABLE <INT I-VOGONS>>
+	 <SETG HEADACHE <>>
+	 <SETG BULLDOZER-COUNTER 0>
+	 <SETG PROSSER-COUNTER 0>
+	 <SETG PROSSER-LYING <>>
+	 <SETG FORD-COUNTER 0>
+	 <SETG DRUNK-LEVEL 0>
+	 <SETG HOUSE-DEMOLISHED <>>
+	 <SETG VOGON-COUNTER 0>
+	 <SETG EARTH-DEMOLISHED T>
+	 <SETG IDENTITY-FLAG ,ARTHUR>
+	 <MOVE ,ARTHUR ,GLOBAL-OBJECTS>
+	 <MOVE ,DOG ,LOCAL-GLOBALS>
+	 <MOVE ,FLEET ,LOCAL-GLOBALS>
+	 <MOVE ,FORD ,LOCAL-GLOBALS>
+	 <COND (<AND <NOT <HELD? ,SANDWICH>>
+		     ,SANDWICH-BOUGHT>
+		<MOVE ,SANDWICH ,LOCAL-GLOBALS>)>
+	 <FSET ,BEER ,NDESCBIT>
+	 <FCLEAR ,PROSSER ,TOUCHBIT>
+	 <FCLEAR ,FRONT-OF-HOUSE ,NDESCBIT>
+	 <FCLEAR ,FRONT-OF-HOUSE ,TOUCHBIT>
+	 <FCLEAR ,COUNTRY-LANE ,TOUCHBIT>>
+
+;"second time around"
+
+<OBJECT ARTHUR
+	(IN LOCAL-GLOBALS) ;"just for the purpose of MOBY-FIND"
+	(DESC "Arthur Dent")
+	(LDESC "Arthur Dent is here.")
+	(SYNONYM ARTHUR DENT)
+	(ADJECTIVE ARTHUR)
+	(FLAGS NARTICLEBIT VOWELBIT ACTORBIT)
+	(ACTION ARTHUR-F)>
+
+<ROUTINE ARTHUR-F ()
+	 <COND (<EQUAL? ,IDENTITY-FLAG ,ARTHUR>
+		<COND (<EQUAL? ,ARTHUR ,PRSO>
+		       <PERFORM ,PRSA ,ME ,PRSI>
+		       <RTRUE>)
+		      (T
+		       <PERFORM ,PRSA ,PRSO ,ME>
+		       <RTRUE>)>)
+	       (<EQUAL? ,ARTHUR ,WINNER>
+		<COND (<IN? ,FLEET ,HERE>
+		       <TELL ,ABOVE-NOISE CR>)
+		      (<AND <VERB? FOLLOW>
+			    <EQUAL? ,HERE ,FRONT-OF-HOUSE>
+			    <PRSO? ,ME>>
+		       <COND (,PROSSER-LYING
+			      <TELL "Arthur seems willing to do so." CR>)
+			     (T
+			      <BUT-THAT-MAN "Arthur exclaims">
+			      <CRLF>)>)
+		      (<AND <VERB? DRINK>
+			    <PRSO? ,BEER>>
+		       <COND (<FSET? ,BEER ,NDESCBIT>
+			      <SETG WINNER ,PROTAGONIST>
+			      <PERFORM ,V?DRINK ,BEER>
+			      <SETG WINNER ,ARTHUR>
+			      <RTRUE>)
+			     (T
+			      <TELL
+"Arthur seems to be waiting to follow your lead." CR>)>)
+		      (T
+		       <TELL "Arthur looks too confused to respond." CR>)>
+		<FUCKING-CLEAR>)
+	       (<AND <VERB? HELLO TELL ASK-FOR ASK-ABOUT TELL-ABOUT>
+		     <EQUAL? ,IDENTITY-FLAG ,TRILLIAN>
+		     <PRSO? ,ARTHUR>>
+		<COND (,FLUFF-REMOVED
+		       <I-ARTHUR>)
+		      (T
+		       <TELL
+"You approach Arthur. He seems to find your tone a little cool, smiles
+unhappily, and wanders to the other end of the room." CR>)>
+		<ENABLE <QUEUE I-ARTHUR 2>>
+		<FUCKING-CLEAR>)
+	       (<AND <VERB? TELL-ABOUT ASK-ABOUT ASK-FOR>
+		     <PRSO? ,ARTHUR>
+		     <EQUAL? ,IDENTITY-FLAG ,TRILLIAN>>
+		<PERFORM ,V?HELLO ,ARTHUR>
+		<RTRUE>)
+	       (<AND <VERB? CARVE>
+		     <PRSI? ,MEMORIAL>>
+		<PERFORM ,V?CARVE ,YOUR-NAME ,MEMORIAL>
+		<RTRUE>)
+	       (<AND <VERB? GIVE>
+		     <PRSO? ,TOWEL>
+		     <EQUAL? ,HERE ,FRONT-OF-HOUSE>
+		     <NOT ,TOWEL-OFFERED>>
+		<SETG TOWEL-OFFERED T>
+	        <TELL
+"Inexplicably, Arthur takes no notice of the towel which, magnificently, you
+are trying to return to him. Instead, he says, \"Ford, what about my home?\"|
+|
+You start guiltily. Does he actually KNOW that the Earth is about to be
+destroyed? You start to ask him, then stop. If he knows, what the Zark is he
+doing lying here in the mud in front of...|
+|
+You look around. You notice the " D ,BULLDOZER " properly for the first time.
+You notice Arthur's house. You notice the workmen. The penny drops. His HOUSE
+is about to be demolished. You feel like a complete...what's the word?">
+		<COND (<IDIOT?>
+		       <TELL
+"Thank you. An idiot is exactly what you feel like.">)
+		      (T
+		       <TELL
+"No, actually, \"idiot\" was the word I was looking for.">)>
+		<TELL CR CR
+"In a reckless moment you go completely mad and decide that you ought to take
+Arthur with you. You try to tell Arthur about the importance of getting a
+drink, but he's rambling on about a man called Prosser." CR>
+		<RFATAL>)
+	       (<AND <PRSO? ,SANDWICH>
+		     <VERB? GIVE>>
+		<MOVE ,SANDWICH ,ARTHUR>
+		<TELL
+"Arthur takes it, sniffs it suspiciously, and wisely decides that it's
+safer in his pocket than in his stomach." CR>)
+	       (<AND <VERB? GIVE>
+		     <PRSO? ,SATCHEL-FLUFF>>
+		<COND (,HOUSE-DEMOLISHED
+		       <MOVE ,SATCHEL-FLUFF ,LOCAL-GLOBALS>
+		       <SETG FLUFF-TO-GOWN T>
+		       <TELL
+"Arthur hiccups, takes the fluff, and sticks it in his pocket." CR>)
+		      (T
+		       <TELL
+"Arthur blinks several times, but doesn't take the fluff. Perhaps if he
+had a few drinks in him..." CR>)>)
+	       (<AND <VERB? EXAMINE>
+		     <EQUAL? ,IDENTITY-FLAG ,TRILLIAN>>
+		<TELL
+"Arthur seems nice and well meaning, but also terribly shy.">
+		<COND (<NOT ,FLUFF-REMOVED>
+		       <MOVE ,JACKET-FLUFF ,HERE>
+		       <ENABLE <QUEUE I-ARTHUR -1>>
+		       <TELL
+" He has tried to start a " D ,CONVERSATION " with you several times, but still
+hasn't gotten past \"Hello.\" He has an enormous, unsightly ball of fluff
+on his jacket.">)>
+		<CRLF>)
+	       (<AND <VERB? FOLLOW>
+		     <EQUAL? ,FOLLOW-FLAG 4>>
+		<DO-WALK ,P?EAST>)
+	       (<AND <VERB? PICK-UP>
+		     <EQUAL? ,IDENTITY-FLAG ,TRILLIAN>>
+		<PERFORM ,V?PICK-UP ,ZAPHOD>
+		<RTRUE>)
+	       (<AND <VERB? LISTEN>
+		     <EQUAL? ,IDENTITY-FLAG ,TRILLIAN>
+		     ,FLUFF-REMOVED>
+		<TELL "Unfortunately, you seem to have no choice." CR>)>> 
+
+<ROUTINE IDIOT? ()
+	 <CRLF> <CRLF>
+	 <PRINTI ">">
+	 <READ ,P-INBUF ,P-LEXV>
+	 <COND (<EQUAL? <GET ,P-LEXV 1> ,W?IDIOT>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<GLOBAL UNEASY-COUNTER 0>
+
+<GLOBAL IDENTITY-FLAG <>>
+
+<ROUTINE I-UNEASY ()
+	 <SETG UNEASY-COUNTER <+ ,UNEASY-COUNTER 1>>
+	 <COND (<NOT <EQUAL? ,HERE ,PUB>>
+		<DISABLE <INT I-UNEASY>>
+		<RFALSE>)>
+	 <CRLF>
+	 <COND (<EQUAL? ,UNEASY-COUNTER 1>
+		<TELL "You feel uneasy about something." CR>)
+	       (<EQUAL? ,UNEASY-COUNTER 2 3 4>
+		<TELL "You still feel uneasy." CR>)
+	       (T
+		<TELL
+"The sense of uneasiness you've been so busy ignoring now utterly engulfs you,
+as you realise that you've broken the fundamental rule of time travel: \"Do as
+you would have done by.\" The rational foundation of the Universe crashes and
+within a few seconds the whole of creation ceases ever to have exis" CR CR CR>
+		<QUIT>)>>
+
+<ROUTINE I-ARTHUR ()
+	 <ENABLE <QUEUE I-ARTHUR -1>>
+	 <COND (<EQUAL? ,IDENTITY-FLAG ,TRILLIAN>
+		<COND (,FLUFF-REMOVED
+		       <CRLF>
+		       <COND (<NOT <IN? ,ARTHUR ,HERE>>
+			      <MOVE ,ARTHUR ,HERE>
+			      <TELL
+"Arthur follows you like an eager puppy." CR>)
+			     (T
+			      <TELL
+"Arthur tries, unsuccessfully, to interest you by talking about "
+<PICK-ONE ,BORES> CR>)>)
+		      (<PROB 20>
+		       <MOVE ,ARTHUR ,HERE>
+		       <MOVE ,JACKET-FLUFF ,HERE>
+		       <TELL CR
+"Arthur walks up and says \"Hello, again.\" He looks shy, embarrassed and stuck
+for anything else to say, and quickly walks to the other end of the room." CR>)
+		      (T
+		       <RFALSE>)>)
+	       (<IN? ,ARTHUR ,HERE>
+		<RFALSE>)
+	       (T
+		<MOVE ,ARTHUR ,HERE>
+		<TELL "Arthur follows you." CR>)>>
+
+<GLOBAL BORES
+	<PLTABLE
+"newts he has known."
+"cricket."
+"how badly Americans make tea."
+"the deteriorating condition of the motorways."
+"a recent visit to Tiverton."
+"a new book by Douglas Adams."
+"computers.">>
+
+<ROUTINE SCENE-THROUGH-WINDOW ()
+	 <MOVE ,ARTHUR ,FRONT-OF-HOUSE>
+	 <DISABLE <INT I-ARTHUR>>
+	 <SETG HOUSE-DEMOLISHED T>
+	 <SETG PROSSER-LYING <>>
+	 <SETG FOLLOW-FLAG 4>
+	 <ENABLE <QUEUE I-FOLLOW 2>>
+	 <TELL
+" You hear a muffled crash. It's probably Arthur's little house getting knocked
+down, which you tell him. This DOES upset him, and he tears out the door.|
+|
+Through the window, you see him running up the lane. A small dog chases after
+him, yapping, ">
+	 <COND (<OR ,DOG-FED
+		    <IN? ,SANDWICH ,ARTHUR>>
+		<SETG DOG-FED T>
+		<TELL "and he throws it a " D ,SANDWICH
+". The dog devours the sandwich" ,WITH-PASSION CR>)
+	       (T
+		<TELL "but he ignores it. The dog gulps uncomfortably." CR>)>>
\ No newline at end of file
diff --git a/globals.zil b/globals.zil
new file mode 100644
index 0000000..8280612
--- /dev/null
+++ b/globals.zil
@@ -0,0 +1,2187 @@
+"GLOBALS for
+		  THE HITCHHIKER'S GUIDE TO THE GALAXY
+	(c) Copyright 1984 Infocom, Inc.  All Rights Reserved."
+
+<DIRECTIONS ;"Do not change the order of the first 8 without consulting MARC!"
+ 	    NORTH NE EAST SE SOUTH SW WEST NW UP DOWN IN OUT>
+
+<GLOBAL LYING-DOWN <>>
+
+<GLOBAL HERE <>>
+
+<GLOBAL LIT <>>
+
+<GLOBAL MOVES 0>
+
+<GLOBAL SCORE 0>
+
+<GLOBAL INDENTS
+	<PTABLE ""
+	        "  "
+	        "    "
+	        "      "
+	        "        "
+	        "          ">>
+
+;"global objects and associated routines"
+
+<OBJECT GLOBAL-OBJECTS
+	(FLAGS INVISIBLE TOUCHBIT SURFACEBIT TRYTAKEBIT OPENBIT REVISITBIT
+	       SEARCHBIT TRANSBIT WEARBIT MUNGEDBIT ONBIT RLANDBIT WORNBIT)>
+
+<OBJECT LOCAL-GLOBALS
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM ZZMGCK)
+	(DESCFCN 0)
+        (GLOBAL GLOBAL-OBJECTS)
+	(FDESC "F")
+	(LDESC "F")
+	(PSEUDO "FOOBAR" V-WALK)
+	(SIZE 0)
+	(TEXT "")
+	(CAPACITY 0)>
+;"Yes, this synonym for LOCAL-GLOBALS needs to exist... sigh"
+
+<OBJECT ROOMS
+	(IN TO ROOMS)>
+
+<OBJECT INTNUM
+	(IN GLOBAL-OBJECTS)
+	(DESC "number")
+	(SYNONYM INTNUM)
+	(ADJECTIVE NUMBER)>
+
+<OBJECT PSEUDO-OBJECT
+	(DESC "pseudo")
+	(ACTION ME-F)>
+
+<OBJECT IT
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM IT THEM HER HIM)
+	(DESC "it")
+	(FLAGS VOWELBIT NARTICLEBIT NDESCBIT TOUCHBIT)>
+
+<OBJECT NOT-HERE-OBJECT
+	(DESC "it")
+	(FLAGS NARTICLEBIT)
+	(ACTION NOT-HERE-OBJECT-F)>
+
+<ROUTINE NOT-HERE-OBJECT-F ("AUX" TBL (PRSO? T) OBJ (X <>))
+	 <COND (<AND <PRSO? ,NOT-HERE-OBJECT>
+		     <PRSI? ,NOT-HERE-OBJECT>>
+		<TELL "Those things aren't here!" CR>
+		<RTRUE>)
+	       (<PRSO? ,NOT-HERE-OBJECT>
+		<SET TBL ,P-PRSO>)
+	       (T
+		<SET TBL ,P-PRSI>
+		<SET PRSO? <>>)>
+	 <COND (.PRSO?
+		<COND (<OR <EQUAL? ,PRSA ,V?FIND ,V?FOLLOW ,V?CALL>
+			   <EQUAL? ,PRSA ,V?WHAT ,V?WHERE ,V?WHO>
+			   <EQUAL? ,PRSA ,V?WAIT-FOR ,V?WALK-TO ,V?WHAT-ABOUT>
+			   <EQUAL? ,PRSA ,V?I-AM ,V?CARVE ,V?CALL-WITH>>
+		       <SET X T>
+		       <COND (<SET OBJ <FIND-NOT-HERE .TBL .PRSO?>>
+			      <COND (<NOT <EQUAL? .OBJ ,NOT-HERE-OBJECT>>
+				     <RTRUE>)>)
+			     (T
+			      <RFALSE>)>)>)
+	       
+	       (T
+		<COND (<OR <EQUAL? ,PRSA ,V?ASK-ABOUT ,V?ASK-FOR ,V?TELL-ABOUT>
+			   <EQUAL? ,PRSA ,V?MY-NAME>>
+		       <SET X T>
+		       <COND (<SET OBJ <FIND-NOT-HERE .TBL .PRSO?>>
+			      <COND (<NOT <EQUAL? .OBJ ,NOT-HERE-OBJECT>>
+				     <RTRUE>)>)
+			     (T
+			      <RFALSE>)>)>)>
+;"Here is the default 'cant see any' printer"
+	 <COND (.X
+		<TELL "You'll have to be more specific, I'm afraid." CR>)
+	       (<EQUAL? ,WINNER ,PROTAGONIST>
+		<TELL "You can't ">
+		<COND (<EQUAL? ,P-XNAM ,W?POEM ,W?POETRY ,W?CONVER>
+		       <TELL "hear">)
+		      (T
+		       <TELL "see">)>
+		<COND (<NOT <NAME? ,P-XNAM>>
+		       <TELL " any">)> 
+		<NOT-HERE-PRINT .PRSO?>
+		<TELL " here!" CR>)
+	       (<OR <AND <EQUAL? ,WINNER ,FORD>
+			 ,FORD-SLEEPING>
+		    <AND <EQUAL? ,WINNER ,BEAST>
+			 <FSET? ,BEAST ,MUNGEDBIT>>>
+		<RFALSE>)
+	       (T
+		<TELL "Looking confused,">
+		<ARTICLE ,WINNER T>
+		<TELL " says, \"I don't see">
+		<COND (<NOT <NAME? ,P-XNAM>>
+		       <TELL " any">)>
+		<NOT-HERE-PRINT .PRSO?>
+		<TELL " here!\"" CR>)>
+	 <FUCKING-CLEAR>>
+
+<ROUTINE FIND-NOT-HERE (TBL PRSO? "AUX" M-F OBJ)
+;"Special-case code goes here. <MOBY-FIND .TBL> returns # of matches. If 1,
+then P-MOBY-FOUND is it. You can treat the 0 and >1 cases alike or differently.
+Always return RFALSE (not handled) if you have resolved the problem."
+	<SET M-F <MOBY-FIND .TBL>>
+	;<COND (,DEBUG
+	       <TELL "[Found " N .M-F " obj]" CR>)>
+	<COND (<EQUAL? 1 .M-F>
+	       ;<COND (,DEBUG
+		      <TELL "[Namely: " D ,P-MOBY-FOUND "]" CR>)>
+	       <COND (.PRSO?
+		      <SETG PRSO ,P-MOBY-FOUND>)
+		     (T
+		      <SETG PRSI ,P-MOBY-FOUND>)>
+	       <RFALSE>)
+	      (<EQUAL? ,P-XNAM ,W?FLUFF>
+	       <COND (.PRSO?
+		      <SETG PRSO ,POCKET-FLUFF>)
+		     (T
+		      <SETG PRSI ,POCKET-FLUFF>)>
+	       <RFALSE>)
+	      (<EQUAL? ,P-XNAM ,W?TOOL ,W?TOOLS>
+	       <COND (.PRSO?
+		      <SETG PRSO ,TWEEZERS>)
+		     (T
+		      <SETG PRSI ,TWEEZERS>)>
+	       <RFALSE>)
+	      (T
+	       ,NOT-HERE-OBJECT)>>
+
+<ROUTINE NOT-HERE-PRINT (PRSO?)
+	 <COND ;(<NAME? ,P-XNAM>
+		<TELL "one by that name">)
+	       (,P-OFLAG
+	        <COND (,P-XADJ
+		       <TELL " ">
+		       <PRINTB ,P-XADJN>)>
+	        <COND (,P-XNAM
+		       <TELL " ">
+		       <PRINTB ,P-XNAM>)>)
+               (.PRSO?
+	        <BUFFER-PRINT <GET ,P-ITBL ,P-NC1> <GET ,P-ITBL ,P-NC1L> <>>)
+               (T
+	        <BUFFER-PRINT <GET ,P-ITBL ,P-NC2> <GET ,P-ITBL ,P-NC2L> <>>)>>
+
+<OBJECT LIGHT
+	(IN GLOBAL-OBJECTS)
+	(DESC "light")
+	(SYNONYM LIGHT LIGHTS LAMP)
+	(FLAGS LIGHTBIT)
+        (ACTION LIGHT-F)>
+
+<ROUTINE LIGHT-F ()
+	 <COND (<AND <OR <IN? ,FLEET ,HERE>
+			 <EQUAL? ,HERE ,AIRLOCK ,INSIDE-WHALE>>
+		     <VISIBLE? ,THUMB>>
+		<COND (<EQUAL? ,LIGHT ,PRSI>
+		       <PERFORM ,PRSA ,PRSO ,THUMB>
+		       <RTRUE>)
+		      (T
+		       <PERFORM ,PRSA ,THUMB ,PRSI>
+		       <RTRUE>)>)
+	       (<EQUAL? ,HERE ,GALLEY>
+		<UNIMPORTANT-THING-F>)
+	       (<AND <EQUAL? ,LIGHT ,PRSO>
+		     <VERB? FIND FOLLOW WHAT WHERE WALK-TO WHAT-ABOUT>>
+		<RFALSE>)
+	       (<AND <EQUAL? ,LIGHT ,PRSI>
+		     <VERB? ASK-ABOUT TELL-ABOUT>>
+		<RFALSE>)
+	       (<NOT <EQUAL? ,HERE ,BEDROOM>>
+		<CANT-SEE ,LIGHT>)
+	       (<VERB? LAMP-ON>
+		<COND (<FSET? ,HERE ,ONBIT>
+		       <TELL "It is." CR>)
+		      (T
+		       <SETG LIT T>
+		       <FSET ,HERE ,ONBIT>
+		       <FSET ,DARK-OBJECT ,DARKBIT>
+		       <MOVE ,DARK-OBJECT ,DARK>
+		       <TELL
+"Good start to the day. Pity it's going to be the worst one of your
+life. The light is now on." CR CR>
+		       <V-LOOK>)>)
+	       (<VERB? LAMP-OFF>
+		<V-DIG>)>>
+
+<OBJECT GLOBAL-SLEEP
+	(IN GLOBAL-OBJECTS)
+	(DESC "sleep")
+	(SYNONYM SLEEP NAP SNOOZE)
+	(FLAGS NARTICLEBIT)
+	(ACTION GLOBAL-SLEEP-F)>
+
+<ROUTINE GLOBAL-SLEEP-F ()
+	 <COND (<VERB? WALK-TO TAKE>
+		<PERFORM ,V?SLEEP>
+		<RTRUE>)>>
+
+<OBJECT SPEECH
+	(IN GLOBAL-OBJECTS)
+	(DESC "speech")
+	(SYNONYM SPEECH)
+	(ACTION SPEECH-F)>
+
+<ROUTINE SPEECH-F ()
+	 <COND (<VERB? GIVE MAKE>
+		<TELL "This isn't the time">
+		<COND (<NOT <EQUAL? ,HERE ,DAIS>>
+		       <TELL " or the place">)>
+		<TELL " for making speeches." CR>)
+	       (<VERB? READ>
+		<TELL "It's extemporaneous." CR>)>>
+
+<OBJECT GROUND
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM FLOOR GROUND MUD)
+	(DESC "ground")
+	(ACTION GROUND-F)>
+
+<ROUTINE GROUND-F ()
+	 <COND (<AND <VERB? THROUGH>
+		     <EQUAL? ,HERE ,ACCESS-SPACE>>
+		<TELL "The mesh is too fine." CR>)
+	       (<VERB? CLIMB-UP CLIMB-ON CLIMB-FOO BOARD>
+		<V-DIG>)
+	       (<VERB? LOOK-UNDER>
+		<V-COUNT>)
+	       (<VERB? LEAVE>
+		<DO-WALK ,P?UP>)
+	       (<VERB? LIE-DOWN>
+		<COND (<IN? ,PROTAGONIST ,BED>
+		       <OUT-OF-FIRST ,BED>)
+		      (,LYING-DOWN
+		       <TELL ,YOU-ARE CR>)
+		      (<EQUAL? ,HERE ,FRONT-OF-HOUSE>
+		       <PERFORM ,V?BLOCK ,BULLDOZER>
+		       <SETG P-IT-OBJECT ,GROUND>
+		       <RTRUE>)
+		      (T
+		       <SETG LYING-DOWN T>
+		       <TELL "You are now lying on the ground." CR>)>)
+	       (<VERB? EXAMINE>
+		<COND (<EQUAL? ,HERE ,GUTS-ROOM>
+		       <TELL
+"The walls, floor, and ceiling are covered with little pieces of
+flesh and bone." CR>)
+		      (<EQUAL? ,HERE ,ACCESS-SPACE>
+		       <TELL
+"The floor is an open metal mesh, like the floor of a catwalk." CR>)>)
+	       (<AND <VERB? LOOK-INSIDE>
+		     <EQUAL? ,HERE ,ACCESS-SPACE>>
+		<PERFORM ,V?LOOK-INSIDE ,FISH-HOLE>
+		<SETG P-IT-OBJECT ,GROUND>
+		<RTRUE>)
+	       (<AND <VERB? ENJOY>
+		     <EQUAL? ,HERE ,FRONT-OF-HOUSE>
+		     ,LYING-DOWN>
+		<TELL
+"It occurs to you that you've never deliberately lain in any mud before and
+that it's actually a pleasant sort of squishy sensation. You let the mud ooze
+between your toes. You may be here for some time, so you may as well make the
+most of it." CR>)>>
+
+<OBJECT WALLS
+	(IN GLOBAL-OBJECTS)
+	(FLAGS NDESCBIT TOUCHBIT)
+	(DESC "wall")
+	(SYNONYM WALL WALLS)
+	(ACTION WALLS-F)>
+
+<ROUTINE WALLS-F ()
+	 <COND (<AND <VERB? EXAMINE>
+		     <EQUAL? ,HERE ,GUTS-ROOM>>
+		<PERFORM ,V?EXAMINE ,GROUND>
+		<RTRUE>)>>
+
+<OBJECT CEILING
+	(IN GLOBAL-OBJECTS)
+	(FLAGS NDESCBIT TOUCHBIT)
+	(DESC "ceiling")
+	(SYNONYM CEILIN ROOF)
+	(ACTION CEILING-F)>
+
+<ROUTINE CEILING-F ()
+	 <COND (<VERB? LOOK-UNDER>
+		<PERFORM ,V?LOOK>
+		<RTRUE>)
+	       (<AND <VERB? EXAMINE>
+		     <EQUAL? ,HERE ,GUTS-ROOM>>
+		<PERFORM ,V?EXAMINE ,GROUND>
+		<RTRUE>)>>
+
+<OBJECT WINDOW
+	(IN LOCAL-GLOBALS)
+	(DESC "window")
+	(SYNONYM WINDOW)
+	(FLAGS TRANSBIT)
+	(ACTION WINDOW-F)>
+
+<ROUTINE WINDOW-F ()
+	 <COND (<NOT ,LIT>
+		<TELL ,TOO-DARK CR>)
+	       (<VERB? MUNG>
+	        <PERFORM ,V?KILL ,WINDOW>
+	        <RTRUE>)
+	       (<EQUAL? ,HERE ,BEDROOM>
+		<COND (<VERB? LOOK-INSIDE EXAMINE>
+		       <PERFORM ,V?OPEN ,CURTAINS>
+		       <RTRUE>)
+		      (<VERB? OPEN CLOSE>
+		       <TELL
+"The bloody thing's been jammed shut for months, now." CR>)>)
+	       (<VERB? LOOK-INSIDE>
+		<TELL "You see the country lane." CR>)
+	       (<VERB? OPEN CLOSE>
+		<TELL ,BUDGE CR>)>>
+
+<OBJECT STAIRS
+	(IN LOCAL-GLOBALS)
+	(DESC "stairs")
+	(SYNONYM STAIR STAIRS STAIRW GANGWA)
+	(FLAGS NARTICLEBIT NDESCBIT)
+	(ACTION STAIRS-F)>
+
+<ROUTINE STAIRS-F ()
+	 <COND (<VERB? CLIMB-UP CLIMB-FOO>
+		<DO-WALK ,P?UP>)
+	       (<VERB? CLIMB-DOWN>
+		<DO-WALK ,P?DOWN>)>>
+
+<OBJECT AIR
+	(IN GLOBAL-OBJECTS)
+	(DESC "air")
+	(SYNONYM AIR)
+	(FLAGS VOWELBIT)>
+
+<OBJECT SKY
+	(IN GLOBAL-OBJECTS)
+	(DESC "sky")
+	(SYNONYM SKY)
+	(ACTION SKY-F)>
+
+<ROUTINE SKY-F ()
+	 <COND (<NOT <FSET? ,HERE ,OUTSIDEBIT>>
+		<CANT-SEE ,SKY>)
+	       (<AND <IN? ,FLEET ,HERE>
+		     <VERB? EXAMINE>>
+		<TELL
+"The sky is filled with the ships of the " D ,FLEET "." CR>)>>
+
+<OBJECT STAR
+	(IN GLOBAL-OBJECTS)
+	(DESC "sun")
+	(SYNONYM STAR SUN SYSTEM SOL)
+	(ADJECTIVE APPROA STAR SOLAR SMALL UNREGA YELLOW ORANGE)
+	(FLAGS NDESCBIT)
+	(ACTION STAR-F)>
+
+<ROUTINE STAR-F ()
+     <COND (<VERB? EXAMINE>
+	    <COND (<EQUAL? ,HERE ,WAR-CHAMBER>
+		   <TELL
+"The approaching star is a small, unregarded yellow sun, with nine planets of
+varying sizes. The " D ,THIRD-PLANET " catches your attention.">
+		   <CRLF>)
+		  (<EQUAL? ,HERE ,DAIS ,SPEEDBOAT>
+		   <TELL "The sun is a smallish orange star." CR>)
+		  (<EQUAL? ,HERE ,FRONT-OF-HOUSE ,COUNTRY-LANE ,BACK-OF-HOUSE>
+		   <TELL "The sun is a smallish yellow star." CR>)
+		  (T
+		   <CANT-SEE ,STAR>)>)>>
+
+<OBJECT HANDS
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM HANDS HAND)
+	(ADJECTIVE BARE MY YOUR)
+	(DESC "your hand")
+	(FLAGS NDESCBIT TOUCHBIT NARTICLEBIT)
+	(ACTION HANDS-F)>
+
+<ROUTINE HANDS-F (ACTOR)
+	 <COND (<VERB? WAVE>
+		<SETG PRSO <>>
+		<PERFORM ,V?WAVE-AT>
+		<RTRUE>)
+	       (<VERB? SHAKE>
+		<COND (<SET ACTOR <FIND-IN ,HERE ,ACTORBIT>>
+		       <PERFORM ,V?THANK .ACTOR>
+		       <RTRUE>)
+		      (T
+		       <TELL "Pleased to meet you." CR>)>)>>
+
+<OBJECT TEETH
+	(IN GLOBAL-OBJECTS)
+	(DESC "your teeth")
+	(SYNONYM TEETH)
+	(ADJECTIVE YOUR MY)
+	(FLAGS NARTICLEBIT)>
+
+<OBJECT HEAD
+	(IN GLOBAL-OBJECTS)
+	(DESC "your head")
+	(SYNONYM HEAD FACE)
+	(ADJECTIVE YOUR MY)
+	(FLAGS NARTICLEBIT)>
+
+<OBJECT EYES
+	(IN GLOBAL-OBJECTS)
+	(DESC "your eyes")
+	(SYNONYM EYE EYES)
+	(ADJECTIVE YOUR MY)
+	(FLAGS NARTICLEBIT)
+	(ACTION EYES-F)>
+
+<ROUTINE EYES-F ()
+	 <COND (<VERB? OPEN>
+		<TELL "They are." CR>)
+	       (<VERB? CLOSE>
+		<COND (<IN? ,BEAST ,HERE>
+		       <TELL "The Beast doesn't notice." ,GETTING-CLOSE CR>)
+		      (T
+		       <TELL "That won't help." CR>)>)>>
+
+<OBJECT EARS
+	(IN GLOBAL-OBJECTS)
+	(DESC "your ears")
+	(SYNONYM EAR EARS)
+	(ADJECTIVE YOUR MY)
+	(FLAGS NARTICLEBIT)>
+
+<OBJECT PROTAGONIST
+	(SYNONYM PROTAG)
+	(DESC "it")
+	(FLAGS NDESCBIT INVISIBLE)
+	(ACTION PROTAGONIST-F)>
+
+<ROUTINE PROTAGONIST-F ()
+	 <COND (<AND <PRSO? ,NO-TEA>
+		     ,PRSI>
+		<NO-TEA-F>)>>
+
+<OBJECT ME
+	(IN GLOBAL-OBJECTS)
+	(SYNONYM I ME MYSELF SELF)
+	(DESC "yourself")
+	(FLAGS ACTORBIT TOUCHBIT NARTICLEBIT)
+	(ACTION ME-F)>
+
+<ROUTINE ME-F ("AUX" OLIT) 
+	 <COND (<VERB? TELL>
+		<TELL
+"Talking to yourself is a sign of impending mental collapse." CR>
+		<FUCKING-CLEAR>)
+	       (<VERB? LISTEN>
+		<TELL "Yes?" CR>)
+	       (<VERB? ALARM>
+		<TELL ,YOU-ARE CR>)
+	       (<AND <VERB? GIVE>
+		     <PRSI? ,ME>>
+		<COND (<AND <IN? ,PRSO ,PROTAGONIST>
+		            <NOT <PRSO? ,NO-TEA ,BABEL-FISH>>>
+		       <PRE-TAKE>)
+		      (T
+		       <PERFORM ,V?TAKE ,PRSO>
+		       <RTRUE>)>)
+	       (<VERB? MOVE>
+		<V-WALK-AROUND>)
+	       (<VERB? SEARCH>
+		<V-INVENTORY>
+		<RTRUE>)
+	       (<OR <VERB? KILL MUNG>
+		    <AND <VERB? SHOOT>
+			 <PRSI? ,BLASTER>>>
+		<JIGS-UP "Done.">
+		<RTRUE>)
+	       (<VERB? FIND>
+		<TELL "You're right here!" CR>)
+	       (<VERB? WHO>
+		<TELL "You are " D ,IDENTITY-FLAG "." CR>)
+	       (<AND <VERB? EXAMINE>
+		     <EQUAL? ,HERE ,MAZE>>
+		<TELL
+"You look perfectly normal (except that you're two microns tall)." CR>)
+	       (<VERB? PULL-TOGETHER>
+		<TELL ,ZEN CR>)
+	       (<VERB? FOLLOW>
+		<TELL
+"I'd like to, but like most computers I don't have legs." CR>)>>
+
+<OBJECT GLOBAL-ROOM
+	(IN GLOBAL-OBJECTS)
+	(DESC "room")
+	(SYNONYM ROOM CHAMBER PLACE HALL)
+	(ADJECTIVE AREA)
+	(ACTION GLOBAL-ROOM-F)>
+
+<ROUTINE GLOBAL-ROOM-F ()
+	 <COND (<VERB? LOOK EXAMINE LOOK-INSIDE>
+		<V-LOOK>
+		<RTRUE>)
+	       (<VERB? THROUGH WALK-TO>
+		<V-WALK-AROUND>)
+	       (<VERB? LEAVE EXIT>
+		<DO-WALK ,P?OUT>)
+	       (<VERB? WALK-AROUND>
+		<COND (<EQUAL? ,HERE ,CAPTAINS-QUARTERS>
+		       <V-STAND>)
+		      (T
+		       <TELL
+"Walking around the room reveals nothing new. To move elsewhere, just type
+the desired direction." CR>)>)
+	       (<VERB? LAMP-ON>
+		<PERFORM ,V?LAMP-ON ,LIGHT>
+		<RTRUE>)>>
+
+<OBJECT OBJECT-OF-GAME
+	(IN GLOBAL-OBJECTS)
+	(DESC "object of the game")
+	(SYNONYM OBJECT GAME GOAL)
+	(FLAGS VOWELBIT)
+	(ACTION OBJECT-OF-GAME-F)>
+
+<ROUTINE OBJECT-OF-GAME-F ()
+	 <COND (<VERB? WHAT>
+		<TELL "That's for me to know and you to find out." CR>)>>
+
+<OBJECT CONTROLS
+	(IN LOCAL-GLOBALS)
+	(DESC "the controls")
+	(SYNONYM CONTRO PANEL CONSOL)
+	(ADJECTIVE CONTRO)
+	(FLAGS NARTICLEBIT)
+	(ACTION CONTROLS-F)>
+
+<ROUTINE CONTROLS-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (<EQUAL? ,HERE ,SPEEDBOAT>
+		       <TELL
+"The only control, other than those related to steering the boat, is the large
+red " D ,AUTOPILOT-BUTTON ".">
+		       <FINE-PRODUCT>
+		       <CRLF>)
+		      (<EQUAL? ,HERE ,BRIDGE>
+		       <TELL
+"Most of the controls are beyond your comprehension. ">
+		       <COND (<IN? ,LARGE-RECEPTACLE ,HERE>
+			      <TELL
+"The simplest one is a " D ,LARGE-RECEPTACLE " of some kind.">
+			      <COND (,DRIVE-TO-CONTROLS
+				     <TELL " ">
+				     <PERFORM ,V?EXAMINE ,LARGE-RECEPTACLE>
+				     <RTRUE>)
+				    (T
+				     <CRLF>)>)
+			     (T
+			      <TELL
+"A fused spot shows where a receptacle once was." CR>)>)>)>>
+
+<OBJECT CONVERSATION
+	(IN LOCAL-GLOBALS)
+	(DESC "conversation")
+	(SYNONYM CONVER)
+	(FLAGS DARKBIT INVISIBLE)
+	(ACTION CONVERSATION-F)>
+
+<ROUTINE CONVERSATION-F ()
+	 <COND (<VERB? LISTEN>
+		<COND (<EQUAL? ,HERE ,FRONT-OF-HOUSE>
+		       <TELL "You can't hear anything from here." CR>)
+		      (T
+		       <PERFORM ,V?LISTEN ,VLHURG>
+		       <RTRUE>)>)>>
+
+<OBJECT GUARDS
+	(IN LOCAL-GLOBALS) ;"just for the purpose of MOBY-FIND"
+	(DESC "one of the guards")
+	(SYNONYM ONE GUARD GUARDS)
+	(ADJECTIVE VOGON)
+        (FLAGS VOWELBIT NARTICLEBIT NDESCBIT ACTORBIT
+	       CONTBIT SEARCHBIT OPENBIT)
+	(ACTION GUARDS-F)>
+
+<ROUTINE GUARDS-F ()
+	 <COND (<EQUAL? ,GUARDS ,WINNER>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <PRSO? ,ME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,GUARDS ,PRSI>
+		       <SETG WINNER ,GUARDS>
+		       <RTRUE>)
+		      (<VERB? HELLO>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?HELLO ,GUARDS>
+		       <SETG WINNER ,GUARDS>
+		       <RTRUE>)
+		      (<EQUAL? ,HERE ,DAIS>
+		       <COND (<OR <AND <IN? ,RIFLES ,GUARDS>
+				       <VERB? SHOOT>
+				       ,DONT-FLAG>
+				  <AND <IN? ,RIFLES ,GUARDS>
+				       <VERB? DROP>
+				       <PRSO? ,RIFLES>>>
+			      <FCLEAR ,RIFLES ,NDESCBIT>
+			      <ENABLE <QUEUE I-GUARDS 8>>
+			      <MOVE ,RIFLES ,HERE>
+			      <FSET ,RIFLES ,TAKEBIT>
+			      <FSET ,RIFLES ,TRYTAKEBIT>
+			      <TELL "The guards hesitate, then toss their "
+D ,RIFLES "s into a pile in front of you." CR>)
+			     (<VERB? SHOOT>
+			      <COND (<IN? ,RIFLES ,GUARDS>
+				     <JIGS-UP
+"The air becomes thick with photon beams.">)
+				    (T
+				     <TELL
+"Someone around here is being very stupid. Let's say it's the guards,
+since they're only fictitious characters and therefore not potential
+Infocom customers. The poor fictitious saps don't understand how they
+can shoot without rifles." CR>)>)
+			     (<AND <VERB? TAKE>
+				   <PRSO? ,RIFLES>>
+			      <COND (<IN? ,RIFLES ,GUARDS>
+				     <TELL "\"We already have them!\"" CR>)
+				    (T
+				     <MOVE ,RIFLES ,GUARDS>
+				     <ENABLE <QUEUE I-GUARDS 5>>
+				     <TELL "They do so." CR>)>)
+			     (<VERB? LEAVE>
+			      <TELL
+"\"We can't leave while you're in trouble, Mr. President!\"" CR>)
+			     (T
+			      <TELL
+"You have failed to issue one of the small set of commands that the
+guards' military intelligences are trained to understand." CR>
+			      <FUCKING-CLEAR>)>)
+		      (T
+		       <COND (<HELD? ,BABEL-FISH ,PROTAGONIST>
+			      <TELL "\"Resistance is useless!\"" CR>)
+			     (T
+			      <TELL "\"I">
+			      <PRODUCE-GIBBERISH 1>
+			      <CRLF>)>
+		       <FUCKING-CLEAR>)>)
+	       (<AND <EQUAL? ,HERE ,CAPTAINS-QUARTERS>
+		     <VERB? TELL HELLO THANK>>
+		<PERFORM ,V?TELL ,VOGON-CAPTAIN>
+		<RTRUE>)
+	       (<AND <EQUAL? ,HERE ,CAPTAINS-QUARTERS>
+		     <AND <VERB? ASK-ABOUT ASK-FOR>
+			  <EQUAL? ,GUARDS ,PRSO>>>
+		<PERFORM ,V?TELL ,VOGON-CAPTAIN>
+		<RTRUE>)
+	       (<AND <VERB? EXAMINE>
+		     <IN? ,RIFLES ,GUARDS>>
+		<TELL "They're holding " D ,RIFLES "s." CR>)
+	       (<AND <EQUAL? ,HERE ,DAIS>		     
+		     <VERB? SHOOT>>
+		<COND (<BLASTER-HOLD>
+		       <RTRUE>)>
+		<TELL ,GUARDS-REALIZE>
+		<JIGS-UP
+"Although you incinerate many, other guards arrive and incinerate you.">
+		<RTRUE>)
+	       (<AND <VERB? GIVE>
+		     <PRSO? ,BLASTER>>
+		<TELL "The guards are more than glad to disarm you. They">
+		<GUARD-DEATH>
+		<RTRUE>)
+	       (<VERB? COUNT>
+		<COND (<EQUAL? ,HERE ,HOLD>
+		       <TELL "One." CR>)
+		      (<EQUAL? ,HERE ,CAPTAINS-QUARTERS>
+		       <TELL "Several." CR>)
+		      (T
+		       <TELL "Many." CR>)>)>>
+
+<ROUTINE WEAPON-PSEUDO ()
+	 <COND (<NOT <IN? ,GUARDS ,HERE>>
+		<TELL "What weapon?" CR>)
+	       (<VERB? SHOOT>
+		<TELL ,NOT-HOLDING " it." CR>)>>
+
+<OBJECT FRUSTATION
+	(IN GLOBAL-OBJECTS)
+	(DESC "problem")
+	(SYNONYM FRUSTR PROBLE PUZZLE)
+	(ACTION FRUSTRATION-F)>
+
+<ROUTINE FRUSTRATION-F ()
+	 <COND (<VERB? ENJOY>
+		<TELL ,ZEN CR>)>>
+
+<ROUTINE UNIMPORTANT-THING-F ()
+	 <COND (<AND <VERB? ASK-ABOUT>
+		     <PRSO? ,GUIDE>>
+		<RFALSE>)
+	       (T
+		<TELL "That's not important; leave it alone." CR>)>>
+
+;"DONT stuff"
+
+<ROUTINE DONT-F ()
+	 <COND (<VERB? PANIC>
+		<COND (<PROB 50>
+		       <TELL 
+"Very clever. It looks like there's a lot you should be panicking about." CR>)
+		      (T
+		       <TELL
+"Why not? Your position appears quite hopeless." CR>)>)
+	       (<VERB? LOOK>
+		<SETG DONT-FLAG <>>
+		<PERFORM ,V?CLOSE ,EYES>
+		<RTRUE>)
+	       (<VERB? WAIT>
+		<TELL "Time doesn't pass..." CR>)
+	       (<VERB? TAKE>
+		<TELL "Not taken." CR>)
+	       (<AND <VERB? LISTEN>
+		     <VISIBLE? ,POETRY>>
+		<SETG DONT-FLAG <>>
+		<PERFORM ,V?LISTEN ,POETRY>
+		<RTRUE>)
+	       (T
+		<TELL "Not done." CR>)>>
+
+;"DARK stuff"
+
+<GLOBAL VOGON-PROB 100>
+
+<GLOBAL HEART-PROB 0>
+
+<GLOBAL TRAAL-PROB 60>
+
+<GLOBAL FLEET-PROB 0>
+
+<GLOBAL WHALE-PROB 0>
+
+<GLOBAL TRILLIAN-PROB 15>
+
+<GLOBAL ZAPHOD-PROB 0>
+
+<GLOBAL FORD-PROB 15>
+
+<GLOBAL DREAMING <>>
+
+<GLOBAL DARK-COUNTER 0>
+
+<GLOBAL DARK-FLAG <>>
+
+<GLOBAL CURRENT-EXIT 0>
+
+<GLOBAL GROGGY <>>
+
+<GLOBAL LYING-COUNTER 0>
+
+<GLOBAL GUTS-ROOM <>>
+
+<ROOM DARK
+      (IN ROOMS)
+      (SYNONYM SUNGLA GLASSE JANTA)
+      (ADJECTIVE JOO JANTA PERIL SENSIT)
+      (DESC "Dark")
+      (FLAGS RLANDBIT ONBIT)
+      (ACTION DARK-F)>
+
+<ROUTINE DARK-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<PUTP ,PROTAGONIST ,P?ACTION ,DARK-FUNCTION>
+		<ROB ,PROTAGONIST ,DARK-OBJECT>
+		<FSET ,CONVERSATION ,INVISIBLE>
+		<SETG DREAMING <>>
+		<SETG LYING-DOWN <>>
+		<REPEAT ()
+			<COND (<PROB ,HEART-PROB>
+			       <SETG HEART-PROB 0>
+			       <SETG VOGON-PROB 10>
+			       <SETG DARK-FLAG ,ENTRY-BAY>
+			       <SETG CURRENT-EXIT 3>)
+			      (<PROB ,VOGON-PROB>
+			       <SETG VOGON-PROB 0>
+			       <SETG HEART-PROB 100>
+			       <SETG DARK-FLAG ,HOLD>
+			       <SETG CURRENT-EXIT 0>)
+			      (<PROB ,TRAAL-PROB>
+			       <COND (<NOT <EQUAL? ,TRAAL-PROB 10>>
+				      <SETG TRAAL-PROB 10>
+				      <SETG TRILLIAN-PROB 25>
+				      <SETG FORD-PROB 25>
+				      <SETG ZAPHOD-PROB 25>)>
+			       <SETG DARK-FLAG ,LAIR>
+			       <SETG CURRENT-EXIT 4>)
+			      (<PROB ,TRILLIAN-PROB>
+			       <SETG TRILLIAN-PROB 10>
+			       <SETG DARK-FLAG ,LIVING-ROOM>
+			       <SETG CURRENT-EXIT 2>)
+			      (<PROB ,FORD-PROB>
+			       <SETG FORD-PROB 10>
+			       <SETG DARK-FLAG ,COUNTRY-LANE>
+			       <SETG CURRENT-EXIT 1>)
+			      (<PROB ,ZAPHOD-PROB>
+			       <SETG ZAPHOD-PROB 10>
+			       <SETG DARK-FLAG ,SPEEDBOAT>
+			       <SETG CURRENT-EXIT 5>)
+			      (<PROB ,FLEET-PROB>
+			       <SETG FLEET-PROB 10>
+			       <SETG DARK-FLAG ,WAR-CHAMBER>
+			       <SETG CURRENT-EXIT 7>)
+			      (<PROB ,WHALE-PROB> ;"this should always be 0"
+			       <TELL "Bug #60" CR>
+			       <SETG DARK-FLAG ,INSIDE-WHALE>
+			       <SETG CURRENT-EXIT 6>)>
+			<COND (,DARK-FLAG
+			       <RETURN>)>>
+		<RFALSE>)
+	       (<EQUAL? .RARG ,M-LOOK>
+		<RTRUE>)>>
+
+<OBJECT DARK-OBJECT
+	(IN GLOBAL-OBJECTS) ;"gets moved to Dark when you turn on the light"
+	(DESC "darkness")
+	(SYNONYM DARK DARKNE NOTHIN)
+	(FLAGS NDESCBIT NARTICLEBIT)>
+
+<OBJECT SHADOW
+	(IN LOCAL-GLOBALS)
+	(DESC "shadow")
+	(SYNONYM SHADOW)
+	(FLAGS NDESCBIT)>
+
+<OBJECT LIQUID
+	(IN LOCAL-GLOBALS)
+	(DESC "liquid")
+	(SYNONYM LIQUID)
+	(ADJECTIVE HOT COLD WARM WET SQUISH)
+	(FLAGS NDESCBIT DRINKBIT)>
+
+<OBJECT PAINFUL-LIGHT
+	(IN LOCAL-GLOBALS)
+	(DESC "light")
+	(SYNONYM LIGHT)
+	(ADJECTIVE PAINFU BRIGHT)
+	(FLAGS NDESCBIT)>
+
+<OBJECT STAR-DRIVE
+	(IN LOCAL-GLOBALS)
+	(DESC "star drive")
+	(SYNONYM DRIVE HUM)
+	(ADJECTIVE STAR DEEP DISTANT)
+	(FLAGS NDESCBIT)>
+
+<ROUTINE DARK-FUNCTION ()
+	 <COND (<VERB? QUIT RESTART RESTORE SCORE VERSION SAVE AGAIN HELP
+		       VERBOSE BRIEF SUPER-BRIEF SCRIPT UNSCRIPT FOOTNOTE>
+		<>)
+	       (,DONT-FLAG
+		<>)
+	       (<VERB? PANIC YELL>
+		<TELL
+"You yell as loudly as you can, but no sound emerges." CR>)
+	       (<OR <VERB? RELAX>
+		    <AND <VERB? ENJOY>
+			 <PRSO? ,DARK-OBJECT>>>
+		<TELL
+"You achieve a state of Negative Capability, and are able to be in
+uncertainties, mysteries, doubts, without any irritable searching
+after fact and reason (Footnote 1)." CR>)
+	       (<AND <EQUAL? ,DARK-FLAG ,ENTRY-BAY ,WAR-CHAMBER>
+		     <VERB? LISTEN>
+		     <PRSO? ,DARK-OBJECT>
+		     <MISSING?>>		
+		<MOVE ,STAR-DRIVE ,HERE>
+		<SETG P-IT-OBJECT ,STAR-DRIVE>
+		<TELL
+"You hear the deep and distant hum of a " D ,STAR-DRIVE " coming from far ">
+		<COND (<EQUAL? ,DARK-FLAG ,ENTRY-BAY>
+		       <TELL "above">)
+		      (T
+		       <TELL "below">)>
+		<TELL ". There is an exit to port." CR>)
+	       (<AND <VERB? WALK>
+		     <MISSING?>
+		     <EQUAL? ,DARK-FLAG ,WAR-CHAMBER ,ENTRY-BAY>
+		     <IN? ,STAR-DRIVE ,HERE>>
+		<COND (<PRSO? ,P?SOUTH>
+		       <COND (<L? ,LYING-COUNTER 4>
+			      <TELL ,LYING-ABOUT-EXIT>)>
+		       <TELL "You emerge from a small doorway...">
+		       <LEAVE-DARK>)
+		      (T
+		       <TELL ,CANT-GO>
+		       <COND (<PRSO? ,P?WEST>
+			      <SETG LYING-COUNTER <+ ,LYING-COUNTER 1>>
+			      <COND (<EQUAL? ,LYING-COUNTER 4>
+				     <TELL
+" " ,LYING-ABOUT-EXIT "There is an exit aft...">)>)>
+		       <CRLF>)>)
+	       (<AND <OR <PRSO? ,STAR-DRIVE>
+		         <PRSI? ,STAR-DRIVE>>
+		     <NOT <VERB? WALK>>>
+		<COND (<NOT <EQUAL? ,DARK-FLAG ,ENTRY-BAY ,WAR-CHAMBER>>
+		       <CANT-SEE ,STAR-DRIVE>)
+		      (<VERB? LISTEN>
+		       <TELL "The sound comes from far ">
+		       <COND (<EQUAL? ,DARK-FLAG ,ENTRY-BAY>
+			      <TELL "above">)
+			     (T
+			      <TELL "below">)>
+		       <TELL "." CR>)
+		      (T
+		       <>)>)
+	       (<AND <EQUAL? ,DARK-FLAG ,COUNTRY-LANE ,SPEEDBOAT>
+		     <VERB? EXAMINE>
+		     <PRSO? ,DARK-OBJECT>
+		     <MISSING?>>
+		<MOVE ,PAINFUL-LIGHT ,HERE>
+		<SETG P-IT-OBJECT ,PAINFUL-LIGHT>
+		<TELL "You see a painfully bright light that stabs at the ">
+		<COND (<EQUAL? ,DARK-FLAG ,COUNTRY-LANE>
+		       <TELL "front">)
+		      (T
+		       <TELL "back">)>
+		<TELL " of your eyes." CR>)
+	       (<AND <OR <PRSO? ,PAINFUL-LIGHT>
+		         <PRSI? ,PAINFUL-LIGHT>>
+		     <NOT <VERB? WALK>>>
+		<COND (<NOT <EQUAL? ,DARK-FLAG ,SPEEDBOAT ,COUNTRY-LANE>>
+		       <CANT-SEE ,PAINFUL-LIGHT>)
+		      (<VERB? EXAMINE>
+		       <TELL "The light resolves itself into the bright ">
+		       <COND (<EQUAL? ,DARK-FLAG ,COUNTRY-LANE>
+			      <TELL "yellow Sun of Earth">)
+			     (T
+			      <TELL "orange Sun of " D ,DAMOGRAN>)>
+		       <TELL ".">
+		       <LEAVE-DARK>)>)
+	       (<AND <EQUAL? ,DARK-FLAG ,LIVING-ROOM ,INSIDE-WHALE>
+		     <VERB? RUB>
+		     <PRSO? ,DARK-OBJECT>
+		     <MISSING?>>
+	        <MOVE ,LIQUID ,HERE>
+		<SETG P-IT-OBJECT ,LIQUID>
+		<TELL "It does feel a bit ">
+		<COND (<EQUAL? ,DARK-FLAG ,LIVING-ROOM>
+		       <TELL "cold">)
+		      (T
+		       <TELL "warm">)>
+		<TELL
+" and wet and squishy. There seems to be some liquid at your fingertips." CR>)
+	       (<AND <OR <PRSO? ,LIQUID>
+			 <PRSI? ,LIQUID>>
+		     <NOT <VERB? WALK>>>
+		<COND (<NOT <EQUAL? ,DARK-FLAG ,LIVING-ROOM ,INSIDE-WHALE>>
+		       <CANT-SEE ,LIQUID>)
+		      (<EQUAL? ,DARK-FLAG ,LIVING-ROOM>
+		       <COND (<VERB? EXAMINE RUB>
+			      <TELL "It seems coldish." CR>)
+			     (<VERB? TASTE DRINK>
+			      <TELL
+"It tastes just like wine. In fact, you realise with growing embarrassment
+that " D ,HANDS " is sitting in a " D ,WINE ".">
+			      <LEAVE-DARK>)>)
+		      (<EQUAL? ,DARK-FLAG ,INSIDE-WHALE>
+		       <COND (<VERB? EXAMINE RUB>
+			      <TELL "It seems warmish." CR>)
+			     (<VERB? TASTE DRINK>
+			      <TELL
+"Yucchhh! You are jerked to your senses by the realisation that you are
+licking the lining of a whale's stomach.">
+			      <LEAVE-DARK>)>)>)
+	       (<AND <EQUAL? ,DARK-FLAG ,HOLD ,LAIR>
+		     <VERB? SMELL>
+		     <PRSO? ,DARK-OBJECT>
+		     <MISSING?>>
+		<MOVE ,SHADOW ,HERE>
+		<SETG P-IT-OBJECT ,SHADOW>
+		<TELL "It does smell a bit. There's something pungent ">
+		<COND (<EQUAL? ,DARK-FLAG ,HOLD>
+		       <TELL "being waved">)
+		      (T
+		       <TELL "waving">)>
+		<TELL
+" under your nose. Your head begins to clear. You can make out a shadow
+moving in the dark." CR>)
+	       (<AND <OR <PRSO? ,SHADOW>
+			 <PRSI? ,SHADOW>>
+		     <NOT <VERB? WALK>>>
+		<COND (<NOT <EQUAL? ,DARK-FLAG ,HOLD ,LAIR>>
+		       <CANT-SEE ,SHADOW>)
+		      (<VERB? EXAMINE>
+		       <TELL "The shadow is vaguely ">
+		       <BEAST-GUARD-FORD>
+		       <TELL "-shaped.">
+		       <LEAVE-DARK>)
+		      (<VERB? RUB>
+		       <TELL "The shadow turns out to be a solid object of a ">
+		       <BEAST-GUARD-FORD>
+		       <TELL "-like nature.">
+		       <LEAVE-DARK>)
+		      (<VERB? SMELL>
+		       <TELL "The shadow has a sort of ">
+		       <BEAST-GUARD-FORD>
+		       <TELL "y smell to it.">
+		       <LEAVE-DARK>)
+		      (T
+		       <>)>)
+	       (T
+		<SETG DARK-COUNTER <+ ,DARK-COUNTER 1>>
+		<COND (,DARK-CONTROLLED
+		       <SETG CURRENT-EXIT <+ ,CURRENT-EXIT 1>>
+		       <COND (<EQUAL? ,CURRENT-EXIT 8>
+			      <SETG CURRENT-EXIT 0>)>
+		       <SETG DARK-FLAG <GET ,DARK-EXIT-TABLE ,CURRENT-EXIT>>)>
+		<COND (<VERB? LOOK>
+		       <TELL "Dark" CR>)>
+		<COND (<PROB 25>
+		       <DARK-ONE>
+		       <FUCKING-CLEAR>)
+		      (<PROB 33>
+		       <DARK-TWO>
+		       <FUCKING-CLEAR>)
+		      (<PROB 50>
+		       <DARK-THREE>
+		       <FUCKING-CLEAR>)
+		      (T
+		       <DARK-FOUR>
+		       <FUCKING-CLEAR>)>
+		<COND (<EQUAL? ,DARK-COUNTER 18>
+		       <TELL CR
+"When will you come to your senses and solve this puzzle?" CR>)
+		      (<EQUAL? ,DARK-COUNTER 33>
+		       <TELL CR
+"4 out of 5 sensitive people solve this puzzle right away." CR>)
+		      (<EQUAL? ,DARK-COUNTER 48>
+		       <TELL CR
+"Don't count your senses before they hatch." CR>)
+		      (<AND <EQUAL? ,DARK-COUNTER 63>
+		            <EQUAL? ,DARK-FLAG ,HOLD>>
+		       <TELL CR
+"Something stinks around here, and I'm not just talking about your
+puzzle-solving ability!" CR>)
+		      (T
+		       <RTRUE>)>)>>  
+
+<GLOBAL DARK-EXIT-TABLE
+	<PTABLE
+	 HOLD
+	 COUNTRY-LANE
+	 LIVING-ROOM
+	 ENTRY-BAY
+	 LAIR
+	 SPEEDBOAT
+	 INSIDE-WHALE
+	 WAR-CHAMBER>>
+
+<ROUTINE LEAVE-DARK ()
+	 <CRLF> <CRLF>
+	 <PUTP ,PROTAGONIST ,P?ACTION ,PROTAGONIST-F>
+	 <SETG DARK-COUNTER 0>
+	 <SETG LYING-COUNTER 0>
+	 <SETG DARK-CONTROLLED <>>
+	 <ROB ,DARK-OBJECT ,PROTAGONIST>
+	 <ROB ,MEMORIAL ,PROTAGONIST>
+	 <MOVE ,SHADOW ,LOCAL-GLOBALS>
+	 <MOVE ,PAINFUL-LIGHT ,LOCAL-GLOBALS>
+	 <MOVE ,LIQUID ,LOCAL-GLOBALS>
+	 <MOVE ,STAR-DRIVE ,LOCAL-GLOBALS>
+	 <COND (,FLUFF-TO-GOWN
+		<MOVE ,SATCHEL-FLUFF ,GOWN>
+		<SETG FLUFF-TO-GOWN <>>)>
+	 <COND (<AND <EQUAL? ,DARK-FLAG ,WAR-CHAMBER>
+		     <FSET? ,WAR-CHAMBER ,REVISITBIT>>
+		<ENABLE <QUEUE I-BRAIN-DEATH 6>>
+		<SETG HERE <META-LOC ,SPARE-DRIVE>>
+		<MOVE ,PROTAGONIST ,HERE>
+		<MOVE ,NAME ,HERE>
+		<SETG GUTS-ROOM ,HERE>
+		<TELL
+"There is a violent explosion around you, leaving you standing in">
+		<ARTICLE ,HERE T>
+		<TELL ". ">
+		<PERFORM ,V?EXAMINE ,GROUND>
+		<TELL CR
+"Apparently, you just materialised inside your own brain. This is very very
+very nasty. You have two choices: quit now, or experience this materialisation
+from the other end, in about five turns." CR>)
+	       (<AND <EQUAL? ,DARK-FLAG ,SPEEDBOAT>
+		     <FSET? ,SPEEDBOAT ,REVISITBIT>>
+		<GOTO ,DAIS>)
+	       (T
+		<COND (<NOT <EQUAL? ,DARK-FLAG ,ENTRY-BAY>>
+		       <MOVE ,MAIN-DRIVE ,LOCAL-GLOBALS>)>
+		<GOTO ,DARK-FLAG>)>
+	 <SETG DARK-FLAG <>>
+	 <RTRUE>>
+
+<ROUTINE MISSING? ()
+	 <COND (<OR ,DARK-CONTROLLED
+		    <G? ,DARK-COUNTER 3>>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE DARK-ONE ()
+	 <TELL "You can ">
+	 <COND (<NOT <AND <MISSING?>
+		          <EQUAL? ,DARK-FLAG ,WAR-CHAMBER ,ENTRY-BAY>>>
+		<TELL "hear nothing, ">)>
+	 <COND (<NOT <AND <MISSING?>
+		          <EQUAL? ,DARK-FLAG ,HOLD ,LAIR>>>
+		<TELL "smell nothing, ">)>
+	 <TELL "taste nothing, ">
+	 <COND (<NOT <AND <MISSING?>
+		          <EQUAL? ,DARK-FLAG ,COUNTRY-LANE ,SPEEDBOAT>>>
+		<TELL "see nothing, ">)>
+	 <COND (<NOT <AND <MISSING?>
+			  <EQUAL? ,DARK-FLAG ,LIVING-ROOM ,INSIDE-WHALE>>>
+		<TELL "feel nothing, ">)>
+	 <TELL "and are not even certain who you are." CR>>
+
+<ROUTINE DARK-TWO ()
+	 <TELL "You can ">
+	 <COND (<NOT <AND <MISSING?>
+		          <EQUAL? ,DARK-FLAG ,COUNTRY-LANE ,SPEEDBOAT>>>
+		<TELL "see nothing, ">)>
+	 <COND (<NOT <AND <MISSING?>
+			  <EQUAL? ,DARK-FLAG ,LIVING-ROOM ,INSIDE-WHALE>>>
+		<TELL "feel nothing, ">)>
+	 <COND (<NOT <AND <MISSING?>
+		          <EQUAL? ,DARK-FLAG ,WAR-CHAMBER ,ENTRY-BAY>>>
+		<TELL "hear nothing, ">)>
+	 <TELL "taste nothing, ">
+	 <COND (<NOT <AND <MISSING?>
+		          <EQUAL? ,DARK-FLAG ,HOLD ,LAIR>>>
+		<TELL "smell nothing, ">)>
+	 <TELL "and are not entirely certain who you are." CR>>
+
+<ROUTINE DARK-THREE ()
+	 <TELL "You can't ">
+	 <COND (<NOT <AND <MISSING?>
+		          <EQUAL? ,DARK-FLAG ,WAR-CHAMBER ,ENTRY-BAY>>>
+		<TELL "hear anything, ">)>
+	 <COND (<NOT <AND <MISSING?>
+		          <EQUAL? ,DARK-FLAG ,COUNTRY-LANE ,SPEEDBOAT>>>
+		<TELL "see anything, ">)>
+	 <COND (<NOT <AND <MISSING?>
+		          <EQUAL? ,DARK-FLAG ,HOLD ,LAIR>>>
+		<TELL "smell anything, ">)>
+	 <COND (<NOT <AND <MISSING?>
+			  <EQUAL? ,DARK-FLAG ,LIVING-ROOM ,INSIDE-WHALE>>>
+		<TELL "feel anything, ">)>
+	 <TELL "or taste anything, and do not even know where you are
+or who you are or how you got there." CR>>
+
+<ROUTINE DARK-FOUR ()
+	 <TELL "There's nothing you can taste, ">
+	 <COND (<NOT <AND <MISSING?>
+		          <EQUAL? ,DARK-FLAG ,COUNTRY-LANE ,SPEEDBOAT>>>
+		<TELL "nothing you can see, ">)>
+	 <COND (<NOT <AND <MISSING?>
+		          <EQUAL? ,DARK-FLAG ,WAR-CHAMBER ,ENTRY-BAY>>>
+		<TELL "nothing you can hear, ">)>
+	 <COND (<NOT <AND <MISSING?>
+			  <EQUAL? ,DARK-FLAG ,LIVING-ROOM ,INSIDE-WHALE>>>
+		<TELL "nothing you can feel, ">)>
+	 <COND (<NOT <AND <MISSING?>
+		          <EQUAL? ,DARK-FLAG ,HOLD ,LAIR>>>
+		<TELL "nothing you can smell, ">)>
+	 <TELL "you do not even know who you are." CR>>
+
+<ROUTINE BEAST-GUARD-FORD ()
+	 <COND (<EQUAL? ,DARK-FLAG ,LAIR>
+		<TELL "Bugblatter Beast">)
+	       (<FSET? ,HOLD ,REVISITBIT>
+		<TELL "guard">)
+	       (T
+		<TELL D ,FORD>)>>
+
+<ROUTINE I-BRAIN-DEATH ()
+	 <TELL "The " D ,ARTHUR>
+	 <JIGS-UP
+" of five turns ago suddenly materialises inside your brain. There is an
+incredibly nasty cracking, scrunching noise, and blood and bone fly everywhere
+as your head, to be perfectly frank about this, explodes. We did warn you.">
+	 <RTRUE>>
+
+;"tools"
+
+<OBJECT TOOTHBRUSH
+	(IN BEDROOM)
+	(DESC "toothbrush")
+	(SYNONYM TOOTHB BRUSH TOOL TOOLS)
+	(ADJECTIVE TOOTH MY PROPER)
+	(FLAGS TAKEBIT TRYTAKEBIT TOOLBIT)
+	(SIZE 3)
+	(GENERIC TWEEZERS)
+	(ACTION TOOTHBRUSH-F)>
+
+<ROUTINE TOOTHBRUSH-F ()
+	 <COND (<AND <VERB? TAKE>
+		     <NOT <FSET? ,TOOTHBRUSH ,TOUCHBIT>>>
+		<MOVE ,TOOTHBRUSH ,PROTAGONIST>
+		<FSET ,TOOTHBRUSH ,TOUCHBIT>
+		<FCLEAR ,TOOTHBRUSH ,TRYTAKEBIT>
+		<TELL
+"As you pick up the " D ,TOOTHBRUSH " a tree outside the window collapses.
+There is no causal relationship between these two events.">
+		<COND (<FSET? ,PHONE ,TOUCHBIT>
+		       <TWO-TREES>)>
+		<CRLF>)>>
+
+<OBJECT SCREWDRIVER
+	(IN BEDROOM)
+	(DESC "flathead screwdriver")
+	(SYNONYM SCREWD TOOL TOOLS)
+	(ADJECTIVE FLATHE PROPER)
+	(FLAGS TAKEBIT TRYTAKEBIT TOOLBIT)
+	(SIZE 3)
+	(GENERIC TWEEZERS)>
+
+<OBJECT WRENCH
+	(IN TOOLBOX)
+	(DESC "laser-assisted monkey wrench")
+	(SYNONYM WRENCH TOOL TOOLS)
+	(ADJECTIVE LASER ASSIST MONKEY PROPER)
+	(FLAGS TAKEBIT TOOLBIT)
+	(SIZE 3)
+	(GENERIC TWEEZERS)>
+
+<OBJECT CHISEL
+	(IN PANTRY)
+	(DESC "thermo-fusion chisel")
+	(SYNONYM CHISEL TOOL TOOLS)
+	(ADJECTIVE THERMO FUSION PROPER)
+	(FLAGS TAKEBIT TOOLBIT)
+	(SIZE 3)
+	(GENERIC TWEEZERS)>
+
+<OBJECT AWL
+	(IN WAR-CHAMBER)
+	(DESC "ultra-plasmic vacuum awl")
+	(SYNONYM AWL TOOL TOOLS)
+	(ADJECTIVE ULTRA PLASMI VACUUM PROPER)
+	(FLAGS TAKEBIT VOWELBIT TOOLBIT)
+	(SIZE 3)
+	(GENERIC TWEEZERS)>
+
+<OBJECT PLIERS
+	(IN LOCAL-GLOBALS) ;"for purposes of MOBY-FIND"
+	(DESC "pair of hypersonic pliers")
+	(SYNONYM PAIR PLIERS TOOL TOOLS)
+	(ADJECTIVE HYPERS PROPER)
+	(FLAGS TAKEBIT TOOLBIT)
+	(SIZE 3)
+	(GENERIC TWEEZERS)>
+
+<OBJECT TWEEZERS
+	(IN HANDBAG)
+	(DESC "pair of tweezers")
+	(SYNONYM TWEEZE PAIR TOOL TOOLS)
+	(ADJECTIVE PROPER)
+	(FLAGS TAKEBIT TOOLBIT)
+	(SIZE 3)
+	(GENERIC TWEEZERS)>
+
+<OBJECT PINCER
+	(IN BRIDGE)
+	(DESC "molecular hyperwave pincer")
+	(SYNONYM PINCER TOOL TOOLS)
+	(ADJECTIVE MOLECU HYPERW PROPER)
+	(FLAGS TAKEBIT TOOLBIT)
+	(SIZE 3)
+	(GENERIC TWEEZERS)>
+
+<OBJECT RASP
+	(IN LOCAL-GLOBALS) ;"for the sake of MOBY-FIND"
+	(DESC "ionic diffusion rasp")
+	(SYNONYM RASP TOOL TOOLS)
+	(ADJECTIVE IONIC DIFFUS PROPER)
+	(FLAGS TAKEBIT VOWELBIT TOOLBIT)
+	(SIZE 3)
+	(GENERIC TWEEZERS)> 
+
+<OBJECT CHIPPER
+	(IN LOCAL-GLOBALS) ;"for purposes of MOBY-FIND"
+	(DESC "number twelve asteroid paint chipper")
+	(SYNONYM CHIPPE TOOL TOOLS)
+	(ADJECTIVE NUMBER TWELVE ASTERO PAINT PROPER)
+	(FLAGS TAKEBIT TOOLBIT)
+	(SIZE 3)
+	(GENERIC TWEEZERS)>
+
+<GLOBAL TOOL-LIST
+	<PLTABLE
+	 SCREWDRIVER
+	 WRENCH
+	 CHISEL
+	 AWL
+	 PLIERS
+	 TWEEZERS
+	 PINCER
+	 RASP
+	 CHIPPER
+	 TOOTHBRUSH>>
+
+;"TEA stuff"
+
+<GLOBAL HOLDING-NO-TEA T>
+
+<ROUTINE LIQUID-SPILL ()
+	 <COND (<PRSI? ,FLOWERPOT ,PLANT>
+		<PERFORM ,V?WATER ,PRSI ,PRSO>
+		<RTRUE>)
+	       (T
+		<MOVE ,PRSO ,LOCAL-GLOBALS>
+		<COND (<EQUAL? ,PRSO ,BROWNIAN-SOURCE>
+		       <SETG BROWNIAN-SOURCE <>>)
+		      (<EQUAL? ,PRSO ,PANEL-BLOCKER>
+		       <SETG PANEL-BLOCKER <>>)>
+		<TELL "It spills all over and then evaporates.">
+		<COND (<PRSO? ,MINERAL-WATER>
+		       <ANTI-LITTER "bottle">)
+		      (T
+		       <ANTI-LITTER "cup">)>
+		<CRLF>)>>
+
+<ROUTINE ANTI-LITTER (STRING)
+	 <TELL " The " .STRING
+" itself vaporises, part of the Galactic Anti-Litter Program.">>
+
+<OBJECT TEA
+	(IN PAD)
+        (DESC "tea")
+	(DESCFCN TEA-DESCFCN)
+	(SYNONYM TEA CUP)
+	(ADJECTIVE REAL NICE HOT)
+	(FLAGS NARTICLEBIT TAKEBIT TRYTAKEBIT DRINKBIT)
+	(ACTION TEA-F)>
+
+<ROUTINE TEA-DESCFCN ("OPTIONAL" X)
+	 <DESCRIBE-DRINK ,TEA>>
+
+<ROUTINE DESCRIBE-DRINK (DRINK)
+	 <TELL "There is a nice, hot cup of " D .DRINK " here." CR>>
+
+<ROUTINE TEA-F ()
+	 <COND (<AND <VERB? TAKE>
+		     <PRSO? ,TEA>>
+		<MOVE ,TEA ,PROTAGONIST>
+		<SETG HOLDING-NO-TEA <>>
+		<TELL "no tea: Dropped." CR>)
+	       (<VERB? DROP>
+		<MOVE ,TEA ,HERE>
+		<COND (<EQUAL? ,HERE ,ACCESS-SPACE>
+		       <SETG HOLDING-NO-TEA T>
+		       <V-DROP>)
+		      (,HOLDING-NO-TEA
+		       <TELL "Dropped." CR>)
+		      (T
+		       <SETG HOLDING-NO-TEA T>
+		       <TELL "no tea: Taken." CR>)>)
+	       (<VERB? DRINK ENJOY DRINK-FROM>
+		<COND (<NOT <HELD? ,PRSO>>
+		       <TELL ,NOT-HOLDING " the cup!" CR>
+		       <RTRUE>)>
+		<SETG SCORE <+ ,SCORE 100>>
+		<MOVE ,TEA ,LOCAL-GLOBALS>
+		<SETG HOLDING-NO-TEA T>
+		<COND (<EQUAL? ,TEA ,BROWNIAN-SOURCE>
+		       <SETG BROWNIAN-SOURCE <>>)>
+		<TELL
+"It is the finest tea you have ever tasted. It has almost made this
+entire misadventure seem worthwhile. You experience several moments
+of complete happiness and relaxation.">
+		<ANTI-LITTER "cup">
+		<CRLF>)
+	       (<VERB? POUR THROW>
+		<LIQUID-SPILL>)
+	       (<VERB? EXAMINE LOOK-INSIDE>
+		<TELL
+,IT-LOOKS-LIKE " it has even more" ,BROWNIAN " than " D ,SUBSTITUTE "!">
+		<COND (<PRSO? ,BROWNIAN-SOURCE>
+		       <TELL " ">
+		       <PERFORM ,V?EXAMINE ,DANGLY-BIT>
+		       <RTRUE>)
+		      (T
+		       <CRLF>)>)>>
+
+<OBJECT NO-TEA
+	(IN GLOBAL-OBJECTS)
+	(DESC "no tea")
+	(SYNONYM TEA)
+	(ADJECTIVE NO)
+	(FLAGS NARTICLEBIT TRYTAKEBIT)
+	(ACTION NO-TEA-F)>
+
+<ROUTINE NO-TEA-F ()
+	 <COND (<AND <VERB? TAKE DROP>
+		     <PRSO? ,NO-TEA>
+		     <NOT <FSET? ,PARTICLE ,MUNGEDBIT>>>
+		<TELL
+"Your common sense tells you that you can't do that." CR>)
+	       (<AND <VERB? TAKE>
+		     <PRSO? ,NO-TEA>
+		     <NOT ,HOLDING-NO-TEA>>
+		<SETG HOLDING-NO-TEA T>
+		<TELL "no tea: Taken." CR>)
+	       (<AND <VERB? SHOW GIVE>
+		     <PRSI? ,SCREENING-DOOR>>
+		<RFALSE>)
+	       (<AND <VERB? ASK-ABOUT>
+		     <PRSO? ,GUIDE>>
+		<RFALSE>)
+	       (<AND <VERB? ASK-FOR>
+		     <PRSO? ,NUTRIMAT>>
+		<PERFORM ,V?RUB ,PAD>
+		<RTRUE>)
+	       (T
+		<TELL
+"You're talking complete nonsense; pull yourself together." CR>)>>
+
+<ROUTINE TEA-PRINT (OBJ) ;"tells MAIN-LOOP when to print OBJ: with VERB ALL"
+	 <COND (<NOT <EQUAL? .OBJ ,TEA ,NO-TEA>>
+		<RTRUE>)
+	       (<VERB? SHOW>
+		<RTRUE>)
+	       (<EQUAL? .OBJ ,TEA>
+		<COND (<VERB? TAKE>
+		       <COND (<HELD? ,TEA>
+			      <RTRUE>)
+			     (<AND ,PRSI
+				   <NOT <EQUAL? ,PRSI <LOC ,PRSO>>>>
+			      <RTRUE>)
+			     (T
+			      <RFALSE>)>)
+		      (<AND <VERB? DROP>
+			    <NOT ,HOLDING-NO-TEA>>
+		       <RFALSE>)>)
+	       (<AND <EQUAL? .OBJ ,NO-TEA>
+		     <VERB? TAKE>
+		     <NOT ,HOLDING-NO-TEA>>
+		<RFALSE>)
+	       (T
+		<RTRUE>)>>
+
+;"THUMB and GUIDE stuff"
+
+<OBJECT THUMB
+	(IN SATCHEL)
+	(DESC "electronic Sub-Etha signaling device")
+	(SYNONYM THUMB DEVICE SENSO)
+	(ADJECTIVE ELECTR SUB-E SIGNAL SMALL BLACK LITTLE BLINKI)
+	(SIZE 10)
+	(FLAGS TAKEBIT VOWELBIT CONTBIT OPENBIT)
+	(ACTION THUMB-F)>
+
+<ROUTINE THUMB-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The " D ,THUMB " is shaped like a small fist with an extended thumb. Various
+lights along its \"knuckles\" are currently ">
+		<COND (<OR <IN? ,FLEET ,HERE>
+			   <EQUAL? ,HERE ,AIRLOCK ,INSIDE-WHALE>>
+		       <TELL
+"blinking wildly, indicating a spaceship in the vicinity">)
+		      (T
+		       <TELL "dark">)>
+		<TELL
+". It has two small buttons, a red one labelled \"Call Engineer\" and a green
+one labelled \"Hitchhike.\"">
+		<FINE-PRODUCT>
+		<TELL
+" Affixed to the Thumb is a lifetime " D ,GUARANTEE "." CR>)
+	       (<AND <VERB? TAKE>
+		     <EQUAL? ,IDENTITY-FLAG ,FORD>
+		     <IN? ,FLEET ,HERE>
+		     <NOT <IN? ,THUMB ,SATCHEL>>>
+		<TELL ,DRIVEN-BACK CR>)
+	       (<VERB? OPEN CLOSE LOOK-INSIDE>
+		<TELL "Impossible." CR>)>>
+
+<OBJECT RED-BUTTON
+	(IN THUMB)
+	(DESC "red button")
+	(SYNONYM BUTTON)
+	(ADJECTIVE RED SMALL)
+	(FLAGS NDESCBIT INTEGRALBIT)
+	(SIZE 1)
+	(ACTION RED-BUTTON-F)>
+
+<ROUTINE RED-BUTTON-F ()
+	 <COND (<VERB? PUSH>
+		<COND (<NOT <HELD? ,THUMB>>
+		       <PERFORM ,V?PUSH ,GREEN-BUTTON>
+		       <RTRUE>)
+		      (<IN? ,ENGINEER ,HERE>
+		       <TELL
+"Another " D ,ENGINEER " zips up, spots the first one, looks confused,
+and leaves again." CR>)
+		      (T
+		       <MOVE ,ENGINEER ,HERE>
+		       <MOVE ,BIKE ,HERE>
+		       <ENABLE <QUEUE I-ENGINEER 2>>
+		       <TELL
+"With a screech of ion brakes a " ,SCC " Repair Robot pulls up on a bike
+from out of the Sub-Etha." CR>)>)>>
+
+<OBJECT GREEN-BUTTON
+	(IN THUMB)
+	(DESC "green button")
+	(SYNONYM BUTTON)
+	(ADJECTIVE GREEN SMALL HITCHH)
+	(FLAGS NDESCBIT INTEGRALBIT)
+	(SIZE 1)
+	(ACTION GREEN-BUTTON-F)>
+
+<ROUTINE GREEN-BUTTON-F ()
+	 <COND (<VERB? PUSH>
+		<COND (<NOT <HELD? ,THUMB>>
+		       <TELL ,NOT-HOLDING " the " D ,THUMB "." CR>
+		       <SETG P-IT-OBJECT ,THUMB>)
+		      (<AND <EQUAL? ,IDENTITY-FLAG ,FORD>
+			    <IN? ,FLEET ,HERE>>
+		       <MOVE ,THUMB ,HERE>
+		       <TELL ,THUMB-FUMBLE CR>)
+		      (<FSET? ,THUMB ,MUNGEDBIT>
+		       <TELL "The" ,THUMB-CLICKS CR>)
+		      (<IN? ,FLEET ,HERE>
+		       <COND (<EQUAL? ,DRUNK-LEVEL 3>
+			      <TELL
+"Lights whirl sickeningly around your head, the ground arches away beneath
+your feet, and every atom of your being is scrambled, an experience you're
+probably going to have to get used to. You are in..." CR CR>
+			      <LEAVE-EARTH>
+			      <GOTO ,DARK>)
+			     (T
+			      <TELL "A" ,BEAM>
+			      <JIGS-UP
+" is certainly a shock to the system. Too bad you didn't consume
+enough alcohol to withstand it.">
+			      <RTRUE>)>)
+		      (<EQUAL? ,HERE ,AIRLOCK ,INSIDE-WHALE>
+		       <TELL
+"Every molecule in your body gets pulled away from every other molecule.
+Then suddenly they snap back together again like elastic, and you find,
+with a dizzy head and very sore molecules, that you are in..." CR CR>
+		       <SETG HEART-PROB 100>
+		       <GOTO ,DARK>)
+		      (T
+		       <FSET ,THUMB ,MUNGEDBIT>
+		       <TELL
+"The Thumb winks and flashes for a second. Nothing further happens." CR>)>)>>
+
+<OBJECT GUARANTEE
+	(IN THUMB)
+	(DESC "guarantee")
+	(SYNONYM GUARAN WARRAN PLAQUE)
+	(ADJECTIVE LIFETI)
+	(FLAGS NDESCBIT INTEGRALBIT)
+	(SIZE 2)
+	(ACTION GUARANTEE-F)>
+
+<ROUTINE GUARANTEE-F ()
+	 <COND (<VERB? READ EXAMINE>
+		<TELL
+"The lifetime " D ,GUARANTEE " states that the Thumb will be repaired on site
+by trained " ,SCC " Field Engineers." CR>)>>
+
+<OBJECT ENGINEER
+	(IN LOCAL-GLOBALS) ;"just for the purpose of MOBY-FIND"
+	(DESC "Engineer robot")
+	(SYNONYM ROBOT ENGINE)
+	(ADJECTIVE ENGINE)
+	(FLAGS VOWELBIT ACTORBIT CONTBIT OPENBIT SEARCHBIT)
+	(ACTION ENGINEER-F)>
+
+<ROUTINE ENGINEER-F ()
+	 <COND (<EQUAL? ,ENGINEER ,WINNER>
+		<ENABLE <QUEUE I-ENGINEER 2>>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <PRSO? ,ME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,ENGINEER ,PRSI>
+		       <SETG WINNER ,ENGINEER>
+		       <RTRUE>)
+		      (<VERB? HELLO>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?HELLO ,ENGINEER>
+		       <SETG WINNER ,ENGINEER>
+		       <RTRUE>)
+		      (<AND <VERB? REPAIR>
+			    <PRSO? ,THUMB>>
+		       <COND (<IN? ,THUMB ,ENGINEER>
+			      <TELL "\"I'm doing my best...\"" CR>
+			      <RTRUE>)>
+		       <SETG WINNER ,PROTAGONIST>
+		       <MOVE ,THUMB ,PROTAGONIST>
+		       <PERFORM ,V?GIVE ,THUMB ,ENGINEER>
+		       <SETG WINNER ,ENGINEER>
+		       <RTRUE>)
+		      (<VERB? REPAIR>
+		       <TELL "\"I repair only " D ,THUMB "s!\"" CR>)
+		      (<AND <VERB? YES>
+			    <EQUAL? ,AWAITING-REPLY 12>>
+		       <V-YES>)
+		      (<AND <VERB? NO>
+			    <EQUAL? ,AWAITING-REPLY 12>>
+		       <V-NO>)
+		      (T
+		       <TELL
+"\"Can't chat, pal, I'm attending to an important repair call.\"" CR>
+		       <FUCKING-CLEAR>)>)
+	       (<AND <VERB? GIVE SHOW>
+		     <PRSO? ,THUMB>>
+		<COND (<FSET? ,THUMB ,MUNGEDBIT>
+		       <ENABLE <QUEUE I-ENGINEER 2>>
+		       <SETG THUMB-SHOWN 1>
+		       <MOVE ,THUMB ,ENGINEER>
+		       <TELL
+"The " D ,ENGINEER " takes it, looks at it with horror, shakes his head, sighs,
+and says \"Who sold you this then?\"" CR CR>
+		       <PRINTI ">">
+		       <READ ,P-INBUF ,P-LEXV>
+		       <TELL
+"The " D ,ENGINEER " ignores your reply and shakes the Thumb despondently.
+\"This is a model 13X,\" he says. \"Not meant for this sort of job. Anyway,
+it's discontinued. Can't get the parts.\"" CR>)
+		      (T
+		       <MOVE ,THUMB ,PROTAGONIST>
+		       <ENGINEER-LEAVE>
+		       <TELL
+"The " D ,ENGINEER " takes the Thumb, shakes it, looks it up and down.
+\"Seems to be working OK to me. Unusual for a 13X.\" He hands it back
+and" ,ROARS-OFF "." CR>)>)
+	       (<AND <VERB? GIVE SHOW>
+		     <PRSO? ,GUARANTEE>>
+		<COND (<NOT <FSET? ,THUMB ,MUNGEDBIT>>
+		       <PERFORM ,V?GIVE ,THUMB ,ENGINEER>
+		       <RTRUE>)>
+		<FCLEAR ,THUMB ,MUNGEDBIT>
+		<ENGINEER-LEAVE>
+		<MOVE ,THUMB ,PROTAGONIST>
+		<COND (<EQUAL? ,THUMB-SHOWN 0>
+		       <TELL
+"The " D ,ENGINEER " looks quizzically at the " D ,GUARANTEE " and says it's
+expired but he'll see what he can do. " ,FIDDLES "\"Can't promise anything.\"
+He" ,ROARS-OFF "." CR>)
+		      (T
+		       <SETG THUMB-SHOWN 0>
+		       <TELL
+"The " D, ENGINEER " looks at it sceptically. \"Guaranteed to work normally for
+life,\" he mutters. \"Well, it's perfectly normal for a 13X to break down. And
+this one's reached the end of its life anyway. But I'll see what I can do.\""
+CR CR ,FIDDLES "\"Best I can do for a 13X on an expired " D ,GUARANTEE ",\" he
+says. \"Can't promise anything.\" He" ,ROARS-OFF "." CR>)>)>>
+
+<GLOBAL ENGINEER-COUNTER 0>
+
+<GLOBAL THUMB-SHOWN 0>
+
+<ROUTINE ENGINEER-LEAVE ()
+	 <COND (<IN? ,THUMB ,ENGINEER>
+		<COND (<IN? ,ENGINEER ,HERE>
+		       <MOVE ,THUMB ,PROTAGONIST>)
+		      (T
+		       <MOVE ,THUMB <LOC ,ENGINEER>>)>)>
+	 <MOVE ,ENGINEER ,LOCAL-GLOBALS>
+	 <MOVE ,BIKE ,LOCAL-GLOBALS>
+	 <DISABLE <INT I-ENGINEER>>
+	 <SETG THUMB-SHOWN 0>
+	 <SETG ENGINEER-COUNTER 0>>
+
+<ROUTINE I-ENGINEER ()
+	 <ENABLE <QUEUE I-ENGINEER -1>>
+	 <SETG ENGINEER-COUNTER <+ ,ENGINEER-COUNTER 1>>
+	 <COND (<NOT <IN? ,ENGINEER ,HERE>>
+		<ENGINEER-LEAVE>
+		<RFALSE>)>
+	 <CRLF>
+	 <COND (<EQUAL? ,THUMB-SHOWN 1>
+		<SETG THUMB-SHOWN 2>
+		<TELL
+"The " D ,ENGINEER " ignores you completely. \"See, this is the model with
+the 5kz booster,\" he says. \"Hopeless.\" He shakes his head grimly." CR>)
+	       (<EQUAL? ,THUMB-SHOWN 2>
+		<TELL
+"The " D ,ENGINEER " ignores you. \"What you want, you see, is one of the new
+Mk7's. Only you can't get them. Out of stock till Zarkmas. Sorry.\" He">
+		<COND (<IN? ,THUMB ,ENGINEER>
+		       <TELL " gives the defunct Thumb back and">)>
+		<ENGINEER-LEAVE>
+		<TELL ,ROARS-OFF "." CR>)
+	       (<EQUAL? ,ENGINEER-COUNTER 1>
+		<SETG AWAITING-REPLY 12>
+		<ENABLE <QUEUE I-REPLY 2>>
+		<TELL
+"The " D, ENGINEER " looks around. \"Somebody call the repair service?\"" CR>)
+	       (<EQUAL? ,ENGINEER-COUNTER 2>
+		<TELL
+"The " D ,ENGINEER " looks impatient and guns the throttle of his cycle." CR>)
+	       (T
+		<ENGINEER-LEAVE>
+		<TELL
+"\"Probably a kid playing around with someone else's Thumb,\" grumbles the "
+D ,ENGINEER " and" ,ROARS-OFF "." CR>)>>
+
+<OBJECT BIKE
+	(IN LOCAL-GLOBALS) ;"for purposes of MOBY-FIND"
+	(DESC "bike")
+	(SYNONYM BIKE CYCLE)
+	(ADJECTIVE ION)
+	(FLAGS NDESCBIT TRYTAKEBIT)>
+
+<OBJECT GUIDE
+	(IN SATCHEL)
+	(DESC "The Hitchhiker's Guide")
+	(DESCFCN GUIDE-DESCFCN)
+	(SYNONYM COPY GUIDE)
+	(ADJECTIVE HITCHH SUB-E)
+	(SIZE 10)
+	(FLAGS NARTICLEBIT TAKEBIT READBIT)
+	(TEXT "Try: CONSULT GUIDE ABOUT (something).")
+	(ACTION GUIDE-F)>
+
+<ROUTINE GUIDE-DESCFCN ("OPTIONAL" X)
+	 <TELL "There is a copy of " ,GUIDE-NAME " here." CR>>
+
+<ROUTINE GUIDE-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The Guide is a Mark II model. Its only resemblance to the Mark IV pictured
+in the brochure in your game package is the large, friendly \"Don't Panic!\"
+on its cover.|
+|
+The Guide is a Sub-Etha Relay. You can use it to tap information from a huge
+and distant data bank by consulting the Guide about some item or subject." CR>)
+	       (<AND <VERB? ASK-ABOUT>
+		     <PRSO? ,GUIDE>>
+		<COND (<FSET? ,TOWEL ,WORNBIT>
+		       <TELL ,WITH-TOWEL CR>
+		       <RTRUE>)
+		      (<PRSI? ,ACCESS-SPACE>
+		       <TELL
+"Suddenly, agents of the " ,AGENCY " pop in using Sub-Etha belts, rough you up
+a bit, tell you there's no such thing as the " ,AGENCY " and never to consult "
+D ,GUIDE " about the " ,AGENCY " again; then they leave." CR>
+		       <RTRUE>)>
+		<TELL
+"The Guide checks through its Sub-Etha-Net database and eventually comes
+up with the following entry:" CR CR>
+		<COND (<PRSI? ,GUIDE>
+		       <TELL
+D ,GUIDE " is a wholly remarkable product." ,ALREADY-KNOW-THAT CR>)
+		      (<PRSI? ,DANGLY-BIT ,SMALL-RECEPTACLE ,LARGE-PLUG
+			      ,SMALL-PLUG ,GREEN-BUTTON ,RED-BUTTON>
+		       <TELL "Part of">
+		       <COND (<AND <PRSI? ,LARGE-PLUG>
+				   <NOT <IN? ,LARGE-PLUG ,SPARE-DRIVE>>>
+			      <ARTICLE ,SPARE-DRIVE>)
+			     (T
+			      <ARTICLE <LOC ,PRSI>>)>
+		       <TELL "." CR>)
+		      (<PRSI? ,WAR-CHAMBER>
+		       <TELL
+"If you have to consult the Guide about that, you're probably in serious
+shape. Consult a medic instead." CR>)
+		      (<PRSI? ,DAMOGRAN>
+		       <TELL
+D ,DAMOGRAN " is a planet whose surface is mostly water. It is a favourite
+spot for Presidential dedication ceremonies" ,ALSO-SEE "France." CR>)
+		      (<PRSI? ,CLIFF>
+		       <TELL
+"France is the largest landmass on the planet " D ,DAMOGRAN "." CR>)
+		      (<PRSI? ,HEART-OF-GOLD>
+		       <TELL
+"There is absolutely no such spaceship as " D ,HEART-OF-GOLD " and anything
+you've ever read in this spot to the contrary was just a prank.|
+   -- " ,AGENCY CR>) 
+		      (<PRSI? ,POETRY>
+		       <TELL
+D ,POETRY " is so awful that even the Sarkopsi of Burphon XII, whose religion
+strictly forbids the taking of one's life, consider suicide a preferable
+alternative to a " D ,POETRY " reading." CR>)
+		      (<PRSI? ,VOGON-CAPTAIN ,FLEET>
+		       <TELL
+"Vogons, whose specialties are bureaucracy and planet-smashing, are the most
+unpleasant race in the Galaxy. They wouldn't think twice about throwing someone
+into space, and wouldn't lift a finger to save their own grandmother from the "
+D ,BEAST ,ALSO-SEE D ,POETRY " and the " D ,BEAST "." CR>)
+		      (<PRSI? ,BEER ,PUB>
+		       <TELL
+"Alcohol, in addition to its familiar enjoyable effects, also helps cushion
+the shock of" ,BEAM "s." CR>)
+		      (<PRSI? ,BRIDGE>
+		       <TELL
+"The best randomness generator is simple" ,BROWNIAN ". Any hot gas or
+liquid is a good source." CR>)
+		      (<PRSI? ,GALLEY>
+		       <TELL
+"The " ,SCC " incompetently produces a wide range of inefficient and unreliable
+high-tech machinery. However, thanks to SCC's ruthless marketing division, this
+junk accounts for over 95% of the high-tech machinery sold in the Galaxy.
+(SCC's marketing division will be the first against the wall when the
+revolution comes.)" CR>)
+		      (<PRSI? ,PANTRY>
+		       <TELL
+"Thirty million generations of philosophers have debated the definition of
+intelligence. The most popular definition appears in the " ,SCC " android
+manuals: \"Intelligence is the ability to reconcile totally contradictory
+situations without going completely bonkers -- for example, having a stomach
+ache and not having a stomach ache at the same time, holding a hole without
+the doughnut, having good luck and bad luck simultaneously, or seeing a real
+estate agent waive his fee.\"" CR>)
+		      (<PRSI? ,SCREENING-DOOR>
+		       <TELL
+"These " ,SCC " doors screen visitors for such qualities as intelligence
+and ability to time travel" ,ALSO-SEE ,SCC ", " ,GPP ", Intelligence,
+and Time Travel." CR>)
+		      (<PRSI? ,HATCHWAY ,MARVIN ,EDDIE>
+		       <TELL
+,GPP " are a misguided attempt by the " ,SCC " to make their machines behave
+more like people. Among the more miserable failures: paranoid-depressive
+robots and over-protective computers." CR>)
+		      (<PRSI? ,DARK>
+		       <TELL
+"A must for the serious hitchhiker, peril-sensitive sunglasses darken at the
+first hint of danger, thus shielding the wearer from seeing anything alarming.
+Recommended brand: Joo Janta." CR>)   
+		      (<PRSI? ,RAMP>
+		       <TELL
+"According to legend, Magrathea was a planet that amassed incredible wealth by
+manufacturing " D ,OTHER-PLANETS ". The legends also mention it as the setting
+of the very eagerly awaited second Infocom Hitchhiker's game." CR>)
+		      (<PRSI? ,ENGINE-ROOM ,MAIN-DRIVE ,SPARE-DRIVE>
+		       <TELL
+"Scientists have long known how to produce FINITE amounts of improbability,
+using a " ,FIG ", an " D ,PLOTTER " and a good source of" ,BROWNIAN ".
+Recently, however, they have learned to generate INFINITE amounts, thanks to
+the invention of the In" ,FIG ". It is rumored that an" ,IID ", based on this
+new generator, is currently under development" ,ALSO-SEE D ,PLOTTER " and"
+,BROWNIAN "." CR>)
+		      (<PRSI? ,PLOTTER>
+		       <TELL
+"The " D ,PLOTTER " is one of the primary application devices of
+Improbability Physics." CR>)
+		      (<PRSI? ,PEANUTS ,HOLD>
+		       <TELL
+"Sources of protein, such as the common peanut, are carried by all serious
+hitchhikers. Protein loss occurs in" ,BEAM "s and you will become groggy
+unless you replace it immediately." CR>)
+		      (<PRSI? ,NUTRIMAT ,NUT-COM-INTERFACE>
+		       <TELL
+"A typically unreliable " ,SCC " product, the " D ,NUTRIMAT " analyses
+the user's neural paths to provide the (supposedly) ideal offering. Its
+computing power is frankly abysmal, so the optional computer interface
+is a good thing to go for.">
+		       <CRLF>)
+		      (<PRSI? ,POCKET-FLUFF ,JACKET-FLUFF
+			      ,SATCHEL-FLUFF ,CUSHION-FLUFF>
+		       <TELL
+"Fluff is interesting stuff: a deadly poison on Bodega Minor, the diet staple
+of Frazelon V, the unit of currency on the moons of the Blurfoid system, and
+the major crop of the laundry supplies planet, Blastus III.|
+One ancient legend claims that four pieces of fluff lie scattered around the
+Galaxy; each forming one-quarter of the seedling of a tree with amazing
+properties, the sole survivor of the tropical planet Fuzzbol (Footnote 8).|
+The ultimate source of fluff is still a mystery, with the scientific community
+torn between the Big Lint Bang theory and the White Lint Hole theory." CR>) 
+		      (<OR <PRSI? ,ZAPHOD>
+			   <AND <PRSI? ,ME>
+				<EQUAL? ,IDENTITY-FLAG ,ZAPHOD>>>
+		       <TELL D ,ZAPHOD " is the current" ,PRESIDENT "." CR>) 
+		      (<PRSI? ,BABEL-FISH>
+		       <TELL
+"A mind-bogglingly improbable creature. A " D ,BABEL-FISH ", when placed in
+one's ear, allows one to understand any language." CR>)
+		      (<PRSI? ,TOWEL>
+		       <TELL
+"A towel is the most useful thing (besides the Guide) a Galactic hitchhiker
+can have. Its uses include travel, combat, communications, protection from the
+elements, hand-drying and reassurance. Towels have great symbolic value, with
+many associated points of honour. Never mock the towel of another, even if it
+has little pink and blue flowers on it. Never do something to somebody else's
+towel that you would not want them to do to yours. And, if you borrow the towel
+of another, you MUST return it before leaving their world." CR>)
+		      (<PRSI? ,THUMB ,GUARANTEE>
+		       <TELL
+"The Electronic Sub-Etha Auto Hitching Thumb is a wonderful thing, but should
+not be mistreated. If used while a ship is near, you will be transported there.
+If no ship is in the vicinity, you will place a heavy strain on the Thumb's
+logic circuits, which could lead to malfunction. The Thumb carries the usual "
+,SCC " lifetime " D ,GUARANTEE "s." CR>)
+		      (<PRSI? ,MINERAL-WATER>
+		       <TELL
+"A strong body of opinion holds that this is not water at all, despite the
+claims on the label about how pure the spring is, and all that tosh about
+sparkling babbling brooks and so on. There is something highly suspect about
+the water on Santraginus Five, as anyone who's ever met any of their fish
+will tell you." CR>)
+		      (<PRSI? ,BEAST>
+		       <TELL
+"The " D ,BEAST " is a mind-bogglingly stupid animal. It has almost no capacity
+for learning from experience and is therefore surprised by virtually everything
+that happens to it. Here is an example of how stupid it is: it thinks that if
+you can't see it, it can't see you.|
+Its behaviour would be quite endearing if it wasn't spoilt by this one
+thing: it is the most violently carnivorous creature in the Galaxy. Avoid,
+avoid, avoid." CR>)
+		      (<PRSI? ,FRONT-PORCH>
+		       <TELL
+"A thoroughly unpleasant means of travelling which involves tearing you apart
+in one place and slamming you back together in another. (Of course, it's
+better than the older method, where disassembled people would be transmitted
+down phone lines and arrive in a garbled and sometimes completely disconnected
+state.) You should have a drink or two or three before going through one"
+,ALSO-SEE "Galaxia Woonbeam, Alcohol, and Protein." CR>)
+		      (<PRSI? ,FRONT-OF-HOUSE>
+		       <TELL
+"Galaxia Woonbeam is the author of \"Slimmer's Guide to Weightloss During
+Matter Disassembly Transition.\" This text is currently the subject of the
+biggest suit for criminal negligence damages in history and is unavailable
+at this time." CR>)
+		      (<PRSI? ,ENTRY-BAY>
+		       <TELL
+"The best drink in existence; somewhat like having your brains smashed out by
+a slice of lemon wrapped around a large gold brick." CR>)
+		      (<PRSI? ,THIRD-PLANET ,MAZE>
+		       <TELL "Mostly harmless." CR>)
+		      (<PRSI? ,COUNTRY-LANE>
+		       <TELL ,SPACE-TEXT CR>)
+		      (<FSET? ,PRSI ,TOOLBIT>
+		       <TELL
+"The editor responsible for entries under this heading has been out to lunch
+for a couple of years but is expected back soon, at which point there will be
+rapid updates. Until then, don't panic, unless your situation is really a life
+or death one, in which case, sure, go ahead, panic." CR>)
+		      (<PRSI? ,BEDROOM ,RIFLES ,BLASTER ,TEA ,NO-TEA ,BEAST-GUN
+			      ,SUBSTITUTE ,AFT-CORRIDOR ,AIRLOCK ,INSIDE-WHALE>
+		       <TELL
+"Sorry, that portion of our Sub-Etha database was accidentally deleted last
+night during a wild office party. The lost data will be restored as soon as
+we find someone who knows where the back-up tapes are kept, if indeed any
+are kept at all." CR>)
+		      (T
+		       <TELL
+"That is one of the Great Unanswered Questions. For a list of the others,
+consult the Guide." CR>)>)>>
+
+<GLOBAL SPACE-TEXT
+"If you hyperventilate and then empty your lungs, you will last about thirty
+seconds in the vacuum of space. However, because space is so vastly hugely
+mind-bogglingly big, getting picked up by another ship within those thirty
+seconds is almost infinitely improbable.">
+
+;"shared stuff"
+
+<ROUTINE CANT-SEE (OBJ)
+	 <TELL "You can't see">
+	 <COND (<NOT <NAME? .OBJ>>
+		<TELL " any">)>
+	 <COND (<EQUAL? .OBJ ,PRSO>
+		<PRSO-PRINT>)
+	       (T
+		<PRSI-PRINT>)>
+	 <TELL " here." CR>
+	 <FUCKING-CLEAR>>
+
+<ROUTINE TELL-ME-HOW ()
+	 <TELL "You must tell me how to do that to">
+	 <ARTICLE ,PRSO>
+	 <TELL "." CR>>
+
+<ROUTINE OUT-OF-FIRST (VEHICLE)
+	 <TELL "You'll have to get out of the " D .VEHICLE " first." CR>>
+
+<ROUTINE PRIVATE (STRING)
+	 <TELL
+"You can't. It's not yours. It's " .STRING "'s and it's private." CR>>
+
+<ROUTINE NOT-VERY-GOOD (STRING)
+	 <TELL "It's not a very good " .STRING ", is it?" CR>>
+
+<ROUTINE FACTOR (STRING)
+	 <TELL
+" at an improbability factor of 2 to the " .STRING "th power to 1 against.">>
+
+<ROUTINE REMOVING-BIT ()
+	 <TELL "(removing the " D ,DANGLY-BIT " first)" CR>>
+
+<ROUTINE PART-OF ()
+	 <TELL "You can't --">
+	 <ARTICLE ,PRSO T>
+	 <TELL " is an integral part of">
+	 <ARTICLE <LOC ,PRSO> T>
+	 <TELL "." CR>>
+
+<ROUTINE BUT-THAT-MAN (STRING)
+	 <TELL
+"Pointing toward Prosser, " .STRING " \"But that man ">
+	 <COND (,HOUSE-DEMOLISHED
+		<TELL "just knocked">)
+	       (T
+		<TELL "wants to knock">)>
+	 <TELL " my house down!\"">>
+
+<ROUTINE CUSHION ()
+	 <TELL
+" cushion your system against the coming shock of the" ,BEAM ".">>
+
+<ROUTINE FINE-PRODUCT ()
+	 <TELL " It bears a small label which reads \"Another fine product
+of the " ,SCC ".\"">>
+
+<ROUTINE MAKE-WAY-FOR ()
+	 <TELL
+" a " D ,FLEET " unexpectedly arrives and demolishes the Earth to make way
+for a new hyperspace bypass." CR>>
+
+<ROUTINE OWN-FEET ()
+	 <TELL "You are now on your feet." CR>>
+
+<GLOBAL DOWN-WELL "It goes down well.">
+
+<GLOBAL NOT-PLUGGED "It's not plugged into anything!">
+
+<GLOBAL LYING-ABOUT-EXIT "(We were lying about the exit to port.) ">
+
+<GLOBAL ROARS-OFF " roars off on his ion bike into the Sub-Etha">
+
+<GLOBAL FIDDLES
+"He fiddles with the Thumb for a moment or two before handing it back. ">
+
+<GLOBAL LOOK-AROUND "Look around you.">
+
+<GLOBAL TOO-DARK "It's too dark to see!">
+
+<GLOBAL CANT-GO "You can't go that way.">
+
+<GLOBAL YOU-ARE "You already are!">
+
+<GLOBAL ALREADY-OPEN "It is already open.">
+
+<GLOBAL ALREADY-CLOSED "It is already closed.">
+
+<GLOBAL REFERRING "I don't see what you're referring to.">
+
+<GLOBAL WHILE-LYING "You can't do that while you're lying down!">
+
+<GLOBAL WITH-TOWEL "With a towel wrapped around your head!?!">
+
+<GLOBAL ZEN "A brave, Zen-like effort. It fails.">
+
+<GLOBAL BULLDOZER-PILES "The bulldozer piles into the side of your home.">
+
+<GLOBAL IT-LOOKS-LIKE "It looks like">
+
+<GLOBAL CLAWS " its tungsten carbide Vast-Pain claws">
+
+<GLOBAL PRESIDENT " President of the Galaxy">
+
+<GLOBAL SCC "Sirius Cybernetics Corporation">
+
+<GLOBAL BEAM " matter transference beam">
+
+<GLOBAL FLEET-PLUNGES "The battle fleet plunges toward Earth and">
+
+<GLOBAL ABOVE-NOISE "He can't hear you above the noise." >
+
+<GLOBAL BATTLE-SHORTS " black jewelled battle shorts, ">
+
+<GLOBAL CLOUD-OF-STEAM " in a cloud of green, sweet-smelling steam. ">
+
+<GLOBAL GUIDE-NAME "The Hitchhiker's Guide to the Galaxy">
+
+<GLOBAL ALREADY-KNOW-THAT 
+" But then again you must already know that, since you bought one.">
+
+<GLOBAL THUMB-CLICKS " Thumb merely makes a few feeble clicking noises.">
+
+<GLOBAL BROWNIAN " Brownian motion">
+
+<GLOBAL ASK-ABOUT-OBJECT "\"Oh...you're trying to figure that out also? The
+manual's not much help, is it? By the way, do you know your score? I don't.
+My computer doesn't have a status line.\"">
+
+<GLOBAL DRIVEN-BACK "You struggle to reach the Thumb, but the wind is too
+fierce and you are driven back.">
+
+<GLOBAL GUARDS-REALIZE "A wisp of an inkling of a thought penetrates the
+three-inch thickness of solid bone surrounding the guards' very tiny brains
+that something suspicious is going on. ">
+
+<GLOBAL GETTING-CLOSE " You're getting close, though.">
+
+<GLOBAL GPP "Genuine People Personalities">
+
+<GLOBAL ALSO-SEE ". Also see the entries on ">
+
+<GLOBAL JUST-AS 
+"Just as the Beast is trying to work out where you've disappeared to, it ">
+
+<GLOBAL BUDGE "It won't budge.">
+
+<GLOBAL BEAST-DESC
+"You notice the Beast's Lasero-Zap eyes, its Swivel Shear Teeth, and its
+several dozen tungsten carbide Vast-Pain claws, forged in the sun furnaces
+of Zangrijad. It has skin like a motorway and breath like a 747.">
+
+<GLOBAL NOT-HOLDING "You're not holding">
+
+<GLOBAL WITH-PASSION
+" with passion, and ignores a passing microscopic space fleet.">
+
+<GLOBAL DIALLING-TONE " A moment later, the dialing tone is suddenly cut off.
+Glancing through the window you can't help but notice the large old oak tree of
+which you are particularly fond crashing down through the phone cable.">
+
+<GLOBAL ANNOUNCEMENT "\"Announcement, announcement. This is ">
+
+<GLOBAL HANDS-OFF "The barman snaps \"Hands off until you pay for it!\"">
+
+<GLOBAL ARRESTED "Do you want to get arrested for indecent exposure?">
+
+<GLOBAL AGENCY "Galactic Security Agency">
+
+<GLOBAL LOST-PLANET " the legendary lost planet of Magrathea">
+
+<GLOBAL DONT-MIX
+"Despite your hangover, you recall that Zaphod and water don't mix.">
+
+<GLOBAL CROWD-CHEERS "The crowd cheers wildly! It thinks you're terrific.">
+
+<GLOBAL HUMANS "Humans are so depressingly ">
+
+<GLOBAL EYE-STALK "electronic eye stalk shoots up from the hood, ">
+
+<GLOBAL SLOWLY-DAWNS
+" Slowly it dawns on the creature that someone is trying to make a fool
+of it. It starts to look for you again.">
+
+<GLOBAL IID " Infinite Improbability Drive">
+
+<GLOBAL FIG "finite Improbability Generator">
+
+<GLOBAL ROBOT-FLIES-IN
+"A small upper-half-of-the-room cleaning robot flies into the room, ">
+
+<GLOBAL ON-OTHER-SIDE "standing on the other side">
+
+<GLOBAL MOP " the manual override receptacle">
+
+<GLOBAL NICE-DAY "t's a bright morning, the sun is shining, the birds are
+singing, the meadows are blooming">
+
+<GLOBAL GET-RID " you've been trying to get rid of it for years.">
+
+<GLOBAL THUMB-FUMBLE "You fumble with the Thumb as you hold onto the tree
+against the fierce wind. It falls to the ground near Arthur's feet.">
+
+<GLOBAL ENGAGED " all circuits are currently engaged by the ">
\ No newline at end of file
diff --git a/heart.zil b/heart.zil
new file mode 100644
index 0000000..f529f35
--- /dev/null
+++ b/heart.zil
@@ -0,0 +1,1978 @@
+"HEART for
+		  THE HITCHHIKER'S GUIDE TO THE GALAXY
+	(c) Copyright 1984 Infocom, Inc.  All Rights Reserved."
+
+<ROUTINE IN-HEART? (OBJ)
+   <COND (<OR <EQUAL? <META-LOC .OBJ> ,ENTRY-BAY ,FORE-CORRIDOR ,AFT-CORRIDOR>
+	      <EQUAL? <META-LOC .OBJ> ,GALLEY ,BRIDGE ,ENGINE-ROOM>
+	      <EQUAL? <META-LOC .OBJ> ,HATCHWAY ,PANTRY ,ACCESS-SPACE>>
+	  <RTRUE>)
+	 (T
+	  <RFALSE>)>>
+
+<OBJECT HEART-OF-GOLD
+	(IN LOCAL-GLOBALS)
+	(DESC "the Heart of Gold")
+	(SYNONYM HEART GOLD SHIP SPACES)
+	(ADJECTIVE SPACE INCRED NEW)
+	(FLAGS NARTICLEBIT)
+	(ACTION HEART-OF-GOLD-F)>
+
+<ROUTINE HEART-OF-GOLD-F ()
+	 <COND (<VERB? LEAVE EXIT DISEMBARK>
+		<COND (<EQUAL? ,HERE ,HATCHWAY>
+		       <DO-WALK ,P?DOWN>)
+		      (<EQUAL? ,HERE ,DAIS>
+		       <TELL ,LOOK-AROUND CR>)
+		      (T
+		       <V-WALK-AROUND>)>)
+	       (<VERB? THROUGH WALK-TO BOARD>
+		<COND (<EQUAL? ,HERE ,DAIS>
+		       <DO-WALK ,P?EAST>)
+		      (<IN-HEART? ,PROTAGONIST>
+		       <TELL ,LOOK-AROUND CR>)>)>>
+
+<GLOBAL TEA-SHOWN <>>
+
+<GLOBAL SUBSTITUTE-DRUNK <>>
+
+<ROOM PANTRY
+      (IN ROOMS)
+      (SYNONYM INTELL)
+      (DESC "Marvin's Pantry")
+      (LDESC "This is a small closet with an exit to starboard.")
+      (EAST TO AFT-CORRIDOR)
+      (OUT TO AFT-CORRIDOR)
+      (FLAGS RLANDBIT ONBIT NARTICLEBIT)
+      (PSEUDO "PANTRY" GLOBAL-ROOM-F "CLOSET" GLOBAL-ROOM-F)
+      (GLOBAL HEART-OF-GOLD SCREENING-DOOR)
+      (ACTION PANTRY-F)>
+
+<ROUTINE PANTRY-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<COND (<NOT ,LANDED>
+		       <MOVE ,MARVIN ,HERE>
+		       <DISABLE <INT I-MARVIN>>)>
+		<COND (<FSET? ,SCREENING-DOOR ,MUNGEDBIT>
+		       <TELL
+"As you pass the door, it slams against you, bruising your upper arm, and then
+opens again. \"Take that, door-kicker.\"" CR CR>)>
+		<TELL
+"Upon entering the room, you are battered by tidal waves of depression. ">
+		<COND (<L? ,SCORE 300>
+		       <JIGS-UP "In fact, a lethal dose.">
+		       <RTRUE>)
+		      (T
+		       <COND (<NOT <FSET? ,PANTRY ,REVISITBIT>>
+			      <FSET ,PANTRY ,REVISITBIT>
+			      <SETG SCORE <+ ,SCORE 25>>)>
+		       <TELL
+"However, the happiness derived from your high score and that thoroughly
+excellent cup of tea you had recently help you to survive." CR CR>)>)>> 
+
+<OBJECT SCREENING-DOOR
+	(IN LOCAL-GLOBALS)
+	(DESC "screening door")
+	(SYNONYM DOOR)
+	(ADJECTIVE SCREEN)
+	(FLAGS DOORBIT NDESCBIT ACTORBIT)
+	(ACTION SCREENING-DOOR-F)>
+
+<ROUTINE SCREENING-DOOR-F ()
+	 <COND (<EQUAL? ,SCREENING-DOOR ,WINNER>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <PRSO? ,ME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,SCREENING-DOOR ,PRSI>
+		       <SETG WINNER ,SCREENING-DOOR>
+		       <RTRUE>)
+		      (<VERB? HELLO>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?HELLO ,SCREENING-DOOR>
+		       <SETG WINNER ,SCREENING-DOOR>
+		       <RTRUE>)
+		      (<AND <VERB? WHAT>
+			    <PRSO? ,OBJECT-OF-GAME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,SCREENING-DOOR ,OBJECT-OF-GAME>
+		       <SETG WINNER ,SCREENING-DOOR>
+		       <RTRUE>)
+		      (T
+		       <TELL
+"\"Unless you're here to show me some clear sign of your intelligence, please
+leave me alone. I'm a very busy door.\"" CR>
+		       <FUCKING-CLEAR>)>)
+	       (<AND <FSET? ,SCREENING-DOOR ,OPENBIT>
+		     <VERB? SHOW GIVE KNOCK OPEN>>
+		<TELL "You already induced the door to open." CR>)
+	       (<AND <FSET? ,SCREENING-DOOR ,OPENBIT>
+		     <VERB? CLOSE>>
+		<TELL
+"The door snaps, \"Hey! I'm resting. I've had a very busy day.\"" CR>)
+	       (<VERB? KICK>
+		<FSET ,SCREENING-DOOR ,MUNGEDBIT>
+		<TELL
+"\"I suppose you think that since you have legs and I have not, you can get
+away with that sort of thing. Well,\" the door continues stiffly, \"maybe you
+can and maybe you can't.\"" CR>)
+	       (<VERB? SHOW GIVE>
+		<COND (<AND <PRSO? ,TEA ,NO-TEA>
+			    ,TEA-SHOWN
+			    <HELD? ,TEA>
+			    ,HOLDING-NO-TEA
+			    <NOT <PRSO? ,TEA-SHOWN>>>
+		       <PERFORM ,V?KNOCK ,SCREENING-DOOR>
+		       <RTRUE>)
+		      (T
+		       <COND (<PRSO? ,TEA ,NO-TEA>
+			      <SETG TEA-SHOWN ,PRSO>)>
+		       <COND (<PROB 50>
+			      <TELL
+"The door says \"Big deal. Anyone can have">
+			      <ARTICLE ,PRSO>
+			      <TELL ".\"" CR>)
+			     (T
+			      <TELL "The door yawns." CR>)>)>)
+	       (<VERB? OPEN KNOCK>
+		<COND (<AND <HELD? ,TEA>
+			    ,HOLDING-NO-TEA>
+		       <FSET ,SCREENING-DOOR ,OPENBIT>
+		       <TELL
+"The door is almost speechless with admiration. \"Wow. Simultaneous tea
+and no tea. My apologies. You are clearly a heavy-duty philosopher.\" It
+opens respectfully." CR>)
+		      (T
+		       <TELL
+"The door explains, in a haughty tone, that the room is occupied by a
+super-intelligent robot and that lesser beings (by which it means you)
+are not to be admitted. \"Show me some tiny example of your intelligence,\"
+it says, \"and maybe, just maybe, I might reconsider.\"" CR>)>)
+	       (<AND <VERB? ASK-ABOUT>
+		     <PRSI? ,OBJECT-OF-GAME>>
+		<TELL "\"To keep out sub-intelligent beings.\"" CR>)
+	       (<VERB? THROUGH>
+		<COND (<EQUAL? ,HERE ,PANTRY>
+		       <DO-WALK ,P?EAST>)
+		      (T
+		       <DO-WALK ,P?WEST>)>)
+	       (<VERB? EXAMINE>
+		<FCLEAR ,SCREENING-DOOR ,ACTORBIT>
+		<V-LOOK-INSIDE>
+		<FSET ,SCREENING-DOOR ,ACTORBIT>)>>
+
+<OBJECT MARVIN
+	(IN PANTRY)
+	(DESC "Marvin")
+	(LDESC "Marvin, the Paranoid Android, is here.")
+	(SYNONYM MARVIN MARV ROBOT ANDROI)
+	(ADJECTIVE DEPRES PARANO)
+	(FLAGS NARTICLEBIT ACTORBIT)
+	(ACTION MARVIN-F)>
+
+<ROUTINE MARVIN-F ()
+	 <COND (<EQUAL? ,MARVIN ,WINNER>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <PRSO? ,ME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,MARVIN ,PRSI>
+		       <SETG WINNER ,MARVIN>
+		       <RTRUE>)
+		      (<VERB? HELLO>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?HELLO ,MARVIN>
+		       <SETG WINNER ,MARVIN>
+		       <RTRUE>)
+		      (<AND <VERB? WHAT>
+			    <PRSO? ,OBJECT-OF-GAME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,MARVIN ,OBJECT-OF-GAME>
+		       <SETG WINNER ,MARVIN>
+		       <RTRUE>)
+		      (<EQUAL? ,HERE ,PANTRY>
+		       <COND (<AND <VERB? REPAIR OPEN>
+				   <PRSO? ,HATCH ,MECHANISM>>
+			      <COND (<NOT ,LANDED>
+				     <TELL
+"\"" ,HUMANS "stupid. Are you aware,\" he asks, \"that this ship is in
+space, that space is an almost perfect vacuum, and that the hatch is the
+only thing holding in all the air?\"" CR>)
+				    (<EQUAL? ,MARVIN-COUNTER 3>
+				     <TELL
+"\"After the help I got last time? " ,HUMANS "ungrateful. Go away.\""CR>)
+				    (<EQUAL? ,MARVIN-COUNTER 4>
+				     <TELL "\"I did.\"" CR>)
+				    (<G? ,MARVIN-COUNTER 0>
+				     <TELL
+"\"Yes, I said I'd do it! " ,HUMANS "repetitious.\"" CR>)
+				    (T
+				     <SETG MARVIN-COUNTER 1>
+				     <ENABLE <QUEUE I-MARVIN 12>>
+				     <TELL
+"\"" ,HUMANS "demanding. Do this. Pick up that. Unjam the opening mechanism
+of the other. Meet me in the hatchway " D ,ACCESS-SPACE " in twelve turns. I
+suppose,\" he mutters, \"you can count up to twelve. So hard to know with
+morons. And don't forget to bring the proper tool.\"" CR>)>)
+			     (<AND <VERB? WHAT>
+				   <PRSO? ,TWEEZERS>
+				   <G? ,MARVIN-COUNTER 0>>
+			      <TELL
+"Marvin looks scornful. \"How did you get past my door if you're so
+primordially benighted that you don't even know which tool is needed
+for a job like this?\"" CR>)
+			     (T
+			      <TELL "\"Please don't feel you have
+to take any notice of me. I'm just a menial robot.\"" CR>
+			      <FUCKING-CLEAR>)>) 
+		      (T
+		       <TELL
+"\"I think you ought to know I'm feeling very depressed.\"" CR>
+		       <FUCKING-CLEAR>)>)
+	       (<AND <VERB? ASK-ABOUT>
+		     <PRSI? ,OBJECT-OF-GAME>>
+		<TELL
+"\"Being clever doesn't always make you happy, you know. Look at me, brain
+the size of a planet, how many points do you think I've got? Minus thirty
+zillion at the last count.\"" CR>)
+	       (<AND <VERB? FOLLOW>
+		     <EQUAL? ,FOLLOW-FLAG 2>>
+		<COND (<IN? ,MARVIN ,PANTRY>
+		       <DO-WALK ,P?WEST>)
+		      (T
+		       <GOTO <LOC ,MARVIN>>)>)
+	       (<AND <VERB? FOLLOW>
+		     <EQUAL? ,FOLLOW-FLAG 7>>
+		<DO-WALK ,P?WEST>)
+	       (<AND <VERB? GIVE>
+		     <EQUAL? ,MARVIN-COUNTER 2>>
+		<COND (<PRSO? ,TOOL-REQUIRED>
+		       <SETG SCORE <+ ,SCORE 25>>
+		       <SETG MARVIN-COUNTER 4>
+		       <SETG FOLLOW-FLAG 7>
+		       <ENABLE <QUEUE I-FOLLOW 2>>
+		       <DISABLE <INT I-MARVIN>>
+		       <FSET ,HATCH ,OPENBIT>
+		       <MOVE ,MARVIN ,PANTRY>
+		       <MOVE ,TOOL-REQUIRED ,MARVIN>
+		       <TELL
+"Marvin fiddles inside the " D ,MECHANISM " with the " D ,TOOL-REQUIRED " for
+about three-tenths of a second. You hear the hatchway slide open. \"I don't
+expect you to be grateful,\" says Marvin, \"or even interested, but that was
+probably more complicated than every single action you'll ever perform in your
+entire life put together.\" He limps away. \"And me,\" you hear him mutter as
+he goes, \"with this terrible pain in all the diodes down my left side.\"" CR>)
+		      (T
+		       <TELL "\"That's not">
+		       <ARTICLE ,TOOL-REQUIRED>
+		       <TELL ".\"" CR>)>)>>
+
+<ROUTINE I-MARVIN ()
+	 <ENABLE <QUEUE I-MARVIN -1>>
+	 <COND (<EQUAL? ,MARVIN-COUNTER 2>
+		<SETG MARVIN-COUNTER 3>
+		<CRLF>
+		<COND (<EQUAL? ,HERE ,HATCHWAY>
+		       <TELL "Marvin emerges from the " D, ACCESS-SPACE ". ">)>
+		<TELL "\"">
+		<MARVIN-BITCH>
+		<SETG MARVIN-COUNTER 3>)
+	       (<IN? ,MARVIN ,ACCESS-SPACE>
+		<COND (<EQUAL? ,HERE ,ACCESS-SPACE>
+		       <COND (<NOT ,TOOL-REQUIRED>
+			      <REPEAT ()
+			       <SETG TOOL-REQUIRED <PICK-ONE ,TOOL-LIST>>
+			       <COND (<NOT <HELD? ,TOOL-REQUIRED ,PROTAGONIST>>
+				      <RETURN>)>>)>
+		       <SETG MARVIN-COUNTER 2>
+		       <TELL "Marvin, looking bored, says \"Hand me">
+		       <ARTICLE ,TOOL-REQUIRED>
+		       <TELL ".\"" CR>)
+		      (T
+		       <TELL CR "Marvin wanders up to you. \"I went to the "
+D ,ACCESS-SPACE " but you never showed up. ">
+		       <MARVIN-BITCH>
+		       <SETG MARVIN-COUNTER 3>)>)
+	       (<EQUAL? ,MARVIN-COUNTER 1>
+		<MOVE ,MARVIN ,ACCESS-SPACE>
+		<COND (<EQUAL? ,HERE ,ACCESS-SPACE>
+		       <TELL "Marvin shambles in." CR>)
+		      (T
+		       <RFALSE>)>)
+	       (<IN? ,MARVIN ,HERE>
+		<ENABLE <QUEUE I-FOLLOW 2>>
+		<SETG FOLLOW-FLAG 2>
+		<CRLF>
+		<COND (<OR <EQUAL? ,HERE ,HATCHWAY ,GALLEY ,ENTRY-BAY>
+		           <EQUAL? ,HERE ,FORE-CORRIDOR ,ENGINE-ROOM ,BRIDGE>>
+		       <TELL "Marvin wanders off." CR>
+		       <COND (<EQUAL? ,HERE ,FORE-CORRIDOR 
+				      	    ,ENGINE-ROOM ,HATCHWAY>
+		              <MOVE ,MARVIN ,AFT-CORRIDOR>)
+		             (T
+		              <MOVE ,MARVIN ,FORE-CORRIDOR>)>)
+		      (<EQUAL? ,HERE ,AFT-CORRIDOR>
+		       <MOVE ,MARVIN ,PANTRY>
+		       <TELL
+"Marvin enters a room to port, and the door closes behind him." CR>)
+		      (T
+		       <TELL "Bug #17">)>)
+	       (<NOT <IN? ,MARVIN ,PANTRY>>
+		<MOVE ,MARVIN ,PANTRY>
+		<RFALSE>)
+	       (<OR <NOT <IN-HEART? ,PROTAGONIST>>
+		    <EQUAL? ,HERE ,ACCESS-SPACE>
+		    <FSET? ,SCREENING-DOOR ,OPENBIT>
+		    ,AWAITING-REPLY>
+		<RFALSE>)
+	       (<AND <EQUAL? ,HERE ,ENGINE-ROOM>
+		     <L? ,LOOK-COUNTER 3>>
+		<RFALSE>)
+	       (<PROB 8>
+		<MOVE ,MARVIN ,HERE>
+		<TELL CR
+"You feel a wave of depression sweep over you, and you turn to see that
+Marvin the robot has stalked miserably into the room." CR>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE MARVIN-BITCH ()
+	 <DISABLE <INT I-MARVIN>>
+	 <MOVE ,MARVIN ,PANTRY>
+	 <TELL
+"Ah. I was misled into thinking that you wanted me to open the hatch,
+probably by the fact that you asked me to. Obviously you changed your mind
+or I misunderstood you or you are a moronic imbecile. I wonder which">
+	 <COND (<NOT <EQUAL? ,HERE ,PANTRY>>
+		<TELL
+". I'm going back to my pantry to be alone with my grief">)>
+	 <TELL ".\" Marvin stalks miserably away." CR>>
+
+<GLOBAL MARVIN-COUNTER 0>
+;"1 = Marvin's been asked to fix hatch.
+  2 = Marvin's waiting for you to hand him the right tool.
+  3 = Marvin's pissed because you weren't there or gave him the wrong tool.
+  4 = Marvin's already opened the hatch."
+
+<GLOBAL TOOL-REQUIRED <>>
+
+<GLOBAL FLUFF-COUNTER 0>
+
+<GLOBAL PLANT-BLOOMED <>>
+
+<OBJECT FLOWERPOT
+	(IN INSIDE-WHALE)
+	(DESC "flowerpot")
+	(SYNONYM FLOWER POT SOIL DIRT)
+	(ADJECTIVE FLOWER FERTIL)
+	(CAPACITY 1)
+	(SIZE 15)
+	(FLAGS TAKEBIT CONTBIT OPENBIT)
+	(ACTION FLOWERPOT-F)>
+
+<ROUTINE FLOWERPOT-F ()
+	 <COND (<AND <VERB? WATER>
+		     <PRSO? ,FLOWERPOT>
+		     <IN? ,PLANT ,FLOWERPOT>>
+		<PERFORM ,V?WATER ,PLANT ,PRSI>
+		<RTRUE>)
+	       (<VERB? EXAMINE READ LOOK-INSIDE>
+		<TELL "The pot is filled with fertile soil">
+		<COND (<IN? ,PLANT ,FLOWERPOT>
+		       <TELL ", out of which has sprouted a ">
+		       <COND (,PLANT-BLOOMED
+		       	      <TELL "large, leafy plant">)
+			     (T
+			      <TELL "tiny plant stalk">)>)
+		      (T
+		       <TELL
+". It is inscribed \"Inertial Guidance System -- Magrathean Missile Company.\"
+It must have been created by the same burst of improbability that created
+the whale itself">)>
+		<TELL "." CR>)
+	       (<AND <VERB? PUT>
+		     <PRSO? ,POCKET-FLUFF ,JACKET-FLUFF
+			    ,SATCHEL-FLUFF ,CUSHION-FLUFF>>
+		<MOVE ,PRSO ,LOCAL-GLOBALS>
+		<SETG FLUFF-COUNTER <+ ,FLUFF-COUNTER 1>>
+		<COND (<EQUAL? ,FLUFF-COUNTER 4>
+		       <ENABLE <QUEUE I-PLANT 10>>)>
+		<TELL
+"You dig a " D ,FISH-HOLE ", gingerly place the fluff at the bottom, and
+cover it over." CR>)
+	       (<AND <VERB? OPEN CLOSE>
+		     <PRSO? ,FLOWERPOT>>
+		<TELL-ME-HOW>)>>
+
+<ROUTINE I-PLANT ()
+	 <MOVE ,PLANT ,FLOWERPOT>
+	 <COND (<VISIBLE? ,FLOWERPOT>
+		<TELL CR
+"You notice a tiny movement from the " D ,FLOWERPOT ". You look closely, and
+see a tiny sprout poking out of the soil." CR>)
+	       (T
+		<RFALSE>)>>
+
+<OBJECT PLANT
+	(IN LOCAL-GLOBALS) ;"just for the purpose of MOBY-FIND"
+	(DESC "plant")
+	(SYNONYM PLANT SPROUT STEM STALK)
+	(ADJECTIVE SMALL LARGE LEAFY)
+	(FLAGS NDESCBIT INTEGRALBIT)
+	(ACTION PLANT-F)>
+
+<ROUTINE PLANT-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (,PLANT-BLOOMED
+		       <TELL "The plant is now large and leafy.">
+		       <COND (<AND <FSET? ,FRUIT ,NDESCBIT>
+				   <VISIBLE? ,FRUIT>>
+			      <TELL
+" Hanging from it is a large, succulent fruit.">)>
+		       <CRLF>)
+		      (T
+		       <TELL "The plant is just a tiny stem." CR>)>)
+	       (<AND <VERB? TAKE DROP>
+		     <PRSO? ,PLANT>>
+		<COND (,PRSI
+		       <PART-OF>)
+		      (T
+		       <PERFORM ,PRSA ,FLOWERPOT ,PRSI>
+		       <RTRUE>)>)
+	       (<AND <VERB? WATER>
+		     <NOT ,PLANT-BLOOMED>
+		     <PRSI? ,MINERAL-WATER ,SUBSTITUTE ,TEA>>
+		<MOVE ,PRSI ,LOCAL-GLOBALS>
+		<MOVE ,PLANT ,LOCAL-GLOBALS>
+		<TELL "After several seconds, the plant shrivels up.">
+		<ANTI-LITTER "cup">
+		<CRLF>)>>
+
+<OBJECT FRUIT
+	(IN LOCAL-GLOBALS) ;"just for the purpose of MOBY-FIND"
+	(DESC "fruit")
+	(SYNONYM FRUIT)
+	(ADJECTIVE LARGE SUCCUL)
+	(FLAGS NDESCBIT TRYTAKEBIT TAKEBIT EATBIT)
+	(ACTION FRUIT-F)>
+
+<ROUTINE FRUIT-F ("AUX" X)
+	 <COND (<AND <VERB? TAKE PICK>
+		     <FSET? ,FRUIT ,TRYTAKEBIT>>
+		<FCLEAR ,FRUIT ,TRYTAKEBIT>
+		<FCLEAR ,FRUIT ,NDESCBIT>
+		<MOVE ,FRUIT ,PROTAGONIST>
+		<TELL "Done." CR>)
+	       (<AND <VERB? DROP THROW>
+		     <FSET? ,FRUIT ,TRYTAKEBIT>>
+		<FCLEAR ,FRUIT ,TRYTAKEBIT>
+		<FCLEAR ,FRUIT ,NDESCBIT>
+		<MOVE ,FRUIT ,HERE>
+		<COND (<VERB? DROP>
+		       <TELL "Dropped." CR>)
+		      (T
+		       <TELL "Thrown." CR>)>)
+	       (<VERB? EAT>
+		<REPEAT ()
+			<SETG TOOL-REQUIRED <PICK-ONE ,TOOL-LIST>>
+			<SET X <+ .X 1>>
+			<COND (<OR <NOT <IN-HEART? ,TOOL-REQUIRED>>
+				   <G? .X 50>>
+			       <RETURN>)>>
+		<MOVE ,FRUIT ,LOCAL-GLOBALS>
+		<TELL
+"The fruit has a zesty taste, and you devour it greedily. Suddenly, your vision
+wavers, and you see yourself, as though from a distance, standing near Marvin,
+who asks you for">
+		<ARTICLE ,TOOL-REQUIRED>
+		<TELL
+". Then, the image vanishes like a movie when the film breaks, and you find
+yourself still in">
+		<ARTICLE ,HERE T>
+		<TELL ".|
+|
+It seems that this plant is a rare horticultural phenomenon long thought to
+be extinct: The Tree of Foreknowledge." CR>)>>
+
+<ROOM GALLEY
+      (IN ROOMS)
+      (SYNONYM CORPOR SCC)
+      (ADJECTIVE SIRIUS CYBERN)
+      (DESC "Galley")
+      (EAST TO FORE-CORRIDOR)
+      (OUT TO FORE-CORRIDOR)
+      (FLAGS RLANDBIT ONBIT)
+      (PSEUDO "GALLEY" GLOBAL-ROOM-F)
+      (GLOBAL HEART-OF-GOLD)
+      (ACTION GALLEY-F)>
+
+<ROUTINE GALLEY-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are in the Galley area of the ship, containing a machine which is the
+state of the art in Nutritional Technology, a " ,SCC " " D ,NUTRIMAT ". There
+is an exit to starboard." CR>)
+	       (<AND <EQUAL? .RARG ,M-END>
+		     <NOT <RUNNING? ,I-TEA>>
+		     <PROB 3>>
+		<SETG FOLLOW-FLAG 6>
+		<ENABLE <QUEUE I-FOLLOW 2>>
+		<TELL CR
+D ,ZAPHOD " walks in and presses the " D ,PAD ". The " D ,NUTRIMAT
+" produces a huge, ice-cold Pan-Galactic Gargle Blaster. Zaphod heads off
+toward the sauna, sipping loudly." CR>)>>
+
+<OBJECT NUTRIMAT
+	(IN GALLEY)
+	(DESC "Nutrimat")
+	(SYNONYM NUTRIM MACHIN PANEL)
+	(ADJECTIVE SERVIC)
+	(FLAGS NDESCBIT ACTORBIT CONTBIT LIGHTBIT SEARCHBIT)
+	(ACTION NUTRIMAT-F)>
+
+<ROUTINE NUTRIMAT-F ()
+	 <COND (<EQUAL? ,NUTRIMAT ,WINNER>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <PRSO? ,ME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,NUTRIMAT ,PRSI>
+		       <SETG WINNER ,NUTRIMAT>
+		       <RTRUE>)
+		      (<VERB? HELLO>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?HELLO ,NUTRIMAT>
+		       <SETG WINNER ,NUTRIMAT>
+		       <RTRUE>)
+		      (<AND <VERB? WHAT>
+			    <PRSO? ,OBJECT-OF-GAME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,NUTRIMAT ,OBJECT-OF-GAME>
+		       <SETG WINNER ,NUTRIMAT>
+		       <RTRUE>)
+		      (<OR <AND <VERB? SGIVE>
+				<PRSO? ,ME>>
+			   <AND <VERB? GIVE>
+				<PRSI? ,ME>>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-FOR ,NUTRIMAT ,PRSI>
+		       <SETG WINNER ,NUTRIMAT>
+		       <RTRUE>)
+		      (<AND <VERB? MAKE>
+			    <PRSO? ,TEA ,NO-TEA>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?RUB ,PAD>
+		       <SETG WINNER ,NUTRIMAT>
+		       <RTRUE>)
+		      (T
+		       <TELL "The " D ,NUTRIMAT " ignores you." CR>
+		       <FUCKING-CLEAR>)>)
+	       (<VERB? EXAMINE>
+		<TELL
+"The " D ,NUTRIMAT " has a " D ,PAD ", a dispensing slot, and a
+service panel which is ">
+		<COND (<FSET? ,NUTRIMAT ,OPENBIT>
+		       <TELL "open">)
+		      (T
+		       <TELL "closed">)>
+		<TELL ".">
+		<FINE-PRODUCT>
+		<COND (<RUNNING? ,I-TEA>
+		       <TELL " ">
+		       <PERFORM ,V?LISTEN ,NUTRIMAT>
+		       <RTRUE>)
+		      (T
+		       <CRLF>)>)
+	       (<AND <VERB? LISTEN>
+		     <RUNNING? ,I-TEA>>
+		<TELL
+"The " D ,NUTRIMAT " is making a faint whirring noise." CR>)
+	       (<AND <VERB? ASK-FOR>
+		     <PRSI? ,TEA ,SUBSTITUTE>>
+		<PERFORM ,V?RUB ,PAD>
+		<RTRUE>)
+	       (<VERB? LAMP-ON>
+		<PERFORM ,V?RUB ,PAD>
+		<RTRUE>)
+	       (<AND <VERB? LAMP-OFF>
+		     <RUNNING? ,I-TEA>>
+		<PERFORM ,V?RUB ,PAD>
+		<RTRUE>)
+	       (<AND <VERB? KILL KICK SHAKE>
+		     ,SUBSTITUTE-DRUNK>
+		<TELL "The " D ,NUTRIMAT " says ">
+		<COND (<PROB 50>
+		       <TELL "\"Share and Enjoy.\"" CR>)
+		      (T
+		       <TELL
+"\"If you have enjoyed the experience of this drink, why not share it with
+your friends?\"" CR>)>)
+	       (<AND <VERB? PUT PLUG>
+		     <PRSI? ,NUTRIMAT>>
+		<COND (<NOT <FSET? ,NUTRIMAT ,OPENBIT>>
+		       <TELL "The panel is closed." CR>)
+		      (<FIRST? ,NUTRIMAT>
+		       <TELL "There's no room." CR>)
+		      (<PRSO? ,BOARD ,NUT-COM-INTERFACE>
+		       <MOVE ,PRSO ,NUTRIMAT>
+		       <TELL "Done." CR>)
+		      (T
+		       <V-PLUG>)>)
+	       (<VERB? LOOK-INSIDE>
+		<COND (<NOT <FSET? ,NUTRIMAT ,OPENBIT>>
+		       <PERFORM ,V?OPEN ,NUTRIMAT>
+		       <RTRUE>)
+		      (<IN? ,BOARD ,NUTRIMAT>
+		       <TELL "There is a " D ,BOARD " there." CR>)
+		      (<IN? ,NUT-COM-INTERFACE ,NUTRIMAT>
+		       <TELL "There is a " D ,NUT-COM-INTERFACE " there." CR>)
+		      (T
+		       <TELL "There's nothing in the " D ,NUTRIMAT "." CR>)>)
+	       (<AND <VERB? ASK-ABOUT>
+		     <PRSI? ,OBJECT-OF-GAME>>
+		<TELL
+"\"To provide a nutritious and flavour-enhanced diet.\"" CR>)>>
+
+<OBJECT PAD
+	(IN GALLEY)
+	(DESC "touch-sensitive pad")
+	(SYNONYM PAD)
+	(ADJECTIVE TOUCH SENSIT)
+	(FLAGS NDESCBIT)
+	(ACTION PAD-F)>
+
+<ROUTINE PAD-F ()
+	 <COND (<VERB? RUB PUSH>
+		<COND (<IN? ,NUT-COM-INTERFACE ,NUTRIMAT>
+		       <COND (<RUNNING? ,I-TEA>
+			      <TELL
+"\"Please wait..." D ,NUTRIMAT " engaged.\"" CR>)
+			     (<IN? ,TEA ,PAD>
+			      <ENABLE <QUEUE I-TEA -1>>
+			      <TELL
+"The " D ,NUTRIMAT " is puzzled that you want something made by pouring
+boiling water on dead leaves and squirting stuff from a cow in it, and
+says that it will need some help from " D ,EDDIE "." CR>)
+			     (T
+			      <TELL
+"\"I won't go through that again. If " D ,SUBSTITUTE " isn't good
+enough, too bad.\"" CR>)>)
+		      (<IN? ,SUBSTITUTE ,PAD>
+		       <MOVE ,SUBSTITUTE ,SLOT>
+		       <SETG P-IT-OBJECT ,SUBSTITUTE>
+		       <TELL
+"The " D ,NUTRIMAT " makes an instant but highly detailed examination of
+your taste buds, a spectroscopic analysis of your metabolism and
+sends tiny experimental signals down your neural pathways to see
+what you like.|
+A cupful of " D ,SUBSTITUTE " appears in the dispensing slot." CR>)
+		      (T
+		       <TELL
+"\"You still haven't drunk the nutritious and flavour-enhanced cupful of "
+D ,SUBSTITUTE " I already gave you,\" scolds the " D ,NUTRIMAT "." CR>)>)>>
+
+<OBJECT SLOT
+	(IN GALLEY)
+	(DESC "slot")
+	(SYNONYM SLOT)
+	(ADJECTIVE DISPEN)
+	(FLAGS NDESCBIT CONTBIT OPENBIT SEARCHBIT)
+	(CAPACITY 20)
+	(ACTION SLOT-F)>
+
+<ROUTINE SLOT-F ()
+	 <COND (<AND <VERB? OPEN CLOSE>
+		     <PRSO? ,SLOT>>
+		<TELL-ME-HOW>)>>
+
+<OBJECT BOARD
+	(IN NUTRIMAT)
+	(DESC "circuit board")
+	(SYNONYM BOARD MESSAG LETTER MICROC)
+	(ADJECTIVE CIRCUI MICROS PRINTE)
+	(FLAGS TAKEBIT CONTBIT TRANSBIT)
+	(ACTION BOARD-F)>
+
+<ROUTINE BOARD-F ()
+	 <COND (<AND <VERB? OPEN CLOSE>
+		     <PRSO? ,BOARD>>
+		<TELL-ME-HOW>)
+	       (<VERB? EXAMINE>
+		<TELL
+"The " D ,PRSO " is square, about ten inches on each side. It has a number
+of microchips, some printed circuitry, and a message printed in microscopic
+letters. There are also eight " D ,DIPSWITCH "es, marked:|
+  1  Cholesterol Register|
+  2  MSG Specifier|
+  3  Thiamin Stack|
+  4  Piquant-O-Mat|
+  5  Flavour Dump|
+  6  Vitamin Interrupts|
+  7  Nose Sequencer|
+  8  Bouquet Arbitration Bus" CR>)
+	       (<VERB? MUNG>
+		<MOVE ,BOARD ,LOCAL-GLOBALS>
+		<TELL
+"It's all the device deserves. It shatters with a satisfying crunch." CR>)
+	       (<AND <VERB? READ EXAMINE-THROUGH>
+		     <PRSI? ,MAGNIFYING-GLASS>>
+		<TELL
+"The message reads \"This is just a satirical device. It has no
+practical function.\"" CR>)
+	       (<VERB? READ>
+		<TELL "The message is too small for you to read." CR>)>>
+
+<OBJECT DIPSWITCH
+	(IN BOARD)
+	(DESC "dipswitch")
+	(SYNONYM SWITCH DIPSWI)
+	(ADJECTIVE FIRST SECOND THIRD FOURTH FIFTH SIXTH SEVENT EIGHTH)
+	(FLAGS NDESCBIT SWITCHBIT)
+	(ACTION DIPSWITCH-F)>
+
+<ROUTINE DIPSWITCH-F ()
+	 <COND (<VERB? TURN THROW LAMP-ON LAMP-OFF PUSH MOVE>
+		<TELL "Switched.">
+		<COND (<IN? ,BOARD ,NUTRIMAT>
+		       <TELL
+" Some lights on the " D ,NUTRIMAT " flash briefly. A promising hum
+quickly dies away." CR>)
+		      (T
+		       <CRLF>
+		       <RTRUE>)>)>>
+
+;<OBJECT DIPSWITCH-8
+	(IN BOARD)
+	(DESC "eighth dipswitch")
+	(SYNONYM SWITCH DIPSWI)
+	(ADJECTIVE EIGHTH DIP)
+	(FLAGS NDESCBIT SWITCHBIT)
+	(ACTION DIPSWITCH-F)>
+
+;<OBJECT DIPSWITCH-7
+	(IN BOARD)
+	(DESC "seventh dipswitch")
+	(SYNONYM SWITCH DIPSWI)
+	(ADJECTIVE SEVENTH DIP)
+	(FLAGS NDESCBIT SWITCHBIT)
+	(ACTION DIPSWITCH-F)>
+
+;<OBJECT DIPSWITCH-6
+	(IN BOARD)
+	(DESC "sixth dipswitch")
+	(SYNONYM SWITCH DIPSWI)
+	(ADJECTIVE SIXTH DIP)
+	(FLAGS NDESCBIT SWITCHBIT)
+	(ACTION DIPSWITCH-F)>
+
+;<OBJECT DIPSWITCH-5
+	(IN BOARD)
+	(DESC "fifth dipswitch")
+	(SYNONYM SWITCH DIPSWI)
+	(ADJECTIVE FIFTH DIP)
+	(FLAGS NDESCBIT SWITCHBIT)
+	(ACTION DIPSWITCH-F)>
+
+;<OBJECT DIPSWITCH-4
+	(IN BOARD)
+	(DESC "fourth dipswitch")
+	(SYNONYM SWITCH DIPSWI)
+	(ADJECTIVE FOURTH DIP)
+	(FLAGS NDESCBIT SWITCHBIT)
+	(ACTION DIPSWITCH-F)>
+
+;<OBJECT DIPSWITCH-3
+	(IN BOARD)
+	(DESC "third dipswitch")
+	(SYNONYM SWITCH DIPSWI)
+	(ADJECTIVE THIRD DIP)
+	(FLAGS NDESCBIT SWITCHBIT)
+	(ACTION DIPSWITCH-F)>
+
+;<OBJECT DIPSWITCH-2
+	(IN BOARD)
+	(DESC "second dipswitch")
+	(SYNONYM SWITCH DIPSWI)
+	(ADJECTIVE SECOND DIP)
+	(FLAGS NDESCBIT SWITCHBIT)
+	(ACTION DIPSWITCH-F)>
+
+<OBJECT SUBSTITUTE
+	(IN PAD)
+	(DESC "Advanced Tea Substitute")
+	(DESCFCN SUBSTITUTE-DESCFCN)
+	(SYNONYM CUP CUPFUL SUBSTI ATS)
+	(ADJECTIVE TEA ADVANC NICE HOT)
+	(FLAGS NARTICLEBIT VOWELBIT TAKEBIT DRINKBIT)
+	(ACTION SUBSTITUTE-F)>
+
+<ROUTINE SUBSTITUTE-DESCFCN ("OPTIONAL" X)
+	 <DESCRIBE-DRINK ,SUBSTITUTE>>
+
+<ROUTINE SUBSTITUTE-F ()
+	 <COND (<VERB? DRINK ENJOY DRINK-FROM>
+		<COND (<NOT <HELD? ,SUBSTITUTE>>
+		       <TELL ,NOT-HOLDING " the cup!" CR>
+		       <RTRUE>)
+		      (<G? ,SCORE 300>
+		       <TELL
+"You'd rather continue savouring that delicious tea." CR>
+		       <RTRUE>)
+		      (,SUBSTITUTE-DRUNK
+		       <SETG SCORE <- ,SCORE 30>>
+		       <SETG DREAMING <>>
+		       <TELL "That last gulp of the vile " D ,SUBSTITUTE>
+		       <JIGS-UP
+" was a bit too much for you. You expire from sheer misery and unhappiness.">
+		       <RTRUE>)>
+		<COND (<EQUAL? ,SUBSTITUTE ,BROWNIAN-SOURCE>
+		       <SETG BROWNIAN-SOURCE <>>)>
+		<SETG SUBSTITUTE-DRUNK T>
+		<SETG SCORE <- ,SCORE 30>>
+		<MOVE ,SUBSTITUTE ,PAD>
+		<TELL
+"It tastes almost, but not quite, entirely unlike tea. It's absolutely
+disgusting.">
+		<ANTI-LITTER "cup">
+		<COND (<EQUAL? ,HERE ,GALLEY>
+		       <TELL " ">
+		       <PERFORM ,V?KILL ,NUTRIMAT>
+		       <RTRUE>)>
+		<CRLF>)
+	       (<VERB? EXAMINE LOOK-INSIDE>
+		<TELL
+"About the only characteristic it shares with tea is that of" ,BROWNIAN ".">
+		<COND (<PRSO? ,BROWNIAN-SOURCE>
+		       <TELL " ">
+		       <PERFORM ,V?EXAMINE ,DANGLY-BIT>
+		       <RTRUE>)
+		      (T
+		       <CRLF>)>)
+	       (<VERB? POUR THROW>
+		<LIQUID-SPILL>)>>
+
+<OBJECT INTERFACE-BOX
+	(IN GALLEY)
+	(DESC "shipping carton")
+	(LDESC
+"A carton labelled \"Nutrimat/Computer Interface\" is sitting here.")
+	(SYNONYM CARTON BOX)
+	(ADJECTIVE SHIPPI)
+	(FLAGS CONTBIT TAKEBIT SEARCHBIT READBIT)
+	(SIZE 15)
+	(CAPACITY 14)
+	(ACTION INTERFACE-BOX-F)>
+
+<ROUTINE INTERFACE-BOX-F ()
+	 <COND (<VERB? READ EXAMINE>
+		<TELL
+"The carton is labelled \"" D ,NUT-COM-INTERFACE ".\"" CR>
+		<COND (<VERB? EXAMINE>
+		       <RFALSE>)
+		      (T
+		       <RTRUE>)>)>> 
+
+<OBJECT BEAST-GUN
+	(IN INTERFACE-BOX)
+	(DESC "strange gun")
+	(SYNONYM GUN WEAPON)
+	(ADJECTIVE STRANGE RAY ANTI- BEAST)
+	(FLAGS TAKEBIT)
+	(SIZE 4)
+	(ACTION BEAST-GUN-F)>
+
+<ROUTINE BEAST-GUN-F ()
+	 <COND (<VERB? EXAMINE READ>
+		<TELL
+"The gun has a large label which reads \"Anti-Bugblatter Beast Ray Gun.\"">
+		<FINE-PRODUCT>
+		<CRLF>)>>
+
+<GLOBAL GUN-COUNTER 0>
+
+<GLOBAL TEA-COUNTER 0>
+
+<GLOBAL LANDED <>>
+
+<ROUTINE I-TEA ()
+	 <SETG TEA-COUNTER <+ ,TEA-COUNTER 1>>
+	 <COND (<AND <NOT <EQUAL? ,HERE ,GALLEY>>
+		     <L? ,TEA-COUNTER 7>>
+		<RFALSE>)>
+	 <CRLF>
+	 <COND (<EQUAL? ,TEA-COUNTER 1>
+		<TELL "The nutrimat begins to whirr." CR>)
+	       (<EQUAL? ,TEA-COUNTER 2>
+		<TELL
+"A red sign lights up saying:|
+   MEMORY OVERLOAD" CR>)
+	       (<EQUAL? ,TEA-COUNTER 3>
+		<TELL
+"Another red sign lights up saying:|
+   RESERVE MEMORY OVERLOAD" CR>)
+	       (<EQUAL? ,TEA-COUNTER 4>
+		<TELL
+"A third sign lights up:|
+   PROCESSOR OVERLOAD,|
+   SWITCH TO TERMINAL MODE" CR>)
+	       (<EQUAL? ,TEA-COUNTER 5>
+		<TELL
+"A blue sign lights up:|
+   NUTRIMAT GOING ON LINE" CR>)
+	       (<EQUAL? ,TEA-COUNTER 6>
+		<TELL
+"More and more signs light up:|
+   SHIPBOARD COMPUTER ACCESSED|
+   MAIN MEMORY OVERLOAD|
+   RESERVE MEMORY ACCESSED|
+   PARALLEL PROCESSORS ON LINE|
+|
+   ****************************|
+   ** NUMBERS BEING CRUNCHED **|
+   ****************************" CR>)
+	       (<EQUAL? ,TEA-COUNTER 7>
+		<FSET ,THUMB ,MUNGEDBIT>
+		<TELL ,ANNOUNCEMENT D ,EDDIE
+". Emergency situation! Nuclear missiles have just been launched at us from the
+approaching planet, which my data banks indicate is" ,LOST-PLANET ". I cannot
+perform evasive maneuvers because" ,ENGAGED D ,NUTRIMAT ". The missiles will
+turn this ship into a huge atomic fireball in approximately eight turns. By
+the way, somebody didn't finish their spinach at dinner.\"" CR>)
+	       (<L? ,TEA-COUNTER 15>
+		<TELL
+"You hear distant sounds of panic: shouts of anger, cries of alarm,
+pounding feet." CR>)
+	       (T
+		<DISABLE <INT I-TEA>>
+		<TELL "It seems that the missiles struck " D ,HEART-OF-GOLD>
+		<JIGS-UP
+" about three nanoseconds ago. Sure enough, here comes that huge atomic fireb">
+		<RTRUE>)>>
+
+<ROUTINE I-LANDING ()
+	 <COND (<NOT <IN-HEART? ,PROTAGONIST>>
+		<ENABLE <QUEUE I-LANDING 12>>
+		<RFALSE>)
+	       (T
+		<MOVE ,MARVIN ,PANTRY>
+		<DISABLE <INT I-MARVIN>>
+		<SETG LANDED T>
+		<TELL CR ,ANNOUNCEMENT D ,EDDIE
+". We have just landed on" ,LOST-PLANET ". I don't want anyone going outside
+until I've checked the atmosphere, climatic conditions, existence of dangerous
+wildlife, airborne diseases, volcanic activity, presence of real estate agents,
+and more than eight thousand other possible dangers. This routine check will
+take 14.9 years. And don't even think about leaving until I finish, because
+I'm jamming the hatch.\"" CR>)>>
+
+<ROOM BRIDGE
+      (IN ROOMS)
+      (SYNONYM MOVEME MOTION RANDOM)
+      (ADJECTIVE BROWNI)
+      (DESC "Bridge")
+      (DOWN TO FORE-CORRIDOR)
+      (WEST PER SAUNA-ENTER-F)
+      (FLAGS ONBIT RLANDBIT)
+      (GLOBAL STAIRS CONTROLS HEART-OF-GOLD)
+      (PSEUDO "SAUNA" SAUNA-PSEUDO "PEOPLE" PEOPLE-PSEUDO)
+      (ACTION BRIDGE-F)>
+
+<ROUTINE SAUNA-ENTER-F ()
+	 <UNPLUG-HELD-STUFF>
+	 <SETG MOVES <+ ,MOVES <+ 10 <RANDOM 12>>>>
+	 <TELL "You enter the sauna. After several ">
+	 <COND (<RUNNING? ,I-FORD>
+		<TELL "minutes">)
+	       (T
+		<TELL "hours">)>
+	 <TELL ", you come out a changed man.">
+	 <COND (<AND <HELD? ,FLOWERPOT>
+		     <IN? ,PLANT ,FLOWERPOT>
+		     <NOT ,PLANT-BLOOMED>>
+		<SETG PLANT-BLOOMED T>
+		<SETG SCORE <+ ,SCORE 25>>
+		<MOVE ,FRUIT ,FLOWERPOT>
+		<TELL " You have with you a changed plant.">)>
+	 <CRLF>
+	 <COND (<IN? ,MARVIN ,BRIDGE>
+		<MOVE ,MARVIN ,PANTRY>)>
+	 <RFALSE>>
+
+<ROUTINE BRIDGE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is the bridge of " D ,HEART-OF-GOLD ". A gangway leads down, and steam
+comes from an entrance to port. Next to the control console is " D ,EDDIE ".">
+		<COND (,DRIVE-TO-CONTROLS
+		       <TELL " ">
+		       <PERFORM ,V?EXAMINE ,LARGE-RECEPTACLE>)
+		      (T
+		       <CRLF>)>
+		<COND (<NOT <FSET? ,BRIDGE ,NDESCBIT>>
+		       <FSET ,BRIDGE ,NDESCBIT>
+		       <TELL CR
+"At the controls, apparently expecting you and Ford, are a man with more than
+the usual number of heads (the name \"Zaphod\" is stitched on his shirt) and a
+dark-haired woman, holding a handbag. Both seem somehow familiar." CR>)>)>>
+
+<ROUTINE SAUNA-PSEUDO ()
+	 <COND (<AND <VERB? THROUGH WALK-TO BOARD>
+		     <EQUAL? ,HERE ,BRIDGE>>
+		<DO-WALK ,P?WEST>)>>
+
+<ROUTINE PEOPLE-PSEUDO ()
+	 <COND (<NOT <IN? ,ZAPHOD ,HERE>>
+		<TELL "What people?" CR>)
+	       (<VERB? EXAMINE>
+		<PERFORM ,V?EXAMINE ,ZAPHOD>
+		<PERFORM ,V?EXAMINE ,TRILLIAN>
+		<RTRUE>)>>
+
+<OBJECT EDDIE
+	(IN BRIDGE)
+	(DESC "Eddie (the shipboard computer)")
+	(SYNONYM EDDIE ED COMPUT)
+	(ADJECTIVE SHIP\'S SHIPBO)
+	(FLAGS VOWELBIT NARTICLEBIT NDESCBIT ACTORBIT LIGHTBIT ONBIT)
+	(ACTION EDDIE-F)>
+
+<ROUTINE EDDIE-F ()
+	 <COND (<EQUAL? ,EDDIE ,WINNER>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <PRSO? ,ME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,EDDIE ,PRSI>
+		       <SETG WINNER ,EDDIE>
+		       <RTRUE>)
+		      (<VERB? HELLO>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?HELLO ,EDDIE>
+		       <SETG WINNER ,EDDIE>
+		       <RTRUE>)
+		      (<AND <VERB? WHAT>
+			    <PRSO? ,OBJECT-OF-GAME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,EDDIE ,OBJECT-OF-GAME>
+		       <SETG WINNER ,EDDIE>
+		       <RTRUE>)
+		      (<AND <VERB? LAMP-ON>
+			    <PRSO? ,MAIN-DRIVE ,SPARE-DRIVE>>
+		       <COND (<RUNNING? ,I-TEA>
+			      <TELL
+"\"Sorry," ,ENGAGED D ,NUTRIMAT ". I can't do everything, you know.\"" CR>)
+			     (T
+			      <TELL "\"Sorry, current course for"
+,LOST-PLANET " can be countermanded only by " D ,ZAPHOD ".\"" CR>)>)
+		      (<AND <VERB? REPAIR OPEN>
+			    <PRSO? ,HATCH>
+			    ,LANDED>
+		       <TELL
+"\"Not until I completely check out the safety of this planet. Please
+wait approximately fourteen years. In the meantime, have you brushed
+your teeth lately?\"" CR>)
+		      (<AND <VERB? YES>
+			    <EQUAL? ,AWAITING-REPLY 18>>
+		       <V-YES>)
+		      (<AND <VERB? NO>
+			    <EQUAL? ,AWAITING-REPLY 18>>
+		       <V-NO>) 
+		      (T
+		       <SETG AWAITING-REPLY 18>
+		       <ENABLE <QUEUE I-REPLY 2>>
+		       <TELL
+"Eddie sighs deeply. \"I can't talk right now. Do you know how difficult it is
+to pilot a ship as complicated as this one?\"" CR>
+		       <FUCKING-CLEAR>)>)
+	       (<VERB? LAMP-OFF>
+		<TELL "You don't know how (fortunately)." CR>)
+	       (<AND <VERB? ASK-ABOUT>
+		     <PRSI? ,OBJECT-OF-GAME>>
+		<SETG AWAITING-REPLY 19>
+		<ENABLE <QUEUE I-REPLY 2>>
+		<TELL
+"\"To pilot " D ,HEART-OF-GOLD ", process data requests from the " D ,NUTRIMAT
+" and keep the crew healthy. Read your manual! How do you expect to get
+anywhere in life? But don't read unless there's enough light.\"" CR>)>>
+
+<OBJECT LARGE-RECEPTACLE
+	(IN BRIDGE)
+	(DESC "large receptacle")
+	(SYNONYM RECEPT)
+	(ADJECTIVE LARGE MANUAL OVERRI)
+	(FLAGS NDESCBIT)
+	(ACTION LARGE-RECEPTACLE-F)>
+
+<ROUTINE LARGE-RECEPTACLE-F ()
+	 <COND (<AND ,DRIVE-TO-CONTROLS
+		     <VERB? EXAMINE>>
+		<TELL
+"A " D ,SPARE-DRIVE " is plugged into the large receptacle." CR>)>>
+
+<OBJECT PHIL
+	(IN LOCAL-GLOBALS) ;"just for the purpose of MOBY-FIND"
+	(DESC "Phil")
+	(LDESC "Phil is here.")
+	(SYNONYM PHIL)
+	(FLAGS NARTICLEBIT ACTORBIT)
+	(ACTION ZAPHOD-F)>
+
+<OBJECT ZAPHOD
+	(IN BRIDGE)
+	(DESC "Zaphod Beeblebrox")
+	(SYNONYM BEEBLE ZAPHOD PRESID)
+	(ADJECTIVE ZAPHOD PRESID)
+	(FLAGS NARTICLEBIT ACTORBIT NDESCBIT)
+	(ACTION ZAPHOD-F)>
+
+<ROUTINE ZAPHOD-F ()
+	 <COND (<EQUAL? ,IDENTITY-FLAG ,ZAPHOD>
+		<COND (<EQUAL? ,ZAPHOD ,PRSO>
+		       <PERFORM ,PRSA ,ME ,PRSI>
+		       <RTRUE>)
+		      (T
+		       <PERFORM ,PRSA ,PRSO ,ME>
+		       <RTRUE>)>)
+	       (<EQUAL? ,WINNER ,ZAPHOD>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <PRSO? ,ME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,ZAPHOD ,PRSI>
+		       <SETG WINNER ,ZAPHOD>
+		       <RTRUE>)
+		      (<VERB? HELLO>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?HELLO ,ZAPHOD>
+		       <SETG WINNER ,ZAPHOD>
+		       <RTRUE>)
+		      (<AND <VERB? WHAT>
+			    <PRSO? ,OBJECT-OF-GAME>>
+		       <TELL ,ASK-ABOUT-OBJECT CR>)
+		      (T
+		       <TELL "\"Shut up, Earthman.\"" CR>
+		       <FUCKING-CLEAR>)>)
+	       (<EQUAL? ,IDENTITY-FLAG ,TRILLIAN>
+		<COND (<AND <PRSI? ,PHIL>
+			    <VERB? SHOW GIVE>>
+		       <PERFORM ,V?HELLO ,PHIL>
+		       <RTRUE>)
+		      (<AND <VERB? SGIVE HELLO TELL ASK-ABOUT ASK-FOR>
+			    <PRSO? ,PHIL>>
+		       <COND (<NOT <IN? ,PHIL ,HERE>>
+			      ;"fixes GIVE ALL TO PHIL case"
+			      <TELL "Phil's not here anymore!" CR>
+			      <RTRUE>)>
+		       <COND (<NOT <FSET? ,JACKET-FLUFF ,TRYTAKEBIT>>
+			      <ENABLE <QUEUE I-ZAPHOD 3>>)>
+		       <TELL
+"Phil must not have noticed you, because he just moved into the ">
+		       <COND (<EQUAL? ,HERE ,LIVING-ROOM>
+			      <MOVE ,PHIL ,DINING-ROOM>
+			      <MOVE ,CAGE ,DINING-ROOM>
+			      <TELL D ,DINING-ROOM>)
+			     (<EQUAL? ,HERE ,DINING-ROOM>
+			      <MOVE ,PHIL ,KITCHEN>
+			      <MOVE ,CAGE ,KITCHEN>
+			      <TELL D ,KITCHEN>)
+			     (T
+			      <MOVE ,PHIL ,LIVING-ROOM>
+			      <MOVE ,CAGE ,LIVING-ROOM>
+			      <TELL D ,LIVING-ROOM>)>
+		       <TELL "." CR>
+		       <FUCKING-CLEAR>)
+		      (<VERB? EXAMINE>
+		       <TELL
+"He is very attractive, if a little weird, and has a slight other-worldly
+look. You suspect he's a party-crasher, an impression reinforced by his
+inappropriate garb; he seems clothed for a fancy dress party or something,
+because he has what appears to be a large birdcage on his shoulder with a
+black drape over it. The bird inside must be asleep, because you can hear
+snoring coming from inside it." CR>)
+		      (<VERB? PICK-UP>
+		       <TELL "You're not that kind of girl." CR>)>)
+	       (<VERB? EXAMINE>
+		<TELL "Zaphod has two heads." CR>)
+	       (<VERB? FOLLOW>
+		<COND (<EQUAL? ,FOLLOW-FLAG 3>
+		       <DO-WALK ,P?WEST>)
+		      (<EQUAL? ,FOLLOW-FLAG 6>
+		       <DO-WALK ,P?EAST>)>)
+	       (<AND <VERB? ASK-ABOUT>
+		     <PRSI? ,OBJECT-OF-GAME>>
+		<TELL ,ASK-ABOUT-OBJECT CR>)>>
+
+<ROUTINE I-ZAPHOD ()
+	 <COND (,ITEM-DROPPED-AT-PARTY
+		<ENABLE <QUEUE I-ZAPHOD 3>>
+		<COND (<RUNNING? ,I-HOSTESS>
+		       <MOVE ,PHIL ,HERE>
+		       <MOVE ,CAGE ,HERE>
+		       <TELL CR
+"Out of the corner of your eye, you see Phil leering at you. He starts
+to approach, but then notices the hostess with you and veers away." CR>)>)
+	       (T
+		<SETG SCORE <+ ,SCORE 25>>
+		<FSET ,LIVING-ROOM ,REVISITBIT>
+		<FSET ,HOSTESS ,NDESCBIT>
+		<CRLF>
+		<JIGS-UP
+"Phil comes up and grips your shoulder. \"Hey babe, this guy boring you? Why
+not come with me instead? I'm from a different planet.\" He takes you out to
+the parking lot, where his flashy inter-orbital ion scooter is parked between
+two Volkswagens. After mounting it, the scooter accelerates at such a great
+speed that you black out almost immediately.">
+		<RTRUE>)>>
+
+<OBJECT TRILLIAN
+	(IN BRIDGE)
+	(DESC "Trillian")
+	(SYNONYM TRILLI MCMILL WOMAN TRICIA)
+	(ADJECTIVE TRICIA DARK- DARK HAIRED)
+	(FLAGS NARTICLEBIT ACTORBIT NDESCBIT CONTBIT OPENBIT)
+	(ACTION TRILLIAN-F)>
+
+<ROUTINE TRILLIAN-F ()
+	 <COND (<EQUAL? ,IDENTITY-FLAG ,TRILLIAN>
+		<COND (<EQUAL? ,TRILLIAN ,PRSO>
+		       <PERFORM ,PRSA ,ME ,PRSI>
+		       <RTRUE>)
+		      (T
+		       <PERFORM ,PRSA ,PRSO ,ME>
+		       <RTRUE>)>)
+	       (<EQUAL? ,TRILLIAN ,WINNER>
+		<COND (<AND <VERB? TELL-ABOUT>
+			    <PRSO? ,ME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,TRILLIAN ,PRSI>
+		       <SETG WINNER ,TRILLIAN>
+		       <RTRUE>)
+		      (<VERB? HELLO>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?HELLO ,TRILLIAN>
+		       <SETG WINNER ,TRILLIAN>
+		       <RTRUE>)
+		      (<AND <VERB? WHAT>
+			    <PRSO? ,OBJECT-OF-GAME>>
+		       <TELL ,ASK-ABOUT-OBJECT CR>)
+		      (<OR <AND <VERB? SHOOT>
+				<IN? ,BLASTER ,TRILLIAN>
+				<PRSO? ,RIFLES>>
+			   <AND <VERB? SSHOOT>
+				<IN? ,BLASTER ,TRILLIAN>
+				<PRSI? ,RIFLES>>>
+		       <MOVE ,BLASTER ,PROTAGONIST>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?SHOOT ,RIFLES ,BLASTER>
+		       <SETG WINNER ,TRILLIAN>
+		       <MOVE ,BLASTER ,TRILLIAN>
+		       <RTRUE>)
+		      (<EQUAL? ,IDENTITY-FLAG ,ZAPHOD>
+		       <TELL "\"Shut up, you jerk!\" hisses " D ,TRILLIAN
+". \"Just get on with the plan.\"" CR>
+		       <FUCKING-CLEAR>)
+		      (T
+		       <TELL
+D ,TRILLIAN " smiles disinterestedly at you and looks away." CR>
+		       <FUCKING-CLEAR>)>)
+	       (<AND <VERB? SHOOT>
+		     <PRSI? ,BLASTER>>
+		<TELL
+"How heartless! Fortunately, justice prevails as the guards">
+		<GUARD-DEATH>
+		<RTRUE>) 
+	       (<AND <VERB? ASK-ABOUT>
+		     <PRSI? ,OBJECT-OF-GAME>>
+		<TELL ,ASK-ABOUT-OBJECT CR>)
+	       (<AND <EQUAL? ,FOLLOW-FLAG 3>
+		     <VERB? FOLLOW>>
+		<DO-WALK ,P?WEST>)
+	       (<AND <VERB? EXAMINE>
+		     <IN? ,BLASTER ,TRILLIAN>>
+		<TELL "She's holding a blaster at your head." CR>)>>
+
+<OBJECT HANDBAG
+	(IN TRILLIAN)
+	(DESC "handbag")
+	(SYNONYM HANDBA BAG PURSE)
+	(FLAGS CONTBIT TAKEBIT TRYTAKEBIT SEARCHBIT NDESCBIT)
+	(SIZE 15)
+	(CAPACITY 10)
+	(ACTION HANDBAG-F)>
+
+<ROUTINE HANDBAG-F ()
+	 <COND (<AND <VERB? DROP THROW>
+		     <EQUAL? ,IDENTITY-FLAG ,TRILLIAN>>
+		<DROP-AT-PARTY>)
+	       (<AND <VERB? TAKE>
+		     <IN? ,HANDBAG ,TRILLIAN>>
+		<TELL D ,TRILLIAN " pulls it away." CR>)>>
+
+<ROOM FORE-CORRIDOR
+      (IN ROOMS)
+      (DESC "Corridor, Fore End")
+      (UP TO BRIDGE)
+      (NORTH TO ENTRY-BAY)
+      (WEST TO GALLEY)
+      (SOUTH TO AFT-CORRIDOR)
+      (FLAGS ONBIT RLANDBIT)
+      (GLOBAL STAIRS HEART-OF-GOLD)
+      (ACTION FORE-CORRIDOR-F)>
+
+<ROUTINE FORE-CORRIDOR-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL "This is one end of a short corridor that continues ">
+		<COND (<EQUAL? ,HERE ,FORE-CORRIDOR>
+		       <TELL "aft">)
+		      (T
+		       <TELL "fore">)>
+		<TELL
+" along the main deck of " D ,HEART-OF-GOLD ". Doorways lead to ">
+		<COND (<EQUAL? ,HERE ,FORE-CORRIDOR>
+		       <TELL "fore">)
+		      (T
+		       <TELL "aft">)>
+		<TELL " and port. In addition, a gangway leads ">
+		<COND (<EQUAL? ,HERE ,FORE-CORRIDOR>
+		       <TELL "up">)
+		      (T
+		       <TELL "down">)>
+		<TELL "ward." CR>)>>
+
+<ROOM AFT-CORRIDOR
+      (IN ROOMS)
+      (SYNONYM ROBOT ROBOTS)
+      (ADJECTIVE CLEANI UPPER LOWER)
+      (DESC "Corridor, Aft End")
+      (SOUTH PER ENGINE-ROOM-ENTER-F)
+      (NORTH TO FORE-CORRIDOR)
+      (WEST TO PANTRY IF SCREENING-DOOR IS OPEN)
+      (DOWN TO HATCHWAY)
+      (FLAGS RLANDBIT ONBIT)
+      (GLOBAL STAIRS HEART-OF-GOLD SCREENING-DOOR)
+      (ACTION AFT-CORRIDOR-F)>
+
+<ROUTINE AFT-CORRIDOR-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<FCLEAR ,HATCH ,DOORBIT>
+		<RFALSE>)
+	       (<EQUAL? .RARG ,M-LOOK>
+		<FORE-CORRIDOR-F ,M-LOOK>)>>
+
+<ROUTINE I-REPLY ()
+	 <SETG AWAITING-REPLY <>>
+	 <RFALSE>>
+
+<GLOBAL AWAITING-REPLY <>>
+
+<GLOBAL ARGUMENT-COUNTER 0>
+
+<GLOBAL LOOK-COUNTER 0>
+
+<ROUTINE ENGINE-ROOM-ENTER-F ()
+	 <SETG ARGUMENT-COUNTER <+ ,ARGUMENT-COUNTER 1>>
+	 <COND (<EQUAL? ,ARGUMENT-COUNTER 1>
+		<SETG AWAITING-REPLY 1>
+		<ENABLE <QUEUE I-ARGUMENT 2>>
+		<TELL
+"That entrance leads to the" ,IID " chamber. It's supposed to be a terribly
+dangerous area of the ship. Are you sure you want to go in there?" CR>
+		<RFALSE>)
+	       (<EQUAL? ,ARGUMENT-COUNTER 2>
+		<SETG AWAITING-REPLY 1>
+		<ENABLE <QUEUE I-ARGUMENT 2>>
+		<TELL "Absolutely sure?" CR>
+		<RFALSE>)
+	       (<EQUAL? ,ARGUMENT-COUNTER 3>
+		<DISABLE <INT I-ARGUMENT>>
+		<SETG AWAITING-REPLY 100>
+		<ENABLE <QUEUE I-REPLY 2>>
+		<TELL
+"I can tell you don't want to really. You stride away with a spring in your
+step, wisely leaving the Drive Chamber safely behind you. Telegrams arrive from
+well-wishers in all corners of the Galaxy congratulating you on your prudence
+and wisdom, cheering you up immensely." CR>
+		<RFALSE>)
+	       (<EQUAL? ,ARGUMENT-COUNTER 4>
+		<ENABLE <QUEUE I-ARGUMENT 2>>
+		<ENABLE <QUEUE I-REPLY 2>>
+		<SETG AWAITING-REPLY 2>
+		<TELL
+"What? You're joking, of course. Can I ask you to reconsider?" CR>
+		<RFALSE>)
+	       (<G? ,ARGUMENT-COUNTER 4>
+		<DISABLE <INT I-ARGUMENT>>
+		<SETG AWAITING-REPLY <>>
+		,ENGINE-ROOM)>>
+
+<ROUTINE I-ARGUMENT ()
+	 <COND (<OR <AND <VERB? NO>
+		         <EQUAL? ,AWAITING-REPLY 1>>
+		    <AND <VERB? YES>
+		         <EQUAL? ,AWAITING-REPLY 2>>>
+		T)
+	       (T
+		<CRLF>)>
+	 <SETG AWAITING-REPLY <>>
+	 <SETG ARGUMENT-COUNTER 0>
+	 <TELL
+"I knew you weren't serious about entering that extremely dangerous area." CR>>
+
+<ROOM ENTRY-BAY
+      (IN ROOMS)
+      (SYNONYM BLASTE)
+      (ADJECTIVE PAN-GA GARGLE)
+      (DESC "Entry Bay Number Two")
+      (LDESC
+"This is an entry bay for the Heart of Gold. A corridor lies aft of here.")
+      (SOUTH TO FORE-CORRIDOR)
+      (FLAGS RLANDBIT ONBIT NARTICLEBIT)
+      (GLOBAL HEART-OF-GOLD)
+      (ACTION ENTRY-BAY-F)>
+
+<ROUTINE ENTRY-BAY-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<SETG IDENTITY-FLAG ,ARTHUR>
+		<MOVE ,HATCH ,GLOBAL-OBJECTS> ;"so you can ask Marv to fix it"
+		<MOVE ,MECHANISM ,GLOBAL-OBJECTS> ;"ditto"
+		<MOVE ,ARTHUR ,GLOBAL-OBJECTS>
+		<COND (<FSET? ,ENTRY-BAY ,NDESCBIT>
+		       <MOVE ,FORD ,LOCAL-GLOBALS>
+		       <MOVE ,TRILLIAN ,LOCAL-GLOBALS>
+		       <MOVE ,ZAPHOD ,LOCAL-GLOBALS>)
+		      (T
+		       <FSET ,ENTRY-BAY ,NDESCBIT>
+		       <ENABLE <QUEUE I-FORD 1>>)>
+		<RFALSE>)>>
+
+<OBJECT SALES-BROCHURE
+	(IN ENTRY-BAY)
+	(DESC "sales brochure")
+	(SYNONYM BROCHURE)
+	(ADJECTIVE SALES)
+	(FLAGS TAKEBIT READBIT)
+	(ACTION SALES-BROCHURE-F)>
+
+<ROUTINE SALES-BROCHURE-F ()
+	 <COND (<VERB? READ>
+		<TELL
+"\"Equipped with a sensational breakthrough in Improbability Physics, "
+D ,HEART-OF-GOLD " will make you the envy of every major government. When the
+ship's" ,IID " is activated, " D ,HEART-OF-GOLD " passes through every point in
+the universe simultaneously, making travel to any single location a breeze!\"|
+|
+The " D ,SALES-BROCHURE " goes on to describe the ship's complement of " ,SCC
+"-designed robots and computers, all equipped with GPP (" ,GPP ")." CR>)>>  
+
+<ROOM ENGINE-ROOM
+      (IN ROOMS)
+      (SYNONYM IMPROB PHYSIC DRIVES PROBAB)
+      (ADJECTIVE IMPROB INFINI)
+      (DESC "Engine Room")
+      (NORTH TO AFT-CORRIDOR)
+      (OUT TO AFT-CORRIDOR)
+      (FLAGS RLANDBIT ONBIT)
+      (GLOBAL HEART-OF-GOLD)
+      (ACTION ENGINE-ROOM-F)>
+
+<ROUTINE ENGINE-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<SETG LOOK-COUNTER <+ ,LOOK-COUNTER 1>>
+		<COND (<EQUAL? ,LOOK-COUNTER 1>
+		       <TELL
+"You're in the" ,IID " chamber. Nothing happens; there is nothing to see." CR>)
+		      (<EQUAL? ,LOOK-COUNTER 2>
+		       <TELL "I mean it! There's nothing to see here!" CR>)
+		      (<G? ,LOOK-COUNTER 2>
+		       <COND (<EQUAL? ,LOOK-COUNTER 3>
+			      <MOVE ,MAIN-DRIVE ,GLOBAL-OBJECTS>
+			      	     	;"so you can ask Ed to turn it on"
+			      <MOVE ,SPARE-DRIVE ,HERE>
+			      <MOVE ,PLIERS ,HERE>
+			      <MOVE ,RASP ,HERE>
+			      <SETG SCORE <+ ,SCORE 25>>
+			      <TELL
+"Okay, okay, there are a FEW things to see here. ">)>
+		       <TELL
+"This is the room that houses the powerful In" ,FIG
+" that drives " D ,HEART-OF-GOLD ". An exit lies fore of here." CR>)>)
+	       (<AND <EQUAL? ,RARG ,M-END>
+		     <EQUAL? ,LOOK-COUNTER 3>>
+		<SETG LOOK-COUNTER 4>
+		<TELL CR "(Footnote 10)" CR>)>>
+
+<OBJECT MAIN-DRIVE
+	(IN LOCAL-GLOBALS) ;"for purposes of MOBY-FIND"
+	(DESC "main Improbability Drive")
+	(SYNONYM DRIVE GENERA)
+	(ADJECTIVE MAIN INFINI IMPROB)
+	(FLAGS NDESCBIT LIGHTBIT)
+	(GENERIC SPARE-DRIVE)
+	(ACTION MAIN-DRIVE-F)>
+
+<ROUTINE MAIN-DRIVE-F ()
+	 <COND (<AND <VERB? EXAMINE RUB>
+		     <NOT <EQUAL? ,HERE ,ENGINE-ROOM>>>
+		<CANT-SEE ,MAIN-DRIVE>)
+	       (<VERB? LAMP-ON>
+		<TELL "Only " D ,EDDIE " can activate the drive." CR>)>>
+
+<GLOBAL DRIVE-TO-CONTROLS <>>
+
+<GLOBAL DRIVE-TO-PLOTTER <>>
+
+<GLOBAL BROWNIAN-SOURCE <>>
+
+<GLOBAL DARK-CONTROLLED <>>
+
+<OBJECT SPARE-DRIVE
+	(IN LOCAL-GLOBALS) ;"for purposes of MOBY-FIND"
+	(DESC "spare Improbability Drive")
+	(FDESC
+"Sitting in the corner is a spare, portable Improbability Generator.")
+	(SYNONYM DRIVE GENERA)
+	(ADJECTIVE SPARE PORTAB INFINI IMPROB)
+	(FLAGS TAKEBIT TRANSBIT CONTBIT LIGHTBIT)
+	(SIZE 50)
+	(GENERIC SPARE-DRIVE)
+	(ACTION SPARE-DRIVE-F)>
+
+<ROUTINE SPARE-DRIVE-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL "The " D ,SPARE-DRIVE " has a switch">
+		<COND (<IN? ,LARGE-PLUG ,SPARE-DRIVE>
+		       <TELL ", a long cord ">
+		       <COND (,DRIVE-TO-CONTROLS
+			      <TELL "plugged into the control console,">)
+			     (T
+			      <TELL "ending with a " D ,LARGE-PLUG ",">)>)
+		      (T
+		       <TELL ", a fused spot where a long cord once began,">)>
+		<TELL " and a short cord ">
+		<COND (,DRIVE-TO-PLOTTER
+		       <TELL "plugged into the " D ,PLOTTER>)
+		      (T
+		       <TELL "ending with a " D ,SMALL-PLUG>)>
+		<TELL ".">
+		<FINE-PRODUCT>
+		<CRLF>)
+	       (<OR <AND <VERB? PLUG TIE>
+			 <PRSO? ,SPARE-DRIVE>>
+		    <AND <VERB? PUT>
+			 <PRSI? ,LARGE-RECEPTACLE ,SMALL-RECEPTACLE>>>
+		<COND (<IN? ,LARGE-PLUG ,SPARE-DRIVE>
+		       <TELL
+"In case you hadn't noticed, there are two connections leading from the "
+D ,SPARE-DRIVE "..." CR>)
+		      (T
+		       <PERFORM ,V?PLUG ,SMALL-PLUG ,PRSI>
+		       <RTRUE>)>)
+	       (<VERB? UNPLUG>
+		<COND (<OR ,DRIVE-TO-CONTROLS ,DRIVE-TO-PLOTTER>
+		       <SETG DRIVE-TO-PLOTTER <>>
+		       <SETG DRIVE-TO-CONTROLS <>>
+		       <FCLEAR ,SPARE-DRIVE ,NDESCBIT>
+		       <TELL "Done." CR>)
+		      (T
+		       <TELL ,NOT-PLUGGED CR>)>)
+	       (<VERB? LAMP-ON>
+		<PERFORM ,V?LAMP-ON ,SWITCH>
+		<RTRUE>)
+	       (<VERB? OPEN CLOSE>
+		<V-CARVE>)>>
+
+<OBJECT LARGE-PLUG
+	(IN SPARE-DRIVE)
+	(DESC "large plug")
+	(SYNONYM CORD PLUG)
+	(ADJECTIVE LARGE LONG)
+	(FLAGS NDESCBIT INTEGRALBIT)
+	(SIZE 1)
+	(ACTION LARGE-PLUG-F)>
+
+<ROUTINE LARGE-PLUG-F ()
+	 <COND (<AND <VERB? PLUG PUT TIE>
+		     <PRSI? ,LARGE-RECEPTACLE ,CONTROLS>>
+		<COND (,DRIVE-TO-CONTROLS
+		       <TELL "It already is!" CR>
+		       <RTRUE>)>
+		<SETG DRIVE-TO-CONTROLS T>
+		<FSET ,SPARE-DRIVE ,NDESCBIT>
+		<TELL "Plugged.">
+		<COND (<NOT <RUNNING? ,I-TEA>>
+		       <TELL
+" " D ,EDDIE " says \"You shouldn't be playing around with a " D ,SPARE-DRIVE
+". Who knows where it's been?\"" CR CR ,ANNOUNCEMENT D ,EDDIE ". Someone has
+connected a " D ,SPARE-DRIVE " to" ,MOP ". Better be an emergency, that's all
+I have to say.\"">)>
+		<CRLF>)
+	       (<AND <VERB? TAKE>
+		     <PRSI? ,CONTROLS>>
+		<PERFORM ,V?UNPLUG ,LARGE-PLUG>
+		<RTRUE>)
+	       (<VERB? UNPLUG REMOVE>
+		<COND (,DRIVE-TO-CONTROLS
+		       <SETG DRIVE-TO-CONTROLS <>>
+		       <FCLEAR ,SPARE-DRIVE ,NDESCBIT>
+		       <TELL "Done." CR>)
+		      (T
+		       <TELL ,NOT-PLUGGED CR>)>)>>
+
+<OBJECT SMALL-PLUG
+	(IN SPARE-DRIVE)
+	(DESC "small plug")
+	(SYNONYM CORD PLUG)
+	(ADJECTIVE SMALL SHORT)
+	(FLAGS NDESCBIT INTEGRALBIT)
+	(SIZE 1)
+	(ACTION SMALL-PLUG-F)>
+
+<ROUTINE SMALL-PLUG-F ()
+	 <COND (<AND <VERB? PLUG PUT TIE>
+		     <PRSI? ,SMALL-RECEPTACLE ,PLOTTER>>
+		<COND (,DRIVE-TO-PLOTTER
+		       <TELL "It already is!" CR>
+		       <RTRUE>)>
+		<SETG DRIVE-TO-PLOTTER T>
+		<TELL "Plugged." CR>)
+	       (<AND <VERB? TAKE>
+		     <PRSI? ,PLOTTER>>
+		<PERFORM ,V?UNPLUG ,SMALL-PLUG>
+		<RTRUE>)
+	       (<VERB? UNPLUG REMOVE>
+		<COND (,DRIVE-TO-PLOTTER
+		       <SETG DRIVE-TO-PLOTTER <>>
+		       <TELL "Done." CR>)
+		      (T
+		       <TELL ,NOT-PLUGGED CR>)>)>>
+
+<OBJECT SWITCH
+	(IN SPARE-DRIVE)
+	(DESC "generator switch")
+	(SYNONYM SWITCH)
+	(ADJECTIVE GENERA)
+	(FLAGS NDESCBIT SWITCHBIT)
+	(SIZE 1)
+	(ACTION SWITCH-F)>
+
+<ROUTINE SWITCH-F ()
+	 <COND (<VERB? LAMP-ON TURN PUSH MOVE THROW>
+		<COND (<AND ,DRIVE-TO-PLOTTER
+			    ,BROWNIAN-SOURCE>
+		       <MOVE ,SPARE-DRIVE ,HERE>
+		       <MOVE ,PLOTTER ,HERE>
+		       <MOVE ,BROWNIAN-SOURCE ,HERE>
+		       <COND (<EQUAL? ,BROWNIAN-SOURCE ,TEA>
+			      <SETG HOLDING-NO-TEA T>)>
+		       <COND (,DRIVE-TO-CONTROLS
+			      <TELL
+"As you flip the switch, sparks fly from the large receptacle. ">
+			      <COND (<AND <RUNNING? ,I-TEA>
+					  <G? ,TEA-COUNTER 6>>
+				     <TELL
+"\"My new control console!\" wails " D ,EDDIE ". \"This is the thanks I get">)
+				    (T
+				     <TELL
+"\"Now look what you've done. You've destroyed" ,MOP ". Don't you
+know it's only for emergencies">)>
+			      <TELL "?\"" CR CR>
+			      <SETG DRIVE-TO-CONTROLS <>>
+			      <FCLEAR ,SPARE-DRIVE ,NDESCBIT>
+			      <MOVE ,LARGE-PLUG ,LOCAL-GLOBALS>
+			      <MOVE ,LARGE-RECEPTACLE ,LOCAL-GLOBALS>
+			      <COND (<AND <RUNNING? ,I-TEA>
+					  <G? ,TEA-COUNTER 6>>
+				     <MOVE ,TEA ,SLOT>
+				     <DISABLE <INT I-TEA>>
+				     <ENABLE <QUEUE I-LANDING 24>>
+	       			     <SETG FOLLOW-FLAG 3>
+			      	     <ENABLE <QUEUE I-FOLLOW 2>>
+				     <TELL
+"The universe goes crazy for a moment." CR CR ,ANNOUNCEMENT D ,EDDIE ". The
+missiles have turned into a sperm whale">
+				     <FACTOR "39,745">
+				     <TELL
+" The whale is currently plummeting toward" ,LOST-PLANET ". I hope this will
+teach you to listen to me when I say that legendary lost planets can be
+dangerous. I am proceeding with the pre-set landing instructions.\"|
+|
+Ford, Zaphod, and " D ,TRILLIAN " saunter by on their way back to the sauna.
+\"Good work, kid,\" says Zaphod, slamming you on the back." CR>)
+				    (T
+				     <DISABLE <INT I-TEA>>
+				     <SETG SCORE <- ,SCORE 30>>
+				     <TELL
+,ANNOUNCEMENT D ,EDDIE ". Someone has activated a " D ,SPARE-DRIVE " at"
+,MOP ", moving us 8 billion parsecs away from our destination, adding seven
+weeks to our trip. As if that isn't bad enough, all 300 members of the
+Fronurbdi Planetary Senate appeared in the " D ,HATCHWAY>
+				     <FACTOR "79,818">
+				     <TELL
+" I'm flushing them into space now, but who knows what sort of germs they've
+dragged into the ship? Everyone should take extra vitamins today.\"" CR>)>)
+			     (<RUNNING? ,I-TEA>
+			      <SETG DREAMING T>
+			      <DISABLE <INT I-TEA>>
+			      <JIGS-UP
+"Everything becomes dark! But no, not quite everything ... There's a big bright
+planet below, just visible behind your mighty tail fin. Air begins rushing by,
+tickling your snout and dorsal fins ... you suddenly realise that, improbably
+enough, you've turned yourself into a sperm whale and are plummeting through
+the atmosphere of a planet! You begin experimenting with your new body, opening
+and closing your spout and wagging your enormous tail. Just as you are getting
+used to being a whale, the ground rushes up and hits you at about 200 mph.">
+			      <RTRUE>)
+			     (T
+			      <COND (<EQUAL? ,BROWNIAN-SOURCE ,TEA>
+				     <SETG DARK-CONTROLLED T>)>
+			      <MOVE ,HATCH ,LOCAL-GLOBALS>
+			      <MOVE ,MECHANISM ,LOCAL-GLOBALS>
+			      <TELL <PICK-ONE ,DARK-ENTRANCES> CR CR>
+			      <GOTO ,DARK>
+			      <RTRUE>)>)
+		      (T
+		       <TELL "Nothing happens." CR>)>)>>
+
+<GLOBAL DARK-ENTRANCES
+	<PLTABLE
+"You are disoriented. Blackness swims toward you like a shoal of eels who
+have just seen something that eels like a lot..."
+"Like fog rolling in off the ocean, a shroud of blackness billows toward
+you. Unlike fog rolling in off the ocean, the blackness hits you like
+a sixteen-tonne truck..." 
+"A mist spins round your head. You fall into what seems like a bottomless
+pit. Suddenly, you hit the bottom so hard that you wish it had been
+bottomless...">>
+
+<OBJECT PLOTTER
+	(IN GLASS-CASE)
+	(DESC "atomic vector plotter")
+	(DESCFCN PLOTTER-DESCFCN)
+	(SYNONYM PLOTTE)
+	(ADJECTIVE ATOMIC VECTOR)
+	(FLAGS VOWELBIT TAKEBIT CONTBIT TRANSBIT TRYTAKEBIT)
+	(SIZE 20)
+	(ACTION PLOTTER-F)>
+
+<ROUTINE PLOTTER-DESCFCN ("OPTIONAL" X)
+	 <TELL "Lying on the deck is a plotter">
+	 <COND (,DRIVE-TO-PLOTTER
+		<TELL " connected to a " D ,SPARE-DRIVE ".">)
+	       (T
+		<TELL ".">)>
+	 <COND (,BROWNIAN-SOURCE
+		<TELL
+" The plotter's " D ,DANGLY-BIT " is submerged in " D ,BROWNIAN-SOURCE ".">)>
+	 <CRLF>>
+
+<ROUTINE PLOTTER-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The " D ,PRSO " has a " D ,SMALL-RECEPTACLE " and a " D ,DANGLY-BIT>
+		<COND (,BROWNIAN-SOURCE
+		       <TELL " which is sitting in " D ,BROWNIAN-SOURCE>)>
+		<COND (,DRIVE-TO-PLOTTER
+		       <TELL
+". The short cord from the " D ,SPARE-DRIVE " is plugged in the receptacle">)>
+		<TELL ".">
+		<FINE-PRODUCT>
+		<CRLF>)
+	       (<AND <VERB? PLUG>
+		     <PRSI? ,SPARE-DRIVE>>
+		<PERFORM ,V?PLUG ,SPARE-DRIVE ,PLOTTER>
+		<RTRUE>)
+	       (<VERB? UNPLUG>
+		<COND (,DRIVE-TO-PLOTTER
+		       <SETG DRIVE-TO-PLOTTER <>>
+		       <TELL "Unplugged." CR>)
+		      (T
+		       <TELL ,NOT-PLUGGED CR>)>)
+	       (<VERB? OPEN CLOSE>
+		<V-CARVE>)>>
+
+<OBJECT SMALL-RECEPTACLE
+	(IN PLOTTER)
+	(DESC "small receptacle")
+	(SYNONYM RECEPT)
+	(ADJECTIVE SMALL)
+	(SIZE 1)
+	(FLAGS NDESCBIT INTEGRALBIT)>
+
+<OBJECT DANGLY-BIT
+	(IN PLOTTER)
+	(DESC "long, dangly bit")
+	(SYNONYM BIT)
+	(ADJECTIVE LONG DANGLY)
+	(FLAGS NDESCBIT INTEGRALBIT)
+	(SIZE 1)
+	(ACTION DANGLY-BIT-F)>
+
+<ROUTINE DANGLY-BIT-F ()
+	 <COND (<AND <VERB? PUT>
+		     <PRSI? ,SUBSTITUTE ,TEA>>
+		<COND (,BROWNIAN-SOURCE
+		       <TELL "But the " D ,DANGLY-BIT " is already in">
+		       <ARTICLE ,BROWNIAN-SOURCE T>
+		       <TELL "!" CR>
+		       <RTRUE>)>
+		<SETG BROWNIAN-SOURCE ,PRSI>
+		<COND (<AND <PRSI? ,TEA>
+			    <NOT ,CARELESS-WORDS-FLAG>>
+		       <SETG CARELESS-WORDS-FLAG T>
+		       <SAVE-INPUT ,FIRST-BUFFER>
+		       <ENABLE <QUEUE I-CARELESS-WORDS 3>>)>
+		<TELL "Done." CR>)
+	       (<AND <VERB? EXAMINE>
+		     ,BROWNIAN-SOURCE>
+		<TELL
+"The " D ,DANGLY-BIT " is suspended in the cup of " D ,BROWNIAN-SOURCE "." CR>)
+	       (<AND <VERB? REMOVE>
+		     ,BROWNIAN-SOURCE>
+		<TELL "The " D ,DANGLY-BIT " is no longer suspended in">
+		<ARTICLE ,BROWNIAN-SOURCE T>
+		<TELL "." CR>
+		<SETG BROWNIAN-SOURCE <>>
+		<RTRUE>)>>
+
+<ROOM HATCHWAY
+      (IN ROOMS)
+      (SYNONYM GPP PERSON)
+      (ADJECTIVE GENUIN PEOPLE)
+      (DESC "Hatchway")
+      (UP TO AFT-CORRIDOR)
+      (DOWN TO RAMP IF HATCH IS OPEN)
+      (OUT TO RAMP IF HATCH IS OPEN)
+      (EAST PER ACCESS-SPACE-ENTER-F)
+      (FLAGS ONBIT RLANDBIT)
+      (GLOBAL STAIRS HEART-OF-GOLD)
+      (ACTION HATCHWAY-F)>
+
+<ROUTINE HATCHWAY-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"You are at the bottom of a gangway. A hatch below you is ">
+		<COND (<FSET? ,HATCH ,OPENBIT>
+		       <TELL "open">)
+		      (T
+		       <TELL "closed">)>
+		<TELL ". There is a small access space to starboard." CR>)
+	       (<EQUAL? .RARG ,M-ENTER>
+		<FSET ,HATCH ,DOORBIT>
+		<RFALSE>)>>
+
+<ROUTINE ACCESS-SPACE-ENTER-F ()
+	 <COND (<G? <ACCESS-SPACE-LOOP ,PROTAGONIST> 1>
+		<TELL
+"That entrance is so narrow that you probably couldn't pass by holding
+anything. Well, maybe ONE thing." CR>
+		<RFALSE>)
+	       (T
+		<FCLEAR ,HATCH ,DOORBIT>
+		,ACCESS-SPACE)>>
+
+<ROUTINE ACCESS-SPACE-LOOP (CONT "AUX" X NUMBER)
+	 <SET X <FIRST? .CONT>>
+	 <REPEAT ()
+		 <COND (<NOT .X>
+			<RETURN>)>
+		 <COND (<AND <NOT <FSET? .X ,WORNBIT>>
+			     <NOT <FSET? .X ,INTEGRALBIT>>
+			     <NOT <EQUAL? .X ,BABEL-FISH>>>
+			<SET NUMBER <+ .NUMBER 1>>)>
+		 <COND (<FIRST? .X>
+			<SET NUMBER <+ .NUMBER <ACCESS-SPACE-LOOP .X>>>)>
+		 <SET X <NEXT? .X>>>
+	 <RETURN .NUMBER>>
+
+<OBJECT HATCH
+	(IN LOCAL-GLOBALS) ;"for purposes of MOBY-FIND"
+	(DESC "hatch")
+	(SYNONYM HATCH HATCHW)
+	(ACTION HATCH-F)>
+
+<ROUTINE HATCH-F ()
+	 <COND (<AND <NOT <EQUAL? ,HERE ,HATCHWAY>>
+		     <VERB? OPEN CLOSE EXAMINE RUB>>
+		<CANT-SEE ,HATCH>)
+	       (<AND <VERB? OPEN THROUGH>
+		     <NOT ,LANDED>>
+		<TELL
+"Loud sirens blare, fantastically bright red lights flash from all sides, and
+a soft female voice mentions that opening this hatch in space will evacuate
+the air from the ship." CR>)
+	       (<AND <VERB? OPEN THROUGH>
+		     <NOT <FSET? ,HATCH ,OPENBIT>>>
+		<TELL "The hatch appears to be jammed shut." CR>)>>
+
+<OBJECT MECHANISM
+	(IN LOCAL-GLOBALS) ;"for purposes of MOBY-FIND"
+	(DESC "mechanism")
+	(SYNONYM MECHAN)
+	(ADJECTIVE HATCH HATCHW)
+	(ACTION MECHANISM-F)>
+
+<ROUTINE MECHANISM-F ()
+	 <COND (<AND <NOT <EQUAL? ,HERE ,ACCESS-SPACE>>
+		     <VERB? EXAMINE SMELL RUB REPAIR>>
+		<CANT-SEE ,MECHANISM>)
+	       (<VERB? REPAIR>
+		<PERFORM ,V?REPAIR ,HATCH>
+		<RTRUE>)
+	       (<VERB? EXAMINE>
+		<TELL
+"I don't even understand it, and I'm a computer!" CR>)>>
+
+<ROOM ACCESS-SPACE
+      (IN ROOMS)
+      (SYNONYM AGENCY)
+      (ADJECTIVE GALACT SECURI)
+      (DESC "Access Space")
+      (OUT TO HATCHWAY)
+      (WEST TO HATCHWAY)
+      (FLAGS ONBIT RLANDBIT)
+      (PSEUDO "MESH" MESH-PSEUDO)
+      (GLOBAL HEART-OF-GOLD)
+      (ACTION ACCESS-SPACE-F)>
+
+<ROUTINE ACCESS-SPACE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This tiny area, with an exit to port, is for working on the hatch
+" D ,MECHANISM ", which is vastly more complicated than your rather
+ordinary intelligence can comprehend. ">
+		<PERFORM ,V?EXAMINE ,GROUND>
+		<RTRUE>)>>
+
+<ROUTINE MESH-PSEUDO ()
+	 <COND (<PRSI? ,PSEUDO-OBJECT>
+		<PERFORM ,PRSA ,PRSO ,GROUND>
+		<RTRUE>)
+	       (T
+		<PERFORM ,PRSA ,GROUND ,PRSI>
+		<RTRUE>)>>
+
+<ROOM RAMP
+      (IN ROOMS)
+      (SYNONYM PLANET MAGRAT)
+      (ADJECTIVE LEGEND)
+      (DESC "Ramp")
+      (LDESC
+"The wind moans. Dust drifts across the surface of the alien world. Zaphod,
+Ford, and Trillian appear and urge you forward.")
+      (FLAGS RLANDBIT ONBIT)
+      (ACTION RAMP-F)>
+
+<ROUTINE RAMP-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<TELL
+"You step onto the landing ramp leading down toward the surface of"
+,LOST-PLANET ". " ,ANNOUNCEMENT D ,EDDIE ". Someone is leaving the ship
+on a strange planet without wrapping up all nice and warm. It'll all end
+in tears, I just know it...\" The voice fades behind you." CR CR>)
+	       (<EQUAL? .RARG ,M-END>
+		<TELL CR
+"Slowly, nervously, you step downwards, the cold thin air rasping in your
+lungs. You set one single foot on the ancient dust -- and almost instantly
+the most incredible adventure starts which you'll have to buy the next game
+to find out about." CR CR>
+		<V-SCORE>
+		<TELL CR
+"By the way, there WAS a causal relationship between your taking the "
+D ,TOOTHBRUSH " and the tree collapsing at the very beginning of the game.
+We apologise for this slight inaccuracy." CR>
+		<QUIT>)>>
\ No newline at end of file
diff --git a/misc.zil b/misc.zil
new file mode 100644
index 0000000..1c26fb5
--- /dev/null
+++ b/misc.zil
@@ -0,0 +1,616 @@
+"MISC for
+		  THE HITCHHIKER'S GUIDE TO THE GALAXY
+	     (c) 1984 by Infocom, Inc.  All Rights Reserved."
+
+;"former MACROS.ZIL stuff"
+
+<ZSTR-OFF>
+
+<SETG C-ENABLED? 0>
+
+<SETG C-ENABLED 1>
+
+<SETG C-DISABLED 0>
+
+;<ROUTINE ENABLED? (RTN "AUX" C E)
+	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
+	 <SET C <REST ,C-TABLE ,C-INTS>>
+	 <REPEAT ()
+		 <COND (<==? .C .E> <RFALSE>)
+		       (<EQUAL? <GET .C ,C-RTN> .RTN>
+			<COND (<0? <GET .C ,C-ENABLED?>>
+			       <RFALSE>)
+			      (T
+			       <RTRUE>)>)>
+		 <SET C <REST .C ,C-INTLEN>>>>
+
+;<ROUTINE QUEUED? (RTN "AUX" C E)
+	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
+	 <SET C <REST ,C-TABLE ,C-INTS>>
+	 <REPEAT ()
+		 <COND (<==? .C .E> <RFALSE>)
+		       (<EQUAL? <GET .C ,C-RTN> .RTN>
+			<COND (<OR <0? <GET .C ,C-ENABLED?>>
+				   <0? <GET .C ,C-TICK>>>
+			       <RFALSE>)
+			      (T <RTRUE>)>)>
+		 <SET C <REST .C ,C-INTLEN>>>>
+
+<ROUTINE RUNNING? (RTN "AUX" C E TICK)
+	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
+	 <SET C <REST ,C-TABLE ,C-INTS>>
+	 <REPEAT ()
+		 <COND (<==? .C .E> <RFALSE>)
+		       (<EQUAL? <GET .C ,C-RTN> .RTN>
+			<COND (<OR <0? <GET .C ,C-ENABLED?>>
+				   <0? <SET TICK <GET .C ,C-TICK>>>
+				   <G? .TICK 1>>
+			       <RFALSE>)
+			      (T <RTRUE>)>)>
+		 <SET C <REST .C ,C-INTLEN>>>>
+
+<DEFMAC TELL ("ARGS" A)
+	<FORM PROG ()
+	      !<MAPF ,LIST
+		     <FUNCTION ("AUX" E P O)
+			  <COND (<EMPTY? .A> <MAPSTOP>)
+				(<SET E <NTH .A 1>>
+				 <SET A <REST .A>>)>
+			  <COND (<TYPE? .E ATOM>
+				 <COND (<OR <=? <SET P <SPNAME .E>>
+						"CRLF">
+					    <=? .P "CR">>
+					<MAPRET '<CRLF>>)
+				       (<EMPTY? .A>
+					<ERROR INDICATOR-AT-END? .E>)
+				       (ELSE
+					<SET O <NTH .A 1>>
+					<SET A <REST .A>>
+					<COND (<OR <=? <SET P <SPNAME .E>>
+						       "DESC">
+						   <=? .P "D">
+						   <=? .P "OBJ">
+						   <=? .P "O">>
+					       <MAPRET <FORM PRINTD .O>>)
+					      (<OR <=? .P "NUM">
+						   <=? .P "N">>
+					       <MAPRET <FORM PRINTN .O>>)
+					      (<OR <=? .P "CHAR">
+						   <=? .P "CHR">
+						   <=? .P "C">>
+					       <MAPRET <FORM PRINTC .O>>)
+					      (ELSE
+					       <MAPRET
+						 <FORM PRINT
+						       <FORM GETP .O .E>>>)>)>)
+				(<TYPE? .E STRING ZSTRING>
+				 <MAPRET <FORM PRINTI .E>>)
+				(<TYPE? .E FORM LVAL GVAL>
+				 <MAPRET <FORM PRINT .E>>)
+				(ELSE <ERROR UNKNOWN-TYPE .E>)>>>>>
+
+<DEFMAC VERB? ("ARGS" ATMS)
+	<MULTIFROB PRSA .ATMS>>
+
+<DEFMAC PRSO? ("ARGS" ATMS)
+	<MULTIFROB PRSO .ATMS>>
+
+<DEFMAC PRSI? ("ARGS" ATMS)
+	<MULTIFROB PRSI .ATMS>>
+
+<DEFMAC ROOM? ("ARGS" ATMS)
+	<MULTIFROB HERE .ATMS>>
+
+<DEFINE MULTIFROB (X ATMS "AUX" (OO (OR)) (O .OO) (L ()) ATM) 
+	<REPEAT ()
+		<COND (<EMPTY? .ATMS>
+		       <RETURN!- <COND (<LENGTH? .OO 1> <ERROR .X>)
+				       (<LENGTH? .OO 2> <NTH .OO 2>)
+				       (ELSE <CHTYPE .OO FORM>)>>)>
+		<REPEAT ()
+			<COND (<EMPTY? .ATMS> <RETURN!->)>
+			<SET ATM <NTH .ATMS 1>>
+			<SET L
+			     (<COND (<TYPE? .ATM ATOM>
+				     <FORM GVAL
+					   <COND (<==? .X PRSA>
+						  <PARSE
+						    <STRING "V?"
+							    <SPNAME .ATM>>>)
+						 (ELSE .ATM)>>)
+				    (ELSE .ATM)>
+			      !.L)>
+			<SET ATMS <REST .ATMS>>
+			<COND (<==? <LENGTH .L> 3> <RETURN!->)>>
+		<SET O <REST <PUTREST .O (<FORM EQUAL? <FORM GVAL .X> !.L>)>>>
+		<SET L ()>>>
+
+<DEFMAC BSET ('OBJ "ARGS" BITS)
+	<MULTIBITS FSET .OBJ .BITS>>
+
+<DEFMAC BCLEAR ('OBJ "ARGS" BITS)
+	<MULTIBITS FCLEAR .OBJ .BITS>>
+
+<DEFMAC BSET? ('OBJ "ARGS" BITS)
+	<MULTIBITS FSET? .OBJ .BITS>>
+
+<DEFINE MULTIBITS (X OBJ ATMS "AUX" (O ()) ATM) 
+	<REPEAT ()
+		<COND (<EMPTY? .ATMS>
+		       <RETURN!- <COND (<LENGTH? .O 1> <NTH .O 1>)
+				       (<EQUAL? .X FSET?> <FORM OR !.O>)
+				       (ELSE <FORM PROG () !.O>)>>)>
+		<SET ATM <NTH .ATMS 1>>
+		<SET ATMS <REST .ATMS>>
+		<SET O
+		     (<FORM .X
+			    .OBJ
+			    <COND (<TYPE? .ATM FORM> .ATM)
+				  (ELSE <FORM GVAL .ATM>)>>
+		      !.O)>>>
+
+<DEFMAC RFATAL ()
+	'<PROG () <PUSH 2> <RSTACK>>>
+
+<DEFMAC PROB ('BASE?)
+	<FORM NOT <FORM L? .BASE? '<RANDOM 100>>>>
+
+<ROUTINE PICK-ONE (FROB)
+	 <GET .FROB <RANDOM <GET .FROB 0>>>>
+
+<DEFMAC ENABLE ('INT)
+	<FORM PUT .INT ,C-ENABLED? 1>>
+
+<DEFMAC DISABLE ('INT)
+	<FORM PUT .INT ,C-ENABLED? 0>>
+
+<ZSTR-ON>
+
+
+;"former MAIN.ZIL stuff"
+
+<GLOBAL PLAYER <>>
+
+<GLOBAL P-WON <>>
+
+<CONSTANT M-FATAL 2>
+<CONSTANT M-BEG 1>
+<CONSTANT M-END 6>
+<CONSTANT M-ENTER 2>
+<CONSTANT M-LOOK 3>
+<CONSTANT M-FLASH 4>
+<CONSTANT M-OBJDESC 5>
+
+<ROUTINE GO () 
+	 <PUTB ,P-LEXV 0 59>
+;"put interrupts on clock chain"
+	 <ENABLE <QUEUE I-HOUSEWRECK 20>>
+	 <ENABLE <QUEUE I-THING 21>>
+	 <ENABLE <QUEUE I-VOGONS 50>>	 
+;"set up and go"
+	 <SETG WINNER ,PROTAGONIST>
+	 <SETG PLAYER ,PROTAGONIST>
+	 <SETG HERE ,BEDROOM>
+	 <SETG IDENTITY-FLAG ,ARTHUR>
+	 <MOVE ,ARTHUR ,GLOBAL-OBJECTS>
+	 <SETG LYING-DOWN T>
+	 <MOVE ,PROTAGONIST ,BED>
+	 <V-VERSION>
+	 <CRLF>
+	 <TELL
+"You wake up. The room is spinning very gently round your head. Or at least
+it would be if you could see it which you can't." CR CR>
+	 <V-LOOK>
+	 <MAIN-LOOP>
+	 <AGAIN>>    
+
+<ROUTINE MAIN-LOOP ("AUX" ICNT OCNT NUM CNT OBJ TBL V PTBL OBJ1 TMP)
+   <REPEAT ()
+     <SET CNT 0>
+     <SET OBJ <>>
+     <SET PTBL T>
+     <COND (<SETG P-WON <PARSER>>
+	    <SET ICNT <GET ,P-PRSI ,P-MATCHLEN>>
+	    <SET OCNT <GET ,P-PRSO ,P-MATCHLEN>>
+	    <COND (<AND ,P-IT-OBJECT <ACCESSIBLE? ,P-IT-OBJECT>>
+		   <SET TMP <>>
+		   <REPEAT ()
+			   <COND (<G? <SET CNT <+ .CNT 1>> .ICNT>
+				  <RETURN>)
+				 (T
+				  <COND (<EQUAL? <GET ,P-PRSI .CNT> ,IT>
+					 <PUT ,P-PRSI .CNT ,P-IT-OBJECT>
+					 <SET TMP T>
+					 <RETURN>)>)>>
+		   <COND (<NOT .TMP>
+			  <SET CNT 0>
+			  <REPEAT ()
+			   <COND (<G? <SET CNT <+ .CNT 1>> .OCNT>
+				  <RETURN>)
+				 (T
+				  <COND (<EQUAL? <GET ,P-PRSO .CNT> ,IT>
+					 <PUT ,P-PRSO .CNT ,P-IT-OBJECT>
+					 <RETURN>)>)>>)>
+		   <SET CNT 0>)>
+	    <SET NUM
+		 <COND (<0? .OCNT> .OCNT)
+		       (<G? .OCNT 1>
+			<SET TBL ,P-PRSO>
+			<COND (<0? .ICNT> <SET OBJ <>>)
+			      (T <SET OBJ <GET ,P-PRSI 1>>)>
+			.OCNT)
+		       (<G? .ICNT 1>
+			<SET PTBL <>>
+			<SET TBL ,P-PRSI>
+			<SET OBJ <GET ,P-PRSO 1>>
+			.ICNT)
+		       (T 1)>>
+	    <COND (<AND <NOT .OBJ>
+			<1? .ICNT>>
+		   <SET OBJ <GET ,P-PRSI 1>>)>
+	    <COND (<EQUAL? ,PRSA ,V?WALK> <SET V <PERFORM ,PRSA ,PRSO>>)
+		  (<0? .NUM>
+		   <COND (<0? <BAND <GETB ,P-SYNTAX ,P-SBITS> ,P-SONUMS>>
+			  <SET V <PERFORM ,PRSA>>
+			  <SETG PRSO <>>)
+			 (<NOT ,LIT>
+			  <TELL ,TOO-DARK CR>
+			  <FUCKING-CLEAR>)
+			 (T
+			  <TELL "There isn't anything to ">
+			  <SET TMP <GET ,P-ITBL ,P-VERBN>>
+			  <COND (<VERB? TELL>
+				 <TELL "talk to">)
+				(<OR ,P-OFLAG ,P-MERGED>
+				 <PRINTB <GET .TMP 0>>)
+				(T
+				 <WORD-PRINT <GETB .TMP 2>
+					     <GETB .TMP 3>>)>
+			  <TELL "!" CR>
+			  <SET V <>>
+			  <FUCKING-CLEAR>)>)
+		  (T
+		   <SETG P-NOT-HERE 0>
+		   <SETG P-MULT <>>
+		   <COND (<G? .NUM 1> <SETG P-MULT T>)>
+		   <SET TMP <>>
+		   <REPEAT ()
+			   <COND (<G? <SET CNT <+ .CNT 1>> .NUM>
+				  <COND (<G? ,P-NOT-HERE 0>
+					 <TELL "The ">
+					 <COND (<NOT <EQUAL? ,P-NOT-HERE .NUM>>
+						<TELL "other ">)>
+					 <TELL "object">
+					 <COND (<NOT <EQUAL? ,P-NOT-HERE 1>>
+						<TELL "s">)>
+					 <TELL " that you mentioned ">
+					 <COND (<NOT <EQUAL? ,P-NOT-HERE 1>>
+						<TELL "are">)
+					       (T <TELL "is">)>
+					 <TELL "n't here." CR>)
+					(<NOT .TMP>
+					 <TELL ,REFERRING CR>)>
+				  <RETURN>)
+				 (T
+				  <COND (.PTBL <SET OBJ1 <GET ,P-PRSO .CNT>>)
+					(T <SET OBJ1 <GET ,P-PRSI .CNT>>)>
+				  <SETG PRSO <COND (.PTBL .OBJ1) (T .OBJ)>>
+				  <SETG PRSI <COND (.PTBL .OBJ) (T .OBJ1)>>
+				  <COND (<OR <G? .NUM 1>
+					     <EQUAL? <GET <GET ,P-ITBL ,P-NC1>
+							  0>
+						     ,W?ALL>>
+					 <COND (<EQUAL? .OBJ1
+							,NOT-HERE-OBJECT>
+						<SETG P-NOT-HERE
+						      <+ ,P-NOT-HERE 1>>
+						<AGAIN>)
+					       (<AND <EQUAL? ,P-GETFLAGS
+							     ,P-ALL>
+						     <VERB? TAKE PICK-UP>
+						     <OR <AND <NOT <EQUAL?
+							       <LOC .OBJ1>
+							       ,WINNER
+							       ,HERE
+							       ,PRSI>>
+							      <NOT <FSET?
+								  <LOC .OBJ1>
+								 ,SURFACEBIT>>>
+							 <AND <NOT <FSET? .OBJ1
+							             ,TAKEBIT>>
+							     <NOT <FSET? .OBJ1
+							       ,TRYTAKEBIT>>>>>
+						<AGAIN>)
+					       (<AND <VERB? TAKE PICK-UP>
+						     ,PRSI
+						     <NOT <IN? ,PRSO ,PRSI>>>
+						<AGAIN>)
+					       (<AND <EQUAL? ,P-GETFLAGS
+							     ,P-ALL>
+						     <VERB? DROP>
+						      <NOT <IN? .OBJ1 ,WINNER>>
+						      ;"next frob semied by JW"
+						      ;<NOT <IN? ,P-IT-OBJECT
+								,WINNER>>>
+						<AGAIN>)
+					       (<AND <EQUAL? ,P-GETFLAGS
+							     ,P-ALL>
+						     ,PRSI
+						     <==? ,PRSO ,PRSI>>
+						<AGAIN>)
+					       (<AND <EQUAL? ,P-GETFLAGS
+							     ,P-ALL>
+						     <VERB? PUT>
+						     <HELD? ,PRSO ,PRSI>>
+						<AGAIN>)
+					       (<NOT <ACCESSIBLE? .OBJ1>>
+						<AGAIN>)
+					       (T
+						<COND (<EQUAL? .OBJ1 ,IT>
+						       <PRINTD ,P-IT-OBJECT>)
+						      (<TEA-PRINT .OBJ1>
+						       <PRINTD .OBJ1>)>
+					        <COND (<TEA-PRINT .OBJ1>
+						       <TELL ": ">)>)>)>
+				  <SET TMP T>
+				  <SET V <PERFORM ,PRSA ,PRSO ,PRSI>>
+				  <COND (<EQUAL? .V ,M-FATAL> <RETURN>)>)>>)>
+	    <COND (<NOT <EQUAL? .V ,M-FATAL>>
+		   <COND (<VERB? TELL BRIEF SUPER-BRIEF VERBOSE
+				 SAVE VERSION RESTORE SCRIPT UNSCRIPT>
+			  T)
+			 (T
+			  <SET V <APPLY <GETP <LOC ,WINNER> ,P?ACTION>
+					,M-END>>)>)>
+	    <COND (<VERB? AGAIN SAVE RESTORE SCRIPT UNSCRIPT
+			  VERBOSE BRIEF SUPER-BRIEF>
+		   T)
+		  (,P-OFLAG T)
+		  (T
+		   <SETG L-PRSA ,PRSA>
+		   <SETG L-PRSO ,PRSO>
+		   <SETG L-PRSI ,PRSI>)>
+	    <COND (,DONT-FLAG
+		   <SETG L-DONT-FLAG T>)
+		  (T
+		   <SETG L-DONT-FLAG <>>)>
+	    <COND (,IN-FRONT-FLAG
+		   <SETG L-FRONT-FLAG T>)
+		  (T
+		   <SETG L-FRONT-FLAG <>>)>
+	    <COND (<EQUAL? .V ,M-FATAL>
+		   <SETG P-CONT <>>)>)
+	   (T
+	    <SETG P-CONT <>>)>
+     <COND (,P-WON
+	    <COND (<VERB? TELL BRIEF SUPER-BRIEF VERBOSE VERSION QUIT SCORE
+			  SAVE RESTORE SCRIPT UNSCRIPT FOOTNOTE HELP RESTART>
+		   T)
+		  (<AND <VERB? AGAIN>
+			<OR <EQUAL? ,L-PRSA ,V?FIND ,V?FOLLOW ,V?CALL>
+			    <EQUAL? ,L-PRSA ,V?WHAT ,V?WHERE ,V?WAIT-FOR>
+			    <EQUAL? ,L-PRSA ,V?WHO ,V?WALK-TO ,V?WHAT-ABOUT>
+			    <EQUAL? ,L-PRSA ,V?ASK-ABOUT ,V?ASK-FOR ,V?I-AM>
+			    <EQUAL? ,L-PRSA ,V?MY-NAME ,V?CARVE ,V?SCORE>
+			    <EQUAL? ,L-PRSA ,V?VERSION ,V?FOOTNOTE ,V?HELP>>>
+		   T)
+		  (<AND <VERB? WAIT>
+			,DONT-FLAG>
+		   T)
+		  (<AND <VERB? AGAIN>
+			<EQUAL? ,L-PRSA ,V?WAIT>
+			,L-DONT-FLAG>
+		   T)
+		  (T
+		   <SET V <CLOCKER>>)>
+	    <SETG PRSA <>>
+	    <SETG PRSO <>>
+	    <SETG PRSI <>>)
+	   (<AND <G? <GETB ,P-LEXV ,P-LEXWORDS> 3>
+		 <NOT ,CARELESS-WORDS-FLAG>
+		 ,EARTH-DEMOLISHED
+		 <SAVE-INPUT ,FIRST-BUFFER>>
+	    <SETG CARELESS-WORDS-FLAG T>
+	    <ENABLE <QUEUE I-CARELESS-WORDS 3>>)>>>
+
+<GLOBAL FIRST-BUFFER <ITABLE BYTE 100>>
+
+<ROUTINE SAVE-INPUT (TBL "AUX" (OFFS 0) CNT TMP)
+	 <SET CNT <+ <GETB ,P-LEXV <SET TMP <* 4 ,P-INPUT-WORDS>>>
+		     <GETB ,P-LEXV <+ .TMP 1>>>>
+	 <COND (<EQUAL? .CNT 0> ;"failed"
+		<RFALSE>)>
+	 <SET CNT <- .CNT 1>>
+	 <REPEAT ()
+		 <COND (<EQUAL? .OFFS .CNT>
+			<PUTB .TBL .OFFS 0>
+			<RETURN>)
+		       (T
+			<PUTB .TBL .OFFS <GETB ,P-INBUF <+ .OFFS 1>>>)>
+		 <SET OFFS <+ .OFFS 1>>>
+	 <RTRUE>>
+
+<ROUTINE RESTORE-INPUT (TBL "AUX" CHR)
+	 <REPEAT ()
+		 <COND (<EQUAL? <SET CHR <GETB .TBL 0>> 0>
+			<RETURN>)
+		       (T
+			<PRINTC .CHR>
+			<SET TBL <REST .TBL>>)>>>
+
+<GLOBAL L-PRSA <>>  
+
+<GLOBAL L-PRSO <>>  
+
+<GLOBAL L-PRSI <>>  
+
+<GLOBAL L-DONT-FLAG <>>
+
+<GLOBAL L-FRONT-FLAG <>>
+
+<GLOBAL P-MULT <>>
+
+<GLOBAL P-NOT-HERE 0>
+
+
+<ROUTINE FAKE-ORPHAN ("AUX" TMP)
+	 <ORPHAN ,P-SYNTAX <>>
+	 <TELL "Be specific: what object do">
+	 <COND (,DONT-FLAG
+		<TELL "n't">)>
+	 <TELL " you want to ">
+	 <SET TMP <GET ,P-OTBL ,P-VERBN>>
+	 <COND (<EQUAL? .TMP 0>
+		<TELL "tell">)
+	       (<0? <GETB ,P-VTBL 2>>
+		<PRINTB <GET .TMP 0>>)
+	       (T
+		<WORD-PRINT <GETB .TMP 2> <GETB .TMP 3>>
+		<PUTB ,P-VTBL 2 0>)>
+	 <SETG P-OFLAG T>
+	 <SETG P-WON <>>
+	 <PREP-PRINT
+	     <GETB ,P-SYNTAX ,P-SPREP1>>
+	 <TELL "?" CR>>
+
+<ROUTINE PERFORM (A "OPTIONAL" (O <>) (I <>) "AUX" V OA OO OI)
+	;<COND (,DEBUG
+	       <TELL "[Perform: ">
+	       %<COND (<GASSIGNED? PREDGEN> '<TELL N .A>)
+		      (T '<PRINC <NTH ,ACTIONS <+ <* .A 2> 1>>>)>
+	       <COND (<AND .O <NOT <EQUAL? .A ,V?WALK>>>
+		      <TELL " / PRSO = " D .O>)>
+	       <COND (.I <TELL " / PRSI = " D .I>)>
+	       <TELL "]" CR>
+	       <COND (,IN-FRONT-FLAG
+		      <TELL "[IN-FRONT-FLAG is set]" CR>)>)>
+	<SET OA ,PRSA>
+	<SET OO ,PRSO>
+	<SET OI ,PRSI>
+	<SETG PRSA .A>
+	<COND (<EQUAL? ,IT .I .O>
+	       <COND (<NOT .I>
+		      <FAKE-ORPHAN>)
+		     (T
+		      <TELL ,REFERRING CR>)>
+	       <RFATAL>)>
+	<SETG PRSO .O>
+	<COND (<AND ,PRSO
+		    <NOT <VERB? WALK>>
+		    <NOT <PRSO? ,NOT-HERE-OBJECT>>>
+	       <SETG P-IT-OBJECT ,PRSO>)>
+	<SETG PRSI .I>
+	;<COND (<NOT <EQUAL? .A ,V?AGAIN>>
+	       <SETG L-PRSA .A>
+	       <COND (<EQUAL? .A ,V?WALK> <SETG L-PRSO <>>)
+		     (T <SETG L-PRSO .O>)>
+	       <SETG L-PRSI .I>)>
+	<COND (<AND <NOT <EQUAL? .A ,V?WALK>>
+		    <EQUAL? ,NOT-HERE-OBJECT ,PRSO ,PRSI>
+		    <SET V <D-APPLY "Not Here" ,NOT-HERE-OBJECT-F>>>
+	       <SETG P-WON <>>
+	       .V)
+	      (T
+	       <SET O ,PRSO>
+	       <SET I ,PRSI>
+	       <COND (<SET V <D-APPLY "Actor" <GETP ,WINNER ,P?ACTION>>>
+		      .V)
+		     (<AND ,DONT-FLAG <SET V <DONT-F>>>
+		      .V)
+		     (<SET V <D-APPLY "M-Beg" <GETP <LOC ,WINNER> ,P?ACTION>
+				      ,M-BEG>>
+		      .V)
+		     (<SET V <D-APPLY "Preaction" <GET ,PREACTIONS .A>>>
+		      .V)
+		     (<AND .I <SET V <D-APPLY "PRSI" <GETP .I ,P?ACTION>>>>
+		      .V)
+		     ;(<AND .O
+			   <NOT <EQUAL? .A ,V?WALK>>
+			   <LOC .O>
+			   <GETP <LOC .O> ,P?CONTFCN>
+			   <SET V <D-APPLY "Cont" <GETP <LOC .O> ,P?CONTFCN>>>>
+		      .V) 
+		     (<AND .O
+			   <NOT <EQUAL? .A ,V?WALK>>
+			   <SET V <D-APPLY "PRSO" <GETP .O ,P?ACTION>>>>
+		      .V)
+		     (<SET V <D-APPLY <> <GET ,ACTIONS .A>>>
+		      .V)>)>
+	<SETG PRSA .OA>
+	<SETG PRSO .OO>
+	<SETG PRSI .OI>
+	.V>
+
+<ROUTINE D-APPLY (STR FCN "OPTIONAL" (FOO <>) "AUX" RES)
+	<COND (<NOT .FCN> <>)
+	      (T
+	       ;<COND (,DEBUG
+		      <COND (<NOT .STR>
+			     <TELL CR "  Default ->" CR>)
+			    (T <TELL CR "  " .STR " -> ">)>)>
+	       <SET RES
+		    <COND (.FOO <APPLY .FCN .FOO>)
+			  (T <APPLY .FCN>)>>
+	       ;<COND (<AND ,DEBUG .STR>
+		      <COND (<EQUAL? .RES ,M-FATAL>
+			     <TELL "Fatal" CR>)
+			    (<NOT .RES>
+			     <TELL "Not handled">)
+			    (T <TELL "Handled" CR>)>)>
+	       .RES)>>
+
+
+;"former CLOCK.ZIL stuff"
+
+<GLOBAL CLOCK-WAIT <>>
+
+<GLOBAL C-TABLE %<COND (<GASSIGNED? PREDGEN>
+			'<ITABLE NONE 105>)
+		       (T
+			'<ITABLE NONE 210>)>>
+
+<CONSTANT C-TABLELEN 210>
+
+<GLOBAL C-INTS 210>
+
+<CONSTANT C-INTLEN 6>
+
+<CONSTANT C-ENABLED? 0>
+
+<CONSTANT C-TICK 1>
+
+<CONSTANT C-RTN 2>
+
+<ROUTINE QUEUE (RTN TICK "AUX" CINT)
+	 <PUT <SET CINT <INT .RTN>> ,C-TICK .TICK>
+	 .CINT>
+
+<ROUTINE INT (RTN "OPTIONAL" E C INT)
+	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
+	 <SET C <REST ,C-TABLE ,C-INTS>>
+	 <REPEAT ()
+		 <COND (<EQUAL? .C .E>
+			<SETG C-INTS <- ,C-INTS ,C-INTLEN>>
+			<SET INT <REST ,C-TABLE ,C-INTS>>
+			<PUT .INT ,C-RTN .RTN>
+			<RETURN .INT>)
+		       (<EQUAL? <GET .C ,C-RTN> .RTN> <RETURN .C>)>
+		 <SET C <REST .C ,C-INTLEN>>>>
+
+<ROUTINE CLOCKER ("AUX" C E TICK (FLG <>))
+	 <COND (,CLOCK-WAIT <SETG CLOCK-WAIT <>> <RFALSE>)>
+	 <SET C <REST ,C-TABLE <COND (,P-WON ,C-INTS)>>>
+	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
+	 <REPEAT ()
+		 <COND (<EQUAL? .C .E>
+			<SETG MOVES <+ ,MOVES 1>>
+			<RETURN .FLG>)
+		       (<NOT <0? <GET .C ,C-ENABLED?>>>
+			<SET TICK <GET .C ,C-TICK>>
+			<COND (<0? .TICK>)
+			      (T
+			       <PUT .C ,C-TICK <- .TICK 1>>
+			       <COND (<AND <NOT <G? .TICK 1>>
+					   <APPLY <GET .C ,C-RTN>>>
+				      <SET FLG T>)>)>)>
+		 <SET C <REST .C ,C-INTLEN>>>>
\ No newline at end of file
diff --git a/parser.zil b/parser.zil
new file mode 100644
index 0000000..afe9bbd
--- /dev/null
+++ b/parser.zil
@@ -0,0 +1,1393 @@
+"PARSER for
+		  THE HITCHHIKER'S GUIDE TO THE GALAXY
+	 (c) Copyright 1984 Infocom, Inc.  All Rights Reserved"
+
+;"Parser global variable convention:  All parser globals will begin
+with 'P-'. Local variables are not restricted in any way." 
+
+<SETG SIBREAKS ".,\"">
+
+<GLOBAL P-AND <>>
+
+<GLOBAL IN-FRONT-FLAG <>> 
+
+<GLOBAL PRSA <>>
+
+<GLOBAL PRSI <>>
+
+<GLOBAL PRSO <>>
+
+<GLOBAL P-TABLE 0>  
+
+<GLOBAL P-ONEOBJ 0> 
+
+<GLOBAL P-SYNTAX 0> 
+
+<GLOBAL P-CCTBL <TABLE 0 0 0 0>>  
+
+;"pointers used by CLAUSE-COPY (source/destination beginning/end pointers)"
+<CONSTANT CC-SBPTR 0>
+<CONSTANT CC-SEPTR 1>
+<CONSTANT CC-DBPTR 2>
+<CONSTANT CC-DEPTR 3>
+
+<GLOBAL P-LEN 0>
+
+<GLOBAL WINNER 0>   
+
+<GLOBAL P-LEXV <ITABLE BYTE 120>>
+
+<GLOBAL P-INBUF <ITABLE BYTE 60>> ;"INBUF - Input buffer for READ"
+
+<GLOBAL P-CONT <>> ;"Parse-cont variable"  
+
+<GLOBAL P-IT-OBJECT <>>
+
+<GLOBAL LAST-PSEUDO-LOC <>>
+
+<GLOBAL P-OFLAG <>> ;"Orphan flag" 
+
+<GLOBAL P-MERGED <>>
+
+<GLOBAL P-ACLAUSE <>>    
+
+<GLOBAL P-ANAM <>>  
+
+<GLOBAL P-AADJ <>>
+
+;"Parser variables and temporaries"
+
+<CONSTANT P-LEXWORDS 1> ;"Byte offset to # of entries in LEXV"
+<CONSTANT P-LEXSTART 1> ;"Word offset to start of LEXV entries"
+<CONSTANT P-LEXELEN 2> ;"Number of words per LEXV entry"
+<CONSTANT P-WORDLEN 4>
+<CONSTANT P-PSOFF 4> ;"Offset to parts of speech byte"
+<CONSTANT P-P1OFF 5> ;"Offset to first part of speech"
+<CONSTANT P-P1BITS 3> ;"First part of speech bit mask in PSOFF byte"
+<CONSTANT P-ITBLLEN 9>
+
+<GLOBAL P-ITBL
+	<TABLE 0 0 0 0 0 0 0 0 0 0>>  
+
+<GLOBAL P-OTBL
+	<TABLE 0 0 0 0 0 0 0 0 0 0>>  
+
+<GLOBAL P-VTBL
+	<TABLE 0 0 0 0>>
+
+<GLOBAL P-OVTBL
+	<TABLE 0 0 0 0>>
+
+<GLOBAL P-NCN 0>    
+
+<CONSTANT P-VERB 0> 
+
+<CONSTANT P-VERBN 1>
+
+<CONSTANT P-PREP1 2>
+
+<CONSTANT P-PREP1N 3>    
+
+<CONSTANT P-PREP2 4>    
+
+<CONSTANT P-NC1 6>  
+
+<CONSTANT P-NC1L 7> 
+
+<CONSTANT P-NC2 8>  
+
+<CONSTANT P-NC2L 9> 
+
+<GLOBAL QUOTE-FLAG <>>
+
+<GLOBAL P-INPUT-WORDS <>>
+
+<GLOBAL P-END-ON-PREP <>>
+
+" Grovel down the input finding the verb, prepositions, and noun clauses.
+   If the input is <direction> or <walk> <direction>, fall out immediately
+   setting PRSA to ,V?WALK and PRSO to <direction>.  Otherwise, perform
+   all required orphaning, syntax checking, and noun clause lookup."   
+
+<ROUTINE PARSER ("AUX" (PTR ,P-LEXSTART) WRD (VAL 0) (VERB <>) (DONT <>)
+		       LEN (DIR <>) (NW 0) (LW 0) NUM SCNT (CNT -1)) 
+	<REPEAT ()
+		<COND (<G? <SET CNT <+ .CNT 1>> ,P-ITBLLEN> <RETURN>)
+		      (T <PUT ,P-ITBL .CNT 0>)>>
+	<SETG IN-FRONT-FLAG <>>
+	<SETG P-ADVERB <>>
+	<SETG P-MERGED <>>
+	<SETG P-END-ON-PREP <>>
+	<PUT ,P-PRSO ,P-MATCHLEN 0>
+	<PUT ,P-PRSI ,P-MATCHLEN 0>
+	<PUT ,P-BUTS ,P-MATCHLEN 0>
+	<COND (<AND <NOT ,QUOTE-FLAG> <N==? ,WINNER ,PLAYER>>
+	       <SETG WINNER ,PLAYER>
+	       <COND (<NOT <FSET? <LOC ,WINNER> ,VEHBIT>>
+		      <SETG HERE <LOC ,WINNER>>)>
+	       <SETG LIT <LIT? ,HERE>>)>
+	<COND (,P-CONT
+	       <SET PTR ,P-CONT>
+	       <COND (<AND <EQUAL? ,VERBOSITY 1 2>
+			   <==? ,PLAYER ,WINNER>>
+		      <CRLF>)>
+	       <SETG P-CONT <>>)
+	      (T
+	       <SETG WINNER ,PLAYER>
+	       <SETG QUOTE-FLAG <>>
+	       <COND (<NOT <FSET? <LOC ,WINNER> ,VEHBIT>>
+		      <SETG HERE <LOC ,WINNER>>)>
+	       <SETG LIT <LIT? ,HERE>>
+	       <COND (<EQUAL? ,VERBOSITY 1 2>
+		      <CRLF>)>
+	       <TELL ">">
+	       <READ ,P-INBUF ,P-LEXV>
+	       <SETG P-INPUT-WORDS <GETB ,P-LEXV ,P-LEXWORDS>>)>
+	<SETG P-LEN <GETB ,P-LEXV ,P-LEXWORDS>>
+	<COND (<0? ,P-LEN>
+	       <TELL "I beg your pardon?" CR>
+	       <RFALSE>)>
+	<SET LEN ,P-LEN>
+	;<SETG P-DIR <>>
+	<SETG P-NCN 0>
+	<SETG P-GETFLAGS 0>
+	<REPEAT ()
+		<COND (<L? <SETG P-LEN <- ,P-LEN 1>> 0>
+		       <SETG QUOTE-FLAG <>>
+		       <RETURN>)
+		      (<OR <SET WRD <GET ,P-LEXV .PTR>>
+			   <SET WRD <NUMBER? .PTR>>>
+		       <COND (<AND <==? .WRD ,W?TO>
+				   <EQUAL? .VERB ,ACT?TELL ,ACT?ASK>
+				   ;"next clause added 8/20/84 by JW to
+				     enable TELL MY NAME TO BEAST"
+				   <WT? <GET ,P-LEXV <+ .PTR ,P-LEXELEN>>
+					,PS?VERB ,P1?VERB>>
+			      <PUT ,P-ITBL ,P-VERB ,ACT?TELL>
+			      <SET WRD ,W?QUOTE>)
+			     (<AND <==? .WRD ,W?THEN>
+				   <NOT .VERB>
+				   <NOT ,QUOTE-FLAG>>
+			      <PUT ,P-ITBL ,P-VERB ,ACT?TELL>
+			      <PUT ,P-ITBL ,P-VERBN 0>
+			      <SET WRD ,W?QUOTE>)>
+		       <COND (<AND <EQUAL? .WRD ,W?PERIOD>
+				   <EQUAL? .LW ,W?MR>>
+			      <SET LW 0>)
+			     (<OR <EQUAL? .WRD ,W?THEN ,W?PERIOD>
+				  <EQUAL? .WRD ,W?QUOTE>> 
+			      <COND (<EQUAL? .WRD ,W?QUOTE>
+				     <COND ;"Following clause added 8/7/84
+					     for CARVE 'FOO' IN BAR"
+				           (<EQUAL? .VERB ,ACT?CARVE ,ACT?MY>
+					    <PUT ,P-LEXV .PTR ,W?THE>
+					    <SETG P-LEN <+ ,P-LEN 1>>
+					    <AGAIN>)
+					   (,QUOTE-FLAG
+					    <SETG QUOTE-FLAG <>>)
+					   (T <SETG QUOTE-FLAG T>)>)>
+			      <OR <0? ,P-LEN>
+				  <SETG P-CONT <+ .PTR ,P-LEXELEN>>>
+			      <PUTB ,P-LEXV ,P-LEXWORDS ,P-LEN>
+			      <RETURN>)
+			     (<AND <SET VAL
+					<WT? .WRD ,PS?DIRECTION ,P1?DIRECTION>>
+				   <EQUAL? .VERB <> ,ACT?WALK>
+				   <OR <==? .LEN 1>
+				       <AND <==? .LEN 2>
+					    <EQUAL? .VERB ,ACT?WALK ;,ACT?FLY>>
+				       <AND <EQUAL? <SET NW
+						     <GET ,P-LEXV
+							  <+ .PTR ,P-LEXELEN>>>
+					            ,W?THEN
+					            ,W?PERIOD
+					            ,W?QUOTE>
+					    <NOT <L? .LEN 2>>>
+				       <AND ,QUOTE-FLAG
+					    <==? .LEN 2>
+					    <EQUAL? .NW ,W?QUOTE>>
+				       <AND <G? .LEN 2>
+					    <EQUAL? .NW ,W?COMMA ,W?AND>>>>
+			      <SET DIR .VAL>
+			      <COND (<EQUAL? .NW ,W?COMMA ,W?AND>
+				     <PUT ,P-LEXV
+					  <+ .PTR ,P-LEXELEN>
+					  ,W?THEN>)>
+			      <COND (<NOT <G? .LEN 2>>
+				     <SETG QUOTE-FLAG <>>
+				     <RETURN>)>)
+			     (<AND <SET VAL <WT? .WRD ,PS?VERB ,P1?VERB>>
+				   <NOT .VERB>>
+			      <SET VERB .VAL>
+			      <PUT ,P-ITBL ,P-VERB .VAL>
+			      <PUT ,P-ITBL ,P-VERBN ,P-VTBL>
+			      <PUT ,P-VTBL 0 .WRD>
+			      <PUTB ,P-VTBL 2 <GETB ,P-LEXV
+						    <SET NUM
+							 <+ <* .PTR 2> 2>>>>
+			      <PUTB ,P-VTBL 3 <GETB ,P-LEXV <+ .NUM 1>>>)
+			     (<OR <SET VAL <WT? .WRD ,PS?PREPOSITION 0>>
+				  <AND <OR <EQUAL? .WRD ,W?ALL ,W?ONE ,W?BOTH>
+					   <WT? .WRD ,PS?ADJECTIVE>
+					   <WT? .WRD ,PS?OBJECT>>
+				       <SET VAL 0>>>
+			      <COND (<AND <G? ,P-LEN 0>
+				      <EQUAL? <GET ,P-LEXV <+ .PTR ,P-LEXELEN>>
+					      ,W?OF>
+				      <0? .VAL>
+				      <NOT <EQUAL? .WRD ,W?ALL ,W?ONE ,W?A>>
+				      <NOT <EQUAL? .WRD ,W?BOTH>>>)
+				    (<AND <NOT <0? .VAL>>
+				          <OR <0? ,P-LEN>
+					      <EQUAL? <GET ,P-LEXV <+ .PTR 2>>
+						      ,W?THEN ,W?PERIOD>>>
+				     <SETG P-END-ON-PREP T>
+				     <COND (<L? ,P-NCN 2>
+					    <PUT ,P-ITBL ,P-PREP1 .VAL>
+					    <PUT ,P-ITBL ,P-PREP1N .WRD>)>)
+				    (<EQUAL? ,P-NCN 2>
+				     <TELL
+"There were too many nouns in that sentence." CR>
+				     <RFALSE>)
+				    (T
+				     <SETG P-NCN <+ ,P-NCN 1>>
+				     ;"This COND added 8/7/84 for IN FRONT OF"
+				     <COND (<AND <EQUAL? .VAL ,PR?IN>
+						 <EQUAL? <GET ,P-LEXV
+							      <+ .PTR 2>>
+							 ,W?FRONT>>
+					    <SETG IN-FRONT-FLAG T>)
+					   (<AND <EQUAL? .VAL ,PR?DOWN>
+						 <EQUAL? <GET ,P-LEXV
+							      <+ .PTR 2>>
+							 ,W?IN>
+						 <EQUAL? <GET ,P-LEXV
+							      <+ .PTR 4>>
+							 ,W?FRONT>>
+					    <SETG IN-FRONT-FLAG T>)>
+				     <OR <SET PTR <CLAUSE .PTR .VAL .WRD>>
+					 <RFALSE>>
+				     <COND (<L? .PTR 0>
+					    <SETG QUOTE-FLAG <>>
+					    <RETURN>)>)>)
+			     (<AND <NOT .VERB>
+				   <EQUAL? .WRD ,W?DON\'T ,W?DONT>>
+			      <SET DONT T>)
+			     (<WT? .WRD ,PS?BUZZ-WORD>)
+			     (<AND <EQUAL? .VERB ,ACT?TELL>
+				   <WT? .WRD ,PS?VERB ,P1?VERB>
+				   ;"Next expr added to fix FORD, TELL ME WHY"
+				   ;"NOT taken out of said expr to fix fix"
+				   <EQUAL? ,WINNER ,PLAYER>>
+			      <TELL
+"Please consult your manual for the correct way to talk to characters." CR>
+			      <RFALSE>)
+			     (T
+			      <CANT-USE .PTR>
+			      <RFALSE>)>)
+		      (T
+		       <UNKNOWN-WORD .PTR>
+		       <RFALSE>)>
+		<SET LW .WRD>
+		<SET PTR <+ .PTR ,P-LEXELEN>>>
+	<COND (.DIR
+	       <SETG PRSA ,V?WALK>
+	       <SETG PRSO .DIR>
+	       <SETG P-OFLAG <>>
+	       <SETG P-WALK-DIR .DIR>
+	       <SETG DONT-FLAG .DONT>
+	       <RETURN T>)>
+	<SETG P-WALK-DIR <>>
+	<COND (<OR <NOT ,P-OFLAG>
+	       	   <NOT <ORPHAN-MERGE>>>
+	       <SETG DONT-FLAG .DONT>)>
+	<COND (<AND <SYNTAX-CHECK>
+		    <SNARF-OBJECTS>
+		    <MANY-CHECK>
+		    <TAKE-CHECK>>
+	       T)>>
+
+<GLOBAL DONT-FLAG <>>
+
+<GLOBAL P-WALK-DIR <>>
+
+;"Check whether word pointed at by PTR is the correct part of speech.
+   The second argument is the part of speech (,PS?<part of speech>).  The
+   3rd argument (,P1?<part of speech>), if given, causes the value
+   for that part of speech to be returned."
+<ROUTINE WT? (PTR BIT "OPTIONAL" (B1 5) "AUX" (OFFS ,P-P1OFF) TYP) 
+	<COND (<BTST <SET TYP <GETB .PTR ,P-PSOFF>> .BIT>
+	       <COND (<G? .B1 4> <RTRUE>)
+		     (T
+		      <SET TYP <BAND .TYP ,P-P1BITS>>
+		      <COND (<NOT <==? .TYP .B1>> <SET OFFS <+ .OFFS 1>>)>
+		      <GETB .PTR .OFFS>)>)>>
+
+;" Scan through a noun clause, leave a pointer to its starting location"
+<ROUTINE CLAUSE (PTR VAL WRD "AUX" OFF NUM (ANDFLG <>) (FIRST?? T) NW (LW 0))
+	<SET OFF <* <- ,P-NCN 1> 2>>
+	<COND (<NOT <==? .VAL 0>>
+	       <PUT ,P-ITBL <SET NUM <+ ,P-PREP1 .OFF>> .VAL>
+	       <PUT ,P-ITBL <+ .NUM 1> .WRD>
+	       <SET PTR <+ .PTR ,P-LEXELEN>>)
+	      (T <SETG P-LEN <+ ,P-LEN 1>>)>
+	<COND (<0? ,P-LEN> <SETG P-NCN <- ,P-NCN 1>> <RETURN -1>)>
+	<PUT ,P-ITBL <SET NUM <+ ,P-NC1 .OFF>> <REST ,P-LEXV <* .PTR 2>>>
+	<COND (<EQUAL? <GET ,P-LEXV .PTR> ,W?THE ,W?A ,W?AN>
+	       <PUT ,P-ITBL .NUM <REST <GET ,P-ITBL .NUM> 4>>)>
+	<REPEAT ()
+		<COND (<L? <SETG P-LEN <- ,P-LEN 1>> 0>
+		       <PUT ,P-ITBL <+ .NUM 1> <REST ,P-LEXV <* .PTR 2>>>
+		       <RETURN -1>)>
+		<COND (<OR <SET WRD <GET ,P-LEXV .PTR>>
+			   <SET WRD <NUMBER? .PTR>>>
+		       <COND (<0? ,P-LEN> <SET NW 0>)
+			     (T <SET NW <GET ,P-LEXV <+ .PTR ,P-LEXELEN>>>)>
+		       <COND (<AND <EQUAL? .WRD ,W?PERIOD>
+				   <EQUAL? .LW ,W?MR>>
+			      <SET LW 0>)
+			     (<EQUAL? .WRD ,W?AND ,W?COMMA> <SET ANDFLG T>)
+			     (<EQUAL? .WRD ,W?ALL ,W?ONE ,W?BOTH>
+			      <COND (<==? .NW ,W?OF>
+				     <SETG P-LEN <- ,P-LEN 1>>
+				     <SET PTR <+ .PTR ,P-LEXELEN>>)>)
+			     (<OR <EQUAL? .WRD ,W?THEN ,W?PERIOD>
+				  <AND <WT? .WRD ,PS?PREPOSITION>
+				       <GET ,P-ITBL ,P-VERB>
+				          ;"ADDED 4/27 FOR TURTLE,UP"
+				       <NOT .FIRST??>>>
+			      <SETG P-LEN <+ ,P-LEN 1>>
+			      <PUT ,P-ITBL
+				   <+ .NUM 1>
+				   <REST ,P-LEXV <* .PTR 2>>>
+			      <RETURN <- .PTR ,P-LEXELEN>>)
+			     ;"This next clause was 2 clauses further down"
+			     ;"This attempts to fix EDDIE, TURN ON COMPUTER"
+			     (<AND .ANDFLG
+				   <EQUAL? <GET ,P-ITBL ,P-VERB> 0>>
+			      <SET PTR <- .PTR 4>>
+			      <PUT ,P-LEXV <+ .PTR 2> ,W?THEN>
+			      <SETG P-LEN <+ ,P-LEN 2>>)
+			     (<WT? .WRD ,PS?OBJECT>
+			      <COND ;"First clause added 1/10/84 to fix
+				      'verb AT synonym OF synonym' bug"
+			            (<AND <G? ,P-LEN 0>
+					  <EQUAL? .NW ,W?OF>
+					  <NOT <EQUAL? .WRD ,W?ALL ,W?ONE>>>
+				     T)
+				    (<AND <WT? .WRD
+					       ,PS?ADJECTIVE
+					       ,P1?ADJECTIVE>
+					  <NOT <==? .NW 0>>
+					  <OR <WT? .NW ,PS?OBJECT>
+					      <WT? .NW ,PS?ADJECTIVE>>>)
+				    (<AND <NOT .ANDFLG>
+					  <NOT <EQUAL? .NW ,W?BUT ,W?EXCEPT>>
+					  <NOT <EQUAL? .NW ,W?AND ,W?COMMA>>>
+				     <PUT ,P-ITBL
+					  <+ .NUM 1>
+					  <REST ,P-LEXV <* <+ .PTR 2> 2>>>
+				     <RETURN .PTR>)
+				    (T <SET ANDFLG <>>)>)
+			     ;"next clause replaced by following on from games
+			       with characters"
+			     ;(<AND <OR ,P-MERGED
+				       ,P-OFLAG
+				       <NOT <EQUAL? <GET ,P-ITBL ,P-VERB> 0>>>
+				   <OR <WT? .WRD ,PS?ADJECTIVE>
+				       <WT? .WRD ,PS?BUZZ-WORD>>>)
+			     (<OR <WT? .WRD ,PS?ADJECTIVE>
+				  <WT? .WRD ,PS?BUZZ-WORD>>)
+			     (<WT? .WRD ,PS?PREPOSITION> T)
+			     (T
+			      <CANT-USE .PTR>
+			      <RFALSE>)>)
+		      (T <UNKNOWN-WORD .PTR> <RFALSE>)>
+		<SET LW .WRD>
+		<SET FIRST?? <>>
+		<SET PTR <+ .PTR ,P-LEXELEN>>>> 
+
+<ROUTINE NUMBER? (PTR "AUX" CNT BPTR CHR (SUM 0) (TIM <>))
+	 <SET CNT <GETB <REST ,P-LEXV <* .PTR 2>> 2>>
+	 <SET BPTR <GETB <REST ,P-LEXV <* .PTR 2>> 3>>
+	 <REPEAT ()
+		 <COND (<L? <SET CNT <- .CNT 1>> 0> <RETURN>)
+		       (T
+			<SET CHR <GETB ,P-INBUF .BPTR>>
+			<COND (<==? .CHR 58>
+			       <SET TIM .SUM>
+			       <SET SUM 0>)
+			      (<G? .SUM 10000> <RFALSE>)
+			      (<AND <L? .CHR 58> <G? .CHR 47>>
+			       <SET SUM <+ <* .SUM 10> <- .CHR 48>>>)
+			      (T <RFALSE>)>
+			<SET BPTR <+ .BPTR 1>>)>>
+	 <PUT ,P-LEXV .PTR ,W?INTNUM>
+	 <COND (<G? .SUM 1000>
+		<RFALSE>)
+	       (.TIM
+		<COND (<L? .TIM 8>
+		       <SET TIM <+ .TIM 12>>)
+		      (<G? .TIM 23>
+		       <RFALSE>)>
+		<SET SUM <+ .SUM <* .TIM 60>>>)>
+	 <SETG P-NUMBER .SUM>
+	 ,W?INTNUM>
+
+<GLOBAL P-NUMBER 0>
+
+
+<ROUTINE ORPHAN-MERGE ("AUX" (CNT -1) TEMP VERB BEG END (ADJ <>) WRD) 
+   <SETG P-OFLAG <>>
+   <COND (<WT? <SET WRD <GET <GET ,P-ITBL ,P-VERBN> 0>>
+	       ,PS?ADJECTIVE ,P1?ADJECTIVE>
+	  <SET ADJ T>)
+	 (<AND <WT? .WRD ,PS?OBJECT ,P1?OBJECT>
+	       <EQUAL? ,P-NCN 0>>
+	  <PUT ,P-ITBL ,P-VERB 0>
+	  <PUT ,P-ITBL ,P-VERBN 0>
+	  <PUT ,P-ITBL ,P-NC1 <REST ,P-LEXV 2>>
+	  <PUT ,P-ITBL ,P-NC1L <REST ,P-LEXV 6>>
+	  <SETG P-NCN 1>)>
+   <COND (<AND <NOT <0? <SET VERB <GET ,P-ITBL ,P-VERB>>>>
+	       <NOT .ADJ>
+	       <NOT <==? .VERB <GET ,P-OTBL ,P-VERB>>>>
+	  <RFALSE>)
+	 (<==? ,P-NCN 2> <RFALSE>)
+	 (<==? <GET ,P-OTBL ,P-NC1> 1>
+	  <COND (<OR <==? <SET TEMP <GET ,P-ITBL ,P-PREP1>>
+			  <GET ,P-OTBL ,P-PREP1>>
+		     <0? .TEMP>>
+		 <COND (.ADJ
+			<PUT ,P-OTBL ,P-NC1 <REST ,P-LEXV 2>>
+			<COND (<0? <GET ,P-ITBL ,P-NC1L>>
+			       <PUT ,P-ITBL ,P-NC1L <REST ,P-LEXV 6>>)>
+			<COND (<0? ,P-NCN> <SETG P-NCN 1>)>)
+		       (T
+			<PUT ,P-OTBL ,P-NC1 <GET ,P-ITBL ,P-NC1>>
+			;<PUT ,P-OTBL ,P-NC1L <GET ,P-ITBL ,P-NC1L>>)>
+		 <PUT ,P-OTBL ,P-NC1L <GET ,P-ITBL ,P-NC1L>>)
+		(T <RFALSE>)>)
+	 (<==? <GET ,P-OTBL ,P-NC2> 1>
+	  <COND (<OR <==? <SET TEMP <GET ,P-ITBL ,P-PREP1>>
+			  <GET ,P-OTBL ,P-PREP2>>
+		     <0? .TEMP>>
+		 <COND (.ADJ
+			<PUT ,P-ITBL ,P-NC1 <REST ,P-LEXV 2>>
+			<COND (<0? <GET ,P-ITBL ,P-NC1L>>
+			       <PUT ,P-ITBL ,P-NC1L <REST ,P-LEXV 6>>)>)>
+		 <PUT ,P-OTBL ,P-NC2 <GET ,P-ITBL ,P-NC1>>
+		 <PUT ,P-OTBL ,P-NC2L <GET ,P-ITBL ,P-NC1L>>
+		 <SETG P-NCN 2>)
+		(T <RFALSE>)>)
+	 (,P-ACLAUSE
+	  <COND (<AND <NOT <==? ,P-NCN 1>> <NOT .ADJ>>
+		 <SETG P-ACLAUSE <>>
+		 <RFALSE>)
+		(T
+		 <SET BEG <GET ,P-ITBL ,P-NC1>>
+		 <COND (.ADJ <SET BEG <REST ,P-LEXV 2>> <SET ADJ <>>)>
+		 <SET END <GET ,P-ITBL ,P-NC1L>>
+		 <REPEAT ()
+			 <SET WRD <GET .BEG 0>>
+			 <COND (<==? .BEG .END>
+				<COND (.ADJ <ACLAUSE-WIN .ADJ> <RETURN>)
+				      (T <SETG P-ACLAUSE <>> <RFALSE>)>)
+			       (<AND <NOT .ADJ>
+				     <OR <BTST <GETB .WRD ,P-PSOFF>
+					       ,PS?ADJECTIVE> ;"same as WT?"
+					 <EQUAL? .WRD ,W?ALL ,W?ONE>>>
+				<SET ADJ .WRD>)
+			       (<==? .WRD ,W?ONE>
+				<ACLAUSE-WIN .ADJ>
+				<RETURN>)
+			       (<BTST <GETB .WRD ,P-PSOFF> ,PS?OBJECT>
+				<COND (<EQUAL? .WRD ,P-ANAM>
+				       <ACLAUSE-WIN .ADJ>)
+				      (T
+				       <NCLAUSE-WIN>)>
+				<RETURN>)>
+			 <SET BEG <REST .BEG ,P-WORDLEN>>
+			 <COND (<EQUAL? .END 0>
+				<SET END .BEG>
+				<SETG P-NCN 1>
+				<PUT ,P-ITBL ,P-NC1 <BACK .BEG 4>>
+				<PUT ,P-ITBL ,P-NC1L .BEG>)>>)>)>
+   <PUT ,P-VTBL 0 <GET ,P-OVTBL 0>>
+   <PUTB ,P-VTBL 2 <GETB ,P-OVTBL 2>>
+   <PUTB ,P-VTBL 3 <GETB ,P-OVTBL 3>>
+   <PUT ,P-OTBL ,P-VERBN ,P-VTBL>
+   <PUTB ,P-VTBL 2 0>
+   ;<AND <NOT <==? <GET ,P-OTBL ,P-NC2> 0>> <SETG P-NCN 2>>
+   <REPEAT ()
+	   <COND (<G? <SET CNT <+ .CNT 1>> ,P-ITBLLEN>
+		  <SETG P-MERGED T>
+		  <RTRUE>)
+		 (T <PUT ,P-ITBL .CNT <GET ,P-OTBL .CNT>>)>>
+   T>
+
+<ROUTINE ACLAUSE-WIN (ADJ) 
+	<PUT ,P-ITBL ,P-VERB <GET ,P-OTBL ,P-VERB>>
+	<COND (<EQUAL? .ADJ ,W?TEA> ;"special case"
+	       <NCLAUSE-WIN>)
+	      (T
+	       <PUT ,P-CCTBL ,CC-SBPTR ,P-ACLAUSE>
+	       <PUT ,P-CCTBL ,CC-SEPTR <+ ,P-ACLAUSE 1>>
+	       <PUT ,P-CCTBL ,CC-DBPTR ,P-ACLAUSE>
+	       <PUT ,P-CCTBL ,CC-DEPTR <+ ,P-ACLAUSE 1>>
+	       <CLAUSE-COPY ,P-OTBL ,P-OTBL .ADJ>)>
+	<AND <NOT <==? <GET ,P-OTBL ,P-NC2> 0>> <SETG P-NCN 2>>
+	<SETG P-ACLAUSE <>>
+	<RTRUE>>
+
+<ROUTINE NCLAUSE-WIN ()
+        <PUT ,P-CCTBL ,CC-SBPTR ,P-NC1>
+	<PUT ,P-CCTBL ,CC-SEPTR ,P-NC1L>
+	<PUT ,P-CCTBL ,CC-DBPTR ,P-ACLAUSE>
+	<PUT ,P-CCTBL ,CC-DEPTR <+ ,P-ACLAUSE 1>>
+	<CLAUSE-COPY ,P-ITBL ,P-OTBL>
+	<AND <NOT <==? <GET ,P-OTBL ,P-NC2> 0>> <SETG P-NCN 2>>
+	<SETG P-ACLAUSE <>>
+	<RTRUE>>
+
+;"Print undefined word in input.
+   PTR points to the unknown word in P-LEXV"   
+
+<ROUTINE WORD-PRINT (CNT BUF)
+	 <REPEAT ()
+		 <COND (<DLESS? CNT 0> <RETURN>)
+		       (ELSE
+			<PRINTC <GETB ,P-INBUF .BUF>>
+			<SET BUF <+ .BUF 1>>)>>>
+
+<ROUTINE UNKNOWN-WORD (PTR "AUX" BUF)
+	<TELL "I don't know the word \"">
+	<WORD-PRINT <GETB <REST ,P-LEXV <SET BUF <* .PTR 2>>> 2>
+		    <GETB <REST ,P-LEXV .BUF> 3>>
+	<TELL "\"." CR>
+	<SETG QUOTE-FLAG <>>
+	<SETG P-OFLAG <>>>
+
+<ROUTINE CANT-USE (PTR "AUX" BUF)
+	<TELL "You used the word \"">
+	<WORD-PRINT <GETB <REST ,P-LEXV <SET BUF <* .PTR 2>>> 2>
+		    <GETB <REST ,P-LEXV .BUF> 3>>
+	<TELL "\" in a way that I don't understand." CR>
+	<SETG QUOTE-FLAG <>>
+	<SETG P-OFLAG <>>>
+
+;" Perform syntax matching operations, using P-ITBL as the source of
+   the verb and adjectives for this input.  Returns false if no
+   syntax matches, and does it's own orphaning.  If return is true,
+   the syntax is saved in P-SYNTAX."
+
+<GLOBAL P-SLOCBITS 0>
+
+<CONSTANT P-SYNLEN 8>
+
+<CONSTANT P-SBITS 0>
+
+<CONSTANT P-SPREP1 1>
+
+<CONSTANT P-SPREP2 2>
+
+<CONSTANT P-SFWIM1 3>
+
+<CONSTANT P-SFWIM2 4>
+
+<CONSTANT P-SLOC1 5>
+
+<CONSTANT P-SLOC2 6>
+
+<CONSTANT P-SACTION 7>
+
+<CONSTANT P-SONUMS 3>
+    
+
+<ROUTINE SYNTAX-CHECK
+	("AUX" SYN LEN NUM OBJ (DRIVE1 <>) (DRIVE2 <>) PREP VERB TMP)
+	<COND (<0? <SET VERB <GET ,P-ITBL ,P-VERB>>>
+	       <TELL "There was no verb in that sentence!" CR>
+	       <RFALSE>)>
+	<SET SYN <GET ,VERBS <- 255 .VERB>>>
+	<SET LEN <GETB .SYN 0>>
+	<SET SYN <REST .SYN>>
+	<REPEAT ()
+		<SET NUM <BAND <GETB .SYN ,P-SBITS> ,P-SONUMS>>
+		<COND (<G? ,P-NCN .NUM> T)
+		      (<AND <NOT <L? .NUM 1>>
+			    <0? ,P-NCN>
+			    <OR <0? <SET PREP <GET ,P-ITBL ,P-PREP1>>>
+				<==? .PREP <GETB .SYN ,P-SPREP1>>>>
+		       <SET DRIVE1 .SYN>)
+		      (<==? <GETB .SYN ,P-SPREP1> <GET ,P-ITBL ,P-PREP1>>
+		       <COND (<AND <==? .NUM 2> <==? ,P-NCN 1>>
+			      <SET DRIVE2 .SYN>)
+			     (<EQUAL? <GETB .SYN ,P-SPREP2>
+				      <GET ,P-ITBL ,P-PREP2>>
+			      <SYNTAX-FOUND .SYN>
+			      <RTRUE>)>)>
+		<COND (<DLESS? LEN 1>
+		       <COND (<OR .DRIVE1 .DRIVE2> <RETURN>)
+			     (T
+			      <V-TELL-TIME>
+			      <RFALSE>)>)
+		      (T <SET SYN <REST .SYN ,P-SYNLEN>>)>>
+	<COND (<AND .DRIVE1
+		    <SET OBJ
+			 <GWIM <GETB .DRIVE1 ,P-SFWIM1>
+			       <GETB .DRIVE1 ,P-SLOC1>
+			       <GETB .DRIVE1 ,P-SPREP1>>>>
+	       <PUT ,P-PRSO ,P-MATCHLEN 1>
+	       <PUT ,P-PRSO 1 .OBJ>
+	       <SYNTAX-FOUND .DRIVE1>)
+	      (<AND .DRIVE2
+		    <SET OBJ
+			 <GWIM <GETB .DRIVE2 ,P-SFWIM2>
+			       <GETB .DRIVE2 ,P-SLOC2>
+			       <GETB .DRIVE2 ,P-SPREP2>>>>
+	       <PUT ,P-PRSI ,P-MATCHLEN 1>
+	       <PUT ,P-PRSI 1 .OBJ>
+	       <SYNTAX-FOUND .DRIVE2>)
+	      (<EQUAL? .VERB ,ACT?FIND ;,ACT?WHAT>
+	       <TELL "I can't answer that question." CR>
+	       <RFALSE>)
+	      (<NOT <==? ,WINNER ,PROTAGONIST>>
+	       <CANT-ORPHAN>)
+	      (T
+	       <ORPHAN .DRIVE1 .DRIVE2>
+	       <TELL "What do">
+	       <COND (,DONT-FLAG
+		      <TELL "n't">)>
+	       <TELL " you want to ">
+	       <SET TMP <GET ,P-OTBL ,P-VERBN>>
+	       <COND (<EQUAL? .TMP 0>
+		      <TELL "tell">)
+		     (<0? <GETB ,P-VTBL 2>>
+		      <PRINTB <GET .TMP 0>>)
+		     (T
+		      <WORD-PRINT <GETB .TMP 2> <GETB .TMP 3>>
+		      <PUTB ,P-VTBL 2 0>)>
+	       <COND (.DRIVE2
+		      <CLAUSE-PRINT ,P-NC1 ,P-NC1L>)>
+	       <SETG P-OFLAG T>
+	       <PREP-PRINT <COND (.DRIVE1 <GETB .DRIVE1 ,P-SPREP1>)
+				 (T <GETB .DRIVE2 ,P-SPREP2>)>>
+	       <TELL "?" CR>
+	       <RFALSE>)>> 
+
+<ROUTINE CANT-ORPHAN ()
+	 <COND (<AND <EQUAL? ,WINNER ,GUARDS>
+		     <EQUAL? ,HERE ,DAIS>>
+		<TELL "\"We">)
+	       (T
+		<TELL "\"I">)>
+	 <TELL " don't understand! What are you referring to?\"" CR>
+	 <RFALSE>>
+
+<ROUTINE ORPHAN (D1 D2 "AUX" (CNT -1))
+	<COND (<NOT ,P-MERGED>
+	       <PUT ,P-OCLAUSE ,P-MATCHLEN 0>)>
+	<PUT ,P-OVTBL 0 <GET ,P-VTBL 0>>
+	<PUTB ,P-OVTBL 2 <GETB ,P-VTBL 2>>
+	<PUTB ,P-OVTBL 3 <GETB ,P-VTBL 3>>
+	<REPEAT ()
+		<COND (<IGRTR? CNT ,P-ITBLLEN> <RETURN>)
+		      (T <PUT ,P-OTBL .CNT <GET ,P-ITBL .CNT>>)>>
+	<COND (<==? ,P-NCN 2>
+	       <PUT ,P-CCTBL ,CC-SBPTR ,P-NC2>
+	       <PUT ,P-CCTBL ,CC-SEPTR ,P-NC2L>
+	       <PUT ,P-CCTBL ,CC-DBPTR ,P-NC2>
+	       <PUT ,P-CCTBL ,CC-DEPTR ,P-NC2L>
+	       <CLAUSE-COPY ,P-ITBL ,P-OTBL>)>
+	<COND (<NOT <L? ,P-NCN 1>>
+	       <PUT ,P-CCTBL ,CC-SBPTR ,P-NC1>
+	       <PUT ,P-CCTBL ,CC-SEPTR ,P-NC1L>
+	       <PUT ,P-CCTBL ,CC-DBPTR ,P-NC1>
+	       <PUT ,P-CCTBL ,CC-DEPTR ,P-NC1L>
+	       <CLAUSE-COPY ,P-ITBL ,P-OTBL>)>
+	<COND (.D1
+	       <PUT ,P-OTBL ,P-PREP1 <GETB .D1 ,P-SPREP1>>
+	       <PUT ,P-OTBL ,P-NC1 1>)
+	      (.D2
+	       <PUT ,P-OTBL ,P-PREP2 <GETB .D2 ,P-SPREP2>>
+	       <PUT ,P-OTBL ,P-NC2 1>)>> 
+ 
+<ROUTINE CLAUSE-PRINT (BPTR EPTR "OPTIONAL" (THE? T)) 
+	<BUFFER-PRINT <GET ,P-ITBL .BPTR> <GET ,P-ITBL .EPTR> .THE?>>    
+ 
+<ROUTINE BUFFER-PRINT (BEG END CP "AUX" (NOSP <>) WRD (FIRST?? T) (PN <>))
+	 <REPEAT ()
+		<COND (<EQUAL? .BEG .END>
+		       <RETURN>)
+		      (T
+		       <COND (.NOSP
+			      <SET NOSP <>>)
+			     (T
+			      <TELL " ">)>
+		       <COND (<EQUAL? <SET WRD <GET .BEG 0>> ,W?PERIOD>
+			      <SET NOSP T>)
+			     (<EQUAL? .WRD ,W?ME>
+			      <PRINTD ,ME>
+			      <SET PN T>)
+			     (<NAME? .WRD>
+			      <CAPITALIZE .BEG>
+			      <SET PN T>)
+			     (T
+			      <COND (<AND .FIRST?? <NOT .PN> .CP>
+				     <TELL "the ">)>
+			      <COND (<OR ,P-OFLAG ,P-MERGED> <PRINTB .WRD>)
+				    (<AND <==? .WRD ,W?IT>
+					  <ACCESSIBLE? ,P-IT-OBJECT>>
+				     <PRINTD ,P-IT-OBJECT>)
+				    (T
+				     <WORD-PRINT <GETB .BEG 2>
+						 <GETB .BEG 3>>)>
+			      <SET FIRST?? <>>)>)>
+		<SET BEG <REST .BEG ,P-WORDLEN>>>>
+
+<ROUTINE NAME? (WRD)
+	 <COND (<OR <EQUAL? .WRD ,W?FORD ,W?ZAPHOD ,W?BEEBLE>
+		    <EQUAL? .WRD ,W?TRILLI ,W?TRICIA ,W?MCMILL>
+		    <EQUAL? .WRD ,W?PROSSE ,W?MARVIN ,W?ARTHUR>
+		    <EQUAL? .WRD ,W?DENT ,W?PREFEC ,W?PHIL>
+		    <EQUAL? .WRD ,W?EDDIE ,W?MARV ,W?ED>>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE CAPITALIZE (PTR)
+	 <COND (<OR ,P-OFLAG ,P-MERGED>
+		<PRINTB <GET .PTR 0>>)
+	       (T
+		<PRINTC <- <GETB ,P-INBUF <GETB .PTR 3>> 32>>
+		<WORD-PRINT <- <GETB .PTR 2> 1> <+ <GETB .PTR 3> 1>>)>>
+
+<ROUTINE PREP-PRINT (PREP "AUX" WRD)
+	<COND (<NOT <0? .PREP>>
+	       <TELL " ">
+	       <COND (<EQUAL? .PREP ,PR?THROUGH>
+		      <TELL "through">)
+		     (T
+		      <SET WRD <PREP-FIND .PREP>>
+		      <PRINTB .WRD>)>)>>    
+ 
+<ROUTINE CLAUSE-COPY (SRC DEST "OPTIONAL" (INSRT <>) "AUX" BEG END)
+	<SET BEG <GET .SRC <GET ,P-CCTBL ,CC-SBPTR>>>
+	<SET END <GET .SRC <GET ,P-CCTBL ,CC-SEPTR>>>
+	<PUT .DEST
+	     <GET ,P-CCTBL ,CC-DBPTR>
+	     <REST ,P-OCLAUSE
+		   <+ <* <GET ,P-OCLAUSE ,P-MATCHLEN> ,P-LEXELEN> 2>>>
+	<REPEAT ()
+		<COND (<==? .BEG .END>
+		       <PUT .DEST
+			    <GET ,P-CCTBL ,CC-DEPTR>
+			    <REST ,P-OCLAUSE
+				  <+ <* <GET ,P-OCLAUSE ,P-MATCHLEN> ,P-LEXELEN>
+				     2>>>
+		       <RETURN>)
+		      (T
+		       <COND (<AND .INSRT <==? ,P-ANAM <GET .BEG 0>>>
+			      <CLAUSE-ADD .INSRT>)>
+		       <CLAUSE-ADD <GET .BEG 0>>)>
+		<SET BEG <REST .BEG ,P-WORDLEN>>>>  
+
+
+<ROUTINE CLAUSE-ADD (WRD "AUX" PTR)
+	<SET PTR <+ <GET ,P-OCLAUSE ,P-MATCHLEN> 2>>
+	<PUT ,P-OCLAUSE <- .PTR 1> .WRD>
+	<PUT ,P-OCLAUSE .PTR 0>
+	<PUT ,P-OCLAUSE ,P-MATCHLEN .PTR>>   
+ 
+<ROUTINE PREP-FIND (PREP "AUX" (CNT 0) SIZE)
+	<SET SIZE <* <GET ,PREPOSITIONS 0> 2>>
+	<REPEAT ()
+		<COND (<IGRTR? CNT .SIZE> <RFALSE>)
+		      (<==? <GET ,PREPOSITIONS .CNT> .PREP>
+		       <RETURN <GET ,PREPOSITIONS <- .CNT 1>>>)>>>  
+ 
+<ROUTINE SYNTAX-FOUND (SYN)
+	<SETG P-SYNTAX .SYN>
+	<SETG PRSA <GETB .SYN ,P-SACTION>>>   
+ 
+<GLOBAL P-GWIMBIT 0>
+ 
+<ROUTINE GWIM (GBIT LBIT PREP "AUX" OBJ)
+	<COND (<==? .GBIT ,RLANDBIT>
+	       <RETURN ,ROOMS>)>
+	<SETG P-GWIMBIT .GBIT>
+	<SETG P-SLOCBITS .LBIT>
+	<PUT ,P-MERGE ,P-MATCHLEN 0>
+	<COND (<GET-OBJECT ,P-MERGE <>>
+	       <SETG P-GWIMBIT 0>
+	       <COND (<==? <GET ,P-MERGE ,P-MATCHLEN> 1>
+		      <SET OBJ <GET ,P-MERGE 1>>
+		      <TELL "(">
+		      <COND (<AND <NOT <0? .PREP>>
+				  <NOT ,P-END-ON-PREP>>
+			     <PRINTB <SET PREP <PREP-FIND .PREP>>>
+			     <COND (<==? .PREP ,W?OUT>
+				    <TELL " of">)>
+			     <COND (<NOT <FSET? .OBJ ,NARTICLEBIT>>
+				    <TELL " the ">)
+				   (T
+				    <TELL " ">)>)>
+		      <TELL D .OBJ ")" CR>
+		      .OBJ)>)
+	      (T <SETG P-GWIMBIT 0> <RFALSE>)>>   
+ 
+<ROUTINE SNARF-OBJECTS ("AUX" PTR)
+	<COND (<NOT <==? <SET PTR <GET ,P-ITBL ,P-NC1>> 0>>
+	       <SETG P-SLOCBITS <GETB ,P-SYNTAX ,P-SLOC1>>
+	       <OR <SNARFEM .PTR <GET ,P-ITBL ,P-NC1L> ,P-PRSO> <RFALSE>>
+	       <OR <0? <GET ,P-BUTS ,P-MATCHLEN>>
+		   <SETG P-PRSO <BUT-MERGE ,P-PRSO>>>)>
+	<COND (<NOT <==? <SET PTR <GET ,P-ITBL ,P-NC2>> 0>>
+	       <SETG P-SLOCBITS <GETB ,P-SYNTAX ,P-SLOC2>>
+	       <OR <SNARFEM .PTR <GET ,P-ITBL ,P-NC2L> ,P-PRSI> <RFALSE>>
+	       <COND (<NOT <0? <GET ,P-BUTS ,P-MATCHLEN>>>
+		      <COND (<==? <GET ,P-PRSI ,P-MATCHLEN> 1>
+			     <SETG P-PRSO <BUT-MERGE ,P-PRSO>>)
+			    (T <SETG P-PRSI <BUT-MERGE ,P-PRSI>>)>)>)>
+	<RTRUE>>  
+
+<ROUTINE BUT-MERGE (TBL "AUX" LEN BUTLEN (CNT 1) (MATCHES 0) OBJ NTBL)
+	<SET LEN <GET .TBL ,P-MATCHLEN>>
+	<PUT ,P-MERGE ,P-MATCHLEN 0>
+	<REPEAT ()
+		<COND (<DLESS? LEN 0> <RETURN>)
+		      (<ZMEMQ <SET OBJ <GET .TBL .CNT>> ,P-BUTS>)
+		      (T
+		       <PUT ,P-MERGE <+ .MATCHES 1> .OBJ>
+		       <SET MATCHES <+ .MATCHES 1>>)>
+		<SET CNT <+ .CNT 1>>>
+	<PUT ,P-MERGE ,P-MATCHLEN .MATCHES>
+	<SET NTBL ,P-MERGE>
+	<SETG P-MERGE .TBL>
+	.NTBL>    
+ 
+<GLOBAL P-NAM <>>   
+ 
+<GLOBAL P-ADJ <>>   
+ 
+<GLOBAL P-ADVERB <>>
+
+<GLOBAL P-ADJN <>>  
+ 
+<GLOBAL P-PRSO <ITABLE NONE 50>>
+
+<GLOBAL P-PRSI <ITABLE NONE 50>>
+
+<GLOBAL P-BUTS <ITABLE NONE 50>>
+
+<GLOBAL P-MERGE <ITABLE NONE 50>>
+
+<GLOBAL P-OCLAUSE <ITABLE NONE 50>>
+ 
+<GLOBAL P-MATCHLEN 0>    
+ 
+<GLOBAL P-GETFLAGS 0>    
+ 
+<CONSTANT P-ALL 1>  
+ 
+<CONSTANT P-ONE 2>  
+ 
+<CONSTANT P-INHIBIT 4>   
+
+<GLOBAL P-CSPTR <>>
+<GLOBAL P-CEPTR <>>
+
+<ROUTINE SNARFEM (PTR EPTR TBL "AUX" (BUT <>) LEN WV WRD NW (WAS-ALL <>))
+   <SETG P-AND <>>
+   <COND (<==? ,P-GETFLAGS ,P-ALL>
+	  <SET WAS-ALL T>)>
+   <SETG P-GETFLAGS 0>
+   <SETG P-CSPTR .PTR>
+   <SETG P-CEPTR .EPTR>
+   <PUT ,P-BUTS ,P-MATCHLEN 0>
+   <PUT .TBL ,P-MATCHLEN 0>
+   <SET WRD <GET .PTR 0>>
+   <REPEAT ()
+	   <COND (<==? .PTR .EPTR>
+		  <SET WV <GET-OBJECT <OR .BUT .TBL>>>
+		  <COND (.WAS-ALL <SETG P-GETFLAGS ,P-ALL>)>
+		  <RETURN .WV>)
+		 (T
+		  <SET NW <GET .PTR ,P-LEXELEN>>
+		  <COND (<EQUAL? .WRD ,W?ALL ,W?BOTH>
+			 <SETG P-GETFLAGS ,P-ALL>
+			 <COND (<==? .NW ,W?OF>
+				<SET PTR <REST .PTR ,P-WORDLEN>>)>)
+			(<EQUAL? .WRD ,W?BUT ,W?EXCEPT>
+			 <OR <GET-OBJECT <OR .BUT .TBL>> <RFALSE>>
+			 <SET BUT ,P-BUTS>
+			 <PUT .BUT ,P-MATCHLEN 0>)
+			(<EQUAL? .WRD ,W?A ,W?ONE>
+			 <COND (<NOT ,P-ADJ>
+				<SETG P-GETFLAGS ,P-ONE>
+				<COND (<==? .NW ,W?OF>
+				       <SET PTR <REST .PTR ,P-WORDLEN>>)>)
+			       (T
+				<SETG P-NAM ,P-ONEOBJ>
+				<OR <GET-OBJECT <OR .BUT .TBL>> <RFALSE>>
+				<AND <0? .NW> <RTRUE>>)>)
+			(<AND <EQUAL? .WRD ,W?AND ,W?COMMA>
+			      <NOT <EQUAL? .NW ,W?AND ,W?COMMA>>>
+			 <SETG P-AND T>
+			 <OR <GET-OBJECT <OR .BUT .TBL>> <RFALSE>>
+			 T)
+			(<WT? .WRD ,PS?BUZZ-WORD>)
+			(<EQUAL? .WRD ,W?AND ,W?COMMA>)
+			(<==? .WRD ,W?OF>
+			 <COND (<0? ,P-GETFLAGS>
+				<SETG P-GETFLAGS ,P-INHIBIT>)>)
+			(<AND <SET WV <WT? .WRD ,PS?ADJECTIVE ,P1?ADJECTIVE>>
+			      <ADJ-CHECK .WRD>
+			      ;"for LOOK AT CUP OF TEA"
+			      <OR <NOT <EQUAL? .WRD ,W?TEA>>
+				  <NOT <EQUAL? ,P-NAM ,W?CUP>>>>
+			 <SETG P-ADJ .WV>
+			 <SETG P-ADJN .WRD>)
+			(<WT? .WRD ,PS?OBJECT ,P1?OBJECT>
+			 <SETG P-NAM .WRD>
+			 <SETG P-ONEOBJ .WRD>)>)>
+	   <COND (<NOT <==? .PTR .EPTR>>
+		  <SET PTR <REST .PTR ,P-WORDLEN>>
+		  <SET WRD .NW>)>>>
+
+;<ROUTINE ADJ-CHECK (WRD) ;"original ADJ-CHECK"
+	 <COND (<NOT ,P-ADJ>
+		<RTRUE>)
+	       (<EQUAL? ,P-ADJ ,W?INNER ,W?OUTER>
+		<RFALSE>)
+	       (T
+		<RTRUE>)>>
+
+;"this ADJ-CHECK will grab the first adjective rather than the last, unless it
+  comes across INNER or OUTER"
+<ROUTINE ADJ-CHECK (WRD)
+	 <COND (<NOT ,P-ADJ>
+		<RTRUE>)
+	       (<EQUAL? .WRD ,W?INNER ,W?OUTER>
+		<RTRUE>)>>		
+
+<CONSTANT SH 128>   
+ 
+<CONSTANT SC 64>    
+ 
+<CONSTANT SIR 32>   
+ 
+<CONSTANT SOG 16>   
+ 
+<CONSTANT STAKE 8>  
+ 
+<CONSTANT SMANY 4>  
+ 
+<CONSTANT SHAVE 2>  
+
+<GLOBAL NOUN-MISSING "There seems to be a noun missing in that sentence.">
+
+<ROUTINE GET-OBJECT (TBL "OPTIONAL" (VRB T)
+		        "AUX" GEN BITS LEN XBITS TLEN (GCHECK <>) (OLEN 0) OBJ)
+	 <SET XBITS ,P-SLOCBITS>
+	 <SET TLEN <GET .TBL ,P-MATCHLEN>>
+	 <COND (<BTST ,P-GETFLAGS ,P-INHIBIT> <RTRUE>)>
+	 <COND (<AND <NOT ,P-NAM> ,P-ADJ <WT? ,P-ADJN ,PS?OBJECT ,P1?OBJECT>>
+		<SETG P-NAM ,P-ADJN>
+		<SETG P-ADJ <>>)>
+	 <COND (<AND <NOT ,P-NAM>
+		     <NOT ,P-ADJ>
+		     <NOT <==? ,P-GETFLAGS ,P-ALL>>
+		     <0? ,P-GWIMBIT>>
+		<COND (.VRB
+		       <TELL ,NOUN-MISSING CR>)>
+		<RFALSE>)>
+	 <COND (<OR <NOT <==? ,P-GETFLAGS ,P-ALL>> <0? ,P-SLOCBITS>>
+		<SETG P-SLOCBITS -1>)>
+	 <SETG P-TABLE .TBL>
+	 <PROG ()
+	       <COND (.GCHECK <GLOBAL-CHECK .TBL>)
+		     (T
+		      <COND (,LIT
+			     <FCLEAR ,PLAYER ,TRANSBIT>
+			     <DO-SL ,HERE ,SOG ,SIR>
+			     <FSET ,PLAYER ,TRANSBIT>)>
+		      <DO-SL ,PLAYER ,SH ,SC>)>
+	       <SET LEN <- <GET .TBL ,P-MATCHLEN> .TLEN>>
+	       <COND (<BTST ,P-GETFLAGS ,P-ALL> ;<AND * <NOT <EQUAL? .LEN 0>>>)
+		     (<AND <BTST ,P-GETFLAGS ,P-ONE>
+			   <NOT <0? .LEN>>>
+		      <COND (<NOT <==? .LEN 1>>
+			     <PUT .TBL 1 <GET .TBL <RANDOM .LEN>>>
+			     <TELL "(How about the ">
+			     <PRINTD <GET .TBL 1>>
+			     <TELL "?)" CR>)>
+		      <PUT .TBL ,P-MATCHLEN 1>)
+		     (<OR <G? .LEN 1>
+			  <AND <0? .LEN> <NOT <==? ,P-SLOCBITS -1>>>>
+		      <COND (<==? ,P-SLOCBITS -1>
+			     <SETG P-SLOCBITS .XBITS>
+			     <SET OLEN .LEN>
+			     <PUT .TBL
+				  ,P-MATCHLEN
+				  <- <GET .TBL ,P-MATCHLEN> .LEN>>
+			     <AGAIN>)
+			    (T
+			     <COND (<0? .LEN> <SET LEN .OLEN>)>
+			     <COND (<AND <G? .LEN 1>
+					 <VERB? ASK-ABOUT WHAT>
+					 <OR <AND <EQUAL? ,P-NAM
+							  ,W?FLUFF ,W?DRIVE>
+						  <NOT ,P-ADJ>>
+					     <AND <EQUAL? ,P-NAM ,W?TOOLS
+							  	 ,W?TOOL>
+						  <EQUAL? ,P-ADJN ,W?PROPER>>
+					     <AND <EQUAL? ,P-NAM ,W?DRIVE>
+						  <EQUAL? ,P-ADJN ,W?IMPROB>>>>
+				    <SET GEN <GETP <GET .TBL .LEN> ,P?GENERIC>>
+				   <PUT .TBL ,P-MATCHLEN <SET LEN <+ .TLEN 1>>>
+				    <PUT .TBL .LEN .GEN>
+				    <SETG P-XNAM ,P-NAM>
+				    <SETG P-XADJ ,P-ADJ>
+				    <SETG P-XADJN ,P-ADJN>
+				    <SETG P-NAM <>>
+				    <SETG P-ADJ <>>
+				    <SETG P-ADJN <>>
+				    <RTRUE>)
+			      	   (<AND .VRB ;".VRB added 8/14/84 by JW"
+					 <NOT <==? ,WINNER ,PROTAGONIST>>>
+				    <CANT-ORPHAN>
+				    <SETG P-NAM <>>
+				    <SETG P-ADJ <>>
+				    <RFALSE>)
+				   (<AND .VRB ,P-NAM>
+				    <WHICH-PRINT .TLEN .LEN .TBL>
+				    <SETG P-ACLAUSE
+					  <COND (<==? .TBL ,P-PRSO> ,P-NC1)
+						(T ,P-NC2)>>
+				    <SETG P-AADJ ,P-ADJ>
+				    <SETG P-ANAM ,P-NAM>
+				    <ORPHAN <> <>>
+				    <SETG P-OFLAG T>)
+				   (.VRB
+				    <TELL ,NOUN-MISSING CR>)>
+			     <SETG P-NAM <>>
+			     <SETG P-ADJ <>>
+			     <RFALSE>)>)
+		     (<AND <0? .LEN> .GCHECK>
+		      <COND (.VRB
+			     <SETG P-SLOCBITS .XBITS>
+			     <COND (<OR ,LIT
+					<EQUAL? ,PRSA ,V?TELL>
+					<EQUAL? ,PRSA ,V?WHERE ,V?WHAT ,V?WHO>>
+				    ;"Changed 6/10/83 - MARC"
+				    <OBJ-FOUND ,NOT-HERE-OBJECT .TBL>
+				    <SETG P-XNAM ,P-NAM>
+				    <SETG P-XADJ ,P-ADJ>
+				    <SETG P-XADJN ,P-ADJN>
+				    <SETG P-NAM <>>
+				    <SETG P-ADJ <>>
+				    <SETG P-ADJN <>>
+				    <RTRUE>)
+				   (T
+				    <TELL ,TOO-DARK CR>)>)>
+		      <SETG P-NAM <>>
+		      <SETG P-ADJ <>>
+		      <RFALSE>)
+		     (<0? .LEN> <SET GCHECK T> <AGAIN>)>
+	       <SETG P-SLOCBITS .XBITS>
+	       <SETG P-NAM <>>
+	       <SETG P-ADJ <>>
+	       <RTRUE>>>
+
+<ROUTINE MOBY-FIND (TBL "AUX" FOO LEN)
+	 <SETG P-MOBY-FLAG T>
+	 <SETG P-SLOCBITS -1>
+	 <SETG P-TABLE .TBL>
+	 <SETG P-NAM ,P-XNAM>
+	 <SETG P-ADJ ,P-XADJ>
+	 <PUT .TBL ,P-MATCHLEN 0>
+	 <SET FOO <FIRST? ,ROOMS>>
+	 <REPEAT ()
+		 <COND (<NOT .FOO> <RETURN>)
+		       (T
+			<SEARCH-LIST .FOO .TBL ,P-SRCALL>
+			<SET FOO <NEXT? .FOO>>)>>
+	 <DO-SL ,LOCAL-GLOBALS 1 1>
+	 <SEARCH-LIST ,ROOMS .TBL ,P-SRCTOP>
+	 <COND (<EQUAL? <SET LEN <GET .TBL ,P-MATCHLEN>> 1>
+		<SETG P-MOBY-FOUND <GET .TBL 1>>)>
+	 <SETG P-MOBY-FLAG <>>
+	 <SETG P-NAM <>>
+	 <SETG P-ADJ <>>
+	 .LEN>
+
+<GLOBAL P-MOBY-FOUND <>>   
+<GLOBAL P-MOBY-FLAG <>>
+<GLOBAL P-XNAM <>>
+<GLOBAL P-XADJ <>>
+<GLOBAL P-XADJN <>>
+
+<ROUTINE WHICH-PRINT (TLEN LEN TBL "AUX" OBJ RLEN)
+	 <SET RLEN .LEN>
+	 <TELL "Which">
+         <COND (<OR ,P-OFLAG
+		    ,P-MERGED
+		    ,P-AND>
+		<TELL " ">
+		<PRINTB ,P-NAM>)
+	       (<EQUAL? .TBL ,P-PRSO>
+		<CLAUSE-PRINT ,P-NC1 ,P-NC1L <>>)
+	       (T
+		<CLAUSE-PRINT ,P-NC2 ,P-NC2L <>>)>
+	 <TELL " do you mean, ">
+	 <REPEAT ()
+		 <SET TLEN <+ .TLEN 1>>
+		 <SET OBJ <GET .TBL .TLEN>>
+		 <COND (<NOT <FSET? .OBJ ,NARTICLEBIT>>
+			<TELL "the ">)>
+		 <TELL D .OBJ>
+		 <COND (<EQUAL? .LEN 2>
+		        <COND (<NOT <EQUAL? .RLEN 2>>
+			       <TELL ",">)>
+		        <TELL " or ">)
+		       (<G? .LEN 2>
+			<TELL ", ">)>
+		 <COND (<L? <SET LEN <- .LEN 1>> 1>
+		        <TELL "?" CR>
+		        <RETURN>)>>>
+
+
+<ROUTINE GLOBAL-CHECK (TBL "AUX" LEN RMG RMGL (CNT 0) OBJ OBITS FOO)
+	<SET LEN <GET .TBL ,P-MATCHLEN>>
+	<SET OBITS ,P-SLOCBITS>
+	<COND (<SET RMG <GETPT ,HERE ,P?GLOBAL>>
+	       <SET RMGL <- <PTSIZE .RMG> 1>>
+	       <REPEAT ()
+		       <COND (<THIS-IT? <SET OBJ <GETB .RMG .CNT>> .TBL>
+			      <OBJ-FOUND .OBJ .TBL>)>
+		       <COND (<IGRTR? CNT .RMGL> <RETURN>)>>)>
+	<COND (<SET RMG <GETPT ,HERE ,P?PSEUDO>>
+	       <SET RMGL <- </ <PTSIZE .RMG> 4> 1>>
+	       <SET CNT 0>
+	       <REPEAT ()
+		       <COND (<==? ,P-NAM <GET .RMG <* .CNT 2>>>
+			      <SETG LAST-PSEUDO-LOC ,HERE>
+			      <PUTP ,PSEUDO-OBJECT
+				    ,P?ACTION
+				    <GET .RMG <+ <* .CNT 2> 1>>>
+			      <SET FOO
+				   <BACK <GETPT ,PSEUDO-OBJECT ,P?ACTION> 5>>
+			      <PUT .FOO 0 <GET ,P-NAM 0>>
+			      <PUT .FOO 1 <GET ,P-NAM 1>>
+			      <OBJ-FOUND ,PSEUDO-OBJECT .TBL>
+			      <RETURN>)
+		             (<IGRTR? CNT .RMGL> <RETURN>)>>)>
+	<COND (<==? <GET .TBL ,P-MATCHLEN> .LEN>
+	       <SETG P-SLOCBITS -1>
+	       <SETG P-TABLE .TBL>
+	       <DO-SL ,GLOBAL-OBJECTS 1 1>
+	       <SETG P-SLOCBITS .OBITS>
+	       ;<COND (<AND <0? <GET .TBL ,P-MATCHLEN>>
+			   <EQUAL? ,PRSA ,V?LOOK-INSIDE ,V?SEARCH ,V?EXAMINE>>
+		      <DO-SL ,ROOMS 1 1>)>)>>
+ 
+<ROUTINE DO-SL (OBJ BIT1 BIT2 "AUX" BTS)
+	<COND (<BTST ,P-SLOCBITS <+ .BIT1 .BIT2>>
+	       <SEARCH-LIST .OBJ ,P-TABLE ,P-SRCALL>)
+	      (T
+	       <COND (<BTST ,P-SLOCBITS .BIT1>
+		      <SEARCH-LIST .OBJ ,P-TABLE ,P-SRCTOP>)
+		     (<BTST ,P-SLOCBITS .BIT2>
+		      <SEARCH-LIST .OBJ ,P-TABLE ,P-SRCBOT>)
+		     (T <RTRUE>)>)>>  
+ 
+<CONSTANT P-SRCBOT 2>    
+ 
+<CONSTANT P-SRCTOP 0>    
+ 
+<CONSTANT P-SRCALL 1>    
+ 
+<ROUTINE SEARCH-LIST (OBJ TBL LVL "AUX" FLS NOBJ)
+	<COND (<SET OBJ <FIRST? .OBJ>>
+	       <REPEAT ()
+		       <COND (<AND <NOT <==? .LVL ,P-SRCBOT>>
+				   <GETPT .OBJ ,P?SYNONYM>
+				   <THIS-IT? .OBJ .TBL>>
+			      <OBJ-FOUND .OBJ .TBL>)>
+		       <COND (<AND <OR <NOT <==? .LVL ,P-SRCTOP>>
+				       <FSET? .OBJ ,SEARCHBIT>
+				       <FSET? .OBJ ,SURFACEBIT>>
+				   <SET NOBJ <FIRST? .OBJ>>>
+			      <COND (<OR <FSET? .OBJ ,OPENBIT>
+					 <FSET? .OBJ ,TRANSBIT>
+					 ,P-MOBY-FLAG>
+				     <SET FLS
+					  <SEARCH-LIST
+					   .OBJ
+					   .TBL
+					   <COND (<FSET? .OBJ ,SURFACEBIT>
+						  ,P-SRCALL)
+						 (<FSET? .OBJ ,SEARCHBIT>
+						  ,P-SRCALL)
+						 (T ,P-SRCTOP)>>>)>)>
+		       <COND (<SET OBJ <NEXT? .OBJ>>) (T <RETURN>)>>)>> 
+ 
+<ROUTINE OBJ-FOUND (OBJ TBL "AUX" PTR)
+	<SET PTR <GET .TBL ,P-MATCHLEN>>
+	<PUT .TBL <+ .PTR 1> .OBJ>
+	<PUT .TBL ,P-MATCHLEN <+ .PTR 1>>>
+
+<ROUTINE TAKE-CHECK () 
+	<AND <ITAKE-CHECK ,P-PRSO <GETB ,P-SYNTAX ,P-SLOC1>>
+	     <ITAKE-CHECK ,P-PRSI <GETB ,P-SYNTAX ,P-SLOC2>>>> 
+
+<ROUTINE ITAKE-CHECK (TBL IBITS "AUX" PTR OBJ TAKEN) ;"changed by MARC 11/83"
+   <COND (<AND <SET PTR <GET .TBL ,P-MATCHLEN>>
+	       <OR <BTST .IBITS ,SHAVE>
+	           <BTST .IBITS ,STAKE>>>
+	  <REPEAT ()
+	    <COND (<L? <SET PTR <- .PTR 1>> 0>
+		   <RETURN>)
+		  (T
+		   <SET OBJ <GET .TBL <+ .PTR 1>>>
+		   <COND (<==? .OBJ ,IT>
+			  <COND (<NOT <ACCESSIBLE? ,P-IT-OBJECT>>
+				 <TELL ,REFERRING CR>
+				 <RFALSE>)
+				(T
+				 <SET OBJ ,P-IT-OBJECT>)>)>
+		   <COND (<OR <HELD? .OBJ>
+			      <EQUAL? .OBJ ,HANDS ,SLEEVES ,SPEECH>
+			      <AND <EQUAL? .OBJ ,NO-TEA>
+				   ,HOLDING-NO-TEA>
+			      <AND <EQUAL? .OBJ ,GUARANTEE>
+				   <VERB? SHOW>>>
+			  T)
+			 (T
+			  <SETG PRSO .OBJ>
+			  <COND (<FSET? .OBJ ,TRYTAKEBIT>
+				 <SET TAKEN T>)
+				(<NOT <==? ,WINNER ,PROTAGONIST>>
+				 <SET TAKEN <>>)
+				(<AND <BTST .IBITS ,STAKE>
+				      <EQUAL? <ITAKE <>> T>>
+				 <SET TAKEN <>>)
+				(T
+				 <SET TAKEN T>)>
+			  <COND (<AND .TAKEN <BTST .IBITS ,SHAVE>>
+				 <COND (<L? 1 <GET .TBL ,P-MATCHLEN>>
+				        <TELL ,NOT-HOLDING
+					      " all those things!">
+					<CRLF>
+					<RFALSE>)
+				       (<EQUAL? .OBJ ,NOT-HERE-OBJECT>
+					<TELL "You can't see that here!" CR>
+					<RFALSE>)>
+				 <COND (<EQUAL? ,WINNER ,PROTAGONIST>
+					<TELL ,NOT-HOLDING>)
+				       (T
+					<TELL "It doesn't look like">
+					<ARTICLE ,WINNER T>
+					<TELL " is holding">)>
+				 <ARTICLE .OBJ T>
+				 <SETG P-IT-OBJECT .OBJ>
+				 <TELL "." CR>
+				 <RFALSE>)
+				(<AND <NOT .TAKEN>
+				      <==? ,WINNER ,PROTAGONIST>>
+				 <TELL "(Taking">
+				 <ARTICLE .OBJ T>
+				 <TELL " first)" CR>)>)>)>>)
+	       (T)>>
+
+<ROUTINE MANY-CHECK ("AUX" (LOSS <>) TMP)
+	<COND (<AND <G? <GET ,P-PRSO ,P-MATCHLEN> 1>
+		    <NOT <BTST <GETB ,P-SYNTAX ,P-SLOC1> ,SMANY>>>
+	       <SET LOSS 1>)
+	      (<AND <G? <GET ,P-PRSI ,P-MATCHLEN> 1>
+		    <NOT <BTST <GETB ,P-SYNTAX ,P-SLOC2> ,SMANY>>>
+	       <SET LOSS 2>)>
+	<COND (.LOSS
+	       <TELL "You can't use multiple ">
+	       <COND (<EQUAL? .LOSS 2>
+		      <TELL "in">)>
+	       <TELL "direct objects with \"">
+	       <SET TMP <GET ,P-ITBL ,P-VERBN>>
+	       <COND (<0? .TMP>
+		      <TELL "tell">)
+		     (<OR ,P-OFLAG ,P-MERGED>
+		      <PRINTB <GET .TMP 0>>)
+		     (T
+		      <WORD-PRINT <GETB .TMP 2> <GETB .TMP 3>>)>
+	       <TELL "\"." CR>
+	       <RFALSE>)
+	      (T)>>  
+ 
+<ROUTINE ZMEMQ (ITM TBL "OPTIONAL" (SIZE -1) "AUX" (CNT 1)) 
+	<COND (<NOT .TBL> <RFALSE>)>
+	<COND (<NOT <L? .SIZE 0>> <SET CNT 0>)
+	      (ELSE <SET SIZE <GET .TBL 0>>)>
+	<REPEAT ()
+		<COND (<==? .ITM <GET .TBL .CNT>> <RTRUE>)
+		      (<IGRTR? CNT .SIZE> <RFALSE>)>>>    
+
+<ROUTINE ZMEMQB (ITM TBL SIZE "AUX" (CNT 0)) 
+	<REPEAT ()
+		<COND (<EQUAL? .ITM <GETB .TBL .CNT>>
+		       <RTRUE>)
+		      (<IGRTR? CNT .SIZE>
+		       <RFALSE>)>>>
+
+<ROUTINE LIT? (RM "OPTIONAL" (RMBIT T) "AUX" OHERE (LIT <>))
+	<SETG P-GWIMBIT ,ONBIT>
+	<SET OHERE ,HERE>
+	<SETG HERE .RM>
+	<COND (<AND .RMBIT
+		    <FSET? .RM ,ONBIT>>
+	       <SET LIT T>)
+	      (T
+	       <PUT ,P-MERGE ,P-MATCHLEN 0>
+	       <SETG P-TABLE ,P-MERGE>
+	       <SETG P-SLOCBITS -1>
+	       <COND (<EQUAL? .OHERE .RM>
+		      <DO-SL ,WINNER 1 1>
+		      <COND (<AND <NOT <EQUAL? ,WINNER ,PLAYER>>
+				  <IN? ,PLAYER .RM>>
+			     <DO-SL ,PLAYER 1 1>)>)>
+	       <DO-SL .RM 1 1>
+	       <COND (<G? <GET ,P-TABLE ,P-MATCHLEN> 0>
+		      <SET LIT T>)>)>
+	<SETG HERE .OHERE>
+	<SETG P-GWIMBIT 0>
+	.LIT>
+
+<ROUTINE PRSO-PRINT ("AUX" PTR)
+	 <COND (<OR ,P-MERGED
+		    <==? <GET <SET PTR <GET ,P-ITBL ,P-NC1>> 0> ,W?IT>>
+		<TELL " " D ,PRSO>)
+	       (T <BUFFER-PRINT .PTR <GET ,P-ITBL ,P-NC1L> <>>)>>
+
+<ROUTINE PRSI-PRINT ("AUX" PTR)
+	 <COND (<OR ,P-MERGED
+		    <==? <GET <SET PTR <GET ,P-ITBL ,P-NC2>> 0> ,W?IT>>
+		<TELL " " D ,PRSO>)
+	       (T <BUFFER-PRINT .PTR <GET ,P-ITBL ,P-NC2L> <>>)>>
+
+;"former CRUFTY.ZIL routine"
+
+<ROUTINE THIS-IT? (OBJ TBL "AUX" SYNS) 
+ <COND (<FSET? .OBJ ,INVISIBLE> <RFALSE>)
+       (<AND ,P-NAM
+	     <NOT <ZMEMQ ,P-NAM
+			 <SET SYNS <GETPT .OBJ ,P?SYNONYM>>
+			 <- </ <PTSIZE .SYNS> 2> 1>>>>
+	<RFALSE>)
+       (<AND ,P-ADJ
+	     <OR <NOT <SET SYNS <GETPT .OBJ ,P?ADJECTIVE>>>
+		 <NOT <ZMEMQB ,P-ADJ .SYNS <- <PTSIZE .SYNS> 1>>>>>
+	<RFALSE>)
+       (<AND <NOT <0? ,P-GWIMBIT>> <NOT <FSET? .OBJ ,P-GWIMBIT>>>
+	<RFALSE>)>
+ <RTRUE>>
\ No newline at end of file
diff --git a/s4.zil b/s4.zil
new file mode 100644
index 0000000..3a2a227
--- /dev/null
+++ b/s4.zil
@@ -0,0 +1,39 @@
+"S4 for
+		  THE HITCHHIKER'S GUIDE TO THE GALAXY
+	(c) Copyright 1984 Infocom, Inc.  All Rights Reserved."
+
+<PRINC "
+ *** THE HITCHHIKER'S GUIDE TO THE GALAXY: Interactive Science Fiction ***
+
+">
+
+<BLOAT 90000 0 0 3300 0 0 0 0 0 256>
+
+<SNAME "S4">
+
+<SET REDEFINE T>
+
+<OR <GASSIGNED? ZILCH>
+    <SETG WBREAKS <STRING !\" !,WBREAKS>>>
+
+<OR <GASSIGNED? INSERT-CRUFTY>
+    <DEFINE INSERT-CRUFTY (STR) <INSERT-FILE .STR T>>>
+
+<COND (<GASSIGNED? PREDGEN>
+       <ID 0>)>
+
+ <COND (<GASSIGNED? PREDGEN>
+	       <SETG ZSTR-ON <SETG ZSTR-OFF ,TIME>>)>
+
+<INSERT-FILE "MISC" T>
+<INSERT-FILE "HEART" T>
+<INSERT-FILE "PARSER" T>
+<INSERT-FILE "SYNTAX" T>
+<INSERT-FILE "VERBS" T>
+<INSERT-FILE "EARTH" T>
+<INSERT-FILE "VOGON" T>
+<INSERT-FILE "UNEARTH" T>
+<INSERT-FILE "GLOBALS" T>
+
+<PROPDEF SIZE 5>
+<PROPDEF CAPACITY 0>
\ No newline at end of file
diff --git a/s4.zip b/s4.zip
new file mode 100644
index 0000000..a82d712
Binary files /dev/null and b/s4.zip differ
diff --git a/syntax.zil b/syntax.zil
new file mode 100644
index 0000000..260e0fa
--- /dev/null
+++ b/syntax.zil
@@ -0,0 +1,622 @@
+"SYNTAX for
+		  THE HITCHHIKER'S GUIDE TO THE GALAXY
+	(c) Copyright 1984 Infocom, Inc.  All Rights Reserved."
+
+<BUZZ A AN THE IS ARE AM AND OF THEN ALL ONE BUT EXCEPT \. \, \"
+      DON\'T DONT PRY PLEASE HERE SOME MORE FRONT>
+
+<SYNONYM TO TOWARD>
+<SYNONYM WITH USING>
+<SYNONYM THROUGH THRU>
+<SYNONYM ON ONTO>
+<SYNONYM OUT OUTSIDE>
+<SYNONYM IN INSIDE INTO>
+<SYNONYM UNDER BELOW BENEATH UNDERNEATH>
+<SYNONYM AROUND ALONG>
+<SYNONYM BEFORE NEAR NEXT AGAINST>
+<SYNONYM ALL BOTH>
+<SYNONYM DRUNK BOMBED SMASHE PLASTE>
+
+<SYNONYM NORTH N FORE F FOREWA>
+<SYNONYM SOUTH S AFT>
+<SYNONYM EAST E STARBO SB>
+<SYNONYM WEST W PORT P>
+<SYNONYM DOWN D>
+<SYNONYM UP U>
+<SYNONYM NW NORTHWEST>
+<SYNONYM NE NORTHE>
+<SYNONYM SW SOUTHWEST>
+<SYNONYM SE SOUTHE>
+
+
+;"game commands"
+
+<SYNTAX VERBOSE = V-VERBOSE>
+
+<SYNTAX BRIEF = V-BRIEF>
+
+<SYNTAX SUPER = V-SUPER-BRIEF>
+<SYNONYM SUPER SUPERBRIEF>
+
+<SYNTAX DIAGNOSE = V-DIAGNOSE>
+
+<SYNTAX INVENT = V-INVENTORY>
+<SYNTAX I = V-INVENTORY>
+<SYNTAX I OBJECT = V-I-AM>
+<SYNONYM I I\'M IM>
+
+<SYNTAX QUIT = V-QUIT>
+<SYNONYM QUIT Q>
+
+<SYNTAX RESTAR = V-RESTART>
+
+<SYNTAX RESTOR = V-RESTORE>
+
+<SYNTAX SAVE = V-SAVE>
+
+<SYNTAX SCORE = V-SCORE>
+
+<SYNTAX SCRIPT = V-SCRIPT>
+
+<SYNTAX UNSCRIPT = V-UNSCRIPT>
+
+<SYNTAX VERSION = V-VERSION>
+
+<SYNTAX $VERIFY = V-$VERIFY>
+<SYNTAX $VERIFY OBJECT = V-$VERIFY>
+
+;<SYNTAX $DEBUG = V-$DEBUG>
+
+;<SYNTAX $CHEAT OBJECT = V-$CHEAT>
+
+;<SYNTAX $PROB = V-$PROB>
+
+
+;"subtitle real verbs"
+
+<SYNTAX ADDRES OBJECT (FIND ACTORBIT) (IN-ROOM) = V-TELL>
+
+<SYNTAX AGAIN = V-AGAIN>
+<SYNONYM AGAIN G>
+
+<SYNTAX ANSWER = V-ANSWER>
+<SYNTAX ANSWER OBJECT = V-REPLY>
+<SYNTAX ANSWER TO OBJECT = V-REPLY>
+<SYNONYM ANSWER REPLY>
+
+<SYNTAX APPLAU = V-APPLAUD>
+<SYNONYM APPLAU CLAP CHEER>
+
+<SYNTAX APPREC OBJECT = V-APPRECIATE>
+
+<SYNTAX APPROA OBJECT = V-WALK-TO>
+
+<SYNTAX ASK OBJECT (FIND ACTORBIT) ABOUT OBJECT = V-ASK-ABOUT>
+<SYNTAX ASK OBJECT (FIND ACTORBIT) ON OBJECT = V-ASK-ABOUT>
+<SYNTAX ASK OBJECT (FIND ACTORBIT) FOR OBJECT = V-ASK-FOR>
+<SYNONYM ASK CONSUL QUERY>
+
+<SYNTAX ATTACK OBJECT (FIND ACTORBIT) (ON-GROUND IN-ROOM) = V-KILL>
+<SYNTAX ATTACK OBJECT (FIND ACTORBIT) (ON-GROUND IN-ROOM)
+	WITH OBJECT (HELD CARRIED HAVE) = V-KILL>
+<SYNONYM ATTACK ASSAULT FIGHT HIT SLAP KILL MURDER STRIKE PUNCH>
+
+<SYNTAX BITE OBJECT = V-BITE>
+
+<SYNTAX BLOCK OBJECT = V-BLOCK>
+<SYNTAX BLOCK OBJECT WITH OBJECT = V-BLOCK-WITH>
+<SYNONYM BLOCK STOP>
+
+<SYNTAX BOARD OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-BOARD PRE-BOARD>
+<SYNONYM BOARD EMBARK>
+
+<SYNTAX BRUSH OBJECT = V-BRUSH>
+<SYNTAX BRUSH OBJECT WITH OBJECT (HAVE) = V-BRUSH>
+<SYNONYM BRUSH>
+
+<SYNTAX ORDER OBJECT = V-BUY>
+<SYNONYM ORDER BUY PURCHASE>
+
+<SYNTAX CARVE OBJECT ON OBJECT = V-CARVE PRE-CARVE>
+<SYNTAX CARVE OBJECT IN OBJECT = V-CARVE PRE-CARVE>
+<SYNTAX CARVE OBJECT WITH OBJECT (HAVE) = V-CARVE-WITH>
+<SYNONYM CARVE INSCRI SCRATC WRITE>
+
+<SYNTAX CLIMB OBJECT (ON-GROUND IN-ROOM) = V-CLIMB-FOO>
+<SYNTAX CLIMB ON OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-CLIMB-ON>
+<SYNTAX CLIMB UP OBJECT (FIND RLANDBIT) (ON-GROUND IN-ROOM) = V-CLIMB-UP>
+<SYNTAX CLIMB DOWN OBJECT (FIND RLANDBIT) (ON-GROUND IN-ROOM) = V-CLIMB-DOWN>
+<SYNTAX CLIMB OVER OBJECT (ON-GROUND IN-ROOM) = V-CLIMB-OVER>
+<SYNTAX CLIMB IN OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-BOARD PRE-BOARD>
+<SYNTAX CLIMB THROUGH OBJECT = V-THROUGH>
+<SYNONYM CLIMB SCALE>
+
+<SYNTAX CLOSE OBJECT (FIND DOORBIT) (HELD CARRIED ON-GROUND IN-ROOM) = V-CLOSE>
+<SYNTAX CLOSE OFF OBJECT (FIND LIGHTBIT) (HELD CARRIED ON-GROUND IN-ROOM TAKE)
+	= V-LAMP-OFF>
+<SYNONYM CLOSE SHUT>
+
+<SYNTAX CONNECT OBJECT TO OBJECT = V-PLUG>
+
+<SYNTAX COVER OBJECT WITH OBJECT (HELD MANY) = V-SPUT-ON>
+
+<SYNTAX COUNT OBJECT = V-COUNT>
+
+<SYNTAX CUT OBJECT WITH OBJECT (CARRIED HELD) = V-CUT>
+<SYNTAX CUT THROUGH OBJECT WITH OBJECT (CARRIED HELD) = V-CUT>
+<SYNONYM CUT SLICE>
+
+<SYNTAX DEMOLI OBJECT (ON-GROUND IN-ROOM) = V-MUNG>
+<SYNTAX DEMOLI OBJECT WITH OBJECT (HELD CARRIED TAKE) = V-MUNG>
+<SYNTAX DEMOLI DOWN OBJECT = V-KILL>
+<SYNONYM DEMOLI CRACK DESTRO DAMAGE BREAK SMASH WRECK>
+
+<SYNTAX DANGLE OBJECT (HELD MANY) IN OBJECT = V-PUT PRE-PUT>
+
+<SYNTAX DESCEN OBJECT (ON-GROUND IN-ROOM) = V-CLIMB-DOWN>
+
+<SYNTAX DIG IN OBJECT = V-DIG>
+<SYNTAX DIG WITH OBJECT = V-DIG>
+<SYNTAX DIG THROUGH OBJECT = V-DIG>
+
+<SYNTAX DISEMBARK OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-DISEMBARK>
+<SYNONYM DISEMBARK DEBARK>
+
+<SYNTAX DISROBE = V-GET-UNDRESSED>
+
+<SYNTAX DOZE = V-DOZE>
+<SYNONYM DOZE NAP SNOOZE>
+
+<SYNTAX DRINK OBJECT (FIND DRINKBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-DRINK>
+<SYNTAX DRINK FROM OBJECT (HELD CARRIED) = V-DRINK-FROM>
+<SYNONYM DRINK SIP SWALLOW IMBIBE QUAFF GUZZLE SWILL>
+
+<SYNTAX DROP OBJECT (HELD MANY HAVE) = V-DROP PRE-DROP>
+<SYNTAX DROP OBJECT (HELD MANY) BEFORE OBJECT = V-PUT-IN-FRONT PRE-GIVE>
+<SYNTAX DROP OBJECT (HELD MANY) DOWN OBJECT = V-PUT PRE-PUT>
+<SYNTAX DROP OBJECT (HELD MANY) IN OBJECT = V-PUT PRE-PUT>
+<SYNTAX DROP OBJECT (HELD MANY) ON OBJECT = V-PUT-ON PRE-PUT>
+
+<SYNTAX EAT OBJECT (FIND EATBIT) (HELD CARRIED ON-GROUND IN-ROOM) = V-EAT>
+<SYNONYM EAT DEVOUR INGEST GOBBLE>
+
+<SYNTAX ENJOY OBJECT = V-ENJOY>
+
+<SYNTAX ENTER = V-ENTER>
+<SYNTAX ENTER OBJECT = V-THROUGH>
+
+<SYNTAX EXIT = V-EXIT>
+<SYNTAX EXIT OBJECT = V-EXIT>
+<SYNONYM EXIT DEPART WITHDR>
+
+<SYNTAX ESCAPE = V-ESCAPE>
+<SYNTAX ESCAPE OBJECT = V-ESCAPE>
+<SYNTAX ESCAPE FROM OBJECT = V-ESCAPE>
+<SYNONYM ESCAPE FLEE>
+
+<SYNTAX EXAMINE OBJECT (HELD CARRIED ON-GROUND IN-ROOM) (FIND DARKBIT)
+	= V-EXAMINE PRE-READ>
+<SYNTAX EXAMINE OBJECT THROUGH OBJECT = V-EXAMINE-THROUGH PRE-READ>
+<SYNTAX EXAMINE IN OBJECT (HELD CARRIED IN-ROOM ON-GROUND)
+	= V-LOOK-INSIDE>
+<SYNTAX EXAMINE ON OBJECT (HELD CARRIED IN-ROOM ON-GROUND)
+	= V-LOOK-INSIDE>
+<SYNTAX EXAMINE FOR OBJECT = V-FIND>
+<SYNONYM EXAMINE INSPECT DESCRIBE STUDY OBSERVE SEE SCOUR>
+
+<SYNTAX EXTINGUISH OBJECT (FIND ONBIT) = V-LAMP-OFF>
+
+<SYNTAX FEED OBJECT (FIND ACTORBIT) = V-FEED>
+<SYNTAX FEED OBJECT (MANY HELD HAVE) TO OBJECT (FIND ACTORBIT) (ON-GROUND)
+	= V-GIVE PRE-GIVE>
+<SYNTAX FEED OBJECT (FIND ACTORBIT) (ON-GROUND) OBJECT (MANY HELD HAVE)
+	= V-SGIVE>
+
+<SYNTAX FILL OBJECT = V-FILL>
+
+<SYNTAX FIND OBJECT = V-FIND>
+<SYNONYM FIND SEEK>
+
+<SYNTAX FOLLOW OBJECT = V-FOLLOW>
+<SYNONYM FOLLOW PURSUE CHASE>
+
+<SYNTAX FOOTNOTE = V-FOOTNOTE>
+<SYNTAX FOOTNOTE OBJECT = V-FOOTNOTE>
+
+<SYNTAX FRIPPI = V-FRIPPI>
+<SYNONYM FRIPPI LYSHUS GASHEE MORPHO THOU BLEEM MISERA VENCHI WIMBGU>
+
+<SYNTAX HAND OBJECT (MANY HELD HAVE) TO OBJECT (FIND ACTORBIT) (ON-GROUND)
+	= V-GIVE PRE-GIVE>
+<SYNTAX HAND OBJECT (FIND ACTORBIT) (ON-GROUND) OBJECT (MANY HELD HAVE)
+	= V-SGIVE>
+<SYNTAX HAND UP OBJECT (FIND RLANDBIT) = V-GIVE-UP>
+<SYNONYM HAND GIVE SELL DONATE OFFER>
+
+<SYNTAX HANG OBJECT ON OBJECT = V-HANG>
+<SYNTAX HANG OBJECT FROM OBJECT = V-HANG>
+<SYNTAX HANG OBJECT (HELD MANY) IN OBJECT = V-PUT PRE-PUT>
+
+<SYNTAX HEAR OBJECT (FIND DARKBIT) = V-LISTEN>
+
+<SYNTAX HELLO = V-HELLO>
+<SYNTAX HELLO OBJECT = V-HELLO>
+<SYNONYM HELLO HI>
+
+<SYNTAX HELP = V-HELP>
+<SYNTAX HELP OBJECT = V-SAVE-SOMETHING>
+<SYNONYM HELP HINT HINTS>
+
+<SYNTAX HIDE = V-HIDE>
+<SYNTAX HIDE UNDER OBJECT = V-HIDE>
+<SYNTAX HIDE BEHIND OBJECT = V-HIDE>
+
+<SYNTAX HITCHH = V-HITCHHIKE>
+<SYNONYM HITCHH HITCH>
+
+<SYNTAX IDIOT = V-IDIOT>
+<SYNONYM IDIOT>
+
+<SYNTAX JUMP = V-LEAP>
+<SYNTAX JUMP OVER OBJECT = V-LEAP>
+<SYNTAX JUMP ACROSS OBJECT = V-LEAP>
+<SYNTAX JUMP IN OBJECT = V-THROUGH>
+<SYNTAX JUMP FROM OBJECT = V-LEAP>
+<SYNTAX JUMP OFF OBJECT = V-LEAP>
+<SYNTAX JUMP OUT OBJECT = V-THROUGH>
+<SYNTAX JUMP THROUGH OBJECT = V-THROUGH>
+<SYNONYM JUMP LEAP DIVE>
+
+<SYNTAX KICK OBJECT = V-KICK>
+
+<SYNTAX KISS OBJECT (FIND ACTORBIT) (ON-GROUND IN-ROOM) = V-KISS>
+
+<SYNTAX KNEEL = V-KNEEL>
+<SYNONYM KNEEL CRAWL PEEK>
+
+<SYNTAX KNOCK AT OBJECT = V-KNOCK>
+<SYNTAX KNOCK ON OBJECT = V-KNOCK>
+<SYNTAX KNOCK DOWN OBJECT (FIND ACTORBIT) (ON-GROUND IN-ROOM) = V-KILL>
+<SYNONYM KNOCK RAP>
+
+<SYNTAX LEAVE = V-LEAVE>
+<SYNTAX LEAVE OBJECT = V-LEAVE>
+
+<SYNTAX LIE ON OBJECT (FIND VEHBIT) = V-LIE-DOWN>
+<SYNTAX LIE IN OBJECT (FIND VEHBIT) = V-LIE-DOWN>
+<SYNTAX LIE DOWN OBJECT (FIND RLANDBIT) = V-LIE-DOWN>
+<SYNTAX LIE BEFORE OBJECT = V-BLOCK>
+<SYNONYM LIE RECLIN>
+
+<SYNTAX LIGHT OBJECT (FIND LIGHTBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-LAMP-ON>
+
+<SYNTAX LISTEN TO OBJECT (FIND DARKBIT) = V-LISTEN>
+
+<SYNTAX LOCK OBJECT (ON-GROUND IN-ROOM) = V-LOCK>
+<SYNTAX LOCK OBJECT (ON-GROUND IN-ROOM) WITH OBJECT (TAKE) = V-LOCK>
+
+<SYNTAX LOOK = V-LOOK>
+<SYNTAX LOOK AROUND OBJECT (FIND RLANDBIT) = V-LOOK>
+<SYNTAX LOOK DOWN OBJECT (FIND RLANDBIT) = V-LOOK-DOWN>
+<SYNTAX LOOK UP OBJECT (FIND RLANDBIT) = V-LOOK-UP>
+<SYNTAX LOOK AT OBJECT (HELD CARRIED ON-GROUND IN-ROOM) (FIND DARKBIT)
+	= V-EXAMINE PRE-READ>
+<SYNTAX LOOK AT OBJECT THROUGH OBJECT = V-EXAMINE-THROUGH PRE-READ>
+<SYNTAX LOOK THROUGH OBJECT = V-LOOK-INSIDE>
+<SYNTAX LOOK OUT OBJECT = V-LOOK-INSIDE>
+<SYNTAX LOOK UNDER OBJECT = V-LOOK-UNDER PRE-READ>
+<SYNTAX LOOK BEHIND OBJECT = V-LOOK-BEHIND PRE-READ>
+<SYNTAX LOOK IN OBJECT (HELD CARRIED ON-GROUND IN-ROOM) = V-LOOK-INSIDE>
+<SYNTAX LOOK ON OBJECT = V-EXAMINE PRE-READ>
+<SYNTAX LOOK FOR OBJECT = V-FIND>
+<SYNTAX LOOK OBJECT = V-CHASTISE>
+<SYNONYM LOOK L STARE GAZE>
+
+<SYNTAX LOWER OBJECT = V-LOWER>
+
+<SYNTAX MAKE OBJECT = V-MAKE>
+
+<SYNTAX MOVE OBJECT (ON-GROUND IN-ROOM) = V-MOVE>
+<SYNTAX MOVE OBJECT OBJECT = V-FLIPSWITCH>
+<SYNTAX MOVE TOGETHER OBJECT = V-PULL-TOGETHER> ;"pull myself together"
+<SYNONYM MOVE PULL>
+
+<SYNTAX MY OBJECT OBJECT = V-MY-NAME>
+
+<SYNTAX NO = V-NO>
+
+<SYNTAX OPEN OBJECT (FIND DOORBIT) (HELD CARRIED ON-GROUND IN-ROOM) = V-OPEN>
+<SYNTAX OPEN UP	OBJECT (FIND DOORBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	= V-OPEN>
+<SYNTAX OPEN OBJECT (FIND DOORBIT) (HELD CARRIED ON-GROUND IN-ROOM)
+	WITH OBJECT (ON-GROUND IN-ROOM HELD CARRIED HAVE) = V-OPEN>
+<SYNONYM OPEN PART DRAW>
+
+<SYNTAX PANIC = V-PANIC>
+
+<SYNTAX PAY FOR OBJECT = V-BUY>
+
+<SYNTAX PHONE OBJECT = V-CALL>
+<SYNTAX PHONE OBJECT WITH OBJECT = V-CALL-WITH>
+<SYNTAX PHONE OBJECT ON OBJECT = V-CALL-WITH>
+<SYNONYM PHONE CALL>
+
+<SYNTAX PICK OBJECT = V-PICK>
+<SYNTAX PICK OBJECT WITH OBJECT = V-PICK>
+<SYNTAX PICK UP OBJECT (FIND TAKEBIT) (ON-GROUND MANY) = V-PICK-UP PRE-TAKE>
+
+<SYNTAX PLANT OBJECT (HELD MANY) IN OBJECT = V-PLANT>
+<SYNONYM PLANT BURY>
+
+<SYNTAX PLUG OBJECT IN OBJECT = V-PLUG>
+<SYNTAX PLUG OBJECT TO OBJECT = V-PLUG>
+<SYNTAX PLUG IN OBJECT IN OBJECT = V-PLUG>
+<SYNTAX PLUG IN OBJECT TO OBJECT = V-PLUG>
+
+<SYNTAX POINT AT OBJECT = V-POINT>
+<SYNTAX POINT TO OBJECT = V-POINT>
+<SYNTAX POINT OBJECT AT OBJECT = V-STEER>
+<SYNTAX POINT OBJECT TO OBJECT = V-STEER>
+<SYNONYM POINT STEER>
+
+<SYNTAX POUR OBJECT (HELD CARRIED) = V-POUR>
+<SYNTAX POUR OBJECT (HELD CARRIED) IN OBJECT = V-POUR>
+<SYNTAX POUR OBJECT (HELD CARRIED) ON OBJECT = V-POUR>
+<SYNTAX POUR OBJECT (HELD CARRIED) OVER OBJECT = V-POUR>
+<SYNONYM POUR SPILL SPRINK>
+
+<SYNTAX PROTEST = V-PROTEST>
+<SYNONYM PROTEST ARGUE>
+
+<SYNTAX PUSH OBJECT = V-PUSH>
+<SYNTAX PUSH OBJECT OBJECT = V-FLIPSWITCH>
+<SYNTAX PUSH ON OBJECT (IN-ROOM ON-GROUND) = V-PUSH>
+<SYNTAX PUSH OBJECT UNDER OBJECT = V-PUT-UNDER>
+<SYNONYM PUSH PRESS>
+
+<SYNTAX PUT OBJECT (HELD MANY) IN OBJECT = V-PUT PRE-PUT>
+<SYNTAX PUT OBJECT (HELD MANY) AT OBJECT = V-PUT-IN-FRONT PRE-GIVE>
+<SYNTAX PUT OBJECT (HELD MANY) BEFORE OBJECT = V-PUT-IN-FRONT PRE-GIVE>
+<SYNTAX PUT OBJECT (HELD MANY) DOWN OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX PUT OBJECT (HELD MANY) ON OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX PUT OBJECT (HELD MANY) AROUND OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX PUT OBJECT (HELD MANY) OVER OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX PUT OBJECT (HELD MANY) ACROSS OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX PUT DOWN OBJECT (HELD MANY HAVE) = V-DROP PRE-DROP>
+<SYNTAX PUT OBJECT UNDER OBJECT = V-PUT-UNDER> 
+<SYNTAX PUT ON OBJECT (FIND WEARBIT) (HAVE) = V-WEAR>
+<SYNTAX PUT OBJECT BEHIND OBJECT = V-PUT-BEHIND>
+<SYNONYM PUT STUFF INSERT PLACE LAY>
+
+<SYNTAX RAISE OBJECT = V-RAISE>
+<SYNTAX RAISE UP OBJECT = V-RAISE>
+<SYNONYM RAISE LIFT>
+
+<SYNTAX RAPE OBJECT (FIND ACTORBIT) = V-RAPE>
+
+;<SYNTAX REACH IN OBJECT (ON-GROUND IN-ROOM) = V-REACH-IN>
+
+<SYNTAX READ OBJECT (FIND READBIT) (HELD CARRIED ON-GROUND IN-ROOM TAKE)
+	= V-READ PRE-READ>
+<SYNTAX READ OBJECT (FIND READBIT) (HELD CARRIED ON-GROUND IN-ROOM TAKE)
+	THROUGH OBJECT = V-READ PRE-READ>
+<SYNTAX READ OBJECT (FIND READBIT) (HELD CARRIED ON-GROUND IN-ROOM TAKE)
+	WITH OBJECT = V-READ PRE-READ>
+<SYNONYM READ SKIM>
+
+<SYNTAX REFUSE OBJECT (IN-ROOM) = V-REFUSE>
+
+<SYNTAX RELAX = V-RELAX>
+
+<SYNTAX REMOVE OBJECT (FIND WORNBIT) = V-REMOVE>
+<SYNTAX REMOVE OBJECT (FIND TAKEBIT) (IN-ROOM CARRIED MANY)
+	FROM OBJECT = V-TAKE PRE-TAKE>
+<SYNONYM REMOVE DOFF SHED>
+
+<SYNTAX REPAIR OBJECT = V-REPAIR>
+<SYNONYM REPAIR FIX UNJAM>
+
+<SYNTAX REPLACE OBJECT = V-REPLACE>
+
+<SYNTAX SAVE OBJECT = V-SAVE-SOMETHING>
+
+<SYNTAX SAY TO OBJECT (FIND ACTORBIT) (IN-ROOM) = V-TELL>
+<SYNTAX SAY OBJECT = V-SAY-NAME>
+<SYNTAX SAY = V-SAY>
+<SYNONYM SAY TALK SPEAK>
+
+<SYNTAX SEARCH OBJECT = V-SEARCH>
+<SYNTAX SEARCH IN OBJECT = V-SEARCH>
+<SYNTAX SEARCH FOR OBJECT = V-FIND>
+<SYNONYM SEARCH RUMMAG FRISK>
+
+<SYNTAX SHAKE OBJECT = V-SHAKE>
+<SYNTAX SHAKE OBJECT WITH OBJECT = V-SHAKE-WITH>
+
+<SYNTAX SHOOT = V-SHOOT>
+<SYNTAX SHOOT OBJECT = V-SHOOT>
+<SYNTAX SHOOT OBJECT WITH OBJECT (HAVE) = V-SHOOT>
+<SYNTAX SHOOT OBJECT (HAVE) AT OBJECT = V-SSHOOT>
+<SYNONYM SHOOT FIRE BLAST>
+
+<SYNTAX SHOW OBJECT (HELD MANY HAVE) TO OBJECT (FIND ACTORBIT) = V-SHOW>
+<SYNTAX SHOW OBJECT (FIND ACTORBIT) OBJECT (HELD MANY HAVE) = V-SSHOW>
+
+<SYNTAX SIT ON OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-CLIMB-ON>
+<SYNTAX SIT DOWN OBJECT (FIND RLANDBIT) (ON-GROUND IN-ROOM) = V-SIT>
+<SYNTAX SIT IN OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-BOARD PRE-BOARD>
+<SYNONYM SIT REST SQUAT>
+
+<SYNTAX SKIP = V-SKIP>
+<SYNONYM SKIP HOP>
+
+<SYNTAX SLEEP = V-SLEEP>
+<SYNTAX SLEEP IN OBJECT (IN-ROOM ON-GROUND) = V-BOARD>
+<SYNTAX SLEEP ON OBJECT (IN-ROOM ON-GROUND) = V-BOARD>
+
+<SYNTAX SLIDE OBJECT = V-PUSH>
+<SYNTAX SLIDE OBJECT UNDER OBJECT = V-PUT-UNDER>
+
+<SYNTAX SMELL OBJECT (FIND DARKBIT) = V-SMELL>
+<SYNONYM SMELL SNIFF WHIFF>
+
+<SYNTAX SMILE = V-SMILE>
+<SYNTAX SMILE AT OBJECT = V-SMILE>
+
+<SYNTAX SPIN OBJECT = V-SPIN>
+<SYNONYM SPIN WHIRL ROTATE>
+
+<SYNTAX STAND = V-STAND>
+<SYNTAX STAND UP OBJECT (FIND RLANDBIT) = V-STAND>
+<SYNTAX STAND ON OBJECT = V-STAND-ON>
+<SYNTAX STAND BEFORE OBJECT = V-STAND-BEFORE>
+<SYNTAX STAND IN OBJECT = V-STAND-ON>
+<SYNONYM STAND RISE>
+
+<SYNTAX START OBJECT = V-LAMP-ON>
+<SYNONYM START ACTIVA>
+
+<SYNTAX SWITCH OBJECT = V-TURN>
+<SYNTAX SWITCH OBJECT OBJECT = V-FLIPSWITCH>
+<SYNTAX SWITCH AROUND OBJECT (FIND RLANDBIT) = V-TURN>
+<SYNTAX SWITCH OBJECT TO OBJECT = V-TURN>
+<SYNTAX SWITCH OBJECT WITH OBJECT (HAVE) = V-TURN>
+<SYNTAX SWITCH ON OBJECT (FIND LIGHTBIT) = V-LAMP-ON>
+<SYNTAX SWITCH ON OBJECT OBJECT = V-FLIPSWITCH>
+<SYNTAX SWITCH OFF OBJECT (FIND LIGHTBIT) (TAKE) = V-LAMP-OFF>
+<SYNTAX SWITCH OFF OBJECT OBJECT = V-FLIPSWITCH>
+<SYNONYM SWITCH TURN FLIP FLICK TOGGLE>
+
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (ON-GROUND IN-ROOM MANY) = V-TAKE PRE-TAKE>
+<SYNTAX TAKE IN OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-BOARD PRE-BOARD>
+<SYNTAX TAKE OUT OBJECT (FIND VEHBIT) (ON-GROUND) = V-DISEMBARK>
+<SYNTAX TAKE ON OBJECT (FIND VEHBIT) (ON-GROUND IN-ROOM) = V-CLIMB-ON>
+<SYNTAX TAKE UP OBJECT (FIND RLANDBIT) = V-STAND>
+<SYNTAX TAKE DRESSE OBJECT (FIND RLANDBIT) = V-GET-DRESSED>
+<SYNTAX TAKE UNDRES OBJECT (FIND RLANDBIT) = V-GET-UNDRESSED>
+<SYNTAX TAKE DRUNK OBJECT (FIND RLANDBIT) = V-GET-DRUNK>
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (CARRIED IN-ROOM MANY)
+	OUT OBJECT = V-TAKE PRE-TAKE>
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (CARRIED IN-ROOM MANY)
+	OFF OBJECT = V-TAKE PRE-TAKE>
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (IN-ROOM CARRIED MANY)
+	FROM OBJECT = V-TAKE PRE-TAKE>
+<SYNTAX TAKE OBJECT (FIND TAKEBIT) (IN-ROOM CARRIED MANY)
+	IN OBJECT = V-TAKE PRE-TAKE>
+<SYNTAX TAKE OFF OBJECT (FIND WORNBIT) (HAVE) = V-TAKE-OFF>
+<SYNONYM TAKE GRAB CATCH GET HOLD CARRY>
+
+<SYNTAX TASTE OBJECT (FIND DARKBIT) = V-TASTE>
+<SYNONYM TASTE LICK>
+
+<SYNTAX TELL OBJECT (FIND ACTORBIT) (IN-ROOM) = V-TELL>
+<SYNTAX TELL OBJECT (FIND ACTORBIT) ABOUT OBJECT = V-TELL-ABOUT>
+<SYNTAX TELL OBJECT OBJECT = V-TELL-TIME>
+<SYNTAX TELL OBJECT TO OBJECT = V-TELL-NAME>
+
+<SYNTAX THANK OBJECT = V-THANK>
+<SYNONYM THANK THANKS>
+
+<SYNTAX THROW OBJECT (HELD CARRIED) = V-THROW PRE-THROW>
+<SYNTAX THROW OBJECT OBJECT = V-FLIPSWITCH>
+<SYNTAX THROW OBJECT (HELD CARRIED) UP OBJECT (FIND RLANDBIT)
+	= V-THROW PRE-THROW>
+<SYNTAX THROW OBJECT (HELD CARRIED) AT OBJECT (ON-GROUND IN-ROOM)
+	= V-THROW PRE-THROW>
+<SYNTAX THROW OBJECT (HELD CARRIED) TO OBJECT (ON-GROUND IN-ROOM)
+	= V-THROW PRE-THROW>
+<SYNTAX THROW OBJECT (HELD CARRIED) OFF OBJECT = V-THROW-OFF>
+<SYNTAX THROW OBJECT (HELD CARRIED) OVER OBJECT = V-THROW-OFF>
+<SYNTAX THROW OBJECT (HELD CARRIED) THROUGH OBJECT (ON-GROUND IN-ROOM)
+	= V-THROW PRE-THROW>
+<SYNTAX THROW OBJECT (HELD CARRIED) IN OBJECT = V-THROW PRE-THROW>
+<SYNTAX THROW IN OBJECT = V-THROW-IN-TOWEL>
+<SYNONYM THROW HURL TOSS>
+
+<SYNTAX TIE OBJECT = V-TIE>
+<SYNTAX TIE TOGETHER OBJECT = V-TIE-TOGETHER>
+<SYNTAX TIE OBJECT (HELD MANY) AROUND OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX TIE OBJECT TO OBJECT = V-PLUG>
+<SYNONYM TIE FASTEN SECURE ATTACH>
+
+<SYNTAX TOUCH OBJECT (FIND DARKBIT) = V-RUB>
+<SYNTAX TOUCH OBJECT WITH OBJECT = V-RUB>
+<SYNONYM TOUCH FEEL PAT PET RUB>
+
+<SYNTAX TYPE = V-TYPE>
+<SYNTAX TYPE ON OBJECT = V-TYPE-ON>
+
+<SYNTAX UNLOCK OBJECT = V-UNLOCK>
+<SYNTAX UNLOCK OBJECT WITH OBJECT (HAVE) = V-UNLOCK>
+
+<SYNTAX UNPLUG OBJECT = V-UNPLUG>
+<SYNONYM UNPLUG DISCON>
+
+<SYNTAX UNTIE OBJECT (ON-GROUND IN-ROOM HELD CARRIED) = V-UNTIE>
+<SYNONYM UNTIE FREE UNFAST UNATTA UNKNOT>
+
+<SYNTAX WAIT = V-WAIT>
+<SYNTAX WAIT FOR OBJECT = V-WAIT-FOR>
+<SYNONYM WAIT Z STAY>
+
+<SYNTAX WAKE OBJECT (FIND RLANDBIT) = V-ALARM>
+<SYNTAX WAKE UP OBJECT (FIND RLANDBIT) = V-ALARM>
+<SYNONYM WAKE AWAKE ROUSE>
+
+<SYNTAX WALK = V-WALK-AROUND>
+<SYNTAX WALK OBJECT = V-WALK>
+<SYNTAX WALK IN OBJECT = V-THROUGH>
+<SYNTAX WALK OUT OBJECT = V-THROUGH>
+<SYNTAX WALK ON OBJECT = V-WALK-AROUND>
+<SYNTAX WALK OVER OBJECT = V-LEAP>
+<SYNTAX WALK THROUGH OBJECT = V-THROUGH>
+<SYNTAX WALK AROUND OBJECT = V-WALK-AROUND>
+<SYNTAX WALK BEHIND OBJECT = V-WALK-AROUND>
+<SYNTAX WALK UP OBJECT (ON-GROUND IN-ROOM) = V-CLIMB-UP>
+<SYNTAX WALK DOWN OBJECT (ON-GROUND IN-ROOM) = V-CLIMB-DOWN>
+<SYNTAX WALK TO OBJECT = V-WALK-TO>
+<SYNTAX WALK AWAY OBJECT (FIND RLANDBIT) = V-LEAVE>
+<SYNONYM WALK GO RUN PROCEE STEP>
+
+<SYNTAX WASH OBJECT = V-CLEAN>
+<SYNTAX WASH UP OBJECT (FIND RLANDBIT) = V-CLEAN>
+<SYNONYM WASH CLEAN TIDY>
+
+<SYNTAX WATER OBJECT WITH OBJECT (HAVE) = V-WATER>
+
+<SYNTAX WAVE OBJECT (HELD CARRIED) = V-WAVE>
+<SYNTAX WAVE = V-WAVE-AT>
+<SYNTAX WAVE AT OBJECT = V-WAVE-AT>
+<SYNTAX WAVE TO OBJECT = V-WAVE-AT>
+
+<SYNTAX WEAR OBJECT (FIND WEARBIT) (HAVE) = V-WEAR>
+<SYNONYM WEAR DON>
+
+<SYNTAX WHAT OBJECT = V-WHAT>
+<SYNTAX WHAT ABOUT OBJECT = V-WHAT-ABOUT>
+<SYNTAX WHAT OBJECT OBJECT = V-WHAT-TIME>
+<SYNONYM WHAT WHATS WHAT\'>
+
+<SYNTAX WHERE OBJECT = V-WHERE>
+<SYNONYM WHERE WHERES>
+
+<SYNTAX WHO OBJECT = V-WHO>
+<SYNONYM WHO WHOS>
+
+<SYNTAX WHY = V-WHY>
+
+<SYNTAX DRAPE OBJECT IN OBJECT (HELD MANY) = V-SPUT-ON>
+<SYNTAX DRAPE OBJECT (HELD MANY) ON OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX DRAPE OBJECT (HELD MANY) AROUND OBJECT = V-PUT-ON PRE-PUT>
+<SYNTAX DRAPE OBJECT (HELD MANY) OVER OBJECT = V-PUT-ON PRE-PUT>
+<SYNONYM DRAPE WRAP>
+
+<SYNTAX YELL = V-YELL>
+<SYNTAX YELL AT OBJECT = V-YELL>
+<SYNTAX YELL TO OBJECT = V-YELL>
+<SYNONYM YELL SCREAM SHOUT HOWL>
+
+<SYNTAX YES = V-YES>
+<SYNONYM YES Y OK OKAY SURE>
\ No newline at end of file
diff --git a/unearth.zil b/unearth.zil
new file mode 100644
index 0000000..3dc13a5
--- /dev/null
+++ b/unearth.zil
@@ -0,0 +1,1566 @@
+"UNEARTH for
+		  THE HITCHHIKER'S GUIDE TO THE GALAXY
+	(c) Copyright 1984 Infocom, Inc.  All Rights Reserved."
+
+;"Traal stuff"
+
+<OBJECT LAIR-OBJECT
+	(IN LOCAL-GLOBALS)
+	(DESC "lair")
+	(SYNONYM LAIR COURTY YARD)
+	(ADJECTIVE COURT INNER OUTER)
+	(ACTION LAIR-OBJECT-F)>
+
+<ROUTINE LAIR-OBJECT-F ()
+	 <COND (<VERB? LEAVE EXIT DISEMBARK THROUGH BOARD WALK-TO>
+		<V-WALK-AROUND>)>>
+
+<ROOM LAIR
+      (IN ROOMS)
+      (DESC "Lair")
+      (EAST TO OUTER-LAIR)
+      (SW PER INNER-LAIR-ENTER-F)
+      (FLAGS RLANDBIT ONBIT)
+      (GLOBAL LAIR-OBJECT)
+      (ACTION LAIR-F)>
+
+<ROUTINE INNER-LAIR-ENTER-F ()
+	 <COND (<FSET? ,BEAST ,MUNGEDBIT>
+		,INNER-LAIR)
+	       (T
+		<TELL "The Beast blocks the exit." CR>
+		<RFALSE>)>>
+
+<ROUTINE LAIR-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL "This is the lair of the " D ,BEAST
+". There are exits east and southwest." CR>)
+	       (<AND <EQUAL? .RARG ,M-END>
+		     <NOT <FSET? ,LAIR ,NDESCBIT>>>
+		<SETG DREAMING T>
+		<FSET ,LAIR ,NDESCBIT>
+		<FCLEAR ,SARCASTIC-NAME ,INVISIBLE>
+		<FCLEAR ,BEAST-NAME ,INVISIBLE>
+		<ENABLE <QUEUE I-BEAST 2>>
+		<CRLF>
+		<TELL
+"The Beast whips its evil-smelling tail away from your nose and bellows a
+brain-shattering roar. By suddenly popping out of nowhere you have disturbed
+its train of thought. However, ">
+		<COND (<FSET? ,LAIR ,REVISITBIT>
+		       <TELL
+"the Beast is beginning to get used to this sort of thing, shrugs it off,
+and sinks ten or so of" ,CLAWS>
+		       <JIGS-UP " into you.">
+		       <RTRUE>)
+		      (T
+		       <TELL
+"since its train of thought was the usual one, and in fact the only one it
+knows, which goes like this \"hungry ... hungry ... hungry ... hungry ...
+bad-tempered ... hungry ...\", it soon starts to chug along again." CR CR
+,BEAST-DESC " It advances on you, and roars out a demand that you say your
+name." CR>)>)>>
+
+<GLOBAL NAME-TOLD <>>
+
+<GLOBAL BEARINGS-LOST <>>
+
+<GLOBAL BEAST-COUNTER 0>
+
+<ROOM OUTER-LAIR
+      (IN ROOMS)
+      (DESC "Beast's Outer Lair")
+      (WEST TO LAIR)
+      (FLAGS RLANDBIT ONBIT OUTSIDEBIT)
+      (PSEUDO "BONE" UNIMPORTANT-THING-F "BONES" UNIMPORTANT-THING-F)
+      (GLOBAL LAIR-OBJECT)
+      (ACTION OUTER-LAIR-F)>
+
+<ROUTINE OUTER-LAIR-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a large walled courtyard. Strewn about are a profusion of gnawed bones
+bleaching in the sun. In case the significance of these fails to strike you,
+there is also a " D ,MEMORIAL " in the middle of the courtyard, on which the
+Beast has roughly carved the names of all its victims.">
+		<COND (<IN? ,STONE ,HERE>
+		       <TELL CR
+"Some " D ,STONE "s lie near the exit to the west.">)>
+		<CRLF>)>>
+
+<OBJECT MEMORIAL
+	(IN OUTER-LAIR)
+	(DESC "sandstone memorial")
+	(SYNONYM MEMORI LIST REMEMB MONUME)
+	(ADJECTIVE SANDST)
+	(FLAGS NDESCBIT READBIT)
+	(ACTION MEMORIAL-F)>
+
+<ROUTINE MEMORIAL-F ()
+	 <COND (<AND <VERB? CARVE>
+		     <EQUAL? ,MEMORIAL ,PRSI>>
+		<COND (<FSET? ,BEAST ,MUNGEDBIT>
+		       <V-DIG>)
+		      (<PRSO? ,NAME>
+		       <TELL
+"Whose name? The " D ,BEAST-NAME "? Your aunt's name? One of the Infinite
+Unknowable names of Buddha? How about the name of Fred who runs (or rather
+ran) your local chip shop? At least that's a short name -- you might have
+time to write it before the Beast eats you." CR>)
+		      (<PRSO? ,SARCASTIC-NAME>
+		       <TELL
+"Concentrate. Learn to distinguish between genuinely helpful suggestions
+and mere sarcasm." CR>)
+		      (<NOT <FSET? ,TOWEL ,WORNBIT>>
+		       <ENABLE <QUEUE I-BEAST 2>>
+		       <TELL
+"Before you even chip the first letter, the Beast sees you and hurls you
+spinning away with a bellow of rage." ,GETTING-CLOSE CR>)
+		      (,BEARINGS-LOST
+		       <TELL
+"You cannot see and have lost your bearings. You stumble hopelessly and begin
+to arouse the Beast's suspicions. It's stupid but not THAT stupid." CR>)
+		      (<PRSO? ,YOUR-NAME ,ARTHUR ,ME>
+		       <COND (<FSET? ,BEAST ,MUNGEDBIT>
+			      <TELL "You already did that!" CR>
+			      <RTRUE>)>
+		       <TELL
+"You chip away with the stone. It's not your best writing, what with
+your mounting sense of panic and a towel wrapped around your head.
+However, it suffices..." CR CR ,JUST-AS>
+		       <COND (,NAME-TOLD
+			      <FSET ,BEAST ,MUNGEDBIT>
+			      <ENABLE <QUEUE I-BEAST 9>>
+			      <TELL
+"suddenly sees your name freshly carved on its memorial of remembrance.
+Mystery solved. It realises it must have already eaten you in a fit of
+absent-mindedness. (Its mind is very very small and quite frequently absent.)
+It decides to give up the rest of its afternoon to the twin arts of
+digestion and contemplation. It settles down for a snooze." CR>)
+			     (T
+			      <TELL
+"sees \"" D ,ARTHUR "\" freshly carved on the " D ,MEMORIAL ". This
+doesn't ring any bells with the Beast. It roars with fury, and eyes
+the thing it can't see because it's got a towel on its head (i.e. you)
+with deepening suspicion." CR>)>)
+		      (T
+		       <TELL ,JUST-AS "suddenly sees ">
+		       <COND (<PRSO? ,BEAST ,BEAST-NAME>
+			      <TELL "its own name">)
+			     (T
+			      <TELL "\"" D ,PRSO "\"">)>
+		       <TELL
+" freshly carved on the " D, MEMORIAL ". This disconcerts it, as it has
+no recollection of eating ">
+		       <COND (<PRSO? ,BEAST ,BEAST-NAME>
+			      <TELL "itself">)
+			     (T
+			      <TELL "anyone by that name">)>
+		       <TELL "." ,SLOWLY-DAWNS CR>)>)
+	       (<VERB? READ>
+		<TELL
+"Gleb Snardfitz, Bibs Trench, Zeke Fitzberry, Elmo Smith, ">
+		<COND (<FSET? ,BEAST ,MUNGEDBIT>
+		       <TELL D ,ARTHUR ", ">)>
+		<TELL
+"Brian \"Spike\" Berkowitz, Clybert Quackentotter..." CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"There are countless names carved on the " D ,MEMORIAL ":" CR>
+		<PERFORM ,V?READ ,MEMORIAL>
+		<RTRUE>)>>
+
+<OBJECT STONE
+	(IN OUTER-LAIR)
+	(DESC "sharp stone")
+	(SYNONYM STONE STONES ROCK ROCKS)
+	(ADJECTIVE SHARP)
+	(FLAGS NDESCBIT TAKEBIT TRYTAKEBIT)
+	(SIZE 20)
+	(ACTION STONE-F)>
+
+<ROUTINE STONE-F ()
+	 <COND (<AND <VERB? TAKE>
+		     <FSET? ,STONE ,TRYTAKEBIT>>
+		<FCLEAR ,STONE ,NDESCBIT>
+		<FCLEAR ,STONE ,TRYTAKEBIT>
+		<RFALSE>)
+	       (<AND <VERB? DROP>
+		     <EQUAL? ,HERE ,OUTER-LAIR>>
+		<FSET ,STONE ,NDESCBIT>
+		<FSET ,STONE ,TRYTAKEBIT>
+		<RFALSE>)
+	       (<VERB? EXAMINE>
+		<TELL "It's hard as a rock." CR>)>>
+
+<OBJECT BEAST
+	(IN LAIR)
+	(DESC "Ravenous Bugblatter Beast of Traal")
+	(DESCFCN BEAST-DESCFCN)
+	(SYNONYM BEAST TRAAL)
+	(ADJECTIVE RAVENO BUGBLA BEAST)
+	(FLAGS ACTORBIT)
+	(ACTION BEAST-F)>
+
+<ROUTINE BEAST-DESCFCN ("OPTIONAL" X)
+	 <COND (<FSET? ,BEAST ,MUNGEDBIT>
+		<TELL
+"The Beast is in the corner, sleeping peacefully (Footnote 5)." CR>)
+	       (T
+		<TELL
+"The " D ,BEAST " is here, looking particularly nasty and hungry." CR>)>>
+
+<ROUTINE BEAST-F ()
+	 <COND (<EQUAL? ,BEAST ,WINNER>
+		<COND (<FSET? ,TOWEL ,WORNBIT>
+		       <V-SAY>)
+		      (<AND <VERB? TELL-ABOUT>
+			    <PRSO? ,ME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,BEAST ,PRSI>
+		       <SETG WINNER ,BEAST>
+		       <RTRUE>)
+		      (<VERB? HELLO>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?HELLO ,BEAST>
+		       <SETG WINNER ,BEAST>
+		       <RTRUE>)
+		      (<AND <VERB? WHAT>
+			    <PRSO? ,OBJECT-OF-GAME>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?ASK-ABOUT ,BEAST ,OBJECT-OF-GAME>
+		       <SETG WINNER ,BEAST>
+		       <RTRUE>)
+		      (<AND <NOT ,NAME-TOLD>
+			    <VERB? MY-NAME>
+			    <PRSO? ,NAME>>
+		       <COND (<PRSI? ,ARTHUR>
+			      <SETG WINNER ,PROTAGONIST>
+			      <PERFORM ,V?SAY-NAME ,YOUR-NAME>
+			      <SETG WINNER ,BEAST>
+			      <RTRUE>)
+			     (T
+			      <SETG WINNER ,PROTAGONIST>
+			      <PERFORM ,V?SAY-NAME ,BEAST-NAME>
+			      <SETG WINNER ,BEAST>
+			      <RTRUE>)>)
+		      (<AND <NOT ,NAME-TOLD>
+			    <VERB? I-AM>>
+		       <COND (<PRSO? ,ARTHUR>
+			      <SETG WINNER ,PROTAGONIST>
+			      <PERFORM ,V?SAY-NAME ,YOUR-NAME>
+			      <SETG WINNER ,BEAST>
+			      <RTRUE>)
+			     (T
+			      <SETG WINNER ,PROTAGONIST>
+			      <PERFORM ,V?SAY-NAME ,BEAST-NAME>
+			      <SETG WINNER ,BEAST>
+			      <RTRUE>)>)
+		      (T
+		       <TELL "The Beast just roars at you." CR>
+		       <FUCKING-CLEAR>)>)
+	       (<AND <VERB? TELL HELLO ASK-ABOUT ASK-FOR TELL-ABOUT>
+		     <PRSO? ,BEAST>>
+		<COND (<FSET? ,BEAST ,MUNGEDBIT>
+		       <TELL "The Beast is sleeping!" CR>
+		       <FUCKING-CLEAR>)
+		      (<FSET? ,TOWEL ,WORNBIT>
+		       <SAID-WITH-TOWEL>
+		       <FUCKING-CLEAR>)>)
+	       (<AND <VERB? TELL-TIME>
+		     <PRSI? ,YOUR-NAME>>
+		<PERFORM ,V?SAY-NAME ,YOUR-NAME>
+		<RTRUE>)
+	       (<AND <VERB? TELL-NAME>
+		     <PRSO? ,YOUR-NAME>>
+		<PERFORM ,V?SAY-NAME ,YOUR-NAME>
+		<RTRUE>)
+	       (<AND <VERB? SHOW GIVE>
+		     <EQUAL? ,THING ,PRSO>>
+		<ENABLE <QUEUE I-BEAST 2>>
+		<TELL
+"The Beast stops in its tracks, deeply impressed, and compliments you on the
+quality of your aunts, and complains that all its aunts are complete horrors.
+It then continues its dreadful attack." CR>)
+	       (<AND <VERB? THROW>
+		     <PRSI? ,BEAST>
+		     <NOT <IDROP>>>
+		<MOVE ,PRSO ,HERE>
+		<PERFORM ,V?KILL ,BEAST>
+		<RTRUE>)
+	       (<AND <VERB? KILL>
+		     <PRSO? ,BEAST>>
+		<COND (<FSET? ,BEAST ,MUNGEDBIT>
+		       <PERFORM ,V?ALARM ,BEAST>
+		       <RTRUE>)>
+		<ENABLE <QUEUE I-BEAST 2>>
+		<TELL "A footling effort. The shock waves of the Beast's
+laughter push you back." CR>)
+	       (<AND <VERB? ALARM>
+		     <FSET? ,BEAST ,MUNGEDBIT>>
+		<TELL "The Beast casually brushes you away with one of" ,CLAWS>
+		<JIGS-UP ".">
+		<RTRUE>)
+	       (<AND <VERB? ASK-ABOUT>
+		     <PRSI? ,OBJECT-OF-GAME>>
+		<TELL
+"\"Eat. Carve name on memorial. Sleep. Eat more. Roar a lot. Stuff like
+that.\"" CR>)
+	       (<VERB? EXAMINE>
+		<TELL ,BEAST-DESC CR>)>>
+
+<ROUTINE I-BEAST ()
+	 <ENABLE <QUEUE I-BEAST -1>>
+	 <CRLF>
+	 <COND (<FSET? ,BEAST ,MUNGEDBIT>
+		<MOVE ,CHIPPER ,PROTAGONIST>
+		<FCLEAR ,LAIR ,NDESCBIT>
+		<FSET ,LAIR ,REVISITBIT>
+		<JIGS-UP
+"Suddenly a team of Fronurbdian Beasthunters charges in, intent on catching
+the Beast for their zoo. Mistaking you for the Beast, they fire stun guns at
+you, wrap you in nets, and install you in a lovely little lair in the
+Fronurbdi National Zoo.|
+|
+Three months later the error is discovered, but while your damage suit is
+pending in the Fronurbdian courts the planet is invaded by Bureaucratic Pirates
+from Pallidon IV. Impressed into bondage for a 16-year filing and sorting
+mission on the so-called \"basement world\" of Sporla in the Lesser Magellanic
+Cloud, you escape with the help of a tribe of nomadic asteroid painters.|
+|
+You develop a unique talent for asteroid painting, gaining considerable fame
+throughout the Cloud. A nickel-ore deluxe is commissioned by His Royal Gorpness
+Orbjfelk, the ruler of the Nine Hundred Worlds of Gorp, but while working on
+this new masterpiece your asteroid slips into a small passing black hole.">
+		<RTRUE>)
+	       (<FSET? ,TOWEL ,WORNBIT>
+		<TELL
+"The Beast still thinks it can't see you, but it's so irritated at having
+an invisible object stumble around its lair that it swipes out angrily
+with one of" ,CLAWS>
+		<JIGS-UP
+" and life in the Universe has to carry on without you.">
+		<RTRUE>)
+	       (<NOT <IN? ,BEAST ,HERE>>
+		<MOVE ,BEAST ,HERE>
+		<MOVE ,NAME ,HERE>
+		<SETG BEAST-COUNTER 0>
+		<TELL "Bellowing with rage, the Beast charges after you." CR>)
+	       (T
+		<SETG BEAST-COUNTER <+ ,BEAST-COUNTER 1>>
+		<COND (<EQUAL? ,BEAST-COUNTER 1>
+		       <TELL
+"With a headsplitting roar, the " D ,BEAST " charges towards you." CR>)
+		      (<AND <EQUAL? ,BEAST-COUNTER 2>
+			    <NOT ,NAME-TOLD>>
+		       <TELL
+"The Beast, sharpening" ,CLAWS ", demands again that you say your name." CR>)
+		      (<G? ,BEAST-COUNTER 4>
+		       <BEAST-DEATH>)
+		      (T
+		       <TELL "The Beast is nearly upon you." CR>)>)>>
+
+<ROUTINE BEAST-DEATH ()
+	 <TELL
+"With a vast savage roar, the Beast tears you limb from limb with" ,CLAWS>
+	 <JIGS-UP " and ... well, do you really want to know the rest?
+The point is that you have died.">
+	 <RTRUE>>
+
+<OBJECT NAME ;"for things like MY NAME IS..."
+	(IN BEDROOM)
+	(DESC "name")
+	(SYNONYM NAME)
+	(FLAGS NDESCBIT)>
+
+<OBJECT SARCASTIC-NAME
+	(IN GLOBAL-OBJECTS)
+	(DESC "other name")
+	(SYNONYM NAME BUDDHA AUNT FRED)
+	(ADJECTIVE AUNT\'S FRED\'S BUDDHA)
+	(FLAGS VOWELBIT INVISIBLE)>
+
+<OBJECT YOUR-NAME
+	(IN GLOBAL-OBJECTS)
+	(DESC "your name")
+	(SYNONYM NAME)
+	(ADJECTIVE YOUR MY ARTHUR)
+	(FLAGS NARTICLEBIT)
+	(ACTION YOUR-NAME-F)>
+
+<ROUTINE YOUR-NAME-F ()
+	 <COND (<VERB? WHAT>
+		<PERFORM ,V?WHO ,ME>
+		<RTRUE>)
+	       (<AND <EQUAL? ,HERE ,OUTER-LAIR>
+		     <FSET? ,BEAST ,MUNGEDBIT>>
+		<RFALSE>)
+	       (<VERB? EXAMINE RUB MOVE>
+		<TELL "Huh?" CR>)>>
+
+<OBJECT BEAST-NAME
+	(IN GLOBAL-OBJECTS)
+	(DESC "Beast's name")
+	(SYNONYM NAME)
+	(ADJECTIVE BEAST)
+	(FLAG NARTICLEBIT INVISIBLE)>
+
+<ROOM INNER-LAIR
+      (IN ROOMS)
+      (DESC "Inner Lair")
+      (LDESC
+"This is the heart of the Beast's lair. The only exit leads northeast.")
+      (NE TO LAIR)
+      (FLAGS ONBIT RLANDBIT)
+      (GLOBAL LAIR-OBJECT)>
+
+<OBJECT SKELETON
+	(IN INNER-LAIR)
+	(DESC "skeleton")
+	(FDESC
+"The skeleton of a dead Beasthunter lies nearby, clutching something labelled
+\"Nutrimat/Computer Interface.\"") 
+	(SYNONYM SKELETON BEASTH BONE BONES)
+	(FLAGS RLANDBIT TRYTAKEBIT)>
+
+<OBJECT NUT-COM-INTERFACE
+	(IN INNER-LAIR)
+	(DESC "Nutrimat/Computer Interface")
+	(SYNONYM INTERF)
+	(ADJECTIVE NUTRIM COMPUT)
+	(FLAGS NDESCBIT TRYTAKEBIT TAKEBIT)
+	(SIZE 4)
+	(ACTION NUT-COM-INTERFACE-F)>
+
+<ROUTINE NUT-COM-INTERFACE-F ()
+	 <COND (<AND <VERB? TAKE>
+		     <FSET? ,NUT-COM-INTERFACE ,TRYTAKEBIT>>
+		<FCLEAR ,NUT-COM-INTERFACE ,TRYTAKEBIT>
+		<FCLEAR ,NUT-COM-INTERFACE ,NDESCBIT>
+		<FSET ,SKELETON ,TOUCHBIT>
+		<SETG SCORE <+ ,SCORE 25>>
+		<RFALSE>)
+	       (<AND <VERB? TAKE>
+		     <RUNNING? ,I-TEA>>
+		<TELL "You get a powerful electric shock." CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"The " D ,PRSO " is square, about ten inches on each side.">
+		<FINE-PRODUCT>
+		<CRLF>)>>
+
+;"V'lhurgs and G'Gugvuntts stuff"
+
+<ROUTINE I-CARELESS-WORDS ()
+	 <CRLF>
+	 <SETG FLEET-PROB 60>
+	 <TELL
+"It is of course well known that careless talk costs lives, but the full
+scale of the problem is not always appreciated. For instance, at the exact
+moment you said \"">
+	 <RESTORE-INPUT ,FIRST-BUFFER>
+	 <TELL "\" a freak wormhole opened in the fabric of the space-time
+continuum and carried your words far far back in time across almost infinite
+reaches of space to a distant galaxy where strange and warlike beings were
+poised on the brink of frightful interstellar battle.|
+|
+The two opposing leaders were meeting for the last time. A dreadful silence
+fell across the conference table as the commander of the Vl'Hurgs, resplendent
+in his" ,BATTLE-SHORTS "gazed levelly at the " D ,GGUGVUNT " squatting opposite
+him" ,CLOUD-OF-STEAM "As a million sleek and horribly beweaponed star cruisers
+poised to unleash electric death at his single word of command, the Vl'Hurg
+challenged his vile enemy to take back what it had said about his mother.|
+|
+The creature stirred in its sickly broiling vapour, and at that very moment
+the words \"">
+	 <RESTORE-INPUT ,FIRST-BUFFER>
+	 <TELL "\" drifted across the conference table.
+Unfortunately, in the Vl'hurg tongue this was the most dreadful insult
+imaginable, and there was nothing for it but to wage terrible war for
+centuries. Eventually the error was detected, but over two hundred and
+fifty thousand worlds, their peoples and cultures perished in the holocaust.|
+|
+You have destroyed most of a small galaxy. Please pick your words with
+greater care." CR>>
+
+<GLOBAL CARELESS-WORDS-FLAG <>>
+
+<GLOBAL DOG-COUNTER 0>
+
+<OBJECT MICROSCOPIC-FLEET
+	(IN WAR-CHAMBER)
+	(DESC "battle fleet")
+	(SYNONYM FLEET SHIP SHIPS SPACES)
+	(ADJECTIVE BATTLE HORRIB BEWEAP MICROS SPACE VAST)
+	(FLAGS NDESCBIT)
+	(ACTION MICROSCOPIC-FLEET-F)>
+
+<ROUTINE MICROSCOPIC-FLEET-F ()
+	 <COND (<VERB? THROUGH>
+		<TELL ,LOOK-AROUND CR>)>>
+
+<OBJECT CANOPY
+	(IN WAR-CHAMBER)
+	(DESC "domed canopy")
+	(SYNONYM CANOPY DOME WINDOW)
+	(ADJECTIVE DOMED)
+	(FLAGS NDESCBIT TRANSBIT)
+	(ACTION CANOPY-F)>
+
+<ROUTINE CANOPY-F ()
+	 <COND (<VERB? LOOK-INSIDE>
+		<TELL "Through the " D ,CANOPY " of the ship you can see a
+vast " D ,MICROSCOPIC-FLEET " flying in formation behind you through the
+black, glittering emptiness of space. Ahead is a star system towards which
+you are hurtling at a terrifying speed." CR>)>>
+
+<ROOM WAR-CHAMBER
+      (IN ROOMS)
+      (SYNONYM WALKIN)
+      (DESC "War Chamber")
+      (FLAGS RLANDBIT ONBIT)
+      (GLOBAL CONVERSATION)
+      (ACTION WAR-CHAMBER-F)>
+
+<ROUTINE WAR-CHAMBER-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<FCLEAR ,CONVERSATION ,INVISIBLE>
+		<MOVE ,THIRD-PLANET ,HERE>
+		<SETG DREAMING T>
+		<ENABLE <QUEUE I-DOG -1>>
+		<RFALSE>)
+	       (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"Spread before you, astonishingly enough, is the " D ,WAR-CHAMBER " of a star
+battle cruiser. ">
+		<PERFORM ,V?LOOK-INSIDE ,CANOPY>
+		<RTRUE>)>>
+
+<OBJECT VLHURG
+	(IN WAR-CHAMBER)
+	(DESC "Vl'Hurg leader")
+	(DESCFCN VLHURG-DESCFCN)
+	(SYNONYM VL\'HUR LEADER CREATU)
+	(ADJECTIVE VL\'HUR)
+	(FLAGS ACTORBIT)
+	(ACTION VLHURG-F)>
+
+<ROUTINE VLHURG-DESCFCN ("OPTIONAL" X)
+	 <TELL CR
+"Standing near you are two creatures who are gazing at the star system with
+terrible hatred in their eyes. One is wearing" ,BATTLE-SHORTS "and the other
+is wreathed" ,CLOUD-OF-STEAM "They are engaged in " D ,CONVERSATION "." CR>>
+
+<ROUTINE VLHURG-F ()
+	 <COND (<VERB? TELL>
+		<TELL
+"You are clearly the worst diplomat that ever lived, and are about to become
+the worst one that ever died. That is an even worse insult in the G'Gugvunt
+tongue than \"">
+		<RESTORE-INPUT ,FIRST-BUFFER>
+		<TELL "\" is in the Vl'Hurg tongue." CR>
+		<FUCKING-CLEAR>)
+	       (<VERB? EXAMINE>
+		<TELL "The " D ,VLHURG " looks typically Vl'Hurgish." CR>)
+	       (<VERB? LISTEN>
+		<COND (<FSET? ,VLHURG ,MUNGEDBIT>
+		       <TELL
+"The creatures are speculating about who you are and what to do with you." CR>)
+		      (T
+		       <FSET ,VLHURG ,MUNGEDBIT>
+		       <TELL
+"  \"Hated planet!\" snarls the Vl'Hurg.|
+  \"Home of he that dared to say '">
+		       <RESTORE-INPUT ,FIRST-BUFFER>
+		       <TELL
+"'\" rasps the G'Gugvunt.|
+  \"Detested words! Even now it sticks my soul to hear them uttered,\"
+barks the Vl'Hurg, \"even though ten thousand years have passed...\"|
+  \"And as many senseless megadeaths! Worlds destroyed! My race and
+yours laid to waste! All because of he that dared shape the words '">
+		       <RESTORE-INPUT ,FIRST-BUFFER>
+		       <TELL "'.\"|
+  \"Torture to my Vl'Hurgish warrior heart to hear it spoken! Yet, even
+now, the hot breath of our vengeance blows hard upon this little world...\"|
+  \"Vengeance on him who said '">
+		       <RESTORE-INPUT ,FIRST-BUFFER>
+		       <TELL "'.\"|
+  \"Yes, there's no need to keep repeating it,\" growls the Vl'Hurg.|
+  \"One happy thought,\" adds the G'Gugvunt. \"After millenia of bloody
+and perpetual conflict, our races have been brought together by this
+Quest for the Source of the Offending Remark. Perhaps, after our vengeance
+has been exacted on him who said '">
+		       <RESTORE-INPUT ,FIRST-BUFFER>
+		       <TELL "'...\"|
+  \"Will you stop saying it?\"|
+  \"...perhaps we will continue to live in peace and harmony and...\"|
+  \"We will talk about that AFTER we ... who's this?\"|
+|
+The two creatures turn and stare at you." CR>)>)>>
+
+<OBJECT GGUGVUNT
+	(IN WAR-CHAMBER)
+	(DESC "G'Gugvunt leader")
+	(SYNONYM G\'GUGV LEADER CREATU)
+	(ADJECTIVE G\'GUGV)
+	(FLAGS ACTORBIT NDESCBIT)
+	(ACTION GGUGVUNT-F)>
+
+<ROUTINE GGUGVUNT-F ()
+	 <COND (<VERB? TELL>
+		<PERFORM ,V?TELL ,VLHURG>
+		<FUCKING-CLEAR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"The " D ,GGUGVUNT " is looking typically G'Gugvuntish." CR>)
+	       (<VERB? LISTEN>
+		<PERFORM ,V?LISTEN ,VLHURG>
+		<RTRUE>)>>
+
+<OBJECT OTHER-PLANETS
+	(IN WAR-CHAMBER)
+	(DESC "other planets")
+	(SYNONYM PLANET)
+	(ADJECTIVE OTHER)
+	(FLAGS NDESCBIT VOWELBIT NARTICLEBIT)>
+
+<OBJECT THIRD-PLANET
+	(IN LOCAL-GLOBALS)
+	(DESC "third planet")
+	(SYNONYM PLANET EARTH)
+	(ADJECTIVE THIRD BLUE BLUE- GREEN SMALL)
+	(FLAGS NDESCBIT)
+	(ACTION THIRD-PLANET-F)>
+
+<ROUTINE THIRD-PLANET-F ()
+	 <COND (<NOT ,EARTH-DEMOLISHED>
+		<COND (<PRSO? ,THIRD-PLANET>
+		       <PERFORM ,PRSA ,GROUND ,PRSI>
+		       <RTRUE>)
+		      (T
+		       <PERFORM ,PRSA ,PRSO ,GROUND>)>)
+	       (<VERB? LEAVE DISEMBARK>
+		<TELL "You did!" CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"It is an utterly insignificant little blue-green planet, of the sort
+where they probably still wear " D ,DIGITAL-WATCH "es." CR>)>>
+
+<ROOM MAZE
+      (IN ROOMS)
+      (SYNONYM INFOCO ADAMS MERETZ)
+      (ADJECTIVE DOUGLA STEVE STEVEN)
+      (DESC "Maze")
+      (LDESC
+"This is part of a spongy gray maze of twisty little synapses, all alike.")
+      (NORTH PER MAZE-EXIT-F)
+      (NE PER MAZE-EXIT-F)
+      (EAST PER MAZE-EXIT-F)
+      (SE PER MAZE-EXIT-F)
+      (SOUTH PER MAZE-EXIT-F)
+      (SW PER MAZE-EXIT-F)
+      (WEST PER MAZE-EXIT-F)
+      (NW PER MAZE-EXIT-F)
+      (UP PER MAZE-EXIT-F)
+      (DOWN PER MAZE-EXIT-F)
+      (IN PER MAZE-EXIT-F)
+      (OUT PER MAZE-EXIT-F)
+      (FLAGS RLANDBIT ONBIT)
+      (PSEUDO "MAZE" GLOBAL-ROOM-F)>
+
+<GLOBAL MAZE-COUNTER 0>
+
+<GLOBAL BRAIN-DAMAGED <>>
+
+<ROUTINE MAZE-EXIT-F ()
+	 <COND (<PROB 40>
+		<TELL
+"An electrical impulse across a synapse gap temporarily blocks your way." CR>)
+	       (T
+		<SETG MAZE-COUNTER <+ ,MAZE-COUNTER 1>>
+		<COND (<EQUAL? ,MAZE-COUNTER 3 17 36>
+		       <MOVE ,PARTICLE ,HERE>)
+		      (T
+		       <MOVE ,PARTICLE ,LOCAL-GLOBALS>)>
+		<V-LOOK>)>
+	 <RFALSE>>
+
+<OBJECT BRAIN
+	(IN MAZE)
+	(DESC "brain")
+	(SYNONYM BRAIN)
+	(ADJECTIVE MY YOUR)
+	(FLAGS NDESCBIT)
+	(ACTION GLOBAL-ROOM-F)>
+
+<OBJECT SYNAPSE
+	(IN MAZE)
+	(DESC "synapse")
+	(SYNONYM SYNAPS GAP)
+	(ADJECTIVE SYNAPS)
+	(FLAGS NDESCBIT)>
+
+<OBJECT PARTICLE
+	(IN LOCAL-GLOBALS) ;"just for the purpose of MOBY-FIND"
+	(DESC "particle")
+	(LDESC
+"Blocking the gap between two synapses is a large black particle. There seem
+to be some faint markings on it.")
+	(SYNONYM PARTIC SENSE LETTER MARKIN)
+	(ADJECTIVE LARGE BLACK COMMON FAINT)
+	(FLAGS TAKEBIT TRYTAKEBIT READBIT)
+	(ACTION PARTICLE-F)>
+
+<ROUTINE PARTICLE-F ()
+	 <COND (<VERB? TAKE MOVE>
+		<MOVE ,PARTICLE ,LOCAL-GLOBALS>
+		<FSET ,PARTICLE ,MUNGEDBIT>
+		<SETG SCORE <+ ,SCORE 25>>
+		<FSET ,WAR-CHAMBER ,REVISITBIT>
+		<TELL "As you remove the " D ,PARTICLE>
+		<JIGS-UP
+" electrical impulses begin leaping madly across the now-unblocked synaptic
+gap. Unfortunately, YOU were in the gap at the time.">
+		<RTRUE>)
+	       (<VERB? EXAMINE READ>
+		<TELL
+"As you look closer you see, inscribed in tiny letters on the "
+D ,PARTICLE ":|
+|
+  Sense, Common for:|
+     Dent, Arthur|
+   (for replacement,|
+  order part #31-541)" CR>)>>
+
+;"the Party stuff"
+
+<OBJECT APARTMENT
+	(IN LOCAL-GLOBALS)
+	(DESC "apartment")
+	(SYNONYM APARTM)
+	(FLAGS VOWELBIT)
+	(ACTION APARTMENT-F)>
+
+<ROUTINE APARTMENT-F ()
+	 <COND (<VERB? LEAVE EXIT>
+		<COND (<EQUAL? ,HERE ,LIVING-ROOM>
+		       <DO-WALK ,P?SOUTH>)
+		      (T
+		       <V-WALK-AROUND>)>)
+	       (<VERB? THROUGH>
+		<TELL ,LOOK-AROUND CR>)>>
+
+<GLOBAL ITEM-DROPPED-AT-PARTY <>>
+
+<GLOBAL FLUFF-REMOVED <>>
+
+<GLOBAL PARTY-TABLE
+	<TABLE 0 0 0>>
+
+<ROUTINE PARTY-DESC (ROOM)
+	 <TELL "You are in a large " D .ROOM
+". There is a party going on. Other rooms lie to the ">>
+
+<ROOM LIVING-ROOM
+      (IN ROOMS)
+      (DESC "Living Room")
+      (SOUTH PER PARTY-EXIT-F)
+      (WEST TO DINING-ROOM)
+      (SW TO KITCHEN)
+      (FLAGS RLANDBIT ONBIT)
+      (GLOBAL APARTMENT)
+      (PSEUDO "PARTY" APARTMENT-F)
+      (ACTION LIVING-ROOM-F)>
+
+<ROUTINE PARTY-EXIT-F ()
+	  <COND (<FSET? ,APARTMENT-DOOR ,OPENBIT>
+		 <TELL "What! Leave a fun party like this?" CR>
+		 <SETG AWAITING-REPLY 3>
+		 <ENABLE <QUEUE I-REPLY 2>>
+		 <RFALSE>)
+		(T
+		 <TELL "The door is closed." CR>
+		 <SETG P-IT-OBJECT ,APARTMENT-DOOR>
+		 <RFALSE>)>>
+
+<ROUTINE LIVING-ROOM-F (RARG)
+	 <COND (<AND <EQUAL? .RARG ,M-ENTER>
+		     <NOT <EQUAL? ,IDENTITY-FLAG ,TRILLIAN>>>
+		<PUT ,PARTY-TABLE 0 <LOC ,HANDBAG>>
+		<PUT ,PARTY-TABLE 1 <LOC ,TWEEZERS>>
+		<COND (<FSET? ,HANDBAG ,OPENBIT>
+		       <PUT ,PARTY-TABLE 2 T>)
+		      (T
+		       <PUT ,PARTY-TABLE 2 <>>)>
+		<SETG IDENTITY-FLAG ,TRILLIAN>
+		<MOVE ,TRILLIAN ,GLOBAL-OBJECTS>
+		<SETG DREAMING T>
+		<ROB ,PROTAGONIST ,MEMORIAL>
+		<ROB ,HANDBAG ,RAMP>
+		<FCLEAR ,HANDBAG ,OPENBIT>
+		<MOVE ,HANDBAG ,PROTAGONIST>
+		<MOVE ,TWEEZERS ,HANDBAG>
+		<MOVE ,WINE ,PROTAGONIST>
+		<MOVE ,APPETIZERS ,PROTAGONIST>
+		<MOVE ,ARTHUR ,HERE>
+		<MOVE ,PHIL ,HERE>
+		<MOVE ,CAGE ,HERE>
+		<TELL
+"You're at a party being given by a distant and incredibly boring acquaintance.
+Among the people you've been introduced to are a shy, mousy fellow from the
+West Country named Arthur, and a flamboyant guy named Phil. You've had too many
+drinks already, and the room is beginning to buzz..." CR CR>)
+	       (<AND <EQUAL? .RARG ,M-END>
+		     <FSET? ,LIVING-ROOM ,REVISITBIT>>
+		<CRLF>
+		<JIGS-UP
+"The hostess, a lethally dull woman, corners you and bores you to
+death. Literally.">
+		<RTRUE>)
+	       (<EQUAL? .RARG ,M-LOOK>
+		<PARTY-DESC ,LIVING-ROOM>
+		<TELL
+"west and southwest, and the " D ,APARTMENT "'s front door is south of
+here." CR>)>> 
+
+<OBJECT APARTMENT-DOOR
+	(IN LIVING-ROOM)
+	(DESC "door")
+	(SYNONYM DOOR)
+	(FLAGS DOORBIT OPENBIT NDESCBIT)
+	(ACTION APARTMENT-DOOR-F)>
+
+<ROUTINE APARTMENT-DOOR-F ()
+	 <COND (<VERB? THROUGH>
+		<DO-WALK ,P?SOUTH>)>>
+
+<ROOM DINING-ROOM
+      (IN ROOMS)
+      (DESC "Dining Room")
+      (SOUTH TO KITCHEN)
+      (EAST TO LIVING-ROOM)
+      (FLAGS RLANDBIT ONBIT)
+      (GLOBAL APARTMENT)
+      (PSEUDO "PARTY" APARTMENT-F)
+      (ACTION DINING-ROOM-F)>
+
+<ROUTINE DINING-ROOM-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<PARTY-DESC ,DINING-ROOM>
+		<TELL "south and east." CR>)>>
+
+<ROOM KITCHEN
+      (IN ROOMS)
+      (DESC "Kitchen")
+      (NORTH TO DINING-ROOM)
+      (NE TO LIVING-ROOM)
+      (FLAGS RLANDBIT ONBIT)
+      (GLOBAL APARTMENT)
+      (PSEUDO "PARTY" APARTMENT-F)
+      (ACTION KITCHEN-F)>
+
+<ROUTINE KITCHEN-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<PARTY-DESC ,KITCHEN>
+		<TELL "north and northeast." CR>)>>
+
+<OBJECT WINE
+	(IN LOCAL-GLOBALS) ;"just for the purpose of MOBY-FIND"
+	(DESC "glass of white wine")
+	(SYNONYM GLASS WINE)
+	(ADJECTIVE WHITE)
+	(FLAGS TAKEBIT DRINKBIT)
+	(SIZE 15)
+	(ACTION WINE-F)>
+
+<ROUTINE WINE-F ()
+	 <COND (<VERB? DRINK ENJOY>
+		<TELL
+"You take a sip, and the room spins a little faster." CR>)
+	       (<VERB? THROW POUR>
+		<SHRIEK>)
+	       (<VERB? DROP>
+		<DROP-AT-PARTY>)>>
+
+<OBJECT APPETIZERS
+	(IN LOCAL-GLOBALS) ;"just for the purpose of MOBY-FIND"
+	(DESC "plate of hors d'oeuvres")
+	(SYNONYM PLATE D\'OEUV APPETI SNACKS)
+	(ADJECTIVE HORS)
+	(FLAGS TAKEBIT EATBIT)
+	(SIZE 15)
+	(ACTION APPETIZERS-F)>
+
+<ROUTINE APPETIZERS-F ()
+	 <COND (<VERB? EAT ENJOY>
+		<TELL
+"You nibble at one of the hors d'oeuvres. It tastes ">
+		<COND (<PROB 40>
+		       <TELL "okay." CR>)
+		      (<PROB 50>
+		       <TELL "delicious." CR>)
+		      (T
+		       <TELL "terrible." CR>)>)
+	       (<VERB? THROW>
+		<SHRIEK>)
+	       (<VERB? COUNT>
+		<TELL
+"More than three, which is as high as you can count in your condition." CR>)
+	       (<VERB? DROP>
+		<DROP-AT-PARTY>)>>
+
+<ROUTINE DROP-AT-PARTY ()
+	 <COND (<NOT ,ITEM-DROPPED-AT-PARTY>
+		<SETG ITEM-DROPPED-AT-PARTY ,PRSO>
+		<FSET ,HOSTESS ,NDESCBIT>
+	 	<ENABLE <QUEUE I-HOSTESS 3>>)>
+	 <MOVE ,PRSO ,HERE>
+	 <COND (<VERB? DROP>
+		<TELL "Dropped." CR>)
+	       (T
+		<TELL "Thrown." CR>)>>
+
+<ROUTINE SHRIEK ()
+	 <TELL
+"The hostess lets out a blood-chilling shriek. \"My new carpet!\" ">
+	 <COND (<VERB? THROW>
+		<TELL
+"Grabbing a shard from your broken " D ,PRSO ", s">)
+	       (T
+		<TELL "S">)>
+	 <JIGS-UP "he rushes toward you, vengeance burning in her eyes.">
+	 <RTRUE>>
+
+<OBJECT HOSTESS
+	(IN LIVING-ROOM)
+	(DESC "hostess")
+	(LDESC
+"You notice the hostess approaching, but using several mingling couples
+as cover you maneuver away.")
+	(SYNONYM HOSTESS)
+	(FLAGS ACTORBIT)
+	(ACTION HOSTESS-F)>
+
+<ROUTINE HOSTESS-F ()
+	 <COND (<EQUAL? ,HOSTESS ,WINNER>
+		<COND (<AND <VERB? YES>
+			    <EQUAL? ,AWAITING-REPLY 4>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <V-YES>
+		       <SETG WINNER ,HOSTESS>)
+		      (<AND <VERB? NO>
+			    <EQUAL? ,AWAITING-REPLY 4>>
+		       <SETG WINNER ,PROTAGONIST>
+		       <V-NO>
+		       <SETG WINNER ,HOSTESS>)
+		      (T
+		       <SETG WINNER ,PROTAGONIST>
+		       <PERFORM ,V?HELLO ,HOSTESS>
+		       <FUCKING-CLEAR>)>)
+	       (<AND <VERB? HELLO ASK-ABOUT TELL-ABOUT>
+		     <PRSO? ,HOSTESS>>
+		<TELL
+"The hostess is delighted to engage in " D ,CONVERSATION>
+		<JIGS-UP
+" and pulls you into a corner. Days later, you expire from thirst
+and exhaustion.">
+		<RTRUE>)>>
+
+<ROUTINE I-HOSTESS ()
+	 <ENABLE <QUEUE I-HOSTESS -1>>
+	 <COND (<NOT ,ITEM-DROPPED-AT-PARTY>
+		<FCLEAR ,HOSTESS ,TOUCHBIT>
+		<DISABLE <INT I-HOSTESS>>
+		<RFALSE>)>
+	 <MOVE ,HOSTESS ,HERE>
+	 <MOVE ,ITEM-DROPPED-AT-PARTY ,HERE>
+	 <CRLF>
+	 <COND (<FSET? ,HOSTESS ,TOUCHBIT>
+		<SETG AWAITING-REPLY 4>
+		<ENABLE <QUEUE I-REPLY 2>>
+		<TELL
+"\"Tricia dear,\" says the hostess insistently, \"don't you want
+your " D ,ITEM-DROPPED-AT-PARTY "?\"" CR>)
+	       (T
+		<FSET ,HOSTESS ,TOUCHBIT>
+		<SETG P-IT-OBJECT ,ITEM-DROPPED-AT-PARTY>
+		<FSET ,ITEM-DROPPED-AT-PARTY ,NDESCBIT>
+		<TELL
+"The hostess, whom you've been avoiding all evening, scurries up with your "
+D ,ITEM-DROPPED-AT-PARTY ". \"Oh, hello Tricia, how lovely to see you, I think
+you dropped this, dear.\"" CR>)>>
+
+<OBJECT JACKET-FLUFF
+	(IN LOCAL-GLOBALS) ;"for purposes of MOBY-FIND"
+	(DESC "jacket fluff")
+	(SYNONYM FLUFF LINT)
+	(ADJECTIVE JACKET UNSIGH)
+	(FLAGS NARTICLEBIT TAKEBIT TRYTAKEBIT NDESCBIT)
+	(GENERIC POCKET-FLUFF)>
+
+<OBJECT CAGE
+	(IN LOCAL-GLOBALS) ;"for the purposes of MOBY-FIND"
+	(DESC "it")
+	(SYNONYM DRAPE CAGE BIRDCA SNORIN)
+	(ADJECTIVE LARGE BLACK BIRD)
+	(FLAGS NDESCBIT NARTICLEBIT)
+	(ACTION UNIMPORTANT-THING-F)> 
+
+;"Damogran stuff"
+
+<OBJECT DAMOGRAN
+	(IN LOCAL-GLOBALS)
+	(DESC "Damogran")
+	(SYNONYM DAMOGR)>
+
+<ROOM SPEEDBOAT
+      (IN ROOMS)
+      (DESC "Presidential Speedboat")
+      (NORTH TO DAIS IF BOAT-DOCKED)
+      (OUT TO DAIS IF BOAT-DOCKED)
+      (FLAGS ONBIT RLANDBIT OUTSIDEBIT)
+      (GLOBAL CONTROLS DAMOGRAN PLATFORM)
+      (PSEUDO "CROWD" CROWD-PSEUDO "WATER" WATER-PSEUDO)
+      (ACTION SPEEDBOAT-F)>
+
+<ROUTINE SPEEDBOAT-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<SETG DREAMING T>
+		<SETG IDENTITY-FLAG ,ZAPHOD>
+		<MOVE ,ZAPHOD ,GLOBAL-OBJECTS>
+		<MOVE ,WRENCH ,TOOLBOX>
+		<MOVE ,MAGNIFYING-GLASS ,TOOLBOX>
+		<FCLEAR ,TOOLBOX ,OPENBIT>
+		<ROB ,PROTAGONIST ,MEMORIAL>
+		<MOVE ,PROTAGONIST ,PILOT-SEAT>
+		<SETG DESTINATION ,CHANNEL>
+		<ENABLE <QUEUE I-SPEEDBOAT 2>>
+		<TELL
+"The pain at the back of your eyes is from partying until very late last night,
+and both your heads are suffering the worst hangover you've ever experienced.
+You remember formulating a plan to steal " D ,HEART-OF-GOLD ", but you can't
+for the life of you remember any details." CR CR>)
+	       (<EQUAL? .RARG ,M-LOOK>
+		<COND (,BOAT-DOCKED
+		       <TELL
+"The boat is resting atop a plume of water. The dais for the dedication
+ceremonies for " D ,HEART-OF-GOLD " lies immediately north." CR>)
+		      (T
+		       <TELL
+"You are piloting the " D ,BOAT-OBJECT ", which features very simple controls,
+toward the island of France (Footnote 3), where the dedication ceremonies for "
+D ,HEART-OF-GOLD " will occur. You are currently steering the boat toward">
+		       <COND (<EQUAL? ,DESTINATION ,CHANNEL>
+		              <TELL
+" a " D ,CHANNEL " between " D ,CLIFF " and a " D ,SPIRE "." CR>)
+		             (T
+		              <ARTICLE ,DESTINATION>
+			      <TELL "." CR>)>)>)>>
+
+<ROUTINE I-SPEEDBOAT ()
+	 <SETG BOAT-COUNTER <+ ,BOAT-COUNTER 1>>
+	 <ENABLE <QUEUE I-SPEEDBOAT -1>>
+	 <COND (<EQUAL? ,DESTINATION ,CLIFF ,SPIRE>
+		<SETG CRASH-COUNTER <+ ,CRASH-COUNTER 1>>
+		<COND (<EQUAL? ,CRASH-COUNTER 4>
+		       <SETG BOAT-DOCKED T>
+		       <DISABLE <INT I-SPEEDBOAT>>
+		       <TELL CR
+"Suddenly, the autopilot leaps to life, steering the boat away from the "
+D ,DESTINATION ". The crowd gathered for the dedication oohs and aahs as the
+boat swerves through the " D ,CHANNEL ". As it reaches the base of the "
+D ,CLIFF " a plume of water forms under it, sending it higher and higher.
+The crowd bursts into applause as the boat reaches the top of the cliff, just
+south of the ceremonial dais." CR>
+		       <RTRUE>)>)> 
+	 <COND (<VERB? STEER POINT>
+		<RFALSE>)>
+	 <COND (<AND <VERB? AGAIN>
+		     <EQUAL? ,L-PRSA ,V?STEER ,V?POINT>>
+		<RFALSE>)>
+	 <CRLF>
+	 <COND (<L? ,BOAT-COUNTER 7>
+		<TELL
+"You continue to steer toward the " D ,DESTINATION "." CR>)
+	       (T
+		<DISABLE <INT I-SPEEDBOAT>>
+		<TELL
+"You almost make it through the " D ,CHANNEL " but the turbulent waters push
+the boat toward the rocks. The " D ,AUTOPILOT-BUTTON>
+		<TELL " lights up and an " ,EYE-STALK>
+		<JIGS-UP
+"but a split-second later the boat smashes into the rocks.">
+		<RTRUE>)>>
+
+<GLOBAL CRASH-COUNTER 0> 
+
+<GLOBAL BOAT-COUNTER 0>
+
+<GLOBAL DESTINATION <>>
+
+<GLOBAL BOAT-DOCKED <>>
+
+<GLOBAL AUTOPILOT-COUNTER 0>
+
+<GLOBAL DAIS-COUNTER 0>
+
+<OBJECT BOAT-OBJECT
+	(IN SPEEDBOAT)
+	(DESC "speedboat")
+	(SYNONYM SPEEDB BOAT)
+	(ADJECTIVE PRESID SPEED)
+	(FLAGS NDESCBIT)
+	(ACTION BOAT-OBJECT-F)>
+
+<ROUTINE BOAT-OBJECT-F ()
+	 <COND (<AND <VERB? STEER>
+		     <PRSO? ,BOAT-OBJECT>>
+		<COND (,BOAT-DOCKED
+		       <TELL "You've already reached your destination!" CR>)
+		      (<PRSI? ,DESTINATION>
+		       <TELL
+"You already ARE steering the boat toward the " D ,DESTINATION "." CR>)
+		      (<NOT <PRSI? ,CLIFF ,SPIRE ,CHANNEL>>
+		       <TELL "You can't steer the boat toward">
+		       <ARTICLE ,PRSI T>
+		       <TELL "!" CR>)
+		      (T
+		       <SETG DESTINATION ,PRSI>
+		       <COND (<G? ,BOAT-COUNTER 3>
+			      <SETG BOAT-COUNTER 3>)>
+		       <TELL
+"The boat is now heading straight at the " D ,DESTINATION "." CR>)>)
+	       (<VERB? EXIT LEAVE DISEMBARK THROUGH>
+		<COND (,BOAT-DOCKED
+		       <DO-WALK ,P?NORTH>)
+		      (T
+		       <TELL ,DONT-MIX CR>)>)>>
+
+<ROUTINE WATER-PSEUDO ()
+	 <COND (<VERB? THROUGH BOARD>
+		<TELL ,DONT-MIX CR>)
+	       (<AND <VERB? PUT THROW>
+		     <PRSI? ,PSEUDO-OBJECT>>
+		<MOVE ,PRSO ,LOCAL-GLOBALS>
+		<TELL "Glub..." CR>)>>
+
+<OBJECT PILOT-SEAT
+	(IN SPEEDBOAT)
+	(DESC "pilot seat")
+	(SYNONYM SEAT CHAIR CUSHION)
+	(ADJECTIVE PILOT SEAT THICK PLUSH)
+	(FLAGS VEHBIT CONTBIT SURFACEBIT SEARCHBIT OPENBIT)
+	(ACTION PILOT-SEAT-F)>
+
+<ROUTINE PILOT-SEAT-F ("OPTIONAL" (RARG <>))
+	 <COND (<EQUAL? .RARG ,M-BEG>
+		<COND (<VERB? WALK>
+		       <OUT-OF-FIRST ,PILOT-SEAT>)>)
+	       (.RARG
+		<RFALSE>)
+	       (<AND <VERB? LOOK-UNDER RAISE SEARCH TAKE>
+		     <IN? ,KEY ,LOCAL-GLOBALS>>
+		<MOVE ,CUSHION-FLUFF ,PROTAGONIST>
+		<MOVE ,KEY ,PROTAGONIST>
+		<TELL
+"You discover and pick up a small key and a piece of fluff under the
+seat cushion." CR>)
+	       (<VERB? EXAMINE>
+		<TELL
+"The chair is very comfortable, with a thick plush cushion." CR>)
+	       (<AND <VERB? OPEN CLOSE>
+		     <PRSO? ,PILOT-SEAT>>
+		<TELL-ME-HOW>)>>
+
+<OBJECT KEY
+	(IN LOCAL-GLOBALS) ;"for purposes of MOBY-FIND"
+	(DESC "small key")
+	(SYNONYM KEY)
+	(ADJECTIVE SMALL)
+	(FLAGS TAKEBIT)
+	(SIZE 2)
+	(ACTION KEY-F)>
+
+<ROUTINE KEY-F ()
+	 <COND (<AND <VERB? WHERE>
+		     <EQUAL? ,HERE ,SPEEDBOAT>
+		     <IN? ,KEY ,LOCAL-GLOBALS>>
+		<TELL "It's probably around the boat somewhere." CR>)>>
+
+<OBJECT CUSHION-FLUFF
+	(IN LOCAL-GLOBALS) ;"just for the purpose of MOBY-FIND"
+	(DESC "seat cushion fluff")
+	(SYNONYM FLUFF LINT)
+	(ADJECTIVE SEAT CUSHION)
+	(FLAGS TAKEBIT NARTICLEBIT)
+	(SIZE 1)
+	(GENERIC POCKET-FLUFF)>
+
+<OBJECT TOOLBOX
+	(IN SPEEDBOAT)
+	(DESC "tool box")
+	(SYNONYM TOOLBO LOCK BOX)
+	(ADJECTIVE TOOL)
+	(FLAGS CONTBIT TAKEBIT SEARCHBIT)
+	(SIZE 25)
+	(CAPACITY 20)
+	(ACTION TOOLBOX-F)>
+
+<ROUTINE TOOLBOX-F ()
+	 <COND (<AND <VERB? OPEN>
+		     <NOT ,PRSI>
+		     <NOT <FSET? ,TOOLBOX ,OPENBIT>>>
+		<TELL "It's locked." CR>)
+	       (<VERB? LOCK>
+		<COND (<FSET? ,TOOLBOX ,OPENBIT>
+		       <PERFORM ,V?CLOSE ,TOOLBOX>
+		       <RTRUE>)
+		      (T
+		       <TELL "It is." CR>)>)
+	       (<VERB? OPEN UNLOCK>
+		<COND (<FSET? ,TOOLBOX ,OPENBIT>
+		       <TELL ,ALREADY-OPEN CR>
+		       <RTRUE>)>
+		<COND (<AND <NOT ,PRSI>
+			    <HELD? ,KEY>>
+		       <SETG PRSI ,KEY>
+		       <TELL "(with the key)" CR>)>
+		<COND (<PRSI? ,KEY>
+		       <FSET ,TOOLBOX ,OPENBIT>
+		       <TELL "The tool box opens">
+		       <COND (<FIRST? ,TOOLBOX>
+			      <TELL " revealing">
+			      <PRINT-CONTENTS ,TOOLBOX>)>
+		       <TELL "." CR>)
+		      (T
+		       <TELL "You can't unlock it with">
+		       <COND (,PRSI
+			      <ARTICLE ,PRSI>)
+			     (T
+			      <TELL " " D ,HANDS>)>
+		       <TELL "!" CR>)>)>>
+
+<OBJECT MAGNIFYING-GLASS
+	(IN TOOLBOX)
+	(DESC "magnifying glass")
+	(SYNONYM GLASS)
+	(ADJECTIVE MAGNIF)
+	(FLAGS TAKEBIT TRANSBIT)
+	(ACTION MAGNIFYING-GLASS-F)>
+
+<ROUTINE MAGNIFYING-GLASS-F ()
+	 <COND (<VERB? LOOK-INSIDE>
+		<TELL
+"You see your environs upside-down and slightly distorted." CR>)>>
+
+<OBJECT AUTOPILOT-BUTTON
+	(IN SPEEDBOAT)
+	(DESC "autopilot button")
+	(SYNONYM BUTTON PILOT AUTOPI)
+	(ADJECTIVE AUTOPI AUTO LARGE RED)
+	(FLAGS VOWELBIT NDESCBIT LIGHTBIT)
+	(ACTION AUTOPILOT-BUTTON-F)>
+
+<ROUTINE AUTOPILOT-BUTTON-F ()
+	 <COND (<VERB? PUSH LAMP-ON>
+		<SETG AUTOPILOT-COUNTER <+ ,AUTOPILOT-COUNTER 1>>
+		<TELL "The button glows. An "
+,EYE-STALK "looks around, and withdraws. The light fades.">
+		<COND (<EQUAL? ,AUTOPILOT-COUNTER 3>
+		       <TELL " (Footnote 13)">)>
+		<CRLF>)>>
+
+<OBJECT CHANNEL
+	(IN SPEEDBOAT)
+	(DESC "narrow channel")
+	(SYNONYM CHANNEL OPENIN)
+	(ADJECTIVE NARROW)
+	(FLAGS NDESCBIT)>
+
+<OBJECT SPIRE
+	(IN SPEEDBOAT)
+	(DESC "rocky spire")
+	(SYNONYM SPIRE ROCK ROCKS)
+	(ADJECTIVE ROCKY)
+	(FLAGS NDESCBIT)
+	(ACTION DESTINATION-F)>
+
+<OBJECT CLIFF
+	(IN SPEEDBOAT)
+	(DESC "towering cliffs")
+	(SYNONYM CLIFF CLIFFS ISLAND FRANCE)
+	(ADJECTIVE TOWERI)
+	(FLAGS NDESCBIT NARTICLEBIT)
+	(ACTION DESTINATION-F)>
+
+<ROUTINE DESTINATION-F ()
+	 <COND (<AND <VERB? WALK-TO>
+		     <NOT ,BOAT-DOCKED>>
+		<PERFORM ,V?STEER ,BOAT-OBJECT ,PRSO>
+		<RTRUE>)>>
+
+<ROOM DAIS
+      (IN ROOMS)
+      (SYNONYM POLICE COPS)
+      (DESC "Dais")
+      (SOUTH "The boat is gone.")
+      (EAST PER DAIS-EXIT-F)
+      (IN PER DAIS-EXIT-F)
+      (OUT PER DAIS-EXIT-F)
+      (FLAGS RLANDBIT ONBIT OUTSIDEBIT)
+      (GLOBAL HEART-OF-GOLD DAMOGRAN PLATFORM)
+      (PSEUDO "CROWD" CROWD-PSEUDO)
+      (ACTION DAIS-F)>
+
+<ROUTINE DAIS-EXIT-F ()
+	 <COND (<NOT <IN? ,GUARDS ,HERE>>
+		<SETG AWAITING-REPLY 5>
+		<ENABLE <QUEUE I-REPLY 2>>
+		<TELL
+"Don't you think it would be a bad idea to leave the ceremonies?" CR>
+		<RFALSE>)
+	       (<OR <IN? ,RIFLES ,HERE>
+		    <IN? ,RIFLES ,GUARDS>>
+		<TELL
+"You and " D ,TRILLIAN " break for " D ,HEART-OF-GOLD ". ">
+		<COND (<FSET? ,BLASTER ,TRYTAKEBIT>
+		       <TELL ,GUARDS-REALIZE "They">)
+		      (T
+		       <TELL "The guards">)>
+		<GUARD-DEATH>
+		<RFALSE>)
+	       (T
+		<SETG SCORE <+ ,SCORE 25>>
+		<FSET ,SPEEDBOAT ,REVISITBIT>
+		<MOVE ,BLASTER ,LOCAL-GLOBALS>
+		<ROB ,PROTAGONIST ,HATCHWAY>
+		<TELL
+"You and " D ,TRILLIAN " enter " D ,HEART-OF-GOLD ", that beautiful bauble
+you've been coveting ever since your decision to run for" ,PRESIDENT>
+		<JIGS-UP
+". The excitement overwhelms you (or perhaps it's just the awesome hangover
+from last night).">
+		<RFALSE>)>> 
+
+<ROUTINE DAIS-F (RARG)
+	 <COND (<AND <EQUAL? .RARG ,M-END>
+		     <FSET? ,SPEEDBOAT ,REVISITBIT>>
+		<SETG DREAMING T>
+		<JIGS-UP
+"The remnants of a rapidly dispersing crowd gasp at your appearance. You
+are immediately seized by guards who, in an unconstitutional departure from
+protocol, hurl you over the cliff.">
+		<RTRUE>)
+	       (<AND <EQUAL? .RARG ,M-ENTER>
+		     <NOT <FSET? ,SPEEDBOAT ,REVISITBIT>>>
+		<PUTP ,PROTAGONIST ,P?ACTION ,DAIS-FUNCTION>
+		<TELL
+"As you step out of the boat, the plume of water lowers it away. The crowd,
+unaware of the autopilot, bursts into a round of admiring applause." CR CR>)
+	       (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a platform surrounded by a crowd. ">
+		<COND (<IN? ,BANNER ,HERE>
+		       <TELL
+"Several members of the crowd are holding a huge banner. ">)>
+		<TELL "Just to the east is " D ,HEART-OF-GOLD>
+		<COND (<IN? ,RIFLES ,GUARDS>
+		       <TELL ". A semi-circle of guards are aiming "
+D ,RIFLES "s at you and " D ,TRILLIAN>)
+		      (<IN? ,GUARDS ,HERE>
+		       <TELL
+". Many disarmed guards are nervously eyeing you and " D ,TRILLIAN>)>
+	        <COND (<IN? ,BLASTER ,TRILLIAN>
+		       <TELL
+", who is pointing a blaster at your head">)>
+		<TELL "." CR>)>>
+
+<ROUTINE DAIS-FUNCTION ()
+	 <COND (<VERB? QUIT RESTART RESTORE SCORE VERSION SAVE AGAIN WALK
+		       VERBOSE BRIEF SUPER-BRIEF SCRIPT UNSCRIPT FOOTNOTE
+		       LOOK INVENTORY HELP WHO WHAT WHERE WHY YES NO THROUGH>
+		<>)
+	       (<AND <PRSO? ,BANNER ,PSEUDO-OBJECT>
+		     <VERB? COUNT EXAMINE THROUGH READ>>
+		<>)
+	       (T
+		<SETG DAIS-COUNTER <+ ,DAIS-COUNTER 1>>
+		<TELL ,CROWD-CHEERS>
+		<COND (<EQUAL? ,DAIS-COUNTER 4>
+		       <PUTP ,PROTAGONIST ,P?ACTION ,PROTAGONIST-F>
+		       <MOVE ,TRILLIAN ,HERE>
+		       <MOVE ,BLASTER ,TRILLIAN>
+		       <MOVE ,GUARDS ,HERE>
+		       <MOVE ,RIFLES ,GUARDS>
+		       <ENABLE <QUEUE I-GUARDS 8>>
+		       <TELL
+" Suddenly, " D ,TRILLIAN " leaps out of the crowd, grabs you by the necks,
+and points a blaster at your left head. Guards rush up, " D ,RIFLES "s poised
+to shoot. \"Stay back!\" shouts " D ,TRILLIAN ". \"One more step and the"
+,PRESIDENT " is fried meat!\" The guards seem unsure, and look at you for
+instructions.">)>
+		<FUCKING-CLEAR>
+		<CRLF>)>>
+
+<ROUTINE CROWD-PSEUDO ()
+	 <COND (<VERB? COUNT EXAMINE>
+		<TELL "It's big." CR>)
+	       (<VERB? SHOOT>
+		<COND (<BLASTER-HOLD>
+		       <RTRUE>)>
+		<TELL
+"You may be a scoundrel, but you're not a mass murderer." CR>)
+	       (<VERB? THROUGH>
+		<TELL
+"You'd be crushed by the enthusiasm of your admirers." CR>)
+	       (<VERB? TELL WAVE-AT>
+		<TELL ,CROWD-CHEERS CR>
+		<FUCKING-CLEAR>
+		<RTRUE>)>>
+
+<OBJECT PLATFORM
+	(IN LOCAL-GLOBALS)
+	(DESC "Dais")
+	(SYNONYM DAIS PLATFO)
+	(ACTION PLATFORM-F)>
+
+<ROUTINE PLATFORM-F ()
+	 <COND (<AND <EQUAL? ,HERE ,SPEEDBOAT>
+		     <NOT ,BOAT-DOCKED>>
+		<CANT-SEE ,PLATFORM>)
+	       (<VERB? THROUGH WALK-TO>
+		<COND (<EQUAL? ,HERE ,DAIS>
+		       <TELL ,LOOK-AROUND CR>)
+		      (T
+		       <DO-WALK ,P?NORTH>)>)
+	       (<VERB? LEAVE DISEMBARK>
+		<COND (<EQUAL? ,HERE ,DAIS>
+		       <DO-WALK ,P?EAST>)
+		      (T
+		       <TELL ,LOOK-AROUND CR>)>)>>
+
+<OBJECT BANNER
+	(IN DAIS)
+	(DESC "banner")
+	(SYNONYM BANNER)
+	(ADJECTIVE HUGE)
+	(FLAGS NDESCBIT READBIT)
+	(TEXT "\"President Beeblebrox is a Swell Guy\" (Footnote 15).")>
+
+<OBJECT BLASTER
+	(IN LOCAL-GLOBALS) ;"just for the purpose of MOBY-FIND"
+	(DESC "blaster")
+	(SYNONYM BLASTE WEAPON)
+	(FLAGS NDESCBIT TAKEBIT TRYTAKEBIT)
+        (ACTION BLASTER-F)>
+
+<ROUTINE BLASTER-F ()
+	 <COND (<AND <VERB? TAKE>
+		     <FSET? ,BLASTER ,TRYTAKEBIT>>
+		<TELL ,GUARDS-REALIZE "They">
+		<COND (<IN? ,RIFLES ,GUARDS>
+		       <GUARD-DEATH>)
+		      (T
+		       <FCLEAR ,BLASTER ,TRYTAKEBIT>
+		       <FCLEAR ,BLASTER ,NDESCBIT>
+		       <MOVE ,BLASTER ,PROTAGONIST>
+		       <ENABLE <QUEUE I-GUARDS 5>>
+		       <TELL
+" are disarmed, though, and unable to do anything as you take
+the blaster." CR>)>)
+	       (<AND <VERB? SHOOT>
+		     <PRSI? ,BLASTER>>
+		<COND (<PRSO? ,BLASTER>
+		       <V-COUNT>)
+		      (<PRSO? ,GROUND>
+		       <V-DIG>)
+		      (<OR <FSET? ,PRSO ,TAKEBIT>
+			   <PRSO? ,BANNER>>
+		       <MOVE ,PRSO ,LOCAL-GLOBALS>
+		       <TELL "With a cloud of sparks">
+		       <COND (<PRSO? ,RIFLES>
+			      <TELL " the pile of " D ,RIFLES "s">)
+			     (T
+			      <ARTICLE ,PRSO T>)>
+		       <TELL " disintegrates. " ,CROWD-CHEERS CR>)
+		      (<PRSO? ,HEART-OF-GOLD>
+		       <TELL "You're too far." CR>)>)>>
+
+<ROUTINE BLASTER-HOLD ()
+	 <COND (<NOT <HELD? ,BLASTER>>
+		<TELL ,NOT-HOLDING " the " D ,BLASTER "." CR>
+		<RTRUE>)>>
+
+<OBJECT RIFLES
+	(IN LOCAL-GLOBALS) ;"for purposes of MOBY-FIND"
+	(DESC "photon rifle")
+	(SYNONYM RIFLE RIFLES PILE WEAPON)
+	(ADJECTIVE PHOTON YOUR)
+	(FLAGS NDESCBIT TRYTAKEBIT)
+        (ACTION RIFLES-F)>
+
+<ROUTINE RIFLES-F ()
+	 <COND (<VERB? SHOOT>
+		<COND (<BLASTER-HOLD>
+		       <RTRUE>)>
+		<COND (<IN? ,RIFLES ,GUARDS>
+		       <PERFORM ,V?SHOOT ,GUARDS>
+		       <RTRUE>)
+		      (T
+		       <MOVE ,RIFLES ,LOCAL-GLOBALS>
+		       <TELL
+"The rifles explode in a flashy display of sparks and shrapnel. " ,CROWD-CHEERS
+" The guards begin to look a bit concerned." CR>)>)
+	       (<AND <VERB? TAKE>
+		     <FSET? ,RIFLES ,TRYTAKEBIT>>
+		<TELL ,GUARDS-REALIZE>
+		<TELL
+"As you begin taking the rifles, so do several of the guards. They may be dim,
+but they know what to do with a " D ,RIFLES>
+		<JIGS-UP ".">
+		<RTRUE>)>>
+
+<ROUTINE GUARD-DEATH ()
+	 <COND (<NOT <VISIBLE? ,RIFLES>>
+		<TELL " grab the blaster and">)
+	       (<NOT <IN? ,RIFLES ,GUARDS>>
+		<TELL " pick up their rifles and">)>
+	 <JIGS-UP " reduce you to a smoking pile of ash.">>
+
+;"Whale stuff"
+
+<ROOM INSIDE-WHALE
+      (IN ROOMS)
+      (SYNONYM TREE FOREKN)
+      (DESC "Inside the Sperm Whale")
+      (LDESC
+"You are in the stomach of a sperm whale. You can hear a distant sound
+of rushing wind.")
+      (FLAGS ONBIT RLANDBIT NARTICLEBIT)
+      (ACTION INSIDE-WHALE-F)>
+
+<ROUTINE INSIDE-WHALE-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-ENTER>
+		<ENABLE <QUEUE I-WHALE 11>>
+		<SETG DREAMING T>
+		<RFALSE>)>>
+
+<ROUTINE I-WHALE ()
+	 <COND (<EQUAL? ,HERE ,INSIDE-WHALE>
+		<CRLF>
+		<JIGS-UP "SPLAT!!!!!">
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<OBJECT WHALE-OBJECT
+	(IN INSIDE-WHALE)
+	(DESC "innard of a whale")
+	(SYNONYM INNARD WHALE STOMAC)
+	(ADJECTIVE SPERM)
+	(FLAGS VOWELBIT NDESCBIT)
+	(ACTION WHALE-OBJECT-F)>
+
+<ROUTINE WHALE-OBJECT-F ()
+	 <COND (<VERB? EXIT LEAVE DISEMBARK>
+		<V-WALK-AROUND>)>>
\ No newline at end of file
diff --git a/verbs.zil b/verbs.zil
new file mode 100644
index 0000000..4d96324
--- /dev/null
+++ b/verbs.zil
@@ -0,0 +1,2930 @@
+"VERBS for
+		  THE HITCHHIKER'S GUIDE TO THE GALAXY
+	(c) Copyright 1984 Infocom, Inc.  All Rights Reserved."
+
+;"subtitle game commands"
+
+<GLOBAL VERBOSITY 1> ;"0 = superbrief, 1 = brief, 2 = verbose"
+
+<ROUTINE V-VERBOSE ()
+	 <SETG VERBOSITY 2>
+	 <TELL "Maximum verbosity." CR CR>
+	 <V-LOOK>>
+
+<ROUTINE V-BRIEF ()
+	 <SETG VERBOSITY 1>
+	 <TELL "Brief descriptions." CR>>
+
+<ROUTINE V-SUPER-BRIEF ()
+	 <SETG VERBOSITY 0>
+	 <TELL "Super-brief descriptions." CR>>
+
+<ROUTINE V-DIAGNOSE ()
+	 <COND (,HEADACHE
+		<TELL "You have a big blinding throbber." CR>)
+	       (,GROGGY
+		<TELL "You feel weak." CR>)
+	       (<EQUAL? ,IDENTITY-FLAG ,ZAPHOD>
+		<TELL "You have two " D ,HANGOVER "s." CR>)
+	       (T
+		<TELL "You are in good health." CR>)>>
+
+<ROUTINE V-INVENTORY ("AUX" SPARE-KLUDGE)
+	 <COND (<FSET? ,SPARE-DRIVE ,NDESCBIT>
+		<SET SPARE-KLUDGE T>
+		<FCLEAR ,SPARE-DRIVE ,NDESCBIT>)
+	       (T
+		<SET SPARE-KLUDGE <>>)>
+	 <COND (<AND <NOT <EQUAL? ,IDENTITY-FLAG ,ARTHUR>>
+		     <NOT <FIRST? ,PROTAGONIST>>>
+		<TELL "You are empty-handed." CR>)
+	       (T
+		<TELL "You have:" CR>
+		<COND (,HEADACHE
+		       <TELL "  a " D ,HANGOVER CR>)>
+		<COND (<AND <EQUAL? ,IDENTITY-FLAG ,ARTHUR>
+			    <OR ,HOLDING-NO-TEA
+				<NOT <HELD? ,TEA>>>>
+		       <SETG HOLDING-NO-TEA T>
+		       <TELL "  no tea" CR>)>
+		<PRINT-CONT ,PROTAGONIST>)>
+	 <COND (.SPARE-KLUDGE
+		<FSET ,SPARE-DRIVE ,NDESCBIT>)>>
+
+<ROUTINE V-QUIT ()
+	 <V-SCORE>
+	 <TELL
+"Do you wish to leave the game? (Y is affirmative): ">
+	 <COND (<YES?>
+		<QUIT>)
+	       (T
+		<TELL "Ok." CR>)>>
+
+<ROUTINE V-RESTART ()
+	 <V-SCORE T>
+	 <TELL "Do you wish to restart? (Y is affirmative): ">
+	 <COND (<YES?>
+		<TELL "Restarting." CR>
+		<RESTART>
+		<TELL "Failed." CR>)>>
+
+<ROUTINE FINISH ("OPTIONAL" (REPEATING <>))
+	 <CRLF>
+	 <COND (<NOT .REPEATING>
+		<V-SCORE>
+		<CRLF>)>
+	 <TELL
+"Would you like to start over, restore a saved position, or end this session
+of the game?|
+(Type RESTART, RESTORE, or QUIT): >">
+	 <READ ,P-INBUF ,P-LEXV>
+	 <COND (<EQUAL? <GET ,P-LEXV 1> ,W?RESTAR>
+	        <RESTART>
+		<TELL "Failed." CR>
+		<FINISH T>)
+	       (<EQUAL? <GET ,P-LEXV 1> ,W?RESTOR>
+		<COND (<RESTORE>
+		       <TELL "Ok." CR>)
+		      (T
+		       <TELL "Failed." CR>
+		       <FINISH T>)>)
+	       (<EQUAL? <GET ,P-LEXV 1> ,W?QUIT ,W?Q>
+		<QUIT>)
+	       (T
+		<FINISH T>)>>
+
+<ROUTINE YES? ()
+	 <PRINTI ">">
+	 <READ ,P-INBUF ,P-LEXV>
+	 <COND (<EQUAL? <GET ,P-LEXV 1> ,W?YES ,W?Y>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE V-RESTORE ()
+	 <COND (<RESTORE>
+		<TELL "Ok." CR>)
+	       (T
+		<TELL "Failed." CR>)>>
+
+<ROUTINE V-SAVE ()
+	 <COND (<SAVE>
+	        <TELL "Ok." CR>)
+	       (T
+		<TELL "Failed." CR>)>>
+
+<ROUTINE V-SCORE ("OPTIONAL" (ASK? T))
+	 <COND (<L? ,SCORE 400>
+		<TELL
+"We are about to give you your score. Put on your peril-sensitive sunglasses
+now. (Hit RETURN or ENTER when ready.) ">
+		<PRINTI ">">
+		<READ ,P-INBUF ,P-LEXV>
+		<SETG P-CONT <>>
+		<CRLF>)>
+	 <TELL "Your score is " N ,SCORE " of a possible 400, in " N ,MOVES>
+	 <COND (<1? ,MOVES>
+		<TELL " turn.">)
+	       (T
+		<TELL " turns.">)>
+	 <CRLF>
+	 ,SCORE>
+
+<ROUTINE V-SCRIPT ()
+	<PUT 0 8 <BOR <GET 0 8> 1>>
+	<COPR-NOTICE "begins">
+	<V-VERSION>>
+
+<ROUTINE V-UNSCRIPT ()
+	<COPR-NOTICE "ends">
+	<V-VERSION>
+	<PUT 0 8 <BAND <GET 0 8> -2>>
+	<RTRUE>>
+
+<ROUTINE COPR-NOTICE (STRING)
+	 <TELL
+"Here " .STRING " a transcript of interaction with " ,GUIDE-NAME "." CR>>
+
+<ROUTINE V-VERSION ("AUX" (CNT 17) V)
+	 <SET V <BAND <GET 0 1> *3777*>>
+	 <TELL
+"THE HITCHHIKER'S GUIDE TO THE GALAXY|
+Infocom interactive fiction - a science fiction story|
+Copyright (c) 1984 by Infocom, Inc. All rights reserved.|">
+	 ;<COND (<NOT <EQUAL? <BAND <GETB 0 1> 8> 0>>
+		<TELL
+"Licensed to Tandy Corporation. Version 00.00." N .V CR>)>
+	 <TELL "Release " N .V " / Serial number ">
+	 <REPEAT ()
+		 <COND (<G? <SET CNT <+ .CNT 1>> 23>
+			<RETURN>)
+		       (T
+			<PRINTC <GETB 0 .CNT>>)>>
+	 <CRLF>>
+
+<ROUTINE V-$VERIFY ()
+	 <COND (<AND <PRSO? ,INTNUM>
+		     <EQUAL? ,P-NUMBER 469>>
+		<TELL N ,SERIAL CR>)
+	       (T
+		<TELL "Verifying..." CR>
+	 	<COND (<VERIFY>
+		       <TELL "Good." CR>)
+	       	      (T
+		       <TELL CR "** Bad **" CR>)>)>>
+
+<CONSTANT SERIAL 0>
+
+;<GLOBAL DEBUG <>>
+
+;<ROUTINE V-$DEBUG ()
+	 <COND (,DEBUG
+		<SETG DEBUG <>>
+		<TELL "Debugging off." CR>)
+	       (T
+		<SETG DEBUG T>
+		<TELL "Debugging on." CR>)>>
+
+;<ROUTINE V-$CHEAT ()
+	 <COND (<NOT <PRSO? ,INTNUM>>
+		<GOTO ,RAMP>)
+	       (<EQUAL? ,P-NUMBER 1>
+		<LEAVE-EARTH>
+		<SETG DOG-FED T>
+	        <FCLEAR ,GOWN ,NDESCBIT>
+		<FCLEAR ,TOOTHBRUSH ,TRYTAKEBIT>
+		<GOTO ,DARK>
+		<SETG DARK-FLAG ,HOLD>
+		<FSET ,DARK-OBJECT ,DARKBIT>
+		<MOVE ,MAIL ,DARK-OBJECT>
+		<MOVE ,TOWEL ,DARK-OBJECT>
+		<MOVE ,THUMB ,DARK-OBJECT>
+		<MOVE ,TOOTHBRUSH ,DARK-OBJECT>
+		<MOVE ,SCREWDRIVER ,DARK-OBJECT>
+		<MOVE ,GOWN ,DARK-OBJECT>
+		<FSET ,GOWN ,WORNBIT>)
+	       (<EQUAL? ,P-NUMBER 2>
+		<LEAVE-EARTH>
+		<FSET ,HOLD ,TOUCHBIT>
+		<SETG DOG-FED T>
+	        <FCLEAR ,GOWN ,NDESCBIT>
+		<FCLEAR ,TOOTHBRUSH ,TRYTAKEBIT>
+		<GOTO ,DARK>
+		<SETG DARK-FLAG ,ENTRY-BAY>
+		<FSET ,DARK-OBJECT ,DARKBIT>
+		<MOVE ,PLOTTER ,PROTAGONIST>
+		<MOVE ,BABEL-FISH ,PROTAGONIST>
+		<MOVE ,TOWEL ,PROTAGONIST>
+		<MOVE ,GUIDE ,PROTAGONIST>
+		<MOVE ,THUMB ,PROTAGONIST>)
+	       (<EQUAL? ,P-NUMBER 3>
+		<LEAVE-EARTH>
+		<FSET ,HOLD ,TOUCHBIT>
+		<SETG DOG-FED T>
+	        <FCLEAR ,GOWN ,NDESCBIT>
+		<FCLEAR ,TOOTHBRUSH ,TRYTAKEBIT>
+		<SETG LYING-DOWN <>>
+		<FSET ,DARK-OBJECT ,DARKBIT>
+		<MOVE ,PLOTTER ,BRIDGE>
+		<MOVE ,SPARE-DRIVE ,BRIDGE>
+		<MOVE ,HATCH ,GLOBAL-OBJECTS>
+		<MOVE ,TEA ,BRIDGE>
+		<MOVE ,BOARD ,LOCAL-GLOBALS>
+		<MOVE ,NUT-COM-INTERFACE ,NUTRIMAT>
+		<FSET ,BEAST ,MUNGEDBIT>
+		<SETG DRIVE-TO-PLOTTER T>
+		<SETG BROWNIAN-SOURCE ,TEA>
+		<MOVE ,FORD ,LOCAL-GLOBALS>
+		<MOVE ,TRILLIAN ,LOCAL-GLOBALS>
+		<MOVE ,ZAPHOD ,LOCAL-GLOBALS>
+		<GOTO ,BRIDGE>)
+	       (<EQUAL? ,P-NUMBER 4>
+		<LEAVE-EARTH>
+		<FSET ,HOLD ,TOUCHBIT>
+		<SETG DOG-FED T>
+	        <FCLEAR ,GOWN ,NDESCBIT>
+		<FCLEAR ,TOOTHBRUSH ,TRYTAKEBIT>
+		<FCLEAR ,JACKET-FLUFF ,TRYTAKEBIT>
+		<FCLEAR ,JACKET-FLUFF ,NDESCBIT>
+		<FSET ,DARK-OBJECT ,DARKBIT>
+		<SETG LYING-DOWN <>>
+		<SETG SCORE 200>
+		<MOVE ,SATCHEL-FLUFF ,PROTAGONIST>
+		<MOVE ,POCKET-FLUFF ,PROTAGONIST>
+		<MOVE ,JACKET-FLUFF ,PROTAGONIST>
+		<MOVE ,CUSHION-FLUFF ,PROTAGONIST>
+		<MOVE ,FLOWERPOT ,PROTAGONIST>
+		<MOVE ,TEA ,PROTAGONIST>
+		<MOVE ,HATCH ,GLOBAL-OBJECTS>
+		<MOVE ,FORD ,LOCAL-GLOBALS>
+		<MOVE ,TRILLIAN ,LOCAL-GLOBALS>
+		<MOVE ,ZAPHOD ,LOCAL-GLOBALS>
+		<FSET ,PARTICLE ,MUNGEDBIT>
+		<COND (<EQUAL? ,BROWNIAN-SOURCE ,TEA>
+		       <SETG BROWNIAN-SOURCE <>>)>
+		<MOVE ,SCREWDRIVER ,HATCHWAY>
+		<MOVE ,TOOTHBRUSH ,HATCHWAY>
+		<MOVE ,TWEEZERS ,HATCHWAY>
+		<MOVE ,RASP ,HATCHWAY>
+		<MOVE ,AWL ,HATCHWAY>
+		<MOVE ,CHISEL ,HATCHWAY>
+		<MOVE ,WRENCH ,HATCHWAY>
+		<MOVE ,PLIERS ,HATCHWAY>
+		<MOVE ,PINCER ,HATCHWAY>
+		<MOVE ,CHIPPER ,HATCHWAY>
+		<GOTO ,AFT-CORRIDOR>)
+	       (T
+		<GOTO ,RAMP>)>>
+
+;<ROUTINE V-$PROB ()
+	 <TELL "Heart: " N ,HEART-PROB CR>
+	 <TELL "Vogon: " N ,VOGON-PROB CR>
+	 <TELL "Traal: " N ,TRAAL-PROB CR>
+	 <TELL "Fleet: " N ,FLEET-PROB CR>
+	 <TELL "Whale: " N ,WHALE-PROB CR>
+	 <TELL "Trillian: " N ,TRILLIAN-PROB CR>
+	 <TELL "Ford: " N ,FORD-PROB CR>
+	 <TELL "Zaphod: " N ,ZAPHOD-PROB CR>>
+
+
+;"subtitle real verbs"
+
+<ROUTINE V-AGAIN ("AUX" OBJ (N <>))
+	 <COND (,L-DONT-FLAG
+		<SETG DONT-FLAG T>
+		<SETG PRSA ,L-PRSA>
+		<DONT-F>
+		<RTRUE>)>
+	 <COND (<NOT ,L-PRSA>
+		<TELL "Not until you do something." CR>)
+	       (<OR <EQUAL? ,L-PRSA ,V?FIND ,V?FOLLOW ,V?CALL>
+		    <EQUAL? ,L-PRSA ,V?WHAT ,V?WHERE ,V?WHO>
+		    <EQUAL? ,L-PRSA ,V?WAIT-FOR ,V?WALK-TO ,V?WHAT-ABOUT>
+		    <EQUAL? ,L-PRSA ,V?ASK-ABOUT ,V?ASK-FOR ,V?I-AM>
+		    <EQUAL? ,L-PRSA ,V?MY-NAME ,V?TELL-ABOUT ,V?CALL-WITH>
+		    <EQUAL? ,L-PRSA ,V?CARVE>>
+		<TELL
+"Sorry, the Galactic Compendium on Interactive Fiction prohibits the use of
+AGAIN after your previous action." CR>
+		<SETG PRSA ,V?VERBOSE>) ;"so this won't run the clock"
+	       (<EQUAL? ,NOT-HERE-OBJECT ,L-PRSO ,L-PRSI>
+		<TELL "You can't see that here." CR>)
+	       (<EQUAL? ,L-PRSA ,V?WALK>
+		<DO-WALK ,L-PRSO>)
+	       (T
+		<SET OBJ
+		     <COND (<AND ,L-PRSO <NOT <VISIBLE? ,L-PRSO>>>
+			    ,L-PRSO)
+			   (<AND ,L-PRSI <NOT <VISIBLE? ,L-PRSI>>>
+			    ,L-PRSI)>>
+		<COND (<AND .OBJ 
+			    <NOT <EQUAL? .OBJ ,ROOMS>>>
+		       <TELL "You can't see">
+		       <COND (.N
+			      <TELL " any " D .OBJ " here." CR>)
+			     (T
+		       	      <ARTICLE .OBJ T>
+		       	      <TELL " anymore." CR>)>
+		       <RFATAL>)
+		      (T
+		       <COND (,L-FRONT-FLAG
+			      <SETG IN-FRONT-FLAG T>)>
+	 	       <PERFORM ,L-PRSA ,L-PRSO ,L-PRSI>)>)>>
+
+<ROUTINE V-ALARM ()
+	 <COND (<PRSO? ,ROOMS>
+		<PERFORM ,V?ALARM ,ME>
+		<RTRUE>)
+	       (T
+		<TELL "I don't think">
+	        <ARTICLE ,PRSO T>
+	        <TELL " is sleeping." CR>)>>
+
+<ROUTINE V-ANSWER ()
+	 <COND (<AND ,AWAITING-REPLY
+		     <EQUAL? <GET ,P-LEXV ,P-CONT> ,W?YES>>
+		<V-YES>
+		<FUCKING-CLEAR>)
+	       (<AND ,AWAITING-REPLY
+		     <EQUAL? <GET ,P-LEXV ,P-CONT> ,W?NO>>
+		<V-NO>
+		<FUCKING-CLEAR>)
+	       (<IN? ,BEAST ,HERE>
+		<V-SAY>
+		<FUCKING-CLEAR>)
+	       (T
+		<TELL "Nobody is awaiting your answer." CR>
+	        <FUCKING-CLEAR>)>>
+
+<ROUTINE V-APPLAUD ()
+	 <COND (<RUNNING? ,I-CAPTAIN>
+		<TELL "If you want to enjoy the poetry, just type that." CR>)
+	       (T
+		<TELL "Thank you, thank you." CR>)>>
+
+<ROUTINE V-APPRECIATE ()
+	 <COND (<RUNNING? ,I-CAPTAIN>
+		<V-APPLAUD>)
+	       (T
+		<TELL
+"Hey, I never get any appreciation! There's absolutely no job satisfaction
+in being a computer." CR>)>>
+
+<ROUTINE V-ASK-ABOUT ()
+	 <COND (<PRSO? ,ME>
+		<PERFORM ,V?TELL ,ME>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,ACTORBIT>
+		<TELL "A long silence tells you that">
+		<ARTICLE ,PRSO T>
+		<TELL " isn't interested in talking about">
+		<COND (<IN? ,PRSI ,ROOMS>
+		       <TELL " that">)
+		      (T
+		       <ARTICLE ,PRSI T>)>
+		<TELL "." CR>)
+	       (T
+		<PERFORM ,V?TELL ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-ASK-FOR ()
+	 <TELL "Unsurprisingly,">
+	 <ARTICLE ,PRSO T>
+	 <TELL " doesn't oblige." CR>>
+
+<ROUTINE V-BITE ()
+	 <HACK-HACK "Biting">>
+
+<ROUTINE V-BLOCK ()
+	 <V-DIG>>
+
+<ROUTINE V-BLOCK-WITH ()
+	 <V-DIG>>
+
+<ROUTINE PRE-BOARD ()
+	 <COND (,IN-FRONT-FLAG
+		<PERFORM ,V?STAND-BEFORE ,PRSO>
+		<RTRUE>)
+	       (<PRSO? <LOC ,PROTAGONIST>>
+		<TELL ,LOOK-AROUND CR>)>>
+
+<ROUTINE V-BOARD ("AUX" AV)
+	 <COND (<FSET? ,PRSO ,VEHBIT>
+		<TELL "You are now in">
+		<ARTICLE ,PRSO T>
+		<TELL "." CR>
+		<MOVE ,WINNER ,PRSO>
+		<COND (<NOT <EQUAL? ,HERE ,SPEEDBOAT>>
+		       <SETG LYING-DOWN T>)>
+		<APPLY <GETP ,PRSO ,P?ACTION> ,M-ENTER>
+		<RTRUE>)
+	       (T
+		<TELL "You can't get into">
+		<ARTICLE ,PRSO T>
+		<TELL "!" CR>)>>
+
+<ROUTINE V-BRUSH ()
+	 <COND (<NOT ,PRSI>
+		<COND (<HELD? ,TOOTHBRUSH>
+		       <TELL "(with the " D ,TOOTHBRUSH ")" CR>
+		       <PERFORM ,V?BRUSH ,PRSO ,TOOTHBRUSH>
+		       <RTRUE>)
+		      (T
+		       <TELL "You have nothing to brush">
+		       <ARTICLE ,PRSO T>
+		       <TELL " with." CR>)>)
+	       (<NOT <PRSI? ,TOOTHBRUSH>>
+		<TELL "With">
+		<ARTICLE ,PRSI>
+		<TELL "!" CR>)
+	       (<NOT <PRSO? ,TEETH>>
+		<TELL
+"In general, " D ,TOOTHBRUSH "es are meant for teeth." CR>)
+	       (T
+		<TELL "Congratulations on your fine dental hygiene." CR>)>>
+
+<ROUTINE V-BUY ()
+	 <TELL "Sorry,">
+	 <ARTICLE ,PRSO T>
+	 <TELL " isn't for sale." CR>>
+
+<ROUTINE V-CALL ()
+	 <COND (<NOT <EQUAL? ,HERE ,BEDROOM>>
+		<TELL "There's no phone here!" CR>)
+	       (,HEADACHE
+		<TELL "You reach for the receiver. " <PICK-ONE ,LURCHES> CR>)
+	       (<FSET? ,PHONE ,TOUCHBIT>
+		<TELL "The cable is down, remember?" CR>)
+	       (<PRSO? ,DAIS>
+		<FSET ,PHONE ,TOUCHBIT>
+		<TELL
+"You explain your situation. The desk sergeant promises to send someone
+over soon, and says not to try anything crazy in the meantime, like lying
+down in front of the " D ,BULLDOZER "." ,DIALLING-TONE CR>)
+	       (<PRSO? ,HOME>
+		<TELL "Who do you think you are, E.T.?" CR>)
+	       (<PRSO? ,MAZE>
+		<V-HELP>)
+	       (T
+		<TELL "You don't know the number." CR>)>>
+
+<ROUTINE V-CALL-WITH ()
+	 <COND (<NOT <PRSI? ,PHONE>>
+		<TELL "You can't use">
+		<ARTICLE ,PRSI>
+		<TELL " as a " D ,PHONE "." CR>)
+	       (T
+		<PERFORM ,V?CALL ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE PRE-CARVE ()
+	 <COND (<NOT <HELD? ,STONE>>
+		<TELL "You have no carving instrument." CR>)>>
+
+<ROUTINE V-CARVE ()
+	 <TELL <PICK-ONE ,YUKS> CR>>
+
+<ROUTINE V-CARVE-WITH ()
+	 <COND (<EQUAL? ,HERE ,OUTER-LAIR>
+		<COND (<PRSI? ,STONE>
+		       <PERFORM ,V?CARVE ,PRSO ,MEMORIAL>
+		       <RTRUE>)
+		      (T
+		       <TELL "No luck;">
+		       <ARTICLE ,PRSI T>
+		       <TELL
+" doesn't even scratch the " D ,MEMORIAL "." CR>)>)
+	       (T
+		<TELL "Huh?" CR>)>>
+
+<ROUTINE V-CHASTISE ()
+	 <TELL
+"Use prepositions to indicate precisely what you want to do: LOOK AT the
+object, LOOK INSIDE it, LOOK UNDER it, etc." CR>>
+
+<ROUTINE V-CLEAN ()
+	 <COND (<AND <PRSO? ,ROOMS ,GLOBAL-ROOM>
+		     <EQUAL? ,HERE ,BEDROOM>>
+		<TELL "Just as you've got it all spick and span">
+		<BETTER-LUCK>)
+	       (<PRSO? ,TEETH>
+		<PERFORM ,V?BRUSH ,TEETH>
+		<RTRUE>)
+	       (T
+		<COND (<PRSO? ,TOWEL>
+		       <SETG TOWEL-MUDDY <>>)>
+		<TELL "It is now much cleaner." CR>)>>
+
+<ROUTINE V-CLIMB-DOWN ()
+	 <COND (<PRSO? ,ROOMS>
+		<DO-WALK ,P?DOWN>)
+	       (T
+		<V-CARVE>)>>
+
+<ROUTINE V-CLIMB-FOO ()
+	 <COND (<PRSO? ,ROOMS>
+		<DO-WALK ,P?UP>)
+	       (T
+		<V-CARVE>)>>
+
+<ROUTINE V-CLIMB-ON ()
+	 <COND (<FSET? ,PRSO ,VEHBIT>
+		<PERFORM ,V?BOARD ,PRSO>
+		<RTRUE>)
+	       (T
+		<TELL "You can't climb onto">
+		<ARTICLE ,PRSO T>
+		<TELL "." CR>)>>
+
+<ROUTINE V-CLIMB-OVER ()
+	 <V-CARVE>>
+
+<ROUTINE V-CLIMB-UP ()
+	 <COND (<PRSO? ,ROOMS>
+		<DO-WALK ,P?UP>)
+	       (T
+		<V-CARVE>)>>
+
+<ROUTINE V-CLOSE ()
+	 <COND (<FSET? ,PRSO ,SURFACEBIT>
+		<V-COUNT>)
+	       (<AND <FSET? ,PRSO ,ACTORBIT>
+		     <NOT <PRSO? ,NUTRIMAT ,SCREENING-DOOR>>>
+		<V-COUNT>)
+	       (<OR <FSET? ,PRSO ,DOORBIT>
+		    <FSET? ,PRSO ,CONTBIT>>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <TELL "Okay,">
+		       <ARTICLE ,PRSO T>
+		       <TELL " is now closed." CR>
+		       <FCLEAR ,PRSO ,OPENBIT>)
+		      (T
+		       <TELL ,ALREADY-CLOSED CR>)>)
+	       (T
+		<TELL-ME-HOW>)>>
+
+<ROUTINE V-COUNT ()
+	 <TELL <PICK-ONE ,IMPOSSIBLES> CR>>
+
+<ROUTINE V-CUT ()
+	 <COND (<NOT ,PRSI>
+		<V-CARVE>)
+	       (T
+		<TELL "I doubt that the \"cutting edge\" of">
+		<ARTICLE ,PRSI>
+		<TELL " is adequate." CR>)>>
+
+<ROUTINE V-DIG ()
+	 <TELL <PICK-ONE ,WASTES> CR>>
+
+<ROUTINE V-DISEMBARK ()
+	 <COND (<AND <FSET? ,PRSO ,TAKEBIT> ;"since GET OUT is also TAKE OUT"
+		     <EQUAL? <META-LOC ,PRSO> ,HERE>
+		     <NOT <IN? ,PRSO ,HERE>>
+		     <NOT <IN? ,PRSO ,PROTAGONIST>>>
+		<PERFORM ,V?TAKE ,PRSO>
+		<RTRUE>)
+	       (<NOT <EQUAL? <LOC ,WINNER> ,PRSO>>
+		<TELL ,LOOK-AROUND CR>
+		<RFATAL>)
+	       (T
+		<OWN-FEET>
+		<SETG LYING-DOWN <>>
+		<MOVE ,WINNER ,HERE>)>>
+
+<ROUTINE V-DOZE ()
+	 <TELL "You doze for several minutes. ">
+	 <V-WAIT>>
+
+<ROUTINE V-DRINK ("AUX" S)
+	 <TELL "You can't drink that!" CR>>
+
+<ROUTINE V-DRINK-FROM ()
+	 <V-COUNT>>
+
+<ROUTINE PRE-DROP ()
+	 <COND (<IDROP>
+		<RTRUE>)>>
+
+<ROUTINE V-DROP ()
+	 <COND (<EQUAL? ,HERE ,MAZE>
+		<COND (<NOT <PRSO? ,THING>>
+		       <SETG BRAIN-DAMAGED ,PRSO>)>
+		<MOVE ,PRSO ,LOCAL-GLOBALS>
+		<TELL "As you release">
+		<ARTICLE ,PRSO T>
+		<TELL ", it vanishes into the maze of synapses." CR>)
+	       (<EQUAL? ,HERE ,ACCESS-SPACE>
+		<MOVE ,PRSO ,LOCAL-GLOBALS>
+		<TELL "If you recall, the floor is just an open mesh, and">
+		<ARTICLE ,PRSO T>
+		<TELL " drops through and disappears." CR>)
+	       (T
+		<MOVE ,PRSO ,HERE>
+		<TELL "Dropped." CR>)>>
+
+<ROUTINE V-EAT ()
+	 <TELL "Stuffing">
+	 <ARTICLE ,PRSO T>
+	 <TELL " in your mouth would do little to help at this point." CR>>
+
+<ROUTINE V-ENJOY ()
+	 <COND (<FSET? ,PRSO ,ACTORBIT>
+		<V-KISS>)
+	       (T
+		<TELL "Not difficult at all, considering how enjoyable">
+	        <ARTICLE ,PRSO T>
+	        <TELL " is." CR>)>>
+
+<ROUTINE V-ENTER ("AUX" VEHICLE)
+	 <COND (<SET VEHICLE <FIND-IN ,HERE ,VEHBIT>>
+		<PERFORM ,V?BOARD .VEHICLE>
+		<RTRUE>)
+	       (T
+		<DO-WALK ,P?IN>)>>
+
+<ROUTINE V-ESCAPE ()
+	 <SETG DREAMING <>>
+	 <TELL
+"You are so keen on escape that you literally leap through the fabric of the
+space-time continuum. You wake up in a shack on tenth-century Earth. A dressing
+gown, a " D ,TOOTHBRUSH>
+	 <JIGS-UP
+", and a flathead axe lie by your bed. Before you have a chance to move, Mongol
+hordes sweep magnificently across the plains of central Asia. They knock down
+your shack and burn the remains with you inside. You lose interest in the rest
+of the game.">
+	 <RTRUE>>
+
+<ROUTINE V-EXAMINE ()
+	 <COND (<FSET? ,PRSO ,DOORBIT>
+		<V-LOOK-INSIDE>)
+	       (<AND <FSET? ,PRSO ,CONTBIT>
+		     <NOT <FSET? ,PRSO ,ACTORBIT>>>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <V-LOOK-INSIDE>)
+		      (T
+		       <TELL "It's closed." CR>)>)
+	       (<GETP ,PRSO ,P?TEXT>
+		<PERFORM ,V?READ ,PRSO>
+		<RTRUE>)
+	       (<PRSO? ,BROWNIAN-SOURCE>
+		<PERFORM ,V?EXAMINE ,DANGLY-BIT>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,TOOLBIT>
+		<TELL
+,IT-LOOKS-LIKE " every other " D ,PRSO " you've ever seen." CR>)
+	       (<PRSO? ,EYES ,TEETH ,HEAD ,EARS>
+		<TELL "That would involve quite a contortion." CR>)
+	       (T
+		<TELL "You see nothing special about">
+		<ARTICLE ,PRSO T>
+		<TELL "." CR>)>>
+
+<ROUTINE V-EXAMINE-THROUGH ()
+	 <TELL "This reveals nothing new." CR>>
+
+<ROUTINE V-EXIT ()
+	 <COND (<FSET? ,PRSO ,VEHBIT>
+		<PERFORM ,V?DISEMBARK ,PRSO>
+		<RTRUE>)
+	       (T
+		<DO-WALK ,P?OUT>)>>
+
+<ROUTINE V-FEED ("AUX" FOOD)
+	 <COND (<SET FOOD <FIND-IN ,PROTAGONIST ,EATBIT>>
+		<TELL "(the " D .FOOD ")" CR>
+		<PERFORM ,V?GIVE .FOOD ,PRSO>
+		<RTRUE>)
+	       (T
+		<TELL "You have nothing to feed">
+		<ARTICLE ,PRSO T>
+		<TELL " with." CR>)>>
+
+<ROUTINE V-FILL ()
+	 <TELL "Phil who?" CR>>
+
+<ROUTINE V-FIND ("OPTIONAL" (WHERE <>) "AUX" (L <LOC ,PRSO>))
+	 <COND (<PRSO? ,HANDS ,HEAD ,EARS ,TEETH ,EYES>
+		<TELL "Are you sure">
+		<ARTICLE ,PRSO T>
+		<TELL " is lost?" CR>)
+	       (<PRSO? ,ME>
+		<TELL "You're in">
+		<ARTICLE ,HERE T>
+		<TELL "." CR>)
+	       (<IN? ,PRSO ,PROTAGONIST>
+		<TELL "You have it!" CR>)
+	       (<AND <PRSO? ,PROSSER>
+		     <EQUAL? ,IDENTITY-FLAG ,FORD>
+		     <NOT ,GONE-AROUND>>
+		<TELL "He's " ,ON-OTHER-SIDE " of the " D ,BULLDOZER "." CR>)
+	       (<OR <IN? ,PRSO ,HERE>
+		    <PRSO? ,PSEUDO-OBJECT>
+		    <AND <PRSO? ,MECHANISM>
+			 <EQUAL? ,HERE ,ACCESS-SPACE>>
+		    <AND <PRSO? ,HATCH>
+			 <EQUAL? ,HERE ,HATCHWAY>>>
+		<TELL "Right in front of you." CR>)
+	       (<GLOBAL-IN? ,PRSO ,HERE>
+		<TELL "You figure it out!" CR>)
+	       (<AND <FSET? .L ,ACTORBIT>
+		     <VISIBLE? .L>>
+		<TELL "As far as you can tell,">
+		<ARTICLE .L T>
+		<TELL " has it." CR>)
+	       (<AND <FSET? .L ,CONTBIT>
+		     <VISIBLE? ,PRSO>>
+		<TELL "It's in">
+		<ARTICLE .L T>
+		<TELL "." CR>)
+	       (.WHERE
+		<TELL "Beats me." CR>)
+	       (T
+		<TELL "You'll have to do that yourself." CR>)>>
+
+<ROUTINE V-FIRST-LOOK ()
+	 <COND (<DESCRIBE-ROOM>
+		<COND (<EQUAL? ,VERBOSITY 1 2>
+		       <DESCRIBE-OBJECTS>)>)>>
+
+<ROUTINE V-FLIPSWITCH ()
+	 <COND (<AND <FSET? ,PRSO ,SWITCHBIT>
+		     <PRSI? ,INTNUM>
+		     <L? ,P-NUMBER 9>
+		     <VISIBLE? ,BOARD>>
+		<PERFORM ,V?TURN ,DIPSWITCH>
+		<RTRUE>)
+	       (T
+		<V-TELL-TIME>)>>
+
+<ROUTINE V-FOLLOW ()
+	 <COND (<IN? ,PRSO ,HERE>
+		<TELL "But">
+		<ARTICLE ,PRSO T>
+		<TELL " is right here!" CR>)
+	       (<NOT <FSET? ,PRSO ,ACTORBIT>>
+		<V-COUNT>)
+	       (T
+		<TELL "You have no idea where">
+		<ARTICLE ,PRSO T>
+		<TELL " is." CR>)>>
+
+<GLOBAL FOLLOW-FLAG <>>
+
+<ROUTINE I-FOLLOW ()
+	 <SETG FOLLOW-FLAG <>>
+	 <RFALSE>>
+
+<ROUTINE V-FOOTNOTE ()
+	 <COND (<OR <NOT ,PRSO>
+		    <NOT <PRSO? ,INTNUM>>>
+		<TELL "Specify a number, as in \"FOOTNOTE 6.\"" CR>)
+	       (<EQUAL? ,P-NUMBER 1>
+		<TELL
+"In case anyone is interested, this quotation is from a letter written by John
+Keats, and thus he becomes the first major 19th Century British poet to feature
+in a computer game." CR>)
+	       (<EQUAL? ,P-NUMBER 2>
+		<TELL "Bob Dylan, 1969." CR>)
+	       (<EQUAL? ,P-NUMBER 3>
+		<TELL "A meaningless coincidence." CR>)
+	       (<EQUAL? ,P-NUMBER 4>
+		<TELL
+"The first single they recorded on their own Apple label, and one of
+their most successful songs ever." CR>)
+	       (<EQUAL? ,P-NUMBER 5>
+		<TELL
+"Peacefully for a " D ,BEAST " that is. Now and then it snorts or rolls over,
+and the walls shake a bit." CR>)
+	       (<EQUAL? ,P-NUMBER 6>
+		<TELL "That was just an example." CR>)
+	       (<EQUAL? ,P-NUMBER 7>
+		<SETG AWAITING-REPLY 13>
+		<ENABLE <QUEUE I-REPLY 1>> ;"only 1 since FOOTNOTE isn't move"
+		<NOT-VERY-GOOD "gun">)
+	       (<EQUAL? ,P-NUMBER 8>
+		<SETG AWAITING-REPLY 13>
+		<ENABLE <QUEUE I-REPLY 1>> ;"only 1 since FOOTNOTE isn't move"
+		<NOT-VERY-GOOD "legend">)
+	       (<EQUAL? ,P-NUMBER 9>
+		<TELL
+"Unfortunately, you couldn't hear a word of it, because sound doesn't travel
+in a vacuum." CR>)
+	       (<EQUAL? ,P-NUMBER 10>
+		<TELL
+"I guess it isn't all that dangerous a place after all." CR>)
+	       (<EQUAL? ,P-NUMBER 11> ;"not referenced"
+		<SETG AWAITING-REPLY 14>
+		<ENABLE <QUEUE I-REPLY 2>>
+		<TELL "Isn't it fun reading through all the footnotes?" CR>)
+	       (<EQUAL? ,P-NUMBER 12>
+	        <TELL
+"This is the famous recursive footnote (Footnote 12)." CR>)
+	       (<EQUAL? ,P-NUMBER 13>
+		<SETG AWAITING-REPLY 13>
+		<ENABLE <QUEUE I-REPLY 1>>
+		<NOT-VERY-GOOD "autopilot">)
+	       (<EQUAL? ,P-NUMBER 14>
+		<TELL
+,GUIDE-NAME " is also the name of a terrific work of interactive fiction by
+Douglas Adams and S. Eric Meretzky." ,ALREADY-KNOW-THAT CR>)
+	       (<EQUAL? ,P-NUMBER 15>
+		<SETG AWAITING-REPLY 13>
+		<ENABLE <QUEUE I-REPLY 1>>
+		<NOT-VERY-GOOD "banner">)
+	       (T
+		<TELL "There is no Footnote " N ,P-NUMBER "." CR>)>>
+
+<ROUTINE V-FRIPPI ()
+	 <TELL "Aaaaaaarggggghhhhhh!" CR>>
+
+<ROUTINE V-GET-DRESSED (GARMENT)
+	 <COND (<PRSO? ,ROOMS>
+		<COND (<OR <NOT <EQUAL? ,IDENTITY-FLAG ,ARTHUR>>
+			   <FSET? ,GOWN ,WORNBIT>>
+		       <TELL "You are!" CR>)
+		      (<HELD? ,GOWN>
+		       <PERFORM ,V?WEAR ,GOWN>
+		       <RTRUE>)
+		      (<VISIBLE? ,GOWN>
+		       <TELL ,NOT-HOLDING " " D ,GOWN "." CR>)
+		      (T
+		       <TELL "There's nothing to wear here." CR>)>)
+	       (T
+		<V-TELL-TIME>)>>
+
+<ROUTINE V-GET-DRUNK ()
+	 <COND (<PRSO? ,ROOMS>
+		<COND (<EQUAL? ,HERE ,PUB>
+		       <TELL
+"You get drunk and have a terrific time for twelve minutes, are the life and
+soul of the Pub, tell some really great stories, make everyone laugh a lot,
+and they all clap you on the back and tell you what a great chap you are and
+then the Earth gets unexpectedly demolished">
+		       <COND (<EQUAL? ,IDENTITY-FLAG ,ARTHUR>
+			      <TELL
+". You wake up with a hangover which lasts for all eternity." CR>
+			      <FINISH>)
+			     (T
+			      <JIGS-UP ".">)>)
+		      (<EQUAL? ,HERE ,LIVING-ROOM ,DINING-ROOM ,KITCHEN>
+		       <TELL ,YOU-ARE CR>)
+		      (T
+		       <TELL "You can't see any alcohol here!" CR>)>)
+	       (T
+		<V-TELL-TIME>)>>
+
+<ROUTINE V-GET-UNDRESSED ()
+	 <COND (<NOT ,PRSO>
+		<SETG PRSO ,ROOMS>)>
+	 <COND (<PRSO? ,ROOMS>
+		<COND (<FSET? ,GOWN ,WORNBIT>
+		       <PERFORM ,V?TAKE-OFF ,GOWN>
+		       <RTRUE>)
+		      (<EQUAL? ,IDENTITY-FLAG ,ARTHUR>
+		       <TELL "You're not wearing anything!" CR>)
+		      (T
+		       <TELL ,ARRESTED CR>)>)
+	       (T
+		<V-TELL-TIME>)>>
+
+<ROUTINE PRE-GIVE ()
+	 <COND (<IDROP>
+		<RTRUE>)>>
+
+<ROUTINE V-GIVE ()
+	 <COND (<FSET? ,PRSI ,ACTORBIT>
+		<TELL "Politely,">
+		<ARTICLE ,PRSI T>
+		<TELL " refuses your offer." CR>)
+	       (T
+		<TELL "You can't give">
+		<ARTICLE ,PRSO>
+		<TELL " to">
+		<ARTICLE ,PRSI>
+		<TELL "!" CR>)>>
+
+<ROUTINE V-GIVE-UP ()
+	 <COND (<PRSO? ,ROOMS>
+		<V-QUIT>)
+	       (T
+		<V-TELL-TIME>)>>
+
+<ROUTINE V-HANG ()
+	 <TELL "You can't hang something from">
+	 <ARTICLE ,PRSI>
+	 <TELL "!" CR>>
+
+<ROUTINE V-HELLO ()
+       <COND (<AND ,PRSO
+		   <FSET? ,PRSO ,ACTORBIT>>
+	      <TELL "\"Hello to you too.\"" CR>)
+	     (,PRSO
+	      <PERFORM ,V?TELL ,PRSO>
+	      <RTRUE>)
+	     (T
+	      <PERFORM ,V?TELL ,ME>
+	      <RTRUE>)>>
+
+<ROUTINE V-HELP ()
+	 <TELL
+"If you're really stuck, a complete map and InvisiClues Hint Booklet are
+available from your dealer, or via mail order with the form that came in
+your package." CR>>
+
+<ROUTINE V-HIDE ()
+	 <TELL "There's no place to hide here." CR>>
+
+<ROUTINE V-HITCHHIKE ()
+	 <PERFORM ,V?PUSH ,GREEN-BUTTON>
+	 <RTRUE>>
+
+<ROUTINE V-I-AM ()
+	 <TELL "Pleased to meet you. I'm your computer." CR>>
+
+<ROUTINE V-IDIOT ()
+	 <PERFORM ,V?TELL ,ME>
+	 <RTRUE>>
+
+<ROUTINE V-KICK ()
+	 <HACK-HACK "Kicking">>
+
+<ROUTINE V-KILL ()
+	 <TELL
+"You are obviously letting things get to you. You should learn to
+relax a little." CR>>
+
+<ROUTINE V-KNEEL ()
+	 <V-TASTE>>
+
+<ROUTINE V-KNOCK ()
+	 <COND (<FSET? ,PRSO ,DOORBIT>
+		<TELL "Nobody's home." CR>)
+	       (T
+		<HACK-HACK "Knocking on">)>>
+
+<ROUTINE V-KISS ()
+	 <TELL "This is family entertainment, not a video nasty." CR>>
+
+<ROUTINE V-LAMP-OFF ()
+	 <COND (<AND <FSET? ,PRSO ,LIGHTBIT>
+		     <NOT <FSET? ,PRSO ,ONBIT>>>
+		<TELL "It is already off." CR>)
+	       (<AND <PRSO? ,INTNUM>
+			 <L? ,P-NUMBER 9>
+			 <ACCESSIBLE? ,BOARD>>
+		<PERFORM ,V?TURN ,DIPSWITCH>
+		<RTRUE>)
+	       (T
+		<TELL "You can't turn that off." CR>)>>
+
+<ROUTINE V-LAMP-ON ()
+	 <COND (<AND <FSET? ,PRSO ,LIGHTBIT>
+		     <FSET? ,PRSO ,ONBIT>>
+		<TELL "It is already on." CR>)
+	       (<AND <PRSO? ,INTNUM>
+		     <L? ,P-NUMBER 9>
+		     <ACCESSIBLE? ,BOARD>>
+		<PERFORM ,V?TURN ,DIPSWITCH>
+		<RTRUE>)
+	       (T
+		<TELL "You can't turn that on." CR>)>>
+
+<ROUTINE V-LEAP ()
+	 <COND (,LYING-DOWN
+		<TELL ,WHILE-LYING CR>)
+	       (<EQUAL? ,HERE ,CAPTAINS-QUARTERS>
+		<V-STAND>)
+	       (<AND ,PRSO
+		     <NOT <IN? ,PRSO ,HERE>>>
+		<V-COUNT>)
+	       (<AND <NOT ,PRSO>
+		     <EQUAL? ,HERE ,SPEEDBOAT>>
+		<TELL ,DONT-MIX CR>
+		<RTRUE>)
+	       (T
+		<V-SKIP>)>>
+
+<ROUTINE V-LEAVE ()
+	 <COND (<NOT ,PRSO>
+		<SETG PRSO ,ROOMS>)>
+	 <COND (<PRSO? ,ROOMS>
+		<DO-WALK ,P?OUT>)
+	       (<PRSO? <LOC ,WINNER>>
+		<PERFORM ,V?DISEMBARK ,PRSO>
+		<RTRUE>)
+	       (T
+		<PERFORM ,V?DROP ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-LIE-DOWN ()
+	 <COND (<EQUAL? ,HERE ,CAPTAINS-QUARTERS>
+		<V-STAND>)
+	       (<PRSO? ,ROOMS>
+		<COND (<EQUAL? ,HERE ,BEDROOM>
+		       <PERFORM ,V?LIE-DOWN ,BED>
+		       <RTRUE>)
+		      (T
+		       <PERFORM ,V?LIE-DOWN ,GROUND>
+		       <RTRUE>)>)
+	       (T
+		<PERFORM ,V?BOARD ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-LISTEN ()
+	 <TELL "At the moment,">
+	 <ARTICLE ,PRSO T>
+	 <TELL " makes no sound." CR>>
+
+<ROUTINE V-LOCK ()
+	 <V-CARVE>>
+
+<ROUTINE V-LOOK ()
+	 <COND (<FSET? ,TOWEL ,WORNBIT>
+		<TELL "You see a towel." CR>)
+	       (<DESCRIBE-ROOM T>
+		<DESCRIBE-OBJECTS T>)>>
+
+<ROUTINE V-LOOK-BEHIND ()
+	 <TELL "There is nothing behind">
+	 <ARTICLE ,PRSO T>
+	 <TELL "." CR>>
+
+<ROUTINE V-LOOK-DOWN ()
+	 <COND (<NOT ,LIT>
+		<TELL ,TOO-DARK CR>)
+	       (<PRSO? ,ROOMS>
+		<PERFORM ,V?EXAMINE ,GROUND>
+		<RTRUE>)
+	       (T
+		<PERFORM ,V?LOOK-INSIDE ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-LOOK-INSIDE ()
+	 <COND (<AND <FSET? ,PRSO ,ACTORBIT>
+		     <NOT <PRSO? ,SCREENING-DOOR>>>
+		<TELL "There is nothing special to be seen." CR>)
+	       (<AND <PRSO? ,SPARE-DRIVE ,THUMB ,PLOTTER>>
+		<TELL "You can't do that." CR>)
+	       (<FSET? ,PRSO ,SURFACEBIT>
+		<COND (<PRSO? <LOC ,WINNER>>
+		       <DESCRIBE-VEHICLE>
+		       <RTRUE>)
+		      (<FIRST? ,PRSO>
+		       <PRINT-CONT ,PRSO>)
+		      (T
+		       <TELL "There is nothing on">
+		       <ARTICLE ,PRSO T>
+		       <TELL "." CR>)>)
+	       (<FSET? ,PRSO ,DOORBIT>
+		<TELL "All you can tell is that">
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <ARTICLE ,PRSO T>
+		       <TELL " is open.">)
+		      (T
+		       <ARTICLE ,PRSO T>
+		       <TELL " is closed.">)>
+		<CRLF>)
+	       (<FSET? ,PRSO ,CONTBIT>
+		<COND (<PRSO? <LOC ,WINNER>>
+		       <DESCRIBE-VEHICLE>
+		       <RTRUE>)
+		      (<SEE-INSIDE? ,PRSO>
+		       <COND (<FIRST? ,PRSO>
+			      <PRINT-CONT ,PRSO>)
+			     (T
+			      <TELL "It's empty." CR>)>)
+		      (<AND <NOT <FSET? ,PRSO ,OPENBIT>>
+			    <FIRST? ,PRSO>>
+		       <PERFORM ,V?OPEN ,PRSO>
+		       <RTRUE>)
+		      (T
+		       <TELL "It seems that">
+		       <ARTICLE ,PRSO T>
+		       <TELL " is closed." CR>)>)
+	       (T
+		<TELL "You can't do that." CR>)>>
+
+<ROUTINE V-LOOK-UNDER ()
+	 <COND (<HELD? ,PRSO>
+		<COND (<FSET? ,PRSO ,WORNBIT>
+		       <TELL "You're wearing it!" CR>)
+		      (T
+		       <TELL "You're holding it!" CR>)>)
+	       (T
+		<TELL "There is nothing but ">
+		<COND (<PRSO? ,HOOK>
+		       <TELL "a " D ,FISH-HOLE>)
+		      (<PRSO? ,BOAT-OBJECT>
+		       <TELL "water">)
+		      (<AND <PRSO? ,TOWEL>
+			    <FSET? ,TOWEL ,SURFACEBIT>>
+		       <TELL "a drain">)
+		      (T
+		       <TELL "dust">)>
+		<TELL " there." CR>)>>
+
+<ROUTINE V-LOOK-UP ()
+	 <COND (<NOT ,LIT>
+		<TELL ,TOO-DARK CR>)
+	       (<PRSO? ,ROOMS>
+		<COND (<FSET? ,HERE ,OUTSIDEBIT>
+		       <PERFORM ,V?EXAMINE ,SKY>
+		       <RTRUE>)
+		      (T
+		       <PERFORM ,V?EXAMINE ,CEILING>
+		       <RTRUE>)>)
+	       (T
+		<PERFORM ,V?LOOK-INSIDE ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-LOWER ()
+	 <V-RAISE>>
+
+<ROUTINE V-MAKE ()
+	 <TELL "You can't make">
+	 <ARTICLE ,PRSO>
+	 <TELL "!" CR>>
+
+<ROUTINE V-MOVE ()
+	 <COND (<HELD? ,PRSO>
+		<TELL "Why juggle objects?" CR>)
+	       (<PRSO? ,PANEL-BLOCKER>
+		<SETG PANEL-BLOCKER <>>
+		<TELL
+"Okay, it's no longer in front of the " D ,ROBOT-PANEL "." CR>)
+	       (<FSET? ,PRSO ,INTEGRALBIT>
+		<PART-OF>)
+	       (<LOC-CLOSED>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,TAKEBIT>
+		<TELL "Moving">
+		<ARTICLE ,PRSO T>
+		<TELL " reveals nothing." CR>)
+	       (<AND <PRSO? ,INTNUM>
+		     <L? ,P-NUMBER 9>
+		     <ACCESSIBLE? ,BOARD>>
+		<PERFORM ,V?TURN ,DIPSWITCH>
+		<RTRUE>)
+	       (T
+		<TELL "You can't move">
+		<ARTICLE ,PRSO T>
+		<TELL "." CR>)>>
+
+<ROUTINE V-MUNG ()
+	 <HACK-HACK "Trying to break">>
+
+<ROUTINE V-MY-NAME ()
+	 <COND (<PRSO? ,NAME>
+		<V-I-AM>)
+	       (T
+		<V-TELL-TIME>)>>
+
+<ROUTINE V-NO ()
+	 <COND (<EQUAL? ,AWAITING-REPLY 1>
+		<RFALSE>)
+	       (<EQUAL? ,AWAITING-REPLY 2>
+		<DO-WALK ,P?SOUTH>)
+	       (<EQUAL? ,AWAITING-REPLY 3 10>
+		<TELL "I should think not." CR>)
+	       (<EQUAL? ,AWAITING-REPLY 4>
+		<TELL "The word \"no\" is not in our hostess' vocabulary." CR>)
+	       (<EQUAL? ,AWAITING-REPLY 5>
+		<SETG AWAITING-REPLY 3>
+		<V-YES>)
+	       (<EQUAL? ,AWAITING-REPLY 6 11>
+		<SETG AWAITING-REPLY 6>
+		<V-YES>)
+	       (<OR <EQUAL? ,AWAITING-REPLY 7 8>
+		    <EQUAL? ,AWAITING-REPLY 13 15>>
+		<SETG AWAITING-REPLY 3>
+		<V-YES>)
+	       (<EQUAL? ,AWAITING-REPLY 9>
+		<TELL "I disagree." CR>)
+	       (<EQUAL? ,AWAITING-REPLY 12>
+		<ENGINEER-LEAVE>
+		<TELL
+"\"Think you're funny, huh?\" The " D ,ENGINEER ,ROARS-OFF ", making sure
+to spray you with his Sub-Ethon exhaust." CR>)
+	       (<EQUAL? ,AWAITING-REPLY 14>
+		<TELL "Then stop." CR>)
+	       (<EQUAL? ,AWAITING-REPLY 16>
+		<TELL "I didn't think so." CR>)
+	       (<EQUAL? ,AWAITING-REPLY 18 19>
+		<V-YES>)
+	       (T
+		<TELL "You sound rather negative." CR>)>>
+
+<ROUTINE V-OPEN ("AUX" F STR)
+	 <COND (<FSET? ,PRSO ,SURFACEBIT>
+		<V-COUNT>)
+	       (<AND <FSET? ,PRSO ,ACTORBIT>
+		     <NOT <PRSO? ,NUTRIMAT>>>
+		<V-COUNT>)
+	       (<FSET? ,PRSO ,CONTBIT>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <TELL ,ALREADY-OPEN CR>)
+		      (T
+		       <FSET ,PRSO ,OPENBIT>
+		       <FSET ,PRSO ,TOUCHBIT>
+		       <COND (<OR <NOT <FIRST? ,PRSO>>
+				  <FSET? ,PRSO ,TRANSBIT>>
+			      <TELL "Opened." CR>)
+			     ;(<AND <SET F <FIRST? ,PRSO>>
+				   <NOT <NEXT? .F>>
+				   <SET STR <GETP .F ,P?FDESC>>>
+			      <TELL "Okay,">
+			      <ARTICLE ,PRSO T>
+			      <TELL " is now open." CR>
+			      <TELL .STR CR>)
+			     (T
+			      <TELL "Opening">
+			      <ARTICLE ,PRSO T>
+			      <TELL " reveals">
+			      <PRINT-CONTENTS ,PRSO>
+			      <TELL "." CR>)>)>)
+	       (<FSET? ,PRSO ,DOORBIT>
+		<COND (<FSET? ,PRSO ,OPENBIT>
+		       <TELL ,ALREADY-OPEN CR>)
+		      (T
+		       <TELL "Okay,">
+		       <ARTICLE ,PRSO T>
+		       <TELL " is now open." CR>
+		       <FSET ,PRSO ,OPENBIT>)>)
+	       (T
+		<TELL-ME-HOW>)>>
+
+<ROUTINE V-PANIC ()
+	 <TELL "Not surprised." CR>>
+
+<ROUTINE V-PICK ()
+	 <V-COUNT>>
+
+<ROUTINE V-PICK-UP ()
+	 <PERFORM ,V?TAKE ,PRSO ,PRSI>
+	 <RTRUE>>
+
+<ROUTINE V-PLANT ()
+	 <COND (<PRSI? ,FLOWERPOT>
+		<PERFORM ,V?PUT ,PRSO ,PRSI>
+		<RTRUE>)
+	       (T
+		<TELL "You can't plant something in">
+		<ARTICLE ,PRSI>
+		<TELL "." CR>)>>
+
+<ROUTINE V-PLUG ()
+	 <TELL "You can't seem to plug">
+	 <ARTICLE ,PRSO T>
+	 <TELL " into">
+	 <ARTICLE ,PRSI T>
+	 <TELL "." CR>>
+
+<ROUTINE V-POINT ()
+	 <COND (<EQUAL? ,HERE ,SPEEDBOAT>
+		<PERFORM ,V?STEER ,BOAT-OBJECT ,PRSO>
+		<RTRUE>)
+	       (T
+		<V-STEER>)>>
+
+<ROUTINE V-POUR ()
+	 <V-CARVE>>
+
+<ROUTINE V-PROTEST ()
+	 <COND (<AND <EQUAL? ,HERE ,FRONT-OF-HOUSE>
+		     <RUNNING? ,I-BULLDOZER>>
+		<TELL
+"Prosser says \"I wouldn't stop the " D ,BULLDOZER " even if you were lying in
+front of it!\"" CR>)
+	       (T
+		<TELL "To whom? About what? Why?" CR>)>>
+
+<ROUTINE V-PULL-TOGETHER ()
+	 <V-TELL-TIME>>
+
+<ROUTINE V-PUSH ()
+	 <COND (<AND <PRSO? ,INTNUM>
+		     <L? ,P-NUMBER 9>
+		     <ACCESSIBLE? ,BOARD>>
+		<PERFORM ,V?TURN ,DIPSWITCH>
+		<RTRUE>)
+	       (T
+		<HACK-HACK "Pushing">)>>
+
+<ROUTINE PRE-PUT ()
+	 <COND (<PRSI? ,GROUND>
+		<PERFORM ,V?DROP ,PRSO>
+		<RTRUE>)
+	       (<HELD? ,PRSI ,PRSO>
+;"formerly <PRSO? <LOC ,PRSI>> but that only checked down one level"
+		<TELL "You can't put">
+		<ARTICLE ,PRSO T>
+		<TELL " in">
+		<ARTICLE ,PRSI T>
+		<TELL " when">
+		<ARTICLE ,PRSI T>
+		<TELL " is already in">
+		<ARTICLE ,PRSO T>
+		<TELL "!" CR>)
+	       (<IDROP>
+		<RTRUE>)
+	       (,IN-FRONT-FLAG
+		<PERFORM ,V?PUT-IN-FRONT ,PRSO ,PRSI>
+		<RTRUE>)
+	       (<PRSO? ,TEA>
+		<PERFORM ,V?POUR ,TEA ,PRSI>
+		<RTRUE>)
+	       (<PRSO? ,BROWNIAN-SOURCE>
+		<SETG BROWNIAN-SOURCE <>>
+		<REMOVING-BIT>
+		<RFALSE>)
+	       (<AND <PRSO? ,PLOTTER>
+		     ,BROWNIAN-SOURCE>
+		<SETG BROWNIAN-SOURCE <>>
+		<REMOVING-BIT>
+		<RFALSE>)
+	       (<OR <AND <PRSO? ,PLOTTER>
+			 ,DRIVE-TO-PLOTTER>
+		    <AND <PRSO? ,SPARE-DRIVE>
+			 ,DRIVE-TO-PLOTTER>
+		    <AND <PRSO? ,SPARE-DRIVE>
+			 ,DRIVE-TO-CONTROLS>>
+		<TELL "You'll have to unplug it first." CR>)>>
+
+<ROUTINE V-PUT ()
+	 <COND (<AND <NOT <FSET? ,PRSI ,OPENBIT>>
+		     <NOT <FSET? ,PRSI ,DOORBIT>>
+		     <NOT <FSET? ,PRSI ,CONTBIT>>
+		     <NOT <FSET? ,PRSI ,SURFACEBIT>>
+		     <NOT <FSET? ,PRSI ,VEHBIT>>>
+		<TELL "You can't put">
+		<ARTICLE ,PRSO T>
+		<TELL " in">
+		<ARTICLE ,PRSI>
+		<TELL "!" CR>
+		<RTRUE>)
+	       (<OR <PRSI? ,PRSO>
+		    <AND <HELD? ,PRSO>
+			 <NOT <FSET? ,PRSO ,TAKEBIT>>>
+		    <PRSI? ,SPARE-DRIVE ,THUMB ,PLOTTER>>
+		<TELL "How can you do that?" CR>)
+	       (<AND <NOT <FSET? ,PRSI ,OPENBIT>>
+		     <NOT <FSET? ,PRSI ,SURFACEBIT>>>
+		<TELL "Inspection reveals that">
+		<ARTICLE ,PRSI T>
+		<TELL " isn't open." CR>
+		<SETG P-IT-OBJECT ,PRSI>)
+	       (<IN? ,PRSO ,PRSI>
+		<TELL "I think">
+		<ARTICLE ,PRSO T>
+		<TELL " is already in">
+		<ARTICLE ,PRSI T>
+		<TELL "." CR>)
+	       (<G? <- <+ <WEIGHT ,PRSI> <GETP ,PRSO ,P?SIZE>>
+		       <GETP ,PRSI ,P?SIZE>>
+		    <GETP ,PRSI ,P?CAPACITY>>
+		<COND (<FSET? ,PRSI ,VEHBIT>
+		       <V-DIG>)
+		      (T
+		       <TELL "There's no room." CR>)>)
+	       (<AND <NOT <HELD? ,PRSO>>
+		     <EQUAL? <ITAKE> ,M-FATAL <>>>
+		<RTRUE>)
+	       (T
+		<MOVE ,PRSO ,PRSI>
+		<FSET ,PRSO ,TOUCHBIT>
+		<TELL "Done." CR>)>>
+
+<ROUTINE V-PUT-BEHIND ()
+	 <V-DIG>>
+
+<ROUTINE V-PUT-IN-FRONT ()
+	 <V-DIG>>
+
+<ROUTINE V-PUT-ON ()
+	 <COND (<PRSI? ,ME>
+		<PERFORM ,V?WEAR ,PRSO>
+		<RTRUE>)
+	       (<FSET? ,PRSI ,SURFACEBIT>
+		<V-PUT>)
+	       (<PRSI? ,HEAD ,EYES>
+		<TELL "You can't cover">
+		<ARTICLE ,PRSI T>
+		<TELL " with that." CR>)
+	       (T
+		<TELL "There's no good surface on">
+		<ARTICLE ,PRSI T>
+		<TELL "." CR>)>>
+
+<ROUTINE V-PUT-UNDER ()
+         <V-DIG>>
+
+<ROUTINE V-RAPE ()
+	 <V-KISS>>
+
+<ROUTINE V-RAISE ()
+	 <HACK-HACK "Playing in this way with">>
+
+;<ROUTINE V-REACH-IN ("AUX" OBJ)
+	 <COND (<OR <NOT <FSET? ,PRSO ,CONTBIT>>
+		    <FSET? ,PRSO ,ACTORBIT>>
+		<V-CARVE>)
+	       (<NOT <FSET? ,PRSO ,OPENBIT>>
+		<TELL "It's not open." CR>)
+	       (<OR <NOT <SET OBJ <FIRST? ,PRSO>>>
+		    <FSET? .OBJ ,INVISIBLE>
+		    <NOT <FSET? .OBJ ,TAKEBIT>>>
+		<TELL "It's empty." CR>)
+	       (T
+		<TELL "You reach into">
+		<ARTICLE ,PRSO T>
+		<TELL " and feel something." CR>
+		<RTRUE>)>>
+
+<ROUTINE PRE-READ ()
+	 <COND (<AND <FSET? ,TOWEL ,WORNBIT>
+		     <NOT <PRSO? ,TOWEL>>>
+		<TELL ,WITH-TOWEL CR>)
+	       (<AND <NOT ,LIT>
+		     <NOT <PRSO? ,HANGOVER>>>
+		<TELL ,TOO-DARK CR>)
+	       (<AND ,PRSI
+		     <NOT <FSET? ,PRSI ,TRANSBIT>>>
+		<TELL "How does one look through">
+		<ARTICLE ,PRSI>
+		<TELL "?" CR>)>>
+
+<ROUTINE V-READ ()
+	 <COND (<FSET? ,PRSO ,READBIT>
+		<TELL <GETP ,PRSO ,P?TEXT> CR>)
+               (T
+                <TELL "How can you read">
+		<ARTICLE ,PRSO>
+		<TELL "?" CR>)>>
+
+<ROUTINE V-REFUSE ()
+	 <SETG PRSA ,V?TAKE>
+	 <DONT-F>>
+
+<ROUTINE V-RELAX ()
+	 <TELL ,ZEN CR>>
+
+<ROUTINE V-REMOVE ()
+	 <COND (<FSET? ,PRSO ,WEARBIT>
+		<PERFORM ,V?TAKE-OFF ,PRSO>
+		<RTRUE>)
+	       (T
+		<PERFORM ,V?TAKE ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-REPLACE ()
+	 <TELL "It's not in need of replacement." CR>>
+
+<ROUTINE V-REPAIR ()
+	 <COND (<OR <AND <PRSO? ,THUMB>
+		         <FSET? ,THUMB ,MUNGEDBIT>>
+		    <AND <PRSO? ,HATCH>
+			 ,LANDED>>
+		<TELL "You have neither the tools nor the expertise." CR>)
+	       (T
+		<TELL "I'm not sure it's broken." CR>)>>
+
+<ROUTINE V-REPLY ()
+	 <TELL "It is hardly likely that">
+	 <ARTICLE ,PRSO T>
+	 <TELL " is interested." CR>
+	 <FUCKING-CLEAR>>
+
+<ROUTINE V-RUB ()
+	 <COND (<LOC-CLOSED>
+		<RTRUE>)
+	       (T
+		<HACK-HACK "Fiddling with">)>>
+
+<ROUTINE V-SAVE-SOMETHING ()
+	 <TELL "Sorry, but">
+	 <ARTICLE ,PRSO T>
+	 <TELL " is beyond help." CR>>
+
+<ROUTINE V-SAY ("AUX" V)
+	 <COND (<AND ,AWAITING-REPLY
+		     <EQUAL? <GET ,P-LEXV ,P-CONT> ,W?YES>>
+		<V-YES>
+		<FUCKING-CLEAR>)
+	       (<AND ,AWAITING-REPLY
+		     <EQUAL? <GET ,P-LEXV ,P-CONT> ,W?NO>>
+		<V-NO>
+		<FUCKING-CLEAR>)
+	       (<AND <IN? ,BEAST ,HERE>
+		     <FSET? ,TOWEL ,WORNBIT>>
+		<SAID-WITH-TOWEL>
+		<FUCKING-CLEAR>)
+	       (<AND <IN? ,BEAST ,HERE>
+		     <NOT ,P-CONT>>
+		<PERFORM ,V?TELL ,BEAST>
+		<RTRUE>)
+	       (<AND <IN? ,BEAST ,HERE>
+		     <SAID-YOUR-NAME?>>
+		<PERFORM ,V?SAY-NAME ,YOUR-NAME>
+		<FUCKING-CLEAR>)
+	       (<IN? ,BEAST ,HERE>
+		<PERFORM ,V?SAY-NAME ,BEAST-NAME>
+		<FUCKING-CLEAR>)
+	       (<SET V <FIND-IN ,HERE ,ACTORBIT>>
+		<TELL "You must address">
+		<ARTICLE .V T>
+		<TELL " directly." CR>
+		<FUCKING-CLEAR>)
+	       (T
+		<PERFORM ,V?TELL ,ME>
+		<FUCKING-CLEAR>)>>
+
+<ROUTINE SAID-YOUR-NAME? ("AUX" OFFS LEN WRD)
+	 <SET OFFS ,P-CONT>
+	 <SET LEN ,P-LEN>
+	 <REPEAT ()
+		 <COND (<L? <SET LEN <- .LEN 1>> 0>
+			<RFALSE>)>
+		 <SET WRD <GET ,P-LEXV .OFFS>>
+		 <COND (<OR <EQUAL? .WRD ,W?MY ,W?NAME ,W?IS>
+			    <EQUAL? .WRD ,W?I ,W?AM ,W?I\'M>> T)
+		       (<EQUAL? .WRD ,W?ARTHUR ,W?DENT>
+			<RTRUE>)
+		       (T
+			<RFALSE>)>
+		 <SET OFFS <+ .OFFS 2>>>>
+
+<ROUTINE SAID-WITH-TOWEL ()
+	 <TELL
+"The Beast is puzzled by a voice coming from something it can't see."
+,SLOWLY-DAWNS CR>>
+
+<ROUTINE V-SAY-NAME ()
+	 <COND (<IN? ,BEAST ,HERE>
+		<COND (,NAME-TOLD
+		       <TELL "You already told the Beast your name." CR>)
+		      (<FSET? ,TOWEL ,WORNBIT>
+		       <SAID-WITH-TOWEL>)
+		      (<PRSO? ,YOUR-NAME ,ARTHUR ,NAME ,ME>
+		       <ENABLE <QUEUE I-BEAST 2>>
+		       <SETG NAME-TOLD T>
+		       <TELL
+"The Beast roars your name with relish, and explains that once it has eaten
+you, your name will be added to its list of remembrance." CR>)
+		      (T
+		       <TELL
+"There's something about detecting insincerity that transcends even the
+vast gulf between Humanity and Bugblatter Bestiality. The Beast bellows,
+obviously convinced that you were lying and that isn't your name nor
+anything remotely like it." CR>)>)
+	       (T
+		<TELL "You should use quotes with this verb." CR>)>>
+
+<ROUTINE V-SEARCH ()
+	 <COND (<FSET? ,PRSO ,ACTORBIT>
+		<TELL "That wouldn't be polite." CR>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,CONTBIT>
+		<COND (<PRSO? <LOC ,WINNER>>
+		       <DESCRIBE-VEHICLE>
+		       <RTRUE>)
+		      (<NOT <FSET? ,PRSO ,OPENBIT>>
+		       <TELL "You'll have to open it first." CR>
+		       <RTRUE>)
+		      (<AND <FIRST? ,PRSO>
+			    <NOT <FSET? <FIRST? ,PRSO> ,NDESCBIT>>>
+		       <PRINT-CONT ,PRSO>
+		       <RTRUE>)>)>
+	 <TELL "You find nothing unusual." CR>>
+
+<ROUTINE V-SGIVE ()
+	 <PERFORM ,V?GIVE ,PRSI ,PRSO>
+	 <RTRUE>>
+
+<ROUTINE V-SHAKE ("AUX" X)
+	 <COND (<FSET? ,PRSO ,ACTORBIT>
+		<TELL "Be real." CR>)
+	       (T
+		<HACK-HACK "Shaking">)>>
+
+<ROUTINE V-SHAKE-WITH ()
+	 <COND (<NOT <PRSO? ,HANDS>>
+		<V-TELL-TIME>)
+	       (<NOT <FSET? ,PRSI ,ACTORBIT>>
+		<TELL "I don't think">
+		<ARTICLE ,PRSI T>
+		<TELL " even has hands." CR>)
+	       (T
+		<PERFORM ,V?THANK ,PRSI>
+		<RTRUE>)>>
+
+<ROUTINE V-SHOOT ()
+	 <COND (<FSET? ,TOWEL ,WORNBIT>
+		<TELL ,WITH-TOWEL CR>
+		<RTRUE>)>
+	 <COND (<NOT ,PRSO>
+		<COND (<HELD? ,BEAST-GUN>
+		       <SETG PRSO ,BEAST-GUN>)
+		      (<HELD? ,BLASTER>
+		       <SETG PRSO ,BLASTER>)
+		      (T
+		       <TELL "With what? At whom? Why?" CR>
+		       <RTRUE>)>)>
+	 <COND (<NOT ,PRSI>
+		<COND (<PRSO? ,BEAST-GUN ,BLASTER>
+		       <TELL "Some rays shoot out of the gun." CR>)
+		      (<HELD? ,BEAST-GUN>
+		       <PERFORM ,V?SHOOT ,PRSO ,BEAST-GUN>
+		       <RTRUE>)
+		      (<HELD? ,BLASTER>
+		       <PERFORM ,V?SHOOT ,PRSO ,BLASTER>
+		       <RTRUE>)
+		      (T
+		       <TELL "You have nothing to shoot">
+		       <ARTICLE ,PRSO T>
+		       <TELL " with." CR>)>)
+	       (<PRSI? ,BEAST-GUN>
+		<TELL "Some rays from the gun strike">
+		<ARTICLE ,PRSO T>
+		<TELL ", but ">
+		<COND (<AND <PRSO? ,BEAST>
+			    <NOT <FSET? ,BEAST ,MUNGEDBIT>>>
+		       <SETG GUN-COUNTER <+ ,GUN-COUNTER 1>>
+		       <TELL "it only seems to make it madder">
+		       <COND (<EQUAL? ,GUN-COUNTER 3>
+			      <TELL " (Footnote 7)">)>
+		       <TELL "." CR>)
+		      (T
+		       <TELL "nothing else happens." CR>)>)
+	       (T
+		<TELL
+"Don't ever bother applying for a job as an armaments expert." CR>)>>
+
+<ROUTINE V-SHOW ()
+	 <TELL "I doubt">
+	 <ARTICLE ,PRSI T>
+	 <TELL " is interested." CR>>
+
+<ROUTINE V-SIT ("AUX" VEHICLE)
+	 <COND (<SET VEHICLE <FIND-IN ,HERE ,VEHBIT>>
+		<PERFORM ,V?BOARD .VEHICLE>
+		<RTRUE>)
+	       (T
+		<V-DIG>)>>
+
+<ROUTINE V-SKIP ()
+	 <SETG AWAITING-REPLY 15>
+	 <ENABLE <QUEUE I-REPLY 2>>
+	 <TELL "Wasn't that fun?" CR>>
+
+<ROUTINE V-SLEEP ("OPTIONAL" (TOLD? <>))
+	 <COND (<EQUAL? ,HERE ,BEDROOM>
+		<TELL
+"You nod off and are wakened briefly a few hours later as">
+		<BETTER-LUCK>)
+	       (<EQUAL? ,HERE ,HOLD>
+		<TELL
+"You try, but the grubby mattresses are too repulsive." CR>)
+	       (T
+		<TELL "There's no bed here." CR>)>>
+
+<ROUTINE V-SMELL ()
+	 <TELL "It smells just like">
+	 <ARTICLE ,PRSO>
+	 <TELL "." CR>>
+
+<ROUTINE V-SMILE ()
+	 <COND (<AND <EQUAL? ,HERE ,CAPTAINS-QUARTERS>
+		     <IN? ,POETRY ,HERE>>
+		<V-APPLAUD>)
+	       (T
+		<TELL "How nice." CR>)>>
+
+<ROUTINE V-SPIN ()
+	 <TELL "You can't spin that!" CR>>
+
+<ROUTINE V-SPUT-ON ()
+	 <COND (<AND <PRSO? ,EARS>
+		     <VISIBLE? ,POETRY>>
+		<PERFORM ,V?LISTEN ,POETRY>
+		<RTRUE>)
+	       (T
+		<PERFORM ,V?PUT-ON ,PRSI ,PRSO>
+		<RTRUE>)>>
+
+<ROUTINE V-SSHOOT ()
+	 <PERFORM ,V?SHOOT ,PRSI ,PRSO>
+	 <RTRUE>>
+
+<ROUTINE V-SSHOW ()
+	 <PERFORM ,V?SHOW ,PRSI ,PRSO>
+	 <RTRUE>>
+
+<ROUTINE V-STAND ()
+	 <COND (<FSET? <LOC ,WINNER> ,VEHBIT>
+		<PERFORM ,V?DISEMBARK <LOC ,WINNER>>
+		<RTRUE>)
+	       (,LYING-DOWN
+		<SETG LYING-DOWN <>>
+		<COND (<RUNNING? ,I-PROSSER>
+		       <TELL
+"You are safe! Prosser heaves a visible sigh of relief, shakes his head
+and wipes his brow. " ,BULLDOZER-PILES CR>
+		       <BRICK-DEATH>)
+		      (<AND <EQUAL? ,HERE ,FRONT-OF-HOUSE>
+			    <NOT ,PROSSER-LYING>
+			    <NOT <IN? ,FLEET ,HERE>>>
+		       <TELL "The " D ,BULLDOZER-DRIVER
+" gives a quick chew of his gum and slams in the clutch. " ,BULLDOZER-PILES CR>
+		       <BRICK-DEATH>)
+		      (T
+		       <OWN-FEET>)>)
+	       (<AND ,PRSO
+		     <FSET? ,PRSO ,TAKEBIT>>
+		<V-DIG>)
+	       (T
+		<TELL "You are already standing." CR>)>>
+
+<ROUTINE V-STAND-BEFORE ()
+	 <COND (<PRSO? ,DISPENSER>
+		<TELL "The slot is too wide to block that way." CR>)
+	       (<PRSO? ,FISH-HOLE ,ROBOT-PANEL ,HOOK>
+		<TELL "You'd never be able to push the "
+D ,DISPENSER-BUTTON " from there." ,GETTING-CLOSE CR>)
+	       (<AND <PRSO? ,BULLDOZER ,HOUSE ,HOME>
+		     <EQUAL? ,IDENTITY-FLAG ,ARTHUR>>
+		<TELL
+"The " D ,BULLDOZER " could easily maneuver around you." ,GETTING-CLOSE CR>)
+	       (T
+		<V-DIG>)>>
+
+<ROUTINE V-STAND-ON ()
+	 <COND (,IN-FRONT-FLAG
+		<PERFORM ,V?STAND-BEFORE ,PRSO>
+		<RTRUE>)
+	       (T
+		<V-DIG>)>>
+
+<ROUTINE V-STEER ()
+	 <TELL "That would be pointless." CR>>
+
+<ROUTINE PRE-TAKE ()
+	 <COND (<OR <AND <PRSO? ,GOWN>
+			 ,GOWN-HUNG
+			 ,LYING-DOWN>
+		    <AND <PRSO? ,TOWEL>
+			 <FSET? ,TOWEL ,SURFACEBIT>
+			 ,LYING-DOWN>>
+		<TELL ,WHILE-LYING CR>)
+	       (<PRSO? ,BABEL-FISH>
+		<RFALSE>)
+	       (<LOC-CLOSED>
+		<RTRUE>)
+	       (<OR <AND <PRSO? ,DANGLY-BIT>
+			 <PRSI? ,BROWNIAN-SOURCE>
+			 ,PRSI>
+		    <AND <PRSO? ,SMALL-PLUG>
+			 <PRSI? ,PLOTTER ,SMALL-RECEPTACLE>
+			 ,DRIVE-TO-PLOTTER>
+		    <AND <PRSO? ,LARGE-PLUG>
+			 <PRSI? ,CONTROLS ,LARGE-RECEPTACLE>
+			 ,DRIVE-TO-CONTROLS>>
+		<PERFORM ,V?REMOVE ,PRSO>
+		<RTRUE>)
+	       (<AND <FSET? ,PRSO ,INTEGRALBIT>
+		     <EQUAL? ,PRSI <LOC ,PRSO>>>
+		<RFALSE>)
+	       (<OR <IN? ,PRSO ,PROTAGONIST>
+		    <AND <HELD? ,PRSO>
+			 <NOT <FSET? ,PRSO ,TAKEBIT>>>>
+		<COND (<FSET? ,PRSO ,WORNBIT>
+		       <TELL "You are already wearing it." CR>)
+		      (T
+		       <TELL "You already have it." CR>)>)
+	       (,PRSI
+		<COND (<PRSO? ,ME>
+		       <PERFORM ,V?DROP ,PRSI>
+		       <RTRUE>)
+		      (<AND <PRSO? ,ITEM-ON-SATCHEL>
+			    <PRSI? ,SATCHEL>>
+		       <RFALSE>)
+		      (<AND <PRSO? ,ITEM-DROPPED-AT-PARTY>
+			    <PRSI? ,HOSTESS>>
+		       <RFALSE>)
+		      (<NOT <PRSI? <LOC ,PRSO>>>
+		       <TELL "But">
+		       <ARTICLE ,PRSO T>
+		       <TELL " isn't ">
+		       <COND (<AND <FSET? ,PRSI ,ACTORBIT>
+				   <NOT <PRSI? ,NUTRIMAT ,SCREENING-DOOR>>>
+			      <TELL "being held by">)
+			     (<FSET? ,PRSI ,SURFACEBIT>
+			      <TELL "on">)
+			     (T
+			      <TELL "in">)>
+		       <ARTICLE ,PRSI T>
+		       <TELL "." CR>)
+		      (T
+		       <SETG PRSI <>>
+		       <RFALSE>)>)
+	       (<PRSO? <LOC ,WINNER>>
+		<TELL "You are in it!" CR>)
+	       (<AND ,HEADACHE
+		     <NOT <PRSO? ,GOWN>>
+		     <FSET? ,PRSO ,TAKEBIT>
+		     <NOT <HELD? ,PRSO>>>
+		<TELL <PICK-ONE ,LURCHES> CR>)>>
+
+<GLOBAL LURCHES
+	<PLTABLE
+"It slips through your fumbling fingers and hits the carpet with a
+nerve-shattering bang."
+"It dances by you like a thing possessed."
+"You lunge for it, but the room spins nauseatingly away. The floor
+gives you a light tap on the forehead."
+"You're certainly picking the tough tasks. The floor acts like a
+trampoline on an ice rink, or like something they've been working
+on for years at Disneyland.">>
+
+<ROUTINE V-TAKE ()
+	 <COND (<EQUAL? <ITAKE> T>
+		<COND (<AND <PRSO? ,JACKET-FLUFF>
+			    <FSET? ,JACKET-FLUFF ,TRYTAKEBIT>>
+		       <FCLEAR ,JACKET-FLUFF ,TRYTAKEBIT>
+		       <FCLEAR ,JACKET-FLUFF ,NDESCBIT>
+		       <SETG FLUFF-REMOVED T>
+		       <ENABLE <QUEUE I-ZAPHOD 6>>
+		       <ENABLE <QUEUE I-ARTHUR 2>>
+		       <TELL
+"You remove the " D ,JACKET-FLUFF ", improving Arthur's appearance greatly.
+He is clearly touched, and starts happily to chat away to you. You discover
+that he is only slightly more interesting to talk to than an averagely
+interesting wall." CR>)
+		      (T
+		       <COND (<PRSO? ,ITEM-DROPPED-AT-PARTY>
+			      <FCLEAR ,ITEM-DROPPED-AT-PARTY ,NDESCBIT>
+			      <COND (<NOT <HELD? ,WINE>>
+				     <SETG ITEM-DROPPED-AT-PARTY ,WINE>
+				     <FCLEAR ,HOSTESS ,TOUCHBIT>)
+				    (<NOT <HELD? ,HANDBAG>>
+				     <SETG ITEM-DROPPED-AT-PARTY ,HANDBAG>
+				     <FCLEAR ,HOSTESS ,TOUCHBIT>)
+				    (<NOT <HELD? ,APPETIZERS>>
+				     <SETG ITEM-DROPPED-AT-PARTY ,APPETIZERS>
+				     <FCLEAR ,HOSTESS ,TOUCHBIT>)
+				    (T
+				     <SETG ITEM-DROPPED-AT-PARTY <>>
+				     <FCLEAR ,HOSTESS ,NDESCBIT>)>)
+			     (<AND <PRSO? ,GOWN>
+				   ,GOWN-HUNG>
+			      <FCLEAR ,GOWN ,TRYTAKEBIT>
+			      <FCLEAR ,GOWN ,NDESCBIT>
+			      <FSET ,GOWN ,OPENBIT>
+			      <SETG GOWN-HUNG <>>)
+			     (<PRSO? ,PANEL-BLOCKER>
+			      <SETG PANEL-BLOCKER <>>
+			      <FCLEAR ,PRSO ,TRYTAKEBIT>
+			      <FCLEAR ,PRSO ,NDESCBIT>)>
+		       <COND (<AND <PRSO? ,SATCHEL>
+				   ,ITEM-ON-SATCHEL>
+			      <MOVE ,ITEM-ON-SATCHEL ,HERE>
+			      <FCLEAR ,ITEM-ON-SATCHEL ,NDESCBIT>
+			      <FCLEAR ,ITEM-ON-SATCHEL ,TRYTAKEBIT>
+			      <SETG ITEM-ON-SATCHEL <>>)
+			     (<PRSO? ,ITEM-ON-SATCHEL>
+			      <FCLEAR ,ITEM-ON-SATCHEL ,NDESCBIT>
+			      <FCLEAR ,ITEM-ON-SATCHEL ,TRYTAKEBIT>
+			      <SETG ITEM-ON-SATCHEL <>>)>
+		       <TELL "Taken." CR>)>)>>
+
+<ROUTINE V-TAKE-OFF ()
+	 <COND (<FSET? ,PRSO ,WORNBIT>
+		<FCLEAR ,PRSO ,WORNBIT>
+		<TELL "Okay, you're no longer wearing">
+		<ARTICLE ,PRSO T>
+		<TELL "." CR>)
+	       (T
+		<TELL "You aren't wearing that!" CR>)>>
+
+<ROUTINE V-TASTE ()
+	 <TELL "You can't. At least, not in this game you can't." CR>>
+
+<ROUTINE V-TELL ()
+	 <COND (<FSET? ,PRSO ,ACTORBIT>
+		<COND (,P-CONT
+		       <SETG WINNER ,PRSO>
+		       <SETG HERE <LOC ,WINNER>>
+		       <RTRUE>)
+		      (T
+		       <TELL "Hmmm ...">
+		       <ARTICLE ,PRSO T>
+		       <TELL
+" looks at you expectantly, as if you seemed to be about to talk." CR>)>)
+	       (T
+		<TELL "You can't talk to">
+		<ARTICLE ,PRSO>
+		<TELL "!" CR>
+		<FUCKING-CLEAR>)>>
+
+<ROUTINE V-TELL-ABOUT ()
+	 <COND (<PRSO? ,ME>
+		<PERFORM ,V?WHAT ,PRSI>
+		<RTRUE>)
+	       (T
+		<TELL "It doesn't look like">
+		<ARTICLE ,PRSO T>
+		<TELL " is interested." CR>)>>
+
+<ROUTINE V-TELL-TIME ()
+	 <TELL "That sentence isn't one I recognise." CR>>
+
+<ROUTINE V-TELL-NAME ()
+	 <V-TELL-TIME>>
+
+<ROUTINE V-THANK ()
+	 <COND (<FSET? ,PRSO ,ACTORBIT>
+		<TELL "You do so, but">
+		<ARTICLE ,PRSO T>
+		<TELL " seems less than overjoyed." CR>)
+	       (T
+		<V-CARVE>)>>
+
+<ROUTINE V-THROUGH ("AUX" M)
+	<COND (<FSET? ,PRSO ,DOORBIT>
+	       <DO-WALK <OTHER-SIDE ,PRSO>>
+	       <RTRUE>)
+	      (<FSET? ,PRSO ,VEHBIT>
+	       <PERFORM ,V?BOARD ,PRSO>
+	       <RTRUE>)
+	      (<NOT <FSET? ,PRSO ,TAKEBIT>>
+	       <TELL "You hit your head against">
+	       <ARTICLE ,PRSO T>
+	       <TELL " as you attempt this feat." CR>)
+	      (<IN? ,PRSO ,WINNER>
+	       <PERFORM ,V?EXAMINE ,EYES>
+	       <RTRUE>)
+	      (T
+	       <V-CARVE>)>>
+
+<ROUTINE PRE-THROW ()
+	 <COND (<AND <PRSO? ,INTNUM>
+		     <L? ,P-NUMBER 9>
+		     <ACCESSIBLE? ,BOARD>>
+		<PERFORM ,V?TURN ,DIPSWITCH>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,SWITCHBIT>
+		<RFALSE>)
+	       (<IDROP>
+		<RTRUE>)>>
+
+<ROUTINE V-THROW ()
+	 <COND (<EQUAL? ,HERE ,HOLD>
+		<MOVE ,PRSO ,LOCAL-GLOBALS>
+		<TELL ,ROBOT-FLIES-IN "collects">
+		<ARTICLE ,PRSO T>
+		<TELL " in mid-air, and flashes away." CR>) 
+	       (<EQUAL? ,HERE ,MAZE ,ACCESS-SPACE>
+		<PERFORM ,V?DROP ,PRSO>
+		<RTRUE>)
+	       (,PRSI
+		<MOVE ,PRSO ,HERE>
+		<TELL "You missed." CR>)
+	       (T
+		<MOVE ,PRSO ,HERE>
+		<TELL "Thrown." CR>)>>
+
+<ROUTINE V-THROW-OFF ()
+	 <TELL "You can't do that!" CR>>
+
+<ROUTINE V-THROW-IN-TOWEL ()
+	 <COND (<PRSO? ,TOWEL>
+		<V-QUIT>)
+	       (T
+		<V-TELL-TIME>)>>
+
+<ROUTINE V-TIE ()
+	 <TELL "You can't tie">
+	 <ARTICLE ,PRSO>
+	 <TELL "." CR>>
+
+<ROUTINE V-TIE-TOGETHER ()
+	 <COND (<PRSO? ,SLEEVES>
+		<PERFORM ,V?TIE ,SLEEVES>
+		<RTRUE>)
+	       (T
+		<V-TELL-TIME>)>>
+
+<ROUTINE V-TURN ()
+	 <COND (<PRSO? ,BOAT-OBJECT>
+		<TELL "Try: STEER BOAT TOWARD (something)." CR>)
+	       (<PRSO? ,ME ,ROOMS>
+		<V-SKIP>)
+	       (<AND <PRSO? ,INTNUM>
+		     <L? ,P-NUMBER 9>
+		     <ACCESSIBLE? ,BOARD>>
+		<PERFORM ,V?TURN ,DIPSWITCH>
+		<RTRUE>)
+	       (T
+		<TELL "This has no effect." CR>)>>
+
+<ROUTINE V-TYPE ()
+	 <COND (<NOT <EQUAL? ,HERE ,HOLD>>
+		<TELL "There's no " D ,KEYBOARD " in sight." CR>
+		<FUCKING-CLEAR>)
+	       (<AND <NOT ,POEM-ENJOYED>
+		     ,P-CONT>
+		<PERFORM ,V?MUNG ,GLASS-CASE>
+		<RTRUE>)
+	       (<AND <EQUAL? <GET ,P-LEXV ,P-CONT> ,W?FRIPPI>
+		     <EQUAL? ,LINE-NUMBER 1 2>
+		     <EQUAL? ,WORD-NUMBER 1>>
+		<GLASS-CASE-OPENS>)
+	       (<AND <EQUAL? <GET ,P-LEXV ,P-CONT> ,W?LYSHUS>
+		     <EQUAL? ,LINE-NUMBER 1 2>
+		     <EQUAL? ,WORD-NUMBER 2>>
+		<GLASS-CASE-OPENS>)
+	       (<AND <EQUAL? <GET ,P-LEXV ,P-CONT> ,W?WIMBGU>
+		     <EQUAL? ,LINE-NUMBER 1 2>
+		     <EQUAL? ,WORD-NUMBER 3>>
+		<GLASS-CASE-OPENS>)
+	       (<AND <EQUAL? <GET ,P-LEXV ,P-CONT> ,W?GASHEE>
+		     <EQUAL? ,LINE-NUMBER 3 4>
+		     <EQUAL? ,WORD-NUMBER 1>>
+		<GLASS-CASE-OPENS>)
+	       (<AND <EQUAL? <GET ,P-LEXV ,P-CONT> ,W?MORPHO>
+		     <EQUAL? ,LINE-NUMBER 3 4>
+		     <EQUAL? ,WORD-NUMBER 2>>
+		<GLASS-CASE-OPENS>)
+	       (<AND <EQUAL? <GET ,P-LEXV ,P-CONT> ,W?THOU>
+		     <EQUAL? ,LINE-NUMBER 3 4>
+		     <EQUAL? ,WORD-NUMBER 3>>
+		<GLASS-CASE-OPENS>)
+	       (<AND <EQUAL? <GET ,P-LEXV ,P-CONT> ,W?BLEEM>
+		     <EQUAL? ,LINE-NUMBER 5 6>
+		     <EQUAL? ,WORD-NUMBER 1>>
+		<GLASS-CASE-OPENS>)
+	       (<AND <EQUAL? <GET ,P-LEXV ,P-CONT> ,W?MISERA>
+		     <EQUAL? ,LINE-NUMBER 5 6>
+		     <EQUAL? ,WORD-NUMBER 2>>
+		<GLASS-CASE-OPENS>)
+	       (<AND <EQUAL? <GET ,P-LEXV ,P-CONT> ,W?VENCHI>
+		     <EQUAL? ,LINE-NUMBER 5 6>
+		     <EQUAL? ,WORD-NUMBER 3>>
+		<GLASS-CASE-OPENS>)
+	       (<NOT ,P-CONT>
+		<TELL "You didn't specify what you wanted to type." CR>)
+	       (T
+		<PERFORM ,V?MUNG ,GLASS-CASE>
+		<RFATAL>)>>
+
+<ROUTINE V-TYPE-ON ()
+	 <COND (<PRSO? ,KEYBOARD>
+		<SETG P-CONT <>>
+		<V-TYPE>)
+	       (T
+		<TELL "You can't type on that!" CR>)>> 
+
+<ROUTINE V-UNLOCK ()
+	 <V-CARVE>>
+
+<ROUTINE V-UNPLUG ()
+	 <COND (<PRSO? ,SPARE-DRIVE ,LARGE-PLUG ,SMALL-PLUG ,PLOTTER>
+		<TELL ,NOT-PLUGGED CR>)
+	       (T
+		<V-COUNT>)>>
+
+<ROUTINE V-UNTIE ()
+	 <V-CARVE>>
+
+<ROUTINE V-WALK ("AUX" PT PTS STR OBJ RM)
+	 <COND (<AND <IN? ,FLEET ,HERE>
+		     <NOT <PRSO? ,P?UP ,P?DOWN>>>
+		<TELL "You would be no safer there." CR>)
+	       (,LYING-DOWN
+		<TELL ,WHILE-LYING CR>)
+	       (<FSET? ,TOWEL ,WORNBIT>
+		<SETG BEARINGS-LOST T>
+		<TELL
+"You stumble in that direction, but as you can't see where you're going you
+wander around in circles.">
+		<COND (<NOT <FSET? ,BEAST ,MUNGEDBIT>>
+		       <TELL
+" The Beast is getting puzzled that something it can't see is stumbling around
+its lair." ,SLOWLY-DAWNS>)>
+		<CRLF>)
+	       (<AND <NOT <EQUAL? ,HERE ,MAZE>>
+		     <EQUAL? ,IDENTITY-FLAG ,ARTHUR>
+		     ,BRAIN-DAMAGED
+		     <PROB 30>>
+		<TELL
+"You notice that you can't remember how to walk. Oddly, as you think about
+walking, all that comes to mind is an image of">
+		<ARTICLE ,BRAIN-DAMAGED>
+		<TELL "." CR>)
+	       (<NOT ,P-WALK-DIR>
+		<PERFORM ,V?WALK-TO ,PRSO>
+		<RTRUE>)
+	       (<SET PT <GETPT ,HERE ,PRSO>>
+		<COND (<EQUAL? <SET PTS <PTSIZE .PT>> ,UEXIT>
+		       <GOTO <GETB .PT ,REXIT>>)
+		      (<EQUAL? .PTS ,NEXIT>
+		       <TELL <GET .PT ,NEXITSTR> CR>
+		       <RFATAL>)
+		      (<EQUAL? .PTS ,FEXIT>
+		       <COND (<SET RM <APPLY <GET .PT ,FEXITFCN>>>
+			      <GOTO .RM>)
+			     (<AND <EQUAL? ,HERE ,BRIDGE>
+				   <EQUAL? ,P-WALK-DIR ,P?WEST>>
+			      <RTRUE>)
+			     (T
+			      <RFATAL>)>)
+		      (<EQUAL? .PTS ,CEXIT>
+		       <COND (<VALUE <GETB .PT ,CEXITFLAG>>
+			      <GOTO <GETB .PT ,REXIT>>)
+			     (<SET STR <GET .PT ,CEXITSTR>>
+			      <TELL .STR CR>
+			      <RFATAL>)
+			     (T
+			      <TELL ,CANT-GO CR>
+			      <RFATAL>)>)
+		      (<EQUAL? .PTS ,DEXIT>
+		       <COND (<FSET? <SET OBJ <GETB .PT ,DEXITOBJ>> ,OPENBIT>
+			      <GOTO <GETB .PT ,REXIT>>)
+			     (<SET STR <GET .PT ,DEXITSTR>>
+			      <TELL .STR CR>
+			      <SETG P-IT-OBJECT .OBJ>
+			      <RFATAL>)
+			     (T
+			      <TELL "The " D .OBJ " is closed." CR>
+			      <SETG P-IT-OBJECT .OBJ>
+			      <RFATAL>)>)>)
+	       (T
+		<COND (<PRSO? ,P?OUT ,P?IN>
+		       <V-WALK-AROUND>)
+		      (T
+		       <TELL ,CANT-GO CR>)>
+		<RFATAL>)>>
+
+<ROUTINE V-WALK-AROUND ()
+	 <SETG AWAITING-REPLY 16>
+	 <ENABLE <QUEUE I-REPLY 2>>
+	 <TELL "Did you have any particular direction in mind?" CR>>
+
+<ROUTINE V-WALK-TO ()
+	 <COND (<OR <IN? ,PRSO ,HERE>
+		    <GLOBAL-IN? ,PRSO ,HERE>>
+		<COND (<PRSO? ,TRILLIAN ,HOSTESS>
+		       <TELL "She">)
+		      (<AND <FSET? ,PRSO ,ACTORBIT>
+			    <NOT <PRSO? ,NUTRIMAT ,SCREENING-DOOR ,BEAST>>>
+		       <TELL "He">)
+		      (T
+		       <TELL "It">)>
+		<TELL "'s here!" CR>)
+	       (T
+		<V-WALK-AROUND>)>>
+
+<ROUTINE V-WAIT ("OPTIONAL" (NUM 3))
+	 <TELL "Time passes..." CR>
+	 <REPEAT ()
+		 <COND (<L? <SET NUM <- .NUM 1>> 0>
+			<RETURN>)
+		       (<CLOCKER>
+			<RETURN>)>>
+	 <SETG CLOCK-WAIT T>>
+
+<ROUTINE V-WAIT-FOR ()
+	 <TELL "You may be waiting quite a while." CR>>
+
+<ROUTINE V-WATER ()
+	 <TELL "It doesn't need watering." CR>>
+
+<ROUTINE V-WAVE ()
+	 <V-CARVE>>
+
+<ROUTINE V-WAVE-AT ()
+	 <COND (<NOT ,PRSO>
+		<V-SMILE>)
+	       (T
+		<TELL "Despite your friendly nature,">
+		<ARTICLE ,PRSO T>
+		<TELL " isn't likely to respond." CR>)>>
+
+<ROUTINE V-WEAR ()
+	 <COND (<NOT <FSET? ,PRSO ,WEARBIT>>
+		<TELL "You can't wear">
+		<ARTICLE ,PRSO T>
+		<TELL "." CR>)
+	       (<FSET? ,PRSO ,WORNBIT>
+		<TELL "You're already wearing">
+		<ARTICLE ,PRSO T>
+		<TELL "!" CR>)
+	       (T
+		<MOVE ,PRSO ,PROTAGONIST>
+		<FSET ,PRSO ,WORNBIT>
+		<TELL "You are now wearing">
+		<ARTICLE ,PRSO T>
+		<TELL "." CR>)>>
+
+<ROUTINE V-WHAT ()
+	 <TELL "Good question." CR>>
+
+<ROUTINE V-WHAT-ABOUT ()
+	 <TELL "Well, what about it?" CR>>
+
+<ROUTINE V-WHAT-TIME ()
+	 <V-TELL-TIME>>
+
+<ROUTINE V-WHERE ()
+	 <V-FIND T>>
+
+<ROUTINE V-WHO ()
+	 <COND (<FSET? ,PRSO ,ACTORBIT>
+		<PERFORM ,V?WHAT ,PRSO>
+		<RTRUE>)
+	       (T
+		<TELL "That's not a person!" CR>)>>
+
+<ROUTINE V-WHY ()
+	 <TELL "Why not?" CR>>
+
+<ROUTINE V-YELL ()
+	 <TELL "You begin to get a sore throat." CR>>
+
+<ROUTINE V-YES ()
+	 <COND (<EQUAL? ,AWAITING-REPLY 1>
+		<DO-WALK ,P?SOUTH>)
+	       (<EQUAL? ,AWAITING-REPLY 2>
+		<RFALSE>)
+	       (<EQUAL? ,AWAITING-REPLY 3>
+		<TELL "Well, tough." CR>)
+	       (<EQUAL? ,AWAITING-REPLY 4>
+		<PERFORM ,V?TAKE ,ITEM-DROPPED-AT-PARTY>
+		<RTRUE>)
+	       (<EQUAL? ,AWAITING-REPLY 5>
+		<TELL "So do I." CR>)
+	       (<OR <EQUAL? ,AWAITING-REPLY 6 8 11>
+		    <EQUAL? ,AWAITING-REPLY 13 14 15>>
+		<TELL "That was just a rhetorical question." CR>)
+	       (<EQUAL? ,AWAITING-REPLY 7 9>
+		<TELL "Well, good for you!" CR>)
+	       (<EQUAL? ,AWAITING-REPLY 10>
+		<PERFORM ,V?ENJOY ,FORD>
+		<RTRUE>)
+	       (<EQUAL? ,AWAITING-REPLY 12>
+		<ENABLE <QUEUE I-ENGINEER 2>>
+		<TELL "\"Well, let's see the malfunctioning equipment.\"" CR>)
+	       (<EQUAL? ,AWAITING-REPLY 16>
+		<TELL "Then type it." CR>)
+	       (<EQUAL? ,AWAITING-REPLY 18 19>
+		<TELL "\"Well, leave me alone then! I'm busy!\"" CR>)
+	       (T
+		<TELL "You sound rather positive." CR>)>>
+
+
+;"subtitle object manipulation"
+
+<ROUTINE ITAKE ("OPTIONAL" (VB T) "AUX" CNT OBJ)
+	 <COND (<FSET? ,PRSO ,INTEGRALBIT>
+		<COND (.VB
+		       <PART-OF>)>
+		<RFATAL>)
+	       (<NOT <FSET? ,PRSO ,TAKEBIT>>
+		<COND (.VB
+		       <V-CARVE>)>
+		<RFATAL>)
+	       (<AND <EQUAL? ,IDENTITY-FLAG ,TRILLIAN>
+		     <G? <CCOUNT ,PROTAGONIST> 2>>
+		<COND (.VB
+		       <TELL
+"As is the case so often at parties, you find that you are holding too much
+and can't pick up anything else." CR>)>
+		<RFATAL>)
+	       (<NOT <IN? <LOC ,PRSO> ,WINNER>>
+		<COND (<G? <+ <WEIGHT ,PRSO> <WEIGHT ,WINNER>> 100>
+		       <COND (.VB
+			      <TELL "Your load is too heavy." CR>)>
+		       <RFATAL>)
+		      (<AND <G? <SET CNT <CCOUNT ,WINNER>> 7>
+			    <PROB <* .CNT 8>>>
+		       <COND (.VB
+			      <TELL "You're holding too much already." CR>)>
+		       <RFATAL>)>)>
+	 <MOVE ,PRSO ,PROTAGONIST>
+	 <FSET ,PRSO ,TOUCHBIT>
+	 <RTRUE>>
+
+<ROUTINE IDROP () ;"revised 7/19/84 by SEM"
+	 <COND (<PRSO? ,HANGOVER>
+		<RFALSE>)
+	       (<AND <PRSO? ,NO-TEA>
+		     ,HOLDING-NO-TEA>
+		<RFALSE>)
+	       (<AND <PRSO? ,DANGLY-BIT ,LARGE-PLUG ,SMALL-PLUG>
+		     <VERB? PUT PUT-ON>>
+		<RFALSE>)
+	       (<AND <VERB? GIVE>
+		     <PRSO? ,SPEECH>>
+		<RFALSE>)
+	       (<PRSO? ,SLEEVES>
+		<V-DIG>)
+	       (<PRSO? ,EYES ,EARS ,HANDS ,HEAD>
+		<COND (<VERB? DROP THROW GIVE>
+		       <V-COUNT>)
+		      (<AND <VERB? PUT-ON>
+			    <PRSI? ,SATCHEL>>
+		       <V-COUNT>)
+		      (T
+		       <RFALSE>)>)
+	       (<AND <PRSO? ,SPARE-DRIVE>
+		     <PRSI? ,LARGE-RECEPTACLE ,SMALL-RECEPTACLE
+			    ,CONTROLS ,PLOTTER>>
+		<RFALSE>)
+	       (<NOT <HELD? ,PRSO>>
+		<TELL "That's easy for you to say since you don't even have">
+		<ARTICLE ,PRSO T>
+		<TELL "." CR>)
+	       (<PRSO? ,PLANT>
+		<PERFORM ,V?DROP ,FLOWERPOT>
+		<RTRUE>)
+	       (<FSET? ,PRSO ,INTEGRALBIT>
+		<PART-OF>)
+	       (<AND <NOT <IN? ,PRSO ,WINNER>>
+		     <FSET? <LOC ,PRSO> ,CONTBIT>
+		     <NOT <FSET? <LOC ,PRSO> ,OPENBIT>>>
+		<TELL "Impossible because">
+		<ARTICLE <LOC ,PRSO> T>
+		<TELL " is closed." CR>)
+	       (<OR <AND <PRSO? ,BABEL-FISH>
+			 <NOT <VERB? SHOW>>>
+		    <FSET? ,PRSO ,WORNBIT>>
+		<TELL "You'll have to remove it first." CR>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE CCOUNT	(OBJ "AUX" (CNT 0) X)
+	 <COND (<SET X <FIRST? .OBJ>>
+		<REPEAT ()
+			<COND (<AND <NOT <FSET? .X ,WORNBIT>>
+				    <NOT <EQUAL? .X ,BABEL-FISH>>>
+			       <SET CNT <+ .CNT 1>>)>
+			<COND (<NOT <SET X <NEXT? .X>>>
+			       <RETURN>)>>)>
+	 .CNT>
+
+;"Gets SIZE of supplied object, recursing to nth level."
+<ROUTINE WEIGHT (OBJ "AUX" CONT (WT 0))
+	 <COND (<SET CONT <FIRST? .OBJ>>
+		<REPEAT ()
+			<COND (<AND <EQUAL? .OBJ ,PLAYER>
+				    <FSET? .CONT ,WORNBIT>>
+			       <SET WT <+ .WT 1>>)
+			              ;"worn things shouldn't count"
+			      (<AND <EQUAL? .OBJ ,PLAYER>
+				    <FSET? <LOC .CONT> ,WORNBIT>>
+			       <SET WT <+ .WT 1>>)
+			              ;"things in worn things shouldn't count"
+			      (<AND <EQUAL? .OBJ ,PLAYER>
+				    <EQUAL? .CONT ,BABEL-FISH>>
+			       <SET WT <+ .WT 1>>)
+			              ;"the babel fish shouldn't count"
+			      (T
+			       <SET WT <+ .WT <WEIGHT .CONT>>>)>
+			<COND (<NOT <SET CONT <NEXT? .CONT>>> <RETURN>)>>)>
+	 <+ .WT <GETP .OBJ ,P?SIZE>>>
+
+
+;"subtitle describers"
+
+<ROUTINE DESCRIBE-ROOM ("OPTIONAL" (LOOK? <>) "AUX" V? STR AV)
+	 <SET V? <OR .LOOK? <EQUAL? ,VERBOSITY 2>>>
+	 <COND (<NOT ,LIT>
+		<TELL "It is pitch black.">
+		<CRLF>
+		<RETURN <>>)>
+	 <COND (<NOT <FSET? ,HERE ,TOUCHBIT>>
+		<FSET ,HERE ,TOUCHBIT>
+		<SET V? T>)>
+	 <COND (<IN? ,HERE ,ROOMS>
+		<TELL D ,HERE>
+		<SET AV <LOC ,WINNER>>
+		<COND (<AND <NOT ,LYING-DOWN>
+			    <NOT <FSET? .AV ,VEHBIT>>>
+		       <CRLF>)>)>
+	 <COND (<OR .LOOK?
+		    <EQUAL? ,VERBOSITY 1 2>>
+		<COND (<FSET? .AV ,VEHBIT>
+		       <TELL ", in the " D .AV CR>)
+		      (,LYING-DOWN
+		       <TELL ", lying down" CR>)>
+		<COND (<AND .V? <APPLY <GETP ,HERE ,P?ACTION> ,M-LOOK>>
+		       <RTRUE>)
+		      (<AND .V? <SET STR <GETP ,HERE ,P?LDESC>>>
+		       <TELL .STR CR>)
+		      (T
+		       <APPLY <GETP ,HERE ,P?ACTION> ,M-FLASH>)>
+		<COND (<AND <NOT <EQUAL? ,HERE .AV>>
+			    <FSET? .AV ,VEHBIT>>
+		       <APPLY <GETP .AV ,P?ACTION> ,M-LOOK>)>)>
+	 T>
+
+<ROUTINE DESCRIBE-OBJECTS ("OPTIONAL" (V? <>))
+   <COND (,LIT
+	  <COND (<FIRST? ,HERE>
+		 <PRINT-CONT ,HERE <SET V? <OR .V? <==? ,VERBOSITY 2>>> -1>)>)
+	 (T
+	  <TELL ,TOO-DARK CR>)>>
+
+"DESCRIBE-OBJECT -- takes object and flag.  if flag is true will print a
+long description (fdesc or ldesc), otherwise will print short."
+<ROUTINE DESCRIBE-OBJECT (OBJ V? LEVEL "AUX" (STR <>) AV)
+	 <COND (<AND <0? .LEVEL>
+		     <APPLY <GETP .OBJ ,P?DESCFCN> ,M-OBJDESC>>
+		<RTRUE>)
+	       (<AND <0? .LEVEL>
+		     <OR <AND <NOT <FSET? .OBJ ,TOUCHBIT>>
+			      <SET STR <GETP .OBJ ,P?FDESC>>>
+			 <SET STR <GETP .OBJ ,P?LDESC>>>>
+		<TELL .STR>)
+	       (<0? .LEVEL>
+		<TELL "There is">
+		<ARTICLE .OBJ>
+		<TELL " here.">)
+	       (T
+		<TELL <GET ,INDENTS .LEVEL>>
+		<COND (<FSET? .OBJ ,NARTICLEBIT>
+		       T)
+		      (<FSET? .OBJ ,VOWELBIT>
+		       <TELL "an ">)
+		      (T
+		       <TELL "a ">)>
+		<TELL D .OBJ>
+		<COND (<FSET? .OBJ ,WORNBIT>
+		       <TELL " (being worn)">)
+		      (<EQUAL? .OBJ ,BABEL-FISH>
+		       <TELL " (in your ear)">)
+		      (<AND <EQUAL? .OBJ ,PLOTTER>
+			    ,BROWNIAN-SOURCE>
+		       <TELL " (suspended in">
+		       <ARTICLE ,BROWNIAN-SOURCE>
+		       <TELL ")">)
+		      (<AND <EQUAL? .OBJ ,SPARE-DRIVE>
+			    <OR ,DRIVE-TO-PLOTTER ,DRIVE-TO-CONTROLS>>
+		       <TELL " (connected to">
+		       <COND (,DRIVE-TO-PLOTTER
+			      <TELL " the plotter">
+			      <COND (,DRIVE-TO-CONTROLS
+				     <TELL " and">)>)>
+		       <COND (,DRIVE-TO-CONTROLS
+			      <TELL " the control console">)>
+		       <TELL ")">)>)>
+	 <COND (<AND <0? .LEVEL>
+		     <NOT <FSET? .OBJ ,ACTORBIT>>
+		     <SET AV <LOC ,WINNER>>
+		     <FSET? .AV ,VEHBIT>>
+		<TELL " (outside the " D .AV ")">)>
+	 <CRLF>
+	 <COND (<AND <SEE-INSIDE? .OBJ> <FIRST? .OBJ>>
+		<PRINT-CONT .OBJ .V? .LEVEL>)>>
+
+<ROUTINE PRINT-CONT (OBJ
+		     "OPTIONAL" (V? <>) (LEVEL 0)
+		     "AUX" Y (1ST? T) (AV <>) STR (PV? <>) (INV? <>) (SC <>))
+	 <COND (<NOT <SET Y <FIRST? .OBJ>>>
+		<RTRUE>)>
+	 <COND (<FSET? <LOC ,WINNER> ,VEHBIT>
+		<SET AV <LOC ,WINNER>>)>
+	 <COND (<EQUAL? ,PROTAGONIST .OBJ <LOC .OBJ>>
+		<SET INV? T>)
+	       (T
+		<REPEAT ()
+			<COND (<NOT .Y>
+			       <RETURN <NOT .1ST?>>)
+			      (<EQUAL? .Y .AV>
+			       <SET PV? T>)
+			      (<EQUAL? .Y ,WINNER>)
+			      (<AND <NOT <FSET? .Y ,INVISIBLE>>
+				    <NOT <FSET? .Y ,TOUCHBIT>>
+				    <SET STR <GETP .Y ,P?FDESC>>>
+			       <COND (<NOT <FSET? .Y ,NDESCBIT>>
+				      <TELL .STR CR>)>
+			       <COND (<AND <SEE-INSIDE? .Y>
+					   <NOT <GETP <LOC .Y> ,P?DESCFCN>>
+					   <FIRST? .Y>>
+				      <PRINT-CONT .Y .V? 0>)>)>
+			<SET Y <NEXT? .Y>>>)>
+	 <SET Y <FIRST? .OBJ>>
+	 ;<COND (<AND <EQUAL? .OBJ ,HERE>
+		     <IN? ,SATCHEL ,HERE>>
+		<DESCRIBE-OBJECT ,SATCHEL .V? .LEVEL>
+		<SET SC T>)>
+	 <REPEAT ()
+		 <COND (<NOT .Y>
+			<COND (<AND .PV? .AV <FIRST? .AV>>
+			       <PRINT-CONT .AV .V? .LEVEL>)>
+			<RETURN <NOT .1ST?>>)
+		       (<EQUAL? .Y .AV ,PROTAGONIST> T)
+		       ;(<AND .SC <EQUAL? .Y ,SATCHEL>> T)
+		       (<AND <NOT <FSET? .Y ,INVISIBLE>>
+			     <OR .INV?
+				 <FSET? .Y ,TOUCHBIT>
+				 <NOT <GETP .Y ,P?FDESC>>>>
+			<COND (<AND <EQUAL? .Y ,STONE>
+				    <EQUAL? ,HERE ,OUTER-LAIR>
+				    <IN? .Y ,HERE>>
+			       <FSET .Y ,NDESCBIT>)
+			      (<NOT <FSET? .Y ,NDESCBIT>>
+			       <COND (.1ST?
+				      <COND (<FIRSTER .OBJ .LEVEL>
+					     <COND (<L? .LEVEL 0>
+						    <SET LEVEL 0>)>)>
+				      <SET LEVEL <+ 1 .LEVEL>>
+				      <SET 1ST? <>>)>
+			       <DESCRIBE-OBJECT .Y .V? .LEVEL>)
+			      (<AND <FIRST? .Y>
+				    <SEE-INSIDE? .Y>>
+			       <PRINT-CONT .Y .V? .LEVEL>)>)>
+		 <SET Y <NEXT? .Y>>>>
+
+<ROUTINE PRINT-CONTENTS (OBJ "AUX" F N (1ST? T) (IT? <>) (TWO? <>))
+	 <COND (<SET F <FIRST? .OBJ>>
+		<REPEAT ()
+			<SET N <NEXT? .F>>
+			<COND (.1ST?
+			       <SET 1ST? <>>)
+			      (T
+			       <TELL ",">
+			       <COND (<NOT .N>
+				      <TELL " and">)>)>
+			<ARTICLE .F>
+			<COND (<AND <NOT .IT?>
+				    <NOT .TWO?>>
+			       <SET IT? .F>)
+			      (T
+			       <SET TWO? T>
+			       <SET IT? <>>)>
+			<SET F .N>
+			<COND (<NOT .F>
+			       <COND (<AND .IT? <NOT .TWO?>>
+				      <SETG P-IT-OBJECT .IT?>)>
+			       <RTRUE>)>>)>>
+
+<ROUTINE FIRSTER (OBJ LEVEL)
+	 <COND (<EQUAL? .OBJ ,WINNER>
+		<RTRUE>)
+	       (<NOT <IN? .OBJ ,ROOMS>>
+		<COND (<G? .LEVEL 0>
+		       <TELL <GET ,INDENTS .LEVEL>>)>
+		<COND (<FSET? .OBJ ,SURFACEBIT>
+		       <TELL "Sitting on the " D .OBJ " is:" CR>)
+		      (<AND <FSET? .OBJ ,ACTORBIT>
+			    <NOT <EQUAL? .OBJ ,NUTRIMAT>>>
+		       <TELL ,IT-LOOKS-LIKE>
+		       <ARTICLE .OBJ T>
+		       <TELL " is holding:" CR>)
+		      (T
+		       <TELL ,IT-LOOKS-LIKE>
+		       <ARTICLE .OBJ T>
+		       <TELL " contains:" CR>)>)>>
+
+<ROUTINE DESCRIBE-VEHICLE () ;"for LOOK AT vehicle when you're in it"
+	 <MOVE ,PROTAGONIST ,ROOMS>
+	 <COND (<FIRST? ,PRSO>
+		<PRINT-CONT ,PRSO>)
+	       (T
+		<TELL "It's empty (not counting you)." CR>)>
+	 <MOVE ,PROTAGONIST ,PRSO>>
+
+
+;"subtitle movement and death"
+
+<CONSTANT REXIT 0>
+<CONSTANT UEXIT 1>
+<CONSTANT NEXIT 2>
+<CONSTANT FEXIT 3>
+<CONSTANT CEXIT 4>
+<CONSTANT DEXIT 5>
+
+<CONSTANT NEXITSTR 0>
+<CONSTANT FEXITFCN 0>
+<CONSTANT CEXITFLAG 1>
+<CONSTANT CEXITSTR 1>
+<CONSTANT DEXITOBJ 1>
+<CONSTANT DEXITSTR 1>
+
+<ROUTINE GOTO (RM "OPTIONAL" (V? T))
+	 <MOVE ,PROTAGONIST .RM>
+	 <SETG HERE .RM>
+	 <COND (<NOT <EQUAL? ,HERE ,DARK>>
+		<MOVE ,NAME ,HERE>)>
+	 <SETG LIT <LIT? ,HERE>>
+	 <UNPLUG-HELD-STUFF>
+	 <APPLY <GETP ,HERE ,P?ACTION> ,M-ENTER>
+	 <COND (<AND .V?
+		     <EQUAL? ,HERE .RM>>
+		<V-FIRST-LOOK>)>
+	 <RTRUE>>
+
+<ROUTINE UNPLUG-HELD-STUFF ()
+	 <COND (<AND ,DRIVE-TO-CONTROLS
+		     <HELD? ,SPARE-DRIVE>>
+		<SETG DRIVE-TO-CONTROLS <>>
+		<FCLEAR ,SPARE-DRIVE ,NDESCBIT>
+		<TELL "(unplugging the spare drive first)" CR>)>
+	 <COND (<AND <HOLDING-ONE-BUT-NOT-BOTH? ,SPARE-DRIVE ,PLOTTER>
+		     ,DRIVE-TO-PLOTTER>
+		<SETG DRIVE-TO-PLOTTER <>>
+		<TELL "(disconnecting the short cord first)" CR>)>
+	 <COND (<AND <HOLDING-ONE-BUT-NOT-BOTH? ,BROWNIAN-SOURCE ,PLOTTER>
+		     ,BROWNIAN-SOURCE>
+		<SETG BROWNIAN-SOURCE <>>
+		<REMOVING-BIT>)>>
+
+<ROUTINE JIGS-UP (DESC)
+	 <TELL .DESC>	       
+	 <COND (,DREAMING
+		<TELL " Everything becomes..." CR CR>
+		<COND (<EQUAL? ,IDENTITY-FLAG ,FORD>
+		       <ROB ,PROTAGONIST ,LOCAL-GLOBALS>
+		       <COND (<GET ,FORD-TABLE 4>
+			      <FSET ,THUMB ,MUNGEDBIT>)>
+		       <ROB ,MEMORIAL ,PROTAGONIST>
+		       <MOVE ,SATCHEL <GET ,FORD-TABLE 0>>
+		       <MOVE ,THUMB <GET ,FORD-TABLE 1>>
+		       <MOVE ,GUIDE <GET ,FORD-TABLE 2>>
+		       <MOVE ,TOWEL <GET ,FORD-TABLE 3>>
+		       <MOVE ,MINERAL-WATER <GET ,FORD-TABLE 5>>
+		       <COND (<NOT <FSET? ,COUNTRY-LANE ,REVISITBIT>>
+		       	      <MOVE ,SATCHEL-FLUFF ,SATCHEL>)>
+		       <FCLEAR ,SATCHEL ,OPENBIT>
+		       <FCLEAR ,COUNTRY-LANE ,NDESCBIT>
+		       <SETG TOWEL-OFFERED <>>
+		       <SETG GONE-AROUND <>>
+		       <DISABLE <INT I-ARTHUR>>
+		       <LEAVE-EARTH>)
+		      (<EQUAL? ,IDENTITY-FLAG ,TRILLIAN>
+		       <MOVE ,HANDBAG <GET ,PARTY-TABLE 0>>
+		       <COND (<IN? ,TWEEZERS ,HANDBAG>
+			      <MOVE ,TWEEZERS <GET ,PARTY-TABLE 1>>)>
+		       <COND (<GET ,PARTY-TABLE 2>
+			      <FSET ,HANDBAG ,OPENBIT>)
+			     (T
+			      <FCLEAR ,HANDBAG ,OPENBIT>)>
+		       <COND (<NOT <FSET? ,LIVING-ROOM ,REVISITBIT>>
+			      <MOVE ,JACKET-FLUFF ,LOCAL-GLOBALS>
+			      <FSET ,JACKET-FLUFF ,TRYTAKEBIT>
+			      <FSET ,JACKET-FLUFF ,NDESCBIT>
+			      <SETG FLUFF-REMOVED <>>
+			      <FCLEAR ,HOSTESS ,NDESCBIT>)>
+		       <ROB ,RAMP ,HANDBAG>
+		       <FCLEAR ,LIVING-ROOM ,TOUCHBIT>
+		       <FCLEAR ,HANDBAG ,NDESCBIT>
+		       <FCLEAR ,WINE ,NDESCBIT>
+		       <FCLEAR ,APPETIZERS ,NDESCBIT>
+		       <MOVE ,WINE ,LOCAL-GLOBALS>
+		       <MOVE ,APPETIZERS ,LOCAL-GLOBALS>
+		       <SETG TRILLIAN-PROB 10>
+		       <SETG ITEM-DROPPED-AT-PARTY <>>
+		       <DISABLE <INT I-ARTHUR>>
+		       <DISABLE <INT I-ZAPHOD>>
+		       <DISABLE <INT I-HOSTESS>>)
+		      (<EQUAL? ,IDENTITY-FLAG ,ZAPHOD>
+		       <SETG BOAT-DOCKED <>>
+		       <SETG BOAT-COUNTER 0>
+		       <SETG CRASH-COUNTER 0>
+		       <SETG DAIS-COUNTER 0>
+		       <MOVE ,GUARDS ,LOCAL-GLOBALS>
+		       <MOVE ,BLASTER ,LOCAL-GLOBALS>
+		       <MOVE ,RIFLES ,LOCAL-GLOBALS>
+		       <FCLEAR ,SPEEDBOAT ,TOUCHBIT>
+		       <FSET ,RIFLES ,NDESCBIT>
+		       <DISABLE <INT I-GUARDS>>
+		       <DISABLE <INT I-SPEEDBOAT>>
+		       <COND (<NOT <FSET? ,SPEEDBOAT ,REVISITBIT>>
+			      <MOVE ,TOOLBOX ,SPEEDBOAT>
+			      <MOVE ,CUSHION-FLUFF ,LOCAL-GLOBALS>
+			      <MOVE ,KEY ,LOCAL-GLOBALS>)>
+		       <ROB ,PROTAGONIST ,LOCAL-GLOBALS>)
+		      (<EQUAL? ,HERE ,INSIDE-WHALE> ;"remove non-worn items"
+		       <ROB ,INSIDE-WHALE ,BULLDOZER>
+		       <MOVE ,WHALE-OBJECT ,INSIDE-WHALE>
+		       <COND (<NOT <HELD? ,FLOWERPOT ,THING>>
+			      <MOVE ,FLOWERPOT ,HERE>)>
+		       <ROB ,PROTAGONIST ,BULLDOZER>
+		       <FCLEAR ,INSIDE-WHALE ,TOUCHBIT>
+		       <COND (<AND <IN? ,GOWN ,BULLDOZER>
+				   <FSET? ,GOWN ,WORNBIT>>
+			      <MOVE ,GOWN ,PROTAGONIST>)>
+		       <COND (<IN? ,BABEL-FISH ,BULLDOZER>
+			      <MOVE ,BABEL-FISH ,PROTAGONIST>)>)
+		      (<EQUAL? ,HERE ,WAR-CHAMBER ,MAZE>
+		       <DISABLE <INT I-DOG>>
+		       <FCLEAR ,WAR-CHAMBER ,TOUCHBIT>
+		       <MOVE ,THIRD-PLANET ,LOCAL-GLOBALS>
+		       <SETG DOG-COUNTER 0>
+		       <COND (<EQUAL? ,HERE ,WAR-CHAMBER>
+			      <ROB ,WAR-CHAMBER ,LOCAL-GLOBALS>
+			      <MOVE ,AWL ,HERE>
+			      <MOVE ,GGUGVUNT ,HERE>
+			      <MOVE ,VLHURG ,HERE>
+			      <MOVE ,CANOPY ,HERE>
+			      <MOVE ,MICROSCOPIC-FLEET ,HERE>
+			      <MOVE ,OTHER-PLANETS ,HERE>
+			      <FCLEAR ,VLHURG ,MUNGEDBIT>)>)
+		      (<EQUAL? ,HERE ,LAIR ,INNER-LAIR ,OUTER-LAIR>
+		       <FCLEAR ,BEAST ,MUNGEDBIT>
+		       <SETG BEAST-COUNTER 0>
+		       <SETG BEARINGS-LOST <>>
+		       <SETG NAME-TOLD <>>
+		       <FCLEAR ,TOWEL ,WORNBIT>
+		       <FCLEAR ,LAIR ,NDESCBIT>
+		       <MOVE ,STONE ,OUTER-LAIR>
+		       <MOVE ,BEAST ,LAIR>
+		       <DISABLE <INT I-BEAST>>)>
+		<SETG TEA-COUNTER 0>
+		<MOVE ,MAIN-DRIVE ,GLOBAL-OBJECTS>
+		<SETG HEART-PROB 100>
+		<GOTO ,DARK>)
+	       (T
+		<TELL CR CR
+"    ****  You have died  ****" CR CR>
+		<FINISH>)>>
+
+
+;"subtitle useful utility routines"
+
+<ROUTINE ACCESSIBLE? (OBJ "AUX" (L <LOC .OBJ>)) ;"can player TOUCH object?"
+	 ;"revised 5/2/84 by SEM and SWG"
+	 <COND (<FSET? .OBJ ,INVISIBLE>
+		<RFALSE>)
+	       (<EQUAL? .OBJ ,PSEUDO-OBJECT>
+		<COND (<EQUAL? ,LAST-PSEUDO-LOC ,HERE>
+		       <RTRUE>)
+		      (T
+		       <RFALSE>)>)
+	       (<NOT .L>
+		<RFALSE>)
+	       (<EQUAL? .L ,GLOBAL-OBJECTS>
+		<RTRUE>)	       
+	       (<AND <EQUAL? .L ,LOCAL-GLOBALS>
+		     <GLOBAL-IN? .OBJ ,HERE>>
+		<RTRUE>)
+	       (<NOT <EQUAL? <META-LOC .OBJ> ,HERE>>
+		<RFALSE>)
+	       (<EQUAL? .L ,WINNER ,HERE>
+		<RTRUE>)
+	       (<AND <FSET? .L ,OPENBIT>
+		     <ACCESSIBLE? .L>>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE VISIBLE? (OBJ "AUX" (L <LOC .OBJ>)) ;"can player SEE object"
+	 ;"revised 5/2/84 by SEM and SWG"
+	 <COND (<ACCESSIBLE? .OBJ>
+		<RTRUE>)
+	       (<AND <SEE-INSIDE? .L>
+		     <VISIBLE? .L>>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE META-LOC (OBJ)
+	 <REPEAT ()
+		 <COND (<NOT .OBJ>
+			<RFALSE>)
+		       (<IN? .OBJ ,GLOBAL-OBJECTS>
+			<RETURN ,GLOBAL-OBJECTS>)>
+		 <COND (<IN? .OBJ ,ROOMS>
+			<RETURN .OBJ>)
+		       (T
+			<SET OBJ <LOC .OBJ>>)>>>
+
+<ROUTINE OTHER-SIDE (DOBJ "AUX" (P 0) TEE) ;"finds room on others side of door"
+	 <REPEAT ()
+		 <COND (<L? <SET P <NEXTP ,HERE .P>> ,LOW-DIRECTION>
+			<RETURN <>>)
+		       (T
+			<SET TEE <GETPT ,HERE .P>>
+			<COND (<AND <EQUAL? <PTSIZE .TEE> ,DEXIT>
+				    <EQUAL? <GETB .TEE ,DEXITOBJ> .DOBJ>>
+			       <RETURN .P>)>)>>>
+
+<ROUTINE HELD? (OBJ "OPTIONAL" (CONT <>))
+	 <COND (<NOT .CONT>
+		<SET CONT ,WINNER>)>
+	 <COND (<NOT .OBJ>
+		<RFALSE>)
+	       (<IN? .OBJ .CONT>
+		<RTRUE>)
+	       (<IN? .OBJ ,ROOMS>
+		<RFALSE>)
+	       (<IN? .OBJ ,GLOBAL-OBJECTS>
+		<RFALSE>)
+	       (T
+		<HELD? <LOC .OBJ> .CONT>)>>
+
+<ROUTINE SEE-INSIDE? (OBJ)
+	 <AND <NOT <FSET? .OBJ ,INVISIBLE>>
+	      <OR <FSET? .OBJ ,TRANSBIT>
+	          <FSET? .OBJ ,OPENBIT>>>>
+
+<ROUTINE GLOBAL-IN? (OBJ1 OBJ2 "AUX" TEE)
+	 <COND (<SET TEE <GETPT .OBJ2 ,P?GLOBAL>>
+		<ZMEMQB .OBJ1 .TEE <- <PTSIZE .TEE> 1>>)>>
+
+<ROUTINE FIND-IN (WHERE WHAT "AUX" W)
+	 <SET W <FIRST? .WHERE>>
+	 <COND (<NOT .W>
+		<RFALSE>)>
+	 <REPEAT ()
+		 <COND (<FSET? .W .WHAT>
+			<RETURN .W>)
+		       (<NOT <SET W <NEXT? .W>>>
+			<RETURN <>>)>>>
+
+<ROUTINE LOC-CLOSED ()
+	 <COND (<AND <FSET? <LOC ,PRSO> ,CONTBIT>
+		     <NOT <FSET? <LOC ,PRSO> ,OPENBIT>>
+		     <FSET? ,PRSO ,TAKEBIT>>
+		<TELL "But">
+		<ARTICLE <LOC ,PRSO> T>
+		<TELL " is closed!" CR>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE DO-WALK (DIR)
+	 <SETG P-WALK-DIR .DIR>
+	 <PERFORM ,V?WALK .DIR>>
+
+<ROUTINE FUCKING-CLEAR ()
+	 <SETG P-CONT <>>
+	 <SETG QUOTE-FLAG <>>
+	 <RFATAL>>
+
+<ROUTINE ROB (WHO "OPTIONAL" (WHERE <>) "AUX" N X)
+	 <SET X <FIRST? .WHO>>
+	 <REPEAT ()
+		 <COND (<NOT .X>
+			<RETURN>)>
+		 <SET N <NEXT? .X>>
+		 <MOVE .X .WHERE>
+		 <SET X .N>>>
+
+<ROUTINE HOLDING-ONE-BUT-NOT-BOTH? (ONE TWO)
+	 <COND (<AND <HELD? .ONE>
+		     <HELD? .TWO>>
+		<RFALSE>)
+	       (<HELD? .ONE>
+		<RTRUE>)
+	       (<HELD? .TWO>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<ROUTINE HACK-HACK (STR)
+	 <TELL .STR>
+	 <ARTICLE ,PRSO T>
+	 <TELL <PICK-ONE ,HO-HUM> CR>>
+
+<ROUTINE ARTICLE (OBJ "OPTIONAL" (THE <>))
+	 <COND (<NOT .OBJ>
+		<SET OBJ ,NOT-HERE-OBJECT>)>
+	 <COND (<NOT <FSET? .OBJ ,NARTICLEBIT>>
+		<COND (.THE
+		       <TELL " the">)
+		      (<FSET? .OBJ ,VOWELBIT>
+		       <TELL " an">)
+		      (T
+		       <TELL " a">)>)>
+	 <TELL " " D .OBJ>>
+
+<GLOBAL HO-HUM
+	<PLTABLE
+	 " doesn't do anything."
+	 " accomplishes nothing."
+	 " has no desirable effect.">>		 
+
+<GLOBAL YUKS
+	<PLTABLE
+	 "What a concept."
+         "Nice try."
+	 "You can't be serious."
+	 "Not bloody likely.">>
+
+<GLOBAL IMPOSSIBLES
+	<PLTABLE
+	 "You have lost your mind."
+	 "You are clearly insane."
+	 "You appear to have gone barking mad."
+	 "I'm not convinced you're allowed to be playing with this computer."
+	 "Run out on the street and say that. See what happens."
+	 "No, no, a thousand times no. Go boil an egg.">>
+
+<GLOBAL WASTES
+	<PLTABLE
+	  "Complete waste of time."
+	  "Useless. Utterly useless."
+	  "A totally unhelpful idea.">>
\ No newline at end of file
diff --git a/vogon.zil b/vogon.zil
new file mode 100644
index 0000000..329e97a
--- /dev/null
+++ b/vogon.zil
@@ -0,0 +1,884 @@
+"VOGON for
+		  THE HITCHHIKER'S GUIDE TO THE GALAXY
+	(c) Copyright 1984 Infocom, Inc.  All Rights Reserved."
+
+<OBJECT MINERAL-WATER
+	(IN SATCHEL)
+	(DESC "Santraginean Mineral Water")
+	(LDESC "There is a bottle of mineral water here.")
+	(SYNONYM BOTTLE WATER)
+	(ADJECTIVE SANTRA MINERA)
+	(FLAGS NARTICLEBIT DRINKBIT TAKEBIT)
+	(GENERIC MINERAL-WATER)
+	(ACTION MINERAL-WATER-F)>
+
+<ROUTINE MINERAL-WATER-F ()
+	 <COND (<VERB? DRINK DRINK-FROM>
+		<TELL
+"Bad idea. Even Santraginus Five seawater is illegal on most planets. (You can
+imagine what kind of beach communities they have.)" CR>)
+	       (<VERB? LOOK-INSIDE>
+		<PERFORM ,V?EXAMINE ,PRSO>
+		<RTRUE>)
+	       (<VERB? OPEN CLOSE>
+		<TELL
+"This is one of those clever new always-open always-closed bottles." CR>)
+	       (<VERB? POUR THROW>
+		<LIQUID-SPILL>)>>
+
+<ROOM HOLD
+      (IN ROOMS)
+      (SYNONYM PROTEI)
+      (DESC "Vogon Hold")
+      (WEST "The door to the corridor is locked (from the outside).")
+      (EAST TO AIRLOCK IF VOGON-INNER-DOOR IS OPEN) ;"shouldn't happen"
+      (FLAGS RLANDBIT ONBIT)
+      (GLOBAL VOGON-INNER-DOOR AIRLOCK-OBJECT FLEET HOLD-FURNISHINGS)
+      (PSEUDO "WEAPON" WEAPON-PSEUDO)
+      (ACTION HOLD-F)>
+
+<ROUTINE HOLD-F (RARG)
+	 <COND (<AND <EQUAL? .RARG ,M-END>
+		     <NOT <FSET? ,HOLD ,NDESCBIT>>>
+		<FSET ,HOLD ,NDESCBIT>
+		<FSET ,PEANUTS ,TAKEBIT>
+		<FCLEAR ,PEANUTS ,NDESCBIT>
+		<FCLEAR ,PEANUTS ,TRYTAKEBIT>
+		<MOVE ,PEANUTS ,PROTAGONIST>
+		<MOVE ,FORD ,HERE>
+		<MOVE ,MINERAL-WATER ,FORD>
+		<SETG GROGGY T>
+		<ENABLE <QUEUE I-GROGGY 3>>
+		<ENABLE <QUEUE I-FORD 6>>
+		<ENABLE <QUEUE I-ANNOUNCEMENT 18>>
+		<ENABLE <QUEUE I-GUARDS 36>>
+		<SETG LINE-NUMBER <RANDOM 6>>
+		<SETG WORD-NUMBER <RANDOM 3>>
+		<SETG SCORE <+ ,SCORE 8>>
+		<SETG P-IT-OBJECT ,PEANUTS>
+		<CRLF>
+		<TELL
+"Ford removes the bottle of " D ,MINERAL-WATER " which he's been waving under
+your nose. He tells you that you are aboard a Vogon spaceship, and gives you
+some peanuts." CR>)
+	       (<AND <EQUAL? .RARG ,M-END>
+		     <FSET? ,HOLD ,REVISITBIT>>
+		<SETG DREAMING T>
+		<JIGS-UP
+"A pair of Vogon guards stand nearby, waving acrid-smelling stun guns an inch
+away from your face. Simultaneously, they fire.">
+		<RTRUE>)
+	       (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is a squalid room filled with grubby mattresses, unwashed cups, and
+unidentifiable bits of smelly alien underwear. A door lies to port, and an
+airlock lies to starboard.">
+		<COND (,GOWN-HUNG
+		       <TELL " Your gown is hanging from a hook">
+		       <COND (<NOT <FSET? ,TOWEL ,SURFACEBIT>>
+			      <TELL ".">)>)>
+		<COND (<FSET? ,TOWEL ,SURFACEBIT>
+		       <COND (,GOWN-HUNG
+			      <TELL " and a ">)
+			     (T
+			      <TELL " A ">)>
+		       <TELL "towel is draped over a drain on the floor.">)>
+		<COND (<AND ,PANEL-BLOCKER
+			    <NOT <EQUAL? ,PANEL-BLOCKER ,SATCHEL>>>
+		       <TELL
+" Resting in front of a " D ,ROBOT-PANEL " at the base of one wall is">
+		       <ARTICLE ,PANEL-BLOCKER>
+		       <TELL ".">)>
+		<CRLF>)>>
+
+<OBJECT HOLD-FURNISHINGS
+	(IN LOCAL-GLOBALS)
+	(DESC "it")
+	(SYNONYM MATTRE CUPS CUP UNDERW)
+	(ADJECTIVE GRUBBY UNWASH UNIDEN SMELLY ALIEN)
+	(FLAGS NDESCBIT NARTICLEBIT)
+	(ACTION UNIMPORTANT-THING-F)>
+
+<ROUTINE I-GROGGY ()
+	 <ENABLE <QUEUE I-GROGGY -1>>
+	 <SETG GROGGY-COUNTER <+ ,GROGGY-COUNTER 1>>
+	 <COND (<NOT ,GROGGY>
+		<DISABLE <INT I-GROGGY>>
+		<SETG GROGGY-COUNTER 0>
+		<RFALSE>)>
+	 <CRLF>
+	 <COND (<EQUAL? ,GROGGY-COUNTER 1 2>
+		<TELL "You begin to feel ">
+		<COND (<EQUAL? ,GROGGY-COUNTER 2>
+		       <TELL "in">)>
+		<TELL "distinctly groggy." CR>)
+	       (<EQUAL? ,GROGGY-COUNTER 3>
+		<TELL "You begin to feel very indistinct." CR>)
+	       (T
+		<TELL
+"Your serious allergic reaction to protein loss from" ,BEAM "s becomes a cause
+celebre amongst various holistic pressure groups in the Galaxy and leads to a
+total ban on dematerialisation. Within fifty years, space travel is replaced by
+a keen interest in old furniture restoration and market gardening. In this new,
+quieter Galaxy, the art of telepathy flourishes as never before, creating a new
+universal harmony which brings all life together, converts all matter into
+thought and brings about the rebirth of the entire Universe on a higher and
+better plane of existence.|
+|
+However, none of this affects you, because you are dead." CR>
+		<FINISH>)>>
+
+<GLOBAL GROGGY-COUNTER 0>
+
+<GLOBAL GOWN-HUNG <>>
+
+<GLOBAL PANEL-BLOCKER <>>
+
+<GLOBAL ITEM-ON-SATCHEL <>>
+
+<GLOBAL FISH-COUNTER 5>
+
+<OBJECT DISPENSER
+	(IN HOLD)
+	(DESC "babel fish dispenser")
+	(LDESC "Along one wall is a tall dispensing machine.")
+	(SYNONYM DISPEN MACHIN SLOT)
+	(ADJECTIVE DISPEN BABEL FISH TALL VENDIN)
+	(ACTION DISPENSER-F)>
+
+<ROUTINE DISPENSER-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL
+"The dispenser is tall, has a button at around eye-level, and says \"Babel
+Fish\" in large letters. Anything dispensed would probably come out the slot
+at around knee-level.">
+		<FINE-PRODUCT>
+		<CRLF>)
+	       (<AND <VERB? PUT-IN-FRONT>
+		     <PRSO? ,HEAD ,EARS>>
+		<SETG LYING-DOWN T>
+		<TELL
+"You are now lying down with your ear near the " D ,DISPENSER " slot." CR>)
+	       (<AND <VERB? LIE-DOWN>
+		     ,IN-FRONT-FLAG>
+		<PERFORM ,V?PUT-IN-FRONT ,HEAD ,DISPENSER>
+		<RTRUE>)>>
+
+<OBJECT DISPENSER-BUTTON
+	(IN HOLD)
+	(DESC "dispenser button")
+	(SYNONYM BUTTON)
+	(ADJECTIVE DISPEN SINGLE BABEL FISH)
+	(FLAGS NDESCBIT)
+	(ACTION DISPENSER-BUTTON-F)>
+
+<ROUTINE DISPENSER-BUTTON-F ()
+ <COND (<VERB? PUSH>
+	<COND (,LYING-DOWN
+	       <TELL "You can't reach it from down here." CR>
+	       <RTRUE>)
+	      (<EQUAL? ,FISH-COUNTER 0>
+	       <TELL "Click." CR>
+	       <RTRUE>)>
+	<SETG FISH-COUNTER <- ,FISH-COUNTER 1>>
+	<TELL
+"A single " D ,BABEL-FISH " shoots out of the slot. It sails across the
+room and ">
+	<COND (<NOT ,GOWN-HUNG>
+	       <TELL
+"through a " D ,FISH-HOLE " in the wall, just under a " D ,HOOK "." CR>)
+	      (T
+	       <TELL "hits the dressing gown. The fish slides down the ">
+	       <COND (,SLEEVE-TIED
+		      <TELL "inside (nice try, though)">)
+		     (T
+		      <TELL "sleeve">)>
+	       <TELL " of the gown and falls to the floor, ">
+	       <COND (<NOT <FSET? ,TOWEL ,SURFACEBIT>>
+		      <TELL
+"vanishing through the grating of a hitherto unnoticed drain." CR>)
+		     (T
+		      <TELL
+"landing on the towel. A split-second later, a tiny cleaning robot whizzes
+across the floor, grabs the fish, and continues its breakneck pace toward
+a " D ,ROBOT-PANEL " at the base of the wall. ">
+		      <COND (<NOT ,PANEL-BLOCKER>
+			     <TELL
+"The robot zips through the panel, and is gone." CR>)
+			    (<NOT <EQUAL? ,PANEL-BLOCKER ,SATCHEL>>
+			     <TELL "The robot zips around">
+			     <ARTICLE ,PANEL-BLOCKER>
+			     <TELL ", through the panel, and is gone." CR>)
+			    (T
+			     <TELL
+"The robot plows into the satchel, sending the " D ,BABEL-FISH>
+			     <COND
+			      (<AND <NOT <EQUAL? ,ITEM-ON-SATCHEL ,MAIL>>
+				    ,ITEM-ON-SATCHEL>
+			       <TELL " and">
+			       <ARTICLE ,ITEM-ON-SATCHEL T>)>
+			     <TELL
+" flying through the air in a graceful arc">
+			     <COND
+			      (<NOT <EQUAL? ,ITEM-ON-SATCHEL ,MAIL>>
+			       <TELL
+". " ,ROBOT-FLIES-IN "catches the " D ,BABEL-FISH " ">
+			       <COND (,ITEM-ON-SATCHEL
+				      <MOVE ,ITEM-ON-SATCHEL ,LOCAL-GLOBALS>
+				      <TELL "and also manages to catch">
+				      <ARTICLE ,ITEM-ON-SATCHEL T>
+				      <SETG ITEM-ON-SATCHEL <>>)
+				     (T
+				      <TELL
+"(which is all the flying junk it can find)">)>
+			       <TELL ", and exits." CR>)
+			      (<EQUAL? ,ITEM-ON-SATCHEL ,MAIL>
+			       <MOVE ,MAIL ,LOCAL-GLOBALS>
+			       <SETG SCORE <+ ,SCORE 12>>
+			       <MOVE ,BABEL-FISH ,PROTAGONIST>
+			       <COND (<RUNNING? ,I-ANNOUNCEMENT>
+				      <ENABLE <QUEUE I-GUARDS 4>>)
+				     (T
+				      <ENABLE <QUEUE I-ANNOUNCEMENT 4>>
+				      <ENABLE <QUEUE I-GUARDS 7>>)>
+			       <SETG FISH-COUNTER 0>
+			       <SETG ITEM-ON-SATCHEL <>>
+			       <TELL
+" surrounded by a cloud of junk mail. Another robot flies in and begins madly
+collecting the cluttered plume of mail. The " D ,BABEL-FISH " continues its
+flight, landing with a loud \"squish\" in your ear." CR>)>)>)>)>)>>
+
+<OBJECT FISH-HOLE
+	(IN HOLD)
+	(DESC "small hole")
+	(SYNONYM HOLE)
+	(ADJECTIVE SMALL)
+	(FLAGS NDESCBIT)
+	(ACTION FISH-HOLE-F)>
+
+<ROUTINE FISH-HOLE-F ()
+	 <COND (<VERB? LOOK-INSIDE>
+		<TELL "You see only " D ,DARK-OBJECT "." CR>)
+	       (<AND <VERB? PUT>
+		     <PRSI? ,FISH-HOLE>>
+		<COND (<FSET? ,PRSO ,INTEGRALBIT>
+		       <PART-OF>)
+		      (<L? <GETP ,PRSO ,P?SIZE> 5>
+		       <MOVE ,PRSO ,LOCAL-GLOBALS>
+		       <TELL "It falls through the hole and vanishes." CR>)
+		      (T
+		       <TELL "It doesn't fit through the hole." CR>)>)
+	       (<AND <VERB? PUT-ON PUT-IN-FRONT>
+		     <PRSI? ,FISH-HOLE>>
+		<COND (<PRSO? ,HANDS ,EARS ,ME ,HEAD>
+		       <PERFORM ,V?STAND-BEFORE ,FISH-HOLE>
+		       <RTRUE>)>
+		<PERFORM ,V?HANG ,PRSO ,HOOK>
+		<RTRUE>)
+	       (<AND <VERB? BLOCK-WITH SPUT-ON>
+		     <PRSO? ,FISH-HOLE>>
+		<PERFORM ,V?HANG ,PRSI ,HOOK>
+		<RTRUE>)
+	       (<VERB? BLOCK>
+		<PERFORM ,V?STAND-BEFORE ,FISH-HOLE>
+		<RTRUE>)
+	       (<AND <VERB? LIE-DOWN>
+		     ,IN-FRONT-FLAG>
+		<PERFORM ,V?STAND-BEFORE ,FISH-HOLE>
+		<RTRUE>)>>
+
+<OBJECT HOOK
+	(IN HOLD)
+	(DESC "metal hook")
+	(SYNONYM HOOK)
+	(ADJECTIVE METAL)
+	(FLAGS NDESCBIT)
+	(ACTION HOOK-F)>
+
+<ROUTINE HOOK-F ()
+	 <COND (<VERB? EXAMINE>
+		<COND (,GOWN-HUNG
+		       <TELL "Your gown is hanging from it." CR>)
+		      (T
+		       <TELL
+"The hook is attached to the wall, inches above a tiny hole." CR>)>)
+	       (<VERB? HANG PUT-ON>
+		<COND (,LYING-DOWN
+		       <TELL ,WHILE-LYING CR>)
+		      (<PRSO?,GOWN>
+		       <COND (<FSET? ,GOWN ,WORNBIT>
+			      <IDROP>
+			      <RTRUE>)>
+		       <SETG GOWN-HUNG T>
+		       <MOVE ,GOWN ,HERE>
+		       <FSET ,GOWN ,NDESCBIT>
+		       <FSET ,GOWN ,TRYTAKEBIT>
+		       <FCLEAR ,GOWN ,OPENBIT>
+		       <TELL
+"The gown is now hanging from the hook, covering a tiny hole." CR>)
+		      (<PRSO? ,HANDS ,EARS ,HEAD>
+		       <PERFORM ,V?STAND-BEFORE ,HOOK>
+		       <RTRUE>)
+		      (<FSET? ,PRSO ,TAKEBIT>
+		       <COND (<FSET? ,PRSO ,TRYTAKEBIT>
+			      <TELL ,NOT-HOLDING>
+			      <ARTICLE ,PRSO T>
+			      <TELL "." CR>)
+			     (T
+		       	      <MOVE ,PRSO ,HERE>
+		       	      <TELL "It slips off the hook." CR>)>)
+		      (T
+		       <V-COUNT>)>)>>
+
+<OBJECT DRAIN
+	(IN HOLD)
+	(DESC "drain")
+	(SYNONYM DRAIN GRATING GRATE)
+	(FLAGS NDESCBIT)
+	(ACTION DRAIN-F)>
+
+<ROUTINE DRAIN-F ()
+	 <COND (<VERB? PUT-ON>
+		<COND (<FSET? ,TOWEL ,SURFACEBIT>
+		       <TELL "The drain is already covered by the towel." CR>)
+		      (,LYING-DOWN
+		       <TELL ,WHILE-LYING CR>)
+		      (<PRSO?,TOWEL>
+		       <FSET ,TOWEL ,CONTBIT>
+		       <FSET ,TOWEL ,SURFACEBIT>
+		       <FSET ,TOWEL ,OPENBIT>
+		       <FSET ,TOWEL ,NDESCBIT>
+		       <FSET ,TOWEL ,TRYTAKEBIT>
+		       <MOVE ,TOWEL ,HERE>
+		       <PERFORM ,V?EXAMINE ,DRAIN>
+		       <RTRUE>)
+		      (T
+		       <TELL "The drain is too large to be covered by">
+		       <ARTICLE ,PRSO T>
+		       <TELL "." CR>)>)
+	       (<VERB? LOOK-INSIDE>
+		<PERFORM ,V?LOOK-INSIDE ,FISH-HOLE>
+		<RTRUE>)
+	       (<AND <VERB? EXAMINE>
+		     <FSET? ,TOWEL ,SURFACEBIT>>
+		<TELL "The towel completely covers the drain." CR>)>> 
+
+<OBJECT ROBOT-PANEL
+	(IN HOLD)
+	(DESC "tiny robot panel")
+	(SYNONYM PANEL)
+	(ADJECTIVE ROBOT TINY)
+	(FLAGS NDESCBIT)
+	(ACTION ROBOT-PANEL-F)>
+
+<ROUTINE ROBOT-PANEL-F ()
+	 <COND (<VERB? EXAMINE CLOSE>
+		<TELL
+"The panel, only a few inches high, is currently closed." CR>)
+	       (<VERB? OPEN>
+		<TELL ,BUDGE CR>)
+	       (<VERB? BLOCK>
+		<SETG AWAITING-REPLY 6>
+		<ENABLE <QUEUE I-REPLY 2>>
+		<TELL "With " D ,HANDS "s? By force of will?" CR>)
+	       (<AND <VERB? LIE-DOWN>
+		     ,IN-FRONT-FLAG>
+		<PERFORM ,V?STAND-BEFORE ,ROBOT-PANEL>
+		<RTRUE>)
+	       (<AND <VERB? PUT-IN-FRONT PUT-IN-FRONT PUT-ON>
+		     <PRSI? ,ROBOT-PANEL>>
+		<PERFORM ,V?BLOCK-WITH ,ROBOT-PANEL ,PRSO>
+		<RTRUE>)
+	       (<AND <VERB? BLOCK-WITH SPUT-ON>
+			 <PRSO? ,ROBOT-PANEL>>
+		<COND (<PRSI? ,HEAD ,HANDS ,EARS ,EYES>
+		       <V-COUNT>)
+		      (<NOT <HELD? ,PRSI>>
+		       <TELL ,NOT-HOLDING>
+		       <ARTICLE ,PRSI T>
+		       <TELL "." CR>)
+		      (,PANEL-BLOCKER
+		       <TELL "But">
+		       <ARTICLE ,PANEL-BLOCKER T>
+		       <TELL
+" is already in front of the " D ,ROBOT-PANEL "." CR>)
+		      (,LYING-DOWN
+		       <TELL ,WHILE-LYING CR>)
+		      (T
+		       <MOVE ,PRSI ,HERE>
+		       <SETG PANEL-BLOCKER ,PRSI>
+		       <FSET ,PRSI ,TRYTAKEBIT>
+		       <TELL "Okay,">
+		       <COND (<PRSI? ,SATCHEL>
+			      <TELL " the satchel is lying on its side">)
+			     (T
+			      <FSET ,PRSI ,NDESCBIT>
+			      <ARTICLE ,PRSI T>
+			      <TELL " is sitting">)>
+		       <TELL " in front of the " D ,ROBOT-PANEL "." CR>)>)>>
+
+<OBJECT BABEL-FISH
+	(IN LOCAL-GLOBALS) ;"just for the purpose of MOBY-FIND"
+	(DESC "babel fish")
+	(SYNONYM FISH)
+	(ADJECTIVE BABEL)
+	(FLAGS TAKEBIT)
+	(ACTION BABEL-FISH-F)>
+
+<ROUTINE BABEL-FISH-F ()
+	 <COND (<VERB? TAKE REMOVE>
+		<TELL
+"That would be foolish. Having a " D ,BABEL-FISH " in your ear is terribly
+useful." CR>)>>
+
+<OBJECT GLASS-CASE
+	(IN HOLD)
+	(DESC "glass case")
+	(LDESC "In the corner is a glass case with a switch and a keyboard.")
+	(SYNONYM CASE LID GLASS)
+	(ADJECTIVE GLASS)
+	(SIZE 40)
+	(FLAGS CONTBIT TRANSBIT SEARCHBIT)
+	(ACTION GLASS-CASE-F)>
+
+<GLOBAL GLASS-CASE-SCORE <>>
+
+<ROUTINE GLASS-CASE-F ()
+	 <COND (<VERB? EXAMINE>
+		<TELL "The " D ,GLASS-CASE " is ">
+		<COND (<FSET? ,GLASS-CASE ,OPENBIT>
+		       <TELL "open">)
+		      (T
+		       <TELL "closed">)>
+		<TELL
+". Attached to it are a " D ,KEYBOARD " and a switch." CR>)
+	       (<AND <VERB? OPEN>
+		     <NOT <FSET? ,GLASS-CASE ,OPENBIT>>>
+		<TELL ,BUDGE CR>)
+	       (<VERB? MUNG>
+		<TELL
+"The hold of the Vogon ship is virtually undamaged by the explosion
+of the " D ,GLASS-CASE>
+		<JIGS-UP
+". You, however, are blasted into tiny bits and smeared all over the room.
+Several cleaning robots fly in and wipe you neatly off the walls.">
+		<RTRUE>)>>
+
+<ROUTINE GLASS-CASE-OPENS () ;"see V-TYPE"
+	 <COND (<FSET? ,GLASS-CASE ,OPENBIT>
+		<TELL "Nothing happens." CR>
+		<FUCKING-CLEAR>)
+	       (T
+		<FSET ,GLASS-CASE ,OPENBIT>
+		<TELL "The " D ,GLASS-CASE " opens." CR>
+		<FCLEAR ,PLOTTER ,TRYTAKEBIT>
+		<COND (<NOT ,GLASS-CASE-SCORE>
+		       <SETG GLASS-CASE-SCORE T>
+		       <SETG SCORE <+ ,SCORE 25>>)>
+		<FUCKING-CLEAR>)>>
+
+<OBJECT KEYBOARD
+	(IN HOLD)
+	(DESC "keyboard")
+	(SYNONYM KEYBOA)
+	(FLAGS NDESCBIT TRYTAKEBIT)>
+
+<OBJECT CASE-SWITCH
+	(IN HOLD)
+	(DESC "switch")
+	(SYNONYM SWITCH)
+	(FLAGS NDESCBIT SWITCHBIT)
+	(ACTION CASE-SWITCH-F)>
+
+<ROUTINE CASE-SWITCH-F ()
+	 <COND (<VERB? LAMP-ON TURN PUSH MOVE THROW>
+		<COND (<HELD? ,BABEL-FISH>
+		       <TELL
+"A recording plays: \"To open the case, type in the ">
+		       <COND (<EQUAL? ,WORD-NUMBER 1>
+			      <TELL "first">)
+			     (<EQUAL? ,WORD-NUMBER 2>
+			      <TELL "second">)
+			     (<EQUAL? ,WORD-NUMBER 3>
+			      <TELL "third">)>
+		       <TELL
+" word from the second verse of the Captain's current favourite poem.
+WARNING: An incorrect input will cause the case to explode.\"" CR>)
+		      (T
+		       <TELL "A recording plays: \"A">
+		       <PRODUCE-GIBBERISH 5>
+		       <CRLF>)>)>>
+
+<ROUTINE PRODUCE-GIBBERISH (N "AUX" GIBBERISH-COUNTER SUPER-COUNTER)
+	 <SET SUPER-COUNTER 0>
+	 <REPEAT ()
+		 <SET SUPER-COUNTER <+ .SUPER-COUNTER 1>>
+		 <SET GIBBERISH-COUNTER 0>
+		 <REPEAT ()
+			 <SET GIBBERISH-COUNTER <+ .GIBBERISH-COUNTER 1>>
+			 <TELL <PICK-ONE ,GIBBERISH>>
+			 <COND (<EQUAL? .GIBBERISH-COUNTER 10>
+				<COND (<NOT <EQUAL? .SUPER-COUNTER .N>>
+				       <TELL " o">)>
+				<RETURN>)>>
+		 <COND (<EQUAL? .SUPER-COUNTER .N>
+			<TELL ".\"">
+			<RETURN>)>>>
+
+<ROUTINE I-ANNOUNCEMENT ()
+	 <ENABLE <QUEUE I-ANNOUNCEMENT -1>>
+	 <TELL CR "An announcement is coming over the ship's intercom. \"">
+	 <COND (<HELD? ,BABEL-FISH ,PROTAGONIST>
+		<TELL
+"This is the Captain. My instruments show that we've picked up a couple of
+hitchhikers. I hate freeloaders, and when my guards find you I'll have you
+thrown into space. On second thought, maybe I'll read you some of my poetry
+first. Repeating...\"" CR>)
+	       (T
+		<TELL "E">
+		<PRODUCE-GIBBERISH 10>
+		<CRLF>)>>
+
+<GLOBAL GIBBERISH
+	<PLTABLE
+"toy" "r g" "irb" "kwa" "o s"
+"fim" "p w" "osh" "flu" "a r"
+"vup" "d t" "imb" "tha" "i l"
+"cav" "s g" "ulp" "cho" "u n"
+"zit" "z z" "eft" "qui" "e h"
+"kon" "l m" "ork" "gry" "o t"
+"huv" "x j" "erl" "tru" "a b"
+"fud" "w c" "oll" "wro" "i s">>
+
+<ROUTINE I-GUARDS ()
+	 <COND (<EQUAL? ,HERE ,HOLD>
+		<DISABLE <INT I-ANNOUNCEMENT>>
+		<TELL CR
+"Guards burst in and grab you and Ford, who comes slowly awake. They drag you
+down the corridor to a large cabin, where they strap you into large, menacing
+chairs..." CR CR>
+		<SETG HERE ,CAPTAINS-QUARTERS>
+		<MOVE ,NAME ,HERE>
+		<SETG LYING-DOWN <>>
+		<ENABLE <QUEUE I-CAPTAIN 2>>
+		<SETG FORD-SLEEPING <>>
+		<FSET ,FORD ,NDESCBIT>
+		<MOVE ,PROTAGONIST ,POETRY-APPRECIATION-CHAIR>
+		<V-LOOK>
+		<MOVE ,FORD ,HERE>
+		<MOVE ,GUARDS ,HERE>)
+	       (<NOT <IN? ,RIFLES ,LOCAL-GLOBALS>>
+		<TELL CR ,GUARDS-REALIZE "They">
+		<GUARD-DEATH>
+		<RTRUE>)
+	       (T
+		<RFALSE>)>>
+
+<ROOM CAPTAINS-QUARTERS
+      (IN ROOMS)
+      (DESC "Captain's Quarters")
+      (FLAGS RLANDBIT ONBIT)
+      (PSEUDO "WEAPON" WEAPON-PSEUDO "STRAPS" UNIMPORTANT-THING-F)
+      (GLOBAL FLEET)
+      (ACTION CAPTAINS-QUARTERS-F)>
+
+<ROUTINE CAPTAINS-QUARTERS-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-LOOK>
+		<TELL
+"This is the cabin of the " D ,VOGON-CAPTAIN ". You and Ford are strapped
+into " D ,POETRY-APPRECIATION-CHAIR "s." CR>)>>
+
+<OBJECT POETRY-APPRECIATION-CHAIR
+	(IN CAPTAINS-QUARTERS)
+	(DESC "poetry appreciation chair")
+	(SYNONYM CHAIR CHAIRS SEAT)
+	(ADJECTIVE POETRY APPREC FORMID LARGE MENACI)
+	(FLAGS VEHBIT OPENBIT SEARCHBIT SURFACEBIT CONTBIT)
+	(ACTION POETRY-APPRECIATION-CHAIR-F)>
+
+<ROUTINE POETRY-APPRECIATION-CHAIR-F ("OPTIONAL" (RARG <>))
+	 <COND (.RARG
+		<RFALSE>)
+	       (<VERB? DISEMBARK WALK LEAP WALK-AROUND>
+		<SETG AWAITING-REPLY 7>
+		<ENABLE <QUEUE I-REPLY 2>>
+		<TELL "You're strapped in, remember?" CR>)
+	       (<AND <VERB? OPEN CLOSE>
+		     <PRSO? ,POETRY-APPRECIATION-CHAIR>>
+		<TELL-ME-HOW>)>> 
+
+<OBJECT VOGON-CAPTAIN
+	(IN CAPTAINS-QUARTERS)
+	(DESC "Vogon Captain")
+	(LDESC
+"The Captain is indescribably hideous, indescribably blubbery,
+and indescribably mid-to-dark green. He is holding samples of his
+favourite poetry.")
+	(SYNONYM CAPTAIN VOGONS)
+	(ADJECTIVE VOGON)
+	(FLAGS ACTORBIT)
+	(ACTION VOGON-CAPTAIN-F)>
+
+<ROUTINE VOGON-CAPTAIN-F ()
+	 <COND (<OR <VERB? TELL HELLO THANK>
+		    <AND <VERB? ASK-ABOUT ASK-FOR>
+			 <EQUAL? ,VOGON-CAPTAIN ,PRSO>>>
+		<TELL
+"One of the guards lightly bashes your skull with the butt of his weapon">
+		<COND (<HELD? ,BABEL-FISH>
+		       <TELL
+". \"This is a poetry appreciation session, prisoner. No talking!\"" CR>)
+		      (T
+		       <TELL " and says, \"A">
+		       <PRODUCE-GIBBERISH 2>
+		       <CRLF>)>
+		<FUCKING-CLEAR>)
+	       (<AND <IN? ,POETRY ,HERE>
+		     <VERB? BLOCK>>
+		<PERFORM ,V?LISTEN ,POETRY>
+		<RTRUE>)>> 
+
+<GLOBAL CAPTAIN-COUNTER 0>
+
+<ROUTINE I-CAPTAIN ()
+	 <ENABLE <QUEUE I-CAPTAIN -1>>
+	 <SETG CAPTAIN-COUNTER <+ ,CAPTAIN-COUNTER 1>>
+         <CRLF>
+	 <COND (<EQUAL? ,CAPTAIN-COUNTER 1>
+		<TELL
+"\"If he's going to read us his poetry,\" mutters Ford, sweating profusely,
+\"just pray he softens us up with some cudgels first...\"" CR CR>)>
+	 <COND (<NOT <HELD? ,BABEL-FISH ,PROTAGONIST>>
+		<TELL "The " D ,VOGON-CAPTAIN " says, \"O">
+		<PRODUCE-GIBBERISH 2>
+		<COND (<EQUAL? ,CAPTAIN-COUNTER 6>
+		       <GUARDS-TO-AIRLOCK>)
+		      (T
+		       <CRLF>)>)
+	       (<EQUAL? ,CAPTAIN-COUNTER 1>
+		<TELL
+"\"Hello, hitchhikers!\" begins the " D ,VOGON-CAPTAIN ". \"I've decided to
+read you a verse of my poetry!\"" CR>)
+	       (<EQUAL? ,CAPTAIN-COUNTER 2>
+		<TELL
+"\"Oh freddled gruntbuggly, thy nacturations are to me!\"" CR>)
+	       (<EQUAL? ,CAPTAIN-COUNTER 3>
+		<TELL
+"\"As plurdled gabbleblotchits on a lurgid bee.\"" CR>)
+	       (<EQUAL? ,CAPTAIN-COUNTER 4>
+		<TELL
+"\"Groop I implore thee, my foonting turlingdromes.\"" CR>)
+	       (<EQUAL? ,CAPTAIN-COUNTER 5>
+		<TELL
+"\"And hooptiously drangle me with crinkly bindlewurdles, or I will rend
+thee in the gobberwarts with my blurglecruncheon, see if I don't!\"" CR>)
+	       (<EQUAL? ,CAPTAIN-COUNTER 6>
+		<COND (,POEM-ENJOYED
+		       <TELL
+"\"You looked like you enjoyed my poem. I think...yes, I think I'll read
+the NEXT verse, also!\"" CR>)
+		      (T
+		       <TELL
+"\"You didn't seem to enjoy my poem at all! Guards, toss
+them out the airlock!\"">
+		       <GUARDS-TO-AIRLOCK>)>)
+	       (<EQUAL? ,CAPTAIN-COUNTER 7>
+		<COND (<EQUAL? ,LINE-NUMBER 1 2>
+		       <TELL ,LINE-A CR>)
+		      (<EQUAL? ,LINE-NUMBER 3 4>
+		       <TELL ,LINE-B CR>)
+		      (T
+		       <TELL ,LINE-C CR>)>)
+	       (<EQUAL? ,CAPTAIN-COUNTER 8>
+		<COND (<EQUAL? ,LINE-NUMBER 3 5>
+		       <TELL ,LINE-A CR>)
+		      (<EQUAL? ,LINE-NUMBER 1 6>
+		       <TELL ,LINE-B CR>)
+		      (T
+		       <TELL ,LINE-C CR>)>)
+	       (<EQUAL? ,CAPTAIN-COUNTER 9>
+		<COND (<EQUAL? ,LINE-NUMBER 4 6>
+		       <TELL ,LINE-A CR>)
+		      (<EQUAL? ,LINE-NUMBER 2 5>
+		       <TELL ,LINE-B CR>)
+		      (T
+		       <TELL ,LINE-C CR>)>)
+	       (<EQUAL? ,CAPTAIN-COUNTER 10>
+		<TELL
+"\"Gerond withoutitude form into formless bloit, why not then? Moose.\"" CR>)
+	       (<EQUAL? ,CAPTAIN-COUNTER 11>
+		<TELL
+"\"Since you have somehow managed to survive two verses of my poetry, I have
+no choice but to space you. Guards!\"">
+		<GUARDS-TO-AIRLOCK>)>>
+
+<GLOBAL LINE-A "\"Fripping lyshus wimbgunts, awhilst moongrovenly kormzibs.\"">
+
+<GLOBAL LINE-B "\"Gashee morphousite, thou expungiest quoopisk!\"">
+
+<GLOBAL LINE-C
+"\"Bleem miserable venchit! Bleem forever mestinglish asunder frapt.\"">
+
+<GLOBAL LINE-NUMBER 0>
+
+;"The line order is set randomly from 1 to 6, with the following result:
+	1	Line A, Line B, Line C
+	2	Line A, Line C, Line B
+	3	Line B, Line A, Line C
+	4	Line B, Line C, Line A
+	5	Line C, Line A, Line B
+	6	Line C, Line B, Line A"
+
+<GLOBAL WORD-NUMBER 0> ;"randomly set between one and three"
+
+<ROUTINE GUARDS-TO-AIRLOCK ()
+	 <DISABLE <INT I-CAPTAIN>>
+	 <TELL
+" A guard grabs you and Ford, and drags you toward the hold. Ford whispers,
+\"Don't worry, I'll think of something!\"" CR CR>
+	 <FCLEAR ,HOLD ,TOUCHBIT>
+	 <GOTO ,HOLD>
+	 <FCLEAR ,FORD ,NDESCBIT>
+	 <MOVE ,GUARDS ,HERE>
+	 <MOVE ,FORD ,HERE>
+	 <ENABLE <QUEUE I-FORD 1>>>
+
+<OBJECT POETRY
+	(IN CAPTAINS-QUARTERS)
+	(DESC "Vogon poetry")
+	(SYNONYM POETRY POEM SAMPLE VERSE)
+	(ADJECTIVE VOGON FIRST SECOND)
+	(FLAGS NDESCBIT NARTICLEBIT DARKBIT)
+	(ACTION POETRY-F)>
+
+<GLOBAL POEM-ENJOYED <>>
+
+<GLOBAL AIRLOCK-COUNTER 0>
+
+<ROUTINE POETRY-F ()
+	 <COND (<AND <VERB? ENJOY LISTEN>
+		     <L? ,CAPTAIN-COUNTER 2>>
+		<TELL "The " D ,VOGON-CAPTAIN " hasn't begun yet!" CR>)
+	       (<VERB? ENJOY>
+		<COND (<NOT <HELD? ,BABEL-FISH>>
+		       <TELL
+"You can't even understand it, let alone enjoy it!" CR>)
+		      (,POEM-ENJOYED
+		       <SETG AWAITING-REPLY 8>
+		       <ENABLE <QUEUE I-REPLY 2>>
+		       <TELL "Hey, let's not overdo it, okay?" CR>)
+		      (T
+		       <SETG POEM-ENJOYED T>
+		       <SETG SCORE <+ ,SCORE 15>>
+		       <TELL
+"You realise that, although the " D ,POETRY " is indeed astoundingly bad,
+worse things happen at sea, and in fact, at school. With an effort for which
+Hercules himself would have patted you on the back, you grit your teeth and
+enjoy the stuff." CR>)>)
+	       (<VERB? LISTEN>
+		<TELL "You have no choice. Why not relax and enjoy it?" CR>)
+	       (<AND <IN? ,POETRY ,HERE>
+		     <VERB? BLOCK>>
+		<PERFORM ,V?LISTEN ,POETRY>
+		<RTRUE>)
+	       (<VERB? READ EXAMINE>
+		<TELL "You can't see it from here." CR>)>>
+
+<OBJECT VOGON-CORRIDOR-DOOR
+	(IN HOLD)
+	(DESC "corridor door")
+	(SYNONYM DOOR)
+	(ADJECTIVE CORRID)
+	(FLAGS DOORBIT NDESCBIT)
+	(ACTION VOGON-CORRIDOR-DOOR-F)>
+
+<ROUTINE VOGON-CORRIDOR-DOOR-F ()
+	 <COND (<VERB? OPEN UNLOCK THROUGH>
+		<DO-WALK ,P?WEST>)>>
+
+<OBJECT VOGON-INNER-DOOR
+	(IN LOCAL-GLOBALS)
+	(DESC "inner door")
+	(SYNONYM DOOR)
+	(ADJECTIVE INNER AIRLOC MASSIV)
+	(FLAGS VOWELBIT NDESCBIT DOORBIT)
+	(ACTION VOGON-AIRLOCK-DOOR-F)>
+
+<OBJECT VOGON-OUTER-DOOR
+	(IN LOCAL-GLOBALS)
+	(DESC "outer door")
+	(SYNONYM DOOR)
+	(ADJECTIVE OUTER AIRLOC MASSIV)
+	(FLAGS VOWELBIT NDESCBIT DOORBIT)
+	(ACTION VOGON-AIRLOCK-DOOR-F)>
+
+<ROUTINE VOGON-AIRLOCK-DOOR-F ()
+	 <COND (<VERB? OPEN THROUGH>
+		<TELL ,BUDGE CR>)>>
+
+<OBJECT AIRLOCK-OBJECT
+	(IN LOCAL-GLOBALS)
+	(DESC "airlock")
+	(SYNONYM AIRLOC)
+	(FLAGS VOWELBIT)
+	(ACTION AIRLOCK-OBJECT-F)>
+
+<ROUTINE AIRLOCK-OBJECT-F ()
+	 <COND (<VERB? THROUGH WALK-TO>
+		<COND (<EQUAL? ,HERE ,AIRLOCK>
+		       <TELL ,LOOK-AROUND CR>)
+		      (<EQUAL? ,HERE ,HOLD>
+		       <DO-WALK ,P?WEST>)>)
+	       (<VERB? LEAVE EXIT DISEMBARK>
+		<COND (<EQUAL? ,HERE ,AIRLOCK>
+		       <DO-WALK ,P?EAST>)
+		      (T
+		       <TELL ,LOOK-AROUND CR>)>)>>
+
+<OBJECT EQUATIONS
+	(IN LOCAL-GLOBALS)
+	(DESC "it")
+	(SYNONYM EQUATI NUMBER PENCIL)
+	(FLAGS NDESCBIT NARTICLEBIT)
+	(ACTION UNIMPORTANT-THING-F)>
+
+<ROOM AIRLOCK
+      (IN ROOMS)
+      (SYNONYM BETELG)
+      (DESC "Airlock")
+      (LDESC "This airlock has massive doors to port and starboard.")
+      (WEST TO HOLD IF VOGON-INNER-DOOR IS OPEN) ;"this should never happen"
+      (EAST TO HOLD IF VOGON-OUTER-DOOR IS OPEN) ;"ditto"
+      (FLAGS RLANDBIT ONBIT)
+      (GLOBAL VOGON-INNER-DOOR VOGON-OUTER-DOOR AIRLOCK-OBJECT FLEET EQUATIONS)
+      (ACTION AIRLOCK-F)>
+
+<ROUTINE AIRLOCK-F (RARG)
+	 <COND (<EQUAL? .RARG ,M-END>
+		<SETG AIRLOCK-COUNTER <+ ,AIRLOCK-COUNTER 1>>
+		<CRLF>
+		<COND (<EQUAL? ,AIRLOCK-COUNTER 1>
+		       <TELL
+"Ford points at the " D ,VOGON-OUTER-DOOR ". \"In about two minutes, it will
+open and we'll be ejected into the vacuum of space. But don't panic, I'll
+think of something.\"" CR>)
+		      (<EQUAL? ,AIRLOCK-COUNTER 2>
+		       <TELL "Ford is mumbling to himself." CR>)
+		      (<EQUAL? ,AIRLOCK-COUNTER 3>
+		       <TELL
+"Ford produces a pencil and begins scribbling equations on the wall." CR>)
+		      (<EQUAL? ,AIRLOCK-COUNTER 4>
+		       <TELL
+"Ford's eyes light up. \"Do you still have the Electronic Sub-Etha Auto
+Hitching Thu...\" At that moment, the airlock door opens, and you and Ford
+are blown out into space.||">
+		       <COND (<HELD? ,GUIDE>
+			      <TELL
+"Your elbow must have struck some key on " D ,GUIDE " because it begins
+droning out an entry, coincidentally enough the entry on SPACE. \""
+,SPACE-TEXT "\" (Footnote 9)" CR CR>)>
+		       <TELL
+"Precisely twenty-nine seconds later, you and Ford are scooped up by a passing
+ship. Gasping for air, you pass out..." CR CR>
+		       <SETG HEART-PROB 100>
+		       <GOTO ,DARK>)>)>>
\ No newline at end of file